data/qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
   7 void() spawnpoint_use;
   8 string ColoredTeamName(float t);
   9
  10 float RandomSelection_totalweight;
  11 float RandomSelection_best_priority;
  12 entity RandomSelection_chosen_ent;
  13 float RandomSelection_chosen_float;
  14 void RandomSelection_Init()
  15 {
  16         RandomSelection_totalweight = 0;
  17         RandomSelection_chosen_ent = world;
  18         RandomSelection_chosen_float = 0;
  19         RandomSelection_best_priority = -1;
  20 }
  21 void RandomSelection_Add(entity e, float f, float weight, float priority)
  22 {
  23         if(priority > RandomSelection_best_priority)
  24         {
  25                 RandomSelection_best_priority = priority;
  26                 RandomSelection_chosen_ent = e;
  27                 RandomSelection_chosen_float = f;
  28                 RandomSelection_totalweight = weight;
  29         }
  30         else if(priority == RandomSelection_best_priority)
  31         {
  32                 RandomSelection_totalweight += weight;
  33                 if(random() * RandomSelection_totalweight <= weight)
  34                 {
  35                         RandomSelection_chosen_ent = e;
  36                         RandomSelection_chosen_float = f;
  37                 }
  38         }
  39 }
  40
  41 float DistributeEvenly_amount;
  42 float DistributeEvenly_totalweight;
  43 void DistributeEvenly_Init(float amount, float totalweight)
  44 {
  45         if(DistributeEvenly_amount)
  46         {
  47                 dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  48                 dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  49         }
  50         if(totalweight == 0)
  51                 DistributeEvenly_amount = 0;
  52         else
  53                 DistributeEvenly_amount = amount;
  54         DistributeEvenly_totalweight = totalweight;
  55 }
  56 float DistributeEvenly_Get(float weight)
  57 {
  58         float f;
  59         if(weight <= 0)
  60                 return 0;
  61         f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  62         DistributeEvenly_totalweight -= weight;
  63         DistributeEvenly_amount -= f;
  64         return f;
  65 }
  66
  67 void move_out_of_solid_expand(entity e, vector by)
  68 {
  69         float eps = 0.0625;
  70         tracebox(e.origin, e.mins - '1 1 1' * eps, e.maxs + '1 1 1' * eps, e.origin + by, MOVE_WORLDONLY, e);
  71         if(trace_startsolid)
  72                 return;
  73         if(trace_fraction < 1)
  74         {
  75                 // hit something
  76                 // adjust origin in the other direction...
  77                 e.origin = e.origin - by * (1 - trace_fraction);
  78         }
  79 }
  80
  81 float move_out_of_solid(entity e)
  82 {
  83         vector o, m0, m1;
  84
  85         o = e.origin;
  86         traceline(o, o, MOVE_WORLDONLY, e);
  87         if(trace_startsolid)
  88                 return 0;
  89
  90         tracebox(o, e.mins, e.maxs, o, MOVE_WORLDONLY, e);
  91         if(!trace_startsolid)
  92                 return 1;
  93
  94         m0 = e.mins;
  95         m1 = e.maxs;
  96         e.mins = '0 0 0';
  97         e.maxs = '0 0 0';
  98         move_out_of_solid_expand(e, '1 0 0' * m0_x); e.mins_x = m0_x;
  99         move_out_of_solid_expand(e, '1 0 0' * m1_x); e.maxs_x = m1_x;
 100         move_out_of_solid_expand(e, '0 1 0' * m0_y); e.mins_y = m0_y;
 101         move_out_of_solid_expand(e, '0 1 0' * m1_y); e.maxs_y = m1_y;
 102         move_out_of_solid_expand(e, '0 0 1' * m0_z); e.mins_z = m0_z;
 103         move_out_of_solid_expand(e, '0 0 1' * m1_z); e.maxs_z = m1_z;
 104         setorigin(e, e.origin);
 105
 106         tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_WORLDONLY, e);
 107         if(trace_startsolid)
 108         {
 109                 setorigin(e, o);
 110                 return 0;
 111         }
 112
 113         return 1;
 114 }
 115
 116 string STR_PLAYER = "player";
 117 string STR_SPECTATOR = "spectator";
 118 string STR_OBSERVER = "observer";
 119
 120 #if 0
 121 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
 122 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
 123 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
 124 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
 125 #else
 126 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
 127 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
 128 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
 129 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
 130 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
 131 #endif
 132
 133 // copies a string to a tempstring (so one can strunzone it)
 134 string strcat1(string s) = #115; // FRIK_FILE
 135
 136 float logfile_open;
 137 float logfile;
 138
 139 void bcenterprint(string s)
 140 {
 141         // TODO replace by MSG_ALL (would show it to spectators too, though)?
 142         entity head;
 143         FOR_EACH_PLAYER(head)
 144                 if(clienttype(head) == CLIENTTYPE_REAL)
 145                         centerprint(head, s);
 146 }
 147
 148 void GameLogEcho(string s)
 149 {
 150         string fn;
 151         float matches;
 152
 153         if(cvar("sv_eventlog_files"))
 154         {
 155                 if(!logfile_open)
 156                 {
 157                         logfile_open = TRUE;
 158                         matches = cvar("sv_eventlog_files_counter") + 1;
 159                         cvar_set("sv_eventlog_files_counter", ftos(matches));
 160                         fn = ftos(matches);
 161                         if(strlen(fn) < 8)
 162                                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 163                         fn = strcat(cvar_string("sv_eventlog_files_nameprefix"), fn, cvar_string("sv_eventlog_files_namesuffix"));
 164                         logfile = fopen(fn, FILE_APPEND);
 165                         fputs(logfile, ":logversion:3\n");
 166                 }
 167                 if(logfile >= 0)
 168                 {
 169                         if(cvar("sv_eventlog_files_timestamps"))
 170                                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 171                         else
 172                                 fputs(logfile, strcat(s, "\n"));
 173                 }
 174         }
 175         if(cvar("sv_eventlog_console"))
 176         {
 177                 print(s, "\n");
 178         }
 179 }
 180
 181 void GameLogInit()
 182 {
 183         logfile_open = 0;
 184         // will be opened later
 185 }
 186
 187 void GameLogClose()
 188 {
 189         if(logfile_open && logfile >= 0)
 190         {
 191                 fclose(logfile);
 192                 logfile = -1;
 193         }
 194 }
 195
 196 float spawnpoint_nag;
 197 void relocate_spawnpoint()
 198 {
 199         // nudge off the floor
 200         setorigin(self, self.origin + '0 0 1');
 201
 202         tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 203         if (trace_startsolid)
 204         {
 205                 vector o;
 206                 o = self.origin;
 207                 self.mins = PL_MIN;
 208                 self.maxs = PL_MAX;
 209                 if(!move_out_of_solid(self))
 210                         objerror("could not get out of solid at all!");
 211                 print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 212                 print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 213                 print(" ", ftos(self.origin_y - o_y));
 214                 print(" ", ftos(self.origin_z - o_z), "'\n");
 215                 if(cvar("g_spawnpoints_auto_move_out_of_solid"))
 216                 {
 217                         if(!spawnpoint_nag)
 218                                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 219                         spawnpoint_nag = 1;
 220                 }
 221                 else
 222                 {
 223                         self.origin = o;
 224                         self.mins = self.maxs = '0 0 0';
 225                         objerror("player spawn point in solid, mapper sucks!\n");
 226                         return;
 227                 }
 228         }
 229
 230         if(cvar("g_spawnpoints_autodrop"))
 231         {
 232                 setsize(self, PL_MIN, PL_MAX);
 233                 droptofloor();
 234         }
 235
 236         self.use = spawnpoint_use;
 237         self.team_saved = self.team;
 238         if(!self.cnt)
 239                 self.cnt = 1;
 240
 241         if(g_ctf || g_assault || g_onslaught || g_domination)
 242         if(self.team)
 243                 have_team_spawns = 1;
 244
 245         if(cvar("r_showbboxes"))
 246         {
 247                 // show where spawnpoints point at too
 248                 makevectors(self.angles);
 249                 entity e;
 250                 e = spawn();
 251                 e.classname = "info_player_foo";
 252                 setorigin(e, self.origin + v_forward * 24);
 253                 setsize(e, '-8 -8 -8', '8 8 8');
 254                 e.solid = SOLID_TRIGGER;
 255         }
 256 }
 257
 258 #define strstr strstrofs
 259 /*
 260 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 261 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 262 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 263 // BE CONSTANT OR strzoneD!
 264 float strstr(string haystack, string needle, float offset)
 265 {
 266         float len, endpos;
 267         string found;
 268         len = strlen(needle);
 269         endpos = strlen(haystack) - len;
 270         while(offset <= endpos)
 271         {
 272                 found = substring(haystack, offset, len);
 273                 if(found == needle)
 274                         return offset;
 275                 offset = offset + 1;
 276         }
 277         return -1;
 278 }
 279 */
 280
 281 float NUM_NEAREST_ENTITIES = 4;
 282 entity nearest_entity[NUM_NEAREST_ENTITIES];
 283 float nearest_length[NUM_NEAREST_ENTITIES];
 284 entity findnearest(vector point, .string field, string value, vector axismod)
 285 {
 286         entity localhead;
 287         float i;
 288         float j;
 289         float len;
 290         vector dist;
 291
 292         float num_nearest;
 293         num_nearest = 0;
 294
 295         localhead = find(world, field, value);
 296         while(localhead)
 297         {
 298                 if((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 299                         dist = localhead.oldorigin;
 300                 else
 301                         dist = localhead.origin;
 302                 dist = dist - point;
 303                 dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 304                 len = vlen(dist);
 305
 306                 for(i = 0; i < num_nearest; ++i)
 307                 {
 308                         if(len < nearest_length[i])
 309                                 break;
 310                 }
 311
 312                 // now i tells us where to insert at
 313                 //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 314                 if(i < NUM_NEAREST_ENTITIES)
 315                 {
 316                         for(j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 317                         {
 318                                 nearest_length[j + 1] = nearest_length[j];
 319                                 nearest_entity[j + 1] = nearest_entity[j];
 320                         }
 321                         nearest_length[i] = len;
 322                         nearest_entity[i] = localhead;
 323                         if(num_nearest < NUM_NEAREST_ENTITIES)
 324                                 num_nearest = num_nearest + 1;
 325                 }
 326
 327                 localhead = find(localhead, field, value);
 328         }
 329
 330         // now use the first one from our list that we can see
 331         for(i = 0; i < num_nearest; ++i)
 332         {
 333                 traceline(point, nearest_entity[i].origin, TRUE, world);
 334                 if(trace_fraction == 1)
 335                 {
 336                         if(i != 0)
 337                         {
 338                                 dprint("Nearest point (");
 339                                 dprint(nearest_entity[0].netname);
 340                                 dprint(") is not visible, using a visible one.\n");
 341                         }
 342                         return nearest_entity[i];
 343                 }
 344         }
 345
 346         if(num_nearest == 0)
 347                 return world;
 348
 349         dprint("Not seeing any location point, using nearest as fallback.\n");
 350         /* DEBUGGING CODE:
 351         dprint("Candidates were: ");
 352         for(j = 0; j < num_nearest; ++j)
 353         {
 354                 if(j != 0)
 355                         dprint(", ");
 356                 dprint(nearest_entity[j].netname);
 357         }
 358         dprint("\n");
 359         */
 360
 361         return nearest_entity[0];
 362 }
 363
 364 void spawnfunc_target_location()
 365 {
 366         self.classname = "target_location";
 367         // location name in netname
 368         // eventually support: count, teamgame selectors, line of sight?
 369 };
 370
 371 void spawnfunc_info_location()
 372 {
 373         self.classname = "target_location";
 374         self.message = self.netname;
 375 };
 376
 377 string NearestLocation(vector p)
 378 {
 379         entity loc;
 380         string ret;
 381         ret = "somewhere";
 382         loc = findnearest(p, classname, "target_location", '1 1 1');
 383         if(loc)
 384         {
 385                 ret = loc.message;
 386         }
 387         else
 388         {
 389                 loc = findnearest(p, target, "###item###", '1 1 4');
 390                 if(loc)
 391                         ret = loc.netname;
 392         }
 393         return ret;
 394 }
 395
 396 string formatmessage(string msg)
 397 {
 398         float p, p1, p2;
 399         float n;
 400         string escape;
 401         string replacement;
 402         p = 0;
 403         n = 7;
 404         while(1)
 405         {
 406                 if(n < 1)
 407                         break; // too many replacements
 408                 n = n - 1;
 409                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 410                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 411
 412                 if(p1 < 0)
 413                         p1 = p2;
 414                 if(p2 < 0)
 415                         p2 = p1;
 416                 p = min(p1, p2);
 417
 418                 if(p < 0)
 419                         break;
 420                 replacement = substring(msg, p, 2);
 421                 escape = substring(msg, p + 1, 1);
 422                 if(escape == "%")
 423                         replacement = "%";
 424                 else if(escape == "\\")
 425                         replacement = "\\";
 426                 else if(escape == "n")
 427                         replacement = "\n";
 428                 else if(escape == "a")
 429                         replacement = ftos(floor(self.armorvalue));
 430                 else if(escape == "h")
 431                         replacement = ftos(floor(self.health));
 432                 else if(escape == "l")
 433                         replacement = NearestLocation(self.origin);
 434                 else if(escape == "y")
 435                         replacement = NearestLocation(self.cursor_trace_endpos);
 436                 else if(escape == "d")
 437                         replacement = NearestLocation(self.death_origin);
 438                 else if(escape == "w")
 439                 {
 440                         float wep;
 441                         wep = self.weapon;
 442                         if(!wep)
 443                                 wep = self.switchweapon;
 444                         if(!wep)
 445                                 wep = self.cnt;
 446                         replacement = W_Name(wep);
 447                 }
 448                 else if(escape == "W")
 449                 {
 450                         if(self.items & IT_SHELLS) replacement = "shells";
 451                         else if(self.items & IT_NAILS) replacement = "bullets";
 452                         else if(self.items & IT_ROCKETS) replacement = "rockets";
 453                         else if(self.items & IT_CELLS) replacement = "cells";
 454                         else replacement = "batteries"; // ;)
 455                 }
 456                 else if(escape == "x")
 457                 {
 458                         replacement = self.cursor_trace_ent.netname;
 459                         if(!replacement || !self.cursor_trace_ent)
 460                                 replacement = "nothing";
 461                 }
 462                 else if(escape == "p")
 463                 {
 464                         if(self.last_selected_player)
 465                                 replacement = self.last_selected_player.netname;
 466                         else
 467                                 replacement = "(nobody)";
 468                 }
 469                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 470                 p = p + strlen(replacement);
 471         }
 472         return msg;
 473 }
 474
 475 /*
 476 =============
 477 GetCvars
 478 =============
 479 Called with:
 480   0:  sends the request
 481   >0: receives a cvar from name=argv(f) value=argv(f+1)
 482 */
 483 void GetCvars_handleString(string thisname, float f, .string field, string name)
 484 {
 485         if(f < 0)
 486         {
 487                 if(self.field)
 488                         strunzone(self.field);
 489                 self.field = string_null;
 490         }
 491         else if(f > 0)
 492         {
 493                 if(thisname == name)
 494                 {
 495                         if(self.field)
 496                                 strunzone(self.field);
 497                         self.field = strzone(argv(f + 1));
 498                 }
 499         }
 500         else
 501                 stuffcmd(self, strcat("sendcvar ", name, "\n"));
 502 }
 503 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 504 {
 505         GetCvars_handleString(thisname, f, field, name);
 506         if(f >= 0) // also initialize to the fitting value for "" when sending cvars out
 507         if(thisname == name)
 508         {
 509                 string s;
 510                 s = func(strcat1(self.field));
 511                 if(s != self.field)
 512                 {
 513                         strunzone(self.field);
 514                         self.field = strzone(s);
 515                 }
 516         }
 517 }
 518 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 519 {
 520         if(f < 0)
 521         {
 522         }
 523         else if(f > 0)
 524         {
 525                 if(thisname == name)
 526                         self.field = stof(argv(f + 1));
 527         }
 528         else
 529                 stuffcmd(self, strcat("sendcvar ", name, "\n"));
 530 }
 531 string W_FixWeaponOrder_ForceComplete(string s);
 532 string W_FixWeaponOrder_AllowIncomplete(string s);
 533 float w_getbestweapon(entity e);
 534 void GetCvars(float f)
 535 {
 536         string s;
 537         if(f > 0)
 538                 s = strcat1(argv(f));
 539         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 540         GetCvars_handleFloat(s, f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
 541         GetCvars_handleFloat(s, f, cvar_scr_centertime, "scr_centertime");
 542         GetCvars_handleFloat(s, f, cvar_cl_shownames, "cl_shownames");
 543         GetCvars_handleString(s, f, cvar_g_nexuizversion, "g_nexuizversion");
 544         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 545         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete);
 546         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 547         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 548         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 549         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 550         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 551         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 552         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 553         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 554         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 555         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 556         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 557         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 558         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 559         GetCvars_handleFloat(s, f, cvar_cl_hitsound, "cl_hitsound");
 560
 561         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 562         if(f > 0)
 563         {
 564                 if(s == "cl_weaponpriority")
 565                         self.switchweapon = w_getbestweapon(self);
 566         }
 567 }
 568
 569 float fexists(string f)
 570 {
 571         float fh;
 572         fh = fopen(f, FILE_READ);
 573         if(fh < 0)
 574                 return FALSE;
 575         fclose(fh);
 576         return TRUE;
 577 }
 578
 579 void backtrace(string msg)
 580 {
 581         float dev;
 582         dev = cvar("developer");
 583         cvar_set("developer", "1");
 584         dprint("\n");
 585         dprint("--- CUT HERE ---\nWARNING: ");
 586         dprint(msg);
 587         dprint("\n");
 588         remove(world); // isn't there any better way to cause a backtrace?
 589         dprint("\n--- CUT UNTIL HERE ---\n");
 590         cvar_set("developer", ftos(dev));
 591 }
 592
 593 string Team_ColorCode(float teamid)
 594 {
 595         if(teamid == COLOR_TEAM1)
 596                 return "^1";
 597         else if(teamid == COLOR_TEAM2)
 598                 return "^4";
 599         else if(teamid == COLOR_TEAM3)
 600                 return "^3";
 601         else if(teamid == COLOR_TEAM4)
 602                 return "^6";
 603         else
 604                 return "^7";
 605 }
 606 string Team_ColorName(float t)
 607 {
 608         // fixme: Search for team entities and get their .netname's!
 609         if(t == COLOR_TEAM1)
 610                 return "Red";
 611         if(t == COLOR_TEAM2)
 612                 return "Blue";
 613         if(t == COLOR_TEAM3)
 614                 return "Yellow";
 615         if(t == COLOR_TEAM4)
 616                 return "Pink";
 617         return "Neutral";
 618 }
 619 string Team_ColorNameLowerCase(float t)
 620 {
 621         // fixme: Search for team entities and get their .netname's!
 622         if(t == COLOR_TEAM1)
 623                 return "red";
 624         if(t == COLOR_TEAM2)
 625                 return "blue";
 626         if(t == COLOR_TEAM3)
 627                 return "yellow";
 628         if(t == COLOR_TEAM4)
 629                 return "pink";
 630         return "neutral";
 631 }
 632
 633 #define CENTERPRIO_POINT 1
 634 #define CENTERPRIO_SPAM 2
 635 #define CENTERPRIO_VOTE 4
 636 #define CENTERPRIO_NORMAL 5
 637 #define CENTERPRIO_SHIELDING 7
 638 #define CENTERPRIO_MAPVOTE 9
 639 #define CENTERPRIO_IDLEKICK 50
 640 #define CENTERPRIO_ADMIN 99
 641 .float centerprint_priority;
 642 .float centerprint_expires;
 643 void centerprint_atprio(entity e, float prio, string s)
 644 {
 645         if(intermission_running)
 646                 if(prio < CENTERPRIO_MAPVOTE)
 647                         return;
 648         if(time > e.centerprint_expires)
 649                 e.centerprint_priority = 0;
 650         if(prio >= e.centerprint_priority)
 651         {
 652                 e.centerprint_priority = prio;
 653                 if(timeoutStatus == 2)
 654                         e.centerprint_expires = time + (e.cvar_scr_centertime * TIMEOUT_SLOWMO_VALUE);
 655                 else
 656                         e.centerprint_expires = time + e.cvar_scr_centertime;
 657                 centerprint_builtin(e, s);
 658         }
 659 }
 660 void centerprint_expire(entity e, float prio)
 661 {
 662         if(prio == e.centerprint_priority)
 663         {
 664                 e.centerprint_priority = 0;
 665                 centerprint_builtin(e, "");
 666         }
 667 }
 668 void centerprint(entity e, string s)
 669 {
 670         centerprint_atprio(e, CENTERPRIO_NORMAL, s);
 671 }
 672
 673 // decolorizes and team colors the player name when needed
 674 string playername(entity p)
 675 {
 676         string t;
 677         if(teams_matter && !intermission_running && p.classname == "player")
 678         {
 679                 t = Team_ColorCode(p.team);
 680                 return strcat(t, strdecolorize(p.netname));
 681         }
 682         else
 683                 return p.netname;
 684 }
 685
 686 vector randompos(vector m1, vector m2)
 687 {
 688         local vector v;
 689         m2 = m2 - m1;
 690         v_x = m2_x * random() + m1_x;
 691         v_y = m2_y * random() + m1_y;
 692         v_z = m2_z * random() + m1_z;
 693         return  v;
 694 };
 695
 696 float g_pickup_shells;
 697 float g_pickup_shells_max;
 698 float g_pickup_nails;
 699 float g_pickup_nails_max;
 700 float g_pickup_rockets;
 701 float g_pickup_rockets_max;
 702 float g_pickup_cells;
 703 float g_pickup_cells_max;
 704 float g_pickup_fuel;
 705 float g_pickup_fuel_max;
 706 float g_pickup_armorsmall;
 707 float g_pickup_armorsmall_max;
 708 float g_pickup_armormedium;
 709 float g_pickup_armormedium_max;
 710 float g_pickup_armorbig;
 711 float g_pickup_armorbig_max;
 712 float g_pickup_armorlarge;
 713 float g_pickup_armorlarge_max;
 714 float g_pickup_healthsmall;
 715 float g_pickup_healthsmall_max;
 716 float g_pickup_healthmedium;
 717 float g_pickup_healthmedium_max;
 718 float g_pickup_healthlarge;
 719 float g_pickup_healthlarge_max;
 720 float g_pickup_healthmega;
 721 float g_pickup_healthmega_max;
 722 float g_weaponarena;
 723 string g_weaponarena_list;
 724
 725 float start_weapons;
 726 float start_items;
 727 float start_ammo_shells;
 728 float start_ammo_nails;
 729 float start_ammo_rockets;
 730 float start_ammo_cells;
 731 float start_ammo_fuel;
 732 float start_health;
 733 float start_armorvalue;
 734 float warmup_start_weapons;
 735 float warmup_start_ammo_shells;
 736 float warmup_start_ammo_nails;
 737 float warmup_start_ammo_rockets;
 738 float warmup_start_ammo_cells;
 739 float warmup_start_ammo_fuel;
 740 float warmup_start_health;
 741 float warmup_start_armorvalue;
 742 float g_weapon_stay;
 743
 744 entity get_weaponinfo(float w);
 745
 746 void readplayerstartcvars()
 747 {
 748         entity e;
 749         float i, j, t;
 750         string s;
 751
 752         // initialize starting values for players
 753         start_weapons = 0;
 754         start_items = 0;
 755         start_ammo_shells = 0;
 756         start_ammo_nails = 0;
 757         start_ammo_rockets = 0;
 758         start_ammo_cells = 0;
 759         start_health = cvar("g_balance_health_start");
 760         start_armorvalue = cvar("g_balance_armor_start");
 761
 762         g_weaponarena = 0;
 763         s = cvar_string("g_weaponarena");
 764         if(s == "0")
 765         {
 766         }
 767         else if(s == "all")
 768         {
 769                 g_weaponarena_list = "All Weapons";
 770                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 771                 {
 772                         e = get_weaponinfo(j);
 773                         g_weaponarena |= e.weapons;
 774                         weapon_action(e.weapon, WR_PRECACHE);
 775                 }
 776         }
 777         else if(s == "most")
 778         {
 779                 g_weaponarena_list = "Most Weapons";
 780                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 781                 {
 782                         e = get_weaponinfo(j);
 783                         if(e.spawnflags & WEPSPAWNFLAG_NORMAL)
 784                         {
 785                                 g_weaponarena |= e.weapons;
 786                                 weapon_action(e.weapon, WR_PRECACHE);
 787                         }
 788                 }
 789         }
 790         else
 791         {
 792                 t = tokenize_sane(s);
 793                 g_weaponarena_list = "";
 794                 for(i = 0; i < t; ++i)
 795                 {
 796                         s = argv(i);
 797                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 798                         {
 799                                 e = get_weaponinfo(j);
 800                                 if(e.netname == s)
 801                                 {
 802                                         g_weaponarena |= e.weapons;
 803                                         weapon_action(e.weapon, WR_PRECACHE);
 804                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 805                                         break;
 806                                 }
 807                         }
 808                         if(j > WEP_LAST)
 809                         {
 810                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 811                         }
 812                 }
 813                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 814         }
 815
 816         if(g_weaponarena)
 817         {
 818                 start_weapons = g_weaponarena;
 819                 start_ammo_rockets = 999;
 820                 start_ammo_shells = 999;
 821                 start_ammo_cells = 999;
 822                 start_ammo_nails = 999;
 823                 start_ammo_fuel = 999;
 824                 start_items |= IT_UNLIMITED_AMMO;
 825         }
 826         else if(g_nixnex)
 827         {
 828                 start_weapons = 0;
 829                 // will be done later
 830                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 831                 {
 832                         e = get_weaponinfo(i);
 833                         if(!(e.weapon))
 834                                 continue;
 835                         weapon_action(e.weapon, WR_PRECACHE);
 836                 }
 837         }
 838         else if(g_minstagib)
 839         {
 840                 start_health = 100;
 841                 start_armorvalue = 0;
 842                 start_weapons = WEPBIT_MINSTANEX;
 843                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
 844                 start_ammo_cells = cvar("g_minstagib_ammo_start");
 845                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 846                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 847
 848                 if(g_minstagib_invis_alpha <= 0)
 849                         g_minstagib_invis_alpha = -1;
 850         }
 851         else
 852         {
 853                 if(g_lms)
 854                 {
 855                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
 856                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
 857                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 858                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
 859                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
 860                         start_health = cvar("g_lms_start_health");
 861                         start_armorvalue = cvar("g_lms_start_armor");
 862                 } else if (cvar("g_use_ammunition")) {
 863                         start_ammo_shells = cvar("g_start_ammo_shells");
 864                         start_ammo_nails = cvar("g_start_ammo_nails");
 865                         start_ammo_rockets = cvar("g_start_ammo_rockets");
 866                         start_ammo_cells = cvar("g_start_ammo_cells");
 867                         start_ammo_fuel = cvar("g_start_ammo_fuel");
 868                 } else {
 869                         start_ammo_shells = cvar("g_pickup_shells_max");
 870                         start_ammo_nails = cvar("g_pickup_nails_max");
 871                         start_ammo_rockets = cvar("g_pickup_rockets_max");
 872                         start_ammo_cells = cvar("g_pickup_cells_max");
 873                         start_ammo_fuel = cvar("g_pickup_fuel_max");
 874                         start_items |= IT_UNLIMITED_AMMO;
 875                 }
 876
 877                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 878                 {
 879                         e = get_weaponinfo(i);
 880                         if(!(e.weapon))
 881                                 continue;
 882
 883                         t = cvar(strcat("g_start_weapon_", e.netname));
 884
 885                         if(t < 0) // "default" weapon selection
 886                         {
 887                                 if(g_lms)
 888                                         t = (e.spawnflags & WEPSPAWNFLAG_NORMAL);
 889                                 else if(g_race)
 890                                         t = (i == WEP_LASER);
 891                                 else
 892                                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
 893                                 if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 894                                         t += (i == WEP_HOOK);
 895                         }
 896
 897                         if(t)
 898                         {
 899                                 start_weapons |= e.weapons;
 900                                 weapon_action(e.weapon, WR_PRECACHE);
 901                         }
 902                 }
 903         }
 904
 905         if(inWarmupStage)
 906         {
 907                 warmup_start_ammo_shells = start_ammo_shells;
 908                 warmup_start_ammo_nails = start_ammo_nails;
 909                 warmup_start_ammo_rockets = start_ammo_rockets;
 910                 warmup_start_ammo_cells = start_ammo_cells;
 911                 warmup_start_health = start_health;
 912                 warmup_start_armorvalue = start_armorvalue;
 913                 warmup_start_weapons = start_weapons;
 914
 915                 if(!g_weaponarena && !g_nixnex && !g_minstagib)
 916                 {
 917                         if(cvar("g_use_ammunition"))
 918                         {
 919                                 warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 920                                 warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 921                                 warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 922                                 warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 923                         }
 924                         warmup_start_health = cvar("g_warmup_start_health");
 925                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 926                         if(cvar("g_warmup_allguns"))
 927                         {
 928                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 929                                 {
 930                                         e = get_weaponinfo(i);
 931                                         if(!(e.weapon))
 932                                                 continue;
 933                                         if(e.spawnflags & WEPSPAWNFLAG_NORMAL)
 934                                         {
 935                                                 warmup_start_weapons |= e.weapons;
 936                                                 weapon_action(e.weapon, WR_PRECACHE);
 937                                         }
 938                                 }
 939                         }
 940                 }
 941         }
 942
 943         if(start_weapons & WEPBIT_HOOK)
 944         {
 945                 // can't have off-hand hook, if hook weapon is enabled
 946
 947                 // note: if g_grappling_hook is 1, also give some initial cells
 948                 if(g_grappling_hook)
 949                 {
 950                         if(!start_ammo_cells)
 951                                 start_ammo_cells = g_pickup_cells;
 952                         if(!warmup_start_ammo_cells)
 953                                 warmup_start_ammo_cells = g_pickup_cells;
 954                 }
 955
 956                 g_grappling_hook = 0;
 957         }
 958
 959         if(g_jetpack)
 960         {
 961                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
 962                 start_items |= IT_JETPACK;
 963                 start_items |= IT_FUEL_REGEN;
 964                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_stable"));
 965         }
 966
 967         if(g_weapon_stay == 2)
 968         {
 969                 if(!start_ammo_shells) start_ammo_shells = g_pickup_shells;
 970                 if(!start_ammo_nails) start_ammo_nails = g_pickup_nails;
 971                 if(!start_ammo_cells) start_ammo_cells = g_pickup_cells;
 972                 if(!start_ammo_rockets) start_ammo_rockets = g_pickup_rockets;
 973                 if(!start_ammo_fuel) start_ammo_fuel = g_pickup_fuel;
 974                 if(!warmup_start_ammo_shells) warmup_start_ammo_shells = g_pickup_shells;
 975                 if(!warmup_start_ammo_nails) warmup_start_ammo_nails = g_pickup_nails;
 976                 if(!warmup_start_ammo_cells) warmup_start_ammo_cells = g_pickup_cells;
 977                 if(!warmup_start_ammo_rockets) warmup_start_ammo_rockets = g_pickup_rockets;
 978                 if(!warmup_start_ammo_fuel) warmup_start_ammo_fuel = g_pickup_fuel;
 979         }
 980
 981         start_ammo_shells = max(0, start_ammo_shells);
 982         start_ammo_nails = max(0, start_ammo_nails);
 983         start_ammo_cells = max(0, start_ammo_cells);
 984         start_ammo_rockets = max(0, start_ammo_rockets);
 985         start_ammo_fuel = max(0, start_ammo_fuel);
 986
 987         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 988         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 989         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 990         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 991         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 992 }
 993
 994 float g_bugrigs;
 995 float g_bugrigs_planar_movement;
 996 float g_bugrigs_planar_movement_car_jumping;
 997 float g_bugrigs_reverse_spinning;
 998 float g_bugrigs_reverse_speeding;
 999 float g_bugrigs_reverse_stopping;
1000 float g_bugrigs_air_steering;
1001 float g_bugrigs_angle_smoothing;
1002 float g_bugrigs_friction_floor;
1003 float g_bugrigs_friction_brake;
1004 float g_bugrigs_friction_air;
1005 float g_bugrigs_accel;
1006 float g_bugrigs_speed_ref;
1007 float g_bugrigs_speed_pow;
1008 float g_bugrigs_steer;
1009
1010 float g_touchexplode;
1011 float g_touchexplode_radius;
1012 float g_touchexplode_damage;
1013 float g_touchexplode_edgedamage;
1014 float g_touchexplode_force;
1015
1016 void readlevelcvars(void)
1017 {
1018         g_bugrigs = cvar("g_bugrigs");
1019         g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1020         g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1021         g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1022         g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1023         g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1024         g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1025         g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1026         g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1027         g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1028         g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1029         g_bugrigs_accel = cvar("g_bugrigs_accel");
1030         g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1031         g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1032         g_bugrigs_steer = cvar("g_bugrigs_steer");
1033
1034         g_touchexplode = cvar("g_touchexplode");
1035         g_touchexplode_radius = cvar("g_touchexplode_radius");
1036         g_touchexplode_damage = cvar("g_touchexplode_damage");
1037         g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1038         g_touchexplode_force = cvar("g_touchexplode_force");
1039
1040         sv_clones = cvar("sv_clones");
1041         sv_cheats = cvar("sv_cheats");
1042         sv_gentle = cvar("sv_gentle");
1043         sv_foginterval = cvar("sv_foginterval");
1044         g_cloaked = cvar("g_cloaked");
1045         g_jump_grunt = cvar("g_jump_grunt");
1046         g_footsteps = cvar("g_footsteps");
1047         g_grappling_hook = cvar("g_grappling_hook");
1048         g_jetpack = cvar("g_jetpack");
1049         g_laserguided_missile = cvar("g_laserguided_missile");
1050         g_midair = cvar("g_midair");
1051         g_minstagib = cvar("g_minstagib");
1052         g_nixnex = cvar("g_nixnex");
1053         g_nixnex_with_laser = cvar("g_nixnex_with_laser");
1054         g_norecoil = cvar("g_norecoil");
1055         g_vampire = cvar("g_vampire");
1056         g_bloodloss = cvar("g_bloodloss");
1057         sv_maxidle = cvar("sv_maxidle");
1058         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1059         sv_pogostick = cvar("sv_pogostick");
1060         sv_doublejump = cvar("sv_doublejump");
1061         g_maplist_allow_hidden = cvar("g_maplist_allow_hidden");
1062         g_ctf_reverse = cvar("g_ctf_reverse");
1063
1064         inWarmupStage = cvar("g_warmup");
1065         g_warmup_limit = cvar("g_warmup_limit");
1066         g_warmup_allguns = cvar("g_warmup_allguns");
1067         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1068
1069         if(g_race && g_race_qualifying == 2 || g_arena || g_assault || cvar("g_campaign"))
1070                 inWarmupStage = 0; // these modes cannot work together, sorry
1071
1072         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1073         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1074         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1075         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1076         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1077         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1078
1079         if(g_minstagib) g_nixnex = g_weaponarena = 0;
1080         if(g_nixnex) g_weaponarena = 0;
1081         g_weaponarena = 0;
1082
1083         g_pickup_shells                    = cvar("g_pickup_shells");
1084         g_pickup_shells_max                = cvar("g_pickup_shells_max");
1085         g_pickup_nails                     = cvar("g_pickup_nails");
1086         g_pickup_nails_max                 = cvar("g_pickup_nails_max");
1087         g_pickup_rockets                   = cvar("g_pickup_rockets");
1088         g_pickup_rockets_max               = cvar("g_pickup_rockets_max");
1089         g_pickup_cells                     = cvar("g_pickup_cells");
1090         g_pickup_cells_max                 = cvar("g_pickup_cells_max");
1091         g_pickup_fuel                     = cvar("g_pickup_fuel");
1092         g_pickup_fuel_max                 = cvar("g_pickup_fuel_max");
1093         g_pickup_armorsmall                = cvar("g_pickup_armorsmall");
1094         g_pickup_armorsmall_max            = cvar("g_pickup_armorsmall_max");
1095         g_pickup_armormedium               = cvar("g_pickup_armormedium");
1096         g_pickup_armormedium_max           = cvar("g_pickup_armormedium_max");
1097         g_pickup_armorbig                  = cvar("g_pickup_armorbig");
1098         g_pickup_armorbig_max              = cvar("g_pickup_armorbig_max");
1099         g_pickup_armorlarge                = cvar("g_pickup_armorlarge");
1100         g_pickup_armorlarge_max            = cvar("g_pickup_armorlarge_max");
1101         g_pickup_healthsmall               = cvar("g_pickup_healthsmall");
1102         g_pickup_healthsmall_max           = cvar("g_pickup_healthsmall_max");
1103         g_pickup_healthmedium              = cvar("g_pickup_healthmedium");
1104         g_pickup_healthmedium_max          = cvar("g_pickup_healthmedium_max");
1105         g_pickup_healthlarge               = cvar("g_pickup_healthlarge");
1106         g_pickup_healthlarge_max           = cvar("g_pickup_healthlarge_max");
1107         g_pickup_healthmega                = cvar("g_pickup_healthmega");
1108         g_pickup_healthmega_max            = cvar("g_pickup_healthmega_max");
1109
1110         g_pinata = cvar("g_pinata");
1111
1112         g_weapon_stay = cvar("g_weapon_stay");
1113         if(!g_weapon_stay && (cvar("deathmatch") == 2))
1114                 g_weapon_stay = 1;
1115
1116         if not(inWarmupStage)
1117                 game_starttime                 = cvar("g_start_delay");
1118
1119         readplayerstartcvars();
1120 }
1121
1122 /*
1123 // TODO sound pack system
1124 string soundpack;
1125
1126 string precache_sound_builtin (string s) = #19;
1127 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1128 string precache_sound(string s)
1129 {
1130         return precache_sound_builtin(strcat(soundpack, s));
1131 }
1132 void play2(entity e, string filename)
1133 {
1134         stuffcmd(e, strcat("play2 ", soundpack, filename, "\n"));
1135 }
1136 void sound(entity e, float chan, string samp, float vol, float atten)
1137 {
1138         sound_builtin(e, chan, strcat(soundpack, samp), vol, atten);
1139 }
1140 */
1141
1142 // Sound functions
1143 string precache_sound (string s) = #19;
1144 void(entity e, float chan, string samp, float vol, float atten) sound = #8;
1145 float precache_sound_index (string s) = #19;
1146
1147 #define SND_VOLUME      1
1148 #define SND_ATTENUATION 2
1149 #define SND_LARGEENTITY 8
1150 #define SND_LARGESOUND  16
1151
1152 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1153 {
1154         float entno, idx;
1155         entno = num_for_edict(e);
1156         idx = precache_sound_index(samp);
1157
1158         float sflags;
1159         sflags = 0;
1160
1161         atten = floor(atten * 64);
1162         vol = floor(vol * 255);
1163
1164         if(vol != 255)
1165                 sflags |= SND_VOLUME;
1166         if(atten != 64)
1167                 sflags |= SND_ATTENUATION;
1168         if(entno >= 8192)
1169                 sflags |= SND_LARGEENTITY;
1170         if(idx >= 256)
1171                 sflags |= SND_LARGESOUND;
1172
1173         WriteByte(dest, SVC_SOUND);
1174         WriteByte(dest, sflags);
1175         if(sflags & SND_VOLUME)
1176                 WriteByte(dest, vol * 255);
1177         if(sflags & SND_ATTENUATION)
1178                 WriteByte(dest, atten);
1179         if(sflags & SND_LARGEENTITY)
1180         {
1181                 WriteShort(dest, entno);
1182                 WriteByte(dest, chan);
1183         }
1184         else
1185         {
1186                 WriteShort(dest, entno * 8 + chan);
1187         }
1188         if(sflags & SND_LARGESOUND)
1189                 WriteShort(dest, idx);
1190         else
1191                 WriteByte(dest, idx);
1192
1193         WriteCoord(dest, o_x);
1194         WriteCoord(dest, o_y);
1195         WriteCoord(dest, o_z);
1196 }
1197 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1198 {
1199         vector o;
1200         o = e.origin + 0.5 * (e.mins + e.maxs);
1201         soundtoat(dest, e, o, chan, samp, vol, atten);
1202 }
1203 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1204 {
1205         soundtoat(MSG_BROADCAST, e, o, chan, samp, vol, atten);
1206 }
1207 void stopsoundto(float dest, entity e, float chan)
1208 {
1209         float entno;
1210         entno = num_for_edict(e);
1211
1212         if(entno >= 8192)
1213         {
1214                 float idx, sflags;
1215                 idx = precache_sound_index("misc/null.wav");
1216                 sflags = SND_LARGEENTITY;
1217                 if(idx >= 256)
1218                         sflags |= SND_LARGESOUND;
1219                 WriteByte(dest, SVC_SOUND);
1220                 WriteByte(dest, sflags);
1221                 WriteShort(dest, entno);
1222                 WriteByte(dest, chan);
1223                 if(sflags & SND_LARGESOUND)
1224                         WriteShort(dest, idx);
1225                 else
1226                         WriteByte(dest, idx);
1227                 WriteCoord(dest, e.origin_x);
1228                 WriteCoord(dest, e.origin_y);
1229                 WriteCoord(dest, e.origin_z);
1230         }
1231         else
1232         {
1233                 WriteByte(dest, SVC_STOPSOUND);
1234                 WriteShort(dest, entno * 8 + chan);
1235         }
1236 }
1237 void stopsound(entity e, float chan)
1238 {
1239         stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1240         stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1241 }
1242
1243 void play2(entity e, string filename)
1244 {
1245         //stuffcmd(e, strcat("play2 ", filename, "\n"));
1246         msg_entity = e;
1247         soundtoat(MSG_ONE, world, '0 0 0', CHAN_AUTO, filename, VOL_BASE, ATTN_NONE);
1248 }
1249
1250 .float announcetime;
1251 float announce(entity player, string msg)
1252 {
1253         if(time > player.announcetime)
1254         if(clienttype(player) == CLIENTTYPE_REAL)
1255         {
1256                 player.announcetime = time + 0.8;
1257                 play2(player, msg);
1258                 return TRUE;
1259         }
1260         return FALSE;
1261 }
1262
1263 void play2team(float t, string filename)
1264 {
1265         local entity head;
1266         FOR_EACH_REALPLAYER(head)
1267         {
1268                 if (head.team == t)
1269                         play2(head, filename);
1270         }
1271 }
1272
1273 void play2all(string samp)
1274 {
1275         sound(world, CHAN_AUTO, samp, VOL_BASE, ATTN_NONE);
1276 }
1277
1278 void PrecachePlayerSounds(string f);
1279 void precache_all_models(string pattern)
1280 {
1281         float globhandle, i, n;
1282         string f;
1283
1284         globhandle = search_begin(pattern, TRUE, FALSE);
1285         if(globhandle < 0)
1286                 return;
1287         n = search_getsize(globhandle);
1288         for(i = 0; i < n; ++i)
1289         {
1290                 //print(search_getfilename(globhandle, i), "\n");
1291                 f = search_getfilename(globhandle, i);
1292                 precache_model(f);
1293                 PrecachePlayerSounds(strcat(f, ".sounds"));
1294         }
1295         search_end(globhandle);
1296 }
1297
1298 void precache()
1299 {
1300         // gamemode related things
1301         precache_model ("models/misc/chatbubble.spr");
1302         precache_model ("models/misc/teambubble.spr");
1303         if (g_runematch)
1304         {
1305                 precache_model ("models/runematch/curse.mdl");
1306                 precache_model ("models/runematch/rune.mdl");
1307         }
1308
1309 #ifdef TTURRETS_ENABLED
1310     if(cvar("g_turrets"))
1311         turrets_precash();
1312 #endif
1313
1314         // Precache all player models if desired
1315         if (cvar("sv_precacheplayermodels"))
1316         {
1317                 PrecachePlayerSounds("sound/player/default.sounds");
1318                 precache_all_models("models/player/*.zym");
1319                 precache_all_models("models/player/*.dpm");
1320                 precache_all_models("models/player/*.md3");
1321                 precache_all_models("models/player/*.psk");
1322                 //precache_model("models/player/carni.zym");
1323                 //precache_model("models/player/crash.zym");
1324                 //precache_model("models/player/grunt.zym");
1325                 //precache_model("models/player/headhunter.zym");
1326                 //precache_model("models/player/insurrectionist.zym");
1327                 //precache_model("models/player/jeandarc.zym");
1328                 //precache_model("models/player/lurk.zym");
1329                 //precache_model("models/player/lycanthrope.zym");
1330                 //precache_model("models/player/marine.zym");
1331                 //precache_model("models/player/nexus.zym");
1332                 //precache_model("models/player/pyria.zym");
1333                 //precache_model("models/player/shock.zym");
1334                 //precache_model("models/player/skadi.zym");
1335                 //precache_model("models/player/specop.zym");
1336                 //precache_model("models/player/visitant.zym");
1337         }
1338
1339         if(cvar("sv_defaultcharacter"))
1340         {
1341                 string s;
1342                 s = cvar_string("sv_defaultplayermodel_red");
1343                 if(s != "")
1344                 {
1345                         precache_model(s);
1346                         PrecachePlayerSounds(strcat(s, ".sounds"));
1347                 }
1348                 s = cvar_string("sv_defaultplayermodel_blue");
1349                 if(s != "")
1350                 {
1351                         precache_model(s);
1352                         PrecachePlayerSounds(strcat(s, ".sounds"));
1353                 }
1354                 s = cvar_string("sv_defaultplayermodel_yellow");
1355                 if(s != "")
1356                 {
1357                         precache_model(s);
1358                         PrecachePlayerSounds(strcat(s, ".sounds"));
1359                 }
1360                 s = cvar_string("sv_defaultplayermodel_pink");
1361                 if(s != "")
1362                 {
1363                         precache_model(s);
1364                         PrecachePlayerSounds(strcat(s, ".sounds"));
1365                 }
1366                 s = cvar_string("sv_defaultplayermodel");
1367                 if(s != "")
1368                 {
1369                         precache_model(s);
1370                         PrecachePlayerSounds(strcat(s, ".sounds"));
1371                 }
1372         }
1373
1374         if (g_footsteps)
1375         {
1376                 PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1377                 PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1378         }
1379
1380         // gore and miscellaneous sounds
1381         //precache_sound ("misc/h2ohit.wav");
1382         precache_model ("models/hook.md3");
1383         precache_sound ("misc/armorimpact.wav");
1384         precache_sound ("misc/bodyimpact1.wav");
1385         precache_sound ("misc/bodyimpact2.wav");
1386         precache_sound ("misc/gib.wav");
1387         precache_sound ("misc/gib_splat01.wav");
1388         precache_sound ("misc/gib_splat02.wav");
1389         precache_sound ("misc/gib_splat03.wav");
1390         precache_sound ("misc/gib_splat04.wav");
1391         precache_sound ("misc/hit.wav");
1392         PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1393         PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1394         precache_sound ("misc/null.wav");
1395         precache_sound ("misc/spawn.wav");
1396         precache_sound ("misc/talk.wav");
1397         precache_sound ("misc/teleport.wav");
1398         precache_sound ("player/lava.wav");
1399         precache_sound ("player/slime.wav");
1400
1401         if(g_jetpack)
1402                 precache_sound ("misc/jetpack_fly.wav");
1403
1404         // announcer sounds - male
1405         precache_sound ("announcer/male/electrobitch.wav");
1406         precache_sound ("announcer/male/airshot.wav");
1407         precache_sound ("announcer/male/03kills.wav");
1408         precache_sound ("announcer/male/05kills.wav");
1409         precache_sound ("announcer/male/10kills.wav");
1410         precache_sound ("announcer/male/15kills.wav");
1411         precache_sound ("announcer/male/20kills.wav");
1412         precache_sound ("announcer/male/25kills.wav");
1413         precache_sound ("announcer/male/30kills.wav");
1414         precache_sound ("announcer/male/botlike.wav");
1415         precache_sound ("announcer/male/yoda.wav");
1416         precache_sound ("announcer/male/headshot.wav");
1417         precache_sound ("announcer/male/impressive.wav");
1418
1419         // announcer sounds - robotic
1420         precache_sound ("announcer/robotic/prepareforbattle.wav");
1421         precache_sound ("announcer/robotic/begin.wav");
1422         precache_sound ("announcer/robotic/timeoutcalled.wav");
1423         precache_sound ("announcer/robotic/1fragleft.wav");
1424         precache_sound ("announcer/robotic/1minuteremains.wav");
1425         precache_sound ("announcer/robotic/2fragsleft.wav");
1426         precache_sound ("announcer/robotic/3fragsleft.wav");
1427         if (g_minstagib)
1428         {
1429                 precache_sound ("announcer/robotic/lastsecond.wav");
1430                 precache_sound ("announcer/robotic/narrowly.wav");
1431         }
1432
1433         precache_model ("models/sprites/1.spr32");
1434         precache_model ("models/sprites/2.spr32");
1435         precache_model ("models/sprites/3.spr32");
1436         precache_model ("models/sprites/4.spr32");
1437         precache_model ("models/sprites/5.spr32");
1438         precache_model ("models/sprites/6.spr32");
1439         precache_model ("models/sprites/7.spr32");
1440         precache_model ("models/sprites/8.spr32");
1441         precache_model ("models/sprites/9.spr32");
1442         precache_model ("models/sprites/10.spr32");
1443         precache_sound ("announcer/robotic/1.wav");
1444         precache_sound ("announcer/robotic/2.wav");
1445         precache_sound ("announcer/robotic/3.wav");
1446         precache_sound ("announcer/robotic/4.wav");
1447         precache_sound ("announcer/robotic/5.wav");
1448         precache_sound ("announcer/robotic/6.wav");
1449         precache_sound ("announcer/robotic/7.wav");
1450         precache_sound ("announcer/robotic/8.wav");
1451         precache_sound ("announcer/robotic/9.wav");
1452         precache_sound ("announcer/robotic/10.wav");
1453
1454         // common weapon precaches
1455         precache_sound ("weapons/weapon_switch.wav");
1456         precache_sound ("weapons/weaponpickup.wav");
1457         if(g_grappling_hook)
1458         {
1459                 precache_sound ("weapons/hook_fire.wav"); // hook
1460                 precache_sound ("weapons/hook_impact.wav"); // hook
1461         }
1462
1463         if (cvar("sv_precacheweapons") || g_nixnex)
1464         {
1465                 //precache weapon models/sounds
1466                 local float wep;
1467                 wep = WEP_FIRST;
1468                 while (wep <= WEP_LAST)
1469                 {
1470                         weapon_action(wep, WR_PRECACHE);
1471                         wep = wep + 1;
1472                 }
1473         }
1474
1475         precache_model("models/elaser.mdl");
1476         precache_model("models/laser.mdl");
1477         precache_model("models/ebomb.mdl");
1478
1479 #if 0
1480         // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1481
1482         if (!self.noise && self.music) // quake 3 uses the music field
1483                 self.noise = self.music;
1484
1485         // plays music for the level if there is any
1486         if (self.noise)
1487         {
1488                 precache_sound (self.noise);
1489                 ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1490         }
1491 #endif
1492 }
1493
1494 // sorry, but using \ in macros breaks line numbers
1495 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1496 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1497 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1498
1499 vector ExactTriggerHit_mins;
1500 vector ExactTriggerHit_maxs;
1501 float ExactTriggerHit_Recurse()
1502 {
1503         float s;
1504         entity se;
1505         float f;
1506
1507         tracebox('0 0 0', ExactTriggerHit_mins, ExactTriggerHit_maxs, '0 0 0', MOVE_NORMAL, other);
1508         if not(trace_ent)
1509                 return 0;
1510         if(trace_ent == self)
1511                 return 1;
1512
1513         se = trace_ent;
1514         s = se.solid;
1515         se.solid = SOLID_NOT;
1516         f = ExactTriggerHit_Recurse();
1517         se.solid = s;
1518
1519         return f;
1520 }
1521
1522 float ExactTriggerHit()
1523 {
1524         float f, s;
1525
1526         if not(self.modelindex)
1527                 return 1;
1528
1529         s = self.solid;
1530         self.solid = SOLID_BSP;
1531         ExactTriggerHit_mins = other.absmin;
1532         ExactTriggerHit_maxs = other.absmax;
1533         f = ExactTriggerHit_Recurse();
1534         self.solid = s;
1535
1536         return f;
1537 }
1538
1539 // WARNING: this kills the trace globals
1540 #define EXACTTRIGGER_TOUCH if not(ExactTriggerHit()) return
1541 #define EXACTTRIGGER_INIT  InitSolidBSPTrigger(); self.solid = SOLID_TRIGGER
1542
1543 #define INITPRIO_FIRST              0
1544 #define INITPRIO_GAMETYPE           0
1545 #define INITPRIO_GAMETYPE_FALLBACK  1
1546 #define INITPRIO_CVARS              5
1547 #define INITPRIO_FINDTARGET        10
1548 #define INITPRIO_DROPTOFLOOR       20
1549 #define INITPRIO_SETLOCATION       90
1550 #define INITPRIO_LINKDOORS         91
1551 #define INITPRIO_LAST              99
1552
1553 .void(void) initialize_entity;
1554 .float initialize_entity_order;
1555 .entity initialize_entity_next;
1556 entity initialize_entity_first;
1557
1558 void make_safe_for_remove(entity e)
1559 {
1560         if(e.initialize_entity)
1561         {
1562                 entity ent, prev;
1563                 for(ent = initialize_entity_first; ent; )
1564                 {
1565                         if((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1566                         {
1567                                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1568                                 // skip it in linked list
1569                                 if(prev)
1570                                 {
1571                                         prev.initialize_entity_next = ent.initialize_entity_next;
1572                                         ent = prev.initialize_entity_next;
1573                                 }
1574                                 else
1575                                 {
1576                                         initialize_entity_first = ent.initialize_entity_next;
1577                                         ent = initialize_entity_first;
1578                                 }
1579                         }
1580                         else
1581                         {
1582                                 prev = ent;
1583                                 ent = ent.initialize_entity_next;
1584                         }
1585                 }
1586         }
1587 }
1588
1589 void objerror(string s)
1590 {
1591         make_safe_for_remove(self);
1592         objerror_builtin(s);
1593 }
1594
1595 void remove_unsafely(entity e)
1596 {
1597         remove_builtin(e);
1598 }
1599
1600 void remove_safely(entity e)
1601 {
1602         make_safe_for_remove(e);
1603         remove_builtin(e);
1604 }
1605
1606 void InitializeEntity(entity e, void(void) func, float order)
1607 {
1608         entity prev, cur;
1609
1610         if(!e || e.initialize_entity)
1611         {
1612                 // make a proxy initializer entity
1613                 entity e_old;
1614                 e_old = e;
1615                 e = spawn();
1616                 e.classname = "initialize_entity";
1617                 e.enemy = e_old;
1618         }
1619
1620         e.initialize_entity = func;
1621         e.initialize_entity_order = order;
1622
1623         cur = initialize_entity_first;
1624         for(;;)
1625         {
1626                 if(!cur || cur.initialize_entity_order > order)
1627                 {
1628                         // insert between prev and cur
1629                         if(prev)
1630                                 prev.initialize_entity_next = e;
1631                         else
1632                                 initialize_entity_first = e;
1633                         e.initialize_entity_next = cur;
1634                         return;
1635                 }
1636                 prev = cur;
1637                 cur = cur.initialize_entity_next;
1638         }
1639 }
1640 void InitializeEntitiesRun()
1641 {
1642         entity startoflist;
1643         startoflist = initialize_entity_first;
1644         initialize_entity_first = world;
1645         for(self = startoflist; self; )
1646         {
1647                 entity e;
1648                 var void(void) func;
1649                 e = self.initialize_entity_next;
1650                 func = self.initialize_entity;
1651                 self.initialize_entity_order = 0;
1652                 self.initialize_entity = func_null;
1653                 self.initialize_entity_next = world;
1654                 if(self.classname == "initialize_entity")
1655                 {
1656                         entity e_old;
1657                         e_old = self.enemy;
1658                         remove_builtin(self);
1659                         self = e_old;
1660                 }
1661                 //dprint("Delayed initialization: ", self.classname, "\n");
1662                 func();
1663                 self = e;
1664         }
1665 }
1666
1667 .float uncustomizeentityforclient_set;
1668 .void(void) uncustomizeentityforclient;
1669 void(void) SUB_Nullpointer = #0;
1670 void UncustomizeEntitiesRun()
1671 {
1672         entity oldself;
1673         oldself = self;
1674         for(self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1675                 self.uncustomizeentityforclient();
1676         self = oldself;
1677 }
1678 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1679 {
1680         e.customizeentityforclient = customizer;
1681         e.uncustomizeentityforclient = uncustomizer;
1682         e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1683 }
1684
1685 .float nottargeted;
1686 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1687
1688 void() SUB_Remove;
1689 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1690 {
1691         vector mi, ma;
1692
1693         if(e.classname == "")
1694                 e.classname = "net_linked";
1695
1696         if(e.model == "" || self.modelindex == 0)
1697         {
1698                 mi = e.mins;
1699                 ma = e.maxs;
1700                 setmodel(e, "null");
1701                 setsize(e, mi, ma);
1702         }
1703
1704         e.SendEntity = sendfunc;
1705         e.SendFlags = 0xFFFFFF;
1706
1707         if(!docull)
1708                 e.effects |= EF_NODEPTHTEST;
1709
1710         if(dt)
1711         {
1712                 e.nextthink = time + dt;
1713                 e.think = SUB_Remove;
1714         }
1715 }
1716
1717 void adaptor_think2touch()
1718 {
1719         entity o;
1720         o = other;
1721         other = world;
1722         self.touch();
1723         other = o;
1724 }
1725
1726 void adaptor_think2use()
1727 {
1728         entity o, a;
1729         o = other;
1730         a = activator;
1731         activator = world;
1732         other = world;
1733         self.use();
1734         other = o;
1735         activator = a;
1736 }
1737
1738 // deferred dropping
1739 void DropToFloor_Handler()
1740 {
1741         droptofloor_builtin();
1742         self.dropped_origin = self.origin;
1743 }
1744
1745 void droptofloor()
1746 {
1747         InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1748 }
1749
1750
1751
1752 float trace_hits_box_a0, trace_hits_box_a1;
1753
1754 float trace_hits_box_1d(float end, float thmi, float thma)
1755 {
1756         if(end == 0)
1757         {
1758                 // just check if x is in range
1759                 if(0 < thmi)
1760                         return FALSE;
1761                 if(0 > thma)
1762                         return FALSE;
1763         }
1764         else
1765         {
1766                 // do the trace with respect to x
1767                 // 0 -> end has to stay in thmi -> thma
1768                 trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1769                 trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1770                 if(trace_hits_box_a0 > trace_hits_box_a1)
1771                         return FALSE;
1772         }
1773         return TRUE;
1774 }
1775
1776 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1777 {
1778         end -= start;
1779         thmi -= start;
1780         thma -= start;
1781         // now it is a trace from 0 to end
1782
1783         trace_hits_box_a0 = 0;
1784         trace_hits_box_a1 = 1;
1785
1786         if(!trace_hits_box_1d(end_x, thmi_x, thma_x))
1787                 return FALSE;
1788         if(!trace_hits_box_1d(end_y, thmi_y, thma_y))
1789                 return FALSE;
1790         if(!trace_hits_box_1d(end_z, thmi_z, thma_z))
1791                 return FALSE;
1792
1793         return TRUE;
1794 }
1795
1796 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1797 {
1798         return trace_hits_box(start, end, thmi - ma, thma - mi);
1799 }
1800
1801 float SUB_NoImpactCheck()
1802 {
1803         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1804                 return 1;
1805         if(other == world && self.size != '0 0 0')
1806         {
1807                 vector tic;
1808                 tic = self.velocity * sys_ticrate;
1809                 tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1810                 traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1811                 if(trace_fraction >= 1)
1812                 {
1813                         dprint("Odd... did not hit...?\n");
1814                 }
1815                 else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1816                 {
1817                         dprint("Detected and prevented the sky-grapple bug.\n");
1818                         return 1;
1819                 }
1820         }
1821
1822         return 0;
1823 }
1824
1825 #define SUB_OwnerCheck() (other && (other == self.owner))
1826
1827 #define PROJECTILE_TOUCH do { if(SUB_OwnerCheck()) return; if(SUB_NoImpactCheck()) { remove(self); return; } if(trace_ent && trace_ent.solid > SOLID_TRIGGER) UpdateCSQCProjectileNextFrame(self); } while(0)
1828
1829 float MAX_IPBAN_URIS = 16;
1830
1831 float URI_GET_DISCARD   = 0;
1832 float URI_GET_IPBAN     = 1;
1833 float URI_GET_IPBAN_END = 16;
1834
1835 void URI_Get_Callback(float id, float status, string data)
1836 {
1837         dprint("Received HTTP request data for id ", ftos(id), "; status is ", ftos(status), "\nData is\n:");
1838         dprint(data);
1839         dprint("\nEnd of data.\n");
1840
1841         if(id == URI_GET_DISCARD)
1842         {
1843                 // discard
1844         }
1845         else if(id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1846         {
1847                 // online ban list
1848                 OnlineBanList_URI_Get_Callback(id, status, data);
1849         }
1850         else
1851         {
1852                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1853         }
1854 }
1855
1856 void print_to(entity e, string s)
1857 {
1858         if(e)
1859                 sprint(e, strcat(s, "\n"));
1860         else
1861                 print(s, "\n");
1862 }
1863
1864 string getrecords()
1865 {
1866         float rec;
1867         string h;
1868         float r;
1869         float i;
1870         string s;
1871
1872         rec = 0;
1873
1874         s = "";
1875
1876         if(g_ctf)
1877         {
1878                 for(i = 0; i < MapInfo_count; ++i)
1879                 {
1880                         if(MapInfo_Get_ByID(i))
1881                         {
1882                                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/time")));
1883                                 if(r == 0)
1884                                         continue;
1885                                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/netname"));
1886                                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-6, ftos_decimals(r, 2)), " ", h, "\n");
1887                                 ++rec;
1888                         }
1889                 }
1890         }
1891
1892         if(g_race)
1893         {
1894                 for(i = 0; i < MapInfo_count; ++i)
1895                 {
1896                         if(MapInfo_Get_ByID(i))
1897                         {
1898                                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/racerecord/time")));
1899                                 if(r == 0)
1900                                         continue;
1901                                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/racerecord/netname"));
1902                                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, mmsss(r)), " ", h, "\n");
1903                                 ++rec;
1904                         }
1905                 }
1906         }
1907         MapInfo_ClearTemps();
1908
1909         if(s == "")
1910                 return "No records are available on this server.\n";
1911         else
1912                 return strcat("Records on this server:\n", s);
1913 }
1914
1915 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1916 {
1917         float m, i;
1918         vector start, org, delta, end, enddown, mstart;
1919
1920         m = e.dphitcontentsmask;
1921         e.dphitcontentsmask = goodcontents | badcontents;
1922
1923         org = world.mins;
1924         delta = world.maxs - world.mins;
1925
1926         for(i = 0; i < attempts; ++i)
1927         {
1928                 start_x = org_x + random() * delta_x;
1929                 start_y = org_y + random() * delta_y;
1930                 start_z = org_z + random() * delta_z;
1931
1932                 // rule 1: start inside world bounds, and outside
1933                 // solid, and don't start from somewhere where you can
1934                 // fall down to evil
1935                 tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
1936                 if(trace_fraction >= 1)
1937                         continue;
1938                 if(trace_startsolid)
1939                         continue;
1940                 if(trace_dphitcontents & badcontents)
1941                         continue;
1942                 if(trace_dphitq3surfaceflags & badsurfaceflags)
1943                         continue;
1944
1945                 // rule 2: if we are too high, lower the point
1946                 if(trace_fraction * delta_z > maxaboveground)
1947                         start = trace_endpos + '0 0 1' * maxaboveground;
1948                 enddown = trace_endpos;
1949
1950                 // rule 3: make sure we aren't outside the map. This only works
1951                 // for somewhat well formed maps. A good rule of thumb is that
1952                 // the map should have a convex outside hull.
1953                 // these can be traceLINES as we already verified the starting box
1954                 mstart = start + 0.5 * (e.mins + e.maxs);
1955                 traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
1956                 if(trace_fraction >= 1)
1957                         continue;
1958                 traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
1959                 if(trace_fraction >= 1)
1960                         continue;
1961                 traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
1962                 if(trace_fraction >= 1)
1963                         continue;
1964                 traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
1965                 if(trace_fraction >= 1)
1966                         continue;
1967                 traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
1968                 if(trace_fraction >= 1)
1969                         continue;
1970
1971                 // find a random vector to "look at"
1972                 end_x = org_x + random() * delta_x;
1973                 end_y = org_y + random() * delta_y;
1974                 end_z = org_z + random() * delta_z;
1975                 end = start + normalize(end - start) * vlen(delta);
1976
1977                 // rule 4: start TO end must not be too short
1978                 tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1979                 if(trace_startsolid)
1980                         continue;
1981                 if(trace_fraction < minviewdistance / vlen(delta))
1982                         continue;
1983
1984                 // rule 5: don't want to look at sky
1985                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1986                         continue;
1987
1988                 // rule 6: we must not end up in trigger_hurt
1989                 if(tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1990                 {
1991                         dprint("trigger_hurt! ouch! and nothing else could find it!\n");
1992                         continue;
1993                 }
1994
1995                 break;
1996         }
1997
1998         e.dphitcontentsmask = m;
1999
2000         if(i < attempts)
2001         {
2002                 setorigin(e, start);
2003                 e.angles = vectoangles(end - start);
2004                 dprint("Needed ", ftos(i + 1), " attempts\n");
2005                 return TRUE;
2006         }
2007         else
2008                 return FALSE;
2009 }
2010
2011 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2012 {
2013         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2014         WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2015         WriteShort(MSG_BROADCAST, effectno);
2016         WriteCoord(MSG_BROADCAST, start_x);
2017         WriteCoord(MSG_BROADCAST, start_y);
2018         WriteCoord(MSG_BROADCAST, start_z);
2019         WriteCoord(MSG_BROADCAST, end_x);
2020         WriteCoord(MSG_BROADCAST, end_y);
2021         WriteCoord(MSG_BROADCAST, end_z);
2022         WriteCoord(MSG_BROADCAST, end_dz);
2023         WriteShort(MSG_BROADCAST, spd / 16);
2024 }
2025
2026 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2027 {
2028         float end_dz;
2029         vector vecxy, velxy;
2030
2031         vecxy = end - start; vecxy_z = 0;
2032         velxy = vel;         velxy_z = 0;
2033
2034         if(vlen(velxy) < 0.000001 * fabs(vel_z))
2035         {
2036                 trailparticles(world, effectno, start, end);
2037                 return;
2038         }
2039
2040         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2041         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2042 }
2043
2044 string GetGametype(); // g_world.qc
2045 void write_recordmarker(entity pl, float tstart, float dt)
2046 {
2047         GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt / 10)));
2048
2049         // also write a marker into demo files for demotc-race-record-extractor to find
2050         stuffcmd(pl,
2051                 strcat(
2052                         strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", mmsss(dt * 10)),
2053                         " ", ftos(tstart), " ", ftos(dt), "\n"));
2054 }
2055
2056 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2057 {
2058         string s;
2059         vector v;
2060         if (cvar("g_shootfromeye"))
2061         {
2062                 if(visual)
2063                 {
2064                         vecs_y = 0;
2065                         vecs_z -= 4;
2066                 }
2067                 else
2068                 {
2069                         vecs_y = 0;
2070                         vecs_z = 0;
2071                 }
2072         }
2073         else if (cvar("g_shootfromcenter"))
2074         {
2075                 vecs_y = 0;
2076                 vecs_z -= 4;
2077         }
2078         else if((s = cvar_string("g_shootfromfixedorigin")) != "")
2079         {
2080                 v = stov(s);
2081                 if(y_is_right)
2082                         v_y = -v_y;
2083                 if(v_x != 0)
2084                         vecs_x = v_x;
2085                 vecs_y = v_y;
2086                 vecs_z = v_z;
2087         }
2088         return vecs;
2089 }
2090
2091
2092
2093 void attach_sameorigin(entity e, entity to, string tag)
2094 {
2095         vector org, t_forward, t_left, t_up, e_forward, e_up;
2096         vector org0, ang0;
2097         float tagscale;
2098
2099         ang0 = e.angles;
2100         org0 = e.origin;
2101
2102         org = e.origin - gettaginfo(to, gettagindex(to, tag));
2103         tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2104         t_forward = v_forward * tagscale;
2105         t_left = v_right * -tagscale;
2106         t_up = v_up * tagscale;
2107
2108         e.origin_x = org * t_forward;
2109         e.origin_y = org * t_left;
2110         e.origin_z = org * t_up;
2111
2112         // current forward and up directions
2113         if(substring(e.model, 0, 1) == "*") // bmodels have their own rules
2114                 e.angles_x = -e.angles_x;
2115         fixedmakevectors(e.angles);
2116
2117         // untransform forward, up!
2118         e_forward_x = v_forward * t_forward;
2119         e_forward_y = v_forward * t_left;
2120         e_forward_z = v_forward * t_up;
2121         e_up_x = v_up * t_forward;
2122         e_up_y = v_up * t_left;
2123         e_up_z = v_up * t_up;
2124
2125         e.angles = fixedvectoangles2(e_forward, e_up);
2126         if(substring(e.model, 0, 1) == "*") // bmodels have their own rules
2127                 e.angles_x = -e.angles_x;
2128
2129         setattachment(e, to, tag);
2130         setorigin(e, e.origin);
2131 }
2132
2133 void detach_sameorigin(entity e)
2134 {
2135         vector org;
2136         org = gettaginfo(e, 0);
2137         e.angles = fixedvectoangles2(v_forward, v_up);
2138         if(substring(e.model, 0, 1) == "*") // bmodels have their own rules
2139                 e.angles_x = -e.angles_x;
2140         e.origin = org;
2141         setattachment(e, world, "");
2142         setorigin(e, e.origin);
2143 }
2144
2145 void follow_sameorigin(entity e, entity to)
2146 {
2147         e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2148         e.aiment = to; // make the hole follow bmodel
2149         e.punchangle = to.angles; // the original angles of bmodel
2150         e.view_ofs = e.origin - to.origin; // relative origin
2151         e.v_angle = e.angles - to.angles; // relative angles
2152 }
2153
2154 void unfollow_sameorigin(entity e)
2155 {
2156         e.movetype = MOVETYPE_NONE;
2157 }
2158
2159 entity gettaginfo_relative_ent;
2160 vector gettaginfo_relative(entity e, float tag)
2161 {
2162         if(!gettaginfo_relative_ent)
2163         {
2164                 gettaginfo_relative_ent = spawn();
2165                 gettaginfo_relative_ent.effects = EF_NODRAW;
2166         }
2167         gettaginfo_relative_ent.model = e.model;
2168         gettaginfo_relative_ent.modelindex = e.modelindex;
2169         gettaginfo_relative_ent.frame = e.frame;
2170         return gettaginfo(gettaginfo_relative_ent, tag);
2171 }
2172
2173 void SoundEntity_StartSound(entity pl, float chan, string samp, float vol, float attn)
2174 {
2175         float p;
2176         p = pow(2, chan);
2177         if(pl.soundentity.cnt & p)
2178                 return;
2179         soundtoat(MSG_ALL, pl.soundentity, gettaginfo(pl.soundentity, 0), chan, samp, vol, attn);
2180         pl.soundentity.cnt |= p;
2181 }
2182
2183 void SoundEntity_StopSound(entity pl, float chan)
2184 {
2185         float p;
2186         p = pow(2, chan);
2187         if(pl.soundentity.cnt & p)
2188         {
2189                 stopsoundto(MSG_ALL, pl.soundentity, chan);
2190                 pl.soundentity.cnt &~= p;
2191         }
2192 }
2193
2194 void SoundEntity_Attach(entity pl)
2195 {
2196         pl.soundentity = spawn();
2197         pl.soundentity.classname = "soundentity";
2198         setattachment(pl.soundentity, pl, "");
2199         setmodel(pl.soundentity, "null");
2200 }
2201
2202 void SoundEntity_Detach(entity pl)
2203 {
2204         float i;
2205         for(i = 0; i <= 7; ++i)
2206                 SoundEntity_StopSound(pl, i);
2207 }