data/qcsrc/server/cl_physics.qc

   1 .float race_penalty;
   2
   3 float sv_accelerate;
   4 float sv_friction;
   5 float sv_maxspeed;
   6 float sv_airaccelerate;
   7 float sv_maxairspeed;
   8 float sv_stopspeed;
   9 float sv_gravity;
  10 float sv_airaccel_sideways_friction;
  11 float sv_airaccel_qw;
  12 float sv_airstopaccelerate;
  13 float sv_airstrafeaccelerate;
  14 float sv_maxairstrafespeed;
  15 float sv_aircontrol;
  16 float sv_warsowbunny_airforwardaccel;
  17 float sv_warsowbunny_accel;
  18 float sv_warsowbunny_topspeed;
  19 float sv_warsowbunny_turnaccel;
  20 float sv_warsowbunny_backtosideratio;
  21
  22 .float ladder_time;
  23 .entity ladder_entity;
  24 .float gravity;
  25 .float swamp_slowdown;
  26 .float lastflags;
  27 .float lastground;
  28 .float wasFlying;
  29 .float spectatorspeed;
  30
  31 #define SHTEST_DELTA 10
  32 #define SHTEST_THRESHOLD 1.1
  33 .float shtest_next;
  34 .float shtest_accumulator;
  35 .float doublejump_nextjumptime;
  36
  37 /*
  38 =============
  39 PlayerJump
  40
  41 When you press the jump key
  42 =============
  43 */
  44 void PlayerJump (void)
  45 {
  46         float mjumpheight;
  47
  48         mjumpheight = cvar("sv_jumpvelocity");
  49         if (self.waterlevel >= WATERLEVEL_SWIMMING)
  50         {
  51                 if (self.watertype == CONTENT_WATER)
  52                         self.velocity_z = 200;
  53                 else if (self.watertype == CONTENT_SLIME)
  54                         self.velocity_z = 80;
  55                 else
  56                         self.velocity_z = 50;
  57
  58                 return;
  59         }
  60
  61         if (!(self.flags & FL_ONGROUND))
  62                 return;
  63
  64         if(!sv_pogostick)
  65                 if (!(self.flags & FL_JUMPRELEASED))
  66                         return;
  67
  68         if(self.health <= g_bloodloss)
  69                 return;
  70
  71         if(sv_doublejump)
  72                 if(time < self.doublejump_nextjumptime)
  73                         return;
  74
  75         if(g_runematch)
  76         {
  77                 if(self.runes & RUNE_SPEED)
  78                 {
  79                         if(self.runes & CURSE_SLOW)
  80                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
  81                         else
  82                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
  83                 }
  84                 else if(self.runes & CURSE_SLOW)
  85                 {
  86                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
  87                 }
  88         }
  89
  90         if(g_minstagib && (self.items & IT_INVINCIBLE))
  91         {
  92                 mjumpheight = mjumpheight * cvar("g_minstagib_speed_jumpheight");
  93         }
  94
  95         if(!(self.lastflags & FL_ONGROUND))
  96         {
  97                 if(cvar("speedmeter"))
  98                         dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
  99                 if(self.lastground < time - 0.3)
 100                         self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
 101                 if(self.jumppadcount > 1)
 102                         dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 103                 self.jumppadcount = 0;
 104         }
 105
 106         self.velocity_z = self.velocity_z + mjumpheight;
 107         self.oldvelocity_z = self.velocity_z;
 108
 109         self.flags &~= FL_ONGROUND;
 110         self.flags &~= FL_JUMPRELEASED;
 111
 112         if (self.crouch)
 113                 setanim(self, self.anim_duckjump, FALSE, TRUE, TRUE);
 114         else
 115                 setanim(self, self.anim_jump, FALSE, TRUE, TRUE);
 116
 117         if(g_jump_grunt)
 118                 PlayerSound(playersound_jump, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 119
 120         if(sv_doublejump)
 121         {
 122                 // we're moving upwards at self.velocity_z
 123                 // only allow jumping after we got 3 units upwards
 124                 // so we for sure leave the FL_ONGROUND check
 125                 //
 126                 // but as this sucks because of factoring in gravity, we'll just do it
 127                 // for 4 units, and constant velocity
 128                 self.doublejump_nextjumptime = time + 4 / max(40, self.velocity_z); // max 0.1s blocking of jumps
 129         }
 130 }
 131
 132 void CheckWaterJump()
 133 {
 134         local vector start, end;
 135
 136 // check for a jump-out-of-water
 137         makevectors (self.angles);
 138         start = self.origin;
 139         start_z = start_z + 8;
 140         v_forward_z = 0;
 141         normalize(v_forward);
 142         end = start + v_forward*24;
 143         traceline (start, end, TRUE, self);
 144         if (trace_fraction < 1)
 145         {       // solid at waist
 146                 start_z = start_z + self.maxs_z - 8;
 147                 end = start + v_forward*24;
 148                 self.movedir = trace_plane_normal * -50;
 149                 traceline (start, end, TRUE, self);
 150                 if (trace_fraction == 1)
 151                 {       // open at eye level
 152                         self.flags |= FL_WATERJUMP;
 153                         self.velocity_z = 225;
 154                         self.flags &~= FL_JUMPRELEASED;
 155                         self.teleport_time = time + 2;  // safety net
 156                         return;
 157                 }
 158         }
 159 };
 160
 161 float racecar_angle(float forward, float down)
 162 {
 163         float ret, angle_mult;
 164
 165         if(forward < 0)
 166         {
 167                 forward = -forward;
 168                 down = -down;
 169         }
 170
 171         ret = vectoyaw('0 1 0' * down + '1 0 0' * forward);
 172
 173         angle_mult = forward / (800 + forward);
 174
 175         if(ret > 180)
 176                 return ret * angle_mult + 360 * (1 - angle_mult);
 177         else
 178                 return ret * angle_mult;
 179 }
 180
 181 void RaceCarPhysics()
 182 {
 183         // using this move type for "big rigs"
 184         // the engine does not push the entity!
 185
 186         float accel, steer, f;
 187         vector angles_save, rigvel;
 188
 189         angles_save = self.angles;
 190         accel = bound(-1, self.movement_x / sv_maxspeed, 1);
 191         steer = bound(-1, self.movement_y / sv_maxspeed, 1);
 192
 193         if(g_bugrigs_reverse_speeding)
 194         {
 195                 if(accel < 0)
 196                 {
 197                         // back accel is DIGITAL
 198                         // to prevent speedhack
 199                         if(accel < -0.5)
 200                                 accel = -1;
 201                         else
 202                                 accel = 0;
 203                 }
 204         }
 205
 206         self.angles_x = 0;
 207         self.angles_z = 0;
 208         makevectors(self.angles); // new forward direction!
 209
 210         if(self.flags & FL_ONGROUND || g_bugrigs_air_steering)
 211         {
 212                 float myspeed, upspeed, steerfactor, accelfactor;
 213
 214                 myspeed = self.velocity * v_forward;
 215                 upspeed = self.velocity * v_up;
 216
 217                 // responsiveness factor for steering and acceleration
 218                 f = 1 / (1 + pow(max(-myspeed, myspeed) / g_bugrigs_speed_ref, g_bugrigs_speed_pow));
 219                 //MAXIMA: f(v) := 1 / (1 + (v / g_bugrigs_speed_ref) ^ g_bugrigs_speed_pow);
 220
 221                 if(myspeed < 0 && g_bugrigs_reverse_spinning)
 222                         steerfactor = -myspeed * g_bugrigs_steer;
 223                 else
 224                         steerfactor = -myspeed * f * g_bugrigs_steer;
 225
 226                 if(myspeed < 0 && g_bugrigs_reverse_speeding)
 227                         accelfactor = g_bugrigs_accel;
 228                 else
 229                         accelfactor = f * g_bugrigs_accel;
 230                 //MAXIMA: accel(v) := f(v) * g_bugrigs_accel;
 231
 232                 if(accel < 0)
 233                 {
 234                         if(myspeed > 0)
 235                         {
 236                                 myspeed = max(0, myspeed - frametime * (g_bugrigs_friction_floor - g_bugrigs_friction_brake * accel));
 237                         }
 238                         else
 239                         {
 240                                 if(!g_bugrigs_reverse_speeding)
 241                                         myspeed = min(0, myspeed + frametime * g_bugrigs_friction_floor);
 242                         }
 243                 }
 244                 else
 245                 {
 246                         if(myspeed >= 0)
 247                         {
 248                                 myspeed = max(0, myspeed - frametime * g_bugrigs_friction_floor);
 249                         }
 250                         else
 251                         {
 252                                 if(g_bugrigs_reverse_stopping)
 253                                         myspeed = 0;
 254                                 else
 255                                         myspeed = min(0, myspeed + frametime * (g_bugrigs_friction_floor + g_bugrigs_friction_brake * accel));
 256                         }
 257                 }
 258                 // terminal velocity = velocity at which 50 == accelfactor, that is, 1549 units/sec
 259                 //MAXIMA: friction(v) := g_bugrigs_friction_floor;
 260
 261                 self.angles_y += steer * frametime * steerfactor; // apply steering
 262                 makevectors(self.angles); // new forward direction!
 263
 264                 myspeed += accel * accelfactor * frametime;
 265
 266                 rigvel = myspeed * v_forward + '0 0 1' * upspeed;
 267         }
 268         else
 269         {
 270                 myspeed = vlen(self.velocity);
 271
 272                 // responsiveness factor for steering and acceleration
 273                 f = 1 / (1 + pow(max(0, myspeed / g_bugrigs_speed_ref), g_bugrigs_speed_pow));
 274                 steerfactor = -myspeed * f;
 275                 self.angles_y += steer * frametime * steerfactor; // apply steering
 276
 277                 rigvel = self.velocity;
 278                 makevectors(self.angles); // new forward direction!
 279         }
 280
 281         rigvel = rigvel * max(0, 1 - vlen(rigvel) * g_bugrigs_friction_air * frametime);
 282         //MAXIMA: airfriction(v) := v * v * g_bugrigs_friction_air;
 283         //MAXIMA: total_acceleration(v) := accel(v) - friction(v) - airfriction(v);
 284         //MAXIMA: solve(total_acceleration(v) = 0, v);
 285
 286         if(g_bugrigs_planar_movement)
 287         {
 288                 vector rigvel_xy, neworigin, up;
 289                 float mt;
 290
 291                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 292                 rigvel_xy = rigvel;
 293                 rigvel_xy_z = 0;
 294
 295                 if(g_bugrigs_planar_movement_car_jumping && !g_touchexplode) // touchexplode is a better way to handle collisions
 296                         mt = MOVE_NORMAL;
 297                 else
 298                         mt = MOVE_NOMONSTERS;
 299
 300                 tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 1024', mt, self);
 301                 up = trace_endpos - self.origin;
 302
 303                 // BUG RIGS: align the move to the surface instead of doing collision testing
 304                 // can we move?
 305                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos + rigvel_xy * frametime, mt, self);
 306
 307                 // align to surface
 308                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos - up + '0 0 1' * rigvel_z * frametime, mt, self);
 309
 310                 if(trace_fraction < 0.5)
 311                 {
 312                         trace_fraction = 1;
 313                         neworigin = self.origin;
 314                 }
 315                 else
 316                         neworigin = trace_endpos;
 317
 318                 if(trace_fraction < 1)
 319                 {
 320                         // now set angles_x so that the car points parallel to the surface
 321                         self.angles = vectoangles(
 322                                         '1 0 0' * v_forward_x * trace_plane_normal_z
 323                                         +
 324                                         '0 1 0' * v_forward_y * trace_plane_normal_z
 325                                         +
 326                                         '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y)
 327                                         );
 328                         self.flags |= FL_ONGROUND;
 329                 }
 330                 else
 331                 {
 332                         // now set angles_x so that the car points forward, but is tilted in velocity direction
 333                         self.flags &~= FL_ONGROUND;
 334                 }
 335
 336                 self.velocity = (neworigin - self.origin) * (1.0 / frametime);
 337                 self.movetype = MOVETYPE_NOCLIP;
 338         }
 339         else
 340         {
 341                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 342                 self.velocity = rigvel;
 343                 self.movetype = MOVETYPE_FLY;
 344         }
 345
 346         trace_fraction = 1;
 347         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 4', MOVE_NORMAL, self);
 348         if(trace_fraction != 1)
 349         {
 350                 self.angles = vectoangles2(
 351                                 '1 0 0' * v_forward_x * trace_plane_normal_z
 352                                 +
 353                                 '0 1 0' * v_forward_y * trace_plane_normal_z
 354                                 +
 355                                 '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y),
 356                                 trace_plane_normal
 357                                 );
 358         }
 359         else
 360         {
 361                 vector vel_local;
 362
 363                 vel_local_x = v_forward * self.velocity;
 364                 vel_local_y = v_right * self.velocity;
 365                 vel_local_z = v_up * self.velocity;
 366
 367                 self.angles_x = racecar_angle(vel_local_x, vel_local_z);
 368                 self.angles_z = racecar_angle(-vel_local_y, vel_local_z);
 369         }
 370
 371         // smooth the angles
 372         vector vf1, vu1, smoothangles;
 373         makevectors(self.angles);
 374         f = bound(0, frametime * g_bugrigs_angle_smoothing, 1);
 375         if(f == 0)
 376                 f = 1;
 377         vf1 = v_forward * f;
 378         vu1 = v_up * f;
 379         makevectors(angles_save);
 380         vf1 = vf1 + v_forward * (1 - f);
 381         vu1 = vu1 + v_up * (1 - f);
 382         smoothangles = vectoangles2(vf1, vu1);
 383         self.angles_x = -smoothangles_x;
 384         self.angles_z =  smoothangles_z;
 385 }
 386
 387 void CPM_PM_Aircontrol(vector wishdir, float wishspeed)
 388 {
 389         float zspeed, xyspeed, dot, k;
 390
 391         if(self.movement_x == 0 || self.movement_y != 0)
 392                 return; // can't control movement if not moving forward or backward
 393
 394         zspeed = self.velocity_z;
 395         self.velocity_z = 0;
 396         xyspeed = vlen(self.velocity);
 397         self.velocity = normalize(self.velocity);
 398
 399         dot = self.velocity * wishdir;
 400         k = 32;
 401         k *= sv_aircontrol*dot*dot*frametime;
 402
 403         if(dot > 0) // we can't change direction while slowing down
 404                 self.velocity = normalize(self.velocity * xyspeed + wishdir * k);
 405
 406         self.velocity = self.velocity * xyspeed;
 407         self.velocity_z = zspeed;
 408 }
 409
 410 void PM_Accelerate(vector wishdir, float wishspeed, float accel, float accelqw, float sidefric)
 411 {
 412         float vel_straight;
 413         float vel_z;
 414         vector vel_perpend;
 415         float addspeed;
 416
 417         vel_straight = self.velocity * wishdir;
 418         vel_z = self.velocity_z;
 419         vel_perpend = self.velocity - vel_straight * wishdir - vel_z * '0 0 1';
 420
 421         addspeed = wishspeed - vel_straight;
 422         if(addspeed > 0)
 423                 vel_straight = vel_straight + min(addspeed, accel * frametime * wishspeed) * accelqw;
 424         if(wishspeed > 0)
 425                 vel_straight = vel_straight + min(wishspeed, accel * frametime * wishspeed) * (1 - accelqw);
 426
 427         vel_perpend = vel_perpend * (1 - frametime * wishspeed * sidefric);
 428
 429         self.velocity = vel_straight * wishdir + vel_z * '0 0 1' + vel_perpend;
 430 }
 431
 432 void PM_AirAccelerate(vector wishdir, float wishspeed)
 433 {
 434         vector curvel, wishvel, acceldir, curdir;
 435         float addspeed, accelspeed, curspeed, f;
 436         float dot;
 437
 438         if(wishspeed == 0)
 439                 return;
 440
 441         curvel = self.velocity;
 442         curvel_z = 0;
 443         curspeed = vlen(curvel);
 444
 445         if(wishspeed > curspeed * 1.01)
 446         {
 447                 wishspeed = min(wishspeed, curspeed + sv_warsowbunny_airforwardaccel * sv_maxspeed * frametime);
 448         }
 449         else
 450         {
 451                 f = max(0, (sv_warsowbunny_topspeed - curspeed) / (sv_warsowbunny_topspeed - sv_maxspeed));
 452                 wishspeed = max(curspeed, sv_maxspeed) + sv_warsowbunny_accel * f * sv_maxspeed * frametime;
 453         }
 454         wishvel = wishdir * wishspeed;
 455         acceldir = wishvel - curvel;
 456         addspeed = vlen(acceldir);
 457         acceldir = normalize(acceldir);
 458
 459         accelspeed = min(addspeed, sv_warsowbunny_turnaccel * sv_maxspeed * frametime);
 460
 461         if(sv_warsowbunny_backtosideratio < 1)
 462         {
 463                 curdir = normalize(curvel);
 464                 dot = acceldir * curdir;
 465                 if(dot < 0)
 466                         acceldir = acceldir - (1 - sv_warsowbunny_backtosideratio) * dot * curdir;
 467         }
 468
 469         self.velocity += accelspeed * acceldir;
 470 }
 471
 472 .vector movement_old;
 473 .float buttons_old;
 474 .vector v_angle_old;
 475 .string lastclassname;
 476
 477 void Nixnex_GiveCurrentWeapon();
 478 .float() PlayerPhysplug;
 479
 480 string specialcommand = "xwxwxsxsxaxdxaxdx1x ";
 481 .float specialcommand_pos;
 482 void SpecialCommand()
 483 {
 484 #ifdef TETRIS
 485         TetrisImpulse();
 486 #else
 487         if(sv_cheats || self.maycheat)
 488                 self.impulse = 99;
 489         else
 490                 print("A hollow voice says \"Plugh\".\n");
 491 #endif
 492 }
 493
 494 void SV_PlayerPhysics()
 495 {
 496         local vector wishvel, wishdir, v;
 497         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod, shtest_score, buttons;
 498         string temps;
 499         float buttons_prev;
 500         float not_allowed_to_move;
 501         string c;
 502
 503         buttons = self.BUTTON_ATCK + 2 * self.BUTTON_JUMP + 4 * self.BUTTON_ATCK2 + 8 * self.BUTTON_ZOOM + 16 * self.BUTTON_CROUCH + 32 * self.BUTTON_HOOK + 64 * self.BUTTON_USE + 128 * (self.movement_x < 0) + 256 * (self.movement_x > 0) + 512 * (self.movement_y < 0) + 1024 * (self.movement_y > 0);
 504
 505         if(!buttons)
 506                 c = "x";
 507         else if(buttons == 1)
 508                 c = "1";
 509         else if(buttons == 2)
 510                 c = " ";
 511         else if(buttons == 128)
 512                 c = "s";
 513         else if(buttons == 256)
 514                 c = "w";
 515         else if(buttons == 512)
 516                 c = "a";
 517         else if(buttons == 1024)
 518                 c = "d";
 519         else
 520                 c = "?";
 521
 522         if(c == substring(specialcommand, self.specialcommand_pos, 1))
 523         {
 524                 self.specialcommand_pos += 1;
 525                 if(self.specialcommand_pos >= strlen(specialcommand))
 526                 {
 527                         self.specialcommand_pos = 0;
 528                         SpecialCommand();
 529                         return;
 530                 }
 531         }
 532         else if(self.specialcommand_pos && (c != substring(specialcommand, self.specialcommand_pos - 1, 1)))
 533                 self.specialcommand_pos = 0;
 534
 535     if(self.PlayerPhysplug)
 536         if(self.PlayerPhysplug())
 537             return;
 538
 539         if(!sv_maxidle_spectatorsareidle || self.movetype == MOVETYPE_WALK)
 540         {
 541                 if(buttons != self.buttons_old || self.movement != self.movement_old || self.v_angle != self.v_angle_old)
 542                         self.parm_idlesince = time;
 543         }
 544         buttons_prev = self.buttons_old;
 545         self.buttons_old = buttons;
 546         self.movement_old = self.movement;
 547         self.v_angle_old = self.v_angle;
 548
 549         if(time < self.nickspamtime)
 550         if(self.nickspamcount >= cvar("g_nick_flood_penalty_yellow"))
 551         {
 552                 // slight annoyance for nick change scripts
 553                 self.movement = -1 * self.movement;
 554                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = self.BUTTON_ZOOM = self.BUTTON_CROUCH = self.BUTTON_HOOK = self.BUTTON_USE = 0;
 555
 556                 if(self.nickspamcount >= cvar("g_nick_flood_penalty_red")) // if you are persistent and the slight annoyance above does not stop you, I'll show you!
 557                 {
 558                         self.angles_x = random() * 360;
 559                         self.angles_y = random() * 360;
 560                         // at least I'm not forcing retardedview by also assigning to angles_z
 561                         self.fixangle = 1;
 562                 }
 563         }
 564
 565         if(time > self.shtest_next)
 566         {
 567                 if(self.shtest_next > 0)
 568                 {
 569                         // self.shtest_accumulator:
 570                         //   started at time - SHTEST_DELTA
 571                         //   should be at SHTEST_DELTA
 572                         shtest_score = self.shtest_accumulator / (SHTEST_DELTA + time - self.shtest_next);
 573                         if(shtest_score > SHTEST_THRESHOLD)
 574                                 print("TIME PARADOX: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 575                         else if(cvar("developer_shtest"))
 576                                 dprint("okay: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 577                 }
 578                 self.shtest_next = time + SHTEST_DELTA;
 579                 self.shtest_accumulator = 0;
 580         }
 581         self.shtest_accumulator += frametime;
 582
 583         if (clienttype(self) == CLIENTTYPE_BOT)
 584                 bot_think();
 585
 586         self.items &~= IT_USING_JETPACK;
 587
 588         if(self.classname == "player")
 589         {
 590                 if(self.race_penalty)
 591                         if(time > self.race_penalty)
 592                                 self.race_penalty = 0;
 593
 594                 not_allowed_to_move = 0;
 595                 if(self.race_penalty)
 596                         not_allowed_to_move = 1;
 597                 if(!cvar("sv_ready_restart_after_countdown"))
 598                 if(time < game_starttime)
 599                         not_allowed_to_move = 1;
 600
 601                 if(not_allowed_to_move)
 602                 {
 603                         self.velocity = '0 0 0';
 604                         self.movetype = MOVETYPE_NONE;
 605                         self.disableclientprediction = 2;
 606                 }
 607                 else if(self.disableclientprediction == 2)
 608                 {
 609                         if(self.movetype == MOVETYPE_NONE)
 610                                 self.movetype = MOVETYPE_WALK;
 611                         self.disableclientprediction = 0;
 612                 }
 613         }
 614
 615         if (self.movetype == MOVETYPE_NONE)
 616                 return;
 617
 618         if (self.punchangle != '0 0 0')
 619         {
 620                 f = vlen(self.punchangle) - 10 * frametime;
 621                 if (f > 0)
 622                         self.punchangle = normalize(self.punchangle) * f;
 623                 else
 624                         self.punchangle = '0 0 0';
 625         }
 626
 627         if (self.punchvector != '0 0 0')
 628         {
 629                 f = vlen(self.punchvector) - 30 * frametime;
 630                 if (f > 0)
 631                         self.punchvector = normalize(self.punchvector) * f;
 632                 else
 633                         self.punchvector = '0 0 0';
 634         }
 635
 636         maxspd_mod = 1;
 637
 638         if(g_runematch)
 639         {
 640                 if(self.runes & RUNE_SPEED)
 641                 {
 642                         if(self.runes & CURSE_SLOW)
 643                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_combo_moverate");
 644                         else
 645                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_moverate");
 646                 }
 647                 else if(self.runes & CURSE_SLOW)
 648                 {
 649                         maxspd_mod = maxspd_mod * cvar("g_balance_curse_slow_moverate");
 650                 }
 651         }
 652
 653         if(g_minstagib && (self.items & IT_INVINCIBLE))
 654         {
 655                 maxspd_mod = cvar("g_minstagib_speed_moverate");
 656         }
 657
 658         if(g_nexball && self.ballcarried)
 659         {
 660                 maxspd_mod = cvar("g_nexball_basketball_carrier_speed");
 661         }
 662
 663         swampspd_mod = 1;
 664         if(self.in_swamp) {
 665                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 666         }
 667
 668         if(self.classname != "player")
 669         {
 670                 maxspd_mod = cvar("sv_spectator_speed_multiplier");
 671                 if(!self.spectatorspeed)
 672                         self.spectatorspeed = maxspd_mod;
 673                 if(self.impulse && self.impulse <= 19)
 674                 {
 675                         if(self.lastclassname != "player")
 676                         {
 677                                 if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 678                                         self.spectatorspeed = bound(1, self.spectatorspeed + 0.5, 5);
 679                                 else if(self.impulse == 11)
 680                                         self.spectatorspeed = maxspd_mod;
 681                                 else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19)
 682                                         self.spectatorspeed = bound(1, self.spectatorspeed - 0.5, 5);
 683                                 else if(self.impulse >= 1 && self.impulse <= 9)
 684                                         self.spectatorspeed = 1 + 0.5 * (self.impulse - 1);
 685                         } // otherwise just clear
 686                         self.impulse = 0;
 687                 }
 688                 maxspd_mod = self.spectatorspeed;
 689         }
 690
 691         spd = max(sv_maxspeed, sv_maxairspeed) * maxspd_mod * swampspd_mod;
 692         if(self.speed != spd)
 693         {
 694                 self.speed = spd;
 695                 temps = ftos(spd);
 696                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 697                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 698                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 699                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 700         }
 701
 702         maxspd_mod *= swampspd_mod; // only one common speed modder please!
 703         swampspd_mod = 1;
 704
 705         // if dead, behave differently
 706         if (self.deadflag)
 707                 goto end;
 708
 709         if (!self.fixangle && !g_bugrigs)
 710         {
 711                 self.angles_x = 0;
 712                 self.angles_y = self.v_angle_y;
 713                 self.angles_z = 0;
 714         }
 715
 716         if(self.flags & FL_ONGROUND)
 717         if(self.wasFlying)
 718         {
 719                 self.wasFlying = 0;
 720
 721                 if(self.waterlevel < WATERLEVEL_SWIMMING)
 722                 if(time >= self.ladder_time)
 723                 if not(self.hook)
 724                 {
 725                         self.nextstep = time + 0.3 + random() * 0.1;
 726                         trace_dphitq3surfaceflags = 0;
 727                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 728                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
 729                         {
 730                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 731                                         GlobalSound(globalsound_metalfall, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 732                                 else
 733                                         GlobalSound(globalsound_fall, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 734                         }
 735                 }
 736         }
 737
 738         if(IsFlying(self))
 739                 self.wasFlying = 1;
 740
 741         if(self.classname == "player")
 742         {
 743                 if(sv_doublejump)
 744                 {
 745                         self.flags &~= FL_ONGROUND;
 746                         tracebox(self.origin + '0 0 1', self.mins, self.maxs, self.origin - '0 0 1', MOVE_NORMAL, self);
 747                         if(trace_fraction < 1 && trace_plane_normal_z > 0.7)
 748                                 self.flags |= FL_ONGROUND;
 749                 }
 750
 751                 if (self.BUTTON_JUMP)
 752                         PlayerJump ();
 753                 else
 754                         self.flags |= FL_JUMPRELEASED;
 755
 756                 if (self.waterlevel == WATERLEVEL_SWIMMING)
 757                         CheckWaterJump ();
 758         }
 759
 760         if (self.flags & FL_WATERJUMP )
 761         {
 762                 self.velocity_x = self.movedir_x;
 763                 self.velocity_y = self.movedir_y;
 764                 if (time > self.teleport_time || self.waterlevel == WATERLEVEL_NONE)
 765                 {
 766                         self.flags &~= FL_WATERJUMP;
 767                         self.teleport_time = 0;
 768                 }
 769         }
 770         else if (g_bugrigs && self.classname == "player")
 771         {
 772                 RaceCarPhysics();
 773         }
 774         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
 775         {
 776                 // noclipping or flying
 777                 self.flags &~= FL_ONGROUND;
 778
 779                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 780                 makevectors(self.v_angle);
 781                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 782                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 783                 // acceleration
 784                 wishdir = normalize(wishvel);
 785                 wishspeed = vlen(wishvel);
 786                 if (wishspeed > sv_maxspeed*maxspd_mod)
 787                         wishspeed = sv_maxspeed*maxspd_mod;
 788                 if (time >= self.teleport_time)
 789                         PM_Accelerate(wishdir, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
 790         }
 791         else if (self.waterlevel >= WATERLEVEL_SWIMMING)
 792         {
 793                 // swimming
 794                 self.flags &~= FL_ONGROUND;
 795
 796                 makevectors(self.v_angle);
 797                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 798                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 799                 if (wishvel == '0 0 0')
 800                         wishvel = '0 0 -60'; // drift towards bottom
 801
 802                 wishdir = normalize(wishvel);
 803                 wishspeed = vlen(wishvel);
 804                 if (wishspeed > sv_maxspeed*maxspd_mod)
 805                         wishspeed = sv_maxspeed*maxspd_mod;
 806                 wishspeed = wishspeed * 0.7;
 807
 808                 // water friction
 809                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 810
 811                 // water acceleration
 812                 PM_Accelerate(wishdir, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
 813         }
 814         else if (time < self.ladder_time)
 815         {
 816                 // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
 817                 self.flags &~= FL_ONGROUND;
 818
 819                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 820                 makevectors(self.v_angle);
 821                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 822                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 823                 if (self.gravity)
 824                         self.velocity_z = self.velocity_z + self.gravity * sv_gravity * frametime;
 825                 else
 826                         self.velocity_z = self.velocity_z + sv_gravity * frametime;
 827                 if (self.ladder_entity.classname == "func_water")
 828                 {
 829                         f = vlen(wishvel);
 830                         if (f > self.ladder_entity.speed)
 831                                 wishvel = wishvel * (self.ladder_entity.speed / f);
 832
 833                         self.watertype = self.ladder_entity.skin;
 834                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
 835                         if ((self.origin_z + self.view_ofs_z) < f)
 836                                 self.waterlevel = WATERLEVEL_SUBMERGED;
 837                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
 838                                 self.waterlevel = WATERLEVEL_SWIMMING;
 839                         else if ((self.origin_z + self.mins_z + 1) < f)
 840                                 self.waterlevel = WATERLEVEL_WETFEET;
 841                         else
 842                         {
 843                                 self.waterlevel = WATERLEVEL_NONE;
 844                                 self.watertype = CONTENT_EMPTY;
 845                         }
 846                 }
 847                 // acceleration
 848                 wishdir = normalize(wishvel);
 849                 wishspeed = vlen(wishvel);
 850                 if (wishspeed > sv_maxspeed*maxspd_mod)
 851                         wishspeed = sv_maxspeed*maxspd_mod;
 852                 if (time >= self.teleport_time)
 853                 {
 854                         // water acceleration
 855                         PM_Accelerate(wishdir, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
 856                 }
 857         }
 858         else if ((self.items & IT_JETPACK) && self.BUTTON_HOOK && (!cvar("g_jetpack_fuel") || self.ammo_fuel >= 0.01 || self.items & IT_UNLIMITED_WEAPON_AMMO))
 859         {
 860                 //makevectors(self.v_angle_y * '0 1 0');
 861                 makevectors(self.v_angle);
 862                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 863                 // add remaining speed as Z component
 864                 maxairspd = sv_maxairspeed*max(1, maxspd_mod);
 865                 // fix speedhacks :P
 866                 wishvel = normalize(wishvel) * min(vlen(wishvel) / maxairspd, 1);
 867                 // add the unused velocity as up component
 868                 wishvel_z = 0;
 869
 870                 // if(self.BUTTON_JUMP)
 871                         wishvel_z = sqrt(max(0, 1 - wishvel * wishvel));
 872
 873                 // it is now normalized, so...
 874                 float a_side, a_up, a_add, a_diff;
 875                 a_side = cvar("g_jetpack_acceleration_side");
 876                 a_up = cvar("g_jetpack_acceleration_up");
 877                 a_add = cvar("g_jetpack_antigravity") * sv_gravity;
 878
 879                 wishvel_x *= a_side;
 880                 wishvel_y *= a_side;
 881                 wishvel_z *= a_up;
 882                 wishvel_z += a_add;
 883
 884                 float best;
 885                 best = 0;
 886                 //////////////////////////////////////////////////////////////////////////////////////
 887                 // finding the maximum over all vectors of above form
 888                 // with wishvel having an absolute value of 1
 889                 //////////////////////////////////////////////////////////////////////////////////////
 890                 // we're finding the maximum over
 891                 //   f(a_side, a_up, a_add, z) := a_side * (1 - z^2) + (a_add + a_up * z)^2;
 892                 // for z in the range from -1 to 1
 893                 //////////////////////////////////////////////////////////////////////////////////////
 894                 // maximum is EITHER attained at the single extreme point:
 895                 a_diff = a_side * a_side - a_up * a_up;
 896                 if(a_diff != 0)
 897                 {
 898                         f = a_add * a_up / a_diff; // this is the zero of diff(f(a_side, a_up, a_add, z), z)
 899                         if(f > -1 && f < 1) // can it be attained?
 900                         {
 901                                 best = (a_diff + a_add * a_add) * (a_diff + a_up * a_up) / a_diff;
 902                                 //print("middle\n");
 903                         }
 904                 }
 905                 // OR attained at z = 1:
 906                 f = (a_up + a_add) * (a_up + a_add);
 907                 if(f > best)
 908                 {
 909                         best = f;
 910                         //print("top\n");
 911                 }
 912                 // OR attained at z = -1:
 913                 f = (a_up - a_add) * (a_up - a_add);
 914                 if(f > best)
 915                 {
 916                         best = f;
 917                         //print("bottom\n");
 918                 }
 919                 best = sqrt(best);
 920                 //////////////////////////////////////////////////////////////////////////////////////
 921
 922                 //print("best possible acceleration: ", ftos(best), "\n");
 923
 924                 float fxy, fz;
 925                 fxy = bound(0, 1 - (self.velocity * normalize(wishvel_x * '1 0 0' + wishvel_y * '0 1 0')) / cvar("g_jetpack_maxspeed_side"), 1);
 926                 if(wishvel_z - sv_gravity > 0)
 927                         fz = bound(0, 1 - self.velocity_z / cvar("g_jetpack_maxspeed_up"), 1);
 928                 else
 929                         fz = bound(0, 1 + self.velocity_z / cvar("g_jetpack_maxspeed_up"), 1);
 930
 931                 float fvel;
 932                 fvel = vlen(wishvel);
 933                 wishvel_x *= fxy;
 934                 wishvel_y *= fxy;
 935                 wishvel_z = (wishvel_z - sv_gravity) * fz + sv_gravity;
 936
 937                 fvel = min(1, vlen(wishvel) / best);
 938                 if(cvar("g_jetpack_fuel") && !(self.items & IT_UNLIMITED_WEAPON_AMMO))
 939                         f = min(1, self.ammo_fuel / (cvar("g_jetpack_fuel") * frametime * fvel));
 940                 else
 941                         f = 1;
 942
 943                 //print("this acceleration: ", ftos(vlen(wishvel) * f), "\n");
 944
 945                 if (f > 0 && wishvel != '0 0 0')
 946                 {
 947                         self.velocity = self.velocity + wishvel * f * frametime;
 948                         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 949                                 self.ammo_fuel -= cvar("g_jetpack_fuel") * frametime * fvel * f;
 950                         self.flags &~= FL_ONGROUND;
 951                         self.items |= IT_USING_JETPACK;
 952
 953                         // jetpack also inhibits health regeneration, but only for 1 second
 954                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_fuel_regen"));
 955                 }
 956         }
 957         else if (self.flags & FL_ONGROUND)
 958         {
 959                 // we get here if we ran out of ammo
 960                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32))
 961                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
 962
 963                 // walking
 964                 makevectors(self.v_angle_y * '0 1 0');
 965                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 966
 967                 if(!(self.lastflags & FL_ONGROUND))
 968                 {
 969                         if(cvar("speedmeter"))
 970                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
 971                         if(self.lastground < time - 0.3)
 972                                 self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
 973                         if(self.jumppadcount > 1)
 974                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 975                         self.jumppadcount = 0;
 976                 }
 977
 978 #ifdef LETS_TEST_FTEQCC
 979                 if(self.velocity_x || self.velocity_y)
 980                 {
 981                         // good
 982                 }
 983                 else
 984                 {
 985                         if(self.velocity_x)
 986                                 checkclient();
 987                         if(self.velocity_y)
 988                                 checkclient();
 989                 }
 990 #endif
 991
 992                 v = self.velocity;
 993                 v_z = 0;
 994                 f = vlen(v);
 995                 if(f > 0)
 996                 {
 997                         if (f < sv_stopspeed)
 998                                 f = 1 - frametime * (sv_stopspeed / f) * sv_friction;
 999                         else
1000                                 f = 1 - frametime * sv_friction;
1001                         if (f > 0)
1002                                 self.velocity = self.velocity * f;
1003                         else
1004                                 self.velocity = '0 0 0';
1005                 }
1006
1007                 // acceleration
1008                 wishdir = normalize(wishvel);
1009                 wishspeed = vlen(wishvel);
1010                 if (wishspeed > sv_maxspeed*maxspd_mod)
1011                         wishspeed = sv_maxspeed*maxspd_mod;
1012                 if (self.crouch)
1013                         wishspeed = wishspeed * 0.5;
1014                 if (time >= self.teleport_time)
1015                         PM_Accelerate(wishdir, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
1016         }
1017         else
1018         {
1019                 // we get here if we ran out of ammo
1020                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32))
1021                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
1022
1023                 if(maxspd_mod < 1)
1024                 {
1025                         maxairspd = sv_maxairspeed*maxspd_mod;
1026                         airaccel = sv_airaccelerate*maxspd_mod;
1027                 }
1028                 else
1029                 {
1030                         maxairspd = sv_maxairspeed;
1031                         airaccel = sv_airaccelerate;
1032                 }
1033                 // airborn
1034                 makevectors(self.v_angle_y * '0 1 0');
1035                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1036                 // acceleration
1037                 wishdir = normalize(wishvel);
1038                 wishspeed = vlen(wishvel);
1039                 if (wishspeed > maxairspd)
1040                         wishspeed = maxairspd;
1041                 if (self.crouch)
1042                         wishspeed = wishspeed * 0.5;
1043                 if (time >= self.teleport_time)
1044                 {
1045                         float accelerating;
1046                         float wishspeed2;
1047                         float airaccelqw;
1048
1049                         airaccelqw = sv_airaccel_qw;
1050                         accelerating = (self.velocity * wishdir > 0);
1051                         wishspeed2 = wishspeed;
1052
1053                         // CPM
1054                         if(sv_airstopaccelerate)
1055                                 if(self.velocity * wishdir < 0)
1056                                         airaccel = sv_airstopaccelerate*maxspd_mod;
1057                         if(self.movement_x == 0 && self.movement_y != 0)
1058                         {
1059                                 if(sv_maxairstrafespeed)
1060                                 {
1061                                         wishspeed = min(wishspeed, sv_maxairstrafespeed*maxspd_mod);
1062                                         if(sv_maxairstrafespeed < sv_maxairspeed)
1063                                                 airaccelqw = 1;
1064                                 }
1065                                 if(sv_airstrafeaccelerate)
1066                                 {
1067                                         airaccel = sv_airstrafeaccelerate*maxspd_mod;
1068                                         if(sv_airstrafeaccelerate > sv_airaccelerate)
1069                                                 airaccelqw = 1;
1070                                 }
1071                         }
1072                         // !CPM
1073
1074                         if(sv_warsowbunny_turnaccel && accelerating && self.movement_y == 0 && self.movement_x != 0)
1075                                 PM_AirAccelerate(wishdir, wishspeed);
1076                         else
1077                                 PM_Accelerate(wishdir, wishspeed, airaccel, airaccelqw, sv_airaccel_sideways_friction / maxairspd);
1078
1079                         if(sv_aircontrol)
1080                                 CPM_PM_Aircontrol(wishdir, wishspeed2);
1081                 }
1082         }
1083
1084 :end
1085         if(self.flags & FL_ONGROUND)
1086                 self.lastground = time;
1087
1088         self.lastflags = self.flags;
1089         self.lastclassname = self.classname;
1090 };