data/qcsrc/server/w_rocketlauncher.qc

   1 .float rl_release;
   2 .float rl_detonate_later;
   3
   4 void W_Rocket_Explode (void)
   5 {
   6         self.event_damage = SUB_Null;
   7         RadiusDamage (self, self.owner, cvar("g_balance_rocketlauncher_damage"), cvar("g_balance_rocketlauncher_edgedamage"), cvar("g_balance_rocketlauncher_radius"), world, cvar("g_balance_rocketlauncher_force"), self.projectiledeathtype, other);
   8
   9         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
  10         {
  11                 if(self.owner.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
  12                 {
  13                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
  14                         ATTACK_FINISHED(self.owner) = time;
  15                         self.owner.switchweapon = w_getbestweapon(self.owner);
  16                 }
  17                 if(g_laserguided_missile)
  18                         ATTACK_FINISHED(self.owner) = time + cvar("g_balance_rocketlauncher_refire");
  19         }
  20         remove (self);
  21 }
  22
  23 entity FindLaserTarget(entity e, float dist_variance, float dot_variance)
  24 {
  25         entity head, selected;
  26         vector dir;
  27         float dist, maxdist,// bestdist,
  28                 dot,// bestdot,
  29                 points, bestpoints;
  30         //bestdist = 9999;
  31         //bestdot = -2;
  32         bestpoints = 0;
  33         maxdist = 800;
  34         selected = world;
  35
  36         makevectors(e.angles);
  37
  38         head = find(world, classname, "laser_target");
  39         while(head)
  40         {
  41                 points = 0;
  42                 dir = normalize(head.origin - self.origin);
  43                 dot = dir * v_forward;
  44                 dist = vlen(head.origin - self.origin);
  45                 if(dist > maxdist)
  46                         dist = maxdist;
  47
  48                 // gain points for being in front
  49                 points = points + ((dot+1)*0.5) * 500
  50                         * (1 + crandom()*dot_variance);
  51                 // gain points for being close away
  52                 points = points + (1 - dist/maxdist) * 1000
  53                         * (1 + crandom()*dot_variance);
  54
  55                 traceline(e.origin, head.origin, TRUE, self);
  56                 if(trace_fraction < 1)
  57                 {
  58                         points = 0;
  59                 }
  60
  61                 if(points > bestpoints)//random() > 0.5)//
  62                 {
  63                         bestpoints = points;
  64                         selected = head;
  65                 }
  66
  67                 head = find(head, classname, "laser_target");
  68         }
  69
  70         //bprint(selected.owner.netname);
  71         //bprint("\n");
  72         return selected;
  73 }
  74
  75 void W_Rocket_RemoteExplode()
  76 {
  77         if(self.owner.deadflag == DEAD_NO)
  78         {
  79                 if((self.spawnshieldtime >= 0)
  80                         ? (time >= self.spawnshieldtime) // timer
  81                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > cvar("g_balance_rocketlauncher_radius")) // safety device
  82                 )
  83                 {
  84                         other = world;
  85                         self.projectiledeathtype |= HITTYPE_BOUNCE;
  86                         W_Rocket_Explode ();
  87                 }
  88                 else
  89                 {
  90                 }
  91         }
  92 }
  93
  94 void W_Rocket_Think (void)
  95 {
  96         entity e;
  97         vector desireddir, olddir, newdir;
  98         float turnrate, velspeed;
  99         self.nextthink = time;
 100         if (time > self.cnt)
 101         {
 102                 other = world;
 103                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 104                 W_Rocket_Explode ();
 105                 return;
 106         }
 107
 108         if(g_laserguided_missile)
 109         {
 110                 // accelerate
 111                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 112                 velspeed = cvar("g_balance_rocketlauncher_laserguided_speed") - (self.velocity * v_forward);
 113                 if (velspeed > 0)
 114                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_laserguided_speedaccel") * frametime, velspeed);
 115         }
 116         else
 117         {
 118                 // accelerate
 119                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 120                 velspeed = cvar("g_balance_rocketlauncher_speed") - (self.velocity * v_forward);
 121                 if (velspeed > 0)
 122                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_speedaccel") * frametime, velspeed);
 123         }
 124
 125         // laser guided, or remote detonation
 126         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
 127         {
 128                 if(g_laserguided_missile)
 129                 {
 130                         if(self.rl_detonate_later)
 131                                 W_Rocket_RemoteExplode();
 132
 133                         if(cvar("g_balance_rocketlauncher_laserguided_allow_steal"))
 134                         {
 135                                 if(self.owner.laser_on)
 136                                 {
 137                                         if(self.attack_finished_single < time)
 138                                         {
 139                                                 self.attack_finished_single = time + 0.2 + random()*0.3;
 140                                                 self.enemy = FindLaserTarget(self, 0.7, 0.7);
 141                                         }
 142
 143                                         if(!self.enemy)
 144                                                 self.enemy = self.owner.weaponentity.lasertarget;
 145                                 }
 146                                 else self.enemy = world;
 147                         }
 148                         else // don't allow stealing: always target my owner's laser (if it exists)
 149                                 self.enemy = self.owner.weaponentity.lasertarget;
 150
 151                         if(self.enemy != world)
 152                         {
 153                                 //bprint("Targeting ", self.enemy.owner.netname, "'s laser\n");
 154                                 velspeed = vlen(self.velocity);
 155                                 e = self.enemy;//self.owner.weaponentity.lasertarget;
 156                                 turnrate = cvar("g_balance_rocketlauncher_laserguided_turnrate");//0.65;                                                // how fast to turn
 157                                 desireddir = normalize(e.origin - self.origin);         // get direction from my position to the laser target
 158                                 olddir = normalize(self.velocity);                                      // get my current direction
 159                                 newdir = normalize((olddir + desireddir * turnrate) * 0.5);     // take the average of the 2 directions; not the best method but simple & easy
 160                                 self.velocity = newdir * velspeed;                                      // make me fly in the new direction at my flight speed
 161                                 self.angles = vectoangles(self.velocity);                       // turn model in the new flight direction
 162
 163                                 ATTACK_FINISHED(self.owner) = time + 0.2;
 164                         }
 165                 }
 166                 else
 167                 {
 168                         if(self.rl_detonate_later)
 169                                 W_Rocket_RemoteExplode();
 170                 }
 171         }
 172
 173         if(self.csqcprojectile_clientanimate == 0)
 174                 UpdateCSQCProjectile(self);
 175 }
 176
 177 void W_Rocket_Touch (void)
 178 {
 179         if(self.owner && self.owner.lastrocket == self)
 180                 self.owner.lastrocket = world;
 181         PROJECTILE_TOUCH;
 182         W_Rocket_Explode ();
 183 }
 184
 185 void W_Rocket_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 186 {
 187         self.health = self.health - damage;
 188         self.angles = vectoangles(self.velocity);
 189         if (self.health <= 0)
 190                 W_PrepareExplosionByDamage(attacker, W_Rocket_Explode);
 191 }
 192
 193 void W_Rocket_Attack (void)
 194 {
 195         local entity missile;
 196         local entity flash, flash2;
 197
 198         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 199                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_rocketlauncher_ammo");
 200
 201         W_SetupShot (self, '25 3 -4', FALSE, 5, "weapons/rocket_fire.wav");
 202         //W_SetupShot (self, '25 8 -8', FALSE, 5, "weapons/rocket_fire.wav"); // TODO: move model to the right a little
 203         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 204
 205         missile = spawn ();
 206         missile.owner = self;
 207         self.lastrocket = missile;
 208         if(cvar("g_balance_rocketlauncher_detonatedelay") >= 0)
 209                 missile.spawnshieldtime = time + cvar("g_balance_rocketlauncher_detonatedelay");
 210         else
 211                 missile.spawnshieldtime = -1;
 212         missile.classname = "rocket";
 213         missile.bot_dodge = TRUE;
 214         missile.bot_dodgerating = cvar("g_balance_rocketlauncher_primary_damage") * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 215
 216         missile.takedamage = DAMAGE_YES;
 217         missile.damageforcescale = 4;
 218         missile.health = cvar("g_balance_rocketlauncher_health");
 219         missile.event_damage = W_Rocket_Damage;
 220
 221         missile.movetype = MOVETYPE_FLY;
 222         missile.solid = SOLID_BBOX;
 223         missile.projectiledeathtype = WEP_ROCKET_LAUNCHER;
 224         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 225
 226         setorigin (missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 227         if(g_laserguided_missile && self.laser_on)
 228                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_laserguided_speedstart");
 229         else
 230                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_speedstart");
 231         W_SetupProjectileVelocity(missile);
 232         missile.angles = vectoangles (missile.velocity);
 233
 234         missile.touch = W_Rocket_Touch;
 235         missile.think = W_Rocket_Think;
 236         missile.nextthink = time;
 237         missile.cnt = time + cvar("g_balance_rocketlauncher_lifetime");
 238         missile.flags = FL_PROJECTILE;
 239
 240         CSQCProjectile(missile, cvar("g_balance_rocketlauncher_speedaccel") == 0 && !g_laserguided_missile, PROJECTILE_ROCKET, FALSE); // because of fly sound
 241
 242         // muzzle flash for 1st person view
 243         flash = spawn ();
 244         flash.scale = 1.2;
 245         flash.angles_z = 180;
 246         flash.owner = self;
 247         flash.viewmodelforclient = self;
 248         flash.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 249         setorigin (flash, '35 8 0');
 250         setmodel (flash, "models/flash.md3"); // precision set below
 251         setattachment(flash, self.weaponentity, "bone01");
 252         SUB_SetFade (flash, time, 0.4);
 253
 254         // muzzle flash for 3rd person view
 255         flash2 = spawn ();
 256         flash2.scale = 0.8;
 257         flash2.angles_y = 180;
 258         flash2.angles_z = 90;
 259         setorigin (flash2, '42 0 5');
 260         setmodel (flash2, "models/flash.md3"); // precision set below
 261         setattachment(flash2, self.exteriorweaponentity, "");
 262         SUB_SetFade (flash2, time, 0.4);
 263
 264         // common properties
 265         flash.effects = flash2.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 266 }
 267
 268 void spawnfunc_weapon_rocketlauncher (void); // defined in t_items.qc
 269
 270 float w_rlauncher(float req)
 271 {
 272         entity rock;
 273         float rockfound;
 274         if (req == WR_AIM)
 275         {
 276                 // aim and decide to fire if appropriate
 277                 self.BUTTON_ATCK = bot_aim(cvar("g_balance_rocketlauncher_speed"), 0, cvar("g_balance_rocketlauncher_lifetime"), FALSE);
 278                 if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 279                 {
 280                         // decide whether to detonate rockets
 281                         local entity missile, targetlist, targ;
 282                         local float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 283                         local float selfdamage, teamdamage, enemydamage;
 284                         edgedamage = cvar("g_balance_rocketlauncher_edgedamage");
 285                         coredamage = cvar("g_balance_rocketlauncher_damage");
 286                         edgeradius = cvar("g_balance_rocketlauncher_radius");
 287                         recipricoledgeradius = 1 / edgeradius;
 288                         selfdamage = 0;
 289                         teamdamage = 0;
 290                         enemydamage = 0;
 291                         targetlist = findchainfloat(bot_attack, TRUE);
 292                         missile = find(world, classname, "rocket");
 293                         while (missile)
 294                         {
 295                                 if (missile.owner != self)
 296                                 {
 297                                         missile = find(missile, classname, "rocket");
 298                                         continue;
 299                                 }
 300                                 targ = targetlist;
 301                                 while (targ)
 302                                 {
 303                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 304                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 305                                         // count potential damage according to type of target
 306                                         if (targ == self)
 307                                                 selfdamage = selfdamage + d;
 308                                         else if (targ.team == self.team && teamplay)
 309                                                 teamdamage = teamdamage + d;
 310                                         else if (bot_shouldattack(targ))
 311                                                 enemydamage = enemydamage + d;
 312                                         targ = targ.chain;
 313                                 }
 314                                 missile = find(missile, classname, "rocket");
 315                         }
 316                         local float desirabledamage;
 317                         desirabledamage = enemydamage;
 318                         if (teamplay != 1 && time > self.invincible_finished && time > self.spawnshieldtime)
 319                                 desirabledamage = desirabledamage - selfdamage * cvar("g_balance_selfdamagepercent");
 320                         if (self.team && teamplay == 2)
 321                                 desirabledamage = desirabledamage - teamdamage;
 322
 323                         missile = find(world, classname, "rocket");
 324                         while (missile)
 325                         {
 326                                 if (missile.owner != self)
 327                                 {
 328                                         missile = find(missile, classname, "rocket");
 329                                         continue;
 330                                 }
 331                                 makevectors(missile.v_angle);
 332                                 targ = targetlist;
 333                                 if (skill > 9) // normal players only do this for the target they are tracking
 334                                 {
 335                                         targ = targetlist;
 336                                         while (targ)
 337                                         {
 338                                                 if (
 339                                                         (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 340                                                         && desirabledamage > 0.1*coredamage
 341                                                 )self.BUTTON_ATCK2 = TRUE;
 342                                                 targ = targ.chain;
 343                                         }
 344                                 }else{
 345                                         local float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 346                                         //As the distance gets larger, a correct detonation gets near imposible
 347                                         //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 348                                         if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 349                                                 if(self.enemy.classname == "player")
 350                                                         if(desirabledamage >= 0.1*coredamage)
 351                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 352                                                                         self.BUTTON_ATCK2 = TRUE;
 353                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 354                                 }
 355
 356                                 missile = find(missile, classname, "rocket");
 357                         }
 358                         // if we would be doing at X percent of the core damage, detonate it
 359                         // but don't fire a new shot at the same time!
 360                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 361                                 self.BUTTON_ATCK2 = TRUE;
 362                         if ((skill > 6.5) && (selfdamage > self.health))
 363                                 self.BUTTON_ATCK2 = FALSE;
 364                         //if(self.BUTTON_ATCK2 == TRUE)
 365                         //      dprint(ftos(desirabledamage),"\n");
 366                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 367                 }
 368         }
 369         else if (req == WR_THINK)
 370         {
 371                 if(g_laserguided_missile)
 372                 {
 373                         if (self.BUTTON_ATCK && self.rl_release)
 374                         {
 375                                 rockfound = 0;
 376                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 377                                 {
 378                                         if(!rock.rl_detonate_later)
 379                                         {
 380                                                 rock.rl_detonate_later = TRUE;
 381                                                 rockfound = 1;
 382                                         }
 383                                 }
 384                                 if(rockfound)
 385                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 386                                 else
 387                                 {
 388                                         if (weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 389                                         {
 390                                                 W_Rocket_Attack();
 391                                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 392                                         }
 393                                 }
 394                                 self.rl_release = 0;
 395                         }
 396                         if (!self.BUTTON_ATCK)
 397                                 self.rl_release = 1;
 398                         if (self.BUTTON_ATCK2)
 399                         if(self.exteriorweaponentity.attack_finished_single < time)
 400                         {
 401                                 self.exteriorweaponentity.attack_finished_single = time + 0.4;
 402                                 self.laser_on = !self.laser_on;
 403                                 // UGLY WORKAROUND: play this on CHAN_WEAPON2 so it can't cut off fire sounds
 404                                 sound (self, CHAN_WEAPON2, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 405                         }
 406                 }
 407                 else
 408                 {
 409                         if (self.BUTTON_ATCK)
 410                         if (weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 411                         {
 412                                 W_Rocket_Attack();
 413                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 414                         }
 415                         if (self.BUTTON_ATCK2)
 416                         {
 417                                 rockfound = 0;
 418                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 419                                 {
 420                                         if(!rock.rl_detonate_later)
 421                                         {
 422                                                 rock.rl_detonate_later = TRUE;
 423                                                 rockfound = 1;
 424                                         }
 425                                 }
 426                                 if(rockfound)
 427                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 428                         }
 429                 }
 430         }
 431         else if (req == WR_PRECACHE)
 432         {
 433                 precache_model ("models/flash.md3");
 434                 precache_model ("models/weapons/g_rl.md3");
 435                 precache_model ("models/weapons/v_rl.md3");
 436                 precache_model ("models/weapons/w_rl.zym");
 437                 precache_sound ("weapons/rocket_det.wav");
 438                 precache_sound ("weapons/rocket_fire.wav");
 439                 if (g_laserguided_missile)
 440                 {
 441                         precache_model ("models/laser_dot.mdl"); // rocket launcher
 442                         precache_sound ("weapons/rocket_mode.wav");
 443                 }
 444         }
 445         else if (req == WR_SETUP)
 446         {
 447                 weapon_setup(WEP_ROCKET_LAUNCHER);
 448                 self.rl_release = 1;
 449         }
 450         else if (req == WR_CHECKAMMO1)
 451         {
 452                 // don't switch while guiding a missile
 453                 if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_ROCKET_LAUNCHER)
 454                         && self.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
 455                         return FALSE;
 456         }
 457         else if (req == WR_CHECKAMMO2)
 458                 return FALSE;
 459         else if (req == WR_SUICIDEMESSAGE)
 460                 w_deathtypestring = "exploded";
 461         else if (req == WR_KILLMESSAGE)
 462         {
 463                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 464                         w_deathtypestring = "got too close to #'s rocket";
 465                 else if(w_deathtype & HITTYPE_SPLASH)
 466                         w_deathtypestring = "almost dodged #'s rocket";
 467                 else
 468                         w_deathtypestring = "ate #'s rocket";
 469         }
 470         return TRUE;
 471 };