data/qcsrc/server/w_rocketlauncher.qc

   1
   2 .float rl_sound;
   3
   4 void W_Rocket_Explode (void)
   5 {
   6         vector  org2;
   7         sound (self, CHAN_BODY, "weapons/rocket_impact.wav", 1, ATTN_NORM);
   8         org2 = findbetterlocation (self.origin, 16);
   9
  10         pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
  11
  12         //effect (org2, "models/sprites/rockexpl.spr", 0, 12, 35);
  13         self.event_damage = SUB_Null;
  14         RadiusDamage (self, self.owner, cvar("g_balance_rocketlauncher_damage"), cvar("g_balance_rocketlauncher_edgedamage"), cvar("g_balance_rocketlauncher_radius"), world, cvar("g_balance_rocketlauncher_force"), IT_ROCKET_LAUNCHER);
  15
  16         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
  17         {
  18                 if(self.owner.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
  19                 {
  20                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
  21                         ATTACK_FINISHED(self.owner) = time;
  22                         self.owner.switchweapon = w_getbestweapon(self.owner);
  23                 }
  24                 if(g_laserguided_missile)
  25                         ATTACK_FINISHED(self.owner) = time + cvar("g_balance_rocketlauncher_refire");
  26         }
  27         remove (self);
  28 }
  29
  30 entity FindLaserTarget(entity e, float dist_variance, float dot_variance)
  31 {
  32         entity head, selected;
  33         vector dir;
  34         float dist, maxdist,// bestdist,
  35                 dot,// bestdot,
  36                 points, bestpoints;
  37         //bestdist = 9999;
  38         //bestdot = -2;
  39         bestpoints = 0;
  40         maxdist = 800;
  41         selected = world;
  42
  43         makevectors(e.angles);
  44
  45         head = find(world, classname, "laser_target");
  46         while(head)
  47         {
  48                 points = 0;
  49                 dir = normalize(head.origin - self.origin);
  50                 dot = dir * v_forward;
  51                 dist = vlen(head.origin - self.origin);
  52                 if(dist > maxdist)
  53                         dist = maxdist;
  54
  55                 // gain points for being in front
  56                 points = points + ((dot+1)*0.5) * 500
  57                         * (1 + crandom()*dot_variance);
  58                 // gain points for being close away
  59                 points = points + (1 - dist/maxdist) * 1000
  60                         * (1 + crandom()*dot_variance);
  61
  62                 traceline(e.origin, head.origin, TRUE, self);
  63                 if(trace_fraction < 1)
  64                 {
  65                         points = 0;
  66                 }
  67
  68                 if(points > bestpoints)//random() > 0.5)//
  69                 {
  70                         bestpoints = points;
  71                         selected = head;
  72                 }
  73
  74                 head = find(head, classname, "laser_target");
  75         }
  76
  77         //bprint(selected.owner.netname);
  78         //bprint("\n");
  79         return selected;
  80 }
  81
  82 void W_Rocket_Think (void)
  83 {
  84         entity e;
  85         vector desireddir, olddir, newdir;
  86         float turnrate, velspeed;
  87         self.nextthink = time;
  88         if (time > self.cnt)
  89         {
  90                 W_Rocket_Explode ();
  91                 return;
  92         }
  93
  94         if(g_laserguided_missile)
  95         {
  96                 // accelerate
  97                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
  98                 velspeed = cvar("g_balance_rocketlauncher_laserguided_speed") - (self.velocity * v_forward);
  99                 if (velspeed > 0)
 100                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_laserguided_speedaccel") * frametime, velspeed);
 101         }
 102         else
 103         {
 104                 // accelerate
 105                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 106                 velspeed = cvar("g_balance_rocketlauncher_speed") - (self.velocity * v_forward);
 107                 if (velspeed > 0)
 108                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_speedaccel") * frametime, velspeed);
 109         }
 110
 111         // laser guided, or remote detonation
 112         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
 113         {
 114                 if(g_laserguided_missile)
 115                 {
 116                         if(!self.owner.button0)
 117                                 self.ltime = -1; // indicate that the player has let go of the button
 118
 119
 120                         if(self.owner.deadflag == DEAD_NO)
 121                         if (self.owner.button0 && self.ltime < 0) // if the player let go of the button and then pushed it again
 122                         {
 123                                   W_Rocket_Explode ();
 124                                   return;
 125                         }
 126
 127                         if(cvar("g_balance_rocketlauncher_laserguided_allow_steal"))
 128                         {
 129                                 if(self.owner.laser_on)
 130                                 {
 131                                         if(self.attack_finished_single < time)
 132                                         {
 133                                                 self.attack_finished_single = time + 0.2 + random()*0.3;
 134                                                 self.enemy = FindLaserTarget(self, 0.7, 0.7);
 135                                         }
 136
 137                                         if(!self.enemy)
 138                                                 self.enemy = self.owner.weaponentity.lasertarget;
 139                                 }
 140                                 else self.enemy = world;
 141                         }
 142                         else // don't allow stealing: always target my owner's laser (if it exists)
 143                                 self.enemy = self.owner.weaponentity.lasertarget;
 144
 145                         if(self.enemy != world)
 146                         {
 147                                 //bprint("Targeting ", self.enemy.owner.netname, "'s laser\n");
 148                                 velspeed = vlen(self.velocity);
 149                                 e = self.enemy;//self.owner.weaponentity.lasertarget;
 150                                 turnrate = cvar("g_balance_rocketlauncher_laserguided_turnrate");//0.65;                                                // how fast to turn
 151                                 desireddir = normalize(e.origin - self.origin);         // get direction from my position to the laser target
 152                                 olddir = normalize(self.velocity);                                      // get my current direction
 153                                 newdir = normalize((olddir + desireddir * turnrate) * 0.5);     // take the average of the 2 directions; not the best method but simple & easy
 154                                 self.velocity = newdir * velspeed;                                      // make me fly in the new direction at my flight speed
 155                                 self.angles = vectoangles(self.velocity);                       // turn model in the new flight direction
 156
 157                                 ATTACK_FINISHED(self.owner) = time + 0.2;
 158                         }
 159                 }
 160                 else
 161                 {
 162                         if(self.owner.deadflag == DEAD_NO)
 163                         if (self.owner.button3)
 164                                   W_Rocket_Explode ();
 165                 }
 166         }
 167 }
 168
 169 void W_Rocket_Touch (void)
 170 {
 171         if(self.owner && self.owner.lastrocket == self)
 172                 self.owner.lastrocket = world;
 173         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 174         {
 175                 sound (self, CHAN_BODY, "misc/null.wav", 1, ATTN_NORM);
 176                 remove(self);
 177                 return;
 178         }
 179         W_Rocket_Explode ();
 180 }
 181
 182 void W_Rocket_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 183 {
 184         self.health = self.health - damage;
 185         self.angles = vectoangles(self.velocity);
 186         if (self.health <= 0)
 187         {
 188                 self.owner = attacker;
 189                 W_Rocket_Explode();
 190         }
 191 }
 192
 193 void W_Rocket_Attack (void)
 194 {
 195         local entity missile;
 196         local entity flash, flash2;
 197
 198         if (cvar("g_use_ammunition") && !g_rocketarena)
 199                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_rocketlauncher_ammo");
 200
 201         W_SetupShot (self, '25 3 -8', FALSE, 5, "weapons/rocket_fire.wav");
 202         //W_SetupShot (self, '25 8 -8', FALSE, 5, "weapons/rocket_fire.wav"); // TODO: move model to the right a little
 203         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 204
 205         missile = spawn ();
 206         missile.owner = self;
 207         self.lastrocket = missile;
 208         missile.classname = "missile";
 209         missile.bot_dodge = TRUE;
 210         missile.bot_dodgerating = cvar("g_balance_rocketlauncher_primary_damage") * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 211
 212         missile.takedamage = DAMAGE_YES;
 213         missile.damageforcescale = 4;
 214         missile.health = 30;
 215         missile.event_damage = W_Rocket_Damage;
 216
 217         missile.movetype = MOVETYPE_FLY;
 218         missile.solid = SOLID_BBOX;
 219         setmodel (missile, "models/rocket.md3"); // precision set below
 220         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 221
 222         setorigin (missile, w_shotorg);
 223         if(g_laserguided_missile && self.laser_on)
 224                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_laserguided_speedstart");
 225         else
 226                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_speedstart");
 227         W_SetupProjectileVelocity(missile);
 228         missile.angles = vectoangles (missile.velocity);
 229
 230         missile.touch = W_Rocket_Touch;
 231         missile.think = W_Rocket_Think;
 232         missile.nextthink = time;
 233         missile.cnt = time + cvar("g_balance_rocketlauncher_lifetime");
 234         missile.effects = EF_LOWPRECISION;
 235         sound (missile, CHAN_BODY, "weapons/rocket_fly.wav", 0.4, ATTN_NORM);
 236         missile.flags = FL_PROJECTILE;
 237
 238         // muzzle flash for 1st person view
 239         flash = spawn ();
 240         flash.scale = 1.2;
 241         flash.angles_z = 180;
 242         flash.owner = self;
 243         flash.viewmodelforclient = self;
 244         flash.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 245         setorigin (flash, '35 5 -12');
 246         setmodel (flash, "models/flash.md3"); // precision set below
 247         setattachment(flash, self.weaponentity, "bone01");
 248         SUB_SetFade (flash, time, 0.4);
 249
 250         // muzzle flash for 3rd person view
 251         flash2 = spawn ();
 252         flash2.scale = 0.8;
 253         flash2.angles_y = 180;
 254         flash2.angles_z = 90;
 255         setorigin (flash2, '42 0 5');
 256         setmodel (flash2, "models/flash.md3"); // precision set below
 257         setattachment(flash2, self.exteriorweaponentity, "");
 258         SUB_SetFade (flash2, time, 0.4);
 259
 260         // common properties
 261         flash.effects = flash2.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 262 }
 263
 264 float(float req) w_rlauncher =
 265 {
 266         if (req == WR_AIM)
 267         {
 268                 // aim and decide to fire if appropriate
 269                 self.button0 = bot_aim(cvar("g_balance_rocketlauncher_speed"), 0, cvar("g_balance_rocketlauncher_lifetime"), FALSE);
 270                 if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 271                 {
 272                         // decide whether to detonate rockets
 273                         local entity missile, targetlist, targ;
 274                         local float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 275                         local float selfdamage, teamdamage, enemydamage;
 276                         edgedamage = cvar("g_balance_rocketlauncher_edgedamage");
 277                         coredamage = cvar("g_balance_rocketlauncher_damage");
 278                         edgeradius = cvar("g_balance_rocketlauncher_radius");
 279                         recipricoledgeradius = 1 / edgeradius;
 280                         selfdamage = 0;
 281                         teamdamage = 0;
 282                         enemydamage = 0;
 283                         targetlist = findchainfloat(bot_attack, TRUE);
 284                         missile = find(world, classname, "missile");
 285                         while (missile)
 286                         {
 287                                 if (missile.owner != self)
 288                                 {
 289                                         missile = find(missile, classname, "missile");
 290                                         continue;
 291                                 }
 292                                 targ = targetlist;
 293                                 while (targ)
 294                                 {
 295                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 296                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 297                                         // count potential damage according to type of target
 298                                         if (targ == self)
 299                                                 selfdamage = selfdamage + d;
 300                                         else if (targ.team == self.team && teamplay)
 301                                                 teamdamage = teamdamage + d;
 302                                         else if (bot_shouldattack(targ))
 303                                                 enemydamage = enemydamage + d;
 304                                         targ = targ.chain;
 305                                 }
 306                                 missile = find(missile, classname, "missile");
 307                         }
 308                         local float desirabledamage;
 309                         desirabledamage = enemydamage;
 310                         if (teamplay != 1 && time > self.invincible_finished && time > self.spawnshieldtime)
 311                                 desirabledamage = desirabledamage - selfdamage * cvar("g_balance_selfdamagepercent");
 312                         if (self.team && teamplay == 2)
 313                                 desirabledamage = desirabledamage - teamdamage;
 314
 315                         missile = find(world, classname, "missile");
 316                         while (missile)
 317                         {
 318                                 if (missile.owner != self)
 319                                 {
 320                                         missile = find(missile, classname, "missile");
 321                                         continue;
 322                                 }
 323                                 makevectors(missile.v_angle);
 324                                 targ = targetlist;
 325                                 if (skill > 9) // normal players only do this for the target they are tracking
 326                                 {
 327                                         targ = targetlist;
 328                                         while (targ)
 329                                         {
 330                                                 if (
 331                                                         (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 332                                                         && desirabledamage > 0.1*coredamage
 333                                                 )self.button3 = TRUE;
 334                                                 targ = targ.chain;
 335                                         }
 336                                 }else{
 337                                         local float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 338                                         //As the distance gets larger, a correct detonation gets near imposible
 339                                         //Bots are assumed to use the rocket light to see if the rocket gets near a player
 340                                         if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 341                                                 if(self.enemy.classname == "player")
 342                                                         if(desirabledamage >= 0.1*coredamage)
 343                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 344                                                                         self.button3 = TRUE;
 345                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 346                                 }
 347
 348                                 missile = find(missile, classname, "missile");
 349                         }
 350                         // if we would be doing at X percent of the core damage, detonate it
 351                         // but don't fire a new shot at the same time!
 352                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 353                                 self.button3 = TRUE;
 354                         if ((skill > 6.5) && (selfdamage > self.health))
 355                                 self.button3 = FALSE;
 356                         //if(self.button3 == TRUE)
 357                         //      dprint(ftos(desirabledamage),"\n");
 358                         if (self.button3 == TRUE) self.button0 = FALSE;
 359                 }
 360         }
 361         else if (req == WR_THINK)
 362         {
 363                 if (self.button0)
 364                 if (weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 365                 {
 366                         W_Rocket_Attack();
 367                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 368                 }
 369                 if (self.button3)
 370                 if(time > self.rl_sound)
 371                 {
 372                         self.rl_sound = time + 1;
 373                         sound (self, CHAN_BODY, "weapons/rocket_det.wav", 0.5, ATTN_NORM);
 374                 }
 375                 if (self.button3)
 376                 if(g_laserguided_missile)
 377                 if(self.exteriorweaponentity.attack_finished_single < time)
 378                 {
 379                         self.exteriorweaponentity.attack_finished_single = time + 0.4;
 380                         self.laser_on = !self.laser_on;
 381                         sound (self, CHAN_AUTO, "weapons/tink1.wav", 1, ATTN_NORM);
 382                 }
 383         }
 384         else if (req == WR_PRECACHE)
 385         {
 386                 precache_model ("models/flash.md3");
 387                 precache_model ("models/rocket.md3");
 388                 precache_model ("models/weapons/g_rl.md3");
 389                 precache_model ("models/weapons/v_rl.md3");
 390                 precache_model ("models/weapons/w_rl.zym");
 391                 precache_sound ("weapons/rocket_det.wav");
 392                 precache_sound ("weapons/rocket_fire.wav");
 393                 precache_sound ("weapons/rocket_fly.wav");
 394                 precache_sound ("weapons/rocket_impact.wav");
 395                 if (g_laserguided_missile)
 396                         precache_model ("models/laser_dot.mdl"); // rocket launcher
 397         }
 398         else if (req == WR_SETUP)
 399                 weapon_setup(WEP_ROCKET_LAUNCHER, "rl", IT_ROCKETS);
 400         else if (req == WR_CHECKAMMO1)
 401         {
 402                 // don't switch while guiding a missile
 403                 if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_ROCKET_LAUNCHER)
 404                         && self.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
 405                         return FALSE;
 406         }
 407         else if (req == WR_CHECKAMMO2)
 408                 return FALSE;
 409         else if (req == WR_REGISTER)
 410                 weapon_register(WEP_ROCKET_LAUNCHER, cvar("g_balance_rocketlauncher_ammo"));
 411         return TRUE;
 412 };