data/qcsrc/server/cl_client.qc

   1 // let's abuse an existing field
   2 #define SPAWNPOINT_SCORE frags
   3
   4 .float wantswelcomemessage;
   5 .string netname_previous;
   6
   7 void spawnfunc_info_player_survivor (void)
   8 {
   9         spawnfunc_info_player_deathmatch();
  10 }
  11
  12 void spawnfunc_info_player_start (void)
  13 {
  14         spawnfunc_info_player_deathmatch();
  15 }
  16
  17 void spawnfunc_info_player_deathmatch (void)
  18 {
  19         self.classname = "info_player_deathmatch";
  20         relocate_spawnpoint();
  21 }
  22
  23 void spawnpoint_use()
  24 {
  25         if(teams_matter)
  26         if(have_team_spawns)
  27         {
  28                 self.team = activator.team;
  29                 some_spawn_has_been_used = 1;
  30         }
  31 };
  32
  33 // Returns:
  34 //   -1 if a spawn can't be used
  35 //   otherwise, a weight of the spawnpoint
  36 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
  37 {
  38         float shortest, thisdist;
  39         entity player;
  40
  41         // filter out spots for the wrong team
  42         if(teamcheck)
  43         if(spot.team != teamcheck)
  44                 return -1;
  45
  46         if(race_spawns)
  47                 if(spot.target == "")
  48                         return -1;
  49
  50         // filter out spots for assault
  51         if(spot.target != "") {
  52                 local entity ent;
  53                 ent = find(world, targetname, spot.target);
  54                 if(!ent)
  55                 {
  56                         return -1;
  57                 }
  58                 while(ent) {
  59                         if(ent.classname == "target_objective")
  60                         {
  61                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  62                                         return -1;
  63                         }
  64                         else if(ent.classname == "trigger_race_checkpoint")
  65                         {
  66                                 if(self.classname == "player") // spectators may spawn everywhere
  67                                 if(ent.cnt != race_PreviousCheckpoint(self.race_checkpoint))
  68                                         // checkpoint -1 players (freshly spawned) spawn close to finish!
  69                                         return -1;
  70                         }
  71                         else
  72                         {
  73                         }
  74                         ent = find(ent, targetname, spot.target);
  75                 }
  76         }
  77
  78         player = playerlist;
  79         shortest = vlen(world.maxs - world.mins);
  80         for(player = playerlist; player; player = player.chain)
  81                 if (player != self)
  82                 {
  83                         thisdist = vlen(player.origin - spot.origin);
  84                         if (thisdist < shortest)
  85                                 shortest = thisdist;
  86                 }
  87         return shortest;
  88 }
  89
  90 float spawn_allbad;
  91 float spawn_allgood;
  92 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  93 {
  94         local entity spot, spotlist, spotlistend;
  95         spawn_allgood = TRUE;
  96         spawn_allbad = TRUE;
  97
  98         spotlist = world;
  99         spotlistend = world;
 100
 101         for(spot = firstspot; spot; spot = spot.chain)
 102         {
 103                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
 104
 105                 if(cvar("spawn_debugview"))
 106                 {
 107                         setmodel(spot, "models/runematch/rune.mdl");
 108                         if(spot.SPAWNPOINT_SCORE < mindist)
 109                         {
 110                                 spot.colormod = '1 0 0';
 111                                 spot.scale = 1;
 112                         }
 113                         else
 114                         {
 115                                 spot.colormod = '0 1 0';
 116                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
 117                         }
 118                 }
 119
 120                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 121                 {
 122                         if(spot.SPAWNPOINT_SCORE < mindist)
 123                         {
 124                                 // too short distance
 125                                 spawn_allgood = FALSE;
 126                         }
 127                         else
 128                         {
 129                                 // perfect
 130                                 spawn_allbad = FALSE;
 131
 132                                 if(spotlistend)
 133                                         spotlistend.chain = spot;
 134                                 spotlistend = spot;
 135                                 if(!spotlist)
 136                                         spotlist = spot;
 137
 138                                 /*
 139                                 if(teamcheck)
 140                                 if(spot.team != teamcheck)
 141                                         error("invalid spawn added");
 142
 143                                 print("added ", etos(spot), "\n");
 144                                 */
 145                         }
 146                 }
 147         }
 148         if(spotlistend)
 149                 spotlistend.chain = world;
 150
 151         /*
 152                 entity e;
 153                 if(teamcheck)
 154                         for(e = spotlist; e; e = e.chain)
 155                         {
 156                                 print("seen ", etos(e), "\n");
 157                                 if(e.team != teamcheck)
 158                                         error("invalid spawn found");
 159                         }
 160         */
 161
 162         return spotlist;
 163 }
 164
 165 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 166 {
 167         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 168         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 169         local entity spot;
 170
 171         RandomSelection_Init();
 172         for(spot = firstspot; spot; spot = spot.chain)
 173                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 174
 175         return RandomSelection_chosen_ent;
 176 }
 177
 178 /*
 179 =============
 180 SelectSpawnPoint
 181
 182 Finds a point to respawn
 183 =============
 184 */
 185 entity SelectSpawnPoint (float anypoint)
 186 {
 187         local float teamcheck;
 188         local entity firstspot_new;
 189         local entity spot, firstspot, playerlist;
 190
 191         spot = find (world, classname, "testplayerstart");
 192         if (spot)
 193                 return spot;
 194
 195         teamcheck = 0;
 196
 197         if(!anypoint && have_team_spawns)
 198                 teamcheck = self.team;
 199
 200         // get the list of players
 201         playerlist = findchain(classname, "player");
 202         // get the entire list of spots
 203         firstspot = findchain(classname, "info_player_deathmatch");
 204         // filter out the bad ones
 205         // (note this returns the original list if none survived)
 206         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 207         if(!firstspot_new)
 208                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 209         firstspot = firstspot_new;
 210
 211         // there is 50/50 chance of choosing a random spot or the furthest spot
 212         // (this means that roughly every other spawn will be furthest, so you
 213         // usually won't get fragged at spawn twice in a row)
 214         if (arena_roundbased)
 215         {
 216                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 217                 if(firstspot_new)
 218                         firstspot = firstspot_new;
 219                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 220         }
 221         else if (random() > cvar("g_spawn_furthest"))
 222                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 223         else
 224                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 225
 226         if(cvar("spawn_debugview"))
 227         {
 228                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 229
 230                 entity e;
 231                 if(teamcheck)
 232                         for(e = firstspot; e; e = e.chain)
 233                                 if(e.team != teamcheck)
 234                                         error("invalid spawn found");
 235         }
 236
 237         if (!spot)
 238         {
 239                 if(cvar("spawn_debug"))
 240                         GotoNextMap();
 241                 else
 242                 {
 243                         if(some_spawn_has_been_used)
 244                                 return world; // team can't spawn any more, because of actions of other team
 245                         else
 246                                 error("Cannot find a spawn point - please fix the map!");
 247                 }
 248         }
 249
 250         return spot;
 251 }
 252
 253 /*
 254 =============
 255 CheckPlayerModel
 256
 257 Checks if the argument string can be a valid playermodel.
 258 Returns a valid one in doubt.
 259 =============
 260 */
 261 string FallbackPlayerModel = "models/player/marine.zym";
 262 string CheckPlayerModel(string plyermodel) {
 263         if(strlen(plyermodel) < 4)
 264                 return FallbackPlayerModel;
 265         if( substring(plyermodel,0,14) != "models/player/")
 266                 return FallbackPlayerModel;
 267         else if(cvar("sv_servermodelsonly"))
 268         {
 269                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 270                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 271                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 272                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 273                         return FallbackPlayerModel;
 274                 if(!fexists(plyermodel))
 275                         return FallbackPlayerModel;
 276         }
 277         return plyermodel;
 278 }
 279
 280 /*
 281 =============
 282 Client_customizeentityforclient
 283
 284 LOD reduction
 285 =============
 286 */
 287 float Client_customizeentityforclient()
 288 {
 289 #ifdef ALLOW_VARIABLE_LOD
 290         // self: me
 291         // other: the player viewing me
 292         float distance;
 293         float f;
 294
 295         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 296                 return TRUE;
 297
 298         if(other.cvar_cl_playerdetailreduction <= 0)
 299         {
 300                 if(other.cvar_cl_playerdetailreduction <= -2)
 301                         self.modelindex = self.modelindex_lod2;
 302                 else if(other.cvar_cl_playerdetailreduction <= -1)
 303                         self.modelindex = self.modelindex_lod1;
 304                 else
 305                         self.modelindex = self.modelindex_lod0;
 306         }
 307         else
 308         {
 309                 distance = vlen(self.origin - other.origin);
 310                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 311                 if(f > 10000)
 312                         self.modelindex = self.modelindex_lod2;
 313                 else if(f > 5000)
 314                         self.modelindex = self.modelindex_lod1;
 315                 else
 316                         self.modelindex = self.modelindex_lod0;
 317         }
 318 #endif
 319
 320         return TRUE;
 321 }
 322
 323 void UpdatePlayerSounds();
 324 void setmodel_lod(entity e, string modelname)
 325 {
 326 #ifdef ALLOW_VARIABLE_LOD
 327         string s;
 328
 329         // FIXME: this only supports 3-letter extensions
 330         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 331         if(fexists(s))
 332         {
 333                 precache_model(s);
 334                 setmodel(e, s); // players have high precision
 335                 self.modelindex_lod1 = self.modelindex;
 336         }
 337         else
 338                 self.modelindex_lod1 = -1;
 339
 340         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 341         if(fexists(s))
 342         {
 343                 precache_model(s);
 344                 setmodel(e, s); // players have high precision
 345                 self.modelindex_lod2 = self.modelindex;
 346         }
 347         else
 348                 self.modelindex_lod2 = -1;
 349
 350         precache_model(modelname);
 351         setmodel(e, modelname); // players have high precision
 352         self.modelindex_lod0 = self.modelindex;
 353
 354         if(self.modelindex_lod1 < 0)
 355                 self.modelindex_lod1 = self.modelindex;
 356
 357         if(self.modelindex_lod2 < 0)
 358                 self.modelindex_lod2 = self.modelindex;
 359 #else
 360         precache_model(modelname);
 361         setmodel(e, modelname); // players have high precision
 362 #endif
 363         player_setupanimsformodel();
 364         UpdatePlayerSounds();
 365 }
 366
 367 /*
 368 =============
 369 PutObserverInServer
 370
 371 putting a client as observer in the server
 372 =============
 373 */
 374 void PutObserverInServer (void)
 375 {
 376         entity  spot;
 377         spot = SelectSpawnPoint (TRUE);
 378         if(!spot)
 379                 error("No spawnpoints for observers?!?\n");
 380         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 381
 382         if(clienttype(self) == CLIENTTYPE_REAL)
 383         {
 384                 msg_entity = self;
 385                 WriteByte(MSG_ONE, SVC_SETVIEW);
 386                 WriteEntity(MSG_ONE, self);
 387         }
 388
 389         DropAllRunes(self);
 390         kh_Key_DropAll(self, TRUE);
 391
 392         if(self.flagcarried)
 393                 DropFlag(self.flagcarried);
 394
 395         WaypointSprite_PlayerDead();
 396
 397         if(self.killcount != -666)
 398         {
 399                 if(g_lms)
 400                 {
 401                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 402                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 403                         else
 404                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 405                 }
 406                 else
 407                         bprint ("^4", self.netname, "^4 is spectating now\n");
 408         }
 409
 410         PlayerScore_Clear(self); // clear scores when needed
 411
 412         self.spectatortime = time;
 413
 414         self.classname = "observer";
 415         self.health = -666;
 416         self.takedamage = DAMAGE_NO;
 417         self.solid = SOLID_NOT;
 418         self.movetype = MOVETYPE_NOCLIP;
 419         self.flags = FL_CLIENT | FL_NOTARGET;
 420         self.armorvalue = 666;
 421         self.effects = 0;
 422         self.armorvalue = cvar("g_balance_armor_start");
 423         self.pauserotarmor_finished = 0;
 424         self.pauserothealth_finished = 0;
 425         self.pauseregen_finished = 0;
 426         self.damageforcescale = 0;
 427         self.death_time = 0;
 428         self.dead_frame = 0;
 429         self.alpha = 0;
 430         self.scale = 0;
 431         self.fade_time = 0;
 432         self.pain_frame = 0;
 433         self.pain_finished = 0;
 434         self.strength_finished = 0;
 435         self.invincible_finished = 0;
 436         self.pushltime = 0;
 437         self.think = SUB_Null;
 438         self.nextthink = 0;
 439         self.hook_time = 0;
 440         self.runes = 0;
 441         self.deadflag = DEAD_NO;
 442         self.angles = spot.angles;
 443         self.angles_z = 0;
 444         self.fixangle = TRUE;
 445         self.crouch = FALSE;
 446
 447         self.view_ofs = PL_VIEW_OFS;
 448         setorigin (self, spot.origin);
 449         setsize (self, '0 0 0', '0 0 0');
 450         self.oldorigin = self.origin;
 451         self.items = 0;
 452         self.model = "";
 453         self.modelindex = 0;
 454         self.weapon = 0;
 455         self.weaponmodel = "";
 456         self.weaponentity = world;
 457         self.killcount = -666;
 458         self.velocity = '0 0 0';
 459         self.avelocity = '0 0 0';
 460         self.punchangle = '0 0 0';
 461         self.punchvector = '0 0 0';
 462         self.oldvelocity = self.velocity;
 463         self.customizeentityforclient = Client_customizeentityforclient;
 464         self.viewzoom = 1;
 465         self.wantswelcomemessage = 1;
 466
 467         if(g_race)
 468                 race_PreparePlayer();
 469
 470         if(g_arena)
 471         {
 472                 if(self.version_mismatch)
 473                 {
 474                         Spawnqueue_Unmark(self);
 475                         Spawnqueue_Remove(self);
 476                 }
 477                 else
 478                 {
 479                         Spawnqueue_Insert(self);
 480                 }
 481         }
 482         else if(g_lms)
 483         {
 484                 // Only if the player cannot play at all
 485                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 486                         self.frags = -666;
 487                 else
 488                         self.frags = -667;
 489         }
 490         else
 491                 self.frags = -666;
 492 }
 493
 494 float RestrictSkin(float s)
 495 {
 496         if(!teams_matter)
 497                 return s;
 498         if(s == 6)
 499                 return 6;
 500         return mod(s, 3);
 501 }
 502
 503 void FixPlayermodel()
 504 {
 505         local string defaultmodel;
 506         local float defaultskin;
 507         local vector m1, m2;
 508
 509         defaultmodel = "";
 510
 511         if(cvar("sv_defaultcharacter") == 1) {
 512                 defaultskin = 0;
 513
 514                 if(teams_matter)
 515                 {
 516                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 517                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 518                 }
 519
 520                 if(defaultmodel == "")
 521                 {
 522                         defaultmodel = cvar_string("sv_defaultplayermodel");
 523                         defaultskin = cvar("sv_defaultplayerskin");
 524                 }
 525         }
 526
 527         if(defaultmodel != "")
 528         {
 529                 if (defaultmodel != self.model)
 530                 {
 531                         m1 = self.mins;
 532                         m2 = self.maxs;
 533                         setmodel_lod (self, defaultmodel);
 534                         setsize (self, m1, m2);
 535                 }
 536
 537                 self.skin = defaultskin;
 538         } else {
 539                 if (self.playermodel != self.model)
 540                 {
 541                         self.playermodel = CheckPlayerModel(self.playermodel);
 542                         m1 = self.mins;
 543                         m2 = self.maxs;
 544                         setmodel_lod (self, self.playermodel);
 545                         setsize (self, m1, m2);
 546                 }
 547
 548                 self.skin = RestrictSkin(stof(self.playerskin));
 549         }
 550
 551         if(!teams_matter)
 552                 if(strlen(cvar_string("sv_defaultplayercolors")))
 553                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 554                                 setcolor(self, cvar("sv_defaultplayercolors"));
 555 }
 556
 557 /*
 558 =============
 559 PutClientInServer
 560
 561 Called when a client spawns in the server
 562 =============
 563 */
 564 //void() ctf_playerchanged;
 565 void PutClientInServer (void)
 566 {
 567         if(clienttype(self) == CLIENTTYPE_BOT)
 568         {
 569                 self.classname = "player";
 570         }
 571         else if(clienttype(self) == CLIENTTYPE_REAL)
 572         {
 573                 msg_entity = self;
 574                 WriteByte(MSG_ONE, SVC_SETVIEW);
 575                 WriteEntity(MSG_ONE, self);
 576         }
 577
 578         // player is dead and becomes observer
 579         // FIXME fix LMS scoring for new system
 580         if(g_lms)
 581         {
 582                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 583                         self.classname = "observer";
 584         }
 585
 586         if(g_arena)
 587         if(!self.spawned)
 588                 self.classname = "observer";
 589
 590         if(self.classname == "player") {
 591                 entity  spot;
 592
 593                 if(g_race)
 594                         if(self.killcount == -666)
 595                                 race_PreparePlayer();
 596
 597                 spot = SelectSpawnPoint (FALSE);
 598                 if(!spot)
 599                 {
 600                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 601                         return; // spawn failed
 602                 }
 603
 604                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 605
 606                 self.classname = "player";
 607                 self.iscreature = TRUE;
 608                 self.movetype = MOVETYPE_WALK;
 609                 if(independent_players)
 610                         self.solid = SOLID_TRIGGER;
 611                 else
 612                         self.solid = SOLID_SLIDEBOX;
 613                 self.flags = FL_CLIENT;
 614                 self.takedamage = DAMAGE_AIM;
 615                 if(g_minstagib)
 616                         self.effects = EF_FULLBRIGHT;
 617                 else
 618                         self.effects = 0;
 619                 self.air_finished = time + 12;
 620                 self.dmg = 2;
 621
 622                 self.ammo_shells = start_ammo_shells;
 623                 self.ammo_nails = start_ammo_nails;
 624                 self.ammo_rockets = start_ammo_rockets;
 625                 self.ammo_cells = start_ammo_cells;
 626                 self.health = start_health;
 627                 self.armorvalue = start_armorvalue;
 628                 self.items = start_items;
 629                 self.switchweapon = start_switchweapon;
 630                 self.cnt = start_switchweapon;
 631                 self.weapon = 0;
 632                 self.jump_interval = time;
 633
 634                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 635                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 636                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 637                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 638                 //extend the pause of rotting if client was reset at the beginning of the countdown
 639                 if(!cvar("sv_ready_restart_after_countdown") && time < restart_countdown) {
 640                         self.spawnshieldtime += RESTART_COUNTDOWN;
 641                         self.pauserotarmor_finished += RESTART_COUNTDOWN;
 642                         self.pauserothealth_finished += RESTART_COUNTDOWN;
 643                         self.pauseregen_finished += RESTART_COUNTDOWN;
 644                 }
 645                 self.damageforcescale = 2;
 646                 self.death_time = 0;
 647                 self.dead_frame = 0;
 648                 self.alpha = 0;
 649                 self.scale = 0;
 650                 self.fade_time = 0;
 651                 self.pain_frame = 0;
 652                 self.pain_finished = 0;
 653                 self.strength_finished = 0;
 654                 self.invincible_finished = 0;
 655                 self.pushltime = 0;
 656                 //self.speed_finished = 0;
 657                 //self.slowmo_finished = 0;
 658                 // players have no think function
 659                 self.think = SUB_Null;
 660                 self.nextthink = 0;
 661                 self.hook_time = 0;
 662
 663                 self.runes = 0;
 664
 665                 self.deadflag = DEAD_NO;
 666
 667                 self.angles = spot.angles;
 668
 669                 self.angles_z = 0; // never spawn tilted even if the spot says to
 670                 self.fixangle = TRUE; // turn this way immediately
 671                 self.velocity = '0 0 0';
 672                 self.avelocity = '0 0 0';
 673                 self.punchangle = '0 0 0';
 674                 self.punchvector = '0 0 0';
 675                 self.oldvelocity = self.velocity;
 676
 677                 self.viewzoom = 0.6;
 678                 self.has_zoomed = 0;
 679
 680                 self.customizeentityforclient = Client_customizeentityforclient;
 681
 682                 self.model = "";
 683                 FixPlayermodel();
 684
 685                 self.crouch = FALSE;
 686                 self.view_ofs = PL_VIEW_OFS;
 687                 setsize (self, PL_MIN, PL_MAX);
 688                 self.spawnorigin = spot.origin;
 689                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 690                 // don't reset back to last position, even if new position is stuck in solid
 691                 self.oldorigin = self.origin;
 692
 693                 if(g_arena)
 694                 {
 695                         Spawnqueue_Remove(self);
 696                         Spawnqueue_Mark(self);
 697                 }
 698
 699                 self.event_damage = PlayerDamage;
 700
 701                 self.bot_attack = TRUE;
 702
 703                 self.statdraintime = time + 5;
 704                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 705
 706                 if(g_race)
 707                         if(self.killcount != -666)
 708                         {
 709                                 if(spot.target == "")
 710                                         // let the player run without timing, if he did not spawn at a targetting spawnpoint
 711                                         race_PreparePlayer();
 712                                 else
 713                                         race_RetractPlayer();
 714                         }
 715
 716                 if(self.killcount == -666) {
 717                         PlayerScore_Clear(self);
 718                         self.killcount = 0;
 719                         self.frags = 0;
 720                 }
 721
 722                 self.cnt = WEP_LASER;
 723                 self.nixnex_lastchange_id = -1;
 724
 725                 CL_SpawnWeaponentity();
 726                 self.alpha = default_player_alpha;
 727                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 728                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 729
 730                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 731                 self.lms_traveled_distance = 0;
 732                 self.speedrunning = FALSE;
 733
 734                 if(cvar("spawn_debug"))
 735                 {
 736                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 737                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 738                 }
 739
 740                 //stuffcmd(self, "chase_active 0");
 741                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 742
 743                 if (cvar("g_spawnsound"))
 744                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 745
 746                 if(g_assault) {
 747                         if(self.team == assault_attacker_team)
 748                                 centerprint(self, "You are attacking!\n");
 749                         else
 750                                 centerprint(self, "You are defending!\n");
 751                 }
 752
 753         } else if(self.classname == "observer") {
 754                 PutObserverInServer ();
 755         }
 756
 757         //if(g_ctf)
 758         //      ctf_playerchanged();
 759 }
 760
 761 /*
 762 =============
 763 SendCSQCInfo
 764
 765 Send whatever CSQC needs NOW and cannot wait for SendServerInfo to happen...
 766 =============
 767 */
 768 void SendCSQCInfo(void)
 769 {
 770         if(clienttype(self) != CLIENTTYPE_REAL)
 771                 return;
 772         msg_entity = self;
 773         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 774         WriteByte(MSG_ONE, TE_CSQC_INIT);
 775         WriteShort(MSG_ONE, CSQC_REVISION);
 776         WriteByte(MSG_ONE, maxclients);
 777 }
 778
 779 /*
 780 =============
 781 SetNewParms
 782 =============
 783 */
 784 void SetNewParms (void)
 785 {
 786         // initialize parms for a new player
 787         parm1 = -(86400 * 366);
 788 }
 789
 790 /*
 791 =============
 792 SetChangeParms
 793 =============
 794 */
 795 void SetChangeParms (void)
 796 {
 797         // save parms for level change
 798         parm1 = self.parm_idlesince - time;
 799 }
 800
 801 /*
 802 =============
 803 DecodeLevelParms
 804 =============
 805 */
 806 void DecodeLevelParms (void)
 807 {
 808         // load parms
 809         self.parm_idlesince = parm1;
 810         if(self.parm_idlesince == -(86400 * 366))
 811                 self.parm_idlesince = time;
 812 }
 813
 814 /*
 815 =============
 816 ClientKill
 817
 818 Called when a client types 'kill' in the console
 819 =============
 820 */
 821
 822 void ClientKill_Now_TeamChange()
 823 {
 824         if(self.killindicator_teamchange == -1)
 825         {
 826                 self.team = -1;
 827                 JoinBestTeam( self, FALSE, FALSE );
 828         }
 829         else
 830         {
 831                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 832         }
 833 }
 834
 835 void ClientKill_Now()
 836 {
 837         if(self.killindicator_teamchange)
 838                 ClientKill_Now_TeamChange();
 839
 840         // in any case:
 841         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 842
 843         if(self.killindicator)
 844         {
 845                 dprint("Cleaned up after a leaked kill indicator.\n");
 846                 remove(self.killindicator);
 847                 self.killindicator = world;
 848         }
 849 }
 850 void KillIndicator_Think()
 851 {
 852         if (!self.owner.modelindex)
 853         {
 854                 self.owner.killindicator = world;
 855                 remove(self);
 856                 return;
 857         }
 858
 859         if(self.cnt <= 0)
 860         {
 861                 self = self.owner;
 862                 ClientKill_Now(); // no oldself needed
 863                 return;
 864         }
 865         else
 866         {
 867                 if(self.cnt <= 10)
 868                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 869                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 870                 {
 871                         if(self.cnt <= 10)
 872                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 873                         if(self.owner.killindicator_teamchange)
 874                         {
 875                                 if(self.owner.killindicator_teamchange == -1)
 876                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 877                                 else
 878                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 879                         }
 880                         else
 881                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 882                 }
 883                 self.nextthink = time + 1;
 884                 self.cnt -= 1;
 885         }
 886 }
 887
 888 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 889 {
 890         float killtime;
 891         entity e;
 892         killtime = cvar("g_balance_kill_delay");
 893
 894         self.killindicator_teamchange = targetteam;
 895
 896         if(!self.killindicator)
 897         {
 898                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 899                 {
 900                         ClientKill_Now();
 901                 }
 902                 else
 903                 {
 904                         self.killindicator = spawn();
 905                         self.killindicator.owner = self;
 906                         self.killindicator.scale = 0.5;
 907                         setattachment(self.killindicator, self, "");
 908                         setorigin(self.killindicator, '0 0 52');
 909                         self.killindicator.think = KillIndicator_Think;
 910                         self.killindicator.nextthink = time + (self.lip) * 0.05;
 911                         self.killindicator.cnt = ceil(killtime);
 912                         self.killindicator.count = bound(0, ceil(killtime), 10);
 913                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 914
 915                         for(e = world; (e = find(e, classname, "body")) != world; )
 916                         {
 917                                 if(e.enemy != self)
 918                                         continue;
 919                                 e.killindicator = spawn();
 920                                 e.killindicator.owner = e;
 921                                 e.killindicator.scale = 0.5;
 922                                 setattachment(e.killindicator, e, "");
 923                                 setorigin(e.killindicator, '0 0 52');
 924                                 e.killindicator.think = KillIndicator_Think;
 925                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
 926                                 e.killindicator.cnt = ceil(killtime);
 927                         }
 928                         self.lip = 0;
 929                 }
 930         }
 931         if(self.killindicator)
 932         {
 933                 if(targetteam)
 934                         self.killindicator.colormod = TeamColor(targetteam);
 935                 else
 936                         self.killindicator.colormod = '0 0 0';
 937         }
 938 }
 939
 940 void ClientKill (void)
 941 {
 942         ClientKill_TeamChange(0);
 943 }
 944
 945 void DoTeamChange(float destteam)
 946 {
 947         float t, c0;
 948         if(!cvar("teamplay"))
 949         {
 950                 if(destteam >= 0)
 951                         SetPlayerColors(self, destteam);
 952                 return;
 953         }
 954         if(self.classname == "player")
 955         if(destteam == -1)
 956         {
 957                 CheckAllowedTeams(self);
 958                 t = FindSmallestTeam(self, TRUE);
 959                 switch(self.team)
 960                 {
 961                         case COLOR_TEAM1: c0 = c1; break;
 962                         case COLOR_TEAM2: c0 = c2; break;
 963                         case COLOR_TEAM3: c0 = c3; break;
 964                         case COLOR_TEAM4: c0 = c4; break;
 965                         default:          c0 = 999;
 966                 }
 967                 switch(t)
 968                 {
 969                         case 1:
 970                                 if(c0 > c1)
 971                                         destteam = COLOR_TEAM1;
 972                                 break;
 973                         case 2:
 974                                 if(c0 > c2)
 975                                         destteam = COLOR_TEAM2;
 976                                 break;
 977                         case 3:
 978                                 if(c0 > c3)
 979                                         destteam = COLOR_TEAM3;
 980                                 break;
 981                         case 4:
 982                                 if(c0 > c4)
 983                                         destteam = COLOR_TEAM4;
 984                                 break;
 985                 }
 986                 if(destteam == -1)
 987                         return;
 988         }
 989         if(destteam == self.team && !self.killindicator)
 990                 return;
 991         ClientKill_TeamChange(destteam);
 992 }
 993
 994 void FixClientCvars(entity e)
 995 {
 996         // send prediction settings to the client
 997         stuffcmd(e, "\nin_bindmap 0 0\n");
 998         /*
 999          * we no longer need to stuff this. Remove this comment block if you feel
1000          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1001         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1002         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1003         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1004         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1005         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1006         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1007         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1008         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1009         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1010         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1011         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1012         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1013         stuffcmd(e, "cl_movement_edgefriction 1\n");
1014          */
1015 }
1016
1017 /*
1018 =============
1019 ClientConnect
1020
1021 Called when a client connects to the server
1022 =============
1023 */
1024 //void ctf_clientconnect();
1025 string ColoredTeamName(float t);
1026 void DecodeLevelParms (void);
1027 //void dom_player_join_team(entity pl);
1028 void ClientConnect (void)
1029 {
1030         local string s;
1031         float wep;
1032
1033         if(self.flags & FL_CLIENT)
1034         {
1035                 print("Warning: ClientConnect, but already connected!\n");
1036                 return;
1037         }
1038
1039         if(Ban_IsClientBanned(self))
1040         {
1041                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
1042                 dropclient(self);
1043                 bprint(s);
1044                 return;
1045         }
1046
1047         DecodeLevelParms();
1048
1049         self.classname = "player_joining";
1050
1051         self.flags = self.flags | FL_CLIENT;
1052         self.version_nagtime = time + 10 + random() * 10;
1053
1054         if(player_count<0)
1055         {
1056                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1057                 player_count = 0;
1058         }
1059
1060         PlayerScore_Attach(self);
1061
1062         bot_clientconnect();
1063
1064         //if(g_domination)
1065         //      dom_player_join_team(self);
1066
1067         //JoinBestTeam(self, FALSE, FALSE);
1068
1069         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1070                 self.classname = "observer";
1071         } else {
1072                 self.classname = "player";
1073                 campaign_bots_may_start = 1;
1074         }
1075
1076         self.playerid = (playerid_last = playerid_last + 1);
1077         if(cvar("sv_eventlog"))
1078         {
1079                 if(clienttype(self) == CLIENTTYPE_REAL)
1080                         s = "player";
1081                 else
1082                         s = "bot";
1083                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
1084                 s = strcat(":team:", ftos(self.playerid), ":");
1085                 s = strcat(s, ftos(self.team));
1086                 GameLogEcho(s, FALSE);
1087         }
1088         self.netname_previous = strzone(self.netname);
1089
1090         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1091
1092         bprint ("^4",self.netname);
1093         bprint ("^4 connected");
1094
1095         if(g_domination || g_ctf)
1096         {
1097                 bprint(" and joined the ");
1098                 bprint(ColoredTeamName(self.team));
1099         }
1100
1101         bprint("\n");
1102
1103         self.welcomemessage_time = 0;
1104
1105         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1106         // TODO: is this being used for anything else than cd tracks?
1107         // Remember: SVC_CDTRACK exists. Maybe it should be used.
1108         //
1109         stuffcmd(self, "cl_particles_reloadeffects\n");
1110
1111         FixClientCvars(self);
1112
1113         // spawnfunc_waypoint sprites
1114         WaypointSprite_InitClient(self);
1115
1116         // Wazat's grappling hook
1117         SetGrappleHookBindings();
1118
1119         // get autoswitch state from player when he toggles it
1120         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1121
1122         // get version info from player
1123         stuffcmd(self, "cmd clientversion $gameversion\n");
1124
1125         // send all weapon info strings
1126         stuffcmd(self, "register_bestweapon clear\n"); // clear the Quake stuff
1127         wep = WEP_FIRST;
1128         while (wep <= WEP_LAST)
1129         {
1130                 weapon_action(wep, WR_REGISTER);
1131                 wep = wep + 1;
1132         }
1133
1134         // get other cvars from player
1135         GetCvars(0);
1136
1137         // set cvar for team scoreboard
1138         if (teams_matter)
1139         {
1140                 local float t;
1141                 t = cvar("teamplay");
1142                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1143                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1144         }
1145         else
1146                 stuffcmd(self, "set teamplay 0\n");
1147
1148         // notify about available teams
1149         if(teamplay)
1150         {
1151                 CheckAllowedTeams(self);
1152                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1153                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1154         }
1155         else
1156                 stuffcmd(self, "set _teams_available 0\n");
1157
1158         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1159
1160         if(g_arena)
1161         {
1162                 self.classname = "observer";
1163                 Spawnqueue_Insert(self);
1164         }
1165         /*else if(g_ctf)
1166         {
1167                 ctf_clientconnect();
1168         }*/
1169
1170         if(entcs_start)
1171                 attach_entcs();
1172
1173         bot_relinkplayerlist();
1174
1175         self.spectatortime = time;
1176         if(blockSpectators)
1177         {
1178                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1179         }
1180
1181         self.jointime = time;
1182         self.allowedTimeouts = cvar("sv_timeout_number");
1183
1184         if(clienttype(self) == CLIENTTYPE_REAL)
1185         {
1186                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1187                 SendCSQCInfo();
1188                 msg_entity = self;
1189                 if(mapvote_initialized && !cvar("g_maplist_textonly"))
1190                 {
1191                         MapVote_SendData(MSG_ONE);
1192                         MapVote_UpdateData(MSG_ONE);
1193                 }
1194                 ScoreInfo_Write(MSG_ONE);
1195         }
1196
1197         if(g_lms)
1198         {
1199                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1200                 {
1201                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1202                         self.frags = -666; // FIXME do we still need this?
1203                 }
1204         }
1205 }
1206
1207 /*
1208 =============
1209 ClientDisconnect
1210
1211 Called when a client disconnects from the server
1212 =============
1213 */
1214 void(entity e) DropFlag;
1215 .entity chatbubbleentity;
1216 .entity teambubbleentity;
1217 //void() ctf_clientdisconnect;
1218 void ClientDisconnect (void)
1219 {
1220         float save;
1221
1222         if not(self.flags & FL_CLIENT)
1223         {
1224                 print("Warning: ClientDisconnect without ClientConnect\n");
1225                 return;
1226         }
1227
1228         bot_clientdisconnect();
1229
1230         if(entcs_start)
1231                 detach_entcs();
1232
1233         if(cvar("sv_eventlog"))
1234                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
1235         bprint ("^4",self.netname);
1236         bprint ("^4 disconnected\n");
1237
1238         if (self.chatbubbleentity)
1239         {
1240                 remove (self.chatbubbleentity);
1241                 self.chatbubbleentity = world;
1242         }
1243
1244         if (self.teambubbleentity)
1245         {
1246                 remove (self.teambubbleentity);
1247                 self.teambubbleentity = world;
1248         }
1249
1250         if (self.killindicator)
1251         {
1252                 remove (self.killindicator);
1253                 self.killindicator = world;
1254         }
1255
1256         WaypointSprite_PlayerGone();
1257
1258         DropAllRunes(self);
1259         kh_Key_DropAll(self, TRUE);
1260
1261         if(self.flagcarried)
1262                 DropFlag(self.flagcarried);
1263
1264         save = self.flags;
1265         self.flags = self.flags - (self.flags & FL_CLIENT);
1266         bot_relinkplayerlist();
1267         self.flags = save;
1268
1269         // remove laserdot
1270         if(self.weaponentity)
1271                 if(self.weaponentity.lasertarget)
1272                         remove(self.weaponentity.lasertarget);
1273
1274         if(g_arena)
1275         {
1276                 Spawnqueue_Unmark(self);
1277                 Spawnqueue_Remove(self);
1278         }
1279         /*if(g_ctf)
1280         {
1281                 ctf_clientdisconnect();
1282         }
1283         */
1284
1285         PlayerScore_Detach(self);
1286
1287         if(self.netname_previous)
1288                 strunzone(self.netname_previous);
1289
1290         ClearPlayerSounds();
1291
1292         // free cvars
1293         GetCvars(-1);
1294         self.playerid = 0;
1295 }
1296
1297 .float BUTTON_CHAT;
1298 void ChatBubbleThink()
1299 {
1300         self.nextthink = time;
1301         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1302         {
1303                 self.owner.chatbubbleentity = world;
1304                 remove(self);
1305                 return;
1306         }
1307         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1308         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1309                 self.model = self.mdl;
1310         else
1311                 self.model = "";
1312 };
1313
1314 void UpdateChatBubble()
1315 {
1316         if (!self.modelindex)
1317                 return;
1318         // spawn a chatbubble entity if needed
1319         if (!self.chatbubbleentity)
1320         {
1321                 self.chatbubbleentity = spawn();
1322                 self.chatbubbleentity.owner = self;
1323                 self.chatbubbleentity.exteriormodeltoclient = self;
1324                 self.chatbubbleentity.think = ChatBubbleThink;
1325                 self.chatbubbleentity.nextthink = time;
1326                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1327                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1328                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1329                 self.chatbubbleentity.model = "";
1330                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1331         }
1332 }
1333
1334
1335 void TeamBubbleThink()
1336 {
1337         self.nextthink = time;
1338         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1339         {
1340                 self.owner.teambubbleentity = world;
1341                 remove(self);
1342                 return;
1343         }
1344 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1345         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1346                 self.model = "";
1347         else
1348                 self.model = self.mdl;
1349
1350 };
1351
1352 float TeamBubble_customizeentityforclient()
1353 {
1354         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1355 }
1356
1357 void UpdateTeamBubble()
1358 {
1359         if (!self.modelindex || !cvar("teamplay"))
1360                 return;
1361         // spawn a teambubble entity if needed
1362         if (!self.teambubbleentity && cvar("teamplay"))
1363         {
1364                 self.teambubbleentity = spawn();
1365                 self.teambubbleentity.owner = self;
1366                 self.teambubbleentity.exteriormodeltoclient = self;
1367                 self.teambubbleentity.think = TeamBubbleThink;
1368                 self.teambubbleentity.nextthink = time;
1369                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1370 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1371                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1372                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1373                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1374                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1375                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1376                 self.teambubbleentity.effects = EF_LOWPRECISION;
1377         }
1378 }
1379
1380 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1381 // added to the model skins
1382 /*void UpdateColorModHack()
1383 {
1384         local float c;
1385         c = self.clientcolors & 15;
1386         // LordHavoc: only bothering to support white, green, red, yellow, blue
1387              if (teamplay == 0) self.colormod = '0 0 0';
1388         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1389         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1390         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1391         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1392         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1393         else self.colormod = '1 1 1';
1394 };*/
1395
1396 void respawn(void)
1397 {
1398         CopyBody(1);
1399         self.effects |= EF_NODRAW; // prevent another CopyBody
1400         PutClientInServer();
1401 }
1402
1403 /**
1404  * When sv_timeout is used this function returs strings like
1405  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1406  * Called by centerprint functions
1407  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1408  */
1409 string getTimeoutText(float addOneSecond) {
1410         if (!cvar("sv_timeout") || !timeoutStatus)
1411                 return "";
1412
1413         local string retStr;
1414         if (timeoutStatus == 1) {
1415                 if (addOneSecond == 1) {
1416                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1417                 }
1418                 else {
1419                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1420                 }
1421                 return retStr;
1422         }
1423         else if (timeoutStatus == 2) {
1424                 if (addOneSecond) {
1425                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1426                         //don't show messages like "Timeout ends in 0 seconds"...
1427                         if ((remainingTimeoutTime + 1) > 0)
1428                                 return retStr;
1429                         else
1430                                 return "";
1431                 }
1432                 else {
1433                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1434                         //don't show messages like "Timeout ends in 0 seconds"...
1435                         if (remainingTimeoutTime > 0)
1436                                 return retStr;
1437                         else
1438                                 return "";
1439                 }
1440         }
1441         else return "";
1442 }
1443
1444 void player_powerups (void)
1445 {
1446         if (g_minstagib)
1447         {
1448                 if (self.items & IT_STRENGTH)
1449                 {
1450                         if (time > self.strength_finished)
1451                         {
1452                                 if (g_minstagib_invis_alpha > 0)
1453                                 {
1454                                         self.alpha = default_player_alpha;
1455                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1456                                         self.effects = self.effects | EF_FULLBRIGHT;
1457                                 }
1458                                 else
1459                                 {
1460                                         self.effects -= self.effects & EF_NODRAW;
1461                                 }
1462                                 self.items = self.items - (self.items & IT_STRENGTH);
1463                                 sprint(self, "^3Invisibility has worn off\n");
1464                         }
1465                 }
1466                 else
1467                 {
1468                         if (time < self.strength_finished)
1469                         {
1470                                 if (g_minstagib_invis_alpha > 0)
1471                                 {
1472                                         self.alpha = g_minstagib_invis_alpha;
1473                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1474                                         self.effects -= self.effects & EF_FULLBRIGHT;
1475                                 }
1476                                 else
1477                                 {
1478                                         self.effects = self.effects | EF_NODRAW;
1479                                 }
1480                                 self.items = self.items | IT_STRENGTH;
1481                                 sprint(self, "^3You are invisible\n");
1482                         }
1483                 }
1484
1485                 if (self.items & IT_INVINCIBLE)
1486                 {
1487                         if (time > self.invincible_finished)
1488                         {
1489                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1490                                 sprint(self, "^3Speed has worn off\n");
1491                         }
1492                 }
1493                 else
1494                 {
1495                         if (time < self.invincible_finished)
1496                         {
1497                                 self.items = self.items | IT_INVINCIBLE;
1498                                 sprint(self, "^3You are on speed\n");
1499                         }
1500                 }
1501                 return;
1502         }
1503
1504         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1505         if (self.items & IT_STRENGTH)
1506         {
1507                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1508                 if (time > self.strength_finished)
1509                 {
1510                         self.items = self.items - (self.items & IT_STRENGTH);
1511                         sprint(self, "^3Strength has worn off\n");
1512                 }
1513         }
1514         else
1515         {
1516                 if (time < self.strength_finished)
1517                 {
1518                         self.items = self.items | IT_STRENGTH;
1519                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1520                 }
1521         }
1522         if (self.items & IT_INVINCIBLE)
1523         {
1524                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1525                 if (time > self.invincible_finished)
1526                 {
1527                         self.items = self.items - (self.items & IT_INVINCIBLE);
1528                         sprint(self, "^3Shield has worn off\n");
1529                 }
1530         }
1531         else
1532         {
1533                 if (time < self.invincible_finished)
1534                 {
1535                         self.items = self.items | IT_INVINCIBLE;
1536                         sprint(self, "^3Shield surrounds you\n");
1537                 }
1538         }
1539
1540         if (cvar("g_fullbrightplayers"))
1541                 self.effects = self.effects | EF_FULLBRIGHT;
1542
1543         // midair gamemode: damage only while in the air
1544         // if in midair mode, being on ground grants temporary invulnerability
1545         // (this is so that multishot weapon don't clear the ground flag on the
1546         // first damage in the frame, leaving the player vulnerable to the
1547         // remaining hits in the same frame)
1548         if (self.flags & FL_ONGROUND)
1549         if (g_midair)
1550                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1551
1552         if (time < self.spawnshieldtime)
1553                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1554 }
1555
1556 float CalcRegen(float current, float stable, float regenfactor)
1557 {
1558         if(current > stable)
1559                 return current;
1560         else if(current > stable - 0.25) // when close enough, "snap"
1561                 return stable;
1562         else
1563                 return min(stable, current + (stable - current) * regenfactor * frametime);
1564 }
1565
1566 void player_regen (void)
1567 {
1568         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1569         maxh = cvar("g_balance_health_stable");
1570         maxa = cvar("g_balance_armor_stable");
1571         limith = cvar("g_balance_health_limit");
1572         limita = cvar("g_balance_armor_limit");
1573
1574         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1575                 return;
1576
1577         max_mod = regen_mod = rot_mod = limit_mod = 1;
1578
1579         if (self.runes & RUNE_REGEN)
1580         {
1581                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1582                 {
1583                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1584                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1585                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1586                 }
1587                 else
1588                 {
1589                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1590                         max_mod = cvar("g_balance_rune_regen_hpmod");
1591                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1592                 }
1593         }
1594         else if (self.runes & CURSE_VENOM)
1595         {
1596                 max_mod = cvar("g_balance_curse_venom_hpmod");
1597                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1598                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1599                 else
1600                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1601                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1602                 //if (!self.runes & RUNE_REGEN)
1603                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1604         }
1605         maxh = maxh * max_mod;
1606         //maxa = maxa * max_mod;
1607         limith = limith * limit_mod;
1608         limita = limita * limit_mod;
1609
1610         if (self.armorvalue > maxa)
1611         {
1612                 if (time > self.pauserotarmor_finished)
1613                 {
1614                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1615                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1616                 }
1617         }
1618         else if (self.armorvalue < maxa)
1619         {
1620                 if (time > self.pauseregen_finished)
1621                 {
1622                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1623                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1624                 }
1625         }
1626         if (self.health > maxh)
1627         {
1628                 if (time > self.pauserothealth_finished)
1629                 {
1630                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1631                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1632                 }
1633         }
1634         else if (self.health < maxh)
1635         {
1636                 if (time > self.pauseregen_finished)
1637                 {
1638                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1639                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1640                 }
1641         }
1642
1643         if (self.health > limith)
1644                 self.health = limith;
1645         if (self.armorvalue > limita)
1646                 self.armorvalue = limita;
1647
1648         // if player rotted to death...  die!
1649         if(self.health < 1)
1650                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1651 }
1652
1653 /*
1654 ======================
1655 spectate mode routines
1656 ======================
1657 */
1658 void SpectateCopy(entity spectatee) {
1659         self.armortype = spectatee.armortype;
1660         self.armorvalue = spectatee.armorvalue;
1661         self.currentammo = spectatee.currentammo;
1662         self.effects = spectatee.effects;
1663         self.health = spectatee.health;
1664         self.impulse = 0;
1665         self.items = spectatee.items;
1666         self.punchangle = spectatee.punchangle;
1667         self.view_ofs = spectatee.view_ofs;
1668         self.v_angle = spectatee.v_angle;
1669         self.viewzoom = spectatee.viewzoom;
1670         self.velocity = spectatee.velocity;
1671         self.dmg_take = spectatee.dmg_take;
1672         self.dmg_save = spectatee.dmg_save;
1673         self.dmg_inflictor = spectatee.dmg_inflictor;
1674         self.angles = spectatee.v_angle;
1675         self.fixangle = TRUE;
1676         setorigin(self, spectatee.origin);
1677         setsize(self, spectatee.mins, spectatee.maxs);
1678 }
1679
1680 float SpectateUpdate() {
1681         if(!self.enemy)
1682                 return 0;
1683
1684         if (self == self.enemy)
1685                 return 0;
1686
1687         if(self.enemy.flags & FL_NOTARGET)
1688                 return 0;
1689
1690         SpectateCopy(self.enemy);
1691
1692         return 1;
1693 }
1694
1695 float SpectateNext() {
1696         other = find(self.enemy, classname, "player");
1697         if (!other) {
1698                 other = find(other, classname, "player");
1699         }
1700         if (other) {
1701                 self.enemy = other;
1702         }
1703         if(self.enemy.classname == "player") {
1704                 msg_entity = self;
1705                 WriteByte(MSG_ONE, SVC_SETVIEW);
1706                 WriteEntity(MSG_ONE, self.enemy);
1707                 self.wantswelcomemessage = 1;
1708                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1709                 if(!SpectateUpdate())
1710                         PutObserverInServer();
1711                 return 1;
1712         } else {
1713                 return 0;
1714         }
1715 }
1716
1717 /*
1718 =============
1719 ShowRespawnCountdown()
1720
1721 Update a respawn countdown display.
1722 =============
1723 */
1724 void ShowRespawnCountdown()
1725 {
1726         float number;
1727         if(self.deadflag == DEAD_NO) // just respawned?
1728                 return;
1729         else
1730         {
1731                 number = ceil(self.death_time - time);
1732                 if(number <= 0)
1733                         return;
1734                 if(number <= self.respawn_countdown)
1735                 {
1736                         self.respawn_countdown = number - 1;
1737                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1738                                 announce(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1739                 }
1740         }
1741 }
1742
1743 void LeaveSpectatorMode()
1744 {
1745         if(isJoinAllowed()) {
1746                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1747                         self.classname = "player";
1748                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1749                                 JoinBestTeam(self, FALSE, TRUE);
1750                         if(cvar("g_campaign"))
1751                                 campaign_bots_may_start = 1;
1752                         PutClientInServer();
1753                         if(!(self.flags & FL_NOTARGET))
1754                                 bprint ("^4", self.netname, "^4 is playing now\n");
1755                         centerprint(self,"");
1756                         return;
1757                 } else {
1758                         stuffcmd(self,"menu_showteamselect\n");
1759                         return;
1760                 }
1761         }
1762         else {
1763                 //player may not join because of g_maxplayers is set
1764                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1765         }
1766 }
1767
1768 /**
1769  * Determines whether the player is allowed to join. This depends on cvar
1770  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1771  * it checks whether the number of currently playing players exceeds g_maxplayers.
1772  * @return bool TRUE if the player is allowed to join, false otherwise
1773  */
1774 float isJoinAllowed() {
1775         if (!cvar("g_maxplayers"))
1776                 return TRUE;
1777
1778         local entity e;
1779         local float currentlyPlaying;
1780         FOR_EACH_REALPLAYER(e) {
1781                 if(e.classname == "player")
1782                         currentlyPlaying += 1;
1783         }
1784         if(currentlyPlaying < cvar("g_maxplayers"))
1785                 return TRUE;
1786
1787         return FALSE;
1788 }
1789
1790 /**
1791  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1792  * g_maxplayers_spectator_blocktime seconds
1793  */
1794 void checkSpectatorBlock() {
1795         if(self.classname == "spectator" || self.classname == "observer") {
1796                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1797                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1798                         dropclient(self);
1799                 }
1800         }
1801 }
1802
1803 float vercmp_recursive(string v1, string v2)
1804 {
1805         float dot1, dot2;
1806         string s1, s2;
1807         float r;
1808
1809         dot1 = strstrofs(v1, ".", 0);
1810         dot2 = strstrofs(v2, ".", 0);
1811         if(dot1 == -1)
1812                 s1 = v1;
1813         else
1814                 s1 = substring(v1, 0, dot1);
1815         if(dot2 == -1)
1816                 s2 = v2;
1817         else
1818                 s2 = substring(v2, 0, dot2);
1819
1820         r = stof(s1) - stof(s2);
1821         if(r != 0)
1822                 return r;
1823
1824         r = strcasecmp(s1, s2);
1825         if(r != 0)
1826                 return r;
1827
1828         if(dot1 == -1)
1829                 if(dot2 == -1)
1830                         return 0;
1831                 else
1832                         return -1;
1833         else
1834                 if(dot2 == -1)
1835                         return 1;
1836                 else
1837                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1838 }
1839
1840 float vercmp(string v1, string v2)
1841 {
1842         if(strcasecmp(v1, v2) == 0) // early out check
1843                 return 0;
1844         return vercmp_recursive(v1, v2);
1845 }
1846
1847 void ObserverThink()
1848 {
1849         if (self.flags & FL_JUMPRELEASED) {
1850                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1851                         self.welcomemessage_time = 0;
1852                         self.flags = self.flags - FL_JUMPRELEASED;
1853                         LeaveSpectatorMode();
1854                         return;
1855                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
1856                         self.welcomemessage_time = 0;
1857                         self.flags = self.flags - FL_JUMPRELEASED;
1858                         if(SpectateNext() == 1) {
1859                                 self.classname = "spectator";
1860                         }
1861                 }
1862         } else {
1863                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
1864                         self.flags = self.flags | FL_JUMPRELEASED;
1865                 }
1866         }
1867         if(self.BUTTON_ZOOM)
1868                 self.wantswelcomemessage = 0;
1869         if(self.wantswelcomemessage)
1870                 PrintWelcomeMessage(self);
1871 }
1872
1873 void SpectatorThink()
1874 {
1875         if (self.flags & FL_JUMPRELEASED) {
1876                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1877                         self.welcomemessage_time = 0;
1878                         self.flags = self.flags - FL_JUMPRELEASED;
1879                         LeaveSpectatorMode();
1880                         return;
1881                 } else if(self.BUTTON_ATCK) {
1882                         self.welcomemessage_time = 0;
1883                         self.flags = self.flags - FL_JUMPRELEASED;
1884                         if(SpectateNext() == 1) {
1885                                 self.classname = "spectator";
1886                         } else {
1887                                 self.classname = "observer";
1888                                 PutClientInServer();
1889                         }
1890                 } else if (self.BUTTON_ATCK2) {
1891                         self.welcomemessage_time = 0;
1892                         self.flags = self.flags - FL_JUMPRELEASED;
1893                         self.classname = "observer";
1894                         PutClientInServer();
1895                 } else {
1896                         if(!SpectateUpdate())
1897                                 PutObserverInServer();
1898                 }
1899         } else {
1900                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
1901                         self.flags = self.flags | FL_JUMPRELEASED;
1902                 }
1903         }
1904         if(self.BUTTON_ZOOM)
1905                 self.wantswelcomemessage = 0;
1906         if(self.wantswelcomemessage)
1907                 PrintWelcomeMessage(self);
1908         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1909 }
1910
1911 /*
1912 =============
1913 PlayerPreThink
1914
1915 Called every frame for each client before the physics are run
1916 =============
1917 */
1918 void() ctf_setstatus;
1919 .float vote_nagtime;
1920 void PlayerPreThink (void)
1921 {
1922         if(blockSpectators)
1923                 checkSpectatorBlock();
1924
1925         if(self.netname_previous != self.netname)
1926         {
1927                 if(cvar("sv_eventlog"))
1928                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname), TRUE);
1929                 if(self.netname_previous)
1930                         strunzone(self.netname_previous);
1931                 self.netname_previous = strzone(self.netname);
1932         }
1933
1934         // version nagging
1935         if(self.version_nagtime)
1936                 if(self.cvar_g_nexuizversion)
1937                         if(time > self.version_nagtime)
1938                         {
1939                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1940                                 {
1941                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
1942                                         {
1943                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1944                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1945                                         }
1946                                         else
1947                                         {
1948                                                 float r;
1949                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
1950                                                 if(r < 0)
1951                                                 {
1952                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
1953                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
1954                                                 }
1955                                                 else if(r > 0)
1956                                                 {
1957                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1958                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1959                                                 }
1960                                         }
1961                                 }
1962                                 self.version_nagtime = 0;
1963                         }
1964
1965         // vote nagging
1966         if(self.cvar_scr_centertime)
1967                 if(time > self.vote_nagtime)
1968                 {
1969                         VoteNag();
1970                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1971                 }
1972
1973         // GOD MODE info
1974         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
1975         {
1976                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
1977                 self.max_armorvalue = 0;
1978         }
1979
1980         if(frametime)
1981                 antilag_record(self);
1982
1983         if(self.classname == "player") {
1984 //              if(self.netname == "Wazat")
1985 //                      bprint(self.classname, "\n");
1986
1987                 CheckRules_Player();
1988
1989                 if(self.BUTTON_INFO)
1990                         PrintWelcomeMessage(self);
1991
1992                 if(g_lms || !cvar("sv_spectate"))
1993                 if((time - self.jointime) <= cvar("welcome_message_time"))
1994                         PrintWelcomeMessage(self);
1995
1996                 if (intermission_running)
1997                 {
1998                         IntermissionThink ();   // otherwise a button could be missed between
1999                         return;                                 // the think tics
2000                 }
2001
2002                 if(self.teleport_time)
2003                 if(time > self.teleport_time)
2004                 {
2005                         self.teleport_time = 0;
2006                         self.effects = self.effects - (self.effects & EF_NODRAW);
2007                         if(self.weaponentity)
2008                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
2009                 }
2010
2011                 Nixnex_GiveCurrentWeapon();
2012
2013                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2014                         UpdateSelectedPlayer();
2015
2016                 //don't allow the player to turn around while game is paused!
2017                 if(timeoutStatus == 2) {
2018                         self.v_angle = self.lastV_angle;
2019                         self.angles = self.lastV_angle;
2020                         self.fixangle = TRUE;
2021                 }
2022
2023                 if (self.deadflag != DEAD_NO)
2024                 {
2025                         float button_pressed, force_respawn;
2026                         player_anim();
2027                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2028                         force_respawn = (g_lms || cvar("g_forced_respawn"));
2029                         if (self.deadflag == DEAD_DYING)
2030                         {
2031                                 if(force_respawn)
2032                                         self.deadflag = DEAD_RESPAWNING;
2033                                 else if(!button_pressed)
2034                                         self.deadflag = DEAD_DEAD;
2035                         }
2036                         else if (self.deadflag == DEAD_DEAD)
2037                         {
2038                                 if(button_pressed)
2039                                         self.deadflag = DEAD_RESPAWNABLE;
2040                         }
2041                         else if (self.deadflag == DEAD_RESPAWNABLE)
2042                         {
2043                                 if(!button_pressed)
2044                                         self.deadflag = DEAD_RESPAWNING;
2045                         }
2046                         else if (self.deadflag == DEAD_RESPAWNING)
2047                         {
2048                                 if(time > self.death_time)
2049                                 {
2050                                         self.death_time = time + 1; // only retry once a second
2051                                         respawn();
2052                                 }
2053                         }
2054                         ShowRespawnCountdown();
2055                         return;
2056                 }
2057
2058                 if((g_race || g_lms) && !self.deadflag && cvar("g_lms_campcheck_interval"))
2059                 {
2060                         vector dist;
2061
2062                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2063                         dist = self.oldorigin - self.origin;
2064                         dist_z = 0;
2065                         self.lms_traveled_distance += fabs(vlen(dist));
2066
2067                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
2068                         {
2069                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2070                                 self.lms_traveled_distance = 0;
2071                         }
2072
2073                         if(time > self.lms_nextcheck)
2074                         {
2075                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2076                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2077                                 {
2078                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2079                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2080                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2081                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2082                                 }
2083                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2084                                 self.lms_traveled_distance = 0;
2085                         }
2086                 }
2087
2088                 if (self.BUTTON_CROUCH && !self.hook.state)
2089                 {
2090                         if (!self.crouch)
2091                         {
2092                                 self.crouch = TRUE;
2093                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2094                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2095                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
2096                         }
2097                 }
2098                 else
2099                 {
2100                         if (self.crouch)
2101                         {
2102                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2103                                 if (!trace_startsolid)
2104                                 {
2105                                         self.crouch = FALSE;
2106                                         self.view_ofs = PL_VIEW_OFS;
2107                                         setsize (self, PL_MIN, PL_MAX);
2108                                 }
2109                         }
2110                 }
2111
2112                 FixPlayermodel();
2113
2114                 GrapplingHookFrame();
2115
2116                 W_WeaponFrame();
2117
2118                 {
2119                         float zoomfactor, zoomspeed, zoomdir;
2120                         zoomfactor = self.cvar_cl_zoomfactor;
2121                         if(zoomfactor < 1 || zoomfactor > 16)
2122                                 zoomfactor = 2.5;
2123                         zoomspeed = self.cvar_cl_zoomspeed;
2124                         if(zoomspeed >= 0) // < 0 is instant zoom
2125                                 if(zoomspeed < 0.5 || zoomspeed > 16)
2126                                         zoomspeed = 3.5;
2127
2128                         zoomdir = self.BUTTON_ZOOM;
2129                         if(self.BUTTON_ATCK2)
2130                                 if(self.weapon == WEP_NEX)
2131                                         if(!g_minstagib)
2132                                                 zoomdir = 1;
2133
2134                         if(zoomdir)
2135                                 self.has_zoomed = 1;
2136
2137                         if(self.has_zoomed)
2138                         {
2139                                 if(zoomspeed <= 0) // instant zoom
2140                                 {
2141                                         if(zoomdir)
2142                                                 self.viewzoom = 1 / zoomfactor;
2143                                         else
2144                                                 self.viewzoom = 1;
2145                                 }
2146                                 else
2147                                 {
2148                                         // geometric zoom would be:
2149                                         //   self.viewzoom = bound(1 / zoomfactor, self.viewzoom * pow(zoomfactor, (zoomdir ? -1 : 1) * frametime * zoomspeed), 1);
2150                                         // however, testing showed that arithmetic/harmonic zoom works better
2151                                         if(zoomdir)
2152                                                 // self.viewzoom = 1 / bound(1, 1 / self.viewzoom + (zoomdir ? 1 : -1) * frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2153                                                 // zoom in = arithmetic: 1x, 2x, 3x, 4x, ..., 8x
2154                                                 self.viewzoom = 1 / bound(1, 1 / self.viewzoom + frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2155                                         else
2156                                                 // self.viewzoom = bound(1 / zoomfactor, self.viewzoom + (zoomdir ? -1 : 1) * frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2157                                                 // zoom out = harmonic: 8/1x, 8/2x, 8/3x, 8/4x, ..., 8/8x
2158                                                 self.viewzoom = bound(1 / zoomfactor, self.viewzoom + frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2159                                 }
2160                         }
2161                         else
2162                                 self.viewzoom = min(1, self.viewzoom + frametime); // spawn zoom-in
2163                 }
2164
2165                 player_powerups();
2166                 player_regen();
2167                 player_anim();
2168
2169                 if (g_minstagib)
2170                         minstagib_ammocheck();
2171
2172                 ctf_setstatus();
2173                 kh_setstatus();
2174
2175                 //self.angles_y=self.v_angle_y + 90;   // temp
2176
2177                 //if (TetrisPreFrame()) return;
2178         } else if(gameover) {
2179                 if (intermission_running)
2180                         IntermissionThink ();   // otherwise a button could be missed between
2181                 return;
2182         } else if(self.classname == "observer") {
2183                 ObserverThink();
2184         } else if(self.classname == "spectator") {
2185                 SpectatorThink();
2186         }
2187 }
2188
2189
2190 /*
2191 =============
2192 PlayerPostThink
2193
2194 Called every frame for each client after the physics are run
2195 =============
2196 */
2197 .float idlekick_lasttimeleft;
2198 void PlayerPostThink (void)
2199 {
2200         // Savage: Check for nameless players
2201         if (strlen(self.netname) < 1) {
2202                 self.netname = "Player";
2203                 stuffcmd(self, "seta _cl_name Player\n");
2204         }
2205
2206         if(sv_maxidle)
2207         {
2208                 float timeleft;
2209                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2210                 if(timeleft <= 0)
2211                 {
2212                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2213                         announce(self, "announcer/robotic/terminated.ogg");
2214                         dropclient(self);
2215                         return;
2216                 }
2217                 else if(timeleft <= 10)
2218                 {
2219                         if(timeleft != self.idlekick_lasttimeleft)
2220                         {
2221                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2222                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".ogg"));
2223                         }
2224                 }
2225                 else
2226                 {
2227                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2228                 }
2229                 self.idlekick_lasttimeleft = timeleft;
2230         }
2231
2232         if(self.classname == "player") {
2233                 CheckRules_Player();
2234                 UpdateChatBubble();
2235                 UpdateTeamBubble();
2236                 if (self.impulse)
2237                         ImpulseCommands();
2238                 if (intermission_running)
2239                         return;         // intermission or finale
2240
2241                 //PrintWelcomeMessage(self);
2242                 //if (TetrisPostFrame()) return;
2243
2244                 // restart countdown
2245                 if (restart_countdown) {
2246                         if(time < restart_countdown) {
2247                                 if (!cvar("sv_ready_restart_after_countdown"))
2248                                 {
2249                                         self.movetype = MOVETYPE_NONE;
2250                                         self.velocity = '0 0 0';
2251                                         self.avelocity = '0 0 0';
2252                                         self.movement = '0 0 0';
2253                                 }
2254                         }
2255                         else
2256                         {
2257                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2258                                 if (!cvar("sv_ready_restart_after_countdown"))
2259                                 {
2260                                         if(self.movetype == MOVETYPE_NONE)
2261                                         {
2262                                                 self.movetype = MOVETYPE_WALK;
2263                                         }
2264                                 }
2265                         }
2266                 }
2267
2268         } else if (self.classname == "observer") {
2269                 //do nothing
2270         } else if (self.classname == "spectator") {
2271                 //do nothing
2272         }
2273
2274         /*
2275         float i;
2276         for(i = 0; i < 1000; ++i)
2277         {
2278                 vector end;
2279                 end = self.origin + '0 0 1024' + 512 * randomvec();
2280                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2281                 if(trace_fraction < 1)
2282                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2283                 {
2284                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2285                         break;
2286                 }
2287         }
2288         */
2289
2290         Arena_Warmup();
2291 }