data/qcsrc/server/havocbot.qc

   1 .void() havocbot_role;
   2 void() havocbot_chooserole;
   3 .float havocbot_keyboardskill;
   4 .float facingwalltime, ignoregoaltime;
   5 .entity ignoregoal;
   6
   7 #ifdef DEBUG_BOT_GOALSTACK
   8 void debuggoalstack();
   9 #endif
  10
  11 vector havocbot_dodge()
  12 {
  13         // LordHavoc: disabled because this is too expensive
  14         return '0 0 0';
  15         /*
  16         local entity head;
  17         local vector dodge, v, n;
  18         local float danger, bestdanger, vl, d;
  19         dodge = '0 0 0';
  20         bestdanger = -20;
  21         // check for dangerous objects near bot or approaching bot
  22         head = findchainfloat(bot_dodge, TRUE);
  23         while(head)
  24         {
  25                 if (head.owner != self)
  26                 {
  27                         vl = vlen(head.velocity);
  28                         if (vl > sv_maxspeed * 0.3)
  29                         {
  30                                 n = normalize(head.velocity);
  31                                 v = self.origin - head.origin;
  32                                 d = v * n;
  33                                 if (d > (0 - head.bot_dodgerating))
  34                                 if (d < (vl * 0.2 + head.bot_dodgerating))
  35                                 {
  36                                         // calculate direction and distance from the flight path, by removing the forward axis
  37                                         v = v - (n * (v * n));
  38                                         danger = head.bot_dodgerating - vlen(v);
  39                                         if (bestdanger < danger)
  40                                         {
  41                                                 bestdanger = danger;
  42                                                 // dodge to the side of the object
  43                                                 dodge = normalize(v);
  44                                         }
  45                                 }
  46                         }
  47                         else
  48                         {
  49                                 danger = head.bot_dodgerating - vlen(head.origin - self.origin);
  50                                 if (bestdanger < danger)
  51                                 {
  52                                         bestdanger = danger;
  53                                         dodge = normalize(self.origin - head.origin);
  54                                 }
  55                         }
  56                 }
  57                 head = head.chain;
  58         }
  59         return dodge;
  60         */
  61 };
  62
  63 .float havocbot_keyboardtime;
  64 .float havocbot_ducktime;
  65 .vector havocbot_keyboard;
  66 void havocbot_keyboard_movement(vector destorg)
  67 {
  68         local vector keyboard;
  69         local float blend, maxspeed;
  70
  71         maxspeed = cvar("sv_maxspeed");
  72
  73         if (time < self.havocbot_keyboardtime)
  74                 return;
  75
  76         self.havocbot_keyboardtime =
  77                 max(
  78                         self.havocbot_keyboardtime
  79                                 + bound(0,0.05/(skill+self.havocbot_keyboardskill),0.05)
  80                                 +random()*bound(0,0.025/(skill+self.havocbot_keyboardskill),100)
  81                 , time);
  82         keyboard = self.movement * (1.0 / maxspeed);
  83
  84         local float trigger, trigger1;
  85         blend = bound(0,skill*0.1,1);
  86         trigger = cvar("bot_ai_keyboard_treshold");
  87         trigger1 = 0 - trigger;
  88
  89         // categorize forward movement
  90         // at skill < 1.5 only forward
  91         // at skill < 2.5 only individual directions
  92         // at skill < 4.5 only individual directions, and forward diagonals
  93         // at skill >= 4.5, all cases allowed
  94         if (keyboard_x > trigger)
  95         {
  96                 keyboard_x = 1;
  97                 if (skill < 2.5)
  98                         keyboard_y = 0;
  99         }
 100         else if (keyboard_x < trigger1 && skill > 1.5)
 101         {
 102                 keyboard_x = -1;
 103                 if (skill < 4.5)
 104                         keyboard_y = 0;
 105         }
 106         else
 107         {
 108                 keyboard_x = 0;
 109                 if (skill < 1.5)
 110                         keyboard_y = 0;
 111         }
 112         if (skill < 4.5)
 113                 keyboard_z = 0;
 114
 115         if (keyboard_y > trigger)
 116                 keyboard_y = 1;
 117         else if (keyboard_y < trigger1)
 118                 keyboard_y = -1;
 119         else
 120                 keyboard_y = 0;
 121
 122         if (keyboard_z > trigger)
 123                 keyboard_z = 1;
 124         else if (keyboard_z < trigger1)
 125                 keyboard_z = -1;
 126         else
 127                 keyboard_z = 0;
 128
 129         self.havocbot_keyboard = keyboard * maxspeed;
 130         if (self.havocbot_ducktime>time) self.BUTTON_CROUCH=TRUE;
 131
 132         keyboard = self.havocbot_keyboard;
 133         blend = bound(0,vlen(destorg-self.origin)/cvar("bot_ai_keyboard_distance"),1); // When getting close move with 360 degree
 134         //dprint("movement ", vtos(self.movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 135         self.movement = self.movement + (keyboard - self.movement) * blend;
 136 };
 137
 138 .entity bot_lastseengoal;
 139 .float bot_timelastseengoal;
 140 .float bot_canruntogoal;
 141 void havocbot_bunnyhop(vector dir)
 142 {
 143         local float bunnyhopdistance;
 144         local vector deviation;
 145         local float maxspeed;
 146
 147         if(self.goalcurrent.classname == "player")
 148                 return;
 149
 150         maxspeed = cvar("sv_maxspeed");
 151
 152         if(self.aistatus & AI_STATUS_DANGER_AHEAD)
 153         {
 154                 self.aistatus &~= AI_STATUS_RUNNING;
 155                 self.BUTTON_JUMP = FALSE;
 156                 return;
 157         }
 158
 159         if(self.waterlevel > WATERLEVEL_WETFEET)
 160         {
 161                 self.aistatus &~= AI_STATUS_RUNNING;
 162                 return;
 163         }
 164
 165         if(self.bot_lastseengoal != self.goalcurrent && !(self.aistatus & AI_STATUS_RUNNING))
 166         {
 167                 self.bot_canruntogoal = 0;
 168                 self.bot_timelastseengoal = 0;
 169         }
 170
 171         bunnyhopdistance = vlen(self.origin - self.goalcurrent.origin);
 172
 173         // Run only to visible goals
 174         if(self.flags & FL_ONGROUND)
 175         if(self.speed==maxspeed)
 176         if(checkpvs(self.origin + self.view_ofs, self.goalcurrent))
 177         {
 178                         self.bot_lastseengoal = self.goalcurrent;
 179
 180                         // seen it before
 181                         if(self.bot_timelastseengoal)
 182                         {
 183                                 // for a period of time
 184                                 if(time - self.bot_timelastseengoal > cvar("bot_ai_bunnyhop_firstjumpdelay"))
 185                                 {
 186                                         local float checkdistance;
 187                                         checkdistance = TRUE;
 188
 189                                         // don't run if it is too close
 190                                         if(self.bot_canruntogoal==0)
 191                                         {
 192                                                 if(bunnyhopdistance > cvar("bot_ai_bunnyhop_startdistance"))
 193                                                         self.bot_canruntogoal = 1;
 194                                                 else
 195                                                         self.bot_canruntogoal = -1;
 196                                         }
 197
 198                                         if(self.bot_canruntogoal != 1)
 199                                                 return;
 200
 201                                         if(self.aistatus & AI_STATUS_ROAMING)
 202                                         if(self.goalcurrent.classname=="waypoint")
 203                                         if(fabs(self.goalcurrent.origin_z - self.origin_z) < self.maxs_z - self.mins_z)
 204                                         if(self.goalstack01!=world)
 205                                         {
 206                                                 deviation = vectoangles(self.goalstack01.origin - self.origin) - vectoangles(self.goalcurrent.origin - self.origin);
 207                                                 while (deviation_y < -180) deviation_y = deviation_y + 360;
 208                                                 while (deviation_y > 180) deviation_y = deviation_y - 360;
 209
 210                                                 if(fabs(deviation_y) < 20)
 211                                                 if(bunnyhopdistance < vlen(self.origin - self.goalstack01.origin))
 212                                                 if(fabs(self.goalstack01.origin_z - self.goalcurrent.origin_z) < self.maxs_z - self.mins_z)
 213                                                 {
 214                                                         if(vlen(self.goalcurrent.origin - self.goalstack01.origin) > cvar("bot_ai_bunnyhop_startdistance"))
 215                                                         if(checkpvs(self.origin + self.view_ofs, self.goalstack01))
 216                                                         {
 217                                                                 checkdistance = FALSE;
 218                                                         }
 219                                                 }
 220                                         }
 221
 222                                         if(checkdistance)
 223                                         {
 224                                                 self.aistatus &~= AI_STATUS_RUNNING;
 225                                                 if(bunnyhopdistance > cvar("bot_ai_bunnyhop_stopdistance"))
 226                                                         self.BUTTON_JUMP = TRUE;
 227                                         }
 228                                         else
 229                                         {
 230                                                 self.aistatus |= AI_STATUS_RUNNING;
 231                                                 self.BUTTON_JUMP = TRUE;
 232                                         }
 233                                 }
 234                         }
 235                         else
 236                         {
 237                                 self.bot_timelastseengoal = time;
 238                         }
 239         }
 240         else
 241         {
 242                 self.bot_timelastseengoal = 0;
 243         }
 244
 245         // Release jump button
 246         if(self.flags & FL_ONGROUND == 0)
 247         {
 248                 if(self.velocity_z < 0 || vlen(self.velocity)<maxspeed)
 249                         self.BUTTON_JUMP = FALSE;
 250
 251                 // Strafe
 252                 if(self.aistatus & AI_STATUS_RUNNING)
 253                 if(vlen(self.velocity)>maxspeed)
 254                 {
 255                         deviation = vectoangles(dir) - vectoangles(self.velocity);
 256                         while (deviation_y < -180) deviation_y = deviation_y + 360;
 257                         while (deviation_y > 180) deviation_y = deviation_y - 360;
 258
 259                         if(fabs(deviation_y)>5)
 260                                 self.movement_x = 0;
 261                 }
 262         }
 263 };
 264
 265 //.float havocbotignoretime;
 266 //.vector bot_dodgevector;
 267 //.float bot_dodgevector_time;
 268 //.float bot_dodgevector_jumpbutton;
 269 .float ladder_time;
 270 .entity ladder_entity;
 271 void havocbot_movetogoal()
 272 {
 273         local vector destorg;
 274         local vector diff;
 275         local vector dir;
 276         local vector flatdir;
 277         local vector m1;
 278         local vector m2;
 279         local vector evadeobstacle;
 280         local vector evadelava;
 281         local float s;
 282         local float maxspeed;
 283         //local float dist;
 284         local vector dodge;
 285         //if (self.goalentity)
 286         //      te_lightning2(self, self.origin, (self.goalentity.absmin + self.goalentity.absmax) * 0.5);
 287         self.movement = '0 0 0';
 288         maxspeed = cvar("sv_maxspeed");
 289
 290         if(self.jumppadcount)
 291         {
 292                 if(self.flags & FL_ONGROUND)
 293                 {
 294                         self.jumppadcount = FALSE;
 295                         if(self.aistatus & AI_STATUS_OUT_JUMPPAD)
 296                                 self.aistatus &~= AI_STATUS_OUT_JUMPPAD;
 297                 }
 298
 299                 // If got stuck on the jump pad try to reach the farther visible item
 300                 if(self.aistatus & AI_STATUS_OUT_JUMPPAD)
 301                 {
 302                         if(fabs(self.velocity_z)<50)
 303                         {
 304                                 local entity head, newgoal;
 305                                 local float distance, bestdistance;
 306
 307                                 for (head = findchainfloat(bot_pickup, TRUE); head; head = head.chain)
 308                                 {
 309                                         if(head.classname=="worldspawn")
 310                                                 continue;
 311
 312                                         distance = vlen(head.origin - self.origin);
 313                                         if(distance>1000)
 314                                                 continue;
 315
 316                                         traceline(self.origin + self.view_ofs , head.origin, TRUE, world);
 317
 318                                         if(trace_fraction<1)
 319                                                 continue;
 320
 321                                         if(distance>bestdistance)
 322                                         {
 323                                                 newgoal = head;
 324                                                 bestdistance = distance;
 325                                         }
 326                                 }
 327
 328                                 if(newgoal)
 329                                 {
 330                                         self.ignoregoal = self.goalcurrent;
 331                                         self.ignoregoaltime = time + cvar("bot_ai_ignoregoal_timeout");
 332                                         navigation_routetogoal(newgoal);
 333                                         self.aistatus &~= AI_STATUS_OUT_JUMPPAD;
 334                                 }
 335                         }
 336                         else
 337                                 return;
 338                 }
 339                 else
 340                 {
 341                         if(self.velocity_z>0)
 342                         {
 343                                 local float threshold;
 344                                 threshold = maxspeed * 0.2;
 345                                 if(fabs(self.velocity_x) < threshold  &&  fabs(self.velocity_y) < threshold)
 346                                         self.aistatus |= AI_STATUS_OUT_JUMPPAD;
 347                                 return;
 348                         }
 349                 }
 350         }
 351
 352         // If we are under water with no goals, swim up
 353         if(self.waterlevel)
 354         if(self.goalcurrent==world)
 355         {
 356                 dir = '0 0 0';
 357                 if(self.waterlevel>WATERLEVEL_SWIMMING)
 358                         dir_z = 1;
 359                 else if(self.velocity_z >= 0 && !(self.waterlevel == WATERLEVEL_WETFEET && self.watertype == CONTENT_WATER))
 360                         self.BUTTON_JUMP = TRUE;
 361                 else
 362                         self.BUTTON_JUMP = FALSE;
 363                 makevectors(self.v_angle_y * '0 1 0');
 364                 self.movement_x = dir * v_forward * maxspeed;
 365                 self.movement_y = dir * v_right * maxspeed;
 366                 self.movement_z = dir * v_up * maxspeed;
 367         }
 368
 369         // if there is nowhere to go, exit
 370         if (self.goalcurrent == world)
 371                 return;
 372
 373         if (self.goalcurrent)
 374                 navigation_poptouchedgoals();
 375
 376         // if ran out of goals try to use an alternative goal or get a new strategy asap
 377         if(self.goalcurrent == world)
 378         if(self.flags & FL_ONGROUND || self.aistatus & AI_STATUS_RUNNING || self.BUTTON_JUMP == TRUE)
 379         {
 380                 if(self.alternativegoal==world)
 381                 {
 382                         // ran out of goals
 383                         self.bot_strategytime = 0;
 384                         return;
 385                 }
 386
 387                 // use the alternative goal
 388                 navigation_findnearestwaypoint(self.alternativegoal, TRUE);
 389                 navigation_routetogoal(self.alternativegoal);
 390                 self.alternativegoal = world;
 391                 bot_strategytoken_taken = TRUE;
 392
 393                 return;
 394         }
 395
 396 #ifdef DEBUG_BOT_GOALSTACK
 397         debuggoalstack();
 398 #endif
 399
 400         m1 = self.goalcurrent.origin + self.goalcurrent.mins;
 401         m2 = self.goalcurrent.origin + self.goalcurrent.maxs;
 402         destorg = self.origin;
 403         destorg_x = bound(m1_x, destorg_x, m2_x);
 404         destorg_y = bound(m1_y, destorg_y, m2_y);
 405         destorg_z = bound(m1_z, destorg_z, m2_z);
 406         diff = destorg - self.origin;
 407         //dist = vlen(diff);
 408         dir = normalize(diff);
 409         flatdir = diff;flatdir_z = 0;
 410         flatdir = normalize(flatdir);
 411
 412         //if (self.bot_dodgevector_time < time)
 413         {
 414         //      self.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 415         //      self.bot_dodgevector_jumpbutton = 1;
 416                 evadeobstacle = '0 0 0';
 417                 evadelava = '0 0 0';
 418
 419                 if (self.waterlevel)
 420                 {
 421                         if(self.waterlevel>WATERLEVEL_SWIMMING)
 422                         {
 423                         //      flatdir_z = 1;
 424                                 self.aistatus |= AI_STATUS_OUT_WATER;
 425                         }
 426                         else
 427                         {
 428                                 if(self.velocity_z >= 0 && !(self.watertype == CONTENT_WATER && self.goalcurrent.origin_z < self.origin_z) &&
 429                                         ( !(self.waterlevel == WATERLEVEL_WETFEET && self.watertype == CONTENT_WATER) || self.aistatus & AI_STATUS_OUT_WATER))
 430                                         self.BUTTON_JUMP = TRUE;
 431                                 else
 432                                         self.BUTTON_JUMP = FALSE;
 433                         }
 434                         dir = normalize(flatdir);
 435                         makevectors(self.v_angle_y * '0 1 0');
 436                 }
 437                 else
 438                 {
 439                         if(self.aistatus & AI_STATUS_OUT_WATER)
 440                                 self.aistatus &~= AI_STATUS_OUT_WATER;
 441
 442                         // jump if going toward an obstacle that doesn't look like stairs we
 443                         // can walk up directly
 444                         tracebox(self.origin, self.mins, self.maxs, self.origin + self.velocity * 0.2, FALSE, self);
 445                         if (trace_fraction < 1)
 446                         if (trace_plane_normal_z < 0.7)
 447                         {
 448                                 s = trace_fraction;
 449                                 tracebox(self.origin + '0 0 16', self.mins, self.maxs, self.origin + self.velocity * 0.2 + '0 0 16', FALSE, self);
 450                                 if (trace_fraction < s + 0.01)
 451                                 if (trace_plane_normal_z < 0.7)
 452                                 {
 453                                         s = trace_fraction;
 454                                         tracebox(self.origin + '0 0 48', self.mins, self.maxs, self.origin + self.velocity * 0.2 + '0 0 48', FALSE, self);
 455                                         if (trace_fraction > s)
 456                                                 self.BUTTON_JUMP = 1;
 457                                 }
 458                         }
 459
 460                         // avoiding dangers and obstacles
 461                         local vector dst_ahead, dst_down;
 462                         dst_ahead = self.origin + self.view_ofs + (self.velocity * 0.32);
 463                         dst_down = dst_ahead + '0 0 -1500';
 464
 465                         // Look ahead
 466                         traceline(self.origin + self.view_ofs , dst_ahead, TRUE, world);
 467
 468                         // Check head-banging against walls
 469                         if(vlen(self.origin + self.view_ofs - trace_endpos) < 2 && !(self.aistatus & AI_STATUS_OUT_WATER))
 470                         {
 471                                 if(self.facingwalltime && time > self.facingwalltime)
 472                                 {
 473                                         self.ignoregoal = self.goalcurrent;
 474                                         self.ignoregoaltime = time + cvar("bot_ai_ignoregoal_timeout");
 475                                         navigation_poproute();
 476                                 }
 477                                 else
 478                                 {
 479                                         self.facingwalltime = time + 0.05;
 480                                 }
 481                         }
 482                         else
 483                         {
 484                                 self.facingwalltime = 0;
 485
 486                                 if(self.ignoregoal != world && time > self.ignoregoaltime)
 487                                 {
 488                                         self.ignoregoal = world;
 489                                         self.ignoregoaltime = 0;
 490                                 }
 491                         }
 492
 493                         // Check for water/slime/lava and dangerous edges
 494                         // (only when the bot is on the ground or jumping intentionally)
 495                         self.aistatus &~= AI_STATUS_DANGER_AHEAD;
 496
 497                         if(trace_fraction == 1)
 498                         if(self.flags & FL_ONGROUND || self.aistatus & AI_STATUS_RUNNING || self.BUTTON_JUMP == TRUE)
 499                         {
 500                                 // Look downwards
 501                                 traceline(dst_ahead , dst_down, TRUE, world);
 502                                 //      te_lightning2(world, self.origin, dst_ahead);   // Draw "ahead" look
 503                                 //      te_lightning2(world, dst_ahead, dst_down);              // Draw "downwards" look
 504                                 if(trace_endpos_z < self.origin_z + self.mins_z)
 505                                 {
 506                                         s = pointcontents(trace_endpos + '0 0 1');
 507                                         if (s != CONTENT_SOLID)
 508                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
 509                                                 evadelava = normalize(self.velocity) * -1;
 510                                         else if (s == CONTENT_SKY)
 511                                                 evadeobstacle = normalize(self.velocity) * -1;
 512                                         else if (!boxesoverlap(dst_ahead - self.view_ofs + self.mins, dst_ahead - self.view_ofs + self.maxs,
 513                                                                 self.goalcurrent.absmin, self.goalcurrent.absmax))
 514                                         {
 515                                                 // if ain't a safe goal with "holes" (like the jumpad on soylent)
 516                                                 // and there is a trigger_hurt below
 517                                                 if(tracebox_hits_trigger_hurt(dst_ahead, self.mins, self.maxs, trace_endpos))
 518                                                 {
 519                                                         // Remove dangerous dynamic goals from stack
 520                                                         if (self.goalcurrent.classname == "player" || self.goalcurrent.classname == "droppedweapon")
 521                                                                 navigation_poproute();
 522                                                         // try to stop
 523                                                         flatdir = '0 0 0';
 524                                                         evadeobstacle = normalize(self.velocity) * -1;
 525                                                 }
 526                                         }
 527                                 }
 528                         }
 529
 530                         dir = flatdir;
 531                         evadeobstacle_z = 0;
 532                         evadelava_z = 0;
 533                         makevectors(self.v_angle_y * '0 1 0');
 534
 535                         if(evadeobstacle!='0 0 0'||evadelava!='0 0 0')
 536                                 self.aistatus |= AI_STATUS_DANGER_AHEAD;
 537                 }
 538
 539                 dodge = havocbot_dodge();
 540                 dodge = dodge * bound(0,3+skill*0.1,1);
 541                 evadelava = evadelava * bound(1,3-skill,3); //Noobs fear lava a lot and take more distance from it
 542                 traceline(self.origin, self.enemy.origin, TRUE, world);
 543                 if(trace_ent.classname == "player")
 544                         dir = dir * bound(0,skill/7,1);
 545
 546                 dir = normalize(dir + dodge + evadeobstacle + evadelava);
 547         //      self.bot_dodgevector = dir;
 548         //      self.bot_dodgevector_jumpbutton = self.BUTTON_JUMP;
 549         }
 550
 551         if(time < self.ladder_time)
 552         {
 553                 if(self.goalcurrent.origin_z + self.goalcurrent.mins_z > self.origin_z + self.mins_z)
 554                 {
 555                         if(self.origin_z + self.mins_z  < self.ladder_entity.origin_z + self.ladder_entity.maxs_z)
 556                                 dir = '0 0 1';
 557                 }
 558                 else
 559                 {
 560                         if(self.origin_z + self.mins_z  > self.ladder_entity.origin_z + self.ladder_entity.mins_z)
 561                                 dir = '0 0 -1';
 562                 }
 563         }
 564
 565         //dir = self.bot_dodgevector;
 566         //if (self.bot_dodgevector_jumpbutton)
 567         //      self.BUTTON_JUMP = 1;
 568         self.movement_x = dir * v_forward * maxspeed;
 569         self.movement_y = dir * v_right * maxspeed;
 570         self.movement_z = dir * v_up * maxspeed;
 571
 572         // Emulate keyboard interface
 573         if (skill < 10)
 574                 havocbot_keyboard_movement(destorg);
 575
 576         // Bunnyhop!
 577 //      if(self.aistatus & AI_STATUS_ROAMING)
 578         if(skill >= cvar("bot_ai_bunnyhop_skilloffset"))
 579                 havocbot_bunnyhop(dir);
 580
 581         if ((dir * v_up) >= cvar("sv_jumpvelocity")*0.5 && (self.flags & FL_ONGROUND)) self.BUTTON_JUMP=1;
 582         if (((dodge * v_up) > 0) && random()*frametime >= 0.2*bound(0,(10-skill)*0.1,1)) self.BUTTON_JUMP=TRUE;
 583         if (((dodge * v_up) < 0) && random()*frametime >= 0.5*bound(0,(10-skill)*0.1,1)) self.havocbot_ducktime=time+0.3/bound(0.1,skill,10);
 584 };
 585
 586 .float havocbot_chooseenemy_finished;
 587 .float havocbot_stickenemy;
 588 void havocbot_chooseenemy()
 589 {
 590         local entity head, best;
 591         local float rating, bestrating;
 592         local vector eye, v;
 593         if (cvar("bot_nofire") || IS_INDEPENDENT_PLAYER(self))
 594         {
 595                 self.enemy = world;
 596                 return;
 597         }
 598         if (self.enemy)
 599         {
 600                 if (!bot_shouldattack(self.enemy))
 601                 {
 602                         // enemy died or something, find a new target
 603                         self.enemy = world;
 604                         self.havocbot_chooseenemy_finished = time;
 605                 }
 606                 else if (self.havocbot_stickenemy)
 607                 {
 608                         // tracking last chosen enemy
 609                         // if enemy is visible
 610                         // and not really really far away
 611                         // and we're not severely injured
 612                         // then keep tracking for a half second into the future
 613                         traceline(self.origin+self.view_ofs, self.enemy.origin+self.enemy.view_ofs*0.5,FALSE,world);
 614                         if (trace_ent == self.enemy || trace_fraction == 1)
 615                         if (vlen(self.enemy.origin - self.origin) < 1000)
 616                         if (self.health > 30)
 617                         {
 618                                 // remain tracking him for a shot while (case he went after a small corner or pilar
 619                                 self.havocbot_chooseenemy_finished = time + cvar("bot_ai_enemydetectioninterval");
 620                                 return;
 621                         }
 622                         // enemy isn't visible, or is far away, or we're injured severely
 623                         // so stop preferring this enemy
 624                         // (it will still take a half second until a new one is chosen)
 625                         self.havocbot_stickenemy = 0;
 626                 }
 627         }
 628         if (time < self.havocbot_chooseenemy_finished)
 629                 return;
 630         self.havocbot_chooseenemy_finished = time + cvar("bot_ai_enemydetectioninterval");
 631         eye = (self.origin + self.view_ofs);
 632         best = world;
 633         bestrating = 100000000;
 634         head = findchainfloat(bot_attack, TRUE);
 635         while (head)
 636         {
 637                 v = (head.absmin + head.absmax) * 0.5;
 638                 rating = vlen(v - eye);
 639                 if (bestrating > rating)
 640                 if (bot_shouldattack(head))
 641                 {
 642                         traceline(eye, v, TRUE, self);
 643                         if (trace_ent == head || trace_fraction >= 1)
 644                         {
 645                                 best = head;
 646                                 bestrating = rating;
 647                         }
 648                 }
 649                 head = head.chain;
 650         }
 651         self.enemy = best;
 652         self.havocbot_stickenemy = TRUE;
 653 };
 654
 655 .float bot_chooseweapontime;
 656 float(entity e) w_getbestweapon;
 657 void havocbot_chooseweapon()
 658 {
 659         local float i;
 660
 661         // TODO: clean this up by moving it to weapon code
 662         if(self.enemy.classname!="player")
 663         {
 664                 // If there aren't enemies at sight use the laser (like most players)
 665                 if(client_hasweapon(self, WEP_LASER, TRUE, FALSE))
 666                 {
 667                         self.switchweapon = WEP_LASER;
 668                         return;
 669                 }
 670
 671                 // Otherwise get the first available weapon
 672                 for(i=WEP_LASER + 1; i < WEP_COUNT ; ++i)
 673                 {
 674                         if(client_hasweapon(self, i, TRUE, FALSE))
 675                         {
 676                                 self.switchweapon = i;
 677                                 return;
 678                         }
 679                 }
 680                 return;
 681         }
 682
 683         local float w, s;
 684         local float rocket  ; rocket   =-1000;
 685         local float nex     ; nex      =-1000;
 686         local float hagar   ; hagar    =-1000;
 687         local float grenade ; grenade  =-1000;
 688         local float electro ; electro  =-1000;
 689         local float crylink ; crylink  =-1000;
 690         local float uzi     ; uzi      =-1000;
 691         local float shotgun ; shotgun  =-1000;
 692         local float campingrifle ; campingrifle  =-1000;
 693         local float laser   ; laser    =-1000;
 694         local float minstanex ; minstanex =-1000;
 695         local float currentscore;
 696         local float bestscore; bestscore = 0;
 697         local float bestweapon; bestweapon=self.switchweapon;
 698         local float distance; distance=bound(10,vlen(self.origin-self.enemy.origin)-200,10000);
 699         local float maxdelaytime=0.5;
 700         local float spreadpenalty=10;
 701         local float distancefromfloor;
 702
 703         local float af, ct, combo_time;
 704
 705         traceline(self.enemy.origin,self.enemy.origin-'0 0 1000',TRUE,world);
 706         distancefromfloor = self.enemy.origin_z - trace_endpos_z;
 707
 708         af = ATTACK_FINISHED(self);
 709         ct = cvar("bot_ai_weapon_combo_threshold");
 710
 711         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
 712         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
 713         combo_time = time + ct + (ct * ((-0.3*skill)+3));
 714
 715         // Custom weapon list based on distance to the enemy
 716         i = 0;
 717         if(bot_custom_weapon){
 718
 719                 // Choose weapons for far distance
 720                 if ( distance > bot_distance_far ) {
 721                         for(i=0; i < WEP_COUNT && bot_weapons_far[i] != -1 ; ++i){
 722                                 w = bot_weapons_far[i];
 723                                 if ( client_hasweapon(self, w, TRUE, FALSE) ){
 724                                         if ( self.weapon == w){
 725                                                 if( cvar("bot_ai_weapon_combo") && af > combo_time)
 726                                                         continue;
 727                                         } else {
 728                                                 self.switchweapon = w;
 729                                         }
 730                                         return;
 731                                 }
 732                         }
 733                 }
 734
 735                 // Choose weapons for mid distance
 736                 if ( distance > bot_distance_close ) {
 737                         for(i= 0; i < WEP_COUNT && bot_weapons_mid[i] != -1 ; ++i){
 738                                 w = bot_weapons_mid[i];
 739                                 if ( client_hasweapon(self, w, TRUE, FALSE) ){
 740                                         if ( self.weapon == w){
 741                                                 if( cvar("bot_ai_weapon_combo") && af > combo_time)
 742                                                         continue;
 743                                         } else {
 744                                                 self.switchweapon = w;
 745                                         }
 746                                         return;
 747                                 }
 748                         }
 749                 }
 750
 751                 // Choose weapons for close distance
 752                 for(i= 0; i < WEP_COUNT && bot_weapons_close[i] != -1 ; ++i){
 753                         w = bot_weapons_close[i];
 754                         if ( client_hasweapon(self, w, TRUE, FALSE) ){
 755                                 if ( self.weapon == w){
 756                                         if( cvar("bot_ai_weapon_combo") && af > combo_time)
 757                                                 continue;
 758                                 } else {
 759                                         self.switchweapon = w;
 760                                 }
 761                                 return;
 762                         }
 763                 }
 764                 // If now weapon was chosen by this system fall back to the previous one
 765         }
 766
 767         // Formula:
 768         //      (Damage/Sec * Weapon spefic change to get that damage)
 769         //      *(Time to get to target * weapon specfic hitchange bonus) / (in a time of maxdelaytime)
 770         //      *(Spread change of hit) // if it applies
 771         //      *(Penality for target beeing in air)
 772         // %weaponaddpoint
 773         if (client_hasweapon(self, WEP_MINSTANEX, TRUE, FALSE))
 774                 minstanex = (1000/cvar("g_balance_minstanex_refire")*1.0)
 775                         * (0.5);
 776
 777         if (client_hasweapon(self, WEP_ROCKET_LAUNCHER, TRUE, FALSE)  &&
 778                 !(      cvar("bot_ai_weapon_combo") && self.weapon == WEP_ROCKET_LAUNCHER &&
 779                         af > combo_time
 780                 )
 781         )
 782                 rocket = (cvar("g_balance_rocketlauncher_damage")/cvar("g_balance_rocketlauncher_refire")*0.75)
 783                         * bound(0,(cvar("g_balance_rocketlauncher_speed")/distance*maxdelaytime),1)*1.5;
 784
 785         if (client_hasweapon(self, WEP_NEX, TRUE, FALSE)  &&
 786                 !(      cvar("bot_ai_weapon_combo") && self.weapon == WEP_NEX &&
 787                         af > combo_time
 788                 )
 789         )
 790                 nex = (cvar("g_balance_nex_damage")/cvar("g_balance_nex_refire")*1.0)
 791                         * (0.5);
 792
 793         if (client_hasweapon(self, WEP_HAGAR, TRUE, FALSE) ) // &&
 794         //      !( cvar("bot_ai_weapon_combo") && self.weapon == WEP_HAGAR &&  time < self.bot_lastshot + cvar("g_balance_hagar_primary_refire") ))
 795                 hagar = (cvar("g_balance_hagar_primary_damage")/cvar("g_balance_hagar_primary_refire")*1.0)
 796                         * bound(0,(cvar("g_balance_hagar_primary_speed")/distance*maxdelaytime),1)*0.2;
 797
 798         if (client_hasweapon(self, WEP_GRENADE_LAUNCHER, TRUE, FALSE) &&
 799                 !(
 800                         cvar("bot_ai_weapon_combo") && self.weapon == WEP_GRENADE_LAUNCHER &&
 801                         af > combo_time
 802                 )
 803         )
 804                 grenade = (cvar("g_balance_grenadelauncher_primary_damage")/cvar("g_balance_grenadelauncher_primary_refire")*1.0)
 805                         * bound(0,(cvar("g_balance_grenadelauncher_primary_speed")/distance*maxdelaytime),1)*1.1;
 806
 807         if (client_hasweapon(self, WEP_ELECTRO, TRUE, FALSE) &&
 808                 !(      cvar("bot_ai_weapon_combo") && self.weapon == WEP_ELECTRO &&
 809                         af > combo_time
 810                 )
 811         )
 812                 electro = (cvar("g_balance_electro_primary_damage")/cvar("g_balance_electro_primary_refire")*0.75)
 813                         * bound(0,(cvar("g_balance_electro_primary_speed")/distance*maxdelaytime),1)*1.0;
 814
 815         if (client_hasweapon(self, WEP_CRYLINK, TRUE, FALSE) ) // &&
 816         //      !( self.weapon == WEP_CRYLINK &&  time < self.bot_lastshot + cvar("g_balance_crylink_primary_refire") ))
 817                 crylink = (cvar("g_balance_crylink_primary_damage")/cvar("g_balance_crylink_primary_refire")*1.0)
 818                         * bound(0,(cvar("g_balance_crylink_primary_speed")/distance*maxdelaytime),1)*(64/(32+cvar("g_balance_crylink_primary_spread")*distance))*1.0;
 819
 820         if (client_hasweapon(self, WEP_UZI, TRUE, FALSE) ) // &&
 821         //      !( self.weapon == WEP_UZI &&  time < self.bot_lastshot + cvar("g_balance_uzi_sustained_refire") ))
 822                 uzi = (cvar("g_balance_uzi_sustained_damage")/cvar("g_balance_uzi_sustained_refire")*1.0)
 823                         * bound(0,32/(32+cvar("g_balance_uzi_sustained_spread")*distance),1);
 824
 825         if (client_hasweapon(self, WEP_SHOTGUN, TRUE, FALSE) &&
 826                 !(      cvar("bot_ai_weapon_combo") && self.weapon == WEP_SHOTGUN &&
 827                         af > combo_time
 828                 )
 829         )
 830                 shotgun = (cvar("g_balance_shotgun_primary_damage")*cvar("g_balance_shotgun_primary_bullets")/cvar("g_balance_shotgun_primary_refire")*1.0)
 831                         * bound(0,32/(32+cvar("g_balance_shotgun_primary_spread")*distance),1);
 832
 833         if (client_hasweapon(self, WEP_LASER, FALSE, FALSE) &&
 834                 !(      cvar("bot_ai_weapon_combo") && self.weapon == WEP_LASER &&
 835                         af > combo_time
 836                 )
 837         )
 838                 laser = (cvar("g_balance_laser_primary_damage")/cvar("g_balance_laser_primary_refire")*1.0)
 839                         * bound(0,cvar("g_balance_laser_primary_speed")/distance*maxdelaytime,1);
 840
 841         if((self.enemy.flags & FL_ONGROUND)==FALSE){
 842                 rocket = rocket   * (1.5-bound(0, distancefromfloor/cvar("g_balance_rocketlauncher_radius"         ),0.9)); //slight bigger change
 843                 grenade = grenade * (1.5-bound(0,distancefromfloor/cvar("g_balance_grenadelauncher_primary_radius"),0.95));
 844                 electro = electro * (1.5-bound(0,distancefromfloor/cvar("g_balance_electro_primary_radius"        ),0.95));
 845                 laser = laser     * (1.5-bound(0,distancefromfloor/cvar("g_balance_laser_primary_radius"                  ),0.95));
 846         }
 847         /*
 848         dprint("Floor distance: ",ftos(distancefromfloor),"\n");
 849         dprint("Rocket: " , ftos(rocket  ), "\n");
 850         dprint("Nex: "    , ftos(nex     ), "\n");
 851         dprint("Hagar: "  , ftos(hagar   ), "\n");
 852         dprint("Grenade: ", ftos(grenade ), "\n");
 853         dprint("Electro: ", ftos(electro ), "\n");
 854         dprint("Crylink: ", ftos(crylink ), "\n");
 855         dprint("Uzi: "    , ftos(uzi     ), "\n");
 856         dprint("Shotgun :", ftos(shotgun ), "\n");
 857         dprint("Laser   :", ftos(laser   ), "\n\n");
 858         */
 859         currentscore = -1;
 860         w = WEP_MINSTANEX        ;s = minstanex;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 861         w = WEP_ROCKET_LAUNCHER  ;s = rocket   ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 862         w = WEP_NEX              ;s = nex      ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 863         w = WEP_HAGAR            ;s = hagar    ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 864         w = WEP_GRENADE_LAUNCHER ;s = grenade  ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 865         w = WEP_ELECTRO          ;s = electro  ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 866         w = WEP_CRYLINK          ;s = crylink  ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 867         w = WEP_UZI              ;s = uzi      ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 868         w = WEP_SHOTGUN          ;s = shotgun  ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 869         w = WEP_LASER            ;s = laser    ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 870
 871         // switch if the best weapon would provide a significant damage increase
 872         if (bestscore > currentscore*1.5){
 873                 self.switchweapon = bestweapon;
 874
 875                 // buys time for detonating the rocket. not tested yet
 876                 if ( cvar("bot_ai_weapon_combo") && bestweapon == WEP_ROCKET_LAUNCHER )
 877                         self.bot_chooseweapontime += (distance  / cvar("g_balance_rocketlauncher_speed"));
 878         }
 879 };
 880
 881 .float nextaim;
 882 void havocbot_aim()
 883 {
 884         local vector selfvel, enemyvel;
 885 //      if(self.flags & FL_INWATER)
 886 //              return;
 887         if (time < self.nextaim)
 888                 return;
 889         self.nextaim = time + 0.1;
 890         selfvel = self.velocity;
 891         if (!self.waterlevel)
 892                 selfvel_z = 0;
 893         if (self.enemy)
 894         {
 895                 enemyvel = self.enemy.velocity;
 896                 if (!self.enemy.waterlevel)
 897                         enemyvel_z = 0;
 898                 lag_additem(time + self.ping, 0, 0, self.enemy, self.origin, selfvel, self.enemy.origin, enemyvel);
 899         }
 900         else
 901                 lag_additem(time + self.ping, 0, 0, world, self.origin, selfvel, self.goalcurrent.origin, '0 0 0');
 902 };
 903
 904 void havocbot_ai()
 905 {
 906         if (bot_strategytoken == self)
 907         if (!bot_strategytoken_taken)
 908         {
 909                 self.havocbot_role();
 910
 911                 // TODO: tracewalk() should take care of this job (better path finding under water)
 912                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
 913                 if(self.goalcurrent==world)
 914                 if(self.waterlevel==WATERLEVEL_SWIMMING || self.aistatus & AI_STATUS_OUT_WATER)
 915                 {
 916                         // Look for the closest waypoint out of water
 917                         local entity newgoal, head;
 918                         local float bestdistance, distance;
 919
 920                         newgoal = world;
 921                         bestdistance = 10000;
 922                         for (head = findchain(classname, "waypoint"); head; head = head.chain)
 923                         {
 924                                 distance = vlen(head.origin - self.origin);
 925                                 if(distance>10000)
 926                                         continue;
 927
 928                                 if(head.origin_z < self.origin_z)
 929                                         continue;
 930
 931                                 if(head.origin_z - self.origin_z - self.view_ofs_z > 100)
 932                                         continue;
 933
 934                                 if (pointcontents(head.origin + head.maxs + '0 0 1') != CONTENT_EMPTY)
 935                                         continue;
 936
 937                                 traceline(self.origin + self.view_ofs , head.origin, TRUE, head);
 938
 939                                 if(trace_fraction<1)
 940                                         continue;
 941
 942                                 if(distance<bestdistance)
 943                                 {
 944                                         newgoal = head;
 945                                         bestdistance = distance;
 946                                 }
 947                         }
 948
 949                         if(newgoal)
 950                         {
 951                         //      te_wizspike(newgoal.origin);
 952                                 navigation_pushroute(newgoal);
 953                         }
 954                 }
 955
 956                 // token has been used this frame
 957                 bot_strategytoken_taken = TRUE;
 958         }
 959         havocbot_chooseenemy();
 960         if (self.bot_chooseweapontime < time )
 961         {
 962                 self.bot_chooseweapontime = time + cvar("bot_ai_chooseweaponinterval");
 963                 havocbot_chooseweapon();
 964         }
 965         havocbot_aim();
 966         lag_update();
 967         if (self.bot_aimtarg)
 968         {
 969                 self.aistatus |= AI_STATUS_ATTACKING;
 970                 self.aistatus &~= AI_STATUS_ROAMING;
 971
 972                 weapon_action(self.weapon, WR_AIM);
 973                 if (cvar("bot_nofire") || IS_INDEPENDENT_PLAYER(self))
 974                 {
 975                         self.BUTTON_ATCK = FALSE;
 976                         self.BUTTON_ATCK2 = FALSE;
 977                 }
 978         }
 979         else if (self.goalcurrent)
 980         {
 981                 self.aistatus |= AI_STATUS_ROAMING;
 982                 self.aistatus &~= AI_STATUS_ATTACKING;
 983
 984                 local vector now,v,next;//,heading;
 985                 local float aimdistance,skillblend,distanceblend,blend;
 986                 next = now = self.goalcurrent.origin - (self.origin + self.view_ofs);
 987                 aimdistance = vlen(now);
 988                 //heading = self.velocity;
 989                 //dprint(self.goalstack01.classname,etos(self.goalstack01),"\n");
 990                 if(self.goalstack01 != self && self.goalstack01 != world && self.aistatus & AI_STATUS_RUNNING == 0)
 991                         next = self.goalstack01.origin - (self.origin + self.view_ofs);
 992                 skillblend=bound(0,(skill-2.5)*0.5,1); //lower skill player can't preturn
 993                 distanceblend=bound(0,aimdistance/cvar("bot_ai_keyboard_distance"),1);
 994                 blend = skillblend * (1-distanceblend);
 995                 //v = (now * (distanceblend) + next * (1-distanceblend)) * (skillblend) + now * (1-skillblend);
 996                 //v = now * (distanceblend) * (skillblend) + next * (1-distanceblend) * (skillblend) + now * (1-skillblend);
 997                 //v = now * ((1-skillblend) + (distanceblend) * (skillblend)) + next * (1-distanceblend) * (skillblend);
 998                 v = now + blend * (next - now);
 999                 //dprint(etos(self), " ");
1000                 //dprint(vtos(now), ":", vtos(next), "=", vtos(v), " (blend ", ftos(blend), ")\n");
1001                 //v = now * (distanceblend) + next * (1-distanceblend);
1002                 if (self.waterlevel < WATERLEVEL_SWIMMING)
1003                         v_z = 0;
1004                 //dprint("walk at:", vtos(v), "\n");
1005                 //te_lightning2(world, self.origin, self.goalcurrent.origin);
1006                 bot_aimdir(v, -1);
1007         }
1008         havocbot_movetogoal();
1009 };
1010
1011 void havocbot_setupbot()
1012 {
1013         self.bot_ai = havocbot_ai;
1014         // will be updated by think code
1015         //Generate some random skill levels
1016         self.havocbot_keyboardskill=random()-0.5;
1017         havocbot_chooserole();
1018 }
1019
1020
1021 #ifdef DEBUG_BOT_GOALSTACK
1022
1023 .float goalcounter;
1024 .vector lastposition;
1025
1026 // Debug the goal stack visually
1027 void debuggoalstack()
1028 {
1029         local entity target;
1030         local vector org;
1031
1032         if(self.goalcounter==0)target=self.goalcurrent;
1033         else if(self.goalcounter==1)target=self.goalstack01;
1034         else if(self.goalcounter==2)target=self.goalstack02;
1035         else if(self.goalcounter==3)target=self.goalstack03;
1036         else if(self.goalcounter==4)target=self.goalstack04;
1037         else if(self.goalcounter==5)target=self.goalstack05;
1038         else if(self.goalcounter==6)target=self.goalstack06;
1039         else if(self.goalcounter==7)target=self.goalstack07;
1040         else if(self.goalcounter==8)target=self.goalstack08;
1041         else if(self.goalcounter==9)target=self.goalstack09;
1042         else if(self.goalcounter==10)target=self.goalstack10;
1043         else if(self.goalcounter==11)target=self.goalstack11;
1044         else if(self.goalcounter==12)target=self.goalstack12;
1045         else if(self.goalcounter==13)target=self.goalstack13;
1046         else if(self.goalcounter==14)target=self.goalstack14;
1047         else if(self.goalcounter==15)target=self.goalstack15;
1048         else if(self.goalcounter==16)target=self.goalstack16;
1049         else if(self.goalcounter==17)target=self.goalstack17;
1050         else if(self.goalcounter==18)target=self.goalstack18;
1051         else if(self.goalcounter==19)target=self.goalstack19;
1052         else if(self.goalcounter==20)target=self.goalstack20;
1053         else if(self.goalcounter==21)target=self.goalstack21;
1054         else if(self.goalcounter==22)target=self.goalstack22;
1055         else if(self.goalcounter==23)target=self.goalstack23;
1056         else if(self.goalcounter==24)target=self.goalstack24;
1057         else if(self.goalcounter==25)target=self.goalstack25;
1058         else if(self.goalcounter==26)target=self.goalstack26;
1059         else if(self.goalcounter==27)target=self.goalstack27;
1060         else if(self.goalcounter==28)target=self.goalstack28;
1061         else if(self.goalcounter==29)target=self.goalstack29;
1062         else if(self.goalcounter==30)target=self.goalstack30;
1063         else if(self.goalcounter==31)target=self.goalstack31;
1064
1065         if(target==world)
1066         {
1067                 self.goalcounter = 0;
1068                 self.lastposition='0 0 0';
1069                 return;
1070         }
1071
1072         if(self.lastposition=='0 0 0')
1073                 org = self.origin;
1074         else
1075                 org = self.lastposition;
1076
1077
1078         te_lightning2(world, org, target.origin);
1079         self.lastposition = target.origin;
1080
1081         self.goalcounter++;
1082 }
1083
1084 #endif