data/qcsrc/server/cl_client.qc

   1 // let's abuse an existing field
   2 #define SPAWNPOINT_SCORE frags
   3
   4 .float wantswelcomemessage;
   5 .string netname_previous;
   6
   7 void spawnfunc_info_player_survivor (void)
   8 {
   9         spawnfunc_info_player_deathmatch();
  10 }
  11
  12 void spawnfunc_info_player_start (void)
  13 {
  14         spawnfunc_info_player_deathmatch();
  15 }
  16
  17 void spawnfunc_info_player_deathmatch (void)
  18 {
  19         self.classname = "info_player_deathmatch";
  20         relocate_spawnpoint();
  21 }
  22
  23 void spawnpoint_use()
  24 {
  25         if(teams_matter)
  26         if(have_team_spawns)
  27         {
  28                 self.team = activator.team;
  29                 some_spawn_has_been_used = 1;
  30         }
  31 };
  32
  33 // Returns:
  34 //   -1 if a spawn can't be used
  35 //   otherwise, a weight of the spawnpoint
  36 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
  37 {
  38         float shortest, thisdist;
  39         entity player;
  40
  41         // filter out spots for the wrong team
  42         if(teamcheck)
  43         if(spot.team != teamcheck)
  44                 return -1;
  45
  46         if(race_spawns)
  47                 if(spot.target == "")
  48                         return -1;
  49
  50         // filter out spots for assault
  51         if(spot.target != "") {
  52                 local entity ent;
  53                 float good;
  54                 ent = find(world, targetname, spot.target);
  55                 while(ent) {
  56                         if(ent.classname == "target_objective")
  57                         {
  58                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  59                                         return -1;
  60                                 good = 1;
  61                         }
  62                         else if(ent.classname == "trigger_race_checkpoint")
  63                         {
  64                                 if(self.classname == "player") // spectators may spawn everywhere
  65                                 {
  66                                         if(ent.race_checkpoint != race_PreviousCheckpoint(self.race_checkpoint))
  67                                                 return -1;
  68                                         print(ftos(race_place_valid), ": ");
  69                                         print(ftos(self.race_place), " <-> ");
  70                                         print(ftos(spot.race_place), "\n");
  71                                         if(race_place_valid && (spot.race_place != self.race_place))
  72                                                 return -1;
  73                                         if(!race_place_valid && (spot.race_place != 0))
  74                                                 return -1;
  75                                 }
  76                                 good = 1;
  77                         }
  78                         else
  79                         {
  80                         }
  81                         ent = find(ent, targetname, spot.target);
  82                 }
  83
  84                 if(!good)
  85                         return -1;
  86         }
  87
  88         player = playerlist;
  89         shortest = vlen(world.maxs - world.mins);
  90         for(player = playerlist; player; player = player.chain)
  91                 if (player != self)
  92                 {
  93                         thisdist = vlen(player.origin - spot.origin);
  94                         if (thisdist < shortest)
  95                                 shortest = thisdist;
  96                 }
  97         return shortest;
  98 }
  99
 100 float spawn_allbad;
 101 float spawn_allgood;
 102 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
 103 {
 104         local entity spot, spotlist, spotlistend;
 105         spawn_allgood = TRUE;
 106         spawn_allbad = TRUE;
 107
 108         spotlist = world;
 109         spotlistend = world;
 110
 111         for(spot = firstspot; spot; spot = spot.chain)
 112         {
 113                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
 114
 115                 if(cvar("spawn_debugview"))
 116                 {
 117                         setmodel(spot, "models/runematch/rune.mdl");
 118                         if(spot.SPAWNPOINT_SCORE < mindist)
 119                         {
 120                                 spot.colormod = '1 0 0';
 121                                 spot.scale = 1;
 122                         }
 123                         else
 124                         {
 125                                 spot.colormod = '0 1 0';
 126                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
 127                         }
 128                 }
 129
 130                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 131                 {
 132                         if(spot.SPAWNPOINT_SCORE < mindist)
 133                         {
 134                                 // too short distance
 135                                 spawn_allgood = FALSE;
 136                         }
 137                         else
 138                         {
 139                                 // perfect
 140                                 spawn_allbad = FALSE;
 141
 142                                 if(spotlistend)
 143                                         spotlistend.chain = spot;
 144                                 spotlistend = spot;
 145                                 if(!spotlist)
 146                                         spotlist = spot;
 147
 148                                 /*
 149                                 if(teamcheck)
 150                                 if(spot.team != teamcheck)
 151                                         error("invalid spawn added");
 152
 153                                 print("added ", etos(spot), "\n");
 154                                 */
 155                         }
 156                 }
 157         }
 158         if(spotlistend)
 159                 spotlistend.chain = world;
 160
 161         /*
 162                 entity e;
 163                 if(teamcheck)
 164                         for(e = spotlist; e; e = e.chain)
 165                         {
 166                                 print("seen ", etos(e), "\n");
 167                                 if(e.team != teamcheck)
 168                                         error("invalid spawn found");
 169                         }
 170         */
 171
 172         return spotlist;
 173 }
 174
 175 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 176 {
 177         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 178         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 179         local entity spot;
 180
 181         RandomSelection_Init();
 182         for(spot = firstspot; spot; spot = spot.chain)
 183                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 184
 185         return RandomSelection_chosen_ent;
 186 }
 187
 188 /*
 189 =============
 190 SelectSpawnPoint
 191
 192 Finds a point to respawn
 193 =============
 194 */
 195 entity SelectSpawnPoint (float anypoint)
 196 {
 197         local float teamcheck;
 198         local entity firstspot_new;
 199         local entity spot, firstspot, playerlist;
 200
 201         spot = find (world, classname, "testplayerstart");
 202         if (spot)
 203                 return spot;
 204
 205         teamcheck = 0;
 206
 207         if(!anypoint && have_team_spawns)
 208                 teamcheck = self.team;
 209
 210         // get the list of players
 211         playerlist = findchain(classname, "player");
 212         // get the entire list of spots
 213         firstspot = findchain(classname, "info_player_deathmatch");
 214         // filter out the bad ones
 215         // (note this returns the original list if none survived)
 216         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 217         if(!firstspot_new)
 218                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 219         firstspot = firstspot_new;
 220
 221         // there is 50/50 chance of choosing a random spot or the furthest spot
 222         // (this means that roughly every other spawn will be furthest, so you
 223         // usually won't get fragged at spawn twice in a row)
 224         if (arena_roundbased)
 225         {
 226                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 227                 if(firstspot_new)
 228                         firstspot = firstspot_new;
 229                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 230         }
 231         else if (random() > cvar("g_spawn_furthest"))
 232                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 233         else
 234                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 235
 236         if(cvar("spawn_debugview"))
 237         {
 238                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 239
 240                 entity e;
 241                 if(teamcheck)
 242                         for(e = firstspot; e; e = e.chain)
 243                                 if(e.team != teamcheck)
 244                                         error("invalid spawn found");
 245         }
 246
 247         if (!spot)
 248         {
 249                 if(cvar("spawn_debug"))
 250                         GotoNextMap();
 251                 else
 252                 {
 253                         if(some_spawn_has_been_used)
 254                                 return world; // team can't spawn any more, because of actions of other team
 255                         else
 256                                 error("Cannot find a spawn point - please fix the map!");
 257                 }
 258         }
 259
 260         return spot;
 261 }
 262
 263 /*
 264 =============
 265 CheckPlayerModel
 266
 267 Checks if the argument string can be a valid playermodel.
 268 Returns a valid one in doubt.
 269 =============
 270 */
 271 string FallbackPlayerModel = "models/player/marine.zym";
 272 string CheckPlayerModel(string plyermodel) {
 273         if(strlen(plyermodel) < 4)
 274                 return FallbackPlayerModel;
 275         if( substring(plyermodel,0,14) != "models/player/")
 276                 return FallbackPlayerModel;
 277         else if(cvar("sv_servermodelsonly"))
 278         {
 279                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 280                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 281                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 282                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 283                         return FallbackPlayerModel;
 284                 if(!fexists(plyermodel))
 285                         return FallbackPlayerModel;
 286         }
 287         return plyermodel;
 288 }
 289
 290 /*
 291 =============
 292 Client_customizeentityforclient
 293
 294 LOD reduction
 295 =============
 296 */
 297 float Client_customizeentityforclient()
 298 {
 299 #ifdef ALLOW_VARIABLE_LOD
 300         // self: me
 301         // other: the player viewing me
 302         float distance;
 303         float f;
 304
 305         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 306                 return TRUE;
 307
 308         if(other.cvar_cl_playerdetailreduction <= 0)
 309         {
 310                 if(other.cvar_cl_playerdetailreduction <= -2)
 311                         self.modelindex = self.modelindex_lod2;
 312                 else if(other.cvar_cl_playerdetailreduction <= -1)
 313                         self.modelindex = self.modelindex_lod1;
 314                 else
 315                         self.modelindex = self.modelindex_lod0;
 316         }
 317         else
 318         {
 319                 distance = vlen(self.origin - other.origin);
 320                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 321                 if(f > 10000)
 322                         self.modelindex = self.modelindex_lod2;
 323                 else if(f > 5000)
 324                         self.modelindex = self.modelindex_lod1;
 325                 else
 326                         self.modelindex = self.modelindex_lod0;
 327         }
 328 #endif
 329
 330         return TRUE;
 331 }
 332
 333 void UpdatePlayerSounds();
 334 void setmodel_lod(entity e, string modelname)
 335 {
 336 #ifdef ALLOW_VARIABLE_LOD
 337         string s;
 338
 339         // FIXME: this only supports 3-letter extensions
 340         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 341         if(fexists(s))
 342         {
 343                 precache_model(s);
 344                 setmodel(e, s); // players have high precision
 345                 self.modelindex_lod1 = self.modelindex;
 346         }
 347         else
 348                 self.modelindex_lod1 = -1;
 349
 350         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 351         if(fexists(s))
 352         {
 353                 precache_model(s);
 354                 setmodel(e, s); // players have high precision
 355                 self.modelindex_lod2 = self.modelindex;
 356         }
 357         else
 358                 self.modelindex_lod2 = -1;
 359
 360         precache_model(modelname);
 361         setmodel(e, modelname); // players have high precision
 362         self.modelindex_lod0 = self.modelindex;
 363
 364         if(self.modelindex_lod1 < 0)
 365                 self.modelindex_lod1 = self.modelindex;
 366
 367         if(self.modelindex_lod2 < 0)
 368                 self.modelindex_lod2 = self.modelindex;
 369 #else
 370         precache_model(modelname);
 371         setmodel(e, modelname); // players have high precision
 372 #endif
 373         player_setupanimsformodel();
 374         UpdatePlayerSounds();
 375 }
 376
 377 /*
 378 =============
 379 PutObserverInServer
 380
 381 putting a client as observer in the server
 382 =============
 383 */
 384 void PutObserverInServer (void)
 385 {
 386         entity  spot;
 387
 388         race_PreSpawnObserver();
 389
 390         spot = SelectSpawnPoint (TRUE);
 391         if(!spot)
 392                 error("No spawnpoints for observers?!?\n");
 393         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 394
 395         if(clienttype(self) == CLIENTTYPE_REAL)
 396         {
 397                 msg_entity = self;
 398                 WriteByte(MSG_ONE, SVC_SETVIEW);
 399                 WriteEntity(MSG_ONE, self);
 400         }
 401
 402         DropAllRunes(self);
 403         kh_Key_DropAll(self, TRUE);
 404
 405         if(self.flagcarried)
 406                 DropFlag(self.flagcarried);
 407
 408         WaypointSprite_PlayerDead();
 409
 410         if(self.killcount != -666)
 411         {
 412                 if(g_lms)
 413                 {
 414                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 415                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 416                         else
 417                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 418                 }
 419                 else
 420                         bprint ("^4", self.netname, "^4 is spectating now\n");
 421         }
 422
 423         PlayerScore_Clear(self); // clear scores when needed
 424
 425         self.spectatortime = time;
 426
 427         self.classname = "observer";
 428         self.health = -666;
 429         self.takedamage = DAMAGE_NO;
 430         self.solid = SOLID_NOT;
 431         self.movetype = MOVETYPE_NOCLIP;
 432         self.flags = FL_CLIENT | FL_NOTARGET;
 433         self.armorvalue = 666;
 434         self.effects = 0;
 435         self.armorvalue = cvar("g_balance_armor_start");
 436         self.pauserotarmor_finished = 0;
 437         self.pauserothealth_finished = 0;
 438         self.pauseregen_finished = 0;
 439         self.damageforcescale = 0;
 440         self.death_time = 0;
 441         self.dead_frame = 0;
 442         self.alpha = 0;
 443         self.scale = 0;
 444         self.fade_time = 0;
 445         self.pain_frame = 0;
 446         self.pain_finished = 0;
 447         self.strength_finished = 0;
 448         self.invincible_finished = 0;
 449         self.pushltime = 0;
 450         self.think = SUB_Null;
 451         self.nextthink = 0;
 452         self.hook_time = 0;
 453         self.runes = 0;
 454         self.deadflag = DEAD_NO;
 455         self.angles = spot.angles;
 456         self.angles_z = 0;
 457         self.fixangle = TRUE;
 458         self.crouch = FALSE;
 459
 460         self.view_ofs = PL_VIEW_OFS;
 461         setorigin (self, spot.origin);
 462         setsize (self, '0 0 0', '0 0 0');
 463         self.oldorigin = self.origin;
 464         self.items = 0;
 465         self.model = "";
 466         self.modelindex = 0;
 467         self.weapon = 0;
 468         self.weaponmodel = "";
 469         self.weaponentity = world;
 470         self.killcount = -666;
 471         self.velocity = '0 0 0';
 472         self.avelocity = '0 0 0';
 473         self.punchangle = '0 0 0';
 474         self.punchvector = '0 0 0';
 475         self.oldvelocity = self.velocity;
 476         self.customizeentityforclient = Client_customizeentityforclient;
 477         self.viewzoom = 1;
 478         self.wantswelcomemessage = 1;
 479
 480         if(g_arena)
 481         {
 482                 if(self.version_mismatch)
 483                 {
 484                         Spawnqueue_Unmark(self);
 485                         Spawnqueue_Remove(self);
 486                 }
 487                 else
 488                 {
 489                         Spawnqueue_Insert(self);
 490                 }
 491         }
 492         else if(g_lms)
 493         {
 494                 // Only if the player cannot play at all
 495                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 496                         self.frags = -666;
 497                 else
 498                         self.frags = -667;
 499         }
 500         else
 501                 self.frags = -666;
 502 }
 503
 504 float RestrictSkin(float s)
 505 {
 506         if(!teams_matter)
 507                 return s;
 508         if(s == 6)
 509                 return 6;
 510         return mod(s, 3);
 511 }
 512
 513 void FixPlayermodel()
 514 {
 515         local string defaultmodel;
 516         local float defaultskin;
 517         local vector m1, m2;
 518
 519         defaultmodel = "";
 520
 521         if(cvar("sv_defaultcharacter") == 1) {
 522                 defaultskin = 0;
 523
 524                 if(teams_matter)
 525                 {
 526                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 527                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 528                 }
 529
 530                 if(defaultmodel == "")
 531                 {
 532                         defaultmodel = cvar_string("sv_defaultplayermodel");
 533                         defaultskin = cvar("sv_defaultplayerskin");
 534                 }
 535         }
 536
 537         if(defaultmodel != "")
 538         {
 539                 if (defaultmodel != self.model)
 540                 {
 541                         m1 = self.mins;
 542                         m2 = self.maxs;
 543                         setmodel_lod (self, defaultmodel);
 544                         setsize (self, m1, m2);
 545                 }
 546
 547                 self.skin = defaultskin;
 548         } else {
 549                 if (self.playermodel != self.model)
 550                 {
 551                         self.playermodel = CheckPlayerModel(self.playermodel);
 552                         m1 = self.mins;
 553                         m2 = self.maxs;
 554                         setmodel_lod (self, self.playermodel);
 555                         setsize (self, m1, m2);
 556                 }
 557
 558                 self.skin = RestrictSkin(stof(self.playerskin));
 559         }
 560
 561         if(!teams_matter)
 562                 if(strlen(cvar_string("sv_defaultplayercolors")))
 563                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 564                                 setcolor(self, cvar("sv_defaultplayercolors"));
 565 }
 566
 567 /*
 568 =============
 569 PutClientInServer
 570
 571 Called when a client spawns in the server
 572 =============
 573 */
 574 //void() ctf_playerchanged;
 575 void PutClientInServer (void)
 576 {
 577         if(clienttype(self) == CLIENTTYPE_BOT)
 578         {
 579                 self.classname = "player";
 580         }
 581         else if(clienttype(self) == CLIENTTYPE_REAL)
 582         {
 583                 msg_entity = self;
 584                 WriteByte(MSG_ONE, SVC_SETVIEW);
 585                 WriteEntity(MSG_ONE, self);
 586         }
 587
 588         // player is dead and becomes observer
 589         // FIXME fix LMS scoring for new system
 590         if(g_lms)
 591         {
 592                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 593                         self.classname = "observer";
 594         }
 595
 596         if(g_arena)
 597         if(!self.spawned)
 598                 self.classname = "observer";
 599
 600         if(self.classname == "player") {
 601                 entity  spot;
 602
 603                 race_PreSpawn();
 604
 605                 spot = SelectSpawnPoint (FALSE);
 606                 if(!spot)
 607                 {
 608                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 609                         return; // spawn failed
 610                 }
 611
 612                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 613
 614                 self.classname = "player";
 615                 self.iscreature = TRUE;
 616                 self.movetype = MOVETYPE_WALK;
 617                 if(independent_players)
 618                         self.solid = SOLID_TRIGGER;
 619                 else
 620                         self.solid = SOLID_SLIDEBOX;
 621                 self.flags = FL_CLIENT;
 622                 self.takedamage = DAMAGE_AIM;
 623                 if(g_minstagib)
 624                         self.effects = EF_FULLBRIGHT;
 625                 else
 626                         self.effects = 0;
 627                 self.air_finished = time + 12;
 628                 self.dmg = 2;
 629
 630                 self.ammo_shells = start_ammo_shells;
 631                 self.ammo_nails = start_ammo_nails;
 632                 self.ammo_rockets = start_ammo_rockets;
 633                 self.ammo_cells = start_ammo_cells;
 634                 self.health = start_health;
 635                 self.armorvalue = start_armorvalue;
 636                 self.items = start_items;
 637                 self.switchweapon = start_switchweapon;
 638                 self.cnt = start_switchweapon;
 639                 self.weapon = 0;
 640                 self.jump_interval = time;
 641
 642                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 643                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 644                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 645                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 646                 //extend the pause of rotting if client was reset at the beginning of the countdown
 647                 if(!cvar("sv_ready_restart_after_countdown") && time < restart_countdown) {
 648                         self.spawnshieldtime += RESTART_COUNTDOWN;
 649                         self.pauserotarmor_finished += RESTART_COUNTDOWN;
 650                         self.pauserothealth_finished += RESTART_COUNTDOWN;
 651                         self.pauseregen_finished += RESTART_COUNTDOWN;
 652                 }
 653                 self.damageforcescale = 2;
 654                 self.death_time = 0;
 655                 self.dead_frame = 0;
 656                 self.alpha = 0;
 657                 self.scale = 0;
 658                 self.fade_time = 0;
 659                 self.pain_frame = 0;
 660                 self.pain_finished = 0;
 661                 self.strength_finished = 0;
 662                 self.invincible_finished = 0;
 663                 self.pushltime = 0;
 664                 //self.speed_finished = 0;
 665                 //self.slowmo_finished = 0;
 666                 // players have no think function
 667                 self.think = SUB_Null;
 668                 self.nextthink = 0;
 669                 self.hook_time = 0;
 670
 671                 self.runes = 0;
 672
 673                 self.deadflag = DEAD_NO;
 674
 675                 self.angles = spot.angles;
 676
 677                 self.angles_z = 0; // never spawn tilted even if the spot says to
 678                 self.fixangle = TRUE; // turn this way immediately
 679                 self.velocity = '0 0 0';
 680                 self.avelocity = '0 0 0';
 681                 self.punchangle = '0 0 0';
 682                 self.punchvector = '0 0 0';
 683                 self.oldvelocity = self.velocity;
 684
 685                 self.viewzoom = 0.6;
 686                 self.has_zoomed = 0;
 687
 688                 self.customizeentityforclient = Client_customizeentityforclient;
 689
 690                 self.model = "";
 691                 FixPlayermodel();
 692
 693                 self.crouch = FALSE;
 694                 self.view_ofs = PL_VIEW_OFS;
 695                 setsize (self, PL_MIN, PL_MAX);
 696                 self.spawnorigin = spot.origin;
 697                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 698                 // don't reset back to last position, even if new position is stuck in solid
 699                 self.oldorigin = self.origin;
 700
 701                 if(g_arena)
 702                 {
 703                         Spawnqueue_Remove(self);
 704                         Spawnqueue_Mark(self);
 705                 }
 706
 707                 self.event_damage = PlayerDamage;
 708
 709                 self.bot_attack = TRUE;
 710
 711                 self.statdraintime = time + 5;
 712                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 713
 714                 if(self.killcount == -666) {
 715                         PlayerScore_Clear(self);
 716                         self.killcount = 0;
 717                         self.frags = 0;
 718                 }
 719
 720                 self.cnt = WEP_LASER;
 721                 self.nixnex_lastchange_id = -1;
 722
 723                 CL_SpawnWeaponentity();
 724                 self.alpha = default_player_alpha;
 725                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 726                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 727
 728                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 729                 self.lms_traveled_distance = 0;
 730                 self.speedrunning = FALSE;
 731
 732                 race_PostSpawn(spot);
 733
 734                 if(cvar("spawn_debug"))
 735                 {
 736                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 737                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 738                 }
 739
 740                 //stuffcmd(self, "chase_active 0");
 741                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 742
 743                 if (cvar("g_spawnsound"))
 744                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 745
 746                 if(g_assault) {
 747                         if(self.team == assault_attacker_team)
 748                                 centerprint(self, "You are attacking!\n");
 749                         else
 750                                 centerprint(self, "You are defending!\n");
 751                 }
 752
 753         } else if(self.classname == "observer") {
 754                 PutObserverInServer ();
 755         }
 756
 757         //if(g_ctf)
 758         //      ctf_playerchanged();
 759 }
 760
 761 /*
 762 =============
 763 SendCSQCInfo
 764
 765 Send whatever CSQC needs NOW and cannot wait for SendServerInfo to happen...
 766 =============
 767 */
 768 void SendCSQCInfo(void)
 769 {
 770         if(clienttype(self) != CLIENTTYPE_REAL)
 771                 return;
 772         msg_entity = self;
 773         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 774         WriteByte(MSG_ONE, TE_CSQC_INIT);
 775         WriteShort(MSG_ONE, CSQC_REVISION);
 776         WriteByte(MSG_ONE, maxclients);
 777 }
 778
 779 /*
 780 =============
 781 SetNewParms
 782 =============
 783 */
 784 void SetNewParms (void)
 785 {
 786         // initialize parms for a new player
 787         parm1 = -(86400 * 366);
 788 }
 789
 790 /*
 791 =============
 792 SetChangeParms
 793 =============
 794 */
 795 void SetChangeParms (void)
 796 {
 797         // save parms for level change
 798         parm1 = self.parm_idlesince - time;
 799 }
 800
 801 /*
 802 =============
 803 DecodeLevelParms
 804 =============
 805 */
 806 void DecodeLevelParms (void)
 807 {
 808         // load parms
 809         self.parm_idlesince = parm1;
 810         if(self.parm_idlesince == -(86400 * 366))
 811                 self.parm_idlesince = time;
 812 }
 813
 814 /*
 815 =============
 816 ClientKill
 817
 818 Called when a client types 'kill' in the console
 819 =============
 820 */
 821
 822 void ClientKill_Now_TeamChange()
 823 {
 824         if(self.killindicator_teamchange == -1)
 825         {
 826                 self.team = -1;
 827                 JoinBestTeam( self, FALSE, FALSE );
 828         }
 829         else
 830         {
 831                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 832         }
 833 }
 834
 835 void ClientKill_Now()
 836 {
 837         if(self.killindicator_teamchange)
 838                 ClientKill_Now_TeamChange();
 839
 840         // in any case:
 841         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 842
 843         if(self.killindicator)
 844         {
 845                 dprint("Cleaned up after a leaked kill indicator.\n");
 846                 remove(self.killindicator);
 847                 self.killindicator = world;
 848         }
 849 }
 850 void KillIndicator_Think()
 851 {
 852         if (!self.owner.modelindex)
 853         {
 854                 self.owner.killindicator = world;
 855                 remove(self);
 856                 return;
 857         }
 858
 859         if(self.cnt <= 0)
 860         {
 861                 self = self.owner;
 862                 ClientKill_Now(); // no oldself needed
 863                 return;
 864         }
 865         else
 866         {
 867                 if(self.cnt <= 10)
 868                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 869                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 870                 {
 871                         if(self.cnt <= 10)
 872                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 873                         if(self.owner.killindicator_teamchange)
 874                         {
 875                                 if(self.owner.killindicator_teamchange == -1)
 876                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 877                                 else
 878                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 879                         }
 880                         else
 881                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 882                 }
 883                 self.nextthink = time + 1;
 884                 self.cnt -= 1;
 885         }
 886 }
 887
 888 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 889 {
 890         float killtime;
 891         entity e;
 892         killtime = cvar("g_balance_kill_delay");
 893
 894         self.killindicator_teamchange = targetteam;
 895
 896         if(!self.killindicator)
 897         {
 898                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 899                 {
 900                         ClientKill_Now();
 901                 }
 902                 else
 903                 {
 904                         self.killindicator = spawn();
 905                         self.killindicator.owner = self;
 906                         self.killindicator.scale = 0.5;
 907                         setattachment(self.killindicator, self, "");
 908                         setorigin(self.killindicator, '0 0 52');
 909                         self.killindicator.think = KillIndicator_Think;
 910                         self.killindicator.nextthink = time + (self.lip) * 0.05;
 911                         self.killindicator.cnt = ceil(killtime);
 912                         self.killindicator.count = bound(0, ceil(killtime), 10);
 913                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 914
 915                         for(e = world; (e = find(e, classname, "body")) != world; )
 916                         {
 917                                 if(e.enemy != self)
 918                                         continue;
 919                                 e.killindicator = spawn();
 920                                 e.killindicator.owner = e;
 921                                 e.killindicator.scale = 0.5;
 922                                 setattachment(e.killindicator, e, "");
 923                                 setorigin(e.killindicator, '0 0 52');
 924                                 e.killindicator.think = KillIndicator_Think;
 925                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
 926                                 e.killindicator.cnt = ceil(killtime);
 927                         }
 928                         self.lip = 0;
 929                 }
 930         }
 931         if(self.killindicator)
 932         {
 933                 if(targetteam)
 934                         self.killindicator.colormod = TeamColor(targetteam);
 935                 else
 936                         self.killindicator.colormod = '0 0 0';
 937         }
 938 }
 939
 940 void ClientKill (void)
 941 {
 942         ClientKill_TeamChange(0);
 943 }
 944
 945 void DoTeamChange(float destteam)
 946 {
 947         float t, c0;
 948         if(!cvar("teamplay"))
 949         {
 950                 if(destteam >= 0)
 951                         SetPlayerColors(self, destteam);
 952                 return;
 953         }
 954         if(self.classname == "player")
 955         if(destteam == -1)
 956         {
 957                 CheckAllowedTeams(self);
 958                 t = FindSmallestTeam(self, TRUE);
 959                 switch(self.team)
 960                 {
 961                         case COLOR_TEAM1: c0 = c1; break;
 962                         case COLOR_TEAM2: c0 = c2; break;
 963                         case COLOR_TEAM3: c0 = c3; break;
 964                         case COLOR_TEAM4: c0 = c4; break;
 965                         default:          c0 = 999;
 966                 }
 967                 switch(t)
 968                 {
 969                         case 1:
 970                                 if(c0 > c1)
 971                                         destteam = COLOR_TEAM1;
 972                                 break;
 973                         case 2:
 974                                 if(c0 > c2)
 975                                         destteam = COLOR_TEAM2;
 976                                 break;
 977                         case 3:
 978                                 if(c0 > c3)
 979                                         destteam = COLOR_TEAM3;
 980                                 break;
 981                         case 4:
 982                                 if(c0 > c4)
 983                                         destteam = COLOR_TEAM4;
 984                                 break;
 985                 }
 986                 if(destteam == -1)
 987                         return;
 988         }
 989         if(destteam == self.team && !self.killindicator)
 990                 return;
 991         ClientKill_TeamChange(destteam);
 992 }
 993
 994 void FixClientCvars(entity e)
 995 {
 996         // send prediction settings to the client
 997         stuffcmd(e, "\nin_bindmap 0 0\n");
 998         /*
 999          * we no longer need to stuff this. Remove this comment block if you feel
1000          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1001         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1002         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1003         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1004         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1005         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1006         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1007         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1008         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1009         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1010         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1011         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1012         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1013         stuffcmd(e, "cl_movement_edgefriction 1\n");
1014          */
1015 }
1016
1017 /*
1018 =============
1019 ClientConnect
1020
1021 Called when a client connects to the server
1022 =============
1023 */
1024 //void ctf_clientconnect();
1025 string ColoredTeamName(float t);
1026 void DecodeLevelParms (void);
1027 //void dom_player_join_team(entity pl);
1028 void ClientConnect (void)
1029 {
1030         local string s;
1031         float wep;
1032
1033         if(self.flags & FL_CLIENT)
1034         {
1035                 print("Warning: ClientConnect, but already connected!\n");
1036                 return;
1037         }
1038
1039         if(Ban_IsClientBanned(self))
1040         {
1041                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
1042                 dropclient(self);
1043                 bprint(s);
1044                 return;
1045         }
1046
1047         DecodeLevelParms();
1048
1049         self.classname = "player_joining";
1050
1051         self.flags = self.flags | FL_CLIENT;
1052         self.version_nagtime = time + 10 + random() * 10;
1053
1054         if(player_count<0)
1055         {
1056                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1057                 player_count = 0;
1058         }
1059
1060         PlayerScore_Attach(self);
1061
1062         bot_clientconnect();
1063
1064         race_PreSpawnObserver();
1065
1066         //if(g_domination)
1067         //      dom_player_join_team(self);
1068
1069         //JoinBestTeam(self, FALSE, FALSE);
1070
1071         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1072                 self.classname = "observer";
1073         } else {
1074                 self.classname = "player";
1075                 campaign_bots_may_start = 1;
1076         }
1077
1078         self.playerid = (playerid_last = playerid_last + 1);
1079         if(cvar("sv_eventlog"))
1080         {
1081                 if(clienttype(self) == CLIENTTYPE_REAL)
1082                         s = "player";
1083                 else
1084                         s = "bot";
1085                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
1086                 s = strcat(":team:", ftos(self.playerid), ":");
1087                 s = strcat(s, ftos(self.team));
1088                 GameLogEcho(s, FALSE);
1089         }
1090         self.netname_previous = strzone(self.netname);
1091
1092         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1093
1094         bprint ("^4",self.netname);
1095         bprint ("^4 connected");
1096
1097         if(g_domination || g_ctf)
1098         {
1099                 bprint(" and joined the ");
1100                 bprint(ColoredTeamName(self.team));
1101         }
1102
1103         bprint("\n");
1104
1105         self.welcomemessage_time = 0;
1106
1107         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1108         // TODO: is this being used for anything else than cd tracks?
1109         // Remember: SVC_CDTRACK exists. Maybe it should be used.
1110         //
1111         stuffcmd(self, "cl_particles_reloadeffects\n");
1112
1113         FixClientCvars(self);
1114
1115         // spawnfunc_waypoint sprites
1116         WaypointSprite_InitClient(self);
1117
1118         // Wazat's grappling hook
1119         SetGrappleHookBindings();
1120
1121         // get autoswitch state from player when he toggles it
1122         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1123
1124         // get version info from player
1125         stuffcmd(self, "cmd clientversion $gameversion\n");
1126
1127         // send all weapon info strings
1128         stuffcmd(self, "register_bestweapon clear\n"); // clear the Quake stuff
1129         wep = WEP_FIRST;
1130         while (wep <= WEP_LAST)
1131         {
1132                 weapon_action(wep, WR_REGISTER);
1133                 wep = wep + 1;
1134         }
1135
1136         // get other cvars from player
1137         GetCvars(0);
1138
1139         // set cvar for team scoreboard
1140         if (teams_matter)
1141         {
1142                 local float t;
1143                 t = cvar("teamplay");
1144                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1145                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1146         }
1147         else
1148                 stuffcmd(self, "set teamplay 0\n");
1149
1150         // notify about available teams
1151         if(teamplay)
1152         {
1153                 CheckAllowedTeams(self);
1154                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1155                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1156         }
1157         else
1158                 stuffcmd(self, "set _teams_available 0\n");
1159
1160         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1161
1162         if(g_arena)
1163         {
1164                 self.classname = "observer";
1165                 Spawnqueue_Insert(self);
1166         }
1167         /*else if(g_ctf)
1168         {
1169                 ctf_clientconnect();
1170         }*/
1171
1172         if(entcs_start)
1173                 attach_entcs();
1174
1175         bot_relinkplayerlist();
1176
1177         self.spectatortime = time;
1178         if(blockSpectators)
1179         {
1180                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1181         }
1182
1183         self.jointime = time;
1184         self.allowedTimeouts = cvar("sv_timeout_number");
1185
1186         if(clienttype(self) == CLIENTTYPE_REAL)
1187         {
1188                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1189                 SendCSQCInfo();
1190                 msg_entity = self;
1191                 if(mapvote_initialized && !cvar("g_maplist_textonly"))
1192                 {
1193                         MapVote_SendData(MSG_ONE);
1194                         MapVote_UpdateData(MSG_ONE);
1195                 }
1196                 ScoreInfo_Write(MSG_ONE);
1197         }
1198
1199         if(g_lms)
1200         {
1201                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1202                 {
1203                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1204                         self.frags = -666; // FIXME do we still need this?
1205                 }
1206         }
1207 }
1208
1209 /*
1210 =============
1211 ClientDisconnect
1212
1213 Called when a client disconnects from the server
1214 =============
1215 */
1216 void(entity e) DropFlag;
1217 .entity chatbubbleentity;
1218 .entity teambubbleentity;
1219 //void() ctf_clientdisconnect;
1220 void ClientDisconnect (void)
1221 {
1222         float save;
1223
1224         if not(self.flags & FL_CLIENT)
1225         {
1226                 print("Warning: ClientDisconnect without ClientConnect\n");
1227                 return;
1228         }
1229
1230         bot_clientdisconnect();
1231
1232         if(entcs_start)
1233                 detach_entcs();
1234
1235         if(cvar("sv_eventlog"))
1236                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
1237         bprint ("^4",self.netname);
1238         bprint ("^4 disconnected\n");
1239
1240         if (self.chatbubbleentity)
1241         {
1242                 remove (self.chatbubbleentity);
1243                 self.chatbubbleentity = world;
1244         }
1245
1246         if (self.teambubbleentity)
1247         {
1248                 remove (self.teambubbleentity);
1249                 self.teambubbleentity = world;
1250         }
1251
1252         if (self.killindicator)
1253         {
1254                 remove (self.killindicator);
1255                 self.killindicator = world;
1256         }
1257
1258         WaypointSprite_PlayerGone();
1259
1260         DropAllRunes(self);
1261         kh_Key_DropAll(self, TRUE);
1262
1263         if(self.flagcarried)
1264                 DropFlag(self.flagcarried);
1265
1266         save = self.flags;
1267         self.flags = self.flags - (self.flags & FL_CLIENT);
1268         bot_relinkplayerlist();
1269         self.flags = save;
1270
1271         // remove laserdot
1272         if(self.weaponentity)
1273                 if(self.weaponentity.lasertarget)
1274                         remove(self.weaponentity.lasertarget);
1275
1276         if(g_arena)
1277         {
1278                 Spawnqueue_Unmark(self);
1279                 Spawnqueue_Remove(self);
1280         }
1281         /*if(g_ctf)
1282         {
1283                 ctf_clientdisconnect();
1284         }
1285         */
1286
1287         PlayerScore_Detach(self);
1288
1289         if(self.netname_previous)
1290                 strunzone(self.netname_previous);
1291
1292         ClearPlayerSounds();
1293
1294         // free cvars
1295         GetCvars(-1);
1296         self.playerid = 0;
1297 }
1298
1299 .float BUTTON_CHAT;
1300 void ChatBubbleThink()
1301 {
1302         self.nextthink = time;
1303         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1304         {
1305                 self.owner.chatbubbleentity = world;
1306                 remove(self);
1307                 return;
1308         }
1309         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1310         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1311                 self.model = self.mdl;
1312         else
1313                 self.model = "";
1314 };
1315
1316 void UpdateChatBubble()
1317 {
1318         if (!self.modelindex)
1319                 return;
1320         // spawn a chatbubble entity if needed
1321         if (!self.chatbubbleentity)
1322         {
1323                 self.chatbubbleentity = spawn();
1324                 self.chatbubbleentity.owner = self;
1325                 self.chatbubbleentity.exteriormodeltoclient = self;
1326                 self.chatbubbleentity.think = ChatBubbleThink;
1327                 self.chatbubbleentity.nextthink = time;
1328                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1329                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1330                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1331                 self.chatbubbleentity.model = "";
1332                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1333         }
1334 }
1335
1336
1337 void TeamBubbleThink()
1338 {
1339         self.nextthink = time;
1340         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1341         {
1342                 self.owner.teambubbleentity = world;
1343                 remove(self);
1344                 return;
1345         }
1346 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1347         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1348                 self.model = "";
1349         else
1350                 self.model = self.mdl;
1351
1352 };
1353
1354 float TeamBubble_customizeentityforclient()
1355 {
1356         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1357 }
1358
1359 void UpdateTeamBubble()
1360 {
1361         if (!self.modelindex || !cvar("teamplay"))
1362                 return;
1363         // spawn a teambubble entity if needed
1364         if (!self.teambubbleentity && cvar("teamplay"))
1365         {
1366                 self.teambubbleentity = spawn();
1367                 self.teambubbleentity.owner = self;
1368                 self.teambubbleentity.exteriormodeltoclient = self;
1369                 self.teambubbleentity.think = TeamBubbleThink;
1370                 self.teambubbleentity.nextthink = time;
1371                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1372 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1373                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1374                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1375                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1376                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1377                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1378                 self.teambubbleentity.effects = EF_LOWPRECISION;
1379         }
1380 }
1381
1382 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1383 // added to the model skins
1384 /*void UpdateColorModHack()
1385 {
1386         local float c;
1387         c = self.clientcolors & 15;
1388         // LordHavoc: only bothering to support white, green, red, yellow, blue
1389              if (teamplay == 0) self.colormod = '0 0 0';
1390         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1391         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1392         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1393         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1394         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1395         else self.colormod = '1 1 1';
1396 };*/
1397
1398 void respawn(void)
1399 {
1400         CopyBody(1);
1401         self.effects |= EF_NODRAW; // prevent another CopyBody
1402         PutClientInServer();
1403 }
1404
1405 /**
1406  * When sv_timeout is used this function returs strings like
1407  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1408  * Called by centerprint functions
1409  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1410  */
1411 string getTimeoutText(float addOneSecond) {
1412         if (!cvar("sv_timeout") || !timeoutStatus)
1413                 return "";
1414
1415         local string retStr;
1416         if (timeoutStatus == 1) {
1417                 if (addOneSecond == 1) {
1418                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1419                 }
1420                 else {
1421                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1422                 }
1423                 return retStr;
1424         }
1425         else if (timeoutStatus == 2) {
1426                 if (addOneSecond) {
1427                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1428                         //don't show messages like "Timeout ends in 0 seconds"...
1429                         if ((remainingTimeoutTime + 1) > 0)
1430                                 return retStr;
1431                         else
1432                                 return "";
1433                 }
1434                 else {
1435                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1436                         //don't show messages like "Timeout ends in 0 seconds"...
1437                         if (remainingTimeoutTime > 0)
1438                                 return retStr;
1439                         else
1440                                 return "";
1441                 }
1442         }
1443         else return "";
1444 }
1445
1446 void player_powerups (void)
1447 {
1448         if (g_minstagib)
1449         {
1450                 if (self.items & IT_STRENGTH)
1451                 {
1452                         if (time > self.strength_finished)
1453                         {
1454                                 if (g_minstagib_invis_alpha > 0)
1455                                 {
1456                                         self.alpha = default_player_alpha;
1457                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1458                                         self.effects = self.effects | EF_FULLBRIGHT;
1459                                 }
1460                                 else
1461                                 {
1462                                         self.effects -= self.effects & EF_NODRAW;
1463                                 }
1464                                 self.items = self.items - (self.items & IT_STRENGTH);
1465                                 sprint(self, "^3Invisibility has worn off\n");
1466                         }
1467                 }
1468                 else
1469                 {
1470                         if (time < self.strength_finished)
1471                         {
1472                                 if (g_minstagib_invis_alpha > 0)
1473                                 {
1474                                         self.alpha = g_minstagib_invis_alpha;
1475                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1476                                         self.effects -= self.effects & EF_FULLBRIGHT;
1477                                 }
1478                                 else
1479                                 {
1480                                         self.effects = self.effects | EF_NODRAW;
1481                                 }
1482                                 self.items = self.items | IT_STRENGTH;
1483                                 sprint(self, "^3You are invisible\n");
1484                         }
1485                 }
1486
1487                 if (self.items & IT_INVINCIBLE)
1488                 {
1489                         if (time > self.invincible_finished)
1490                         {
1491                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1492                                 sprint(self, "^3Speed has worn off\n");
1493                         }
1494                 }
1495                 else
1496                 {
1497                         if (time < self.invincible_finished)
1498                         {
1499                                 self.items = self.items | IT_INVINCIBLE;
1500                                 sprint(self, "^3You are on speed\n");
1501                         }
1502                 }
1503                 return;
1504         }
1505
1506         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1507         if (self.items & IT_STRENGTH)
1508         {
1509                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1510                 if (time > self.strength_finished)
1511                 {
1512                         self.items = self.items - (self.items & IT_STRENGTH);
1513                         sprint(self, "^3Strength has worn off\n");
1514                 }
1515         }
1516         else
1517         {
1518                 if (time < self.strength_finished)
1519                 {
1520                         self.items = self.items | IT_STRENGTH;
1521                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1522                 }
1523         }
1524         if (self.items & IT_INVINCIBLE)
1525         {
1526                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1527                 if (time > self.invincible_finished)
1528                 {
1529                         self.items = self.items - (self.items & IT_INVINCIBLE);
1530                         sprint(self, "^3Shield has worn off\n");
1531                 }
1532         }
1533         else
1534         {
1535                 if (time < self.invincible_finished)
1536                 {
1537                         self.items = self.items | IT_INVINCIBLE;
1538                         sprint(self, "^3Shield surrounds you\n");
1539                 }
1540         }
1541
1542         if (cvar("g_fullbrightplayers"))
1543                 self.effects = self.effects | EF_FULLBRIGHT;
1544
1545         // midair gamemode: damage only while in the air
1546         // if in midair mode, being on ground grants temporary invulnerability
1547         // (this is so that multishot weapon don't clear the ground flag on the
1548         // first damage in the frame, leaving the player vulnerable to the
1549         // remaining hits in the same frame)
1550         if (self.flags & FL_ONGROUND)
1551         if (g_midair)
1552                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1553
1554         if (time < self.spawnshieldtime)
1555                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1556 }
1557
1558 float CalcRegen(float current, float stable, float regenfactor)
1559 {
1560         if(current > stable)
1561                 return current;
1562         else if(current > stable - 0.25) // when close enough, "snap"
1563                 return stable;
1564         else
1565                 return min(stable, current + (stable - current) * regenfactor * frametime);
1566 }
1567
1568 void player_regen (void)
1569 {
1570         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1571         maxh = cvar("g_balance_health_stable");
1572         maxa = cvar("g_balance_armor_stable");
1573         limith = cvar("g_balance_health_limit");
1574         limita = cvar("g_balance_armor_limit");
1575
1576         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1577                 return;
1578
1579         max_mod = regen_mod = rot_mod = limit_mod = 1;
1580
1581         if (self.runes & RUNE_REGEN)
1582         {
1583                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1584                 {
1585                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1586                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1587                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1588                 }
1589                 else
1590                 {
1591                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1592                         max_mod = cvar("g_balance_rune_regen_hpmod");
1593                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1594                 }
1595         }
1596         else if (self.runes & CURSE_VENOM)
1597         {
1598                 max_mod = cvar("g_balance_curse_venom_hpmod");
1599                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1600                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1601                 else
1602                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1603                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1604                 //if (!self.runes & RUNE_REGEN)
1605                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1606         }
1607         maxh = maxh * max_mod;
1608         //maxa = maxa * max_mod;
1609         limith = limith * limit_mod;
1610         limita = limita * limit_mod;
1611
1612         if (self.armorvalue > maxa)
1613         {
1614                 if (time > self.pauserotarmor_finished)
1615                 {
1616                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1617                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1618                 }
1619         }
1620         else if (self.armorvalue < maxa)
1621         {
1622                 if (time > self.pauseregen_finished)
1623                 {
1624                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1625                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1626                 }
1627         }
1628         if (self.health > maxh)
1629         {
1630                 if (time > self.pauserothealth_finished)
1631                 {
1632                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1633                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1634                 }
1635         }
1636         else if (self.health < maxh)
1637         {
1638                 if (time > self.pauseregen_finished)
1639                 {
1640                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1641                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1642                 }
1643         }
1644
1645         if (self.health > limith)
1646                 self.health = limith;
1647         if (self.armorvalue > limita)
1648                 self.armorvalue = limita;
1649
1650         // if player rotted to death...  die!
1651         if(self.health < 1)
1652                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1653 }
1654
1655 /*
1656 ======================
1657 spectate mode routines
1658 ======================
1659 */
1660 void SpectateCopy(entity spectatee) {
1661         self.armortype = spectatee.armortype;
1662         self.armorvalue = spectatee.armorvalue;
1663         self.currentammo = spectatee.currentammo;
1664         self.effects = spectatee.effects;
1665         self.health = spectatee.health;
1666         self.impulse = 0;
1667         self.items = spectatee.items;
1668         self.punchangle = spectatee.punchangle;
1669         self.view_ofs = spectatee.view_ofs;
1670         self.v_angle = spectatee.v_angle;
1671         self.viewzoom = spectatee.viewzoom;
1672         self.velocity = spectatee.velocity;
1673         self.dmg_take = spectatee.dmg_take;
1674         self.dmg_save = spectatee.dmg_save;
1675         self.dmg_inflictor = spectatee.dmg_inflictor;
1676         self.angles = spectatee.v_angle;
1677         self.fixangle = TRUE;
1678         setorigin(self, spectatee.origin);
1679         setsize(self, spectatee.mins, spectatee.maxs);
1680 }
1681
1682 float SpectateUpdate() {
1683         if(!self.enemy)
1684                 return 0;
1685
1686         if (self == self.enemy)
1687                 return 0;
1688
1689         if(self.enemy.flags & FL_NOTARGET)
1690                 return 0;
1691
1692         SpectateCopy(self.enemy);
1693
1694         return 1;
1695 }
1696
1697 float SpectateNext() {
1698         other = find(self.enemy, classname, "player");
1699         if (!other) {
1700                 other = find(other, classname, "player");
1701         }
1702         if (other) {
1703                 self.enemy = other;
1704         }
1705         if(self.enemy.classname == "player") {
1706                 msg_entity = self;
1707                 WriteByte(MSG_ONE, SVC_SETVIEW);
1708                 WriteEntity(MSG_ONE, self.enemy);
1709                 self.wantswelcomemessage = 1;
1710                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1711                 if(!SpectateUpdate())
1712                         PutObserverInServer();
1713                 return 1;
1714         } else {
1715                 return 0;
1716         }
1717 }
1718
1719 /*
1720 =============
1721 ShowRespawnCountdown()
1722
1723 Update a respawn countdown display.
1724 =============
1725 */
1726 void ShowRespawnCountdown()
1727 {
1728         float number;
1729         if(self.deadflag == DEAD_NO) // just respawned?
1730                 return;
1731         else
1732         {
1733                 number = ceil(self.death_time - time);
1734                 if(number <= 0)
1735                         return;
1736                 if(number <= self.respawn_countdown)
1737                 {
1738                         self.respawn_countdown = number - 1;
1739                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1740                                 announce(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1741                 }
1742         }
1743 }
1744
1745 void LeaveSpectatorMode()
1746 {
1747         if(isJoinAllowed()) {
1748                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1749                         self.classname = "player";
1750                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1751                                 JoinBestTeam(self, FALSE, TRUE);
1752                         if(cvar("g_campaign"))
1753                                 campaign_bots_may_start = 1;
1754                         PutClientInServer();
1755                         if(!(self.flags & FL_NOTARGET))
1756                                 bprint ("^4", self.netname, "^4 is playing now\n");
1757                         centerprint(self,"");
1758                         return;
1759                 } else {
1760                         stuffcmd(self,"menu_showteamselect\n");
1761                         return;
1762                 }
1763         }
1764         else {
1765                 //player may not join because of g_maxplayers is set
1766                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1767         }
1768 }
1769
1770 /**
1771  * Determines whether the player is allowed to join. This depends on cvar
1772  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1773  * it checks whether the number of currently playing players exceeds g_maxplayers.
1774  * @return bool TRUE if the player is allowed to join, false otherwise
1775  */
1776 float isJoinAllowed() {
1777         if (!cvar("g_maxplayers"))
1778                 return TRUE;
1779
1780         local entity e;
1781         local float currentlyPlaying;
1782         FOR_EACH_REALPLAYER(e) {
1783                 if(e.classname == "player")
1784                         currentlyPlaying += 1;
1785         }
1786         if(currentlyPlaying < cvar("g_maxplayers"))
1787                 return TRUE;
1788
1789         return FALSE;
1790 }
1791
1792 /**
1793  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1794  * g_maxplayers_spectator_blocktime seconds
1795  */
1796 void checkSpectatorBlock() {
1797         if(self.classname == "spectator" || self.classname == "observer") {
1798                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1799                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1800                         dropclient(self);
1801                 }
1802         }
1803 }
1804
1805 float vercmp_recursive(string v1, string v2)
1806 {
1807         float dot1, dot2;
1808         string s1, s2;
1809         float r;
1810
1811         dot1 = strstrofs(v1, ".", 0);
1812         dot2 = strstrofs(v2, ".", 0);
1813         if(dot1 == -1)
1814                 s1 = v1;
1815         else
1816                 s1 = substring(v1, 0, dot1);
1817         if(dot2 == -1)
1818                 s2 = v2;
1819         else
1820                 s2 = substring(v2, 0, dot2);
1821
1822         r = stof(s1) - stof(s2);
1823         if(r != 0)
1824                 return r;
1825
1826         r = strcasecmp(s1, s2);
1827         if(r != 0)
1828                 return r;
1829
1830         if(dot1 == -1)
1831                 if(dot2 == -1)
1832                         return 0;
1833                 else
1834                         return -1;
1835         else
1836                 if(dot2 == -1)
1837                         return 1;
1838                 else
1839                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1840 }
1841
1842 float vercmp(string v1, string v2)
1843 {
1844         if(strcasecmp(v1, v2) == 0) // early out check
1845                 return 0;
1846         return vercmp_recursive(v1, v2);
1847 }
1848
1849 void ObserverThink()
1850 {
1851         if (self.flags & FL_JUMPRELEASED) {
1852                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1853                         self.welcomemessage_time = 0;
1854                         self.flags = self.flags - FL_JUMPRELEASED;
1855                         LeaveSpectatorMode();
1856                         return;
1857                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
1858                         self.welcomemessage_time = 0;
1859                         self.flags = self.flags - FL_JUMPRELEASED;
1860                         if(SpectateNext() == 1) {
1861                                 self.classname = "spectator";
1862                         }
1863                 }
1864         } else {
1865                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
1866                         self.flags = self.flags | FL_JUMPRELEASED;
1867                 }
1868         }
1869         if(self.BUTTON_ZOOM)
1870                 self.wantswelcomemessage = 0;
1871         if(self.wantswelcomemessage)
1872                 PrintWelcomeMessage(self);
1873 }
1874
1875 void SpectatorThink()
1876 {
1877         if (self.flags & FL_JUMPRELEASED) {
1878                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1879                         self.welcomemessage_time = 0;
1880                         self.flags = self.flags - FL_JUMPRELEASED;
1881                         LeaveSpectatorMode();
1882                         return;
1883                 } else if(self.BUTTON_ATCK) {
1884                         self.welcomemessage_time = 0;
1885                         self.flags = self.flags - FL_JUMPRELEASED;
1886                         if(SpectateNext() == 1) {
1887                                 self.classname = "spectator";
1888                         } else {
1889                                 self.classname = "observer";
1890                                 PutClientInServer();
1891                         }
1892                 } else if (self.BUTTON_ATCK2) {
1893                         self.welcomemessage_time = 0;
1894                         self.flags = self.flags - FL_JUMPRELEASED;
1895                         self.classname = "observer";
1896                         PutClientInServer();
1897                 } else {
1898                         if(!SpectateUpdate())
1899                                 PutObserverInServer();
1900                 }
1901         } else {
1902                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
1903                         self.flags = self.flags | FL_JUMPRELEASED;
1904                 }
1905         }
1906         if(self.BUTTON_ZOOM)
1907                 self.wantswelcomemessage = 0;
1908         if(self.wantswelcomemessage)
1909                 PrintWelcomeMessage(self);
1910         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1911 }
1912
1913 /*
1914 =============
1915 PlayerPreThink
1916
1917 Called every frame for each client before the physics are run
1918 =============
1919 */
1920 void() ctf_setstatus;
1921 .float vote_nagtime;
1922 void PlayerPreThink (void)
1923 {
1924         if(blockSpectators)
1925                 checkSpectatorBlock();
1926
1927         if(self.netname_previous != self.netname)
1928         {
1929                 if(cvar("sv_eventlog"))
1930                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname), TRUE);
1931                 if(self.netname_previous)
1932                         strunzone(self.netname_previous);
1933                 self.netname_previous = strzone(self.netname);
1934         }
1935
1936         // version nagging
1937         if(self.version_nagtime)
1938                 if(self.cvar_g_nexuizversion)
1939                         if(time > self.version_nagtime)
1940                         {
1941                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1942                                 {
1943                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
1944                                         {
1945                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1946                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1947                                         }
1948                                         else
1949                                         {
1950                                                 float r;
1951                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
1952                                                 if(r < 0)
1953                                                 {
1954                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
1955                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
1956                                                 }
1957                                                 else if(r > 0)
1958                                                 {
1959                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1960                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1961                                                 }
1962                                         }
1963                                 }
1964                                 self.version_nagtime = 0;
1965                         }
1966
1967         // vote nagging
1968         if(self.cvar_scr_centertime)
1969                 if(time > self.vote_nagtime)
1970                 {
1971                         VoteNag();
1972                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1973                 }
1974
1975         // GOD MODE info
1976         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
1977         {
1978                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
1979                 self.max_armorvalue = 0;
1980         }
1981
1982         if(frametime)
1983                 antilag_record(self);
1984
1985         if(self.classname == "player") {
1986 //              if(self.netname == "Wazat")
1987 //                      bprint(self.classname, "\n");
1988
1989                 CheckRules_Player();
1990
1991                 if(self.BUTTON_INFO)
1992                         PrintWelcomeMessage(self);
1993
1994                 if(g_lms || !cvar("sv_spectate"))
1995                 if((time - self.jointime) <= cvar("welcome_message_time"))
1996                         PrintWelcomeMessage(self);
1997
1998                 if (intermission_running)
1999                 {
2000                         IntermissionThink ();   // otherwise a button could be missed between
2001                         return;                                 // the think tics
2002                 }
2003
2004                 if(self.teleport_time)
2005                 if(time > self.teleport_time)
2006                 {
2007                         self.teleport_time = 0;
2008                         self.effects = self.effects - (self.effects & EF_NODRAW);
2009                         if(self.weaponentity)
2010                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
2011                 }
2012
2013                 Nixnex_GiveCurrentWeapon();
2014
2015                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2016                         UpdateSelectedPlayer();
2017
2018                 //don't allow the player to turn around while game is paused!
2019                 if(timeoutStatus == 2) {
2020                         self.v_angle = self.lastV_angle;
2021                         self.angles = self.lastV_angle;
2022                         self.fixangle = TRUE;
2023                 }
2024
2025                 if (self.deadflag != DEAD_NO)
2026                 {
2027                         float button_pressed, force_respawn;
2028                         player_anim();
2029                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2030                         force_respawn = (g_lms || cvar("g_forced_respawn"));
2031                         if (self.deadflag == DEAD_DYING)
2032                         {
2033                                 if(force_respawn)
2034                                         self.deadflag = DEAD_RESPAWNING;
2035                                 else if(!button_pressed)
2036                                         self.deadflag = DEAD_DEAD;
2037                         }
2038                         else if (self.deadflag == DEAD_DEAD)
2039                         {
2040                                 if(button_pressed)
2041                                         self.deadflag = DEAD_RESPAWNABLE;
2042                         }
2043                         else if (self.deadflag == DEAD_RESPAWNABLE)
2044                         {
2045                                 if(!button_pressed)
2046                                         self.deadflag = DEAD_RESPAWNING;
2047                         }
2048                         else if (self.deadflag == DEAD_RESPAWNING)
2049                         {
2050                                 if(time > self.death_time)
2051                                 {
2052                                         self.death_time = time + 1; // only retry once a second
2053                                         respawn();
2054                                 }
2055                         }
2056                         ShowRespawnCountdown();
2057                         return;
2058                 }
2059
2060                 if((g_race || g_lms) && !self.deadflag && cvar("g_lms_campcheck_interval"))
2061                 {
2062                         vector dist;
2063
2064                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2065                         dist = self.oldorigin - self.origin;
2066                         dist_z = 0;
2067                         self.lms_traveled_distance += fabs(vlen(dist));
2068
2069                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
2070                         {
2071                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2072                                 self.lms_traveled_distance = 0;
2073                         }
2074
2075                         if(time > self.lms_nextcheck)
2076                         {
2077                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2078                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2079                                 {
2080                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2081                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2082                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2083                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2084                                 }
2085                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2086                                 self.lms_traveled_distance = 0;
2087                         }
2088                 }
2089
2090                 if (self.BUTTON_CROUCH && !self.hook.state)
2091                 {
2092                         if (!self.crouch)
2093                         {
2094                                 self.crouch = TRUE;
2095                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2096                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2097                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
2098                         }
2099                 }
2100                 else
2101                 {
2102                         if (self.crouch)
2103                         {
2104                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2105                                 if (!trace_startsolid)
2106                                 {
2107                                         self.crouch = FALSE;
2108                                         self.view_ofs = PL_VIEW_OFS;
2109                                         setsize (self, PL_MIN, PL_MAX);
2110                                 }
2111                         }
2112                 }
2113
2114                 FixPlayermodel();
2115
2116                 GrapplingHookFrame();
2117
2118                 W_WeaponFrame();
2119
2120                 {
2121                         float zoomfactor, zoomspeed, zoomdir;
2122                         zoomfactor = self.cvar_cl_zoomfactor;
2123                         if(zoomfactor < 1 || zoomfactor > 16)
2124                                 zoomfactor = 2.5;
2125                         zoomspeed = self.cvar_cl_zoomspeed;
2126                         if(zoomspeed >= 0) // < 0 is instant zoom
2127                                 if(zoomspeed < 0.5 || zoomspeed > 16)
2128                                         zoomspeed = 3.5;
2129
2130                         zoomdir = self.BUTTON_ZOOM;
2131                         if(self.BUTTON_ATCK2)
2132                                 if(self.weapon == WEP_NEX)
2133                                         if(!g_minstagib)
2134                                                 zoomdir = 1;
2135
2136                         if(zoomdir)
2137                                 self.has_zoomed = 1;
2138
2139                         if(self.has_zoomed)
2140                         {
2141                                 if(zoomspeed <= 0) // instant zoom
2142                                 {
2143                                         if(zoomdir)
2144                                                 self.viewzoom = 1 / zoomfactor;
2145                                         else
2146                                                 self.viewzoom = 1;
2147                                 }
2148                                 else
2149                                 {
2150                                         // geometric zoom would be:
2151                                         //   self.viewzoom = bound(1 / zoomfactor, self.viewzoom * pow(zoomfactor, (zoomdir ? -1 : 1) * frametime * zoomspeed), 1);
2152                                         // however, testing showed that arithmetic/harmonic zoom works better
2153                                         if(zoomdir)
2154                                                 // self.viewzoom = 1 / bound(1, 1 / self.viewzoom + (zoomdir ? 1 : -1) * frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2155                                                 // zoom in = arithmetic: 1x, 2x, 3x, 4x, ..., 8x
2156                                                 self.viewzoom = 1 / bound(1, 1 / self.viewzoom + frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2157                                         else
2158                                                 // self.viewzoom = bound(1 / zoomfactor, self.viewzoom + (zoomdir ? -1 : 1) * frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2159                                                 // zoom out = harmonic: 8/1x, 8/2x, 8/3x, 8/4x, ..., 8/8x
2160                                                 self.viewzoom = bound(1 / zoomfactor, self.viewzoom + frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2161                                 }
2162                         }
2163                         else
2164                                 self.viewzoom = min(1, self.viewzoom + frametime); // spawn zoom-in
2165                 }
2166
2167                 player_powerups();
2168                 player_regen();
2169                 player_anim();
2170
2171                 if (g_minstagib)
2172                         minstagib_ammocheck();
2173
2174                 ctf_setstatus();
2175                 kh_setstatus();
2176
2177                 //self.angles_y=self.v_angle_y + 90;   // temp
2178
2179                 //if (TetrisPreFrame()) return;
2180         } else if(gameover) {
2181                 if (intermission_running)
2182                         IntermissionThink ();   // otherwise a button could be missed between
2183                 return;
2184         } else if(self.classname == "observer") {
2185                 ObserverThink();
2186         } else if(self.classname == "spectator") {
2187                 SpectatorThink();
2188         }
2189 }
2190
2191
2192 /*
2193 =============
2194 PlayerPostThink
2195
2196 Called every frame for each client after the physics are run
2197 =============
2198 */
2199 .float idlekick_lasttimeleft;
2200 .float race_penalty;
2201 .float race_penalty_nagged;
2202 void PlayerPostThink (void)
2203 {
2204         // Savage: Check for nameless players
2205         if (strlen(self.netname) < 1) {
2206                 self.netname = "Player";
2207                 stuffcmd(self, "seta _cl_name Player\n");
2208         }
2209
2210         if(sv_maxidle)
2211         {
2212                 float timeleft;
2213                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2214                 if(timeleft <= 0)
2215                 {
2216                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2217                         announce(self, "announcer/robotic/terminated.ogg");
2218                         dropclient(self);
2219                         return;
2220                 }
2221                 else if(timeleft <= 10)
2222                 {
2223                         if(timeleft != self.idlekick_lasttimeleft)
2224                         {
2225                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2226                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".ogg"));
2227                         }
2228                 }
2229                 else
2230                 {
2231                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2232                 }
2233                 self.idlekick_lasttimeleft = timeleft;
2234         }
2235
2236         if(self.classname == "player") {
2237                 CheckRules_Player();
2238                 UpdateChatBubble();
2239                 UpdateTeamBubble();
2240                 if (self.impulse)
2241                         ImpulseCommands();
2242                 if (intermission_running)
2243                         return;         // intermission or finale
2244
2245                 //PrintWelcomeMessage(self);
2246                 //if (TetrisPostFrame()) return;
2247
2248                 // restart countdown
2249                 if (restart_countdown) {
2250                         if(time < restart_countdown) {
2251                                 if (!cvar("sv_ready_restart_after_countdown"))
2252                                 {
2253                                         if(self.movement != '0 0 0' && g_race && !g_race_qualifying)
2254                                         {
2255                                                 if(time < restart_countdown - 2)
2256                                                 {
2257                                                         if(!self.race_penalty_nagged)
2258                                                         {
2259                                                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1DO NOT MOVE DURING THE COUNTDOWN.");
2260                                                                 self.race_penalty_nagged = 1;
2261                                                         }
2262                                                 }
2263                                                 else if(!self.race_penalty)
2264                                                 {
2265                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1FIVE SECONDS PENALTY.");
2266                                                         self.race_penalty = time + 5;
2267                                                 }
2268                                         }
2269                                         self.movetype = MOVETYPE_NONE;
2270                                         self.velocity = '0 0 0';
2271                                         self.avelocity = '0 0 0';
2272                                         self.movement = '0 0 0';
2273                                 }
2274                         }
2275                         else if (time < self.race_penalty)
2276                         {
2277                                 self.movetype = MOVETYPE_NONE;
2278                                 self.velocity = '0 0 0';
2279                                 self.avelocity = '0 0 0';
2280                                 self.movement = '0 0 0';
2281                         }
2282                         else
2283                         {
2284                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2285                                 if (!cvar("sv_ready_restart_after_countdown"))
2286                                 {
2287                                         if(self.movetype == MOVETYPE_NONE)
2288                                         {
2289                                                 self.movetype = MOVETYPE_WALK;
2290                                         }
2291                                         self.race_penalty = 0;
2292                                         self.race_penalty_nagged = 0;
2293                                 }
2294                         }
2295                 }
2296
2297         } else if (self.classname == "observer") {
2298                 //do nothing
2299         } else if (self.classname == "spectator") {
2300                 //do nothing
2301         }
2302
2303         /*
2304         float i;
2305         for(i = 0; i < 1000; ++i)
2306         {
2307                 vector end;
2308                 end = self.origin + '0 0 1024' + 512 * randomvec();
2309                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2310                 if(trace_fraction < 1)
2311                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2312                 {
2313                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2314                         break;
2315                 }
2316         }
2317         */
2318
2319         Arena_Warmup();
2320 }