data/qcsrc/server/teamplay.qc

   1 string cache_mutatormsg;
   2 string cache_lastmutatormsg;
   3
   4 // client counts for each team
   5 float c1, c2, c3, c4;
   6 // # of bots on those teams
   7 float cb1, cb2, cb3, cb4;
   8
   9 float audit_teams_time;
  10
  11 float IsTeamBalanceForced()
  12 {
  13         if(intermission_running)
  14                 return 0; // no rebalancing whatsoever please
  15         if(!teams_matter)
  16                 return 0;
  17         if(cvar("g_campaign"))
  18                 return 0;
  19         if(!cvar("g_balance_teams_force"))
  20                 return -1;
  21         return 1;
  22 }
  23
  24 void TeamchangeFrags(entity e)
  25 {
  26         PlayerScore_Clear(e);
  27 }
  28
  29 vector TeamColor(float teem)
  30 {
  31         switch(teem)
  32         {
  33                 case COLOR_TEAM1:
  34                         return '1 0.0625 0.0625';
  35                 case COLOR_TEAM2:
  36                         return '0.0625 0.0625 1';
  37                 case COLOR_TEAM3:
  38                         return '1 1 0.0625';
  39                 case COLOR_TEAM4:
  40                         return '1 0.0625 1';
  41                 default:
  42                         return '1 1 1';
  43         }
  44 }
  45
  46 string TeamName(float t)
  47 {
  48         return strcat(Team_ColorName(t), " Team");
  49 }
  50 string ColoredTeamName(float t)
  51 {
  52         return strcat(Team_ColorCode(t), Team_ColorName(t), " Team^7");
  53 }
  54 string TeamNoName(float t)
  55 {
  56         // fixme: Search for team entities and get their .netname's!
  57         if(t == 1)
  58                 return "Red Team";
  59         if(t == 2)
  60                 return "Blue Team";
  61         if(t == 3)
  62                 return "Yellow Team";
  63         if(t == 4)
  64                 return "Pink Team";
  65         return "Neutral Team";
  66 }
  67
  68 void dom_init();
  69 void ctf_init();
  70 void runematch_init();
  71 void tdm_init();
  72 void nb_init();
  73 void entcs_init();
  74
  75 void LogTeamchange(entity pl)
  76 {
  77         string str;
  78         if(!cvar("sv_eventlog"))
  79                 return;
  80         if(pl.playerid < 1)
  81                 return;
  82         str = strcat(":team:", ftos(pl.playerid), ":");
  83         str = strcat(str, ftos(pl.team));
  84         GameLogEcho(str);
  85 }
  86
  87 void WriteGameCvars()
  88 {
  89         cvar_set("g_dm", ftos(g_dm));
  90         cvar_set("g_tdm", ftos(g_tdm));
  91         cvar_set("g_domination", ftos(g_domination));
  92         cvar_set("g_ctf", ftos(g_ctf));
  93         cvar_set("g_runematch", ftos(g_runematch));
  94         cvar_set("g_lms", ftos(g_lms));
  95         cvar_set("g_arena", ftos(g_arena));
  96         cvar_set("g_keyhunt", ftos(g_keyhunt));
  97         cvar_set("g_assault", ftos(g_assault));
  98         cvar_set("g_onslaught", ftos(g_onslaught));
  99         cvar_set("g_race", ftos(g_race));
 100         cvar_set("g_nexball", ftos(g_nexball));
 101 }
 102
 103 void ReadGameCvars()
 104 {
 105         float found;
 106         float prev;
 107         float i;
 108
 109         found = 0;
 110         prev = cvar("gamecfg");
 111         for(i = 0; i < 2; ++i)
 112         {
 113                 found += (g_dm = (!found && (prev != GAME_DEATHMATCH) && cvar("g_dm")));
 114                 found += (g_tdm = (!found && (prev != GAME_TEAM_DEATHMATCH) && cvar("g_tdm")));
 115                 found += (g_domination = (!found && (prev != GAME_DOMINATION) && cvar("g_domination")));
 116                 found += (g_ctf = (!found && (prev != GAME_CTF) && cvar("g_ctf")));
 117                 found += (g_runematch = (!found && (prev != GAME_RUNEMATCH) && cvar("g_runematch")));
 118                 found += (g_lms = (!found && (prev != GAME_LMS) && cvar("g_lms")));
 119                 found += (g_arena = (!found && (prev != GAME_ARENA) && cvar("g_arena")));
 120                 found += (g_keyhunt = (!found && (prev != GAME_KEYHUNT) && cvar("g_keyhunt")));
 121                 found += (g_assault = (!found && (prev != GAME_ASSAULT) && cvar("g_assault")));
 122                 found += (g_onslaught = (!found && (prev != GAME_ONSLAUGHT) && cvar("g_onslaught")));
 123                 found += (g_race = (!found && (prev != GAME_RACE) && cvar("g_race")));
 124                 found += (g_nexball = (!found && (prev != GAME_NEXBALL) && cvar("g_nexball")));
 125
 126                 if(found)
 127                         break;
 128
 129                 prev = -1; // second attempt takes place WITHOUT prev set
 130         }
 131
 132         if(!found)
 133                 g_dm = 1;
 134
 135         if(g_dm && cvar("deathmatch_force_teamplay"))
 136         {
 137                 g_dm = 0;
 138                 g_tdm = 1;
 139         }
 140
 141         teams_matter = 0;
 142 }
 143
 144 void default_delayedinit()
 145 {
 146         if(!scores_initialized)
 147                 ScoreRules_generic();
 148 }
 149
 150 void ActivateTeamplay()
 151 {
 152         float teamplay_default;
 153         teamplay_default = cvar("teamplay_default");
 154
 155         if(teamplay_default)
 156                 teamplay = teamplay_default;
 157         else
 158                 teamplay = 3;
 159         cvar_set("teamplay", ftos(teamplay));
 160
 161         teams_matter = 1;
 162 }
 163
 164 void InitGameplayMode()
 165 {
 166         float fraglimit_override, timelimit_override;
 167
 168         VoteReset();
 169
 170         teams_matter = 0;
 171         cvar_set("teamplay", "0");
 172
 173         // make sure only ONE type is selected
 174         ReadGameCvars();
 175         WriteGameCvars();
 176
 177         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 178         get_mi_min_max(1);
 179         world.mins = mi_min;
 180         world.maxs = mi_max;
 181
 182         MapInfo_LoadMapSettings(mapname);
 183
 184         if not(cvar_value_issafe(world.fog))
 185         {
 186                 print("The current map contains a potentially harmful fog setting, ignored\n");
 187                 world.fog = string_null;
 188         }
 189         if(MapInfo_Map_fog != "")
 190                 if(MapInfo_Map_fog == "none")
 191                         world.fog = string_null;
 192                 else
 193                         world.fog = strzone(MapInfo_Map_fog);
 194         clientstuff = strzone(MapInfo_Map_clientstuff);
 195
 196         MapInfo_ClearTemps();
 197
 198         // in case mapinfo switched the type
 199         ReadGameCvars();
 200
 201         // set both here, gamemode can override it later
 202         timelimit_override = cvar("timelimit_override");
 203         fraglimit_override = cvar("fraglimit_override");
 204
 205         if(g_dm)
 206         {
 207                 game = GAME_DEATHMATCH;
 208                 gamemode_name = "Deathmatch";
 209         }
 210
 211         if(g_tdm)
 212         {
 213                 game = GAME_TEAM_DEATHMATCH;
 214                 gamemode_name = "Team Deathmatch";
 215                 ActivateTeamplay();
 216                 tdm_init();
 217         }
 218
 219         if(g_domination)
 220         {
 221                 game = GAME_DOMINATION;
 222                 gamemode_name = "Domination";
 223                 ActivateTeamplay();
 224                 fraglimit_override = cvar("g_domination_point_limit");
 225                 dom_init();
 226         }
 227
 228         if(g_ctf)
 229         {
 230                 game = GAME_CTF;
 231                 gamemode_name = "Capture the Flag";
 232                 ActivateTeamplay();
 233                 if(cvar("g_campaign"))
 234                         g_ctf_win_mode = 2;
 235                 else
 236                         g_ctf_win_mode = cvar("g_ctf_win_mode");
 237                 g_ctf_ignore_frags = cvar("g_ctf_ignore_frags");
 238                 if(g_ctf_win_mode == 2)
 239                         fraglimit_override = cvar("g_ctf_capture_limit");
 240                 else
 241                         fraglimit_override = cvar("capturelimit_override");
 242                 ctf_init();
 243         }
 244
 245         if(g_runematch)
 246         {
 247                 game = GAME_RUNEMATCH;
 248                 gamemode_name = "Rune Match";
 249                 if(cvar("deathmatch_force_teamplay"))
 250                         ActivateTeamplay();
 251                 fraglimit_override = cvar("g_runematch_point_limit");
 252                 runematch_init();
 253         }
 254
 255         if(g_lms)
 256         {
 257                 game = GAME_LMS;
 258                 gamemode_name = "Last Man Standing";
 259                 fraglimit_override = cvar("g_lms_lives_override");
 260                 if(fraglimit_override == 0)
 261                         fraglimit_override = -1;
 262                 lms_lowest_lives = 9999;
 263                 lms_next_place = 0;
 264                 ScoreRules_lms();
 265         }
 266
 267         if(g_arena)
 268         {
 269                 game = GAME_ARENA;
 270                 gamemode_name = "Arena";
 271                 fraglimit_override = cvar("g_arena_point_limit");
 272                 maxspawned = cvar("g_arena_maxspawned");
 273                 if(maxspawned < 2)
 274                         maxspawned = 2;
 275                 arena_roundbased = cvar("g_arena_roundbased");
 276         }
 277
 278         if(g_keyhunt)
 279         {
 280                 game = GAME_KEYHUNT;
 281                 gamemode_name = "Key Hunt";
 282                 ActivateTeamplay();
 283                 fraglimit_override = cvar("g_keyhunt_point_limit");
 284                 kh_init();
 285         }
 286
 287         if(g_assault)
 288         {
 289                 game = GAME_ASSAULT;
 290                 gamemode_name = "Assault";
 291                 ActivateTeamplay();
 292                 ScoreRules_assault();
 293         }
 294
 295         if(g_onslaught)
 296         {
 297                 game = GAME_ONSLAUGHT;
 298                 gamemode_name = "Onslaught";
 299                 ActivateTeamplay();
 300         }
 301
 302         if(g_race)
 303         {
 304                 game = GAME_RACE;
 305                 gamemode_name = "Race";
 306                 g_race_qualifying = cvar("g_race_qualifying");
 307
 308                 if(cvar("g_race_teams"))
 309                 {
 310                         g_race_qualifying = 0; // not supported!
 311                         ActivateTeamplay();
 312                         race_teams = bound(2, cvar("g_race_teams"), 4);
 313                 }
 314                 else
 315                         race_teams = 0;
 316
 317                 if(g_race_qualifying == 1)
 318                         fraglimit_override = 0;
 319                 else
 320                         fraglimit_override = cvar("g_race_laps_limit");
 321
 322                 if(g_race_qualifying)
 323                         independent_players = 1;
 324
 325                 ScoreRules_race();
 326         }
 327
 328         if(g_nexball)
 329         {
 330                 game = GAME_NEXBALL;
 331                 gamemode_name = "Nexball";
 332                 fraglimit_override = cvar("g_nexball_goallimit");
 333                 ActivateTeamplay();
 334                 nb_init();
 335                 ScoreRules_nexball();
 336         }
 337
 338         if(teams_matter)
 339                 entcs_init();
 340
 341         // save it (for the next startup)
 342         cvar_set("gamecfg", ftos(game));
 343
 344         cache_mutatormsg = strzone("");
 345         cache_lastmutatormsg = strzone("");
 346
 347         // enforce the server's universal frag/time limits
 348         if(!cvar("g_campaign"))
 349         {
 350                 if(fraglimit_override >= 0)
 351                         cvar_set("fraglimit", ftos(fraglimit_override));
 352                 if(timelimit_override >= 0)
 353                         cvar_set("timelimit", ftos(timelimit_override));
 354         }
 355
 356         if(g_race && g_race_qualifying == 2)
 357         {
 358                 race_fraglimit = cvar("fraglimit");
 359                 cvar_set("fraglimit", "0");
 360         }
 361
 362         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 363 }
 364
 365 string GetClientVersionMessage() {
 366         local string versionmsg;
 367         if (self.version_mismatch) {
 368                 if(self.version < cvar("gameversion")) {
 369                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 370                 } else {
 371                         versionmsg = "^3This server is using an outdated Nexuiz version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 372                 }
 373         } else {
 374                 versionmsg = "^2client version and server version are compatible.^8";
 375         }
 376         return versionmsg;
 377 }
 378
 379
 380 void PrintWelcomeMessage(entity pl)
 381 {
 382         string s, modifications, motd;
 383
 384         if(self.cvar_scr_centertime == 0) return;
 385         if((time - self.jointime) > cvar("welcome_message_time")
 386            && !self.BUTTON_INFO)
 387                 return;
 388
 389         if( !(timeoutStatus >= 1) ) { //really print the WelcomeMessage to the player every frame when timeout-seconds are shown or the game is restarted, to make sure that the shown number is accurate
 390                 if(self.welcomemessage_time > time) return;
 391                 self.welcomemessage_time = time + self.cvar_scr_centertime * 0.6;
 392         }
 393
 394         if(cvar("g_campaign"))
 395         {
 396                 centerprint(pl, campaign_message);
 397                 return;
 398         }
 399
 400 //TODO GreEn`mArine: make the timeout-messages clientside as well (just like the ready restart countdown)!
 401         if(!self.BUTTON_INFO)
 402         {
 403                 // TODO get rid of this too
 404                 local string specString;
 405                 specString = NEWLINES;
 406                 //if(time < game_starttime) //also show the countdown when being a spectator
 407                 //      specString = strcat(specString, "\n\n^1Game starts in ", ftos(ceil(game_starttime - time)), " seconds^7");
 408                 //else
 409                 if (timeoutStatus != 0)
 410                         specString = strcat(specString, "\n\n", getTimeoutText(1));
 411                 else
 412                 {
 413                         if(!self.BUTTON_INFO && self.classname == "player")
 414                                 return;
 415                         goto normal;
 416                 }
 417                 return centerprint_atprio(self, CENTERPRIO_SPAM, specString);
 418         }
 419
 420 :normal
 421         modifications = "";
 422         if(g_minstagib)
 423                 modifications = strcat(modifications, ", MinstaGib");
 424         if(g_nixnex)
 425                 modifications = strcat(modifications, ", NixNex");
 426         if(g_weaponarena)
 427                 modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 428         if(cvar("sv_gravity") < 800)
 429                 modifications = strcat(modifications, ", Low gravity");
 430         if(g_cloaked)
 431                 modifications = strcat(modifications, ", Cloaked");
 432         if(g_footsteps)
 433                 modifications = strcat(modifications, ", Steps");
 434         if(g_grappling_hook)
 435                 modifications = strcat(modifications, ", Hook");
 436         if(g_laserguided_missile)
 437                 modifications = strcat(modifications, ", LG missiles");
 438         if(g_midair)
 439                 modifications = strcat(modifications, ", Midair");
 440         if(g_vampire)
 441                 modifications = strcat(modifications, ", Vampire");
 442         if(g_pinata)
 443                 modifications = strcat(modifications, ", Pinata");
 444         if(g_weapon_stay)
 445                 modifications = strcat(modifications, ", Weapons stay");
 446         if(g_bloodloss > 0)
 447                 modifications = strcat(modifications, ", Bloodloss");
 448         if(g_jetpack)
 449                 modifications = strcat(modifications, ", Jet pack");
 450         modifications = substring(modifications, 2, strlen(modifications) - 2);
 451
 452         local string versionmessage;
 453         versionmessage = GetClientVersionMessage();
 454
 455         s = strcat(s, NEWLINES, "This is Nexuiz ", cvar_string("g_nexuizversion"), "\n", versionmessage);
 456         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 457
 458         if(modifications != "")
 459                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 460
 461         if(timeoutStatus != 0)
 462                 s = strcat(s, "\n\n", getTimeoutText(1));
 463
 464         if (g_grappling_hook)
 465                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 466
 467         if(cache_lastmutatormsg != cvar_string("g_mutatormsg"))
 468         {
 469                 if(cache_lastmutatormsg)
 470                         strunzone(cache_lastmutatormsg);
 471                 if(cache_mutatormsg)
 472                         strunzone(cache_mutatormsg);
 473                 cache_lastmutatormsg = strzone(cvar_string("g_mutatormsg"));
 474                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 475         }
 476
 477         if (cache_mutatormsg != "") {
 478                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 479         }
 480
 481         motd = cvar_string("sv_motd");
 482         if (motd != "") {
 483                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 484         }
 485         s = strcat(s, "\n");
 486
 487         centerprint(pl, s);
 488 }
 489
 490
 491 void SetPlayerColors(entity pl, float _color)
 492 {
 493         /*string s;
 494         s = ftos(cl);
 495         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 496         pl.team = cl + 1;
 497         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 498         pl.clientcolors = 16*cl + cl;*/
 499
 500         float pants, shirt;
 501         pants = _color & 0x0F;
 502         shirt = _color & 0xF0;
 503
 504
 505         if(teams_matter) {
 506                 setcolor(pl, 16*pants + pants);
 507         } else {
 508                 setcolor(pl, shirt + pants);
 509         }
 510 }
 511
 512 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 513 {
 514         float _color;
 515
 516         if(t == 4)
 517                 _color = COLOR_TEAM4 - 1;
 518         else if(t == 3)
 519                 _color = COLOR_TEAM3 - 1;
 520         else if(t == 2)
 521                 _color = COLOR_TEAM2 - 1;
 522         else
 523                 _color = COLOR_TEAM1 - 1;
 524
 525         SetPlayerColors(pl,_color);
 526
 527         if(!noprint && t != s)
 528         {
 529                 //bprint(pl.netname, " has changed to ", TeamNoName(t), "\n");
 530                 bprint(pl.netname, "^7 has changed from ", TeamNoName(s), " to ", TeamNoName(t), "\n");
 531         }
 532
 533         if(t != s)
 534                 LogTeamchange(pl);
 535 }
 536
 537
 538
 539
 540
 541
 542 // set c1...c4 to show what teams are allowed
 543 void CheckAllowedTeams (entity for_whom)
 544 {
 545         string teament_name;
 546         float dm;
 547         entity head;
 548
 549 //      if(!dom && !ctf)
 550 //              dm = 1;
 551
 552         c1 = c2 = c3 = c4 = -1;
 553         cb1 = cb2 = cb3 = cb4 = 0;
 554
 555         // onslaught is special
 556         if(g_onslaught)
 557         {
 558                 head = findchain(classname, "onslaught_generator");
 559                 while (head)
 560                 {
 561                         if (head.team == COLOR_TEAM1) c1 = 0;
 562                         if (head.team == COLOR_TEAM2) c2 = 0;
 563                         if (head.team == COLOR_TEAM3) c3 = 0;
 564                         if (head.team == COLOR_TEAM4) c4 = 0;
 565                         head = head.chain;
 566                 }
 567                 return;
 568         }
 569
 570         if(g_domination)
 571                 teament_name = "dom_team";
 572         else if(g_ctf)
 573                 teament_name = "ctf_team";
 574         else if(g_tdm)
 575                 teament_name = "tdm_team";
 576         else if(g_nexball)
 577                 teament_name = "nexball_team";
 578         else if(g_assault)
 579         {
 580                 c1 = c2 = 0; // Assault always has 2 teams
 581                 return;
 582         }
 583         else
 584         {
 585                 // cover anything else by treating it like tdm with no teams spawned
 586                 if(g_keyhunt)
 587                         dm = kh_teams;
 588                 else if(g_race)
 589                         dm = race_teams;
 590                 else
 591                         dm = cvar("g_tdm_teams");
 592                 if(dm < 2)
 593                         error("g_tdm_teams < 2, not enough teams to play team deathmatch\n");
 594
 595                 if(dm >= 4)
 596                 {
 597                         c1 = c2 = c3 = c4 = 0;
 598                 }
 599                 else if(dm >= 3)
 600                 {
 601                         c1 = c2 = c3 = 0;
 602                 }
 603                 else// if(dm >= 2)
 604                 {
 605                         c1 = c2 = 0;
 606                 }
 607                 return;
 608         }
 609
 610         // first find out what teams are allowed
 611         head = find(world, classname, teament_name);
 612         while(head)
 613         {
 614                 if(!(g_domination && head.netname == ""))
 615                 {
 616                         if(head.team == COLOR_TEAM1)
 617                         {
 618                                 c1 = 0;
 619                         }
 620                         if(head.team == COLOR_TEAM2)
 621                         {
 622                                 c2 = 0;
 623                         }
 624                         if(head.team == COLOR_TEAM3)
 625                         {
 626                                 c3 = 0;
 627                         }
 628                         if(head.team == COLOR_TEAM4)
 629                         {
 630                                 c4 = 0;
 631                         }
 632                 }
 633                 head = find(head, classname, teament_name);
 634         }
 635
 636         if(for_whom)
 637         {
 638                 if(cvar("bot_vs_human") > 0)
 639                 {
 640                         // bots are all blue
 641                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 642                                 c1 = c3 = c4 = -1;
 643                         else
 644                                 c2 = -1;
 645                 }
 646                 else if(cvar("bot_vs_human") < 0)
 647                 {
 648                         // bots are all red
 649                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 650                                 c2 = c3 = c4 = -1;
 651                         else
 652                                 c1 = -1;
 653                 }
 654         }
 655 }
 656
 657 float PlayerValue(entity p)
 658 {
 659         if(IsTeamBalanceForced() == 1)
 660                 return 1;
 661         return 1;
 662 }
 663
 664 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 665 // teams that are allowed will now have their player counts stored in c1...c4
 666 void GetTeamCounts(entity ignore)
 667 {
 668         entity head;
 669         float value, bvalue;
 670         // now count how many players are on each team already
 671
 672         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 673         // also remember the lowest-scoring player
 674
 675         FOR_EACH_PLAYER(head)
 676         {
 677                 if(head != ignore)// && head.netname != "")
 678                 {
 679                         value = PlayerValue(head);
 680                         if(clienttype(head) == CLIENTTYPE_BOT)
 681                                 bvalue = value;
 682                         else
 683                                 bvalue = 0;
 684                         if(head.team == COLOR_TEAM1)
 685                         {
 686                                 if(c1 >= 0)
 687                                 {
 688                                         c1 = c1 + value;
 689                                         cb1 = cb1 + bvalue;
 690                                 }
 691                         }
 692                         if(head.team == COLOR_TEAM2)
 693                         {
 694                                 if(c2 >= 0)
 695                                 {
 696                                         c2 = c2 + value;
 697                                         cb2 = cb2 + bvalue;
 698                                 }
 699                         }
 700                         if(head.team == COLOR_TEAM3)
 701                         {
 702                                 if(c3 >= 0)
 703                                 {
 704                                         c3 = c3 + value;
 705                                         cb3 = cb3 + bvalue;
 706                                 }
 707                         }
 708                         if(head.team == COLOR_TEAM4)
 709                         {
 710                                 if(c4 >= 0)
 711                                 {
 712                                         c4 = c4 + value;
 713                                         cb4 = cb4 + bvalue;
 714                                 }
 715                         }
 716                 }
 717         }
 718 }
 719
 720 // returns # of smallest team (1, 2, 3, 4)
 721 // NOTE: Assumes CheckAllowedTeams has already been called!
 722 float FindSmallestTeam(entity pl, float ignore_pl)
 723 {
 724         float totalteams, smallestteam, smallestteam_count, smallestteam_score, balance_type;
 725         totalteams = 0;
 726
 727         // find out what teams are available
 728         //CheckAllowedTeams();
 729
 730         // make sure there are at least 2 teams to join
 731         if(c1 >= 0)
 732                 totalteams = totalteams + 1;
 733         if(c2 >= 0)
 734                 totalteams = totalteams + 1;
 735         if(c3 >= 0)
 736                 totalteams = totalteams + 1;
 737         if(c4 >= 0)
 738                 totalteams = totalteams + 1;
 739
 740         if(cvar("bot_vs_human"))
 741                 totalteams += 1;
 742
 743         if(totalteams <= 1)
 744         {
 745                 if(g_domination)
 746                         error("Too few teams available for domination\n");
 747                 else if(g_ctf)
 748                         error("Too few teams available for ctf\n");
 749                 else if(g_keyhunt)
 750                         error("Too few teams available for key hunt\n");
 751                 else
 752                         error("Too few teams available for team deathmatch\n");
 753         }
 754
 755         // count how many players are in each team
 756         if(ignore_pl)
 757                 GetTeamCounts(pl);
 758         else
 759                 GetTeamCounts(world);
 760
 761         // c1...c4 now have counts of each team
 762         // figure out which is smallest, giving priority to the team the player is already on as a tie-breaker
 763
 764         smallestteam = 0;
 765         smallestteam_count = 999999999;
 766         smallestteam_score = 999999999;
 767
 768         // 2 gives priority to what team you're already on, 1 goes in order
 769         // 2 doesn't seem to work though...
 770         balance_type = 1;
 771
 772         if(bots_would_leave)
 773         //if(pl.classname != "player")
 774         if(clienttype(pl) != CLIENTTYPE_BOT)
 775         {
 776                 c1 -= cb1 * 255.0/256;
 777                 c2 -= cb2 * 255.0/256;
 778                 c3 -= cb3 * 255.0/256;
 779                 c4 -= cb4 * 255.0/256;
 780         }
 781
 782         if(balance_type == 1)
 783         {
 784                 if(c1 >= 0 && (c1 < smallestteam_count || (c1 <= smallestteam_count && team1_score < smallestteam_score)))
 785                 {
 786                         smallestteam = 1;
 787                         smallestteam_count = c1;
 788                         smallestteam_score = team1_score;
 789                 }
 790                 if(c2 >= 0 && (c2 < smallestteam_count || (c2 <= smallestteam_count && team2_score < smallestteam_score)))
 791                 {
 792                         smallestteam = 2;
 793                         smallestteam_count = c2;
 794                         smallestteam_score = team2_score;
 795                 }
 796                 if(c3 >= 0 && (c3 < smallestteam_count || (c3 <= smallestteam_count && team3_score < smallestteam_score)))
 797                 {
 798                         smallestteam = 3;
 799                         smallestteam_count = c3;
 800                         smallestteam_score = team3_score;
 801                 }
 802                 if(c4 >= 0 && (c4 < smallestteam_count || (c4 <= smallestteam_count && team4_score < smallestteam_score)))
 803                 {
 804                         smallestteam = 4;
 805                         smallestteam_count = c4;
 806                         smallestteam_score = team4_score;
 807                 }
 808         }
 809         else
 810         {
 811                 if(c1 >= 0 && (c1 < smallestteam_count ||
 812                                         (c1 == smallestteam_count && self.team == COLOR_TEAM1) ) )
 813                 {
 814                         smallestteam = 1;
 815                         smallestteam_count = c1;
 816                 }
 817                 if(c2 >= 0 && c2 < (c2 < smallestteam_count ||
 818                                         (c2 == smallestteam_count && self.team == COLOR_TEAM2) ) )
 819                 {
 820                         smallestteam = 2;
 821                         smallestteam_count = c2;
 822                 }
 823                 if(c3 >= 0 && c3 < (c3 < smallestteam_count ||
 824                                         (c3 == smallestteam_count && self.team == COLOR_TEAM3) ) )
 825                 {
 826                         smallestteam = 3;
 827                         smallestteam_count = c3;
 828                 }
 829                 if(c4 >= 0 && c4 < (c4 < smallestteam_count ||
 830                                         (c4 == smallestteam_count && self.team == COLOR_TEAM4) ) )
 831                 {
 832                         smallestteam = 4;
 833                         smallestteam_count = c4;
 834                 }
 835         }
 836
 837         return smallestteam;
 838 }
 839
 840 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 841 {
 842         float smallest, selectedteam;
 843
 844         // don't join a team if we're not playing a team game
 845         if(!teams_matter)
 846                 return 0;
 847
 848         // find out what teams are available
 849         CheckAllowedTeams(pl);
 850
 851         if(g_domination)
 852         {
 853                 // <div0> WHY? TODO
 854                 if(cvar("g_domination_default_teams") < 3)
 855                         c3 = 999999999;
 856                 if(cvar("g_domination_default_teams") < 4)
 857                         c4 = 999999999;
 858         }
 859
 860         // if we don't care what team he ends up on, put him on whatever team he entered as.
 861         // if he's not on a valid team, then let other code put him on the smallest team
 862         if(!forcebestteam)
 863         {
 864                 if(     c1 >= 0 && pl.team == COLOR_TEAM1)
 865                         selectedteam = pl.team;
 866                 else if(c2 >= 0 && pl.team == COLOR_TEAM2)
 867                         selectedteam = pl.team;
 868                 else if(c3 >= 0 && pl.team == COLOR_TEAM3)
 869                         selectedteam = pl.team;
 870                 else if(c4 >= 0 && pl.team == COLOR_TEAM4)
 871                         selectedteam = pl.team;
 872                 else
 873                         selectedteam = -1;
 874                 if(selectedteam > 0)
 875                 {
 876                         if(!only_return_best)
 877                         {
 878                                 SetPlayerColors(pl, selectedteam - 1);
 879                                 LogTeamchange(pl);
 880                         }
 881                         return selectedteam;
 882                 }
 883                 // otherwise end up on the smallest team (handled below)
 884         }
 885
 886         smallest = FindSmallestTeam(pl, TRUE);
 887
 888
 889         if(!only_return_best)
 890         {
 891                 TeamchangeFrags(self);
 892                 if(smallest == 1)
 893                 {
 894                         SetPlayerColors(pl, COLOR_TEAM1 - 1);
 895                 }
 896                 else if(smallest == 2)
 897                 {
 898                         SetPlayerColors(pl, COLOR_TEAM2 - 1);
 899                 }
 900                 else if(smallest == 3)
 901                 {
 902                         SetPlayerColors(pl, COLOR_TEAM3 - 1);
 903                 }
 904                 else if(smallest == 4)
 905                 {
 906                         SetPlayerColors(pl, COLOR_TEAM4 - 1);
 907                 }
 908                 else
 909                 {
 910                         error("smallest team: invalid team\n");
 911                 }
 912                 LogTeamchange(pl);
 913                 if(pl.deadflag == DEAD_NO)
 914                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 915         }
 916
 917         return smallest;
 918 }
 919
 920 //void() ctf_playerchanged;
 921 void SV_ChangeTeam(float _color)
 922 {
 923         float scolor, dcolor, steam, dteam, dbotcount, scount, dcount;
 924
 925         // in normal deathmatch we can just apply the color and we're done
 926         if(!teams_matter) {
 927                 SetPlayerColors(self, _color);
 928                 return;
 929         }
 930
 931         scolor = self.clientcolors & 0x0F;
 932         dcolor = _color & 0x0F;
 933
 934         if(scolor == COLOR_TEAM1 - 1)
 935                 steam = 1;
 936         else if(scolor == COLOR_TEAM2 - 1)
 937                 steam = 2;
 938         else if(scolor == COLOR_TEAM3 - 1)
 939                 steam = 3;
 940         else // if(scolor == COLOR_TEAM4 - 1)
 941                 steam = 4;
 942         if(dcolor == COLOR_TEAM1 - 1)
 943                 dteam = 1;
 944         else if(dcolor == COLOR_TEAM2 - 1)
 945                 dteam = 2;
 946         else if(dcolor == COLOR_TEAM3 - 1)
 947                 dteam = 3;
 948         else // if(dcolor == COLOR_TEAM4 - 1)
 949                 dteam = 4;
 950
 951         CheckAllowedTeams(self);
 952
 953         if(dteam == 1 && c1 < 0) dteam = 4;
 954         if(dteam == 4 && c4 < 0) dteam = 3;
 955         if(dteam == 3 && c3 < 0) dteam = 2;
 956         if(dteam == 2 && c2 < 0) dteam = 1;
 957
 958         // not changing teams
 959         if(scolor == dcolor)
 960         {
 961                 //bprint("same team change\n");
 962                 SetPlayerTeam(self, dteam, steam, TRUE);
 963                 return;
 964         }
 965
 966         if(cvar("g_campaign"))
 967         {
 968                 sprint(self, "Team changes not allowed\n");
 969                 return; // changing teams is not allowed
 970         }
 971
 972         if(cvar("g_changeteam_banned") && self.wasplayer)
 973         {
 974                 sprint(self, "Team changes not allowed\n");
 975                 return;
 976         }
 977
 978         if(cvar("g_balance_teams_prevent_imbalance"))
 979         {
 980                 // only allow changing to a smaller or equal size team
 981
 982                 // find out what teams are available
 983                 //CheckAllowedTeams();
 984                 // count how many players on each team
 985                 GetTeamCounts(world);
 986
 987                 // get desired team
 988                 if(dteam == 1 && c1 >= 0)//dcolor == COLOR_TEAM1 - 1)
 989                 {
 990                         dcount = c1;
 991                         dbotcount = cb1;
 992                 }
 993                 else if(dteam == 2 && c2 >= 0)//dcolor == COLOR_TEAM2 - 1)
 994                 {
 995                         dcount = c2;
 996                         dbotcount = cb2;
 997                 }
 998                 else if(dteam == 3 && c3 >= 0)//dcolor == COLOR_TEAM3 - 1)
 999                 {
1000                         dcount = c3;
1001                         dbotcount = cb3;
1002                 }
1003                 else if(dteam == 4 && c4 >= 0)//dcolor == COLOR_TEAM4 - 1)
1004                 {
1005                         dcount = c4;
1006                         dbotcount = cb4;
1007                 }
1008                 else
1009                 {
1010                         sprint(self, "Cannot change to an invalid team\n");
1011
1012                         return;
1013                 }
1014
1015                 // get starting team
1016                 if(steam == 1)//scolor == COLOR_TEAM1 - 1)
1017                         scount = c1;
1018                 else if(steam == 2)//scolor == COLOR_TEAM2 - 1)
1019                         scount = c2;
1020                 else if(steam == 3)//scolor == COLOR_TEAM3 - 1)
1021                         scount = c3;
1022                 else if(steam == 4)//scolor == COLOR_TEAM4 - 1)
1023                         scount = c4;
1024
1025                 if(scount) // started at a valid, nonempty team
1026                 {
1027                         // check if we're trying to change to a larger team that doens't have bots to swap with
1028                         if(dcount >= scount && dbotcount <= 0)
1029                         {
1030                                 sprint(self, "Cannot change to a larger team\n");
1031                                 return; // can't change to a larger team
1032                         }
1033                 }
1034         }
1035
1036 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
1037
1038         if(self.classname == "player" && steam != dteam)
1039         {
1040                 // reduce frags during a team change
1041                 TeamchangeFrags(self);
1042         }
1043
1044         SetPlayerTeam(self, dteam, steam, FALSE);
1045
1046         if(self.classname == "player" && steam != dteam)
1047         {
1048                 // kill player when changing teams
1049                 if(self.deadflag == DEAD_NO)
1050                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
1051         }
1052         //ctf_playerchanged();
1053 }
1054
1055 void ShufflePlayerOutOfTeam (float source_team)
1056 {
1057         float smallestteam, smallestteam_count, steam;
1058         float lowest_bot_score, lowest_player_score;
1059         entity head, lowest_bot, lowest_player, selected;
1060
1061         smallestteam = 0;
1062         smallestteam_count = 999999999;
1063
1064         if(c1 >= 0 && c1 < smallestteam_count)
1065         {
1066                 smallestteam = 1;
1067                 smallestteam_count = c1;
1068         }
1069         if(c2 >= 0 && c2 < smallestteam_count)
1070         {
1071                 smallestteam = 2;
1072                 smallestteam_count = c2;
1073         }
1074         if(c3 >= 0 && c3 < smallestteam_count)
1075         {
1076                 smallestteam = 3;
1077                 smallestteam_count = c3;
1078         }
1079         if(c4 >= 0 && c4 < smallestteam_count)
1080         {
1081                 smallestteam = 4;
1082                 smallestteam_count = c4;
1083         }
1084
1085         if(!smallestteam)
1086         {
1087                 bprint("warning: no smallest team\n");
1088                 return;
1089         }
1090
1091         if(source_team == 1)
1092                 steam = COLOR_TEAM1;
1093         else if(source_team == 2)
1094                 steam = COLOR_TEAM2;
1095         else if(source_team == 3)
1096                 steam = COLOR_TEAM3;
1097         else if(source_team == 4)
1098                 steam = COLOR_TEAM4;
1099
1100         lowest_bot = world;
1101         lowest_bot_score = 999999999;
1102         lowest_player = world;
1103         lowest_player_score = 999999999;
1104
1105         // find the lowest-scoring player & bot of that team
1106         FOR_EACH_PLAYER(head)
1107         {
1108                 if(head.team == steam)
1109                 {
1110                         if(head.isbot)
1111                         {
1112                                 if(head.totalfrags < lowest_bot_score)
1113                                 {
1114                                         lowest_bot = head;
1115                                         lowest_bot_score = head.totalfrags;
1116                                 }
1117                         }
1118                         else
1119                         {
1120                                 if(head.totalfrags < lowest_player_score)
1121                                 {
1122                                         lowest_player = head;
1123                                         lowest_player_score = head.totalfrags;
1124                                 }
1125                         }
1126                 }
1127         }
1128
1129         // prefers to move a bot...
1130         if(lowest_bot != world)
1131                 selected = lowest_bot;
1132         // but it will move a player if it has to
1133         else
1134                 selected = lowest_player;
1135         // don't do anything if it couldn't find anyone
1136         if(!selected)
1137         {
1138                 bprint("warning: couldn't find a player to move from team\n");
1139                 return;
1140         }
1141
1142         // smallest team gains a member
1143         if(smallestteam == 1)
1144         {
1145                 c1 = c1 + 1;
1146         }
1147         else if(smallestteam == 2)
1148         {
1149                 c2 = c2 + 1;
1150         }
1151         else if(smallestteam == 3)
1152         {
1153                 c3 = c3 + 1;
1154         }
1155         else if(smallestteam == 4)
1156         {
1157                 c4 = c4 + 1;
1158         }
1159         else
1160         {
1161                 bprint("warning: destination team invalid\n");
1162                 return;
1163         }
1164         // source team loses a member
1165         if(source_team == 1)
1166         {
1167                 c1 = c1 + 1;
1168         }
1169         else if(source_team == 2)
1170         {
1171                 c2 = c2 + 2;
1172         }
1173         else if(source_team == 3)
1174         {
1175                 c3 = c3 + 3;
1176         }
1177         else if(source_team == 4)
1178         {
1179                 c4 = c4 + 4;
1180         }
1181         else
1182         {
1183                 bprint("warning: source team invalid\n");
1184                 return;
1185         }
1186
1187         // move the player to the new team
1188         TeamchangeFrags(selected);
1189         SetPlayerTeam(selected, smallestteam, source_team, FALSE);
1190
1191         if(selected.deadflag == DEAD_NO)
1192                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
1193         centerprint(selected, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", ColoredTeamName(selected.team)));
1194 }
1195
1196 void CauseRebalance(float source_team, float howmany_toomany)
1197 {
1198         if(IsTeamBalanceForced() == 1)
1199         {
1200                 bprint("Rebalancing Teams\n");
1201                 ShufflePlayerOutOfTeam(source_team);
1202         }
1203 }
1204
1205 // part of g_balance_teams_force
1206 // occasionally perform an audit of the teams to make
1207 // sure they're more or less balanced in player count.
1208 void AuditTeams()
1209 {
1210         float numplayers, numteams, smallest, toomany;
1211         float balance;
1212         balance = IsTeamBalanceForced();
1213         if(balance == 0)
1214                 return;
1215
1216         if(audit_teams_time > time)
1217                 return;
1218
1219         audit_teams_time = time + 4 + random();
1220
1221 //      bprint("Auditing teams\n");
1222
1223         CheckAllowedTeams(world);
1224         GetTeamCounts(world);
1225
1226
1227         numteams = numplayers = smallest = 0;
1228         if(c1 >= 0)
1229         {
1230                 numteams = numteams + 1;
1231                 numplayers = numplayers + c1;
1232                 smallest = c1;
1233         }
1234         if(c2 >= 0)
1235         {
1236                 numteams = numteams + 1;
1237                 numplayers = numplayers + c2;
1238                 if(c2 < smallest)
1239                         smallest = c2;
1240         }
1241         if(c3 >= 0)
1242         {
1243                 numteams = numteams + 1;
1244                 numplayers = numplayers + c3;
1245                 if(c3 < smallest)
1246                         smallest = c3;
1247         }
1248         if(c4 >= 0)
1249         {
1250                 numteams = numteams + 1;
1251                 numplayers = numplayers + c4;
1252                 if(c4 < smallest)
1253                         smallest = c4;
1254         }
1255
1256         if(numplayers <= 0)
1257                 return; // no players to move around
1258         if(numteams < 2)
1259                 return; // don't bother shuffling if for some reason there aren't any teams
1260
1261         toomany = smallest + 1;
1262
1263         if(c1 && c1 > toomany)
1264                 CauseRebalance(1, c1 - toomany);
1265         if(c2 && c2 > toomany)
1266                 CauseRebalance(2, c2 - toomany);
1267         if(c3 && c3 > toomany)
1268                 CauseRebalance(3, c3 - toomany);
1269         if(c4 && c4 > toomany)
1270                 CauseRebalance(4, c4 - toomany);
1271
1272         // if teams are still unbalanced, balance them further in the next audit,
1273         // which will happen sooner (keep doing rapid audits until things are in order)
1274         audit_teams_time = time + 0.7 + random()*0.3;
1275 }
1276
1277 // code from here on is just to support maps that don't have team entities
1278 void tdm_spawnteam (string teamname, float teamcolor)
1279 {
1280         local entity e;
1281         e = spawn();
1282         e.classname = "tdm_team";
1283         e.netname = teamname;
1284         e.cnt = teamcolor;
1285         e.team = e.cnt + 1;
1286 };
1287
1288 // spawn some default teams if the map is not set up for tdm
1289 void tdm_spawnteams()
1290 {
1291         float numteams;
1292
1293         numteams = cvar("g_tdm_teams");
1294
1295         tdm_spawnteam("Red", COLOR_TEAM1-1);
1296         tdm_spawnteam("Blue", COLOR_TEAM2-1);
1297         if(numteams >= 3)
1298                 tdm_spawnteam("Yellow", COLOR_TEAM3-1);
1299         if(numteams >= 4)
1300                 tdm_spawnteam("Pink", COLOR_TEAM4-1);
1301 };
1302
1303 void tdm_delayedinit()
1304 {
1305         // if no teams are found, spawn defaults
1306         if (find(world, classname, "tdm_team") == world)
1307                 tdm_spawnteams();
1308 };
1309
1310 void tdm_init()
1311 {
1312         InitializeEntity(world, tdm_delayedinit, INITPRIO_GAMETYPE);
1313 };