data/qcsrc/server/keyhunt.qc

   1 string STR_ITEM_KH_KEY = "item_kh_key";
   2 #define FOR_EACH_KH_KEY(v) for(v = world; (v = find(v, classname, STR_ITEM_KH_KEY)); )
   3
   4 // #define KH_PLAYER_USE_ATTACHMENT
   5 // #define KH_PLAYER_USE_CARRIEDMODEL
   6 // #define KH_KEY_ATTACHMENT_DEBUG
   7
   8 #ifdef KH_PLAYER_USE_ATTACHMENT
   9 vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
  10 vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
  11 vector KH_PLAYER_ATTACHMENT = '0 0 0';
  12 vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  13 string KH_PLAYER_ATTACHMENT_BONE = "";
  14 #else
  15 float KH_KEY_ZSHIFT = -15;
  16 float KH_KEY_XYDIST = 24;
  17 float KH_KEY_XYSPEED = 45;
  18 #endif
  19
  20 vector KH_KEY_MIN = '-8 -8 -8';
  21 vector KH_KEY_MAX = '8 8 40';
  22
  23 typedef void(void) kh_Think_t;
  24 var kh_Think_t kh_Controller_Thinkfunc;
  25 string kh_Controller_Waitmsg;
  26
  27 float kh_Team_ByID(float t)
  28 {
  29         if(t == 0) return COLOR_TEAM1;
  30         if(t == 1) return COLOR_TEAM2;
  31         if(t == 2) return COLOR_TEAM3;
  32         if(t == 3) return COLOR_TEAM4;
  33         return 0;
  34 }
  35
  36 entity kh_controller;
  37 float kh_tracking_enabled;
  38 float kh_teams;
  39 float kh_interferemsg_time, kh_interferemsg_team;
  40 .entity kh_next, kh_prev; // linked list
  41 .float kh_droptime;
  42
  43 string kh_sound_capture = "sound/ctf/capture.wav";
  44 string kh_sound_destroy = "sound/ctf/return.wav";
  45 string kh_sound_drop = "sound/misc/mouseclick.wav";
  46 string kh_sound_collect = "sound/ctf/take.wav";
  47
  48 float kh_sprite_dropped, kh_sprite_finish, kh_sprite_red, kh_sprite_blue, kh_sprite_pink, kh_sprite_yellow, kh_sprite_friend;
  49 float kh_key_dropped, kh_key_carried;
  50
  51 float kh_GetCarrierSprite(float t, float e)
  52 {
  53         if(t == e)           return kh_sprite_friend;
  54         if(t == COLOR_TEAM1) return kh_sprite_red;
  55         if(t == COLOR_TEAM2) return kh_sprite_blue;
  56         if(t == COLOR_TEAM3) return kh_sprite_yellow;
  57         if(t == COLOR_TEAM4) return kh_sprite_pink;
  58         return 0;
  59 }
  60
  61 void kh_Controller_SetThink(float t, string msg, kh_Think_t func)
  62 {
  63         kh_Controller_Thinkfunc = func;
  64         kh_controller.cnt = t;
  65         if(kh_Controller_Waitmsg != "")
  66                 strunzone(kh_Controller_Waitmsg);
  67         if(msg == "")
  68                 kh_Controller_Waitmsg = "";
  69         else
  70                 kh_Controller_Waitmsg = strzone(msg);
  71         if(t == 0)
  72                 kh_controller.nextthink = time; // force
  73 }
  74
  75 void kh_Controller_Think()
  76 {
  77         entity e;
  78         if(intermission_running)
  79                 return;
  80         if(self.cnt > 0)
  81         {
  82                 if(kh_Controller_Waitmsg != "")
  83                 {
  84                         string s;
  85                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
  86                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
  87                         else
  88                                 s = kh_Controller_Waitmsg;
  89
  90                         dprint(s, "\n");
  91
  92                         FOR_EACH_PLAYER(e)
  93                                 if(clienttype(e) == CLIENTTYPE_REAL)
  94                                         centerprint_atprio(e, CENTERPRIO_SPAM, s);
  95                 }
  96                 self.cnt -= 1;
  97         }
  98         else if(self.cnt == 0)
  99         {
 100                 self.cnt -= 1;
 101                 kh_Controller_Thinkfunc();
 102         }
 103         self.nextthink = time + 1;
 104 }
 105
 106 // frags f: take from cvar * f
 107 // frags 0: no frags
 108 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)
 109 {
 110         string s;
 111         if(frags_player)
 112                 player.frags = player.frags + floor(0.5 + frags_player);
 113         if(frags_owner)
 114                 key.owner.frags = key.owner.frags + floor(0.5 + frags_owner);
 115         if(!cvar("sv_eventlog"))
 116                 return;
 117         s = strcat(":keyhunt:", what, ":", ftos(player.playerid));
 118         s = strcat(s, ":", ftos(frags_player));
 119         if(key && key.owner)
 120                 s = strcat(s, ":", ftos(key.owner.playerid));
 121         else
 122                 s = strcat(s, ":0");
 123         s = strcat(s, ":", ftos(frags_owner), ":");
 124         if(key)
 125                 s = strcat(s, key.netname);
 126         GameLogEcho(s, FALSE);
 127 }
 128
 129 vector kh_AttachedOrigin(entity e)
 130 {
 131         if(e.tag_entity)
 132         {
 133                 makevectors(e.tag_entity.angles);
 134                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 135         }
 136         else
 137                 return e.origin;
 138 }
 139
 140 void kh_Key_Attach(entity key)
 141 {
 142 #ifdef KH_PLAYER_USE_ATTACHMENT
 143         entity first;
 144         first = key.owner.kh_next;
 145         if(key == first)
 146         {
 147                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 148                 if(key.kh_next)
 149                 {
 150                         setattachment(key.kh_next, key, "");
 151                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 152                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 153                         key.kh_next.angles = '0 0 0';
 154                 }
 155                 else
 156                         setorigin(key, KH_PLAYER_ATTACHMENT);
 157                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 158         }
 159         else
 160         {
 161                 setattachment(key, key.kh_prev, "");
 162                 if(key.kh_next)
 163                         setattachment(key.kh_next, key, "");
 164                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 165                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 166                 key.angles = '0 0 0';
 167         }
 168 #else
 169         setattachment(key, key.owner, "");
 170         setorigin(key, '0 0 -15'); // fixing x, y in think
 171         key.angles_y -= key.owner.angles_y;
 172 #endif
 173         key.flags = 0;
 174         key.solid = SOLID_NOT;
 175         key.movetype = MOVETYPE_NONE;
 176         key.team = key.owner.team;
 177         key.nextthink = time;
 178         key.damageforcescale = 0;
 179         key.modelindex = kh_key_carried;
 180 }
 181
 182 void kh_Key_Detach(entity key)
 183 {
 184 #ifdef KH_PLAYER_USE_ATTACHMENT
 185         entity first;
 186         first = key.owner.kh_next;
 187         if(key == first)
 188         {
 189                 if(key.kh_next)
 190                 {
 191                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 192                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 193                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 194                 }
 195         }
 196         else
 197         {
 198                 if(key.kh_next)
 199                         setattachment(key.kh_next, key.kh_prev, "");
 200                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 201         }
 202         // in any case:
 203         setattachment(key, world, "");
 204         setorigin(key, key.owner.origin + '0 0 1' * (PL_MIN_z - KH_KEY_MIN_z));
 205         key.angles = key.owner.angles;
 206 #else
 207         setorigin(key, key.owner.origin + key.origin_z * '0 0 1');
 208         setattachment(key, world, "");
 209         key.angles_y += key.owner.angles_y;
 210 #endif
 211         key.aiment = world;
 212         key.flags = FL_ITEM;
 213         key.solid = SOLID_TRIGGER;
 214         key.movetype = MOVETYPE_TOSS;
 215         key.pain_finished = time + cvar("g_balance_keyhunt_delay_return");
 216         key.damageforcescale = cvar("g_balance_keyhunt_damageforcescale");
 217         // let key.team stay
 218         key.modelindex = kh_key_dropped;
 219 }
 220
 221 void kh_Key_AssignTo(entity key, entity player)
 222 {
 223         if(key.owner == player)
 224                 return;
 225
 226         if(key.owner)
 227         {
 228                 kh_Key_Detach(key);
 229
 230                 // remove from linked list
 231                 if(key.kh_next)
 232                         key.kh_next.kh_prev = key.kh_prev;
 233                 key.kh_prev.kh_next = key.kh_next;
 234                 key.kh_next = world;
 235                 key.kh_prev = world;
 236
 237                 if(key.owner.kh_next == world)
 238                 {
 239                         // No longer a key carrier
 240                         WaypointSprite_DetachCarrier(key.owner);
 241                 }
 242         }
 243
 244         key.owner = player;
 245
 246         if(player)
 247         {
 248                 // insert into linked list
 249                 key.kh_next = player.kh_next;
 250                 key.kh_prev = player;
 251                 player.kh_next = key;
 252                 if(key.kh_next)
 253                         key.kh_next.kh_prev = key;
 254
 255                 kh_Key_Attach(key);
 256
 257                 if(key.kh_next == world)
 258                 {
 259                         // player is now a key carrier
 260                         WaypointSprite_AttachCarrier("", player);
 261                         player.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_KeyCarrier_waypointsprite_for_player;
 262                         player.waypointsprite_attachedforcarrier.team = player.team;
 263                 }
 264         }
 265
 266         key.pusher = world;
 267 }
 268
 269 void kh_Key_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 270 {
 271         if(self.owner)
 272                 return;
 273         if(vlen(force) <= 0)
 274                 return;
 275         if(time > self.pushltime)
 276                 if(attacker.classname == "player")
 277                         self.team = attacker.team;
 278 }
 279
 280 void kh_Key_Spawn(entity initial_owner, float angle)
 281 {
 282         entity key;
 283         key = spawn();
 284         key.classname = STR_ITEM_KH_KEY;
 285         key.touch = kh_Key_Touch;
 286         key.think = kh_Key_Think;
 287         key.nextthink = time;
 288         key.items = IT_KEY1 | IT_KEY2;
 289         key.cnt = angle;
 290         key.angles = '0 360 0' * random();
 291         key.event_damage = kh_Key_Damage;
 292         key.modelindex = kh_key_dropped;
 293         key.model = "key";
 294         setsize(key, '-8 -8 -8', '8 8 40');
 295         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 296
 297         switch(initial_owner.team)
 298         {
 299                 case COLOR_TEAM1:
 300                         key.netname = "^1red key";
 301                         key.colormod = '103 0 0' * (1/96);
 302                         break;
 303                 case COLOR_TEAM2:
 304                         key.netname = "^4blue key";
 305                         key.colormod = '35 35 191' * (1/96);
 306                         break;
 307                 case COLOR_TEAM3:
 308                         key.netname = "^3yellow key";
 309                         key.colormod = '187 167 15' * (1/96);
 310                         break;
 311                 case COLOR_TEAM4:
 312                         key.netname = "^6pink key";
 313                         key.colormod = '139 79 107' * (1/96);
 314                         break;
 315                 default:
 316                         key.netname = "NETGIER key";
 317                         key.colormod = '1 1 1';
 318                         break;
 319         }
 320
 321         sprint(initial_owner, strcat("You got the ^2", key.netname, "\n"));
 322
 323         WaypointSprite_AttachCarrier("", key);
 324         key.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_Key_waypointsprite_for_player;
 325
 326         kh_Key_AssignTo(key, initial_owner);
 327 }
 328
 329 void kh_Key_Remove(entity key)
 330 {
 331         entity o;
 332         o = key.owner;
 333         kh_Key_AssignTo(key, world);
 334         if(o) // it was attached
 335                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 336         else // it was dropped
 337                 WaypointSprite_DetachCarrier(key);
 338
 339         remove(key);
 340 }
 341
 342 // -1 when no team completely owns all keys yet
 343 float kh_Key_AllOwnedByWhichTeam()
 344 {
 345         entity key;
 346         float teem;
 347
 348         teem = -1;
 349         FOR_EACH_KH_KEY(key)
 350         {
 351                 if(!key.owner)
 352                         return -1;
 353                 if(teem == -1)
 354                         teem = key.team;
 355                 else if(teem != key.team)
 356                         return -1;
 357         }
 358         return teem;
 359 }
 360
 361 void kh_Key_Collect(entity key, entity player)
 362 {
 363         sound(key, CHAN_AUTO, kh_sound_collect, 1, ATTN_NORM);
 364
 365         kh_Scores_Event(player, key, "collect", cvar("g_balance_keyhunt_score_collect"), 0);
 366         bprint(player.netname, "^7 collected the ", key.netname, "\n");
 367         kh_Key_AssignTo(key, player);
 368
 369         if(kh_Key_AllOwnedByWhichTeam() != -1)
 370         {
 371                 kh_interferemsg_time = time + 0.2;
 372                 kh_interferemsg_team = player.team;
 373         }
 374 }
 375
 376 void kh_Key_DropAll(entity player)
 377 {
 378         entity key;
 379         entity mypusher;
 380         if(player.kh_next)
 381         {
 382                 mypusher = world;
 383                 if(player.pusher)
 384                         if(time < player.pushltime)
 385                                 mypusher = player.pusher;
 386                 while((key = player.kh_next))
 387                 {
 388                         kh_Scores_Event(player, key, "losekey", 0, 0);
 389                         bprint(player.netname, "^7 lost the ", key.netname, "\n");
 390                         kh_Key_AssignTo(key, world);
 391                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 392                         key.velocity = W_CalculateProjectileVelocity(player.velocity, cvar("g_balance_keyhunt_dropvelocity") * v_forward);
 393                         key.pusher = mypusher;
 394                         key.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 395                 }
 396                 sound(player, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 397         }
 398 }
 399
 400 void kh_Key_Touch()
 401 {
 402         if(self.owner) // already carried
 403                 return;
 404         if(other.classname != "player")
 405                 return;
 406         if(other.deadflag != DEAD_NO)
 407                 return;
 408         if(other == self.enemy)
 409                 if(time < self.kh_droptime + cvar("g_balance_keyhunt_delay_collect"))
 410                         return; // you just dropped it!
 411         kh_Key_Collect(self, other);
 412 }
 413
 414 void kh_Key_Think()
 415 {
 416         entity head;
 417
 418 #ifdef KH_KEY_ATTACHMENT_DEBUG
 419         if(self.kh_prev == self.owner)
 420         {
 421                 if(cvar_string("_angles") != "")
 422                 {
 423                         self.angles = stov(cvar_string("_angles"));
 424                         self.origin = stov(cvar_string("_origin"));
 425                 }
 426         }
 427 #endif
 428
 429         if(self.owner)
 430         {
 431 #ifndef KH_PLAYER_USE_ATTACHMENT
 432                 makevectors('0 1 0' * (self.cnt + math_mod(time, 360) * KH_KEY_XYSPEED));
 433                 setorigin(self, v_forward * KH_KEY_XYDIST + '0 0 1' * self.origin_z);
 434 #endif
 435
 436                 if(self.owner.buttonuse)
 437                 if(time >= self.owner.kh_droptime + cvar("g_balance_keyhunt_delay_drop"))
 438                 {
 439                         self.owner.kh_droptime = time;
 440                         self.kh_droptime = time; // prevent collecting this one for some time
 441                         self.enemy = self.owner;
 442                         self.pusher = world;
 443                         kh_Scores_Event(self.owner, self, "dropkey", 0, 0);
 444                         bprint(self.owner.netname, "^7 dropped the ", self.netname, "\n");
 445                         sound(self.owner, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 446                         makevectors(self.owner.v_angle);
 447                         self.velocity = W_CalculateProjectileVelocity(self.owner.velocity, cvar("g_balance_keyhunt_throwvelocity") * v_forward);
 448                         kh_Key_AssignTo(self, world);
 449                         self.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 450                 }
 451         }
 452
 453         // if in nodrop or time over, end the round
 454         if(!self.owner)
 455                 if(time > self.pain_finished)
 456                         kh_LoserTeam(self.team, self);
 457
 458         if(self.owner)
 459         if(kh_Key_AllOwnedByWhichTeam() != -1)
 460         {
 461                 entity key;
 462                 vector p;
 463                 p = self.owner.origin;
 464                 FOR_EACH_KH_KEY(key)
 465                         if(vlen(key.owner.origin - p) > cvar("g_balance_keyhunt_maxdist"))
 466                                 goto not_winning;
 467                 kh_WinnerTeam(self.team);
 468 :not_winning
 469         }
 470
 471         if(kh_interferemsg_time && time > kh_interferemsg_time)
 472         {
 473                 kh_interferemsg_time = 0;
 474                 FOR_EACH_PLAYER(head)
 475                 {
 476                         if(head.team == kh_interferemsg_team)
 477                                 if(head.kh_next)
 478                                         centerprint(head, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!\n");
 479                                 else
 480                                         centerprint(head, "All keys are in your team's hands!\n\nHelp the key carriers to meet!\n");
 481                         else
 482                                 centerprint(head, "All keys are in the enemy's hands!\n\nInterfere ^1NOW^7!\n");
 483                 }
 484         }
 485
 486         self.nextthink = time + 0.05;
 487 }
 488
 489 void kh_WinnerTeam(float teem)
 490 {
 491         // all key carriers get some points
 492         vector firstorigin, lastorigin;
 493         float first;
 494         entity key;
 495         float score;
 496         score = (kh_teams - 1) * cvar("g_balance_keyhunt_score_capture");
 497         DistributeEvenly_Init(score, kh_teams);
 498         // twice the score for 3 team games, three times the score for 4 team games!
 499         // note: for a win by destroying the key, this should NOT be applied
 500         FOR_EACH_KH_KEY(key)
 501                 kh_Scores_Event(key.owner, key, "capture", DistributeEvenly_Get(1), 0);
 502
 503         first = TRUE;
 504         FOR_EACH_KH_KEY(key)
 505                 if(key.owner.kh_next == key)
 506                 {
 507                         if(!first)
 508                                 bprint("^7, ");
 509                         bprint(key.owner.netname);
 510                         first = FALSE;
 511                 }
 512         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 513
 514         first = TRUE;
 515         FOR_EACH_KH_KEY(key)
 516         {
 517                 vector thisorigin;
 518
 519                 thisorigin = kh_AttachedOrigin(key);
 520
 521                 if(!first)
 522                         te_lightning2(world, lastorigin, thisorigin);
 523                 lastorigin = thisorigin;
 524                 if(first)
 525                         firstorigin = thisorigin;
 526                 first = FALSE;
 527         }
 528         if(kh_teams > 2)
 529         {
 530                 te_lightning2(world, lastorigin, firstorigin);
 531         }
 532
 533         sound(world, CHAN_AUTO, kh_sound_capture, 1, ATTN_NONE);
 534         kh_FinishRound();
 535 }
 536
 537 void kh_LoserTeam(float teem, entity lostkey)
 538 {
 539         entity player, key, attacker;
 540         float players;
 541         float keys;
 542
 543         attacker = world;
 544         if(lostkey.pusher)
 545                 if(lostkey.pusher.team != teem)
 546                         if(lostkey.pusher.classname == "player")
 547                                 attacker = lostkey.pusher;
 548
 549         players = keys = 0;
 550
 551         if(attacker)
 552         {
 553                 kh_Scores_Event(attacker, world, "push", cvar("g_balance_keyhunt_score_push"), 0);
 554                 centerprint(attacker, "Your push is the best!\n\n\n");
 555                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 556         }
 557         else
 558         {
 559                 float of, fragsleft, i, thisteam;
 560                 of = cvar("g_balance_keyhunt_score_destroyed_ownfactor");
 561
 562                 FOR_EACH_PLAYER(player)
 563                         if(player.team != teem)
 564                                 ++players;
 565
 566                 FOR_EACH_KH_KEY(key)
 567                         if(key.owner && key.team != teem)
 568                                 ++keys;
 569
 570                 DistributeEvenly_Init(cvar("g_balance_keyhunt_score_destroyed"), keys * of + players);
 571
 572                 FOR_EACH_KH_KEY(key)
 573                         if(key.owner && key.team != teem)
 574                                 kh_Scores_Event(key.owner, world, "destroyed_holdingkey", DistributeEvenly_Get(of), 0);
 575
 576                 fragsleft = DistributeEvenly_Get(players);
 577
 578                 // Now distribute these among all other teams...
 579                 for(i = 0; i < kh_teams; ++i)
 580                 {
 581                         thisteam = kh_Team_ByID(i);
 582                         players = 0;
 583                         FOR_EACH_PLAYER(player)
 584                                 if(player.team == thisteam)
 585                                         ++players;
 586
 587                         DistributeEvenly_Init(fragsleft, kh_teams - i);
 588                         fragsleft = DistributeEvenly_Get(kh_teams - i - 1);
 589                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 590
 591                         FOR_EACH_PLAYER(player)
 592                                 if(player.team == thisteam)
 593                                         kh_Scores_Event(player, world, "destroyed", DistributeEvenly_Get(1), 0);
 594                 }
 595
 596                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 597         }
 598         sound(world, CHAN_AUTO, kh_sound_destroy, 1, ATTN_NONE);
 599
 600         kh_FinishRound();
 601 }
 602
 603 void kh_FinishRound()
 604 {
 605         // prepare next round
 606         kh_interferemsg_time = 0;
 607         entity key;
 608         FOR_EACH_KH_KEY(key)
 609                 kh_Key_Remove(key);
 610
 611         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 612 }
 613
 614 float kh_EnoughPlayers()
 615 {
 616         float i, players, teem;
 617         entity player;
 618
 619         // find a random player per team
 620         for(i = 0; i < kh_teams; ++i)
 621         {
 622                 teem = kh_Team_ByID(i);
 623                 players = 0;
 624                 FOR_EACH_PLAYER(player)
 625                         if(player.deadflag == DEAD_NO)
 626                                 if(player.team == teem)
 627                                         ++players;
 628                 if(players == 0)
 629                         return FALSE;
 630         }
 631         return TRUE;
 632 }
 633
 634 void kh_WaitForPlayers()
 635 {
 636         if(kh_EnoughPlayers())
 637                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 638         else
 639                 kh_Controller_SetThink(1, "Waiting for players to join...", kh_WaitForPlayers);
 640 }
 641
 642 void kh_StartRound()
 643 {
 644         float i, players, teem;
 645         entity player;
 646
 647         if(!kh_EnoughPlayers())
 648         {
 649                 kh_Controller_SetThink(1, "Waiting for players to join...", kh_WaitForPlayers);
 650                 return;
 651         }
 652
 653         FOR_EACH_PLAYER(player)
 654                 if(clienttype(player) == CLIENTTYPE_REAL)
 655                         centerprint_expire(player, CENTERPRIO_SPAM);
 656
 657         for(i = 0; i < kh_teams; ++i)
 658         {
 659                 teem = kh_Team_ByID(i);
 660                 players = 0;
 661                 entity my_player;
 662                 FOR_EACH_PLAYER(player)
 663                         if(player.deadflag == DEAD_NO)
 664                                 if(player.team == teem)
 665                                 {
 666                                         ++players;
 667                                         if(random() * players <= 1)
 668                                                 my_player = player;
 669                                 }
 670                 kh_Key_Spawn(my_player, 360 * i / kh_teams);
 671                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 672                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 673         }
 674
 675         kh_tracking_enabled = FALSE;
 676         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_tracking"), "Scanning frequency range...", kh_EnableTrackingDevice);
 677 }
 678
 679 void kh_setstatus()
 680 {
 681         if(kh_teams)
 682         {
 683                 float kh_KEY;
 684                 kh_KEY = (IT_RED_FLAG_TAKEN | IT_RED_FLAG_LOST | IT_BLUE_FLAG_TAKEN | IT_BLUE_FLAG_LOST); // the one impossible combination
 685                 if(self.kh_next)
 686                         self.items = self.items | kh_KEY;
 687                 else
 688                         self.items = self.items - (self.items & kh_KEY);
 689         }
 690 }
 691
 692 void kh_EnableTrackingDevice()
 693 {
 694         entity player;
 695
 696         FOR_EACH_PLAYER(player)
 697                 if(clienttype(player) == CLIENTTYPE_REAL)
 698                         centerprint_expire(player, CENTERPRIO_SPAM);
 699
 700         kh_tracking_enabled = TRUE;
 701 }
 702
 703 float kh_Key_waypointsprite_for_player(entity e)
 704 {
 705         if(!kh_tracking_enabled)
 706                 return 0;
 707         if(!self.owner)
 708                 return kh_sprite_dropped;
 709         if(!self.owner.owner)
 710                 return kh_sprite_dropped;
 711         return 0; // draw only when key is not owned
 712 }
 713
 714 float kh_KeyCarrier_waypointsprite_for_player(entity e)
 715 {
 716         if(e.classname != "player" || self.team != e.team)
 717                 if(!kh_tracking_enabled)
 718                         return 0;
 719
 720         // e is spectator? That's no team mate...
 721         if(e.classname != "player")
 722                 return kh_GetCarrierSprite(self.team, -1);
 723
 724         // e is no key carrier: simple case...
 725         if(!e.kh_next)
 726                 return kh_GetCarrierSprite(self.team, e.team);
 727
 728         // e is a key carrier: if any key is dropped or owned by another team, show
 729         // the carrier sprite; otherwise show run here
 730         if(kh_Key_AllOwnedByWhichTeam() == e.team)
 731                 return kh_sprite_finish;
 732
 733         return kh_GetCarrierSprite(self.team, e.team);
 734 }
 735
 736 float kh_HandleFrags(entity attacker, entity targ, float f)
 737 {
 738         if(f <= 0)
 739                 return f;
 740         if(attacker == targ)
 741                 return f;
 742
 743         if(targ.kh_next)
 744                 kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", cvar("g_balance_keyhunt_score_carrierfrag")-1, 0);
 745
 746         return f;
 747 }
 748
 749 void kh_init()
 750 {
 751         precache_sound(kh_sound_capture);
 752         precache_sound(kh_sound_destroy);
 753         precache_sound(kh_sound_drop);
 754         precache_sound(kh_sound_collect);
 755
 756         precache_model("models/sprites/key-dropped.sp2");
 757         precache_model("models/sprites/keycarrier-finish.sp2");
 758         precache_model("models/sprites/keycarrier-friend.sp2");
 759         precache_model("models/sprites/keycarrier-red.sp2");
 760         precache_model("models/sprites/keycarrier-blue.sp2");
 761         precache_model("models/sprites/keycarrier-yellow.sp2");
 762         precache_model("models/sprites/keycarrier-pink.sp2");
 763 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 764         precache_model("models/keyhunt/key-carried.md3");
 765 #endif
 766         precache_model("models/keyhunt/key.md3");
 767
 768         // setup variables
 769         kh_teams = cvar("g_keyhunt_teams_override");
 770         if(kh_teams < 2)
 771                 kh_teams = cvar("g_keyhunt_teams");
 772         kh_teams = bound(2, kh_teams, 4);
 773
 774         // make a KH entity for controlling the game
 775         kh_controller = spawn();
 776         kh_controller.think = kh_Controller_Think;
 777         kh_Controller_SetThink(0, "", kh_WaitForPlayers);
 778
 779         setmodel(kh_controller, "models/keyhunt/key.md3");
 780         kh_key_dropped = kh_controller.modelindex;
 781 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 782         setmodel(kh_controller, "models/keyhunt/key-carried.md3");
 783         kh_key_carried = kh_controller.modelindex;
 784 #else
 785         kh_key_carried = kh_key_dropped;
 786 #endif
 787         setmodel(kh_controller, "models/sprites/key-dropped.sp2");
 788         kh_sprite_dropped = kh_controller.modelindex;
 789         setmodel(kh_controller, "models/sprites/keycarrier-finish.sp2");
 790         kh_sprite_finish = kh_controller.modelindex;
 791         setmodel(kh_controller, "models/sprites/keycarrier-friend.sp2");
 792         kh_sprite_friend = kh_controller.modelindex;
 793         setmodel(kh_controller, "models/sprites/keycarrier-red.sp2");
 794         kh_sprite_red = kh_controller.modelindex;
 795         setmodel(kh_controller, "models/sprites/keycarrier-blue.sp2");
 796         kh_sprite_blue = kh_controller.modelindex;
 797         setmodel(kh_controller, "models/sprites/keycarrier-pink.sp2");
 798         kh_sprite_pink = kh_controller.modelindex;
 799         setmodel(kh_controller, "models/sprites/keycarrier-yellow.sp2");
 800         kh_sprite_yellow = kh_controller.modelindex;
 801         setmodel(kh_controller, "");
 802 }
 803
 804 void kh_finalize()
 805 {
 806         // to be called before intermission
 807         kh_FinishRound();
 808         remove(kh_controller);
 809         kh_controller = world;
 810 }