data/qcsrc/server/cl_client.qc

   1 .float wantswelcomemessage;
   2 .string netname_previous;
   3
   4 void spawnfunc_info_player_survivor (void)
   5 {
   6         spawnfunc_info_player_deathmatch();
   7 }
   8
   9 void spawnfunc_info_player_start (void)
  10 {
  11         spawnfunc_info_player_deathmatch();
  12 }
  13
  14 void spawnfunc_info_player_deathmatch (void)
  15 {
  16         self.classname = "info_player_deathmatch";
  17         relocate_spawnpoint();
  18 }
  19
  20 void spawnpoint_use()
  21 {
  22         if(teams_matter)
  23         if(have_team_spawns)
  24         {
  25                 self.team = activator.team;
  26                 some_spawn_has_been_used = 1;
  27         }
  28 };
  29
  30 // Returns:
  31 //   -1 if a spawn can't be used
  32 //   otherwise, a weight of the spawnpoint
  33 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
  34 {
  35         float shortest, thisdist;
  36         entity player;
  37
  38         // filter out spots for the wrong team
  39         if(teamcheck)
  40         if(spot.team != teamcheck)
  41                 return -1;
  42
  43         // filter out spots for assault
  44         if(spot.target != "") {
  45                 local entity ent;
  46                 ent = find(world, targetname, spot.target);
  47                 while(ent) {
  48                         if(ent.classname == "target_objective")
  49                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  50                                         return -1;
  51                         ent = find(ent, targetname, spot.target);
  52                 }
  53         }
  54
  55         player = playerlist;
  56         shortest = vlen(world.maxs - world.mins);
  57         for(player = playerlist; player; player = player.chain)
  58                 if (player != self)
  59                 {
  60                         thisdist = vlen(player.origin - spot.origin);
  61                         if (thisdist < shortest)
  62                                 shortest = thisdist;
  63                 }
  64         return shortest;
  65 }
  66
  67 float spawn_allbad;
  68 float spawn_allgood;
  69 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  70 {
  71         local entity spot, spotlist, spotlistend;
  72         spawn_allgood = TRUE;
  73         spawn_allbad = TRUE;
  74
  75         spotlist = world;
  76         spotlistend = world;
  77
  78         for(spot = firstspot; spot; spot = spot.chain)
  79         {
  80                 spot.frags = Spawn_Score(spot, playerlist, teamcheck);
  81
  82                 if(cvar("spawn_debugview"))
  83                 {
  84                         setmodel(spot, "models/runematch/rune.mdl");
  85                         if(spot.frags < mindist)
  86                         {
  87                                 spot.colormod = '1 0 0';
  88                                 spot.scale = 1;
  89                         }
  90                         else
  91                         {
  92                                 spot.colormod = '0 1 0';
  93                                 spot.scale = spot.frags / mindist;
  94                         }
  95                 }
  96
  97                 if(spot.frags >= 0) // spawning allowed here
  98                 {
  99                         if(spot.frags < mindist)
 100                         {
 101                                 // too short distance
 102                                 spawn_allgood = FALSE;
 103                         }
 104                         else
 105                         {
 106                                 // perfect
 107                                 spawn_allbad = FALSE;
 108
 109                                 if(spotlistend)
 110                                         spotlistend.chain = spot;
 111                                 spotlistend = spot;
 112                                 if(!spotlist)
 113                                         spotlist = spot;
 114
 115                                 /*
 116                                 if(teamcheck)
 117                                 if(spot.team != teamcheck)
 118                                         error("invalid spawn added");
 119
 120                                 print("added ", etos(spot), "\n");
 121                                 */
 122                         }
 123                 }
 124         }
 125         if(spotlistend)
 126                 spotlistend.chain = world;
 127
 128         /*
 129                 entity e;
 130                 if(teamcheck)
 131                         for(e = spotlist; e; e = e.chain)
 132                         {
 133                                 print("seen ", etos(e), "\n");
 134                                 if(e.team != teamcheck)
 135                                         error("invalid spawn found");
 136                         }
 137         */
 138
 139         return spotlist;
 140 }
 141
 142 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 143 {
 144         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 145         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 146         local entity spot;
 147
 148         RandomSelection_Init();
 149         for(spot = firstspot; spot; spot = spot.chain)
 150                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.frags, upper), exponent) * spot.cnt);
 151
 152         return RandomSelection_chosen_ent;
 153 }
 154
 155 /*
 156 =============
 157 SelectSpawnPoint
 158
 159 Finds a point to respawn
 160 =============
 161 */
 162 entity SelectSpawnPoint (float anypoint)
 163 {
 164         local float teamcheck;
 165         local entity firstspot_new;
 166         local entity spot, firstspot, playerlist;
 167
 168         spot = find (world, classname, "testplayerstart");
 169         if (spot)
 170                 return spot;
 171
 172         teamcheck = 0;
 173
 174         if(!anypoint && have_team_spawns)
 175                 teamcheck = self.team;
 176
 177         // get the list of players
 178         playerlist = findchain(classname, "player");
 179         // get the entire list of spots
 180         firstspot = findchain(classname, "info_player_deathmatch");
 181         // filter out the bad ones
 182         // (note this returns the original list if none survived)
 183         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 184         if(!firstspot_new)
 185                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 186         firstspot = firstspot_new;
 187
 188         // there is 50/50 chance of choosing a random spot or the furthest spot
 189         // (this means that roughly every other spawn will be furthest, so you
 190         // usually won't get fragged at spawn twice in a row)
 191         if (arena_roundbased)
 192         {
 193                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 194                 if(firstspot_new)
 195                         firstspot = firstspot_new;
 196                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 197         }
 198         else if (random() > cvar("g_spawn_furthest"))
 199                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 200         else
 201                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 202
 203         if(cvar("spawn_debugview"))
 204         {
 205                 print("spot mindistance: ", ftos(spot.frags), "\n");
 206
 207                 entity e;
 208                 if(teamcheck)
 209                         for(e = firstspot; e; e = e.chain)
 210                                 if(e.team != teamcheck)
 211                                         error("invalid spawn found");
 212         }
 213
 214         if (!spot)
 215         {
 216                 if(cvar("spawn_debug"))
 217                         GotoNextMap();
 218                 else
 219                 {
 220                         if(some_spawn_has_been_used)
 221                                 return world; // team can't spawn any more, because of actions of other team
 222                         else
 223                                 error("Cannot find a spawn point - please fix the map!");
 224                 }
 225         }
 226
 227         return spot;
 228 }
 229
 230 /*
 231 =============
 232 CheckPlayerModel
 233
 234 Checks if the argument string can be a valid playermodel.
 235 Returns a valid one in doubt.
 236 =============
 237 */
 238 string FallbackPlayerModel = "models/player/marine.zym";
 239 string CheckPlayerModel(string plyermodel) {
 240         if(strlen(plyermodel) < 4)
 241                 return FallbackPlayerModel;
 242         if( substring(plyermodel,0,14) != "models/player/")
 243                 return FallbackPlayerModel;
 244         else if(cvar("sv_servermodelsonly"))
 245         {
 246                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 247                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 248                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 249                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 250                         return FallbackPlayerModel;
 251                 if(!fexists(plyermodel))
 252                         return FallbackPlayerModel;
 253         }
 254         return plyermodel;
 255 }
 256
 257 /*
 258 =============
 259 Client_customizeentityforclient
 260
 261 LOD reduction
 262 =============
 263 */
 264 float Client_customizeentityforclient()
 265 {
 266 #ifdef ALLOW_VARIABLE_LOD
 267         // self: me
 268         // other: the player viewing me
 269         float distance;
 270         float f;
 271
 272         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 273                 return TRUE;
 274
 275         if(other.cvar_cl_playerdetailreduction <= 0)
 276         {
 277                 if(other.cvar_cl_playerdetailreduction <= -2)
 278                         self.modelindex = self.modelindex_lod2;
 279                 else if(other.cvar_cl_playerdetailreduction <= -1)
 280                         self.modelindex = self.modelindex_lod1;
 281                 else
 282                         self.modelindex = self.modelindex_lod0;
 283         }
 284         else
 285         {
 286                 distance = vlen(self.origin - other.origin);
 287                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 288                 if(f > 10000)
 289                         self.modelindex = self.modelindex_lod2;
 290                 else if(f > 5000)
 291                         self.modelindex = self.modelindex_lod1;
 292                 else
 293                         self.modelindex = self.modelindex_lod0;
 294         }
 295 #endif
 296
 297         return TRUE;
 298 }
 299
 300 void UpdatePlayerSounds();
 301 void setmodel_lod(entity e, string modelname)
 302 {
 303 #ifdef ALLOW_VARIABLE_LOD
 304         string s;
 305
 306         // FIXME: this only supports 3-letter extensions
 307         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 308         if(fexists(s))
 309         {
 310                 precache_model(s);
 311                 setmodel(e, s); // players have high precision
 312                 self.modelindex_lod1 = self.modelindex;
 313         }
 314         else
 315                 self.modelindex_lod1 = -1;
 316
 317         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 318         if(fexists(s))
 319         {
 320                 precache_model(s);
 321                 setmodel(e, s); // players have high precision
 322                 self.modelindex_lod2 = self.modelindex;
 323         }
 324         else
 325                 self.modelindex_lod2 = -1;
 326
 327         precache_model(modelname);
 328         setmodel(e, modelname); // players have high precision
 329         self.modelindex_lod0 = self.modelindex;
 330
 331         if(self.modelindex_lod1 < 0)
 332                 self.modelindex_lod1 = self.modelindex;
 333
 334         if(self.modelindex_lod2 < 0)
 335                 self.modelindex_lod2 = self.modelindex;
 336 #else
 337         precache_model(modelname);
 338         setmodel(e, modelname); // players have high precision
 339 #endif
 340         player_setupanimsformodel();
 341         UpdatePlayerSounds();
 342 }
 343
 344 /*
 345 =============
 346 PutObserverInServer
 347
 348 putting a client as observer in the server
 349 =============
 350 */
 351 void ctf_UpdateCaptures();
 352 void PutObserverInServer (void)
 353 {
 354         entity  spot;
 355         spot = SelectSpawnPoint (TRUE);
 356         if(!spot)
 357                 error("No spawnpoints for observers?!?\n");
 358         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 359
 360         if(clienttype(self) == CLIENTTYPE_REAL)
 361         {
 362                 msg_entity = self;
 363                 WriteByte(MSG_ONE, SVC_SETVIEW);
 364                 WriteEntity(MSG_ONE, self);
 365         }
 366
 367         DropAllRunes(self);
 368         kh_Key_DropAll(self, TRUE);
 369
 370         if(self.flagcarried)
 371                 DropFlag(self.flagcarried);
 372
 373         WaypointSprite_PlayerDead();
 374
 375         DistributeFragsAmongTeam(self, self.team, 1);
 376         if(g_ctf)
 377         {
 378                 self.captures = 0;
 379                 ctf_UpdateCaptures();
 380         }
 381
 382         if(self.frags <= 0 && self.frags > -666 && g_lms && self.killcount != -666)
 383                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 384         else if(self.killcount != -666)
 385                 bprint ("^4", self.netname, "^4 is spectating now\n");
 386
 387         self.spectatortime = time;
 388
 389         self.classname = "observer";
 390         self.health = -666;
 391         self.takedamage = DAMAGE_NO;
 392         self.solid = SOLID_NOT;
 393         self.movetype = MOVETYPE_NOCLIP;
 394         self.flags = FL_CLIENT | FL_NOTARGET;
 395         self.armorvalue = 666;
 396         self.effects = 0;
 397         self.armorvalue = cvar("g_balance_armor_start");
 398         self.pauserotarmor_finished = 0;
 399         self.pauserothealth_finished = 0;
 400         self.pauseregen_finished = 0;
 401         self.damageforcescale = 0;
 402         self.death_time = 0;
 403         self.dead_frame = 0;
 404         self.deaths = 0;
 405         self.alpha = 0;
 406         self.scale = 0;
 407         self.fade_time = 0;
 408         self.pain_frame = 0;
 409         self.pain_finished = 0;
 410         self.strength_finished = 0;
 411         self.invincible_finished = 0;
 412         self.pushltime = 0;
 413         self.think = SUB_Null;
 414         self.nextthink = 0;
 415         self.hook_time = 0;
 416         self.runes = 0;
 417         self.deadflag = DEAD_NO;
 418         self.angles = spot.angles;
 419         self.angles_z = 0;
 420         self.fixangle = TRUE;
 421         self.crouch = FALSE;
 422
 423         self.view_ofs = PL_VIEW_OFS;
 424         setorigin (self, spot.origin);
 425         setsize (self, '0 0 0', '0 0 0');
 426         self.oldorigin = self.origin;
 427         self.items = 0;
 428         self.model = "";
 429         self.modelindex = 0;
 430         self.weapon = 0;
 431         self.weaponmodel = "";
 432         self.weaponentity = world;
 433         self.killcount = -666;
 434         self.velocity = '0 0 0';
 435         self.avelocity = '0 0 0';
 436         self.punchangle = '0 0 0';
 437         self.punchvector = '0 0 0';
 438         self.oldvelocity = self.velocity;
 439         self.customizeentityforclient = Client_customizeentityforclient;
 440         self.viewzoom = 1;
 441         self.wantswelcomemessage = 1;
 442
 443         if(g_arena)
 444         {
 445                 if(self.frags != -2)
 446                 {
 447                         Spawnqueue_Insert(self);
 448                 }
 449                 else
 450                 {
 451                         Spawnqueue_Unmark(self);
 452                         Spawnqueue_Remove(self);
 453                 }
 454         }
 455         else if(!g_lms)
 456                 self.frags = -666;
 457 }
 458
 459 float RestrictSkin(float s)
 460 {
 461         if(!teams_matter)
 462                 return s;
 463         if(s == 6)
 464                 return 6;
 465         return mod(s, 3);
 466 }
 467
 468 void FixPlayermodel()
 469 {
 470         local string defaultmodel;
 471         local float defaultskin;
 472         local vector m1, m2;
 473
 474         defaultmodel = "";
 475
 476         if(cvar("sv_defaultcharacter") == 1) {
 477                 defaultskin = 0;
 478
 479                 if(teams_matter)
 480                 {
 481                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 482                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 483                 }
 484
 485                 if(defaultmodel == "")
 486                 {
 487                         defaultmodel = cvar_string("sv_defaultplayermodel");
 488                         defaultskin = cvar("sv_defaultplayerskin");
 489                 }
 490         }
 491
 492         if(defaultmodel != "")
 493         {
 494                 if (defaultmodel != self.model)
 495                 {
 496                         m1 = self.mins;
 497                         m2 = self.maxs;
 498                         setmodel_lod (self, defaultmodel);
 499                         setsize (self, m1, m2);
 500                 }
 501
 502                 self.skin = defaultskin;
 503         } else {
 504                 if (self.playermodel != self.model)
 505                 {
 506                         self.playermodel = CheckPlayerModel(self.playermodel);
 507                         m1 = self.mins;
 508                         m2 = self.maxs;
 509                         setmodel_lod (self, self.playermodel);
 510                         setsize (self, m1, m2);
 511                 }
 512
 513                 self.skin = RestrictSkin(stof(self.playerskin));
 514         }
 515
 516         if(!teams_matter)
 517                 if(strlen(cvar_string("sv_defaultplayercolors")))
 518                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 519                                 setcolor(self, cvar("sv_defaultplayercolors"));
 520 }
 521
 522 /*
 523 =============
 524 PutClientInServer
 525
 526 Called when a client spawns in the server
 527 =============
 528 */
 529 //void() ctf_playerchanged;
 530 void PutClientInServer (void)
 531 {
 532         if(clienttype(self) == CLIENTTYPE_BOT)
 533         {
 534                 self.classname = "player";
 535         }
 536         else if(clienttype(self) == CLIENTTYPE_REAL)
 537         {
 538                 msg_entity = self;
 539                 WriteByte(MSG_ONE, SVC_SETVIEW);
 540                 WriteEntity(MSG_ONE, self);
 541         }
 542
 543         // player is dead and becomes observer
 544         if(g_lms && self.frags < 1)
 545                 self.classname = "observer";
 546
 547         if(g_arena)
 548         if(!self.spawned)
 549                 self.classname = "observer";
 550
 551         if(self.classname == "player") {
 552                 entity  spot;
 553
 554                 spot = SelectSpawnPoint (FALSE);
 555                 if(!spot)
 556                 {
 557                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 558                         return; // spawn failed
 559                 }
 560
 561                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 562
 563                 self.classname = "player";
 564                 self.iscreature = TRUE;
 565                 self.movetype = MOVETYPE_WALK;
 566                 self.solid = SOLID_SLIDEBOX;
 567                 self.flags = FL_CLIENT;
 568                 self.takedamage = DAMAGE_AIM;
 569                 if(g_minstagib)
 570                         self.effects = EF_FULLBRIGHT;
 571                 else
 572                         self.effects = 0;
 573                 self.air_finished = time + 12;
 574                 self.dmg = 2;
 575
 576                 self.ammo_shells = start_ammo_shells;
 577                 self.ammo_nails = start_ammo_nails;
 578                 self.ammo_rockets = start_ammo_rockets;
 579                 self.ammo_cells = start_ammo_cells;
 580                 self.health = start_health;
 581                 self.armorvalue = start_armorvalue;
 582                 self.items = start_items;
 583                 self.switchweapon = start_switchweapon;
 584                 self.cnt = start_switchweapon;
 585                 self.weapon = 0;
 586                 self.jump_interval = time;
 587
 588                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 589                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 590                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 591                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 592                 //extend the pause of rotting if client was reset at the beginning of the countdown
 593                 if(!cvar("sv_ready_restart_after_countdown") && time < restart_countdown) {
 594                         self.spawnshieldtime += RESTART_COUNTDOWN;
 595                         self.pauserotarmor_finished += RESTART_COUNTDOWN;
 596                         self.pauserothealth_finished += RESTART_COUNTDOWN;
 597                         self.pauseregen_finished += RESTART_COUNTDOWN;
 598                 }
 599                 self.damageforcescale = 2;
 600                 self.death_time = 0;
 601                 self.dead_frame = 0;
 602                 self.alpha = 0;
 603                 self.scale = 0;
 604                 self.fade_time = 0;
 605                 self.pain_frame = 0;
 606                 self.pain_finished = 0;
 607                 self.strength_finished = 0;
 608                 self.invincible_finished = 0;
 609                 self.pushltime = 0;
 610                 //self.speed_finished = 0;
 611                 //self.slowmo_finished = 0;
 612                 // players have no think function
 613                 self.think = SUB_Null;
 614                 self.nextthink = 0;
 615                 self.hook_time = 0;
 616
 617                 self.runes = 0;
 618
 619                 self.deadflag = DEAD_NO;
 620
 621                 self.angles = spot.angles;
 622
 623                 self.angles_z = 0; // never spawn tilted even if the spot says to
 624                 self.fixangle = TRUE; // turn this way immediately
 625                 self.velocity = '0 0 0';
 626                 self.avelocity = '0 0 0';
 627                 self.punchangle = '0 0 0';
 628                 self.punchvector = '0 0 0';
 629                 self.oldvelocity = self.velocity;
 630
 631                 self.viewzoom = 0.6;
 632                 self.has_zoomed = 0;
 633
 634                 self.customizeentityforclient = Client_customizeentityforclient;
 635
 636                 self.model = "";
 637                 FixPlayermodel();
 638
 639                 self.crouch = FALSE;
 640                 self.view_ofs = PL_VIEW_OFS;
 641                 setsize (self, PL_MIN, PL_MAX);
 642                 self.spawnorigin = spot.origin;
 643                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 644                 // don't reset back to last position, even if new position is stuck in solid
 645                 self.oldorigin = self.origin;
 646
 647                 if(g_arena)
 648                 {
 649                         Spawnqueue_Remove(self);
 650                         Spawnqueue_Mark(self);
 651                 }
 652
 653                 self.event_damage = PlayerDamage;
 654
 655                 self.bot_attack = TRUE;
 656
 657                 self.statdraintime = time + 5;
 658                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 659
 660                 if(self.killcount == -666) {
 661                         self.killcount = 0;
 662                         if(!g_arena)
 663                         if(!g_lms)
 664                                 self.frags = 0;
 665                 }
 666
 667                 self.cnt = WEP_LASER;
 668                 self.nixnex_lastchange_id = -1;
 669
 670                 CL_SpawnWeaponentity();
 671                 self.alpha = default_player_alpha;
 672                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 673                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 674
 675                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 676                 self.lms_traveled_distance = 0;
 677                 self.speedrunning = FALSE;
 678
 679                 if(cvar("spawn_debug"))
 680                 {
 681                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 682                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 683                 }
 684
 685                 //stuffcmd(self, "chase_active 0");
 686                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 687
 688                 if (cvar("g_spawnsound"))
 689                         sound (self, CHAN_AUTO, "misc/spawn.wav", 1, ATTN_NORM);
 690
 691                 if(g_assault) {
 692                         if(self.team == assault_attacker_team)
 693                                 centerprint(self, "You are attacking!\n");
 694                         else
 695                                 centerprint(self, "You are defending!\n");
 696                 }
 697
 698         } else if(self.classname == "observer") {
 699                 PutObserverInServer ();
 700         }
 701
 702         //if(g_ctf)
 703         //      ctf_playerchanged();
 704 }
 705
 706 /*
 707 =============
 708 SendCSQCInfo
 709
 710 Send whatever CSQC needs NOW and cannot wait for SendServerInfo to happen...
 711 =============
 712 */
 713 void SendCSQCInfo(void)
 714 {
 715         if(clienttype(self) != CLIENTTYPE_REAL)
 716                 return;
 717         msg_entity = self;
 718         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 719         WriteByte(MSG_ONE, TE_CSQC_INIT);
 720         WriteByte(MSG_ONE, maxclients-1);
 721 }
 722
 723 /*
 724 =============
 725 SetNewParms
 726 =============
 727 */
 728 void SetNewParms (void)
 729 {
 730         // initialize parms for a new player
 731         parm1 = -(86400 * 366);
 732 }
 733
 734 /*
 735 =============
 736 SetChangeParms
 737 =============
 738 */
 739 void SetChangeParms (void)
 740 {
 741         // save parms for level change
 742         parm1 = self.parm_idlesince - time;
 743 }
 744
 745 /*
 746 =============
 747 DecodeLevelParms
 748 =============
 749 */
 750 void DecodeLevelParms (void)
 751 {
 752         // load parms
 753         self.parm_idlesince = parm1;
 754         if(self.parm_idlesince == -(86400 * 366))
 755                 self.parm_idlesince = time;
 756 }
 757
 758 /*
 759 =============
 760 ClientKill
 761
 762 Called when a client types 'kill' in the console
 763 =============
 764 */
 765
 766 void ClientKill_Now_TeamChange()
 767 {
 768         if(g_ctf)
 769         {
 770                 self.captures = 0;
 771                 ctf_UpdateCaptures();
 772         }
 773         if(self.killindicator_teamchange == -1)
 774         {
 775                 self.team = -1;
 776                 JoinBestTeam( self, FALSE, FALSE );
 777         }
 778         else
 779         {
 780                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 781         }
 782 }
 783
 784 void ClientKill_Now()
 785 {
 786         if(self.killindicator_teamchange)
 787                 ClientKill_Now_TeamChange();
 788
 789         // in any case:
 790         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 791 }
 792 void KillIndicator_Think()
 793 {
 794         if (!self.owner.modelindex)
 795         {
 796                 self.owner.killindicator = world;
 797                 remove(self);
 798                 return;
 799         }
 800
 801         if(self.cnt <= 0)
 802         {
 803                 self = self.owner;
 804                 ClientKill_Now(); // no oldself needed
 805                 return;
 806         }
 807         else
 808         {
 809                 if(self.cnt <= 10)
 810                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 811                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 812                 {
 813                         if(self.cnt <= 10)
 814                                 play2(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 815                         if(self.owner.killindicator_teamchange)
 816                         {
 817                                 if(self.owner.killindicator_teamchange == -1)
 818                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 819                                 else
 820                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 821                         }
 822                         else
 823                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 824                 }
 825                 self.nextthink = time + 1;
 826                 self.cnt -= 1;
 827         }
 828 }
 829
 830 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 831 {
 832         float killtime;
 833         entity e;
 834         killtime = cvar("g_balance_kill_delay");
 835
 836         self.killindicator_teamchange = targetteam;
 837
 838         if(!self.killindicator)
 839         {
 840                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 841                 {
 842                         ClientKill_Now();
 843                 }
 844                 else
 845                 {
 846                         self.killindicator = spawn();
 847                         self.killindicator.owner = self;
 848                         self.killindicator.scale = 0.5;
 849                         setattachment(self.killindicator, self, "");
 850                         setorigin(self.killindicator, '0 0 52');
 851                         self.killindicator.think = KillIndicator_Think;
 852                         self.killindicator.nextthink = time + (self.lip) * 0.05;
 853                         self.killindicator.cnt = ceil(killtime);
 854                         self.killindicator.count = bound(0, ceil(killtime), 10);
 855                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 856
 857                         for(e = world; (e = find(e, classname, "body")) != world; )
 858                         {
 859                                 if(e.enemy != self)
 860                                         continue;
 861                                 e.killindicator = spawn();
 862                                 e.killindicator.owner = e;
 863                                 e.killindicator.scale = 0.5;
 864                                 setattachment(e.killindicator, e, "");
 865                                 setorigin(e.killindicator, '0 0 52');
 866                                 e.killindicator.think = KillIndicator_Think;
 867                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
 868                                 e.killindicator.cnt = ceil(killtime);
 869                         }
 870                         self.lip = 0;
 871                 }
 872         }
 873         if(self.killindicator)
 874         {
 875                 if(targetteam)
 876                         self.killindicator.colormod = TeamColor(targetteam);
 877                 else
 878                         self.killindicator.colormod = '0 0 0';
 879         }
 880 }
 881
 882 void ClientKill (void)
 883 {
 884         ClientKill_TeamChange(0);
 885 }
 886
 887 void DoTeamChange(float destteam)
 888 {
 889         float t, c0;
 890         if(!cvar("teamplay"))
 891         {
 892                 if(destteam >= 0)
 893                         SetPlayerColors(self, destteam);
 894                 return;
 895         }
 896         if(self.classname == "player")
 897         if(destteam == -1)
 898         {
 899                 CheckAllowedTeams(self);
 900                 t = FindSmallestTeam(self, TRUE);
 901                 switch(self.team)
 902                 {
 903                         case COLOR_TEAM1: c0 = c1; break;
 904                         case COLOR_TEAM2: c0 = c2; break;
 905                         case COLOR_TEAM3: c0 = c3; break;
 906                         case COLOR_TEAM4: c0 = c4; break;
 907                         default:          c0 = 999;
 908                 }
 909                 switch(t)
 910                 {
 911                         case 1:
 912                                 if(c0 > c1)
 913                                         destteam = COLOR_TEAM1;
 914                                 break;
 915                         case 2:
 916                                 if(c0 > c2)
 917                                         destteam = COLOR_TEAM2;
 918                                 break;
 919                         case 3:
 920                                 if(c0 > c3)
 921                                         destteam = COLOR_TEAM3;
 922                                 break;
 923                         case 4:
 924                                 if(c0 > c4)
 925                                         destteam = COLOR_TEAM4;
 926                                 break;
 927                 }
 928                 if(destteam == -1)
 929                         return;
 930         }
 931         if(destteam == self.team && !self.killindicator)
 932                 return;
 933         ClientKill_TeamChange(destteam);
 934 }
 935
 936 void FixClientCvars(entity e)
 937 {
 938         // send prediction settings to the client
 939         stuffcmd(e, "\nin_bindmap 0 0\n");
 940         /*
 941          * we no longer need to stuff this. Remove this comment block if you feel
 942          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 943         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
 944         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 945         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 946         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 947         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 948         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 949         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 950         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
 951         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 952         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 953         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 954         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 955         stuffcmd(e, "cl_movement_edgefriction 1\n");
 956          */
 957 }
 958
 959 /*
 960 =============
 961 ClientConnect
 962
 963 Called when a client connects to the server
 964 =============
 965 */
 966 //void ctf_clientconnect();
 967 string ColoredTeamName(float t);
 968 void DecodeLevelParms (void);
 969 void ctf_SendCaptures(entity);
 970 //void dom_player_join_team(entity pl);
 971 void ClientConnect (void)
 972 {
 973         local string s;
 974         float wep;
 975
 976         if(Ban_IsClientBanned(self))
 977         {
 978                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
 979                 dropclient(self);
 980                 bprint(s);
 981                 return;
 982         }
 983
 984         DecodeLevelParms();
 985
 986         self.classname = "player_joining";
 987         self.flags = self.flags | FL_CLIENT;
 988         self.version_nagtime = time + 10 + random() * 10;
 989
 990         if(player_count<0)
 991         {
 992                 dprint("BUG player count is lower than zero, this cannot happen!\n");
 993                 player_count = 0;
 994         }
 995
 996         bot_clientconnect();
 997
 998         //if(g_domination)
 999         //      dom_player_join_team(self);
1000
1001         //JoinBestTeam(self, FALSE, FALSE);
1002
1003         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1004                 self.classname = "observer";
1005         } else {
1006                 self.classname = "player";
1007                 campaign_bots_may_start = 1;
1008         }
1009
1010         self.playerid = (playerid_last = playerid_last + 1);
1011         if(cvar("sv_eventlog"))
1012         {
1013                 if(clienttype(self) == CLIENTTYPE_REAL)
1014                         s = "player";
1015                 else
1016                         s = "bot";
1017                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
1018                 s = strcat(":team:", ftos(self.playerid), ":");
1019                 s = strcat(s, ftos(self.team));
1020                 GameLogEcho(s, FALSE);
1021         }
1022         self.netname_previous = strzone(self.netname);
1023
1024         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1025
1026         bprint ("^4",self.netname);
1027         bprint ("^4 connected");
1028
1029         if(g_domination || g_ctf)
1030         {
1031                 bprint(" and joined the ");
1032                 bprint(ColoredTeamName(self.team));
1033         }
1034
1035         bprint("\n");
1036
1037         self.welcomemessage_time = 0;
1038
1039         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1040         // TODO: is this being used for anything else than cd tracks?
1041         // Remember: SVC_CDTRACK exists. Maybe it should be used.
1042         //
1043         stuffcmd(self, "cl_particles_reloadeffects\n");
1044
1045         FixClientCvars(self);
1046
1047         // spawnfunc_waypoint sprites
1048         WaypointSprite_InitClient(self);
1049
1050         // Wazat's grappling hook
1051         SetGrappleHookBindings();
1052
1053         // get autoswitch state from player when he toggles it
1054         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1055
1056         // get version info from player
1057         stuffcmd(self, "cmd clientversion $gameversion\n");
1058
1059         // send all weapon info strings
1060         stuffcmd(self, "register_bestweapon clear\n"); // clear the Quake stuff
1061         wep = WEP_FIRST;
1062         while (wep <= WEP_LAST)
1063         {
1064                 weapon_action(wep, WR_REGISTER);
1065                 wep = wep + 1;
1066         }
1067
1068         // get other cvars from player
1069         GetCvars(0);
1070
1071         // set cvar for team scoreboard
1072         if (teams_matter)
1073         {
1074                 local float t;
1075                 t = cvar("teamplay");
1076                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1077                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1078         }
1079         else
1080                 stuffcmd(self, "set teamplay 0\n");
1081
1082         // notify about available teams
1083         if(teamplay)
1084         {
1085                 CheckAllowedTeams(self);
1086                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1087                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1088         }
1089         else
1090                 stuffcmd(self, "set _teams_available 0\n");
1091
1092         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1093
1094         if(g_lms)
1095         {
1096                 self.frags = LMS_NewPlayerLives();
1097                 if(!self.frags)
1098                         self.frags = -666;
1099         }
1100         else if(g_arena)
1101         {
1102                 self.classname = "observer";
1103                 Spawnqueue_Insert(self);
1104         }
1105         /*else if(g_ctf)
1106         {
1107                 ctf_clientconnect();
1108         }*/
1109
1110         if(entcs_start)
1111                 attach_entcs();
1112
1113         bot_relinkplayerlist();
1114
1115         self.spectatortime = time;
1116         if(blockSpectators)
1117         {
1118                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1119         }
1120
1121         self.jointime = time;
1122         self.allowedTimeouts = cvar("sv_timeout_number");
1123
1124         SendCSQCInfo();
1125         ctf_SendCaptures(self);
1126 }
1127
1128 /*
1129 =============
1130 ClientDisconnect
1131
1132 Called when a client disconnects from the server
1133 =============
1134 */
1135 void(entity e) DropFlag;
1136 .entity chatbubbleentity;
1137 .entity teambubbleentity;
1138 //void() ctf_clientdisconnect;
1139 void ClientDisconnect (void)
1140 {
1141         float save;
1142
1143         if(entcs_start)
1144                 detach_entcs();
1145
1146         if(cvar("sv_eventlog"))
1147                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
1148         bprint ("^4",self.netname);
1149         bprint ("^4 disconnected\n");
1150
1151         if (self.chatbubbleentity)
1152         {
1153                 remove (self.chatbubbleentity);
1154                 self.chatbubbleentity = world;
1155         }
1156
1157         if (self.teambubbleentity)
1158         {
1159                 remove (self.teambubbleentity);
1160                 self.teambubbleentity = world;
1161         }
1162
1163         if (self.killindicator)
1164         {
1165                 remove (self.killindicator);
1166                 self.killindicator = world;
1167         }
1168
1169         WaypointSprite_PlayerGone();
1170
1171         DropAllRunes(self);
1172         kh_Key_DropAll(self, TRUE);
1173
1174         if(self.flagcarried)
1175                 DropFlag(self.flagcarried);
1176
1177         DistributeFragsAmongTeam(self, self.team, 1);
1178         if(g_ctf)
1179         {
1180                 self.captures = 0;
1181                 ctf_UpdateCaptures();
1182         }
1183
1184         save = self.flags;
1185         self.flags = self.flags - (self.flags & FL_CLIENT);
1186         bot_relinkplayerlist();
1187         self.flags = save;
1188
1189         // remove laserdot
1190         if(self.weaponentity)
1191                 if(self.weaponentity.lasertarget)
1192                         remove(self.weaponentity.lasertarget);
1193
1194         if(g_arena)
1195         {
1196                 Spawnqueue_Unmark(self);
1197                 Spawnqueue_Remove(self);
1198         }
1199         /*if(g_ctf)
1200         {
1201                 ctf_clientdisconnect();
1202         }
1203         */
1204
1205         if(self.netname_previous)
1206                 strunzone(self.netname_previous);
1207
1208         // free cvars
1209         GetCvars(-1);
1210 }
1211
1212 .float BUTTON_CHAT;
1213 void ChatBubbleThink()
1214 {
1215         self.nextthink = time;
1216         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1217         {
1218                 self.owner.chatbubbleentity = world;
1219                 remove(self);
1220                 return;
1221         }
1222         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1223         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1224                 self.model = self.mdl;
1225         else
1226                 self.model = "";
1227 };
1228
1229 void UpdateChatBubble()
1230 {
1231         if (!self.modelindex)
1232                 return;
1233         // spawn a chatbubble entity if needed
1234         if (!self.chatbubbleentity)
1235         {
1236                 self.chatbubbleentity = spawn();
1237                 self.chatbubbleentity.owner = self;
1238                 self.chatbubbleentity.exteriormodeltoclient = self;
1239                 self.chatbubbleentity.think = ChatBubbleThink;
1240                 self.chatbubbleentity.nextthink = time;
1241                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1242                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1243                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1244                 self.chatbubbleentity.model = "";
1245                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1246         }
1247 }
1248
1249
1250 void TeamBubbleThink()
1251 {
1252         self.nextthink = time;
1253         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1254         {
1255                 self.owner.teambubbleentity = world;
1256                 remove(self);
1257                 return;
1258         }
1259 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1260         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1261                 self.model = "";
1262         else
1263                 self.model = self.mdl;
1264
1265 };
1266
1267 float TeamBubble_customizeentityforclient()
1268 {
1269         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1270 }
1271
1272 void UpdateTeamBubble()
1273 {
1274         if (!self.modelindex || !cvar("teamplay"))
1275                 return;
1276         // spawn a teambubble entity if needed
1277         if (!self.teambubbleentity && cvar("teamplay"))
1278         {
1279                 self.teambubbleentity = spawn();
1280                 self.teambubbleentity.owner = self;
1281                 self.teambubbleentity.exteriormodeltoclient = self;
1282                 self.teambubbleentity.think = TeamBubbleThink;
1283                 self.teambubbleentity.nextthink = time;
1284                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1285 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1286                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1287                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1288                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1289                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1290                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1291                 self.teambubbleentity.effects = EF_LOWPRECISION;
1292         }
1293 }
1294
1295 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1296 // added to the model skins
1297 /*void UpdateColorModHack()
1298 {
1299         local float c;
1300         c = self.clientcolors & 15;
1301         // LordHavoc: only bothering to support white, green, red, yellow, blue
1302              if (teamplay == 0) self.colormod = '0 0 0';
1303         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1304         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1305         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1306         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1307         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1308         else self.colormod = '1 1 1';
1309 };*/
1310
1311 void respawn(void)
1312 {
1313         CopyBody(1);
1314         self.effects |= EF_NODRAW; // prevent another CopyBody
1315         PutClientInServer();
1316 }
1317
1318 /**
1319  * When sv_timeout is used this function returs strings like
1320  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1321  * Called by centerprint functions
1322  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1323  */
1324 string getTimeoutText(float addOneSecond) {
1325         if (!cvar("sv_timeout") || !timeoutStatus)
1326                 return "";
1327
1328         local string retStr;
1329         if (timeoutStatus == 1) {
1330                 if (addOneSecond == 1) {
1331                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1332                 }
1333                 else {
1334                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1335                 }
1336                 return retStr;
1337         }
1338         else if (timeoutStatus == 2) {
1339                 if (addOneSecond) {
1340                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1341                         //don't show messages like "Timeout ends in 0 seconds"...
1342                         if ((remainingTimeoutTime + 1) > 0)
1343                                 return retStr;
1344                         else
1345                                 return "";
1346                 }
1347                 else {
1348                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1349                         //don't show messages like "Timeout ends in 0 seconds"...
1350                         if (remainingTimeoutTime > 0)
1351                                 return retStr;
1352                         else
1353                                 return "";
1354                 }
1355         }
1356         else return "";
1357 }
1358
1359 void player_powerups (void)
1360 {
1361         if (g_minstagib)
1362         {
1363                 if (self.items & IT_STRENGTH)
1364                 {
1365                         if (time > self.strength_finished)
1366                         {
1367                                 if (g_minstagib_invis_alpha > 0)
1368                                 {
1369                                         self.alpha = default_player_alpha;
1370                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1371                                         self.effects = self.effects | EF_FULLBRIGHT;
1372                                 }
1373                                 else
1374                                 {
1375                                         self.effects -= self.effects & EF_NODRAW;
1376                                 }
1377                                 self.items = self.items - (self.items & IT_STRENGTH);
1378                                 sprint(self, "^3Invisibility has worn off\n");
1379                         }
1380                 }
1381                 else
1382                 {
1383                         if (time < self.strength_finished)
1384                         {
1385                                 if (g_minstagib_invis_alpha > 0)
1386                                 {
1387                                         self.alpha = g_minstagib_invis_alpha;
1388                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1389                                         self.effects -= self.effects & EF_FULLBRIGHT;
1390                                 }
1391                                 else
1392                                 {
1393                                         self.effects = self.effects | EF_NODRAW;
1394                                 }
1395                                 self.items = self.items | IT_STRENGTH;
1396                                 sprint(self, "^3You are invisible\n");
1397                         }
1398                 }
1399
1400                 if (self.items & IT_INVINCIBLE)
1401                 {
1402                         if (time > self.invincible_finished)
1403                         {
1404                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1405                                 sprint(self, "^3Speed has worn off\n");
1406                         }
1407                 }
1408                 else
1409                 {
1410                         if (time < self.invincible_finished)
1411                         {
1412                                 self.items = self.items | IT_INVINCIBLE;
1413                                 sprint(self, "^3You are on speed\n");
1414                         }
1415                 }
1416                 return;
1417         }
1418
1419         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1420         if (self.items & IT_STRENGTH)
1421         {
1422                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1423                 if (time > self.strength_finished)
1424                 {
1425                         self.items = self.items - (self.items & IT_STRENGTH);
1426                         sprint(self, "^3Strength has worn off\n");
1427                 }
1428         }
1429         else
1430         {
1431                 if (time < self.strength_finished)
1432                 {
1433                         self.items = self.items | IT_STRENGTH;
1434                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1435                 }
1436         }
1437         if (self.items & IT_INVINCIBLE)
1438         {
1439                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1440                 if (time > self.invincible_finished)
1441                 {
1442                         self.items = self.items - (self.items & IT_INVINCIBLE);
1443                         sprint(self, "^3Shield has worn off\n");
1444                 }
1445         }
1446         else
1447         {
1448                 if (time < self.invincible_finished)
1449                 {
1450                         self.items = self.items | IT_INVINCIBLE;
1451                         sprint(self, "^3Shield surrounds you\n");
1452                 }
1453         }
1454
1455         if (cvar("g_fullbrightplayers"))
1456                 self.effects = self.effects | EF_FULLBRIGHT;
1457
1458         // midair gamemode: damage only while in the air
1459         // if in midair mode, being on ground grants temporary invulnerability
1460         // (this is so that multishot weapon don't clear the ground flag on the
1461         // first damage in the frame, leaving the player vulnerable to the
1462         // remaining hits in the same frame)
1463         if (self.flags & FL_ONGROUND)
1464         if (g_midair)
1465                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1466
1467         if (time < self.spawnshieldtime)
1468                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1469 }
1470
1471 float CalcRegen(float current, float stable, float regenfactor)
1472 {
1473         if(current > stable)
1474                 return current;
1475         else if(current > stable - 0.25) // when close enough, "snap"
1476                 return stable;
1477         else
1478                 return min(stable, current + (stable - current) * regenfactor * frametime);
1479 }
1480
1481 void player_regen (void)
1482 {
1483         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1484         maxh = cvar("g_balance_health_stable");
1485         maxa = cvar("g_balance_armor_stable");
1486         limith = cvar("g_balance_health_limit");
1487         limita = cvar("g_balance_armor_limit");
1488
1489         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1490                 return;
1491
1492         max_mod = regen_mod = rot_mod = limit_mod = 1;
1493
1494         if (self.runes & RUNE_REGEN)
1495         {
1496                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1497                 {
1498                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1499                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1500                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1501                 }
1502                 else
1503                 {
1504                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1505                         max_mod = cvar("g_balance_rune_regen_hpmod");
1506                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1507                 }
1508         }
1509         else if (self.runes & CURSE_VENOM)
1510         {
1511                 max_mod = cvar("g_balance_curse_venom_hpmod");
1512                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1513                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1514                 else
1515                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1516                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1517                 //if (!self.runes & RUNE_REGEN)
1518                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1519         }
1520         maxh = maxh * max_mod;
1521         //maxa = maxa * max_mod;
1522         limith = limith * limit_mod;
1523         limita = limita * limit_mod;
1524
1525         if (self.armorvalue > maxa)
1526         {
1527                 if (time > self.pauserotarmor_finished)
1528                 {
1529                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1530                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1531                 }
1532         }
1533         else if (self.armorvalue < maxa)
1534         {
1535                 if (time > self.pauseregen_finished)
1536                 {
1537                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1538                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1539                 }
1540         }
1541         if (self.health > maxh)
1542         {
1543                 if (time > self.pauserothealth_finished)
1544                 {
1545                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1546                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1547                 }
1548         }
1549         else if (self.health < maxh)
1550         {
1551                 if (time > self.pauseregen_finished)
1552                 {
1553                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1554                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1555                 }
1556         }
1557
1558         if (self.health > limith)
1559                 self.health = limith;
1560         if (self.armorvalue > limita)
1561                 self.armorvalue = limita;
1562
1563         // if player rotted to death...  die!
1564         if(self.health < 1)
1565                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1566 }
1567
1568 /*
1569 ======================
1570 spectate mode routines
1571 ======================
1572 */
1573 void SpectateCopy(entity spectatee) {
1574         self.armortype = spectatee.armortype;
1575         self.armorvalue = spectatee.armorvalue;
1576         self.currentammo = spectatee.currentammo;
1577         self.effects = spectatee.effects;
1578         self.health = spectatee.health;
1579         self.impulse = 0;
1580         self.items = spectatee.items;
1581         self.punchangle = spectatee.punchangle;
1582         self.view_ofs = spectatee.view_ofs;
1583         self.v_angle = spectatee.v_angle;
1584         self.viewzoom = spectatee.viewzoom;
1585         self.velocity = spectatee.velocity;
1586         self.dmg_take = spectatee.dmg_take;
1587         self.dmg_save = spectatee.dmg_save;
1588         self.dmg_inflictor = spectatee.dmg_inflictor;
1589         self.angles = spectatee.v_angle;
1590         self.fixangle = TRUE;
1591         setorigin(self, spectatee.origin);
1592         setsize(self, spectatee.mins, spectatee.maxs);
1593 }
1594
1595 float SpectateUpdate() {
1596         if(!self.enemy)
1597                 return 0;
1598
1599         if (self == self.enemy)
1600                 return 0;
1601
1602         if(self.enemy.flags & FL_NOTARGET)
1603                 return 0;
1604
1605         SpectateCopy(self.enemy);
1606
1607         return 1;
1608 }
1609
1610 float SpectateNext() {
1611         other = find(self.enemy, classname, "player");
1612         if (!other) {
1613                 other = find(other, classname, "player");
1614         }
1615         if (other) {
1616                 self.enemy = other;
1617         }
1618         if(self.enemy.classname == "player") {
1619                 msg_entity = self;
1620                 WriteByte(MSG_ONE, SVC_SETVIEW);
1621                 WriteEntity(MSG_ONE, self.enemy);
1622                 self.wantswelcomemessage = 1;
1623                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1624                 if(!SpectateUpdate())
1625                         PutObserverInServer();
1626                 return 1;
1627         } else {
1628                 return 0;
1629         }
1630 }
1631
1632 /*
1633 =============
1634 ShowRespawnCountdown()
1635
1636 Update a respawn countdown display.
1637 =============
1638 */
1639 void ShowRespawnCountdown()
1640 {
1641         float number;
1642         if(self.deadflag == DEAD_NO) // just respawned?
1643                 return;
1644         else
1645         {
1646                 number = ceil(self.death_time - time);
1647                 if(number <= 0)
1648                         return;
1649                 if(number <= self.respawn_countdown)
1650                 {
1651                         self.respawn_countdown = number - 1;
1652                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1653                                 play2(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1654                 }
1655         }
1656 }
1657
1658 void LeaveSpectatorMode()
1659 {
1660         if(isJoinAllowed()) {
1661                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1662                         self.classname = "player";
1663                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1664                                 JoinBestTeam(self, FALSE, TRUE);
1665                         if(cvar("g_campaign"))
1666                                 campaign_bots_may_start = 1;
1667                         PutClientInServer();
1668                         if(!(self.flags & FL_NOTARGET))
1669                                 bprint ("^4", self.netname, "^4 is playing now\n");
1670                         centerprint(self,"");
1671                         return;
1672                 } else {
1673                         stuffcmd(self,"menu_showteamselect\n");
1674                         return;
1675                 }
1676         }
1677         else {
1678                 //player may not join because of g_maxplayers is set
1679                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1680         }
1681 }
1682
1683 /**
1684  * Determines whether the player is allowed to join. This depends on cvar
1685  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1686  * it checks whether the number of currently playing players exceeds g_maxplayers.
1687  * @return bool TRUE if the player is allowed to join, false otherwise
1688  */
1689 float isJoinAllowed() {
1690         if (!cvar("g_maxplayers"))
1691                 return TRUE;
1692
1693         local entity e;
1694         local float currentlyPlaying;
1695         FOR_EACH_REALPLAYER(e) {
1696                 if(e.classname == "player")
1697                         currentlyPlaying += 1;
1698         }
1699         if(currentlyPlaying < cvar("g_maxplayers"))
1700                 return TRUE;
1701
1702         return FALSE;
1703 }
1704
1705 /**
1706  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1707  * g_maxplayers_spectator_blocktime seconds
1708  */
1709 void checkSpectatorBlock() {
1710         if(self.classname == "spectator" || self.classname == "observer") {
1711                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1712                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1713                         dropclient(self);
1714                 }
1715         }
1716 }
1717
1718 float vercmp_recursive(string v1, string v2)
1719 {
1720         float dot1, dot2;
1721         string s1, s2;
1722         float r;
1723
1724         dot1 = strstrofs(v1, ".", 0);
1725         dot2 = strstrofs(v2, ".", 0);
1726         if(dot1 == -1)
1727                 s1 = v1;
1728         else
1729                 s1 = substring(v1, 0, dot1);
1730         if(dot2 == -1)
1731                 s2 = v2;
1732         else
1733                 s2 = substring(v2, 0, dot2);
1734
1735         r = stof(s1) - stof(s2);
1736         if(r != 0)
1737                 return r;
1738
1739         r = strcasecmp(s1, s2);
1740         if(r != 0)
1741                 return r;
1742
1743         if(dot1 == -1)
1744                 if(dot2 == -1)
1745                         return 0;
1746                 else
1747                         return -1;
1748         else
1749                 if(dot2 == -1)
1750                         return 1;
1751                 else
1752                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1753 }
1754
1755 float vercmp(string v1, string v2)
1756 {
1757         if(strcasecmp(v1, v2) == 0) // early out check
1758                 return 0;
1759         return vercmp_recursive(v1, v2);
1760 }
1761
1762 void ObserverThink()
1763 {
1764         if (self.flags & FL_JUMPRELEASED) {
1765                 if (self.BUTTON_JUMP && self.version == cvar("gameversion")) {
1766                         self.welcomemessage_time = 0;
1767                         self.flags = self.flags - FL_JUMPRELEASED;
1768                         LeaveSpectatorMode();
1769                         return;
1770                 } else if(self.BUTTON_ATCK && self.version == cvar("gameversion")) {
1771                         self.welcomemessage_time = 0;
1772                         self.flags = self.flags - FL_JUMPRELEASED;
1773                         if(SpectateNext() == 1) {
1774                                 self.classname = "spectator";
1775                         }
1776                 }
1777         } else {
1778                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
1779                         self.flags = self.flags | FL_JUMPRELEASED;
1780                 }
1781         }
1782         if(self.BUTTON_ZOOM)
1783                 self.wantswelcomemessage = 0;
1784         if(self.wantswelcomemessage)
1785                 PrintWelcomeMessage(self);
1786 }
1787
1788 void SpectatorThink()
1789 {
1790         if (self.flags & FL_JUMPRELEASED) {
1791                 if (self.BUTTON_JUMP && self.version == cvar("gameversion")) {
1792                         self.welcomemessage_time = 0;
1793                         self.flags = self.flags - FL_JUMPRELEASED;
1794                         LeaveSpectatorMode();
1795                         return;
1796                 } else if(self.BUTTON_ATCK) {
1797                         self.welcomemessage_time = 0;
1798                         self.flags = self.flags - FL_JUMPRELEASED;
1799                         if(SpectateNext() == 1) {
1800                                 self.classname = "spectator";
1801                         } else {
1802                                 self.classname = "observer";
1803                                 PutClientInServer();
1804                         }
1805                 } else if (self.BUTTON_ATCK2) {
1806                         self.welcomemessage_time = 0;
1807                         self.flags = self.flags - FL_JUMPRELEASED;
1808                         self.classname = "observer";
1809                         PutClientInServer();
1810                 } else {
1811                         if(!SpectateUpdate())
1812                                 PutObserverInServer();
1813                 }
1814         } else {
1815                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
1816                         self.flags = self.flags | FL_JUMPRELEASED;
1817                 }
1818         }
1819         if(self.BUTTON_ZOOM)
1820                 self.wantswelcomemessage = 0;
1821         if(self.wantswelcomemessage)
1822                 PrintWelcomeMessage(self);
1823         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1824 }
1825
1826 /*
1827 =============
1828 PlayerPreThink
1829
1830 Called every frame for each client before the physics are run
1831 =============
1832 */
1833 void() ctf_setstatus;
1834 .float vote_nagtime;
1835 void PlayerPreThink (void)
1836 {
1837         if(blockSpectators)
1838                 checkSpectatorBlock();
1839
1840         if(self.netname_previous != self.netname)
1841         {
1842                 if(cvar("sv_eventlog"))
1843                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname), TRUE);
1844                 if(self.netname_previous)
1845                         strunzone(self.netname_previous);
1846                 self.netname_previous = strzone(self.netname);
1847         }
1848
1849         // version nagging
1850         if(self.version_nagtime)
1851                 if(self.cvar_g_nexuizversion)
1852                         if(time > self.version_nagtime)
1853                         {
1854                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1855                                 {
1856                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
1857                                         {
1858                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1859                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1860                                         }
1861                                         else
1862                                         {
1863                                                 float r;
1864                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
1865                                                 if(r < 0)
1866                                                 {
1867                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
1868                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
1869                                                 }
1870                                                 else if(r > 0)
1871                                                 {
1872                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1873                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1874                                                 }
1875                                         }
1876                                 }
1877                                 self.version_nagtime = 0;
1878                         }
1879
1880         // vote nagging
1881         if(self.cvar_scr_centertime)
1882                 if(time > self.vote_nagtime)
1883                 {
1884                         VoteNag();
1885                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1886                 }
1887
1888         // GOD MODE info
1889         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
1890         {
1891                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
1892                 self.max_armorvalue = 0;
1893         }
1894
1895         if(frametime)
1896                 antilag_record(self);
1897
1898         if(self.classname == "player") {
1899 //              if(self.netname == "Wazat")
1900 //                      bprint(self.classname, "\n");
1901
1902                 CheckRules_Player();
1903
1904                 if(self.BUTTON_INFO)
1905                         PrintWelcomeMessage(self);
1906
1907                 if(g_lms || !cvar("sv_spectate"))
1908                 if((time - self.jointime) <= cvar("welcome_message_time"))
1909                         PrintWelcomeMessage(self);
1910
1911                 if (intermission_running)
1912                 {
1913                         IntermissionThink ();   // otherwise a button could be missed between
1914                         return;                                 // the think tics
1915                 }
1916
1917                 if(self.teleport_time)
1918                 if(time > self.teleport_time)
1919                 {
1920                         self.teleport_time = 0;
1921                         self.effects = self.effects - (self.effects & EF_NODRAW);
1922                         if(self.weaponentity)
1923                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
1924                 }
1925
1926                 Nixnex_GiveCurrentWeapon();
1927
1928                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
1929                         UpdateSelectedPlayer();
1930
1931                 //don't allow the player to turn around while game is paused!
1932                 if(timeoutStatus == 2) {
1933                         self.v_angle = self.lastV_angle;
1934                         self.angles = self.lastV_angle;
1935                         self.fixangle = TRUE;
1936                 }
1937
1938                 if (self.deadflag != DEAD_NO)
1939                 {
1940                         float button_pressed, force_respawn;
1941                         player_anim();
1942                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
1943                         force_respawn = (g_lms || cvar("g_forced_respawn"));
1944                         if (self.deadflag == DEAD_DYING)
1945                         {
1946                                 if(force_respawn)
1947                                         self.deadflag = DEAD_RESPAWNING;
1948                                 else if(!button_pressed)
1949                                         self.deadflag = DEAD_DEAD;
1950                         }
1951                         else if (self.deadflag == DEAD_DEAD)
1952                         {
1953                                 if(button_pressed)
1954                                         self.deadflag = DEAD_RESPAWNABLE;
1955                         }
1956                         else if (self.deadflag == DEAD_RESPAWNABLE)
1957                         {
1958                                 if(!button_pressed)
1959                                         self.deadflag = DEAD_RESPAWNING;
1960                         }
1961                         else if (self.deadflag == DEAD_RESPAWNING)
1962                         {
1963                                 if(time > self.death_time)
1964                                 {
1965                                         self.death_time = time + 1; // only retry once a second
1966                                         respawn();
1967                                 }
1968                         }
1969                         ShowRespawnCountdown();
1970                         return;
1971                 }
1972
1973                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
1974                 {
1975                         vector dist;
1976
1977                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1978                         dist = self.oldorigin - self.origin;
1979                         dist_z = 0;
1980                         self.lms_traveled_distance += fabs(vlen(dist));
1981
1982                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
1983                         {
1984                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1985                                 self.lms_traveled_distance = 0;
1986                         }
1987
1988                         if(time > self.lms_nextcheck)
1989                         {
1990                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1991                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1992                                 {
1993                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1994                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1995                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1996                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1997                                 }
1998                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1999                                 self.lms_traveled_distance = 0;
2000                         }
2001                 }
2002
2003                 if (self.BUTTON_CROUCH && !self.hook.state)
2004                 {
2005                         if (!self.crouch)
2006                         {
2007                                 self.crouch = TRUE;
2008                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2009                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2010                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
2011                         }
2012                 }
2013                 else
2014                 {
2015                         if (self.crouch)
2016                         {
2017                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2018                                 if (!trace_startsolid)
2019                                 {
2020                                         self.crouch = FALSE;
2021                                         self.view_ofs = PL_VIEW_OFS;
2022                                         setsize (self, PL_MIN, PL_MAX);
2023                                 }
2024                         }
2025                 }
2026
2027                 FixPlayermodel();
2028
2029                 GrapplingHookFrame();
2030
2031                 W_WeaponFrame();
2032
2033                 {
2034                         float zoomfactor, zoomspeed, zoomdir;
2035                         zoomfactor = self.cvar_cl_zoomfactor;
2036                         if(zoomfactor < 1 || zoomfactor > 16)
2037                                 zoomfactor = 2.5;
2038                         zoomspeed = self.cvar_cl_zoomspeed;
2039                         if(zoomspeed >= 0) // < 0 is instant zoom
2040                                 if(zoomspeed < 0.5 || zoomspeed > 16)
2041                                         zoomspeed = 3.5;
2042
2043                         zoomdir = self.BUTTON_ZOOM;
2044                         if(self.BUTTON_ATCK2)
2045                                 if(self.weapon == WEP_NEX)
2046                                         if(!g_minstagib)
2047                                                 zoomdir = 1;
2048
2049                         if(zoomdir)
2050                                 self.has_zoomed = 1;
2051
2052                         if(self.has_zoomed)
2053                         {
2054                                 if(zoomspeed <= 0) // instant zoom
2055                                 {
2056                                         if(zoomdir)
2057                                                 self.viewzoom = 1 / zoomfactor;
2058                                         else
2059                                                 self.viewzoom = 1;
2060                                 }
2061                                 else
2062                                 {
2063                                         // geometric zoom would be:
2064                                         //   self.viewzoom = bound(1 / zoomfactor, self.viewzoom * pow(zoomfactor, (zoomdir ? -1 : 1) * frametime * zoomspeed), 1);
2065                                         // however, testing showed that arithmetic/harmonic zoom works better
2066                                         if(zoomdir)
2067                                                 // self.viewzoom = 1 / bound(1, 1 / self.viewzoom + (zoomdir ? 1 : -1) * frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2068                                                 // zoom in = arithmetic: 1x, 2x, 3x, 4x, ..., 8x
2069                                                 self.viewzoom = 1 / bound(1, 1 / self.viewzoom + frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2070                                         else
2071                                                 // self.viewzoom = bound(1 / zoomfactor, self.viewzoom + (zoomdir ? -1 : 1) * frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2072                                                 // zoom out = harmonic: 8/1x, 8/2x, 8/3x, 8/4x, ..., 8/8x
2073                                                 self.viewzoom = bound(1 / zoomfactor, self.viewzoom + frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2074                                 }
2075                         }
2076                         else
2077                                 self.viewzoom = min(1, self.viewzoom + frametime); // spawn zoom-in
2078                 }
2079
2080                 player_powerups();
2081                 player_regen();
2082                 player_anim();
2083
2084                 if (g_minstagib)
2085                         minstagib_ammocheck();
2086
2087                 ctf_setstatus();
2088                 kh_setstatus();
2089
2090                 //self.angles_y=self.v_angle_y + 90;   // temp
2091
2092                 //if (TetrisPreFrame()) return;
2093         } else if(gameover) {
2094                 if (intermission_running)
2095                         IntermissionThink ();   // otherwise a button could be missed between
2096                 return;
2097         } else if(self.classname == "observer") {
2098                 ObserverThink();
2099         } else if(self.classname == "spectator") {
2100                 SpectatorThink();
2101         }
2102 }
2103
2104
2105 /*
2106 =============
2107 PlayerPostThink
2108
2109 Called every frame for each client after the physics are run
2110 =============
2111 */
2112 .float idlekick_lasttimeleft;
2113 void PlayerPostThink (void)
2114 {
2115         // Savage: Check for nameless players
2116         if (strlen(self.netname) < 1) {
2117                 self.netname = "Player";
2118                 stuffcmd(self, "seta _cl_name Player\n");
2119         }
2120
2121         if(sv_maxidle)
2122         {
2123                 float timeleft;
2124                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2125                 if(timeleft <= 0)
2126                 {
2127                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2128                         play2(self, "announcer/robotic/terminated.ogg");
2129                         dropclient(self);
2130                         return;
2131                 }
2132                 else if(timeleft <= 10)
2133                 {
2134                         if(timeleft != self.idlekick_lasttimeleft)
2135                         {
2136                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2137                                 play2(self, strcat("announcer/robotic/", ftos(timeleft), ".ogg"));
2138                         }
2139                 }
2140                 else
2141                 {
2142                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2143                 }
2144                 self.idlekick_lasttimeleft = timeleft;
2145         }
2146
2147         if(self.classname == "player") {
2148                 CheckRules_Player();
2149                 UpdateChatBubble();
2150                 UpdateTeamBubble();
2151                 if (self.impulse)
2152                         ImpulseCommands();
2153                 if (intermission_running)
2154                         return;         // intermission or finale
2155
2156                 //PrintWelcomeMessage(self);
2157                 //if (TetrisPostFrame()) return;
2158
2159                 // restart countdown
2160                 if (restart_countdown) {
2161                         if(time < restart_countdown) {
2162                                 if (!cvar("sv_ready_restart_after_countdown"))
2163                                 {
2164                                         self.movetype = MOVETYPE_NONE;
2165                                         self.velocity = '0 0 0';
2166                                         self.avelocity = '0 0 0';
2167                                         self.movement = '0 0 0';
2168                                 }
2169                         }
2170                         else
2171                         {
2172                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2173                                 if (!cvar("sv_ready_restart_after_countdown"))
2174                                 {
2175                                         if(self.movetype == MOVETYPE_NONE)
2176                                         {
2177                                                 self.movetype = MOVETYPE_WALK;
2178                                         }
2179                                 }
2180                         }
2181                 }
2182
2183         } else if (self.classname == "observer") {
2184                 //do nothing
2185         } else if (self.classname == "spectator") {
2186                 //do nothing
2187         }
2188
2189         Arena_Warmup();
2190 }