data/qcsrc/server/w_tuba.qc

   1 #define TUBA_NOTE(n) strcat("weapons/tuba_note", ftos(n), ".wav")
   2 .float tuba_notecount;
   3
   4 float Tuba_GetNote(entity pl, float hittype)
   5 {
   6         float note;
   7         float movestate;
   8         movestate = 5;
   9         if(pl.movement_x < 0) movestate -= 3;
  10         if(pl.movement_x > 0) movestate += 3;
  11         if(pl.movement_y < 0) movestate -= 1;
  12         if(pl.movement_y > 0) movestate += 1;
  13         switch(movestate)
  14         {
  15         // layout: originally I wanted
  16         //   eb e  e#=f
  17         //   B  c  d
  18         //   Gb G  G#
  19         // but then you only use forward and right key. So to make things more
  20         // interesting, I swapped B with e#. Har har har...
  21         //   eb e  B
  22         // f=e# c  d
  23         //   Gb G  G#
  24                 case 1: note = -6; break; // Gb
  25                 case 2: note = -5; break; // G
  26                 case 3: note = -4; break; // G#
  27                 case 4: note = +5; break; // e#
  28                 case 5: note =  0; break; // c
  29                 case 6: note = +2; break; // d
  30                 case 7: note = +3; break; // eb
  31                 case 8: note = +4; break; // e
  32                 case 9: note = -1; break; // B
  33         }
  34         if(pl.BUTTON_CROUCH)
  35                 note -= 12;
  36         if(pl.BUTTON_JUMP)
  37                 note += 12;
  38         if(hittype & HITTYPE_SECONDARY)
  39                 note += 7;
  40
  41         // we support two kinds of tubas, those tuned in Eb and those tuned in C
  42         // kind of tuba currently is player slot number, or team number if in
  43         // teamplay
  44         // that way, holes in the range of notes are "plugged"
  45         if(teams_matter)
  46         {
  47                 if(pl.team == COLOR_TEAM2 || pl.team == COLOR_TEAM4)
  48                         note += 3;
  49         }
  50         else
  51         {
  52                 if(pl.clientcolors & 1)
  53                         note += 3;
  54         }
  55
  56         // total range of notes:
  57         //                       0
  58         //                 ***  ** ****
  59         //                        ***  ** ****
  60         //     ***  ** ****
  61         //            ***  ** ****
  62         //     ***  ********************* ****
  63         //     -18.........................+12
  64         //        ***  ********************* ****
  65         //     -18............................+15
  66         //     with jump: ... +24
  67         //     ... +27
  68         return note;
  69 }
  70
  71 void W_Tuba_Attack(float hittype)
  72 {
  73         W_SetupShot(self, FALSE, 2, "");
  74         self.tuba_notecount = !self.tuba_notecount;
  75         if(self.tuba_notecount)
  76                 sound(self, CHAN_WEAPON, TUBA_NOTE(Tuba_GetNote(self, hittype)), VOL_BASE, cvar("g_balance_tuba_attenuation"));
  77         else
  78                 sound(self, CHAN_WEAPON2, TUBA_NOTE(Tuba_GetNote(self, hittype)), VOL_BASE, cvar("g_balance_tuba_attenuation"));
  79         RadiusDamage(self, self, cvar("g_balance_tuba_damage"), cvar("g_balance_tuba_edgedamage"), cvar("g_balance_tuba_radius"), world, cvar("g_balance_tuba_force"), hittype | WEP_TUBA, world);
  80 }
  81
  82 void spawnfunc_weapon_tuba (void)
  83 {
  84         if(!sv_cheats && !cvar("developer"))
  85         {
  86                 print("The @!#%'n Tuba awaits you... not.\n");
  87                 remove(self);
  88                 return;
  89         }
  90         weapon_defaultspawnfunc(WEP_TUBA);
  91 }
  92
  93 float w_tuba(float req)
  94 {
  95         if (req == WR_AIM)
  96         {
  97                 // bots cannot play the Tuba yet
  98                 // I think they should start with the recorder first
  99         }
 100         else if (req == WR_THINK)
 101         {
 102                 if (self.BUTTON_ATCK)
 103                 if (weapon_prepareattack(0, cvar("g_balance_tuba_refire")))
 104                 {
 105                         W_Tuba_Attack(0);
 106                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_tuba_animtime"), w_ready);
 107                 }
 108                 if (self.BUTTON_ATCK2)
 109                 if (weapon_prepareattack(1, cvar("g_balance_tuba_refire")))
 110                 {
 111                         W_Tuba_Attack(HITTYPE_SECONDARY);
 112                         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_tuba_animtime"), w_ready);
 113                 }
 114         }
 115         else if (req == WR_PRECACHE)
 116         {
 117                 precache_model ("models/weapons/g_tuba.md3");
 118                 precache_model ("models/weapons/v_tuba.md3");
 119                 precache_model ("models/weapons/h_tuba.dpm");
 120
 121                 float i;
 122                 for(i = -18; i <= +27; ++i)
 123                         precache_sound(TUBA_NOTE(i));
 124         }
 125         else if (req == WR_SETUP)
 126                 weapon_setup(WEP_TUBA);
 127         else if (req == WR_CHECKAMMO1)
 128                 return TRUE; // TODO use fuel?
 129         else if (req == WR_CHECKAMMO2)
 130                 return TRUE; // TODO use fuel?
 131         else if (req == WR_SUICIDEMESSAGE)
 132         {
 133                 w_deathtypestring = "hurt his own ears with the @!#%'n Tuba";
 134         }
 135         else if (req == WR_KILLMESSAGE)
 136         {
 137                 w_deathtypestring = "died of #'s great playing on the @!#%'n Tuba";
 138         }
 139         return TRUE;
 140 };