data/qcsrc/server/g_violence.qc

   1 float Violence_GibSplash_SendEntity(entity to, float sf)
   2 {
   3         WriteByte(MSG_ENTITY, ENT_CLIENT_GIBSPLASH);
   4         WriteByte(MSG_ENTITY, self.state); // actually type
   5         WriteByte(MSG_ENTITY, bound(1, self.cnt * 16, 255)); // gibbage amount multiplier
   6         WriteShort(MSG_ENTITY, floor(self.origin_x / 4)); // not using a coord here, as gibs don't need this accuracy
   7         WriteShort(MSG_ENTITY, floor(self.origin_y / 4)); // not using a coord here, as gibs don't need this accuracy
   8         WriteShort(MSG_ENTITY, floor(self.origin_z / 4)); // not using a coord here, as gibs don't need this accuracy
   9         WriteShort(MSG_ENTITY, self.oldorigin_x); // acrually compressed velocity
  10         WriteShort(MSG_ENTITY, self.oldorigin_y); // acrually compressed mins
  11         WriteShort(MSG_ENTITY, self.oldorigin_z); // acrually compressed maxs
  12         return TRUE;
  13 }
  14
  15 // TODO maybe convert this to a TE?
  16 void Violence_GibSplash_At(vector org, vector mi, vector ma, vector dir, float type, float amount)
  17 {
  18         entity e;
  19
  20         e = spawn();
  21         e.classname = "gibsplash";
  22         e.cnt = amount;
  23         e.state = type;
  24         if(sv_gentle)
  25                 e.state |= 0x80; // "force gentle" bit
  26         setorigin(e, org);
  27         setsize(e, mi, ma);
  28         e.velocity = dir;
  29
  30         e.oldorigin_x = compressShortVector(e.velocity);
  31         e.oldorigin_y = compressShortVector(e.mins);
  32         e.oldorigin_z = compressShortVector(e.maxs);
  33
  34         Net_LinkEntity(e, FALSE, 0.2, Violence_GibSplash_SendEntity);
  35 }
  36
  37 void Violence_GibSplash(entity source, float type, float amount)
  38 {
  39         Violence_GibSplash_At(source.origin + source.view_ofs, source.mins - source.view_ofs, source.maxs - source.view_ofs, source.velocity, type, amount);
  40 }