data/qcsrc/server/portals.qc

   1 #define SAFENUDGE '1 1 1'
   2 #define SAFERNUDGE '8 8 8'
   3
   4 .vector portal_transform;
   5 .vector portal_safe_origin;
   6 .float portal_wants_to_vanish;
   7 .float portal_activatetime;
   8
   9 vector Portal_Transform_Apply(vector transform, vector v)
  10 {
  11         fixedmakevectors(transform);
  12         return v_forward * v_x
  13              + v_right   * (-v_y)
  14                  + v_up      * v_z;
  15 }
  16
  17 vector Portal_Transform_Multiply(vector t1, vector t2)
  18 {
  19         vector m_forward, m_up;
  20         fixedmakevectors(t2); m_forward = v_forward; m_up = v_up;
  21         m_forward = Portal_Transform_Apply(t1, m_forward); m_up = Portal_Transform_Apply(t1, m_up);
  22         return fixedvectoangles2(m_forward, m_up);
  23 }
  24
  25 vector Portal_Transform_Invert(vector transform)
  26 {
  27         vector i_forward, i_up;
  28         fixedmakevectors(transform);
  29         // we want angles that turn v_forward into '1 0 0', v_right into '0 1 0' and v_up into '0 0 1'
  30         // but these are orthogonal unit vectors!
  31         // so to invert, we can simply fixedvectoangles the TRANSPOSED matrix
  32         // TODO is this always -transform?
  33         i_forward_x = v_forward_x;
  34         i_forward_y = -v_right_x;
  35         i_forward_z = v_up_x;
  36         i_up_x = v_forward_z;
  37         i_up_y = -v_right_z;
  38         i_up_z = v_up_z;
  39 #ifdef DEBUG
  40         vector v;
  41         v = fixedvectoangles2(i_forward, i_up);
  42         print("Transform: ", vtos(transform), "\n");
  43         print("Inverted: ", vtos(v), "\n");
  44         print("Verify: ", vtos(Portal_Transform_Multiply(v, transform)), "\n");
  45         fixedmakevectors(Portal_Transform_Multiply(v, transform));
  46         print("Verify: ", vtos(v_forward), "\n");
  47         print("Verify: ", vtos(v_right), "\n");
  48         print("Verify: ", vtos(v_up), "\n");
  49 #endif
  50         return fixedvectoangles2(i_forward, i_up);
  51 }
  52
  53 vector Portal_Transform_TurnDirection(vector transform)
  54 {
  55         // turn 180 degrees around v_up
  56         // changes in-direction to out-direction
  57         fixedmakevectors(transform);
  58         return fixedvectoangles2(-1 * v_forward, 1 * v_up);
  59 }
  60
  61 vector Portal_Transform_Divide(vector to_transform, vector from_transform)
  62 {
  63         return Portal_Transform_Multiply(to_transform, Portal_Transform_Invert(from_transform));
  64 }
  65
  66 float PlayerEdgeDistance(entity p, vector v)
  67 {
  68         vector vbest;
  69
  70         if(v_x < 0) vbest_x = p.mins_x; else vbest_x = p.maxs_x;
  71         if(v_y < 0) vbest_y = p.mins_y; else vbest_y = p.maxs_y;
  72         if(v_z < 0) vbest_z = p.mins_z; else vbest_z = p.maxs_z;
  73
  74         return vbest * v;
  75 }
  76
  77 .vector right_vector;
  78 float Portal_TeleportPlayer(entity teleporter, entity player)
  79 {
  80         vector from, to, safe, step, transform, ang, newvel;
  81         vector new_forward, new_up;
  82         vector old_forward, old_up;
  83         vector new_yawforward;
  84         vector old_yawforward;
  85         float planeshift, s, t;
  86
  87         from = teleporter.origin;
  88         transform = teleporter.portal_transform;
  89
  90         to = teleporter.enemy.origin;
  91         to = to + Portal_Transform_Apply(teleporter.portal_transform, player.origin - from);
  92         newvel = Portal_Transform_Apply(transform, player.velocity);
  93         // this now is INSIDE the plane... can't use that
  94
  95         // shift it out
  96         fixedmakevectors(teleporter.enemy.angles);
  97
  98         // first shift it ON the plane if needed
  99         planeshift = ((teleporter.enemy.origin - to) * v_forward) + PlayerEdgeDistance(player, v_forward) + 1;
 100         if(planeshift > 0 && (newvel * v_forward) > vlen(newvel) * 0.01)
 101                 // if we can't, let us not do the planeshift and do somewhat incorrect transformation in the end
 102                 to += newvel * (planeshift / (newvel * v_forward));
 103         else
 104                 to += trace_plane_normal * planeshift;
 105
 106         s = (to - teleporter.enemy.origin) * v_right;
 107         t = (to - teleporter.enemy.origin) * v_up;
 108         s = bound(-48, s, 48);
 109         t = bound(-48, t, 48);
 110         to = teleporter.enemy.origin
 111            + ((to - teleporter.enemy.origin) * v_forward) * v_forward
 112            +     s                                        * v_right
 113            +     t                                        * v_up;
 114
 115         safe = teleporter.enemy.portal_safe_origin; // a valid player origin
 116         step = to + ((safe - to) * v_forward) * v_forward;
 117         tracebox(safe, player.mins - SAFENUDGE, player.maxs + SAFENUDGE, step, MOVE_NOMONSTERS, player);
 118         if(trace_startsolid)
 119         {
 120                 print("'safe' teleport location is not safe!\n");
 121                 // FAIL TODO why does this happen?
 122                 return 0;
 123         }
 124         safe = trace_endpos + normalize(safe - trace_endpos) * 0;
 125         tracebox(safe, player.mins - SAFENUDGE, player.maxs + SAFENUDGE, to, MOVE_NOMONSTERS, player);
 126         if(trace_startsolid)
 127         {
 128                 print("trace_endpos in solid, this can't be!\n");
 129                 // FAIL TODO why does this happen? (reported by MrBougo)
 130                 return 0;
 131         }
 132         to = trace_endpos + normalize(safe - trace_endpos) * 0;
 133         //print(vtos(to), "\n");
 134
 135         // ang_x stuff works around weird quake angles
 136         if(player.classname == "player")
 137         {
 138                 ang = player.v_angle;
 139                 /*
 140                 ang_x = bound(-89, mod(-ang_x + 180, 360) - 180, 89);
 141                 ang = Portal_Transform_Multiply(transform, ang);
 142                 */
 143
 144                 // PLAYERS use different math
 145                 ang_x = -ang_x;
 146
 147                 //print("reference: ", vtos(Portal_Transform_Multiply(transform, ang)), "\n");
 148
 149                 fixedmakevectors(ang);
 150                 old_forward = v_forward;
 151                 old_up = v_up;
 152                 fixedmakevectors(ang_y * '0 1 0');
 153                 old_yawforward = v_forward;
 154
 155                 // their aiming directions are portalled...
 156                 new_forward = Portal_Transform_Apply(transform, old_forward);
 157                 new_up = Portal_Transform_Apply(transform, old_up);
 158                 new_yawforward = Portal_Transform_Apply(transform, old_yawforward);
 159
 160                 // but now find a new sense of direction
 161                 // this is NOT easy!
 162                 // assume new_forward points straight up.
 163                 // What is our yaw?
 164                 //
 165                 // new_up could now point forward OR backward... which direction to choose?
 166
 167                 if(new_forward_z > 0.7 || new_forward_z < -0.7) // far up; in this case, the "up" vector points backwards
 168                 {
 169                         // new_yawforward and new_yawup define the new aiming half-circle
 170                         // we "just" need to find out whether new_up or -new_up is in that half circle
 171                         ang = fixedvectoangles(new_forward); // this still gets us a nice pitch value...
 172                         if(new_up * new_yawforward < 0)
 173                                 new_up = -1 * new_up;
 174                         ang_y = vectoyaw(new_up); // this vector is the yaw we want
 175                         //print("UP/DOWN path: ", vtos(ang), "\n");
 176                 }
 177                 else
 178                 {
 179                         // good angles; here, "forward" suffices
 180                         ang = fixedvectoangles(new_forward);
 181                         //print("GOOD path: ", vtos(ang), "\n");
 182                 }
 183
 184                 ang_x = -ang_x;
 185                 ang_z = player.angles_z;
 186         }
 187         else
 188         {
 189                 ang = player.angles;
 190                 ang = Portal_Transform_Multiply(transform, player.angles);
 191         }
 192
 193         // factor -1 allows chaining portals, but may be weird
 194         player.right_vector = -1 * Portal_Transform_Apply(transform, player.right_vector);
 195
 196         if(player.flagcarried)
 197                 DropFlag(player.flagcarried, player, world);
 198         TeleportPlayer(teleporter, player, to, ang, newvel, teleporter.enemy.absmin, teleporter.enemy.absmax);
 199
 200         // reset fade counter
 201         teleporter.portal_wants_to_vanish = 0;
 202         teleporter.fade_time = time + cvar("g_balance_portal_lifetime");
 203         teleporter.health = cvar("g_balance_portal_health");
 204         teleporter.enemy.health = cvar("g_balance_portal_health");
 205
 206         return 1;
 207 }
 208
 209 float Portal_FindSafeOrigin(entity portal)
 210 {
 211         vector o;
 212         o = portal.origin;
 213         portal.mins = PL_MIN - SAFERNUDGE;
 214         portal.maxs = PL_MAX + SAFERNUDGE;
 215         fixedmakevectors(portal.angles);
 216         portal.origin += 16 * v_forward;
 217         if(!move_out_of_solid(portal))
 218         {
 219 #ifdef DEBUG
 220                 print("NO SAFE ORIGIN\n");
 221 #endif
 222                 return 0;
 223         }
 224         portal.portal_safe_origin = portal.origin;
 225         setorigin(portal, o);
 226         return 1;
 227 }
 228
 229 float Portal_WillHitPlane(vector eorg, vector emins, vector emaxs, vector evel, vector porg, vector pnorm, float psize)
 230 {
 231         float dist, distpersec, delta;
 232         vector v;
 233
 234         dist = (eorg - porg) * pnorm;
 235         dist += min(emins_x * pnorm_x, emaxs_x * pnorm_x);
 236         dist += min(emins_y * pnorm_y, emaxs_y * pnorm_y);
 237         dist += min(emins_z * pnorm_z, emaxs_z * pnorm_z);
 238         if(dist < -1) // other side?
 239                 return 0;
 240         distpersec = evel * pnorm;
 241         if(distpersec >= 0) // going away from the portal?
 242                 return 0;
 243         delta = dist / distpersec;
 244         v = eorg - evel * delta - porg;
 245         v = v - pnorm * (pnorm * v);
 246         return vlen(v) < psize;
 247 }
 248
 249 void Portal_Touch()
 250 {
 251         vector g;
 252
 253         // portal is being removed?
 254         if(self.solid != SOLID_TRIGGER)
 255                 return; // possibly engine bug
 256
 257         if(!self.enemy)
 258                 error("Portal_Touch called for a broken portal\n");
 259
 260         if(trace_fraction < 1)
 261                 return; // only handle TouchAreaGrid ones (only these can teleport)
 262                 // for some unknown reason, this also gets collisions from SV_Impact sometimes
 263
 264         if(other.classname == "porto")
 265         {
 266                 if(other.portal_id == self.portal_id)
 267                         return;
 268         }
 269         if(time < self.portal_activatetime)
 270                 if(other == self.owner)
 271                 {
 272                         self.portal_activatetime = time + 0.1;
 273                         return;
 274                 }
 275         if(other != self.owner)
 276                 if(other.classname == "player")
 277                         if(IS_INDEPENDENT_PLAYER(other) || IS_INDEPENDENT_PLAYER(self.owner))
 278                                 return; // cannot go through someone else's portal
 279         if(other.owner != self.owner)
 280                 if(other.owner.classname == "player")
 281                         if(IS_INDEPENDENT_PLAYER(other.owner) || IS_INDEPENDENT_PLAYER(self.owner))
 282                                 return; // cannot go through someone else's portal
 283         fixedmakevectors(self.angles);
 284         g = frametime * '0 0 -1' * cvar("sv_gravity");
 285         if(!Portal_WillHitPlane(other.origin, other.mins, other.maxs, other.velocity + g, self.origin, v_forward, self.maxs_x))
 286                 return;
 287
 288         /*
 289         if(other.mins_x < PL_MIN_x || other.mins_y < PL_MIN_y || other.mins_z < PL_MIN_z
 290         || other.maxs_x > PL_MAX_x || other.maxs_y > PL_MAX_y || other.maxs_z > PL_MAX_z)
 291         {
 292                 // can't teleport this
 293                 return;
 294         }
 295         */
 296
 297         if(Portal_TeleportPlayer(self, other))
 298                 if(other.classname == "porto")
 299                         if(other.effects & EF_RED)
 300                                 other.effects += EF_BLUE - EF_RED;
 301 }
 302
 303 void Portal_Think();
 304 void Portal_MakeBrokenPortal(entity portal)
 305 {
 306         portal.solid = SOLID_NOT;
 307         portal.touch = SUB_Null;
 308         portal.think = SUB_Null;
 309         portal.effects = 0;
 310         //portal.colormod = '1 1 1';
 311         portal.nextthink = 0;
 312         portal.takedamage = DAMAGE_NO;
 313 }
 314
 315 void Portal_MakeWaitingPortal(entity portal)
 316 {
 317         portal.solid = SOLID_NOT;
 318         portal.touch = SUB_Null;
 319         portal.think = SUB_Null;
 320         portal.effects = EF_ADDITIVE;
 321         portal.colormod = '1 1 1';
 322         portal.nextthink = 0;
 323         portal.takedamage = DAMAGE_YES;
 324 }
 325
 326 void Portal_MakeInPortal(entity portal)
 327 {
 328         portal.solid = SOLID_TRIGGER;
 329         portal.touch = Portal_Touch;
 330         portal.think = Portal_Think;
 331         portal.effects = EF_RED;
 332         portal.colormod = '1 0 0';
 333         portal.nextthink = time;
 334         portal.takedamage = DAMAGE_NO;
 335 }
 336
 337 void Portal_MakeOutPortal(entity portal)
 338 {
 339         portal.solid = SOLID_NOT;
 340         portal.touch = SUB_Null;
 341         portal.think = SUB_Null;
 342         portal.effects = EF_STARDUST | EF_BLUE;
 343         portal.colormod = '0 0 1';
 344         portal.nextthink = 0;
 345         portal.takedamage = DAMAGE_YES;
 346 }
 347
 348 void Portal_Disconnect(entity teleporter, entity destination)
 349 {
 350         teleporter.enemy = world;
 351         destination.enemy = world;
 352         Portal_MakeBrokenPortal(teleporter);
 353         Portal_MakeBrokenPortal(destination);
 354 }
 355
 356 void Portal_Connect(entity teleporter, entity destination)
 357 {
 358         teleporter.portal_transform = Portal_Transform_Divide(Portal_Transform_TurnDirection(destination.angles), teleporter.angles);
 359
 360 #ifdef DEBUG
 361         {
 362                 // let's verify the transform
 363                 vector in_f, in_r, in_u;
 364                 vector out_f, out_r, out_u;
 365                 fixedmakevectors(teleporter.angles);
 366                 in_f = v_forward;
 367                 in_r = v_right;
 368                 in_u = v_up;
 369                 print("teleporter: ", vtos(in_f), " ", vtos(in_r), " ", vtos(in_u), "\n");
 370                 fixedmakevectors(destination.angles);
 371                 out_f = v_forward;
 372                 out_r = v_right;
 373                 out_u = v_up;
 374                 print("dest: ", vtos(out_f), " ", vtos(out_r), " ", vtos(out_u), "\n");
 375                 // INTENDED TRANSFORM:
 376                 //   in_f -> -out_f
 377                 //   in_r -> -out_r
 378                 //   in_u -> +out_u
 379                 print("FORWARD: ", vtos(in_f), " -> ", vtos(Portal_Transform_Apply(teleporter.portal_transform, in_f)), ", should be", vtos(-1 * out_f), "\n");
 380                 print("RIGHT: ", vtos(in_r), " -> ", vtos(Portal_Transform_Apply(teleporter.portal_transform, in_r)), ", should be", vtos(-1 * out_r), "\n");
 381                 print("UP: ", vtos(in_u), " -> ", vtos(Portal_Transform_Apply(teleporter.portal_transform, in_u)), ", should be", vtos(out_u), "\n");
 382
 383                 te_lightning3(world, teleporter.origin, teleporter.origin + in_r * 1000);
 384                 te_lightning3(world, destination.origin, destination.origin + out_r * 1000);
 385         }
 386 #endif
 387
 388         teleporter.enemy = destination;
 389         destination.enemy = teleporter;
 390         Portal_MakeInPortal(teleporter);
 391         Portal_MakeOutPortal(destination);
 392         teleporter.fade_time = time + 15;
 393         destination.fade_time = time + 15;
 394         teleporter.portal_wants_to_vanish = 0;
 395         destination.portal_wants_to_vanish = 0;
 396 }
 397
 398 void Portal_Remove(entity portal, float killed)
 399 {
 400         entity e;
 401         e = portal.enemy;
 402
 403         if(e)
 404         {
 405                 Portal_Disconnect(portal, e);
 406                 Portal_Remove(e, killed);
 407         }
 408
 409         if(portal == portal.owner.portal_in)
 410                 portal.owner.portal_in = world;
 411         if(portal == portal.owner.portal_out)
 412                 portal.owner.portal_out = world;
 413         //portal.owner = world;
 414
 415         // makes the portal vanish
 416         if(killed)
 417         {
 418                 fixedmakevectors(portal.angles);
 419                 sound(portal, CHAN_PROJECTILE, "porto/explode.ogg", VOL_BASE, ATTN_NORM);
 420                 pointparticles(particleeffectnum("rocket_explode"), portal.origin + v_forward * 16, v_forward * 1024, 4);
 421                 remove(portal);
 422         }
 423         else
 424         {
 425                 Portal_MakeBrokenPortal(portal);
 426                 sound(portal, CHAN_PROJECTILE, "porto/expire.ogg", VOL_BASE, ATTN_NORM);
 427                 SUB_SetFade(portal, time, 0.5);
 428         }
 429 }
 430
 431 void Portal_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 432 {
 433         if(deathtype == DEATH_TELEFRAG)
 434                 return;
 435         if(attacker != self.owner)
 436                 if(IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(self.owner))
 437                         return;
 438         self.health -= damage;
 439         if(self.health < 0)
 440                 Portal_Remove(self, 1);
 441 }
 442
 443 void Portal_Think()
 444 {
 445         entity e, o;
 446         vector g;
 447
 448         // portal is being removed?
 449         if(self.solid != SOLID_TRIGGER)
 450                 return; // possibly engine bug
 451
 452         if(!self.enemy)
 453                 error("Portal_Think called for a broken portal\n");
 454
 455         o = self.owner;
 456         self.solid = SOLID_BBOX;
 457         self.owner = world;
 458
 459         g = frametime * '0 0 -1' * cvar("sv_gravity");
 460
 461         fixedmakevectors(self.angles);
 462
 463         FOR_EACH_PLAYER(e)
 464         {
 465                 if(time < self.portal_activatetime)
 466                         if(e == o)
 467                                 continue;
 468                 if(e != o)
 469                         if(IS_INDEPENDENT_PLAYER(e) || IS_INDEPENDENT_PLAYER(o))
 470                                 continue; // cannot go through someone else's portal
 471                 if(!Portal_WillHitPlane(e.origin, e.mins, e.maxs, e.velocity + g, self.origin, v_forward, self.maxs_x))
 472                         continue;
 473
 474                 // if e would hit the portal in a frame...
 475                 // already teleport him
 476                 tracebox(e.origin, e.mins, e.maxs, e.origin + e.velocity * 2 * frametime, MOVE_NORMAL, e);
 477                 if(trace_ent == self)
 478                         Portal_TeleportPlayer(self, e);
 479         }
 480         self.solid = SOLID_TRIGGER;
 481         self.owner = o;
 482
 483         self.nextthink = time;
 484
 485         if(time > self.fade_time)
 486                 Portal_Remove(self, 0);
 487 }
 488
 489 float Portal_Customize()
 490 {
 491         if(other.classname == "spectator")
 492                 other = other.enemy;
 493         if(other == self.owner)
 494         {
 495                 self.modelindex = self.modelindex_lod0;
 496         }
 497         else if(IS_INDEPENDENT_PLAYER(other) || IS_INDEPENDENT_PLAYER(self.owner))
 498         {
 499                 self.modelindex = 0;
 500         }
 501         else
 502         {
 503                 self.modelindex = self.modelindex_lod0;
 504         }
 505         return TRUE;
 506 }
 507
 508 // cleanup:
 509 //   when creating in-portal:
 510 //     disconnect
 511 //     clear existing in-portal
 512 //     set as in-portal
 513 //     connect
 514 //   when creating out-portal:
 515 //     disconnect
 516 //     clear existing out-portal
 517 //     set as out-portal
 518 //   when player dies:
 519 //     disconnect portals
 520 //     clear both portals
 521 //   after timeout of in-portal:
 522 //     disconnect portals
 523 //     clear both portals
 524 //   TODO: ensure only one portal shot at once
 525 float Portal_SetInPortal(entity own, entity portal)
 526 {
 527         if(own.portal_in)
 528         {
 529                 if(own.portal_out)
 530                         Portal_Disconnect(own.portal_in, own.portal_out);
 531                 Portal_Remove(own.portal_in, 0);
 532         }
 533         own.portal_in = portal;
 534         if(own.portal_out)
 535         {
 536                 own.portal_out.portal_id = portal.portal_id;
 537                 Portal_Connect(own.portal_in, own.portal_out);
 538         }
 539         return 2;
 540 }
 541 float Portal_SetOutPortal(entity own, entity portal)
 542 {
 543         if(own.portal_out)
 544         {
 545                 if(own.portal_in)
 546                         Portal_Disconnect(own.portal_in, own.portal_out);
 547                 Portal_Remove(own.portal_out, 0);
 548         }
 549         own.portal_out = portal;
 550         if(own.portal_in)
 551         {
 552                 own.portal_in.portal_id = portal.portal_id;
 553                 Portal_Connect(own.portal_in, own.portal_out);
 554         }
 555         return 1;
 556 }
 557 void Portal_ClearAll_PortalsOnly(entity own)
 558 {
 559         if(own.portal_in)
 560                 Portal_Remove(own.portal_in, 0);
 561         if(own.portal_out)
 562                 Portal_Remove(own.portal_out, 0);
 563 }
 564 void Portal_ClearAll(entity own)
 565 {
 566         Portal_ClearAll_PortalsOnly(own);
 567         W_Porto_Remove(own);
 568 }
 569 void Portal_RemoveLater_Think()
 570 {
 571         Portal_Remove(self, self.cnt);
 572 }
 573 void Portal_RemoveLater(entity portal, float kill)
 574 {
 575         Portal_MakeBrokenPortal(portal);
 576         portal.cnt = kill;
 577         portal.think = Portal_RemoveLater_Think;
 578         portal.nextthink = time;
 579 }
 580 void Portal_ClearAllLater_PortalsOnly(entity own)
 581 {
 582         if(own.portal_in)
 583                 Portal_RemoveLater(own.portal_in, 0);
 584         if(own.portal_out)
 585                 Portal_RemoveLater(own.portal_out, 0);
 586 }
 587 void Portal_ClearAllLater(entity own)
 588 {
 589         Portal_ClearAllLater_PortalsOnly(own);
 590         W_Porto_Remove(own);
 591 }
 592 void Portal_ClearWithID(entity own, float id)
 593 {
 594         if(own.portal_in)
 595                 if(own.portal_in.portal_id == id)
 596                 {
 597                         if(own.portal_out)
 598                                 Portal_Disconnect(own.portal_in, own.portal_out);
 599                         Portal_Remove(own.portal_in, 0);
 600                 }
 601         if(own.portal_out)
 602                 if(own.portal_out.portal_id == id)
 603                 {
 604                         if(own.portal_in)
 605                                 Portal_Disconnect(own.portal_in, own.portal_out);
 606                         Portal_Remove(own.portal_out, 0);
 607                 }
 608 }
 609
 610 entity Portal_Spawn(entity own, vector org, vector ang)
 611 {
 612         entity portal;
 613
 614         fixedmakevectors(ang);
 615         if(!CheckWireframeBox(own, org - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 616                 return world;
 617
 618         portal = spawn();
 619         portal.classname = "portal";
 620         portal.owner = own;
 621         portal.origin = org;
 622         portal.angles = ang;
 623         portal.think = Portal_Think;
 624         portal.nextthink = 0;
 625         portal.portal_activatetime = time + 0.1;
 626         portal.event_damage = Portal_Damage;
 627         portal.health = 200;
 628         portal.fade_time = time + cvar("g_balance_portal_lifetime");
 629         portal.health = cvar("g_balance_portal_health");
 630         setmodel(portal, "models/portal.md3");
 631         portal.modelindex_lod0 = portal.modelindex;
 632         portal.customizeentityforclient = Portal_Customize;
 633
 634         if(!Portal_FindSafeOrigin(portal))
 635         {
 636                 remove(portal);
 637                 return world;
 638         }
 639
 640         setsize(portal, '-48 -48 -48', '48 48 48');
 641         Portal_MakeWaitingPortal(portal);
 642
 643         return portal;
 644 }
 645
 646 float Portal_SpawnInPortalAtTrace(entity own, vector dir, float portal_id_val)
 647 {
 648         entity portal;
 649         vector ang;
 650         vector org;
 651
 652         org = trace_endpos;
 653         ang = fixedvectoangles2(trace_plane_normal, dir);
 654         fixedmakevectors(ang);
 655
 656         portal = Portal_Spawn(own, org, ang);
 657         if(!portal)
 658         {
 659                 // if(!own.portal_out || own.portal_out.portal_id == portal_id_val)
 660                         Portal_ClearAll_PortalsOnly(own);
 661                 return 0;
 662         }
 663
 664         portal.portal_id = portal_id_val;
 665         Portal_SetInPortal(own, portal);
 666
 667         return 1;
 668 }
 669
 670 float Portal_SpawnOutPortalAtTrace(entity own, vector dir, float portal_id_val)
 671 {
 672         entity portal;
 673         vector ang;
 674         vector org;
 675
 676         org = trace_endpos;
 677         ang = fixedvectoangles2(trace_plane_normal, dir);
 678         fixedmakevectors(ang);
 679
 680         portal = Portal_Spawn(own, org, ang);
 681         if(!portal)
 682         {
 683                 // if(!own.portal_in || own.portal_in.portal_id == portal_id_val)
 684                         Portal_ClearAll_PortalsOnly(own);
 685                 return 0;
 686         }
 687
 688         portal.portal_id = portal_id_val;
 689         Portal_SetOutPortal(own, portal);
 690
 691         return 1;
 692 }