data/qcsrc/server/havocbot.qc

   1 .void() havocbot_role;
   2 void() havocbot_chooserole;
   3 .float havocbot_keyboardskill;
   4 .float facingwalltime, ignoregoaltime;
   5 .entity ignoregoal;
   6
   7 #ifdef DEBUG_BOT_GOALSTACK
   8 void debuggoalstack();
   9 #endif
  10
  11 vector havocbot_dodge()
  12 {
  13         // LordHavoc: disabled because this is too expensive
  14         return '0 0 0';
  15         /*
  16         local entity head;
  17         local vector dodge, v, n;
  18         local float danger, bestdanger, vl, d;
  19         dodge = '0 0 0';
  20         bestdanger = -20;
  21         // check for dangerous objects near bot or approaching bot
  22         head = findchainfloat(bot_dodge, TRUE);
  23         while(head)
  24         {
  25                 if (head.owner != self)
  26                 {
  27                         vl = vlen(head.velocity);
  28                         if (vl > sv_maxspeed * 0.3)
  29                         {
  30                                 n = normalize(head.velocity);
  31                                 v = self.origin - head.origin;
  32                                 d = v * n;
  33                                 if (d > (0 - head.bot_dodgerating))
  34                                 if (d < (vl * 0.2 + head.bot_dodgerating))
  35                                 {
  36                                         // calculate direction and distance from the flight path, by removing the forward axis
  37                                         v = v - (n * (v * n));
  38                                         danger = head.bot_dodgerating - vlen(v);
  39                                         if (bestdanger < danger)
  40                                         {
  41                                                 bestdanger = danger;
  42                                                 // dodge to the side of the object
  43                                                 dodge = normalize(v);
  44                                         }
  45                                 }
  46                         }
  47                         else
  48                         {
  49                                 danger = head.bot_dodgerating - vlen(head.origin - self.origin);
  50                                 if (bestdanger < danger)
  51                                 {
  52                                         bestdanger = danger;
  53                                         dodge = normalize(self.origin - head.origin);
  54                                 }
  55                         }
  56                 }
  57                 head = head.chain;
  58         }
  59         return dodge;
  60         */
  61 };
  62
  63 .float havocbot_keyboardtime;
  64 .float havocbot_ducktime;
  65 .vector havocbot_keyboard;
  66 void havocbot_keyboard_movement(vector destorg)
  67 {
  68         local vector keyboard;
  69         local float blend, maxspeed;
  70
  71         maxspeed = cvar("sv_maxspeed");
  72
  73         if (time < self.havocbot_keyboardtime)
  74                 return;
  75
  76         self.havocbot_keyboardtime =
  77                 max(
  78                         self.havocbot_keyboardtime
  79                                 + bound(0,0.05/(skill+self.havocbot_keyboardskill),0.05)
  80                                 +random()*bound(0,0.025/(skill+self.havocbot_keyboardskill),100)
  81                 , time);
  82         keyboard = self.movement * (1.0 / maxspeed);
  83
  84         local float trigger, trigger1;
  85         blend = bound(0,skill*0.1,1);
  86         trigger = cvar("bot_ai_keyboard_treshold");
  87         trigger1 = 0 - trigger;
  88
  89         // categorize forward movement
  90         // at skill < 1.5 only forward
  91         // at skill < 2.5 only individual directions
  92         // at skill < 4.5 only individual directions, and forward diagonals
  93         // at skill >= 4.5, all cases allowed
  94         if (keyboard_x > trigger)
  95         {
  96                 keyboard_x = 1;
  97                 if (skill < 2.5)
  98                         keyboard_y = 0;
  99         }
 100         else if (keyboard_x < trigger1 && skill > 1.5)
 101         {
 102                 keyboard_x = -1;
 103                 if (skill < 4.5)
 104                         keyboard_y = 0;
 105         }
 106         else
 107         {
 108                 keyboard_x = 0;
 109                 if (skill < 1.5)
 110                         keyboard_y = 0;
 111         }
 112         if (skill < 4.5)
 113                 keyboard_z = 0;
 114
 115         if (keyboard_y > trigger)
 116                 keyboard_y = 1;
 117         else if (keyboard_y < trigger1)
 118                 keyboard_y = -1;
 119         else
 120                 keyboard_y = 0;
 121
 122         if (keyboard_z > trigger)
 123                 keyboard_z = 1;
 124         else if (keyboard_z < trigger1)
 125                 keyboard_z = -1;
 126         else
 127                 keyboard_z = 0;
 128
 129         self.havocbot_keyboard = keyboard * maxspeed;
 130         if (self.havocbot_ducktime>time) self.BUTTON_CROUCH=TRUE;
 131
 132         keyboard = self.havocbot_keyboard;
 133         blend = bound(0,vlen(destorg-self.origin)/cvar("bot_ai_keyboard_distance"),1); // When getting close move with 360 degree
 134         //dprint("movement ", vtos(self.movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 135         self.movement = self.movement + (keyboard - self.movement) * blend;
 136 };
 137
 138 .entity bot_lastseengoal;
 139 .float bot_timelastseengoal;
 140 .float bot_canruntogoal;
 141 void havocbot_bunnyhop(vector dir)
 142 {
 143         local float bunnyhopdistance;
 144         local vector deviation;
 145         local float maxspeed;
 146
 147         if(self.goalcurrent.classname == "player")
 148                 return;
 149
 150         maxspeed = cvar("sv_maxspeed");
 151
 152         if(self.aistatus & AI_STATUS_DANGER_AHEAD)
 153         {
 154                 self.aistatus &~= AI_STATUS_RUNNING;
 155                 self.BUTTON_JUMP = FALSE;
 156                 return;
 157         }
 158
 159         if(self.waterlevel > WATERLEVEL_WETFEET)
 160         {
 161                 self.aistatus &~= AI_STATUS_RUNNING;
 162                 return;
 163         }
 164
 165         if(self.bot_lastseengoal != self.goalcurrent && !(self.aistatus & AI_STATUS_RUNNING))
 166         {
 167                 self.bot_canruntogoal = 0;
 168                 self.bot_timelastseengoal = 0;
 169         }
 170
 171         bunnyhopdistance = vlen(self.origin - self.goalcurrent.origin);
 172
 173         // Run only to visible goals
 174         if(self.flags & FL_ONGROUND)
 175         if(self.speed==maxspeed)
 176         if(checkpvs(self.origin + self.view_ofs, self.goalcurrent))
 177         {
 178                         self.bot_lastseengoal = self.goalcurrent;
 179
 180                         // seen it before
 181                         if(self.bot_timelastseengoal)
 182                         {
 183                                 // for a period of time
 184                                 if(time - self.bot_timelastseengoal > cvar("bot_ai_bunnyhop_firstjumpdelay"))
 185                                 {
 186                                         local float checkdistance;
 187                                         checkdistance = TRUE;
 188
 189                                         // don't run if it is too close
 190                                         if(self.bot_canruntogoal==0)
 191                                         {
 192                                                 if(bunnyhopdistance > cvar("bot_ai_bunnyhop_startdistance"))
 193                                                         self.bot_canruntogoal = 1;
 194                                                 else
 195                                                         self.bot_canruntogoal = -1;
 196                                         }
 197
 198                                         if(self.bot_canruntogoal != 1)
 199                                                 return;
 200
 201                                         if(self.aistatus & AI_STATUS_ROAMING)
 202                                         if(self.goalcurrent.classname=="waypoint")
 203                                         if(fabs(self.goalcurrent.origin_z - self.origin_z) < self.maxs_z - self.mins_z)
 204                                         if(self.goalstack01!=world)
 205                                         {
 206                                                 deviation = vectoangles(self.goalstack01.origin - self.origin) - vectoangles(self.goalcurrent.origin - self.origin);
 207                                                 while (deviation_y < -180) deviation_y = deviation_y + 360;
 208                                                 while (deviation_y > 180) deviation_y = deviation_y - 360;
 209
 210                                                 if(fabs(deviation_y) < 20)
 211                                                 if(bunnyhopdistance < vlen(self.origin - self.goalstack01.origin))
 212                                                 if(fabs(self.goalstack01.origin_z - self.goalcurrent.origin_z) < self.maxs_z - self.mins_z)
 213                                                 {
 214                                                         if(vlen(self.goalcurrent.origin - self.goalstack01.origin) > cvar("bot_ai_bunnyhop_startdistance"))
 215                                                         if(checkpvs(self.origin + self.view_ofs, self.goalstack01))
 216                                                         {
 217                                                                 checkdistance = FALSE;
 218                                                         }
 219                                                 }
 220                                         }
 221
 222                                         if(checkdistance)
 223                                         {
 224                                                 self.aistatus &~= AI_STATUS_RUNNING;
 225                                                 if(bunnyhopdistance > cvar("bot_ai_bunnyhop_stopdistance"))
 226                                                         self.BUTTON_JUMP = TRUE;
 227                                         }
 228                                         else
 229                                         {
 230                                                 self.aistatus |= AI_STATUS_RUNNING;
 231                                                 self.BUTTON_JUMP = TRUE;
 232                                         }
 233                                 }
 234                         }
 235                         else
 236                         {
 237                                 self.bot_timelastseengoal = time;
 238                         }
 239         }
 240         else
 241         {
 242                 self.bot_timelastseengoal = 0;
 243         }
 244
 245         // Release jump button
 246         if(self.flags & FL_ONGROUND == 0)
 247         {
 248                 if(self.velocity_z < 0 || vlen(self.velocity)<maxspeed)
 249                         self.BUTTON_JUMP = FALSE;
 250
 251                 // Strafe
 252                 if(self.aistatus & AI_STATUS_RUNNING)
 253                 if(vlen(self.velocity)>maxspeed)
 254                 {
 255                         deviation = vectoangles(dir) - vectoangles(self.velocity);
 256                         while (deviation_y < -180) deviation_y = deviation_y + 360;
 257                         while (deviation_y > 180) deviation_y = deviation_y - 360;
 258
 259                         if(fabs(deviation_y)>10)
 260                                 self.movement_x = 0;
 261
 262                         if(deviation_y>10)
 263                                 self.movement_y = maxspeed * -1;
 264                         else if(deviation_y<10)
 265                                 self.movement_y = maxspeed;
 266
 267                 }
 268         }
 269 };
 270
 271 //.float havocbotignoretime;
 272 //.vector bot_dodgevector;
 273 //.float bot_dodgevector_time;
 274 //.float bot_dodgevector_jumpbutton;
 275 .float ladder_time;
 276 .entity ladder_entity;
 277 void havocbot_movetogoal()
 278 {
 279         local vector destorg;
 280         local vector diff;
 281         local vector dir;
 282         local vector flatdir;
 283         local vector m1;
 284         local vector m2;
 285         local vector evadeobstacle;
 286         local vector evadelava;
 287         local float s;
 288         local float maxspeed;
 289         //local float dist;
 290         local vector dodge;
 291         //if (self.goalentity)
 292         //      te_lightning2(self, self.origin, (self.goalentity.absmin + self.goalentity.absmax) * 0.5);
 293         self.movement = '0 0 0';
 294         maxspeed = cvar("sv_maxspeed");
 295
 296         if(self.jumppadcount)
 297         {
 298                 if(self.flags & FL_ONGROUND)
 299                 {
 300                         self.jumppadcount = FALSE;
 301                         if(self.aistatus & AI_STATUS_OUT_JUMPPAD)
 302                                 self.aistatus &~= AI_STATUS_OUT_JUMPPAD;
 303                 }
 304
 305                 // If got stuck on the jump pad try to reach the farther visible item
 306                 if(self.aistatus & AI_STATUS_OUT_JUMPPAD)
 307                 {
 308                         if(fabs(self.velocity_z)<50)
 309                         {
 310                                 local entity head, newgoal;
 311                                 local float distance, bestdistance;
 312
 313                                 for (head = findchainfloat(bot_pickup, TRUE); head; head = head.chain)
 314                                 {
 315                                         if(head.classname=="worldspawn")
 316                                                 continue;
 317
 318                                         distance = vlen(head.origin - self.origin);
 319                                         if(distance>1000)
 320                                                 continue;
 321
 322                                         traceline(self.origin + self.view_ofs , head.origin, TRUE, world);
 323
 324                                         if(trace_fraction<1)
 325                                                 continue;
 326
 327                                         if(distance>bestdistance)
 328                                         {
 329                                                 newgoal = head;
 330                                                 bestdistance = distance;
 331                                         }
 332                                 }
 333
 334                                 if(newgoal)
 335                                 {
 336                                         self.ignoregoal = self.goalcurrent;
 337                                         self.ignoregoaltime = time + cvar("bot_ai_ignoregoal_timeout");
 338                                         navigation_routetogoal(newgoal);
 339                                         self.aistatus &~= AI_STATUS_OUT_JUMPPAD;
 340                                 }
 341                         }
 342                         else
 343                                 return;
 344                 }
 345                 else
 346                 {
 347                         if(self.velocity_z>0)
 348                         {
 349                                 local float threshold;
 350                                 threshold = maxspeed * 0.2;
 351                                 if(fabs(self.velocity_x) < threshold  &&  fabs(self.velocity_y) < threshold)
 352                                         self.aistatus |= AI_STATUS_OUT_JUMPPAD;
 353                                 return;
 354                         }
 355                 }
 356         }
 357
 358         // If we are under water with no goals, swim up
 359         if(self.waterlevel)
 360         if(self.goalcurrent==world)
 361         {
 362                 dir = '0 0 0';
 363                 if(self.waterlevel>WATERLEVEL_SWIMMING)
 364                         dir_z = 1;
 365                 else if(self.velocity_z >= 0 && !(self.waterlevel == WATERLEVEL_WETFEET && self.watertype == CONTENT_WATER))
 366                         self.BUTTON_JUMP = TRUE;
 367                 else
 368                         self.BUTTON_JUMP = FALSE;
 369                 makevectors(self.v_angle_y * '0 1 0');
 370                 self.movement_x = dir * v_forward * maxspeed;
 371                 self.movement_y = dir * v_right * maxspeed;
 372                 self.movement_z = dir * v_up * maxspeed;
 373         }
 374
 375         // if there is nowhere to go, exit
 376         if (self.goalcurrent == world)
 377                 return;
 378
 379         if (self.goalcurrent)
 380                 navigation_poptouchedgoals();
 381
 382         // if ran out of goals try to use an alternative goal or get a new strategy asap
 383         if(self.goalcurrent == world)
 384         if(self.flags & FL_ONGROUND || self.aistatus & AI_STATUS_RUNNING || self.BUTTON_JUMP == TRUE)
 385         {
 386                 if(self.alternativegoal==world)
 387                 {
 388                         // ran out of goals
 389                         self.bot_strategytime = 0;
 390                         return;
 391                 }
 392
 393                 // use the alternative goal
 394                 navigation_findnearestwaypoint(self.alternativegoal, TRUE);
 395                 navigation_routetogoal(self.alternativegoal);
 396                 self.alternativegoal = world;
 397                 bot_strategytoken_taken = TRUE;
 398
 399                 return;
 400         }
 401
 402 #ifdef DEBUG_BOT_GOALSTACK
 403         debuggoalstack();
 404 #endif
 405
 406         m1 = self.goalcurrent.origin + self.goalcurrent.mins;
 407         m2 = self.goalcurrent.origin + self.goalcurrent.maxs;
 408         destorg = self.origin;
 409         destorg_x = bound(m1_x, destorg_x, m2_x);
 410         destorg_y = bound(m1_y, destorg_y, m2_y);
 411         destorg_z = bound(m1_z, destorg_z, m2_z);
 412         diff = destorg - self.origin;
 413         //dist = vlen(diff);
 414         dir = normalize(diff);
 415         flatdir = diff;flatdir_z = 0;
 416         flatdir = normalize(flatdir);
 417
 418         //if (self.bot_dodgevector_time < time)
 419         {
 420         //      self.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 421         //      self.bot_dodgevector_jumpbutton = 1;
 422                 evadeobstacle = '0 0 0';
 423                 evadelava = '0 0 0';
 424
 425                 if (self.waterlevel)
 426                 {
 427                         if(self.waterlevel>WATERLEVEL_SWIMMING)
 428                         {
 429                         //      flatdir_z = 1;
 430                                 self.aistatus |= AI_STATUS_OUT_WATER;
 431                         }
 432                         else
 433                         {
 434                                 if(self.velocity_z >= 0 && !(self.watertype == CONTENT_WATER && self.goalcurrent.origin_z < self.origin_z) &&
 435                                         ( !(self.waterlevel == WATERLEVEL_WETFEET && self.watertype == CONTENT_WATER) || self.aistatus & AI_STATUS_OUT_WATER))
 436                                         self.BUTTON_JUMP = TRUE;
 437                                 else
 438                                         self.BUTTON_JUMP = FALSE;
 439                         }
 440                         dir = normalize(flatdir);
 441                         makevectors(self.v_angle_y * '0 1 0');
 442                 }
 443                 else
 444                 {
 445                         if(self.aistatus & AI_STATUS_OUT_WATER)
 446                                 self.aistatus &~= AI_STATUS_OUT_WATER;
 447
 448                         // jump if going toward an obstacle that doesn't look like stairs we
 449                         // can walk up directly
 450                         tracebox(self.origin, self.mins, self.maxs, self.origin + self.velocity * 0.2, FALSE, self);
 451                         if (trace_fraction < 1)
 452                         if (trace_plane_normal_z < 0.7)
 453                         {
 454                                 s = trace_fraction;
 455                                 tracebox(self.origin + '0 0 16', self.mins, self.maxs, self.origin + self.velocity * 0.2 + '0 0 16', FALSE, self);
 456                                 if (trace_fraction < s + 0.01)
 457                                 if (trace_plane_normal_z < 0.7)
 458                                 {
 459                                         s = trace_fraction;
 460                                         tracebox(self.origin + '0 0 48', self.mins, self.maxs, self.origin + self.velocity * 0.2 + '0 0 48', FALSE, self);
 461                                         if (trace_fraction > s)
 462                                                 self.BUTTON_JUMP = 1;
 463                                 }
 464                         }
 465
 466                         // avoiding dangers and obstacles
 467                         local vector dst_ahead, dst_down;
 468                         dst_ahead = self.origin + self.view_ofs + (self.velocity * 0.32);
 469                         dst_down = dst_ahead + '0 0 -1500';
 470
 471                         // Look ahead
 472                         traceline(self.origin + self.view_ofs , dst_ahead, TRUE, world);
 473
 474                         // Check head-banging against walls
 475                         if(vlen(self.origin + self.view_ofs - trace_endpos) < 2 && !(self.aistatus & AI_STATUS_OUT_WATER))
 476                         {
 477                                 if(self.facingwalltime && time > self.facingwalltime)
 478                                 {
 479                                         self.ignoregoal = self.goalcurrent;
 480                                         self.ignoregoaltime = time + cvar("bot_ai_ignoregoal_timeout");
 481                                         navigation_poproute();
 482                                 }
 483                                 else
 484                                 {
 485                                         self.facingwalltime = time + 0.05;
 486                                 }
 487                         }
 488                         else
 489                         {
 490                                 self.facingwalltime = 0;
 491
 492                                 if(self.ignoregoal != world && time > self.ignoregoaltime)
 493                                 {
 494                                         self.ignoregoal = world;
 495                                         self.ignoregoaltime = 0;
 496                                 }
 497                         }
 498
 499                         // Check for water/slime/lava and dangerous edges
 500                         // (only when the bot is on the ground or jumping intentionally)
 501                         self.aistatus &~= AI_STATUS_DANGER_AHEAD;
 502
 503                         if(trace_fraction == 1)
 504                         if(self.flags & FL_ONGROUND || self.aistatus & AI_STATUS_RUNNING || self.BUTTON_JUMP == TRUE)
 505                         {
 506                                 // Look downwards
 507                                 traceline(dst_ahead , dst_down, TRUE, world);
 508                                 //      te_lightning2(world, self.origin, dst_ahead);   // Draw "ahead" look
 509                                 //      te_lightning2(world, dst_ahead, dst_down);              // Draw "downwards" look
 510                                 if(trace_endpos_z < self.origin_z + self.mins_z)
 511                                 {
 512                                         s = pointcontents(trace_endpos + '0 0 1');
 513                                         if (s != CONTENT_SOLID)
 514                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
 515                                                 evadelava = normalize(self.velocity) * -1;
 516                                         else if (s == CONTENT_SKY)
 517                                                 evadeobstacle = normalize(self.velocity) * -1;
 518                                         else if (!boxesoverlap(dst_ahead - self.view_ofs + self.mins, dst_ahead - self.view_ofs + self.maxs,
 519                                                                 self.goalcurrent.absmin, self.goalcurrent.absmax))
 520                                         {
 521                                                 // if ain't a safe goal with "holes" (like the jumpad on soylent)
 522                                                 // and there is a trigger_hurt below
 523                                                 if(tracebox_hits_trigger_hurt(dst_ahead, self.mins, self.maxs, trace_endpos))
 524                                                 {
 525                                                         // Remove dangerous dynamic goals from stack
 526                                                         if (self.goalcurrent.classname == "player" || self.goalcurrent.classname == "droppedweapon")
 527                                                                 navigation_poproute();
 528                                                         // try to stop
 529                                                         flatdir = '0 0 0';
 530                                                         evadeobstacle = normalize(self.velocity) * -1;
 531                                                 }
 532                                         }
 533                                 }
 534                         }
 535
 536                         dir = flatdir;
 537                         evadeobstacle_z = 0;
 538                         evadelava_z = 0;
 539                         makevectors(self.v_angle_y * '0 1 0');
 540
 541                         if(evadeobstacle!='0 0 0'||evadelava!='0 0 0')
 542                                 self.aistatus |= AI_STATUS_DANGER_AHEAD;
 543                 }
 544
 545                 dodge = havocbot_dodge();
 546                 dodge = dodge * bound(0,3+skill*0.1,1);
 547                 evadelava = evadelava * bound(1,3-skill,3); //Noobs fear lava a lot and take more distance from it
 548                 traceline(self.origin, self.enemy.origin, TRUE, world);
 549                 if(trace_ent.classname == "player")
 550                         dir = dir * bound(0,skill/7,1);
 551
 552                 dir = normalize(dir + dodge + evadeobstacle + evadelava);
 553         //      self.bot_dodgevector = dir;
 554         //      self.bot_dodgevector_jumpbutton = self.BUTTON_JUMP;
 555         }
 556
 557         if(time < self.ladder_time)
 558         {
 559                 if(self.goalcurrent.origin_z + self.goalcurrent.mins_z > self.origin_z + self.mins_z)
 560                 {
 561                         if(self.origin_z + self.mins_z  < self.ladder_entity.origin_z + self.ladder_entity.maxs_z)
 562                                 dir = '0 0 1';
 563                 }
 564                 else
 565                 {
 566                         if(self.origin_z + self.mins_z  > self.ladder_entity.origin_z + self.ladder_entity.mins_z)
 567                                 dir = '0 0 -1';
 568                 }
 569         }
 570
 571         //dir = self.bot_dodgevector;
 572         //if (self.bot_dodgevector_jumpbutton)
 573         //      self.BUTTON_JUMP = 1;
 574         self.movement_x = dir * v_forward * maxspeed;
 575         self.movement_y = dir * v_right * maxspeed;
 576         self.movement_z = dir * v_up * maxspeed;
 577
 578         // Emulate keyboard interface
 579         if (skill < 10)
 580                 havocbot_keyboard_movement(destorg);
 581
 582         // Bunnyhop!
 583 //      if(self.aistatus & AI_STATUS_ROAMING)
 584         if(skill >= cvar("bot_ai_bunnyhop_skilloffset"))
 585                 havocbot_bunnyhop(dir);
 586
 587         if ((dir * v_up) >= cvar("sv_jumpvelocity")*0.5 && (self.flags & FL_ONGROUND)) self.BUTTON_JUMP=1;
 588         if (((dodge * v_up) > 0) && random()*frametime >= 0.2*bound(0,(10-skill)*0.1,1)) self.BUTTON_JUMP=TRUE;
 589         if (((dodge * v_up) < 0) && random()*frametime >= 0.5*bound(0,(10-skill)*0.1,1)) self.havocbot_ducktime=time+0.3/bound(0.1,skill,10);
 590 };
 591
 592 .float havocbot_chooseenemy_finished;
 593 .float havocbot_stickenemy;
 594 void havocbot_chooseenemy()
 595 {
 596         local entity head, best;
 597         local float rating, bestrating;
 598         local vector eye, v;
 599         if (cvar("bot_nofire") || IS_INDEPENDENT_PLAYER(self))
 600         {
 601                 self.enemy = world;
 602                 return;
 603         }
 604         if (self.enemy)
 605         {
 606                 if (!bot_shouldattack(self.enemy))
 607                 {
 608                         // enemy died or something, find a new target
 609                         self.enemy = world;
 610                         self.havocbot_chooseenemy_finished = time;
 611                 }
 612                 else if (self.havocbot_stickenemy)
 613                 {
 614                         // tracking last chosen enemy
 615                         // if enemy is visible
 616                         // and not really really far away
 617                         // and we're not severely injured
 618                         // then keep tracking for a half second into the future
 619                         traceline(self.origin+self.view_ofs, self.enemy.origin+self.enemy.view_ofs*0.5,FALSE,world);
 620                         if (trace_ent == self.enemy || trace_fraction == 1)
 621                         if (vlen(self.enemy.origin - self.origin) < 1000)
 622                         if (self.health > 30)
 623                         {
 624                                 // remain tracking him for a shot while (case he went after a small corner or pilar
 625                                 self.havocbot_chooseenemy_finished = time + cvar("bot_ai_enemydetectioninterval");
 626                                 return;
 627                         }
 628                         // enemy isn't visible, or is far away, or we're injured severely
 629                         // so stop preferring this enemy
 630                         // (it will still take a half second until a new one is chosen)
 631                         self.havocbot_stickenemy = 0;
 632                 }
 633         }
 634         if (time < self.havocbot_chooseenemy_finished)
 635                 return;
 636         self.havocbot_chooseenemy_finished = time + cvar("bot_ai_enemydetectioninterval");
 637         eye = (self.origin + self.view_ofs);
 638         best = world;
 639         bestrating = 100000000;
 640         head = findchainfloat(bot_attack, TRUE);
 641         while (head)
 642         {
 643                 v = (head.absmin + head.absmax) * 0.5;
 644                 rating = vlen(v - eye);
 645                 if (bestrating > rating)
 646                 if (bot_shouldattack(head))
 647                 {
 648                         traceline(eye, v, TRUE, self);
 649                         if (trace_ent == head || trace_fraction >= 1)
 650                         {
 651                                 best = head;
 652                                 bestrating = rating;
 653                         }
 654                 }
 655                 head = head.chain;
 656         }
 657         self.enemy = best;
 658         self.havocbot_stickenemy = TRUE;
 659 };
 660
 661 .float bot_chooseweapontime;
 662 float(entity e) w_getbestweapon;
 663 void havocbot_chooseweapon()
 664 {
 665         local float i;
 666
 667         // TODO: clean this up by moving it to weapon code
 668         if(self.enemy.classname!="player")
 669         {
 670                 // If there aren't enemies at sight use the laser (like most players)
 671                 if(client_hasweapon(self, WEP_LASER, TRUE, FALSE))
 672                 {
 673                         self.switchweapon = WEP_LASER;
 674                         return;
 675                 }
 676
 677                 // Otherwise get the first available weapon
 678                 for(i=WEP_LASER + 1; i < WEP_COUNT ; ++i)
 679                 {
 680                         if(client_hasweapon(self, i, TRUE, FALSE))
 681                         {
 682                                 self.switchweapon = i;
 683                                 return;
 684                         }
 685                 }
 686                 return;
 687         }
 688
 689         local float w, s;
 690         local float rocket  ; rocket   =-1000;
 691         local float nex     ; nex      =-1000;
 692         local float hagar   ; hagar    =-1000;
 693         local float grenade ; grenade  =-1000;
 694         local float electro ; electro  =-1000;
 695         local float crylink ; crylink  =-1000;
 696         local float uzi     ; uzi      =-1000;
 697         local float shotgun ; shotgun  =-1000;
 698         local float campingrifle ; campingrifle  =-1000;
 699         local float laser   ; laser    =-1000;
 700         local float minstanex ; minstanex =-1000;
 701         local float currentscore;
 702         local float bestscore; bestscore = 0;
 703         local float bestweapon; bestweapon=self.switchweapon;
 704         local float distance; distance=bound(10,vlen(self.origin-self.enemy.origin)-200,10000);
 705         local float maxdelaytime=0.5;
 706         local float spreadpenalty=10;
 707         local float distancefromfloor;
 708
 709         local float af, ct, combo_time;
 710
 711         traceline(self.enemy.origin,self.enemy.origin-'0 0 1000',TRUE,world);
 712         distancefromfloor = self.enemy.origin_z - trace_endpos_z;
 713
 714         af = ATTACK_FINISHED(self);
 715         ct = cvar("bot_ai_weapon_combo_threshold");
 716
 717         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
 718         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
 719         combo_time = time + ct + (ct * ((-0.3*skill)+3));
 720
 721         // Custom weapon list based on distance to the enemy
 722         i = 0;
 723         if(bot_custom_weapon){
 724
 725                 // Choose weapons for far distance
 726                 if ( distance > bot_distance_far ) {
 727                         for(i=0; i < WEP_COUNT && bot_weapons_far[i] != -1 ; ++i){
 728                                 w = bot_weapons_far[i];
 729                                 if ( client_hasweapon(self, w, TRUE, FALSE) ){
 730                                         if ( self.weapon == w){
 731                                                 if( cvar("bot_ai_weapon_combo") && af > combo_time)
 732                                                         continue;
 733                                         } else {
 734                                                 self.switchweapon = w;
 735                                         }
 736                                         return;
 737                                 }
 738                         }
 739                 }
 740
 741                 // Choose weapons for mid distance
 742                 if ( distance > bot_distance_close ) {
 743                         for(i= 0; i < WEP_COUNT && bot_weapons_mid[i] != -1 ; ++i){
 744                                 w = bot_weapons_mid[i];
 745                                 if ( client_hasweapon(self, w, TRUE, FALSE) ){
 746                                         if ( self.weapon == w){
 747                                                 if( cvar("bot_ai_weapon_combo") && af > combo_time)
 748                                                         continue;
 749                                         } else {
 750                                                 self.switchweapon = w;
 751                                         }
 752                                         return;
 753                                 }
 754                         }
 755                 }
 756
 757                 // Choose weapons for close distance
 758                 for(i= 0; i < WEP_COUNT && bot_weapons_close[i] != -1 ; ++i){
 759                         w = bot_weapons_close[i];
 760                         if ( client_hasweapon(self, w, TRUE, FALSE) ){
 761                                 if ( self.weapon == w){
 762                                         if( cvar("bot_ai_weapon_combo") && af > combo_time)
 763                                                 continue;
 764                                 } else {
 765                                         self.switchweapon = w;
 766                                 }
 767                                 return;
 768                         }
 769                 }
 770                 // If now weapon was chosen by this system fall back to the previous one
 771         }
 772
 773         // Formula:
 774         //      (Damage/Sec * Weapon spefic change to get that damage)
 775         //      *(Time to get to target * weapon specfic hitchange bonus) / (in a time of maxdelaytime)
 776         //      *(Spread change of hit) // if it applies
 777         //      *(Penality for target beeing in air)
 778         // %weaponaddpoint
 779         if (client_hasweapon(self, WEP_MINSTANEX, TRUE, FALSE))
 780                 minstanex = (1000/cvar("g_balance_minstanex_refire")*1.0)
 781                         * (0.5);
 782
 783         if (client_hasweapon(self, WEP_ROCKET_LAUNCHER, TRUE, FALSE)  &&
 784                 !(      cvar("bot_ai_weapon_combo") && self.weapon == WEP_ROCKET_LAUNCHER &&
 785                         af > combo_time
 786                 )
 787         )
 788                 rocket = (cvar("g_balance_rocketlauncher_damage")/cvar("g_balance_rocketlauncher_refire")*0.75)
 789                         * bound(0,(cvar("g_balance_rocketlauncher_speed")/distance*maxdelaytime),1)*1.5;
 790
 791         if (client_hasweapon(self, WEP_NEX, TRUE, FALSE)  &&
 792                 !(      cvar("bot_ai_weapon_combo") && self.weapon == WEP_NEX &&
 793                         af > combo_time
 794                 )
 795         )
 796                 nex = (cvar("g_balance_nex_damage")/cvar("g_balance_nex_refire")*1.0)
 797                         * (0.5);
 798
 799         if (client_hasweapon(self, WEP_HAGAR, TRUE, FALSE) ) // &&
 800         //      !( cvar("bot_ai_weapon_combo") && self.weapon == WEP_HAGAR &&  time < self.bot_lastshot + cvar("g_balance_hagar_primary_refire") ))
 801                 hagar = (cvar("g_balance_hagar_primary_damage")/cvar("g_balance_hagar_primary_refire")*1.0)
 802                         * bound(0,(cvar("g_balance_hagar_primary_speed")/distance*maxdelaytime),1)*0.2;
 803
 804         if (client_hasweapon(self, WEP_GRENADE_LAUNCHER, TRUE, FALSE) &&
 805                 !(
 806                         cvar("bot_ai_weapon_combo") && self.weapon == WEP_GRENADE_LAUNCHER &&
 807                         af > combo_time
 808                 )
 809         )
 810                 grenade = (cvar("g_balance_grenadelauncher_primary_damage")/cvar("g_balance_grenadelauncher_primary_refire")*1.0)
 811                         * bound(0,(cvar("g_balance_grenadelauncher_primary_speed")/distance*maxdelaytime),1)*1.1;
 812
 813         if (client_hasweapon(self, WEP_ELECTRO, TRUE, FALSE) &&
 814                 !(      cvar("bot_ai_weapon_combo") && self.weapon == WEP_ELECTRO &&
 815                         af > combo_time
 816                 )
 817         )
 818                 electro = (cvar("g_balance_electro_primary_damage")/cvar("g_balance_electro_primary_refire")*0.75)
 819                         * bound(0,(cvar("g_balance_electro_primary_speed")/distance*maxdelaytime),1)*1.0;
 820
 821         if (client_hasweapon(self, WEP_CRYLINK, TRUE, FALSE) ) // &&
 822         //      !( self.weapon == WEP_CRYLINK &&  time < self.bot_lastshot + cvar("g_balance_crylink_primary_refire") ))
 823                 crylink = (cvar("g_balance_crylink_primary_damage")/cvar("g_balance_crylink_primary_refire")*1.0)
 824                         * bound(0,(cvar("g_balance_crylink_primary_speed")/distance*maxdelaytime),1)*(64/(32+cvar("g_balance_crylink_primary_spread")*distance))*1.0;
 825
 826         if (client_hasweapon(self, WEP_UZI, TRUE, FALSE) ) // &&
 827         //      !( self.weapon == WEP_UZI &&  time < self.bot_lastshot + cvar("g_balance_uzi_sustained_refire") ))
 828                 uzi = (cvar("g_balance_uzi_sustained_damage")/cvar("g_balance_uzi_sustained_refire")*1.0)
 829                         * bound(0,32/(32+cvar("g_balance_uzi_sustained_spread")*distance),1);
 830
 831         if (client_hasweapon(self, WEP_SHOTGUN, TRUE, FALSE) &&
 832                 !(      cvar("bot_ai_weapon_combo") && self.weapon == WEP_SHOTGUN &&
 833                         af > combo_time
 834                 )
 835         )
 836                 shotgun = (cvar("g_balance_shotgun_primary_damage")*cvar("g_balance_shotgun_primary_bullets")/cvar("g_balance_shotgun_primary_refire")*1.0)
 837                         * bound(0,32/(32+cvar("g_balance_shotgun_primary_spread")*distance),1);
 838
 839         if (client_hasweapon(self, WEP_LASER, FALSE, FALSE) &&
 840                 !(      cvar("bot_ai_weapon_combo") && self.weapon == WEP_LASER &&
 841                         af > combo_time
 842                 )
 843         )
 844                 laser = (cvar("g_balance_laser_primary_damage")/cvar("g_balance_laser_primary_refire")*1.0)
 845                         * bound(0,cvar("g_balance_laser_primary_speed")/distance*maxdelaytime,1);
 846
 847         if((self.enemy.flags & FL_ONGROUND)==FALSE){
 848                 rocket = rocket   * (1.5-bound(0, distancefromfloor/cvar("g_balance_rocketlauncher_radius"         ),0.9)); //slight bigger change
 849                 grenade = grenade * (1.5-bound(0,distancefromfloor/cvar("g_balance_grenadelauncher_primary_radius"),0.95));
 850                 electro = electro * (1.5-bound(0,distancefromfloor/cvar("g_balance_electro_primary_radius"        ),0.95));
 851                 laser = laser     * (1.5-bound(0,distancefromfloor/cvar("g_balance_laser_primary_radius"                  ),0.95));
 852         }
 853         /*
 854         dprint("Floor distance: ",ftos(distancefromfloor),"\n");
 855         dprint("Rocket: " , ftos(rocket  ), "\n");
 856         dprint("Nex: "    , ftos(nex     ), "\n");
 857         dprint("Hagar: "  , ftos(hagar   ), "\n");
 858         dprint("Grenade: ", ftos(grenade ), "\n");
 859         dprint("Electro: ", ftos(electro ), "\n");
 860         dprint("Crylink: ", ftos(crylink ), "\n");
 861         dprint("Uzi: "    , ftos(uzi     ), "\n");
 862         dprint("Shotgun :", ftos(shotgun ), "\n");
 863         dprint("Laser   :", ftos(laser   ), "\n\n");
 864         */
 865         currentscore = -1;
 866         w = WEP_MINSTANEX        ;s = minstanex;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 867         w = WEP_ROCKET_LAUNCHER  ;s = rocket   ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 868         w = WEP_NEX              ;s = nex      ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 869         w = WEP_HAGAR            ;s = hagar    ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 870         w = WEP_GRENADE_LAUNCHER ;s = grenade  ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 871         w = WEP_ELECTRO          ;s = electro  ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 872         w = WEP_CRYLINK          ;s = crylink  ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 873         w = WEP_UZI              ;s = uzi      ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 874         w = WEP_SHOTGUN          ;s = shotgun  ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 875         w = WEP_LASER            ;s = laser    ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 876
 877         // switch if the best weapon would provide a significant damage increase
 878         if (bestscore > currentscore*1.5){
 879                 self.switchweapon = bestweapon;
 880
 881                 // buys time for detonating the rocket. not tested yet
 882                 if ( cvar("bot_ai_weapon_combo") && bestweapon == WEP_ROCKET_LAUNCHER )
 883                         self.bot_chooseweapontime += (distance  / cvar("g_balance_rocketlauncher_speed"));
 884         }
 885 };
 886
 887 .float nextaim;
 888 void havocbot_aim()
 889 {
 890         local vector selfvel, enemyvel;
 891 //      if(self.flags & FL_INWATER)
 892 //              return;
 893         if (time < self.nextaim)
 894                 return;
 895         self.nextaim = time + 0.1;
 896         selfvel = self.velocity;
 897         if (!self.waterlevel)
 898                 selfvel_z = 0;
 899         if (self.enemy)
 900         {
 901                 enemyvel = self.enemy.velocity;
 902                 if (!self.enemy.waterlevel)
 903                         enemyvel_z = 0;
 904                 lag_additem(time + self.ping, 0, 0, self.enemy, self.origin, selfvel, self.enemy.origin, enemyvel);
 905         }
 906         else
 907                 lag_additem(time + self.ping, 0, 0, world, self.origin, selfvel, self.goalcurrent.origin, '0 0 0');
 908 };
 909
 910 void havocbot_ai()
 911 {
 912         if (bot_strategytoken == self)
 913         if (!bot_strategytoken_taken)
 914         {
 915                 self.havocbot_role();
 916
 917                 // TODO: tracewalk() should take care of this job (better path finding under water)
 918                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
 919                 if(self.goalcurrent==world)
 920                 if(self.waterlevel==WATERLEVEL_SWIMMING || self.aistatus & AI_STATUS_OUT_WATER)
 921                 {
 922                         // Look for the closest waypoint out of water
 923                         local entity newgoal, head;
 924                         local float bestdistance, distance;
 925
 926                         newgoal = world;
 927                         bestdistance = 10000;
 928                         for (head = findchain(classname, "waypoint"); head; head = head.chain)
 929                         {
 930                                 distance = vlen(head.origin - self.origin);
 931                                 if(distance>10000)
 932                                         continue;
 933
 934                                 if(head.origin_z < self.origin_z)
 935                                         continue;
 936
 937                                 if(head.origin_z - self.origin_z - self.view_ofs_z > 100)
 938                                         continue;
 939
 940                                 if (pointcontents(head.origin + head.maxs + '0 0 1') != CONTENT_EMPTY)
 941                                         continue;
 942
 943                                 traceline(self.origin + self.view_ofs , head.origin, TRUE, head);
 944
 945                                 if(trace_fraction<1)
 946                                         continue;
 947
 948                                 if(distance<bestdistance)
 949                                 {
 950                                         newgoal = head;
 951                                         bestdistance = distance;
 952                                 }
 953                         }
 954
 955                         if(newgoal)
 956                         {
 957                         //      te_wizspike(newgoal.origin);
 958                                 navigation_pushroute(newgoal);
 959                         }
 960                 }
 961
 962                 // token has been used this frame
 963                 bot_strategytoken_taken = TRUE;
 964         }
 965         havocbot_chooseenemy();
 966         if (self.bot_chooseweapontime < time )
 967         {
 968                 self.bot_chooseweapontime = time + cvar("bot_ai_chooseweaponinterval");
 969                 havocbot_chooseweapon();
 970         }
 971         havocbot_aim();
 972         lag_update();
 973         if (self.bot_aimtarg)
 974         {
 975                 self.aistatus |= AI_STATUS_ATTACKING;
 976                 self.aistatus &~= AI_STATUS_ROAMING;
 977
 978                 weapon_action(self.weapon, WR_AIM);
 979                 if (cvar("bot_nofire") || IS_INDEPENDENT_PLAYER(self))
 980                 {
 981                         self.BUTTON_ATCK = FALSE;
 982                         self.BUTTON_ATCK2 = FALSE;
 983                 }
 984         }
 985         else if (self.goalcurrent)
 986         {
 987                 self.aistatus |= AI_STATUS_ROAMING;
 988                 self.aistatus &~= AI_STATUS_ATTACKING;
 989
 990                 local vector now,v,next;//,heading;
 991                 local float aimdistance,skillblend,distanceblend,blend;
 992                 next = now = self.goalcurrent.origin - (self.origin + self.view_ofs);
 993                 aimdistance = vlen(now);
 994                 //heading = self.velocity;
 995                 //dprint(self.goalstack01.classname,etos(self.goalstack01),"\n");
 996                 if(self.goalstack01 != self && self.goalstack01 != world && self.aistatus & AI_STATUS_RUNNING == 0)
 997                         next = self.goalstack01.origin - (self.origin + self.view_ofs);
 998                 skillblend=bound(0,(skill-2.5)*0.5,1); //lower skill player can't preturn
 999                 distanceblend=bound(0,aimdistance/cvar("bot_ai_keyboard_distance"),1);
1000                 blend = skillblend * (1-distanceblend);
1001                 //v = (now * (distanceblend) + next * (1-distanceblend)) * (skillblend) + now * (1-skillblend);
1002                 //v = now * (distanceblend) * (skillblend) + next * (1-distanceblend) * (skillblend) + now * (1-skillblend);
1003                 //v = now * ((1-skillblend) + (distanceblend) * (skillblend)) + next * (1-distanceblend) * (skillblend);
1004                 v = now + blend * (next - now);
1005                 //dprint(etos(self), " ");
1006                 //dprint(vtos(now), ":", vtos(next), "=", vtos(v), " (blend ", ftos(blend), ")\n");
1007                 //v = now * (distanceblend) + next * (1-distanceblend);
1008                 if (self.waterlevel < WATERLEVEL_SWIMMING)
1009                         v_z = 0;
1010                 //dprint("walk at:", vtos(v), "\n");
1011                 //te_lightning2(world, self.origin, self.goalcurrent.origin);
1012                 bot_aimdir(v, -1);
1013         }
1014         havocbot_movetogoal();
1015 };
1016
1017 void havocbot_setupbot()
1018 {
1019         self.bot_ai = havocbot_ai;
1020         // will be updated by think code
1021         //Generate some random skill levels
1022         self.havocbot_keyboardskill=random()-0.5;
1023         havocbot_chooserole();
1024 }
1025
1026
1027 #ifdef DEBUG_BOT_GOALSTACK
1028
1029 .float goalcounter;
1030 .vector lastposition;
1031
1032 // Debug the goal stack visually
1033 void debuggoalstack()
1034 {
1035         local entity target;
1036         local vector org;
1037
1038         if(self.goalcounter==0)target=self.goalcurrent;
1039         else if(self.goalcounter==1)target=self.goalstack01;
1040         else if(self.goalcounter==2)target=self.goalstack02;
1041         else if(self.goalcounter==3)target=self.goalstack03;
1042         else if(self.goalcounter==4)target=self.goalstack04;
1043         else if(self.goalcounter==5)target=self.goalstack05;
1044         else if(self.goalcounter==6)target=self.goalstack06;
1045         else if(self.goalcounter==7)target=self.goalstack07;
1046         else if(self.goalcounter==8)target=self.goalstack08;
1047         else if(self.goalcounter==9)target=self.goalstack09;
1048         else if(self.goalcounter==10)target=self.goalstack10;
1049         else if(self.goalcounter==11)target=self.goalstack11;
1050         else if(self.goalcounter==12)target=self.goalstack12;
1051         else if(self.goalcounter==13)target=self.goalstack13;
1052         else if(self.goalcounter==14)target=self.goalstack14;
1053         else if(self.goalcounter==15)target=self.goalstack15;
1054         else if(self.goalcounter==16)target=self.goalstack16;
1055         else if(self.goalcounter==17)target=self.goalstack17;
1056         else if(self.goalcounter==18)target=self.goalstack18;
1057         else if(self.goalcounter==19)target=self.goalstack19;
1058         else if(self.goalcounter==20)target=self.goalstack20;
1059         else if(self.goalcounter==21)target=self.goalstack21;
1060         else if(self.goalcounter==22)target=self.goalstack22;
1061         else if(self.goalcounter==23)target=self.goalstack23;
1062         else if(self.goalcounter==24)target=self.goalstack24;
1063         else if(self.goalcounter==25)target=self.goalstack25;
1064         else if(self.goalcounter==26)target=self.goalstack26;
1065         else if(self.goalcounter==27)target=self.goalstack27;
1066         else if(self.goalcounter==28)target=self.goalstack28;
1067         else if(self.goalcounter==29)target=self.goalstack29;
1068         else if(self.goalcounter==30)target=self.goalstack30;
1069         else if(self.goalcounter==31)target=self.goalstack31;
1070
1071         if(target==world)
1072         {
1073                 self.goalcounter = 0;
1074                 self.lastposition='0 0 0';
1075                 return;
1076         }
1077
1078         if(self.lastposition=='0 0 0')
1079                 org = self.origin;
1080         else
1081                 org = self.lastposition;
1082
1083
1084         te_lightning2(world, org, target.origin);
1085         self.lastposition = target.origin;
1086
1087         self.goalcounter++;
1088 }
1089
1090 #endif