data/qcsrc/server/cl_client.qc

   1 void info_player_start (void)
   2 {
   3         self.classname = "info_player_deathmatch";
   4         relocate_spawnpoint();
   5 }
   6
   7 void info_player_deathmatch (void)
   8 {
   9         relocate_spawnpoint();
  10 }
  11
  12 float spawn_allbad;
  13 float spawn_allgood;
  14 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  15 {
  16         local entity spot, player, nextspot, previousspot, newfirstspot;
  17         local float pcount;
  18         spot = firstspot;
  19         newfirstspot = world;
  20         previousspot = world;
  21         spawn_allgood = TRUE;
  22         spawn_allbad = TRUE;
  23         while (spot)
  24         {
  25                 nextspot = spot.chain;
  26                 // count team mismatches as bad spots
  27                 if (spot.team == teamcheck)
  28                 {
  29                         pcount = 0;
  30                         player = playerlist;
  31                         while (player)
  32                         {
  33                                 if (player != self)
  34                                 if (vlen(player.origin - spot.origin) < mindist)
  35                                         pcount = pcount + 1;
  36                                 player = player.chain;
  37                         }
  38                         if (!pcount)
  39                         {
  40                                 spawn_allbad = FALSE;
  41                                 if (newfirstspot)
  42                                         previousspot.chain = spot;
  43                                 else
  44                                         newfirstspot = spot;
  45                                 previousspot = spot;
  46                                 spot.chain = world;
  47                         }
  48                         else
  49                                 spawn_allgood = FALSE;
  50                 }
  51                 spot = nextspot;
  52         }
  53         // if we couldn't find ANY good points, return the original list
  54         if (!newfirstspot)
  55                 newfirstspot = firstspot;
  56         return newfirstspot;
  57 }
  58
  59 entity Spawn_RandomPoint(entity firstspot)
  60 {
  61         local entity spot;
  62         local float numspots;
  63         // count number of spots
  64         numspots = 0;
  65         spot = firstspot;
  66         while (spot)
  67         {
  68                 numspots = numspots + 1;
  69                 spot = spot.chain;
  70         }
  71         // pick a random one
  72         numspots = numspots * random();
  73         spot = firstspot;
  74         while (spot.chain && numspots >= 1)
  75         {
  76                 numspots = numspots - 1;
  77                 spot = spot.chain;
  78         }
  79         return spot;
  80 }
  81
  82 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  83 {
  84         local entity best, spot, player;
  85         local float bestrating, rating;
  86         best = world;
  87         bestrating = -1000000;
  88         spot = firstspot;
  89         while (spot)
  90         {
  91                 rating = 1000000000;
  92                 player = playerlist;
  93                 while (player)
  94                 {
  95                         if (player != self)
  96                                 rating = min(rating, vlen(player.origin - spot.origin));
  97                         player = player.chain;
  98                 }
  99                 rating = rating + random() * 16;
 100                 if (bestrating < rating)
 101                 {
 102                         best = spot;
 103                         bestrating = rating;
 104                 }
 105                 spot = spot.chain;
 106         }
 107         return best;
 108 }
 109
 110 /*
 111 =============
 112 SelectSpawnPoint
 113
 114 Finds a point to respawn
 115 =============
 116 */
 117 entity SelectSpawnPoint (float anypoint)
 118 {
 119         local float teamcheck;
 120         local entity spot, firstspot, playerlist;
 121
 122         spot = find (world, classname, "testplayerstart");
 123         if (spot)
 124                 return spot;
 125
 126         teamcheck = 0;
 127
 128         if(!anypoint && cvar("g_ctf") )
 129                 teamcheck = self.team;
 130
 131         // get the list of players
 132         playerlist = findchain(classname, "player");
 133         // get the entire list of spots
 134         firstspot = findchain(classname, "info_player_deathmatch");
 135         // filter out the bad ones
 136         // (note this returns the original list if none survived)
 137         firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 138
 139         // there is 50/50 chance of choosing a random spot or the furthest spot
 140         // (this means that roughly every other spawn will be furthest, so you
 141         // usually won't get fragged at spawn twice in a row)
 142         if (arena_roundbased)
 143         {
 144                 firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 145                 spot = Spawn_RandomPoint(firstspot);
 146         }
 147         else if (random() > 0.5 || spawn_allbad || spawn_allgood)
 148                 spot = Spawn_RandomPoint(firstspot);
 149         else
 150                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 151
 152         if (!spot)
 153         {
 154                 if(cvar("spawn_debug"))
 155                         GotoNextMap();
 156                 else
 157                         error ("PutClientInServer: no start points on level");
 158         }
 159
 160         return spot;
 161 }
 162
 163 /*
 164 =============
 165 CheckPlayerModel
 166
 167 Checks if the argument string can be a valid playermodel.
 168 Returns a valid one in doubt.
 169 =============
 170 */
 171 string FallbackPlayerModel = "models/player/marine.zym";
 172 string CheckPlayerModel(string plyermodel) {
 173         if(strlen(plyermodel) < 4)
 174                 return FallbackPlayerModel;
 175         if( substring(plyermodel,0,14) != "models/player/")
 176                 return FallbackPlayerModel;
 177         else if(cvar("sv_servermodelsonly"))
 178         {
 179                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 180                         return FallbackPlayerModel;
 181                 if(!fexists(plyermodel))
 182                         return FallbackPlayerModel;
 183         }
 184         return plyermodel;
 185 }
 186
 187 /*
 188 =============
 189 Client_customizeentityforclient
 190
 191 LOD reduction
 192 =============
 193 */
 194 float Client_customizeentityforclient()
 195 {
 196 #ifdef ALLOW_VARIABLE_LOD
 197         // self: me
 198         // other: the player viewing me
 199         float distance;
 200         float f;
 201
 202         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 203                 return TRUE;
 204
 205         if(other.cvar_cl_playerdetailreduction <= 0)
 206         {
 207                 if(other.cvar_cl_playerdetailreduction <= -2)
 208                         self.modelindex = self.modelindex_lod2;
 209                 else if(other.cvar_cl_playerdetailreduction <= -1)
 210                         self.modelindex = self.modelindex_lod1;
 211                 else
 212                         self.modelindex = self.modelindex_lod0;
 213         }
 214         else
 215         {
 216                 distance = vlen(self.origin - other.origin);
 217                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 218                 if(f > 10000)
 219                         self.modelindex = self.modelindex_lod2;
 220                 else if(f > 5000)
 221                         self.modelindex = self.modelindex_lod1;
 222                 else
 223                         self.modelindex = self.modelindex_lod0;
 224         }
 225 #endif
 226
 227         return TRUE;
 228 }
 229
 230 void setmodel_lod(entity e, string modelname)
 231 {
 232 #ifdef ALLOW_VARIABLE_LOD
 233         string s;
 234
 235         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1.zym");
 236         if(fexists(s))
 237         {
 238                 precache_model(s);
 239                 setmodel(e, s);
 240                 self.modelindex_lod1 = self.modelindex;
 241         }
 242         else
 243                 self.modelindex_lod1 = -1;
 244
 245         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2.zym");
 246         if(fexists(s))
 247         {
 248                 precache_model(s);
 249                 setmodel(e, s);
 250                 self.modelindex_lod2 = self.modelindex;
 251         }
 252         else
 253                 self.modelindex_lod2 = -1;
 254
 255         precache_model(modelname);
 256         setmodel(e, modelname);
 257         self.modelindex_lod0 = self.modelindex;
 258
 259         if(self.modelindex_lod1 < 0)
 260                 self.modelindex_lod1 = self.modelindex;
 261
 262         if(self.modelindex_lod2 < 0)
 263                 self.modelindex_lod2 = self.modelindex;
 264 #else
 265         precache_model(modelname);
 266         setmodel(e, modelname);
 267 #endif
 268 }
 269
 270 /*
 271 =============
 272 PutObserverInServer
 273
 274 putting a client as observer in the server
 275 =============
 276 */
 277 void PutObserverInServer (void)
 278 {
 279         entity  spot;
 280         spot = SelectSpawnPoint (FALSE);
 281         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 282
 283         if(clienttype(self) == CLIENTTYPE_REAL)
 284         {
 285                 msg_entity = self;
 286                 WriteByte(MSG_ONE, SVC_SETVIEW);
 287                 WriteEntity(MSG_ONE, self);
 288         }
 289
 290         if (cvar("g_runematch"))
 291                 DropAllRunes(self);
 292
 293         DistributeFragsAmongTeam(self, self.team, 1);
 294
 295         if(self.frags <= 0 && self.frags > -666 && cvar("g_lms") && self.killcount != -666)
 296                 bprint (strcat("^4", self.netname, "^4 has no more lives left\n"));
 297         else if(self.killcount != -666)
 298                 bprint (strcat("^4", self.netname, "^4 is spectating now\n"));
 299
 300         self.classname = "observer";
 301         self.health = -666;
 302         self.takedamage = DAMAGE_NO;
 303         self.solid = SOLID_NOT;
 304         self.movetype = MOVETYPE_NOCLIP;
 305         self.flags = FL_CLIENT | FL_NOTARGET;
 306         self.armorvalue = 666;
 307         self.effects = 0;
 308         self.armorvalue = cvar("g_balance_armor_start");
 309         self.pauserotarmor_finished = 0;
 310         self.pauserothealth_finished = 0;
 311         self.pauseregen_finished = 0;
 312         self.damageforcescale = 0;
 313         self.death_time = 0;
 314         self.dead_time = 0;
 315         self.dead_frame = 0;
 316         self.die_frame = 0;
 317         self.deaths = 0;
 318         self.alpha = 0;
 319         self.scale = 0;
 320         self.fade_time = 0;
 321         self.pain_frame = 0;
 322         self.pain_finished = 0;
 323         self.strength_finished = 0;
 324         self.invincible_finished = 0;
 325         self.pushltime = 0;
 326         self.think = SUB_Null;
 327         self.nextthink = 0;
 328         self.hook_time = 0;
 329         self.runes = 0;
 330         self.deadflag = DEAD_NO;
 331         self.angles = spot.angles;
 332         self.angles_z = 0;
 333         self.fixangle = TRUE;
 334         self.crouch = FALSE;
 335
 336         self.view_ofs = PL_VIEW_OFS;
 337         setorigin (self, spot.origin);
 338         setsize (self, '0 0 0', '0 0 0');
 339         self.oldorigin = self.origin;
 340         self.items = 0;
 341         self.model = "";
 342         self.modelindex = 0;
 343         self.weapon = 0;
 344         self.weaponmodel = "";
 345         self.weaponentity = world;
 346         self.killcount = -666;
 347         self.velocity = '0 0 0';
 348         self.avelocity = '0 0 0';
 349         self.punchangle = '0 0 0';
 350         self.punchvector = '0 0 0';
 351         self.oldvelocity = self.velocity;
 352         self.customizeentityforclient = Client_customizeentityforclient;
 353
 354         if(cvar("g_arena"))
 355         {
 356                 if(self.frags != -2)
 357                 {
 358                         Spawnqueue_Insert(self);
 359                 }
 360                 else
 361                 {
 362                         Spawnqueue_Unmark(self);
 363                         Spawnqueue_Remove(self);
 364                 }
 365         }
 366         else if(!cvar("g_lms"))
 367                 self.frags = -666;
 368 }
 369
 370
 371 /*
 372 =============
 373 PutClientInServer
 374
 375 Called when a client spawns in the server
 376 =============
 377 */
 378 void PutClientInServer (void)
 379 {
 380         if(clienttype(self) == CLIENTTYPE_BOT)
 381         {
 382                 self.classname = "player";
 383         }
 384         else if(clienttype(self) == CLIENTTYPE_REAL)
 385         {
 386                 msg_entity = self;
 387                 WriteByte(MSG_ONE, SVC_SETVIEW);
 388                 WriteEntity(MSG_ONE, self);
 389         }
 390
 391         // player is dead and becomes observer
 392         if(cvar("g_lms") && self.frags < 1)
 393                 self.classname = "observer";
 394
 395         if(cvar("g_arena"))
 396         if(!self.spawned)
 397                 self.classname = "observer";
 398
 399         if(self.classname == "player") {
 400                 entity  spot;
 401
 402                 spot = SelectSpawnPoint (FALSE);
 403
 404                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 405
 406                 self.classname = "player";
 407                 self.iscreature = TRUE;
 408                 self.movetype = MOVETYPE_WALK;
 409                 self.solid = SOLID_SLIDEBOX;
 410                 self.flags = FL_CLIENT;
 411                 self.takedamage = DAMAGE_AIM;
 412                 self.effects = 0;
 413                 self.health = cvar("g_balance_health_start");
 414                 self.armorvalue = cvar("g_balance_armor_start");
 415                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 416                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 417                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 418                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 419                 self.damageforcescale = 2;
 420                 self.death_time = 0;
 421                 self.dead_time = 0;
 422                 self.dead_frame = 0;
 423                 self.die_frame = 0;
 424                 self.alpha = 0;
 425                 self.scale = 0;
 426                 self.fade_time = 0;
 427                 self.pain_frame = 0;
 428                 self.pain_finished = 0;
 429                 self.strength_finished = 0;
 430                 self.invincible_finished = 0;
 431                 self.pushltime = 0;
 432                 //self.speed_finished = 0;
 433                 //self.slowmo_finished = 0;
 434                 // players have no think function
 435                 self.think = SUB_Null;
 436                 self.nextthink = 0;
 437                 self.weapon = 0;
 438                 self.switchweapon = 0;
 439                 self.hook_time = 0;
 440
 441                 self.runes = 0;
 442
 443                 self.deadflag = DEAD_NO;
 444
 445                 self.angles = spot.angles;
 446
 447                 self.angles_z = 0; // never spawn tilted even if the spot says to
 448                 self.fixangle = TRUE; // turn this way immediately
 449                 self.velocity = '0 0 0';
 450                 self.avelocity = '0 0 0';
 451                 self.punchangle = '0 0 0';
 452                 self.punchvector = '0 0 0';
 453                 self.oldvelocity = self.velocity;
 454
 455                 self.viewzoom = 0.6;
 456
 457                 self.customizeentityforclient = Client_customizeentityforclient;
 458
 459                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
 460                         local string defaultmodel;
 461                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
 462                         setmodel_lod (self, defaultmodel);
 463                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 464                 } else {
 465                         self.playermodel = CheckPlayerModel(self.playermodel);
 466                         setmodel_lod (self, self.playermodel);
 467                         self.skin = stof(self.playerskin);
 468
 469                 }
 470
 471                 self.crouch = FALSE;
 472                 self.view_ofs = PL_VIEW_OFS;
 473                 setsize (self, PL_MIN, PL_MAX);
 474                 self.spawnorigin = spot.origin;
 475                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 476                 // don't reset back to last position, even if new position is stuck in solid
 477                 self.oldorigin = self.origin;
 478
 479                 if(cvar("g_lms"))
 480                 {
 481                         self.ammo_shells = cvar("g_lms_start_ammo_shells");
 482                         self.ammo_nails = cvar("g_lms_start_ammo_nails");
 483                         self.ammo_rockets = cvar("g_lms_start_ammo_rockets");
 484                         self.ammo_cells = cvar("g_lms_start_ammo_cells");
 485                         self.health = cvar("g_lms_start_health");
 486                         self.armorvalue = cvar("g_lms_start_armor");
 487                 }
 488                 else if (cvar("g_use_ammunition")) {
 489                         self.ammo_shells = cvar("g_start_ammo_shells");
 490                         self.ammo_nails = cvar("g_start_ammo_nails");
 491                         self.ammo_rockets = cvar("g_start_ammo_rockets");
 492                         self.ammo_cells = cvar("g_start_ammo_cells");
 493                 } else {
 494                         self.ammo_shells = 999;
 495                         self.ammo_nails = 999;
 496                         self.ammo_rockets = 999;
 497                         self.ammo_cells = 999;
 498                 }
 499
 500                 self.items = 0;
 501                 if (cvar("g_start_weapon_laser") || cvar("g_lms"))
 502                 {
 503                         self.items = self.items | IT_LASER;
 504                         self.switchweapon = WEP_LASER;
 505                 }
 506                 if (cvar("g_start_weapon_shotgun") || cvar("g_lms"))
 507                 {
 508                         self.items = self.items | IT_SHOTGUN;
 509                         self.switchweapon = WEP_SHOTGUN;
 510                 }
 511                 if (cvar("g_start_weapon_uzi") || cvar("g_lms"))
 512                 {
 513                         self.items = self.items | IT_UZI;
 514                         self.switchweapon = WEP_UZI;
 515                 }
 516                 if (cvar("g_start_weapon_grenadelauncher") || cvar("g_lms"))
 517                 {
 518                         self.items = self.items | IT_GRENADE_LAUNCHER;
 519                         self.switchweapon = WEP_GRENADE_LAUNCHER;
 520                 }
 521                 if (cvar("g_start_weapon_electro") || cvar("g_lms"))
 522                 {
 523                         self.items = self.items | IT_ELECTRO;
 524                         self.switchweapon = WEP_ELECTRO;
 525                 }
 526                 if (cvar("g_start_weapon_crylink") || cvar("g_lms"))
 527                 {
 528                         self.items = self.items | IT_CRYLINK;
 529                         self.switchweapon = WEP_CRYLINK;
 530                 }
 531                 if (cvar("g_start_weapon_nex") || cvar("g_lms"))
 532                 {
 533                         self.items = self.items | IT_NEX;
 534                         self.switchweapon = WEP_NEX;
 535                 }
 536                 if (cvar("g_start_weapon_hagar") || cvar("g_lms"))
 537                 {
 538                         self.items = self.items | IT_HAGAR;
 539                         self.switchweapon = WEP_HAGAR;
 540                 }
 541                 if (cvar("g_start_weapon_rocketlauncher") || cvar("g_lms"))
 542                 {
 543                         self.items = self.items | IT_ROCKET_LAUNCHER;
 544                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 545                 }
 546
 547                 if(cvar("g_instagib"))
 548                 {
 549                         self.items = IT_NEX;
 550                         self.switchweapon = WEP_NEX;
 551                         self.ammo_cells = 999;
 552                 }
 553
 554                 if(cvar("g_rocketarena"))
 555                 {
 556                         self.items = IT_ROCKET_LAUNCHER;
 557                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 558                         self.ammo_rockets = 999;
 559                 }
 560
 561                 if(cvar("g_nixnex"))
 562                 {
 563                         self.items = 0;
 564                         // will be done later
 565                 }
 566
 567                 if(cvar("g_minstagib"))
 568                 {
 569                         self.health = 100;
 570                         self.armorvalue = 0;
 571                         self.items = IT_NEX;
 572                         self.switchweapon = WEP_NEX;
 573                         self.ammo_cells = cvar("g_minstagib_ammo_start");
 574                         self.extralives = 0;
 575                         self.jump_interval = time;
 576                 }
 577
 578                 if(cvar("g_arena"))
 579                 {
 580                         Spawnqueue_Remove(self);
 581                         Spawnqueue_Mark(self);
 582                 }
 583
 584                 self.event_damage = PlayerDamage;
 585
 586                 self.bot_attack = TRUE;
 587
 588                 self.statdraintime = time + 5;
 589                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 590
 591                 if(self.killcount == -666) {
 592                         self.killcount = 0;
 593                         if(!cvar("g_arena"))
 594                         if(!cvar("g_lms"))
 595                                 self.frags = 0;
 596                 }
 597
 598                 self.cnt = WEP_LASER;
 599                 self.nixnex_lastchange_id = -1;
 600
 601                 CL_SpawnWeaponentity();
 602                 self.alpha = default_player_alpha;
 603                 self.exteriorweaponentity.alpha = default_player_alpha;
 604
 605                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 606                 self.lms_traveled_distance = 0;
 607
 608                 if(cvar("spawn_debug"))
 609                 {
 610                                 sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 611                                 remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 612                 }
 613
 614                 //stuffcmd(self, "chase_active 0");
 615                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 616         } else if(self.classname == "observer") {
 617                 PutObserverInServer ();
 618         }
 619 }
 620
 621 /*
 622 =============
 623 SetNewParms
 624 =============
 625 */
 626 void SetNewParms (void)
 627 {
 628
 629 }
 630
 631 /*
 632 =============
 633 SetChangeParms
 634 =============
 635 */
 636 void SetChangeParms (void)
 637 {
 638
 639 }
 640
 641 /*
 642 =============
 643 ClientKill
 644
 645 Called when a client types 'kill' in the console
 646 =============
 647 */
 648 void ClientKill (void)
 649 {
 650         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 651 }
 652
 653 /*
 654 =============
 655 ClientConnect
 656
 657 Called when a client connects to the server
 658 =============
 659 */
 660 string ColoredTeamName(float t);
 661 //void dom_player_join_team(entity pl);
 662 void ClientConnect (void)
 663 {
 664         local float fh;
 665         local string s;
 666
 667         self.classname = "player_joining";
 668         self.flags = self.flags | FL_CLIENT;
 669
 670         if(player_count<0) player_count = 0;
 671
 672         bot_clientconnect();
 673
 674         //if(cvar("g_domination"))
 675         //      dom_player_join_team(self);
 676
 677         //JoinBestTeam(self, FALSE);
 678
 679         if((cvar("sv_spectate") == 1 && !cvar("g_lms")) || cvar("g_campaign")) {
 680                 self.classname = "observer";
 681         } else {
 682                 self.classname = "player";
 683                 campaign_bots_may_start = 1;
 684         }
 685
 686         self.playerid = (playerid_last = playerid_last + 1);
 687         if(cvar("sv_eventlog"))
 688         {
 689                 if(clienttype(self) == CLIENTTYPE_REAL)
 690                         s = "player";
 691                 else
 692                         s = "bot";
 693                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 694                 s = strcat(":team:", ftos(self.playerid), ":");
 695                 s = strcat(s, ftos(self.team));
 696                 GameLogEcho(s, FALSE);
 697         }
 698
 699         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 700
 701         bprint ("^4",self.netname);
 702         bprint ("^4 connected");
 703
 704         if(cvar("g_domination") || cvar("g_ctf"))
 705         {
 706                 bprint(" and joined the ");
 707                 bprint(ColoredTeamName(self.team));
 708         }
 709
 710         bprint("\n");
 711
 712         self.welcomemessage_time = time + cvar("welcome_message_time");
 713         self.welcomemessage_time2 = 0;
 714
 715         // the client might not have his maps/%s.cfg file yet!
 716         // so send the one from the server...
 717         fh = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 718         if(fh >= 0)
 719         {
 720                 while((s = fgets(fh)))
 721                         stuffcmd(self, strcat(s, "\n"));
 722                 fclose(fh);
 723         }
 724         // and then execute the client's so he can still override CD tracks
 725         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 726
 727         // TODO: is this being used for anything else than cd tracks?
 728         // Remember: SVC_CDTRACK exists. Maybe it should be used.
 729
 730         // send prediction settings to the client
 731         stuffcmd(self, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 732         stuffcmd(self, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 733         stuffcmd(self, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 734         stuffcmd(self, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 735         stuffcmd(self, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 736         stuffcmd(self, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 737         stuffcmd(self, strcat("cl_movement_jumpvelocity ", ftos(cvar("g_balance_jumpheight")), "\n"));
 738         stuffcmd(self, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 739         stuffcmd(self, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 740         stuffcmd(self, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 741         stuffcmd(self, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 742         stuffcmd(self, strcat("cl_movement_edgefriction 0\n"));
 743         // Wazat's grappling hook
 744         SetGrappleHookBindings();
 745
 746         // get autoswitch state from player
 747         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1; cmd autoswitch $1\"\n");
 748         stuffcmd(self, "cmd autoswitch $cl_autoswitch\n");
 749
 750         // get version info from player
 751         stuffcmd(self, "cmd clientversion $gameversion\n");
 752
 753         // get other cvars from player
 754         GetCvars(0);
 755
 756         // set cvar for team scoreboard
 757         if (teams_matter)
 758         {
 759                 local float t;
 760                 t = cvar("teamplay");
 761                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
 762                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
 763         }
 764         else
 765                 stuffcmd(self, strcat("set teamplay 0\n"));
 766
 767         if(cvar("g_lms"))
 768         {
 769                 self.frags = cvar("fraglimit");
 770                 // no fraglimit was set, so player gets 999 lives
 771                 if(self.frags < 1)
 772                         self.frags = 999;
 773
 774                 // disallow player to join after the worst player has lost g_lms_last_join lives
 775                 // if "g_lms_join_anytime" new players spawn with same amount of lives as the worst active player
 776                 if(((cvar("fraglimit") - cvar("g_lms_last_join")) > lms_lowest_lives && !cvar("g_lms_join_anytime")) || lms_lowest_lives < 1)
 777                 {
 778                         self.frags = -666;
 779                         lms_dead_count += 1;
 780                 }
 781                 else if(cvar("fraglimit") > lms_lowest_lives)
 782                 {
 783                         self.frags = lms_lowest_lives;
 784                 }
 785         }
 786         else if(cvar("g_arena"))
 787         {
 788                 self.classname = "observer";
 789                 Spawnqueue_Insert(self);
 790         }
 791
 792         bot_relinkplayerlist();
 793
 794         self.jointime = time;
 795 }
 796
 797 /*
 798 =============
 799 ClientDisconnect
 800
 801 Called when a client disconnects from the server
 802 =============
 803 */
 804 void(entity e) DropFlag;
 805 .entity chatbubbleentity;
 806 .entity teambubbleentity;
 807 void ClientDisconnect (void)
 808 {
 809         float save;
 810         if(cvar("sv_eventlog"))
 811                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
 812         bprint ("^4",self.netname);
 813         bprint ("^4 disconnected\n");
 814
 815         if (self.chatbubbleentity)
 816         {
 817                 remove (self.chatbubbleentity);
 818                 self.chatbubbleentity = world;
 819         }
 820
 821         if (self.teambubbleentity)
 822         {
 823                 remove (self.teambubbleentity);
 824                 self.teambubbleentity = world;
 825         }
 826
 827         DropAllRunes(self);
 828
 829         if(self.flagcarried)
 830                 DropFlag(self.flagcarried);
 831
 832         DistributeFragsAmongTeam(self, self.team, 1);
 833
 834         save = self.flags;
 835         self.flags = self.flags - (self.flags & FL_CLIENT);
 836         bot_relinkplayerlist();
 837         self.flags = save;
 838
 839         // remove laserdot
 840         if(self.weaponentity)
 841                 if(self.weaponentity.lasertarget)
 842                         remove(self.weaponentity.lasertarget);
 843
 844         // player was dead, decrease dead count
 845         if(cvar("g_lms") && self.frags < 1)
 846                 lms_dead_count -= 1;
 847         else if(cvar("g_arena"))
 848         {
 849                 Spawnqueue_Unmark(self);
 850                 Spawnqueue_Remove(self);
 851         }
 852 }
 853
 854 .float buttonchat;
 855 void() ChatBubbleThink =
 856 {
 857         self.nextthink = time;
 858         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 859         {
 860                 self.owner.chatbubbleentity = world;
 861                 remove(self);
 862                 return;
 863         }
 864         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 865         if (self.owner.buttonchat && !self.owner.deadflag)
 866                 self.model = self.mdl;
 867         else
 868                 self.model = "";
 869 };
 870
 871 void() UpdateChatBubble =
 872 {
 873         if (!self.modelindex)
 874                 return;
 875         // spawn a chatbubble entity if needed
 876         if (!self.chatbubbleentity)
 877         {
 878                 self.chatbubbleentity = spawn();
 879                 self.chatbubbleentity.owner = self;
 880                 self.chatbubbleentity.exteriormodeltoclient = self;
 881                 self.chatbubbleentity.think = ChatBubbleThink;
 882                 self.chatbubbleentity.nextthink = time;
 883                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr");
 884                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 885                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 886                 self.chatbubbleentity.model = "";
 887         }
 888 }
 889
 890
 891 void() TeamBubbleThink =
 892 {
 893         self.nextthink = time;
 894         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 895         {
 896                 self.owner.teambubbleentity = world;
 897                 remove(self);
 898                 return;
 899         }
 900 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 901         if (self.owner.buttonchat || self.owner.deadflag)
 902                 self.model = "";
 903         else
 904                 self.model = self.mdl;
 905
 906 };
 907
 908 float() ChatBubble_customizeentityforclient = {return (self.owner.team == other.team && other.killcount > -666);};
 909
 910 void() UpdateTeamBubble =
 911 {
 912         if (!self.modelindex || !cvar("teamplay"))
 913                 return;
 914         // spawn a teambubble entity if needed
 915         if (!self.teambubbleentity && cvar("teamplay"))
 916         {
 917                 self.teambubbleentity = spawn();
 918                 self.teambubbleentity.owner = self;
 919                 self.teambubbleentity.exteriormodeltoclient = self;
 920                 self.teambubbleentity.think = TeamBubbleThink;
 921                 self.teambubbleentity.nextthink = time;
 922                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr");
 923 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 924                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 925                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 926                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 927                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 928                 self.teambubbleentity.customizeentityforclient = ChatBubble_customizeentityforclient;
 929         }
 930 }
 931
 932 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 933 // added to the model skins
 934 /*void() UpdateColorModHack =
 935 {
 936         local float c;
 937         c = self.clientcolors & 15;
 938         // LordHavoc: only bothering to support white, green, red, yellow, blue
 939              if (teamplay == 0) self.colormod = '0 0 0';
 940         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 941         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 942         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 943         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 944         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 945         else self.colormod = '1 1 1';
 946 };*/
 947
 948 /*
 949 =============
 950 PlayerJump
 951
 952 When you press the jump key
 953 =============
 954 */
 955 void PlayerJump (void)
 956 {
 957         float mjumpheight;
 958
 959         mjumpheight = cvar("g_balance_jumpheight");
 960         if (self.waterlevel >= 2)
 961         {
 962                 if (self.watertype == CONTENT_WATER)
 963                         self.velocity_z = 200;
 964                 else if (self.watertype == CONTENT_SLIME)
 965                         self.velocity_z = 80;
 966                 else
 967                         self.velocity_z = 50;
 968
 969                 return;
 970         }
 971
 972
 973         if (!(self.flags & FL_ONGROUND))
 974                 return;
 975
 976         if (!(self.flags & FL_JUMPRELEASED))
 977                 return;
 978
 979         if(cvar("g_runematch"))
 980         {
 981                 if(self.runes & RUNE_SPEED)
 982                 {
 983                         if(self.runes & CURSE_SLOW)
 984                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
 985                         else
 986                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 987                 }
 988                 else if(self.runes & CURSE_SLOW)
 989                 {
 990                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
 991                 }
 992         }
 993
 994         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
 995         {
 996                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 997         }
 998
 999         self.velocity_z = self.velocity_z + mjumpheight;
1000         self.oldvelocity_z = self.velocity_z;
1001
1002         self.flags = self.flags - FL_ONGROUND;
1003         self.flags = self.flags - FL_JUMPRELEASED;
1004 }
1005
1006 void() CheckWaterJump =
1007 {
1008         local vector start, end;
1009
1010 // check for a jump-out-of-water
1011         makevectors (self.angles);
1012         start = self.origin;
1013         start_z = start_z + 8;
1014         v_forward_z = 0;
1015         normalize(v_forward);
1016         end = start + v_forward*24;
1017         traceline (start, end, TRUE, self);
1018         if (trace_fraction < 1)
1019         {       // solid at waist
1020                 start_z = start_z + self.maxs_z - 8;
1021                 end = start + v_forward*24;
1022                 self.movedir = trace_plane_normal * -50;
1023                 traceline (start, end, TRUE, self);
1024                 if (trace_fraction == 1)
1025                 {       // open at eye level
1026                         self.flags = self.flags | FL_WATERJUMP;
1027                         self.velocity_z = 225;
1028                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
1029                         self.teleport_time = time + 2;  // safety net
1030                         return;
1031                 }
1032         }
1033 };
1034
1035
1036 void respawn(void)
1037 {
1038         CopyBody(1);
1039         PutClientInServer();
1040 }
1041
1042 void player_powerups (void)
1043 {
1044         if (cvar("g_minstagib"))
1045         {
1046                 self.effects = EF_FULLBRIGHT;
1047                 if (self.items & IT_STRENGTH)
1048                 {
1049                         if (time > self.strength_finished)
1050                         {
1051                                 self.alpha = default_player_alpha;
1052                                 self.exteriorweaponentity.alpha = default_player_alpha;
1053                                 self.items = self.items - (self.items & IT_STRENGTH);
1054                                 sprint(self, "^3Invisibility has worn off\n");
1055                         }
1056                 }
1057                 else
1058                 {
1059                         if (time < self.strength_finished)
1060                         {
1061                                 self.alpha = cvar("g_minstagib_invis_alpha");
1062                                 self.exteriorweaponentity.alpha = cvar("g_minstagib_invis_alpha");
1063                                 self.items = self.items | IT_STRENGTH;
1064                                 sprint(self, "^3You are invisible\n");
1065                         }
1066                 }
1067
1068                 if (self.items & IT_INVINCIBLE)
1069                 {
1070                         if (time > self.invincible_finished)
1071                         {
1072                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1073                                 sprint(self, "^3Speed has worn off\n");
1074                         }
1075                 }
1076                 else
1077                 {
1078                         if (time < self.invincible_finished)
1079                         {
1080                                 self.items = self.items | IT_INVINCIBLE;
1081                                 sprint(self, "^3You are on speed\n");
1082                         }
1083                 }
1084                 return;
1085         }
1086
1087         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1088         if (self.items & IT_STRENGTH)
1089         {
1090                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1091                 if (time > self.strength_finished)
1092                 {
1093                         self.items = self.items - (self.items & IT_STRENGTH);
1094                         sprint(self, "^3Strength has worn off\n");
1095                 }
1096         }
1097         else
1098         {
1099                 if (time < self.strength_finished)
1100                 {
1101                         self.items = self.items | IT_STRENGTH;
1102                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1103                 }
1104         }
1105         if (self.items & IT_INVINCIBLE)
1106         {
1107                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1108                 if (time > self.invincible_finished)
1109                 {
1110                         self.items = self.items - (self.items & IT_INVINCIBLE);
1111                         sprint(self, "^3Shield has worn off\n");
1112                 }
1113         }
1114         else
1115         {
1116                 if (time < self.invincible_finished)
1117                 {
1118                         self.items = self.items | IT_INVINCIBLE;
1119                         sprint(self, "^3Shield surrounds you\n");
1120                 }
1121         }
1122
1123         if (cvar("g_fullbrightplayers"))
1124                 self.effects = self.effects | EF_FULLBRIGHT;
1125
1126         // midair gamemode: damage only while in the air
1127         // if in midair mode, being on ground grants temporary invulnerability
1128         // (this is so that multishot weapon don't clear the ground flag on the
1129         // first damage in the frame, leaving the player vulnerable to the
1130         // remaining hits in the same frame)
1131         if (self.flags & FL_ONGROUND)
1132         if (cvar("g_midair"))
1133                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1134
1135         if (time < self.spawnshieldtime)
1136                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1137 }
1138
1139 void player_regen (void)
1140 {
1141         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1142         maxh = cvar("g_balance_health_stable");
1143         maxa = cvar("g_balance_armor_stable");
1144         limith = cvar("g_balance_health_limit");
1145         limita = cvar("g_balance_armor_limit");
1146
1147         if (cvar("g_minstagib") || (cvar("g_lms") && !cvar("g_lms_regenerate")))
1148                 return;
1149
1150         if(cvar("g_runematch"))
1151         {
1152                 max_mod = regen_mod = rot_mod = limit_mod = 1;
1153                 if (self.runes & RUNE_REGEN)
1154                 {
1155                         if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1156                         {
1157                                 regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1158                                 max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1159                                 limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1160                         }
1161                         else
1162                         {
1163                                 regen_mod = cvar("g_balance_rune_regen_regenrate");
1164                                 max_mod = cvar("g_balance_rune_regen_hpmod");
1165                                 limit_mod = cvar("g_balance_rune_regen_limitmod");
1166                         }
1167                 }
1168                 else if (self.runes & CURSE_VENOM)
1169                 {
1170                         max_mod = cvar("g_balance_curse_venom_hpmod");
1171                         if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1172                                 rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1173                         else
1174                                 rot_mod = cvar("g_balance_curse_venom_rotrate");
1175                         limit_mod = cvar("g_balance_curse_venom_limitmod");
1176                         //if (!self.runes & RUNE_REGEN)
1177                         //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1178                 }
1179                 maxh = maxh * max_mod;
1180                 //maxa = maxa * max_mod;
1181
1182                 if (time > self.pauserotarmor_finished)
1183                 {
1184                         if (self.armorvalue > maxa)
1185                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1186                 }
1187                 if (time > self.pauserothealth_finished)
1188                 {
1189                         if (self.health > maxh)
1190                                 self.health = bound(0, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime, 1000);
1191                 }
1192                 if (time > self.pauseregen_finished)
1193                 {
1194                         if (self.health < maxh)
1195                                 self.health = bound(0, self.health + (maxh- self.health) * regen_mod*cvar("g_balance_health_regen") * frametime  + 0.001, 1000);
1196                         if (self.armorvalue < maxa)
1197                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime  + 0.001, 1000);
1198                 }
1199         }
1200         else
1201         {
1202                 if (time > self.pauserothealth_finished)
1203                 if (self.health > maxh)
1204                         self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_rot") * frametime, 1000);
1205                 if (time > self.pauserotarmor_finished)
1206                 if (self.armorvalue > maxa)
1207                         self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1208                 if (time > self.pauseregen_finished)
1209                 {
1210                         if (self.health < maxh)
1211                                  self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_regen") * frametime + 0.001, 1000);
1212                         if (self.armorvalue < maxa)
1213                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime + 0.001, 1000);
1214                 }
1215         }
1216
1217         if (self.health > limith)
1218                 self.health = limith;
1219         if(self.health < 1)
1220                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1221         if (self.armorvalue > limita)
1222                 self.armorvalue = limita;
1223 }
1224
1225 /*
1226 ======================
1227 spectate mode routines
1228 ======================
1229 */
1230 void SpectateCopy(entity spectatee) {
1231         self.armortype = spectatee.armortype;
1232         self.armorvalue = spectatee.armorvalue;
1233         self.currentammo = spectatee.currentammo;
1234         self.effects = spectatee.effects;
1235         self.health = spectatee.health;
1236         self.impulse = 0;
1237         self.items = spectatee.items;
1238         self.punchangle = spectatee.punchangle;
1239         self.view_ofs = spectatee.view_ofs;
1240         self.v_angle = spectatee.v_angle;
1241         self.viewzoom = spectatee.viewzoom;
1242         setorigin(self, spectatee.origin);
1243         setsize(self, spectatee.mins, spectatee.maxs);
1244 }
1245
1246 void SpectateUpdate() {
1247         if(!self.enemy)
1248                         PutObserverInServer();
1249
1250         if (self != self.enemy) {
1251                 if(self.enemy.flags & FL_NOTARGET)
1252                         PutObserverInServer();
1253                 SpectateCopy(self.enemy);
1254                 self.dmg_take = self.enemy.dmg_take;
1255                 self.dmg_save = self.enemy.dmg_save;
1256                 self.dmg_inflictor = self.enemy.dmg_inflictor;
1257                 self.fixangle = TRUE;
1258                 self.angles = self.enemy.v_angle;
1259                 //msg_entity = self;
1260                 //WriteByte(MSG_ONE, SVC_SETANGLE);
1261                 //WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1262                 //WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1263                 //WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1264         }
1265 }
1266
1267 float SpectateNext() {
1268         other = find(self.enemy, classname, "player");
1269         if (!other) {
1270                 other = find(other, classname, "player");
1271         }
1272         if (other) {
1273                 self.enemy = other;
1274         }
1275         if(self.enemy.classname == "player") {
1276                 msg_entity = self;
1277                 WriteByte(MSG_ONE, SVC_SETVIEW);
1278                 WriteEntity(MSG_ONE, self.enemy);
1279                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1280                 SpectateUpdate();
1281                 return 1;
1282         } else {
1283                 return 0;
1284         }
1285 }
1286
1287 /*
1288 =============
1289 PlayerPreThink
1290
1291 Called every frame for each client before the physics are run
1292 =============
1293 */
1294 void() ctf_setstatus;
1295 void PlayerPreThink (void)
1296 {
1297         if(self.classname == "player") {
1298                 local vector m1, m2;
1299
1300 //              if(self.netname == "Wazat")
1301 //                      bprint(strcat(self.classname, "\n"));
1302
1303                 CheckRules_Player();
1304
1305                 Nixnex_GiveCurrentWeapon();
1306
1307                 if(self.button7)
1308                         PrintWelcomeMessage(self);
1309
1310                 if(cvar("g_lms") || !cvar("sv_spectate"))
1311                 if((time - self.jointime) <= cvar("welcome_message_time"))
1312                         PrintWelcomeMessage(self);
1313
1314                 if (intermission_running)
1315                 {
1316                         IntermissionThink ();   // otherwise a button could be missed between
1317                         return;                                 // the think tics
1318                 }
1319
1320                 if (self.deadflag != DEAD_NO)
1321                 {
1322                         player_anim();
1323                         if (self.deadflag == DEAD_DYING)
1324                         {
1325                                 if (time > self.dead_time)
1326                                         self.deadflag = DEAD_DEAD;
1327                         }
1328                         else if (self.deadflag == DEAD_DEAD)
1329                         {
1330                                 if (cvar("g_lms") || cvar("g_arena") || cvar("g_forced_respawn"))
1331                                         self.deadflag = DEAD_RESPAWNABLE;
1332                                 else if (!self.button0 && !self.button2 && !self.button3)
1333                                         self.deadflag = DEAD_RESPAWNABLE;
1334                         }
1335                         else if (self.deadflag == DEAD_RESPAWNABLE)
1336                         {
1337                                 if (self.button0  ||
1338                                     self.button2  ||
1339                                     self.button3  ||
1340                                     self.button4  ||
1341                                     self.button5  ||
1342                                     self.button6  ||
1343                                     self.button7  ||
1344                                     self.button8  ||
1345                                     self.buttonuse ||
1346                                     cvar("g_lms") ||
1347                                     cvar("g_forced_respawn"))
1348                                         respawn();
1349                         }
1350                         return;
1351                 }
1352
1353                 if(cvar("g_lms") && !self.deadflag && cvar("g_lms_campcheck_interval"))
1354                 {
1355                         vector dist;
1356
1357                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1358                         dist = self.oldorigin - self.origin;
1359                         dist_z = 0;
1360                         self.lms_traveled_distance += fabs(vlen(dist));
1361
1362                         if(cvar("g_campaign"))
1363                         if(!campaign_bots_may_start)
1364                         {
1365                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1366                                 self.lms_traveled_distance = 0;
1367                         }
1368
1369                         if(time > self.lms_nextcheck)
1370                         {
1371                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1372                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1373                                 {
1374                                         centermsg_set(CENTERMSG_CAMP, cvar_string("g_lms_campcheck_message"));
1375                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1376                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1377                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1378                                 }
1379                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1380                                 self.lms_traveled_distance = 0;
1381                         }
1382                 }
1383
1384                 if (self.button5 && !self.hook.state)
1385                 {
1386                         if (!self.crouch)
1387                         {
1388                                 self.crouch = TRUE;
1389                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1390                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1391                         }
1392                 }
1393                 else
1394                 {
1395                         if (self.crouch)
1396                         {
1397                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1398                                 if (!trace_startsolid)
1399                                 {
1400                                         self.crouch = FALSE;
1401                                         self.view_ofs = PL_VIEW_OFS;
1402                                         setsize (self, PL_MIN, PL_MAX);
1403                                 }
1404                         }
1405                 }
1406
1407                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
1408                         local string defaultmodel;
1409                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
1410
1411                         if (defaultmodel != self.model)
1412                         {
1413                                 m1 = self.mins;
1414                                 m2 = self.maxs;
1415                                 setmodel_lod (self, defaultmodel);
1416                                 setsize (self, m1, m2);
1417                         }
1418
1419                         if (self.skin != cvar("sv_defaultplayerskin"))
1420                                 self.skin = cvar("sv_defaultplayerskin");
1421                 } else {
1422                         if (self.playermodel != self.model)
1423                         {
1424                                 self.playermodel = CheckPlayerModel(self.playermodel);
1425                                 m1 = self.mins;
1426                                 m2 = self.maxs;
1427                                 setmodel_lod (self, self.playermodel);
1428                                 setsize (self, m1, m2);
1429                         }
1430
1431                         if (self.skin != stof(self.playerskin))
1432                                 self.skin = stof(self.playerskin);
1433                 }
1434                 // Savage: Check for nameless players
1435                 if (strlen(self.netname) < 1) {
1436                         self.netname = "Player";
1437                         stuffcmd(self, "name Player\n");
1438                 }
1439
1440                 GrapplingHookFrame();
1441
1442                 W_WeaponFrame();
1443
1444                 if (self.button4 || (self.weapon == WEP_NEX && self.button3))
1445                 {
1446                         if (cvar("g_minstagib") && self.button3)
1447                         {
1448                                 if (self.jump_interval <= (time + 0.1))
1449                                 {
1450                                         self.jump_interval = time + 1;
1451                                         W_Laser_Attack();
1452                                 }
1453                         }
1454                         else if (self.viewzoom > 0.4)
1455                                 self.viewzoom = max (0.4, self.viewzoom - frametime * 2);
1456                 }
1457                 else if (self.viewzoom < 1.0)
1458                         self.viewzoom = min (1.0, self.viewzoom + frametime);
1459
1460
1461                 if (self.button2)
1462                         PlayerJump ();
1463                 else
1464                         self.flags = self.flags | FL_JUMPRELEASED;
1465
1466                 player_powerups();
1467                 player_regen();
1468                 player_anim();
1469
1470                 if (cvar("g_minstagib"))
1471                         minstagib_ammocheck();
1472
1473                 ctf_setstatus();
1474
1475                 //self.angles_y=self.v_angle_y + 90;   // temp
1476
1477                 if (self.waterlevel == 2)
1478                         CheckWaterJump ();
1479
1480                 //if (TetrisPreFrame()) return;
1481         } else if(gameover) {
1482                 if (intermission_running)
1483                         IntermissionThink ();   // otherwise a button could be missed between
1484                 return;
1485         } else if(self.classname == "observer") {
1486
1487                 if (self.flags & FL_JUMPRELEASED) {
1488                         if (self.button2 && self.version == cvar("gameversion")) {
1489                                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1490                                         self.flags = self.flags & !FL_JUMPRELEASED;
1491                                         self.classname = "player";
1492                                         if(cvar("g_campaign") || cvar("g_balance_teams"))
1493                                                 JoinBestTeam(self, 0);
1494                                         if(cvar("g_campaign"))
1495                                                 campaign_bots_may_start = 1;
1496                                         PutClientInServer();
1497                                         if(self.flags & !FL_NOTARGET)
1498                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1499                                         centermsg_reset();
1500                                         return;
1501                                 } else {
1502                                         self.flags = self.flags & !FL_JUMPRELEASED;
1503                                         stuffcmd(self,"menu_showteamselect\n");
1504                                         return;
1505                                 }
1506                         } else if(self.button0 && self.version == cvar("gameversion")) {
1507                                 self.flags = self.flags & !FL_JUMPRELEASED;
1508                                 if(SpectateNext() == 1) {
1509                                         self.classname = "spectator";
1510                                 }
1511                         }
1512                 } else {
1513                         if (!(self.button0 || self.button2)) {
1514                                 self.flags = self.flags | FL_JUMPRELEASED;
1515                         }
1516                 }
1517                 PrintWelcomeMessage(self);
1518         } else if(self.classname == "spectator") {
1519                 if (self.flags & FL_JUMPRELEASED) {
1520                         if (self.button2 && self.version == cvar("gameversion")) {
1521                                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1522                                         self.flags = self.flags & !FL_JUMPRELEASED;
1523                                         self.classname = "player";
1524                                         if(!cvar("g_lms"))
1525                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1526
1527                                         if(cvar("g_campaign") || cvar("g_balance_teams"))
1528                                                 JoinBestTeam(self, 0);
1529                                         if(cvar("g_campaign"))
1530                                                 campaign_bots_may_start = 1;
1531                                         PutClientInServer();
1532                                         centermsg_reset();
1533                                         return;
1534                                 } else {
1535                                         self.flags = self.flags & !FL_JUMPRELEASED;
1536                                         stuffcmd(self,"menu_showteamselect\n");
1537                                         return;
1538                                 }
1539                         } else if(self.button0) {
1540                                 self.flags = self.flags & !FL_JUMPRELEASED;
1541                                 if(SpectateNext() == 1) {
1542                                         self.classname = "spectator";
1543                                 } else {
1544                                         self.classname = "observer";
1545                                         PutClientInServer();
1546                                 }
1547                         } else if (self.button3) {
1548                                 self.flags = self.flags & !FL_JUMPRELEASED;
1549                                 self.classname = "observer";
1550                                 PutClientInServer();
1551                         } else {
1552                                 SpectateUpdate();
1553                         }
1554                 } else {
1555                         if (!(self.button0 || self.button3)) {
1556                                 self.flags = self.flags | FL_JUMPRELEASED;
1557                         }
1558                 }
1559                 PrintWelcomeMessage(self);
1560                 self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1561         }
1562 }
1563
1564
1565 /*
1566 =============
1567 PlayerPostThink
1568
1569 Called every frame for each client after the physics are run
1570 =============
1571 */
1572 void PlayerPostThink (void)
1573 {
1574         if(self.classname == "player") {
1575                 CheckRules_Player();
1576                 UpdateChatBubble();
1577                 UpdateTeamBubble();
1578                 if (self.deadflag == DEAD_NO)
1579                 if (self.impulse)
1580                         ImpulseCommands ();
1581                 if (intermission_running)
1582                         return;         // intermission or finale
1583
1584                 //PrintWelcomeMessage(self);
1585                 //if (TetrisPostFrame()) return;
1586         } else if (self.classname == "observer") {
1587                 //do nothing
1588         } else if (self.classname == "spectator") {
1589                 //do nothing
1590         }
1591         Arena_Warmup();
1592 }