src/liblzma/check/crc32_x86.S

   1 /*
   2  * Speed-optimized CRC32 using slicing-by-eight algorithm
   3  *
   4  * This uses only i386 instructions, but it is optimized for i686 and later
   5  * (including e.g. Pentium II/III/IV, Athlon XP, and Core 2). For i586
   6  * (e.g. Pentium), slicing-by-four would be better, and even the C version
   7  * of slicing-by-eight built with gcc -march=i586 tends to be a little bit
   8  * better than this. Very few probably run this code on i586 or older x86
   9  * so this shouldn't be a problem in practice.
  10  *
  11  * Authors: Igor Pavlov (original version)
  12  *          Lasse Collin (AT&T syntax, PIC support, better portability)
  13  *
  14  * This file has been put into the public domain.
  15  * You can do whatever you want with this file.
  16  *
  17  * This code needs lzma_crc32_table, which can be created using the
  18  * following C code:
  19
  20 uint32_t lzma_crc32_table[8][256];
  21
  22 void
  23 init_table(void)
  24 {
  25         // IEEE-802.3
  26         static const uint32_t poly32 = UINT32_C(0xEDB88320);
  27
  28         // Castagnoli
  29         // static const uint32_t poly32 = UINT32_C(0x82F63B78);
  30
  31         // Koopman
  32         // static const uint32_t poly32 = UINT32_C(0xEB31D82E);
  33
  34         for (size_t s = 0; s < 8; ++s) {
  35                 for (size_t b = 0; b < 256; ++b) {
  36                         uint32_t r = s == 0 ? b : lzma_crc32_table[s - 1][b];
  37
  38                         for (size_t i = 0; i < 8; ++i) {
  39                                 if (r & 1)
  40                                         r = (r >> 1) ^ poly32;
  41                                 else
  42                                         r >>= 1;
  43                         }
  44
  45                         lzma_crc32_table[s][b] = r;
  46                 }
  47         }
  48 }
  49
  50  * The prototype of the CRC32 function:
  51  * extern uint32_t lzma_crc32(const uint8_t *buf, size_t size, uint32_t crc);
  52  */
  53
  54 /*
  55  * On some systems, the functions need to be prefixed. The prefix is
  56  * usually an underscore.
  57  */
  58 #ifndef __USER_LABEL_PREFIX__
  59 #       define __USER_LABEL_PREFIX__
  60 #endif
  61 #define MAKE_SYM_CAT(prefix, sym) prefix ## sym
  62 #define MAKE_SYM(prefix, sym) MAKE_SYM_CAT(prefix, sym)
  63 #define LZMA_CRC32 MAKE_SYM(__USER_LABEL_PREFIX__, lzma_crc32)
  64 #define LZMA_CRC32_TABLE MAKE_SYM(__USER_LABEL_PREFIX__, lzma_crc32_table)
  65
  66 /*
  67  * Solaris assembler doesn't have .p2align, and Darwin uses .align
  68  * differently than GNU/Linux and Solaris.
  69  */
  70 #if defined(__MACH__) || defined(__MSDOS__)
  71 #       define ALIGN(pow2, abs) .align pow2
  72 #else
  73 #       define ALIGN(pow2, abs) .align abs
  74 #endif
  75
  76         .text
  77         .globl  LZMA_CRC32
  78
  79 #if !defined(__MACH__) && !defined(_WIN32) && !defined(__CYGWIN__) \
  80                 && !defined(__MSDOS__)
  81         .type   LZMA_CRC32, @function
  82 #endif
  83
  84         ALIGN(4, 16)
  85 LZMA_CRC32:
  86         /*
  87          * Register usage:
  88          * %eax crc
  89          * %esi buf
  90          * %edi size or buf + size
  91          * %ebx lzma_crc32_table
  92          * %ebp Table index
  93          * %ecx Temporary
  94          * %edx Temporary
  95          */
  96         pushl   %ebx
  97         pushl   %esi
  98         pushl   %edi
  99         pushl   %ebp
 100         movl    0x14(%esp), %esi /* buf */
 101         movl    0x18(%esp), %edi /* size */
 102         movl    0x1C(%esp), %eax /* crc */
 103
 104         /*
 105          * Store the address of lzma_crc32_table to %ebx. This is needed to
 106          * get position-independent code (PIC).
 107          *
 108          * The PIC macro is defined by libtool, while __PIC__ is defined
 109          * by GCC but only on some systems. Testing for both makes it simpler
 110          * to test this code without libtool, and keeps the code working also
 111          * when built with libtool but using something else than GCC.
 112          */
 113 #if !defined(PIC) && !defined(__PIC__)
 114         /* Not PIC */
 115         movl    $LZMA_CRC32_TABLE, %ebx
 116 #elif defined(__MACH__)
 117         /* Mach-O */
 118         call    .L_get_pc
 119 .L_pic:
 120         leal    .L_lzma_crc32_table$non_lazy_ptr-.L_pic(%ebx), %ebx
 121         movl    (%ebx), %ebx
 122 #else
 123         /* ELF */
 124         call    .L_get_pc
 125         addl    $_GLOBAL_OFFSET_TABLE_, %ebx
 126         movl    LZMA_CRC32_TABLE@GOT(%ebx), %ebx
 127 #endif
 128
 129         /* Complement the initial value. */
 130         notl    %eax
 131
 132         ALIGN(4, 16)
 133 .L_align:
 134         /*
 135          * Check if there is enough input to use slicing-by-eight.
 136          * We need 16 bytes, because the loop pre-reads eight bytes.
 137          */
 138         cmpl    $16, %edi
 139         jl      .L_rest
 140
 141         /* Check if we have reached alignment of eight bytes. */
 142         testl   $7, %esi
 143         jz      .L_slice
 144
 145         /* Calculate CRC of the next input byte. */
 146         movzbl  (%esi), %ebp
 147         incl    %esi
 148         movzbl  %al, %ecx
 149         xorl    %ecx, %ebp
 150         shrl    $8, %eax
 151         xorl    (%ebx, %ebp, 4), %eax
 152         decl    %edi
 153         jmp     .L_align
 154
 155         ALIGN(2, 4)
 156 .L_slice:
 157         /*
 158          * If we get here, there's at least 16 bytes of aligned input
 159          * available. Make %edi multiple of eight bytes. Store the possible
 160          * remainder over the "size" variable in the argument stack.
 161          */
 162         movl    %edi, 0x18(%esp)
 163         andl    $-8, %edi
 164         subl    %edi, 0x18(%esp)
 165
 166         /*
 167          * Let %edi be buf + size - 8 while running the main loop. This way
 168          * we can compare for equality to determine when exit the loop.
 169          */
 170         addl    %esi, %edi
 171         subl    $8, %edi
 172
 173         /* Read in the first eight aligned bytes. */
 174         xorl    (%esi), %eax
 175         movl    4(%esi), %ecx
 176         movzbl  %cl, %ebp
 177
 178 .L_loop:
 179         movl    0x0C00(%ebx, %ebp, 4), %edx
 180         movzbl  %ch, %ebp
 181         xorl    0x0800(%ebx, %ebp, 4), %edx
 182         shrl    $16, %ecx
 183         xorl    8(%esi), %edx
 184         movzbl  %cl, %ebp
 185         xorl    0x0400(%ebx, %ebp, 4), %edx
 186         movzbl  %ch, %ebp
 187         xorl    (%ebx, %ebp, 4), %edx
 188         movzbl  %al, %ebp
 189
 190         /*
 191          * Read the next four bytes, for which the CRC is calculated
 192          * on the next interation of the loop.
 193          */
 194         movl    12(%esi), %ecx
 195
 196         xorl    0x1C00(%ebx, %ebp, 4), %edx
 197         movzbl  %ah, %ebp
 198         shrl    $16, %eax
 199         xorl    0x1800(%ebx, %ebp, 4), %edx
 200         movzbl  %ah, %ebp
 201         movzbl  %al, %eax
 202         movl    0x1400(%ebx, %eax, 4), %eax
 203         addl    $8, %esi
 204         xorl    %edx, %eax
 205         xorl    0x1000(%ebx, %ebp, 4), %eax
 206
 207         /* Check for end of aligned input. */
 208         cmpl    %edi, %esi
 209         movzbl  %cl, %ebp
 210         jne     .L_loop
 211
 212         /*
 213          * Process the remaining eight bytes, which we have already
 214          * copied to %ecx and %edx.
 215          */
 216         movl    0x0C00(%ebx, %ebp, 4), %edx
 217         movzbl  %ch, %ebp
 218         xorl    0x0800(%ebx, %ebp, 4), %edx
 219         shrl    $16, %ecx
 220         movzbl  %cl, %ebp
 221         xorl    0x0400(%ebx, %ebp, 4), %edx
 222         movzbl  %ch, %ebp
 223         xorl    (%ebx, %ebp, 4), %edx
 224         movzbl  %al, %ebp
 225
 226         xorl    0x1C00(%ebx, %ebp, 4), %edx
 227         movzbl  %ah, %ebp
 228         shrl    $16, %eax
 229         xorl    0x1800(%ebx, %ebp, 4), %edx
 230         movzbl  %ah, %ebp
 231         movzbl  %al, %eax
 232         movl    0x1400(%ebx, %eax, 4), %eax
 233         addl    $8, %esi
 234         xorl    %edx, %eax
 235         xorl    0x1000(%ebx, %ebp, 4), %eax
 236
 237         /* Copy the number of remaining bytes to %edi. */
 238         movl    0x18(%esp), %edi
 239
 240 .L_rest:
 241         /* Check for end of input. */
 242         testl   %edi, %edi
 243         jz      .L_return
 244
 245         /* Calculate CRC of the next input byte. */
 246         movzbl  (%esi), %ebp
 247         incl    %esi
 248         movzbl  %al, %ecx
 249         xorl    %ecx, %ebp
 250         shrl    $8, %eax
 251         xorl    (%ebx, %ebp, 4), %eax
 252         decl    %edi
 253         jmp     .L_rest
 254
 255 .L_return:
 256         /* Complement the final value. */
 257         notl    %eax
 258
 259         popl    %ebp
 260         popl    %edi
 261         popl    %esi
 262         popl    %ebx
 263         ret
 264
 265 #if defined(PIC) || defined(__PIC__)
 266         ALIGN(4, 16)
 267 .L_get_pc:
 268         movl    (%esp), %ebx
 269         ret
 270 #endif
 271
 272 #if defined(__MACH__) && (defined(PIC) || defined(__PIC__))
 273         /* Mach-O PIC */
 274         .section __IMPORT,__pointers,non_lazy_symbol_pointers
 275 .L_lzma_crc32_table$non_lazy_ptr:
 276         .indirect_symbol LZMA_CRC32_TABLE
 277         .long 0
 278
 279 #elif defined(_WIN32) || defined(__CYGWIN__)
 280 #       ifdef DLL_EXPORT
 281         /* This is equivalent of __declspec(dllexport). */
 282         .section .drectve
 283         .ascii " -export:lzma_crc32"
 284 #       endif
 285
 286 #elif !defined(__MSDOS__)
 287         /* ELF */
 288         .size   LZMA_CRC32, .-LZMA_CRC32
 289 #endif
 290
 291 /*
 292  * This is needed to support non-executable stack. It's ugly to
 293  * use __linux__ here, but I don't know a way to detect when
 294  * we are using GNU assembler.
 295  */
 296 #if defined(__ELF__) && defined(__linux__)
 297         .section        .note.GNU-stack,"",@progbits
 298 #endif