data/qcsrc/server/cl_client.qc

   1 // let's abuse an existing field
   2 #define SPAWNPOINT_SCORE frags
   3
   4 .float wantswelcomemessage;
   5 .string netname_previous;
   6
   7 void spawnfunc_info_player_survivor (void)
   8 {
   9         spawnfunc_info_player_deathmatch();
  10 }
  11
  12 void spawnfunc_info_player_start (void)
  13 {
  14         spawnfunc_info_player_deathmatch();
  15 }
  16
  17 void spawnfunc_info_player_deathmatch (void)
  18 {
  19         self.classname = "info_player_deathmatch";
  20         relocate_spawnpoint();
  21 }
  22
  23 void spawnpoint_use()
  24 {
  25         if(teams_matter)
  26         if(have_team_spawns)
  27         {
  28                 self.team = activator.team;
  29                 some_spawn_has_been_used = 1;
  30         }
  31 };
  32
  33 // Returns:
  34 //   -1 if a spawn can't be used
  35 //   otherwise, a weight of the spawnpoint
  36 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
  37 {
  38         float shortest, thisdist;
  39         entity player;
  40
  41         // filter out spots for the wrong team
  42         if(teamcheck)
  43         if(spot.team != teamcheck)
  44                 return -1;
  45
  46         // filter out spots for assault
  47         if(spot.target != "") {
  48                 local entity ent;
  49                 ent = find(world, targetname, spot.target);
  50                 while(ent) {
  51                         if(ent.classname == "target_objective")
  52                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  53                                         return -1;
  54                         ent = find(ent, targetname, spot.target);
  55                 }
  56         }
  57
  58         player = playerlist;
  59         shortest = vlen(world.maxs - world.mins);
  60         for(player = playerlist; player; player = player.chain)
  61                 if (player != self)
  62                 {
  63                         thisdist = vlen(player.origin - spot.origin);
  64                         if (thisdist < shortest)
  65                                 shortest = thisdist;
  66                 }
  67         return shortest;
  68 }
  69
  70 float spawn_allbad;
  71 float spawn_allgood;
  72 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  73 {
  74         local entity spot, spotlist, spotlistend;
  75         spawn_allgood = TRUE;
  76         spawn_allbad = TRUE;
  77
  78         spotlist = world;
  79         spotlistend = world;
  80
  81         for(spot = firstspot; spot; spot = spot.chain)
  82         {
  83                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
  84
  85                 if(cvar("spawn_debugview"))
  86                 {
  87                         setmodel(spot, "models/runematch/rune.mdl");
  88                         if(spot.SPAWNPOINT_SCORE < mindist)
  89                         {
  90                                 spot.colormod = '1 0 0';
  91                                 spot.scale = 1;
  92                         }
  93                         else
  94                         {
  95                                 spot.colormod = '0 1 0';
  96                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
  97                         }
  98                 }
  99
 100                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 101                 {
 102                         if(spot.SPAWNPOINT_SCORE < mindist)
 103                         {
 104                                 // too short distance
 105                                 spawn_allgood = FALSE;
 106                         }
 107                         else
 108                         {
 109                                 // perfect
 110                                 spawn_allbad = FALSE;
 111
 112                                 if(spotlistend)
 113                                         spotlistend.chain = spot;
 114                                 spotlistend = spot;
 115                                 if(!spotlist)
 116                                         spotlist = spot;
 117
 118                                 /*
 119                                 if(teamcheck)
 120                                 if(spot.team != teamcheck)
 121                                         error("invalid spawn added");
 122
 123                                 print("added ", etos(spot), "\n");
 124                                 */
 125                         }
 126                 }
 127         }
 128         if(spotlistend)
 129                 spotlistend.chain = world;
 130
 131         /*
 132                 entity e;
 133                 if(teamcheck)
 134                         for(e = spotlist; e; e = e.chain)
 135                         {
 136                                 print("seen ", etos(e), "\n");
 137                                 if(e.team != teamcheck)
 138                                         error("invalid spawn found");
 139                         }
 140         */
 141
 142         return spotlist;
 143 }
 144
 145 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 146 {
 147         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 148         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 149         local entity spot;
 150
 151         RandomSelection_Init();
 152         for(spot = firstspot; spot; spot = spot.chain)
 153                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 154
 155         return RandomSelection_chosen_ent;
 156 }
 157
 158 /*
 159 =============
 160 SelectSpawnPoint
 161
 162 Finds a point to respawn
 163 =============
 164 */
 165 entity SelectSpawnPoint (float anypoint)
 166 {
 167         local float teamcheck;
 168         local entity firstspot_new;
 169         local entity spot, firstspot, playerlist;
 170
 171         spot = find (world, classname, "testplayerstart");
 172         if (spot)
 173                 return spot;
 174
 175         teamcheck = 0;
 176
 177         if(!anypoint && have_team_spawns)
 178                 teamcheck = self.team;
 179
 180         // get the list of players
 181         playerlist = findchain(classname, "player");
 182         // get the entire list of spots
 183         firstspot = findchain(classname, "info_player_deathmatch");
 184         // filter out the bad ones
 185         // (note this returns the original list if none survived)
 186         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 187         if(!firstspot_new)
 188                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 189         firstspot = firstspot_new;
 190
 191         // there is 50/50 chance of choosing a random spot or the furthest spot
 192         // (this means that roughly every other spawn will be furthest, so you
 193         // usually won't get fragged at spawn twice in a row)
 194         if (arena_roundbased)
 195         {
 196                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 197                 if(firstspot_new)
 198                         firstspot = firstspot_new;
 199                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 200         }
 201         else if (random() > cvar("g_spawn_furthest"))
 202                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 203         else
 204                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 205
 206         if(cvar("spawn_debugview"))
 207         {
 208                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 209
 210                 entity e;
 211                 if(teamcheck)
 212                         for(e = firstspot; e; e = e.chain)
 213                                 if(e.team != teamcheck)
 214                                         error("invalid spawn found");
 215         }
 216
 217         if (!spot)
 218         {
 219                 if(cvar("spawn_debug"))
 220                         GotoNextMap();
 221                 else
 222                 {
 223                         if(some_spawn_has_been_used)
 224                                 return world; // team can't spawn any more, because of actions of other team
 225                         else
 226                                 error("Cannot find a spawn point - please fix the map!");
 227                 }
 228         }
 229
 230         return spot;
 231 }
 232
 233 /*
 234 =============
 235 CheckPlayerModel
 236
 237 Checks if the argument string can be a valid playermodel.
 238 Returns a valid one in doubt.
 239 =============
 240 */
 241 string FallbackPlayerModel = "models/player/marine.zym";
 242 string CheckPlayerModel(string plyermodel) {
 243         if(strlen(plyermodel) < 4)
 244                 return FallbackPlayerModel;
 245         if( substring(plyermodel,0,14) != "models/player/")
 246                 return FallbackPlayerModel;
 247         else if(cvar("sv_servermodelsonly"))
 248         {
 249                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 250                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 251                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 252                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 253                         return FallbackPlayerModel;
 254                 if(!fexists(plyermodel))
 255                         return FallbackPlayerModel;
 256         }
 257         return plyermodel;
 258 }
 259
 260 /*
 261 =============
 262 Client_customizeentityforclient
 263
 264 LOD reduction
 265 =============
 266 */
 267 float Client_customizeentityforclient()
 268 {
 269 #ifdef ALLOW_VARIABLE_LOD
 270         // self: me
 271         // other: the player viewing me
 272         float distance;
 273         float f;
 274
 275         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 276                 return TRUE;
 277
 278         if(other.cvar_cl_playerdetailreduction <= 0)
 279         {
 280                 if(other.cvar_cl_playerdetailreduction <= -2)
 281                         self.modelindex = self.modelindex_lod2;
 282                 else if(other.cvar_cl_playerdetailreduction <= -1)
 283                         self.modelindex = self.modelindex_lod1;
 284                 else
 285                         self.modelindex = self.modelindex_lod0;
 286         }
 287         else
 288         {
 289                 distance = vlen(self.origin - other.origin);
 290                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 291                 if(f > 10000)
 292                         self.modelindex = self.modelindex_lod2;
 293                 else if(f > 5000)
 294                         self.modelindex = self.modelindex_lod1;
 295                 else
 296                         self.modelindex = self.modelindex_lod0;
 297         }
 298 #endif
 299
 300         return TRUE;
 301 }
 302
 303 void UpdatePlayerSounds();
 304 void setmodel_lod(entity e, string modelname)
 305 {
 306 #ifdef ALLOW_VARIABLE_LOD
 307         string s;
 308
 309         // FIXME: this only supports 3-letter extensions
 310         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 311         if(fexists(s))
 312         {
 313                 precache_model(s);
 314                 setmodel(e, s); // players have high precision
 315                 self.modelindex_lod1 = self.modelindex;
 316         }
 317         else
 318                 self.modelindex_lod1 = -1;
 319
 320         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 321         if(fexists(s))
 322         {
 323                 precache_model(s);
 324                 setmodel(e, s); // players have high precision
 325                 self.modelindex_lod2 = self.modelindex;
 326         }
 327         else
 328                 self.modelindex_lod2 = -1;
 329
 330         precache_model(modelname);
 331         setmodel(e, modelname); // players have high precision
 332         self.modelindex_lod0 = self.modelindex;
 333
 334         if(self.modelindex_lod1 < 0)
 335                 self.modelindex_lod1 = self.modelindex;
 336
 337         if(self.modelindex_lod2 < 0)
 338                 self.modelindex_lod2 = self.modelindex;
 339 #else
 340         precache_model(modelname);
 341         setmodel(e, modelname); // players have high precision
 342 #endif
 343         player_setupanimsformodel();
 344         UpdatePlayerSounds();
 345 }
 346
 347 /*
 348 =============
 349 PutObserverInServer
 350
 351 putting a client as observer in the server
 352 =============
 353 */
 354 void PutObserverInServer (void)
 355 {
 356         entity  spot;
 357         spot = SelectSpawnPoint (TRUE);
 358         if(!spot)
 359                 error("No spawnpoints for observers?!?\n");
 360         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 361
 362         if(clienttype(self) == CLIENTTYPE_REAL)
 363         {
 364                 msg_entity = self;
 365                 WriteByte(MSG_ONE, SVC_SETVIEW);
 366                 WriteEntity(MSG_ONE, self);
 367         }
 368
 369         DropAllRunes(self);
 370         kh_Key_DropAll(self, TRUE);
 371
 372         if(self.flagcarried)
 373                 DropFlag(self.flagcarried);
 374
 375         WaypointSprite_PlayerDead();
 376
 377         if(self.killcount != -666)
 378         {
 379                 if(g_lms)
 380                 {
 381                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 382                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 383                         else
 384                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 385                 }
 386                 else
 387                         bprint ("^4", self.netname, "^4 is spectating now\n");
 388         }
 389
 390         PlayerScore_Clear(self); // clear scores when needed
 391
 392         self.spectatortime = time;
 393
 394         self.classname = "observer";
 395         self.health = -666;
 396         self.takedamage = DAMAGE_NO;
 397         self.solid = SOLID_NOT;
 398         self.movetype = MOVETYPE_NOCLIP;
 399         self.flags = FL_CLIENT | FL_NOTARGET;
 400         self.armorvalue = 666;
 401         self.effects = 0;
 402         self.armorvalue = cvar("g_balance_armor_start");
 403         self.pauserotarmor_finished = 0;
 404         self.pauserothealth_finished = 0;
 405         self.pauseregen_finished = 0;
 406         self.damageforcescale = 0;
 407         self.death_time = 0;
 408         self.dead_frame = 0;
 409         self.alpha = 0;
 410         self.scale = 0;
 411         self.fade_time = 0;
 412         self.pain_frame = 0;
 413         self.pain_finished = 0;
 414         self.strength_finished = 0;
 415         self.invincible_finished = 0;
 416         self.pushltime = 0;
 417         self.think = SUB_Null;
 418         self.nextthink = 0;
 419         self.hook_time = 0;
 420         self.runes = 0;
 421         self.deadflag = DEAD_NO;
 422         self.angles = spot.angles;
 423         self.angles_z = 0;
 424         self.fixangle = TRUE;
 425         self.crouch = FALSE;
 426
 427         self.view_ofs = PL_VIEW_OFS;
 428         setorigin (self, spot.origin);
 429         setsize (self, '0 0 0', '0 0 0');
 430         self.oldorigin = self.origin;
 431         self.items = 0;
 432         self.model = "";
 433         self.modelindex = 0;
 434         self.weapon = 0;
 435         self.weaponmodel = "";
 436         self.weaponentity = world;
 437         self.killcount = -666;
 438         self.velocity = '0 0 0';
 439         self.avelocity = '0 0 0';
 440         self.punchangle = '0 0 0';
 441         self.punchvector = '0 0 0';
 442         self.oldvelocity = self.velocity;
 443         self.customizeentityforclient = Client_customizeentityforclient;
 444         self.viewzoom = 1;
 445         self.wantswelcomemessage = 1;
 446
 447         if(g_arena)
 448         {
 449                 if(self.frags != -2)
 450                 {
 451                         Spawnqueue_Insert(self);
 452                         // FIXME what IS this?
 453                 }
 454                 else
 455                 {
 456                         Spawnqueue_Unmark(self);
 457                         Spawnqueue_Remove(self);
 458                 }
 459         }
 460         else if(g_lms)
 461         {
 462                 // Only if the player cannot play at all
 463                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 464                         self.frags = -666;
 465                 else
 466                         self.frags = -667;
 467         }
 468         else
 469                 self.frags = -666;
 470 }
 471
 472 float RestrictSkin(float s)
 473 {
 474         if(!teams_matter)
 475                 return s;
 476         if(s == 6)
 477                 return 6;
 478         return mod(s, 3);
 479 }
 480
 481 void FixPlayermodel()
 482 {
 483         local string defaultmodel;
 484         local float defaultskin;
 485         local vector m1, m2;
 486
 487         defaultmodel = "";
 488
 489         if(cvar("sv_defaultcharacter") == 1) {
 490                 defaultskin = 0;
 491
 492                 if(teams_matter)
 493                 {
 494                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 495                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 496                 }
 497
 498                 if(defaultmodel == "")
 499                 {
 500                         defaultmodel = cvar_string("sv_defaultplayermodel");
 501                         defaultskin = cvar("sv_defaultplayerskin");
 502                 }
 503         }
 504
 505         if(defaultmodel != "")
 506         {
 507                 if (defaultmodel != self.model)
 508                 {
 509                         m1 = self.mins;
 510                         m2 = self.maxs;
 511                         setmodel_lod (self, defaultmodel);
 512                         setsize (self, m1, m2);
 513                 }
 514
 515                 self.skin = defaultskin;
 516         } else {
 517                 if (self.playermodel != self.model)
 518                 {
 519                         self.playermodel = CheckPlayerModel(self.playermodel);
 520                         m1 = self.mins;
 521                         m2 = self.maxs;
 522                         setmodel_lod (self, self.playermodel);
 523                         setsize (self, m1, m2);
 524                 }
 525
 526                 self.skin = RestrictSkin(stof(self.playerskin));
 527         }
 528
 529         if(!teams_matter)
 530                 if(strlen(cvar_string("sv_defaultplayercolors")))
 531                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 532                                 setcolor(self, cvar("sv_defaultplayercolors"));
 533 }
 534
 535 /*
 536 =============
 537 PutClientInServer
 538
 539 Called when a client spawns in the server
 540 =============
 541 */
 542 //void() ctf_playerchanged;
 543 void PutClientInServer (void)
 544 {
 545         if(clienttype(self) == CLIENTTYPE_BOT)
 546         {
 547                 self.classname = "player";
 548         }
 549         else if(clienttype(self) == CLIENTTYPE_REAL)
 550         {
 551                 msg_entity = self;
 552                 WriteByte(MSG_ONE, SVC_SETVIEW);
 553                 WriteEntity(MSG_ONE, self);
 554         }
 555
 556         // player is dead and becomes observer
 557         // FIXME fix LMS scoring for new system
 558         if(g_lms)
 559         {
 560                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 561                         self.classname = "observer";
 562         }
 563
 564         if(g_arena)
 565         if(!self.spawned)
 566                 self.classname = "observer";
 567
 568         if(self.classname == "player") {
 569                 entity  spot;
 570
 571                 spot = SelectSpawnPoint (FALSE);
 572                 if(!spot)
 573                 {
 574                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 575                         return; // spawn failed
 576                 }
 577
 578                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 579
 580                 self.classname = "player";
 581                 self.iscreature = TRUE;
 582                 self.movetype = MOVETYPE_WALK;
 583                 self.solid = SOLID_SLIDEBOX;
 584                 self.flags = FL_CLIENT;
 585                 self.takedamage = DAMAGE_AIM;
 586                 if(g_minstagib)
 587                         self.effects = EF_FULLBRIGHT;
 588                 else
 589                         self.effects = 0;
 590                 self.air_finished = time + 12;
 591                 self.dmg = 2;
 592
 593                 self.ammo_shells = start_ammo_shells;
 594                 self.ammo_nails = start_ammo_nails;
 595                 self.ammo_rockets = start_ammo_rockets;
 596                 self.ammo_cells = start_ammo_cells;
 597                 self.health = start_health;
 598                 self.armorvalue = start_armorvalue;
 599                 self.items = start_items;
 600                 self.switchweapon = start_switchweapon;
 601                 self.cnt = start_switchweapon;
 602                 self.weapon = 0;
 603                 self.jump_interval = time;
 604
 605                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 606                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 607                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 608                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 609                 //extend the pause of rotting if client was reset at the beginning of the countdown
 610                 if(!cvar("sv_ready_restart_after_countdown") && time < restart_countdown) {
 611                         self.spawnshieldtime += RESTART_COUNTDOWN;
 612                         self.pauserotarmor_finished += RESTART_COUNTDOWN;
 613                         self.pauserothealth_finished += RESTART_COUNTDOWN;
 614                         self.pauseregen_finished += RESTART_COUNTDOWN;
 615                 }
 616                 self.damageforcescale = 2;
 617                 self.death_time = 0;
 618                 self.dead_frame = 0;
 619                 self.alpha = 0;
 620                 self.scale = 0;
 621                 self.fade_time = 0;
 622                 self.pain_frame = 0;
 623                 self.pain_finished = 0;
 624                 self.strength_finished = 0;
 625                 self.invincible_finished = 0;
 626                 self.pushltime = 0;
 627                 //self.speed_finished = 0;
 628                 //self.slowmo_finished = 0;
 629                 // players have no think function
 630                 self.think = SUB_Null;
 631                 self.nextthink = 0;
 632                 self.hook_time = 0;
 633
 634                 self.runes = 0;
 635
 636                 self.deadflag = DEAD_NO;
 637
 638                 self.angles = spot.angles;
 639
 640                 self.angles_z = 0; // never spawn tilted even if the spot says to
 641                 self.fixangle = TRUE; // turn this way immediately
 642                 self.velocity = '0 0 0';
 643                 self.avelocity = '0 0 0';
 644                 self.punchangle = '0 0 0';
 645                 self.punchvector = '0 0 0';
 646                 self.oldvelocity = self.velocity;
 647
 648                 self.viewzoom = 0.6;
 649                 self.has_zoomed = 0;
 650
 651                 self.customizeentityforclient = Client_customizeentityforclient;
 652
 653                 self.model = "";
 654                 FixPlayermodel();
 655
 656                 self.crouch = FALSE;
 657                 self.view_ofs = PL_VIEW_OFS;
 658                 setsize (self, PL_MIN, PL_MAX);
 659                 self.spawnorigin = spot.origin;
 660                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 661                 // don't reset back to last position, even if new position is stuck in solid
 662                 self.oldorigin = self.origin;
 663
 664                 if(g_arena)
 665                 {
 666                         Spawnqueue_Remove(self);
 667                         Spawnqueue_Mark(self);
 668                 }
 669
 670                 self.event_damage = PlayerDamage;
 671
 672                 self.bot_attack = TRUE;
 673
 674                 self.statdraintime = time + 5;
 675                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 676
 677                 if(self.killcount == -666) {
 678                         PlayerScore_Clear(self);
 679                         self.killcount = 0;
 680                         self.frags = 0;
 681                 }
 682
 683                 self.cnt = WEP_LASER;
 684                 self.nixnex_lastchange_id = -1;
 685
 686                 CL_SpawnWeaponentity();
 687                 self.alpha = default_player_alpha;
 688                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 689                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 690
 691                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 692                 self.lms_traveled_distance = 0;
 693                 self.speedrunning = FALSE;
 694
 695                 if(cvar("spawn_debug"))
 696                 {
 697                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 698                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 699                 }
 700
 701                 //stuffcmd(self, "chase_active 0");
 702                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 703
 704                 if (cvar("g_spawnsound"))
 705                         sound (self, CHAN_AUTO, "misc/spawn.wav", 1, ATTN_NORM);
 706
 707                 if(g_assault) {
 708                         if(self.team == assault_attacker_team)
 709                                 centerprint(self, "You are attacking!\n");
 710                         else
 711                                 centerprint(self, "You are defending!\n");
 712                 }
 713
 714         } else if(self.classname == "observer") {
 715                 PutObserverInServer ();
 716         }
 717
 718         //if(g_ctf)
 719         //      ctf_playerchanged();
 720 }
 721
 722 /*
 723 =============
 724 SendCSQCInfo
 725
 726 Send whatever CSQC needs NOW and cannot wait for SendServerInfo to happen...
 727 =============
 728 */
 729 void SendCSQCInfo(void)
 730 {
 731         if(clienttype(self) != CLIENTTYPE_REAL)
 732                 return;
 733         msg_entity = self;
 734         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 735         WriteByte(MSG_ONE, TE_CSQC_INIT);
 736         WriteShort(MSG_ONE, CSQC_REVISION);
 737         WriteByte(MSG_ONE, maxclients);
 738 }
 739
 740 /*
 741 =============
 742 SetNewParms
 743 =============
 744 */
 745 void SetNewParms (void)
 746 {
 747         // initialize parms for a new player
 748         parm1 = -(86400 * 366);
 749 }
 750
 751 /*
 752 =============
 753 SetChangeParms
 754 =============
 755 */
 756 void SetChangeParms (void)
 757 {
 758         // save parms for level change
 759         parm1 = self.parm_idlesince - time;
 760 }
 761
 762 /*
 763 =============
 764 DecodeLevelParms
 765 =============
 766 */
 767 void DecodeLevelParms (void)
 768 {
 769         // load parms
 770         self.parm_idlesince = parm1;
 771         if(self.parm_idlesince == -(86400 * 366))
 772                 self.parm_idlesince = time;
 773 }
 774
 775 /*
 776 =============
 777 ClientKill
 778
 779 Called when a client types 'kill' in the console
 780 =============
 781 */
 782
 783 void ClientKill_Now_TeamChange()
 784 {
 785         if(self.killindicator_teamchange == -1)
 786         {
 787                 self.team = -1;
 788                 JoinBestTeam( self, FALSE, FALSE );
 789         }
 790         else
 791         {
 792                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 793         }
 794 }
 795
 796 void ClientKill_Now()
 797 {
 798         if(self.killindicator_teamchange)
 799                 ClientKill_Now_TeamChange();
 800
 801         // in any case:
 802         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 803 }
 804 void KillIndicator_Think()
 805 {
 806         if (!self.owner.modelindex)
 807         {
 808                 self.owner.killindicator = world;
 809                 remove(self);
 810                 return;
 811         }
 812
 813         if(self.cnt <= 0)
 814         {
 815                 self = self.owner;
 816                 ClientKill_Now(); // no oldself needed
 817                 return;
 818         }
 819         else
 820         {
 821                 if(self.cnt <= 10)
 822                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 823                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 824                 {
 825                         if(self.cnt <= 10)
 826                                 play2(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 827                         if(self.owner.killindicator_teamchange)
 828                         {
 829                                 if(self.owner.killindicator_teamchange == -1)
 830                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 831                                 else
 832                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 833                         }
 834                         else
 835                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 836                 }
 837                 self.nextthink = time + 1;
 838                 self.cnt -= 1;
 839         }
 840 }
 841
 842 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 843 {
 844         float killtime;
 845         entity e;
 846         killtime = cvar("g_balance_kill_delay");
 847
 848         self.killindicator_teamchange = targetteam;
 849
 850         if(!self.killindicator)
 851         {
 852                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 853                 {
 854                         ClientKill_Now();
 855                 }
 856                 else
 857                 {
 858                         self.killindicator = spawn();
 859                         self.killindicator.owner = self;
 860                         self.killindicator.scale = 0.5;
 861                         setattachment(self.killindicator, self, "");
 862                         setorigin(self.killindicator, '0 0 52');
 863                         self.killindicator.think = KillIndicator_Think;
 864                         self.killindicator.nextthink = time + (self.lip) * 0.05;
 865                         self.killindicator.cnt = ceil(killtime);
 866                         self.killindicator.count = bound(0, ceil(killtime), 10);
 867                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 868
 869                         for(e = world; (e = find(e, classname, "body")) != world; )
 870                         {
 871                                 if(e.enemy != self)
 872                                         continue;
 873                                 e.killindicator = spawn();
 874                                 e.killindicator.owner = e;
 875                                 e.killindicator.scale = 0.5;
 876                                 setattachment(e.killindicator, e, "");
 877                                 setorigin(e.killindicator, '0 0 52');
 878                                 e.killindicator.think = KillIndicator_Think;
 879                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
 880                                 e.killindicator.cnt = ceil(killtime);
 881                         }
 882                         self.lip = 0;
 883                 }
 884         }
 885         if(self.killindicator)
 886         {
 887                 if(targetteam)
 888                         self.killindicator.colormod = TeamColor(targetteam);
 889                 else
 890                         self.killindicator.colormod = '0 0 0';
 891         }
 892 }
 893
 894 void ClientKill (void)
 895 {
 896         ClientKill_TeamChange(0);
 897 }
 898
 899 void DoTeamChange(float destteam)
 900 {
 901         float t, c0;
 902         if(!cvar("teamplay"))
 903         {
 904                 if(destteam >= 0)
 905                         SetPlayerColors(self, destteam);
 906                 return;
 907         }
 908         if(self.classname == "player")
 909         if(destteam == -1)
 910         {
 911                 CheckAllowedTeams(self);
 912                 t = FindSmallestTeam(self, TRUE);
 913                 switch(self.team)
 914                 {
 915                         case COLOR_TEAM1: c0 = c1; break;
 916                         case COLOR_TEAM2: c0 = c2; break;
 917                         case COLOR_TEAM3: c0 = c3; break;
 918                         case COLOR_TEAM4: c0 = c4; break;
 919                         default:          c0 = 999;
 920                 }
 921                 switch(t)
 922                 {
 923                         case 1:
 924                                 if(c0 > c1)
 925                                         destteam = COLOR_TEAM1;
 926                                 break;
 927                         case 2:
 928                                 if(c0 > c2)
 929                                         destteam = COLOR_TEAM2;
 930                                 break;
 931                         case 3:
 932                                 if(c0 > c3)
 933                                         destteam = COLOR_TEAM3;
 934                                 break;
 935                         case 4:
 936                                 if(c0 > c4)
 937                                         destteam = COLOR_TEAM4;
 938                                 break;
 939                 }
 940                 if(destteam == -1)
 941                         return;
 942         }
 943         if(destteam == self.team && !self.killindicator)
 944                 return;
 945         ClientKill_TeamChange(destteam);
 946 }
 947
 948 void FixClientCvars(entity e)
 949 {
 950         // send prediction settings to the client
 951         stuffcmd(e, "\nin_bindmap 0 0\n");
 952         /*
 953          * we no longer need to stuff this. Remove this comment block if you feel
 954          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 955         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
 956         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 957         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 958         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 959         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 960         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 961         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 962         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
 963         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 964         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 965         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 966         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 967         stuffcmd(e, "cl_movement_edgefriction 1\n");
 968          */
 969 }
 970
 971 /*
 972 =============
 973 ClientConnect
 974
 975 Called when a client connects to the server
 976 =============
 977 */
 978 //void ctf_clientconnect();
 979 string ColoredTeamName(float t);
 980 void DecodeLevelParms (void);
 981 //void dom_player_join_team(entity pl);
 982 void ClientConnect (void)
 983 {
 984         local string s;
 985         float wep;
 986
 987         if(Ban_IsClientBanned(self))
 988         {
 989                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
 990                 dropclient(self);
 991                 bprint(s);
 992                 return;
 993         }
 994
 995         DecodeLevelParms();
 996
 997         self.classname = "player_joining";
 998         self.flags = self.flags | FL_CLIENT;
 999         self.version_nagtime = time + 10 + random() * 10;
1000
1001         if(player_count<0)
1002         {
1003                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1004                 player_count = 0;
1005         }
1006
1007         PlayerScore_Attach(self);
1008
1009         bot_clientconnect();
1010
1011         //if(g_domination)
1012         //      dom_player_join_team(self);
1013
1014         //JoinBestTeam(self, FALSE, FALSE);
1015
1016         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1017                 self.classname = "observer";
1018         } else {
1019                 self.classname = "player";
1020                 campaign_bots_may_start = 1;
1021         }
1022
1023         self.playerid = (playerid_last = playerid_last + 1);
1024         if(cvar("sv_eventlog"))
1025         {
1026                 if(clienttype(self) == CLIENTTYPE_REAL)
1027                         s = "player";
1028                 else
1029                         s = "bot";
1030                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
1031                 s = strcat(":team:", ftos(self.playerid), ":");
1032                 s = strcat(s, ftos(self.team));
1033                 GameLogEcho(s, FALSE);
1034         }
1035         self.netname_previous = strzone(self.netname);
1036
1037         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1038
1039         bprint ("^4",self.netname);
1040         bprint ("^4 connected");
1041
1042         if(g_domination || g_ctf)
1043         {
1044                 bprint(" and joined the ");
1045                 bprint(ColoredTeamName(self.team));
1046         }
1047
1048         bprint("\n");
1049
1050         self.welcomemessage_time = 0;
1051
1052         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1053         // TODO: is this being used for anything else than cd tracks?
1054         // Remember: SVC_CDTRACK exists. Maybe it should be used.
1055         //
1056         stuffcmd(self, "cl_particles_reloadeffects\n");
1057
1058         FixClientCvars(self);
1059
1060         // spawnfunc_waypoint sprites
1061         WaypointSprite_InitClient(self);
1062
1063         // Wazat's grappling hook
1064         SetGrappleHookBindings();
1065
1066         // get autoswitch state from player when he toggles it
1067         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1068
1069         // get version info from player
1070         stuffcmd(self, "cmd clientversion $gameversion\n");
1071
1072         // send all weapon info strings
1073         stuffcmd(self, "register_bestweapon clear\n"); // clear the Quake stuff
1074         wep = WEP_FIRST;
1075         while (wep <= WEP_LAST)
1076         {
1077                 weapon_action(wep, WR_REGISTER);
1078                 wep = wep + 1;
1079         }
1080
1081         // get other cvars from player
1082         GetCvars(0);
1083
1084         // set cvar for team scoreboard
1085         if (teams_matter)
1086         {
1087                 local float t;
1088                 t = cvar("teamplay");
1089                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1090                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1091         }
1092         else
1093                 stuffcmd(self, "set teamplay 0\n");
1094
1095         // notify about available teams
1096         if(teamplay)
1097         {
1098                 CheckAllowedTeams(self);
1099                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1100                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1101         }
1102         else
1103                 stuffcmd(self, "set _teams_available 0\n");
1104
1105         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1106
1107         if(g_arena)
1108         {
1109                 self.classname = "observer";
1110                 Spawnqueue_Insert(self);
1111         }
1112         /*else if(g_ctf)
1113         {
1114                 ctf_clientconnect();
1115         }*/
1116
1117         if(entcs_start)
1118                 attach_entcs();
1119
1120         bot_relinkplayerlist();
1121
1122         self.spectatortime = time;
1123         if(blockSpectators)
1124         {
1125                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1126         }
1127
1128         self.jointime = time;
1129         self.allowedTimeouts = cvar("sv_timeout_number");
1130
1131         if(clienttype(self) == CLIENTTYPE_REAL)
1132         {
1133                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1134                 SendCSQCInfo();
1135                 msg_entity = self;
1136                 if(mapvote_initialized && !cvar("g_maplist_textonly"))
1137                 {
1138                         MapVote_SendData(MSG_ONE);
1139                         MapVote_UpdateData(MSG_ONE);
1140                 }
1141         }
1142
1143         if(g_lms)
1144         {
1145                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1146                 {
1147                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1148                         self.frags = -666; // FIXME do we still need this?
1149                 }
1150         }
1151 }
1152
1153 /*
1154 =============
1155 ClientDisconnect
1156
1157 Called when a client disconnects from the server
1158 =============
1159 */
1160 void(entity e) DropFlag;
1161 .entity chatbubbleentity;
1162 .entity teambubbleentity;
1163 //void() ctf_clientdisconnect;
1164 void ClientDisconnect (void)
1165 {
1166         float save;
1167
1168         bot_clientdisconnect();
1169
1170         if(entcs_start)
1171                 detach_entcs();
1172
1173         if(cvar("sv_eventlog"))
1174                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
1175         bprint ("^4",self.netname);
1176         bprint ("^4 disconnected\n");
1177
1178         if (self.chatbubbleentity)
1179         {
1180                 remove (self.chatbubbleentity);
1181                 self.chatbubbleentity = world;
1182         }
1183
1184         if (self.teambubbleentity)
1185         {
1186                 remove (self.teambubbleentity);
1187                 self.teambubbleentity = world;
1188         }
1189
1190         if (self.killindicator)
1191         {
1192                 remove (self.killindicator);
1193                 self.killindicator = world;
1194         }
1195
1196         WaypointSprite_PlayerGone();
1197
1198         DropAllRunes(self);
1199         kh_Key_DropAll(self, TRUE);
1200
1201         if(self.flagcarried)
1202                 DropFlag(self.flagcarried);
1203
1204         save = self.flags;
1205         self.flags = self.flags - (self.flags & FL_CLIENT);
1206         bot_relinkplayerlist();
1207         self.flags = save;
1208
1209         // remove laserdot
1210         if(self.weaponentity)
1211                 if(self.weaponentity.lasertarget)
1212                         remove(self.weaponentity.lasertarget);
1213
1214         if(g_arena)
1215         {
1216                 Spawnqueue_Unmark(self);
1217                 Spawnqueue_Remove(self);
1218         }
1219         /*if(g_ctf)
1220         {
1221                 ctf_clientdisconnect();
1222         }
1223         */
1224
1225         if(self.flags & FL_CLIENT)
1226                 PlayerScore_Detach(self);
1227         else
1228                 print("Warning: ClientDisconnect without ClientConnect\n");
1229
1230         if(self.netname_previous)
1231                 strunzone(self.netname_previous);
1232
1233         // free cvars
1234         GetCvars(-1);
1235 }
1236
1237 .float BUTTON_CHAT;
1238 void ChatBubbleThink()
1239 {
1240         self.nextthink = time;
1241         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1242         {
1243                 self.owner.chatbubbleentity = world;
1244                 remove(self);
1245                 return;
1246         }
1247         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1248         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1249                 self.model = self.mdl;
1250         else
1251                 self.model = "";
1252 };
1253
1254 void UpdateChatBubble()
1255 {
1256         if (!self.modelindex)
1257                 return;
1258         // spawn a chatbubble entity if needed
1259         if (!self.chatbubbleentity)
1260         {
1261                 self.chatbubbleentity = spawn();
1262                 self.chatbubbleentity.owner = self;
1263                 self.chatbubbleentity.exteriormodeltoclient = self;
1264                 self.chatbubbleentity.think = ChatBubbleThink;
1265                 self.chatbubbleentity.nextthink = time;
1266                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1267                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1268                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1269                 self.chatbubbleentity.model = "";
1270                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1271         }
1272 }
1273
1274
1275 void TeamBubbleThink()
1276 {
1277         self.nextthink = time;
1278         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1279         {
1280                 self.owner.teambubbleentity = world;
1281                 remove(self);
1282                 return;
1283         }
1284 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1285         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1286                 self.model = "";
1287         else
1288                 self.model = self.mdl;
1289
1290 };
1291
1292 float TeamBubble_customizeentityforclient()
1293 {
1294         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1295 }
1296
1297 void UpdateTeamBubble()
1298 {
1299         if (!self.modelindex || !cvar("teamplay"))
1300                 return;
1301         // spawn a teambubble entity if needed
1302         if (!self.teambubbleentity && cvar("teamplay"))
1303         {
1304                 self.teambubbleentity = spawn();
1305                 self.teambubbleentity.owner = self;
1306                 self.teambubbleentity.exteriormodeltoclient = self;
1307                 self.teambubbleentity.think = TeamBubbleThink;
1308                 self.teambubbleentity.nextthink = time;
1309                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1310 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1311                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1312                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1313                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1314                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1315                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1316                 self.teambubbleentity.effects = EF_LOWPRECISION;
1317         }
1318 }
1319
1320 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1321 // added to the model skins
1322 /*void UpdateColorModHack()
1323 {
1324         local float c;
1325         c = self.clientcolors & 15;
1326         // LordHavoc: only bothering to support white, green, red, yellow, blue
1327              if (teamplay == 0) self.colormod = '0 0 0';
1328         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1329         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1330         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1331         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1332         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1333         else self.colormod = '1 1 1';
1334 };*/
1335
1336 void respawn(void)
1337 {
1338         CopyBody(1);
1339         self.effects |= EF_NODRAW; // prevent another CopyBody
1340         PutClientInServer();
1341 }
1342
1343 /**
1344  * When sv_timeout is used this function returs strings like
1345  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1346  * Called by centerprint functions
1347  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1348  */
1349 string getTimeoutText(float addOneSecond) {
1350         if (!cvar("sv_timeout") || !timeoutStatus)
1351                 return "";
1352
1353         local string retStr;
1354         if (timeoutStatus == 1) {
1355                 if (addOneSecond == 1) {
1356                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1357                 }
1358                 else {
1359                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1360                 }
1361                 return retStr;
1362         }
1363         else if (timeoutStatus == 2) {
1364                 if (addOneSecond) {
1365                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1366                         //don't show messages like "Timeout ends in 0 seconds"...
1367                         if ((remainingTimeoutTime + 1) > 0)
1368                                 return retStr;
1369                         else
1370                                 return "";
1371                 }
1372                 else {
1373                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1374                         //don't show messages like "Timeout ends in 0 seconds"...
1375                         if (remainingTimeoutTime > 0)
1376                                 return retStr;
1377                         else
1378                                 return "";
1379                 }
1380         }
1381         else return "";
1382 }
1383
1384 void player_powerups (void)
1385 {
1386         if (g_minstagib)
1387         {
1388                 if (self.items & IT_STRENGTH)
1389                 {
1390                         if (time > self.strength_finished)
1391                         {
1392                                 if (g_minstagib_invis_alpha > 0)
1393                                 {
1394                                         self.alpha = default_player_alpha;
1395                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1396                                         self.effects = self.effects | EF_FULLBRIGHT;
1397                                 }
1398                                 else
1399                                 {
1400                                         self.effects -= self.effects & EF_NODRAW;
1401                                 }
1402                                 self.items = self.items - (self.items & IT_STRENGTH);
1403                                 sprint(self, "^3Invisibility has worn off\n");
1404                         }
1405                 }
1406                 else
1407                 {
1408                         if (time < self.strength_finished)
1409                         {
1410                                 if (g_minstagib_invis_alpha > 0)
1411                                 {
1412                                         self.alpha = g_minstagib_invis_alpha;
1413                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1414                                         self.effects -= self.effects & EF_FULLBRIGHT;
1415                                 }
1416                                 else
1417                                 {
1418                                         self.effects = self.effects | EF_NODRAW;
1419                                 }
1420                                 self.items = self.items | IT_STRENGTH;
1421                                 sprint(self, "^3You are invisible\n");
1422                         }
1423                 }
1424
1425                 if (self.items & IT_INVINCIBLE)
1426                 {
1427                         if (time > self.invincible_finished)
1428                         {
1429                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1430                                 sprint(self, "^3Speed has worn off\n");
1431                         }
1432                 }
1433                 else
1434                 {
1435                         if (time < self.invincible_finished)
1436                         {
1437                                 self.items = self.items | IT_INVINCIBLE;
1438                                 sprint(self, "^3You are on speed\n");
1439                         }
1440                 }
1441                 return;
1442         }
1443
1444         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1445         if (self.items & IT_STRENGTH)
1446         {
1447                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1448                 if (time > self.strength_finished)
1449                 {
1450                         self.items = self.items - (self.items & IT_STRENGTH);
1451                         sprint(self, "^3Strength has worn off\n");
1452                 }
1453         }
1454         else
1455         {
1456                 if (time < self.strength_finished)
1457                 {
1458                         self.items = self.items | IT_STRENGTH;
1459                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1460                 }
1461         }
1462         if (self.items & IT_INVINCIBLE)
1463         {
1464                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1465                 if (time > self.invincible_finished)
1466                 {
1467                         self.items = self.items - (self.items & IT_INVINCIBLE);
1468                         sprint(self, "^3Shield has worn off\n");
1469                 }
1470         }
1471         else
1472         {
1473                 if (time < self.invincible_finished)
1474                 {
1475                         self.items = self.items | IT_INVINCIBLE;
1476                         sprint(self, "^3Shield surrounds you\n");
1477                 }
1478         }
1479
1480         if (cvar("g_fullbrightplayers"))
1481                 self.effects = self.effects | EF_FULLBRIGHT;
1482
1483         // midair gamemode: damage only while in the air
1484         // if in midair mode, being on ground grants temporary invulnerability
1485         // (this is so that multishot weapon don't clear the ground flag on the
1486         // first damage in the frame, leaving the player vulnerable to the
1487         // remaining hits in the same frame)
1488         if (self.flags & FL_ONGROUND)
1489         if (g_midair)
1490                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1491
1492         if (time < self.spawnshieldtime)
1493                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1494 }
1495
1496 float CalcRegen(float current, float stable, float regenfactor)
1497 {
1498         if(current > stable)
1499                 return current;
1500         else if(current > stable - 0.25) // when close enough, "snap"
1501                 return stable;
1502         else
1503                 return min(stable, current + (stable - current) * regenfactor * frametime);
1504 }
1505
1506 void player_regen (void)
1507 {
1508         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1509         maxh = cvar("g_balance_health_stable");
1510         maxa = cvar("g_balance_armor_stable");
1511         limith = cvar("g_balance_health_limit");
1512         limita = cvar("g_balance_armor_limit");
1513
1514         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1515                 return;
1516
1517         max_mod = regen_mod = rot_mod = limit_mod = 1;
1518
1519         if (self.runes & RUNE_REGEN)
1520         {
1521                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1522                 {
1523                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1524                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1525                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1526                 }
1527                 else
1528                 {
1529                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1530                         max_mod = cvar("g_balance_rune_regen_hpmod");
1531                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1532                 }
1533         }
1534         else if (self.runes & CURSE_VENOM)
1535         {
1536                 max_mod = cvar("g_balance_curse_venom_hpmod");
1537                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1538                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1539                 else
1540                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1541                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1542                 //if (!self.runes & RUNE_REGEN)
1543                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1544         }
1545         maxh = maxh * max_mod;
1546         //maxa = maxa * max_mod;
1547         limith = limith * limit_mod;
1548         limita = limita * limit_mod;
1549
1550         if (self.armorvalue > maxa)
1551         {
1552                 if (time > self.pauserotarmor_finished)
1553                 {
1554                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1555                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1556                 }
1557         }
1558         else if (self.armorvalue < maxa)
1559         {
1560                 if (time > self.pauseregen_finished)
1561                 {
1562                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1563                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1564                 }
1565         }
1566         if (self.health > maxh)
1567         {
1568                 if (time > self.pauserothealth_finished)
1569                 {
1570                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1571                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1572                 }
1573         }
1574         else if (self.health < maxh)
1575         {
1576                 if (time > self.pauseregen_finished)
1577                 {
1578                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1579                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1580                 }
1581         }
1582
1583         if (self.health > limith)
1584                 self.health = limith;
1585         if (self.armorvalue > limita)
1586                 self.armorvalue = limita;
1587
1588         // if player rotted to death...  die!
1589         if(self.health < 1)
1590                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1591 }
1592
1593 /*
1594 ======================
1595 spectate mode routines
1596 ======================
1597 */
1598 void SpectateCopy(entity spectatee) {
1599         self.armortype = spectatee.armortype;
1600         self.armorvalue = spectatee.armorvalue;
1601         self.currentammo = spectatee.currentammo;
1602         self.effects = spectatee.effects;
1603         self.health = spectatee.health;
1604         self.impulse = 0;
1605         self.items = spectatee.items;
1606         self.punchangle = spectatee.punchangle;
1607         self.view_ofs = spectatee.view_ofs;
1608         self.v_angle = spectatee.v_angle;
1609         self.viewzoom = spectatee.viewzoom;
1610         self.velocity = spectatee.velocity;
1611         self.dmg_take = spectatee.dmg_take;
1612         self.dmg_save = spectatee.dmg_save;
1613         self.dmg_inflictor = spectatee.dmg_inflictor;
1614         self.angles = spectatee.v_angle;
1615         self.fixangle = TRUE;
1616         setorigin(self, spectatee.origin);
1617         setsize(self, spectatee.mins, spectatee.maxs);
1618 }
1619
1620 float SpectateUpdate() {
1621         if(!self.enemy)
1622                 return 0;
1623
1624         if (self == self.enemy)
1625                 return 0;
1626
1627         if(self.enemy.flags & FL_NOTARGET)
1628                 return 0;
1629
1630         SpectateCopy(self.enemy);
1631
1632         return 1;
1633 }
1634
1635 float SpectateNext() {
1636         other = find(self.enemy, classname, "player");
1637         if (!other) {
1638                 other = find(other, classname, "player");
1639         }
1640         if (other) {
1641                 self.enemy = other;
1642         }
1643         if(self.enemy.classname == "player") {
1644                 msg_entity = self;
1645                 WriteByte(MSG_ONE, SVC_SETVIEW);
1646                 WriteEntity(MSG_ONE, self.enemy);
1647                 self.wantswelcomemessage = 1;
1648                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1649                 if(!SpectateUpdate())
1650                         PutObserverInServer();
1651                 return 1;
1652         } else {
1653                 return 0;
1654         }
1655 }
1656
1657 /*
1658 =============
1659 ShowRespawnCountdown()
1660
1661 Update a respawn countdown display.
1662 =============
1663 */
1664 void ShowRespawnCountdown()
1665 {
1666         float number;
1667         if(self.deadflag == DEAD_NO) // just respawned?
1668                 return;
1669         else
1670         {
1671                 number = ceil(self.death_time - time);
1672                 if(number <= 0)
1673                         return;
1674                 if(number <= self.respawn_countdown)
1675                 {
1676                         self.respawn_countdown = number - 1;
1677                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1678                                 play2(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1679                 }
1680         }
1681 }
1682
1683 void LeaveSpectatorMode()
1684 {
1685         if(isJoinAllowed()) {
1686                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1687                         self.classname = "player";
1688                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1689                                 JoinBestTeam(self, FALSE, TRUE);
1690                         if(cvar("g_campaign"))
1691                                 campaign_bots_may_start = 1;
1692                         PutClientInServer();
1693                         if(!(self.flags & FL_NOTARGET))
1694                                 bprint ("^4", self.netname, "^4 is playing now\n");
1695                         centerprint(self,"");
1696                         return;
1697                 } else {
1698                         stuffcmd(self,"menu_showteamselect\n");
1699                         return;
1700                 }
1701         }
1702         else {
1703                 //player may not join because of g_maxplayers is set
1704                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1705         }
1706 }
1707
1708 /**
1709  * Determines whether the player is allowed to join. This depends on cvar
1710  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1711  * it checks whether the number of currently playing players exceeds g_maxplayers.
1712  * @return bool TRUE if the player is allowed to join, false otherwise
1713  */
1714 float isJoinAllowed() {
1715         if (!cvar("g_maxplayers"))
1716                 return TRUE;
1717
1718         local entity e;
1719         local float currentlyPlaying;
1720         FOR_EACH_REALPLAYER(e) {
1721                 if(e.classname == "player")
1722                         currentlyPlaying += 1;
1723         }
1724         if(currentlyPlaying < cvar("g_maxplayers"))
1725                 return TRUE;
1726
1727         return FALSE;
1728 }
1729
1730 /**
1731  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1732  * g_maxplayers_spectator_blocktime seconds
1733  */
1734 void checkSpectatorBlock() {
1735         if(self.classname == "spectator" || self.classname == "observer") {
1736                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1737                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1738                         dropclient(self);
1739                 }
1740         }
1741 }
1742
1743 float vercmp_recursive(string v1, string v2)
1744 {
1745         float dot1, dot2;
1746         string s1, s2;
1747         float r;
1748
1749         dot1 = strstrofs(v1, ".", 0);
1750         dot2 = strstrofs(v2, ".", 0);
1751         if(dot1 == -1)
1752                 s1 = v1;
1753         else
1754                 s1 = substring(v1, 0, dot1);
1755         if(dot2 == -1)
1756                 s2 = v2;
1757         else
1758                 s2 = substring(v2, 0, dot2);
1759
1760         r = stof(s1) - stof(s2);
1761         if(r != 0)
1762                 return r;
1763
1764         r = strcasecmp(s1, s2);
1765         if(r != 0)
1766                 return r;
1767
1768         if(dot1 == -1)
1769                 if(dot2 == -1)
1770                         return 0;
1771                 else
1772                         return -1;
1773         else
1774                 if(dot2 == -1)
1775                         return 1;
1776                 else
1777                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1778 }
1779
1780 float vercmp(string v1, string v2)
1781 {
1782         if(strcasecmp(v1, v2) == 0) // early out check
1783                 return 0;
1784         return vercmp_recursive(v1, v2);
1785 }
1786
1787 void ObserverThink()
1788 {
1789         if (self.flags & FL_JUMPRELEASED) {
1790                 if (self.BUTTON_JUMP && self.version == cvar("gameversion")) {
1791                         self.welcomemessage_time = 0;
1792                         self.flags = self.flags - FL_JUMPRELEASED;
1793                         LeaveSpectatorMode();
1794                         return;
1795                 } else if(self.BUTTON_ATCK && self.version == cvar("gameversion")) {
1796                         self.welcomemessage_time = 0;
1797                         self.flags = self.flags - FL_JUMPRELEASED;
1798                         if(SpectateNext() == 1) {
1799                                 self.classname = "spectator";
1800                         }
1801                 }
1802         } else {
1803                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
1804                         self.flags = self.flags | FL_JUMPRELEASED;
1805                 }
1806         }
1807         if(self.BUTTON_ZOOM)
1808                 self.wantswelcomemessage = 0;
1809         if(self.wantswelcomemessage)
1810                 PrintWelcomeMessage(self);
1811 }
1812
1813 void SpectatorThink()
1814 {
1815         if (self.flags & FL_JUMPRELEASED) {
1816                 if (self.BUTTON_JUMP && self.version == cvar("gameversion")) {
1817                         self.welcomemessage_time = 0;
1818                         self.flags = self.flags - FL_JUMPRELEASED;
1819                         LeaveSpectatorMode();
1820                         return;
1821                 } else if(self.BUTTON_ATCK) {
1822                         self.welcomemessage_time = 0;
1823                         self.flags = self.flags - FL_JUMPRELEASED;
1824                         if(SpectateNext() == 1) {
1825                                 self.classname = "spectator";
1826                         } else {
1827                                 self.classname = "observer";
1828                                 PutClientInServer();
1829                         }
1830                 } else if (self.BUTTON_ATCK2) {
1831                         self.welcomemessage_time = 0;
1832                         self.flags = self.flags - FL_JUMPRELEASED;
1833                         self.classname = "observer";
1834                         PutClientInServer();
1835                 } else {
1836                         if(!SpectateUpdate())
1837                                 PutObserverInServer();
1838                 }
1839         } else {
1840                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
1841                         self.flags = self.flags | FL_JUMPRELEASED;
1842                 }
1843         }
1844         if(self.BUTTON_ZOOM)
1845                 self.wantswelcomemessage = 0;
1846         if(self.wantswelcomemessage)
1847                 PrintWelcomeMessage(self);
1848         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1849 }
1850
1851 /*
1852 =============
1853 PlayerPreThink
1854
1855 Called every frame for each client before the physics are run
1856 =============
1857 */
1858 void() ctf_setstatus;
1859 .float vote_nagtime;
1860 void PlayerPreThink (void)
1861 {
1862         if(blockSpectators)
1863                 checkSpectatorBlock();
1864
1865         if(self.netname_previous != self.netname)
1866         {
1867                 if(cvar("sv_eventlog"))
1868                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname), TRUE);
1869                 if(self.netname_previous)
1870                         strunzone(self.netname_previous);
1871                 self.netname_previous = strzone(self.netname);
1872         }
1873
1874         // version nagging
1875         if(self.version_nagtime)
1876                 if(self.cvar_g_nexuizversion)
1877                         if(time > self.version_nagtime)
1878                         {
1879                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1880                                 {
1881                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
1882                                         {
1883                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1884                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1885                                         }
1886                                         else
1887                                         {
1888                                                 float r;
1889                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
1890                                                 if(r < 0)
1891                                                 {
1892                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
1893                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
1894                                                 }
1895                                                 else if(r > 0)
1896                                                 {
1897                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1898                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1899                                                 }
1900                                         }
1901                                 }
1902                                 self.version_nagtime = 0;
1903                         }
1904
1905         // vote nagging
1906         if(self.cvar_scr_centertime)
1907                 if(time > self.vote_nagtime)
1908                 {
1909                         VoteNag();
1910                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1911                 }
1912
1913         // GOD MODE info
1914         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
1915         {
1916                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
1917                 self.max_armorvalue = 0;
1918         }
1919
1920         if(frametime)
1921                 antilag_record(self);
1922
1923         if(self.classname == "player") {
1924 //              if(self.netname == "Wazat")
1925 //                      bprint(self.classname, "\n");
1926
1927                 CheckRules_Player();
1928
1929                 if(self.BUTTON_INFO)
1930                         PrintWelcomeMessage(self);
1931
1932                 if(g_lms || !cvar("sv_spectate"))
1933                 if((time - self.jointime) <= cvar("welcome_message_time"))
1934                         PrintWelcomeMessage(self);
1935
1936                 if (intermission_running)
1937                 {
1938                         IntermissionThink ();   // otherwise a button could be missed between
1939                         return;                                 // the think tics
1940                 }
1941
1942                 if(self.teleport_time)
1943                 if(time > self.teleport_time)
1944                 {
1945                         self.teleport_time = 0;
1946                         self.effects = self.effects - (self.effects & EF_NODRAW);
1947                         if(self.weaponentity)
1948                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
1949                 }
1950
1951                 Nixnex_GiveCurrentWeapon();
1952
1953                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
1954                         UpdateSelectedPlayer();
1955
1956                 //don't allow the player to turn around while game is paused!
1957                 if(timeoutStatus == 2) {
1958                         self.v_angle = self.lastV_angle;
1959                         self.angles = self.lastV_angle;
1960                         self.fixangle = TRUE;
1961                 }
1962
1963                 if (self.deadflag != DEAD_NO)
1964                 {
1965                         float button_pressed, force_respawn;
1966                         player_anim();
1967                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
1968                         force_respawn = (g_lms || cvar("g_forced_respawn"));
1969                         if (self.deadflag == DEAD_DYING)
1970                         {
1971                                 if(force_respawn)
1972                                         self.deadflag = DEAD_RESPAWNING;
1973                                 else if(!button_pressed)
1974                                         self.deadflag = DEAD_DEAD;
1975                         }
1976                         else if (self.deadflag == DEAD_DEAD)
1977                         {
1978                                 if(button_pressed)
1979                                         self.deadflag = DEAD_RESPAWNABLE;
1980                         }
1981                         else if (self.deadflag == DEAD_RESPAWNABLE)
1982                         {
1983                                 if(!button_pressed)
1984                                         self.deadflag = DEAD_RESPAWNING;
1985                         }
1986                         else if (self.deadflag == DEAD_RESPAWNING)
1987                         {
1988                                 if(time > self.death_time)
1989                                 {
1990                                         self.death_time = time + 1; // only retry once a second
1991                                         respawn();
1992                                 }
1993                         }
1994                         ShowRespawnCountdown();
1995                         return;
1996                 }
1997
1998                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
1999                 {
2000                         vector dist;
2001
2002                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2003                         dist = self.oldorigin - self.origin;
2004                         dist_z = 0;
2005                         self.lms_traveled_distance += fabs(vlen(dist));
2006
2007                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
2008                         {
2009                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2010                                 self.lms_traveled_distance = 0;
2011                         }
2012
2013                         if(time > self.lms_nextcheck)
2014                         {
2015                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2016                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2017                                 {
2018                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2019                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2020                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2021                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2022                                 }
2023                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2024                                 self.lms_traveled_distance = 0;
2025                         }
2026                 }
2027
2028                 if (self.BUTTON_CROUCH && !self.hook.state)
2029                 {
2030                         if (!self.crouch)
2031                         {
2032                                 self.crouch = TRUE;
2033                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2034                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2035                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
2036                         }
2037                 }
2038                 else
2039                 {
2040                         if (self.crouch)
2041                         {
2042                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2043                                 if (!trace_startsolid)
2044                                 {
2045                                         self.crouch = FALSE;
2046                                         self.view_ofs = PL_VIEW_OFS;
2047                                         setsize (self, PL_MIN, PL_MAX);
2048                                 }
2049                         }
2050                 }
2051
2052                 FixPlayermodel();
2053
2054                 GrapplingHookFrame();
2055
2056                 W_WeaponFrame();
2057
2058                 {
2059                         float zoomfactor, zoomspeed, zoomdir;
2060                         zoomfactor = self.cvar_cl_zoomfactor;
2061                         if(zoomfactor < 1 || zoomfactor > 16)
2062                                 zoomfactor = 2.5;
2063                         zoomspeed = self.cvar_cl_zoomspeed;
2064                         if(zoomspeed >= 0) // < 0 is instant zoom
2065                                 if(zoomspeed < 0.5 || zoomspeed > 16)
2066                                         zoomspeed = 3.5;
2067
2068                         zoomdir = self.BUTTON_ZOOM;
2069                         if(self.BUTTON_ATCK2)
2070                                 if(self.weapon == WEP_NEX)
2071                                         if(!g_minstagib)
2072                                                 zoomdir = 1;
2073
2074                         if(zoomdir)
2075                                 self.has_zoomed = 1;
2076
2077                         if(self.has_zoomed)
2078                         {
2079                                 if(zoomspeed <= 0) // instant zoom
2080                                 {
2081                                         if(zoomdir)
2082                                                 self.viewzoom = 1 / zoomfactor;
2083                                         else
2084                                                 self.viewzoom = 1;
2085                                 }
2086                                 else
2087                                 {
2088                                         // geometric zoom would be:
2089                                         //   self.viewzoom = bound(1 / zoomfactor, self.viewzoom * pow(zoomfactor, (zoomdir ? -1 : 1) * frametime * zoomspeed), 1);
2090                                         // however, testing showed that arithmetic/harmonic zoom works better
2091                                         if(zoomdir)
2092                                                 // self.viewzoom = 1 / bound(1, 1 / self.viewzoom + (zoomdir ? 1 : -1) * frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2093                                                 // zoom in = arithmetic: 1x, 2x, 3x, 4x, ..., 8x
2094                                                 self.viewzoom = 1 / bound(1, 1 / self.viewzoom + frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2095                                         else
2096                                                 // self.viewzoom = bound(1 / zoomfactor, self.viewzoom + (zoomdir ? -1 : 1) * frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2097                                                 // zoom out = harmonic: 8/1x, 8/2x, 8/3x, 8/4x, ..., 8/8x
2098                                                 self.viewzoom = bound(1 / zoomfactor, self.viewzoom + frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2099                                 }
2100                         }
2101                         else
2102                                 self.viewzoom = min(1, self.viewzoom + frametime); // spawn zoom-in
2103                 }
2104
2105                 player_powerups();
2106                 player_regen();
2107                 player_anim();
2108
2109                 if (g_minstagib)
2110                         minstagib_ammocheck();
2111
2112                 ctf_setstatus();
2113                 kh_setstatus();
2114
2115                 //self.angles_y=self.v_angle_y + 90;   // temp
2116
2117                 //if (TetrisPreFrame()) return;
2118         } else if(gameover) {
2119                 if (intermission_running)
2120                         IntermissionThink ();   // otherwise a button could be missed between
2121                 return;
2122         } else if(self.classname == "observer") {
2123                 ObserverThink();
2124         } else if(self.classname == "spectator") {
2125                 SpectatorThink();
2126         }
2127 }
2128
2129
2130 /*
2131 =============
2132 PlayerPostThink
2133
2134 Called every frame for each client after the physics are run
2135 =============
2136 */
2137 .float idlekick_lasttimeleft;
2138 void PlayerPostThink (void)
2139 {
2140         // Savage: Check for nameless players
2141         if (strlen(self.netname) < 1) {
2142                 self.netname = "Player";
2143                 stuffcmd(self, "seta _cl_name Player\n");
2144         }
2145
2146         if(sv_maxidle)
2147         {
2148                 float timeleft;
2149                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2150                 if(timeleft <= 0)
2151                 {
2152                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2153                         play2(self, "announcer/robotic/terminated.ogg");
2154                         dropclient(self);
2155                         return;
2156                 }
2157                 else if(timeleft <= 10)
2158                 {
2159                         if(timeleft != self.idlekick_lasttimeleft)
2160                         {
2161                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2162                                 play2(self, strcat("announcer/robotic/", ftos(timeleft), ".ogg"));
2163                         }
2164                 }
2165                 else
2166                 {
2167                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2168                 }
2169                 self.idlekick_lasttimeleft = timeleft;
2170         }
2171
2172         if(self.classname == "player") {
2173                 CheckRules_Player();
2174                 UpdateChatBubble();
2175                 UpdateTeamBubble();
2176                 if (self.impulse)
2177                         ImpulseCommands();
2178                 if (intermission_running)
2179                         return;         // intermission or finale
2180
2181                 //PrintWelcomeMessage(self);
2182                 //if (TetrisPostFrame()) return;
2183
2184                 // restart countdown
2185                 if (restart_countdown) {
2186                         if(time < restart_countdown) {
2187                                 if (!cvar("sv_ready_restart_after_countdown"))
2188                                 {
2189                                         self.movetype = MOVETYPE_NONE;
2190                                         self.velocity = '0 0 0';
2191                                         self.avelocity = '0 0 0';
2192                                         self.movement = '0 0 0';
2193                                 }
2194                         }
2195                         else
2196                         {
2197                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2198                                 if (!cvar("sv_ready_restart_after_countdown"))
2199                                 {
2200                                         if(self.movetype == MOVETYPE_NONE)
2201                                         {
2202                                                 self.movetype = MOVETYPE_WALK;
2203                                         }
2204                                 }
2205                         }
2206                 }
2207
2208         } else if (self.classname == "observer") {
2209                 //do nothing
2210         } else if (self.classname == "spectator") {
2211                 //do nothing
2212         }
2213
2214         /*
2215         float i;
2216         for(i = 0; i < 1000; ++i)
2217         {
2218                 vector end;
2219                 end = self.origin + '0 0 1024' + 512 * randomvec();
2220                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2221                 if(trace_fraction < 1)
2222                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2223                 {
2224                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2225                         break;
2226                 }
2227         }
2228         */
2229
2230         Arena_Warmup();
2231 }