data/qcsrc/server/clientcommands.qc

   1 void ReadyCount();
   2 float ValidateMap(string vote);
   3 void(entity e) DropFlag;
   4
   5 void Say(entity source, float teamsay, string msgin)
   6 {
   7         string msgstr, colorstr, cmsgstr;
   8         entity head;
   9
  10         msgin = formatmessage(msgin);
  11
  12         if(msgin == "")
  13                 return;
  14
  15         colorstr = Team_ColorCode(source.team);
  16
  17         if(!teams_matter)
  18                 teamsay = FALSE;
  19
  20         if(source.classname != "player") // observers can't
  21                 teamsay = FALSE;
  22
  23         // how can we prevent the message from appearing in a listen server?
  24         // for now, just give "say" back and only handle say_team
  25         if(!teamsay)
  26         {
  27                 clientcommand(self, strcat("say ", msgin));
  28                 return;
  29         }
  30
  31         if(teamsay)
  32         {
  33                 msgstr = strzone(strcat("\{1}", colorstr, "(^3", source.netname, colorstr, ") ^7", msgin, "\n"));
  34                 cmsgstr = strcat(colorstr, "(^3", source.netname, colorstr, ")\n^7", wordwrap(msgin, 50));
  35         }
  36         else
  37                 msgstr = strzone(strcat("\{1}^3", source.netname, "^7: ", msgin, "\n"));
  38
  39         head = find(world, classname, "player");
  40         while(head)
  41         {
  42                 if(clienttype(head) == CLIENTTYPE_REAL)
  43                         if(!teamsay || (head.team == source.team))
  44                         {
  45                                 sprint(head, msgstr);
  46                                 if(teamsay)
  47                                         centermsg_setfor(head, CENTERMSG_TEAMSAY, cmsgstr);
  48                                 //stuffcmd(head, "play2 misc/talk.wav\n");
  49                         }
  50                 head = find(head, classname, "player");
  51         }
  52
  53         if(!teamsay)
  54         {
  55                 head = find(world, classname, "observer");
  56                 while(head)
  57                 {
  58                         if(clienttype(head) == CLIENTTYPE_REAL)
  59                         {
  60                                 sprint(head, msgstr);
  61                                 //stuffcmd(head, "play2 misc/talk.wav\n");
  62                         }
  63                         head = find(head, classname, "observer");
  64                 }
  65                 head = find(world, classname, "spectator");
  66                 while(head)
  67                 {
  68                         if(clienttype(head) == CLIENTTYPE_REAL)
  69                         {
  70                                 sprint(head, msgstr);
  71                                 //stuffcmd(head, "play2 misc/talk.wav\n");
  72                         }
  73                         head = find(head, classname, "spectator");
  74                 }
  75                 ServerConsoleEcho(substring(msgstr, 1, strlen(msgstr) - 2), TRUE);
  76         }
  77
  78         strunzone(msgstr);
  79 }
  80
  81 void SV_ParseClientCommand(string s) {
  82         local float index;
  83         local string cmd;
  84
  85         tokenize(s);
  86
  87         if(argv(0) == "clogin") {
  88                 if(cvar("sv_clientcommands")) {
  89                         if(self.adminstatus < -5) {
  90                                 sprint(self, "Too many unsuccessful tries.\n");
  91                         } else if(argv(1) == cvar_string("sv_clientcommands_password")) {
  92                                 self.adminstatus = 1;
  93                                 sprint(self, "You now have remote admin status.\n");
  94                                 ServerConsoleEcho(strcat("ClientCommands: ", self.netname, " received admin status"), TRUE);
  95                         } else {
  96                                 sprint(self, "Wrong password.\n");
  97                                 // use of -- produces compiler warning in the if() line???
  98                                 self.adminstatus = self.adminstatus - 1;
  99                                 if(self.adminstatus == 0)
 100                                 {
 101                                         sprint(self, "You lost remote admin status.\n");
 102                                         ServerConsoleEcho(strcat("ClientCommands: ", self.netname, " lost admin status"), TRUE);
 103                                 }
 104                         }
 105                 } else {
 106                         sprint(self, "Clientside commands NOT allowed.\n");
 107                 }
 108         } else if(argv(0) == "ccmd") {
 109                 if(cvar("sv_clientcommands")) {
 110                         if(self.adminstatus > 0) {
 111                                 local string command;
 112                                 command = argv(1);
 113                                 index = 2;
 114                                 while(argv(index) != "") {
 115                                         command = strcat(command, " ", argv(index));
 116                                         index++;
 117                                 }
 118                                 command = strzone(command);
 119                                 ServerConsoleEcho(strcat("ClientCommands: ", self.netname, " issued command '", command, "'"), TRUE);
 120                                 localcmd(strcat(command, "\n"));
 121                                 strunzone(command);
 122                         } else
 123                                 sprint(self, "You don't have remote admin status.\n");
 124                 } else {
 125                         sprint(self, "Clientside commands NOT allowed.\n");
 126                 }
 127         } else if(argv(0) == "vote") {
 128                 if(argv(1) == "help") {
 129                         local string vmasterdis;
 130                         if(!cvar("sv_vote_master")) {
 131                                 vmasterdis = " ^1(disabled)";
 132                         }
 133                         local string vcalldis;
 134                         if(!cvar("sv_vote_call")) {
 135                                 vcalldis = " ^1(disabled)";
 136                         }
 137                         sprint(self, "^7You can use voting with \"^2cmd vote help^7\" \"^2cmd vote status^7\" \"^2cmd vote call ^3COMMAND ARGUMENTS^7\" \"^2cmd vote stop^7\" \"^2cmd vote master^7\" \"^2cmd vote do ^3COMMAND ARGUMENTS^7\" \"^2cmd vote yes^7\" \"^2cmd vote no^7\".\n");
 138                         sprint(self, "^7Or if your version is up to date you can use these aliases \"^2vhelp^7\" \"^2vstatus^7\" \"^2vcall ^3COMMAND ARGUMENTS^7\" \"^2vstop^7\" \"^2vmaster^7\" \"^2vdo ^3COMMAND ARGUMENTS^7\" \"^2vyes^7\" \"^2vno^7\".\n");
 139                         sprint(self, "^7\"^2help^7\" shows this info.\n");
 140                         sprint(self, "^7\"^2status^7\" shows if there is a vote called and who called it.\n");
 141                         sprint(self, strcat("^7\"^2call^7\" is used to call a vote. See the list of allowed commands.", vcalldis, "^7\n"));
 142                         sprint(self, "^7\"^2stop^7\" can be used by the vote caller or an admin to stop a vote and maybe correct it.\n");
 143                         sprint(self, strcat("^7\"^2master^7\" is used to call a vote to become a master.", vmasterdis, "^7\n"));
 144                         sprint(self, "^7\"^2do^7\" If you are a master you can execute a command without a vote. See the list of allowed commands.\n");
 145                         sprint(self, "^7\"^2yes^7\" and \"^2no^7\" to make your vote.\n");
 146                         sprint(self, "^7If more then 50% of the players vote yes the vote is accepted.\n");
 147                         sprint(self, "^7If more then 50% of the players vote no the vote is rejected.\n");
 148                         sprint(self, strcat("^7The vote will end after ", cvar_string("sv_vote_timeout"), "^7 seconds.\n"));
 149                         sprint(self, "^7You can call a vote for or execute these commands:\n");
 150                         sprint(self, strcat("^3", cvar_string("sv_vote_commands"), "^7 and maybe further ^3arguments^7\n"));
 151                 } else if(argv(1) == "status") {
 152                         if(votecalled) {
 153                                 sprint(self, strcat("^7Vote for \"^1", votecalledvote, "^7\" called by \"^7", votecaller.netname, "^7\".\n"));
 154                         } else {
 155                                 sprint(self, "^1No vote called.\n");
 156                         }
 157                 } else if(argv(1) == "call") {
 158                         if(cvar("sv_vote_call")) {
 159                                 if(votecalled) {
 160                                         sprint(self, "^1There is already a vote called.\n");
 161                                 } else {
 162                                         local string vote;
 163                                         vote = VoteParse();
 164                                         if(vote == "") {
 165                                                 sprint(self, "^1Your vote is empty. See help for more info.\n");
 166                                         } else if(time < self.vote_next) {
 167                                                 sprint(self, strcat("^1You have to wait ^2", ftos(self.vote_next - time), "^1 seconds before you can again call a vote.\n"));
 168                                         } else if(VoteAllowed(strcat(argv(2)))) { // strcat seems to be necessary
 169                                                 if(!ValidateMap(vote))
 170                                                         return;
 171                                                 votecalled = TRUE;
 172                                                 votecalledmaster = FALSE;
 173                                                 // remap chmap to gomap (forces intermission)
 174                                                 if(strlen(vote) >= 6)
 175                                                         if(substring(vote, 0, 6) == "chmap ")
 176                                                                 vote = strcat("gotomap ", substring(vote, 6, strlen(vote) - 6));
 177                                                 votecalledvote = strzone(vote);
 178                                                 votecaller = self; // remember who called the vote
 179                                                 votefinished = time + cvar("sv_vote_timeout");
 180                                                 votecaller.vote_vote = 1; // of course you vote yes
 181                                                 votecaller.vote_next = time + cvar("sv_vote_wait");
 182                                                 bprint(strcat("\{1}^2* ^3", votecaller.netname, "^2 calls a vote for ^1", votecalledvote, "\n"));
 183                                                 VoteCount(); // needed if you are the only one
 184                                         } else {
 185                                                 sprint(self, "^1This vote is not ok. See help for more info.\n");
 186                                         }
 187                                 }
 188                         } else {
 189                                 sprint(self, "^1Vote calling is NOT allowed.\n");
 190                         }
 191                 } else if(argv(1) == "stop") {
 192                         if(!votecalled) {
 193                                 sprint(self, "^1No vote called.\n");
 194                         } else if(self == votecaller
 195                                   || self.adminstatus > 0) { // the votecaller and admins can stop a vote
 196                                 VoteStop(self);
 197                         } else {
 198                                 sprint(self, "^1You are not allowed to stop that Vote.\n");
 199                         }
 200                 } else if(argv(1) == "master") {
 201                         if(cvar("sv_vote_master")) {
 202                                 if(votecalled) {
 203                                         sprint(self, "^1There is already a vote called.\n");
 204                                 } else {
 205                                         votecalled = TRUE;
 206                                         votecalledmaster = TRUE;
 207                                         votecalledvote = strzone("^3master");
 208                                         votecaller = self; // remember who called the vote
 209                                         votefinished = time + cvar("sv_vote_timeout");
 210                                         votecaller.vote_vote = 1; // of course you vote yes
 211                                         votecaller.vote_next = time + cvar("sv_vote_wait");
 212                                         bprint(strcat("\"^3", votecaller.netname, "^3\" called a vote to become ^3master^3.\n"));
 213                                         VoteCount(); // needed if you are the only one
 214                                 }
 215                         } else {
 216                                 sprint(self, "^1Vote to become master is NOT allowed.\n");
 217                         }
 218                 } else if(argv(1) == "do") {
 219                         if(self.vote_master) {
 220                                 local string dovote;
 221                                 dovote = VoteParse();
 222                                 if(dovote == "") {
 223                                         sprint(self, "^1Your command was empty. See help for more info.\n");
 224                                 } else if(VoteAllowed(strcat(argv(2)))) { // strcat seems to be necessary
 225                                         bprint("\"^7", strcat(self.netname, "^2 used his ^3master^2 status to do \"^2", dovote, "^2\".\n"));
 226                                         localcmd(strcat(dovote, "\n"));
 227                                 } else {
 228                                         sprint(self, "^1This command is not ok. See help for more info.\n");
 229                                 }
 230                         } else {
 231                                 sprint(self, "^1You are NOT a master.\n");
 232                         }
 233                 } else if(argv(1) == "yes") {
 234                         if(!votecalled) {
 235                                 sprint(self, "^1No vote called.\n");
 236                         } else if(self.vote_vote == 0
 237                                   || cvar("sv_vote_change")) {
 238                                 sprint(self, "^1You accepted the vote.\n");
 239                                 self.vote_vote = 1;
 240                                 if(!cvar("sv_vote_singlecount")) {
 241                                         VoteCount();
 242                                 }
 243                         } else {
 244                                 sprint(self, "^1You have already voted.\n");
 245                         }
 246                 } else if(argv(1) == "no") {
 247                         if(!votecalled) {
 248                                 sprint(self, "^1No vote called.\n");
 249                         } else if(self.vote_vote == 0
 250                                   || cvar("sv_vote_change")) {
 251                                 sprint(self, "^1You rejected the vote.\n");
 252                                 self.vote_vote = -1;
 253                                 if(!cvar("sv_vote_singlecount")) {
 254                                         VoteCount();
 255                                 }
 256                         } else {
 257                                 sprint(self, "^1You have already voted.\n");
 258                         }
 259                 } else {
 260                         // ignore this?
 261                         sprint(self, "^1Unknown vote command.\n");
 262                 }
 263         } else if(argv(0) == "autoswitch") {
 264                 // be backwards compatible with older clients (enabled)
 265                 self.autoswitch = ("0" != argv(1));
 266                 local string autoswitchmsg;
 267                 if (self.autoswitch) {
 268                         autoswitchmsg = "on";
 269                 } else {
 270                         autoswitchmsg = "off";
 271                 }
 272                 sprint(self, strcat("^1autoswitch turned ", autoswitchmsg, "\n"));
 273         } else if(argv(0) == "clientversion") {
 274                 if (argv(1) == "$gameversion") {
 275                         //versionmsg = "^1client is too old to get versioninfo.\nUPDATE!!! (http://www.nexuiz.com)^8";
 276                         // either that or someone wants to be funny
 277                         self.version = 1;
 278                 } else {
 279                         self.version = stof(argv(1));
 280                 }
 281                 if(self.version != cvar("gameversion"))
 282                 {
 283                         self.classname = "observer";
 284                         self.frags = -2;
 285                         PutClientInServer();
 286                 } else if(cvar("g_campaign") || cvar("g_balance_teams")) {
 287                         //JoinBestTeam(self, 0);
 288                 } else if(cvar("teamplay") && !cvar("sv_spectate")) {
 289                         self.classname = "observer";
 290                         stuffcmd(self,"menu_showteamselect\n");
 291                 }
 292         } else if(argv(0) == "reportcvar") {
 293                 GetCvars(1);
 294         } else if(argv(0) == "spectate") {
 295                 if(cvar("g_lms") || cvar("g_arena"))
 296                         return; // don't allow spectating in lms, unless player runs out of lives
 297                 if(self.classname == "player" && cvar("sv_spectate") == 1) {
 298                         if(self.flagcarried)
 299                                 DropFlag(self.flagcarried);
 300                         DistributeFragsAmongTeam(self, self.team, 1.0);
 301                         self.classname = "observer";
 302                         PutClientInServer();
 303                 }
 304         } else if(argv(0) == "join") {
 305                 if(!cvar("g_arena"))
 306                 if (self.classname != "player")
 307                 {
 308                         self.classname = "player";
 309                         self.frags = 0;
 310                         bprint (strcat("^4", self.netname, "^4 is playing now\n"));
 311                         PutClientInServer();
 312                 }
 313         } else if( argv(0) == "selectteam" ) {
 314                 if( !cvar("teamplay") ) {
 315                         sprint( self, "selecteam can only be used in teamgames\n");
 316                 } else if(cvar("g_campaign")) {
 317                         //JoinBestTeam(self, 0);
 318                 } else if( argv(1) == "none" ) {
 319                         SV_ChangeTeam( 0 );
 320                 } else if( argv(1) == "red" ) {
 321                         SV_ChangeTeam( COLOR_TEAM1 - 1 );
 322                 } else if( argv(1) == "blue" ) {
 323                         SV_ChangeTeam( COLOR_TEAM2 - 1 );
 324                 } else if( argv(1) == "pink" ) {
 325                         SV_ChangeTeam( COLOR_TEAM3 - 1 );
 326                 } else if( argv(1) == "yellow" ) {
 327                         SV_ChangeTeam( COLOR_TEAM4 - 1 );
 328                 } else if( argv(1) == "auto" ) {
 329                         self.team = -1;
 330                         JoinBestTeam( self, 0 );
 331                 } else {
 332                         sprint( self, strcat( "selectteam none/red/blue/pink/yellow/auto - \"", argv(1), "\" not recognised\n" ) );
 333                 }
 334         } else if(argv(0) == "ready") {
 335                 if(cvar("sv_ready_restart"))
 336                 {
 337                         self.ready = TRUE;
 338                         bprint(self.netname, "^2 is ready\n");
 339                         ReadyCount();
 340                 }
 341         } else if(argv(0) == "maplist") {
 342                 local float i, n;
 343                 local string col;
 344                 n = tokenize(cvar_string("g_maplist"));
 345                 sprint(self, "^7Maps in list: ");
 346                 for(i = 0; i < n; ++i)
 347                 {
 348                         if(math_mod(i, 2))
 349                                 col = "^2";
 350                         else
 351                                 col = "^3";
 352                         sprint(self, strcat(col, argv(i), " "));
 353                 }
 354                 sprint(self, "\n");
 355         } else if(argv(0) == "say") {
 356                 Say(self, FALSE, substring(s, 4, strlen(s) - 4));
 357                 //clientcommand(self, formatmessage(s));
 358         } else if(argv(0) == "say_team") {
 359                 Say(self, TRUE, substring(s, 9, strlen(s) - 9));
 360                 //clientcommand(self, formatmessage(s));
 361         } else if(argv(0) == "info") {
 362                 cmd = cvar_string(strcat("sv_info_", argv(1)));
 363                 if(cmd == "")
 364                         sprint(self, "ERROR: unsupported info command\n");
 365                 else
 366                         wordwrap_sprint(cmd, 1111);
 367         } else {
 368                 cmd = argv(0);
 369                 if(cmd != "status")
 370                 if(cmd != "name")
 371                 //if(cmd != "say") // handled above
 372                 //if(cmd != "say_team") // handled above
 373                 if(cmd != "tell")
 374                 if(cmd != "color")
 375                 if(cmd != "kill")
 376                 if(cmd != "pause")
 377                 if(cmd != "kick")
 378                 if(cmd != "ping")
 379                 if(cmd != "pings")
 380                 if(cmd != "ban")
 381                 if(cmd != "pmodel")
 382                 if(cmd != "rate")
 383                 if(cmd != "playermodel")
 384                 if(cmd != "playerskin")
 385                 if(cmd != "god") if(cmd != "notarget") if(cmd != "fly") if(cmd != "give") if(cmd != "noclip")
 386                 {
 387                         ServerConsoleEcho(strcat("WARNING: Invalid clientcommand by ", self.netname, ": ", s), TRUE);
 388                         return;
 389                 }
 390                 clientcommand(self,s);
 391         }
 392 }
 393
 394 float ValidateMap(string vote)
 395 {
 396         string ext;
 397
 398         tokenize(vote);
 399         if(argv(0) == "map" || argv(0) == "changelevel")
 400                 ext = ".bsp";
 401         else if(argv(0) == "chmap")
 402                 ext = ".mapcfg";
 403         else if(argv(0) == "gotomap")
 404                 ext = ".mapcfg";
 405         else
 406                 return TRUE;
 407
 408         if(!TryFile(strcat("maps/", argv(1), ext)))
 409         {
 410                 sprint(self, strcat("^1Invalid mapname, \"^3", argv(1), "^1\" does not exist on this server.\n"));
 411                 return FALSE;
 412         }
 413         return TRUE;
 414 }
 415
 416
 417 void VoteThink() {
 418         if(votefinished > 0 // a vote was called
 419             && time > votefinished) // time is up
 420         {
 421                 VoteCount();
 422         }
 423 }
 424
 425 string VoteParse() {
 426         local float index;
 427         index = 3;
 428         local string vote;
 429         vote = argv(2);
 430         while(argv(index) != "") {
 431                 vote = strcat(vote, " ", argv(index));
 432                 index++;
 433         }
 434
 435         // necessary for some of the string operations
 436         vote = strzone(vote);
 437
 438         // now we remove some things that could be misused
 439         index = 0;
 440         local float found;
 441         found = FALSE;
 442         local float votelength;
 443         votelength = strlen(vote);
 444         while(!found && index < votelength)
 445         {
 446                 local string badchar;
 447                 badchar = substring(vote, index, 1);
 448                 if(badchar == ";"
 449                    || badchar == "\r"
 450                    || badchar == "\n")
 451                 {
 452                         found = TRUE;
 453                 } else {
 454                         index++;
 455                 }
 456         }
 457         return substring(vote, 0, index);
 458 }
 459
 460 float VoteAllowed(string votecommand) {
 461         tokenize(cvar_string("sv_vote_commands"));
 462         local float index;
 463         index = 0;
 464         while(argv(index) != "") {
 465                 local string allowed;
 466                 allowed = argv(index);
 467                 if(votecommand == allowed) {
 468                         return TRUE;
 469                 }
 470                 index++;
 471         }
 472         return FALSE;
 473 }
 474
 475 void VoteReset() {
 476         local string searchclass;
 477         searchclass = "player";
 478
 479         while (TRUE)
 480         {
 481                 local entity player;
 482                 player = find(player, classname, searchclass);
 483                 while(player)
 484                 {
 485                         player.vote_vote = 0;
 486                         player = find(player, classname, searchclass);
 487                 }
 488
 489                 if("player" == searchclass) {
 490                         searchclass = "observer";
 491                 } else if("observer" == searchclass) {
 492                         searchclass = "spectator";
 493                 } else {
 494                         break;
 495                 }
 496         }
 497
 498         votecalled = FALSE;
 499         votecalledmaster = FALSE;
 500         votefinished = 0;
 501 }
 502
 503 void VoteAccept() {
 504         bprint(strcat("\{1}^2* ^3", votecaller.netname, "^2's vote for ^1", votecalledvote, "^2 was accepted\n"));
 505         if(votecalledmaster)
 506         {
 507                 votecaller.vote_master = 1;
 508         } else {
 509                 localcmd(strcat(votecalledvote, "\n"));
 510         }
 511         votecaller.vote_next = 0; // people like your votes, no wait for next vote
 512         VoteReset();
 513 }
 514
 515 void VoteReject() {
 516         bprint(strcat("\{1}^2* ^3", votecaller.netname, "^2's vote for ^1", votecalledvote, "^2 was rejected\n"));
 517         VoteReset();
 518 }
 519
 520 void VoteTimeout() {
 521         bprint(strcat("\{1}^2* ^3", votecaller.netname, "^2's vote for ^1", votecalledvote, "^2 timed out\n"));
 522         VoteReset();
 523 }
 524
 525 void VoteStop(entity stopper) {
 526         bprint(strcat("\{1}^2* ^3", stopper.netname, "^2 stopped ^3", votecaller.netname, "^2's vote\n"));
 527         if(stopper == votecaller) {
 528                 // no wait for next vote so you can correct your vote
 529                 votecaller.vote_next = 0;
 530         }
 531         VoteReset();
 532 }
 533
 534 void VoteCount() {
 535         local float playercount;
 536         playercount = 0;
 537         local float yescount;
 538         yescount = 0;
 539         local float nocount;
 540         nocount = 0;
 541         local string searchclass;
 542         searchclass = "player";
 543
 544         while (TRUE)
 545         {
 546                 local entity player;
 547                 player = find(player, classname, searchclass);
 548
 549                 while(player)
 550                 {
 551                         if(clienttype(player) != CLIENTTYPE_BOT) {
 552                                 if(player.vote_vote < 0) {
 553                                         nocount++;
 554                                 } else if(player.vote_vote > 0) {
 555                                         yescount++;
 556                                 }
 557                                 playercount++;
 558                         }
 559                         player = find(player, classname, searchclass);
 560                 }
 561
 562                 if("player" == searchclass) {
 563                         searchclass = "observer";
 564                 } else if("observer" == searchclass) {
 565                         searchclass = "specator";
 566                 } else {
 567                         break;
 568                 }
 569         }
 570
 571         if((playercount == 1) && votecalledmaster) {
 572                 // if only one player is on the server becoming vote
 573                 // master is not allowed.  This could be used for
 574                 // trolling or worse. 'self' is the user who has
 575                 // called the vote because this function is called
 576                 // by SV_ParseClientCommand. Maybe all voting should
 577                 // be disabled for a single player?
 578                 sprint(self, "^1You are the only player on this server so you can not become vote master.\n");
 579                 votecaller.vote_next = 0;
 580                 VoteReset();
 581         } else if((playercount / 2) < yescount) { // vote accepted
 582                 VoteAccept();
 583         } else if((playercount / 2) < nocount) { // vote rejected
 584                 VoteReject();
 585         } else if(time > votefinished) { // vote timedout
 586                 VoteTimeout();
 587         } // else still running
 588 }
 589
 590
 591 void ReadyCount()
 592 {
 593         local entity e;
 594         local float r, p;
 595
 596         e = find(world, classname, "player");
 597
 598         while(e)
 599         {
 600                 if(clienttype(e) == CLIENTTYPE_REAL)
 601                 {
 602                         p += 1;
 603                         if(e.ready) r += 1;
 604                 }
 605                 e = find(e, classname, "player");
 606         }
 607
 608         if(p && r == p)
 609         {
 610                 bprint("^1Server is restarting...\n");
 611                 localcmd("restart\n");
 612         }
 613 }