data/qcsrc/server/vote.qc

   1 float VoteCheckNasty(string cmd)
   2 {
   3         if(strstrofs(cmd, ";", 0) >= 0)
   4                 return TRUE;
   5         if(strstrofs(cmd, "\n", 0) >= 0)
   6                 return TRUE;
   7         if(strstrofs(cmd, "\r", 0) >= 0)
   8                 return TRUE;
   9         if(strstrofs(cmd, "$", 0) >= 0)
  10                 return TRUE;
  11         return FALSE;
  12 }
  13
  14 entity GetKickVoteVictim(string vote, string cmd, entity caller)
  15 {
  16         float tokens;
  17         float i, n, t;
  18         string ns;
  19         entity e;
  20
  21         tokens = tokenize(vote);
  22         ns = "";
  23
  24         if(tokens >= 2)
  25                 if(substring(argv(1), 0, 1) == "#")
  26                 {
  27                         ns = substring(argv(1), 1, 999);
  28                         t = 2;
  29                 }
  30
  31         if(tokens >= 3)
  32                 if(argv(1) == "#")
  33                 {
  34                         ns = argv(2);
  35                         t = 3;
  36                 }
  37
  38         if(ns != "")
  39         {
  40                 GetKickVoteVictim_reason = "";
  41                 for(i = t; i < tokens; ++i)
  42                         GetKickVoteVictim_reason = strcat(GetKickVoteVictim_reason, argv(i), " ");
  43                 GetKickVoteVictim_reason = substring(GetKickVoteVictim_reason, 0, strlen(GetKickVoteVictim_reason) - 1);
  44
  45                 n = stof(ns);
  46                 if(ns == ftos(n)) if(n >= 1) if(n <= maxclients)
  47                 {
  48                         e = edict_num(n);
  49                         if(clienttype(e) == CLIENTTYPE_REAL)
  50                         {
  51                                 GetKickVoteVictim_newcommand = strcat(argv(0), " # ", ns);
  52                                 return e;
  53                         }
  54                 }
  55         }
  56
  57         print_to(caller, strcat("Usage: ", cmd, " ", argv(0), " #playernumber (as in \"status\")\n"));
  58         return world;
  59 }
  60
  61 float GameCommand_Vote(string s, entity e) {
  62         local entity victim;
  63         if(argv(0) == "help") {
  64                 print_to(e, "  vote COMMANDS ARGUMENTS. See 'vote help' for more info.");
  65                 return TRUE;
  66         } else if(argv(0) == "vote") {
  67                 if(argv(1) == "") {
  68                         print_to(e, "^1You have to supply a vote command. See help for more info.");
  69                 } else if(argv(1) == "help") {
  70                         VoteHelp(e);
  71                 } else if(argv(1) == "status") {
  72                         if(votecalled) {
  73                                 print_to(e, strcat("^7Vote for ", votecalledvote_display, "^7 called by ^7", VoteNetname(votecaller), "^7."));
  74                         } else {
  75                                 print_to(e, "^1No vote called.");
  76                         }
  77                 } else if(argv(1) == "call") {
  78                         if(!e || cvar("sv_vote_call")) {
  79                                 if(cvar("sv_vote_nospectators") && e.classname != "player") {
  80                                         print_to(e, "^1Error: Only players can call a vote during the match-stage.");
  81                                 }
  82                                 else if(timeoutStatus) { //don't allow a vote call during a timeout
  83                                         print_to(e, "^1Error: You can not call a vote while a timeout is active.");
  84                                 }
  85                                 else if(votecalled) {
  86                                         print_to(e, "^1There is already a vote called.");
  87                                 } else {
  88                                         local string vote;
  89                                         vote = VoteParse();
  90                                         if(vote == "") {
  91                                                 print_to(e, "^1Your vote is empty. See help for more info.");
  92                                         } else if(e
  93                                                 && time < e.vote_next) {
  94                                                         print_to(e, strcat("^1You have to wait ^2", ftos(e.vote_next - time), "^1 seconds before you can again call a vote."));
  95                                         } else if(VoteCheckNasty(vote)) {
  96                                                 print_to(e, "Syntax error in command. See help for more info.");
  97                                         } else if(VoteAllowed(strcat1(argv(2)))) { // strcat seems to be necessary
  98                                                 // remap chmap to gotomap (forces intermission)
  99                                                 if(vote == "chmap" || vote == "gotomap") // won't work without arguments
 100                                                         return TRUE;
 101                                                 if(substring(vote, 0, 6) == "chmap ")
 102                                                         vote = strcat("gotomap ", substring(vote, 6, strlen(vote) - 6));
 103                                                 if(substring(vote, 0, 8) == "gotomap ")
 104                                                 {
 105                                                         if(!(vote = ValidateMap(substring(vote, 8, strlen(vote) - 8), e)))
 106                                                                 return TRUE;
 107                                                         vote = strcat("gotomap ", vote);
 108                                                 }
 109
 110                                                 // make kick and kickban votes a bit nicer (and reject them if formatted badly)
 111                                                 if(substring(vote, 0, 5) == "kick " || substring(vote, 0, 8) == "kickban ")
 112                                                 {
 113                                                         if(!(victim = GetKickVoteVictim(vote, "vcall", e)))
 114                                                                 return TRUE;
 115                                                         vote = GetKickVoteVictim_newcommand;
 116                                                         votecalledvote_display = strzone(strcat("^1", vote, " (^7", victim.netname, "^1): ", GetKickVoteVictim_reason));
 117                                                 }
 118                                                 else if(vote == "kick" || vote == "kickban")
 119                                                 {
 120                                                         print_to(e, strcat("Usage: ", vote, " #playernumber (as in \"status\")\n"));
 121                                                         return TRUE;
 122                                                 }
 123                                                 else
 124                                                 {
 125                                                         votecalledvote_display = strzone(strcat("^1", vote));
 126                                                 }
 127                                                 votecalledvote = strzone(vote);
 128                                                 votecalled = TRUE;
 129                                                 votecalledmaster = FALSE;
 130                                                 votefinished = time + cvar("sv_vote_timeout");
 131                                                 votecaller = e; // remember who called the vote
 132                                                 if(e) {
 133                                                         e.vote_vote = 1; // of course you vote yes
 134                                                         e.vote_next = time + cvar("sv_vote_wait");
 135                                                 }
 136                                                 bprint("\{1}^2* ^3", VoteNetname(votecaller), "^2 calls a vote for ", votecalledvote_display, "\n");
 137                                                 if(cvar("sv_eventlog"))
 138                                                         GameLogEcho(strcat(":vote:vcall:", ftos(votecaller.playerid), ":", votecalledvote_display));
 139                                                 VoteCount(); // needed if you are the only one
 140                                         } else {
 141                                                 print_to(e, "^1This vote is not ok. See help for more info.");
 142                                         }
 143                                 }
 144                         } else {
 145                                 print_to(e, "^1Vote calling is NOT allowed.");
 146                         }
 147                 } else if(argv(1) == "stop") {
 148                         if(!votecalled) {
 149                                 print_to(e, "^1No vote called.");
 150                         } else if(e == votecaller) { // the votecaller can stop a vote
 151                                 VoteStop(e);
 152                         } else if(!e) { // server admin / console can too
 153                                 VoteStop(e);
 154                         } else if(e.vote_master) { // masters can too
 155                                 VoteStop(e);
 156                         } else {
 157                                 print_to(e, "^1You are not allowed to stop that Vote.");
 158                         }
 159                 } else if(argv(1) == "master") {
 160                         if(cvar("sv_vote_master")) {
 161                                 if(votecalled) {
 162                                         print_to(e, "^1There is already a vote called.");
 163                                 } else {
 164                                         votecalled = TRUE;
 165                                         votecalledmaster = TRUE;
 166                                         votecalledvote = strzone("XXX");
 167                                         votecalledvote_display = strzone("^3master");
 168                                         votefinished = time + cvar("sv_vote_timeout");
 169                                         votecaller = e; // remember who called the vote
 170                                         if(e) {
 171                                                 e.vote_vote = 1; // of course you vote yes
 172                                                 e.vote_next = time + cvar("sv_vote_wait");
 173                                         }
 174                                         bprint("\{1}^2* ^3", VoteNetname(votecaller), "^2 calls a vote to become ^3master^2.\n");
 175                                         if(cvar("sv_eventlog"))
 176                                                 GameLogEcho(strcat(":vote:vcall:", ftos(votecaller.playerid), ":", votecalledvote_display));
 177                                         VoteCount(); // needed if you are the only one
 178                                 }
 179                         } else {
 180                                 print_to(e, "^1Vote to become master is NOT allowed.");
 181                         }
 182                 } else if(argv(1) == "do") {
 183                         if(!e || e.vote_master) {
 184                                 local string dovote, dovote_display;
 185                                 dovote = VoteParse();
 186                                 if(dovote == "") {
 187                                         print_to(e, "^1Your command was empty. See help for more info.");
 188                                 } else if(VoteCheckNasty(dovote)) {
 189                                         print_to(e, "Syntax error in command. See help for more info.");
 190                                 } else if(VoteAllowed(strcat1(argv(2)))) { // strcat seems to be necessary
 191                                         if(dovote == "chmap" || dovote == "gotomap") // won't work without arguments
 192                                                 return TRUE;
 193                                         if(substring(dovote, 0, 6) == "chmap ")
 194                                                 dovote = strcat("gotomap ", substring(dovote, 6, strlen(dovote) - 6));
 195                                         if(substring(dovote, 0, 8) == "gotomap ")
 196                                         {
 197                                                 if(!(dovote = ValidateMap(substring(dovote, 8, strlen(dovote) - 8), e)))
 198                                                         return TRUE;
 199                                                 dovote = strcat("gotomap ", dovote);
 200                                         }
 201
 202                                         dovote_display = dovote;
 203                                         if(substring(dovote, 0, 5) == "kick " || substring(dovote, 0, 8) == "kickban ")
 204                                         {
 205                                                 if(!(victim = GetKickVoteVictim(dovote, "vdo", e)))
 206                                                         return TRUE;
 207                                                 dovote = GetKickVoteVictim_newcommand;
 208                                                 dovote_display = strcat("^1", dovote, " (^7", victim.netname, "^1): ", GetKickVoteVictim_reason);
 209                                         }
 210                                         else if(dovote == "kick" || dovote == "kickban")
 211                                         {
 212                                                 print_to(e, strcat("Usage: ", dovote, " #playernumber (as in \"status\")\n"));
 213                                                 return TRUE;
 214                                         }
 215                                         bprint("\{1}^2* ^3", VoteNetname(e), "^2 used his ^3master^2 status to do \"^2", dovote_display, "^2\".\n");
 216                                         if(cvar("sv_eventlog"))
 217                                                 GameLogEcho(strcat(":vote:vdo:", ftos(e.playerid), ":", dovote_display));
 218                                         localcmd(strcat(dovote, "\n"));
 219                                 } else {
 220                                         print_to(e, "^1This command is not ok. See help for more info.");
 221                                 }
 222                         } else {
 223                                 print_to(e, "^1You are NOT a master.  You might need to login or vote to become master first. See help for more info.");
 224                         }
 225                 } else if(argv(1) == "login") {
 226                         local string masterpwd;
 227                         masterpwd = cvar_string("sv_vote_master_password");
 228                         if(masterpwd != "") {
 229                                 local float granted;
 230                                 granted = (masterpwd == argv(2));
 231                                 if (e)
 232                                         e.vote_master = granted;
 233                                 if(granted) {
 234                                         print("Accepted master login from ", VoteNetname(e), "\n");
 235                                         bprint("\{1}^2* ^3", VoteNetname(e), "^2 logged in as ^3master^2\n");
 236                                         if(cvar("sv_eventlog"))
 237                                                 GameLogEcho(strcat(":vote:vlogin:", ftos(e.playerid)));
 238                                 }
 239                                 else
 240                                         print("REJECTED master login from ", VoteNetname(e), "\n");
 241                         }
 242                         else
 243                                 print_to(e, "^1Login to become master is NOT allowed.");
 244                 } else if(argv(1) == "yes") {
 245                         if(!votecalled) {
 246                                 print_to(e, "^1No vote called.");
 247                         } else if (!e) {
 248                                 print_to(e, "^1You can't vote from the server console.");
 249                         } else if(e.vote_vote == 0
 250                                   || cvar("sv_vote_change")) {
 251                                 print_to(e, "^1You accepted the vote.");
 252                                 e.vote_vote = 1;
 253                                 centerprint_expire(e, CENTERPRIO_VOTE);
 254                                 if(!cvar("sv_vote_singlecount")) {
 255                                         VoteCount();
 256                                 }
 257                         } else {
 258                                 print_to(e, "^1You have already voted.");
 259                         }
 260                 } else if(argv(1) == "no") {
 261                         if(!votecalled) {
 262                                 print_to(e, "^1No vote called.");
 263                         } else if (!e) {
 264                                 print_to(e, "^1You can't vote from the server console.");
 265                         } else if(e.vote_vote == 0
 266                                   || cvar("sv_vote_change")) {
 267                                 print_to(e, "^1You rejected the vote.");
 268                                 e.vote_vote = -1;
 269                                 centerprint_expire(e, CENTERPRIO_VOTE);
 270                                 if(!cvar("sv_vote_singlecount")) {
 271                                         VoteCount();
 272                                 }
 273                         } else {
 274                                 print_to(e, "^1You have already voted.");
 275                         }
 276                 } else if(argv(1) == "abstain" || argv(1) == "dontcare") {
 277                         if(!votecalled) {
 278                                 print_to(e, "^1No vote called.");
 279                         } else if (!e) {
 280                                 print_to(e, "^1You can't vote from the server console.");
 281                         } else if(e.vote_vote == 0
 282                                   || cvar("sv_vote_change")) {
 283                                 print_to(e, "^1You abstained from your vote.");
 284                                 e.vote_vote = -2;
 285                                 centerprint_expire(e, CENTERPRIO_VOTE);
 286                                 if(!cvar("sv_vote_singlecount")) {
 287                                         VoteCount();
 288                                 }
 289                         } else {
 290                                 print_to(e, "^1You have already voted.");
 291                         }
 292                 } else {
 293                         // ignore this?
 294                         print_to(e, "^1Unknown vote command.");
 295                 }
 296                 return TRUE;
 297         }
 298         return FALSE;
 299 }
 300
 301 void VoteHelp(entity e) {
 302         local string vmasterdis;
 303         if(!cvar("sv_vote_master")) {
 304                 vmasterdis = " ^1(disabled)";
 305         }
 306
 307         local string vlogindis;
 308         if("" == cvar_string("sv_vote_master_password")) {
 309                 vlogindis = " ^1(disabled)";
 310         }
 311
 312         local string vcalldis;
 313         if(!cvar("sv_vote_call")) {
 314                 vcalldis = " ^1(disabled)";
 315         }
 316
 317         print_to(e, "^7You can use voting with \"^2cmd vote help^7\" \"^2cmd vote status^7\" \"^2cmd vote call ^3COMMAND ARGUMENTS^7\" \"^2cmd vote stop^7\" \"^2cmd vote master^7\" \"^2cmd vote login^7\" \"^2cmd vote do ^3COMMAND ARGUMENTS^7\" \"^2cmd vote yes^7\" \"^2cmd vote no^7\" \"^2cmd vote abstain^7\" \"^2cmd vote dontcare^7\".");
 318         print_to(e, "^7Or if your version is up to date you can use these aliases \"^2vhelp^7\" \"^2vstatus^7\" \"^2vcall ^3COMMAND ARGUMENTS^7\" \"^2vstop^7\" \"^2vmaster^7\" \"^2vlogin^7\" \"^2vdo ^3COMMAND ARGUMENTS^7\" \"^2vyes^7\" \"^2vno^7\" \"^2abstain^7\" \"^2vdontcare^7\".");
 319         print_to(e, "^7\"^2help^7\" shows this info.");
 320         print_to(e, "^7\"^2status^7\" shows if there is a vote called and who called it.");
 321         print_to(e, strcat("^7\"^2call^7\" is used to call a vote. See the list of allowed commands.", vcalldis, "^7"));
 322         print_to(e, "^7\"^2stop^7\" can be used by the vote caller or an admin to stop a vote and maybe correct it.");
 323         print_to(e, strcat("^7\"^2master^7\" call a vote to become master who can execute commands without a vote", vmasterdis, "^7"));
 324         print_to(e, strcat("^7\"^2login^7\" login to become master who can execute commands without a vote.", vlogindis, "^7"));
 325         print_to(e, "^7\"^2do^7\" executes a command if you are a master. See the list of allowed commands.");
 326         print_to(e, "^7\"^2yes^7\", \"^2no^7\", \"^2abstain^7\" and \"^2dontcare^7\" to make your vote.");
 327         print_to(e, "^7If enough of the players vote yes the vote is accepted.");
 328         print_to(e, "^7If enough of the players vote no the vote is rejected.");
 329         print_to(e, strcat("^7If neither the vote will timeout after ", cvar_string("sv_vote_timeout"), "^7 seconds."));
 330         print_to(e, "^7You can call a vote for or execute these commands:");
 331         print_to(e, strcat("^3", cvar_string("sv_vote_commands"), "^7 and maybe further ^3arguments^7"));
 332 }
 333
 334 string VoteNetname(entity e)
 335 {
 336         if(e) {
 337                 return e.netname;
 338         } else {
 339                 if(cvar_string("sv_adminnick") != "") {
 340                         return cvar_string("sv_adminnick");
 341                 } else {
 342                         return cvar_string("hostname");
 343                 }
 344         }
 345 }
 346
 347 string ValidateMap(string m, entity e)
 348 {
 349         m = MapInfo_FixName(m);
 350         if(!m)
 351         {
 352                 print_to(e, "This map is not available on this server.");
 353                 return string_null;
 354         }
 355         if(!cvar("sv_vote_override_mostrecent"))
 356                 if(Map_IsRecent(m))
 357                 {
 358                         print_to(e, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 359                         return string_null;
 360                 }
 361         if(!MapInfo_CheckMap(m))
 362         {
 363                 print_to(e, strcat("^1Invalid mapname, \"^3", m, "^1\" does not support the current game mode."));
 364                 return string_null;
 365         }
 366
 367         return m;
 368 }
 369
 370
 371 void VoteThink() {
 372         if(votefinished > 0) // a vote was called
 373         if(time > votefinished) // time is up
 374         {
 375                 VoteCount();
 376         }
 377 }
 378
 379 string VoteParse() {
 380         local float index;
 381         index = 3;
 382         local string vote;
 383         vote = argv(2);
 384         while(argv(index) != "") {
 385                 vote = strcat(vote, " ", argv(index));
 386                 ++index;
 387         }
 388
 389         return vote;
 390 }
 391
 392 float VoteAllowed(string votecommand) {
 393         tokenize(cvar_string("sv_vote_commands"));
 394         local float index;
 395         index = 0;
 396         while(argv(index) != "") {
 397                 if(votecommand == argv(index)) {
 398                         return TRUE;
 399                 }
 400                 ++index;
 401         }
 402         return FALSE;
 403 }
 404
 405 void VoteReset() {
 406         local entity player;
 407
 408         FOR_EACH_CLIENT(player)
 409         {
 410                 player.vote_vote = 0;
 411                 centerprint_expire(player, CENTERPRIO_VOTE);
 412         }
 413
 414         if(votecalled)
 415         {
 416                 strunzone(votecalledvote);
 417                 strunzone(votecalledvote_display);
 418         }
 419
 420         votecalled = FALSE;
 421         votecalledmaster = FALSE;
 422         votefinished = 0;
 423 }
 424
 425 void VoteAccept() {
 426         bprint("\{1}^2* ^3", VoteNetname(votecaller), "^2's vote for ^1", votecalledvote_display, "^2 was accepted\n");
 427         if(votecalledmaster)
 428         {
 429                 if(votecaller) {
 430                         votecaller.vote_master = 1;
 431                 }
 432         } else {
 433                 localcmd(strcat(votecalledvote, "\n"));
 434         }
 435         if(votecaller) {
 436                 votecaller.vote_next = 0; // people like your votes,
 437                                           // no wait for next vote
 438         }
 439         VoteReset();
 440 }
 441
 442 void VoteReject() {
 443         bprint("\{1}^2* ^3", VoteNetname(votecaller), "^2's vote for ", votecalledvote_display, "^2 was rejected\n");
 444         VoteReset();
 445 }
 446
 447 void VoteTimeout() {
 448         bprint("\{1}^2* ^3", VoteNetname(votecaller), "^2's vote for ", votecalledvote_display, "^2 timed out\n");
 449         VoteReset();
 450 }
 451
 452 void VoteStop(entity stopper) {
 453         bprint("\{1}^2* ^3", VoteNetname(stopper), "^2 stopped ^3", VoteNetname(votecaller), "^2's vote\n");
 454         if(cvar("sv_eventlog"))
 455                 GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 456         if(stopper == votecaller) {
 457                 // no wait for next vote so you can correct your vote
 458                 if(votecaller) {
 459                         votecaller.vote_next = 0;
 460                 }
 461         }
 462         VoteReset();
 463 }
 464
 465 void VoteNag() {
 466         if(votecalled)
 467         if(self.vote_vote == 0)
 468                 centerprint_atprio(self, CENTERPRIO_VOTE, strcat("^7^3", VoteNetname(votecaller), "^2 called a vote for ", votecalledvote_display, "\n\n^2You have not voted yet!\n^2HINT: By default, F1 is yes and F2 is no."));
 469 }
 470
 471 void VoteSpam(float yescount, float nocount, float abstaincount, float notvoters, float mincount, string result)
 472 {
 473         string s;
 474         if(mincount >= 0)
 475         {
 476                 s = strcat("\{1}^2* vote results: ^1", ftos(yescount), "^2:^1");
 477                 s = strcat(s, ftos(nocount), "^2 (^1");
 478                 s = strcat(s, ftos(mincount), "^2 needed), ^1");
 479                 s = strcat(s, ftos(abstaincount), "^2 didn't care, ^1");
 480                 s = strcat(s, ftos(notvoters), "^2 didn't vote\n");
 481         }
 482         else
 483         {
 484                 s = strcat("\{1}^2* vote results: ^1", ftos(yescount), "^2:^1");
 485                 s = strcat(s, ftos(nocount), "^2, ^1");
 486                 s = strcat(s, ftos(abstaincount), "^2 didn't care, ^1");
 487                 s = strcat(s, ftos(notvoters), "^2 didn't have to vote\n");
 488         }
 489         bprint(s);
 490         if(cvar("sv_eventlog"))
 491         {
 492                 s = strcat(":vote:v", result, ":", ftos(yescount));
 493                 s = strcat(s, ":", ftos(nocount));
 494                 s = strcat(s, ":", ftos(abstaincount));
 495                 s = strcat(s, ":", ftos(notvoters));
 496                 s = strcat(s, ":", ftos(mincount));
 497                 GameLogEcho(s);
 498         }
 499 }
 500
 501 void VoteCount() {
 502         local float playercount;
 503         playercount = 0;
 504         local float yescount;
 505         yescount = 0;
 506         local float nocount;
 507         nocount = 0;
 508         local float abstaincount;
 509         abstaincount = 0;
 510         local entity player;
 511         //same for real players
 512         local float realplayercount;
 513         local float realplayeryescount;
 514         local float realplayernocount;
 515         local float realplayerabstaincount;
 516         realplayercount = realplayernocount = realplayerabstaincount = realplayeryescount = 0;
 517
 518         FOR_EACH_REALCLIENT(player)
 519         {
 520                 if(player.vote_vote == -1) {
 521                         ++nocount;
 522                 } else if(player.vote_vote == 1) {
 523                         ++yescount;
 524                 } else if(player.vote_vote == -2) {
 525                         ++abstaincount;
 526                 }
 527                 ++playercount;
 528                 //do the same for real players
 529                 if(player.classname == "player") {
 530                         if(player.vote_vote == -1) {
 531                                 ++realplayernocount;
 532                         } else if(player.vote_vote == 1) {
 533                                 ++realplayeryescount;
 534                         } else if(player.vote_vote == -2) {
 535                                 ++realplayerabstaincount;
 536                         }
 537                         ++realplayercount;
 538                 }
 539         }
 540
 541         //in tournament mode, if we have at least one player then don't make the vote dependent on spectators (so specs don't have to press F1)
 542         if(cvar("sv_vote_nospectators"))
 543         if(realplayercount > 0) {
 544                 yescount = realplayeryescount;
 545                 nocount = realplayernocount;
 546                 abstaincount = realplayerabstaincount;
 547                 playercount = realplayercount;
 548         }
 549
 550
 551         if(votecalledmaster
 552            && playercount == 1) {
 553                 // if only one player is on the server becoming vote
 554                 // master is not allowed.  This could be used for
 555                 // trolling or worse. 'self' is the user who has
 556                 // called the vote because this function is called
 557                 // by SV_ParseClientCommand. Maybe all voting should
 558                 // be disabled for a single player?
 559                 print_to(votecaller, "^1You are the only player on this server so you can not become vote master.");
 560                 if(votecaller) {
 561                         votecaller.vote_next = 0;
 562                 }
 563                 VoteReset();
 564         } else {
 565                 float votefactor;
 566                 votefactor = bound(0.5, cvar("sv_vote_majority_factor"), 0.999);
 567                 if(yescount > (playercount - abstaincount) * votefactor)
 568                 {
 569                         VoteSpam(yescount, nocount, abstaincount, playercount - yescount - nocount - abstaincount, -1, "yes");
 570                         VoteAccept();
 571                 }
 572                 else if(nocount >= (playercount - abstaincount) * (1 - votefactor)) // that means, yescount cannot reach minyes any more
 573                 {
 574                         VoteSpam(yescount, nocount, abstaincount, playercount - yescount - nocount - abstaincount, -1, "no");
 575                         VoteReject();
 576                 }
 577                 else if(time > votefinished)
 578                 {
 579                         if(cvar("sv_vote_simple_majority"))
 580                         {
 581                                 string result;
 582                                 if(yescount > (yescount + nocount) * votefactor)
 583                                         result = "yes";
 584                                 else if(yescount + nocount > 0)
 585                                         result = "no";
 586                                 else
 587                                         result = "timeout";
 588                                 VoteSpam(yescount, nocount, abstaincount, playercount - yescount - nocount - abstaincount, floor((yescount + nocount) * votefactor) + 1, result);
 589                                 if(result == "yes")
 590                                         VoteAccept();
 591                                 else if(result == "no")
 592                                         VoteReject();
 593                                 else
 594                                         VoteTimeout();
 595                         }
 596                         else
 597                         {
 598                                 VoteSpam(yescount, nocount, abstaincount, playercount - yescount - nocount - abstaincount, floor((playercount - abstaincount) * votefactor) + 1, "timeout");
 599                                 VoteTimeout();
 600                         }
 601                 }
 602         }
 603 }