data/qcsrc/server/cl_physics.qc

   1 float sv_accelerate;
   2 float sv_friction;
   3 float sv_maxspeed;
   4 float sv_airaccelerate;
   5 float sv_maxairspeed;
   6 float sv_stopspeed;
   7 float sv_gravity;
   8 float sv_airaccel_sideways_friction;
   9 float sv_airaccel_qw;
  10 .float ladder_time;
  11 .entity ladder_entity;
  12 .float gravity;
  13 .float swamp_slowdown;
  14 .float lastflags;
  15 .float lastground;
  16 .float wasFlying;
  17 .float spectatorspeed;
  18
  19 #define SHTEST_DELTA 10
  20 #define SHTEST_THRESHOLD 1.1
  21 .float shtest_next;
  22 .float shtest_accumulator;
  23
  24 /*
  25 =============
  26 PlayerJump
  27
  28 When you press the jump key
  29 =============
  30 */
  31 void PlayerJump (void)
  32 {
  33         float mjumpheight;
  34
  35         mjumpheight = cvar("sv_jumpvelocity");
  36         if (self.waterlevel >= WATERLEVEL_SWIMMING)
  37         {
  38                 if (self.watertype == CONTENT_WATER)
  39                         self.velocity_z = 200;
  40                 else if (self.watertype == CONTENT_SLIME)
  41                         self.velocity_z = 80;
  42                 else
  43                         self.velocity_z = 50;
  44
  45                 return;
  46         }
  47
  48
  49         if (!(self.flags & FL_ONGROUND))
  50                 return;
  51
  52         if(!sv_pogostick)
  53                 if (!(self.flags & FL_JUMPRELEASED))
  54                         return;
  55
  56         if(self.health <= g_bloodloss)
  57                 return;
  58
  59         if(g_runematch)
  60         {
  61                 if(self.runes & RUNE_SPEED)
  62                 {
  63                         if(self.runes & CURSE_SLOW)
  64                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
  65                         else
  66                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
  67                 }
  68                 else if(self.runes & CURSE_SLOW)
  69                 {
  70                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
  71                 }
  72         }
  73
  74         if(g_minstagib && (self.items & IT_INVINCIBLE))
  75         {
  76                 mjumpheight = mjumpheight * cvar("g_minstagib_speed_jumpheight");
  77         }
  78
  79         self.velocity_z = self.velocity_z + mjumpheight;
  80         self.oldvelocity_z = self.velocity_z;
  81
  82         self.flags &~= FL_ONGROUND;
  83         self.flags &~= FL_JUMPRELEASED;
  84
  85         if (self.crouch)
  86                 setanim(self, self.anim_duckjump, FALSE, TRUE, TRUE);
  87         else
  88                 setanim(self, self.anim_jump, FALSE, TRUE, TRUE);
  89
  90         if(g_jump_grunt)
  91                 PlayerSound(playersound_jump, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
  92 }
  93
  94 void CheckWaterJump()
  95 {
  96         local vector start, end;
  97
  98 // check for a jump-out-of-water
  99         makevectors (self.angles);
 100         start = self.origin;
 101         start_z = start_z + 8;
 102         v_forward_z = 0;
 103         normalize(v_forward);
 104         end = start + v_forward*24;
 105         traceline (start, end, TRUE, self);
 106         if (trace_fraction < 1)
 107         {       // solid at waist
 108                 start_z = start_z + self.maxs_z - 8;
 109                 end = start + v_forward*24;
 110                 self.movedir = trace_plane_normal * -50;
 111                 traceline (start, end, TRUE, self);
 112                 if (trace_fraction == 1)
 113                 {       // open at eye level
 114                         self.flags |= FL_WATERJUMP;
 115                         self.velocity_z = 225;
 116                         self.flags &~= FL_JUMPRELEASED;
 117                         self.teleport_time = time + 2;  // safety net
 118                         return;
 119                 }
 120         }
 121 };
 122
 123 float racecar_angle(float forward, float down)
 124 {
 125         float ret, angle_mult;
 126
 127         if(forward < 0)
 128         {
 129                 forward = -forward;
 130                 down = -down;
 131         }
 132
 133         ret = vectoyaw('0 1 0' * down + '1 0 0' * forward);
 134
 135         angle_mult = forward / (800 + forward);
 136
 137         if(ret > 180)
 138                 return ret * angle_mult + 360 * (1 - angle_mult);
 139         else
 140                 return ret * angle_mult;
 141 }
 142
 143 void RaceCarPhysics()
 144 {
 145         // using this move type for "big rigs"
 146         // the engine does not push the entity!
 147
 148         float accel, steer, f;
 149         vector angles_save, rigvel;
 150
 151         angles_save = self.angles;
 152         accel = bound(-1, self.movement_x / sv_maxspeed, 1);
 153         steer = bound(-1, self.movement_y / sv_maxspeed, 1);
 154
 155         if(g_bugrigs_reverse_speeding)
 156         {
 157                 if(accel < 0)
 158                 {
 159                         // back accel is DIGITAL
 160                         // to prevent speedhack
 161                         if(accel < -0.5)
 162                                 accel = -1;
 163                         else
 164                                 accel = 0;
 165                 }
 166         }
 167
 168         self.angles_x = 0;
 169         self.angles_z = 0;
 170         makevectors(self.angles); // new forward direction!
 171
 172         if(self.flags & FL_ONGROUND || g_bugrigs_air_steering)
 173         {
 174                 float myspeed, upspeed, steerfactor, accelfactor;
 175
 176                 myspeed = self.velocity * v_forward;
 177                 upspeed = self.velocity * v_up;
 178
 179                 // responsiveness factor for steering and acceleration
 180                 f = 1 / (1 + pow(max(-myspeed, myspeed) / g_bugrigs_speed_ref, g_bugrigs_speed_pow));
 181                 //MAXIMA: f(v) := 1 / (1 + (v / g_bugrigs_speed_ref) ^ g_bugrigs_speed_pow);
 182
 183                 if(myspeed < 0 && g_bugrigs_reverse_spinning)
 184                         steerfactor = -myspeed * g_bugrigs_steer;
 185                 else
 186                         steerfactor = -myspeed * f * g_bugrigs_steer;
 187
 188                 if(myspeed < 0 && g_bugrigs_reverse_speeding)
 189                         accelfactor = g_bugrigs_accel;
 190                 else
 191                         accelfactor = f * g_bugrigs_accel;
 192                 //MAXIMA: accel(v) := f(v) * g_bugrigs_accel;
 193
 194                 if(accel < 0)
 195                 {
 196                         if(myspeed > 0)
 197                         {
 198                                 myspeed = max(0, myspeed - frametime * (g_bugrigs_friction_floor - g_bugrigs_friction_brake * accel));
 199                         }
 200                         else
 201                         {
 202                                 if(!g_bugrigs_reverse_speeding)
 203                                         myspeed = min(0, myspeed + frametime * g_bugrigs_friction_floor);
 204                         }
 205                 }
 206                 else
 207                 {
 208                         if(myspeed >= 0)
 209                         {
 210                                 myspeed = max(0, myspeed - frametime * g_bugrigs_friction_floor);
 211                         }
 212                         else
 213                         {
 214                                 if(g_bugrigs_reverse_stopping)
 215                                         myspeed = 0;
 216                                 else
 217                                         myspeed = min(0, myspeed + frametime * (g_bugrigs_friction_floor + g_bugrigs_friction_brake * accel));
 218                         }
 219                 }
 220                 // terminal velocity = velocity at which 50 == accelfactor, that is, 1549 units/sec
 221                 //MAXIMA: friction(v) := g_bugrigs_friction_floor;
 222
 223                 self.angles_y += steer * frametime * steerfactor; // apply steering
 224                 makevectors(self.angles); // new forward direction!
 225
 226                 myspeed += accel * accelfactor * frametime;
 227
 228                 rigvel = myspeed * v_forward + '0 0 1' * upspeed;
 229         }
 230         else
 231         {
 232                 myspeed = vlen(self.velocity);
 233
 234                 // responsiveness factor for steering and acceleration
 235                 f = 1 / (1 + pow(max(0, myspeed / g_bugrigs_speed_ref), g_bugrigs_speed_pow));
 236                 steerfactor = -myspeed * f;
 237                 self.angles_y += steer * frametime * steerfactor; // apply steering
 238
 239                 rigvel = self.velocity;
 240                 makevectors(self.angles); // new forward direction!
 241         }
 242
 243         rigvel = rigvel * max(0, 1 - vlen(rigvel) * g_bugrigs_friction_air * frametime);
 244         //MAXIMA: airfriction(v) := v * v * g_bugrigs_friction_air;
 245         //MAXIMA: total_acceleration(v) := accel(v) - friction(v) - airfriction(v);
 246         //MAXIMA: solve(total_acceleration(v) = 0, v);
 247
 248         if(g_bugrigs_planar_movement)
 249         {
 250                 vector rigvel_xy, neworigin, up;
 251                 float mt;
 252
 253                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 254                 rigvel_xy = rigvel;
 255                 rigvel_xy_z = 0;
 256
 257                 if(g_bugrigs_planar_movement_car_jumping && !g_touchexplode) // touchexplode is a better way to handle collisions
 258                         mt = MOVE_NORMAL;
 259                 else
 260                         mt = MOVE_NOMONSTERS;
 261
 262                 tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 1024', mt, self);
 263                 up = trace_endpos - self.origin;
 264
 265                 // BUG RIGS: align the move to the surface instead of doing collision testing
 266                 // can we move?
 267                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos + rigvel_xy * frametime, mt, self);
 268
 269                 // align to surface
 270                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos - up + '0 0 1' * rigvel_z * frametime, mt, self);
 271
 272                 if(trace_fraction < 0.5)
 273                 {
 274                         trace_fraction = 1;
 275                         neworigin = self.origin;
 276                 }
 277                 else
 278                         neworigin = trace_endpos;
 279
 280                 if(trace_fraction < 1)
 281                 {
 282                         // now set angles_x so that the car points parallel to the surface
 283                         self.angles = vectoangles(
 284                                         '1 0 0' * v_forward_x * trace_plane_normal_z
 285                                         +
 286                                         '0 1 0' * v_forward_y * trace_plane_normal_z
 287                                         +
 288                                         '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y)
 289                                         );
 290                         self.flags |= FL_ONGROUND;
 291                 }
 292                 else
 293                 {
 294                         // now set angles_x so that the car points forward, but is tilted in velocity direction
 295                         self.flags &~= FL_ONGROUND;
 296                 }
 297
 298                 self.velocity = (neworigin - self.origin) * (1.0 / frametime);
 299                 self.movetype = MOVETYPE_NOCLIP;
 300         }
 301         else
 302         {
 303                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 304                 self.velocity = rigvel;
 305                 self.movetype = MOVETYPE_FLY;
 306         }
 307
 308         trace_fraction = 1;
 309         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 4', MOVE_NORMAL, self);
 310         if(trace_fraction != 1)
 311         {
 312                 self.angles = vectoangles2(
 313                                 '1 0 0' * v_forward_x * trace_plane_normal_z
 314                                 +
 315                                 '0 1 0' * v_forward_y * trace_plane_normal_z
 316                                 +
 317                                 '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y),
 318                                 trace_plane_normal
 319                                 );
 320         }
 321         else
 322         {
 323                 vector vel_local;
 324
 325                 vel_local_x = v_forward * self.velocity;
 326                 vel_local_y = v_right * self.velocity;
 327                 vel_local_z = v_up * self.velocity;
 328
 329                 self.angles_x = racecar_angle(vel_local_x, vel_local_z);
 330                 self.angles_z = racecar_angle(-vel_local_y, vel_local_z);
 331         }
 332
 333         // smooth the angles
 334         vector vf1, vu1, smoothangles;
 335         makevectors(self.angles);
 336         f = bound(0, frametime * g_bugrigs_angle_smoothing, 1);
 337         if(f == 0)
 338                 f = 1;
 339         vf1 = v_forward * f;
 340         vu1 = v_up * f;
 341         makevectors(angles_save);
 342         vf1 = vf1 + v_forward * (1 - f);
 343         vu1 = vu1 + v_up * (1 - f);
 344         smoothangles = vectoangles2(vf1, vu1);
 345         self.angles_x = -smoothangles_x;
 346         self.angles_z =  smoothangles_z;
 347 }
 348
 349 .vector movement_old;
 350 .float buttons_old;
 351 .vector v_angle_old;
 352 .string lastclassname;
 353
 354 void Nixnex_GiveCurrentWeapon();
 355 void SV_PlayerPhysics()
 356 {
 357         local vector wishvel, wishdir, v;
 358         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod, shtest_score, buttons;
 359         string temps;
 360         float buttons_prev;
 361
 362         buttons = self.BUTTON_ATCK + 2 * self.BUTTON_JUMP + 4 * self.BUTTON_ATCK2 + 8 * self.BUTTON_ZOOM + 16 * self.BUTTON_CROUCH + 32 * self.BUTTON_HOOK + 64 * self.BUTTON_USE;
 363         if(!sv_maxidle_spectatorsareidle || self.movetype == MOVETYPE_WALK)
 364         {
 365                 if(buttons != self.buttons_old || self.movement != self.movement_old || self.v_angle != self.v_angle_old)
 366                         self.parm_idlesince = time;
 367         }
 368         buttons_prev = self.buttons_old;
 369         self.buttons_old = buttons;
 370         self.movement_old = self.movement;
 371         self.v_angle_old = self.v_angle;
 372
 373         if(time > self.shtest_next)
 374         {
 375                 if(self.shtest_next > 0)
 376                 {
 377                         // self.shtest_accumulator:
 378                         //   started at time - SHTEST_DELTA
 379                         //   should be at SHTEST_DELTA
 380                         shtest_score = self.shtest_accumulator / (SHTEST_DELTA + time - self.shtest_next);
 381                         if(shtest_score > SHTEST_THRESHOLD)
 382                                 print("TIME PARADOX: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 383                         else if(cvar("developer_shtest"))
 384                                 dprint("okay: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 385                 }
 386                 self.shtest_next = time + SHTEST_DELTA;
 387                 self.shtest_accumulator = 0;
 388         }
 389         self.shtest_accumulator += frametime;
 390
 391         if (clienttype(self) == CLIENTTYPE_BOT)
 392                 bot_think();
 393
 394         self.items &~= IT_USING_JETPACK;
 395
 396         if (self.movetype == MOVETYPE_NONE && self.disableclientprediction != 2)
 397                 return;
 398
 399         if (self.punchangle != '0 0 0')
 400         {
 401                 f = vlen(self.punchangle) - 10 * frametime;
 402                 if (f > 0)
 403                         self.punchangle = normalize(self.punchangle) * f;
 404                 else
 405                         self.punchangle = '0 0 0';
 406         }
 407
 408         if (self.punchvector != '0 0 0')
 409         {
 410                 f = vlen(self.punchvector) - 30 * frametime;
 411                 if (f > 0)
 412                         self.punchvector = normalize(self.punchvector) * f;
 413                 else
 414                         self.punchvector = '0 0 0';
 415         }
 416
 417         maxspd_mod = 1;
 418
 419         if(g_runematch)
 420         {
 421                 if(self.runes & RUNE_SPEED)
 422                 {
 423                         if(self.runes & CURSE_SLOW)
 424                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_combo_moverate");
 425                         else
 426                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_moverate");
 427                 }
 428                 else if(self.runes & CURSE_SLOW)
 429                 {
 430                         maxspd_mod = maxspd_mod * cvar("g_balance_curse_slow_moverate");
 431                 }
 432         }
 433
 434         if(g_minstagib && (self.items & IT_INVINCIBLE))
 435         {
 436                 maxspd_mod = cvar("g_minstagib_speed_moverate");
 437         }
 438
 439         swampspd_mod = 1;
 440         if(self.in_swamp) {
 441                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 442         }
 443
 444         if(self.classname != "player")
 445         {
 446                 maxspd_mod = cvar("sv_spectator_speed_multiplier");
 447                 if(!self.spectatorspeed)
 448                         self.spectatorspeed = maxspd_mod;
 449                 if(self.impulse && self.impulse <= 19)
 450                 {
 451                         if(self.lastclassname != "player")
 452                         {
 453                                 if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 454                                         self.spectatorspeed = bound(1, self.spectatorspeed + 0.5, 5);
 455                                 else if(self.impulse == 11)
 456                                         self.spectatorspeed = maxspd_mod;
 457                                 else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19)
 458                                         self.spectatorspeed = bound(1, self.spectatorspeed - 0.5, 5);
 459                                 else if(self.impulse >= 1 && self.impulse <= 9)
 460                                         self.spectatorspeed = 1 + 0.5 * (self.impulse - 1);
 461                         } // otherwise just clear
 462                         self.impulse = 0;
 463                 }
 464                 maxspd_mod = self.spectatorspeed;
 465         }
 466
 467         spd = sv_maxspeed * maxspd_mod * swampspd_mod;
 468
 469         if(self.speed != spd)
 470         {
 471                 self.speed = spd;
 472                 temps = ftos(spd);
 473                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 474                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 475                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 476                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 477
 478                 temps = ftos(sv_accelerate * maxspd_mod);
 479                 stuffcmd(self, strcat("cl_movement_accelerate ", temps, "\n"));
 480         }
 481
 482         // if dead, behave differently
 483         if (self.deadflag)
 484                 goto end;
 485
 486         if (!self.fixangle && !g_bugrigs)
 487         {
 488                 self.angles_x = 0;
 489                 self.angles_y = self.v_angle_y;
 490                 self.angles_z = 0;
 491         }
 492
 493         if(self.flags & FL_ONGROUND)
 494         if(self.wasFlying)
 495         {
 496                 self.wasFlying = 0;
 497
 498                 if(self.waterlevel < WATERLEVEL_SWIMMING)
 499                 if(time >= self.ladder_time)
 500                 if not(self.hook)
 501                 {
 502                         self.nextstep = time + 0.3 + random() * 0.1;
 503                         trace_dphitq3surfaceflags = 0;
 504                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 505                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
 506                         {
 507                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 508                                         GlobalSound(globalsound_metalfall, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 509                                 else
 510                                         GlobalSound(globalsound_fall, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 511                         }
 512                 }
 513         }
 514
 515         if(IsFlying(self))
 516                 self.wasFlying = 1;
 517
 518         if(self.classname == "player")
 519         {
 520                 if(sv_doublejump)
 521                 {
 522                         self.flags &~= FL_ONGROUND;
 523                         tracebox(self.origin + '0 0 1', self.mins, self.maxs, self.origin - '0 0 2', MOVE_NORMAL, self);
 524                         if(trace_fraction < 1 && trace_plane_normal_z > 0.7)
 525                                 self.flags |= FL_ONGROUND;
 526                 }
 527
 528                 if (self.BUTTON_JUMP)
 529                         PlayerJump ();
 530                 else
 531                         self.flags |= FL_JUMPRELEASED;
 532
 533                 if (self.waterlevel == WATERLEVEL_SWIMMING)
 534                         CheckWaterJump ();
 535         }
 536
 537         if (self.flags & FL_WATERJUMP )
 538         {
 539                 self.velocity_x = self.movedir_x;
 540                 self.velocity_y = self.movedir_y;
 541                 if (time > self.teleport_time || self.waterlevel == WATERLEVEL_NONE)
 542                 {
 543                         self.flags &~= FL_WATERJUMP;
 544                         self.teleport_time = 0;
 545                 }
 546         }
 547         else if (g_bugrigs && self.classname == "player")
 548         {
 549                 RaceCarPhysics();
 550         }
 551         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
 552         {
 553                 // noclipping or flying
 554                 self.flags &~= FL_ONGROUND;
 555
 556                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 557                 makevectors(self.v_angle);
 558                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 559                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 560                 // acceleration
 561                 wishdir = normalize(wishvel);
 562                 wishspeed = vlen(wishvel);
 563                 if (wishspeed > sv_maxspeed*maxspd_mod)
 564                         wishspeed = sv_maxspeed*maxspd_mod;
 565                 if (time >= self.teleport_time)
 566                 {
 567                         f = wishspeed - (self.velocity * wishdir);
 568                         if (f > 0)
 569                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 570                 }
 571         }
 572         else if (self.waterlevel >= WATERLEVEL_SWIMMING)
 573         {
 574                 // swimming
 575                 self.flags &~= FL_ONGROUND;
 576
 577                 makevectors(self.v_angle);
 578                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 579                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 580                 if (wishvel == '0 0 0')
 581                         wishvel = '0 0 -60'; // drift towards bottom
 582
 583                 wishdir = normalize(wishvel);
 584                 wishspeed = vlen(wishvel);
 585                 if (wishspeed > sv_maxspeed*maxspd_mod)
 586                         wishspeed = sv_maxspeed*maxspd_mod;
 587                 wishspeed = wishspeed * 0.7;
 588
 589                 // water friction
 590                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 591
 592                 // water acceleration
 593                 f = wishspeed - (self.velocity * wishdir);
 594                 if (f > 0)
 595                         self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 596         }
 597         else if (time < self.ladder_time)
 598         {
 599                 // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
 600                 self.flags &~= FL_ONGROUND;
 601
 602                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 603                 makevectors(self.v_angle);
 604                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 605                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 606                 if (self.gravity)
 607                         self.velocity_z = self.velocity_z + self.gravity * sv_gravity * frametime;
 608                 else
 609                         self.velocity_z = self.velocity_z + sv_gravity * frametime;
 610                 if (self.ladder_entity.classname == "func_water")
 611                 {
 612                         f = vlen(wishvel);
 613                         if (f > self.ladder_entity.speed)
 614                                 wishvel = wishvel * (self.ladder_entity.speed / f);
 615
 616                         self.watertype = self.ladder_entity.skin;
 617                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
 618                         if ((self.origin_z + self.view_ofs_z) < f)
 619                                 self.waterlevel = WATERLEVEL_SUBMERGED;
 620                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
 621                                 self.waterlevel = WATERLEVEL_SWIMMING;
 622                         else if ((self.origin_z + self.mins_z + 1) < f)
 623                                 self.waterlevel = WATERLEVEL_WETFEET;
 624                         else
 625                         {
 626                                 self.waterlevel = WATERLEVEL_NONE;
 627                                 self.watertype = CONTENT_EMPTY;
 628                         }
 629                 }
 630                 // acceleration
 631                 wishdir = normalize(wishvel);
 632                 wishspeed = vlen(wishvel);
 633                 if (wishspeed > sv_maxspeed)
 634                         wishspeed = sv_maxspeed;
 635                 if (time >= self.teleport_time)
 636                 {
 637                         f = wishspeed - (self.velocity * wishdir);
 638                         if (f > 0)
 639                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 640                 }
 641         }
 642         else if ((self.items & IT_JETPACK) && self.BUTTON_HOOK && (!cvar("g_jetpack_fuel") || self.ammo_fuel >= 0.01 || self.items & IT_UNLIMITED_WEAPON_AMMO))
 643         {
 644                 //makevectors(self.v_angle_y * '0 1 0');
 645                 makevectors(self.v_angle);
 646                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 647                 // add remaining speed as Z component
 648                 maxairspd = sv_maxairspeed*max(1, maxspd_mod);
 649                 // fix speedhacks :P
 650                 wishvel = normalize(wishvel) * min(vlen(wishvel) / maxairspd, 1);
 651                 // add the unused velocity as up component
 652                 wishvel_z = 0;
 653
 654                 // if(self.BUTTON_JUMP)
 655                         wishvel_z = sqrt(max(0, 1 - wishvel * wishvel));
 656
 657                 // it is now normalized, so...
 658                 float a_side, a_up, a_add, a_diff;
 659                 a_side = cvar("g_jetpack_acceleration_side");
 660                 a_up = cvar("g_jetpack_acceleration_up");
 661                 a_add = cvar("g_jetpack_antigravity") * sv_gravity;
 662
 663                 wishvel_x *= a_side;
 664                 wishvel_y *= a_side;
 665                 wishvel_z *= a_up;
 666                 wishvel_z += a_add;
 667
 668                 float best;
 669                 best = 0;
 670                 //////////////////////////////////////////////////////////////////////////////////////
 671                 // finding the maximum over all vectors of above form
 672                 // with wishvel having an absolute value of 1
 673                 //////////////////////////////////////////////////////////////////////////////////////
 674                 // we're finding the maximum over
 675                 //   f(a_side, a_up, a_add, z) := a_side * (1 - z^2) + (a_add + a_up * z)^2;
 676                 // for z in the range from -1 to 1
 677                 //////////////////////////////////////////////////////////////////////////////////////
 678                 // maximum is EITHER attained at the single extreme point:
 679                 a_diff = a_side * a_side - a_up * a_up;
 680                 if(a_diff != 0)
 681                 {
 682                         f = a_add * a_up / a_diff; // this is the zero of diff(f(a_side, a_up, a_add, z), z)
 683                         if(f > -1 && f < 1) // can it be attained?
 684                         {
 685                                 best = (a_diff + a_add * a_add) * (a_diff + a_up * a_up) / a_diff;
 686                                 //print("middle\n");
 687                         }
 688                 }
 689                 // OR attained at z = 1:
 690                 f = (a_up + a_add) * (a_up + a_add);
 691                 if(f > best)
 692                 {
 693                         best = f;
 694                         //print("top\n");
 695                 }
 696                 // OR attained at z = -1:
 697                 f = (a_up - a_add) * (a_up - a_add);
 698                 if(f > best)
 699                 {
 700                         best = f;
 701                         //print("bottom\n");
 702                 }
 703                 best = sqrt(best);
 704                 //////////////////////////////////////////////////////////////////////////////////////
 705
 706                 //print("best possible acceleration: ", ftos(best), "\n");
 707
 708                 float fxy, fz;
 709                 fxy = bound(0, 1 - (self.velocity * normalize(wishvel_x * '1 0 0' + wishvel_y * '0 1 0')) / cvar("g_jetpack_maxspeed_side"), 1);
 710                 if(wishvel_z - sv_gravity > 0)
 711                         fz = bound(0, 1 - self.velocity_z / cvar("g_jetpack_maxspeed_up"), 1);
 712                 else
 713                         fz = bound(0, 1 + self.velocity_z / cvar("g_jetpack_maxspeed_up"), 1);
 714
 715                 float fvel;
 716                 fvel = vlen(wishvel);
 717                 wishvel_x *= fxy;
 718                 wishvel_y *= fxy;
 719                 wishvel_z = (wishvel_z - sv_gravity) * fz + sv_gravity;
 720
 721                 fvel = min(1, vlen(wishvel) / best);
 722                 if(cvar("g_jetpack_fuel") && !(self.items & IT_UNLIMITED_WEAPON_AMMO))
 723                         f = min(1, self.ammo_fuel / (cvar("g_jetpack_fuel") * frametime * fvel));
 724                 else
 725                         f = 1;
 726
 727                 //print("this acceleration: ", ftos(vlen(wishvel) * f), "\n");
 728
 729                 if (f > 0 && wishvel != '0 0 0')
 730                 {
 731                         self.velocity = self.velocity + wishvel * f * frametime;
 732                         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 733                                 self.ammo_fuel -= cvar("g_jetpack_fuel") * frametime * fvel * f;
 734                         self.flags &~= FL_ONGROUND;
 735                         self.items |= IT_USING_JETPACK;
 736
 737                         // jetpack also inhibits health regeneration, but only for 1 second
 738                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_fuel_regen"));
 739                 }
 740         }
 741         else if (self.flags & FL_ONGROUND)
 742         {
 743                 // we get here if we ran out of ammo
 744                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32))
 745                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
 746
 747                 // walking
 748                 makevectors(self.v_angle_y * '0 1 0');
 749                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 750
 751                 if(!(self.lastflags & FL_ONGROUND))
 752                 {
 753                         if(cvar("speedmeter"))
 754                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
 755                         if(self.lastground < time - 0.3)
 756                                 self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
 757                         if(self.jumppadcount > 1)
 758                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 759                         self.jumppadcount = 0;
 760                 }
 761
 762                 if (self.velocity_x || self.velocity_y)
 763                 if (!(self.flags & FL_JUMPRELEASED) || !self.BUTTON_JUMP)
 764                 {
 765                         v = self.velocity;
 766                         v_z = 0;
 767                         f = vlen(v);
 768                         if (f < sv_stopspeed)
 769                                 f = 1 - frametime * (sv_stopspeed / f) * sv_friction;
 770                         else
 771                                 f = 1 - frametime * sv_friction;
 772                         if (f > 0)
 773                                 self.velocity = self.velocity * f;
 774                         else
 775                                 self.velocity = '0 0 0';
 776                 }
 777                 // acceleration
 778                 wishdir = normalize(wishvel);
 779                 wishspeed = vlen(wishvel);
 780                 if (wishspeed > sv_maxspeed*maxspd_mod)
 781                         wishspeed = sv_maxspeed*maxspd_mod;
 782                 if (self.crouch)
 783                         wishspeed = wishspeed * 0.5;
 784                 if (time >= self.teleport_time)
 785                 {
 786                         f = wishspeed - (self.velocity * wishdir);
 787                         if (f > 0)
 788                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 789                 }
 790         }
 791         else
 792         {
 793                 // we get here if we ran out of ammo
 794                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32))
 795                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
 796
 797                 if(maxspd_mod < 1)
 798                 {
 799                         maxairspd = sv_maxairspeed*maxspd_mod;
 800                         airaccel = sv_airaccelerate*maxspd_mod;
 801                 }
 802                 else
 803                 {
 804                         maxairspd = sv_maxairspeed;
 805                         airaccel = sv_airaccelerate;
 806                 }
 807                 // airborn
 808                 makevectors(self.v_angle_y * '0 1 0');
 809                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 810                 // acceleration
 811                 wishdir = normalize(wishvel);
 812                 wishspeed = vlen(wishvel);
 813                 if (wishspeed > maxairspd)
 814                         wishspeed = maxairspd;
 815                 if (self.crouch)
 816                         wishspeed = wishspeed * 0.5;
 817                 if (time >= self.teleport_time)
 818                 {
 819                         // NOTE: this does the same as the commented out old code if:
 820                         //   sv_airaccel_qw 0
 821                         //   sv_airaccel_sideways_friction 0
 822
 823                         float vel_straight;
 824                         float vel_z;
 825                         vector vel_perpend;
 826                         vel_straight = self.velocity * wishdir;
 827                         vel_z = self.velocity_z;
 828                         vel_perpend = self.velocity - vel_straight * wishdir - vel_z * '0 0 1';
 829
 830                         f = wishspeed - vel_straight;
 831                         if(f > 0)
 832                                 vel_straight = vel_straight + min(f, airaccel * frametime * wishspeed) * sv_airaccel_qw;
 833                         if(wishspeed > 0)
 834                                 vel_straight = vel_straight + min(wishspeed, airaccel * frametime * wishspeed) * (1 - sv_airaccel_qw);
 835
 836                         // anti-sideways friction to fix QW-style bunnyhopping
 837                         vel_perpend = vel_perpend * (1 - frametime * (wishspeed / maxairspd) * sv_airaccel_sideways_friction);
 838
 839                         self.velocity = vel_straight * wishdir + vel_z * '0 0 1' + vel_perpend;
 840
 841                         /*
 842                         f = wishspeed;// - (self.velocity * wishdir);
 843                         if (f > 0)
 844                                 self.velocity = self.velocity + wishdir * min(f, airaccel * frametime * wishspeed);
 845                         */
 846                 }
 847         }
 848
 849 :end
 850         if(self.flags & FL_ONGROUND)
 851                 self.lastground = time;
 852
 853         self.lastflags = self.flags;
 854         self.lastclassname = self.classname;
 855 };