configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 ###############################################################################
   5 #
   6 # Author: Lasse Collin
   7 #
   8 # This file has been put into the public domain.
   9 # You can do whatever you want with this file.
  10 #
  11 ###############################################################################
  12
  13 # NOTE: Don't add useless checks. autoscan detects this and that, but don't
  14 # let it confuse you. For example, we don't care about checking for behavior
  15 # of malloc(), stat(), or lstat(), since we don't use those functions in
  16 # a way that would cause the problems the autoconf macros check.
  17
  18 AC_PREREQ([2.61])
  19
  20 AC_INIT([XZ Utils], m4_esyscmd([/bin/sh version.sh]),
  21         [lasse.collin@tukaani.org], [xz])
  22 AC_CONFIG_SRCDIR([src/liblzma/common/common.h])
  23 AC_CONFIG_AUX_DIR([build-aux])
  24 AC_CONFIG_MACRO_DIR([m4])
  25 AC_CONFIG_HEADER([config.h])
  26
  27 PACKAGE_HOMEPAGE=http://tukaani.org/xz/
  28 AC_DEFINE_UNQUOTED([PACKAGE_HOMEPAGE], ["$PACKAGE_HOMEPAGE"],
  29         [Define to the URL of the home page of this package.])
  30 AC_SUBST([PACKAGE_HOMEPAGE])
  31
  32 echo
  33 echo "$PACKAGE_STRING"
  34
  35 echo
  36 echo "System type:"
  37 # This is needed to know if assembler optimizations can be used.
  38 AC_CANONICAL_HOST
  39
  40 # We do some special things on Windows (32-bit or 64-bit) builds.
  41 case $host_os in
  42         mingw* | cygwin*) is_w32=yes ;;
  43         *)                is_w32=no ;;
  44 esac
  45 AM_CONDITIONAL([COND_W32], [test "$is_w32" = yes])
  46
  47 # We need to use $EXEEXT with $(LN_S) when creating symlinks to
  48 # executables. Cygwin is an exception to this, since it is recommended
  49 # that symlinks don't have the .exe suffix. To make this work, we
  50 # define LN_EXEEXT.
  51 case $host_os in
  52         cygwin)  LN_EXEEXT= ;;
  53         *)       LN_EXEEXT='$(EXEEXT)' ;;
  54 esac
  55 AC_SUBST([LN_EXEEXT])
  56
  57 echo
  58 echo "Configure options:"
  59 AM_CFLAGS=
  60
  61
  62 #############
  63 # Debugging #
  64 #############
  65
  66 AC_MSG_CHECKING([if debugging code should be compiled])
  67 AC_ARG_ENABLE([debug], AC_HELP_STRING([--enable-debug], [Enable debugging code.]),
  68         [], enable_debug=no)
  69 if test "x$enable_debug" = xyes; then
  70         AC_MSG_RESULT([yes])
  71 else
  72         AC_DEFINE([NDEBUG], [1], [Define to 1 to disable debugging code.])
  73         AC_MSG_RESULT([no])
  74 fi
  75
  76
  77 ###########
  78 # Filters #
  79 ###########
  80
  81 m4_define([SUPPORTED_FILTERS], [lzma1,lzma2,subblock,delta,x86,powerpc,ia64,arm,armthumb,sparc])dnl
  82 m4_define([SIMPLE_FILTERS], [x86,powerpc,ia64,arm,armthumb,sparc])
  83 m4_define([LZ_FILTERS], [lzma1,lzma2])
  84
  85 m4_foreach([NAME], [SUPPORTED_FILTERS],
  86 [enable_filter_[]NAME=no
  87 enable_encoder_[]NAME=no
  88 enable_decoder_[]NAME=no
  89 ])dnl
  90
  91 AC_MSG_CHECKING([which encoders to build])
  92 AC_ARG_ENABLE([encoders], AC_HELP_STRING([--enable-encoders=LIST],
  93                 [Comma-separated list of encoders to build. Default=all.
  94                 Available encoders:]
  95                         m4_translit(m4_defn([SUPPORTED_FILTERS]), [,], [ ])),
  96         [], [enable_encoders=SUPPORTED_FILTERS])
  97 enable_encoders=`echo "$enable_encoders" | sed 's/,subblock//; s/,/ /g'`
  98 if test "x$enable_encoders" = xno || test "x$enable_encoders" = x; then
  99         AC_MSG_RESULT([(none)])
 100 else
 101         AC_DEFINE([HAVE_ENCODER], [1],
 102                 [Define to 1 if encoder components are enabled.])
 103         for arg in $enable_encoders
 104         do
 105                 case $arg in m4_foreach([NAME], [SUPPORTED_FILTERS], [
 106                         NAME)
 107                                 enable_filter_[]NAME=yes
 108                                 enable_encoder_[]NAME=yes
 109                                 AC_DEFINE(HAVE_ENCODER_[]m4_toupper(NAME), [1],
 110                                 [Define to 1 if] NAME [encoder is enabled.])
 111                                 ;;])
 112                         *)
 113                                 AC_MSG_RESULT([])
 114                                 AC_MSG_ERROR([unknown filter: $arg])
 115                                 ;;
 116                 esac
 117         done
 118         AC_MSG_RESULT([$enable_encoders])
 119 fi
 120
 121 AC_MSG_CHECKING([which decoders to build])
 122 AC_ARG_ENABLE([decoders], AC_HELP_STRING([--enable-decoders=LIST],
 123                 [Comma-separated list of decoders to build. Default=all.
 124                 Available decoders are the same as available encoders.]),
 125         [], [enable_decoders=SUPPORTED_FILTERS])
 126 enable_decoders=`echo "$enable_decoders" | sed 's/,subblock//; s/,/ /g'`
 127 if test "x$enable_decoders" = xno || test "x$enable_decoders" = x; then
 128         AC_MSG_RESULT([(none)])
 129 else
 130         AC_DEFINE([HAVE_DECODER], [1],
 131                 [Define to 1 if decoder components are enabled.])
 132         for arg in $enable_decoders
 133         do
 134                 case $arg in m4_foreach([NAME], [SUPPORTED_FILTERS], [
 135                         NAME)
 136                                 enable_filter_[]NAME=yes
 137                                 enable_decoder_[]NAME=yes
 138                                 AC_DEFINE(HAVE_DECODER_[]m4_toupper(NAME), [1],
 139                                 [Define to 1 if] NAME [decoder is enabled.])
 140                                 ;;])
 141                         *)
 142                                 AC_MSG_RESULT([])
 143                                 AC_MSG_ERROR([unknown filter: $arg])
 144                                 ;;
 145                 esac
 146         done
 147
 148         # LZMA2 requires that LZMA1 is enabled.
 149         test "x$enable_encoder_lzma2" = xyes && enable_encoder_lzma1=yes
 150         test "x$enable_decoder_lzma2" = xyes && enable_decoder_lzma1=yes
 151
 152         AC_MSG_RESULT([$enable_decoders])
 153 fi
 154
 155 if test "x$enable_encoder_lzma2$enable_encoder_lzma1" = xyesno \
 156                 || test "x$enable_decoder_lzma2$enable_decoder_lzma1" = xyesno; then
 157         AC_MSG_ERROR([LZMA2 requires that LZMA1 is also enabled.])
 158 fi
 159
 160 AM_CONDITIONAL(COND_MAIN_ENCODER, test "x$enable_encoders" != xno && test "x$enable_encoders" != x)
 161 AM_CONDITIONAL(COND_MAIN_DECODER, test "x$enable_decoders" != xno && test "x$enable_decoders" != x)
 162
 163 m4_foreach([NAME], [SUPPORTED_FILTERS],
 164 [AM_CONDITIONAL(COND_FILTER_[]m4_toupper(NAME), test "x$enable_filter_[]NAME" = xyes)
 165 AM_CONDITIONAL(COND_ENCODER_[]m4_toupper(NAME), test "x$enable_encoder_[]NAME" = xyes)
 166 AM_CONDITIONAL(COND_DECODER_[]m4_toupper(NAME), test "x$enable_decoder_[]NAME" = xyes)
 167 ])dnl
 168
 169 # The so called "simple filters" share common code.
 170 enable_filter_simple=no
 171 enable_encoder_simple=no
 172 enable_decoder_simple=no
 173 m4_foreach([NAME], [SIMPLE_FILTERS],
 174 [test "x$enable_filter_[]NAME" = xyes && enable_filter_simple=yes
 175 test "x$enable_encoder_[]NAME" = xyes && enable_encoder_simple=yes
 176 test "x$enable_decoder_[]NAME" = xyes && enable_decoder_simple=yes
 177 ])dnl
 178 AM_CONDITIONAL(COND_FILTER_SIMPLE, test "x$enable_filter_simple" = xyes)
 179 AM_CONDITIONAL(COND_ENCODER_SIMPLE, test "x$enable_encoder_simple" = xyes)
 180 AM_CONDITIONAL(COND_DECODER_SIMPLE, test "x$enable_decoder_simple" = xyes)
 181
 182 # LZ-based filters share common code.
 183 enable_filter_lz=no
 184 enable_encoder_lz=no
 185 enable_decoder_lz=no
 186 m4_foreach([NAME], [LZ_FILTERS],
 187 [test "x$enable_filter_[]NAME" = xyes && enable_filter_lz=yes
 188 test "x$enable_encoder_[]NAME" = xyes && enable_encoder_lz=yes
 189 test "x$enable_decoder_[]NAME" = xyes && enable_decoder_lz=yes
 190 ])dnl
 191 AM_CONDITIONAL(COND_FILTER_LZ, test "x$enable_filter_lz" = xyes)
 192 AM_CONDITIONAL(COND_ENCODER_LZ, test "x$enable_encoder_lz" = xyes)
 193 AM_CONDITIONAL(COND_DECODER_LZ, test "x$enable_decoder_lz" = xyes)
 194
 195
 196 #################
 197 # Match finders #
 198 #################
 199
 200 m4_define([SUPPORTED_MATCH_FINDERS], [hc3,hc4,bt2,bt3,bt4])
 201
 202 m4_foreach([NAME], [SUPPORTED_MATCH_FINDERS],
 203 [enable_match_finder_[]NAME=no
 204 ])
 205
 206 AC_MSG_CHECKING([which match finders to build])
 207 AC_ARG_ENABLE([match-finders], AC_HELP_STRING([--enable-match-finders=LIST],
 208                 [Comma-separated list of match finders to build. Default=all.
 209                 At least one match finder is required for encoding with
 210                 the LZMA1 and LZMA2 filters. Available match finders:]
 211                 m4_translit(m4_defn([SUPPORTED_MATCH_FINDERS]), [,], [ ])), [],
 212         [enable_match_finders=SUPPORTED_MATCH_FINDERS])
 213 enable_match_finders=`echo "$enable_match_finders" | sed 's/,/ /g'`
 214 if test "x$enable_encoder_lz" = xyes ; then
 215         for arg in $enable_match_finders
 216                 do
 217                 case $arg in m4_foreach([NAME], [SUPPORTED_MATCH_FINDERS], [
 218                         NAME)
 219                                 enable_match_finder_[]NAME=yes
 220                                 AC_DEFINE(HAVE_MF_[]m4_toupper(NAME), [1],
 221                                 [Define to 1 to enable] NAME [match finder.])
 222                                 ;;])
 223                         *)
 224                                 AC_MSG_RESULT([])
 225                                 AC_MSG_ERROR([unknown match finder: $arg])
 226                                 ;;
 227                 esac
 228         done
 229         AC_MSG_RESULT([$enable_match_finders])
 230 else
 231         AC_MSG_RESULT([(none because not building any LZ-based encoder)])
 232 fi
 233
 234
 235 ####################
 236 # Integrity checks #
 237 ####################
 238
 239 m4_define([SUPPORTED_CHECKS], [crc32,crc64,sha256])
 240
 241 m4_foreach([NAME], [SUPPORTED_FILTERS],
 242 [enable_check_[]NAME=no
 243 ])dnl
 244
 245 AC_MSG_CHECKING([which integrity checks to build])
 246 AC_ARG_ENABLE([checks], AC_HELP_STRING([--enable-checks=LIST],
 247                 [Comma-separated list of integrity checks to build.
 248                 Default=all. Available integrity checks:]
 249                 m4_translit(m4_defn([SUPPORTED_CHECKS]), [,], [ ])),
 250         [], [enable_checks=SUPPORTED_CHECKS])
 251 enable_checks=`echo "$enable_checks" | sed 's/,/ /g'`
 252 if test "x$enable_checks" = xno || test "x$enable_checks" = x; then
 253         AC_MSG_RESULT([(none)])
 254 else
 255         for arg in $enable_checks
 256         do
 257                 case $arg in m4_foreach([NAME], [SUPPORTED_CHECKS], [
 258                         NAME)
 259                                 enable_check_[]NAME=yes
 260                                 AC_DEFINE(HAVE_CHECK_[]m4_toupper(NAME), [1],
 261                                 [Define to 1 if] NAME
 262                                 [integrity check is enabled.])
 263                                 ;;])
 264                         *)
 265                                 AC_MSG_RESULT([])
 266                                 AC_MSG_ERROR([unknown integrity check: $arg])
 267                                 ;;
 268                 esac
 269         done
 270         AC_MSG_RESULT([$enable_checks])
 271 fi
 272 if test "x$enable_checks_crc32" = xno ; then
 273         AC_MSG_ERROR([For now, the CRC32 check must always be enabled.])
 274 fi
 275
 276 m4_foreach([NAME], [SUPPORTED_CHECKS],
 277 [AM_CONDITIONAL(COND_CHECK_[]m4_toupper(NAME), test "x$enable_check_[]NAME" = xyes)
 278 ])dnl
 279
 280
 281 ###########################
 282 # Assembler optimizations #
 283 ###########################
 284
 285 AC_MSG_CHECKING([if assembler optimizations should be used])
 286 AC_ARG_ENABLE([assembler], AC_HELP_STRING([--disable-assembler],
 287                 [Do not use assembler optimizations even if such exist
 288                 for the architecture.]),
 289         [], [enable_assembler=yes])
 290 if test "x$enable_assembler" = xyes; then
 291         enable_assembler=no
 292         case $host_os in
 293                 # Darwin should work too but only if not creating universal
 294                 # binaries. Solaris x86 could work too but I cannot test.
 295                 linux* | *bsd* | mingw* | cygwin*)
 296                         case $host_cpu in
 297                                 i?86)   enable_assembler=x86 ;;
 298                                 x86_64) enable_assembler=x86_64 ;;
 299                         esac
 300                         ;;
 301         esac
 302 fi
 303 case $enable_assembler in
 304         x86 | x86_64 | no)
 305                 AC_MSG_RESULT([$enable_assembler])
 306                 ;;
 307         *)
 308                 AC_MSG_RESULT([])
 309                 AC_MSG_ERROR([--enable-assembler accepts only \`yes', \`no', \`x86', or \`x86_64'.])
 310                 ;;
 311 esac
 312 AM_CONDITIONAL(COND_ASM_X86, test "x$enable_assembler" = xx86)
 313 AM_CONDITIONAL(COND_ASM_X86_64, test "x$enable_assembler" = xx86_64)
 314
 315
 316 #####################
 317 # Size optimization #
 318 #####################
 319
 320 AC_MSG_CHECKING([if small size is preferred over speed])
 321 AC_ARG_ENABLE([small], AC_HELP_STRING([--enable-small],
 322                 [Make liblzma smaller and a little slower.
 323                 This is disabled by default to optimize for speed.]),
 324         [], [enable_small=no])
 325 if test "x$enable_small" = xyes; then
 326         AC_DEFINE([HAVE_SMALL], [1], [Define to 1 if optimizing for size.])
 327 elif test "x$enable_small" != xno; then
 328         AC_MSG_RESULT([])
 329         AC_MSG_ERROR([--enable-small accepts only \`yes' or \`no'])
 330 fi
 331 AC_MSG_RESULT([$enable_small])
 332 AM_CONDITIONAL(COND_SMALL, test "x$enable_small" = xyes)
 333
 334
 335 #############
 336 # Threading #
 337 #############
 338
 339 AC_MSG_CHECKING([if threading support is wanted])
 340 AC_ARG_ENABLE([threads], AC_HELP_STRING([--disable-threads],
 341                 [Disable threading support.
 342                 This makes some things thread-unsafe.]),
 343         [], [enable_threads=yes])
 344 if test "x$enable_threads" != xyes && test "x$enable_threads" != xno; then
 345         AC_MSG_RESULT([])
 346         AC_MSG_ERROR([--enable-threads accepts only \`yes' or \`no'])
 347 fi
 348 AC_MSG_RESULT([$enable_threads])
 349 # We use the actual result a little later.
 350
 351
 352 #########################
 353 # Assumed amount of RAM #
 354 #########################
 355
 356 # We use 32 MiB as default, because it should be small enough for most
 357 # cases and allows decompressing files compressed with the default settings.
 358 # Probably it is too small for most systems, but it's safer to guess too low.
 359 AC_MSG_CHECKING([how much RAM to assume if the real amount is unknown])
 360 AC_ARG_ENABLE([assume-ram], AC_HELP_STRING([--enable-assume-ram=SIZE],
 361                 [If and only if the real amount of RAM cannot be determined,
 362                 assume SIZE MiB. The default is 32 MiB. This affects the
 363                 default memory usage limit.]),
 364         [], [enable_assume_ram=32])
 365 assume_ram_check=`echo "$enable_assume_ram" | tr -d 0123456789`
 366 if test -z "$enable_assume_ram" || test -n "$assume_ram_check"; then
 367         AC_MSG_RESULT([])
 368         AC_MSG_ERROR([--enable-assume-ram accepts only an integer argument])
 369 fi
 370 AC_MSG_RESULT([$enable_assume_ram MiB])
 371 AC_DEFINE_UNQUOTED([ASSUME_RAM], [$enable_assume_ram],
 372                 [How many MiB of RAM to assume if the real amount cannot
 373                 be determined.])
 374
 375
 376 ############################################
 377 # xz/xzdec/lzmadec linkage against liblzma #
 378 ############################################
 379
 380 # Link the xz, xzdec, and lzmadec command line tools against static liblzma
 381 # unless using --enable-dynamic. Using static liblzma gives a little bit
 382 # faster executable on x86, because no register is wasted for PIC. We also
 383 # have one dependency less, which allows users to more freely copy the xz
 384 # binary to other boxes. However, I wouldn't be surprised if distro
 385 # maintainers still prefer dynamic linking, so let's make it easy for them.
 386
 387 AC_MSG_CHECKING([how programs should be linked against liblzma])
 388 AC_ARG_ENABLE([dynamic], [AC_HELP_STRING([--enable-dynamic=TYPE],
 389                         [Set how command line tools are linked against liblzma.
 390                         TYPE can be mixed, yes, or no. The default is mixed.])],
 391                 [], [enable_dynamic=mixed])
 392 case $enable_dynamic in
 393         mixed)
 394                 AC_MSG_RESULT([mixed (some dynamically, some statically)])
 395                 ;;
 396         yes)
 397                 AC_MSG_RESULT([dynamically])
 398                 ;;
 399         no)
 400                 AC_MSG_RESULT([statically])
 401                 ;;
 402         *)
 403                 AC_MSG_RESULT([])
 404                 AC_MSG_ERROR([--enable-dynamic accepts only \`mixed', \`yes', or \`no'])
 405                 ;;
 406 esac
 407 # We use the actual results later, because we don't know yet
 408 # if --disable-shared or --disable-static was used.
 409
 410
 411 ###############################################################################
 412 # Checks for programs.
 413 ###############################################################################
 414
 415 echo
 416 gl_POSIX_SHELL
 417 if test -z "$POSIX_SHELL" ; then
 418         AC_MSG_ERROR([No POSIX conforming shell (sh) was found.])
 419 fi
 420
 421 echo
 422 echo "Initializing Automake:"
 423
 424 AM_INIT_AUTOMAKE([1.10 foreign tar-v7 filename-length-max=99])
 425 AC_PROG_LN_S
 426
 427 AC_PROG_CC_C99
 428 if test x$ac_cv_prog_cc_c99 = xno ; then
 429         AC_MSG_ERROR([No C99 compiler was found.])
 430 fi
 431
 432 AM_PROG_CC_C_O
 433 AM_PROG_AS
 434 AC_USE_SYSTEM_EXTENSIONS
 435
 436 if test "x$enable_threads" = xyes; then
 437         echo
 438         echo "Threading support:"
 439         ACX_PTHREAD
 440         LIBS="$LIBS $PTHREAD_LIBS"
 441         AM_CFLAGS="$AM_CFLAGS $PTHREAD_CFLAGS"
 442         CC="$PTHREAD_CC"
 443 fi
 444
 445 echo
 446 echo "Initializing Libtool:"
 447 LT_PREREQ([2.2])
 448 LT_INIT([win32-dll])
 449 LT_LANG([Windows Resource])
 450
 451 # This is a bit wrong since it is possible to request that only some libs
 452 # are built as shared. Using that feature isn't so common though, and this
 453 # breaks only on Windows (at least for now) if the user enables only some
 454 # libs as shared.
 455 AM_CONDITIONAL([COND_SHARED], [test "x$enable_shared" != xno])
 456
 457
 458 ###############################################################################
 459 # Checks for libraries.
 460 ###############################################################################
 461
 462 echo
 463 echo "Initializing gettext:"
 464 AM_GNU_GETTEXT_VERSION([0.16.1])
 465 AM_GNU_GETTEXT([external])
 466
 467 ###############################################################################
 468 # Checks for header files.
 469 ###############################################################################
 470
 471 echo
 472 echo "System headers and functions:"
 473
 474 # There is currently no workarounds in this package if some of
 475 # these headers are missing.
 476 AC_CHECK_HEADERS([fcntl.h limits.h sys/time.h],
 477         [],
 478         [AC_MSG_ERROR([Required header file(s) are missing.])])
 479
 480
 481 ###############################################################################
 482 # Checks for typedefs, structures, and compiler characteristics.
 483 ###############################################################################
 484
 485 dnl We don't need these as long as we need a C99 compiler anyway.
 486 dnl AC_C_INLINE
 487 dnl AC_C_RESTRICT
 488
 489 AC_HEADER_STDBOOL
 490
 491 AC_TYPE_UINT8_T
 492 AC_TYPE_UINT16_T
 493 AC_TYPE_INT32_T
 494 AC_TYPE_UINT32_T
 495 AC_TYPE_INT64_T
 496 AC_TYPE_UINT64_T
 497 AC_TYPE_UINTPTR_T
 498
 499 AC_CHECK_SIZEOF([size_t])
 500
 501 # The command line tool can copy high resolution timestamps if such
 502 # information is availabe in struct stat. Otherwise one second accuracy
 503 # is used.
 504 AC_CHECK_MEMBERS([
 505         struct stat.st_atim.tv_nsec,
 506         struct stat.st_atimespec.tv_nsec,
 507         struct stat.st_atimensec,
 508         struct stat.st_uatime,
 509         struct stat.st_atim.st__tim.tv_nsec])
 510
 511 AC_SYS_LARGEFILE
 512 AC_C_BIGENDIAN
 513
 514
 515 ###############################################################################
 516 # Checks for library functions.
 517 ###############################################################################
 518
 519 # Gnulib replacements as needed
 520 gl_GETOPT
 521
 522 # Find the best function to set timestamps.
 523 AC_CHECK_FUNCS([futimens futimes futimesat utimes utime], [break])
 524
 525 TUKLIB_PROGNAME
 526 TUKLIB_INTEGER
 527 TUKLIB_PHYSMEM
 528 TUKLIB_CPUCORES
 529
 530
 531 ###############################################################################
 532 # If using GCC, set some additional AM_CFLAGS:
 533 ###############################################################################
 534
 535 if test "$GCC" = yes ; then
 536         echo
 537         echo "GCC extensions:"
 538 fi
 539
 540 # Always do the visibility check but don't set AM_CFLAGS on Windows.
 541 # This way things get set properly even on Windows.
 542 gl_VISIBILITY
 543 if test -n "$CFLAG_VISIBILITY" && test "$is_w32" = no; then
 544         AM_CFLAGS="$AM_CFLAGS $CFLAG_VISIBILITY"
 545 fi
 546
 547 if test "$GCC" = yes ; then
 548         # Enable as much warnings as possible. These commented warnings won't
 549         # work for this package though:
 550         #   * -Wunreachable-code breaks several assert(0) cases, which are
 551         #     backed up with "return LZMA_PROG_ERROR".
 552         #   * -Wcast-qual would break various things where we need a non-const
 553         #     pointer although we don't modify anything through it.
 554         #   * -Wcast-align breaks optimized CRC32 and CRC64 implementation
 555         #     on some architectures (not on x86), where this warning is bogus,
 556         #     because we take care of correct alignment.
 557         #   * -Winline, -Wdisabled-optimization, -Wunsafe-loop-optimizations
 558         #     don't seem so useful here; at least the last one gives some
 559         #     warnings which are not bugs.
 560         for NEW_FLAG in \
 561                         -Wall \
 562                         -Wextra \
 563                         -Wformat=2 \
 564                         -Winit-self \
 565                         -Wmissing-include-dirs \
 566                         -Wstrict-aliasing \
 567                         -Wfloat-equal \
 568                         -Wundef \
 569                         -Wshadow \
 570                         -Wpointer-arith \
 571                         -Wbad-function-cast \
 572                         -Wwrite-strings \
 573                         -Wlogical-op \
 574                         -Waggregate-return \
 575                         -Wstrict-prototypes \
 576                         -Wold-style-definition \
 577                         -Wmissing-prototypes \
 578                         -Wmissing-declarations \
 579                         -Wmissing-noreturn \
 580                         -Wredundant-decls
 581         do
 582                 AC_MSG_CHECKING([if $CC accepts $NEW_FLAG])
 583                 OLD_CFLAGS="$CFLAGS"
 584                 CFLAGS="$CFLAGS $NEW_FLAG"
 585                 AC_COMPILE_IFELSE([void foo(void) { }], [
 586                         AM_CFLAGS="$AM_CFLAGS $NEW_FLAG"
 587                         AC_MSG_RESULT([yes])
 588                 ], [
 589                         AC_MSG_RESULT([no])
 590                 ])
 591                 CFLAGS="$OLD_CFLAGS"
 592         done
 593
 594         AC_ARG_ENABLE([werror],
 595                 AC_HELP_STRING([--enable-werror], [Enable -Werror to abort
 596                         compilation on all compiler warnings.]),
 597                 [], [enable_werror=no])
 598         if test "x$enable_werror" = "xyes"; then
 599                 AM_CFLAGS="$AM_CFLAGS -Werror"
 600         fi
 601 fi
 602
 603
 604 ###############################################################################
 605 # Create the makefiles and config.h
 606 ###############################################################################
 607
 608 echo
 609
 610 # Don't build the lib directory at all if we don't need any replacement
 611 # functions.
 612 AM_CONDITIONAL([COND_GNULIB], test -n "$LIBOBJS")
 613
 614 # Add default AM_CFLAGS.
 615 AC_SUBST([AM_CFLAGS])
 616
 617 # Set additional flags for static/dynamic linking. The idea is that every
 618 # program (not library) being built will use either STATIC_{CPPFLAGS,LDFLAGS}
 619 # or DYNAMIC_{CPPFLAGS,LDFLAGS} depending on which type of linkage is
 620 # preferred. These preferences get overriden by use of --disable-static,
 621 # --disable-shared, or --enable-dynamic.
 622 #
 623 # This is quite messy, because we want to use LZMA_API_STATIC when linking
 624 # against static liblzma. It's needed on Windows.
 625 if test "x$enable_static" = xno; then
 626         enable_dynamic=yes
 627 fi
 628 if test "x$enable_shared" = xno; then
 629         enable_dynamic=no
 630 fi
 631 case $enable_dynamic in
 632         yes)
 633                 STATIC_CPPFLAGS=
 634                 STATIC_LDFLAGS=
 635                 DYNAMIC_CPPFLAGS=
 636                 DYNAMIC_LDFLAGS=
 637                 ;;
 638         mixed)
 639                 STATIC_CPPFLAGS="-DLZMA_API_STATIC"
 640                 STATIC_LDFLAGS="-static"
 641                 DYNAMIC_CPPFLAGS=
 642                 DYNAMIC_LDFLAGS=
 643                 ;;
 644         no)
 645                 STATIC_CPPFLAGS="-DLZMA_API_STATIC"
 646                 STATIC_LDFLAGS="-static"
 647                 DYNAMIC_CPPFLAGS="-DLZMA_API_STATIC"
 648                 DYNAMIC_LDFLAGS="-static"
 649                 ;;
 650 esac
 651 AC_SUBST([STATIC_CPPFLAGS])
 652 AC_SUBST([STATIC_LDFLAGS])
 653 AC_SUBST([DYNAMIC_CPPFLAGS])
 654 AC_SUBST([DYNAMIC_LDFLAGS])
 655
 656 # This is needed for src/scripts.
 657 xz=`echo xz | sed "$program_transform_name"`
 658 AC_SUBST([xz])
 659
 660 AC_CONFIG_FILES([
 661         Doxyfile
 662         Makefile
 663         po/Makefile.in
 664         lib/Makefile
 665         src/Makefile
 666         src/liblzma/liblzma.pc
 667         src/liblzma/Makefile
 668         src/liblzma/api/Makefile
 669         src/xz/Makefile
 670         src/xzdec/Makefile
 671         src/lzmainfo/Makefile
 672         src/scripts/Makefile
 673         src/scripts/xzdiff
 674         src/scripts/xzgrep
 675         src/scripts/xzmore
 676         src/scripts/xzless
 677         tests/Makefile
 678         debug/Makefile
 679 ])
 680
 681 AC_OUTPUT
 682
 683 # Some warnings
 684 if test x$tuklib_cv_physmem_method = xunknown; then
 685         echo
 686         echo "WARNING:"
 687         echo "No supported method to detect the amount of RAM."
 688         echo "Consider using --enable-assume-ram (if you didn't already)"
 689         echo "or make a patch to add support for this operating system."
 690 fi
 691
 692 # Not threading yet so don't warn.
 693 #if test x$tuklib_cv_cpucores_method = xunknown; then
 694 #       echo
 695 #       echo "WARNING:"
 696 #       echo "No supported method to detect the number of CPU cores."
 697 #fi