data/qcsrc/server/cl_client.qc

   1 // let's abuse an existing field
   2 #define SPAWNPOINT_SCORE frags
   3
   4 .float wantswelcomemessage;
   5 .string netname_previous;
   6
   7 void spawnfunc_info_player_survivor (void)
   8 {
   9         spawnfunc_info_player_deathmatch();
  10 }
  11
  12 void spawnfunc_info_player_start (void)
  13 {
  14         spawnfunc_info_player_deathmatch();
  15 }
  16
  17 void spawnfunc_info_player_deathmatch (void)
  18 {
  19         self.classname = "info_player_deathmatch";
  20         relocate_spawnpoint();
  21 }
  22
  23 void spawnpoint_use()
  24 {
  25         if(teams_matter)
  26         if(have_team_spawns)
  27         {
  28                 self.team = activator.team;
  29                 some_spawn_has_been_used = 1;
  30         }
  31 };
  32
  33 // Returns:
  34 //   -1 if a spawn can't be used
  35 //   otherwise, a weight of the spawnpoint
  36 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
  37 {
  38         float shortest, thisdist;
  39         entity player;
  40
  41         // filter out spots for the wrong team
  42         if(teamcheck)
  43         if(spot.team != teamcheck)
  44                 return -1;
  45
  46         // filter out spots for assault
  47         if(spot.target != "") {
  48                 local entity ent;
  49                 ent = find(world, targetname, spot.target);
  50                 while(ent) {
  51                         if(ent.classname == "target_objective")
  52                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  53                                         return -1;
  54                         ent = find(ent, targetname, spot.target);
  55                 }
  56         }
  57
  58         player = playerlist;
  59         shortest = vlen(world.maxs - world.mins);
  60         for(player = playerlist; player; player = player.chain)
  61                 if (player != self)
  62                 {
  63                         thisdist = vlen(player.origin - spot.origin);
  64                         if (thisdist < shortest)
  65                                 shortest = thisdist;
  66                 }
  67         return shortest;
  68 }
  69
  70 float spawn_allbad;
  71 float spawn_allgood;
  72 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  73 {
  74         local entity spot, spotlist, spotlistend;
  75         spawn_allgood = TRUE;
  76         spawn_allbad = TRUE;
  77
  78         spotlist = world;
  79         spotlistend = world;
  80
  81         for(spot = firstspot; spot; spot = spot.chain)
  82         {
  83                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
  84
  85                 if(cvar("spawn_debugview"))
  86                 {
  87                         setmodel(spot, "models/runematch/rune.mdl");
  88                         if(spot.SPAWNPOINT_SCORE < mindist)
  89                         {
  90                                 spot.colormod = '1 0 0';
  91                                 spot.scale = 1;
  92                         }
  93                         else
  94                         {
  95                                 spot.colormod = '0 1 0';
  96                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
  97                         }
  98                 }
  99
 100                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 101                 {
 102                         if(spot.SPAWNPOINT_SCORE < mindist)
 103                         {
 104                                 // too short distance
 105                                 spawn_allgood = FALSE;
 106                         }
 107                         else
 108                         {
 109                                 // perfect
 110                                 spawn_allbad = FALSE;
 111
 112                                 if(spotlistend)
 113                                         spotlistend.chain = spot;
 114                                 spotlistend = spot;
 115                                 if(!spotlist)
 116                                         spotlist = spot;
 117
 118                                 /*
 119                                 if(teamcheck)
 120                                 if(spot.team != teamcheck)
 121                                         error("invalid spawn added");
 122
 123                                 print("added ", etos(spot), "\n");
 124                                 */
 125                         }
 126                 }
 127         }
 128         if(spotlistend)
 129                 spotlistend.chain = world;
 130
 131         /*
 132                 entity e;
 133                 if(teamcheck)
 134                         for(e = spotlist; e; e = e.chain)
 135                         {
 136                                 print("seen ", etos(e), "\n");
 137                                 if(e.team != teamcheck)
 138                                         error("invalid spawn found");
 139                         }
 140         */
 141
 142         return spotlist;
 143 }
 144
 145 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 146 {
 147         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 148         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 149         local entity spot;
 150
 151         RandomSelection_Init();
 152         for(spot = firstspot; spot; spot = spot.chain)
 153                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 154
 155         return RandomSelection_chosen_ent;
 156 }
 157
 158 /*
 159 =============
 160 SelectSpawnPoint
 161
 162 Finds a point to respawn
 163 =============
 164 */
 165 entity SelectSpawnPoint (float anypoint)
 166 {
 167         local float teamcheck;
 168         local entity firstspot_new;
 169         local entity spot, firstspot, playerlist;
 170
 171         spot = find (world, classname, "testplayerstart");
 172         if (spot)
 173                 return spot;
 174
 175         teamcheck = 0;
 176
 177         if(!anypoint && have_team_spawns)
 178                 teamcheck = self.team;
 179
 180         // get the list of players
 181         playerlist = findchain(classname, "player");
 182         // get the entire list of spots
 183         firstspot = findchain(classname, "info_player_deathmatch");
 184         // filter out the bad ones
 185         // (note this returns the original list if none survived)
 186         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 187         if(!firstspot_new)
 188                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 189         firstspot = firstspot_new;
 190
 191         // there is 50/50 chance of choosing a random spot or the furthest spot
 192         // (this means that roughly every other spawn will be furthest, so you
 193         // usually won't get fragged at spawn twice in a row)
 194         if (arena_roundbased)
 195         {
 196                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 197                 if(firstspot_new)
 198                         firstspot = firstspot_new;
 199                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 200         }
 201         else if (random() > cvar("g_spawn_furthest"))
 202                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 203         else
 204                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 205
 206         if(cvar("spawn_debugview"))
 207         {
 208                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 209
 210                 entity e;
 211                 if(teamcheck)
 212                         for(e = firstspot; e; e = e.chain)
 213                                 if(e.team != teamcheck)
 214                                         error("invalid spawn found");
 215         }
 216
 217         if (!spot)
 218         {
 219                 if(cvar("spawn_debug"))
 220                         GotoNextMap();
 221                 else
 222                 {
 223                         if(some_spawn_has_been_used)
 224                                 return world; // team can't spawn any more, because of actions of other team
 225                         else
 226                                 error("Cannot find a spawn point - please fix the map!");
 227                 }
 228         }
 229
 230         return spot;
 231 }
 232
 233 /*
 234 =============
 235 CheckPlayerModel
 236
 237 Checks if the argument string can be a valid playermodel.
 238 Returns a valid one in doubt.
 239 =============
 240 */
 241 string FallbackPlayerModel = "models/player/marine.zym";
 242 string CheckPlayerModel(string plyermodel) {
 243         if(strlen(plyermodel) < 4)
 244                 return FallbackPlayerModel;
 245         if( substring(plyermodel,0,14) != "models/player/")
 246                 return FallbackPlayerModel;
 247         else if(cvar("sv_servermodelsonly"))
 248         {
 249                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 250                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 251                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 252                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 253                         return FallbackPlayerModel;
 254                 if(!fexists(plyermodel))
 255                         return FallbackPlayerModel;
 256         }
 257         return plyermodel;
 258 }
 259
 260 /*
 261 =============
 262 Client_customizeentityforclient
 263
 264 LOD reduction
 265 =============
 266 */
 267 float Client_customizeentityforclient()
 268 {
 269 #ifdef ALLOW_VARIABLE_LOD
 270         // self: me
 271         // other: the player viewing me
 272         float distance;
 273         float f;
 274
 275         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 276                 return TRUE;
 277
 278         if(other.cvar_cl_playerdetailreduction <= 0)
 279         {
 280                 if(other.cvar_cl_playerdetailreduction <= -2)
 281                         self.modelindex = self.modelindex_lod2;
 282                 else if(other.cvar_cl_playerdetailreduction <= -1)
 283                         self.modelindex = self.modelindex_lod1;
 284                 else
 285                         self.modelindex = self.modelindex_lod0;
 286         }
 287         else
 288         {
 289                 distance = vlen(self.origin - other.origin);
 290                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 291                 if(f > 10000)
 292                         self.modelindex = self.modelindex_lod2;
 293                 else if(f > 5000)
 294                         self.modelindex = self.modelindex_lod1;
 295                 else
 296                         self.modelindex = self.modelindex_lod0;
 297         }
 298 #endif
 299
 300         return TRUE;
 301 }
 302
 303 void UpdatePlayerSounds();
 304 void setmodel_lod(entity e, string modelname)
 305 {
 306 #ifdef ALLOW_VARIABLE_LOD
 307         string s;
 308
 309         // FIXME: this only supports 3-letter extensions
 310         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 311         if(fexists(s))
 312         {
 313                 precache_model(s);
 314                 setmodel(e, s); // players have high precision
 315                 self.modelindex_lod1 = self.modelindex;
 316         }
 317         else
 318                 self.modelindex_lod1 = -1;
 319
 320         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 321         if(fexists(s))
 322         {
 323                 precache_model(s);
 324                 setmodel(e, s); // players have high precision
 325                 self.modelindex_lod2 = self.modelindex;
 326         }
 327         else
 328                 self.modelindex_lod2 = -1;
 329
 330         precache_model(modelname);
 331         setmodel(e, modelname); // players have high precision
 332         self.modelindex_lod0 = self.modelindex;
 333
 334         if(self.modelindex_lod1 < 0)
 335                 self.modelindex_lod1 = self.modelindex;
 336
 337         if(self.modelindex_lod2 < 0)
 338                 self.modelindex_lod2 = self.modelindex;
 339 #else
 340         precache_model(modelname);
 341         setmodel(e, modelname); // players have high precision
 342 #endif
 343         player_setupanimsformodel();
 344         UpdatePlayerSounds();
 345 }
 346
 347 /*
 348 =============
 349 PutObserverInServer
 350
 351 putting a client as observer in the server
 352 =============
 353 */
 354 void ctf_UpdateCaptures(float);
 355 void ctf_UpdateReturns(float);
 356 void PutObserverInServer (void)
 357 {
 358         entity  spot;
 359         spot = SelectSpawnPoint (TRUE);
 360         if(!spot)
 361                 error("No spawnpoints for observers?!?\n");
 362         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 363
 364         if(clienttype(self) == CLIENTTYPE_REAL)
 365         {
 366                 msg_entity = self;
 367                 WriteByte(MSG_ONE, SVC_SETVIEW);
 368                 WriteEntity(MSG_ONE, self);
 369         }
 370
 371         DropAllRunes(self);
 372         kh_Key_DropAll(self, TRUE);
 373
 374         if(self.flagcarried)
 375                 DropFlag(self.flagcarried);
 376
 377         WaypointSprite_PlayerDead();
 378
 379         if(self.killcount != -666)
 380         {
 381                 if(g_lms)
 382                 {
 383                         if(PlayerScore_Add(self, SP_LMS_PLACE, 0) > 0)
 384                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 385                         else
 386                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 387                 }
 388                 else
 389                         bprint ("^4", self.netname, "^4 is spectating now\n");
 390         }
 391
 392         PlayerScore_Clear(self); // clear scores when needed
 393
 394         self.spectatortime = time;
 395
 396         self.classname = "observer";
 397         self.health = -666;
 398         self.takedamage = DAMAGE_NO;
 399         self.solid = SOLID_NOT;
 400         self.movetype = MOVETYPE_NOCLIP;
 401         self.flags = FL_CLIENT | FL_NOTARGET;
 402         self.armorvalue = 666;
 403         self.effects = 0;
 404         self.armorvalue = cvar("g_balance_armor_start");
 405         self.pauserotarmor_finished = 0;
 406         self.pauserothealth_finished = 0;
 407         self.pauseregen_finished = 0;
 408         self.damageforcescale = 0;
 409         self.death_time = 0;
 410         self.dead_frame = 0;
 411         self.deaths = 0;
 412         self.captures = 0;
 413         self.returns = 0;
 414         self.alpha = 0;
 415         self.scale = 0;
 416         self.fade_time = 0;
 417         self.pain_frame = 0;
 418         self.pain_finished = 0;
 419         self.strength_finished = 0;
 420         self.invincible_finished = 0;
 421         self.pushltime = 0;
 422         self.think = SUB_Null;
 423         self.nextthink = 0;
 424         self.hook_time = 0;
 425         self.runes = 0;
 426         self.deadflag = DEAD_NO;
 427         self.angles = spot.angles;
 428         self.angles_z = 0;
 429         self.fixangle = TRUE;
 430         self.crouch = FALSE;
 431
 432         self.view_ofs = PL_VIEW_OFS;
 433         setorigin (self, spot.origin);
 434         setsize (self, '0 0 0', '0 0 0');
 435         self.oldorigin = self.origin;
 436         self.items = 0;
 437         self.model = "";
 438         self.modelindex = 0;
 439         self.weapon = 0;
 440         self.weaponmodel = "";
 441         self.weaponentity = world;
 442         self.killcount = -666;
 443         self.velocity = '0 0 0';
 444         self.avelocity = '0 0 0';
 445         self.punchangle = '0 0 0';
 446         self.punchvector = '0 0 0';
 447         self.oldvelocity = self.velocity;
 448         self.customizeentityforclient = Client_customizeentityforclient;
 449         self.viewzoom = 1;
 450         self.wantswelcomemessage = 1;
 451
 452         if(g_arena)
 453         {
 454                 if(self.frags != -2)
 455                 {
 456                         Spawnqueue_Insert(self);
 457                         // FIXME what IS this?
 458                 }
 459                 else
 460                 {
 461                         Spawnqueue_Unmark(self);
 462                         Spawnqueue_Remove(self);
 463                 }
 464         }
 465         else if(g_lms)
 466         {
 467                 // Only if the player cannot play at all
 468                 if(PlayerScore_Add(self, SP_LMS_PLACE, 0) == 666)
 469                         self.frags = -666;
 470                 else
 471                         self.frags = -667;
 472         }
 473         else
 474                 self.frags = -666;
 475
 476         net_UpdateDeaths(MSG_BROADCAST);
 477 }
 478
 479 float RestrictSkin(float s)
 480 {
 481         if(!teams_matter)
 482                 return s;
 483         if(s == 6)
 484                 return 6;
 485         return mod(s, 3);
 486 }
 487
 488 void FixPlayermodel()
 489 {
 490         local string defaultmodel;
 491         local float defaultskin;
 492         local vector m1, m2;
 493
 494         defaultmodel = "";
 495
 496         if(cvar("sv_defaultcharacter") == 1) {
 497                 defaultskin = 0;
 498
 499                 if(teams_matter)
 500                 {
 501                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 502                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 503                 }
 504
 505                 if(defaultmodel == "")
 506                 {
 507                         defaultmodel = cvar_string("sv_defaultplayermodel");
 508                         defaultskin = cvar("sv_defaultplayerskin");
 509                 }
 510         }
 511
 512         if(defaultmodel != "")
 513         {
 514                 if (defaultmodel != self.model)
 515                 {
 516                         m1 = self.mins;
 517                         m2 = self.maxs;
 518                         setmodel_lod (self, defaultmodel);
 519                         setsize (self, m1, m2);
 520                 }
 521
 522                 self.skin = defaultskin;
 523         } else {
 524                 if (self.playermodel != self.model)
 525                 {
 526                         self.playermodel = CheckPlayerModel(self.playermodel);
 527                         m1 = self.mins;
 528                         m2 = self.maxs;
 529                         setmodel_lod (self, self.playermodel);
 530                         setsize (self, m1, m2);
 531                 }
 532
 533                 self.skin = RestrictSkin(stof(self.playerskin));
 534         }
 535
 536         if(!teams_matter)
 537                 if(strlen(cvar_string("sv_defaultplayercolors")))
 538                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 539                                 setcolor(self, cvar("sv_defaultplayercolors"));
 540 }
 541
 542 /*
 543 =============
 544 PutClientInServer
 545
 546 Called when a client spawns in the server
 547 =============
 548 */
 549 //void() ctf_playerchanged;
 550 void PutClientInServer (void)
 551 {
 552         if(clienttype(self) == CLIENTTYPE_BOT)
 553         {
 554                 self.classname = "player";
 555         }
 556         else if(clienttype(self) == CLIENTTYPE_REAL)
 557         {
 558                 msg_entity = self;
 559                 WriteByte(MSG_ONE, SVC_SETVIEW);
 560                 WriteEntity(MSG_ONE, self);
 561         }
 562
 563         // player is dead and becomes observer
 564         // FIXME fix LMS scoring for new system
 565         if(g_lms)
 566         {
 567                 if(PlayerScore_Add(self, SP_LMS_PLACE, 0) > 0)
 568                         self.classname = "observer";
 569         }
 570
 571         if(g_arena)
 572         if(!self.spawned)
 573                 self.classname = "observer";
 574
 575         if(self.classname == "player") {
 576                 entity  spot;
 577
 578                 spot = SelectSpawnPoint (FALSE);
 579                 if(!spot)
 580                 {
 581                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 582                         return; // spawn failed
 583                 }
 584
 585                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 586
 587                 self.classname = "player";
 588                 self.iscreature = TRUE;
 589                 self.movetype = MOVETYPE_WALK;
 590                 self.solid = SOLID_SLIDEBOX;
 591                 self.flags = FL_CLIENT;
 592                 self.takedamage = DAMAGE_AIM;
 593                 if(g_minstagib)
 594                         self.effects = EF_FULLBRIGHT;
 595                 else
 596                         self.effects = 0;
 597                 self.air_finished = time + 12;
 598                 self.dmg = 2;
 599
 600                 self.ammo_shells = start_ammo_shells;
 601                 self.ammo_nails = start_ammo_nails;
 602                 self.ammo_rockets = start_ammo_rockets;
 603                 self.ammo_cells = start_ammo_cells;
 604                 self.health = start_health;
 605                 self.armorvalue = start_armorvalue;
 606                 self.items = start_items;
 607                 self.switchweapon = start_switchweapon;
 608                 self.cnt = start_switchweapon;
 609                 self.weapon = 0;
 610                 self.jump_interval = time;
 611
 612                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 613                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 614                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 615                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 616                 //extend the pause of rotting if client was reset at the beginning of the countdown
 617                 if(!cvar("sv_ready_restart_after_countdown") && time < restart_countdown) {
 618                         self.spawnshieldtime += RESTART_COUNTDOWN;
 619                         self.pauserotarmor_finished += RESTART_COUNTDOWN;
 620                         self.pauserothealth_finished += RESTART_COUNTDOWN;
 621                         self.pauseregen_finished += RESTART_COUNTDOWN;
 622                 }
 623                 self.damageforcescale = 2;
 624                 self.death_time = 0;
 625                 self.dead_frame = 0;
 626                 self.alpha = 0;
 627                 self.scale = 0;
 628                 self.fade_time = 0;
 629                 self.pain_frame = 0;
 630                 self.pain_finished = 0;
 631                 self.strength_finished = 0;
 632                 self.invincible_finished = 0;
 633                 self.pushltime = 0;
 634                 //self.speed_finished = 0;
 635                 //self.slowmo_finished = 0;
 636                 // players have no think function
 637                 self.think = SUB_Null;
 638                 self.nextthink = 0;
 639                 self.hook_time = 0;
 640
 641                 self.runes = 0;
 642
 643                 self.deadflag = DEAD_NO;
 644
 645                 self.angles = spot.angles;
 646
 647                 self.angles_z = 0; // never spawn tilted even if the spot says to
 648                 self.fixangle = TRUE; // turn this way immediately
 649                 self.velocity = '0 0 0';
 650                 self.avelocity = '0 0 0';
 651                 self.punchangle = '0 0 0';
 652                 self.punchvector = '0 0 0';
 653                 self.oldvelocity = self.velocity;
 654
 655                 self.viewzoom = 0.6;
 656                 self.has_zoomed = 0;
 657
 658                 self.customizeentityforclient = Client_customizeentityforclient;
 659
 660                 self.model = "";
 661                 FixPlayermodel();
 662
 663                 self.crouch = FALSE;
 664                 self.view_ofs = PL_VIEW_OFS;
 665                 setsize (self, PL_MIN, PL_MAX);
 666                 self.spawnorigin = spot.origin;
 667                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 668                 // don't reset back to last position, even if new position is stuck in solid
 669                 self.oldorigin = self.origin;
 670
 671                 if(g_arena)
 672                 {
 673                         Spawnqueue_Remove(self);
 674                         Spawnqueue_Mark(self);
 675                 }
 676
 677                 self.event_damage = PlayerDamage;
 678
 679                 self.bot_attack = TRUE;
 680
 681                 self.statdraintime = time + 5;
 682                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 683
 684                 if(self.killcount == -666) {
 685                         PlayerScore_Clear(self);
 686                         self.killcount = 0;
 687                         self.frags = 0;
 688                 }
 689
 690                 self.cnt = WEP_LASER;
 691                 self.nixnex_lastchange_id = -1;
 692
 693                 CL_SpawnWeaponentity();
 694                 self.alpha = default_player_alpha;
 695                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 696                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 697
 698                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 699                 self.lms_traveled_distance = 0;
 700                 self.speedrunning = FALSE;
 701
 702                 if(cvar("spawn_debug"))
 703                 {
 704                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 705                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 706                 }
 707
 708                 //stuffcmd(self, "chase_active 0");
 709                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 710
 711                 if (cvar("g_spawnsound"))
 712                         sound (self, CHAN_AUTO, "misc/spawn.wav", 1, ATTN_NORM);
 713
 714                 if(g_assault) {
 715                         if(self.team == assault_attacker_team)
 716                                 centerprint(self, "You are attacking!\n");
 717                         else
 718                                 centerprint(self, "You are defending!\n");
 719                 }
 720
 721         } else if(self.classname == "observer") {
 722                 PutObserverInServer ();
 723         }
 724
 725         //if(g_ctf)
 726         //      ctf_playerchanged();
 727 }
 728
 729 /*
 730 =============
 731 SendCSQCInfo
 732
 733 Send whatever CSQC needs NOW and cannot wait for SendServerInfo to happen...
 734 =============
 735 */
 736 void SendCSQCInfo(void)
 737 {
 738         if(clienttype(self) != CLIENTTYPE_REAL)
 739                 return;
 740         msg_entity = self;
 741         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 742         WriteByte(MSG_ONE, TE_CSQC_INIT);
 743         WriteShort(MSG_ONE, CSQC_REVISION);
 744         WriteByte(MSG_ONE, maxclients);
 745 }
 746
 747 /*
 748 =============
 749 SetNewParms
 750 =============
 751 */
 752 void SetNewParms (void)
 753 {
 754         // initialize parms for a new player
 755         parm1 = -(86400 * 366);
 756 }
 757
 758 /*
 759 =============
 760 SetChangeParms
 761 =============
 762 */
 763 void SetChangeParms (void)
 764 {
 765         // save parms for level change
 766         parm1 = self.parm_idlesince - time;
 767 }
 768
 769 /*
 770 =============
 771 DecodeLevelParms
 772 =============
 773 */
 774 void DecodeLevelParms (void)
 775 {
 776         // load parms
 777         self.parm_idlesince = parm1;
 778         if(self.parm_idlesince == -(86400 * 366))
 779                 self.parm_idlesince = time;
 780 }
 781
 782 /*
 783 =============
 784 ClientKill
 785
 786 Called when a client types 'kill' in the console
 787 =============
 788 */
 789
 790 void ClientKill_Now_TeamChange()
 791 {
 792         if(g_ctf)
 793         {
 794                 self.captures = 0;
 795                 self.returns = 0;
 796                 ctf_UpdateCaptures(MSG_BROADCAST);
 797                 ctf_UpdateReturns(MSG_BROADCAST);
 798         }
 799         self.deaths = 0;
 800         net_UpdateDeaths(MSG_BROADCAST);
 801         if(self.killindicator_teamchange == -1)
 802         {
 803                 self.team = -1;
 804                 JoinBestTeam( self, FALSE, FALSE );
 805         }
 806         else
 807         {
 808                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 809         }
 810 }
 811
 812 void ClientKill_Now()
 813 {
 814         if(self.killindicator_teamchange)
 815                 ClientKill_Now_TeamChange();
 816
 817         // in any case:
 818         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 819 }
 820 void KillIndicator_Think()
 821 {
 822         if (!self.owner.modelindex)
 823         {
 824                 self.owner.killindicator = world;
 825                 remove(self);
 826                 return;
 827         }
 828
 829         if(self.cnt <= 0)
 830         {
 831                 self = self.owner;
 832                 ClientKill_Now(); // no oldself needed
 833                 return;
 834         }
 835         else
 836         {
 837                 if(self.cnt <= 10)
 838                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 839                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 840                 {
 841                         if(self.cnt <= 10)
 842                                 play2(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 843                         if(self.owner.killindicator_teamchange)
 844                         {
 845                                 if(self.owner.killindicator_teamchange == -1)
 846                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 847                                 else
 848                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 849                         }
 850                         else
 851                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 852                 }
 853                 self.nextthink = time + 1;
 854                 self.cnt -= 1;
 855         }
 856 }
 857
 858 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 859 {
 860         float killtime;
 861         entity e;
 862         killtime = cvar("g_balance_kill_delay");
 863
 864         self.killindicator_teamchange = targetteam;
 865
 866         if(!self.killindicator)
 867         {
 868                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 869                 {
 870                         ClientKill_Now();
 871                 }
 872                 else
 873                 {
 874                         self.killindicator = spawn();
 875                         self.killindicator.owner = self;
 876                         self.killindicator.scale = 0.5;
 877                         setattachment(self.killindicator, self, "");
 878                         setorigin(self.killindicator, '0 0 52');
 879                         self.killindicator.think = KillIndicator_Think;
 880                         self.killindicator.nextthink = time + (self.lip) * 0.05;
 881                         self.killindicator.cnt = ceil(killtime);
 882                         self.killindicator.count = bound(0, ceil(killtime), 10);
 883                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 884
 885                         for(e = world; (e = find(e, classname, "body")) != world; )
 886                         {
 887                                 if(e.enemy != self)
 888                                         continue;
 889                                 e.killindicator = spawn();
 890                                 e.killindicator.owner = e;
 891                                 e.killindicator.scale = 0.5;
 892                                 setattachment(e.killindicator, e, "");
 893                                 setorigin(e.killindicator, '0 0 52');
 894                                 e.killindicator.think = KillIndicator_Think;
 895                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
 896                                 e.killindicator.cnt = ceil(killtime);
 897                         }
 898                         self.lip = 0;
 899                 }
 900         }
 901         if(self.killindicator)
 902         {
 903                 if(targetteam)
 904                         self.killindicator.colormod = TeamColor(targetteam);
 905                 else
 906                         self.killindicator.colormod = '0 0 0';
 907         }
 908 }
 909
 910 void ClientKill (void)
 911 {
 912         ClientKill_TeamChange(0);
 913 }
 914
 915 void DoTeamChange(float destteam)
 916 {
 917         float t, c0;
 918         if(!cvar("teamplay"))
 919         {
 920                 if(destteam >= 0)
 921                         SetPlayerColors(self, destteam);
 922                 return;
 923         }
 924         if(self.classname == "player")
 925         if(destteam == -1)
 926         {
 927                 CheckAllowedTeams(self);
 928                 t = FindSmallestTeam(self, TRUE);
 929                 switch(self.team)
 930                 {
 931                         case COLOR_TEAM1: c0 = c1; break;
 932                         case COLOR_TEAM2: c0 = c2; break;
 933                         case COLOR_TEAM3: c0 = c3; break;
 934                         case COLOR_TEAM4: c0 = c4; break;
 935                         default:          c0 = 999;
 936                 }
 937                 switch(t)
 938                 {
 939                         case 1:
 940                                 if(c0 > c1)
 941                                         destteam = COLOR_TEAM1;
 942                                 break;
 943                         case 2:
 944                                 if(c0 > c2)
 945                                         destteam = COLOR_TEAM2;
 946                                 break;
 947                         case 3:
 948                                 if(c0 > c3)
 949                                         destteam = COLOR_TEAM3;
 950                                 break;
 951                         case 4:
 952                                 if(c0 > c4)
 953                                         destteam = COLOR_TEAM4;
 954                                 break;
 955                 }
 956                 if(destteam == -1)
 957                         return;
 958         }
 959         if(destteam == self.team && !self.killindicator)
 960                 return;
 961         ClientKill_TeamChange(destteam);
 962 }
 963
 964 void FixClientCvars(entity e)
 965 {
 966         // send prediction settings to the client
 967         stuffcmd(e, "\nin_bindmap 0 0\n");
 968         /*
 969          * we no longer need to stuff this. Remove this comment block if you feel
 970          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 971         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
 972         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 973         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 974         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 975         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 976         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 977         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 978         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
 979         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 980         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 981         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 982         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 983         stuffcmd(e, "cl_movement_edgefriction 1\n");
 984          */
 985 }
 986
 987 /*
 988 =============
 989 ClientConnect
 990
 991 Called when a client connects to the server
 992 =============
 993 */
 994 //void ctf_clientconnect();
 995 string ColoredTeamName(float t);
 996 void DecodeLevelParms (void);
 997 //void dom_player_join_team(entity pl);
 998 void ClientConnect (void)
 999 {
1000         local string s;
1001         float wep;
1002
1003         if(Ban_IsClientBanned(self))
1004         {
1005                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
1006                 dropclient(self);
1007                 bprint(s);
1008                 return;
1009         }
1010
1011         DecodeLevelParms();
1012
1013         self.classname = "player_joining";
1014         self.flags = self.flags | FL_CLIENT;
1015         self.version_nagtime = time + 10 + random() * 10;
1016
1017         if(player_count<0)
1018         {
1019                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1020                 player_count = 0;
1021         }
1022
1023         bot_clientconnect();
1024
1025         //if(g_domination)
1026         //      dom_player_join_team(self);
1027
1028         //JoinBestTeam(self, FALSE, FALSE);
1029
1030         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1031                 self.classname = "observer";
1032         } else {
1033                 self.classname = "player";
1034                 campaign_bots_may_start = 1;
1035         }
1036
1037         self.playerid = (playerid_last = playerid_last + 1);
1038         if(cvar("sv_eventlog"))
1039         {
1040                 if(clienttype(self) == CLIENTTYPE_REAL)
1041                         s = "player";
1042                 else
1043                         s = "bot";
1044                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
1045                 s = strcat(":team:", ftos(self.playerid), ":");
1046                 s = strcat(s, ftos(self.team));
1047                 GameLogEcho(s, FALSE);
1048         }
1049         self.netname_previous = strzone(self.netname);
1050
1051         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1052
1053         bprint ("^4",self.netname);
1054         bprint ("^4 connected");
1055
1056         if(g_domination || g_ctf)
1057         {
1058                 bprint(" and joined the ");
1059                 bprint(ColoredTeamName(self.team));
1060         }
1061
1062         bprint("\n");
1063
1064         self.welcomemessage_time = 0;
1065
1066         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1067         // TODO: is this being used for anything else than cd tracks?
1068         // Remember: SVC_CDTRACK exists. Maybe it should be used.
1069         //
1070         stuffcmd(self, "cl_particles_reloadeffects\n");
1071
1072         FixClientCvars(self);
1073
1074         // spawnfunc_waypoint sprites
1075         WaypointSprite_InitClient(self);
1076
1077         // Wazat's grappling hook
1078         SetGrappleHookBindings();
1079
1080         // get autoswitch state from player when he toggles it
1081         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1082
1083         // get version info from player
1084         stuffcmd(self, "cmd clientversion $gameversion\n");
1085
1086         // send all weapon info strings
1087         stuffcmd(self, "register_bestweapon clear\n"); // clear the Quake stuff
1088         wep = WEP_FIRST;
1089         while (wep <= WEP_LAST)
1090         {
1091                 weapon_action(wep, WR_REGISTER);
1092                 wep = wep + 1;
1093         }
1094
1095         // get other cvars from player
1096         GetCvars(0);
1097
1098         // set cvar for team scoreboard
1099         if (teams_matter)
1100         {
1101                 local float t;
1102                 t = cvar("teamplay");
1103                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1104                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1105         }
1106         else
1107                 stuffcmd(self, "set teamplay 0\n");
1108
1109         // notify about available teams
1110         if(teamplay)
1111         {
1112                 CheckAllowedTeams(self);
1113                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1114                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1115         }
1116         else
1117                 stuffcmd(self, "set _teams_available 0\n");
1118
1119         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1120
1121         if(g_arena)
1122         {
1123                 self.classname = "observer";
1124                 Spawnqueue_Insert(self);
1125         }
1126         /*else if(g_ctf)
1127         {
1128                 ctf_clientconnect();
1129         }*/
1130
1131         if(entcs_start)
1132                 attach_entcs();
1133
1134         PlayerScore_Attach(self);
1135
1136         bot_relinkplayerlist();
1137
1138         self.spectatortime = time;
1139         if(blockSpectators)
1140         {
1141                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1142         }
1143
1144         self.jointime = time;
1145         self.allowedTimeouts = cvar("sv_timeout_number");
1146
1147         if(clienttype(self) == CLIENTTYPE_REAL)
1148         {
1149                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1150                 SendCSQCInfo();
1151                 msg_entity = self;
1152                 ctf_UpdateCaptures(MSG_ONE);
1153                 ctf_UpdateReturns(MSG_ONE);
1154                 net_UpdateDeaths(MSG_ONE);
1155                 if(mapvote_initialized && !cvar("g_maplist_textonly"))
1156                 {
1157                         MapVote_SendData(MSG_ONE);
1158                         MapVote_UpdateData(MSG_ONE);
1159                 }
1160         }
1161
1162         if(g_lms)
1163         {
1164                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1165                 {
1166                         PlayerScore_Add(self, SP_LMS_PLACE, 666);
1167                         self.frags = -666; // FIXME do we still need this?
1168                 }
1169         }
1170 }
1171
1172 /*
1173 =============
1174 ClientDisconnect
1175
1176 Called when a client disconnects from the server
1177 =============
1178 */
1179 void(entity e) DropFlag;
1180 .entity chatbubbleentity;
1181 .entity teambubbleentity;
1182 //void() ctf_clientdisconnect;
1183 void ClientDisconnect (void)
1184 {
1185         float save;
1186
1187         bot_clientdisconnect();
1188
1189         if(entcs_start)
1190                 detach_entcs();
1191
1192         if(cvar("sv_eventlog"))
1193                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
1194         bprint ("^4",self.netname);
1195         bprint ("^4 disconnected\n");
1196
1197         if (self.chatbubbleentity)
1198         {
1199                 remove (self.chatbubbleentity);
1200                 self.chatbubbleentity = world;
1201         }
1202
1203         if (self.teambubbleentity)
1204         {
1205                 remove (self.teambubbleentity);
1206                 self.teambubbleentity = world;
1207         }
1208
1209         if (self.killindicator)
1210         {
1211                 remove (self.killindicator);
1212                 self.killindicator = world;
1213         }
1214
1215         WaypointSprite_PlayerGone();
1216
1217         DropAllRunes(self);
1218         kh_Key_DropAll(self, TRUE);
1219
1220         if(self.flagcarried)
1221                 DropFlag(self.flagcarried);
1222
1223         save = self.flags;
1224         self.flags = self.flags - (self.flags & FL_CLIENT);
1225         bot_relinkplayerlist();
1226         self.flags = save;
1227
1228         // remove laserdot
1229         if(self.weaponentity)
1230                 if(self.weaponentity.lasertarget)
1231                         remove(self.weaponentity.lasertarget);
1232
1233         if(g_arena)
1234         {
1235                 Spawnqueue_Unmark(self);
1236                 Spawnqueue_Remove(self);
1237         }
1238         /*if(g_ctf)
1239         {
1240                 ctf_clientdisconnect();
1241         }
1242         */
1243
1244         PlayerScore_Detach(self);
1245
1246         if(self.netname_previous)
1247                 strunzone(self.netname_previous);
1248
1249         // free cvars
1250         GetCvars(-1);
1251 }
1252
1253 .float BUTTON_CHAT;
1254 void ChatBubbleThink()
1255 {
1256         self.nextthink = time;
1257         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1258         {
1259                 self.owner.chatbubbleentity = world;
1260                 remove(self);
1261                 return;
1262         }
1263         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1264         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1265                 self.model = self.mdl;
1266         else
1267                 self.model = "";
1268 };
1269
1270 void UpdateChatBubble()
1271 {
1272         if (!self.modelindex)
1273                 return;
1274         // spawn a chatbubble entity if needed
1275         if (!self.chatbubbleentity)
1276         {
1277                 self.chatbubbleentity = spawn();
1278                 self.chatbubbleentity.owner = self;
1279                 self.chatbubbleentity.exteriormodeltoclient = self;
1280                 self.chatbubbleentity.think = ChatBubbleThink;
1281                 self.chatbubbleentity.nextthink = time;
1282                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1283                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1284                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1285                 self.chatbubbleentity.model = "";
1286                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1287         }
1288 }
1289
1290
1291 void TeamBubbleThink()
1292 {
1293         self.nextthink = time;
1294         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1295         {
1296                 self.owner.teambubbleentity = world;
1297                 remove(self);
1298                 return;
1299         }
1300 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1301         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1302                 self.model = "";
1303         else
1304                 self.model = self.mdl;
1305
1306 };
1307
1308 float TeamBubble_customizeentityforclient()
1309 {
1310         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1311 }
1312
1313 void UpdateTeamBubble()
1314 {
1315         if (!self.modelindex || !cvar("teamplay"))
1316                 return;
1317         // spawn a teambubble entity if needed
1318         if (!self.teambubbleentity && cvar("teamplay"))
1319         {
1320                 self.teambubbleentity = spawn();
1321                 self.teambubbleentity.owner = self;
1322                 self.teambubbleentity.exteriormodeltoclient = self;
1323                 self.teambubbleentity.think = TeamBubbleThink;
1324                 self.teambubbleentity.nextthink = time;
1325                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1326 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1327                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1328                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1329                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1330                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1331                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1332                 self.teambubbleentity.effects = EF_LOWPRECISION;
1333         }
1334 }
1335
1336 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1337 // added to the model skins
1338 /*void UpdateColorModHack()
1339 {
1340         local float c;
1341         c = self.clientcolors & 15;
1342         // LordHavoc: only bothering to support white, green, red, yellow, blue
1343              if (teamplay == 0) self.colormod = '0 0 0';
1344         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1345         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1346         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1347         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1348         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1349         else self.colormod = '1 1 1';
1350 };*/
1351
1352 void respawn(void)
1353 {
1354         CopyBody(1);
1355         self.effects |= EF_NODRAW; // prevent another CopyBody
1356         PutClientInServer();
1357 }
1358
1359 /**
1360  * When sv_timeout is used this function returs strings like
1361  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1362  * Called by centerprint functions
1363  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1364  */
1365 string getTimeoutText(float addOneSecond) {
1366         if (!cvar("sv_timeout") || !timeoutStatus)
1367                 return "";
1368
1369         local string retStr;
1370         if (timeoutStatus == 1) {
1371                 if (addOneSecond == 1) {
1372                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1373                 }
1374                 else {
1375                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1376                 }
1377                 return retStr;
1378         }
1379         else if (timeoutStatus == 2) {
1380                 if (addOneSecond) {
1381                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1382                         //don't show messages like "Timeout ends in 0 seconds"...
1383                         if ((remainingTimeoutTime + 1) > 0)
1384                                 return retStr;
1385                         else
1386                                 return "";
1387                 }
1388                 else {
1389                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1390                         //don't show messages like "Timeout ends in 0 seconds"...
1391                         if (remainingTimeoutTime > 0)
1392                                 return retStr;
1393                         else
1394                                 return "";
1395                 }
1396         }
1397         else return "";
1398 }
1399
1400 void player_powerups (void)
1401 {
1402         if (g_minstagib)
1403         {
1404                 if (self.items & IT_STRENGTH)
1405                 {
1406                         if (time > self.strength_finished)
1407                         {
1408                                 if (g_minstagib_invis_alpha > 0)
1409                                 {
1410                                         self.alpha = default_player_alpha;
1411                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1412                                         self.effects = self.effects | EF_FULLBRIGHT;
1413                                 }
1414                                 else
1415                                 {
1416                                         self.effects -= self.effects & EF_NODRAW;
1417                                 }
1418                                 self.items = self.items - (self.items & IT_STRENGTH);
1419                                 sprint(self, "^3Invisibility has worn off\n");
1420                         }
1421                 }
1422                 else
1423                 {
1424                         if (time < self.strength_finished)
1425                         {
1426                                 if (g_minstagib_invis_alpha > 0)
1427                                 {
1428                                         self.alpha = g_minstagib_invis_alpha;
1429                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1430                                         self.effects -= self.effects & EF_FULLBRIGHT;
1431                                 }
1432                                 else
1433                                 {
1434                                         self.effects = self.effects | EF_NODRAW;
1435                                 }
1436                                 self.items = self.items | IT_STRENGTH;
1437                                 sprint(self, "^3You are invisible\n");
1438                         }
1439                 }
1440
1441                 if (self.items & IT_INVINCIBLE)
1442                 {
1443                         if (time > self.invincible_finished)
1444                         {
1445                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1446                                 sprint(self, "^3Speed has worn off\n");
1447                         }
1448                 }
1449                 else
1450                 {
1451                         if (time < self.invincible_finished)
1452                         {
1453                                 self.items = self.items | IT_INVINCIBLE;
1454                                 sprint(self, "^3You are on speed\n");
1455                         }
1456                 }
1457                 return;
1458         }
1459
1460         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1461         if (self.items & IT_STRENGTH)
1462         {
1463                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1464                 if (time > self.strength_finished)
1465                 {
1466                         self.items = self.items - (self.items & IT_STRENGTH);
1467                         sprint(self, "^3Strength has worn off\n");
1468                 }
1469         }
1470         else
1471         {
1472                 if (time < self.strength_finished)
1473                 {
1474                         self.items = self.items | IT_STRENGTH;
1475                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1476                 }
1477         }
1478         if (self.items & IT_INVINCIBLE)
1479         {
1480                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1481                 if (time > self.invincible_finished)
1482                 {
1483                         self.items = self.items - (self.items & IT_INVINCIBLE);
1484                         sprint(self, "^3Shield has worn off\n");
1485                 }
1486         }
1487         else
1488         {
1489                 if (time < self.invincible_finished)
1490                 {
1491                         self.items = self.items | IT_INVINCIBLE;
1492                         sprint(self, "^3Shield surrounds you\n");
1493                 }
1494         }
1495
1496         if (cvar("g_fullbrightplayers"))
1497                 self.effects = self.effects | EF_FULLBRIGHT;
1498
1499         // midair gamemode: damage only while in the air
1500         // if in midair mode, being on ground grants temporary invulnerability
1501         // (this is so that multishot weapon don't clear the ground flag on the
1502         // first damage in the frame, leaving the player vulnerable to the
1503         // remaining hits in the same frame)
1504         if (self.flags & FL_ONGROUND)
1505         if (g_midair)
1506                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1507
1508         if (time < self.spawnshieldtime)
1509                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1510 }
1511
1512 float CalcRegen(float current, float stable, float regenfactor)
1513 {
1514         if(current > stable)
1515                 return current;
1516         else if(current > stable - 0.25) // when close enough, "snap"
1517                 return stable;
1518         else
1519                 return min(stable, current + (stable - current) * regenfactor * frametime);
1520 }
1521
1522 void player_regen (void)
1523 {
1524         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1525         maxh = cvar("g_balance_health_stable");
1526         maxa = cvar("g_balance_armor_stable");
1527         limith = cvar("g_balance_health_limit");
1528         limita = cvar("g_balance_armor_limit");
1529
1530         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1531                 return;
1532
1533         max_mod = regen_mod = rot_mod = limit_mod = 1;
1534
1535         if (self.runes & RUNE_REGEN)
1536         {
1537                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1538                 {
1539                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1540                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1541                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1542                 }
1543                 else
1544                 {
1545                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1546                         max_mod = cvar("g_balance_rune_regen_hpmod");
1547                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1548                 }
1549         }
1550         else if (self.runes & CURSE_VENOM)
1551         {
1552                 max_mod = cvar("g_balance_curse_venom_hpmod");
1553                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1554                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1555                 else
1556                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1557                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1558                 //if (!self.runes & RUNE_REGEN)
1559                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1560         }
1561         maxh = maxh * max_mod;
1562         //maxa = maxa * max_mod;
1563         limith = limith * limit_mod;
1564         limita = limita * limit_mod;
1565
1566         if (self.armorvalue > maxa)
1567         {
1568                 if (time > self.pauserotarmor_finished)
1569                 {
1570                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1571                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1572                 }
1573         }
1574         else if (self.armorvalue < maxa)
1575         {
1576                 if (time > self.pauseregen_finished)
1577                 {
1578                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1579                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1580                 }
1581         }
1582         if (self.health > maxh)
1583         {
1584                 if (time > self.pauserothealth_finished)
1585                 {
1586                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1587                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1588                 }
1589         }
1590         else if (self.health < maxh)
1591         {
1592                 if (time > self.pauseregen_finished)
1593                 {
1594                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1595                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1596                 }
1597         }
1598
1599         if (self.health > limith)
1600                 self.health = limith;
1601         if (self.armorvalue > limita)
1602                 self.armorvalue = limita;
1603
1604         // if player rotted to death...  die!
1605         if(self.health < 1)
1606                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1607 }
1608
1609 /*
1610 ======================
1611 spectate mode routines
1612 ======================
1613 */
1614 void SpectateCopy(entity spectatee) {
1615         self.armortype = spectatee.armortype;
1616         self.armorvalue = spectatee.armorvalue;
1617         self.currentammo = spectatee.currentammo;
1618         self.effects = spectatee.effects;
1619         self.health = spectatee.health;
1620         self.impulse = 0;
1621         self.items = spectatee.items;
1622         self.punchangle = spectatee.punchangle;
1623         self.view_ofs = spectatee.view_ofs;
1624         self.v_angle = spectatee.v_angle;
1625         self.viewzoom = spectatee.viewzoom;
1626         self.velocity = spectatee.velocity;
1627         self.dmg_take = spectatee.dmg_take;
1628         self.dmg_save = spectatee.dmg_save;
1629         self.dmg_inflictor = spectatee.dmg_inflictor;
1630         self.angles = spectatee.v_angle;
1631         self.fixangle = TRUE;
1632         setorigin(self, spectatee.origin);
1633         setsize(self, spectatee.mins, spectatee.maxs);
1634 }
1635
1636 float SpectateUpdate() {
1637         if(!self.enemy)
1638                 return 0;
1639
1640         if (self == self.enemy)
1641                 return 0;
1642
1643         if(self.enemy.flags & FL_NOTARGET)
1644                 return 0;
1645
1646         SpectateCopy(self.enemy);
1647
1648         return 1;
1649 }
1650
1651 float SpectateNext() {
1652         other = find(self.enemy, classname, "player");
1653         if (!other) {
1654                 other = find(other, classname, "player");
1655         }
1656         if (other) {
1657                 self.enemy = other;
1658         }
1659         if(self.enemy.classname == "player") {
1660                 msg_entity = self;
1661                 WriteByte(MSG_ONE, SVC_SETVIEW);
1662                 WriteEntity(MSG_ONE, self.enemy);
1663                 self.wantswelcomemessage = 1;
1664                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1665                 if(!SpectateUpdate())
1666                         PutObserverInServer();
1667                 return 1;
1668         } else {
1669                 return 0;
1670         }
1671 }
1672
1673 /*
1674 =============
1675 ShowRespawnCountdown()
1676
1677 Update a respawn countdown display.
1678 =============
1679 */
1680 void ShowRespawnCountdown()
1681 {
1682         float number;
1683         if(self.deadflag == DEAD_NO) // just respawned?
1684                 return;
1685         else
1686         {
1687                 number = ceil(self.death_time - time);
1688                 if(number <= 0)
1689                         return;
1690                 if(number <= self.respawn_countdown)
1691                 {
1692                         self.respawn_countdown = number - 1;
1693                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1694                                 play2(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1695                 }
1696         }
1697 }
1698
1699 void LeaveSpectatorMode()
1700 {
1701         if(isJoinAllowed()) {
1702                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1703                         self.classname = "player";
1704                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1705                                 JoinBestTeam(self, FALSE, TRUE);
1706                         if(cvar("g_campaign"))
1707                                 campaign_bots_may_start = 1;
1708                         PutClientInServer();
1709                         if(!(self.flags & FL_NOTARGET))
1710                                 bprint ("^4", self.netname, "^4 is playing now\n");
1711                         centerprint(self,"");
1712                         return;
1713                 } else {
1714                         stuffcmd(self,"menu_showteamselect\n");
1715                         return;
1716                 }
1717         }
1718         else {
1719                 //player may not join because of g_maxplayers is set
1720                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1721         }
1722 }
1723
1724 /**
1725  * Determines whether the player is allowed to join. This depends on cvar
1726  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1727  * it checks whether the number of currently playing players exceeds g_maxplayers.
1728  * @return bool TRUE if the player is allowed to join, false otherwise
1729  */
1730 float isJoinAllowed() {
1731         if (!cvar("g_maxplayers"))
1732                 return TRUE;
1733
1734         local entity e;
1735         local float currentlyPlaying;
1736         FOR_EACH_REALPLAYER(e) {
1737                 if(e.classname == "player")
1738                         currentlyPlaying += 1;
1739         }
1740         if(currentlyPlaying < cvar("g_maxplayers"))
1741                 return TRUE;
1742
1743         return FALSE;
1744 }
1745
1746 /**
1747  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1748  * g_maxplayers_spectator_blocktime seconds
1749  */
1750 void checkSpectatorBlock() {
1751         if(self.classname == "spectator" || self.classname == "observer") {
1752                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1753                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1754                         dropclient(self);
1755                 }
1756         }
1757 }
1758
1759 float vercmp_recursive(string v1, string v2)
1760 {
1761         float dot1, dot2;
1762         string s1, s2;
1763         float r;
1764
1765         dot1 = strstrofs(v1, ".", 0);
1766         dot2 = strstrofs(v2, ".", 0);
1767         if(dot1 == -1)
1768                 s1 = v1;
1769         else
1770                 s1 = substring(v1, 0, dot1);
1771         if(dot2 == -1)
1772                 s2 = v2;
1773         else
1774                 s2 = substring(v2, 0, dot2);
1775
1776         r = stof(s1) - stof(s2);
1777         if(r != 0)
1778                 return r;
1779
1780         r = strcasecmp(s1, s2);
1781         if(r != 0)
1782                 return r;
1783
1784         if(dot1 == -1)
1785                 if(dot2 == -1)
1786                         return 0;
1787                 else
1788                         return -1;
1789         else
1790                 if(dot2 == -1)
1791                         return 1;
1792                 else
1793                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1794 }
1795
1796 float vercmp(string v1, string v2)
1797 {
1798         if(strcasecmp(v1, v2) == 0) // early out check
1799                 return 0;
1800         return vercmp_recursive(v1, v2);
1801 }
1802
1803 void ObserverThink()
1804 {
1805         if (self.flags & FL_JUMPRELEASED) {
1806                 if (self.BUTTON_JUMP && self.version == cvar("gameversion")) {
1807                         self.welcomemessage_time = 0;
1808                         self.flags = self.flags - FL_JUMPRELEASED;
1809                         LeaveSpectatorMode();
1810                         return;
1811                 } else if(self.BUTTON_ATCK && self.version == cvar("gameversion")) {
1812                         self.welcomemessage_time = 0;
1813                         self.flags = self.flags - FL_JUMPRELEASED;
1814                         if(SpectateNext() == 1) {
1815                                 self.classname = "spectator";
1816                         }
1817                 }
1818         } else {
1819                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
1820                         self.flags = self.flags | FL_JUMPRELEASED;
1821                 }
1822         }
1823         if(self.BUTTON_ZOOM)
1824                 self.wantswelcomemessage = 0;
1825         if(self.wantswelcomemessage)
1826                 PrintWelcomeMessage(self);
1827 }
1828
1829 void SpectatorThink()
1830 {
1831         if (self.flags & FL_JUMPRELEASED) {
1832                 if (self.BUTTON_JUMP && self.version == cvar("gameversion")) {
1833                         self.welcomemessage_time = 0;
1834                         self.flags = self.flags - FL_JUMPRELEASED;
1835                         LeaveSpectatorMode();
1836                         return;
1837                 } else if(self.BUTTON_ATCK) {
1838                         self.welcomemessage_time = 0;
1839                         self.flags = self.flags - FL_JUMPRELEASED;
1840                         if(SpectateNext() == 1) {
1841                                 self.classname = "spectator";
1842                         } else {
1843                                 self.classname = "observer";
1844                                 PutClientInServer();
1845                         }
1846                 } else if (self.BUTTON_ATCK2) {
1847                         self.welcomemessage_time = 0;
1848                         self.flags = self.flags - FL_JUMPRELEASED;
1849                         self.classname = "observer";
1850                         PutClientInServer();
1851                 } else {
1852                         if(!SpectateUpdate())
1853                                 PutObserverInServer();
1854                 }
1855         } else {
1856                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
1857                         self.flags = self.flags | FL_JUMPRELEASED;
1858                 }
1859         }
1860         if(self.BUTTON_ZOOM)
1861                 self.wantswelcomemessage = 0;
1862         if(self.wantswelcomemessage)
1863                 PrintWelcomeMessage(self);
1864         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1865 }
1866
1867 /*
1868 =============
1869 PlayerPreThink
1870
1871 Called every frame for each client before the physics are run
1872 =============
1873 */
1874 void() ctf_setstatus;
1875 .float vote_nagtime;
1876 void PlayerPreThink (void)
1877 {
1878         if(blockSpectators)
1879                 checkSpectatorBlock();
1880
1881         if(self.netname_previous != self.netname)
1882         {
1883                 if(cvar("sv_eventlog"))
1884                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname), TRUE);
1885                 if(self.netname_previous)
1886                         strunzone(self.netname_previous);
1887                 self.netname_previous = strzone(self.netname);
1888         }
1889
1890         // version nagging
1891         if(self.version_nagtime)
1892                 if(self.cvar_g_nexuizversion)
1893                         if(time > self.version_nagtime)
1894                         {
1895                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1896                                 {
1897                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
1898                                         {
1899                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1900                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1901                                         }
1902                                         else
1903                                         {
1904                                                 float r;
1905                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
1906                                                 if(r < 0)
1907                                                 {
1908                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
1909                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
1910                                                 }
1911                                                 else if(r > 0)
1912                                                 {
1913                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1914                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1915                                                 }
1916                                         }
1917                                 }
1918                                 self.version_nagtime = 0;
1919                         }
1920
1921         // vote nagging
1922         if(self.cvar_scr_centertime)
1923                 if(time > self.vote_nagtime)
1924                 {
1925                         VoteNag();
1926                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1927                 }
1928
1929         // GOD MODE info
1930         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
1931         {
1932                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
1933                 self.max_armorvalue = 0;
1934         }
1935
1936         if(frametime)
1937                 antilag_record(self);
1938
1939         if(self.classname == "player") {
1940 //              if(self.netname == "Wazat")
1941 //                      bprint(self.classname, "\n");
1942
1943                 CheckRules_Player();
1944
1945                 if(self.BUTTON_INFO)
1946                         PrintWelcomeMessage(self);
1947
1948                 if(g_lms || !cvar("sv_spectate"))
1949                 if((time - self.jointime) <= cvar("welcome_message_time"))
1950                         PrintWelcomeMessage(self);
1951
1952                 if (intermission_running)
1953                 {
1954                         IntermissionThink ();   // otherwise a button could be missed between
1955                         return;                                 // the think tics
1956                 }
1957
1958                 if(self.teleport_time)
1959                 if(time > self.teleport_time)
1960                 {
1961                         self.teleport_time = 0;
1962                         self.effects = self.effects - (self.effects & EF_NODRAW);
1963                         if(self.weaponentity)
1964                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
1965                 }
1966
1967                 Nixnex_GiveCurrentWeapon();
1968
1969                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
1970                         UpdateSelectedPlayer();
1971
1972                 //don't allow the player to turn around while game is paused!
1973                 if(timeoutStatus == 2) {
1974                         self.v_angle = self.lastV_angle;
1975                         self.angles = self.lastV_angle;
1976                         self.fixangle = TRUE;
1977                 }
1978
1979                 if (self.deadflag != DEAD_NO)
1980                 {
1981                         float button_pressed, force_respawn;
1982                         player_anim();
1983                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
1984                         force_respawn = (g_lms || cvar("g_forced_respawn"));
1985                         if (self.deadflag == DEAD_DYING)
1986                         {
1987                                 if(force_respawn)
1988                                         self.deadflag = DEAD_RESPAWNING;
1989                                 else if(!button_pressed)
1990                                         self.deadflag = DEAD_DEAD;
1991                         }
1992                         else if (self.deadflag == DEAD_DEAD)
1993                         {
1994                                 if(button_pressed)
1995                                         self.deadflag = DEAD_RESPAWNABLE;
1996                         }
1997                         else if (self.deadflag == DEAD_RESPAWNABLE)
1998                         {
1999                                 if(!button_pressed)
2000                                         self.deadflag = DEAD_RESPAWNING;
2001                         }
2002                         else if (self.deadflag == DEAD_RESPAWNING)
2003                         {
2004                                 if(time > self.death_time)
2005                                 {
2006                                         self.death_time = time + 1; // only retry once a second
2007                                         respawn();
2008                                 }
2009                         }
2010                         ShowRespawnCountdown();
2011                         return;
2012                 }
2013
2014                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2015                 {
2016                         vector dist;
2017
2018                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2019                         dist = self.oldorigin - self.origin;
2020                         dist_z = 0;
2021                         self.lms_traveled_distance += fabs(vlen(dist));
2022
2023                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
2024                         {
2025                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2026                                 self.lms_traveled_distance = 0;
2027                         }
2028
2029                         if(time > self.lms_nextcheck)
2030                         {
2031                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2032                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2033                                 {
2034                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2035                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2036                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2037                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2038                                 }
2039                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2040                                 self.lms_traveled_distance = 0;
2041                         }
2042                 }
2043
2044                 if (self.BUTTON_CROUCH && !self.hook.state)
2045                 {
2046                         if (!self.crouch)
2047                         {
2048                                 self.crouch = TRUE;
2049                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2050                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2051                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
2052                         }
2053                 }
2054                 else
2055                 {
2056                         if (self.crouch)
2057                         {
2058                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2059                                 if (!trace_startsolid)
2060                                 {
2061                                         self.crouch = FALSE;
2062                                         self.view_ofs = PL_VIEW_OFS;
2063                                         setsize (self, PL_MIN, PL_MAX);
2064                                 }
2065                         }
2066                 }
2067
2068                 FixPlayermodel();
2069
2070                 GrapplingHookFrame();
2071
2072                 W_WeaponFrame();
2073
2074                 {
2075                         float zoomfactor, zoomspeed, zoomdir;
2076                         zoomfactor = self.cvar_cl_zoomfactor;
2077                         if(zoomfactor < 1 || zoomfactor > 16)
2078                                 zoomfactor = 2.5;
2079                         zoomspeed = self.cvar_cl_zoomspeed;
2080                         if(zoomspeed >= 0) // < 0 is instant zoom
2081                                 if(zoomspeed < 0.5 || zoomspeed > 16)
2082                                         zoomspeed = 3.5;
2083
2084                         zoomdir = self.BUTTON_ZOOM;
2085                         if(self.BUTTON_ATCK2)
2086                                 if(self.weapon == WEP_NEX)
2087                                         if(!g_minstagib)
2088                                                 zoomdir = 1;
2089
2090                         if(zoomdir)
2091                                 self.has_zoomed = 1;
2092
2093                         if(self.has_zoomed)
2094                         {
2095                                 if(zoomspeed <= 0) // instant zoom
2096                                 {
2097                                         if(zoomdir)
2098                                                 self.viewzoom = 1 / zoomfactor;
2099                                         else
2100                                                 self.viewzoom = 1;
2101                                 }
2102                                 else
2103                                 {
2104                                         // geometric zoom would be:
2105                                         //   self.viewzoom = bound(1 / zoomfactor, self.viewzoom * pow(zoomfactor, (zoomdir ? -1 : 1) * frametime * zoomspeed), 1);
2106                                         // however, testing showed that arithmetic/harmonic zoom works better
2107                                         if(zoomdir)
2108                                                 // self.viewzoom = 1 / bound(1, 1 / self.viewzoom + (zoomdir ? 1 : -1) * frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2109                                                 // zoom in = arithmetic: 1x, 2x, 3x, 4x, ..., 8x
2110                                                 self.viewzoom = 1 / bound(1, 1 / self.viewzoom + frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2111                                         else
2112                                                 // self.viewzoom = bound(1 / zoomfactor, self.viewzoom + (zoomdir ? -1 : 1) * frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2113                                                 // zoom out = harmonic: 8/1x, 8/2x, 8/3x, 8/4x, ..., 8/8x
2114                                                 self.viewzoom = bound(1 / zoomfactor, self.viewzoom + frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2115                                 }
2116                         }
2117                         else
2118                                 self.viewzoom = min(1, self.viewzoom + frametime); // spawn zoom-in
2119                 }
2120
2121                 player_powerups();
2122                 player_regen();
2123                 player_anim();
2124
2125                 if (g_minstagib)
2126                         minstagib_ammocheck();
2127
2128                 ctf_setstatus();
2129                 kh_setstatus();
2130
2131                 //self.angles_y=self.v_angle_y + 90;   // temp
2132
2133                 //if (TetrisPreFrame()) return;
2134         } else if(gameover) {
2135                 if (intermission_running)
2136                         IntermissionThink ();   // otherwise a button could be missed between
2137                 return;
2138         } else if(self.classname == "observer") {
2139                 ObserverThink();
2140         } else if(self.classname == "spectator") {
2141                 SpectatorThink();
2142         }
2143 }
2144
2145
2146 /*
2147 =============
2148 PlayerPostThink
2149
2150 Called every frame for each client after the physics are run
2151 =============
2152 */
2153 .float idlekick_lasttimeleft;
2154 void PlayerPostThink (void)
2155 {
2156         // Savage: Check for nameless players
2157         if (strlen(self.netname) < 1) {
2158                 self.netname = "Player";
2159                 stuffcmd(self, "seta _cl_name Player\n");
2160         }
2161
2162         if(sv_maxidle)
2163         {
2164                 float timeleft;
2165                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2166                 if(timeleft <= 0)
2167                 {
2168                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2169                         play2(self, "announcer/robotic/terminated.ogg");
2170                         dropclient(self);
2171                         return;
2172                 }
2173                 else if(timeleft <= 10)
2174                 {
2175                         if(timeleft != self.idlekick_lasttimeleft)
2176                         {
2177                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2178                                 play2(self, strcat("announcer/robotic/", ftos(timeleft), ".ogg"));
2179                         }
2180                 }
2181                 else
2182                 {
2183                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2184                 }
2185                 self.idlekick_lasttimeleft = timeleft;
2186         }
2187
2188         if(self.classname == "player") {
2189                 CheckRules_Player();
2190                 UpdateChatBubble();
2191                 UpdateTeamBubble();
2192                 if (self.impulse)
2193                         ImpulseCommands();
2194                 if (intermission_running)
2195                         return;         // intermission or finale
2196
2197                 //PrintWelcomeMessage(self);
2198                 //if (TetrisPostFrame()) return;
2199
2200                 // restart countdown
2201                 if (restart_countdown) {
2202                         if(time < restart_countdown) {
2203                                 if (!cvar("sv_ready_restart_after_countdown"))
2204                                 {
2205                                         self.movetype = MOVETYPE_NONE;
2206                                         self.velocity = '0 0 0';
2207                                         self.avelocity = '0 0 0';
2208                                         self.movement = '0 0 0';
2209                                 }
2210                         }
2211                         else
2212                         {
2213                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2214                                 if (!cvar("sv_ready_restart_after_countdown"))
2215                                 {
2216                                         if(self.movetype == MOVETYPE_NONE)
2217                                         {
2218                                                 self.movetype = MOVETYPE_WALK;
2219                                         }
2220                                 }
2221                         }
2222                 }
2223
2224         } else if (self.classname == "observer") {
2225                 //do nothing
2226         } else if (self.classname == "spectator") {
2227                 //do nothing
2228         }
2229
2230         /*
2231         float i;
2232         for(i = 0; i < 1000; ++i)
2233         {
2234                 vector end;
2235                 end = self.origin + '0 0 1024' + 512 * randomvec();
2236                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2237                 if(trace_fraction < 1)
2238                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2239                 {
2240                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2241                         break;
2242                 }
2243         }
2244         */
2245
2246         Arena_Warmup();
2247 }