data/qcsrc/server/w_common.qc

   1
   2 void W_GiveWeapon (entity e, float wep, string name)
   3 {
   4         entity oldself;
   5
   6         if (!wep)
   7                 return;
   8
   9         e.weapons = e.weapons | W_WeaponBit(wep);
  10
  11         oldself = self;
  12         self = e;
  13
  14         if (other.classname == "player")
  15         {
  16                 sprint (other, "You got the ^2");
  17                 sprint (other, name);
  18                 sprint (other, "\n");
  19         }
  20
  21
  22         self = oldself;
  23 }
  24
  25 void FireRailgunBullet (vector start, vector end, float bdamage, float bforce, float deathtype)
  26 {
  27         local vector hitloc, force, endpoint, dir;
  28         local entity ent, endent;
  29         local float endq3surfaceflags;
  30         //local entity explosion;
  31
  32         railgun_start = start;
  33         railgun_end = end;
  34
  35         dir = normalize(end - start);
  36         force = dir * bforce;
  37
  38         // go a little bit into the wall because we need to hit this wall later
  39         end = end + dir;
  40
  41         // trace multiple times until we hit a wall, each obstacle will be made
  42         // non-solid so we can hit the next, while doing this we spawn effects and
  43         // note down which entities were hit so we can damage them later
  44         while (1)
  45         {
  46                 if(self.antilag_debug)
  47                         traceline_antilag (self, start, end, FALSE, self, self.antilag_debug);
  48                 else
  49                         traceline_antilag (self, start, end, FALSE, self, ANTILAG_LATENCY(self));
  50
  51                 // if it is world we can't hurt it so stop now
  52                 if (trace_ent == world || trace_fraction == 1)
  53                         break;
  54
  55                 // make the entity non-solid so we can hit the next one
  56                 trace_ent.railgunhit = TRUE;
  57                 trace_ent.railgunhitloc = end;
  58                 trace_ent.railgunhitsolidbackup = trace_ent.solid;
  59
  60                 // stop if this is a wall
  61                 if (trace_ent.solid == SOLID_BSP)
  62                         break;
  63
  64                 // make the entity non-solid
  65                 trace_ent.solid = SOLID_NOT;
  66         }
  67
  68         endpoint = trace_endpos;
  69         endent = trace_ent;
  70         endq3surfaceflags = trace_dphitq3surfaceflags;
  71
  72         // find all the entities the railgun hit and restore their solid state
  73         ent = findfloat(world, railgunhit, TRUE);
  74         while (ent)
  75         {
  76                 // restore their solid type
  77                 ent.solid = ent.railgunhitsolidbackup;
  78                 ent = findfloat(ent, railgunhit, TRUE);
  79         }
  80
  81         // spawn a temporary explosion entity for RadiusDamage calls
  82         //explosion = spawn();
  83
  84         // find all the entities the railgun hit and hurt them
  85         ent = findfloat(world, railgunhit, TRUE);
  86         while (ent)
  87         {
  88                 // get the details we need to call the damage function
  89                 hitloc = ent.railgunhitloc;
  90                 ent.railgunhitloc = '0 0 0';
  91                 ent.railgunhitsolidbackup = SOLID_NOT;
  92                 ent.railgunhit = FALSE;
  93
  94                 // apply the damage
  95                 if (ent.takedamage || ent.classname == "case")
  96                         Damage (ent, self, self, bdamage, deathtype, hitloc, force);
  97
  98                 // create a small explosion to throw gibs around (if applicable)
  99                 //setorigin (explosion, hitloc);
 100                 //RadiusDamage (explosion, self, 10, 0, 50, world, 300, deathtype);
 101
 102                 // advance to the next entity
 103                 ent = findfloat(ent, railgunhit, TRUE);
 104         }
 105
 106         // we're done with the explosion entity, remove it
 107         //remove(explosion);
 108
 109         trace_endpos = endpoint;
 110         trace_ent = endent;
 111         trace_dphitq3surfaceflags = endq3surfaceflags;
 112 }
 113
 114 .float dmg_edge;
 115 .float dmg_force;
 116 .float dmg_radius;
 117 void W_BallisticBullet_Hit (void)
 118 {
 119         float f;
 120
 121         if (DEATH_ISWEAPON(self.projectiledeathtype, WEP_SHOTGUN))
 122                 pointparticles(particleeffectnum("shotgun_impact"), self.origin, normalize(self.velocity) * 1000, 1);
 123         else
 124                 pointparticles(particleeffectnum("machinegun_impact"), self.origin, normalize(self.velocity) * 1000, 1);
 125
 126         if(other && other != self.enemy)
 127         {
 128                 self.enemy = other; // don't hit the same player twice with the same bullet
 129
 130                 f = pow(bound(0, vlen(self.velocity) / vlen(self.oldvelocity), 1), 2); // energy multiplier
 131
 132                 headshot = 0;
 133                 yoda = 0;
 134                 damage_headshotbonus = self.dmg_edge;
 135                 railgun_start = self.origin - 2 * frametime * self.oldvelocity;
 136                 railgun_end = self.origin + 2 * frametime * self.oldvelocity;
 137                 Damage(other, self, self.owner, self.dmg * f, self.projectiledeathtype, self.origin, self.dmg_force * normalize(self.velocity) * f);
 138                 damage_headshotbonus = 0;
 139
 140                 if(self.dmg_edge != 0)
 141                 {
 142                         if(headshot)
 143                                 announce(self.owner, "announcer/male/headshot.wav");
 144                         if(yoda)
 145                                 announce(self.owner, "announcer/male/yoda.wav");
 146                 }
 147
 148                 //sound (self, CHAN_PROJECTILE, "weapons/electro_impact.wav", VOL_BASE, ATTN_NORM);
 149         }
 150 }
 151
 152 .void(void) W_BallisticBullet_LeaveSolid_think_save;
 153 .float W_BallisticBullet_LeaveSolid_nextthink_save;
 154 .vector W_BallisticBullet_LeaveSolid_origin;
 155 .vector W_BallisticBullet_LeaveSolid_velocity;
 156
 157 void W_BallisticBullet_LeaveSolid_think()
 158 {
 159         setorigin(self, self.W_BallisticBullet_LeaveSolid_origin);
 160         self.velocity = self.W_BallisticBullet_LeaveSolid_velocity;
 161
 162         self.think = self.W_BallisticBullet_LeaveSolid_think_save;
 163         self.nextthink = max(time, self.W_BallisticBullet_LeaveSolid_nextthink_save) + 1;
 164         self.W_BallisticBullet_LeaveSolid_think_save = SUB_Null;
 165
 166         self.flags &~= FL_ONGROUND;
 167         self.effects &~= EF_NODRAW;
 168
 169         if (DEATH_ISWEAPON(self.projectiledeathtype, WEP_SHOTGUN))
 170                 pointparticles(particleeffectnum("shotgun_impact"), self.origin, normalize(self.velocity) * 1000, 1);
 171         else
 172                 pointparticles(particleeffectnum("machinegun_impact"), self.origin, normalize(self.velocity) * 1000, 1);
 173 }
 174
 175 // a fake logarithm function
 176 float log(float x)
 177 {
 178         if(x < 0.0001)
 179                 return 0;
 180         if(x > 0.9 && x < 1.1)
 181                 return x - 1;
 182         return 2 * log(sqrt(x));
 183 }
 184
 185 float W_BallisticBullet_LeaveSolid(entity e, vector vel, float constant)
 186 {
 187         // move the entity along its velocity until it's out of solid, then let it resume
 188
 189         vector tracevel, org, skiporg, endorg, t;
 190         float dt, dst, velfactor, v0, vs;
 191         float maxdist;
 192         float E0_m, Es_m;
 193
 194         // E(s) = E0 - constant * s, constant = area of bullet circle * material constant / mass
 195         v0 = vlen(vel);
 196
 197         E0_m = 0.5 * v0 * v0;
 198         maxdist = E0_m / constant;
 199         // maxdist = 0.5 * v0 * v0 / constant
 200         // dprint("max dist = ", ftos(maxdist), "\n");
 201
 202         if(maxdist <= 0.5)
 203                 return 0;
 204
 205         tracevel = normalize(vel);
 206
 207         org = self.origin;
 208         skiporg = org + tracevel;
 209         endorg = org + tracevel * maxdist;
 210
 211         for(;;)
 212         {
 213                 traceline(skiporg, endorg, MOVE_NORMAL, self);
 214                 t = trace_endpos;
 215
 216                 if(trace_startsolid)
 217                 {
 218                         // good: skiporg is actually in solid
 219                         traceline(t, skiporg, MOVE_NORMAL, self);
 220                         t = trace_endpos;
 221
 222                         if(trace_startsolid)
 223                         {
 224                                 // we're stuck inside solid :(
 225                                 // force advance by 1 unit, and retry
 226                                 // CAN we go by 1 unit?
 227                                 if(vlen(skiporg + tracevel - org) < maxdist)
 228                                         skiporg = skiporg + tracevel;
 229                                 else
 230                                         return 0;
 231                         }
 232                         else
 233                         {
 234                                 // we managed to leave solid
 235                                 // so trace_endpos is good
 236                                 self.W_BallisticBullet_LeaveSolid_origin = t;
 237                                 break;
 238                         }
 239                 }
 240                 else
 241                 {
 242                         // bad: skiporg is outside solid. Then imagine it's alright.
 243                         self.W_BallisticBullet_LeaveSolid_origin = skiporg;
 244                         break;
 245                 }
 246         }
 247
 248         dst = vlen(self.W_BallisticBullet_LeaveSolid_origin - org);
 249         // E(s) = E0 - constant * s, constant = area of bullet circle * material constant / mass
 250         Es_m = E0_m - constant * dst;
 251         if(Es_m <= 0)
 252         {
 253                 // roundoff errors got us
 254                 return 0;
 255         }
 256         vs = sqrt(2 * Es_m);
 257         velfactor = vs / v0;
 258
 259         dt = dst / (0.5 * (v0 + vs));
 260         // this is not correct, but the differential equations have no analytic
 261         // solution - and these times are very small anyway
 262         //print("dt = ", ftos(dt), "\n");
 263
 264         self.W_BallisticBullet_LeaveSolid_think_save = self.think;
 265         self.W_BallisticBullet_LeaveSolid_nextthink_save = self.nextthink;
 266         self.think = W_BallisticBullet_LeaveSolid_think;
 267         self.nextthink = time + dt;
 268
 269         vel = vel * velfactor;
 270
 271         self.velocity = '0 0 0';
 272         self.flags |= FL_ONGROUND; // prevent moving
 273         self.effects |= EF_NODRAW;
 274         self.W_BallisticBullet_LeaveSolid_velocity = vel;
 275
 276         return 1;
 277 }
 278
 279 void W_BallisticBullet_Touch (void)
 280 {
 281         if(self.think == W_BallisticBullet_LeaveSolid_think) // skip this!
 282                 return;
 283
 284         PROJECTILE_TOUCH;
 285         W_BallisticBullet_Hit ();
 286
 287         // go through solid!
 288         if(!W_BallisticBullet_LeaveSolid(self, self.velocity, self.dmg_radius))
 289         {
 290                 remove(self);
 291                 return;
 292         }
 293
 294         self.projectiledeathtype |= HITTYPE_BOUNCE;
 295 }
 296
 297 void fireBallisticBullet(vector start, vector dir, float spread, float pSpeed, float lifetime, float damage, float headshotbonus, float force, float dtype, float tracereffects, float gravityfactor, float bulletconstant)
 298 {
 299         entity proj;
 300         proj = spawn();
 301         proj.owner = self;
 302         proj.solid = SOLID_BBOX;
 303         if(gravityfactor > 0)
 304         {
 305                 proj.movetype = MOVETYPE_TOSS;
 306                 proj.gravity = gravityfactor;
 307         }
 308         else
 309                 proj.movetype = MOVETYPE_FLY;
 310         proj.think = SUB_Remove;
 311         proj.nextthink = time + lifetime; // min(pLifetime, vlen(world.maxs - world.mins) / pSpeed);
 312         proj.velocity = (dir + randomvec() * spread) * pSpeed;
 313         W_SetupProjectileVelocity(proj);
 314         proj.angles = vectoangles(proj.velocity);
 315         proj.dmg_radius = cvar("g_ballistics_materialconstant") / bulletconstant;
 316         // so: bulletconstant = bullet mass / area of bullet circle
 317         setmodel(proj, "models/tracer.mdl");
 318         setsize(proj, '0 0 0', '0 0 0');
 319         setorigin(proj, start);
 320         proj.effects = EF_LOWPRECISION | tracereffects;
 321         proj.flags = FL_PROJECTILE;
 322
 323         proj.touch = W_BallisticBullet_Touch;
 324         proj.dmg = damage;
 325         proj.dmg_edge = headshotbonus;
 326         proj.dmg_force = force;
 327         proj.projectiledeathtype = dtype;
 328
 329         proj.oldvelocity = proj.velocity;
 330 }
 331
 332 void fireBullet (vector start, vector dir, float spread, float damage, float force, float dtype, float tracer)
 333 {
 334         vector  end;
 335         local entity e;
 336
 337         if(cvar("g_ballistics_force"))
 338         {
 339                 if (DEATH_ISWEAPON(dtype, WEP_SHOTGUN))
 340                         fireBallisticBullet(start, dir, spread, cvar("g_ballistics_force_shotgun_speed"), 5, damage, 0, force, dtype, 0, 1, cvar("g_ballistics_force_shotgun_bulletconstant"));
 341                 else
 342                         fireBallisticBullet(start, dir, spread, cvar("g_ballistics_force_uzi_speed"), 5, damage, 0, force, dtype, 0, 1, cvar("g_ballistics_force_shotgun_bulletconstant"));
 343                 return;
 344         }
 345
 346         dir = dir + randomvec() * spread;
 347         end = start + dir * MAX_SHOT_DISTANCE;
 348         if(self.antilag_debug)
 349                 traceline_antilag (self, start, end, FALSE, self, self.antilag_debug);
 350         else
 351                 traceline_antilag (self, start, end, FALSE, self, ANTILAG_LATENCY(self));
 352
 353         if (tracer)
 354         {
 355                 e = spawn();
 356                 e.owner = self;
 357                 e.movetype = MOVETYPE_FLY;
 358                 e.solid = SOLID_NOT;
 359                 e.think = SUB_Remove;
 360                 e.nextthink = time + vlen(trace_endpos - start) / 6000;
 361                 e.velocity = dir * 6000;
 362                 e.angles = vectoangles(e.velocity);
 363                 setmodel (e, "models/tracer.mdl"); // precision set below
 364                 setsize (e, '0 0 0', '0 0 0');
 365                 setorigin (e, start);
 366                 e.effects = EF_LOWPRECISION;
 367                 e.flags = FL_PROJECTILE;
 368         }
 369
 370         if ((trace_fraction != 1.0) && (pointcontents (trace_endpos) != CONTENT_SKY))
 371         {
 372                 if (trace_ent.solid == SOLID_BSP && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 373                 {
 374                         if (DEATH_ISWEAPON(dtype, WEP_SHOTGUN))
 375                                 pointparticles(particleeffectnum("shotgun_impact"), trace_endpos, trace_plane_normal * 1000, 1);
 376                         else
 377                                 pointparticles(particleeffectnum("machinegun_impact"), trace_endpos, trace_plane_normal * 1000, 1);
 378                 }
 379                 Damage (trace_ent, self, self, damage, dtype, trace_endpos, dir * force);
 380         }
 381 }
 382
 383 void W_PrepareExplosionByDamage(entity attacker, void() explode)
 384 {
 385         self.takedamage = DAMAGE_NO;
 386         self.event_damage = SUB_Null;
 387         self.owner = attacker;
 388
 389         // do not explode NOW but in the NEXT FRAME!
 390         // because recursive calls to RadiusDamage are not allowed
 391         self.nextthink = time;
 392         self.think = explode;
 393 }