data/qcsrc/server/g_world.qc

   1 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
   2 string redirection_target;
   3 float world_initialized;
   4
   5 string GetMapname();
   6 string GetGametype();
   7 void GotoNextMap();
   8 void ShuffleMaplist()
   9 float() DoNextMapOverride;
  10
  11 .string fog;
  12
  13 void SetDefaultAlpha()
  14 {
  15         if(cvar("g_running_guns"))
  16         {
  17                 default_player_alpha = -1;
  18                 default_weapon_alpha = +1;
  19         }
  20         else if(g_cloaked)
  21         {
  22                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  23                 default_weapon_alpha = default_player_alpha;
  24         }
  25         else
  26         {
  27                 default_player_alpha = cvar("g_player_alpha");
  28                 if(default_player_alpha <= 0)
  29                         default_player_alpha = 1;
  30                 default_weapon_alpha = default_player_alpha;
  31         }
  32 }
  33
  34 void fteqcc_testbugs()
  35 {
  36         float a, b;
  37
  38         if(!cvar("developer_fteqccbugs"))
  39                 return;
  40
  41         dprint("*** fteqcc test: checking for bugs...\n");
  42
  43         a = 1;
  44         b = 5;
  45         if(sqrt(a) - sqrt(b - a) == 0)
  46                 dprint("*** fteqcc test: found same-function-twice bug\n");
  47         else
  48                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  49
  50         world.cnt = -10;
  51         world.enemy = world;
  52         world.enemy.cnt += 10;
  53         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  54                 dprint("*** fteqcc test: found += bug\n");
  55         else
  56                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  57         world.cnt = 0;
  58 }
  59
  60 /**
  61  * Takes care of pausing and unpausing the game.
  62  * Centerprints the information about an upcoming or active timeout to all active
  63  * players. Also plays reminder sounds.
  64  */
  65 void timeoutHandler_Think() {
  66         local string timeStr;
  67         local entity plr;
  68         if (timeoutStatus == 1) {
  69                 if (remainingLeadTime > 0) {
  70                         //centerprint the information to every player
  71                         timeStr = getTimeoutText(0);
  72                         FOR_EACH_REALCLIENT(plr) {
  73                                 if(plr.classname == "player") {
  74                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  75                                 }
  76                         }
  77                         remainingLeadTime -= 1;
  78                         //think again in 1 second:
  79                         self.nextthink = time + 1;
  80                 }
  81                 else {
  82                         //now pause the game:
  83                         timeoutStatus = 2;
  84                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
  85                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
  86                         FOR_EACH_REALPLAYER(plr) {
  87                                 plr.lastV_angle = plr.v_angle;
  88                         }
  89                         self.nextthink = time;
  90                 }
  91         }
  92         else if (timeoutStatus == 2) {
  93                 if (remainingTimeoutTime > 0) {
  94                         timeStr = getTimeoutText(0);
  95                         FOR_EACH_REALCLIENT(plr) {
  96                                 if(plr.classname == "player") {
  97                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  98                                 }
  99                         }
 100                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 101                                 sound(world, CHAN_AUTO, "announcer/robotic/prepareforbattle.wav", 1, ATTN_NONE);
 102                         }
 103                         remainingTimeoutTime -= 1;
 104                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 105                 }
 106                 else {
 107                         //unpause the game again
 108                         remainingTimeoutTime = timeoutStatus = 0;
 109                         cvar_set("slowmo", ftos(orig_slowmo));
 110                         //and unlock the fixed view again once there is no timeout active anymore
 111                         FOR_EACH_REALPLAYER(plr) {
 112                                 plr.fixangle = FALSE;
 113                         }
 114                         //get rid of the countdown message
 115                         FOR_EACH_REALCLIENT(plr) {
 116                                 if(plr.classname == "player") {
 117                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 118                                 }
 119                         }
 120                         remove(self);
 121                         return;
 122                 }
 123
 124         }
 125         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 126                 FOR_EACH_REALCLIENT(plr) {
 127                         if(plr.classname == "player") {
 128                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 129                         }
 130                 }
 131                 remove(self);
 132                 return;
 133         }
 134 }
 135
 136 float GotoFirstMap()
 137 {
 138         if(cvar("_sv_init"))
 139         {
 140                 cvar_set("_sv_init", "0");
 141                 if(cvar("g_maplist_shuffle"))
 142                         ShuffleMaplist();
 143 #ifdef MAPINFO
 144                 tokenizebyseparator(cvar_string("g_maplist"), " ");
 145 #else
 146                 tokenize(cvar_string("g_maplist"));
 147                 if(argv(0) != GetMapname())
 148 #endif
 149                 {
 150                         cvar_set("nextmap", argv(0));
 151
 152 #ifdef MAPINFO
 153                         MapInfo_Enumerate();
 154                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0);
 155 #endif
 156
 157                         if(!DoNextMapOverride())
 158                                 GotoNextMap();
 159
 160                         return 1;
 161                 }
 162         }
 163         return 0;
 164 }
 165
 166 float world_already_spawned;
 167 void spawnfunc_worldspawn (void)
 168 {
 169         float fd, l;
 170         string s;
 171
 172         dprint_load(); // load dprint status from cvar
 173
 174         if(world_already_spawned)
 175                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 176         world_already_spawned = TRUE;
 177
 178         local entity head;
 179         head = nextent(world);
 180         maxclients = 0;
 181         while(head)
 182         {
 183                 ++maxclients;
 184                 head = nextent(head);
 185         }
 186
 187         if(GotoFirstMap())
 188                 return;
 189
 190 #ifdef MAPINFO
 191         MapInfo_LoadMapSettings(mapname);
 192 #endif
 193
 194         if(sv_cheats)
 195                 ServerProgsDB = db_create();
 196         else
 197                 ServerProgsDB = db_load("server.db");
 198
 199         /*
 200         TODO sound pack system
 201         // initialize sound pack system
 202         soundpack = cvar_string("g_soundpack");
 203         if(soundpack != "")
 204                 soundpack = strcat(soundpack, "/");
 205         soundpack = strzone(soundpack);
 206         */
 207
 208         // 0 normal
 209         lightstyle(0, "m");
 210
 211         // 1 FLICKER (first variety)
 212         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 213
 214         // 2 SLOW STRONG PULSE
 215         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 216
 217         // 3 CANDLE (first variety)
 218         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 219
 220         // 4 FAST STROBE
 221         lightstyle(4, "mamamamamama");
 222
 223         // 5 GENTLE PULSE 1
 224         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 225
 226         // 6 FLICKER (second variety)
 227         lightstyle(6, "nmonqnmomnmomomno");
 228
 229         // 7 CANDLE (second variety)
 230         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 231
 232         // 8 CANDLE (third variety)
 233         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 234
 235         // 9 SLOW STROBE (fourth variety)
 236         lightstyle(9, "aaaaaaaazzzzzzzz");
 237
 238         // 10 FLUORESCENT FLICKER
 239         lightstyle(10, "mmamammmmammamamaaamammma");
 240
 241         // 11 SLOW PULSE NOT FADE TO BLACK
 242         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 243
 244         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 245
 246         // 63 testing
 247         lightstyle(63, "a");
 248
 249         // for setting by mapinfo
 250         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 251         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 252
 253         player_count = 0;
 254         lms_lowest_lives = 0;
 255         lms_next_place = 0;
 256
 257         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 258         if(bot_waypoints_for_items == 1)
 259                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 260                         bot_waypoints_for_items = 0;
 261
 262         if(cvar("g_campaign"))
 263                 CampaignPreInit();
 264
 265         InitGameplayMode();
 266         readlevelcvars();
 267         precache();
 268
 269         WaypointSprite_Init();
 270
 271         //if (g_domination)
 272         //      dom_init();
 273
 274         GameLogInit(); // prepare everything
 275         if(cvar("sv_eventlog"))
 276         {
 277                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 278                 s = strcat(s, ftos(random()));
 279 #ifdef MAPINFO
 280                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s), FALSE);
 281 #else
 282                 GameLogEcho(strcat(":gamestart:", GetMapname(), ":", s), FALSE);
 283 #endif
 284                 s = ":gameinfo:mutators:LIST";
 285                 if(cvar("g_grappling_hook"))
 286                         s = strcat(s, ":grappling_hook");
 287                 if(!cvar("g_use_ammunition"))
 288                         s = strcat(s, ":no_use_ammunition");
 289                 if(!cvar("g_pickup_items"))
 290                         s = strcat(s, ":no_pickup_items");
 291                 if(cvar("g_instagib"))
 292                         s = strcat(s, ":instagib");
 293                 if(cvar("g_rocketarena"))
 294                         s = strcat(s, ":rockerarena");
 295                 if(cvar("g_nixnex"))
 296                         s = strcat(s, ":nixnex");
 297                 if(cvar("g_vampire"))
 298                         s = strcat(s, ":vampire");
 299                 if(cvar("g_laserguided_missile"))
 300                         s = strcat(s, ":laserguided_missile");
 301                 if(cvar("g_norecoil"))
 302                         s = strcat(s, ":norecoil");
 303                 if(cvar("g_midair"))
 304                         s = strcat(s, ":midair");
 305                 if(cvar("g_minstagib"))
 306                         s = strcat(s, ":minstagib");
 307                 GameLogEcho(s, FALSE);
 308                 GameLogEcho(":gameinfo:end", FALSE);
 309         }
 310
 311         cvar_set("nextmap", "");
 312
 313         SetDefaultAlpha();
 314
 315         if(cvar("g_campaign"))
 316                 CampaignPostInit();
 317
 318         fteqcc_testbugs();
 319
 320         Ban_LoadBans();
 321
 322         //initialise globals related to sv_timeout
 323         sys_ticrate = cvar("sys_ticrate");
 324         orig_slowmo = cvar("slowmo");
 325
 326 #ifdef MAPINFO
 327         MapInfo_Enumerate();
 328         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 1);
 329 #endif
 330
 331         //if tourney is used map starts in warmup mode. if this mode shall stay unlimited, reset timelimit, but save the original one
 332         if(g_tourney && cvar("g_tourney_warmup_unlimited_time")) {
 333                 timelimit_orig = cvar("timelimit");
 334                 cvar_set("timelimit", "0");
 335         }
 336
 337         fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 338         if(fd != -1)
 339         {
 340                 while((s = fgets(fd)))
 341                 {
 342                         l = tokenize(s);
 343                         if(l < 2)
 344                                 continue;
 345                         if(argv(0) != "fog")
 346                                 continue;
 347                         s = "";
 348                         while(l >= 2)
 349                         {
 350                                 --l;
 351                                 s = strcat(argv(l), " ", s);
 352                         }
 353                         s = substring(s, 0, strlen(s) - 1);
 354                         print("Found ^1DEPRECATED^7 fog command in .cfg file: ", s, "\n");
 355                         world.fog = strzone(s);
 356                 }
 357                 fclose(fd);
 358         }
 359
 360         next_pingtime = time + 5;
 361         world_initialized = 1;
 362 }
 363
 364 void spawnfunc_light (void)
 365 {
 366         //makestatic (self); // Who the f___ did that?
 367         remove(self);
 368 }
 369
 370 float TryFile( string pFilename )
 371 {
 372         local float lHandle;
 373         dprint("TryFile(\"", pFilename, "\")\n");
 374         lHandle = fopen( pFilename, FILE_READ );
 375         if( lHandle != -1 ) {
 376                 fclose( lHandle );
 377                 return TRUE;
 378         } else {
 379                 return FALSE;
 380         }
 381 };
 382
 383 string GetGametype()
 384 {
 385         return GametypeNameFromType(game);
 386 }
 387
 388 float IsSameGametype(string mapcfgname)
 389 {
 390 #ifdef MAPINFO
 391         return TRUE; // can't change game type by map name here
 392 #else
 393         string gt;
 394         gt = GetGametype();
 395         if(substring(mapcfgname, 0, strlen(gt) + 1) == strcat(gt, "_"))
 396                 return TRUE;
 397         return FALSE;
 398 #endif
 399 }
 400
 401 string getmapname_stored;
 402 string GetMapname()
 403 {
 404 #ifdef MAPINFO
 405         return mapname;
 406 #else
 407         if(getmapname_stored == "")
 408                 getmapname_stored = strzone(strcat(GetGametype(), "_", mapname));
 409         return getmapname_stored;
 410 #endif
 411 }
 412
 413 float Map_Count, Map_Current;
 414 string Map_Current_Name;
 415
 416 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 417 float GetMaplistPosition()
 418 {
 419         float pos, idx;
 420         string map;
 421
 422         map = GetMapname();
 423         idx = cvar("g_maplist_index");
 424
 425         if(idx >= 0)
 426                 if(idx < Map_Count)
 427                         if(map == argv(idx))
 428                                 return idx;
 429
 430         for(pos = 0; pos < Map_Count; ++pos)
 431                 if(map == argv(pos))
 432                         return pos;
 433
 434         // resume normal maplist rotation if current map is not in g_maplist
 435         return idx;
 436 }
 437
 438 float MapHasRightSize(string map)
 439 {
 440         float fh;
 441         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 442         if(cvar("g_maplist_check_waypoints"))
 443         {
 444                 dprint("checkwp "); dprint(map);
 445                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 446                 if(fh < 0)
 447                 {
 448                         dprint(": no waypoints\n");
 449                         return FALSE;
 450                 }
 451                 dprint(": has waypoints\n");
 452                 fclose(fh);
 453         }
 454
 455         // open map size restriction file
 456         dprint("opensize "); dprint(map);
 457         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 458         if(fh >= 0)
 459         {
 460                 float mapmin, mapmax;
 461                 dprint(": ok, ");
 462                 mapmin = stof(fgets(fh));
 463                 mapmax = stof(fgets(fh));
 464                 fclose(fh);
 465                 if(player_count < mapmin)
 466                 {
 467                         dprint("not enough\n");
 468                         return FALSE;
 469                 }
 470                 if(player_count > mapmax)
 471                 {
 472                         dprint("too many\n");
 473                         return FALSE;
 474                 }
 475                 dprint("right size\n");
 476                 return TRUE;
 477         }
 478         dprint(": not found\n");
 479         return TRUE;
 480 }
 481
 482 string Map_Filename(float position)
 483 {
 484 #ifdef MAPINFO
 485         return strcat("maps/", argv(position), ".bsp");
 486 #else
 487         return strcat("maps/", argv(position), ".mapcfg");
 488 #endif
 489 }
 490
 491 string strwords(string s, float w)
 492 {
 493         float endpos;
 494         for(endpos = 0; w && endpos >= 0; --w)
 495                 endpos = strstrofs(s, " ", endpos + 1);
 496         if(endpos < 0)
 497                 return s;
 498         else
 499                 return substring(s, 0, endpos);
 500 }
 501
 502 float strhasword(string s, string w)
 503 {
 504         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 505 }
 506
 507 void Map_MarkAsRecent(string m)
 508 {
 509         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), cvar("g_maplist_mostrecent_count")));
 510 }
 511
 512 float Map_IsRecent(string m)
 513 {
 514         return strhasword(cvar_string("g_maplist_mostrecent"), m);
 515 }
 516
 517 float Map_Check(float position, float pass)
 518 {
 519         string filename;
 520         string map_next;
 521         map_next = argv(position);
 522         if(pass <= 1)
 523         {
 524                 if(map_next == Map_Current_Name) // same map again in first pass?
 525                         return 0;
 526                 if(Map_IsRecent(map_next))
 527                         return 0;
 528         }
 529         filename = Map_Filename(position);
 530 #ifdef MAPINFO
 531         if(MapInfo_CheckMap(map_next))
 532 #else
 533         if(TryFile(filename))
 534 #endif
 535         {
 536                 if(pass == 2)
 537                         return 1;
 538                 if(MapHasRightSize(map_next))
 539                         return 1;
 540                 return 0;
 541         }
 542         else
 543                 dprint( "Couldn't select '", filename, "'..\n" );
 544
 545         return 0;
 546 }
 547
 548 void Map_Goto_SetStr(string nextmapname)
 549 {
 550         if(getmapname_stored != "")
 551                 strunzone(getmapname_stored);
 552         if(nextmapname == "")
 553                 getmapname_stored = "";
 554         else
 555                 getmapname_stored = strzone(nextmapname);
 556 }
 557
 558 void Map_Goto_SetFloat(float position)
 559 {
 560         cvar_set("g_maplist_index", ftos(position));
 561         Map_Goto_SetStr(argv(position));
 562 }
 563
 564 void GameResetCfg()
 565 {
 566 #ifdef MAPINFO
 567         // settings persist, except...
 568         if(cvar("g_campaign"))
 569                 localcmd("\nexec mutator_reset.cfg\n");
 570         localcmd("\nsettemp_restore\n");
 571 #else
 572         // if an exit cfg is defined by exiting map, exec it.
 573         string exit_cfg;
 574         exit_cfg = cvar_string("exit_cfg");
 575         if(exit_cfg != "")
 576                 localcmd(strcat("exec \"", exit_cfg, "\"\n"));
 577
 578         localcmd("exec game_reset.cfg\n");
 579 #endif
 580 };
 581
 582 void Map_Goto()
 583 {
 584         Map_MarkAsRecent(getmapname_stored);
 585         GameResetCfg();
 586 #ifdef MAPINFO
 587         MapInfo_LoadMap(getmapname_stored);
 588 #else
 589         localcmd(strcat("exec \"maps/", getmapname_stored ,".mapcfg\"\n"));
 590 #endif
 591 }
 592
 593 // return codes of map selectors:
 594 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
 595 //   -2 = permanent failure
 596 float() MaplistMethod_Iterate = // usual method
 597 {
 598         float pass, i;
 599
 600         for(pass = 1; pass <= 2; ++pass)
 601         {
 602                 for(i = 1; i < Map_Count; ++i)
 603                 {
 604                         float mapindex;
 605                         mapindex = mod(i + Map_Current, Map_Count);
 606                         if(Map_Check(mapindex, pass))
 607                                 return mapindex;
 608                 }
 609         }
 610         return -1;
 611 }
 612
 613 float() MaplistMethod_Repeat = // fallback method
 614 {
 615         if(Map_Check(Map_Current, 2))
 616                 return Map_Current;
 617         return -2;
 618 }
 619
 620 float() MaplistMethod_Random = // random map selection
 621 {
 622         float i, imax;
 623
 624         imax = 42;
 625
 626         for(i = 0; i <= imax; ++i)
 627         {
 628                 float mapindex;
 629                 mapindex = mod(Map_Current + ceil(random() * (Map_Count - 1)), Map_Count); // any OTHER map
 630                 if(Map_Check(mapindex, 1))
 631                         return mapindex;
 632         }
 633         return -1;
 634 }
 635
 636 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
 637 // the exponent sets a bias on the map selection:
 638 // the higher the exponent, the less likely "shortly repeated" same maps are
 639 {
 640         float i, j, imax, insertpos;
 641
 642         imax = 42;
 643
 644         for(i = 0; i <= imax; ++i)
 645         {
 646                 string newlist;
 647
 648                 // now reinsert this at another position
 649                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
 650                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
 651                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
 652                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
 653
 654                 // insert the current map there
 655                 newlist = "";
 656 #ifdef MAPINFO
 657                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
 658                         newlist = strcat(newlist, " ", argv(j));
 659                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
 660                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
 661                         newlist = strcat(newlist, " ", argv(j));
 662                 newlist = substring(newlist, 1, strlen(newlist) - 1);
 663 #else
 664                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
 665                         newlist = strcat(newlist, "'", argv(j), "'");
 666                 newlist = strcat(newlist, "'", argv(0), "'");  // now insert the just selected map
 667                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
 668                         newlist = strcat(newlist, "'", argv(j), "'");
 669 #endif
 670                 cvar_set("g_maplist", newlist);
 671 #ifdef MAPINFO
 672                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 673 #else
 674                 Map_Count = tokenize(newlist);
 675 #endif
 676
 677                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
 678                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
 679                 if(Map_Check(Map_Current, 1))
 680                         return Map_Current;
 681         }
 682         return -1;
 683 }
 684
 685 void Maplist_Init()
 686 {
 687         string temp;
 688         temp = cvar_string("g_maplist");
 689 #ifdef MAPINFO
 690         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 691 #else
 692         Map_Count = tokenize(temp);
 693 #endif
 694         if(Map_Count == 0)
 695         {
 696                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
 697 #ifdef MAPINFO
 698                 cvar_set("g_maplist", temp = MapInfo_ListAllowedMaps());
 699                 localcmd("\nmenu_cmd sync\n");
 700                 Map_Count = tokenizebyseparator(temp, " ");
 701 #else
 702                 cvar_set("g_maplist", temp = cvar_string("g_maplist_defaultlist"));
 703                 Map_Count = tokenize(temp);
 704 #endif
 705         }
 706         if(Map_Count == 0)
 707                 error("empty maplist, cannot select a new map");
 708         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
 709
 710         if(Map_Current_Name)
 711                 strunzone(Map_Current_Name);
 712         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
 713         // this may or may not be correct, but who cares, in the worst case a map
 714         // isn't chosen in the first pass that should have been
 715 }
 716
 717 string GetNextMap()
 718 {
 719         float nextMap;
 720
 721         Maplist_Init();
 722         nextMap = -1;
 723
 724         if(nextMap == -1)
 725                 if(cvar("g_maplist_shuffle") > 0)
 726                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
 727
 728         if(nextMap == -1)
 729                 if(cvar("g_maplist_selectrandom"))
 730                         nextMap = MaplistMethod_Random();
 731
 732         if(nextMap == -1)
 733                 nextMap = MaplistMethod_Iterate();
 734
 735         if(nextMap == -1)
 736                 nextMap = MaplistMethod_Repeat();
 737
 738         if(nextMap >= 0)
 739         {
 740                 Map_Goto_SetFloat(nextMap);
 741                 return getmapname_stored;
 742         }
 743
 744         return "";
 745 };
 746
 747 float DoNextMapOverride()
 748 {
 749         if(cvar("g_campaign"))
 750         {
 751                 CampaignPostIntermission();
 752                 alreadychangedlevel = TRUE;
 753                 return TRUE;
 754         }
 755         if(cvar("quit_when_empty"))
 756         {
 757                 if(player_count <= currentbots)
 758                 {
 759                         localcmd("quit\n");
 760                         alreadychangedlevel = TRUE;
 761                         return TRUE;
 762                 }
 763         }
 764         if(cvar_string("quit_and_redirect") != "")
 765         {
 766                 redirection_target = strzone(cvar_string("quit_and_redirect"));
 767                 alreadychangedlevel = TRUE;
 768                 return TRUE;
 769         }
 770         if (cvar("samelevel")) // if samelevel is set, stay on same level
 771         {
 772                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
 773                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
 774                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
 775                 localcmd("restart\n");
 776                 //changelevel (mapname);
 777                 alreadychangedlevel = TRUE;
 778                 return TRUE;
 779         }
 780         if(cvar_string("nextmap") != "")
 781 #ifdef MAPINFO
 782                 if(MapInfo_CheckMap(cvar_string("nextmap")))
 783 #else
 784                 if(TryFile(strcat("maps/", cvar_string("nextmap"), ".mapcfg")))
 785 #endif
 786                 {
 787                         Map_Goto_SetStr(cvar_string("nextmap"));
 788                         Map_Goto();
 789                         alreadychangedlevel = TRUE;
 790                         return TRUE;
 791                 }
 792         if(cvar("lastlevel"))
 793         {
 794                 GameResetCfg();
 795                 localcmd("set lastlevel 0\ntogglemenu\n");
 796                 alreadychangedlevel = TRUE;
 797                 return TRUE;
 798         }
 799         return FALSE;
 800 };
 801
 802 void GotoNextMap()
 803 {
 804         //local string nextmap;
 805         //local float n, nummaps;
 806         //local string s;
 807         if (alreadychangedlevel)
 808                 return;
 809         alreadychangedlevel = TRUE;
 810
 811         {
 812                 string nextMap;
 813                 float allowReset;
 814
 815                 for(allowReset = 1; allowReset >= 0; --allowReset)
 816                 {
 817                         nextMap = GetNextMap();
 818                         if(nextMap != "")
 819                                 break;
 820
 821                         if(allowReset)
 822                         {
 823                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
 824 #ifdef MAPINFO
 825                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps());
 826                                 localcmd("\nmenu_cmd sync\n");
 827 #else
 828                                 cvar_set("g_maplist", cvar_string("g_maplist_defaultlist"));
 829 #endif
 830                         }
 831                         else
 832                         {
 833                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
 834                         }
 835                 }
 836                 Map_Goto();
 837         }
 838 };
 839
 840
 841 /*
 842 ============
 843 IntermissionThink
 844
 845 When the player presses attack or jump, change to the next level
 846 ============
 847 */
 848 .float autoscreenshot;
 849 void() MapVote_Start;
 850 void() MapVote_Think;
 851 float mapvote_initialized;
 852 void IntermissionThink()
 853 {
 854         FixIntermissionClient(self);
 855
 856         if(cvar("sv_autoscreenshot"))
 857         if(self.autoscreenshot > 0)
 858         if(time > self.autoscreenshot)
 859         {
 860                 self.autoscreenshot = -1;
 861                 if(clienttype(self) == CLIENTTYPE_REAL)
 862                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
 863                 return;
 864         }
 865
 866         if (time < intermission_exittime)
 867                 return;
 868
 869         if(!mapvote_initialized)
 870                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
 871                         return;
 872
 873         MapVote_Start();
 874 };
 875
 876 /*
 877 ============
 878 FindIntermission
 879
 880 Returns the entity to view from
 881 ============
 882 */
 883 /*
 884 entity FindIntermission()
 885 {
 886         local   entity spot;
 887         local   float cyc;
 888
 889 // look for info_intermission first
 890         spot = find (world, classname, "info_intermission");
 891         if (spot)
 892         {       // pick a random one
 893                 cyc = random() * 4;
 894                 while (cyc > 1)
 895                 {
 896                         spot = find (spot, classname, "info_intermission");
 897                         if (!spot)
 898                                 spot = find (spot, classname, "info_intermission");
 899                         cyc = cyc - 1;
 900                 }
 901                 return spot;
 902         }
 903
 904 // then look for the start position
 905         spot = find (world, classname, "info_player_start");
 906         if (spot)
 907                 return spot;
 908
 909 // testinfo_player_start is only found in regioned levels
 910         spot = find (world, classname, "testplayerstart");
 911         if (spot)
 912                 return spot;
 913
 914 // then look for the start position
 915         spot = find (world, classname, "info_player_deathmatch");
 916         if (spot)
 917                 return spot;
 918
 919         //objerror ("FindIntermission: no spot");
 920         return world;
 921 };
 922 */
 923
 924 /*
 925 ===============================================================================
 926
 927 RULES
 928
 929 ===============================================================================
 930 */
 931
 932 void DumpStats(float final)
 933 {
 934         local float file;
 935         local string s;
 936         local float to_console;
 937         local float to_eventlog;
 938         local float to_file;
 939
 940         to_console = cvar("sv_logscores_console");
 941         to_eventlog = cvar("sv_eventlog");
 942         to_file = cvar("sv_logscores_file");
 943
 944         if(!final)
 945         {
 946                 to_console = TRUE; // always print printstats replies
 947                 to_eventlog = FALSE; // but never print them to the event log
 948         }
 949
 950         if(to_eventlog)
 951                 if(cvar("sv_eventlog_console"))
 952                         to_console = FALSE; // otherwise we get the output twice
 953
 954         if(final)
 955                 s = ":scores:";
 956         else
 957                 s = ":status:";
 958 #ifdef MAPINFO
 959         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
 960 #else
 961         s = strcat(s, GetMapname(), ":", ftos(rint(time)));
 962 #endif
 963
 964         if(to_console)
 965                 ServerConsoleEcho(s, FALSE);
 966         if(to_eventlog)
 967                 GameLogEcho(s, FALSE);
 968         if(to_file)
 969         {
 970                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
 971                 if(file == -1)
 972                         to_file = FALSE;
 973                 else
 974                         fputs(file, strcat(s, "\n"));
 975         }
 976
 977         FOR_EACH_CLIENT(other)
 978         {
 979                 // FIXME make this use the new score system
 980                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
 981                 {
 982                         s = strcat(":player:", ftos(other.frags), ":");
 983                         s = strcat(s, ftos(other.deaths), ":");
 984                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
 985                         s = strcat(s, ftos(other.team), ":");
 986
 987                         if(to_console)
 988                                 ServerConsoleEcho(strcat(s, other.netname), TRUE);
 989                         if(to_eventlog)
 990                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname), TRUE);
 991                         if(to_file)
 992                                 fputs(file, strcat(s, other.netname, "\n"));
 993                 }
 994         }
 995
 996         if(g_ctf)
 997         if(cvar("g_ctf_win_mode") != 2)
 998         {
 999                 s = strcat(":teamscores:", ftos(COLOR_TEAM1), ":");
1000                 s = strcat(s, ftos(caps_team1), ":");
1001                 s = strcat(s, ftos(COLOR_TEAM2), ":");
1002                 s = strcat(s, ftos(caps_team2));
1003                 if(to_console)
1004                         ServerConsoleEcho(s, TRUE);
1005                 if(to_eventlog)
1006                         GameLogEcho(s, TRUE);
1007                 if(to_file)
1008                         fputs(file, strcat(s, "\n"));
1009         }
1010
1011         if(to_console)
1012                 ServerConsoleEcho(":end", FALSE);
1013         if(to_eventlog)
1014                 GameLogEcho(":end", FALSE);
1015         if(to_file)
1016         {
1017                 fputs(file, ":end\n");
1018                 fclose(file);
1019         }
1020 }
1021
1022 void FixIntermissionClient(entity e)
1023 {
1024         string s;
1025         if(!e.autoscreenshot) // initial call
1026         {
1027                 e.angles = e.v_angle;
1028                 e.angles_x = -e.angles_x;
1029                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1030                 e.health = -2342;
1031                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1032                 e.solid = SOLID_NOT;
1033                 e.movetype = MOVETYPE_NONE;
1034                 e.takedamage = DAMAGE_NO;
1035                 if(e.weaponentity)
1036                         e.weaponentity.effects = EF_NODRAW;
1037                 if(clienttype(e) == CLIENTTYPE_REAL)
1038                 {
1039                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1040                         s = cvar_string("sv_intermission_cdtrack");
1041                         if(s != "")
1042                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1043                         msg_entity = e;
1044                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1045                 }
1046         }
1047
1048         //e.velocity = '0 0 0';
1049         //e.fixangle = TRUE;
1050
1051         // TODO halt weapon animation
1052 }
1053
1054
1055 /*
1056 go to the next level for deathmatch
1057 only called if a time or frag limit has expired
1058 */
1059 void NextLevel()
1060 {
1061         float minTotalFrags;
1062         float maxTotalFrags;
1063         float score;
1064         float f;
1065
1066         gameover = TRUE;
1067
1068         intermission_running = 1;
1069
1070 // enforce a wait time before allowing changelevel
1071         if(player_count > 0)
1072                 intermission_exittime = time + cvar("sv_mapchange_delay");
1073         else
1074                 intermission_exittime = -1;
1075
1076         /*
1077         WriteByte (MSG_ALL, SVC_CDTRACK);
1078         WriteByte (MSG_ALL, 3);
1079         WriteByte (MSG_ALL, 3);
1080         // done in FixIntermission
1081         */
1082
1083         //pos = FindIntermission ();
1084
1085         VoteReset();
1086
1087         DumpStats(TRUE);
1088
1089         if(cvar("sv_eventlog"))
1090                 GameLogEcho(":gameover", FALSE);
1091
1092         GameLogClose();
1093
1094         FOR_EACH_CLIENT(other)
1095         {
1096                 FixIntermissionClient(other);
1097
1098                 if(other.winning)
1099                         bprint(other.netname, " ^7wins.\n");
1100         }
1101
1102         minTotalFrags = 0;
1103         maxTotalFrags = 0;
1104         FOR_EACH_PLAYER(other)
1105         {
1106                 if(maxTotalFrags < other.totalfrags)
1107                         maxTotalFrags = other.totalfrags;
1108                 if(minTotalFrags > other.totalfrags)
1109                         minTotalFrags = other.totalfrags;
1110         }
1111
1112         if(!currentbots)
1113         {
1114                 FOR_EACH_PLAYER(other)
1115                 {
1116                         score = (other.totalfrags - minTotalFrags) / max(maxTotalFrags - minTotalFrags, 1);
1117                         f = bound(0, other.play_time / max(time, 1), 1);
1118                         // store some statistics?
1119                 }
1120         }
1121
1122         if(cvar("g_campaign"))
1123                 CampaignPreIntermission();
1124
1125         // WriteByte (MSG_ALL, SVC_INTERMISSION);
1126 };
1127
1128 /*
1129 ============
1130 CheckRules_Player
1131
1132 Exit deathmatch games upon conditions
1133 ============
1134 */
1135 .float fogtime;
1136 void CheckRules_Player()
1137 {
1138         if (gameover)   // someone else quit the game already
1139                 return;
1140
1141         if(self.deadflag == DEAD_NO)
1142                 self.play_time += frametime;
1143
1144         if(sv_foginterval)
1145         if(world.fog)
1146         if(time > self.fogtime)
1147         {
1148                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1149                 self.fogtime = time + sv_foginterval;
1150         }
1151
1152         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1153         //   (div0: and that in CheckRules_World please)
1154 };
1155
1156 float checkrules_oneminutewarning;
1157 float checkrules_leaderfrags;
1158 float tdm_max_score, tdm_old_score;
1159
1160 float checkrules_equality;
1161 float checkrules_overtimewarning;
1162 float checkrules_overtimeend;
1163
1164 void InitiateOvertime()
1165 {
1166         if(!checkrules_overtimeend)
1167                 checkrules_overtimeend = time + 60 * cvar("timelimit_maxovertime");
1168 }
1169
1170 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1171 float WINNING_YES = 1; // winner found
1172 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1173 float WINNING_STARTOVERTIME = 3; // no winner, enter overtime NOW
1174
1175 float GetWinningCode(float fraglimitreached, float equality)
1176 {
1177         if(equality)
1178                 if(fraglimitreached)
1179                         return WINNING_STARTOVERTIME;
1180                 else
1181                         return WINNING_NEVER;
1182         else
1183                 if(fraglimitreached)
1184                         return WINNING_YES;
1185                 else
1186                         return WINNING_NO;
1187 }
1188
1189 // set the .winning flag for exactly those players with a given field value
1190 void SetWinners(.float field, float value)
1191 {
1192         entity head;
1193         FOR_EACH_PLAYER(head)
1194                 head.winning = (head.field == value);
1195 }
1196
1197 // set the .winning flag for those players with a given field value
1198 void AddWinners(.float field, float value)
1199 {
1200         entity head;
1201         FOR_EACH_PLAYER(head)
1202                 if(head.field == value)
1203                         head.winning = 1;
1204 }
1205
1206 // clear the .winning flags
1207 void ClearWinners(void)
1208 {
1209         entity head;
1210         FOR_EACH_PLAYER(head)
1211                 head.winning = 0;
1212 }
1213
1214 // Onslaught winning condition:
1215 // game terminates if only one team has a working generator (or none)
1216 float WinningCondition_Onslaught()
1217 {
1218         entity head;
1219         local float t1, t2, t3, t4;
1220         // first check if the game has ended
1221         t1 = t2 = t3 = t4 = 0;
1222         head = find(world, classname, "onslaught_generator");
1223         while (head)
1224         {
1225                 if (head.health > 0)
1226                 {
1227                         if (head.team == COLOR_TEAM1) t1 = 1;
1228                         if (head.team == COLOR_TEAM2) t2 = 1;
1229                         if (head.team == COLOR_TEAM3) t3 = 1;
1230                         if (head.team == COLOR_TEAM4) t4 = 1;
1231                 }
1232                 head = find(head, classname, "onslaught_generator");
1233         }
1234         if (t1 + t2 + t3 + t4 < 2)
1235         {
1236                 // game over, only one team remains (or none)
1237                 ClearWinners();
1238                 if (t1) SetWinners(team, COLOR_TEAM1);
1239                 if (t2) SetWinners(team, COLOR_TEAM2);
1240                 if (t3) SetWinners(team, COLOR_TEAM3);
1241                 if (t4) SetWinners(team, COLOR_TEAM4);
1242                 dprint("Have a winner, ending game.\n");
1243                 return WINNING_YES;
1244         }
1245
1246         // Two or more teams remain
1247         return WINNING_NO;
1248 }
1249
1250 float LMS_NewPlayerLives()
1251 {
1252         float fl;
1253         fl = cvar("fraglimit");
1254         if(fl == 0)
1255                 fl = 999;
1256
1257         // first player has left the game for dying too much? Nobody else can get in.
1258         if(lms_lowest_lives < 1)
1259                 return 0;
1260
1261         if(!cvar("g_lms_join_anytime"))
1262                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1263                         return 0;
1264
1265         return bound(1, lms_lowest_lives, fl);
1266 }
1267
1268 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1269 // they win. Otherwise the defending team wins once the timelimit passes.
1270 void assault_new_round();
1271 float WinningCondition_Assault()
1272 {
1273         local float status;
1274         status = WINNING_NO;
1275
1276         // as the timelimit has not yet passed just assume the defending team will win
1277         if(assault_attacker_team == COLOR_TEAM1)
1278         {
1279                 SetWinners(team, COLOR_TEAM2);
1280         }
1281         else
1282         {
1283                 SetWinners(team, COLOR_TEAM1);
1284         }
1285
1286         local entity ent;
1287         ent = find(world, classname, "target_assault_roundend");
1288         if(ent)
1289         {
1290                 if(ent.winning) // round end has been triggered by attacking team
1291                 {
1292                         SetWinners(team, assault_attacker_team);
1293                         if(assault_attacker_team == COLOR_TEAM1)
1294                         {
1295                                 team1_score = team1_score + 50;
1296                         }
1297                         else
1298                         {
1299                                 team2_score = team2_score + 50;
1300                         }
1301
1302                         if(ent.cnt == 1) // this was the second round
1303                         {
1304                                 status = WINNING_YES;
1305                         }
1306                         else
1307                         {
1308                                 local entity oldself;
1309                                 oldself = self;
1310                                 self = ent;
1311                                 cvar_set("timelimit", ftos((2*time)/60));
1312                                 assault_new_round();
1313                                 self = oldself;
1314                         }
1315                 }
1316         }
1317
1318         return status;
1319
1320 }
1321
1322 // LMS winning condition: game terminates if and only if there's at most one
1323 // one player who's living lives. Top two scores being equal cancels the time
1324 // limit.
1325 float WinningCondition_LMS()
1326 {
1327         // FIXME make this use the new score system
1328         entity head;
1329         float have_player;
1330         float have_players;
1331         float l;
1332
1333         have_player = FALSE;
1334         have_players = FALSE;
1335         l = LMS_NewPlayerLives();
1336
1337         head = find(world, classname, "player");
1338         if(head)
1339                 have_player = TRUE;
1340         head = find(head, classname, "player");
1341         if(head)
1342                 have_players = TRUE;
1343
1344         if(have_player)
1345         {
1346                 // we have at least one player
1347                 if(have_players)
1348                 {
1349                         // two or more active players - continue with the game
1350                 }
1351                 else
1352                 {
1353                         // exactly one player?
1354
1355                         ClearWinners();
1356                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1357
1358                         if(l)
1359                         {
1360                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1361                                 return WINNING_NO;
1362                         }
1363                         else
1364                         {
1365                                 // a winner!
1366                                 return WINNING_YES;
1367                         }
1368                 }
1369         }
1370         else
1371         {
1372                 // nobody is playing at all...
1373                 if(l)
1374                 {
1375                         // wait for players...
1376                 }
1377                 else
1378                 {
1379                         // SNAFU (maybe a draw game?)
1380                         ClearWinners();
1381                         dprint("No players, ending game.\n");
1382                         return WINNING_YES;
1383                 }
1384         }
1385
1386         // When we get here, we have at least two players who are actually LIVING,
1387         // now check if the top two players have equal score.
1388         WinningConditionHelper();
1389
1390         ClearWinners();
1391         if(WinningConditionHelper_winner)
1392                 WinningConditionHelper_winner.winning = TRUE;
1393         if(WinningConditionHelper_equality)
1394                 return WINNING_NEVER;
1395
1396         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1397         return WINNING_NO;
1398 }
1399
1400 void print_to(entity e, string s)
1401 {
1402         if(e)
1403                 sprint(e, strcat(s, "\n"));
1404         else
1405                 ServerConsoleEcho(s, TRUE);
1406 }
1407
1408 void ShuffleMaplist()
1409 {
1410         string result;
1411         float start;
1412         float litems;
1413         float selected;
1414         float i;
1415
1416         result = cvar_string("g_maplist");
1417 #ifdef MAPINFO
1418         litems = tokenizebyseparator(result, " ");
1419 #else
1420         litems = tokenize(result);
1421 #endif
1422
1423         for(start = 0; start < litems - 1; ++start)
1424         {
1425                 result = "";
1426
1427                 // select a random item
1428                 selected = ceil(random() * (litems - start) + start) - 1;
1429
1430                 // shift this item to the place start
1431 #ifdef MAPINFO
1432                 for(i = 0; i < start; ++i)
1433                         result = strcat(result, " ", argv(i));
1434                 result = strcat(result, " ", argv(selected));
1435                 for(i = start; i < litems; ++i)
1436                         if(i != selected)
1437                                 result = strcat(result, " ", argv(i));
1438                 result = substring(result, 1, strlen(result) - 1);
1439
1440                 litems = tokenizebyseparator(result, " ");
1441 #else
1442                 for(i = 0; i < start; ++i)
1443                         result = strcat(result, "'", argv(i), "'");
1444                 result = strcat(result, "'", argv(selected), "'");
1445                 for(i = start; i < litems; ++i)
1446                         if(i != selected)
1447                                 result = strcat(result, "'", argv(i), "'");
1448
1449                 litems = tokenize(result);
1450 #endif
1451
1452                 //dprint(result, "\n");
1453         }
1454
1455         cvar_set("g_maplist", result);
1456 }
1457
1458 float WinningCondition_Scores(float limit)
1459 {
1460         // TODO make everything use THIS winning condition (except LMS)
1461         WinningConditionHelper();
1462
1463         ClearWinners();
1464         if(WinningConditionHelper_winner)
1465                 WinningConditionHelper_winner.winning = 1;
1466         if(WinningConditionHelper_winnerteam >= 0)
1467                 SetWinners(team, WinningConditionHelper_winnerteam);
1468
1469         return GetWinningCode(WinningConditionHelper_topscore >= limit, WinningConditionHelper_equality);
1470 }
1471
1472 float WinningCondition_RanOutOfSpawns()
1473 {
1474         entity head;
1475
1476         if(!have_team_spawns)
1477                 return WINNING_NO;
1478
1479         if(!some_spawn_has_been_used)
1480                 return WINNING_NO;
1481
1482         team1_score = team2_score = team3_score = team4_score = 0;
1483
1484         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1485         {
1486                 if(head.team == COLOR_TEAM1)
1487                         team1_score = 1;
1488                 else if(head.team == COLOR_TEAM2)
1489                         team2_score = 1;
1490                 else if(head.team == COLOR_TEAM3)
1491                         team3_score = 1;
1492                 else if(head.team == COLOR_TEAM4)
1493                         team4_score = 1;
1494         }
1495
1496         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1497         {
1498                 if(head.team == COLOR_TEAM1)
1499                         team1_score = 1;
1500                 else if(head.team == COLOR_TEAM2)
1501                         team2_score = 1;
1502                 else if(head.team == COLOR_TEAM3)
1503                         team3_score = 1;
1504                 else if(head.team == COLOR_TEAM4)
1505                         team4_score = 1;
1506         }
1507
1508         ClearWinners();
1509         if(team1_score + team2_score + team3_score + team4_score == 0)
1510         {
1511                 checkrules_equality = TRUE;
1512                 return WINNING_YES;
1513         }
1514         else if(team1_score + team2_score + team3_score + team4_score == 1)
1515         {
1516                 float t, i;
1517                 if(team1_score) t = COLOR_TEAM1;
1518                 if(team2_score) t = COLOR_TEAM2;
1519                 if(team3_score) t = COLOR_TEAM3;
1520                 if(team4_score) t = COLOR_TEAM4;
1521                 CheckAllowedTeams(world);
1522                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1523                 {
1524                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_Add(COLOR_TEAM1, i, -1000);
1525                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_Add(COLOR_TEAM2, i, -1000);
1526                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_Add(COLOR_TEAM3, i, -1000);
1527                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_Add(COLOR_TEAM4, i, -1000);
1528                 }
1529
1530                 AddWinners(team, t);
1531                 return WINNING_YES;
1532         }
1533         else
1534                 return WINNING_NO;
1535 }
1536
1537 /*
1538 ============
1539 CheckRules_World
1540
1541 Exit deathmatch games upon conditions
1542 ============
1543 */
1544 void CheckRules_World()
1545 {
1546         local float status;
1547         local float timelimit;
1548         local float fraglimit;
1549         local float capturelimit;
1550
1551         VoteThink();
1552         MapVote_Think();
1553
1554         SetDefaultAlpha();
1555
1556         /*
1557         MapVote_Think should now do that part
1558         if (intermission_running)
1559                 if (time >= intermission_exittime + 60)
1560                 {
1561                         if(!DoNextMapOverride())
1562                                 GotoNextMap();
1563                         return;
1564                 }
1565         */
1566
1567         if (gameover)   // someone else quit the game already
1568         {
1569                 if(player_count == 0) // Nobody there? Then let's go to the next map
1570                         MapVote_Start();
1571                         // this will actually check the player count in the next frame
1572                         // again, but this shouldn't hurt
1573                 return;
1574         }
1575
1576         timelimit = cvar("timelimit") * 60;
1577         fraglimit = cvar("fraglimit");
1578         capturelimit = cvar("capturelimit");
1579
1580         if(checkrules_overtimeend)
1581         {
1582                 if(!checkrules_overtimewarning)
1583                 {
1584                         checkrules_overtimewarning = TRUE;
1585                         //sound(world, CHAN_AUTO, "announcer/robotic/1minuteremains.wav", 1, ATTN_NONE);
1586                         bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
1587                 }
1588         }
1589         else
1590         {
1591                 if (timelimit && time >= timelimit)
1592                         InitiateOvertime();
1593         }
1594
1595         if (checkrules_overtimeend && time >= checkrules_overtimeend)
1596         {
1597                 NextLevel();
1598                 return;
1599         }
1600
1601         if (!checkrules_oneminutewarning && timelimit > 0 && time > timelimit - 60)
1602         {
1603                 checkrules_oneminutewarning = TRUE;
1604                 sound(world, CHAN_AUTO, "announcer/robotic/1minuteremains.wav", 1, ATTN_NONE);
1605         }
1606
1607         status = WinningCondition_RanOutOfSpawns();
1608         if(status == WINNING_YES)
1609         {
1610                 bprint("Hey! Someone ran out of spawns!\n");
1611         }
1612         else if(g_assault)
1613         {
1614                 status = WinningCondition_Assault(); // TODO remove this?
1615         }
1616         else if(g_lms)
1617         {
1618                 status = WinningCondition_LMS();
1619         }
1620         else if (g_onslaught)
1621         {
1622                 status = WinningCondition_Onslaught(); // TODO remove this?
1623         }
1624         else
1625         {
1626                 status = WinningCondition_Scores(fraglimit);
1627         }
1628
1629         if(status == WINNING_STARTOVERTIME)
1630         {
1631                 status = WINNING_NEVER;
1632                 InitiateOvertime();
1633         }
1634
1635         if(status == WINNING_NEVER)
1636                 // equality cases! Nobody wins if the overtime ends in a draw.
1637                 ClearWinners();
1638
1639         if(checkrules_overtimeend)
1640                 if(status != WINNING_NEVER || time >= checkrules_overtimeend)
1641                         status = WINNING_YES;
1642
1643         if(status == WINNING_YES)
1644                 NextLevel();
1645 };
1646
1647 float mapvote_nextthink;
1648 float mapvote_initialized;
1649 float mapvote_keeptwotime;
1650 float mapvote_timeout;
1651 string mapvote_message;
1652 string mapvote_screenshot_dir;
1653
1654 float mapvote_count;
1655 float mapvote_count_real;
1656 string mapvote_maps[MAPVOTE_COUNT];
1657 float mapvote_maps_suggested[MAPVOTE_COUNT];
1658 string mapvote_suggestions[MAPVOTE_COUNT];
1659 float mapvote_suggestion_ptr;
1660 float mapvote_maxlen;
1661 float mapvote_voters;
1662 float mapvote_votes[MAPVOTE_COUNT];
1663 float mapvote_run;
1664 float mapvote_detail;
1665 float mapvote_abstain;
1666 float mapvote_dirty;
1667 .float mapvote;
1668
1669 void MapVote_ClearAllVotes()
1670 {
1671         FOR_EACH_CLIENT(other)
1672                 other.mapvote = 0;
1673 }
1674
1675 string MapVote_Suggest(string m)
1676 {
1677         float i;
1678         if(m == "")
1679                 return "That's not how to use this command.";
1680         if(!cvar("g_maplist_votable_suggestions"))
1681                 return "Suggestions are not accepted on this server.";
1682         if(mapvote_initialized)
1683                 return "Can't suggest - voting is already in progress!";
1684 #ifdef MAPINFO
1685         m = MapInfo_FixName(m);
1686         if(!m)
1687                 return "The map you suggested is not available on this server.";
1688 #else
1689         if(!cvar("g_maplist_votable_suggestions_change_gametype"))
1690                 if(!IsSameGametype(m))
1691                         return "This server does not allow changing the game type by map suggestions.";
1692 #endif
1693         if(!cvar("g_maplist_votable_override_mostrecent"))
1694                 if(Map_IsRecent(m))
1695                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
1696
1697 #ifdef MAPINFO
1698         if(!MapInfo_CheckMap(m))
1699                 return "The map you suggested does not support the current game mode.";
1700 #else
1701         if(!TryFile(strcat("maps/", m, ".mapcfg")))
1702                 return "The map you suggested is not available on this server.";
1703 #endif
1704         for(i = 0; i < mapvote_suggestion_ptr; ++i)
1705                 if(mapvote_suggestions[i] == m)
1706                         return "This map was already suggested.";
1707         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
1708         {
1709                 i = ceil(random() * mapvote_suggestion_ptr) - 1;
1710         }
1711         else
1712         {
1713                 i = mapvote_suggestion_ptr;
1714                 mapvote_suggestion_ptr += 1;
1715         }
1716         if(mapvote_suggestions[i] != "")
1717                 strunzone(mapvote_suggestions[i]);
1718         mapvote_suggestions[i] = strzone(m);
1719         if(cvar("sv_eventlog"))
1720                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)), TRUE);
1721         return strcat("Suggestion of ", m, " accepted.");
1722 }
1723
1724 void MapVote_AddVotable(string nextMap, float isSuggestion)
1725 {
1726         float j;
1727         if(nextMap == "")
1728                 return;
1729         for(j = 0; j < mapvote_count; ++j)
1730                 if(mapvote_maps[j] == nextMap)
1731                         return;
1732         if(strlen(nextMap) > mapvote_maxlen)
1733                 mapvote_maxlen = strlen(nextMap);
1734         mapvote_maps[mapvote_count] = strzone(nextMap);
1735         mapvote_maps_suggested[mapvote_count] = isSuggestion;
1736         mapvote_count += 1;
1737 }
1738
1739 void MapVote_SendData(float target);
1740 void MapVote_Init()
1741 {
1742         float i;
1743         float nmax, smax;
1744
1745         MapVote_ClearAllVotes();
1746
1747         mapvote_count = 0;
1748         mapvote_detail = !cvar("g_maplist_votable_nodetail");
1749         mapvote_abstain = cvar("g_maplist_votable_abstain");
1750
1751         if(mapvote_abstain)
1752                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
1753         else
1754                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
1755         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
1756
1757         if(mapvote_suggestion_ptr)
1758                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
1759                         MapVote_AddVotable(mapvote_suggestions[ceil(random() * mapvote_suggestion_ptr) - 1], TRUE);
1760
1761         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
1762                 MapVote_AddVotable(GetNextMap(), FALSE);
1763
1764         if(mapvote_count == 0)
1765         {
1766                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1767 #ifdef MAPINFO
1768                 cvar_set("g_maplist", MapInfo_ListAllowedMaps());
1769                 localcmd("\nmenu_cmd sync\n");
1770 #else
1771                 cvar_set("g_maplist", cvar_string("g_maplist_defaultlist"));
1772 #endif
1773                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
1774                         MapVote_AddVotable(GetNextMap(), FALSE);
1775         }
1776
1777         mapvote_count_real = mapvote_count;
1778         if(mapvote_abstain)
1779                 MapVote_AddVotable("don't care", 0);
1780
1781         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
1782
1783         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
1784         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
1785         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
1786                 mapvote_keeptwotime = 0;
1787         mapvote_message = "Choose a map and press its key!";
1788
1789         mapvote_screenshot_dir = cvar_string("g_maplist_votable_screenshot_dir");
1790         if(mapvote_screenshot_dir == "")
1791                 mapvote_screenshot_dir = "maps";
1792         mapvote_screenshot_dir = strzone(mapvote_screenshot_dir);
1793
1794         if(!cvar("g_maplist_textonly"))
1795                 MapVote_SendData(MSG_BROADCAST);
1796 }
1797
1798 void MapVote_SendPicture(float id)
1799 {
1800         msg_entity = self;
1801         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1802         WriteByte(MSG_ONE, TE_CSQC_MAPVOTE);
1803         WriteByte(MSG_ONE, MAPVOTE_NET_PIC);
1804         WriteByte(MSG_ONE, id);
1805         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dir, "/", mapvote_maps[id]), 1024);
1806 }
1807
1808 float GameCommand_MapVote(string cmd)
1809 {
1810         if(!intermission_running)
1811                 return FALSE;
1812         if(!cvar("g_maplist_textonly"))
1813         {
1814                 if(cmd == "mv_getpic")
1815                 {
1816                         MapVote_SendPicture(stof(argv(1)));
1817                         return TRUE;
1818                 }
1819         }
1820
1821         return FALSE;
1822 }
1823
1824 float MapVote_GetMapMask()
1825 {
1826         float mask, i, power;
1827         mask = 0;
1828         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
1829                 if(mapvote_maps[i] != "")
1830                         mask |= power;
1831         return mask;
1832 }
1833
1834 void MapVote_SendData(float targ)
1835 {
1836         string mapfile, pakfile;
1837         float i, o;
1838         WriteByte(targ, SVC_TEMPENTITY);
1839         WriteByte(targ, TE_CSQC_CONFIG);
1840         WriteString(targ, "mv_screenshot_dir");
1841         WriteString(targ, mapvote_screenshot_dir);
1842
1843         WriteByte(targ, SVC_TEMPENTITY);
1844         WriteByte(targ, TE_CSQC_MAPVOTE);
1845         WriteByte(targ, MAPVOTE_NET_INIT);
1846
1847         WriteByte(targ, mapvote_count);
1848         WriteByte(targ, mapvote_abstain);
1849         WriteByte(targ, mapvote_detail);
1850         WriteByte(targ, mapvote_timeout - time);
1851         if(mapvote_count <= 8)
1852                 WriteByte(targ, MapVote_GetMapMask());
1853         else
1854                 WriteShort(targ, MapVote_GetMapMask());
1855         for(i = 0; i < mapvote_count; ++i)
1856                 if(mapvote_maps[i] != "")
1857                 {
1858                         WriteString(targ, mapvote_maps[i]);
1859                         mapfile = strcat(mapvote_screenshot_dir, "/", mapvote_maps[i]);
1860                         pakfile = whichpack(strcat(mapfile, ".tga"));
1861                         if(pakfile == "")
1862                                 pakfile = whichpack(strcat(mapfile, ".jpg"));
1863                         if(pakfile == "")
1864                                 pakfile = whichpack(strcat(mapfile, ".png"));
1865                         print("pakfile is ", pakfile, "\n");
1866                         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
1867                                 pakfile = substring(pakfile, o, 999);
1868                         WriteString(targ, pakfile);
1869                 }
1870 }
1871
1872 void MapVote_UpdateData(float targ)
1873 {
1874         float i;
1875         WriteByte(targ, SVC_TEMPENTITY);
1876         WriteByte(targ, TE_CSQC_MAPVOTE);
1877         WriteByte(targ, MAPVOTE_NET_UPDATE);
1878         if(mapvote_count <= 8)
1879                 WriteByte(targ, MapVote_GetMapMask());
1880         else
1881                 WriteShort(targ, MapVote_GetMapMask());
1882         if(mapvote_detail)
1883                 for(i = 0; i < mapvote_count; ++i)
1884                         if(mapvote_maps[i] != "")
1885                                 WriteByte(targ, mapvote_votes[i]);
1886 }
1887
1888 void MapVote_TellVote(float targ, float vote)
1889 {
1890         WriteByte(targ, SVC_TEMPENTITY);
1891         WriteByte(targ, TE_CSQC_MAPVOTE);
1892         WriteByte(targ, MAPVOTE_NET_OWNVOTE);
1893         WriteByte(targ, vote);
1894 }
1895
1896 float MapVote_Finished(float mappos)
1897 {
1898         string result;
1899         float i;
1900         float didntvote;
1901
1902         if(cvar("sv_eventlog"))
1903         {
1904                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
1905                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
1906                 didntvote = mapvote_voters;
1907                 for(i = 0; i < mapvote_count; ++i)
1908                         if(mapvote_maps[i] != "")
1909                         {
1910                                 didntvote -= mapvote_votes[i];
1911                                 if(i != mappos)
1912                                 {
1913                                         result = strcat(result, ":", mapvote_maps[i]);
1914                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
1915                                 }
1916                         }
1917                 result = strcat(result, ":didn't vote:", ftos(didntvote));
1918
1919                 GameLogEcho(result, FALSE);
1920                 if(mapvote_maps_suggested[mappos])
1921                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]), FALSE);
1922         }
1923
1924         FOR_EACH_REALCLIENT(other)
1925                 FixClientCvars(other);
1926
1927         Map_Goto_SetStr(mapvote_maps[mappos]);
1928         Map_Goto();
1929         alreadychangedlevel = TRUE;
1930         return TRUE;
1931 }
1932 void MapVote_CheckRules_1()
1933 {
1934         float i;
1935
1936         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
1937         {
1938                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
1939                 mapvote_votes[i] = 0;
1940         }
1941
1942         mapvote_voters = 0;
1943         FOR_EACH_REALCLIENT(other)
1944         {
1945                 ++mapvote_voters;
1946                 if(other.mapvote)
1947                 {
1948                         i = other.mapvote - 1;
1949                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
1950                         mapvote_votes[i] = mapvote_votes[i] + 1;
1951                 }
1952         }
1953 }
1954
1955 float MapVote_CheckRules_2()
1956 {
1957         float i;
1958         float firstPlace, secondPlace;
1959         float firstPlaceVotes, secondPlaceVotes;
1960         float mapvote_voters_real;
1961         string result;
1962
1963         mapvote_voters_real = mapvote_voters;
1964         if(mapvote_abstain)
1965                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
1966
1967         RandomSelection_Init();
1968         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
1969                 RandomSelection_Add(world, i, 1, mapvote_votes[i]);
1970         firstPlace = RandomSelection_chosen_float;
1971         firstPlaceVotes = RandomSelection_best_priority;
1972         //dprint("First place: ", ftos(firstPlace), "\n");
1973         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
1974
1975         RandomSelection_Init();
1976         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
1977                 if(i != firstPlace)
1978                         RandomSelection_Add(world, i, 1, mapvote_votes[i]);
1979         secondPlace = RandomSelection_chosen_float;
1980         secondPlaceVotes = RandomSelection_best_priority;
1981         //dprint("Second place: ", ftos(secondPlace), "\n");
1982         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
1983
1984         if(firstPlace == -1)
1985                 error("No first place in map vote... WTF?");
1986
1987         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
1988                 return MapVote_Finished(firstPlace);
1989
1990         if(mapvote_keeptwotime)
1991                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
1992                 {
1993                         float didntvote;
1994                         mapvote_dirty = TRUE;
1995                         mapvote_message = "Now decide between the TOP TWO!";
1996                         mapvote_keeptwotime = 0;
1997                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
1998                         result = strcat(result, ":", ftos(firstPlaceVotes));
1999                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2000                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2001                         didntvote = mapvote_voters;
2002                         for(i = 0; i < mapvote_count; ++i)
2003                                 if(mapvote_maps[i] != "")
2004                                 {
2005                                         didntvote -= mapvote_votes[i];
2006                                         if(i != firstPlace)
2007                                                 if(i != secondPlace)
2008                                                 {
2009                                                         result = strcat(result, ":", mapvote_maps[i]);
2010                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2011                                                         if(i < mapvote_count_real)
2012                                                         {
2013                                                                 strunzone(mapvote_maps[i]);
2014                                                                 mapvote_maps[i] = "";
2015                                                         }
2016                                                 }
2017                                 }
2018                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2019                         if(cvar("sv_eventlog"))
2020                                 GameLogEcho(result, FALSE);
2021                 }
2022
2023         return FALSE;
2024 }
2025 void MapVote_Tick()
2026 {
2027         string msgstr;
2028         string tmp;
2029         float i;
2030         float keeptwo;
2031         float totalvotes;
2032
2033         keeptwo = mapvote_keeptwotime;
2034         MapVote_CheckRules_1(); // count
2035         if(MapVote_CheckRules_2()) // decide
2036                 return;
2037
2038         totalvotes = 0;
2039         FOR_EACH_REALCLIENT(other)
2040         {
2041                 // hide scoreboard again
2042                 if(other.health != 2342)
2043                 {
2044                         other.health = 2342;
2045                         other.impulse = 0;
2046                         if(clienttype(other) == CLIENTTYPE_REAL)
2047                         {
2048                                 if(cvar("g_maplist_textonly"))
2049                                         stuffcmd(other, "\nin_bind 7 1 \"impulse 1\"; in_bind 7 2 \"impulse 2\"; in_bind 7 3 \"impulse 3\"; in_bind 7 4 \"impulse 4\"; in_bind 7 5 \"impulse 5\"; in_bind 7 6 \"impulse 6\"; in_bind 7 7 \"impulse 7\"; in_bind 7 8 \"impulse 8\"; in_bind 7 9 \"impulse 9\"; in_bind 7 0 \"impulse 10\"; in_bind 7 KP_1 \"impulse 1\"; in_bind 7 KP_2 \"impulse 2\"; in_bind 7 KP_3 \"impulse 3\"; in_bind 7 KP_4 \"impulse 4\"; in_bind 7 KP_5 \"impulse 5\"; in_bind 7 KP_6 \"impulse 6\"; in_bind 7 KP_7 \"impulse 7\"; in_bind 7 KP_8 \"impulse 8\"; in_bind 7 KP_9 \"impulse 9\"; in_bind 7 KP_0 \"impulse 10\"; in_bindmap 7 0\n");
2050
2051                                 msg_entity = other;
2052                                 WriteByte(MSG_ONE, SVC_FINALE);
2053                                 WriteString(MSG_ONE, "");
2054                         }
2055                 }
2056
2057                 // notify about keep-two
2058                 if(keeptwo != 0 && mapvote_keeptwotime == 0)
2059                         play2(other, "misc/invshot.wav");
2060
2061                 // clear possibly invalid votes
2062                 if(mapvote_maps[other.mapvote - 1] == "")
2063                         other.mapvote = 0;
2064                 // use impulses as new vote
2065                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2066                         if(mapvote_maps[other.impulse - 1] != "")
2067                         {
2068                                 other.mapvote = other.impulse;
2069                                 if(mapvote_detail)
2070                                         mapvote_dirty = TRUE;
2071
2072                                 msg_entity = other;
2073                                 MapVote_TellVote(MSG_ONE, other.mapvote);
2074                         }
2075                 other.impulse = 0;
2076
2077                 if(other.mapvote)
2078                         ++totalvotes;
2079         }
2080
2081         MapVote_CheckRules_1(); // just count
2082
2083         if(!cvar("g_maplist_textonly"))
2084         if(mapvote_dirty) // 1 if "keeptwo" or "impulse" happened before
2085         {
2086                 MapVote_UpdateData(MSG_BROADCAST);
2087                 mapvote_dirty = FALSE;
2088         }
2089
2090         if(cvar("g_maplist_textonly"))
2091         {
2092                 FOR_EACH_REALCLIENT(other)
2093                 {
2094                         // display voting screen
2095                         msgstr = "\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n";
2096                         msgstr = substring(msgstr, 0, strlen(msgstr) - mapvote_count);
2097                         if(mapvote_abstain)
2098                                 msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
2099                         msgstr = strcat(msgstr, mapvote_message);
2100                         msgstr = strcat(msgstr, "\n\n");
2101                         for(i = 0; i < mapvote_count; ++i)
2102                                 if(mapvote_maps[i] == "")
2103                                         msgstr = strcat(msgstr, "\n");
2104                                 else
2105                                 {
2106                                         tmp = mapvote_maps[i];
2107                                         tmp = strpad(mapvote_maxlen, tmp);
2108                                         tmp = strcat(ftos(mod(i + 1, 10)), ": ", tmp);
2109                                         if(mapvote_detail)
2110                                         {
2111                                                 tmp = strcat(tmp, " ^2(", ftos(mapvote_votes[i]), " vote");
2112                                                 if(mapvote_votes[i] != 1)
2113                                                         tmp = strcat(tmp, "s");
2114                                                 tmp = strcat(tmp, ")");
2115                                                 tmp = strpad(mapvote_maxlen + 15, tmp);
2116                                         }
2117                                         if(mapvote_abstain)
2118                                                 if(i == mapvote_count - 1)
2119                                                         msgstr = strcat(msgstr, "\n");
2120                                         if(other.mapvote == i + 1)
2121                                                 msgstr = strcat(msgstr, "^3> ", tmp, "\n");
2122                                         else
2123                                                 msgstr = strcat(msgstr, "^7  ", tmp, "\n");
2124                                 }
2125
2126                         msgstr = strcat(msgstr, "\n\n^2", ftos(totalvotes), " vote");
2127                         if(totalvotes != 1)
2128                                 msgstr = strcat(msgstr, "s");
2129                         msgstr = strcat(msgstr, " cast");
2130                         i = ceil(mapvote_timeout - time);
2131                         msgstr = strcat(msgstr, "\n", ftos(i), " second");
2132                         if(i != 1)
2133                                 msgstr = strcat(msgstr, "s");
2134                         msgstr = strcat(msgstr, " left");
2135
2136                         centerprint_atprio(other, CENTERPRIO_MAPVOTE, msgstr);
2137                 }
2138         }
2139 }
2140 void MapVote_Start()
2141 {
2142         if(mapvote_run)
2143                 return;
2144
2145 #ifdef MAPINFO
2146         MapInfo_Enumerate();
2147         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 1))
2148 #endif
2149                 mapvote_run = TRUE;
2150 }
2151 void MapVote_Think()
2152 {
2153         if(!mapvote_run)
2154                 return;
2155
2156         if(alreadychangedlevel)
2157                 return;
2158
2159         if(time < mapvote_nextthink)
2160                 return;
2161         //dprint("tick\n");
2162
2163         mapvote_nextthink = time + 0.5;
2164
2165         if(!mapvote_initialized)
2166         {
2167                 mapvote_initialized = TRUE;
2168                 if(DoNextMapOverride())
2169                         return;
2170                 if(!cvar("g_maplist_votable") || player_count <= 0)
2171                 {
2172                         GotoNextMap();
2173                         return;
2174                 }
2175                 MapVote_Init();
2176         }
2177
2178         MapVote_Tick();
2179 };
2180
2181 string GotoMap(string m)
2182 {
2183 #ifdef MAPINFO
2184         if(!MapInfo_CheckMap(m))
2185 #else
2186         if(!TryFile(strcat("maps/", m, ".mapcfg")))
2187 #endif
2188                 return "The map you chose is not available on this server.";
2189         cvar_set("nextmap", m);
2190         cvar_set("timelimit", "-1");
2191         if(mapvote_initialized || alreadychangedlevel)
2192         {
2193                 if(DoNextMapOverride())
2194                         return "Map switch initiated.";
2195                 else
2196                         return "Hm... no. For some reason I like THIS map more.";
2197         }
2198         else
2199                 return "Map switch will happen after scoreboard.";
2200 }
2201
2202
2203 void EndFrame()
2204 {
2205         FOR_EACH_REALCLIENT(self)
2206         {
2207                 if(self.classname == "spectator")
2208                 {
2209                         if(self.enemy.hitsound)
2210                                 play2(self, "misc/hit.wav");
2211                 }
2212                 else
2213                 {
2214                         if(self.hitsound)
2215                                 play2(self, "misc/hit.wav");
2216                 }
2217         }
2218         FOR_EACH_CLIENT(self)
2219                 self.hitsound = FALSE;
2220 }
2221
2222
2223 /*
2224  * RedirectionThink:
2225  * returns TRUE if redirecting
2226  */
2227 float redirection_timeout;
2228 float redirection_nextthink;
2229 float RedirectionThink()
2230 {
2231         float clients_found;
2232
2233         if(redirection_target == "")
2234                 return FALSE;
2235
2236         if(!redirection_timeout)
2237         {
2238                 cvar_set("sv_public", "-2");
2239                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2240                 if(redirection_target == "self")
2241                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2242                 else
2243                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2244         }
2245
2246         if(time < redirection_nextthink)
2247                 return TRUE;
2248
2249         redirection_nextthink = time + 1;
2250
2251         clients_found = 0;
2252         FOR_EACH_REALCLIENT(self)
2253         {
2254                 ServerConsoleEcho(strcat("Redirecting: sending connect command to ", self.netname), FALSE);
2255                 if(redirection_target == "self")
2256                         stuffcmd(self, "\ndisconnect; reconnect\n");
2257                 else
2258                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2259                 ++clients_found;
2260         }
2261
2262         ServerConsoleEcho(strcat("Redirecting: ", ftos(clients_found), " clients left."), FALSE);
2263
2264         if(time > redirection_timeout || clients_found == 0)
2265                 localcmd("\nwait; wait; wait; quit\n");
2266
2267         return TRUE;
2268 }
2269
2270 void SV_Shutdown()
2271 {
2272         if(world_initialized)
2273         {
2274                 world_initialized = 0;
2275                 print("Saving persistent data...\n");
2276                 Ban_SaveBans();
2277                 if(!sv_cheats)
2278                         db_save(ServerProgsDB, "server.db");
2279                 db_close(ServerProgsDB);
2280                 print("done!\n");
2281                 // tell the bot system the game is ending now
2282                 bot_endgame();
2283
2284                 MapInfo_Shutdown();
2285         }
2286         else
2287         {
2288                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2289         }
2290 }