data/qcsrc/server/g_world.qc

   1 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
   2 string redirection_target;
   3 float world_initialized;
   4
   5 string GetMapname();
   6 string GetGametype();
   7 void GotoNextMap();
   8 void ShuffleMaplist()
   9 float() DoNextMapOverride;
  10
  11 void SetDefaultAlpha()
  12 {
  13         if(cvar("g_running_guns"))
  14         {
  15                 default_player_alpha = -1;
  16                 default_weapon_alpha = +1;
  17         }
  18         else if(g_cloaked)
  19         {
  20                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  21                 default_weapon_alpha = default_player_alpha;
  22         }
  23         else
  24         {
  25                 default_player_alpha = cvar("g_player_alpha");
  26                 if(default_player_alpha == 0)
  27                         default_player_alpha = 1;
  28                 default_weapon_alpha = default_player_alpha;
  29         }
  30 }
  31
  32 void fteqcc_testbugs()
  33 {
  34         float a, b;
  35
  36         if(!cvar("developer_fteqccbugs"))
  37                 return;
  38
  39         dprint("*** fteqcc test: checking for bugs...\n");
  40
  41         a = 1;
  42         b = 5;
  43         if(sqrt(a) - sqrt(b - a) == 0)
  44                 dprint("*** fteqcc test: found same-function-twice bug\n");
  45         else
  46                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  47
  48         world.cnt = -10;
  49         world.enemy = world;
  50         world.enemy.cnt += 10;
  51         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  52                 dprint("*** fteqcc test: found += bug\n");
  53         else
  54                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  55         world.cnt = 0;
  56 }
  57
  58 /**
  59  * Takes care of pausing and unpausing the game.
  60  * Centerprints the information about an upcoming or active timeout to all active
  61  * players. Also plays reminder sounds.
  62  */
  63 void timeoutHandler_Think() {
  64         local string timeStr;
  65         local entity plr;
  66         if (timeoutStatus == 1) {
  67                 if (remainingLeadTime > 0) {
  68                         //centerprint the information to every player
  69                         timeStr = getTimeoutText(0);
  70                         FOR_EACH_REALCLIENT(plr) {
  71                                 if(plr.classname == "player") {
  72                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  73                                 }
  74                         }
  75                         remainingLeadTime -= 1;
  76                         //think again in 1 second:
  77                         self.nextthink = time + 1;
  78                 }
  79                 else {
  80                         //now pause the game:
  81                         timeoutStatus = 2;
  82                         //reset all the flood variables
  83                         FOR_EACH_CLIENT(plr) {
  84                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
  85                         }
  86                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
  87                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
  88                         FOR_EACH_REALPLAYER(plr) {
  89                                 plr.lastV_angle = plr.v_angle;
  90                         }
  91                         self.nextthink = time;
  92                 }
  93         }
  94         else if (timeoutStatus == 2) {
  95                 if (remainingTimeoutTime > 0) {
  96                         timeStr = getTimeoutText(0);
  97                         FOR_EACH_REALCLIENT(plr) {
  98                                 if(plr.classname == "player") {
  99                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 100                                 }
 101                         }
 102                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 103                                 play2all("announcer/robotic/prepareforbattle.wav");
 104                         }
 105                         remainingTimeoutTime -= 1;
 106                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 107                 }
 108                 else {
 109                         //unpause the game again
 110                         remainingTimeoutTime = timeoutStatus = 0;
 111                         cvar_set("slowmo", ftos(orig_slowmo));
 112                         //and unlock the fixed view again once there is no timeout active anymore
 113                         FOR_EACH_REALPLAYER(plr) {
 114                                 plr.fixangle = FALSE;
 115                         }
 116                         //get rid of the countdown message
 117                         FOR_EACH_REALCLIENT(plr) {
 118                                 if(plr.classname == "player") {
 119                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 120                                 }
 121                         }
 122                         remove(self);
 123                         return;
 124                 }
 125
 126         }
 127         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 128                 FOR_EACH_REALCLIENT(plr) {
 129                         if(plr.classname == "player") {
 130                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 131                         }
 132                 }
 133                 remove(self);
 134                 return;
 135         }
 136 }
 137
 138 void GotoFirstMap()
 139 {
 140         float n;
 141         if(cvar("_sv_init"))
 142         {
 143                 // cvar_set("_sv_init", "0");
 144                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 145                 // to this "init" map on a dedicated server will cause no permanent
 146                 // harm
 147                 if(cvar("g_maplist_shuffle"))
 148                         ShuffleMaplist();
 149                 n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 150                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 151
 152                 MapInfo_Enumerate();
 153                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN) | MAPINFO_FLAG_FORBIDDEN, 0);
 154
 155                 if(!DoNextMapOverride())
 156                         GotoNextMap();
 157
 158                 return;
 159         }
 160
 161         if(time < 5)
 162         {
 163                 self.nextthink = time;
 164         }
 165         else
 166         {
 167                 self.nextthink = time + 1;
 168                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 169         }
 170 }
 171
 172 void cvar_changes_init()
 173 {
 174         float h;
 175         string k, v, d;
 176         float n, i;
 177
 178         if(cvar_changes)
 179                 strunzone(cvar_changes);
 180         cvar_changes = string_null;
 181
 182         h = buf_create();
 183         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 184         n = buf_getsize(h);
 185
 186         for(i = 0; i < n; ++i)
 187         {
 188                 k = bufstr_get(h, i);
 189
 190 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 191 #define BADCVAR(p) if(k == p) continue
 192                 // internal
 193                 BADPREFIX("csqc_");
 194                 BADPREFIX("cvar_check_");
 195                 BADCVAR("gamecfg");
 196                 BADCVAR("g_configversion");
 197                 BADCVAR("g_maplist_index");
 198                 BADCVAR("halflifebsp");
 199
 200                 // client
 201                 BADPREFIX("cl_");
 202                 BADPREFIX("con_");
 203                 BADPREFIX("g_campaign");
 204                 BADPREFIX("gl_");
 205                 BADPREFIX("joy");
 206                 BADPREFIX("menu_");
 207                 BADPREFIX("net_slist_");
 208                 BADPREFIX("r_");
 209                 BADPREFIX("sbar_");
 210                 BADPREFIX("scr_");
 211                 BADPREFIX("userbind");
 212                 BADPREFIX("v_");
 213                 BADPREFIX("vid_");
 214                 BADPREFIX("crosshair");
 215                 BADCVAR("mod_q3bsp_lightmapmergepower");
 216                 BADCVAR("mod_q3bsp_nolightmaps");
 217
 218                 // private
 219                 BADPREFIX("g_ban_");
 220                 BADPREFIX("g_chat_flood_");
 221                 BADPREFIX("g_voice_flood_");
 222                 BADPREFIX("rcon_");
 223                 BADPREFIX("settemp_");
 224                 BADPREFIX("sv_allowdownloads_");
 225                 BADPREFIX("sv_autodemo");
 226                 BADPREFIX("sv_curl_");
 227                 BADPREFIX("sv_eventlog");
 228                 BADPREFIX("sv_logscores_");
 229                 BADPREFIX("sv_master");
 230                 BADCVAR("g_banned_list");
 231                 BADCVAR("log_dest_udp");
 232                 BADCVAR("log_file");
 233                 BADCVAR("net_address");
 234                 BADCVAR("port");
 235                 BADCVAR("savedgamecfg");
 236                 BADCVAR("sv_heartbeatperoid");
 237                 BADCVAR("sv_vote_master_password");
 238                 BADCVAR("sys_colortranslation");
 239                 BADCVAR("sys_specialcharactertranslation");
 240                 BADCVAR("timestamps");
 241
 242                 // mapinfo
 243                 BADCVAR("timelimit");
 244                 BADCVAR("fraglimit");
 245                 BADCVAR("g_arena");
 246                 BADCVAR("g_assault");
 247                 BADCVAR("g_ctf");
 248                 BADCVAR("g_dm");
 249                 BADCVAR("g_domination");
 250                 BADCVAR("g_keyhunt");
 251                 BADCVAR("g_keyhunt_teams");
 252                 BADCVAR("g_onslaught");
 253                 BADCVAR("g_race");
 254                 BADCVAR("g_runematch");
 255                 BADCVAR("g_tdm");
 256                 BADCVAR("teamplay");
 257
 258                 // long
 259                 BADCVAR("hostname");
 260                 BADCVAR("g_maplist");
 261                 BADCVAR("g_maplist_mostrecent");
 262                 BADCVAR("sv_motd");
 263 #undef BADPREFIX
 264 #undef BADCVAR
 265
 266                 v = cvar_string(k);
 267                 d = cvar_defstring(k);
 268                 if(v != d)
 269                 {
 270                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 271                         if(strlen(cvar_changes) > 16384)
 272                         {
 273                                 cvar_changes = "// too many settings have been changed to show them here\n";
 274                                 break;
 275                         }
 276                 }
 277         }
 278         buf_del(h);
 279         if(cvar_changes == "")
 280                 cvar_changes = "// this server runs at default settings\n";
 281         else
 282                 cvar_changes = strcat("// this server runs at modified settings:\n", cvar_changes);
 283         cvar_changes = strzone(cvar_changes);
 284 }
 285
 286 void detect_maptype()
 287 {
 288 #if 0
 289         vector o, v;
 290         float i;
 291
 292         for(;;)
 293         {
 294                 o = world.mins;
 295                 o_x += random() * (world.maxs_x - world.mins_x);
 296                 o_y += random() * (world.maxs_y - world.mins_y);
 297                 o_z += random() * (world.maxs_z - world.mins_z);
 298
 299                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 300                 if(trace_fraction == 1)
 301                         continue;
 302
 303                 v = trace_endpos;
 304
 305                 for(i = 0; i < 64; i += 4)
 306                 {
 307                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 308         if(trace_fraction == 1)
 309                 continue;
 310                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 311                 }
 312
 313                 break;
 314         }
 315 #endif
 316 }
 317
 318 entity randomseed;
 319 float RandomSeed_Send(entity to, float sf)
 320 {
 321         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 322         WriteShort(MSG_ENTITY, self.cnt);
 323         return TRUE;
 324 }
 325 void RandomSeed_Think()
 326 {
 327         self.cnt = bound(0, floor(random() * 65536), 65535);
 328         self.nextthink = time + 5;
 329
 330         self.SendFlags |= 1;
 331 }
 332 void RandomSeed_Spawn()
 333 {
 334         randomseed = spawn();
 335         randomseed.think = RandomSeed_Think;
 336         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 337
 338         entity oldself;
 339         oldself = self;
 340         self = randomseed;
 341         self.think(); // sets random seed and nextthink
 342         self = oldself;
 343 }
 344
 345 void spawnfunc___init_dedicated_server(void)
 346 {
 347         // handler for _init/_init map (only for dedicated server initialization)
 348
 349         world_initialized = -1; // don't complain
 350         cvar = cvar_builtin;
 351         cvar_string = cvar_string_builtin;
 352         cvar_set = cvar_set_builtin;
 353         dprint_load(); // load dprint status from cvar
 354
 355         remove = remove_unsafely;
 356
 357         entity e;
 358         e = spawn();
 359         e.think = GotoFirstMap;
 360         e.nextthink = time; // this is usually 1 at this point
 361
 362         e = spawn();
 363         e.classname = "info_player_deathmatch"; // safeguard against player joining
 364
 365         self.classname = "worldspawn"; // safeguard against various stuff ;)
 366
 367         g_maplist_allow_hidden = cvar("g_maplist_allow_hidden");
 368         MapInfo_Enumerate();
 369         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN) | MAPINFO_FLAG_FORBIDDEN, 0);
 370 }
 371
 372 void Map_MarkAsRecent(string m);
 373 float world_already_spawned;
 374 void RegisterWeapons();
 375 void Nagger_Init();
 376 void ClientInit_Spawn();
 377 void spawnfunc_worldspawn (void)
 378 {
 379         float fd, l, i, j, n;
 380         string s, col;
 381
 382         cvar = cvar_builtin;
 383         cvar_string = cvar_string_builtin;
 384         cvar_set = cvar_set_builtin;
 385         dprint_load(); // load dprint status from cvar
 386
 387         if(world_already_spawned)
 388                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 389         world_already_spawned = TRUE;
 390
 391         remove = remove_safely; // during spawning, watch what you remove!
 392
 393         check_unacceptable_compiler_bugs();
 394
 395         if(cvar_string("cvar_check_default") != "bypass")
 396         {
 397                 if(cvar_string("cvar_check_default") != CVAR_CHECK_DEFAULT)
 398                         error("Config file mismatch! Please update defaultNexuiz.cfg to match the QuakeC code, and restart the engine!");
 399
 400                 if(cvar_string("cvar_check_weapons") != CVAR_CHECK_WEAPONS)
 401                         error("Config file mismatch! Please update weapons.cfg and weaponsHavoc.cfg to match the QuakeC code, and restart the engine!");
 402         }
 403
 404         compressShortVector_init();
 405
 406         local entity head;
 407         head = nextent(world);
 408         maxclients = 0;
 409         while(head)
 410         {
 411                 ++maxclients;
 412                 head = nextent(head);
 413         }
 414
 415         // needs to be done so early as they would still spawn
 416         RegisterWeapons();
 417
 418         if(sv_cheats)
 419                 ServerProgsDB = db_create();
 420         else
 421                 ServerProgsDB = db_load("server.db");
 422
 423         TemporaryDB = db_create();
 424
 425         /*
 426         TODO sound pack system
 427         // initialize sound pack system
 428         soundpack = cvar_string("g_soundpack");
 429         if(soundpack != "")
 430                 soundpack = strcat(soundpack, "/");
 431         soundpack = strzone(soundpack);
 432         */
 433
 434         // 0 normal
 435         lightstyle(0, "m");
 436
 437         // 1 FLICKER (first variety)
 438         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 439
 440         // 2 SLOW STRONG PULSE
 441         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 442
 443         // 3 CANDLE (first variety)
 444         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 445
 446         // 4 FAST STROBE
 447         lightstyle(4, "mamamamamama");
 448
 449         // 5 GENTLE PULSE 1
 450         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 451
 452         // 6 FLICKER (second variety)
 453         lightstyle(6, "nmonqnmomnmomomno");
 454
 455         // 7 CANDLE (second variety)
 456         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 457
 458         // 8 CANDLE (third variety)
 459         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 460
 461         // 9 SLOW STROBE (fourth variety)
 462         lightstyle(9, "aaaaaaaazzzzzzzz");
 463
 464         // 10 FLUORESCENT FLICKER
 465         lightstyle(10, "mmamammmmammamamaaamammma");
 466
 467         // 11 SLOW PULSE NOT FADE TO BLACK
 468         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 469
 470         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 471
 472         // 63 testing
 473         lightstyle(63, "a");
 474
 475         if(cvar("g_campaign"))
 476                 CampaignPreInit();
 477
 478         Map_MarkAsRecent(mapname);
 479
 480         precache_model ("null"); // we need this one before InitGameplayMode
 481         InitGameplayMode();
 482         readlevelcvars();
 483         GrappleHookInit();
 484
 485         player_count = 0;
 486         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 487         if(bot_waypoints_for_items == 1)
 488                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 489                         bot_waypoints_for_items = 0;
 490
 491         // for setting by mapinfo
 492         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 493         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 494
 495         precache();
 496
 497         WaypointSprite_Init();
 498
 499         //if (g_domination)
 500         //      dom_init();
 501
 502         GameLogInit(); // prepare everything
 503         if(cvar("sv_eventlog"))
 504         {
 505                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 506                 s = strcat(s, ftos(random()));
 507                 matchid = strzone(s);
 508
 509                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 510                 s = ":gameinfo:mutators:LIST";
 511                 if(cvar("g_grappling_hook"))
 512                         s = strcat(s, ":grappling_hook");
 513                 if(!cvar("g_use_ammunition"))
 514                         s = strcat(s, ":no_use_ammunition");
 515                 if(!cvar("g_pickup_items"))
 516                         s = strcat(s, ":no_pickup_items");
 517                 if(cvar("g_instagib"))
 518                         s = strcat(s, ":instagib");
 519                 if(cvar_string("g_weaponarena") != "0")
 520                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 521                 if(cvar("g_nixnex"))
 522                         s = strcat(s, ":nixnex");
 523                 if(cvar("g_vampire"))
 524                         s = strcat(s, ":vampire");
 525                 if(cvar("g_laserguided_missile"))
 526                         s = strcat(s, ":laserguided_missile");
 527                 if(cvar("g_norecoil"))
 528                         s = strcat(s, ":norecoil");
 529                 if(cvar("g_midair"))
 530                         s = strcat(s, ":midair");
 531                 if(cvar("g_minstagib"))
 532                         s = strcat(s, ":minstagib");
 533                 GameLogEcho(s);
 534                 GameLogEcho(":gameinfo:end");
 535         }
 536         else
 537                 matchid = strzone(ftos(random()));
 538
 539         cvar_set("nextmap", "");
 540
 541         SetDefaultAlpha();
 542
 543         if(cvar("g_campaign"))
 544                 CampaignPostInit();
 545
 546         fteqcc_testbugs();
 547
 548         Ban_LoadBans();
 549
 550         //initialise globals related to sv_timeout
 551         sys_ticrate = cvar("sys_ticrate");
 552         orig_slowmo = cvar("slowmo");
 553
 554         MapInfo_Enumerate();
 555         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN) | MAPINFO_FLAG_FORBIDDEN, 1);
 556
 557         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 558         {
 559                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 560                 if(fd != -1)
 561                 {
 562                         while((s = fgets(fd)))
 563                         {
 564                                 l = tokenize_console(s);
 565                                 if(l < 2)
 566                                         continue;
 567                                 if(argv(0) == "cd")
 568                                 {
 569                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 570                                         print("  cdtrack ", argv(2), "\n");
 571                                 }
 572                                 else if(argv(0) == "fog")
 573                                 {
 574                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 575                                         print("  \"fog\" \"", s, "\"\n");
 576                                 }
 577                                 else if(argv(0) == "set")
 578                                 {
 579                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 580                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 581                                 }
 582                                 else if(argv(0) != "//")
 583                                 {
 584                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 585                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 586                                 }
 587                         }
 588                         fclose(fd);
 589                 }
 590         }
 591
 592         addstat(STAT_SYS_TICRATE, AS_FLOAT, stat_sys_ticrate);
 593         addstat(STAT_WEAPONS, AS_INT, weapons);
 594         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 595         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 596         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 597         Nagger_Init();
 598
 599         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 600         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 601         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 602         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 603         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 604
 605         next_pingtime = time + 5;
 606         InitializeEntity(self, cvar_changes_init, INITPRIO_CVARS);
 607
 608         detect_maptype();
 609
 610         lsmaps_reply = "^7Maps available: ";
 611         for(i = 0, j = 0; i < MapInfo_count; ++i)
 612         {
 613                 if(MapInfo_Get_ByID(i))
 614                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 615                         {
 616                                 if(mod(i, 2))
 617                                         col = "^2";
 618                                 else
 619                                         col = "^3";
 620                                 ++j;
 621                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 622                         }
 623         }
 624         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 625
 626         maplist_reply = "^7Maps in list: ";
 627         n = tokenize_console(cvar_string("g_maplist"));
 628         for(i = 0, j = 0; i < n; ++i)
 629         {
 630                 if(MapInfo_CheckMap(argv(i)))
 631                 {
 632                         if(mod(j, 2))
 633                                 col = "^2";
 634                         else
 635                                 col = "^3";
 636                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 637                         ++j;
 638                 }
 639         }
 640         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 641         MapInfo_ClearTemps();
 642
 643         records_reply = strzone(getrecords());
 644
 645         ClientInit_Spawn();
 646         RandomSeed_Spawn();
 647
 648         world_initialized = 1;
 649 }
 650
 651 void spawnfunc_light (void)
 652 {
 653         //makestatic (self); // Who the f___ did that?
 654         remove(self);
 655 }
 656
 657 float TryFile( string pFilename )
 658 {
 659         local float lHandle;
 660         dprint("TryFile(\"", pFilename, "\")\n");
 661         lHandle = fopen( pFilename, FILE_READ );
 662         if( lHandle != -1 ) {
 663                 fclose( lHandle );
 664                 return TRUE;
 665         } else {
 666                 return FALSE;
 667         }
 668 };
 669
 670 string GetGametype()
 671 {
 672         return GametypeNameFromType(game);
 673 }
 674
 675 string getmapname_stored;
 676 string GetMapname()
 677 {
 678         return mapname;
 679 }
 680
 681 float Map_Count, Map_Current;
 682 string Map_Current_Name;
 683
 684 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 685 float GetMaplistPosition()
 686 {
 687         float pos, idx;
 688         string map;
 689
 690         map = GetMapname();
 691         idx = cvar("g_maplist_index");
 692
 693         if(idx >= 0)
 694                 if(idx < Map_Count)
 695                         if(map == argv(idx))
 696                                 return idx;
 697
 698         for(pos = 0; pos < Map_Count; ++pos)
 699                 if(map == argv(pos))
 700                         return pos;
 701
 702         // resume normal maplist rotation if current map is not in g_maplist
 703         return idx;
 704 }
 705
 706 float MapHasRightSize(string map)
 707 {
 708         float fh;
 709         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 710         if(cvar("g_maplist_check_waypoints"))
 711         {
 712                 dprint("checkwp "); dprint(map);
 713                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 714                 if(fh < 0)
 715                 {
 716                         dprint(": no waypoints\n");
 717                         return FALSE;
 718                 }
 719                 dprint(": has waypoints\n");
 720                 fclose(fh);
 721         }
 722
 723         // open map size restriction file
 724         dprint("opensize "); dprint(map);
 725         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 726         if(fh >= 0)
 727         {
 728                 float mapmin, mapmax;
 729                 dprint(": ok, ");
 730                 mapmin = stof(fgets(fh));
 731                 mapmax = stof(fgets(fh));
 732                 fclose(fh);
 733                 if(player_count < mapmin)
 734                 {
 735                         dprint("not enough\n");
 736                         return FALSE;
 737                 }
 738                 if(player_count > mapmax)
 739                 {
 740                         dprint("too many\n");
 741                         return FALSE;
 742                 }
 743                 dprint("right size\n");
 744                 return TRUE;
 745         }
 746         dprint(": not found\n");
 747         return TRUE;
 748 }
 749
 750 string Map_Filename(float position)
 751 {
 752         return strcat("maps/", argv(position), ".bsp");
 753 }
 754
 755 string strwords(string s, float w)
 756 {
 757         float endpos;
 758         for(endpos = 0; w && endpos >= 0; --w)
 759                 endpos = strstrofs(s, " ", endpos + 1);
 760         if(endpos < 0)
 761                 return s;
 762         else
 763                 return substring(s, 0, endpos);
 764 }
 765
 766 float strhasword(string s, string w)
 767 {
 768         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 769 }
 770
 771 void Map_MarkAsRecent(string m)
 772 {
 773         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), max(0, cvar("g_maplist_mostrecent_count"))));
 774 }
 775
 776 float Map_IsRecent(string m)
 777 {
 778         return strhasword(cvar_string("g_maplist_mostrecent"), m);
 779 }
 780
 781 float Map_Check(float position, float pass)
 782 {
 783         string filename;
 784         string map_next;
 785         map_next = argv(position);
 786         if(pass <= 1)
 787         {
 788                 if(Map_IsRecent(map_next))
 789                         return 0;
 790         }
 791         filename = Map_Filename(position);
 792         if(MapInfo_CheckMap(map_next))
 793         {
 794                 if(pass == 2)
 795                         return 1;
 796                 if(MapHasRightSize(map_next))
 797                         return 1;
 798                 return 0;
 799         }
 800         else
 801                 dprint( "Couldn't select '", filename, "'..\n" );
 802
 803         return 0;
 804 }
 805
 806 void Map_Goto_SetStr(string nextmapname)
 807 {
 808         if(getmapname_stored != "")
 809                 strunzone(getmapname_stored);
 810         if(nextmapname == "")
 811                 getmapname_stored = "";
 812         else
 813                 getmapname_stored = strzone(nextmapname);
 814 }
 815
 816 void Map_Goto_SetFloat(float position)
 817 {
 818         cvar_set("g_maplist_index", ftos(position));
 819         Map_Goto_SetStr(argv(position));
 820 }
 821
 822 void GameResetCfg()
 823 {
 824         // settings persist, except...
 825         localcmd("\nsettemp_restore\n");
 826 };
 827
 828 void Map_Goto()
 829 {
 830         GameResetCfg();
 831         MapInfo_LoadMap(getmapname_stored);
 832 }
 833
 834 // return codes of map selectors:
 835 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
 836 //   -2 = permanent failure
 837 float() MaplistMethod_Iterate = // usual method
 838 {
 839         float pass, i;
 840
 841         for(pass = 1; pass <= 2; ++pass)
 842         {
 843                 for(i = 1; i < Map_Count; ++i)
 844                 {
 845                         float mapindex;
 846                         mapindex = mod(i + Map_Current, Map_Count);
 847                         if(Map_Check(mapindex, pass))
 848                                 return mapindex;
 849                 }
 850         }
 851         return -1;
 852 }
 853
 854 float() MaplistMethod_Repeat = // fallback method
 855 {
 856         if(Map_Check(Map_Current, 2))
 857                 return Map_Current;
 858         return -2;
 859 }
 860
 861 float() MaplistMethod_Random = // random map selection
 862 {
 863         float i, imax;
 864
 865         imax = 42;
 866
 867         for(i = 0; i <= imax; ++i)
 868         {
 869                 float mapindex;
 870                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
 871                 if(Map_Check(mapindex, 1))
 872                         return mapindex;
 873         }
 874         return -1;
 875 }
 876
 877 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
 878 // the exponent sets a bias on the map selection:
 879 // the higher the exponent, the less likely "shortly repeated" same maps are
 880 {
 881         float i, j, imax, insertpos;
 882
 883         imax = 42;
 884
 885         for(i = 0; i <= imax; ++i)
 886         {
 887                 string newlist;
 888
 889                 // now reinsert this at another position
 890                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
 891                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
 892                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
 893                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
 894
 895                 // insert the current map there
 896                 newlist = "";
 897                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
 898                         newlist = strcat(newlist, " ", argv(j));
 899                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
 900                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
 901                         newlist = strcat(newlist, " ", argv(j));
 902                 newlist = substring(newlist, 1, strlen(newlist) - 1);
 903                 cvar_set("g_maplist", newlist);
 904                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 905
 906                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
 907                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
 908                 if(Map_Check(Map_Current, 1))
 909                         return Map_Current;
 910         }
 911         return -1;
 912 }
 913
 914 void Maplist_Init()
 915 {
 916         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 917         if(Map_Count == 0)
 918         {
 919                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
 920                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN));
 921                 if(cvar("g_maplist_shuffle"))
 922                         ShuffleMaplist();
 923                 localcmd("\nmenu_cmd sync\n");
 924                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 925         }
 926         if(Map_Count == 0)
 927                 error("empty maplist, cannot select a new map");
 928         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
 929
 930         if(Map_Current_Name)
 931                 strunzone(Map_Current_Name);
 932         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
 933         // this may or may not be correct, but who cares, in the worst case a map
 934         // isn't chosen in the first pass that should have been
 935 }
 936
 937 string GetNextMap()
 938 {
 939         float nextMap;
 940
 941         Maplist_Init();
 942         nextMap = -1;
 943
 944         if(nextMap == -1)
 945                 if(cvar("g_maplist_shuffle") > 0)
 946                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
 947
 948         if(nextMap == -1)
 949                 if(cvar("g_maplist_selectrandom"))
 950                         nextMap = MaplistMethod_Random();
 951
 952         if(nextMap == -1)
 953                 nextMap = MaplistMethod_Iterate();
 954
 955         if(nextMap == -1)
 956                 nextMap = MaplistMethod_Repeat();
 957
 958         if(nextMap >= 0)
 959         {
 960                 Map_Goto_SetFloat(nextMap);
 961                 return getmapname_stored;
 962         }
 963
 964         return "";
 965 };
 966
 967 float DoNextMapOverride()
 968 {
 969         if(cvar("g_campaign"))
 970         {
 971                 CampaignPostIntermission();
 972                 alreadychangedlevel = TRUE;
 973                 return TRUE;
 974         }
 975         if(cvar("quit_when_empty"))
 976         {
 977                 if(player_count <= currentbots)
 978                 {
 979                         localcmd("quit\n");
 980                         alreadychangedlevel = TRUE;
 981                         return TRUE;
 982                 }
 983         }
 984         if(cvar_string("quit_and_redirect") != "")
 985         {
 986                 redirection_target = strzone(cvar_string("quit_and_redirect"));
 987                 alreadychangedlevel = TRUE;
 988                 return TRUE;
 989         }
 990         if (cvar("samelevel")) // if samelevel is set, stay on same level
 991         {
 992                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
 993                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
 994                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
 995                 localcmd("restart\n");
 996                 //changelevel (mapname);
 997                 alreadychangedlevel = TRUE;
 998                 return TRUE;
 999         }
1000         if(cvar_string("nextmap") != "")
1001                 if(MapInfo_CheckMap(cvar_string("nextmap")))
1002                 {
1003                         Map_Goto_SetStr(cvar_string("nextmap"));
1004                         Map_Goto();
1005                         alreadychangedlevel = TRUE;
1006                         return TRUE;
1007                 }
1008         if(cvar("lastlevel"))
1009         {
1010                 GameResetCfg();
1011                 localcmd("set lastlevel 0\ntogglemenu\n");
1012                 alreadychangedlevel = TRUE;
1013                 return TRUE;
1014         }
1015         return FALSE;
1016 };
1017
1018 void GotoNextMap()
1019 {
1020         //local string nextmap;
1021         //local float n, nummaps;
1022         //local string s;
1023         if (alreadychangedlevel)
1024                 return;
1025         alreadychangedlevel = TRUE;
1026
1027         {
1028                 string nextMap;
1029                 float allowReset;
1030
1031                 for(allowReset = 1; allowReset >= 0; --allowReset)
1032                 {
1033                         nextMap = GetNextMap();
1034                         if(nextMap != "")
1035                                 break;
1036
1037                         if(allowReset)
1038                         {
1039                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1040                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN));
1041                                 if(cvar("g_maplist_shuffle"))
1042                                         ShuffleMaplist();
1043                                 localcmd("\nmenu_cmd sync\n");
1044                         }
1045                         else
1046                         {
1047                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1048                         }
1049                 }
1050                 Map_Goto();
1051         }
1052 };
1053
1054
1055 /*
1056 ============
1057 IntermissionThink
1058
1059 When the player presses attack or jump, change to the next level
1060 ============
1061 */
1062 .float autoscreenshot;
1063 void() MapVote_Start;
1064 void() MapVote_Think;
1065 float mapvote_initialized;
1066 void IntermissionThink()
1067 {
1068         FixIntermissionClient(self);
1069
1070         if(cvar("sv_autoscreenshot"))
1071         if(self.autoscreenshot > 0)
1072         if(time > self.autoscreenshot)
1073         {
1074                 self.autoscreenshot = -1;
1075                 if(clienttype(self) == CLIENTTYPE_REAL)
1076                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1077                 return;
1078         }
1079
1080         if (time < intermission_exittime)
1081                 return;
1082
1083         if(!mapvote_initialized)
1084                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1085                         return;
1086
1087         MapVote_Start();
1088 };
1089
1090 /*
1091 ============
1092 FindIntermission
1093
1094 Returns the entity to view from
1095 ============
1096 */
1097 /*
1098 entity FindIntermission()
1099 {
1100         local   entity spot;
1101         local   float cyc;
1102
1103 // look for info_intermission first
1104         spot = find (world, classname, "info_intermission");
1105         if (spot)
1106         {       // pick a random one
1107                 cyc = random() * 4;
1108                 while (cyc > 1)
1109                 {
1110                         spot = find (spot, classname, "info_intermission");
1111                         if (!spot)
1112                                 spot = find (spot, classname, "info_intermission");
1113                         cyc = cyc - 1;
1114                 }
1115                 return spot;
1116         }
1117
1118 // then look for the start position
1119         spot = find (world, classname, "info_player_start");
1120         if (spot)
1121                 return spot;
1122
1123 // testinfo_player_start is only found in regioned levels
1124         spot = find (world, classname, "testplayerstart");
1125         if (spot)
1126                 return spot;
1127
1128 // then look for the start position
1129         spot = find (world, classname, "info_player_deathmatch");
1130         if (spot)
1131                 return spot;
1132
1133         //objerror ("FindIntermission: no spot");
1134         return world;
1135 };
1136 */
1137
1138 /*
1139 ===============================================================================
1140
1141 RULES
1142
1143 ===============================================================================
1144 */
1145
1146 void DumpStats(float final)
1147 {
1148         local float file;
1149         local string s;
1150         local float to_console;
1151         local float to_eventlog;
1152         local float to_file;
1153         local float i;
1154
1155         to_console = cvar("sv_logscores_console");
1156         to_eventlog = cvar("sv_eventlog");
1157         to_file = cvar("sv_logscores_file");
1158
1159         if(!final)
1160         {
1161                 to_console = TRUE; // always print printstats replies
1162                 to_eventlog = FALSE; // but never print them to the event log
1163         }
1164
1165         if(to_eventlog)
1166                 if(cvar("sv_eventlog_console"))
1167                         to_console = FALSE; // otherwise we get the output twice
1168
1169         if(final)
1170                 s = ":scores:";
1171         else
1172                 s = ":status:";
1173         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1174
1175         if(to_console)
1176                 print(s, "\n");
1177         if(to_eventlog)
1178                 GameLogEcho(s);
1179         if(to_file)
1180         {
1181                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1182                 if(file == -1)
1183                         to_file = FALSE;
1184                 else
1185                         fputs(file, strcat(s, "\n"));
1186         }
1187
1188         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1189         if(to_console)
1190                 print(s, "\n");
1191         if(to_eventlog)
1192                 GameLogEcho(s);
1193         if(to_file)
1194                 fputs(file, strcat(s, "\n"));
1195
1196         FOR_EACH_CLIENT(other)
1197         {
1198                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1199                 {
1200                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1201                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1202                         if(other.classname == "player" || g_arena || g_lms)
1203                                 s = strcat(s, ftos(other.team), ":");
1204                         else
1205                                 s = strcat(s, "spectator:");
1206
1207                         if(to_console)
1208                                 print(s, other.netname, "\n");
1209                         if(to_eventlog)
1210                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1211                         if(to_file)
1212                                 fputs(file, strcat(s, other.netname, "\n"));
1213                 }
1214         }
1215
1216         if(teams_matter)
1217         {
1218                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1219                 if(to_console)
1220                         print(s, "\n");
1221                 if(to_eventlog)
1222                         GameLogEcho(s);
1223                 if(to_file)
1224                         fputs(file, strcat(s, "\n"));
1225
1226                 for(i = 1; i < 16; ++i)
1227                 {
1228                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1229                         s = strcat(s, ":", ftos(i));
1230                         if(to_console)
1231                                 print(s, "\n");
1232                         if(to_eventlog)
1233                                 GameLogEcho(s);
1234                         if(to_file)
1235                                 fputs(file, strcat(s, "\n"));
1236                 }
1237         }
1238
1239         if(to_console)
1240                 print(":end\n");
1241         if(to_eventlog)
1242                 GameLogEcho(":end");
1243         if(to_file)
1244         {
1245                 fputs(file, ":end\n");
1246                 fclose(file);
1247         }
1248 }
1249
1250 void FixIntermissionClient(entity e)
1251 {
1252         string s;
1253         if(!e.autoscreenshot) // initial call
1254         {
1255                 e.angles = e.v_angle;
1256                 e.angles_x = -e.angles_x;
1257                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1258                 e.health = -2342;
1259                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1260                 e.solid = SOLID_NOT;
1261                 e.movetype = MOVETYPE_NONE;
1262                 e.takedamage = DAMAGE_NO;
1263                 if(e.weaponentity)
1264                 {
1265                         e.weaponentity.effects = EF_NODRAW;
1266                         if (e.weaponentity.weaponentity)
1267                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1268                 }
1269                 if(clienttype(e) == CLIENTTYPE_REAL)
1270                 {
1271                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1272                         s = cvar_string("sv_intermission_cdtrack");
1273                         if(s != "")
1274                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1275                         msg_entity = e;
1276                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1277                 }
1278         }
1279
1280         //e.velocity = '0 0 0';
1281         //e.fixangle = TRUE;
1282
1283         // TODO halt weapon animation
1284 }
1285
1286
1287 /*
1288 go to the next level for deathmatch
1289 only called if a time or frag limit has expired
1290 */
1291 void NextLevel()
1292 {
1293         float minTotalFrags;
1294         float maxTotalFrags;
1295         float score;
1296         float f;
1297
1298         gameover = TRUE;
1299
1300         intermission_running = 1;
1301
1302 // enforce a wait time before allowing changelevel
1303         if(player_count > 0)
1304                 intermission_exittime = time + cvar("sv_mapchange_delay");
1305         else
1306                 intermission_exittime = -1;
1307
1308         /*
1309         WriteByte (MSG_ALL, SVC_CDTRACK);
1310         WriteByte (MSG_ALL, 3);
1311         WriteByte (MSG_ALL, 3);
1312         // done in FixIntermission
1313         */
1314
1315         //pos = FindIntermission ();
1316
1317         VoteReset();
1318
1319         DumpStats(TRUE);
1320
1321         if(cvar("sv_eventlog"))
1322                 GameLogEcho(":gameover");
1323
1324         GameLogClose();
1325
1326         FOR_EACH_CLIENT(other)
1327         {
1328                 FixIntermissionClient(other);
1329
1330                 if(other.winning)
1331                         bprint(other.netname, " ^7wins.\n");
1332         }
1333
1334         minTotalFrags = 0;
1335         maxTotalFrags = 0;
1336         FOR_EACH_PLAYER(other)
1337         {
1338                 if(maxTotalFrags < other.totalfrags)
1339                         maxTotalFrags = other.totalfrags;
1340                 if(minTotalFrags > other.totalfrags)
1341                         minTotalFrags = other.totalfrags;
1342         }
1343
1344         if(!currentbots)
1345         {
1346                 FOR_EACH_PLAYER(other)
1347                 {
1348                         score = (other.totalfrags - minTotalFrags) / max(maxTotalFrags - minTotalFrags, 1);
1349                         f = bound(0, other.play_time / max(time, 1), 1);
1350                         // store some statistics?
1351                 }
1352         }
1353
1354         if(cvar("g_campaign"))
1355                 CampaignPreIntermission();
1356
1357         // WriteByte (MSG_ALL, SVC_INTERMISSION);
1358 };
1359
1360 /*
1361 ============
1362 CheckRules_Player
1363
1364 Exit deathmatch games upon conditions
1365 ============
1366 */
1367 void CheckRules_Player()
1368 {
1369         if (gameover)   // someone else quit the game already
1370                 return;
1371
1372         if(self.deadflag == DEAD_NO)
1373                 self.play_time += frametime;
1374
1375         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1376         //   (div0: and that in CheckRules_World please)
1377 };
1378
1379 float checkrules_equality;
1380 float checkrules_suddendeathwarning;
1381 float checkrules_suddendeathend;
1382 float checkrules_overtimesadded; //how many overtimes have been already added
1383 float checkrules_status;
1384
1385 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1386 float WINNING_YES = 1; // winner found
1387 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1388 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1389
1390 void InitiateOvertime()
1391 {
1392         // Check first whether normal overtimes could be added before initiating suddendeath mode
1393         // - for this timelimit_overtime needs to be >0 of course
1394         // - also check the winning condition calculated in the previous frame and only add normal overtime
1395         //   again, if at the point at which timelimit would be extended again, still no winner was found
1396         if ((checkrules_overtimesadded < cvar("timelimit_overtimes")) && cvar("timelimit_overtime") && (checkrules_status == WINNING_NEVER))
1397         {
1398                 ++checkrules_overtimesadded;
1399                 //add one more overtime by simply extending the timelimit
1400                 float tl;
1401                 tl = cvar("timelimit");
1402                 tl += cvar("timelimit_overtime");
1403                 cvar_set("timelimit", ftos(tl));
1404                 string minutesPlural;
1405                 if (cvar("timelimit_overtime") == 1)
1406                         minutesPlural = " ^3minute";
1407                 else
1408                         minutesPlural = " ^3minutes";
1409
1410                 bcenterprint(
1411                         strcat(
1412                                 "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1413                                 ftos(cvar("timelimit_overtime")),
1414                                 minutesPlural,
1415                                 " to the game!"
1416                         )
1417                 );
1418         }
1419         else
1420         {
1421                 if(!checkrules_suddendeathend)
1422                         checkrules_suddendeathend = time + 60 * cvar("timelimit_suddendeath");
1423         }
1424 }
1425
1426 float GetWinningCode(float fraglimitreached, float equality)
1427 {
1428         if(equality)
1429                 if(fraglimitreached)
1430                         return WINNING_STARTSUDDENDEATHOVERTIME;
1431                 else
1432                         return WINNING_NEVER;
1433         else
1434                 if(fraglimitreached)
1435                         return WINNING_YES;
1436                 else
1437                         return WINNING_NO;
1438 }
1439
1440 // set the .winning flag for exactly those players with a given field value
1441 void SetWinners(.float field, float value)
1442 {
1443         entity head;
1444         FOR_EACH_PLAYER(head)
1445                 head.winning = (head.field == value);
1446 }
1447
1448 // set the .winning flag for those players with a given field value
1449 void AddWinners(.float field, float value)
1450 {
1451         entity head;
1452         FOR_EACH_PLAYER(head)
1453                 if(head.field == value)
1454                         head.winning = 1;
1455 }
1456
1457 // clear the .winning flags
1458 void ClearWinners(void)
1459 {
1460         entity head;
1461         FOR_EACH_PLAYER(head)
1462                 head.winning = 0;
1463 }
1464
1465 // Onslaught winning condition:
1466 // game terminates if only one team has a working generator (or none)
1467 float WinningCondition_Onslaught()
1468 {
1469         entity head;
1470         local float t1, t2, t3, t4;
1471
1472         WinningConditionHelper(); // set worldstatus
1473
1474         // first check if the game has ended
1475         t1 = t2 = t3 = t4 = 0;
1476         head = find(world, classname, "onslaught_generator");
1477         while (head)
1478         {
1479                 if (head.health > 0)
1480                 {
1481                         if (head.team == COLOR_TEAM1) t1 = 1;
1482                         if (head.team == COLOR_TEAM2) t2 = 1;
1483                         if (head.team == COLOR_TEAM3) t3 = 1;
1484                         if (head.team == COLOR_TEAM4) t4 = 1;
1485                 }
1486                 head = find(head, classname, "onslaught_generator");
1487         }
1488         if (t1 + t2 + t3 + t4 < 2)
1489         {
1490                 // game over, only one team remains (or none)
1491                 ClearWinners();
1492                 if (t1) SetWinners(team, COLOR_TEAM1);
1493                 if (t2) SetWinners(team, COLOR_TEAM2);
1494                 if (t3) SetWinners(team, COLOR_TEAM3);
1495                 if (t4) SetWinners(team, COLOR_TEAM4);
1496                 dprint("Have a winner, ending game.\n");
1497                 return WINNING_YES;
1498         }
1499
1500         // Two or more teams remain
1501         return WINNING_NO;
1502 }
1503
1504 float LMS_NewPlayerLives()
1505 {
1506         float fl;
1507         fl = cvar("fraglimit");
1508         if(fl == 0)
1509                 fl = 999;
1510
1511         // first player has left the game for dying too much? Nobody else can get in.
1512         if(lms_lowest_lives < 1)
1513                 return 0;
1514
1515         if(!cvar("g_lms_join_anytime"))
1516                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1517                         return 0;
1518
1519         return bound(1, lms_lowest_lives, fl);
1520 }
1521
1522 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1523 // they win. Otherwise the defending team wins once the timelimit passes.
1524 void assault_new_round();
1525 float WinningCondition_Assault()
1526 {
1527         local float status;
1528
1529         WinningConditionHelper(); // set worldstatus
1530
1531         status = WINNING_NO;
1532         // as the timelimit has not yet passed just assume the defending team will win
1533         if(assault_attacker_team == COLOR_TEAM1)
1534         {
1535                 SetWinners(team, COLOR_TEAM2);
1536         }
1537         else
1538         {
1539                 SetWinners(team, COLOR_TEAM1);
1540         }
1541
1542         local entity ent;
1543         ent = find(world, classname, "target_assault_roundend");
1544         if(ent)
1545         {
1546                 if(ent.winning) // round end has been triggered by attacking team
1547                 {
1548                         bprint("ASSAULT: round completed...\n");
1549                         SetWinners(team, assault_attacker_team);
1550
1551                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1552
1553                         if(ent.cnt == 1) // this was the second round
1554                         {
1555                                 status = WINNING_YES;
1556                         }
1557                         else
1558                         {
1559                                 local entity oldself;
1560                                 oldself = self;
1561                                 self = ent;
1562                                 assault_new_round();
1563                                 self = oldself;
1564                         }
1565                 }
1566         }
1567
1568         return status;
1569 }
1570
1571 // LMS winning condition: game terminates if and only if there's at most one
1572 // one player who's living lives. Top two scores being equal cancels the time
1573 // limit.
1574 float WinningCondition_LMS()
1575 {
1576         entity head, head2;
1577         float have_player;
1578         float have_players;
1579         float l;
1580
1581         have_player = FALSE;
1582         have_players = FALSE;
1583         l = LMS_NewPlayerLives();
1584
1585         head = find(world, classname, "player");
1586         if(head)
1587                 have_player = TRUE;
1588         head2 = find(head, classname, "player");
1589         if(head2)
1590                 have_players = TRUE;
1591
1592         if(have_player)
1593         {
1594                 // we have at least one player
1595                 if(have_players)
1596                 {
1597                         // two or more active players - continue with the game
1598                 }
1599                 else
1600                 {
1601                         // exactly one player?
1602
1603                         ClearWinners();
1604                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1605
1606                         if(l)
1607                         {
1608                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1609                                 return WINNING_NO;
1610                         }
1611                         else
1612                         {
1613                                 // a winner!
1614                                 // and assign him his first place
1615                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1616                                 return WINNING_YES;
1617                         }
1618                 }
1619         }
1620         else
1621         {
1622                 // nobody is playing at all...
1623                 if(l)
1624                 {
1625                         // wait for players...
1626                 }
1627                 else
1628                 {
1629                         // SNAFU (maybe a draw game?)
1630                         ClearWinners();
1631                         dprint("No players, ending game.\n");
1632                         return WINNING_YES;
1633                 }
1634         }
1635
1636         // When we get here, we have at least two players who are actually LIVING,
1637         // now check if the top two players have equal score.
1638         WinningConditionHelper();
1639
1640         ClearWinners();
1641         if(WinningConditionHelper_winner)
1642                 WinningConditionHelper_winner.winning = TRUE;
1643         if(WinningConditionHelper_equality)
1644                 return WINNING_NEVER;
1645
1646         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1647         return WINNING_NO;
1648 }
1649
1650 void ShuffleMaplist()
1651 {
1652         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
1653 }
1654
1655 float leaderfrags;
1656 float WinningCondition_Scores(float limit)
1657 {
1658         // TODO make everything use THIS winning condition (except LMS)
1659         WinningConditionHelper();
1660
1661         if(teams_matter)
1662         {
1663                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1664                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1665                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1666                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1667         }
1668
1669         ClearWinners();
1670         if(WinningConditionHelper_winner)
1671                 WinningConditionHelper_winner.winning = 1;
1672         if(WinningConditionHelper_winnerteam >= 0)
1673                 SetWinners(team, WinningConditionHelper_winnerteam);
1674
1675         if(WinningConditionHelper_lowerisbetter)
1676         {
1677                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1678                 limit = -limit;
1679         }
1680
1681         if(g_dm || g_tdm || g_arena || (g_race && !g_race_qualifying) || g_nexball)
1682         // these modes always score in increments of 1, thus this makes sense
1683         {
1684                 if(leaderfrags != WinningConditionHelper_topscore)
1685                 {
1686                         leaderfrags = WinningConditionHelper_topscore;
1687
1688                         if (limit)
1689                         if (leaderfrags == limit - 1)
1690                                 play2all("announcer/robotic/1fragleft.wav");
1691                         else if (leaderfrags == limit - 2)
1692                                 play2all("announcer/robotic/2fragsleft.wav");
1693                         else if (leaderfrags == limit - 3)
1694                                 play2all("announcer/robotic/3fragsleft.wav");
1695                 }
1696         }
1697
1698         return GetWinningCode(limit && WinningConditionHelper_topscore && (WinningConditionHelper_topscore >= limit), WinningConditionHelper_equality);
1699 }
1700
1701 float WinningCondition_Race(float fraglimit)
1702 {
1703         float wc;
1704         entity p;
1705         wc = WinningCondition_Scores(fraglimit);
1706
1707         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1708         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1709         // do NOT support equality when the laps are all raced!
1710         {
1711                 FOR_EACH_PLAYER(p)
1712                         if not(p.race_completed)
1713                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1714                 return WINNING_YES;
1715         }
1716         return wc;
1717 }
1718
1719 void ReadyRestart();
1720 float WinningCondition_QualifyingThenRace(float limit)
1721 {
1722         float wc;
1723         wc = WinningCondition_Scores(limit);
1724
1725         // NEVER initiate overtime
1726         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1727         {
1728                 return WINNING_YES;
1729         }
1730
1731         return wc;
1732 }
1733
1734 float WinningCondition_RanOutOfSpawns()
1735 {
1736         entity head;
1737
1738         if(!have_team_spawns)
1739                 return WINNING_NO;
1740
1741         if(!some_spawn_has_been_used)
1742                 return WINNING_NO;
1743
1744         team1_score = team2_score = team3_score = team4_score = 0;
1745
1746         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1747         {
1748                 if(head.team == COLOR_TEAM1)
1749                         team1_score = 1;
1750                 else if(head.team == COLOR_TEAM2)
1751                         team2_score = 1;
1752                 else if(head.team == COLOR_TEAM3)
1753                         team3_score = 1;
1754                 else if(head.team == COLOR_TEAM4)
1755                         team4_score = 1;
1756         }
1757
1758         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1759         {
1760                 if(head.team == COLOR_TEAM1)
1761                         team1_score = 1;
1762                 else if(head.team == COLOR_TEAM2)
1763                         team2_score = 1;
1764                 else if(head.team == COLOR_TEAM3)
1765                         team3_score = 1;
1766                 else if(head.team == COLOR_TEAM4)
1767                         team4_score = 1;
1768         }
1769
1770         ClearWinners();
1771         if(team1_score + team2_score + team3_score + team4_score == 0)
1772         {
1773                 checkrules_equality = TRUE;
1774                 return WINNING_YES;
1775         }
1776         else if(team1_score + team2_score + team3_score + team4_score == 1)
1777         {
1778                 float t, i;
1779                 if(team1_score) t = COLOR_TEAM1;
1780                 if(team2_score) t = COLOR_TEAM2;
1781                 if(team3_score) t = COLOR_TEAM3;
1782                 if(team4_score) t = COLOR_TEAM4;
1783                 CheckAllowedTeams(world);
1784                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1785                 {
1786                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
1787                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
1788                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
1789                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
1790                 }
1791
1792                 AddWinners(team, t);
1793                 return WINNING_YES;
1794         }
1795         else
1796                 return WINNING_NO;
1797 }
1798
1799 /*
1800 ============
1801 CheckRules_World
1802
1803 Exit deathmatch games upon conditions
1804 ============
1805 */
1806 void CheckRules_World()
1807 {
1808         local float timelimit;
1809         local float fraglimit;
1810
1811         VoteThink();
1812         MapVote_Think();
1813
1814         SetDefaultAlpha();
1815
1816         /*
1817         MapVote_Think should now do that part
1818         if (intermission_running)
1819                 if (time >= intermission_exittime + 60)
1820                 {
1821                         if(!DoNextMapOverride())
1822                                 GotoNextMap();
1823                         return;
1824                 }
1825         */
1826
1827         if (gameover)   // someone else quit the game already
1828         {
1829                 if(player_count == 0) // Nobody there? Then let's go to the next map
1830                         MapVote_Start();
1831                         // this will actually check the player count in the next frame
1832                         // again, but this shouldn't hurt
1833                 return;
1834         }
1835
1836         timelimit = cvar("timelimit") * 60;
1837         fraglimit = cvar("fraglimit");
1838
1839         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1840         {
1841                 if(timelimit > 0)
1842                         timelimit = 0; // timelimit is not made for warmup
1843                 if(fraglimit > 0)
1844                         fraglimit = 0; // no fraglimit for now
1845         }
1846
1847         if(timelimit > 0)
1848         {
1849                 timelimit += game_starttime;
1850         }
1851         else if (timelimit < 0)
1852         {
1853                 // endmatch
1854                 NextLevel();
1855                 return;
1856         }
1857
1858         if(checkrules_suddendeathend)
1859         {
1860                 if(!checkrules_suddendeathwarning)
1861                 {
1862                         checkrules_suddendeathwarning = TRUE;
1863                         if(g_race && !g_race_qualifying)
1864                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
1865                         else
1866                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
1867                 }
1868         }
1869         else
1870         {
1871                 if (timelimit && time >= timelimit)
1872                 {
1873                         if(g_race && g_race_qualifying == 2 && timelimit > 0)
1874                         {
1875                                 float totalplayers;
1876                                 float playerswithlaps;
1877                                 float readyplayers;
1878                                 entity head;
1879                                 totalplayers = playerswithlaps = readyplayers = 0;
1880                                 FOR_EACH_PLAYER(head)
1881                                 {
1882                                         ++totalplayers;
1883                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
1884                                                 ++playerswithlaps;
1885                                         if(head.ready)
1886                                                 ++readyplayers;
1887                                 }
1888
1889                                 // at least 2/3 of the players have completed a lap: start the RACE
1890                                 // otherwise, the players should end the qualifying on their own
1891                                 if(readyplayers || ((totalplayers >= 3) && (playerswithlaps * 3 >= totalplayers * 2)))
1892                                 {
1893                                         checkrules_suddendeathend = 0;
1894                                         ReadyRestart(); // go to race
1895                                 }
1896                                 else
1897                                         InitiateOvertime();
1898                         }
1899                         else
1900                                 InitiateOvertime();
1901                 }
1902         }
1903
1904         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1905         {
1906                 NextLevel();
1907                 return;
1908         }
1909
1910         checkrules_status = WinningCondition_RanOutOfSpawns();
1911         if(checkrules_status == WINNING_YES)
1912         {
1913                 bprint("Hey! Someone ran out of spawns!\n");
1914         }
1915         else if(g_race && !g_race_qualifying && timelimit >= 0)
1916         {
1917                 checkrules_status = WinningCondition_Race(fraglimit);
1918         }
1919         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
1920         {
1921                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
1922         }
1923         else if(g_assault)
1924         {
1925                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
1926         }
1927         else if(g_lms)
1928         {
1929                 checkrules_status = WinningCondition_LMS();
1930         }
1931         else if (g_onslaught)
1932         {
1933                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
1934         }
1935         else
1936         {
1937                 checkrules_status = WinningCondition_Scores(fraglimit);
1938         }
1939
1940         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1941         {
1942                 checkrules_status = WINNING_NEVER;
1943                 InitiateOvertime();
1944         }
1945
1946         if(checkrules_status == WINNING_NEVER)
1947                 // equality cases! Nobody wins if the overtime ends in a draw.
1948                 ClearWinners();
1949
1950         if(checkrules_suddendeathend)
1951                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1952                         checkrules_status = WINNING_YES;
1953
1954         if(checkrules_status == WINNING_YES)
1955                 NextLevel();
1956 };
1957
1958 float mapvote_nextthink;
1959 float mapvote_initialized;
1960 float mapvote_keeptwotime;
1961 float mapvote_timeout;
1962 string mapvote_message;
1963 string mapvote_screenshot_dir;
1964
1965 float mapvote_count;
1966 float mapvote_count_real;
1967 string mapvote_maps[MAPVOTE_COUNT];
1968 float mapvote_maps_suggested[MAPVOTE_COUNT];
1969 string mapvote_suggestions[MAPVOTE_COUNT];
1970 float mapvote_suggestion_ptr;
1971 float mapvote_maxlen;
1972 float mapvote_voters;
1973 float mapvote_votes[MAPVOTE_COUNT];
1974 float mapvote_run;
1975 float mapvote_detail;
1976 float mapvote_abstain;
1977 .float mapvote;
1978
1979 void MapVote_ClearAllVotes()
1980 {
1981         FOR_EACH_CLIENT(other)
1982                 other.mapvote = 0;
1983 }
1984
1985 string MapVote_Suggest(string m)
1986 {
1987         float i;
1988         if(m == "")
1989                 return "That's not how to use this command.";
1990         if(!cvar("g_maplist_votable_suggestions"))
1991                 return "Suggestions are not accepted on this server.";
1992         if(mapvote_initialized)
1993                 return "Can't suggest - voting is already in progress!";
1994         m = MapInfo_FixName(m);
1995         if(!m)
1996                 return "The map you suggested is not available on this server.";
1997         if(!cvar("g_maplist_votable_override_mostrecent"))
1998                 if(Map_IsRecent(m))
1999                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2000
2001         if(!MapInfo_CheckMap(m))
2002                 return "The map you suggested does not support the current game mode.";
2003         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2004                 if(mapvote_suggestions[i] == m)
2005                         return "This map was already suggested.";
2006         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2007         {
2008                 i = floor(random() * mapvote_suggestion_ptr);
2009         }
2010         else
2011         {
2012                 i = mapvote_suggestion_ptr;
2013                 mapvote_suggestion_ptr += 1;
2014         }
2015         if(mapvote_suggestions[i] != "")
2016                 strunzone(mapvote_suggestions[i]);
2017         mapvote_suggestions[i] = strzone(m);
2018         if(cvar("sv_eventlog"))
2019                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2020         return strcat("Suggestion of ", m, " accepted.");
2021 }
2022
2023 void MapVote_AddVotable(string nextMap, float isSuggestion)
2024 {
2025         float j;
2026         if(nextMap == "")
2027                 return;
2028         for(j = 0; j < mapvote_count; ++j)
2029                 if(mapvote_maps[j] == nextMap)
2030                         return;
2031         if(strlen(nextMap) > mapvote_maxlen)
2032                 mapvote_maxlen = strlen(nextMap);
2033         mapvote_maps[mapvote_count] = strzone(nextMap);
2034         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2035         mapvote_count += 1;
2036 }
2037
2038 void MapVote_Spawn();
2039 void MapVote_Init()
2040 {
2041         float i;
2042         float nmax, smax;
2043
2044         MapVote_ClearAllVotes();
2045
2046         mapvote_count = 0;
2047         mapvote_detail = !cvar("g_maplist_votable_nodetail");
2048         mapvote_abstain = cvar("g_maplist_votable_abstain");
2049
2050         if(mapvote_abstain)
2051                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
2052         else
2053                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2054         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2055
2056         if(mapvote_suggestion_ptr)
2057                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2058                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2059
2060         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2061                 MapVote_AddVotable(GetNextMap(), FALSE);
2062
2063         if(mapvote_count == 0)
2064         {
2065                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2066                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN));
2067                 if(cvar("g_maplist_shuffle"))
2068                         ShuffleMaplist();
2069                 localcmd("\nmenu_cmd sync\n");
2070                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2071                         MapVote_AddVotable(GetNextMap(), FALSE);
2072         }
2073
2074         mapvote_count_real = mapvote_count;
2075         if(mapvote_abstain)
2076                 MapVote_AddVotable("don't care", 0);
2077
2078         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2079
2080         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2081         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2082         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2083                 mapvote_keeptwotime = 0;
2084         mapvote_message = "Choose a map and press its key!";
2085
2086         mapvote_screenshot_dir = cvar_string("g_maplist_votable_screenshot_dir");
2087         if(mapvote_screenshot_dir == "")
2088                 mapvote_screenshot_dir = "maps";
2089         mapvote_screenshot_dir = strzone(mapvote_screenshot_dir);
2090
2091         MapVote_Spawn();
2092 }
2093
2094 void MapVote_SendPicture(float id)
2095 {
2096         msg_entity = self;
2097         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2098         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2099         WriteByte(MSG_ONE, id);
2100         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dir, "/", mapvote_maps[id]), 3072);
2101 }
2102
2103 float GameCommand_MapVote(string cmd)
2104 {
2105         if(!intermission_running)
2106                 return FALSE;
2107
2108         if(cmd == "mv_getpic")
2109         {
2110                 MapVote_SendPicture(stof(argv(1)));
2111                 return TRUE;
2112         }
2113
2114         return FALSE;
2115 }
2116
2117 float MapVote_GetMapMask()
2118 {
2119         float mask, i, power;
2120         mask = 0;
2121         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2122                 if(mapvote_maps[i] != "")
2123                         mask |= power;
2124         return mask;
2125 }
2126
2127 entity mapvote_ent;
2128 float MapVote_SendEntity(entity to, float sf)
2129 {
2130         string mapfile, pakfile;
2131         float i, o;
2132
2133         if(sf & 1)
2134                 sf &~= 2; // if we send 1, we don't need to also send 2
2135
2136         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2137         WriteByte(MSG_ENTITY, sf);
2138
2139         if(sf & 1)
2140         {
2141                 // flag 1 == initialization
2142                 WriteString(MSG_ENTITY, mapvote_screenshot_dir);
2143                 WriteByte(MSG_ENTITY, mapvote_count);
2144                 WriteByte(MSG_ENTITY, mapvote_abstain);
2145                 WriteByte(MSG_ENTITY, mapvote_detail);
2146                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2147                 if(mapvote_count <= 8)
2148                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2149                 else
2150                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2151                 for(i = 0; i < mapvote_count; ++i)
2152                         if(mapvote_maps[i] != "")
2153                         {
2154                                 if(mapvote_abstain && i == mapvote_count - 1)
2155                                 {
2156                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2157                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2158                                 }
2159                                 else
2160                                 {
2161                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2162                                         mapfile = strcat(mapvote_screenshot_dir, "/", mapvote_maps[i]);
2163                                         pakfile = whichpack(strcat(mapfile, ".tga"));
2164                                         if(pakfile == "")
2165                                                 pakfile = whichpack(strcat(mapfile, ".jpg"));
2166                                         if(pakfile == "")
2167                                                 pakfile = whichpack(strcat(mapfile, ".png"));
2168                                         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2169                                                 pakfile = substring(pakfile, o, 999);
2170                                         WriteString(MSG_ENTITY, pakfile);
2171                                 }
2172                         }
2173         }
2174
2175         if(sf & 2)
2176         {
2177                 // flag 2 == update of mask
2178                 if(mapvote_count <= 8)
2179                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2180                 else
2181                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2182         }
2183
2184         if(sf & 4)
2185         {
2186                 if(mapvote_detail)
2187                         for(i = 0; i < mapvote_count; ++i)
2188                                 if(mapvote_maps[i] != "")
2189                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2190
2191                 WriteByte(MSG_ENTITY, to.mapvote);
2192         }
2193
2194         return TRUE;
2195 }
2196
2197 void MapVote_Spawn()
2198 {
2199         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2200 }
2201
2202 void MapVote_TouchMask()
2203 {
2204         mapvote_ent.SendFlags |= 2;
2205 }
2206
2207 void MapVote_TouchVotes(entity voter)
2208 {
2209         mapvote_ent.SendFlags |= 4;
2210 }
2211
2212 float MapVote_Finished(float mappos)
2213 {
2214         string result;
2215         float i;
2216         float didntvote;
2217
2218         if(cvar("sv_eventlog"))
2219         {
2220                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2221                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2222                 didntvote = mapvote_voters;
2223                 for(i = 0; i < mapvote_count; ++i)
2224                         if(mapvote_maps[i] != "")
2225                         {
2226                                 didntvote -= mapvote_votes[i];
2227                                 if(i != mappos)
2228                                 {
2229                                         result = strcat(result, ":", mapvote_maps[i]);
2230                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2231                                 }
2232                         }
2233                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2234
2235                 GameLogEcho(result);
2236                 if(mapvote_maps_suggested[mappos])
2237                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2238         }
2239
2240         FOR_EACH_REALCLIENT(other)
2241                 FixClientCvars(other);
2242
2243         Map_Goto_SetStr(mapvote_maps[mappos]);
2244         Map_Goto();
2245         alreadychangedlevel = TRUE;
2246         return TRUE;
2247 }
2248 void MapVote_CheckRules_1()
2249 {
2250         float i;
2251
2252         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2253         {
2254                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2255                 mapvote_votes[i] = 0;
2256         }
2257
2258         mapvote_voters = 0;
2259         FOR_EACH_REALCLIENT(other)
2260         {
2261                 ++mapvote_voters;
2262                 if(other.mapvote)
2263                 {
2264                         i = other.mapvote - 1;
2265                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2266                         mapvote_votes[i] = mapvote_votes[i] + 1;
2267                 }
2268         }
2269 }
2270
2271 float MapVote_CheckRules_2()
2272 {
2273         float i;
2274         float firstPlace, secondPlace;
2275         float firstPlaceVotes, secondPlaceVotes;
2276         float mapvote_voters_real;
2277         string result;
2278
2279         if(mapvote_count_real == 1)
2280                 return MapVote_Finished(0);
2281
2282         mapvote_voters_real = mapvote_voters;
2283         if(mapvote_abstain)
2284                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2285
2286         RandomSelection_Init();
2287         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2288                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2289         firstPlace = RandomSelection_chosen_float;
2290         firstPlaceVotes = RandomSelection_best_priority;
2291         //dprint("First place: ", ftos(firstPlace), "\n");
2292         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2293
2294         RandomSelection_Init();
2295         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2296                 if(i != firstPlace)
2297                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2298         secondPlace = RandomSelection_chosen_float;
2299         secondPlaceVotes = RandomSelection_best_priority;
2300         //dprint("Second place: ", ftos(secondPlace), "\n");
2301         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2302
2303         if(firstPlace == -1)
2304                 error("No first place in map vote... WTF?");
2305
2306         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2307                 return MapVote_Finished(firstPlace);
2308
2309         if(mapvote_keeptwotime)
2310                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2311                 {
2312                         float didntvote;
2313                         MapVote_TouchMask();
2314                         mapvote_message = "Now decide between the TOP TWO!";
2315                         mapvote_keeptwotime = 0;
2316                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2317                         result = strcat(result, ":", ftos(firstPlaceVotes));
2318                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2319                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2320                         didntvote = mapvote_voters;
2321                         for(i = 0; i < mapvote_count; ++i)
2322                                 if(mapvote_maps[i] != "")
2323                                 {
2324                                         didntvote -= mapvote_votes[i];
2325                                         if(i != firstPlace)
2326                                                 if(i != secondPlace)
2327                                                 {
2328                                                         result = strcat(result, ":", mapvote_maps[i]);
2329                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2330                                                         if(i < mapvote_count_real)
2331                                                         {
2332                                                                 strunzone(mapvote_maps[i]);
2333                                                                 mapvote_maps[i] = "";
2334                                                         }
2335                                                 }
2336                                 }
2337                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2338                         if(cvar("sv_eventlog"))
2339                                 GameLogEcho(result);
2340                 }
2341
2342         return FALSE;
2343 }
2344 void MapVote_Tick()
2345 {
2346         float keeptwo;
2347         float totalvotes;
2348
2349         keeptwo = mapvote_keeptwotime;
2350         MapVote_CheckRules_1(); // count
2351         if(MapVote_CheckRules_2()) // decide
2352                 return;
2353
2354         totalvotes = 0;
2355         FOR_EACH_REALCLIENT(other)
2356         {
2357                 // hide scoreboard again
2358                 if(other.health != 2342)
2359                 {
2360                         other.health = 2342;
2361                         other.impulse = 0;
2362                         if(clienttype(other) == CLIENTTYPE_REAL)
2363                         {
2364                                 msg_entity = other;
2365                                 WriteByte(MSG_ONE, SVC_FINALE);
2366                                 WriteString(MSG_ONE, "");
2367                         }
2368                 }
2369
2370                 // clear possibly invalid votes
2371                 if(mapvote_maps[other.mapvote - 1] == "")
2372                         other.mapvote = 0;
2373                 // use impulses as new vote
2374                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2375                         if(mapvote_maps[other.impulse - 1] != "")
2376                         {
2377                                 other.mapvote = other.impulse;
2378                                 MapVote_TouchVotes(other);
2379                         }
2380                 other.impulse = 0;
2381
2382                 if(other.mapvote)
2383                         ++totalvotes;
2384         }
2385
2386         MapVote_CheckRules_1(); // just count
2387 }
2388 void MapVote_Start()
2389 {
2390         if(mapvote_run)
2391                 return;
2392
2393         MapInfo_Enumerate();
2394         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN) | MAPINFO_FLAG_FORBIDDEN, 1))
2395                 mapvote_run = TRUE;
2396 }
2397 void MapVote_Think()
2398 {
2399         if(!mapvote_run)
2400                 return;
2401
2402         if(alreadychangedlevel)
2403                 return;
2404
2405         if(time < mapvote_nextthink)
2406                 return;
2407         //dprint("tick\n");
2408
2409         mapvote_nextthink = time + 0.5;
2410
2411         if(!mapvote_initialized)
2412         {
2413                 mapvote_initialized = TRUE;
2414                 if(DoNextMapOverride())
2415                         return;
2416                 if(!cvar("g_maplist_votable") || player_count <= 0)
2417                 {
2418                         GotoNextMap();
2419                         return;
2420                 }
2421                 MapVote_Init();
2422         }
2423
2424         MapVote_Tick();
2425 };
2426
2427 string GotoMap(string m)
2428 {
2429         if(!MapInfo_CheckMap(m))
2430                 return "The map you chose is not available on this server.";
2431         cvar_set("nextmap", m);
2432         cvar_set("timelimit", "-1");
2433         if(mapvote_initialized || alreadychangedlevel)
2434         {
2435                 if(DoNextMapOverride())
2436                         return "Map switch initiated.";
2437                 else
2438                         return "Hm... no. For some reason I like THIS map more.";
2439         }
2440         else
2441                 return "Map switch will happen after scoreboard.";
2442 }
2443
2444
2445 void EndFrame()
2446 {
2447         FOR_EACH_REALCLIENT(self)
2448         {
2449                 if(self.classname == "spectator")
2450                 {
2451                         if(self.enemy.typehitsound)
2452                                 play2(self, "misc/typehit.wav");
2453                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2454                                 play2(self, "misc/hit.wav");
2455                 }
2456                 else
2457                 {
2458                         if(self.typehitsound)
2459                                 play2(self, "misc/typehit.wav");
2460                         else if(self.hitsound && self.cvar_cl_hitsound)
2461                                 play2(self, "misc/hit.wav");
2462                 }
2463         }
2464         FOR_EACH_CLIENT(self)
2465         {
2466                 self.hitsound = FALSE;
2467                 self.typehitsound = FALSE;
2468         }
2469 }
2470
2471
2472 /*
2473  * RedirectionThink:
2474  * returns TRUE if redirecting
2475  */
2476 float redirection_timeout;
2477 float redirection_nextthink;
2478 float RedirectionThink()
2479 {
2480         float clients_found;
2481
2482         if(redirection_target == "")
2483                 return FALSE;
2484
2485         if(!redirection_timeout)
2486         {
2487                 cvar_set("sv_public", "-2");
2488                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2489                 if(redirection_target == "self")
2490                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2491                 else
2492                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2493         }
2494
2495         if(time < redirection_nextthink)
2496                 return TRUE;
2497
2498         redirection_nextthink = time + 1;
2499
2500         clients_found = 0;
2501         FOR_EACH_REALCLIENT(self)
2502         {
2503                 print("Redirecting: sending connect command to ", self.netname, "\n");
2504                 if(redirection_target == "self")
2505                         stuffcmd(self, "\ndisconnect; reconnect\n");
2506                 else
2507                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2508                 ++clients_found;
2509         }
2510
2511         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2512
2513         if(time > redirection_timeout || clients_found == 0)
2514                 localcmd("\nwait; wait; wait; quit\n");
2515
2516         return TRUE;
2517 }
2518
2519 void RestoreGame()
2520 {
2521         // Loaded from a save game
2522         // some things then break, so let's work around them...
2523
2524         // Progs DB (capture records)
2525         if(sv_cheats)
2526                 ServerProgsDB = db_create();
2527         else
2528                 ServerProgsDB = db_load("server.db");
2529
2530         // Mapinfo
2531         MapInfo_Shutdown();
2532         MapInfo_Enumerate();
2533         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN) | MAPINFO_FLAG_FORBIDDEN, 1);
2534 }
2535
2536 void SV_Shutdown()
2537 {
2538         if(world_initialized > 0)
2539         {
2540                 world_initialized = 0;
2541                 print("Saving persistent data...\n");
2542                 Ban_SaveBans();
2543                 if(!sv_cheats)
2544                         db_save(ServerProgsDB, "server.db");
2545                 if(cvar("developer"))
2546                         db_save(TemporaryDB, "server-temp.db");
2547                 db_close(ServerProgsDB);
2548                 db_close(TemporaryDB);
2549                 print("done!\n");
2550                 // tell the bot system the game is ending now
2551                 bot_endgame();
2552
2553                 MapInfo_Shutdown();
2554         }
2555         else if(world_initialized == 0)
2556         {
2557                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2558         }
2559 }