data/qcsrc/server/keyhunt.qc

   1 string STR_ITEM_KH_KEY = "item_kh_key";
   2 #define FOR_EACH_KH_KEY(v) for(v = world; (v = find(v, classname, STR_ITEM_KH_KEY)); )
   3
   4 // #define KH_PLAYER_USE_ATTACHMENT
   5 // #define KH_PLAYER_USE_CARRIEDMODEL
   6 // #define KH_KEY_ATTACHMENT_DEBUG
   7
   8 #ifdef KH_PLAYER_USE_ATTACHMENT
   9 vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
  10 vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
  11 vector KH_PLAYER_ATTACHMENT = '0 0 0';
  12 vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  13 string KH_PLAYER_ATTACHMENT_BONE = "";
  14 #else
  15 float KH_KEY_ZSHIFT = 22;
  16 float KH_KEY_XYDIST = 24;
  17 float KH_KEY_XYSPEED = 45;
  18 #endif
  19 float KH_KEY_WP_ZSHIFT = 20;
  20
  21 vector KH_KEY_MIN = '-10 -10 -46';
  22 vector KH_KEY_MAX = '10 10 3';
  23 float KH_KEY_BRIGHTNESS = 4;
  24
  25 typedef void(void) kh_Think_t;
  26 var kh_Think_t kh_Controller_Thinkfunc;
  27 string kh_Controller_Waitmsg;
  28
  29 float kh_Team_ByID(float t)
  30 {
  31         if(t == 0) return COLOR_TEAM1;
  32         if(t == 1) return COLOR_TEAM2;
  33         if(t == 2) return COLOR_TEAM3;
  34         if(t == 3) return COLOR_TEAM4;
  35         return 0;
  36 }
  37
  38 entity kh_controller;
  39 float kh_tracking_enabled;
  40 float kh_teams;
  41 float kh_interferemsg_time, kh_interferemsg_team;
  42 .entity kh_next, kh_prev; // linked list
  43 .float kh_droptime;
  44 .float kh_dropperteam;
  45 .entity kh_previous_owner;
  46
  47 string kh_sound_capture = "sound/kh/capture.wav";
  48 string kh_sound_destroy = "sound/kh/destroy.wav";
  49 string kh_sound_drop = "sound/kh/drop.wav";
  50 string kh_sound_collect = "sound/kh/collect.wav";
  51
  52 float kh_sprite_dropped, kh_sprite_finish, kh_sprite_red, kh_sprite_blue, kh_sprite_pink, kh_sprite_yellow, kh_sprite_friend;
  53 float kh_key_dropped, kh_key_carried;
  54
  55 float kh_GetCarrierSprite(float t, float e)
  56 {
  57         if(t == e)           return kh_sprite_friend;
  58         if(t == COLOR_TEAM1) return kh_sprite_red;
  59         if(t == COLOR_TEAM2) return kh_sprite_blue;
  60         if(t == COLOR_TEAM3) return kh_sprite_yellow;
  61         if(t == COLOR_TEAM4) return kh_sprite_pink;
  62         return 0;
  63 }
  64
  65 void kh_Controller_SetThink(float t, string msg, kh_Think_t func)
  66 {
  67         kh_Controller_Thinkfunc = func;
  68         kh_controller.cnt = t;
  69         if(kh_Controller_Waitmsg != "")
  70                 strunzone(kh_Controller_Waitmsg);
  71         if(msg == "")
  72                 kh_Controller_Waitmsg = "";
  73         else
  74                 kh_Controller_Waitmsg = strzone(msg);
  75         if(t == 0)
  76                 kh_controller.nextthink = time; // force
  77 }
  78
  79 void kh_Controller_Think()
  80 {
  81         entity e;
  82         if(intermission_running)
  83                 return;
  84         if(self.cnt > 0)
  85         {
  86                 if(kh_Controller_Waitmsg != "")
  87                 {
  88                         string s;
  89                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
  90                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
  91                         else
  92                                 s = kh_Controller_Waitmsg;
  93
  94                         //dprint(s, "\n");
  95
  96                         FOR_EACH_PLAYER(e)
  97                                 if(clienttype(e) == CLIENTTYPE_REAL)
  98                                         centerprint_atprio(e, CENTERPRIO_SPAM, s);
  99                 }
 100                 self.cnt -= 1;
 101         }
 102         else if(self.cnt == 0)
 103         {
 104                 self.cnt -= 1;
 105                 kh_Controller_Thinkfunc();
 106         }
 107         self.nextthink = time + 1;
 108 }
 109
 110 // frags f: take from cvar * f
 111 // frags 0: no frags
 112 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)
 113 {
 114         string s;
 115         if(intermission_running)
 116                 return;
 117         if(frags_player)
 118                 UpdateFrags(player, frags_player);
 119         if(key && key.owner && frags_owner)
 120                 UpdateFrags(key.owner, frags_owner);
 121         if(!cvar("sv_eventlog"))
 122                 return;
 123         s = strcat(":keyhunt:", what, ":", ftos(player.playerid));
 124         s = strcat(s, ":", ftos(frags_player));
 125         if(key && key.owner)
 126                 s = strcat(s, ":", ftos(key.owner.playerid));
 127         else
 128                 s = strcat(s, ":0");
 129         s = strcat(s, ":", ftos(frags_owner), ":");
 130         if(key)
 131                 s = strcat(s, key.netname);
 132         GameLogEcho(s, FALSE);
 133 }
 134
 135 vector kh_AttachedOrigin(entity e)
 136 {
 137         if(e.tag_entity)
 138         {
 139                 makevectors(e.tag_entity.angles);
 140                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 141         }
 142         else
 143                 return e.origin;
 144 }
 145
 146 void kh_Key_Attach(entity key)
 147 {
 148 #ifdef KH_PLAYER_USE_ATTACHMENT
 149         entity first;
 150         first = key.owner.kh_next;
 151         if(key == first)
 152         {
 153                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 154                 if(key.kh_next)
 155                 {
 156                         setattachment(key.kh_next, key, "");
 157                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 158                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 159                         key.kh_next.angles = '0 0 0';
 160                 }
 161                 else
 162                         setorigin(key, KH_PLAYER_ATTACHMENT);
 163                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 164         }
 165         else
 166         {
 167                 setattachment(key, key.kh_prev, "");
 168                 if(key.kh_next)
 169                         setattachment(key.kh_next, key, "");
 170                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 171                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 172                 key.angles = '0 0 0';
 173         }
 174 #else
 175         setattachment(key, key.owner, "");
 176         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT); // fixing x, y in think
 177         key.angles_y -= key.owner.angles_y;
 178 #endif
 179         key.flags = 0;
 180         key.solid = SOLID_NOT;
 181         key.movetype = MOVETYPE_NONE;
 182         key.team = key.owner.team;
 183         key.nextthink = time;
 184         key.damageforcescale = 0;
 185         key.modelindex = kh_key_carried;
 186 }
 187
 188 void kh_Key_Detach(entity key)
 189 {
 190 #ifdef KH_PLAYER_USE_ATTACHMENT
 191         entity first;
 192         first = key.owner.kh_next;
 193         if(key == first)
 194         {
 195                 if(key.kh_next)
 196                 {
 197                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 198                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 199                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 200                 }
 201         }
 202         else
 203         {
 204                 if(key.kh_next)
 205                         setattachment(key.kh_next, key.kh_prev, "");
 206                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 207         }
 208         // in any case:
 209         setattachment(key, world, "");
 210         setorigin(key, key.owner.origin + '0 0 1' * (PL_MIN_z - KH_KEY_MIN_z));
 211         key.angles = key.owner.angles;
 212 #else
 213         setorigin(key, key.owner.origin + key.origin_z * '0 0 1');
 214         setattachment(key, world, "");
 215         key.angles_y += key.owner.angles_y;
 216 #endif
 217         key.aiment = world;
 218         key.flags = FL_ITEM;
 219         key.solid = SOLID_TRIGGER;
 220         key.movetype = MOVETYPE_TOSS;
 221         key.pain_finished = time + cvar("g_balance_keyhunt_delay_return");
 222         key.damageforcescale = cvar("g_balance_keyhunt_damageforcescale");
 223         // let key.team stay
 224         key.modelindex = kh_key_dropped;
 225         key.kh_previous_owner = key.owner;
 226 }
 227
 228 void kh_Key_AssignTo(entity key, entity player)
 229 {
 230         if(key.owner == player)
 231                 return;
 232
 233         if(key.owner)
 234         {
 235                 kh_Key_Detach(key);
 236
 237                 // remove from linked list
 238                 if(key.kh_next)
 239                         key.kh_next.kh_prev = key.kh_prev;
 240                 key.kh_prev.kh_next = key.kh_next;
 241                 key.kh_next = world;
 242                 key.kh_prev = world;
 243
 244                 if(key.owner.kh_next == world)
 245                 {
 246                         // No longer a key carrier
 247                         WaypointSprite_DetachCarrier(key.owner);
 248                 }
 249         }
 250
 251         key.owner = player;
 252
 253         if(player)
 254         {
 255                 // insert into linked list
 256                 key.kh_next = player.kh_next;
 257                 key.kh_prev = player;
 258                 player.kh_next = key;
 259                 if(key.kh_next)
 260                         key.kh_next.kh_prev = key;
 261
 262                 kh_Key_Attach(key);
 263
 264                 if(key.kh_next == world)
 265                 {
 266                         // player is now a key carrier
 267                         WaypointSprite_AttachCarrier("", player);
 268                         player.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_KeyCarrier_waypointsprite_for_player;
 269                         player.waypointsprite_attachedforcarrier.team = player.team;
 270                 }
 271         }
 272
 273         key.pusher = world;
 274 }
 275
 276 void kh_Key_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 277 {
 278         if(self.owner)
 279                 return;
 280         if(vlen(force) <= 0)
 281                 return;
 282         if(time > self.pushltime)
 283                 if(attacker.classname == "player")
 284                         self.team = attacker.team;
 285 }
 286
 287 vector kh_TeamColor(float teem)
 288 {
 289         switch(teem)
 290         {
 291                 case COLOR_TEAM1:
 292                         //return '103 0 0' / 255.0;
 293                         return '0.4039 0.0000 0.0000';
 294                 case COLOR_TEAM2:
 295                         //return '35 35 191' / 255.0;
 296                         return '0.1373 0.1373 0.7490';
 297                 case COLOR_TEAM3:
 298                         //return '187 167 15' / 255.0;
 299                         return '0.7333 0.6549 0.0588';
 300                 case COLOR_TEAM4:
 301                         //return '139 79 107' / 255.0;
 302                         return '0.5451 0.3099 0.4196';
 303                 default:
 304                         return '1 1 1';
 305         }
 306 }
 307
 308 void kh_Key_Spawn(entity initial_owner, float angle)
 309 {
 310         entity key;
 311         key = spawn();
 312         key.classname = STR_ITEM_KH_KEY;
 313         key.touch = kh_Key_Touch;
 314         key.think = kh_Key_Think;
 315         key.nextthink = time;
 316         key.items = IT_KEY1 | IT_KEY2;
 317         key.cnt = angle;
 318         key.angles = '0 360 0' * random();
 319         key.event_damage = kh_Key_Damage;
 320         key.modelindex = kh_key_dropped;
 321         key.model = "key";
 322         key.kh_dropperteam = 0;
 323         key.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 324         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 325         key.colormod = kh_TeamColor(initial_owner.team) * KH_KEY_BRIGHTNESS;
 326
 327         switch(initial_owner.team)
 328         {
 329                 case COLOR_TEAM1:
 330                         key.netname = "^1red key";
 331                         break;
 332                 case COLOR_TEAM2:
 333                         key.netname = "^4blue key";
 334                         break;
 335                 case COLOR_TEAM3:
 336                         key.netname = "^3yellow key";
 337                         break;
 338                 case COLOR_TEAM4:
 339                         key.netname = "^6pink key";
 340                         break;
 341                 default:
 342                         key.netname = "NETGIER key";
 343                         break;
 344         }
 345
 346         sprint(initial_owner, strcat("You got the ^2", key.netname, "\n"));
 347
 348         WaypointSprite_Spawn("", 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, world, key.team, key, waypointsprite_attachedforcarrier, FALSE);
 349         key.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_Key_waypointsprite_for_player;
 350
 351         kh_Key_AssignTo(key, initial_owner);
 352 }
 353
 354 void kh_Key_Remove(entity key)
 355 {
 356         entity o;
 357         o = key.owner;
 358         kh_Key_AssignTo(key, world);
 359         if(o) // it was attached
 360                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 361         else // it was dropped
 362                 WaypointSprite_DetachCarrier(key);
 363
 364         remove(key);
 365 }
 366
 367 // -1 when no team completely owns all keys yet
 368 float kh_Key_AllOwnedByWhichTeam()
 369 {
 370         entity key;
 371         float teem;
 372
 373         teem = -1;
 374         FOR_EACH_KH_KEY(key)
 375         {
 376                 if(!key.owner)
 377                         return -1;
 378                 if(teem == -1)
 379                         teem = key.team;
 380                 else if(teem != key.team)
 381                         return -1;
 382         }
 383         return teem;
 384 }
 385
 386 void kh_Key_Collect(entity key, entity player)
 387 {
 388         sound(player, CHAN_AUTO, kh_sound_collect, 1, ATTN_NORM);
 389
 390         if(key.kh_dropperteam != player.team)
 391                 kh_Scores_Event(player, key, "collect", cvar("g_balance_keyhunt_score_collect"), 0);
 392         key.kh_dropperteam = 0;
 393         bprint(player.netname, "^7 collected the ", key.netname, "\n");
 394         kh_Key_AssignTo(key, player);
 395
 396         if(kh_Key_AllOwnedByWhichTeam() != -1)
 397         {
 398                 kh_interferemsg_time = time + 0.2;
 399                 kh_interferemsg_team = player.team;
 400         }
 401 }
 402
 403 void kh_Key_DropAll(entity player, float suicide)
 404 {
 405         entity key;
 406         entity mypusher;
 407         if(player.kh_next)
 408         {
 409                 mypusher = world;
 410                 if(player.pusher)
 411                         if(time < player.pushltime)
 412                                 mypusher = player.pusher;
 413                 while((key = player.kh_next))
 414                 {
 415                         kh_Scores_Event(player, key, "losekey", 0, 0);
 416                         bprint(player.netname, "^7 lost the ", key.netname, "\n");
 417                         kh_Key_AssignTo(key, world);
 418                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 419                         key.velocity = W_CalculateProjectileVelocity(player.velocity, cvar("g_balance_keyhunt_dropvelocity") * v_forward);
 420                         key.pusher = mypusher;
 421                         key.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 422                         if(suicide)
 423                                 key.kh_dropperteam = player.team;
 424                 }
 425                 sound(player, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 426         }
 427 }
 428
 429 void kh_Key_Touch()
 430 {
 431         if(intermission_running)
 432                 return;
 433
 434         if(self.owner) // already carried
 435                 return;
 436         if(other.classname != "player")
 437                 return;
 438         if(other.deadflag != DEAD_NO)
 439                 return;
 440         if(other == self.enemy)
 441                 if(time < self.kh_droptime + cvar("g_balance_keyhunt_delay_collect"))
 442                         return; // you just dropped it!
 443         kh_Key_Collect(self, other);
 444 }
 445
 446 void kh_Key_Think()
 447 {
 448         entity head;
 449
 450         if(intermission_running)
 451                 return;
 452
 453 #ifdef KH_KEY_ATTACHMENT_DEBUG
 454         if(self.kh_prev == self.owner)
 455         {
 456                 if(cvar_string("_angles") != "")
 457                 {
 458                         self.angles = stov(cvar_string("_angles"));
 459                         self.origin = stov(cvar_string("_origin"));
 460                 }
 461         }
 462 #endif
 463
 464         if(self.owner)
 465         {
 466 #ifndef KH_PLAYER_USE_ATTACHMENT
 467                 makevectors('0 1 0' * (self.cnt + math_mod(time, 360) * KH_KEY_XYSPEED));
 468                 setorigin(self, v_forward * KH_KEY_XYDIST + '0 0 1' * self.origin_z);
 469 #endif
 470
 471                 if(self.owner.buttonuse)
 472                 if(time >= self.owner.kh_droptime + cvar("g_balance_keyhunt_delay_drop"))
 473                 {
 474                         self.owner.kh_droptime = time;
 475                         self.kh_droptime = time; // prevent collecting this one for some time
 476                         self.enemy = self.owner;
 477                         self.pusher = world;
 478                         kh_Scores_Event(self.owner, self, "dropkey", 0, 0);
 479                         bprint(self.owner.netname, "^7 dropped the ", self.netname, "\n");
 480                         sound(self.owner, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 481                         makevectors(self.owner.v_angle);
 482                         self.velocity = W_CalculateProjectileVelocity(self.owner.velocity, cvar("g_balance_keyhunt_throwvelocity") * v_forward);
 483                         kh_Key_AssignTo(self, world);
 484                         self.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 485                         self.kh_dropperteam = self.team;
 486                 }
 487         }
 488
 489         // if in nodrop or time over, end the round
 490         if(!self.owner)
 491                 if(time > self.pain_finished)
 492                         kh_LoserTeam(self.team, self);
 493
 494         if(self.owner)
 495         if(kh_Key_AllOwnedByWhichTeam() != -1)
 496         {
 497                 entity key;
 498                 vector p;
 499                 p = self.owner.origin;
 500                 FOR_EACH_KH_KEY(key)
 501                         if(vlen(key.owner.origin - p) > cvar("g_balance_keyhunt_maxdist"))
 502                                 goto not_winning;
 503                 kh_WinnerTeam(self.team);
 504 :not_winning
 505         }
 506
 507         if(kh_interferemsg_time && time > kh_interferemsg_time)
 508         {
 509                 kh_interferemsg_time = 0;
 510                 FOR_EACH_PLAYER(head)
 511                 {
 512                         if(head.team == kh_interferemsg_team)
 513                                 if(head.kh_next)
 514                                         centerprint(head, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!\n");
 515                                 else
 516                                         centerprint(head, "All keys are in your team's hands!\n\nHelp the key carriers to meet!\n");
 517                         else
 518                                 centerprint(head, strcat("All keys are in the ", ColoredTeamName(kh_interferemsg_team), "^7's hands!\n\nInterfere ^1NOW^7!\n"));
 519                 }
 520         }
 521
 522         self.nextthink = time + 0.05;
 523 }
 524
 525 void kh_WinnerTeam(float teem)
 526 {
 527         // all key carriers get some points
 528         vector firstorigin, lastorigin, midpoint;
 529         float first;
 530         entity key;
 531         float score;
 532         score = (kh_teams - 1) * cvar("g_balance_keyhunt_score_capture");
 533         DistributeEvenly_Init(score, kh_teams);
 534         // twice the score for 3 team games, three times the score for 4 team games!
 535         // note: for a win by destroying the key, this should NOT be applied
 536         FOR_EACH_KH_KEY(key)
 537                 kh_Scores_Event(key.owner, key, "capture", DistributeEvenly_Get(1), 0);
 538
 539         first = TRUE;
 540         FOR_EACH_KH_KEY(key)
 541                 if(key.owner.kh_next == key)
 542                 {
 543                         if(!first)
 544                                 bprint("^7, ");
 545                         bprint(key.owner.netname);
 546                         first = FALSE;
 547                 }
 548         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 549
 550         first = TRUE;
 551         midpoint = '0 0 0';
 552         FOR_EACH_KH_KEY(key)
 553         {
 554                 vector thisorigin;
 555
 556                 thisorigin = kh_AttachedOrigin(key);
 557                 //dprint("Key origin: ", vtos(thisorigin), "\n");
 558                 midpoint += thisorigin;
 559
 560                 if(!first)
 561                         te_lightning2(world, lastorigin, thisorigin);
 562                 lastorigin = thisorigin;
 563                 if(first)
 564                         firstorigin = thisorigin;
 565                 first = FALSE;
 566         }
 567         if(kh_teams > 2)
 568         {
 569                 te_lightning2(world, lastorigin, firstorigin);
 570         }
 571         midpoint = midpoint * (1 / kh_teams);
 572         te_customflash(midpoint, 1000, 1, kh_TeamColor(teem) * 0.5 + '0.5 0.5 0.5'); // make the color >=0.5 in each component
 573
 574         sound(world, CHAN_AUTO, kh_sound_capture, 1, ATTN_NONE);
 575         kh_FinishRound();
 576 }
 577
 578 void kh_LoserTeam(float teem, entity lostkey)
 579 {
 580         entity player, key, attacker;
 581         float players;
 582         float keys;
 583
 584         attacker = world;
 585         if(lostkey.pusher)
 586                 if(lostkey.pusher.team != teem)
 587                         if(lostkey.pusher.classname == "player")
 588                                 attacker = lostkey.pusher;
 589
 590         players = keys = 0;
 591
 592         if(attacker)
 593         {
 594                 if(lostkey.kh_previous_owner)
 595                         kh_Scores_Event(lostkey.kh_previous_owner, world, "pushed", 0, -cvar("g_balance_keyhunt_score_push"));
 596                         // don't actually GIVE him the -nn points, just log
 597                 kh_Scores_Event(attacker, world, "push", cvar("g_balance_keyhunt_score_push"), 0);
 598                 centerprint(attacker, "Your push is the best!\n\n\n");
 599                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "^7 when ", attacker.netname, "^7 came\n");
 600         }
 601         else
 602         {
 603                 float of, fragsleft, i, j, thisteam;
 604                 of = cvar("g_balance_keyhunt_score_destroyed_ownfactor");
 605
 606                 FOR_EACH_PLAYER(player)
 607                         if(player.team != teem)
 608                                 ++players;
 609
 610                 FOR_EACH_KH_KEY(key)
 611                         if(key.owner && key.team != teem)
 612                                 ++keys;
 613
 614                 if(lostkey.kh_previous_owner)
 615                         kh_Scores_Event(lostkey.kh_previous_owner, world, "destroyed", 0, -cvar("g_balance_keyhunt_score_destroyed"));
 616                         // don't actually GIVE him the -nn points, just log
 617
 618                 DistributeEvenly_Init(cvar("g_balance_keyhunt_score_destroyed"), keys * of + players);
 619
 620                 FOR_EACH_KH_KEY(key)
 621                         if(key.owner && key.team != teem)
 622                                 kh_Scores_Event(key.owner, world, "destroyed_holdingkey", DistributeEvenly_Get(of), 0);
 623
 624                 fragsleft = DistributeEvenly_Get(players);
 625
 626                 // Now distribute these among all other teams...
 627                 j = kh_teams - 1;
 628                 for(i = 0; i < kh_teams; ++i)
 629                 {
 630                         thisteam = kh_Team_ByID(i);
 631                         if(thisteam == teem) // bad boy, no cookie - this WILL happen
 632                                 continue;
 633
 634                         players = 0;
 635                         FOR_EACH_PLAYER(player)
 636                                 if(player.team == thisteam)
 637                                         ++players;
 638
 639                         DistributeEvenly_Init(fragsleft, j);
 640                         fragsleft = DistributeEvenly_Get(j - 1);
 641                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 642
 643                         FOR_EACH_PLAYER(player)
 644                                 if(player.team == thisteam)
 645                                         kh_Scores_Event(player, world, "destroyed", DistributeEvenly_Get(1), 0);
 646
 647                         --j;
 648                 }
 649
 650                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 651         }
 652         sound(world, CHAN_AUTO, kh_sound_destroy, 1, ATTN_NONE);
 653         te_tarexplosion(lostkey.origin);
 654
 655         kh_FinishRound();
 656 }
 657
 658 void kh_FinishRound()
 659 {
 660         // prepare next round
 661         kh_interferemsg_time = 0;
 662         entity key;
 663         FOR_EACH_KH_KEY(key)
 664                 kh_Key_Remove(key);
 665
 666         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 667 }
 668
 669 string kh_CheckEnoughPlayers()
 670 {
 671         float i, players, teem;
 672         entity player;
 673         string result;
 674         result = "";
 675
 676         // find a random player per team
 677         for(i = 0; i < kh_teams; ++i)
 678         {
 679                 teem = kh_Team_ByID(i);
 680                 players = 0;
 681                 FOR_EACH_PLAYER(player)
 682                         if(player.deadflag == DEAD_NO)
 683                                 if(!player.buttonchat)
 684                                         if(player.team == teem)
 685                                                 ++players;
 686                 if(players == 0)
 687                 {
 688                         if(result != "")
 689                                 result = strcat(result, ", ");
 690                         result = strcat(result, ColoredTeamName(teem));
 691                 }
 692         }
 693         return result;
 694 }
 695
 696 void kh_WaitForPlayers()
 697 {
 698         string teams_missing;
 699         teams_missing = kh_CheckEnoughPlayers();
 700         if(teams_missing == "")
 701                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 702         else
 703                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 704 }
 705
 706 void kh_StartRound()
 707 {
 708         string teams_missing;
 709         float i, players, teem;
 710         entity player;
 711
 712         teams_missing = kh_CheckEnoughPlayers();
 713         if(teams_missing != "")
 714         {
 715                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 716                 return;
 717         }
 718
 719         FOR_EACH_PLAYER(player)
 720                 if(clienttype(player) == CLIENTTYPE_REAL)
 721                         centerprint_expire(player, CENTERPRIO_SPAM);
 722
 723         for(i = 0; i < kh_teams; ++i)
 724         {
 725                 teem = kh_Team_ByID(i);
 726                 players = 0;
 727                 entity my_player;
 728                 FOR_EACH_PLAYER(player)
 729                         if(player.deadflag == DEAD_NO)
 730                                 if(!player.buttonchat)
 731                                         if(player.team == teem)
 732                                         {
 733                                                 ++players;
 734                                                 if(random() * players <= 1)
 735                                                         my_player = player;
 736                                         }
 737                 kh_Key_Spawn(my_player, 360 * i / kh_teams);
 738                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 739                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 740         }
 741
 742         kh_tracking_enabled = FALSE;
 743         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_tracking"), "Scanning frequency range...", kh_EnableTrackingDevice);
 744 }
 745
 746 void kh_setstatus()
 747 {
 748         if(kh_teams)
 749         {
 750                 float kh_KEY;
 751                 kh_KEY = (IT_RED_FLAG_TAKEN | IT_RED_FLAG_LOST | IT_BLUE_FLAG_TAKEN | IT_BLUE_FLAG_LOST); // the one impossible combination
 752                 if(self.kh_next)
 753                         self.items = self.items | kh_KEY;
 754                 else
 755                         self.items = self.items - (self.items & kh_KEY);
 756         }
 757 }
 758
 759 void kh_EnableTrackingDevice()
 760 {
 761         entity player;
 762
 763         FOR_EACH_PLAYER(player)
 764                 if(clienttype(player) == CLIENTTYPE_REAL)
 765                         centerprint_expire(player, CENTERPRIO_SPAM);
 766
 767         kh_tracking_enabled = TRUE;
 768 }
 769
 770 float kh_Key_waypointsprite_for_player(entity e)
 771 {
 772         if(!kh_tracking_enabled)
 773                 return 0;
 774         if(!self.owner)
 775                 return kh_sprite_dropped;
 776         if(!self.owner.owner)
 777                 return kh_sprite_dropped;
 778         return 0; // draw only when key is not owned
 779 }
 780
 781 float kh_KeyCarrier_waypointsprite_for_player(entity e)
 782 {
 783         if(e.classname != "player" || self.team != e.team)
 784                 if(!kh_tracking_enabled)
 785                         return 0;
 786
 787         // e is spectator? That's no team mate...
 788         if(e.classname != "player")
 789                 return kh_GetCarrierSprite(self.team, -1);
 790
 791         // e is no key carrier: simple case...
 792         if(!e.kh_next)
 793                 return kh_GetCarrierSprite(self.team, e.team);
 794
 795         // e is a key carrier: if any key is dropped or owned by another team, show
 796         // the carrier sprite; otherwise show run here
 797         if(kh_Key_AllOwnedByWhichTeam() == e.team)
 798                 return kh_sprite_finish;
 799
 800         return kh_GetCarrierSprite(self.team, e.team);
 801 }
 802
 803 float kh_HandleFrags(entity attacker, entity targ, float f)
 804 {
 805         if(attacker == targ)
 806                 return f;
 807
 808         if(targ.kh_next)
 809         {
 810                 if(attacker.team == targ.team)
 811                 {
 812                         entity k;
 813                         float nk;
 814                         nk = 0;
 815                         for(k = targ.kh_next; k != world; k = k.kh_next)
 816                                 ++nk;
 817                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * cvar("g_balance_keyhunt_score_collect"), 0);
 818                 }
 819                 else
 820                 {
 821                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", cvar("g_balance_keyhunt_score_carrierfrag")-1, 0);
 822                 }
 823         }
 824
 825         return f;
 826 }
 827
 828 void kh_init()
 829 {
 830         precache_sound(kh_sound_capture);
 831         precache_sound(kh_sound_destroy);
 832         precache_sound(kh_sound_drop);
 833         precache_sound(kh_sound_collect);
 834
 835         precache_model("models/sprites/key-dropped.sp2");
 836         precache_model("models/sprites/keycarrier-finish.sp2");
 837         precache_model("models/sprites/keycarrier-friend.sp2");
 838         precache_model("models/sprites/keycarrier-red.sp2");
 839         precache_model("models/sprites/keycarrier-blue.sp2");
 840         precache_model("models/sprites/keycarrier-yellow.sp2");
 841         precache_model("models/sprites/keycarrier-pink.sp2");
 842 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 843         precache_model("models/keyhunt/key-carried.md3");
 844 #endif
 845         precache_model("models/keyhunt/key.md3");
 846
 847         // setup variables
 848         kh_teams = cvar("g_keyhunt_teams_override");
 849         if(kh_teams < 2)
 850                 kh_teams = cvar("g_keyhunt_teams");
 851         kh_teams = bound(2, kh_teams, 4);
 852
 853         // make a KH entity for controlling the game
 854         kh_controller = spawn();
 855         kh_controller.think = kh_Controller_Think;
 856         kh_Controller_SetThink(0, "", kh_WaitForPlayers);
 857
 858         setmodel(kh_controller, "models/keyhunt/key.md3");
 859         kh_key_dropped = kh_controller.modelindex;
 860         /*
 861         dprint(vtos(kh_controller.mins));
 862         dprint(vtos(kh_controller.maxs));
 863         dprint("\n");
 864         */
 865 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 866         setmodel(kh_controller, "models/keyhunt/key-carried.md3");
 867         kh_key_carried = kh_controller.modelindex;
 868 #else
 869         kh_key_carried = kh_key_dropped;
 870 #endif
 871         setmodel(kh_controller, "models/sprites/key-dropped.sp2");
 872         kh_sprite_dropped = kh_controller.modelindex;
 873         setmodel(kh_controller, "models/sprites/keycarrier-finish.sp2");
 874         kh_sprite_finish = kh_controller.modelindex;
 875         setmodel(kh_controller, "models/sprites/keycarrier-friend.sp2");
 876         kh_sprite_friend = kh_controller.modelindex;
 877         setmodel(kh_controller, "models/sprites/keycarrier-red.sp2");
 878         kh_sprite_red = kh_controller.modelindex;
 879         setmodel(kh_controller, "models/sprites/keycarrier-blue.sp2");
 880         kh_sprite_blue = kh_controller.modelindex;
 881         setmodel(kh_controller, "models/sprites/keycarrier-pink.sp2");
 882         kh_sprite_pink = kh_controller.modelindex;
 883         setmodel(kh_controller, "models/sprites/keycarrier-yellow.sp2");
 884         kh_sprite_yellow = kh_controller.modelindex;
 885         setmodel(kh_controller, "");
 886 }
 887
 888 void kh_finalize()
 889 {
 890         // to be called before intermission
 891         kh_FinishRound();
 892         remove(kh_controller);
 893         kh_controller = world;
 894 }