data/qcsrc/server/gamec/cl_physics.c

   1 float sv_accelerate;
   2 float sv_maxairspeed;
   3 float sv_friction;
   4 float sv_maxspeed;
   5 float sv_stopspeed;
   6 float sv_gravity;
   7 float sv_airaccel_sideways_friction;
   8 float sv_airaccel_qw;
   9 .float ladder_time;
  10 .entity ladder_entity;
  11 .float gravity;
  12 .float swamp_slowdown;
  13 .float lastflags;
  14 .float lastground;
  15
  16 void Nixnex_GiveCurrentWeapon();
  17 void SV_PlayerPhysics()
  18 {
  19         local vector wishvel, wishdir, v;
  20         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod;
  21         string temps;
  22
  23         if (clienttype(self) == CLIENTTYPE_BOT)
  24                 bot_think();
  25
  26         if (self.movetype == MOVETYPE_NONE)
  27                 return;
  28
  29         if (self.punchangle != '0 0 0')
  30         {
  31                 f = vlen(self.punchangle) - 10 * frametime;
  32                 if (f > 0)
  33                         self.punchangle = normalize(self.punchangle) * f;
  34                 else
  35                         self.punchangle = '0 0 0';
  36         }
  37
  38         if (self.punchvector != '0 0 0')
  39         {
  40                 f = vlen(self.punchvector) - 30 * frametime;
  41                 if (f > 0)
  42                         self.punchvector = normalize(self.punchvector) * f;
  43                 else
  44                         self.punchvector = '0 0 0';
  45         }
  46
  47         maxspd_mod = 1;
  48
  49         if(cvar("g_runematch"))
  50         {
  51                 if(self.runes & RUNE_SPEED)
  52                 {
  53                         if(self.runes & CURSE_SLOW)
  54                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_combo_moverate");
  55                         else
  56                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_moverate");
  57                 }
  58                 else if(self.runes & CURSE_SLOW)
  59                 {
  60                         maxspd_mod = maxspd_mod * cvar("g_balance_curse_slow_moverate");
  61                 }
  62         }
  63
  64         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
  65         {
  66                 maxspd_mod = cvar("g_balance_rune_speed_moverate");
  67         }
  68
  69         swampspd_mod = 1;
  70         if(self.in_swamp) {
  71                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
  72         }
  73
  74
  75         spd = sv_maxspeed * maxspd_mod * swampspd_mod;
  76
  77         if(self.speed != spd)
  78         {
  79                 self.speed = spd;
  80                 temps = ftos(spd);
  81                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
  82                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
  83                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
  84                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
  85
  86                 temps = ftos(sv_accelerate * maxspd_mod);
  87                 stuffcmd(self, strcat("cl_movement_accelerate ", temps, "\n"));
  88         }
  89
  90         // if dead, behave differently
  91         if (self.deadflag)
  92                 return;
  93
  94         if (!self.fixangle)
  95         {
  96                 self.angles_x = 0;
  97                 self.angles_y = self.v_angle_y;
  98                 self.angles_z = 0;
  99         }
 100
 101         if (self.flags & FL_WATERJUMP )
 102         {
 103                 self.velocity_x = self.movedir_x;
 104                 self.velocity_y = self.movedir_y;
 105                 if (time > self.teleport_time || self.waterlevel == 0)
 106                 {
 107                         self.flags = self.flags - (self.flags & FL_WATERJUMP);
 108                         self.teleport_time = 0;
 109                 }
 110         }
 111         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
 112         {
 113                 // noclipping or flying
 114                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 115
 116                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 117                 makevectors(self.v_angle);
 118                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 119                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 120                 // acceleration
 121                 wishdir = normalize(wishvel);
 122                 wishspeed = vlen(wishvel);
 123                 if (wishspeed > sv_maxspeed*maxspd_mod)
 124                         wishspeed = sv_maxspeed*maxspd_mod;
 125                 if (time >= self.teleport_time)
 126                 {
 127                         f = wishspeed - (self.velocity * wishdir);
 128                         if (f > 0)
 129                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 130                 }
 131         }
 132         else if (self.waterlevel >= 2)
 133         {
 134                 // swimming
 135                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 136
 137                 makevectors(self.v_angle);
 138                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 139                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 140                 if (wishvel == '0 0 0')
 141                         wishvel = '0 0 -60'; // drift towards bottom
 142
 143                 wishdir = normalize(wishvel);
 144                 wishspeed = vlen(wishvel);
 145                 if (wishspeed > sv_maxspeed*maxspd_mod)
 146                         wishspeed = sv_maxspeed*maxspd_mod;
 147                 wishspeed = wishspeed * 0.7;
 148
 149                 // water friction
 150                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 151
 152                 // water acceleration
 153                 f = wishspeed - (self.velocity * wishdir);
 154                 if (f > 0)
 155                         self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 156         }
 157         else if (time < self.ladder_time)
 158         {
 159                 // on a func_ladder or swimming in func_water
 160                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 161
 162                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 163                 makevectors(self.v_angle);
 164                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 165                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 166                 if (self.gravity)
 167                         self.velocity_z = self.velocity_z + self.gravity * sv_gravity * frametime;
 168                 else
 169                         self.velocity_z = self.velocity_z + sv_gravity * frametime;
 170                 if (self.ladder_entity.classname == "func_water")
 171                 {
 172                         f = vlen(wishvel);
 173                         if (f > self.ladder_entity.speed)
 174                                 wishvel = wishvel * (self.ladder_entity.speed / f);
 175
 176                         self.watertype = self.ladder_entity.skin;
 177                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
 178                         if ((self.origin_z + self.view_ofs_z) < f)
 179                                 self.waterlevel = 3;
 180                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
 181                                 self.waterlevel = 2;
 182                         else if ((self.origin_z + self.mins_z + 1) < f)
 183                                 self.waterlevel = 1;
 184                         else
 185                         {
 186                                 self.waterlevel = 0;
 187                                 self.watertype = CONTENT_EMPTY;
 188                         }
 189                 }
 190                 // acceleration
 191                 wishdir = normalize(wishvel);
 192                 wishspeed = vlen(wishvel);
 193                 if (wishspeed > sv_maxspeed)
 194                         wishspeed = sv_maxspeed;
 195                 if (time >= self.teleport_time)
 196                 {
 197                         f = wishspeed - (self.velocity * wishdir);
 198                         if (f > 0)
 199                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 200                 }
 201         }
 202         else if (self.flags & FL_ONGROUND)
 203         {
 204                 // walking
 205                 makevectors(self.v_angle_y * '0 1 0');
 206                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 207
 208                 if(!(self.lastflags & FL_ONGROUND))
 209                 {
 210                         if(cvar("speedmeter"))
 211                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
 212                         if(self.lastground < time - 0.3)
 213                                 self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
 214                 }
 215
 216                 if (self.velocity_x || self.velocity_y)
 217                 if (!(self.flags & FL_JUMPRELEASED) || !self.button2)
 218                 {
 219                         v = self.velocity;
 220                         v_z = 0;
 221                         f = vlen(v);
 222                         if (f < sv_stopspeed)
 223                                 f = 1 - frametime * (sv_stopspeed / f) * sv_friction;
 224                         else
 225                                 f = 1 - frametime * sv_friction;
 226                         if (f > 0)
 227                                 self.velocity = self.velocity * f;
 228                         else
 229                                 self.velocity = '0 0 0';
 230                 }
 231                 // acceleration
 232                 wishdir = normalize(wishvel);
 233                 wishspeed = vlen(wishvel);
 234                 if (wishspeed > sv_maxspeed*maxspd_mod)
 235                         wishspeed = sv_maxspeed*maxspd_mod;
 236                 if (self.crouch)
 237                         wishspeed = wishspeed * 0.5;
 238                 if (time >= self.teleport_time)
 239                 {
 240                         f = wishspeed - (self.velocity * wishdir);
 241                         if (f > 0)
 242                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 243                 }
 244         }
 245         else
 246         {
 247                 if(maxspd_mod < 1)
 248                 {
 249                         maxairspd = sv_maxairspeed*maxspd_mod;
 250                         airaccel = sv_accelerate*maxspd_mod;
 251                 }
 252                 else
 253                 {
 254                         maxairspd = sv_maxairspeed;
 255                         airaccel = sv_accelerate;
 256                 }
 257                 // airborn
 258                 makevectors(self.v_angle_y * '0 1 0');
 259                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 260                 // acceleration
 261                 wishdir = normalize(wishvel);
 262                 wishspeed = vlen(wishvel);
 263                 if (wishspeed > maxairspd)
 264                         wishspeed = maxairspd;
 265                 if (self.crouch)
 266                         wishspeed = wishspeed * 0.5;
 267                 if (time >= self.teleport_time)
 268                 {
 269                         // NOTE: this does the same as the commented out old code if:
 270                         //   sv_airaccel_qw 0
 271                         //   sv_airaccel_sideways_friction 0
 272
 273                         float vel_straight;
 274                         float vel_z;
 275                         vector vel_perpend;
 276                         vel_straight = self.velocity * wishdir;
 277                         vel_z = self.velocity_z;
 278                         vel_perpend = self.velocity - vel_straight * wishdir - vel_z * '0 0 1';
 279
 280                         f = wishspeed - vel_straight;
 281                         if(f > 0)
 282                                 vel_straight = vel_straight + min(f, airaccel * frametime * wishspeed) * sv_airaccel_qw;
 283                         if(wishspeed > 0)
 284                                 vel_straight = vel_straight + min(wishspeed, airaccel * frametime * wishspeed) * (1 - sv_airaccel_qw);
 285
 286                         // anti-sideways friction to fix QW-style bunnyhopping
 287                         vel_perpend = vel_perpend * (1 - frametime * (wishspeed / maxairspd) * sv_airaccel_sideways_friction);
 288
 289                         self.velocity = vel_straight * wishdir + vel_z * '0 0 1' + vel_perpend;
 290
 291                         /*
 292                         f = wishspeed;// - (self.velocity * wishdir);
 293                         if (f > 0)
 294                                 self.velocity = self.velocity + wishdir * min(f, airaccel * frametime * wishspeed);
 295                         */
 296                 }
 297         }
 298
 299         if(self.flags & FL_ONGROUND)
 300                 self.lastground = time;
 301
 302         self.lastflags = self.flags;
 303 };