data/qcsrc/server/gamec/w_rocketlauncher.c

   1 void() rlauncher_ready_01;
   2 void() rlauncher_fire1_01;
   3 void() rlauncher_deselect_01;
   4 void() rlauncher_select_01;
   5 .float rl_sound;
   6
   7 float() rlauncher_check =
   8 {
   9         if ((self.attack_finished > time && self.weapon == WEP_ROCKET_LAUNCHER)  // don't switch while guiding a missile
  10                 || self.ammo_rockets >= cvar("g_balance_rocketlauncher_ammo"))
  11                 return TRUE;
  12         return FALSE;
  13 };
  14
  15 void(float req) w_rlauncher =
  16 {
  17         if (req == WR_IDLE)
  18                 rlauncher_ready_01();
  19         else if (req == WR_AIM)
  20         {
  21                 // aim and decide to fire if appropriate
  22                 self.button0 = bot_aim(cvar("g_balance_rocketlauncher_speed"), 0, cvar("g_balance_rocketlauncher_lifetime"), FALSE);
  23                 if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
  24                 {
  25                         // decide whether to detonate rockets
  26                         local entity missile, targetlist, targ;
  27                         local float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
  28                         local float selfdamage, teamdamage, enemydamage;
  29                         edgedamage = cvar("g_balance_rocketlauncher_edgedamage");
  30                         coredamage = cvar("g_balance_rocketlauncher_damage");
  31                         edgeradius = cvar("g_balance_rocketlauncher_radius");
  32                         recipricoledgeradius = 1 / edgeradius;
  33                         selfdamage = 0;
  34                         teamdamage = 0;
  35                         enemydamage = 0;
  36                         targetlist = findchainfloat(bot_attack, TRUE);
  37                         missile = find(world, classname, "missile");
  38                         while (missile)
  39                         {
  40                                 targ = targetlist;
  41                                 while (targ)
  42                                 {
  43                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
  44                                         d = edgedamage + (coredamage - edgedamage) * (1 - d * recipricoledgeradius);
  45                                         // count potential damage according to type of target
  46                                         if (targ == self)
  47                                                 selfdamage = selfdamage + d;
  48                                         else if (targ.team == self.team && teamplay)
  49                                                 teamdamage = teamdamage + d;
  50                                         else if (bot_shouldattack(targ))
  51                                                 enemydamage = enemydamage + d;
  52                                         targ = targ.chain;
  53                                 }
  54                                 missile = find(missile, classname, "missile");
  55                         }
  56                         local float desirabledamage;
  57                         desirabledamage = enemydamage;
  58                         if (teamplay != 1 && time > self.invincible_finished && time > self.spawnshieldtime)
  59                                 desirabledamage = desirabledamage - selfdamage * cvar("g_balance_selfdamagepercent");
  60                         if (self.team && teamplay == 2)
  61                                 desirabledamage = desirabledamage - teamdamage;
  62                         // if we would be doing at least half of the core damage, detonate it
  63                         // but don't fire a new shot at the same time!
  64                         if (desirabledamage >= 0.5 * coredamage)
  65                         {
  66                                 self.button3 = TRUE;
  67                                 self.button0 = FALSE;
  68                         }
  69                 }
  70         }
  71         else if (req == WR_FIRE1)
  72                 weapon_prepareattack(rlauncher_check, rlauncher_check, rlauncher_fire1_01, cvar("g_balance_rocketlauncher_refire"));
  73         else if (req == WR_FIRE2)
  74         {
  75                 if(time > self.rl_sound)
  76                 {
  77                         self.rl_sound = time + 1;
  78                         sound (self, CHAN_BODY, "weapons/rocket_det.ogg", 0.5, ATTN_NORM);
  79                 }
  80                 if(cvar("g_laserguided_missile"))
  81                 if(self.exteriorweaponentity.attack_finished < time)
  82                 {
  83                         self.exteriorweaponentity.attack_finished = time + 0.4;
  84                         self.laser_on = !self.laser_on;
  85                         sound (self, CHAN_AUTO, "weapons/tink1.ogg", 1, ATTN_NORM);
  86                 }
  87         }
  88         else if (req == WR_RAISE)
  89                 rlauncher_select_01();
  90         else if (req == WR_UPDATECOUNTS)
  91                 self.currentammo = self.ammo_rockets;
  92         else if (req == WR_DROP)
  93                 rlauncher_deselect_01();
  94         else if (req == WR_SETUP)
  95                 weapon_setup(WEP_ROCKET_LAUNCHER, "w_rl.zym", IT_ROCKETS);
  96         else if (req == WR_CHECKAMMO)
  97                 weapon_hasammo = rlauncher_check();
  98 };
  99
 100
 101 void W_Rocket_Explode (void)
 102 {
 103         vector  org2;
 104         sound (self, CHAN_BODY, "weapons/rocket_impact.ogg", 1, ATTN_NORM);
 105         org2 = findbetterlocation (self.origin, 16);
 106
 107         //te_explosion (org2);
 108         // LordHavoc: TE_TEI_BIGEXPLOSION
 109         WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
 110         WriteByte (MSG_BROADCAST, 78);
 111         WriteCoord (MSG_BROADCAST, org2_x);
 112         WriteCoord (MSG_BROADCAST, org2_y);
 113         WriteCoord (MSG_BROADCAST, org2_z);
 114
 115         //effect (org2, "models/sprites/rockexpl.spr", 0, 12, 35);
 116         self.event_damage = SUB_Null;
 117         RadiusDamage (self, self.owner, cvar("g_balance_rocketlauncher_damage"), cvar("g_balance_rocketlauncher_edgedamage"), cvar("g_balance_rocketlauncher_radius"), world, cvar("g_balance_rocketlauncher_force"), IT_ROCKET_LAUNCHER);
 118
 119         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
 120         {
 121                 if(self.owner.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
 122                 {
 123                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
 124                         self.owner.attack_finished = time;
 125                         self.owner.switchweapon = w_getbestweapon(self.owner);
 126                 }
 127                 if(cvar("g_laserguided_missile"))
 128                                   self.owner.attack_finished = time + cvar("g_balance_rocketlauncher_refire");
 129         }
 130         remove (self);
 131 }
 132
 133 entity FindLaserTarget(entity e, float dist_variance, float dot_variance)
 134 {
 135         entity head, selected;
 136         vector dir;
 137         float dist, maxdist,// bestdist,
 138                 dot,// bestdot,
 139                 points, bestpoints;
 140         //bestdist = 9999;
 141         //bestdot = -2;
 142         bestpoints = 0;
 143         maxdist = 800;
 144         selected = world;
 145
 146         makevectors(e.angles);
 147
 148         head = find(world, classname, "laser_target");
 149         while(head)
 150         {
 151                 points = 0;
 152                 dir = normalize(head.origin - self.origin);
 153                 dot = dir * v_forward;
 154                 dist = vlen(head.origin - self.origin);
 155                 if(dist > maxdist)
 156                         dist = maxdist;
 157
 158                 // gain points for being in front
 159                 points = points + ((dot+1)*0.5) * 500
 160                         * (1 + crandom()*dot_variance);
 161                 // gain points for being close away
 162                 points = points + (1 - dist/maxdist) * 1000
 163                         * (1 + crandom()*dot_variance);
 164
 165                 traceline(e.origin, head.origin, TRUE, self);
 166                 if(trace_fraction < 1)
 167                 {
 168                         points = 0;
 169                 }
 170
 171                 if(points > bestpoints)//random() > 0.5)//
 172                 {
 173                         bestpoints = points;
 174                         selected = head;
 175                 }
 176
 177
 178                 /*
 179                 dot = dir * v_forward;
 180                 if(dot > bestdot * (1 + crandom()*dot_variance))
 181                 {
 182                         dist = vlen(head.origin - self.origin);
 183                         if(dist < bestdist * (1 + crandom()*dist_variance))
 184                         {
 185                                 traceline(e.origin, head.origin, TRUE, self);
 186                                 if(trace_fraction >= 1)
 187                                 {
 188                                 }
 189                         }
 190                 }
 191                 */
 192                 head = find(head, classname, "laser_target");
 193         }
 194
 195         //bprint(selected.owner.netname);
 196         //bprint("\n");
 197         return selected;
 198 }
 199
 200 void W_Rocket_Think (void)
 201 {
 202         entity e;
 203         vector desireddir, olddir, newdir;
 204         float turnrate;
 205         self.nextthink = time;
 206         if (time > self.cnt)
 207         {
 208                 W_Rocket_Explode ();
 209                 return;
 210         }
 211         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
 212         {
 213                 if(cvar("g_laserguided_missile"))
 214                 {
 215                         if(!self.owner.button0)
 216                                 self.ltime = -1; // indicate that the player has let go of the button
 217
 218
 219                         if (self.owner.button0 && self.ltime < 0) // if the player let go of the button and then pushed it again
 220                         {
 221                                   W_Rocket_Explode ();
 222                                   return;
 223                         }
 224
 225                         if(cvar("g_balance_rocketlauncher_laserguided_allow_steal"))
 226                         {
 227                                 if(self.owner.laser_on)
 228                                 {
 229                                         if(self.attack_finished < time)
 230                                         {
 231                                                 self.attack_finished = time + 0.2 + random()*0.3;
 232                                                 self.enemy = FindLaserTarget(self, 0.7, 0.7);
 233                                         }
 234
 235                                         if(!self.enemy)
 236                                                 self.enemy = self.owner.weaponentity.lasertarget;
 237                                 }
 238                                 else self.enemy = world;
 239                         }
 240                         else // don't allow stealing: always target my owner's laser (if it exists)
 241                                 self.enemy = self.owner.weaponentity.lasertarget;
 242
 243                         if(self.enemy != world)
 244                         {
 245                                 //bprint(strcat("Targeting ", self.enemy.owner.netname, "'s laser\n"));
 246                                 if(!self.speed)
 247                                         self.speed = vlen(self.velocity);
 248                                 e = self.enemy;//self.owner.weaponentity.lasertarget;
 249                                 turnrate = cvar("g_balance_rocketlauncher_laserguided_turnrate");//0.65;                                                // how fast to turn
 250                                 desireddir = normalize(e.origin - self.origin);         // get direction from my position to the laser target
 251                                 olddir = normalize(self.velocity);                              // get my current direction
 252                                 newdir = normalize((olddir + desireddir * turnrate) * 0.5);     // take the average of the 2 directions; not the best method but simple & easy
 253                                 self.velocity = newdir * self.speed;                    // make me fly in the new direction at my flight speed
 254                                 self.angles = vectoangles(self.velocity);                       // turn model in the new flight direction
 255
 256                                 self.owner.attack_finished = time + 0.2;
 257                         }
 258                 }
 259                 else
 260                 {
 261                         if (self.owner.button3)
 262                                   W_Rocket_Explode ();
 263                 }
 264         }
 265 }
 266
 267 void W_Rocket_Touch (void)
 268 {
 269         if(self.owner && self.owner.lastrocket == self)
 270                 self.owner.lastrocket = world;
 271         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 272         {
 273                 sound (self, CHAN_BODY, "misc/null.wav", 1, ATTN_NORM);
 274                 remove(self);
 275                 return;
 276         }
 277         W_Rocket_Explode ();
 278 }
 279
 280 void W_Rocket_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 281 {
 282         self.health = self.health - damage;
 283         if (self.health <= 0)
 284         {
 285                 self.owner = attacker;
 286                 W_Rocket_Explode();
 287         }
 288 }
 289
 290 void W_Rocket_Attack (void)
 291 {
 292         local entity missile;
 293         local entity flash;
 294         local vector org;
 295
 296         local vector trueaim;
 297         trueaim = W_TrueAim();
 298
 299         sound (self, CHAN_WEAPON, "weapons/rocket_fire.ogg", 1, ATTN_NORM);
 300         if (self.items & IT_STRENGTH)
 301                 sound (self, CHAN_AUTO, "weapons/strength_fire.ogg", 1, ATTN_NORM);
 302
 303         if (cvar("g_use_ammunition") && !cvar("g_rocketarena"))
 304                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_rocketlauncher_ammo");
 305         self.punchangle_x = -4;
 306
 307         org = W_MuzzleOrigin (self, '15 3 -11');
 308         te_smallflash(org);
 309
 310         missile = spawn ();
 311         missile.owner = self;
 312         self.lastrocket = missile;
 313         missile.classname = "missile";
 314         missile.bot_dodge = TRUE;
 315         missile.bot_dodgerating = cvar("g_balance_rocketlauncher_primary_damage") * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 316
 317         missile.takedamage = DAMAGE_YES;
 318         missile.damageforcescale = 4;
 319         missile.health = 30;
 320         missile.event_damage = W_Rocket_Damage;
 321
 322         missile.movetype = MOVETYPE_FLY;
 323         missile.solid = SOLID_BBOX;
 324         setmodel (missile, "models/rocket.md3");
 325         setsize (missile, '0 0 0', '0 0 0');
 326
 327         setorigin (missile, org);
 328         if(cvar("g_laserguided_missile") && self.laser_on)
 329                 missile.velocity = normalize(trueaim - org) * cvar("g_balance_rocketlauncher_laserguided_speed");
 330         else
 331                 missile.velocity = normalize(trueaim - org) * cvar("g_balance_rocketlauncher_speed");
 332         missile.angles = vectoangles (missile.velocity);
 333
 334         missile.touch = W_Rocket_Touch;
 335         missile.think = W_Rocket_Think;
 336         missile.nextthink = time;
 337         missile.cnt = time + cvar("g_balance_rocketlauncher_lifetime");
 338         missile.effects = EF_NOSHADOW;
 339         sound (missile, CHAN_BODY, "weapons/rocket_fly.wav", 0.4, ATTN_NORM);
 340         missile.flags = FL_PROJECTILE;
 341
 342         flash = spawn ();
 343         setorigin (flash, org);
 344         setmodel (flash, "models/flash.md3");
 345         flash.velocity = v_forward * 20;
 346         flash.angles = vectoangles (flash.velocity);
 347         SUB_SetFade (flash, time, 0.4);
 348         flash.effects = flash.effects | EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 349 }
 350
 351 // weapon frames
 352
 353 void()  rlauncher_ready_01 =    {weapon_thinkf(WFRAME_IDLE, 0.1, rlauncher_ready_01); self.weaponentity.state = WS_READY;};
 354 void()  rlauncher_select_01 =   {weapon_thinkf(-1, cvar("g_balance_weaponswitchdelay"), w_ready); weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, '0 0 0'); self.laser_on = 1;};
 355 void()  rlauncher_deselect_01 = {weapon_thinkf(-1, cvar("g_balance_weaponswitchdelay"), w_clear); weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, PLAYER_WEAPONSELECTION_RANGE);  self.laser_on = 0;};
 356 void()  rlauncher_fire1_01 =
 357 {
 358         weapon_doattack(rlauncher_check, rlauncher_check, W_Rocket_Attack);
 359         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), rlauncher_ready_01);
 360 };