data/qcsrc/server/t_teleporters.qc

   1 void trigger_teleport_use()
   2 {
   3         if(teams_matter)
   4                 self.team = activator.team;
   5 }
   6
   7 float tdeath_hit;
   8 void tdeath(entity player, entity teleporter, entity telefragger, vector telefragmin, vector telefragmax)
   9 {
  10         entity head;
  11         vector deathmin;
  12         vector deathmax;
  13         float deathradius;
  14         deathmin = player.absmin;
  15         deathmax = player.absmax;
  16         if(telefragmin != telefragmax)
  17         {
  18                 if(deathmin_x > telefragmin_x) deathmin_x = telefragmin_x;
  19                 if(deathmin_y > telefragmin_y) deathmin_y = telefragmin_y;
  20                 if(deathmin_z > telefragmin_z) deathmin_z = telefragmin_z;
  21                 if(deathmax_x < telefragmax_x) deathmax_x = telefragmax_x;
  22                 if(deathmax_y < telefragmax_y) deathmax_y = telefragmax_y;
  23                 if(deathmax_z < telefragmax_z) deathmax_z = telefragmax_z;
  24         }
  25         deathradius = max(vlen(deathmin), vlen(deathmax));
  26         for(head = findradius(player.origin, deathradius); head; head = head.chain)
  27                 if(head != player)
  28                         if(head.takedamage)
  29                                 if(boxesoverlap(deathmin, deathmax, head.absmin, head.absmax))
  30                                 {
  31                                         if ((player.classname == "player") && (player.health >= 1))
  32                                                 Damage (head, teleporter, telefragger, 10000, DEATH_TELEFRAG, head.origin, '0 0 0');
  33                                         else if (telefragger.health < 1) // corpses gib
  34                                                 Damage (head, teleporter, telefragger, 10000, DEATH_TELEFRAG, head.origin, '0 0 0');
  35                                         else // dead bodies and monsters gib themselves instead of telefragging
  36                                                 Damage (telefragger, teleporter, telefragger, 10000, DEATH_TELEFRAG, telefragger.origin, '0 0 0');
  37                                         ++tdeath_hit;
  38                                 }
  39 }
  40
  41 void spawn_tdeath(vector v0, entity e, vector v)
  42 {
  43         tdeath(e, e, e, '0 0 0', '0 0 0');
  44 }
  45
  46 .entity pusher;
  47 void TeleportPlayer(entity teleporter, entity player, vector to, vector to_angles, vector to_velocity, vector telefragmin, vector telefragmax)
  48 {
  49         entity oldself;
  50         entity telefragger;
  51         vector from;
  52
  53         if(teleporter.owner)
  54                 telefragger = teleporter.owner;
  55         else
  56                 telefragger = player;
  57
  58         makevectors (to_angles);
  59
  60         if(self.pushltime < time) // only show one teleport effect per teleporter per 0.2 seconds, for better fps
  61         {
  62                 sound (player, CHAN_TRIGGER, "misc/teleport.wav", VOL_BASE, ATTN_NORM);
  63                 pointparticles(particleeffectnum("teleport"), player.origin, '0 0 0', 1);
  64                 pointparticles(particleeffectnum("teleport"), to + v_forward * 32, '0 0 0', 1);
  65                 self.pushltime = time + 0.2;
  66         }
  67
  68         // Relocate the player
  69         // assuming to allows PL_MIN to PL_MAX box and some more
  70         from = player.origin;
  71         setorigin (player, to);
  72         player.oldorigin = to; // don't undo the teleport by unsticking
  73         player.angles = to_angles;
  74         player.fixangle = TRUE;
  75         player.velocity = to_velocity;
  76         BITXOR_ASSIGN(player.effects, EF_TELEPORT_BIT);
  77
  78         UpdateCSQCProjectile(player);
  79
  80         if(player.classname == "player")
  81         {
  82                 if(player.takedamage && player.deadflag == DEAD_NO && !g_race)
  83                         tdeath(player, teleporter, telefragger, telefragmin, telefragmax);
  84
  85                 // player no longer is on ground
  86                 player.flags &~= FL_ONGROUND;
  87
  88                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
  89                 player.oldvelocity = player.velocity;
  90
  91                 // reset tracking of who pushed you into a hazard (for kill credit)
  92                 if(teleporter.owner)
  93                 {
  94                         player.pusher = teleporter.owner;
  95                         player.pushltime = time + cvar("g_maxpushtime");
  96                 }
  97                 else
  98                 {
  99                         player.pushltime = 0;
 100                 }
 101
 102                 if(player.isbot)
 103                         player.lastteleporttime = time;
 104
 105                 // stop player name display
 106                 {
 107                         oldself = self;
 108                         self = player;
 109                         ClearSelectedPlayer();
 110                         self = oldself;
 111                 }
 112         }
 113 }
 114
 115 void Teleport_Touch (void)
 116 {
 117         entity oldself, e;
 118
 119         if (other.health < 1)
 120                 return;
 121         if (!other.flags & FL_CLIENT)   // FIXME: Make missiles firable through the teleport too
 122                 return;
 123
 124         if(self.team)
 125                 if((self.spawnflags & 4 == 0) == (self.team != other.team))
 126                         return;
 127
 128         EXACTTRIGGER_TOUCH;
 129
 130         makevectors(self.enemy.mangle);
 131
 132         if(other.classname == "player")
 133                 RemoveGrapplingHook(other);
 134
 135         if(self.enemy)
 136         {
 137                 e = self.enemy;
 138         }
 139         else
 140         {
 141                 RandomSelection_Init();
 142                 for(e = world; (e = find(e, targetname, self.target)); )
 143                 {
 144                         if(e.cnt)
 145                                 RandomSelection_Add(e, 0, string_null, e.cnt, 0);
 146                         else
 147                                 RandomSelection_Add(e, 0, string_null, 1, 0);
 148                 }
 149                 e = RandomSelection_chosen_ent;
 150         }
 151
 152         if(!e)
 153         {
 154                 sprint(other, "Teleport destination vanished. Sorry... please complain to the mapper.\n");
 155         }
 156
 157         TeleportPlayer(self, other, e.origin + '0 0 1' * (1 - other.mins_z - 24), e.mangle, v_forward * vlen(other.velocity), '0 0 0', '0 0 0');
 158
 159         if(e.target)
 160         {
 161                 oldself = self;
 162                 activator = other;
 163                 self = e;
 164                 SUB_UseTargets();
 165                 self = oldself;
 166         }
 167 }
 168
 169 void spawnfunc_info_teleport_destination (void)
 170 {
 171         self.classname = "info_teleport_destination";
 172
 173         self.mangle = self.angles;
 174         self.angles = '0 0 0';
 175
 176         //setorigin (self, self.origin + '0 0 27');     // To fix a mappers' habit as old as Quake
 177         setorigin (self, self.origin);
 178
 179         IFTARGETED
 180         {
 181         }
 182         else
 183                 objerror ("^3Teleport destination without a targetname");
 184 }
 185
 186 void spawnfunc_misc_teleporter_dest (void)
 187 {
 188         spawnfunc_info_teleport_destination();
 189 }
 190
 191 void spawnfunc_target_teleporter (void)
 192 {
 193         spawnfunc_info_teleport_destination();
 194 }
 195
 196 void teleport_findtarget (void)
 197 {
 198         entity e;
 199         float n;
 200
 201         n = 0;
 202         for(e = world; (e = find(e, targetname, self.target)); )
 203         {
 204                 ++n;
 205                 if(e.movetype == MOVETYPE_NONE)
 206                         waypoint_spawnforteleporter(self, e.origin, 0);
 207                 if(e.classname != "info_teleport_destination")
 208                         print("^3MAPPER ERROR: teleporter does target an invalid teleport destination entity. Angles will not work.\n");
 209         }
 210
 211         if(n == 0)
 212         {
 213                 // no dest!
 214                 objerror ("Teleporter with nonexistant target");
 215                 return;
 216         }
 217         else if(n == 1)
 218         {
 219                 // exactly one dest - bots love that
 220                 self.enemy = find(e, targetname, self.target);
 221                 self.dest = self.enemy.origin;
 222         }
 223         else
 224         {
 225                 // have to use random selection every single time
 226                 self.enemy = world;
 227         }
 228
 229         // now enable touch
 230         self.touch = Teleport_Touch;
 231 }
 232
 233 void spawnfunc_trigger_teleport (void)
 234 {
 235         self.angles = '0 0 0';
 236
 237         EXACTTRIGGER_INIT;
 238
 239         self.use = trigger_teleport_use;
 240
 241         // this must be called to spawn the teleport waypoints for bots
 242         InitializeEntity(self, teleport_findtarget, INITPRIO_FINDTARGET);
 243
 244         if (!self.target)
 245         {
 246                 objerror ("Teleporter with no target");
 247                 return;
 248         }
 249 }