data/qcsrc/server/cl_client.qc

   1 // let's abuse an existing field
   2 #define SPAWNPOINT_SCORE frags
   3
   4 .float wantswelcomemessage;
   5 .string netname_previous;
   6
   7 void spawnfunc_info_player_survivor (void)
   8 {
   9         spawnfunc_info_player_deathmatch();
  10 }
  11
  12 void spawnfunc_info_player_start (void)
  13 {
  14         spawnfunc_info_player_deathmatch();
  15 }
  16
  17 void spawnfunc_info_player_deathmatch (void)
  18 {
  19         self.classname = "info_player_deathmatch";
  20         relocate_spawnpoint();
  21 }
  22
  23 void spawnpoint_use()
  24 {
  25         if(teams_matter)
  26         if(have_team_spawns)
  27         {
  28                 self.team = activator.team;
  29                 some_spawn_has_been_used = 1;
  30         }
  31 };
  32
  33 // Returns:
  34 //   -1 if a spawn can't be used
  35 //   otherwise, a weight of the spawnpoint
  36 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
  37 {
  38         float shortest, thisdist;
  39         entity player;
  40
  41         // filter out spots for the wrong team
  42         if(teamcheck)
  43         if(spot.team != teamcheck)
  44                 return -1;
  45
  46         if(race_spawns)
  47                 if(spot.target == "")
  48                         return -1;
  49
  50         // filter out spots for assault
  51         if(spot.target != "") {
  52                 local entity ent;
  53                 float good;
  54                 ent = find(world, targetname, spot.target);
  55                 while(ent) {
  56                         if(ent.classname == "target_objective")
  57                         {
  58                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  59                                         return -1;
  60                                 good = 1;
  61                         }
  62                         else if(ent.classname == "trigger_race_checkpoint")
  63                         {
  64                                 if(self.classname == "player") // spectators may spawn everywhere
  65                                 {
  66                                         if(ent.race_checkpoint != race_PreviousCheckpoint(self.race_checkpoint))
  67                                                 return -1;
  68                                         float pl;
  69                                         pl = self.race_place;
  70                                         if(pl > race_highest_place_spawn)
  71                                                 pl = 0;
  72                                         if(spot.race_place != pl)
  73                                                 return -1;
  74                                 }
  75                                 good = 1;
  76                         }
  77                         else
  78                         {
  79                         }
  80                         ent = find(ent, targetname, spot.target);
  81                 }
  82
  83                 if(!good)
  84                         return -1;
  85         }
  86
  87         player = playerlist;
  88         shortest = vlen(world.maxs - world.mins);
  89         for(player = playerlist; player; player = player.chain)
  90                 if (player != self)
  91                 {
  92                         thisdist = vlen(player.origin - spot.origin);
  93                         if (thisdist < shortest)
  94                                 shortest = thisdist;
  95                 }
  96         return shortest;
  97 }
  98
  99 float spawn_allbad;
 100 float spawn_allgood;
 101 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
 102 {
 103         local entity spot, spotlist, spotlistend;
 104         spawn_allgood = TRUE;
 105         spawn_allbad = TRUE;
 106
 107         spotlist = world;
 108         spotlistend = world;
 109
 110         for(spot = firstspot; spot; spot = spot.chain)
 111         {
 112                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
 113
 114                 if(cvar("spawn_debugview"))
 115                 {
 116                         setmodel(spot, "models/runematch/rune.mdl");
 117                         if(spot.SPAWNPOINT_SCORE < mindist)
 118                         {
 119                                 spot.colormod = '1 0 0';
 120                                 spot.scale = 1;
 121                         }
 122                         else
 123                         {
 124                                 spot.colormod = '0 1 0';
 125                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
 126                         }
 127                 }
 128
 129                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 130                 {
 131                         if(spot.SPAWNPOINT_SCORE < mindist)
 132                         {
 133                                 // too short distance
 134                                 spawn_allgood = FALSE;
 135                         }
 136                         else
 137                         {
 138                                 // perfect
 139                                 spawn_allbad = FALSE;
 140
 141                                 if(spotlistend)
 142                                         spotlistend.chain = spot;
 143                                 spotlistend = spot;
 144                                 if(!spotlist)
 145                                         spotlist = spot;
 146
 147                                 /*
 148                                 if(teamcheck)
 149                                 if(spot.team != teamcheck)
 150                                         error("invalid spawn added");
 151
 152                                 print("added ", etos(spot), "\n");
 153                                 */
 154                         }
 155                 }
 156         }
 157         if(spotlistend)
 158                 spotlistend.chain = world;
 159
 160         /*
 161                 entity e;
 162                 if(teamcheck)
 163                         for(e = spotlist; e; e = e.chain)
 164                         {
 165                                 print("seen ", etos(e), "\n");
 166                                 if(e.team != teamcheck)
 167                                         error("invalid spawn found");
 168                         }
 169         */
 170
 171         return spotlist;
 172 }
 173
 174 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 175 {
 176         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 177         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 178         local entity spot;
 179
 180         RandomSelection_Init();
 181         for(spot = firstspot; spot; spot = spot.chain)
 182                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 183
 184         return RandomSelection_chosen_ent;
 185 }
 186
 187 /*
 188 =============
 189 SelectSpawnPoint
 190
 191 Finds a point to respawn
 192 =============
 193 */
 194 entity SelectSpawnPoint (float anypoint)
 195 {
 196         local float teamcheck;
 197         local entity firstspot_new;
 198         local entity spot, firstspot, playerlist;
 199
 200         spot = find (world, classname, "testplayerstart");
 201         if (spot)
 202                 return spot;
 203
 204         teamcheck = 0;
 205
 206         if(!anypoint && have_team_spawns)
 207                 teamcheck = self.team;
 208
 209         // get the list of players
 210         playerlist = findchain(classname, "player");
 211         // get the entire list of spots
 212         firstspot = findchain(classname, "info_player_deathmatch");
 213         // filter out the bad ones
 214         // (note this returns the original list if none survived)
 215         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 216         if(!firstspot_new)
 217                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 218         firstspot = firstspot_new;
 219
 220         // there is 50/50 chance of choosing a random spot or the furthest spot
 221         // (this means that roughly every other spawn will be furthest, so you
 222         // usually won't get fragged at spawn twice in a row)
 223         if (arena_roundbased)
 224         {
 225                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 226                 if(firstspot_new)
 227                         firstspot = firstspot_new;
 228                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 229         }
 230         else if (random() > cvar("g_spawn_furthest"))
 231                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 232         else
 233                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 234
 235         if(cvar("spawn_debugview"))
 236         {
 237                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 238
 239                 entity e;
 240                 if(teamcheck)
 241                         for(e = firstspot; e; e = e.chain)
 242                                 if(e.team != teamcheck)
 243                                         error("invalid spawn found");
 244         }
 245
 246         if (!spot)
 247         {
 248                 if(cvar("spawn_debug"))
 249                         GotoNextMap();
 250                 else
 251                 {
 252                         if(some_spawn_has_been_used)
 253                                 return world; // team can't spawn any more, because of actions of other team
 254                         else
 255                                 error("Cannot find a spawn point - please fix the map!");
 256                 }
 257         }
 258
 259         return spot;
 260 }
 261
 262 /*
 263 =============
 264 CheckPlayerModel
 265
 266 Checks if the argument string can be a valid playermodel.
 267 Returns a valid one in doubt.
 268 =============
 269 */
 270 string FallbackPlayerModel = "models/player/marine.zym";
 271 string CheckPlayerModel(string plyermodel) {
 272         if(strlen(plyermodel) < 4)
 273                 return FallbackPlayerModel;
 274         if( substring(plyermodel,0,14) != "models/player/")
 275                 return FallbackPlayerModel;
 276         else if(cvar("sv_servermodelsonly"))
 277         {
 278                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 279                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 280                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 281                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 282                         return FallbackPlayerModel;
 283                 if(!fexists(plyermodel))
 284                         return FallbackPlayerModel;
 285         }
 286         return plyermodel;
 287 }
 288
 289 /*
 290 =============
 291 Client_customizeentityforclient
 292
 293 LOD reduction
 294 =============
 295 */
 296 float Client_customizeentityforclient()
 297 {
 298 #ifdef ALLOW_VARIABLE_LOD
 299         // self: me
 300         // other: the player viewing me
 301         float distance;
 302         float f;
 303
 304         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 305                 return TRUE;
 306
 307         if(other.cvar_cl_playerdetailreduction <= 0)
 308         {
 309                 if(other.cvar_cl_playerdetailreduction <= -2)
 310                         self.modelindex = self.modelindex_lod2;
 311                 else if(other.cvar_cl_playerdetailreduction <= -1)
 312                         self.modelindex = self.modelindex_lod1;
 313                 else
 314                         self.modelindex = self.modelindex_lod0;
 315         }
 316         else
 317         {
 318                 distance = vlen(self.origin - other.origin);
 319                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 320                 if(f > 10000)
 321                         self.modelindex = self.modelindex_lod2;
 322                 else if(f > 5000)
 323                         self.modelindex = self.modelindex_lod1;
 324                 else
 325                         self.modelindex = self.modelindex_lod0;
 326         }
 327 #endif
 328
 329         return TRUE;
 330 }
 331
 332 void UpdatePlayerSounds();
 333 void setmodel_lod(entity e, string modelname)
 334 {
 335 #ifdef ALLOW_VARIABLE_LOD
 336         string s;
 337
 338         // FIXME: this only supports 3-letter extensions
 339         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 340         if(fexists(s))
 341         {
 342                 precache_model(s);
 343                 setmodel(e, s); // players have high precision
 344                 self.modelindex_lod1 = self.modelindex;
 345         }
 346         else
 347                 self.modelindex_lod1 = -1;
 348
 349         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 350         if(fexists(s))
 351         {
 352                 precache_model(s);
 353                 setmodel(e, s); // players have high precision
 354                 self.modelindex_lod2 = self.modelindex;
 355         }
 356         else
 357                 self.modelindex_lod2 = -1;
 358
 359         precache_model(modelname);
 360         setmodel(e, modelname); // players have high precision
 361         self.modelindex_lod0 = self.modelindex;
 362
 363         if(self.modelindex_lod1 < 0)
 364                 self.modelindex_lod1 = self.modelindex;
 365
 366         if(self.modelindex_lod2 < 0)
 367                 self.modelindex_lod2 = self.modelindex;
 368 #else
 369         precache_model(modelname);
 370         setmodel(e, modelname); // players have high precision
 371 #endif
 372         player_setupanimsformodel();
 373         UpdatePlayerSounds();
 374 }
 375
 376 /*
 377 =============
 378 PutObserverInServer
 379
 380 putting a client as observer in the server
 381 =============
 382 */
 383 void PutObserverInServer (void)
 384 {
 385         entity  spot;
 386
 387         race_PreSpawnObserver();
 388
 389         spot = SelectSpawnPoint (TRUE);
 390         if(!spot)
 391                 error("No spawnpoints for observers?!?\n");
 392         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 393
 394         if(clienttype(self) == CLIENTTYPE_REAL)
 395         {
 396                 msg_entity = self;
 397                 WriteByte(MSG_ONE, SVC_SETVIEW);
 398                 WriteEntity(MSG_ONE, self);
 399         }
 400
 401         DropAllRunes(self);
 402         kh_Key_DropAll(self, TRUE);
 403
 404         if(self.flagcarried)
 405                 DropFlag(self.flagcarried);
 406
 407         WaypointSprite_PlayerDead();
 408
 409         if(self.killcount != -666)
 410         {
 411                 if(g_lms)
 412                 {
 413                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 414                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 415                         else
 416                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 417                 }
 418                 else
 419                         bprint ("^4", self.netname, "^4 is spectating now\n");
 420         }
 421
 422         PlayerScore_Clear(self); // clear scores when needed
 423
 424         self.spectatortime = time;
 425
 426         self.classname = "observer";
 427         self.health = -666;
 428         self.takedamage = DAMAGE_NO;
 429         self.solid = SOLID_NOT;
 430         self.movetype = MOVETYPE_NOCLIP;
 431         self.flags = FL_CLIENT | FL_NOTARGET;
 432         self.armorvalue = 666;
 433         self.effects = 0;
 434         self.armorvalue = cvar("g_balance_armor_start");
 435         self.pauserotarmor_finished = 0;
 436         self.pauserothealth_finished = 0;
 437         self.pauseregen_finished = 0;
 438         self.damageforcescale = 0;
 439         self.death_time = 0;
 440         self.dead_frame = 0;
 441         self.alpha = 0;
 442         self.scale = 0;
 443         self.fade_time = 0;
 444         self.pain_frame = 0;
 445         self.pain_finished = 0;
 446         self.strength_finished = 0;
 447         self.invincible_finished = 0;
 448         self.pushltime = 0;
 449         self.think = SUB_Null;
 450         self.nextthink = 0;
 451         self.hook_time = 0;
 452         self.runes = 0;
 453         self.deadflag = DEAD_NO;
 454         self.angles = spot.angles;
 455         self.angles_z = 0;
 456         self.fixangle = TRUE;
 457         self.crouch = FALSE;
 458
 459         self.view_ofs = PL_VIEW_OFS;
 460         setorigin (self, spot.origin);
 461         setsize (self, '0 0 0', '0 0 0');
 462         self.oldorigin = self.origin;
 463         self.items = 0;
 464         self.model = "";
 465         self.modelindex = 0;
 466         self.weapon = 0;
 467         self.weaponmodel = "";
 468         self.weaponentity = world;
 469         self.killcount = -666;
 470         self.velocity = '0 0 0';
 471         self.avelocity = '0 0 0';
 472         self.punchangle = '0 0 0';
 473         self.punchvector = '0 0 0';
 474         self.oldvelocity = self.velocity;
 475         self.customizeentityforclient = Client_customizeentityforclient;
 476         self.viewzoom = 1;
 477         self.wantswelcomemessage = 1;
 478
 479         if(g_arena)
 480         {
 481                 if(self.version_mismatch)
 482                 {
 483                         Spawnqueue_Unmark(self);
 484                         Spawnqueue_Remove(self);
 485                 }
 486                 else
 487                 {
 488                         Spawnqueue_Insert(self);
 489                 }
 490         }
 491         else if(g_lms)
 492         {
 493                 // Only if the player cannot play at all
 494                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 495                         self.frags = -666;
 496                 else
 497                         self.frags = -667;
 498         }
 499         else
 500                 self.frags = -666;
 501 }
 502
 503 float RestrictSkin(float s)
 504 {
 505         if(!teams_matter)
 506                 return s;
 507         if(s == 6)
 508                 return 6;
 509         return mod(s, 3);
 510 }
 511
 512 void FixPlayermodel()
 513 {
 514         local string defaultmodel;
 515         local float defaultskin;
 516         local vector m1, m2;
 517
 518         defaultmodel = "";
 519
 520         if(cvar("sv_defaultcharacter") == 1) {
 521                 defaultskin = 0;
 522
 523                 if(teams_matter)
 524                 {
 525                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 526                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 527                 }
 528
 529                 if(defaultmodel == "")
 530                 {
 531                         defaultmodel = cvar_string("sv_defaultplayermodel");
 532                         defaultskin = cvar("sv_defaultplayerskin");
 533                 }
 534         }
 535
 536         if(defaultmodel != "")
 537         {
 538                 if (defaultmodel != self.model)
 539                 {
 540                         m1 = self.mins;
 541                         m2 = self.maxs;
 542                         setmodel_lod (self, defaultmodel);
 543                         setsize (self, m1, m2);
 544                 }
 545
 546                 self.skin = defaultskin;
 547         } else {
 548                 if (self.playermodel != self.model)
 549                 {
 550                         self.playermodel = CheckPlayerModel(self.playermodel);
 551                         m1 = self.mins;
 552                         m2 = self.maxs;
 553                         setmodel_lod (self, self.playermodel);
 554                         setsize (self, m1, m2);
 555                 }
 556
 557                 self.skin = RestrictSkin(stof(self.playerskin));
 558         }
 559
 560         if(!teams_matter)
 561                 if(strlen(cvar_string("sv_defaultplayercolors")))
 562                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 563                                 setcolor(self, cvar("sv_defaultplayercolors"));
 564 }
 565
 566 /*
 567 =============
 568 PutClientInServer
 569
 570 Called when a client spawns in the server
 571 =============
 572 */
 573 //void() ctf_playerchanged;
 574 void PutClientInServer (void)
 575 {
 576         if(clienttype(self) == CLIENTTYPE_BOT)
 577         {
 578                 self.classname = "player";
 579         }
 580         else if(clienttype(self) == CLIENTTYPE_REAL)
 581         {
 582                 msg_entity = self;
 583                 WriteByte(MSG_ONE, SVC_SETVIEW);
 584                 WriteEntity(MSG_ONE, self);
 585         }
 586
 587         // player is dead and becomes observer
 588         // FIXME fix LMS scoring for new system
 589         if(g_lms)
 590         {
 591                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 592                         self.classname = "observer";
 593         }
 594
 595         if(g_arena)
 596         if(!self.spawned)
 597                 self.classname = "observer";
 598
 599         if(self.classname == "player") {
 600                 entity  spot;
 601
 602                 race_PreSpawn();
 603
 604                 spot = SelectSpawnPoint (FALSE);
 605                 if(!spot)
 606                 {
 607                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 608                         return; // spawn failed
 609                 }
 610
 611                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 612
 613                 self.classname = "player";
 614                 self.iscreature = TRUE;
 615                 self.movetype = MOVETYPE_WALK;
 616                 if(independent_players)
 617                         self.solid = SOLID_TRIGGER;
 618                 else
 619                         self.solid = SOLID_SLIDEBOX;
 620                 self.flags = FL_CLIENT;
 621                 self.takedamage = DAMAGE_AIM;
 622                 if(g_minstagib)
 623                         self.effects = EF_FULLBRIGHT;
 624                 else
 625                         self.effects = 0;
 626                 self.air_finished = time + 12;
 627                 self.dmg = 2;
 628
 629                 self.ammo_shells = start_ammo_shells;
 630                 self.ammo_nails = start_ammo_nails;
 631                 self.ammo_rockets = start_ammo_rockets;
 632                 self.ammo_cells = start_ammo_cells;
 633                 self.health = start_health;
 634                 self.armorvalue = start_armorvalue;
 635                 self.items = start_items;
 636                 self.switchweapon = start_switchweapon;
 637                 self.cnt = start_switchweapon;
 638                 self.weapon = 0;
 639                 self.jump_interval = time;
 640
 641                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 642                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 643                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 644                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 645                 //extend the pause of rotting if client was reset at the beginning of the countdown
 646                 if(!cvar("sv_ready_restart_after_countdown") && time < restart_countdown) {
 647                         self.spawnshieldtime += RESTART_COUNTDOWN;
 648                         self.pauserotarmor_finished += RESTART_COUNTDOWN;
 649                         self.pauserothealth_finished += RESTART_COUNTDOWN;
 650                         self.pauseregen_finished += RESTART_COUNTDOWN;
 651                 }
 652                 self.damageforcescale = 2;
 653                 self.death_time = 0;
 654                 self.dead_frame = 0;
 655                 self.alpha = 0;
 656                 self.scale = 0;
 657                 self.fade_time = 0;
 658                 self.pain_frame = 0;
 659                 self.pain_finished = 0;
 660                 self.strength_finished = 0;
 661                 self.invincible_finished = 0;
 662                 self.pushltime = 0;
 663                 //self.speed_finished = 0;
 664                 //self.slowmo_finished = 0;
 665                 // players have no think function
 666                 self.think = SUB_Null;
 667                 self.nextthink = 0;
 668                 self.hook_time = 0;
 669
 670                 self.runes = 0;
 671
 672                 self.deadflag = DEAD_NO;
 673
 674                 self.angles = spot.angles;
 675
 676                 self.angles_z = 0; // never spawn tilted even if the spot says to
 677                 self.fixangle = TRUE; // turn this way immediately
 678                 self.velocity = '0 0 0';
 679                 self.avelocity = '0 0 0';
 680                 self.punchangle = '0 0 0';
 681                 self.punchvector = '0 0 0';
 682                 self.oldvelocity = self.velocity;
 683
 684                 self.viewzoom = 0.6;
 685                 self.has_zoomed = 0;
 686
 687                 self.customizeentityforclient = Client_customizeentityforclient;
 688
 689                 self.model = "";
 690                 FixPlayermodel();
 691
 692                 self.crouch = FALSE;
 693                 self.view_ofs = PL_VIEW_OFS;
 694                 setsize (self, PL_MIN, PL_MAX);
 695                 self.spawnorigin = spot.origin;
 696                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 697                 // don't reset back to last position, even if new position is stuck in solid
 698                 self.oldorigin = self.origin;
 699
 700                 if(g_arena)
 701                 {
 702                         Spawnqueue_Remove(self);
 703                         Spawnqueue_Mark(self);
 704                 }
 705
 706                 self.event_damage = PlayerDamage;
 707
 708                 self.bot_attack = TRUE;
 709
 710                 self.statdraintime = time + 5;
 711                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 712
 713                 if(self.killcount == -666) {
 714                         PlayerScore_Clear(self);
 715                         self.killcount = 0;
 716                         self.frags = 0;
 717                 }
 718
 719                 self.cnt = WEP_LASER;
 720                 self.nixnex_lastchange_id = -1;
 721
 722                 CL_SpawnWeaponentity();
 723                 self.alpha = default_player_alpha;
 724                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 725                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 726
 727                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 728                 self.lms_traveled_distance = 0;
 729                 self.speedrunning = FALSE;
 730
 731                 race_PostSpawn(spot);
 732
 733                 if(cvar("spawn_debug"))
 734                 {
 735                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 736                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 737                 }
 738
 739                 //stuffcmd(self, "chase_active 0");
 740                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 741
 742                 if (cvar("g_spawnsound"))
 743                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 744
 745                 if(g_assault) {
 746                         if(self.team == assault_attacker_team)
 747                                 centerprint(self, "You are attacking!\n");
 748                         else
 749                                 centerprint(self, "You are defending!\n");
 750                 }
 751
 752         } else if(self.classname == "observer") {
 753                 PutObserverInServer ();
 754         }
 755
 756         //if(g_ctf)
 757         //      ctf_playerchanged();
 758 }
 759
 760 /*
 761 =============
 762 SendCSQCInfo
 763
 764 Send whatever CSQC needs NOW and cannot wait for SendServerInfo to happen...
 765 =============
 766 */
 767 void SendCSQCInfo(void)
 768 {
 769         if(clienttype(self) != CLIENTTYPE_REAL)
 770                 return;
 771         msg_entity = self;
 772         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 773         WriteByte(MSG_ONE, TE_CSQC_INIT);
 774         WriteShort(MSG_ONE, CSQC_REVISION);
 775         WriteByte(MSG_ONE, maxclients);
 776 }
 777
 778 /*
 779 =============
 780 SetNewParms
 781 =============
 782 */
 783 void SetNewParms (void)
 784 {
 785         // initialize parms for a new player
 786         parm1 = -(86400 * 366);
 787 }
 788
 789 /*
 790 =============
 791 SetChangeParms
 792 =============
 793 */
 794 void SetChangeParms (void)
 795 {
 796         // save parms for level change
 797         parm1 = self.parm_idlesince - time;
 798 }
 799
 800 /*
 801 =============
 802 DecodeLevelParms
 803 =============
 804 */
 805 void DecodeLevelParms (void)
 806 {
 807         // load parms
 808         self.parm_idlesince = parm1;
 809         if(self.parm_idlesince == -(86400 * 366))
 810                 self.parm_idlesince = time;
 811 }
 812
 813 /*
 814 =============
 815 ClientKill
 816
 817 Called when a client types 'kill' in the console
 818 =============
 819 */
 820
 821 void ClientKill_Now_TeamChange()
 822 {
 823         if(self.killindicator_teamchange == -1)
 824         {
 825                 self.team = -1;
 826                 JoinBestTeam( self, FALSE, FALSE );
 827         }
 828         else
 829         {
 830                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 831         }
 832 }
 833
 834 void ClientKill_Now()
 835 {
 836         if(self.killindicator_teamchange)
 837                 ClientKill_Now_TeamChange();
 838
 839         // in any case:
 840         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 841
 842         if(self.killindicator)
 843         {
 844                 dprint("Cleaned up after a leaked kill indicator.\n");
 845                 remove(self.killindicator);
 846                 self.killindicator = world;
 847         }
 848 }
 849 void KillIndicator_Think()
 850 {
 851         if (!self.owner.modelindex)
 852         {
 853                 self.owner.killindicator = world;
 854                 remove(self);
 855                 return;
 856         }
 857
 858         if(self.cnt <= 0)
 859         {
 860                 self = self.owner;
 861                 ClientKill_Now(); // no oldself needed
 862                 return;
 863         }
 864         else
 865         {
 866                 if(self.cnt <= 10)
 867                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 868                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 869                 {
 870                         if(self.cnt <= 10)
 871                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 872                         if(self.owner.killindicator_teamchange)
 873                         {
 874                                 if(self.owner.killindicator_teamchange == -1)
 875                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 876                                 else
 877                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 878                         }
 879                         else
 880                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 881                 }
 882                 self.nextthink = time + 1;
 883                 self.cnt -= 1;
 884         }
 885 }
 886
 887 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 888 {
 889         float killtime;
 890         entity e;
 891         killtime = cvar("g_balance_kill_delay");
 892
 893         self.killindicator_teamchange = targetteam;
 894
 895         if(!self.killindicator)
 896         {
 897                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 898                 {
 899                         ClientKill_Now();
 900                 }
 901                 else
 902                 {
 903                         self.killindicator = spawn();
 904                         self.killindicator.owner = self;
 905                         self.killindicator.scale = 0.5;
 906                         setattachment(self.killindicator, self, "");
 907                         setorigin(self.killindicator, '0 0 52');
 908                         self.killindicator.think = KillIndicator_Think;
 909                         self.killindicator.nextthink = time + (self.lip) * 0.05;
 910                         self.killindicator.cnt = ceil(killtime);
 911                         self.killindicator.count = bound(0, ceil(killtime), 10);
 912                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 913
 914                         for(e = world; (e = find(e, classname, "body")) != world; )
 915                         {
 916                                 if(e.enemy != self)
 917                                         continue;
 918                                 e.killindicator = spawn();
 919                                 e.killindicator.owner = e;
 920                                 e.killindicator.scale = 0.5;
 921                                 setattachment(e.killindicator, e, "");
 922                                 setorigin(e.killindicator, '0 0 52');
 923                                 e.killindicator.think = KillIndicator_Think;
 924                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
 925                                 e.killindicator.cnt = ceil(killtime);
 926                         }
 927                         self.lip = 0;
 928                 }
 929         }
 930         if(self.killindicator)
 931         {
 932                 if(targetteam)
 933                         self.killindicator.colormod = TeamColor(targetteam);
 934                 else
 935                         self.killindicator.colormod = '0 0 0';
 936         }
 937 }
 938
 939 void ClientKill (void)
 940 {
 941         ClientKill_TeamChange(0);
 942 }
 943
 944 void DoTeamChange(float destteam)
 945 {
 946         float t, c0;
 947         if(!cvar("teamplay"))
 948         {
 949                 if(destteam >= 0)
 950                         SetPlayerColors(self, destteam);
 951                 return;
 952         }
 953         if(self.classname == "player")
 954         if(destteam == -1)
 955         {
 956                 CheckAllowedTeams(self);
 957                 t = FindSmallestTeam(self, TRUE);
 958                 switch(self.team)
 959                 {
 960                         case COLOR_TEAM1: c0 = c1; break;
 961                         case COLOR_TEAM2: c0 = c2; break;
 962                         case COLOR_TEAM3: c0 = c3; break;
 963                         case COLOR_TEAM4: c0 = c4; break;
 964                         default:          c0 = 999;
 965                 }
 966                 switch(t)
 967                 {
 968                         case 1:
 969                                 if(c0 > c1)
 970                                         destteam = COLOR_TEAM1;
 971                                 break;
 972                         case 2:
 973                                 if(c0 > c2)
 974                                         destteam = COLOR_TEAM2;
 975                                 break;
 976                         case 3:
 977                                 if(c0 > c3)
 978                                         destteam = COLOR_TEAM3;
 979                                 break;
 980                         case 4:
 981                                 if(c0 > c4)
 982                                         destteam = COLOR_TEAM4;
 983                                 break;
 984                 }
 985                 if(destteam == -1)
 986                         return;
 987         }
 988         if(destteam == self.team && !self.killindicator)
 989                 return;
 990         ClientKill_TeamChange(destteam);
 991 }
 992
 993 void FixClientCvars(entity e)
 994 {
 995         // send prediction settings to the client
 996         stuffcmd(e, "\nin_bindmap 0 0\n");
 997         /*
 998          * we no longer need to stuff this. Remove this comment block if you feel
 999          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1000         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1001         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1002         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1003         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1004         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1005         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1006         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1007         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1008         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1009         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1010         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1011         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1012         stuffcmd(e, "cl_movement_edgefriction 1\n");
1013          */
1014 }
1015
1016 /*
1017 =============
1018 ClientConnect
1019
1020 Called when a client connects to the server
1021 =============
1022 */
1023 //void ctf_clientconnect();
1024 string ColoredTeamName(float t);
1025 void DecodeLevelParms (void);
1026 //void dom_player_join_team(entity pl);
1027 void ClientConnect (void)
1028 {
1029         local string s;
1030         float wep;
1031
1032         if(self.flags & FL_CLIENT)
1033         {
1034                 print("Warning: ClientConnect, but already connected!\n");
1035                 return;
1036         }
1037
1038         if(Ban_IsClientBanned(self))
1039         {
1040                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
1041                 dropclient(self);
1042                 bprint(s);
1043                 return;
1044         }
1045
1046         DecodeLevelParms();
1047
1048         self.classname = "player_joining";
1049
1050         self.flags = self.flags | FL_CLIENT;
1051         self.version_nagtime = time + 10 + random() * 10;
1052
1053         if(player_count<0)
1054         {
1055                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1056                 player_count = 0;
1057         }
1058
1059         PlayerScore_Attach(self);
1060
1061         bot_clientconnect();
1062
1063         race_PreSpawnObserver();
1064
1065         //if(g_domination)
1066         //      dom_player_join_team(self);
1067
1068         //JoinBestTeam(self, FALSE, FALSE);
1069
1070         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1071                 self.classname = "observer";
1072         } else {
1073                 self.classname = "player";
1074                 campaign_bots_may_start = 1;
1075         }
1076
1077         self.playerid = (playerid_last = playerid_last + 1);
1078         if(cvar("sv_eventlog"))
1079         {
1080                 if(clienttype(self) == CLIENTTYPE_REAL)
1081                         s = "player";
1082                 else
1083                         s = "bot";
1084                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
1085                 s = strcat(":team:", ftos(self.playerid), ":");
1086                 s = strcat(s, ftos(self.team));
1087                 GameLogEcho(s, FALSE);
1088         }
1089         self.netname_previous = strzone(self.netname);
1090
1091         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1092
1093         bprint ("^4",self.netname);
1094         bprint ("^4 connected");
1095
1096         if(g_domination || g_ctf)
1097         {
1098                 bprint(" and joined the ");
1099                 bprint(ColoredTeamName(self.team));
1100         }
1101
1102         bprint("\n");
1103
1104         self.welcomemessage_time = 0;
1105
1106         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1107         // TODO: is this being used for anything else than cd tracks?
1108         // Remember: SVC_CDTRACK exists. Maybe it should be used.
1109         //
1110         stuffcmd(self, "cl_particles_reloadeffects\n");
1111
1112         FixClientCvars(self);
1113
1114         // spawnfunc_waypoint sprites
1115         WaypointSprite_InitClient(self);
1116
1117         // Wazat's grappling hook
1118         SetGrappleHookBindings();
1119
1120         // get autoswitch state from player when he toggles it
1121         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1122
1123         // get version info from player
1124         stuffcmd(self, "cmd clientversion $gameversion\n");
1125
1126         // send all weapon info strings
1127         stuffcmd(self, "register_bestweapon clear\n"); // clear the Quake stuff
1128         wep = WEP_FIRST;
1129         while (wep <= WEP_LAST)
1130         {
1131                 weapon_action(wep, WR_REGISTER);
1132                 wep = wep + 1;
1133         }
1134
1135         // get other cvars from player
1136         GetCvars(0);
1137
1138         // set cvar for team scoreboard
1139         if (teams_matter)
1140         {
1141                 local float t;
1142                 t = cvar("teamplay");
1143                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1144                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1145         }
1146         else
1147                 stuffcmd(self, "set teamplay 0\n");
1148
1149         // notify about available teams
1150         if(teamplay)
1151         {
1152                 CheckAllowedTeams(self);
1153                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1154                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1155         }
1156         else
1157                 stuffcmd(self, "set _teams_available 0\n");
1158
1159         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1160
1161         if(g_arena)
1162         {
1163                 self.classname = "observer";
1164                 Spawnqueue_Insert(self);
1165         }
1166         /*else if(g_ctf)
1167         {
1168                 ctf_clientconnect();
1169         }*/
1170
1171         if(entcs_start)
1172                 attach_entcs();
1173
1174         bot_relinkplayerlist();
1175
1176         self.spectatortime = time;
1177         if(blockSpectators)
1178         {
1179                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1180         }
1181
1182         self.jointime = time;
1183         self.allowedTimeouts = cvar("sv_timeout_number");
1184
1185         if(clienttype(self) == CLIENTTYPE_REAL)
1186         {
1187                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1188                 SendCSQCInfo();
1189                 msg_entity = self;
1190                 if(mapvote_initialized && !cvar("g_maplist_textonly"))
1191                 {
1192                         MapVote_SendData(MSG_ONE);
1193                         MapVote_UpdateData(MSG_ONE);
1194                 }
1195                 ScoreInfo_Write(MSG_ONE);
1196         }
1197
1198         if(g_lms)
1199         {
1200                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1201                 {
1202                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1203                         self.frags = -666; // FIXME do we still need this?
1204                 }
1205         }
1206 }
1207
1208 /*
1209 =============
1210 ClientDisconnect
1211
1212 Called when a client disconnects from the server
1213 =============
1214 */
1215 void(entity e) DropFlag;
1216 .entity chatbubbleentity;
1217 .entity teambubbleentity;
1218 //void() ctf_clientdisconnect;
1219 void ClientDisconnect (void)
1220 {
1221         float save;
1222
1223         if not(self.flags & FL_CLIENT)
1224         {
1225                 print("Warning: ClientDisconnect without ClientConnect\n");
1226                 return;
1227         }
1228
1229         bot_clientdisconnect();
1230
1231         if(entcs_start)
1232                 detach_entcs();
1233
1234         if(cvar("sv_eventlog"))
1235                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
1236         bprint ("^4",self.netname);
1237         bprint ("^4 disconnected\n");
1238
1239         if (self.chatbubbleentity)
1240         {
1241                 remove (self.chatbubbleentity);
1242                 self.chatbubbleentity = world;
1243         }
1244
1245         if (self.teambubbleentity)
1246         {
1247                 remove (self.teambubbleentity);
1248                 self.teambubbleentity = world;
1249         }
1250
1251         if (self.killindicator)
1252         {
1253                 remove (self.killindicator);
1254                 self.killindicator = world;
1255         }
1256
1257         WaypointSprite_PlayerGone();
1258
1259         DropAllRunes(self);
1260         kh_Key_DropAll(self, TRUE);
1261
1262         if(self.flagcarried)
1263                 DropFlag(self.flagcarried);
1264
1265         save = self.flags;
1266         self.flags = self.flags - (self.flags & FL_CLIENT);
1267         bot_relinkplayerlist();
1268         self.flags = save;
1269
1270         // remove laserdot
1271         if(self.weaponentity)
1272                 if(self.weaponentity.lasertarget)
1273                         remove(self.weaponentity.lasertarget);
1274
1275         if(g_arena)
1276         {
1277                 Spawnqueue_Unmark(self);
1278                 Spawnqueue_Remove(self);
1279         }
1280         /*if(g_ctf)
1281         {
1282                 ctf_clientdisconnect();
1283         }
1284         */
1285
1286         PlayerScore_Detach(self);
1287
1288         if(self.netname_previous)
1289                 strunzone(self.netname_previous);
1290
1291         ClearPlayerSounds();
1292
1293         // free cvars
1294         GetCvars(-1);
1295         self.playerid = 0;
1296 }
1297
1298 .float BUTTON_CHAT;
1299 void ChatBubbleThink()
1300 {
1301         self.nextthink = time;
1302         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1303         {
1304                 self.owner.chatbubbleentity = world;
1305                 remove(self);
1306                 return;
1307         }
1308         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1309         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1310                 self.model = self.mdl;
1311         else
1312                 self.model = "";
1313 };
1314
1315 void UpdateChatBubble()
1316 {
1317         if (!self.modelindex)
1318                 return;
1319         // spawn a chatbubble entity if needed
1320         if (!self.chatbubbleentity)
1321         {
1322                 self.chatbubbleentity = spawn();
1323                 self.chatbubbleentity.owner = self;
1324                 self.chatbubbleentity.exteriormodeltoclient = self;
1325                 self.chatbubbleentity.think = ChatBubbleThink;
1326                 self.chatbubbleentity.nextthink = time;
1327                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1328                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1329                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1330                 self.chatbubbleentity.model = "";
1331                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1332         }
1333 }
1334
1335
1336 void TeamBubbleThink()
1337 {
1338         self.nextthink = time;
1339         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1340         {
1341                 self.owner.teambubbleentity = world;
1342                 remove(self);
1343                 return;
1344         }
1345 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1346         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1347                 self.model = "";
1348         else
1349                 self.model = self.mdl;
1350
1351 };
1352
1353 float TeamBubble_customizeentityforclient()
1354 {
1355         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1356 }
1357
1358 void UpdateTeamBubble()
1359 {
1360         if (!self.modelindex || !cvar("teamplay"))
1361                 return;
1362         // spawn a teambubble entity if needed
1363         if (!self.teambubbleentity && cvar("teamplay"))
1364         {
1365                 self.teambubbleentity = spawn();
1366                 self.teambubbleentity.owner = self;
1367                 self.teambubbleentity.exteriormodeltoclient = self;
1368                 self.teambubbleentity.think = TeamBubbleThink;
1369                 self.teambubbleentity.nextthink = time;
1370                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1371 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1372                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1373                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1374                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1375                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1376                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1377                 self.teambubbleentity.effects = EF_LOWPRECISION;
1378         }
1379 }
1380
1381 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1382 // added to the model skins
1383 /*void UpdateColorModHack()
1384 {
1385         local float c;
1386         c = self.clientcolors & 15;
1387         // LordHavoc: only bothering to support white, green, red, yellow, blue
1388              if (teamplay == 0) self.colormod = '0 0 0';
1389         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1390         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1391         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1392         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1393         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1394         else self.colormod = '1 1 1';
1395 };*/
1396
1397 void respawn(void)
1398 {
1399         CopyBody(1);
1400         self.effects |= EF_NODRAW; // prevent another CopyBody
1401         PutClientInServer();
1402 }
1403
1404 /**
1405  * When sv_timeout is used this function returs strings like
1406  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1407  * Called by centerprint functions
1408  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1409  */
1410 string getTimeoutText(float addOneSecond) {
1411         if (!cvar("sv_timeout") || !timeoutStatus)
1412                 return "";
1413
1414         local string retStr;
1415         if (timeoutStatus == 1) {
1416                 if (addOneSecond == 1) {
1417                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1418                 }
1419                 else {
1420                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1421                 }
1422                 return retStr;
1423         }
1424         else if (timeoutStatus == 2) {
1425                 if (addOneSecond) {
1426                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1427                         //don't show messages like "Timeout ends in 0 seconds"...
1428                         if ((remainingTimeoutTime + 1) > 0)
1429                                 return retStr;
1430                         else
1431                                 return "";
1432                 }
1433                 else {
1434                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1435                         //don't show messages like "Timeout ends in 0 seconds"...
1436                         if (remainingTimeoutTime > 0)
1437                                 return retStr;
1438                         else
1439                                 return "";
1440                 }
1441         }
1442         else return "";
1443 }
1444
1445 void player_powerups (void)
1446 {
1447         if (g_minstagib)
1448         {
1449                 if (self.items & IT_STRENGTH)
1450                 {
1451                         if (time > self.strength_finished)
1452                         {
1453                                 if (g_minstagib_invis_alpha > 0)
1454                                 {
1455                                         self.alpha = default_player_alpha;
1456                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1457                                         self.effects = self.effects | EF_FULLBRIGHT;
1458                                 }
1459                                 else
1460                                 {
1461                                         self.effects -= self.effects & EF_NODRAW;
1462                                 }
1463                                 self.items = self.items - (self.items & IT_STRENGTH);
1464                                 sprint(self, "^3Invisibility has worn off\n");
1465                         }
1466                 }
1467                 else
1468                 {
1469                         if (time < self.strength_finished)
1470                         {
1471                                 if (g_minstagib_invis_alpha > 0)
1472                                 {
1473                                         self.alpha = g_minstagib_invis_alpha;
1474                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1475                                         self.effects -= self.effects & EF_FULLBRIGHT;
1476                                 }
1477                                 else
1478                                 {
1479                                         self.effects = self.effects | EF_NODRAW;
1480                                 }
1481                                 self.items = self.items | IT_STRENGTH;
1482                                 sprint(self, "^3You are invisible\n");
1483                         }
1484                 }
1485
1486                 if (self.items & IT_INVINCIBLE)
1487                 {
1488                         if (time > self.invincible_finished)
1489                         {
1490                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1491                                 sprint(self, "^3Speed has worn off\n");
1492                         }
1493                 }
1494                 else
1495                 {
1496                         if (time < self.invincible_finished)
1497                         {
1498                                 self.items = self.items | IT_INVINCIBLE;
1499                                 sprint(self, "^3You are on speed\n");
1500                         }
1501                 }
1502                 return;
1503         }
1504
1505         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1506         if (self.items & IT_STRENGTH)
1507         {
1508                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1509                 if (time > self.strength_finished)
1510                 {
1511                         self.items = self.items - (self.items & IT_STRENGTH);
1512                         sprint(self, "^3Strength has worn off\n");
1513                 }
1514         }
1515         else
1516         {
1517                 if (time < self.strength_finished)
1518                 {
1519                         self.items = self.items | IT_STRENGTH;
1520                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1521                 }
1522         }
1523         if (self.items & IT_INVINCIBLE)
1524         {
1525                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1526                 if (time > self.invincible_finished)
1527                 {
1528                         self.items = self.items - (self.items & IT_INVINCIBLE);
1529                         sprint(self, "^3Shield has worn off\n");
1530                 }
1531         }
1532         else
1533         {
1534                 if (time < self.invincible_finished)
1535                 {
1536                         self.items = self.items | IT_INVINCIBLE;
1537                         sprint(self, "^3Shield surrounds you\n");
1538                 }
1539         }
1540
1541         if (cvar("g_fullbrightplayers"))
1542                 self.effects = self.effects | EF_FULLBRIGHT;
1543
1544         // midair gamemode: damage only while in the air
1545         // if in midair mode, being on ground grants temporary invulnerability
1546         // (this is so that multishot weapon don't clear the ground flag on the
1547         // first damage in the frame, leaving the player vulnerable to the
1548         // remaining hits in the same frame)
1549         if (self.flags & FL_ONGROUND)
1550         if (g_midair)
1551                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1552
1553         if (time < self.spawnshieldtime)
1554                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1555 }
1556
1557 float CalcRegen(float current, float stable, float regenfactor)
1558 {
1559         if(current > stable)
1560                 return current;
1561         else if(current > stable - 0.25) // when close enough, "snap"
1562                 return stable;
1563         else
1564                 return min(stable, current + (stable - current) * regenfactor * frametime);
1565 }
1566
1567 void player_regen (void)
1568 {
1569         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1570         maxh = cvar("g_balance_health_stable");
1571         maxa = cvar("g_balance_armor_stable");
1572         limith = cvar("g_balance_health_limit");
1573         limita = cvar("g_balance_armor_limit");
1574
1575         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1576                 return;
1577
1578         max_mod = regen_mod = rot_mod = limit_mod = 1;
1579
1580         if (self.runes & RUNE_REGEN)
1581         {
1582                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1583                 {
1584                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1585                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1586                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1587                 }
1588                 else
1589                 {
1590                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1591                         max_mod = cvar("g_balance_rune_regen_hpmod");
1592                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1593                 }
1594         }
1595         else if (self.runes & CURSE_VENOM)
1596         {
1597                 max_mod = cvar("g_balance_curse_venom_hpmod");
1598                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1599                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1600                 else
1601                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1602                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1603                 //if (!self.runes & RUNE_REGEN)
1604                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1605         }
1606         maxh = maxh * max_mod;
1607         //maxa = maxa * max_mod;
1608         limith = limith * limit_mod;
1609         limita = limita * limit_mod;
1610
1611         if (self.armorvalue > maxa)
1612         {
1613                 if (time > self.pauserotarmor_finished)
1614                 {
1615                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1616                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1617                 }
1618         }
1619         else if (self.armorvalue < maxa)
1620         {
1621                 if (time > self.pauseregen_finished)
1622                 {
1623                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1624                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1625                 }
1626         }
1627         if (self.health > maxh)
1628         {
1629                 if (time > self.pauserothealth_finished)
1630                 {
1631                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1632                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1633                 }
1634         }
1635         else if (self.health < maxh)
1636         {
1637                 if (time > self.pauseregen_finished)
1638                 {
1639                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1640                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1641                 }
1642         }
1643
1644         if (self.health > limith)
1645                 self.health = limith;
1646         if (self.armorvalue > limita)
1647                 self.armorvalue = limita;
1648
1649         // if player rotted to death...  die!
1650         if(self.health < 1)
1651                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1652 }
1653
1654 /*
1655 ======================
1656 spectate mode routines
1657 ======================
1658 */
1659 void SpectateCopy(entity spectatee) {
1660         self.armortype = spectatee.armortype;
1661         self.armorvalue = spectatee.armorvalue;
1662         self.currentammo = spectatee.currentammo;
1663         self.effects = spectatee.effects;
1664         self.health = spectatee.health;
1665         self.impulse = 0;
1666         self.items = spectatee.items;
1667         self.punchangle = spectatee.punchangle;
1668         self.view_ofs = spectatee.view_ofs;
1669         self.v_angle = spectatee.v_angle;
1670         self.viewzoom = spectatee.viewzoom;
1671         self.velocity = spectatee.velocity;
1672         self.dmg_take = spectatee.dmg_take;
1673         self.dmg_save = spectatee.dmg_save;
1674         self.dmg_inflictor = spectatee.dmg_inflictor;
1675         self.angles = spectatee.v_angle;
1676         self.fixangle = TRUE;
1677         setorigin(self, spectatee.origin);
1678         setsize(self, spectatee.mins, spectatee.maxs);
1679 }
1680
1681 float SpectateUpdate() {
1682         if(!self.enemy)
1683                 return 0;
1684
1685         if (self == self.enemy)
1686                 return 0;
1687
1688         if(self.enemy.flags & FL_NOTARGET)
1689                 return 0;
1690
1691         SpectateCopy(self.enemy);
1692
1693         return 1;
1694 }
1695
1696 float SpectateNext() {
1697         other = find(self.enemy, classname, "player");
1698         if (!other) {
1699                 other = find(other, classname, "player");
1700         }
1701         if (other) {
1702                 self.enemy = other;
1703         }
1704         if(self.enemy.classname == "player") {
1705                 msg_entity = self;
1706                 WriteByte(MSG_ONE, SVC_SETVIEW);
1707                 WriteEntity(MSG_ONE, self.enemy);
1708                 self.wantswelcomemessage = 1;
1709                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1710                 if(!SpectateUpdate())
1711                         PutObserverInServer();
1712                 return 1;
1713         } else {
1714                 return 0;
1715         }
1716 }
1717
1718 /*
1719 =============
1720 ShowRespawnCountdown()
1721
1722 Update a respawn countdown display.
1723 =============
1724 */
1725 void ShowRespawnCountdown()
1726 {
1727         float number;
1728         if(self.deadflag == DEAD_NO) // just respawned?
1729                 return;
1730         else
1731         {
1732                 number = ceil(self.death_time - time);
1733                 if(number <= 0)
1734                         return;
1735                 if(number <= self.respawn_countdown)
1736                 {
1737                         self.respawn_countdown = number - 1;
1738                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1739                                 announce(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1740                 }
1741         }
1742 }
1743
1744 void LeaveSpectatorMode()
1745 {
1746         if(isJoinAllowed()) {
1747                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1748                         self.classname = "player";
1749                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1750                                 JoinBestTeam(self, FALSE, TRUE);
1751                         if(cvar("g_campaign"))
1752                                 campaign_bots_may_start = 1;
1753                         PutClientInServer();
1754                         if(!(self.flags & FL_NOTARGET))
1755                                 bprint ("^4", self.netname, "^4 is playing now\n");
1756                         centerprint(self,"");
1757                         return;
1758                 } else {
1759                         stuffcmd(self,"menu_showteamselect\n");
1760                         return;
1761                 }
1762         }
1763         else {
1764                 //player may not join because of g_maxplayers is set
1765                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1766         }
1767 }
1768
1769 /**
1770  * Determines whether the player is allowed to join. This depends on cvar
1771  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1772  * it checks whether the number of currently playing players exceeds g_maxplayers.
1773  * @return bool TRUE if the player is allowed to join, false otherwise
1774  */
1775 float isJoinAllowed() {
1776         if (!cvar("g_maxplayers"))
1777                 return TRUE;
1778
1779         local entity e;
1780         local float currentlyPlaying;
1781         FOR_EACH_REALPLAYER(e) {
1782                 if(e.classname == "player")
1783                         currentlyPlaying += 1;
1784         }
1785         if(currentlyPlaying < cvar("g_maxplayers"))
1786                 return TRUE;
1787
1788         return FALSE;
1789 }
1790
1791 /**
1792  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1793  * g_maxplayers_spectator_blocktime seconds
1794  */
1795 void checkSpectatorBlock() {
1796         if(self.classname == "spectator" || self.classname == "observer") {
1797                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1798                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1799                         dropclient(self);
1800                 }
1801         }
1802 }
1803
1804 float vercmp_recursive(string v1, string v2)
1805 {
1806         float dot1, dot2;
1807         string s1, s2;
1808         float r;
1809
1810         dot1 = strstrofs(v1, ".", 0);
1811         dot2 = strstrofs(v2, ".", 0);
1812         if(dot1 == -1)
1813                 s1 = v1;
1814         else
1815                 s1 = substring(v1, 0, dot1);
1816         if(dot2 == -1)
1817                 s2 = v2;
1818         else
1819                 s2 = substring(v2, 0, dot2);
1820
1821         r = stof(s1) - stof(s2);
1822         if(r != 0)
1823                 return r;
1824
1825         r = strcasecmp(s1, s2);
1826         if(r != 0)
1827                 return r;
1828
1829         if(dot1 == -1)
1830                 if(dot2 == -1)
1831                         return 0;
1832                 else
1833                         return -1;
1834         else
1835                 if(dot2 == -1)
1836                         return 1;
1837                 else
1838                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1839 }
1840
1841 float vercmp(string v1, string v2)
1842 {
1843         if(strcasecmp(v1, v2) == 0) // early out check
1844                 return 0;
1845         return vercmp_recursive(v1, v2);
1846 }
1847
1848 void ObserverThink()
1849 {
1850         if (self.flags & FL_JUMPRELEASED) {
1851                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1852                         self.welcomemessage_time = 0;
1853                         self.flags = self.flags - FL_JUMPRELEASED;
1854                         LeaveSpectatorMode();
1855                         return;
1856                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
1857                         self.welcomemessage_time = 0;
1858                         self.flags = self.flags - FL_JUMPRELEASED;
1859                         if(SpectateNext() == 1) {
1860                                 self.classname = "spectator";
1861                         }
1862                 }
1863         } else {
1864                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
1865                         self.flags = self.flags | FL_JUMPRELEASED;
1866                 }
1867         }
1868         if(self.BUTTON_ZOOM)
1869                 self.wantswelcomemessage = 0;
1870         if(self.wantswelcomemessage)
1871                 PrintWelcomeMessage(self);
1872 }
1873
1874 void SpectatorThink()
1875 {
1876         if (self.flags & FL_JUMPRELEASED) {
1877                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1878                         self.welcomemessage_time = 0;
1879                         self.flags = self.flags - FL_JUMPRELEASED;
1880                         LeaveSpectatorMode();
1881                         return;
1882                 } else if(self.BUTTON_ATCK) {
1883                         self.welcomemessage_time = 0;
1884                         self.flags = self.flags - FL_JUMPRELEASED;
1885                         if(SpectateNext() == 1) {
1886                                 self.classname = "spectator";
1887                         } else {
1888                                 self.classname = "observer";
1889                                 PutClientInServer();
1890                         }
1891                 } else if (self.BUTTON_ATCK2) {
1892                         self.welcomemessage_time = 0;
1893                         self.flags = self.flags - FL_JUMPRELEASED;
1894                         self.classname = "observer";
1895                         PutClientInServer();
1896                 } else {
1897                         if(!SpectateUpdate())
1898                                 PutObserverInServer();
1899                 }
1900         } else {
1901                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
1902                         self.flags = self.flags | FL_JUMPRELEASED;
1903                 }
1904         }
1905         if(self.BUTTON_ZOOM)
1906                 self.wantswelcomemessage = 0;
1907         if(self.wantswelcomemessage)
1908                 PrintWelcomeMessage(self);
1909         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1910 }
1911
1912 /*
1913 =============
1914 PlayerPreThink
1915
1916 Called every frame for each client before the physics are run
1917 =============
1918 */
1919 void() ctf_setstatus;
1920 .float vote_nagtime;
1921 void PlayerPreThink (void)
1922 {
1923         if(blockSpectators)
1924                 checkSpectatorBlock();
1925
1926         if(self.netname_previous != self.netname)
1927         {
1928                 if(cvar("sv_eventlog"))
1929                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname), TRUE);
1930                 if(self.netname_previous)
1931                         strunzone(self.netname_previous);
1932                 self.netname_previous = strzone(self.netname);
1933         }
1934
1935         // version nagging
1936         if(self.version_nagtime)
1937                 if(self.cvar_g_nexuizversion)
1938                         if(time > self.version_nagtime)
1939                         {
1940                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1941                                 {
1942                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
1943                                         {
1944                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1945                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1946                                         }
1947                                         else
1948                                         {
1949                                                 float r;
1950                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
1951                                                 if(r < 0)
1952                                                 {
1953                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
1954                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
1955                                                 }
1956                                                 else if(r > 0)
1957                                                 {
1958                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1959                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1960                                                 }
1961                                         }
1962                                 }
1963                                 self.version_nagtime = 0;
1964                         }
1965
1966         // vote nagging
1967         if(self.cvar_scr_centertime)
1968                 if(time > self.vote_nagtime)
1969                 {
1970                         VoteNag();
1971                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1972                 }
1973
1974         // GOD MODE info
1975         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
1976         {
1977                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
1978                 self.max_armorvalue = 0;
1979         }
1980
1981         if(frametime)
1982                 antilag_record(self);
1983
1984         if(self.classname == "player") {
1985 //              if(self.netname == "Wazat")
1986 //                      bprint(self.classname, "\n");
1987
1988                 CheckRules_Player();
1989
1990                 if(self.BUTTON_INFO)
1991                         PrintWelcomeMessage(self);
1992
1993                 if(g_lms || !cvar("sv_spectate"))
1994                 if((time - self.jointime) <= cvar("welcome_message_time"))
1995                         PrintWelcomeMessage(self);
1996
1997                 if (intermission_running)
1998                 {
1999                         IntermissionThink ();   // otherwise a button could be missed between
2000                         return;                                 // the think tics
2001                 }
2002
2003                 if(self.teleport_time)
2004                 if(time > self.teleport_time)
2005                 {
2006                         self.teleport_time = 0;
2007                         self.effects = self.effects - (self.effects & EF_NODRAW);
2008                         if(self.weaponentity)
2009                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
2010                 }
2011
2012                 Nixnex_GiveCurrentWeapon();
2013
2014                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2015                         UpdateSelectedPlayer();
2016
2017                 //don't allow the player to turn around while game is paused!
2018                 if(timeoutStatus == 2) {
2019                         self.v_angle = self.lastV_angle;
2020                         self.angles = self.lastV_angle;
2021                         self.fixangle = TRUE;
2022                 }
2023
2024                 if (self.deadflag != DEAD_NO)
2025                 {
2026                         float button_pressed, force_respawn;
2027                         player_anim();
2028                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2029                         force_respawn = (g_lms || cvar("g_forced_respawn"));
2030                         if (self.deadflag == DEAD_DYING)
2031                         {
2032                                 if(force_respawn)
2033                                         self.deadflag = DEAD_RESPAWNING;
2034                                 else if(!button_pressed)
2035                                         self.deadflag = DEAD_DEAD;
2036                         }
2037                         else if (self.deadflag == DEAD_DEAD)
2038                         {
2039                                 if(button_pressed)
2040                                         self.deadflag = DEAD_RESPAWNABLE;
2041                         }
2042                         else if (self.deadflag == DEAD_RESPAWNABLE)
2043                         {
2044                                 if(!button_pressed)
2045                                         self.deadflag = DEAD_RESPAWNING;
2046                         }
2047                         else if (self.deadflag == DEAD_RESPAWNING)
2048                         {
2049                                 if(time > self.death_time)
2050                                 {
2051                                         self.death_time = time + 1; // only retry once a second
2052                                         respawn();
2053                                 }
2054                         }
2055                         ShowRespawnCountdown();
2056                         return;
2057                 }
2058
2059                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2060                 {
2061                         vector dist;
2062
2063                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2064                         dist = self.oldorigin - self.origin;
2065                         dist_z = 0;
2066                         self.lms_traveled_distance += fabs(vlen(dist));
2067
2068                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
2069                         {
2070                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2071                                 self.lms_traveled_distance = 0;
2072                         }
2073
2074                         if(time > self.lms_nextcheck)
2075                         {
2076                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2077                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2078                                 {
2079                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2080                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2081                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2082                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2083                                 }
2084                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2085                                 self.lms_traveled_distance = 0;
2086                         }
2087                 }
2088
2089                 if (self.BUTTON_CROUCH && !self.hook.state)
2090                 {
2091                         if (!self.crouch)
2092                         {
2093                                 self.crouch = TRUE;
2094                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2095                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2096                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
2097                         }
2098                 }
2099                 else
2100                 {
2101                         if (self.crouch)
2102                         {
2103                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2104                                 if (!trace_startsolid)
2105                                 {
2106                                         self.crouch = FALSE;
2107                                         self.view_ofs = PL_VIEW_OFS;
2108                                         setsize (self, PL_MIN, PL_MAX);
2109                                 }
2110                         }
2111                 }
2112
2113                 FixPlayermodel();
2114
2115                 GrapplingHookFrame();
2116
2117                 W_WeaponFrame();
2118
2119                 {
2120                         float zoomfactor, zoomspeed, zoomdir;
2121                         zoomfactor = self.cvar_cl_zoomfactor;
2122                         if(zoomfactor < 1 || zoomfactor > 16)
2123                                 zoomfactor = 2.5;
2124                         zoomspeed = self.cvar_cl_zoomspeed;
2125                         if(zoomspeed >= 0) // < 0 is instant zoom
2126                                 if(zoomspeed < 0.5 || zoomspeed > 16)
2127                                         zoomspeed = 3.5;
2128
2129                         zoomdir = self.BUTTON_ZOOM;
2130                         if(self.BUTTON_ATCK2)
2131                                 if(self.weapon == WEP_NEX)
2132                                         if(!g_minstagib)
2133                                                 zoomdir = 1;
2134
2135                         if(zoomdir)
2136                                 self.has_zoomed = 1;
2137
2138                         if(self.has_zoomed)
2139                         {
2140                                 if(zoomspeed <= 0) // instant zoom
2141                                 {
2142                                         if(zoomdir)
2143                                                 self.viewzoom = 1 / zoomfactor;
2144                                         else
2145                                                 self.viewzoom = 1;
2146                                 }
2147                                 else
2148                                 {
2149                                         // geometric zoom would be:
2150                                         //   self.viewzoom = bound(1 / zoomfactor, self.viewzoom * pow(zoomfactor, (zoomdir ? -1 : 1) * frametime * zoomspeed), 1);
2151                                         // however, testing showed that arithmetic/harmonic zoom works better
2152                                         if(zoomdir)
2153                                                 // self.viewzoom = 1 / bound(1, 1 / self.viewzoom + (zoomdir ? 1 : -1) * frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2154                                                 // zoom in = arithmetic: 1x, 2x, 3x, 4x, ..., 8x
2155                                                 self.viewzoom = 1 / bound(1, 1 / self.viewzoom + frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2156                                         else
2157                                                 // self.viewzoom = bound(1 / zoomfactor, self.viewzoom + (zoomdir ? -1 : 1) * frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2158                                                 // zoom out = harmonic: 8/1x, 8/2x, 8/3x, 8/4x, ..., 8/8x
2159                                                 self.viewzoom = bound(1 / zoomfactor, self.viewzoom + frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2160                                 }
2161                         }
2162                         else
2163                                 self.viewzoom = min(1, self.viewzoom + frametime); // spawn zoom-in
2164                 }
2165
2166                 player_powerups();
2167                 player_regen();
2168                 player_anim();
2169
2170                 if (g_minstagib)
2171                         minstagib_ammocheck();
2172
2173                 ctf_setstatus();
2174                 kh_setstatus();
2175
2176                 //self.angles_y=self.v_angle_y + 90;   // temp
2177
2178                 //if (TetrisPreFrame()) return;
2179         } else if(gameover) {
2180                 if (intermission_running)
2181                         IntermissionThink ();   // otherwise a button could be missed between
2182                 return;
2183         } else if(self.classname == "observer") {
2184                 ObserverThink();
2185         } else if(self.classname == "spectator") {
2186                 SpectatorThink();
2187         }
2188 }
2189
2190
2191 /*
2192 =============
2193 PlayerPostThink
2194
2195 Called every frame for each client after the physics are run
2196 =============
2197 */
2198 .float idlekick_lasttimeleft;
2199 .float race_penalty;
2200 .float race_penalty_nagged;
2201 void PlayerPostThink (void)
2202 {
2203         // Savage: Check for nameless players
2204         if (strlen(self.netname) < 1) {
2205                 self.netname = "Player";
2206                 stuffcmd(self, "seta _cl_name Player\n");
2207         }
2208
2209         if(sv_maxidle)
2210         {
2211                 float timeleft;
2212                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2213                 if(timeleft <= 0)
2214                 {
2215                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2216                         announce(self, "announcer/robotic/terminated.ogg");
2217                         dropclient(self);
2218                         return;
2219                 }
2220                 else if(timeleft <= 10)
2221                 {
2222                         if(timeleft != self.idlekick_lasttimeleft)
2223                         {
2224                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2225                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".ogg"));
2226                         }
2227                 }
2228                 else
2229                 {
2230                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2231                 }
2232                 self.idlekick_lasttimeleft = timeleft;
2233         }
2234
2235         if(self.classname == "player") {
2236                 CheckRules_Player();
2237                 UpdateChatBubble();
2238                 UpdateTeamBubble();
2239                 if (self.impulse)
2240                         ImpulseCommands();
2241                 if (intermission_running)
2242                         return;         // intermission or finale
2243
2244                 //PrintWelcomeMessage(self);
2245                 //if (TetrisPostFrame()) return;
2246
2247                 // restart countdown
2248                 if (restart_countdown) {
2249                         if(time < restart_countdown) {
2250                                 if (!cvar("sv_ready_restart_after_countdown"))
2251                                 {
2252                                         if(self.movement != '0 0 0' && g_race && !g_race_qualifying)
2253                                         {
2254                                                 if(time < restart_countdown - 2)
2255                                                 {
2256                                                         if(!self.race_penalty_nagged)
2257                                                         {
2258                                                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1DO NOT MOVE DURING THE COUNTDOWN.");
2259                                                                 self.race_penalty_nagged = 1;
2260                                                         }
2261                                                 }
2262                                                 else if(!self.race_penalty)
2263                                                 {
2264                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1FIVE SECONDS PENALTY.");
2265                                                         self.race_penalty = time + 5;
2266                                                 }
2267                                         }
2268                                         self.movetype = MOVETYPE_NONE;
2269                                         self.velocity = '0 0 0';
2270                                         self.avelocity = '0 0 0';
2271                                         self.movement = '0 0 0';
2272                                 }
2273                         }
2274                         else if (time < self.race_penalty)
2275                         {
2276                                 self.movetype = MOVETYPE_NONE;
2277                                 self.velocity = '0 0 0';
2278                                 self.avelocity = '0 0 0';
2279                                 self.movement = '0 0 0';
2280                         }
2281                         else
2282                         {
2283                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2284                                 if (!cvar("sv_ready_restart_after_countdown"))
2285                                 {
2286                                         if(self.movetype == MOVETYPE_NONE)
2287                                         {
2288                                                 self.movetype = MOVETYPE_WALK;
2289                                         }
2290                                         self.race_penalty = 0;
2291                                         self.race_penalty_nagged = 0;
2292                                 }
2293                         }
2294                 }
2295
2296         } else if (self.classname == "observer") {
2297                 //do nothing
2298         } else if (self.classname == "spectator") {
2299                 //do nothing
2300         }
2301
2302         /*
2303         float i;
2304         for(i = 0; i < 1000; ++i)
2305         {
2306                 vector end;
2307                 end = self.origin + '0 0 1024' + 512 * randomvec();
2308                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2309                 if(trace_fraction < 1)
2310                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2311                 {
2312                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2313                         break;
2314                 }
2315         }
2316         */
2317
2318         Arena_Warmup();
2319 }