data/qcsrc/server/ctf.qc

   1 .entity sprite;
   2 entity ctf_worldflaglist; // CTF flags in the map
   3 .entity ctf_worldflagnext;
   4 .float dropperid;
   5 .float ctf_droptime;
   6
   7 .float next_take_time;                  // the next time a player can pick up a flag (time + blah)
   8                                                                 /// I used this, in part, to fix the looping score bug. - avirox
   9 //float FLAGSCORE_PICKUP        =  1;
  10 //float FLAGSCORE_RETURN        =  5; // returned by owner team
  11 //float FLAGSCORE_RETURNROGUE   = 10; // returned by rogue team
  12 //float FLAGSCORE_CAPTURE       =  5;
  13
  14 #define FLAG_CARRY_POS '-15 0 7'
  15
  16 .float ctf_captureshielded; // set to 1 if the player is too bad to be allowed to capture
  17
  18 float captureshield_min_negscore; // punish at -20 points
  19 float captureshield_max_ratio; // punish at most 30% of each team
  20 float captureshield_force; // push force of the shield
  21
  22 float ctf_captureshield_shielded(entity p)
  23 {
  24         float s, se;
  25         entity e;
  26         float players_worseeq, players_total;
  27
  28         if(captureshield_max_ratio <= 0)
  29                 return FALSE;
  30
  31         s = PlayerScore_Add(p, SP_SCORE, 0);
  32         if(s >= -captureshield_min_negscore)
  33                 return FALSE;
  34
  35         players_total = players_worseeq = 0;
  36         FOR_EACH_PLAYER(e)
  37         {
  38                 if(e.team != p.team)
  39                         continue;
  40                 se = PlayerScore_Add(e, SP_SCORE, 0);
  41                 if(se <= s)
  42                         ++players_worseeq;
  43                 ++players_total;
  44         }
  45
  46         // player is in the worse half, if >= half the players are better than him, or consequently, if < half of the players are worse
  47         // use this rule here
  48
  49         if(players_worseeq >= players_total * captureshield_max_ratio)
  50                 return FALSE;
  51
  52         return TRUE;
  53 }
  54
  55 void ctf_captureshield_update(entity p, float dir)
  56 {
  57         float should;
  58         if(dir == p.ctf_captureshielded) // 0: shield only, 1: unshield only
  59         {
  60                 should = ctf_captureshield_shielded(p);
  61                 if(should != dir)
  62                 {
  63                         if(should)
  64                         {
  65                                 centerprint_atprio(p, CENTERPRIO_SHIELDING, "^3You are now ^4shielded^3 from the flag\n^3for ^1too many unsuccessful attempts^3 to capture.\n\n^3Make some defensive scores before trying again.");
  66                                 // TODO csqc notifier for this
  67                         }
  68                         else
  69                         {
  70                                 centerprint_atprio(p, CENTERPRIO_SHIELDING, "^3You are now free.\n\n^3Feel free to ^1try to capture^3 the flag again\n^3if you think you will succeed.");
  71                                 // TODO csqc notifier for this
  72                         }
  73                         p.ctf_captureshielded = should;
  74                 }
  75         }
  76 }
  77
  78 float ctf_captureshield_customize()
  79 {
  80         if not(other.ctf_captureshielded)
  81                 return FALSE;
  82         if(self.team == other.team)
  83                 return FALSE;
  84         return TRUE;
  85 }
  86
  87 void ctf_captureshield_touch()
  88 {
  89         if not(other.ctf_captureshielded)
  90                 return;
  91         if(self.team == other.team)
  92                 return;
  93         vector mymid;
  94         vector othermid;
  95         mymid = (self.absmin + self.absmax) * 0.5;
  96         othermid = (other.absmin + other.absmax) * 0.5;
  97         Damage(other, self, self, 0, DEATH_HURTTRIGGER, mymid, normalize(othermid - mymid) * captureshield_force);
  98         centerprint_atprio(other, CENTERPRIO_SHIELDING, "^3You are ^4shielded^3 from the flag\n^3for ^1too many unsuccessful attempts^3 to capture.\n\n^3Get some defensive scores before trying again.");
  99 }
 100
 101 void ctf_captureshield_spawn()
 102 {
 103         entity e;
 104         e = spawn();
 105         e.enemy = self;
 106         e.team = self.team;
 107         e.touch = ctf_captureshield_touch;
 108         e.customizeentityforclient = ctf_captureshield_customize;
 109         e.classname = "ctf_captureshield";
 110         e.effects = EF_ADDITIVE;
 111         e.movetype = MOVETYPE_NOCLIP;
 112         e.solid = SOLID_TRIGGER;
 113         e.avelocity = '7 0 11';
 114         setorigin(e, self.origin);
 115         setmodel(e, "models/onslaught/generator_shield.md3");
 116         e.scale = 0.5;
 117         setsize(e, e.scale * e.mins, e.scale * e.maxs);
 118         print(etos(e), "\n");
 119 }
 120
 121 float ctf_score_value(string parameter)
 122 {
 123         if(g_ctf_win_mode != 2)
 124                 return cvar(strcat("g_ctf_personal", parameter));
 125         else
 126                 return cvar(strcat("g_ctf_flag", parameter));
 127 }
 128
 129 void FakeTimeLimit(entity e, float t)
 130 {
 131         msg_entity = e;
 132         WriteByte(MSG_ONE, 3); // svc_updatestat
 133         WriteByte(MSG_ONE, 236); // STAT_TIMELIMIT
 134         if(t < 0)
 135                 WriteCoord(MSG_ONE, cvar("timelimit"));
 136         else
 137                 WriteCoord(MSG_ONE, (t + 1) / 60);
 138 }
 139
 140 float   flagcaptimerecord;
 141 .float  flagpickuptime;
 142 //.float  iscommander;
 143 //.float  ctf_state;
 144
 145 void() FlagThink;
 146 void() FlagTouch;
 147
 148 void place_flag()
 149 {
 150         if(!self.t_width)
 151                 self.t_width = 0.1; // frame animation rate
 152         if(!self.t_length)
 153                 self.t_length = 119; // maximum frame
 154
 155         setattachment(self, world, "");
 156         self.mdl = self.model;
 157         self.flags = FL_ITEM;
 158         self.solid = SOLID_TRIGGER;
 159         self.movetype = MOVETYPE_NONE;
 160         self.velocity = '0 0 0';
 161         self.origin_z = self.origin_z + 6;
 162         self.think = FlagThink;
 163         self.touch = FlagTouch;
 164         self.nextthink = time + 0.1;
 165         self.cnt = FLAG_BASE;
 166         self.mangle = self.angles;
 167         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 168         //self.effects = self.effects | EF_DIMLIGHT;
 169         if(self.noalign)
 170         {
 171                 self.dropped_origin = self.origin;
 172         }
 173         else
 174         {
 175                 droptofloor();
 176                 self.movetype = MOVETYPE_TOSS;
 177         }
 178         InitializeEntity(self, ctf_captureshield_spawn, INITPRIO_SETLOCATION);
 179 };
 180
 181 void LogCTF(string mode, float flagteam, entity actor)
 182 {
 183         string s;
 184         if(!cvar("sv_eventlog"))
 185                 return;
 186         s = strcat(":ctf:", mode);
 187         s = strcat(s, ":", ftos(flagteam));
 188         if(actor != world)
 189                 s = strcat(s, ":", ftos(actor.playerid));
 190         GameLogEcho(s);
 191 }
 192
 193 void RegenFlag(entity e)
 194 {
 195         setattachment(e, world, "");
 196         e.damageforcescale = 0;
 197         e.movetype = MOVETYPE_NONE;
 198         if(!self.noalign)
 199                 e.movetype = MOVETYPE_TOSS;
 200         e.solid = SOLID_TRIGGER;
 201         // TODO: play a sound here
 202         setorigin(e, e.dropped_origin);
 203         e.angles = e.mangle;
 204         e.cnt = FLAG_BASE;
 205         e.owner = world;
 206         e.flags = FL_ITEM; // clear FL_ONGROUND and any other junk
 207 };
 208
 209 void ReturnFlag(entity e)
 210 {
 211         if (e.owner)
 212         if (e.owner.flagcarried == e)
 213         {
 214                 WaypointSprite_DetachCarrier(e.owner);
 215                 e.owner.flagcarried = world;
 216
 217                 if(e.speedrunning)
 218                         FakeTimeLimit(e.owner, -1);
 219         }
 220         e.owner = world;
 221         RegenFlag(e);
 222 };
 223
 224 void DropFlag(entity e, entity penalty_receiver, entity attacker)
 225 {
 226         local entity p;
 227
 228         if(e.speedrunning)
 229         {
 230                 ReturnFlag(e);
 231                 return;
 232         }
 233
 234         if (!e.owner)
 235         {
 236                 dprint("FLAG: drop - no owner?!?!\n");
 237                 return;
 238         }
 239         p = e.owner;
 240         if (p.flagcarried != e)
 241         {
 242                 dprint("FLAG: drop - owner is not carrying this flag??\n");
 243                 return;
 244         }
 245         bprint(p.netname, "^7 lost the ", e.netname, "\n");
 246
 247         if(penalty_receiver)
 248                 UpdateFrags(penalty_receiver, -ctf_score_value("penalty_suicidedrop"));
 249         else
 250                 UpdateFrags(p, -ctf_score_value("penalty_drop"));
 251         PlayerScore_Add(p, SP_CTF_DROPS, +1);
 252         ctf_captureshield_update(p, 0); // shield only
 253         e.playerid = attacker.playerid;
 254         e.ctf_droptime = time;
 255
 256         if(p.waypointsprite_attachedforcarrier)
 257         {
 258                 WaypointSprite_Ping(p.waypointsprite_attachedforcarrier);
 259                 WaypointSprite_DetachCarrier(p);
 260         }
 261         else
 262         {
 263                 bprint("\{1}^1Flag carrier had no flag sprite?!?\n");
 264                 backtrace("Flag carrier had no flag sprite?!?");
 265         }
 266         LogCTF("dropped", p.team, p);
 267
 268         setattachment(e, world, "");
 269         e.damageforcescale = cvar("g_balance_ctf_damageforcescale");
 270
 271         if (p.flagcarried == e)
 272                 p.flagcarried = world;
 273         e.owner = world;
 274
 275         e.flags = FL_ITEM; // clear FL_ONGROUND and any other junk
 276         e.solid = SOLID_TRIGGER;
 277         e.movetype = MOVETYPE_TOSS;
 278         // setsize(e, '-16 -16 0', '16 16 74');
 279         setorigin(e, p.origin - '0 0 24' + '0 0 37');
 280         e.cnt = FLAG_DROPPED;
 281         e.velocity = '0 0 300';
 282         e.pain_finished = time + cvar("g_ctf_flag_returntime");//30;
 283
 284         trace_startsolid = FALSE;
 285         tracebox(e.origin, e.mins, e.maxs, e.origin, TRUE, e);
 286         if(trace_startsolid)
 287                 dprint("FLAG FALLTHROUGH will happen SOON\n");
 288 };
 289
 290 void AnimateFlag()
 291 {
 292         if(self.delay > time)
 293                 return;
 294         self.delay = time + self.t_width;
 295         if(self.nextthink > self.delay)
 296                 self.nextthink = self.delay;
 297
 298         self.frame = self.frame + 1;
 299         if(self.frame > self.t_length)
 300                 self.frame = 0;
 301 }
 302
 303 void FlagThink()
 304 {
 305         local entity e;
 306
 307         self.nextthink = time + 0.1;
 308
 309         if(self == ctf_worldflaglist) // only for the first flag
 310         {
 311                 FOR_EACH_CLIENT(e)
 312                         ctf_captureshield_update(e, 1); // release shield only
 313         }
 314
 315         AnimateFlag();
 316
 317         if(self.speedrunning)
 318         if(self.cnt == FLAG_CARRY)
 319         {
 320                 if(self.owner)
 321                 if(flagcaptimerecord)
 322                 if(time >= self.flagpickuptime + flagcaptimerecord)
 323                 {
 324                         bprint("The ", self.netname, " became impatient after ", ftos_decimals(flagcaptimerecord, 2), " seconds and returned itself\n");
 325
 326                         self.owner.impulse = 77; // returning!
 327                         e = self;
 328                         self = self.owner;
 329                         ReturnFlag(e);
 330                         ImpulseCommands();
 331                         self = e;
 332                         return;
 333                 }
 334         }
 335
 336         if (self.cnt == FLAG_BASE)
 337                 return;
 338
 339         if (self.cnt == FLAG_DROPPED)
 340         {
 341                 // flag fallthrough? FIXME remove this if bug is really fixed now
 342                 if(self.origin_z < -131072)
 343                 {
 344                         dprint("FLAG FALLTHROUGH just happened\n");
 345                         self.pain_finished = 0;
 346                 }
 347                 setattachment(self, world, "");
 348                 if (time > self.pain_finished)
 349                 {
 350                         bprint("The ", self.netname, " has returned to base\n");
 351                         sound (self, CHAN_TRIGGER, self.noise3, VOL_BASE, ATTN_NONE);
 352                         LogCTF("returned", self.team, world);
 353                         ReturnFlag(self);
 354                 }
 355                 return;
 356         }
 357
 358         e = self.owner;
 359         if (e.classname != "player" || (e.deadflag) || (e.flagcarried != self))
 360         {
 361                 dprint("CANNOT HAPPEN - player dead and STILL had a flag!\n");
 362                 DropFlag(self, world, world);
 363                 return;
 364         }
 365
 366         if(cvar("g_ctf_allow_drop"))
 367         if(e.BUTTON_USE)
 368                 DropFlag(self, e, world);
 369 };
 370
 371 void FlagTouch()
 372 {
 373         if(gameover) return;
 374
 375         local float t;
 376         local entity player;
 377         local string s, s0, h0, h1;
 378         if (other.classname != "player")
 379                 return;
 380         if (other.health < 1) // ignore dead players
 381                 return;
 382
 383         if (self.cnt == FLAG_CARRY)
 384                 return;
 385
 386         if (self.cnt == FLAG_BASE)
 387         if (other.team == self.team)
 388         if (other.flagcarried) // he's got a flag
 389         if (other.flagcarried.team != self.team) // capture
 390         {
 391                 if (other.flagcarried == world)
 392                 {
 393                         return;
 394                 }
 395                 t = time - other.flagcarried.flagpickuptime;
 396                 s = ftos_decimals(t, 2);
 397                 s0 = ftos_decimals(flagcaptimerecord, 2);
 398                 h0 = db_get(ServerProgsDB, strcat(GetMapname(), "/captimerecord/netname"));
 399                 h1 = other.netname;
 400                 if(h0 == h1)
 401                         h0 = "his";
 402                 else
 403                         h0 = strcat(h0, "^7's"); // h0: display text for previous netname
 404                 if (flagcaptimerecord == 0)
 405                 {
 406                         bprint(other.netname, "^7 captured the ", other.flagcarried.netname, " in ", s, " seconds\n");
 407                         flagcaptimerecord = t;
 408                         db_put(ServerProgsDB, strcat(GetMapname(), "/captimerecord/time"), ftos(t));
 409                         db_put(ServerProgsDB, strcat(GetMapname(), "/captimerecord/netname"), h1);
 410                         GameLogEcho(strcat(":recordset:", ftos(other.playerid), ":", ftos(t)));
 411                 }
 412                 else if (t < flagcaptimerecord)
 413                 {
 414                         bprint(other.netname, "^7 captured the ", other.flagcarried.netname, " in ", s, ", breaking ", strcat(h0, " previous record of ", s0, " seconds\n"));
 415                         flagcaptimerecord = t;
 416                         db_put(ServerProgsDB, strcat(GetMapname(), "/captimerecord/time"), ftos(t));
 417                         db_put(ServerProgsDB, strcat(GetMapname(), "/captimerecord/netname"), h1);
 418                         GameLogEcho(strcat(":recordset:", ftos(other.playerid), ":", ftos(t)));
 419                 }
 420                 else
 421                 {
 422                         bprint(other.netname, "^7 captured the ", other.flagcarried.netname, " in ", s, ", failing to break ", strcat(h0, " record of ", s0, " seconds\n"));
 423                 }
 424
 425                 PlayerTeamScore_Add(other, SP_CTF_CAPS, ST_CTF_CAPS, 1);
 426                 LogCTF("capture", other.flagcarried.team, other);
 427                 // give credit to the individual player
 428                 UpdateFrags(other, ctf_score_value("score_capture"));
 429
 430                 sound (other, CHAN_AUTO, self.noise2, VOL_BASE, ATTN_NONE);
 431                 WaypointSprite_DetachCarrier(other);
 432                 if(self.speedrunning)
 433                         FakeTimeLimit(other, -1);
 434                 RegenFlag (other.flagcarried);
 435                 other.flagcarried = world;
 436                 other.next_take_time = time + 1;
 437         }
 438         if (self.cnt == FLAG_BASE)
 439         if (other.team == COLOR_TEAM1 || other.team == COLOR_TEAM2) // only red and blue team can steal flags
 440         if (other.team != self.team)
 441         if (!other.flagcarried)
 442         if (!other.ctf_captureshielded)
 443         {
 444                 if (other.next_take_time > time)
 445                         return;
 446                 // pick up
 447                 self.flagpickuptime = time; // used for timing runs
 448                 self.speedrunning = other.speedrunning; // if speedrunning, flag will self-return and teleport the owner back after the record
 449                 if(other.speedrunning)
 450                 if(flagcaptimerecord)
 451                         FakeTimeLimit(other, time + flagcaptimerecord);
 452                 self.solid = SOLID_NOT;
 453                 setorigin(self, self.origin); // relink
 454                 self.owner = other;
 455                 other.flagcarried = self;
 456                 self.cnt = FLAG_CARRY;
 457                 self.angles = '0 0 0';
 458                 bprint(other.netname, "^7 got the ", self.netname, "\n");
 459                 UpdateFrags(other, ctf_score_value("score_pickup_base"));
 460                 self.dropperid = other.playerid;
 461                 PlayerScore_Add(other, SP_CTF_PICKUPS, 1);
 462                 LogCTF("steal", self.team, other);
 463                 sound (other, CHAN_AUTO, self.noise, VOL_BASE, ATTN_NONE);
 464
 465                 FOR_EACH_PLAYER(player)
 466                         if(player.team == self.team)
 467                                 centerprint(player, "The enemy got your flag! Retrieve it!");
 468
 469                 self.movetype = MOVETYPE_NONE;
 470                 setorigin(self, FLAG_CARRY_POS);
 471                 setattachment(self, other, "");
 472                 WaypointSprite_AttachCarrier("flagcarrier", other);
 473                 WaypointSprite_UpdateTeamRadar(other.waypointsprite_attachedforcarrier, RADARICON_FLAGCARRIER, '1 1 0');
 474                 WaypointSprite_Ping(self.sprite);
 475
 476                 return;
 477         }
 478
 479         if (self.cnt == FLAG_DROPPED)
 480         {
 481                 self.flags = FL_ITEM; // clear FL_ONGROUND and any other junk
 482                 if (other.team == self.team || (other.team != COLOR_TEAM1 && other.team != COLOR_TEAM2))
 483                 {
 484                         // return flag
 485                         bprint(other.netname, "^7 returned the ", self.netname, "\n");
 486
 487                         // punish the player who last had it
 488                         FOR_EACH_PLAYER(player)
 489                                 if(player.playerid == self.dropperid)
 490                                 {
 491                                         PlayerScore_Add(player, SP_SCORE, -ctf_score_value("penalty_returned"));
 492                                         ctf_captureshield_update(player, 0); // shield only
 493                                 }
 494
 495                         // punish the team who was last carrying it
 496                         if(self.team == COLOR_TEAM1)
 497                                 TeamScore_AddToTeam(COLOR_TEAM2, ST_SCORE, -ctf_score_value("penalty_returned"));
 498                         else
 499                                 TeamScore_AddToTeam(COLOR_TEAM1, ST_SCORE, -ctf_score_value("penalty_returned"));
 500
 501                         // reward the player who returned it
 502                         if(other.playerid == self.playerid) // is this the guy who killed the FC last?
 503                         {
 504                                 if (other.team == COLOR_TEAM1 || other.team == COLOR_TEAM2)
 505                                         UpdateFrags(other, ctf_score_value("score_return_by_killer"));
 506                                 else
 507                                         UpdateFrags(other, ctf_score_value("score_return_rogue_by_killer"));
 508                         }
 509                         else
 510                         {
 511                                 if (other.team == COLOR_TEAM1 || other.team == COLOR_TEAM2)
 512                                         UpdateFrags(other, ctf_score_value("score_return"));
 513                                 else
 514                                         UpdateFrags(other, ctf_score_value("score_return_rogue"));
 515                         }
 516                         PlayerScore_Add(other, SP_CTF_RETURNS, 1);
 517                         LogCTF("return", self.team, other);
 518                         sound (other, CHAN_AUTO, self.noise1, VOL_BASE, ATTN_NONE);
 519                         ReturnFlag(self);
 520                 }
 521                 else if (!other.flagcarried && (other.playerid != self.dropperid || time > self.ctf_droptime + cvar("g_balance_ctf_delay_collect")))
 522                 {
 523                         // pick up
 524                         self.solid = SOLID_NOT;
 525                         setorigin(self, self.origin); // relink
 526                         self.owner = other;
 527                         other.flagcarried = self;
 528                         self.cnt = FLAG_CARRY;
 529                         bprint(other.netname, "^7 picked up the ", self.netname, "\n");
 530
 531                         float f;
 532                         f = bound(0, (self.pain_finished - time) / cvar("g_ctf_flag_returntime"), 1);
 533                         //print("factor is ", ftos(f), "\n");
 534                         f = ctf_score_value("score_pickup_dropped_late") * (1-f)
 535                           + ctf_score_value("score_pickup_dropped_early") * f;
 536                         f = floor(f + 0.5);
 537                         self.dropperid = other.playerid;
 538                         //print("score is ", ftos(f), "\n");
 539
 540                         UpdateFrags(other, f);
 541                         PlayerScore_Add(other, SP_CTF_PICKUPS, 1);
 542                         LogCTF("pickup", self.team, other);
 543                         sound (other, CHAN_AUTO, self.noise, VOL_BASE, ATTN_NONE);
 544
 545                         FOR_EACH_PLAYER(player)
 546                                 if(player.team == self.team)
 547                                         centerprint(player, "The enemy got your flag! Retrieve it!");
 548
 549                         self.movetype = MOVETYPE_NONE;  // flag must have MOVETYPE_NONE here, otherwise it will drop through the floor...
 550                         setorigin(self, FLAG_CARRY_POS);
 551                         setattachment(self, other, "");
 552                         self.damageforcescale = 0;
 553                         WaypointSprite_AttachCarrier("flagcarrier", other);
 554                         WaypointSprite_UpdateTeamRadar(other.waypointsprite_attachedforcarrier, RADARICON_FLAGCARRIER, '1 1 0');
 555                 }
 556         }
 557 };
 558
 559 /*QUAKED spawnfunc_info_player_team1 (1 0 0) (-16 -16 -24) (16 16 24)
 560 CTF Starting point for a player
 561 in team one (Red).
 562
 563 Keys:
 564 "angle"
 565  viewing angle when spawning
 566 */
 567 void spawnfunc_info_player_team1()
 568 {
 569         self.team = COLOR_TEAM1; // red
 570         spawnfunc_info_player_deathmatch();
 571 };
 572 //self.team = 4;self.classname = "info_player_start";spawnfunc_info_player_start();};
 573
 574 /*QUAKED spawnfunc_info_player_team2 (1 0 0) (-16 -16 -24) (16 16 24)
 575 CTF Starting point for a player in
 576 team two (Blue).
 577
 578 Keys:
 579 "angle"
 580  viewing angle when spawning
 581 */
 582 void spawnfunc_info_player_team2()
 583 {
 584         self.team = COLOR_TEAM2; // blue
 585         spawnfunc_info_player_deathmatch();
 586 };
 587 //self.team = 13;self.classname = "info_player_start";spawnfunc_info_player_start();};
 588
 589 /*QUAKED spawnfunc_info_player_team3 (1 0 0) (-16 -16 -24) (16 16 24)
 590 CTF Starting point for a player in
 591 team three (Magenta).
 592
 593 Keys:
 594 "angle"
 595  viewing angle when spawning
 596 */
 597 void spawnfunc_info_player_team3()
 598 {
 599         self.team = COLOR_TEAM3; // purple
 600         spawnfunc_info_player_deathmatch();
 601 };
 602
 603
 604 /*QUAKED spawnfunc_info_player_team4 (1 0 0) (-16 -16 -24) (16 16 24)
 605 CTF Starting point for a player in
 606 team four (Yellow).
 607
 608 Keys:
 609 "angle"
 610  viewing angle when spawning
 611 */
 612 void spawnfunc_info_player_team4()
 613 {
 614         self.team = COLOR_TEAM4; // yellow
 615         spawnfunc_info_player_deathmatch();
 616 };
 617
 618
 619
 620
 621 /*QUAKED spawnfunc_item_flag_team1 (0 0.5 0.8) (-48 -48 -37) (48 48 37)
 622 CTF flag for team one (Red).
 623 Multiple are allowed.
 624
 625 Keys:
 626 "angle"
 627  Angle the flag will point
 628 (minus 90 degrees)
 629 "model"
 630  model to use, note this needs red and blue as skins 0 and 1
 631  (default models/ctf/flag.md3)
 632 "noise"
 633  sound played when flag is picked up
 634  (default ctf/take.wav)
 635 "noise1"
 636  sound played when flag is returned by a teammate
 637  (default ctf/return.wav)
 638 "noise2"
 639  sound played when flag is captured
 640  (default ctf/redcapture.wav)
 641 "noise3"
 642  sound played when flag is lost in the field and respawns itself
 643  (default ctf/respawn.wav)
 644 */
 645
 646 void spawnfunc_item_flag_team1()
 647 {
 648         if (!g_ctf)
 649         {
 650                 remove(self);
 651                 return;
 652         }
 653
 654         //if(!cvar("teamplay"))
 655         //      cvar_set("teamplay", "3");
 656
 657         // link flag into ctf_worldflaglist
 658         self.ctf_worldflagnext = ctf_worldflaglist;
 659         ctf_worldflaglist = self;
 660
 661         self.classname = "item_flag_team";
 662         if(g_ctf_reverse)
 663         {
 664                 self.team = COLOR_TEAM2; // color 13 team (blue)
 665                 self.items = IT_KEY1; // silver key (bluish enough)
 666         }
 667         else
 668         {
 669                 self.team = COLOR_TEAM1; // color 4 team (red)
 670                 self.items = IT_KEY2; // gold key (redish enough)
 671         }
 672         self.netname = "^1RED^7 flag";
 673         self.target = "###item###";
 674         self.skin = 0;
 675         if(self.spawnflags & 1)
 676                 self.noalign = 1;
 677         if (!self.model)
 678                 self.model = "models/ctf/flag_red.md3";
 679         if (!self.noise)
 680                 self.noise = "ctf/take.wav";
 681         if (!self.noise1)
 682                 self.noise1 = "ctf/return.wav";
 683         if (!self.noise2)
 684                 self.noise2 = "ctf/redcapture.wav"; // blue team scores by capturing the red flag
 685         if (!self.noise3)
 686                 self.noise3 = "ctf/respawn.wav";
 687         precache_model (self.model);
 688         setmodel (self, self.model); // precision set below
 689         precache_sound (self.noise);
 690         precache_sound (self.noise1);
 691         precache_sound (self.noise2);
 692         precache_sound (self.noise3);
 693         //setsize(self, '-16 -16 -37', '16 16 37');
 694         setsize(self, PL_MIN + '0 0 -13', PL_MAX + '0 0 -13');
 695         setorigin(self, self.origin + '0 0 37');
 696         self.nextthink = time + 0.2; // start after doors etc
 697         self.think = place_flag;
 698
 699         if(!self.scale)
 700                 self.scale = 0.6;
 701         //if(!self.glow_size)
 702         //      self.glow_size = 50;
 703
 704         self.effects = self.effects | EF_LOWPRECISION;
 705         if(cvar("g_ctf_fullbrightflags"))
 706                 self.effects |= EF_FULLBRIGHT;
 707
 708         waypoint_spawnforitem(self);
 709
 710         WaypointSprite_SpawnFixed("redbase", self.origin + '0 0 37', self, sprite);
 711         WaypointSprite_UpdateTeamRadar(self.sprite, RADARICON_FLAG, '1 0 0');
 712
 713         precache_model("models/onslaught/generator_shield.md3");
 714 };
 715
 716 /*QUAKED spawnfunc_item_flag_team2 (0 0.5 0.8) (-48 -48 -24) (48 48 64)
 717 CTF flag for team two (Blue).
 718 Multiple are allowed.
 719
 720 Keys:
 721 "angle"
 722  Angle the flag will point
 723 (minus 90 degrees)
 724 "model"
 725  model to use, note this needs red and blue as skins 0 and 1
 726  (default models/ctf/flag.md3)
 727 "noise"
 728  sound played when flag is picked up
 729  (default ctf/take.wav)
 730 "noise1"
 731  sound played when flag is returned by a teammate
 732  (default ctf/return.wav)
 733 "noise2"
 734  sound played when flag is captured
 735  (default ctf/bluecapture.wav)
 736 "noise3"
 737  sound played when flag is lost in the field and respawns itself
 738  (default ctf/respawn.wav)
 739 */
 740
 741 void spawnfunc_item_flag_team2()
 742 {
 743         if (!g_ctf)
 744         {
 745                 remove(self);
 746                 return;
 747         }
 748         //if(!cvar("teamplay"))
 749         //      cvar_set("teamplay", "3");
 750
 751         // link flag into ctf_worldflaglist
 752         self.ctf_worldflagnext = ctf_worldflaglist;
 753         ctf_worldflaglist = self;
 754
 755         self.classname = "item_flag_team";
 756         if(g_ctf_reverse)
 757         {
 758                 self.team = COLOR_TEAM1; // color 4 team (red)
 759                 self.items = IT_KEY2; // gold key (redish enough)
 760         }
 761         else
 762         {
 763                 self.team = COLOR_TEAM2; // color 13 team (blue)
 764                 self.items = IT_KEY1; // silver key (bluish enough)
 765         }
 766         self.netname = "^4BLUE^7 flag";
 767         self.target = "###item###";
 768         self.skin = 0;
 769         if(self.spawnflags & 1)
 770                 self.noalign = 1;
 771         if (!self.model)
 772                 self.model = "models/ctf/flag_blue.md3";
 773         if (!self.noise)
 774                 self.noise = "ctf/take.wav";
 775         if (!self.noise1)
 776                 self.noise1 = "ctf/return.wav";
 777         if (!self.noise2)
 778                 self.noise2 = "ctf/bluecapture.wav"; // red team scores by capturing the blue flag
 779         if (!self.noise3)
 780                 self.noise3 = "ctf/respawn.wav";
 781         precache_model (self.model);
 782         setmodel (self, self.model); // precision set below
 783         precache_sound (self.noise);
 784         precache_sound (self.noise1);
 785         precache_sound (self.noise2);
 786         precache_sound (self.noise3);
 787         //setsize(self, '-16 -16 -37', '16 16 37');
 788         setsize(self, PL_MIN + '0 0 -13', PL_MAX + '0 0 -13');
 789         setorigin(self, self.origin + '0 0 37');
 790         self.nextthink = time + 0.2; // start after doors etc
 791         self.think = place_flag;
 792
 793         if(!self.scale)
 794                 self.scale = 0.6;
 795         //if(!self.glow_size)
 796         //      self.glow_size = 50;
 797
 798         self.effects = self.effects | EF_LOWPRECISION;
 799         if(cvar("g_ctf_fullbrightflags"))
 800                 self.effects |= EF_FULLBRIGHT;
 801
 802         waypoint_spawnforitem(self);
 803
 804         WaypointSprite_SpawnFixed("bluebase", self.origin + '0 0 37', self, sprite);
 805         WaypointSprite_UpdateTeamRadar(self.sprite, RADARICON_FLAG, '0 0 1');
 806
 807         precache_model("models/onslaught/generator_shield.md3");
 808 };
 809
 810
 811 /*QUAKED spawnfunc_ctf_team (0 .5 .8) (-16 -16 -24) (16 16 32)
 812 Team declaration for CTF gameplay, this allows you to decide what team
 813 names and control point models are used in your map.
 814
 815 Note: If you use spawnfunc_ctf_team entities you must define at least 2!  However, unlike
 816 domination, you don't need to make a blank one too.
 817
 818 Keys:
 819 "netname"
 820  Name of the team (for example Red, Blue, Green, Yellow, Life, Death, Offense, Defense, etc)
 821 "cnt"
 822  Scoreboard color of the team (for example 4 is red and 13 is blue)
 823
 824 */
 825
 826 void spawnfunc_ctf_team()
 827 {
 828         if (!g_ctf)
 829         {
 830                 remove(self);
 831                 return;
 832         }
 833         self.classname = "ctf_team";
 834         self.team = self.cnt + 1;
 835 };
 836
 837 // code from here on is just to support maps that don't have control point and team entities
 838 void ctf_spawnteam (string teamname, float teamcolor)
 839 {
 840         local entity oldself;
 841         oldself = self;
 842         self = spawn();
 843         self.classname = "ctf_team";
 844         self.netname = teamname;
 845         self.cnt = teamcolor;
 846
 847         spawnfunc_ctf_team();
 848
 849         self = oldself;
 850 };
 851
 852 // spawn some default teams if the map is not set up for ctf
 853 void ctf_spawnteams()
 854 {
 855         float numteams;
 856
 857         numteams = 2;//cvar("g_ctf_default_teams");
 858
 859         ctf_spawnteam("Red", COLOR_TEAM1 - 1);
 860         ctf_spawnteam("Blue", COLOR_TEAM2 - 1);
 861 };
 862
 863 void ctf_delayedinit()
 864 {
 865         // if no teams are found, spawn defaults
 866         if (find(world, classname, "ctf_team") == world)
 867                 ctf_spawnteams();
 868
 869         ScoreRules_ctf();
 870 };
 871
 872 void ctf_init()
 873 {
 874         InitializeEntity(world, ctf_delayedinit, INITPRIO_GAMETYPE);
 875         flagcaptimerecord = stof(db_get(ServerProgsDB, strcat(GetMapname(), "/captimerecord/time")));
 876
 877         captureshield_min_negscore = cvar("g_ctf_shield_min_negscore");
 878         captureshield_max_ratio = cvar("g_ctf_shield_max_ratio");
 879         captureshield_force = cvar("g_ctf_shield_force");
 880 };
 881
 882 void ctf_setstatus2(entity flag, float shift)
 883 {
 884         if (flag.cnt == FLAG_CARRY)
 885                 if (flag.owner == self)
 886                         self.items |= shift * 3;
 887                 else
 888                         self.items |= shift * 1;
 889         else if (flag.cnt == FLAG_DROPPED)
 890                 self.items |= shift * 2;
 891         else
 892         {
 893                 // no status bits
 894         }
 895 };
 896
 897 void ctf_setstatus()
 898 {
 899         self.items (-) IT_RED_FLAG_TAKEN;
 900         self.items (-) IT_RED_FLAG_LOST;
 901         self.items (-) IT_BLUE_FLAG_TAKEN;
 902         self.items (-) IT_BLUE_FLAG_LOST;
 903         self.items (-) IT_CTF_SHIELDED;
 904
 905         if (g_ctf) {
 906                 local entity flag;
 907                 float redflags, blueflags;
 908
 909                 if(self.ctf_captureshielded)
 910                         self.items |= IT_CTF_SHIELDED;
 911
 912                 redflags = 0;
 913                 blueflags = 0;
 914
 915                 for (flag = ctf_worldflaglist; flag; flag = flag.ctf_worldflagnext) if(flag.cnt != FLAG_BASE)
 916                 {
 917                         if(flag.items & IT_KEY2) // blue
 918                                 ++redflags;
 919                         else if(flag.items & IT_KEY1) // red
 920                                 ++blueflags;
 921                 }
 922
 923                 // blinking magic: if there is more than one flag, show one of these in a clever way
 924                 if(redflags)
 925                         redflags = mod(floor(time * redflags * 0.75), redflags);
 926                 if(blueflags)
 927                         blueflags = mod(floor(time * blueflags * 0.75), blueflags);
 928
 929                 for (flag = ctf_worldflaglist; flag; flag = flag.ctf_worldflagnext) if(flag.cnt != FLAG_BASE)
 930                 {
 931                         if(flag.items & IT_KEY2) // blue
 932                         {
 933                                 if(--redflags == -1) // happens exactly once (redflags is in 0..count-1, and will --'ed count times)
 934                                         ctf_setstatus2(flag, IT_RED_FLAG_TAKEN);
 935                         }
 936                         else if(flag.items & IT_KEY1) // red
 937                         {
 938                                 if(--blueflags == -1) // happens exactly once
 939                                         ctf_setstatus2(flag, IT_BLUE_FLAG_TAKEN);
 940                         }
 941                 }
 942         }
 943 };
 944 /*
 945 entity(float cteam) ctf_team_has_commander =
 946 {
 947         entity pl;
 948         if(cteam != COLOR_TEAM1 || cteam != COLOR_TEAM2)
 949                 return world;
 950
 951         FOR_EACH_REALPLAYER(pl) {
 952                 if(pl.team == cteam && pl.iscommander) {
 953                         return pl;
 954                 }
 955         }
 956         return world;
 957 };
 958
 959 void(entity e, float st) ctf_setstate =
 960 {
 961         e.ctf_state = st;
 962         ++e.version;
 963 };
 964
 965 void(float cteam) ctf_new_commander =
 966 {
 967         entity pl, plmax;
 968
 969         plmax = world;
 970         FOR_EACH_REALPLAYER(pl) {
 971                 if(pl.team == cteam) {
 972                         if(pl.iscommander) { // don't reassign if alreay there
 973                                 return;
 974                         }
 975                         if(plmax == world || plmax.frags < pl.frags) <<<<<<<<<<<<<<<<< BROKEN in new scoring system
 976                                 plmax = pl;
 977                 }
 978         }
 979         if(plmax == world) {
 980                 bprint(strcat(ColoredTeamName(cteam), " Team has no Commander!\n"));
 981                 return;
 982         }
 983
 984         plmax.iscommander = TRUE;
 985         ctf_setstate(plmax, 3);
 986         sprint(plmax, "^3You're the commander now!\n");
 987         centerprint(plmax, "^3You're the commander now!\n");
 988 };
 989
 990 void() ctf_clientconnect =
 991 {
 992         self.iscommander = FALSE;
 993
 994         if(!self.team || self.classname != "player") {
 995                 ctf_setstate(self, -1);
 996         } else
 997                 ctf_setstate(self, 0);
 998
 999         self.team_saved = self.team;
1000
1001         if(self.team != 0 && self.classname == "player" && !ctf_team_has_commander(self.team)) {
1002                 ctf_new_commander(self.team);
1003         }
1004 };
1005
1006 void() ctf_playerchanged =
1007 {
1008         if(!self.team || self.classname != "player") {
1009                 ctf_setstate(self, -1);
1010         } else if(self.ctf_state < 0 && self.classname == "player") {
1011                 ctf_setstate(self, 0);
1012         }
1013
1014         if(self.iscommander &&
1015            (self.classname != "player" || self.team != self.team_saved)
1016                 )
1017         {
1018                 self.iscommander = FALSE;
1019                 if(self.classname == "player")
1020                         ctf_setstate(self, 0);
1021                 else
1022                         ctf_setstate(self, -1);
1023                 ctf_new_commander(self.team_saved);
1024         }
1025
1026         self.team_saved = self.team;
1027
1028         ctf_new_commander(self.team);
1029 };
1030
1031 void() ctf_clientdisconnect =
1032 {
1033         if(self.iscommander)
1034         {
1035                 ctf_new_commander(self.team);
1036         }
1037 };
1038
1039 entity GetPlayer(string);
1040 float() ctf_clientcommand =
1041 {
1042         entity e;
1043         if(argv(0) == "order") {
1044                 if(!g_ctf) {
1045                         sprint(self, "This command is not supported in this gamemode.\n");
1046                         return TRUE;
1047                 }
1048                 if(!self.iscommander) {
1049                         sprint(self, "^1You are not the commander!\n");
1050                         return TRUE;
1051                 }
1052                 if(argv(2) == "") {
1053                         sprint(self, "Usage: order #player status   - (playernumber as in status)\n");
1054                         return TRUE;
1055                 }
1056                 e = GetPlayer(argv(1));
1057                 if(e == world) {
1058                         sprint(self, "Invalid player.\nUsage: order #player status   - (playernumber as in status)\n");
1059                         return TRUE;
1060                 }
1061                 if(e.team != self.team) {
1062                         sprint(self, "^3You can only give orders to your own team!\n");
1063                         return TRUE;
1064                 }
1065                 if(argv(2) == "attack") {
1066                         sprint(self, strcat("Ordering ", e.netname, " to attack!\n"));
1067                         sprint(e, "^1Attack!\n");
1068                         centerprint(e, "^7You've been ordered to^9\n^1Attack!\n");
1069                         ctf_setstate(e, 1);
1070                 } else if(argv(2) == "defend") {
1071                         sprint(self, strcat("Ordering ", e.netname, " to defend!\n"));
1072                         sprint(e, "^Defend!\n");
1073                         centerprint(e, "^7You've been ordered to^9\n^2Defend!\n");
1074                         ctf_setstate(e, 2);
1075                 } else {
1076                         sprint(self, "^7Invalid command, use ^3attack^7, or ^3defend^7.\n");
1077                 }
1078                 return TRUE;
1079         }
1080         return FALSE;
1081 };
1082 */