data/qcsrc/server/cl_client.qc

   1 // let's abuse an existing field
   2 #define SPAWNPOINT_SCORE frags
   3
   4 .float wantswelcomemessage;
   5 .string netname_previous;
   6
   7 void spawnfunc_info_player_survivor (void)
   8 {
   9         spawnfunc_info_player_deathmatch();
  10 }
  11
  12 void spawnfunc_info_player_start (void)
  13 {
  14         spawnfunc_info_player_deathmatch();
  15 }
  16
  17 void spawnfunc_info_player_deathmatch (void)
  18 {
  19         self.classname = "info_player_deathmatch";
  20         relocate_spawnpoint();
  21 }
  22
  23 void spawnpoint_use()
  24 {
  25         if(teams_matter)
  26         if(have_team_spawns)
  27         {
  28                 self.team = activator.team;
  29                 some_spawn_has_been_used = 1;
  30         }
  31 };
  32
  33 // Returns:
  34 //   -1 if a spawn can't be used
  35 //   otherwise, a weight of the spawnpoint
  36 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
  37 {
  38         float shortest, thisdist;
  39         entity player;
  40
  41         // filter out spots for the wrong team
  42         if(teamcheck)
  43         if(spot.team != teamcheck)
  44                 return -1;
  45
  46         // filter out spots for assault
  47         if(spot.target != "") {
  48                 local entity ent;
  49                 ent = find(world, targetname, spot.target);
  50                 while(ent) {
  51                         if(ent.classname == "target_objective")
  52                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  53                                         return -1;
  54                         ent = find(ent, targetname, spot.target);
  55                 }
  56         }
  57
  58         player = playerlist;
  59         shortest = vlen(world.maxs - world.mins);
  60         for(player = playerlist; player; player = player.chain)
  61                 if (player != self)
  62                 {
  63                         thisdist = vlen(player.origin - spot.origin);
  64                         if (thisdist < shortest)
  65                                 shortest = thisdist;
  66                 }
  67         return shortest;
  68 }
  69
  70 float spawn_allbad;
  71 float spawn_allgood;
  72 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  73 {
  74         local entity spot, spotlist, spotlistend;
  75         spawn_allgood = TRUE;
  76         spawn_allbad = TRUE;
  77
  78         spotlist = world;
  79         spotlistend = world;
  80
  81         for(spot = firstspot; spot; spot = spot.chain)
  82         {
  83                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
  84
  85                 if(cvar("spawn_debugview"))
  86                 {
  87                         setmodel(spot, "models/runematch/rune.mdl");
  88                         if(spot.SPAWNPOINT_SCORE < mindist)
  89                         {
  90                                 spot.colormod = '1 0 0';
  91                                 spot.scale = 1;
  92                         }
  93                         else
  94                         {
  95                                 spot.colormod = '0 1 0';
  96                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
  97                         }
  98                 }
  99
 100                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 101                 {
 102                         if(spot.SPAWNPOINT_SCORE < mindist)
 103                         {
 104                                 // too short distance
 105                                 spawn_allgood = FALSE;
 106                         }
 107                         else
 108                         {
 109                                 // perfect
 110                                 spawn_allbad = FALSE;
 111
 112                                 if(spotlistend)
 113                                         spotlistend.chain = spot;
 114                                 spotlistend = spot;
 115                                 if(!spotlist)
 116                                         spotlist = spot;
 117
 118                                 /*
 119                                 if(teamcheck)
 120                                 if(spot.team != teamcheck)
 121                                         error("invalid spawn added");
 122
 123                                 print("added ", etos(spot), "\n");
 124                                 */
 125                         }
 126                 }
 127         }
 128         if(spotlistend)
 129                 spotlistend.chain = world;
 130
 131         /*
 132                 entity e;
 133                 if(teamcheck)
 134                         for(e = spotlist; e; e = e.chain)
 135                         {
 136                                 print("seen ", etos(e), "\n");
 137                                 if(e.team != teamcheck)
 138                                         error("invalid spawn found");
 139                         }
 140         */
 141
 142         return spotlist;
 143 }
 144
 145 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 146 {
 147         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 148         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 149         local entity spot;
 150
 151         RandomSelection_Init();
 152         for(spot = firstspot; spot; spot = spot.chain)
 153                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 154
 155         return RandomSelection_chosen_ent;
 156 }
 157
 158 /*
 159 =============
 160 SelectSpawnPoint
 161
 162 Finds a point to respawn
 163 =============
 164 */
 165 entity SelectSpawnPoint (float anypoint)
 166 {
 167         local float teamcheck;
 168         local entity firstspot_new;
 169         local entity spot, firstspot, playerlist;
 170
 171         spot = find (world, classname, "testplayerstart");
 172         if (spot)
 173                 return spot;
 174
 175         teamcheck = 0;
 176
 177         if(!anypoint && have_team_spawns)
 178                 teamcheck = self.team;
 179
 180         // get the list of players
 181         playerlist = findchain(classname, "player");
 182         // get the entire list of spots
 183         firstspot = findchain(classname, "info_player_deathmatch");
 184         // filter out the bad ones
 185         // (note this returns the original list if none survived)
 186         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 187         if(!firstspot_new)
 188                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 189         firstspot = firstspot_new;
 190
 191         // there is 50/50 chance of choosing a random spot or the furthest spot
 192         // (this means that roughly every other spawn will be furthest, so you
 193         // usually won't get fragged at spawn twice in a row)
 194         if (arena_roundbased)
 195         {
 196                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 197                 if(firstspot_new)
 198                         firstspot = firstspot_new;
 199                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 200         }
 201         else if (random() > cvar("g_spawn_furthest"))
 202                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 203         else
 204                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 205
 206         if(cvar("spawn_debugview"))
 207         {
 208                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 209
 210                 entity e;
 211                 if(teamcheck)
 212                         for(e = firstspot; e; e = e.chain)
 213                                 if(e.team != teamcheck)
 214                                         error("invalid spawn found");
 215         }
 216
 217         if (!spot)
 218         {
 219                 if(cvar("spawn_debug"))
 220                         GotoNextMap();
 221                 else
 222                 {
 223                         if(some_spawn_has_been_used)
 224                                 return world; // team can't spawn any more, because of actions of other team
 225                         else
 226                                 error("Cannot find a spawn point - please fix the map!");
 227                 }
 228         }
 229
 230         return spot;
 231 }
 232
 233 /*
 234 =============
 235 CheckPlayerModel
 236
 237 Checks if the argument string can be a valid playermodel.
 238 Returns a valid one in doubt.
 239 =============
 240 */
 241 string FallbackPlayerModel = "models/player/marine.zym";
 242 string CheckPlayerModel(string plyermodel) {
 243         if(strlen(plyermodel) < 4)
 244                 return FallbackPlayerModel;
 245         if( substring(plyermodel,0,14) != "models/player/")
 246                 return FallbackPlayerModel;
 247         else if(cvar("sv_servermodelsonly"))
 248         {
 249                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 250                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 251                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 252                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 253                         return FallbackPlayerModel;
 254                 if(!fexists(plyermodel))
 255                         return FallbackPlayerModel;
 256         }
 257         return plyermodel;
 258 }
 259
 260 /*
 261 =============
 262 Client_customizeentityforclient
 263
 264 LOD reduction
 265 =============
 266 */
 267 float Client_customizeentityforclient()
 268 {
 269 #ifdef ALLOW_VARIABLE_LOD
 270         // self: me
 271         // other: the player viewing me
 272         float distance;
 273         float f;
 274
 275         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 276                 return TRUE;
 277
 278         if(other.cvar_cl_playerdetailreduction <= 0)
 279         {
 280                 if(other.cvar_cl_playerdetailreduction <= -2)
 281                         self.modelindex = self.modelindex_lod2;
 282                 else if(other.cvar_cl_playerdetailreduction <= -1)
 283                         self.modelindex = self.modelindex_lod1;
 284                 else
 285                         self.modelindex = self.modelindex_lod0;
 286         }
 287         else
 288         {
 289                 distance = vlen(self.origin - other.origin);
 290                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 291                 if(f > 10000)
 292                         self.modelindex = self.modelindex_lod2;
 293                 else if(f > 5000)
 294                         self.modelindex = self.modelindex_lod1;
 295                 else
 296                         self.modelindex = self.modelindex_lod0;
 297         }
 298 #endif
 299
 300         return TRUE;
 301 }
 302
 303 void UpdatePlayerSounds();
 304 void setmodel_lod(entity e, string modelname)
 305 {
 306 #ifdef ALLOW_VARIABLE_LOD
 307         string s;
 308
 309         // FIXME: this only supports 3-letter extensions
 310         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 311         if(fexists(s))
 312         {
 313                 precache_model(s);
 314                 setmodel(e, s); // players have high precision
 315                 self.modelindex_lod1 = self.modelindex;
 316         }
 317         else
 318                 self.modelindex_lod1 = -1;
 319
 320         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 321         if(fexists(s))
 322         {
 323                 precache_model(s);
 324                 setmodel(e, s); // players have high precision
 325                 self.modelindex_lod2 = self.modelindex;
 326         }
 327         else
 328                 self.modelindex_lod2 = -1;
 329
 330         precache_model(modelname);
 331         setmodel(e, modelname); // players have high precision
 332         self.modelindex_lod0 = self.modelindex;
 333
 334         if(self.modelindex_lod1 < 0)
 335                 self.modelindex_lod1 = self.modelindex;
 336
 337         if(self.modelindex_lod2 < 0)
 338                 self.modelindex_lod2 = self.modelindex;
 339 #else
 340         precache_model(modelname);
 341         setmodel(e, modelname); // players have high precision
 342 #endif
 343         player_setupanimsformodel();
 344         UpdatePlayerSounds();
 345 }
 346
 347 /*
 348 =============
 349 PutObserverInServer
 350
 351 putting a client as observer in the server
 352 =============
 353 */
 354 void PutObserverInServer (void)
 355 {
 356         entity  spot;
 357         spot = SelectSpawnPoint (TRUE);
 358         if(!spot)
 359                 error("No spawnpoints for observers?!?\n");
 360         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 361
 362         if(clienttype(self) == CLIENTTYPE_REAL)
 363         {
 364                 msg_entity = self;
 365                 WriteByte(MSG_ONE, SVC_SETVIEW);
 366                 WriteEntity(MSG_ONE, self);
 367         }
 368
 369         DropAllRunes(self);
 370         kh_Key_DropAll(self, TRUE);
 371
 372         if(self.flagcarried)
 373                 DropFlag(self.flagcarried);
 374
 375         WaypointSprite_PlayerDead();
 376
 377         if(self.killcount != -666)
 378         {
 379                 if(g_lms)
 380                 {
 381                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 382                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 383                         else
 384                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 385                 }
 386                 else
 387                         bprint ("^4", self.netname, "^4 is spectating now\n");
 388         }
 389
 390         PlayerScore_Clear(self); // clear scores when needed
 391
 392         self.spectatortime = time;
 393
 394         self.classname = "observer";
 395         self.health = -666;
 396         self.takedamage = DAMAGE_NO;
 397         self.solid = SOLID_NOT;
 398         self.movetype = MOVETYPE_NOCLIP;
 399         self.flags = FL_CLIENT | FL_NOTARGET;
 400         self.armorvalue = 666;
 401         self.effects = 0;
 402         self.armorvalue = cvar("g_balance_armor_start");
 403         self.pauserotarmor_finished = 0;
 404         self.pauserothealth_finished = 0;
 405         self.pauseregen_finished = 0;
 406         self.damageforcescale = 0;
 407         self.death_time = 0;
 408         self.dead_frame = 0;
 409         self.alpha = 0;
 410         self.scale = 0;
 411         self.fade_time = 0;
 412         self.pain_frame = 0;
 413         self.pain_finished = 0;
 414         self.strength_finished = 0;
 415         self.invincible_finished = 0;
 416         self.pushltime = 0;
 417         self.think = SUB_Null;
 418         self.nextthink = 0;
 419         self.hook_time = 0;
 420         self.runes = 0;
 421         self.deadflag = DEAD_NO;
 422         self.angles = spot.angles;
 423         self.angles_z = 0;
 424         self.fixangle = TRUE;
 425         self.crouch = FALSE;
 426
 427         self.view_ofs = PL_VIEW_OFS;
 428         setorigin (self, spot.origin);
 429         setsize (self, '0 0 0', '0 0 0');
 430         self.oldorigin = self.origin;
 431         self.items = 0;
 432         self.model = "";
 433         self.modelindex = 0;
 434         self.weapon = 0;
 435         self.weaponmodel = "";
 436         self.weaponentity = world;
 437         self.killcount = -666;
 438         self.velocity = '0 0 0';
 439         self.avelocity = '0 0 0';
 440         self.punchangle = '0 0 0';
 441         self.punchvector = '0 0 0';
 442         self.oldvelocity = self.velocity;
 443         self.customizeentityforclient = Client_customizeentityforclient;
 444         self.viewzoom = 1;
 445         self.wantswelcomemessage = 1;
 446
 447         race_PreparePlayer();
 448
 449         if(g_arena)
 450         {
 451                 if(self.version_mismatch)
 452                 {
 453                         Spawnqueue_Unmark(self);
 454                         Spawnqueue_Remove(self);
 455                 }
 456                 else
 457                 {
 458                         Spawnqueue_Insert(self);
 459                 }
 460         }
 461         else if(g_lms)
 462         {
 463                 // Only if the player cannot play at all
 464                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 465                         self.frags = -666;
 466                 else
 467                         self.frags = -667;
 468         }
 469         else
 470                 self.frags = -666;
 471 }
 472
 473 float RestrictSkin(float s)
 474 {
 475         if(!teams_matter)
 476                 return s;
 477         if(s == 6)
 478                 return 6;
 479         return mod(s, 3);
 480 }
 481
 482 void FixPlayermodel()
 483 {
 484         local string defaultmodel;
 485         local float defaultskin;
 486         local vector m1, m2;
 487
 488         defaultmodel = "";
 489
 490         if(cvar("sv_defaultcharacter") == 1) {
 491                 defaultskin = 0;
 492
 493                 if(teams_matter)
 494                 {
 495                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 496                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 497                 }
 498
 499                 if(defaultmodel == "")
 500                 {
 501                         defaultmodel = cvar_string("sv_defaultplayermodel");
 502                         defaultskin = cvar("sv_defaultplayerskin");
 503                 }
 504         }
 505
 506         if(defaultmodel != "")
 507         {
 508                 if (defaultmodel != self.model)
 509                 {
 510                         m1 = self.mins;
 511                         m2 = self.maxs;
 512                         setmodel_lod (self, defaultmodel);
 513                         setsize (self, m1, m2);
 514                 }
 515
 516                 self.skin = defaultskin;
 517         } else {
 518                 if (self.playermodel != self.model)
 519                 {
 520                         self.playermodel = CheckPlayerModel(self.playermodel);
 521                         m1 = self.mins;
 522                         m2 = self.maxs;
 523                         setmodel_lod (self, self.playermodel);
 524                         setsize (self, m1, m2);
 525                 }
 526
 527                 self.skin = RestrictSkin(stof(self.playerskin));
 528         }
 529
 530         if(!teams_matter)
 531                 if(strlen(cvar_string("sv_defaultplayercolors")))
 532                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 533                                 setcolor(self, cvar("sv_defaultplayercolors"));
 534 }
 535
 536 /*
 537 =============
 538 PutClientInServer
 539
 540 Called when a client spawns in the server
 541 =============
 542 */
 543 //void() ctf_playerchanged;
 544 void PutClientInServer (void)
 545 {
 546         if(clienttype(self) == CLIENTTYPE_BOT)
 547         {
 548                 self.classname = "player";
 549         }
 550         else if(clienttype(self) == CLIENTTYPE_REAL)
 551         {
 552                 msg_entity = self;
 553                 WriteByte(MSG_ONE, SVC_SETVIEW);
 554                 WriteEntity(MSG_ONE, self);
 555         }
 556
 557         // player is dead and becomes observer
 558         // FIXME fix LMS scoring for new system
 559         if(g_lms)
 560         {
 561                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 562                         self.classname = "observer";
 563         }
 564
 565         if(g_arena)
 566         if(!self.spawned)
 567                 self.classname = "observer";
 568
 569         if(self.classname == "player") {
 570                 entity  spot;
 571
 572                 spot = SelectSpawnPoint (FALSE);
 573                 if(!spot)
 574                 {
 575                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 576                         return; // spawn failed
 577                 }
 578
 579                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 580
 581                 self.classname = "player";
 582                 self.iscreature = TRUE;
 583                 self.movetype = MOVETYPE_WALK;
 584                 self.solid = SOLID_SLIDEBOX;
 585                 self.flags = FL_CLIENT;
 586                 self.takedamage = DAMAGE_AIM;
 587                 if(g_minstagib)
 588                         self.effects = EF_FULLBRIGHT;
 589                 else
 590                         self.effects = 0;
 591                 self.air_finished = time + 12;
 592                 self.dmg = 2;
 593
 594                 self.ammo_shells = start_ammo_shells;
 595                 self.ammo_nails = start_ammo_nails;
 596                 self.ammo_rockets = start_ammo_rockets;
 597                 self.ammo_cells = start_ammo_cells;
 598                 self.health = start_health;
 599                 self.armorvalue = start_armorvalue;
 600                 self.items = start_items;
 601                 self.switchweapon = start_switchweapon;
 602                 self.cnt = start_switchweapon;
 603                 self.weapon = 0;
 604                 self.jump_interval = time;
 605
 606                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 607                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 608                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 609                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 610                 //extend the pause of rotting if client was reset at the beginning of the countdown
 611                 if(!cvar("sv_ready_restart_after_countdown") && time < restart_countdown) {
 612                         self.spawnshieldtime += RESTART_COUNTDOWN;
 613                         self.pauserotarmor_finished += RESTART_COUNTDOWN;
 614                         self.pauserothealth_finished += RESTART_COUNTDOWN;
 615                         self.pauseregen_finished += RESTART_COUNTDOWN;
 616                 }
 617                 self.damageforcescale = 2;
 618                 self.death_time = 0;
 619                 self.dead_frame = 0;
 620                 self.alpha = 0;
 621                 self.scale = 0;
 622                 self.fade_time = 0;
 623                 self.pain_frame = 0;
 624                 self.pain_finished = 0;
 625                 self.strength_finished = 0;
 626                 self.invincible_finished = 0;
 627                 self.pushltime = 0;
 628                 //self.speed_finished = 0;
 629                 //self.slowmo_finished = 0;
 630                 // players have no think function
 631                 self.think = SUB_Null;
 632                 self.nextthink = 0;
 633                 self.hook_time = 0;
 634
 635                 self.runes = 0;
 636
 637                 self.deadflag = DEAD_NO;
 638
 639                 self.angles = spot.angles;
 640
 641                 self.angles_z = 0; // never spawn tilted even if the spot says to
 642                 self.fixangle = TRUE; // turn this way immediately
 643                 self.velocity = '0 0 0';
 644                 self.avelocity = '0 0 0';
 645                 self.punchangle = '0 0 0';
 646                 self.punchvector = '0 0 0';
 647                 self.oldvelocity = self.velocity;
 648
 649                 self.viewzoom = 0.6;
 650                 self.has_zoomed = 0;
 651
 652                 self.customizeentityforclient = Client_customizeentityforclient;
 653
 654                 self.model = "";
 655                 FixPlayermodel();
 656
 657                 self.crouch = FALSE;
 658                 self.view_ofs = PL_VIEW_OFS;
 659                 setsize (self, PL_MIN, PL_MAX);
 660                 self.spawnorigin = spot.origin;
 661                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 662                 // don't reset back to last position, even if new position is stuck in solid
 663                 self.oldorigin = self.origin;
 664
 665                 if(g_arena)
 666                 {
 667                         Spawnqueue_Remove(self);
 668                         Spawnqueue_Mark(self);
 669                 }
 670
 671                 self.event_damage = PlayerDamage;
 672
 673                 self.bot_attack = TRUE;
 674
 675                 self.statdraintime = time + 5;
 676                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 677
 678                 if(self.killcount == -666) {
 679                         PlayerScore_Clear(self);
 680                         self.killcount = 0;
 681                         self.frags = 0;
 682                 }
 683
 684                 self.cnt = WEP_LASER;
 685                 self.nixnex_lastchange_id = -1;
 686
 687                 CL_SpawnWeaponentity();
 688                 self.alpha = default_player_alpha;
 689                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 690                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 691
 692                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 693                 self.lms_traveled_distance = 0;
 694                 self.speedrunning = FALSE;
 695
 696                 race_PreparePlayer();
 697
 698                 if(cvar("spawn_debug"))
 699                 {
 700                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 701                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 702                 }
 703
 704                 //stuffcmd(self, "chase_active 0");
 705                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 706
 707                 if (cvar("g_spawnsound"))
 708                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 709
 710                 if(g_assault) {
 711                         if(self.team == assault_attacker_team)
 712                                 centerprint(self, "You are attacking!\n");
 713                         else
 714                                 centerprint(self, "You are defending!\n");
 715                 }
 716
 717         } else if(self.classname == "observer") {
 718                 PutObserverInServer ();
 719         }
 720
 721         //if(g_ctf)
 722         //      ctf_playerchanged();
 723 }
 724
 725 /*
 726 =============
 727 SendCSQCInfo
 728
 729 Send whatever CSQC needs NOW and cannot wait for SendServerInfo to happen...
 730 =============
 731 */
 732 void SendCSQCInfo(void)
 733 {
 734         if(clienttype(self) != CLIENTTYPE_REAL)
 735                 return;
 736         msg_entity = self;
 737         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 738         WriteByte(MSG_ONE, TE_CSQC_INIT);
 739         WriteShort(MSG_ONE, CSQC_REVISION);
 740         WriteByte(MSG_ONE, maxclients);
 741 }
 742
 743 /*
 744 =============
 745 SetNewParms
 746 =============
 747 */
 748 void SetNewParms (void)
 749 {
 750         // initialize parms for a new player
 751         parm1 = -(86400 * 366);
 752 }
 753
 754 /*
 755 =============
 756 SetChangeParms
 757 =============
 758 */
 759 void SetChangeParms (void)
 760 {
 761         // save parms for level change
 762         parm1 = self.parm_idlesince - time;
 763 }
 764
 765 /*
 766 =============
 767 DecodeLevelParms
 768 =============
 769 */
 770 void DecodeLevelParms (void)
 771 {
 772         // load parms
 773         self.parm_idlesince = parm1;
 774         if(self.parm_idlesince == -(86400 * 366))
 775                 self.parm_idlesince = time;
 776 }
 777
 778 /*
 779 =============
 780 ClientKill
 781
 782 Called when a client types 'kill' in the console
 783 =============
 784 */
 785
 786 void ClientKill_Now_TeamChange()
 787 {
 788         if(self.killindicator_teamchange == -1)
 789         {
 790                 self.team = -1;
 791                 JoinBestTeam( self, FALSE, FALSE );
 792         }
 793         else
 794         {
 795                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 796         }
 797 }
 798
 799 void ClientKill_Now()
 800 {
 801         if(self.killindicator_teamchange)
 802                 ClientKill_Now_TeamChange();
 803
 804         // in any case:
 805         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 806
 807         if(self.killindicator)
 808         {
 809                 dprint("Cleaned up after a leaked kill indicator.\n");
 810                 remove(self.killindicator);
 811                 self.killindicator = world;
 812         }
 813 }
 814 void KillIndicator_Think()
 815 {
 816         if (!self.owner.modelindex)
 817         {
 818                 self.owner.killindicator = world;
 819                 remove(self);
 820                 return;
 821         }
 822
 823         if(self.cnt <= 0)
 824         {
 825                 self = self.owner;
 826                 ClientKill_Now(); // no oldself needed
 827                 return;
 828         }
 829         else
 830         {
 831                 if(self.cnt <= 10)
 832                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 833                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 834                 {
 835                         if(self.cnt <= 10)
 836                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 837                         if(self.owner.killindicator_teamchange)
 838                         {
 839                                 if(self.owner.killindicator_teamchange == -1)
 840                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 841                                 else
 842                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 843                         }
 844                         else
 845                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 846                 }
 847                 self.nextthink = time + 1;
 848                 self.cnt -= 1;
 849         }
 850 }
 851
 852 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 853 {
 854         float killtime;
 855         entity e;
 856         killtime = cvar("g_balance_kill_delay");
 857
 858         self.killindicator_teamchange = targetteam;
 859
 860         if(!self.killindicator)
 861         {
 862                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 863                 {
 864                         ClientKill_Now();
 865                 }
 866                 else
 867                 {
 868                         self.killindicator = spawn();
 869                         self.killindicator.owner = self;
 870                         self.killindicator.scale = 0.5;
 871                         setattachment(self.killindicator, self, "");
 872                         setorigin(self.killindicator, '0 0 52');
 873                         self.killindicator.think = KillIndicator_Think;
 874                         self.killindicator.nextthink = time + (self.lip) * 0.05;
 875                         self.killindicator.cnt = ceil(killtime);
 876                         self.killindicator.count = bound(0, ceil(killtime), 10);
 877                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 878
 879                         for(e = world; (e = find(e, classname, "body")) != world; )
 880                         {
 881                                 if(e.enemy != self)
 882                                         continue;
 883                                 e.killindicator = spawn();
 884                                 e.killindicator.owner = e;
 885                                 e.killindicator.scale = 0.5;
 886                                 setattachment(e.killindicator, e, "");
 887                                 setorigin(e.killindicator, '0 0 52');
 888                                 e.killindicator.think = KillIndicator_Think;
 889                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
 890                                 e.killindicator.cnt = ceil(killtime);
 891                         }
 892                         self.lip = 0;
 893                 }
 894         }
 895         if(self.killindicator)
 896         {
 897                 if(targetteam)
 898                         self.killindicator.colormod = TeamColor(targetteam);
 899                 else
 900                         self.killindicator.colormod = '0 0 0';
 901         }
 902 }
 903
 904 void ClientKill (void)
 905 {
 906         ClientKill_TeamChange(0);
 907 }
 908
 909 void DoTeamChange(float destteam)
 910 {
 911         float t, c0;
 912         if(!cvar("teamplay"))
 913         {
 914                 if(destteam >= 0)
 915                         SetPlayerColors(self, destteam);
 916                 return;
 917         }
 918         if(self.classname == "player")
 919         if(destteam == -1)
 920         {
 921                 CheckAllowedTeams(self);
 922                 t = FindSmallestTeam(self, TRUE);
 923                 switch(self.team)
 924                 {
 925                         case COLOR_TEAM1: c0 = c1; break;
 926                         case COLOR_TEAM2: c0 = c2; break;
 927                         case COLOR_TEAM3: c0 = c3; break;
 928                         case COLOR_TEAM4: c0 = c4; break;
 929                         default:          c0 = 999;
 930                 }
 931                 switch(t)
 932                 {
 933                         case 1:
 934                                 if(c0 > c1)
 935                                         destteam = COLOR_TEAM1;
 936                                 break;
 937                         case 2:
 938                                 if(c0 > c2)
 939                                         destteam = COLOR_TEAM2;
 940                                 break;
 941                         case 3:
 942                                 if(c0 > c3)
 943                                         destteam = COLOR_TEAM3;
 944                                 break;
 945                         case 4:
 946                                 if(c0 > c4)
 947                                         destteam = COLOR_TEAM4;
 948                                 break;
 949                 }
 950                 if(destteam == -1)
 951                         return;
 952         }
 953         if(destteam == self.team && !self.killindicator)
 954                 return;
 955         ClientKill_TeamChange(destteam);
 956 }
 957
 958 void FixClientCvars(entity e)
 959 {
 960         // send prediction settings to the client
 961         stuffcmd(e, "\nin_bindmap 0 0\n");
 962         /*
 963          * we no longer need to stuff this. Remove this comment block if you feel
 964          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 965         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
 966         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 967         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 968         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 969         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 970         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 971         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 972         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
 973         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 974         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 975         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 976         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 977         stuffcmd(e, "cl_movement_edgefriction 1\n");
 978          */
 979 }
 980
 981 /*
 982 =============
 983 ClientConnect
 984
 985 Called when a client connects to the server
 986 =============
 987 */
 988 //void ctf_clientconnect();
 989 string ColoredTeamName(float t);
 990 void DecodeLevelParms (void);
 991 //void dom_player_join_team(entity pl);
 992 void ClientConnect (void)
 993 {
 994         local string s;
 995         float wep;
 996
 997         if(self.flags & FL_CLIENT)
 998         {
 999                 print("Warning: ClientConnect, but already connected!\n");
1000                 return;
1001         }
1002
1003         if(Ban_IsClientBanned(self))
1004         {
1005                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
1006                 dropclient(self);
1007                 bprint(s);
1008                 return;
1009         }
1010
1011         DecodeLevelParms();
1012
1013         self.classname = "player_joining";
1014
1015         self.flags = self.flags | FL_CLIENT;
1016         self.version_nagtime = time + 10 + random() * 10;
1017
1018         if(player_count<0)
1019         {
1020                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1021                 player_count = 0;
1022         }
1023
1024         PlayerScore_Attach(self);
1025
1026         bot_clientconnect();
1027
1028         //if(g_domination)
1029         //      dom_player_join_team(self);
1030
1031         //JoinBestTeam(self, FALSE, FALSE);
1032
1033         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1034                 self.classname = "observer";
1035         } else {
1036                 self.classname = "player";
1037                 campaign_bots_may_start = 1;
1038         }
1039
1040         self.playerid = (playerid_last = playerid_last + 1);
1041         if(cvar("sv_eventlog"))
1042         {
1043                 if(clienttype(self) == CLIENTTYPE_REAL)
1044                         s = "player";
1045                 else
1046                         s = "bot";
1047                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
1048                 s = strcat(":team:", ftos(self.playerid), ":");
1049                 s = strcat(s, ftos(self.team));
1050                 GameLogEcho(s, FALSE);
1051         }
1052         self.netname_previous = strzone(self.netname);
1053
1054         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1055
1056         bprint ("^4",self.netname);
1057         bprint ("^4 connected");
1058
1059         if(g_domination || g_ctf)
1060         {
1061                 bprint(" and joined the ");
1062                 bprint(ColoredTeamName(self.team));
1063         }
1064
1065         bprint("\n");
1066
1067         self.welcomemessage_time = 0;
1068
1069         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1070         // TODO: is this being used for anything else than cd tracks?
1071         // Remember: SVC_CDTRACK exists. Maybe it should be used.
1072         //
1073         stuffcmd(self, "cl_particles_reloadeffects\n");
1074
1075         FixClientCvars(self);
1076
1077         // spawnfunc_waypoint sprites
1078         WaypointSprite_InitClient(self);
1079
1080         // Wazat's grappling hook
1081         SetGrappleHookBindings();
1082
1083         // get autoswitch state from player when he toggles it
1084         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1085
1086         // get version info from player
1087         stuffcmd(self, "cmd clientversion $gameversion\n");
1088
1089         // send all weapon info strings
1090         stuffcmd(self, "register_bestweapon clear\n"); // clear the Quake stuff
1091         wep = WEP_FIRST;
1092         while (wep <= WEP_LAST)
1093         {
1094                 weapon_action(wep, WR_REGISTER);
1095                 wep = wep + 1;
1096         }
1097
1098         // get other cvars from player
1099         GetCvars(0);
1100
1101         // set cvar for team scoreboard
1102         if (teams_matter)
1103         {
1104                 local float t;
1105                 t = cvar("teamplay");
1106                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1107                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1108         }
1109         else
1110                 stuffcmd(self, "set teamplay 0\n");
1111
1112         // notify about available teams
1113         if(teamplay)
1114         {
1115                 CheckAllowedTeams(self);
1116                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1117                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1118         }
1119         else
1120                 stuffcmd(self, "set _teams_available 0\n");
1121
1122         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1123
1124         if(g_arena)
1125         {
1126                 self.classname = "observer";
1127                 Spawnqueue_Insert(self);
1128         }
1129         /*else if(g_ctf)
1130         {
1131                 ctf_clientconnect();
1132         }*/
1133
1134         if(entcs_start)
1135                 attach_entcs();
1136
1137         bot_relinkplayerlist();
1138
1139         self.spectatortime = time;
1140         if(blockSpectators)
1141         {
1142                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1143         }
1144
1145         self.jointime = time;
1146         self.allowedTimeouts = cvar("sv_timeout_number");
1147
1148         if(clienttype(self) == CLIENTTYPE_REAL)
1149         {
1150                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1151                 SendCSQCInfo();
1152                 msg_entity = self;
1153                 if(mapvote_initialized && !cvar("g_maplist_textonly"))
1154                 {
1155                         MapVote_SendData(MSG_ONE);
1156                         MapVote_UpdateData(MSG_ONE);
1157                 }
1158                 ScoreInfo_Write(MSG_ONE);
1159         }
1160
1161         if(g_lms)
1162         {
1163                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1164                 {
1165                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1166                         self.frags = -666; // FIXME do we still need this?
1167                 }
1168         }
1169 }
1170
1171 /*
1172 =============
1173 ClientDisconnect
1174
1175 Called when a client disconnects from the server
1176 =============
1177 */
1178 void(entity e) DropFlag;
1179 .entity chatbubbleentity;
1180 .entity teambubbleentity;
1181 //void() ctf_clientdisconnect;
1182 void ClientDisconnect (void)
1183 {
1184         float save;
1185
1186         if not(self.flags & FL_CLIENT)
1187         {
1188                 print("Warning: ClientDisconnect without ClientConnect\n");
1189                 return;
1190         }
1191
1192         bot_clientdisconnect();
1193
1194         if(entcs_start)
1195                 detach_entcs();
1196
1197         if(cvar("sv_eventlog"))
1198                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
1199         bprint ("^4",self.netname);
1200         bprint ("^4 disconnected\n");
1201
1202         if (self.chatbubbleentity)
1203         {
1204                 remove (self.chatbubbleentity);
1205                 self.chatbubbleentity = world;
1206         }
1207
1208         if (self.teambubbleentity)
1209         {
1210                 remove (self.teambubbleentity);
1211                 self.teambubbleentity = world;
1212         }
1213
1214         if (self.killindicator)
1215         {
1216                 remove (self.killindicator);
1217                 self.killindicator = world;
1218         }
1219
1220         WaypointSprite_PlayerGone();
1221
1222         DropAllRunes(self);
1223         kh_Key_DropAll(self, TRUE);
1224
1225         if(self.flagcarried)
1226                 DropFlag(self.flagcarried);
1227
1228         save = self.flags;
1229         self.flags = self.flags - (self.flags & FL_CLIENT);
1230         bot_relinkplayerlist();
1231         self.flags = save;
1232
1233         // remove laserdot
1234         if(self.weaponentity)
1235                 if(self.weaponentity.lasertarget)
1236                         remove(self.weaponentity.lasertarget);
1237
1238         if(g_arena)
1239         {
1240                 Spawnqueue_Unmark(self);
1241                 Spawnqueue_Remove(self);
1242         }
1243         /*if(g_ctf)
1244         {
1245                 ctf_clientdisconnect();
1246         }
1247         */
1248
1249         PlayerScore_Detach(self);
1250
1251         if(self.netname_previous)
1252                 strunzone(self.netname_previous);
1253
1254         ClearPlayerSounds();
1255
1256         // free cvars
1257         GetCvars(-1);
1258         self.playerid = 0;
1259 }
1260
1261 .float BUTTON_CHAT;
1262 void ChatBubbleThink()
1263 {
1264         self.nextthink = time;
1265         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1266         {
1267                 self.owner.chatbubbleentity = world;
1268                 remove(self);
1269                 return;
1270         }
1271         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1272         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1273                 self.model = self.mdl;
1274         else
1275                 self.model = "";
1276 };
1277
1278 void UpdateChatBubble()
1279 {
1280         if (!self.modelindex)
1281                 return;
1282         // spawn a chatbubble entity if needed
1283         if (!self.chatbubbleentity)
1284         {
1285                 self.chatbubbleentity = spawn();
1286                 self.chatbubbleentity.owner = self;
1287                 self.chatbubbleentity.exteriormodeltoclient = self;
1288                 self.chatbubbleentity.think = ChatBubbleThink;
1289                 self.chatbubbleentity.nextthink = time;
1290                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1291                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1292                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1293                 self.chatbubbleentity.model = "";
1294                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1295         }
1296 }
1297
1298
1299 void TeamBubbleThink()
1300 {
1301         self.nextthink = time;
1302         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1303         {
1304                 self.owner.teambubbleentity = world;
1305                 remove(self);
1306                 return;
1307         }
1308 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1309         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1310                 self.model = "";
1311         else
1312                 self.model = self.mdl;
1313
1314 };
1315
1316 float TeamBubble_customizeentityforclient()
1317 {
1318         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1319 }
1320
1321 void UpdateTeamBubble()
1322 {
1323         if (!self.modelindex || !cvar("teamplay"))
1324                 return;
1325         // spawn a teambubble entity if needed
1326         if (!self.teambubbleentity && cvar("teamplay"))
1327         {
1328                 self.teambubbleentity = spawn();
1329                 self.teambubbleentity.owner = self;
1330                 self.teambubbleentity.exteriormodeltoclient = self;
1331                 self.teambubbleentity.think = TeamBubbleThink;
1332                 self.teambubbleentity.nextthink = time;
1333                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1334 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1335                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1336                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1337                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1338                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1339                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1340                 self.teambubbleentity.effects = EF_LOWPRECISION;
1341         }
1342 }
1343
1344 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1345 // added to the model skins
1346 /*void UpdateColorModHack()
1347 {
1348         local float c;
1349         c = self.clientcolors & 15;
1350         // LordHavoc: only bothering to support white, green, red, yellow, blue
1351              if (teamplay == 0) self.colormod = '0 0 0';
1352         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1353         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1354         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1355         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1356         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1357         else self.colormod = '1 1 1';
1358 };*/
1359
1360 void respawn(void)
1361 {
1362         CopyBody(1);
1363         self.effects |= EF_NODRAW; // prevent another CopyBody
1364         PutClientInServer();
1365 }
1366
1367 /**
1368  * When sv_timeout is used this function returs strings like
1369  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1370  * Called by centerprint functions
1371  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1372  */
1373 string getTimeoutText(float addOneSecond) {
1374         if (!cvar("sv_timeout") || !timeoutStatus)
1375                 return "";
1376
1377         local string retStr;
1378         if (timeoutStatus == 1) {
1379                 if (addOneSecond == 1) {
1380                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1381                 }
1382                 else {
1383                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1384                 }
1385                 return retStr;
1386         }
1387         else if (timeoutStatus == 2) {
1388                 if (addOneSecond) {
1389                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1390                         //don't show messages like "Timeout ends in 0 seconds"...
1391                         if ((remainingTimeoutTime + 1) > 0)
1392                                 return retStr;
1393                         else
1394                                 return "";
1395                 }
1396                 else {
1397                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1398                         //don't show messages like "Timeout ends in 0 seconds"...
1399                         if (remainingTimeoutTime > 0)
1400                                 return retStr;
1401                         else
1402                                 return "";
1403                 }
1404         }
1405         else return "";
1406 }
1407
1408 void player_powerups (void)
1409 {
1410         if (g_minstagib)
1411         {
1412                 if (self.items & IT_STRENGTH)
1413                 {
1414                         if (time > self.strength_finished)
1415                         {
1416                                 if (g_minstagib_invis_alpha > 0)
1417                                 {
1418                                         self.alpha = default_player_alpha;
1419                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1420                                         self.effects = self.effects | EF_FULLBRIGHT;
1421                                 }
1422                                 else
1423                                 {
1424                                         self.effects -= self.effects & EF_NODRAW;
1425                                 }
1426                                 self.items = self.items - (self.items & IT_STRENGTH);
1427                                 sprint(self, "^3Invisibility has worn off\n");
1428                         }
1429                 }
1430                 else
1431                 {
1432                         if (time < self.strength_finished)
1433                         {
1434                                 if (g_minstagib_invis_alpha > 0)
1435                                 {
1436                                         self.alpha = g_minstagib_invis_alpha;
1437                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1438                                         self.effects -= self.effects & EF_FULLBRIGHT;
1439                                 }
1440                                 else
1441                                 {
1442                                         self.effects = self.effects | EF_NODRAW;
1443                                 }
1444                                 self.items = self.items | IT_STRENGTH;
1445                                 sprint(self, "^3You are invisible\n");
1446                         }
1447                 }
1448
1449                 if (self.items & IT_INVINCIBLE)
1450                 {
1451                         if (time > self.invincible_finished)
1452                         {
1453                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1454                                 sprint(self, "^3Speed has worn off\n");
1455                         }
1456                 }
1457                 else
1458                 {
1459                         if (time < self.invincible_finished)
1460                         {
1461                                 self.items = self.items | IT_INVINCIBLE;
1462                                 sprint(self, "^3You are on speed\n");
1463                         }
1464                 }
1465                 return;
1466         }
1467
1468         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1469         if (self.items & IT_STRENGTH)
1470         {
1471                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1472                 if (time > self.strength_finished)
1473                 {
1474                         self.items = self.items - (self.items & IT_STRENGTH);
1475                         sprint(self, "^3Strength has worn off\n");
1476                 }
1477         }
1478         else
1479         {
1480                 if (time < self.strength_finished)
1481                 {
1482                         self.items = self.items | IT_STRENGTH;
1483                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1484                 }
1485         }
1486         if (self.items & IT_INVINCIBLE)
1487         {
1488                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1489                 if (time > self.invincible_finished)
1490                 {
1491                         self.items = self.items - (self.items & IT_INVINCIBLE);
1492                         sprint(self, "^3Shield has worn off\n");
1493                 }
1494         }
1495         else
1496         {
1497                 if (time < self.invincible_finished)
1498                 {
1499                         self.items = self.items | IT_INVINCIBLE;
1500                         sprint(self, "^3Shield surrounds you\n");
1501                 }
1502         }
1503
1504         if (cvar("g_fullbrightplayers"))
1505                 self.effects = self.effects | EF_FULLBRIGHT;
1506
1507         // midair gamemode: damage only while in the air
1508         // if in midair mode, being on ground grants temporary invulnerability
1509         // (this is so that multishot weapon don't clear the ground flag on the
1510         // first damage in the frame, leaving the player vulnerable to the
1511         // remaining hits in the same frame)
1512         if (self.flags & FL_ONGROUND)
1513         if (g_midair)
1514                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1515
1516         if (time < self.spawnshieldtime)
1517                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1518 }
1519
1520 float CalcRegen(float current, float stable, float regenfactor)
1521 {
1522         if(current > stable)
1523                 return current;
1524         else if(current > stable - 0.25) // when close enough, "snap"
1525                 return stable;
1526         else
1527                 return min(stable, current + (stable - current) * regenfactor * frametime);
1528 }
1529
1530 void player_regen (void)
1531 {
1532         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1533         maxh = cvar("g_balance_health_stable");
1534         maxa = cvar("g_balance_armor_stable");
1535         limith = cvar("g_balance_health_limit");
1536         limita = cvar("g_balance_armor_limit");
1537
1538         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1539                 return;
1540
1541         max_mod = regen_mod = rot_mod = limit_mod = 1;
1542
1543         if (self.runes & RUNE_REGEN)
1544         {
1545                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1546                 {
1547                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1548                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1549                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1550                 }
1551                 else
1552                 {
1553                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1554                         max_mod = cvar("g_balance_rune_regen_hpmod");
1555                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1556                 }
1557         }
1558         else if (self.runes & CURSE_VENOM)
1559         {
1560                 max_mod = cvar("g_balance_curse_venom_hpmod");
1561                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1562                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1563                 else
1564                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1565                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1566                 //if (!self.runes & RUNE_REGEN)
1567                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1568         }
1569         maxh = maxh * max_mod;
1570         //maxa = maxa * max_mod;
1571         limith = limith * limit_mod;
1572         limita = limita * limit_mod;
1573
1574         if (self.armorvalue > maxa)
1575         {
1576                 if (time > self.pauserotarmor_finished)
1577                 {
1578                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1579                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1580                 }
1581         }
1582         else if (self.armorvalue < maxa)
1583         {
1584                 if (time > self.pauseregen_finished)
1585                 {
1586                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1587                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1588                 }
1589         }
1590         if (self.health > maxh)
1591         {
1592                 if (time > self.pauserothealth_finished)
1593                 {
1594                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1595                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1596                 }
1597         }
1598         else if (self.health < maxh)
1599         {
1600                 if (time > self.pauseregen_finished)
1601                 {
1602                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1603                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1604                 }
1605         }
1606
1607         if (self.health > limith)
1608                 self.health = limith;
1609         if (self.armorvalue > limita)
1610                 self.armorvalue = limita;
1611
1612         // if player rotted to death...  die!
1613         if(self.health < 1)
1614                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1615 }
1616
1617 /*
1618 ======================
1619 spectate mode routines
1620 ======================
1621 */
1622 void SpectateCopy(entity spectatee) {
1623         self.armortype = spectatee.armortype;
1624         self.armorvalue = spectatee.armorvalue;
1625         self.currentammo = spectatee.currentammo;
1626         self.effects = spectatee.effects;
1627         self.health = spectatee.health;
1628         self.impulse = 0;
1629         self.items = spectatee.items;
1630         self.punchangle = spectatee.punchangle;
1631         self.view_ofs = spectatee.view_ofs;
1632         self.v_angle = spectatee.v_angle;
1633         self.viewzoom = spectatee.viewzoom;
1634         self.velocity = spectatee.velocity;
1635         self.dmg_take = spectatee.dmg_take;
1636         self.dmg_save = spectatee.dmg_save;
1637         self.dmg_inflictor = spectatee.dmg_inflictor;
1638         self.angles = spectatee.v_angle;
1639         self.fixangle = TRUE;
1640         setorigin(self, spectatee.origin);
1641         setsize(self, spectatee.mins, spectatee.maxs);
1642 }
1643
1644 float SpectateUpdate() {
1645         if(!self.enemy)
1646                 return 0;
1647
1648         if (self == self.enemy)
1649                 return 0;
1650
1651         if(self.enemy.flags & FL_NOTARGET)
1652                 return 0;
1653
1654         SpectateCopy(self.enemy);
1655
1656         return 1;
1657 }
1658
1659 float SpectateNext() {
1660         other = find(self.enemy, classname, "player");
1661         if (!other) {
1662                 other = find(other, classname, "player");
1663         }
1664         if (other) {
1665                 self.enemy = other;
1666         }
1667         if(self.enemy.classname == "player") {
1668                 msg_entity = self;
1669                 WriteByte(MSG_ONE, SVC_SETVIEW);
1670                 WriteEntity(MSG_ONE, self.enemy);
1671                 self.wantswelcomemessage = 1;
1672                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1673                 if(!SpectateUpdate())
1674                         PutObserverInServer();
1675                 return 1;
1676         } else {
1677                 return 0;
1678         }
1679 }
1680
1681 /*
1682 =============
1683 ShowRespawnCountdown()
1684
1685 Update a respawn countdown display.
1686 =============
1687 */
1688 void ShowRespawnCountdown()
1689 {
1690         float number;
1691         if(self.deadflag == DEAD_NO) // just respawned?
1692                 return;
1693         else
1694         {
1695                 number = ceil(self.death_time - time);
1696                 if(number <= 0)
1697                         return;
1698                 if(number <= self.respawn_countdown)
1699                 {
1700                         self.respawn_countdown = number - 1;
1701                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1702                                 announce(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1703                 }
1704         }
1705 }
1706
1707 void LeaveSpectatorMode()
1708 {
1709         if(isJoinAllowed()) {
1710                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1711                         self.classname = "player";
1712                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1713                                 JoinBestTeam(self, FALSE, TRUE);
1714                         if(cvar("g_campaign"))
1715                                 campaign_bots_may_start = 1;
1716                         PutClientInServer();
1717                         if(!(self.flags & FL_NOTARGET))
1718                                 bprint ("^4", self.netname, "^4 is playing now\n");
1719                         centerprint(self,"");
1720                         return;
1721                 } else {
1722                         stuffcmd(self,"menu_showteamselect\n");
1723                         return;
1724                 }
1725         }
1726         else {
1727                 //player may not join because of g_maxplayers is set
1728                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1729         }
1730 }
1731
1732 /**
1733  * Determines whether the player is allowed to join. This depends on cvar
1734  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1735  * it checks whether the number of currently playing players exceeds g_maxplayers.
1736  * @return bool TRUE if the player is allowed to join, false otherwise
1737  */
1738 float isJoinAllowed() {
1739         if (!cvar("g_maxplayers"))
1740                 return TRUE;
1741
1742         local entity e;
1743         local float currentlyPlaying;
1744         FOR_EACH_REALPLAYER(e) {
1745                 if(e.classname == "player")
1746                         currentlyPlaying += 1;
1747         }
1748         if(currentlyPlaying < cvar("g_maxplayers"))
1749                 return TRUE;
1750
1751         return FALSE;
1752 }
1753
1754 /**
1755  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1756  * g_maxplayers_spectator_blocktime seconds
1757  */
1758 void checkSpectatorBlock() {
1759         if(self.classname == "spectator" || self.classname == "observer") {
1760                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1761                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1762                         dropclient(self);
1763                 }
1764         }
1765 }
1766
1767 float vercmp_recursive(string v1, string v2)
1768 {
1769         float dot1, dot2;
1770         string s1, s2;
1771         float r;
1772
1773         dot1 = strstrofs(v1, ".", 0);
1774         dot2 = strstrofs(v2, ".", 0);
1775         if(dot1 == -1)
1776                 s1 = v1;
1777         else
1778                 s1 = substring(v1, 0, dot1);
1779         if(dot2 == -1)
1780                 s2 = v2;
1781         else
1782                 s2 = substring(v2, 0, dot2);
1783
1784         r = stof(s1) - stof(s2);
1785         if(r != 0)
1786                 return r;
1787
1788         r = strcasecmp(s1, s2);
1789         if(r != 0)
1790                 return r;
1791
1792         if(dot1 == -1)
1793                 if(dot2 == -1)
1794                         return 0;
1795                 else
1796                         return -1;
1797         else
1798                 if(dot2 == -1)
1799                         return 1;
1800                 else
1801                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1802 }
1803
1804 float vercmp(string v1, string v2)
1805 {
1806         if(strcasecmp(v1, v2) == 0) // early out check
1807                 return 0;
1808         return vercmp_recursive(v1, v2);
1809 }
1810
1811 void ObserverThink()
1812 {
1813         if (self.flags & FL_JUMPRELEASED) {
1814                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1815                         self.welcomemessage_time = 0;
1816                         self.flags = self.flags - FL_JUMPRELEASED;
1817                         LeaveSpectatorMode();
1818                         return;
1819                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
1820                         self.welcomemessage_time = 0;
1821                         self.flags = self.flags - FL_JUMPRELEASED;
1822                         if(SpectateNext() == 1) {
1823                                 self.classname = "spectator";
1824                         }
1825                 }
1826         } else {
1827                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
1828                         self.flags = self.flags | FL_JUMPRELEASED;
1829                 }
1830         }
1831         if(self.BUTTON_ZOOM)
1832                 self.wantswelcomemessage = 0;
1833         if(self.wantswelcomemessage)
1834                 PrintWelcomeMessage(self);
1835 }
1836
1837 void SpectatorThink()
1838 {
1839         if (self.flags & FL_JUMPRELEASED) {
1840                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1841                         self.welcomemessage_time = 0;
1842                         self.flags = self.flags - FL_JUMPRELEASED;
1843                         LeaveSpectatorMode();
1844                         return;
1845                 } else if(self.BUTTON_ATCK) {
1846                         self.welcomemessage_time = 0;
1847                         self.flags = self.flags - FL_JUMPRELEASED;
1848                         if(SpectateNext() == 1) {
1849                                 self.classname = "spectator";
1850                         } else {
1851                                 self.classname = "observer";
1852                                 PutClientInServer();
1853                         }
1854                 } else if (self.BUTTON_ATCK2) {
1855                         self.welcomemessage_time = 0;
1856                         self.flags = self.flags - FL_JUMPRELEASED;
1857                         self.classname = "observer";
1858                         PutClientInServer();
1859                 } else {
1860                         if(!SpectateUpdate())
1861                                 PutObserverInServer();
1862                 }
1863         } else {
1864                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
1865                         self.flags = self.flags | FL_JUMPRELEASED;
1866                 }
1867         }
1868         if(self.BUTTON_ZOOM)
1869                 self.wantswelcomemessage = 0;
1870         if(self.wantswelcomemessage)
1871                 PrintWelcomeMessage(self);
1872         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1873 }
1874
1875 /*
1876 =============
1877 PlayerPreThink
1878
1879 Called every frame for each client before the physics are run
1880 =============
1881 */
1882 void() ctf_setstatus;
1883 .float vote_nagtime;
1884 void PlayerPreThink (void)
1885 {
1886         if(blockSpectators)
1887                 checkSpectatorBlock();
1888
1889         if(self.netname_previous != self.netname)
1890         {
1891                 if(cvar("sv_eventlog"))
1892                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname), TRUE);
1893                 if(self.netname_previous)
1894                         strunzone(self.netname_previous);
1895                 self.netname_previous = strzone(self.netname);
1896         }
1897
1898         // version nagging
1899         if(self.version_nagtime)
1900                 if(self.cvar_g_nexuizversion)
1901                         if(time > self.version_nagtime)
1902                         {
1903                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1904                                 {
1905                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
1906                                         {
1907                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1908                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1909                                         }
1910                                         else
1911                                         {
1912                                                 float r;
1913                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
1914                                                 if(r < 0)
1915                                                 {
1916                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
1917                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
1918                                                 }
1919                                                 else if(r > 0)
1920                                                 {
1921                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1922                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1923                                                 }
1924                                         }
1925                                 }
1926                                 self.version_nagtime = 0;
1927                         }
1928
1929         // vote nagging
1930         if(self.cvar_scr_centertime)
1931                 if(time > self.vote_nagtime)
1932                 {
1933                         VoteNag();
1934                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1935                 }
1936
1937         // GOD MODE info
1938         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
1939         {
1940                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
1941                 self.max_armorvalue = 0;
1942         }
1943
1944         if(frametime)
1945                 antilag_record(self);
1946
1947         if(self.classname == "player") {
1948 //              if(self.netname == "Wazat")
1949 //                      bprint(self.classname, "\n");
1950
1951                 CheckRules_Player();
1952
1953                 if(self.BUTTON_INFO)
1954                         PrintWelcomeMessage(self);
1955
1956                 if(g_lms || !cvar("sv_spectate"))
1957                 if((time - self.jointime) <= cvar("welcome_message_time"))
1958                         PrintWelcomeMessage(self);
1959
1960                 if (intermission_running)
1961                 {
1962                         IntermissionThink ();   // otherwise a button could be missed between
1963                         return;                                 // the think tics
1964                 }
1965
1966                 if(self.teleport_time)
1967                 if(time > self.teleport_time)
1968                 {
1969                         self.teleport_time = 0;
1970                         self.effects = self.effects - (self.effects & EF_NODRAW);
1971                         if(self.weaponentity)
1972                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
1973                 }
1974
1975                 Nixnex_GiveCurrentWeapon();
1976
1977                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
1978                         UpdateSelectedPlayer();
1979
1980                 //don't allow the player to turn around while game is paused!
1981                 if(timeoutStatus == 2) {
1982                         self.v_angle = self.lastV_angle;
1983                         self.angles = self.lastV_angle;
1984                         self.fixangle = TRUE;
1985                 }
1986
1987                 if (self.deadflag != DEAD_NO)
1988                 {
1989                         float button_pressed, force_respawn;
1990                         player_anim();
1991                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
1992                         force_respawn = (g_lms || cvar("g_forced_respawn"));
1993                         if (self.deadflag == DEAD_DYING)
1994                         {
1995                                 if(force_respawn)
1996                                         self.deadflag = DEAD_RESPAWNING;
1997                                 else if(!button_pressed)
1998                                         self.deadflag = DEAD_DEAD;
1999                         }
2000                         else if (self.deadflag == DEAD_DEAD)
2001                         {
2002                                 if(button_pressed)
2003                                         self.deadflag = DEAD_RESPAWNABLE;
2004                         }
2005                         else if (self.deadflag == DEAD_RESPAWNABLE)
2006                         {
2007                                 if(!button_pressed)
2008                                         self.deadflag = DEAD_RESPAWNING;
2009                         }
2010                         else if (self.deadflag == DEAD_RESPAWNING)
2011                         {
2012                                 if(time > self.death_time)
2013                                 {
2014                                         self.death_time = time + 1; // only retry once a second
2015                                         respawn();
2016                                 }
2017                         }
2018                         ShowRespawnCountdown();
2019                         return;
2020                 }
2021
2022                 if((g_race || g_lms) && !self.deadflag && cvar("g_lms_campcheck_interval"))
2023                 {
2024                         vector dist;
2025
2026                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2027                         dist = self.oldorigin - self.origin;
2028                         dist_z = 0;
2029                         self.lms_traveled_distance += fabs(vlen(dist));
2030
2031                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
2032                         {
2033                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2034                                 self.lms_traveled_distance = 0;
2035                         }
2036
2037                         if(time > self.lms_nextcheck)
2038                         {
2039                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2040                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2041                                 {
2042                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2043                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2044                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2045                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2046                                 }
2047                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2048                                 self.lms_traveled_distance = 0;
2049                         }
2050                 }
2051
2052                 if (self.BUTTON_CROUCH && !self.hook.state)
2053                 {
2054                         if (!self.crouch)
2055                         {
2056                                 self.crouch = TRUE;
2057                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2058                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2059                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
2060                         }
2061                 }
2062                 else
2063                 {
2064                         if (self.crouch)
2065                         {
2066                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2067                                 if (!trace_startsolid)
2068                                 {
2069                                         self.crouch = FALSE;
2070                                         self.view_ofs = PL_VIEW_OFS;
2071                                         setsize (self, PL_MIN, PL_MAX);
2072                                 }
2073                         }
2074                 }
2075
2076                 FixPlayermodel();
2077
2078                 GrapplingHookFrame();
2079
2080                 W_WeaponFrame();
2081
2082                 {
2083                         float zoomfactor, zoomspeed, zoomdir;
2084                         zoomfactor = self.cvar_cl_zoomfactor;
2085                         if(zoomfactor < 1 || zoomfactor > 16)
2086                                 zoomfactor = 2.5;
2087                         zoomspeed = self.cvar_cl_zoomspeed;
2088                         if(zoomspeed >= 0) // < 0 is instant zoom
2089                                 if(zoomspeed < 0.5 || zoomspeed > 16)
2090                                         zoomspeed = 3.5;
2091
2092                         zoomdir = self.BUTTON_ZOOM;
2093                         if(self.BUTTON_ATCK2)
2094                                 if(self.weapon == WEP_NEX)
2095                                         if(!g_minstagib)
2096                                                 zoomdir = 1;
2097
2098                         if(zoomdir)
2099                                 self.has_zoomed = 1;
2100
2101                         if(self.has_zoomed)
2102                         {
2103                                 if(zoomspeed <= 0) // instant zoom
2104                                 {
2105                                         if(zoomdir)
2106                                                 self.viewzoom = 1 / zoomfactor;
2107                                         else
2108                                                 self.viewzoom = 1;
2109                                 }
2110                                 else
2111                                 {
2112                                         // geometric zoom would be:
2113                                         //   self.viewzoom = bound(1 / zoomfactor, self.viewzoom * pow(zoomfactor, (zoomdir ? -1 : 1) * frametime * zoomspeed), 1);
2114                                         // however, testing showed that arithmetic/harmonic zoom works better
2115                                         if(zoomdir)
2116                                                 // self.viewzoom = 1 / bound(1, 1 / self.viewzoom + (zoomdir ? 1 : -1) * frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2117                                                 // zoom in = arithmetic: 1x, 2x, 3x, 4x, ..., 8x
2118                                                 self.viewzoom = 1 / bound(1, 1 / self.viewzoom + frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2119                                         else
2120                                                 // self.viewzoom = bound(1 / zoomfactor, self.viewzoom + (zoomdir ? -1 : 1) * frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2121                                                 // zoom out = harmonic: 8/1x, 8/2x, 8/3x, 8/4x, ..., 8/8x
2122                                                 self.viewzoom = bound(1 / zoomfactor, self.viewzoom + frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2123                                 }
2124                         }
2125                         else
2126                                 self.viewzoom = min(1, self.viewzoom + frametime); // spawn zoom-in
2127                 }
2128
2129                 player_powerups();
2130                 player_regen();
2131                 player_anim();
2132
2133                 if (g_minstagib)
2134                         minstagib_ammocheck();
2135
2136                 ctf_setstatus();
2137                 kh_setstatus();
2138
2139                 //self.angles_y=self.v_angle_y + 90;   // temp
2140
2141                 //if (TetrisPreFrame()) return;
2142         } else if(gameover) {
2143                 if (intermission_running)
2144                         IntermissionThink ();   // otherwise a button could be missed between
2145                 return;
2146         } else if(self.classname == "observer") {
2147                 ObserverThink();
2148         } else if(self.classname == "spectator") {
2149                 SpectatorThink();
2150         }
2151 }
2152
2153
2154 /*
2155 =============
2156 PlayerPostThink
2157
2158 Called every frame for each client after the physics are run
2159 =============
2160 */
2161 .float idlekick_lasttimeleft;
2162 void PlayerPostThink (void)
2163 {
2164         // Savage: Check for nameless players
2165         if (strlen(self.netname) < 1) {
2166                 self.netname = "Player";
2167                 stuffcmd(self, "seta _cl_name Player\n");
2168         }
2169
2170         if(sv_maxidle)
2171         {
2172                 float timeleft;
2173                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2174                 if(timeleft <= 0)
2175                 {
2176                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2177                         announce(self, "announcer/robotic/terminated.ogg");
2178                         dropclient(self);
2179                         return;
2180                 }
2181                 else if(timeleft <= 10)
2182                 {
2183                         if(timeleft != self.idlekick_lasttimeleft)
2184                         {
2185                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2186                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".ogg"));
2187                         }
2188                 }
2189                 else
2190                 {
2191                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2192                 }
2193                 self.idlekick_lasttimeleft = timeleft;
2194         }
2195
2196         if(self.classname == "player") {
2197                 CheckRules_Player();
2198                 UpdateChatBubble();
2199                 UpdateTeamBubble();
2200                 if (self.impulse)
2201                         ImpulseCommands();
2202                 if (intermission_running)
2203                         return;         // intermission or finale
2204
2205                 //PrintWelcomeMessage(self);
2206                 //if (TetrisPostFrame()) return;
2207
2208                 // restart countdown
2209                 if (restart_countdown) {
2210                         if(time < restart_countdown) {
2211                                 if (!cvar("sv_ready_restart_after_countdown"))
2212                                 {
2213                                         self.movetype = MOVETYPE_NONE;
2214                                         self.velocity = '0 0 0';
2215                                         self.avelocity = '0 0 0';
2216                                         self.movement = '0 0 0';
2217                                 }
2218                         }
2219                         else
2220                         {
2221                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2222                                 if (!cvar("sv_ready_restart_after_countdown"))
2223                                 {
2224                                         if(self.movetype == MOVETYPE_NONE)
2225                                         {
2226                                                 self.movetype = MOVETYPE_WALK;
2227                                         }
2228                                 }
2229                         }
2230                 }
2231
2232         } else if (self.classname == "observer") {
2233                 //do nothing
2234         } else if (self.classname == "spectator") {
2235                 //do nothing
2236         }
2237
2238         /*
2239         float i;
2240         for(i = 0; i < 1000; ++i)
2241         {
2242                 vector end;
2243                 end = self.origin + '0 0 1024' + 512 * randomvec();
2244                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2245                 if(trace_fraction < 1)
2246                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2247                 {
2248                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2249                         break;
2250                 }
2251         }
2252         */
2253
2254         Arena_Warmup();
2255 }