data/qcsrc/server/keyhunt.qc

   1 string STR_ITEM_KH_KEY = "item_kh_key";
   2 #define FOR_EACH_KH_KEY(v) for(v = world; (v = find(v, classname, STR_ITEM_KH_KEY)); )
   3
   4 typedef void(void) kh_Think_t;
   5 var kh_Think_t kh_Controller_Thinkfunc;
   6 string kh_Controller_Waitmsg;
   7
   8 float kh_Team_ByID(float t)
   9 {
  10         if(t == 0) return COLOR_TEAM1;
  11         if(t == 1) return COLOR_TEAM2;
  12         if(t == 2) return COLOR_TEAM3;
  13         if(t == 3) return COLOR_TEAM4;
  14         return 0;
  15 }
  16
  17 entity kh_controller;
  18 float kh_tracking_enabled;
  19 float kh_teams;
  20 float kh_interferemsg_time, kh_interferemsg_team;
  21 .entity kh_next, kh_prev; // linked list
  22 .float kh_droptime;
  23
  24 string kh_sound_capture = "sound/ctf/capture.wav";
  25 string kh_sound_destroy = "sound/ctf/return.wav";
  26 string kh_sound_drop = "sound/misc/mouseclick.wav";
  27 string kh_sound_collect = "sound/ctf/take.wav";
  28
  29 float kh_sprite_dropped, kh_sprite_finish, kh_sprite_red, kh_sprite_blue, kh_sprite_pink, kh_sprite_yellow, kh_sprite_friend;
  30
  31 float kh_GetCarrierSprite(float t, float e)
  32 {
  33         if(t == e)           return kh_sprite_friend;
  34         if(t == COLOR_TEAM1) return kh_sprite_red;
  35         if(t == COLOR_TEAM2) return kh_sprite_blue;
  36         if(t == COLOR_TEAM3) return kh_sprite_yellow;
  37         if(t == COLOR_TEAM4) return kh_sprite_pink;
  38         return 0;
  39 }
  40
  41 void kh_Controller_SetThink(float t, string msg, kh_Think_t func)
  42 {
  43         kh_Controller_Thinkfunc = func;
  44         kh_controller.cnt = t;
  45         if(kh_Controller_Waitmsg != "")
  46                 strunzone(kh_Controller_Waitmsg);
  47         if(msg == "")
  48                 kh_Controller_Waitmsg = "";
  49         else
  50                 kh_Controller_Waitmsg = strzone(msg);
  51         if(t == 0)
  52                 kh_controller.nextthink = time; // force
  53 }
  54
  55 void kh_Controller_Think()
  56 {
  57         entity e;
  58         if(intermission_running)
  59                 return;
  60         if(self.cnt > 0)
  61         {
  62                 if(kh_Controller_Waitmsg != "")
  63                 {
  64                         string s;
  65                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
  66                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
  67                         else
  68                                 s = kh_Controller_Waitmsg;
  69
  70                         dprint(s, "\n");
  71
  72                         FOR_EACH_PLAYER(e)
  73                                 if(clienttype(e) == CLIENTTYPE_REAL)
  74                                         centerprint_atprio(e, CENTERPRIO_SPAM, s);
  75                 }
  76                 self.cnt -= 1;
  77         }
  78         else if(self.cnt == 0)
  79         {
  80                 self.cnt -= 1;
  81                 kh_Controller_Thinkfunc();
  82         }
  83         self.nextthink = time + 1;
  84 }
  85
  86 void kh_Log()
  87 {
  88         string s;
  89         if(!cvar("sv_eventlog"))
  90                 return;
  91         // TODO ...
  92         GameLogEcho(s, FALSE);
  93 }
  94
  95 // frags f: take from cvar * f
  96 // frags 0: no frags
  97 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)
  98 {
  99         float basefrags;
 100         basefrags = cvar(strcat("g_balance_keyhunt_score_", what));
 101
 102         if(frags_player)
 103                 player.frags = player.frags + floor(0.5 + basefrags * frags_player);
 104         if(frags_owner)
 105                 key.owner.frags = key.owner.frags + floor(0.5 + basefrags * frags_owner);
 106 }
 107
 108 void kh_Key_Attach(entity key)
 109 {
 110         setattachment(key, key.owner, "");
 111         setorigin(key, '0 0 -15'); // x/y fixed later in think, z has to be -15 to make the key fit even in the crouchbox
 112         key.angles_y -= key.owner.angles_y;
 113         key.flags = 0;
 114         key.solid = SOLID_NOT;
 115         key.movetype = MOVETYPE_NONE;
 116         key.team = key.owner.team;
 117         key.nextthink = time;
 118         key.damageforcescale = 0;
 119 }
 120
 121 vector kh_AttachedOrigin(entity e)
 122 {
 123         if(e.tag_entity)
 124         {
 125                 makevectors(e.tag_entity.angles);
 126                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 127         }
 128         else
 129                 return e.origin;
 130 }
 131
 132 void kh_Key_Detach(entity key)
 133 {
 134         setorigin(key, key.owner.origin + key.origin_z * '0 0 1');
 135         setattachment(key, world, "");
 136         key.angles_y += key.owner.angles_y;
 137         key.aiment = world;
 138         key.flags = FL_ITEM;
 139         key.solid = SOLID_TRIGGER;
 140         key.movetype = MOVETYPE_TOSS;
 141         key.pain_finished = time + cvar("g_balance_keyhunt_delay_return");
 142         key.damageforcescale = cvar("g_balance_keyhunt_damageforcescale");
 143         // let key.team stay
 144 }
 145
 146 void kh_Key_AssignTo(entity key, entity player)
 147 {
 148         if(key.owner == player)
 149                 return;
 150
 151         if(key.owner)
 152         {
 153                 kh_Key_Detach(key);
 154
 155                 // remove from linked list
 156                 if(key.kh_next)
 157                         key.kh_next.kh_prev = key.kh_prev;
 158                 key.kh_prev.kh_next = key.kh_next;
 159                 key.kh_next = world;
 160                 key.kh_prev = world;
 161
 162                 if(key.owner.kh_next == world)
 163                 {
 164                         // No longer a key carrier
 165                         WaypointSprite_DetachCarrier(key.owner);
 166                 }
 167         }
 168
 169         key.owner = player;
 170
 171         if(player)
 172         {
 173                 // insert into linked list
 174                 key.kh_next = player.kh_next;
 175                 key.kh_prev = player;
 176                 player.kh_next = key;
 177                 if(key.kh_next)
 178                         key.kh_next.kh_prev = key;
 179
 180                 kh_Key_Attach(key);
 181
 182                 if(key.kh_next == world)
 183                 {
 184                         // player is now a key carrier
 185                         WaypointSprite_AttachCarrier("", player);
 186                         player.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_KeyCarrier_waypointsprite_for_player;
 187                         player.waypointsprite_attachedforcarrier.team = player.team;
 188                 }
 189         }
 190
 191         key.pusher = world;
 192 }
 193
 194 void kh_Key_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 195 {
 196         if(self.owner)
 197                 return;
 198         if(vlen(force) <= 0)
 199                 return;
 200         if(time > self.pushltime)
 201                 if(attacker.classname == "player")
 202                         self.team = attacker.team;
 203 }
 204
 205 void kh_Key_Spawn(entity initial_owner, float angle)
 206 {
 207         entity key;
 208         key = spawn();
 209         key.classname = STR_ITEM_KH_KEY;
 210         key.touch = kh_Key_Touch;
 211         key.think = kh_Key_Think;
 212         key.nextthink = time;
 213         key.items = IT_KEY1 | IT_KEY2;
 214         key.cnt = angle;
 215         key.angles = '0 360 0' * random();
 216         key.event_damage = kh_Key_Damage;
 217         setmodel(key, "models/keyhunt/key.md3");
 218         setsize(key, '-8 -8 -8', '8 8 40');
 219
 220         switch(initial_owner.team)
 221         {
 222                 case COLOR_TEAM1:
 223                         key.netname = "^1red key";
 224                         key.colormod = '103 0 0' * (1/96);
 225                         break;
 226                 case COLOR_TEAM2:
 227                         key.netname = "^4blue key";
 228                         key.colormod = '35 35 191' * (1/96);
 229                         break;
 230                 case COLOR_TEAM3:
 231                         key.netname = "^3yellow key";
 232                         key.colormod = '187 167 15' * (1/96);
 233                         break;
 234                 case COLOR_TEAM4:
 235                         key.netname = "^6pink key";
 236                         key.colormod = '139 79 107' * (1/96);
 237                         break;
 238                 default:
 239                         key.netname = "NETGIER key";
 240                         key.colormod = '1 1 1';
 241                         break;
 242         }
 243
 244         sprint(initial_owner, strcat("You got the ^2", key.netname, "\n"));
 245
 246         WaypointSprite_AttachCarrier("", key);
 247         key.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_Key_waypointsprite_for_player;
 248
 249         kh_Key_AssignTo(key, initial_owner);
 250 }
 251
 252 void kh_Key_Remove(entity key)
 253 {
 254         entity o;
 255         o = key.owner;
 256         kh_Key_AssignTo(key, world);
 257         if(o) // it was attached
 258                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 259         else // it was dropped
 260                 WaypointSprite_DetachCarrier(key);
 261
 262         remove(key);
 263 }
 264
 265 // -1 when no team completely owns all keys yet
 266 float kh_Key_AllOwnedByWhichTeam()
 267 {
 268         entity key;
 269         float teem;
 270
 271         teem = -1;
 272         FOR_EACH_KH_KEY(key)
 273         {
 274                 if(!key.owner)
 275                         return -1;
 276                 if(teem == -1)
 277                         teem = key.team;
 278                 else if(teem != key.team)
 279                         return -1;
 280         }
 281         return teem;
 282 }
 283
 284 void kh_Key_Collect(entity key, entity player)
 285 {
 286         sound(key, CHAN_AUTO, kh_sound_collect, 1, ATTN_NORM);
 287
 288         kh_Scores_Event(player, key, "collect", 1, 0);
 289         bprint(player.netname, "^7 collected the ", key.netname, "\n");
 290         kh_Key_AssignTo(key, player);
 291
 292         if(kh_Key_AllOwnedByWhichTeam() != -1)
 293         {
 294                 kh_interferemsg_time = time + 0.2;
 295                 kh_interferemsg_team = player.team;
 296         }
 297 }
 298
 299 void kh_Key_DropAll(entity player)
 300 {
 301         entity key;
 302         entity mypusher;
 303         if(player.kh_next)
 304         {
 305                 mypusher = world;
 306                 if(player.pusher)
 307                         if(time < player.pushltime)
 308                                 mypusher = player.pusher;
 309                 while((key = player.kh_next))
 310                 {
 311                         kh_Scores_Event(player, key, "losekey", 0, 0);
 312                         bprint(player.netname, "^7 lost the ", key.netname, "\n");
 313                         kh_Key_AssignTo(key, world);
 314                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 315                         key.velocity = W_CalculateProjectileVelocity(player.velocity, cvar("g_balance_keyhunt_dropvelocity") * v_forward);
 316                         key.pusher = mypusher;
 317                         key.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 318                 }
 319                 sound(player, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 320         }
 321 }
 322
 323 void kh_Key_Touch()
 324 {
 325         if(self.owner) // already carried
 326                 return;
 327         if(other.classname != "player")
 328                 return;
 329         if(other.deadflag != DEAD_NO)
 330                 return;
 331         if(other == self.enemy)
 332                 if(time < self.kh_droptime + cvar("g_balance_keyhunt_delay_collect"))
 333                         return; // you just dropped it!
 334         kh_Key_Collect(self, other);
 335 }
 336
 337 void kh_Key_Think()
 338 {
 339         entity head;
 340
 341         //self.angles_y = math_mod(self.angles_y + 0.05 * 135, 360);
 342         // model is EF_ROTATING now
 343
 344         if(self.owner)
 345         {
 346                 makevectors('0 1 0' * (self.cnt + math_mod(time, 360) * 45));
 347                 setorigin(self, v_forward * 24 + '0 0 1' * self.origin_z);
 348
 349                 if(self.owner.buttonuse)
 350                 if(time >= self.owner.kh_droptime + cvar("g_balance_keyhunt_delay_drop"))
 351                 {
 352                         self.owner.kh_droptime = time;
 353                         self.kh_droptime = time; // prevent collecting this one for some time
 354                         self.enemy = self.owner;
 355                         self.pusher = world;
 356                         kh_Scores_Event(self.owner, self, "dropkey", 0, 0);
 357                         bprint(self.owner.netname, "^7 dropped the ", self.netname, "\n");
 358                         sound(self.owner, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 359                         makevectors(self.owner.v_angle);
 360                         self.velocity = W_CalculateProjectileVelocity(self.owner.velocity, cvar("g_balance_keyhunt_throwvelocity") * v_forward);
 361                         kh_Key_AssignTo(self, world);
 362                         self.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 363                 }
 364         }
 365
 366         // if in nodrop or time over, end the round
 367         if(!self.owner)
 368                 if(time > self.pain_finished)
 369                         kh_LoserTeam(self.team, self);
 370
 371         if(self.owner)
 372         if(kh_Key_AllOwnedByWhichTeam() != -1)
 373         {
 374                 entity key;
 375                 vector p;
 376                 p = self.owner.origin;
 377                 FOR_EACH_KH_KEY(key)
 378                         if(vlen(key.owner.origin - p) > cvar("g_balance_keyhunt_maxdist"))
 379                                 goto not_winning;
 380                 kh_WinnerTeam(self.team);
 381 :not_winning
 382         }
 383
 384         if(kh_interferemsg_time && time > kh_interferemsg_time)
 385         {
 386                 kh_interferemsg_time = 0;
 387                 FOR_EACH_PLAYER(head)
 388                 {
 389                         if(head.team == kh_interferemsg_team)
 390                                 if(head.kh_next)
 391                                         centerprint(head, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!\n");
 392                                 else
 393                                         centerprint(head, "All keys are in your team's hands!\n\nHelp the key carriers to meet!\n");
 394                         else
 395                                 centerprint(head, "All keys are in the enemy's hands!\n\nInterfere ^1NOW^7!\n");
 396                 }
 397         }
 398
 399         self.nextthink = time + 0.05;
 400 }
 401
 402 void kh_WinnerTeam(float teem)
 403 {
 404         // all key carriers get some points
 405         vector firstorigin, lastorigin;
 406         float first;
 407         entity key;
 408         float score;
 409         score = (kh_teams - 1) / kh_teams;
 410         // twice the score for 3 team games, three times the score for 4 team games!
 411         // note: for a win by destroying the key, this should NOT be applied
 412         first = TRUE;
 413         FOR_EACH_KH_KEY(key)
 414         {
 415                 kh_Scores_Event(key.owner, key, "capture", score, 0);
 416                 if(key.owner.kh_next == key)
 417                 {
 418                         if(!first)
 419                                 bprint("^7, ");
 420                         bprint(key.owner.netname);
 421                         first = FALSE;
 422                 }
 423         }
 424
 425         first = TRUE;
 426         FOR_EACH_KH_KEY(key)
 427         {
 428                 vector thisorigin;
 429
 430                 thisorigin = kh_AttachedOrigin(key);
 431
 432                 if(!first)
 433                         te_lightning2(world, lastorigin, thisorigin);
 434                 lastorigin = thisorigin;
 435                 if(first)
 436                         firstorigin = thisorigin;
 437                 first = FALSE;
 438         }
 439         if(kh_teams > 2)
 440         {
 441                 te_lightning2(world, lastorigin, firstorigin);
 442         }
 443
 444         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 445         sound(world, CHAN_AUTO, kh_sound_capture, 1, ATTN_NONE);
 446         kh_FinishRound();
 447 }
 448
 449 void kh_LoserTeam(float teem, entity lostkey)
 450 {
 451         entity player, key, attacker;
 452         float players;
 453         float keys;
 454         float score;
 455
 456         attacker = world;
 457         if(lostkey.pusher)
 458                 if(lostkey.pusher.team != teem)
 459                         if(lostkey.pusher.classname == "player")
 460                                 attacker = lostkey.pusher;
 461
 462         players = keys = 0;
 463
 464         if(attacker)
 465         {
 466                 kh_Scores_Event(attacker, world, "push", 1, 0);
 467                 centerprint(attacker, "Your push is the best!\n\n\n");
 468                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 469         }
 470         else
 471         {
 472                 FOR_EACH_PLAYER(player)
 473                         if(player.team != teem)
 474                                 ++players;
 475
 476                 FOR_EACH_KH_KEY(key)
 477                         if(key.owner && key.team != teem)
 478                                 ++keys;
 479
 480                 score = 1.0 / max(1, keys * cvar("g_balance_keyhunt_score_destroyed_ownfactor") + players);
 481
 482                 FOR_EACH_PLAYER(player)
 483                         if(player.team != teem)
 484                                 kh_Scores_Event(player, world, "destroyed", score, 0);
 485
 486                 FOR_EACH_KH_KEY(key)
 487                         if(key.owner && key.team != teem)
 488                                 kh_Scores_Event(key.owner, world, "destroyed", score * cvar("g_balance_keyhunt_score_destroyed_ownfactor"), 0);
 489
 490                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 491         }
 492         sound(world, CHAN_AUTO, kh_sound_destroy, 1, ATTN_NONE);
 493
 494         kh_FinishRound();
 495 }
 496
 497 void kh_FinishRound()
 498 {
 499         // prepare next round
 500         kh_interferemsg_time = 0;
 501         entity key;
 502         FOR_EACH_KH_KEY(key)
 503                 kh_Key_Remove(key);
 504
 505         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 506 }
 507
 508 float kh_EnoughPlayers()
 509 {
 510         float i, players, teem;
 511         entity player;
 512
 513         // find a random player per team
 514         for(i = 0; i < kh_teams; ++i)
 515         {
 516                 teem = kh_Team_ByID(i);
 517                 players = 0;
 518                 FOR_EACH_PLAYER(player)
 519                         if(player.deadflag == DEAD_NO)
 520                                 if(player.team == teem)
 521                                         ++players;
 522                 if(players == 0)
 523                         return FALSE;
 524         }
 525         return TRUE;
 526 }
 527
 528 void kh_WaitForPlayers()
 529 {
 530         if(kh_EnoughPlayers())
 531                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 532         else
 533                 kh_Controller_SetThink(1, "Waiting for players to join...", kh_WaitForPlayers);
 534 }
 535
 536 void kh_StartRound()
 537 {
 538         float i, players, teem;
 539         entity player;
 540
 541         if(!kh_EnoughPlayers())
 542         {
 543                 kh_Controller_SetThink(1, "Waiting for players to join...", kh_WaitForPlayers);
 544                 return;
 545         }
 546
 547         FOR_EACH_PLAYER(player)
 548                 if(clienttype(player) == CLIENTTYPE_REAL)
 549                         centerprint_expire(player, CENTERPRIO_SPAM);
 550
 551         for(i = 0; i < kh_teams; ++i)
 552         {
 553                 teem = kh_Team_ByID(i);
 554                 players = 0;
 555                 entity my_player;
 556                 FOR_EACH_PLAYER(player)
 557                         if(player.deadflag == DEAD_NO)
 558                                 if(player.team == teem)
 559                                 {
 560                                         ++players;
 561                                         if(random() * players <= 1)
 562                                                 my_player = player;
 563                                 }
 564                 kh_Key_Spawn(my_player, 360 * i / kh_teams);
 565         }
 566
 567         kh_tracking_enabled = FALSE;
 568         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_tracking"), "Scanning frequency range...", kh_EnableTrackingDevice);
 569 }
 570
 571 void kh_setstatus()
 572 {
 573         if(kh_teams)
 574         {
 575                 float kh_KEY;
 576                 kh_KEY = (IT_RED_FLAG_TAKEN | IT_RED_FLAG_LOST | IT_BLUE_FLAG_TAKEN | IT_BLUE_FLAG_LOST); // the one impossible combination
 577                 if(self.kh_next)
 578                         self.items = self.items | kh_KEY;
 579                 else
 580                         self.items = self.items - (self.items & kh_KEY);
 581         }
 582 }
 583
 584 void kh_EnableTrackingDevice()
 585 {
 586         entity player;
 587
 588         FOR_EACH_PLAYER(player)
 589                 if(clienttype(player) == CLIENTTYPE_REAL)
 590                         centerprint_expire(player, CENTERPRIO_SPAM);
 591
 592         kh_tracking_enabled = TRUE;
 593 }
 594
 595 float kh_Key_waypointsprite_for_player(entity e)
 596 {
 597         if(!kh_tracking_enabled)
 598                 return 0;
 599         if(!self.owner)
 600                 return kh_sprite_dropped;
 601         if(!self.owner.owner)
 602                 return kh_sprite_dropped;
 603         return 0; // draw only when key is not owned
 604 }
 605
 606 float kh_KeyCarrier_waypointsprite_for_player(entity e)
 607 {
 608         if(e.classname != "player" || self.team != e.team)
 609                 if(!kh_tracking_enabled)
 610                         return 0;
 611
 612         // e is spectator? That's no team mate...
 613         if(e.classname != "player")
 614                 return kh_GetCarrierSprite(self.team, -1);
 615
 616         // e is no key carrier: simple case...
 617         if(!e.kh_next)
 618                 return kh_GetCarrierSprite(self.team, e.team);
 619
 620         // e is a key carrier: if any key is dropped or owned by another team, show
 621         // the carrier sprite; otherwise show run here
 622         if(kh_Key_AllOwnedByWhichTeam() == e.team)
 623                 return kh_sprite_finish;
 624
 625         return kh_GetCarrierSprite(self.team, e.team);
 626 }
 627
 628 float kh_HandleFrags(entity attacker, entity targ, float f)
 629 {
 630         float newfrags;
 631
 632         if(f <= 0)
 633                 return f;
 634         if(attacker == targ)
 635                 return f;
 636
 637         if(targ.kh_next)
 638                 f = f - 1 + cvar("g_balance_keyhunt_score_carrierfrag");
 639
 640         if(newfrags)
 641                 f = f - 1 + newfrags;
 642         return f;
 643 }
 644
 645 void kh_init()
 646 {
 647         precache_sound(kh_sound_capture);
 648         precache_sound(kh_sound_destroy);
 649         precache_sound(kh_sound_drop);
 650         precache_sound(kh_sound_collect);
 651
 652         precache_model("models/sprites/key-dropped.sp2");
 653         precache_model("models/sprites/keycarrier-finish.sp2");
 654         precache_model("models/sprites/keycarrier-friend.sp2");
 655         precache_model("models/sprites/keycarrier-red.sp2");
 656         precache_model("models/sprites/keycarrier-blue.sp2");
 657         precache_model("models/sprites/keycarrier-yellow.sp2");
 658         precache_model("models/sprites/keycarrier-pink.sp2");
 659         precache_model("models/keyhunt/key.md3");
 660
 661         // setup variables
 662         kh_teams = cvar("g_keyhunt_teams_override");
 663         if(kh_teams < 2)
 664                 kh_teams = cvar("g_keyhunt_teams");
 665         kh_teams = bound(2, kh_teams, 4);
 666
 667         // make a KH entity for controlling the game
 668         kh_controller = spawn();
 669         kh_controller.think = kh_Controller_Think;
 670         kh_Controller_SetThink(0, "", kh_WaitForPlayers);
 671
 672         setmodel(kh_controller, "models/sprites/key-dropped.sp2");
 673         kh_sprite_dropped = kh_controller.modelindex;
 674         setmodel(kh_controller, "models/sprites/keycarrier-finish.sp2");
 675         kh_sprite_finish = kh_controller.modelindex;
 676         setmodel(kh_controller, "models/sprites/keycarrier-friend.sp2");
 677         kh_sprite_friend = kh_controller.modelindex;
 678         setmodel(kh_controller, "models/sprites/keycarrier-red.sp2");
 679         kh_sprite_red = kh_controller.modelindex;
 680         setmodel(kh_controller, "models/sprites/keycarrier-blue.sp2");
 681         kh_sprite_blue = kh_controller.modelindex;
 682         setmodel(kh_controller, "models/sprites/keycarrier-pink.sp2");
 683         kh_sprite_pink = kh_controller.modelindex;
 684         setmodel(kh_controller, "models/sprites/keycarrier-yellow.sp2");
 685         kh_sprite_yellow = kh_controller.modelindex;
 686         setmodel(kh_controller, "");
 687 }
 688
 689 void kh_finalize()
 690 {
 691         // to be called before intermission
 692         kh_FinishRound();
 693         remove(kh_controller);
 694         kh_controller = world;
 695 }