data/qcsrc/server/cl_client.qc

   1 .float spectatee_status;
   2 .float zoomstate;
   3 .float bloodloss_timer;
   4
   5 .entity clientdata;
   6 float ClientData_Send(entity to, float sf)
   7 {
   8         if(to != self.owner)
   9         {
  10                 error("wtf");
  11                 return FALSE;
  12         }
  13
  14         entity e;
  15
  16         e = to;
  17         if(to.classname == "spectator")
  18                 e = to.enemy;
  19
  20         sf = 0;
  21
  22         if(e.race_completed)
  23                 sf |= 1; // forced scoreboard
  24         if(to.spectatee_status)
  25                 sf |= 2; // spectator ent number follows
  26         if(e.zoomstate)
  27                 sf |= 4; // zoomed
  28         if(e.porto_v_angle_held)
  29                 sf |= 8; // angles held
  30
  31         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  32         WriteByte(MSG_ENTITY, sf);
  33
  34         if(sf & 2)
  35                 WriteByte(MSG_ENTITY, to.spectatee_status);
  36
  37         if(sf & 8)
  38         {
  39                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  40                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  41         }
  42
  43         return TRUE;
  44 }
  45
  46 void ClientData_Attach()
  47 {
  48         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  49         self.clientdata.drawonlytoclient = self;
  50         self.clientdata.owner = self;
  51 }
  52
  53 void ClientData_Detach()
  54 {
  55         remove(self.clientdata);
  56         self.clientdata = world;
  57 }
  58
  59 void ClientData_Touch(entity e)
  60 {
  61         e.clientdata.SendFlags = 1;
  62
  63         // make it spectatable
  64         entity e2;
  65         FOR_EACH_REALCLIENT(e2)
  66         {
  67                 if(e2 != e)
  68                         if(e2.classname == "spectator")
  69                                 if(e2.enemy == e)
  70                                         e2.clientdata.SendFlags = 1;
  71         }
  72 }
  73
  74
  75 #define SPAWNPOINT_SCORE frags
  76
  77 .string netname_previous;
  78
  79 void spawnfunc_info_player_survivor (void)
  80 {
  81         spawnfunc_info_player_deathmatch();
  82 }
  83
  84 void spawnfunc_info_player_start (void)
  85 {
  86         spawnfunc_info_player_deathmatch();
  87 }
  88
  89 void spawnfunc_info_player_deathmatch (void)
  90 {
  91         self.classname = "info_player_deathmatch";
  92         relocate_spawnpoint();
  93 }
  94
  95 void spawnpoint_use()
  96 {
  97         if(teams_matter)
  98         if(have_team_spawns)
  99         {
 100                 self.team = activator.team;
 101                 some_spawn_has_been_used = 1;
 102         }
 103 };
 104
 105 // Returns:
 106 //   -1 if a spawn can't be used
 107 //   otherwise, a weight of the spawnpoint
 108 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
 109 {
 110         float shortest, thisdist;
 111         entity player;
 112
 113         // filter out spots for the wrong team
 114         if(teamcheck)
 115         if(spot.team != teamcheck)
 116                 return -1;
 117
 118         if(race_spawns)
 119                 if(spot.target == "")
 120                         return -1;
 121
 122         // filter out spots for assault
 123         if(spot.target != "") {
 124                 local entity ent;
 125                 float good, found;
 126                 ent = find(world, targetname, spot.target);
 127                 while(ent) {
 128                         if(ent.classname == "target_objective")
 129                         {
 130                                 found = 1;
 131                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 132                                         return -1;
 133                                 good = 1;
 134                         }
 135                         else if(ent.classname == "trigger_race_checkpoint")
 136                         {
 137                                 found = 1;
 138                                 if(self.classname == "player") // spectators may spawn everywhere
 139                                 {
 140                                         if(g_race_qualifying)
 141                                         {
 142                                                 // spawn at first
 143                                                 if(ent.race_checkpoint != 0)
 144                                                         return -1;
 145                                                 if(spot.race_place != race_lowest_place_spawn)
 146                                                         return -1;
 147                                         }
 148                                         else
 149                                         {
 150                                                 if(ent.race_checkpoint != race_PreviousCheckpoint(self.race_checkpoint))
 151                                                         return -1;
 152                                                 float pl;
 153                                                 pl = self.race_place;
 154                                                 if(pl > race_highest_place_spawn)
 155                                                         pl = 0;
 156                                                 if(spot.race_place != pl)
 157                                                         return -1;
 158                                         }
 159                                 }
 160                                 good = 1;
 161                         }
 162                         ent = find(ent, targetname, spot.target);
 163                 }
 164
 165                 if(found && !good)
 166                         return -1;
 167         }
 168
 169         player = playerlist;
 170         shortest = vlen(world.maxs - world.mins);
 171         for(player = playerlist; player; player = player.chain)
 172                 if (player != self)
 173                 {
 174                         thisdist = vlen(player.origin - spot.origin);
 175                         if (thisdist < shortest)
 176                                 shortest = thisdist;
 177                 }
 178         return shortest;
 179 }
 180
 181 float spawn_allbad;
 182 float spawn_allgood;
 183 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
 184 {
 185         local entity spot, spotlist, spotlistend;
 186         spawn_allgood = TRUE;
 187         spawn_allbad = TRUE;
 188
 189         spotlist = world;
 190         spotlistend = world;
 191
 192         for(spot = firstspot; spot; spot = spot.chain)
 193         {
 194                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
 195
 196                 if(cvar("spawn_debugview"))
 197                 {
 198                         setmodel(spot, "models/runematch/rune.mdl");
 199                         if(spot.SPAWNPOINT_SCORE < mindist)
 200                         {
 201                                 spot.colormod = '1 0 0';
 202                                 spot.scale = 1;
 203                         }
 204                         else
 205                         {
 206                                 spot.colormod = '0 1 0';
 207                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
 208                         }
 209                 }
 210
 211                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 212                 {
 213                         if(spot.SPAWNPOINT_SCORE < mindist)
 214                         {
 215                                 // too short distance
 216                                 spawn_allgood = FALSE;
 217                         }
 218                         else
 219                         {
 220                                 // perfect
 221                                 spawn_allbad = FALSE;
 222
 223                                 if(spotlistend)
 224                                         spotlistend.chain = spot;
 225                                 spotlistend = spot;
 226                                 if(!spotlist)
 227                                         spotlist = spot;
 228
 229                                 /*
 230                                 if(teamcheck)
 231                                 if(spot.team != teamcheck)
 232                                         error("invalid spawn added");
 233
 234                                 print("added ", etos(spot), "\n");
 235                                 */
 236                         }
 237                 }
 238         }
 239         if(spotlistend)
 240                 spotlistend.chain = world;
 241
 242         /*
 243                 entity e;
 244                 if(teamcheck)
 245                         for(e = spotlist; e; e = e.chain)
 246                         {
 247                                 print("seen ", etos(e), "\n");
 248                                 if(e.team != teamcheck)
 249                                         error("invalid spawn found");
 250                         }
 251         */
 252
 253         return spotlist;
 254 }
 255
 256 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 257 {
 258         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 259         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 260         local entity spot;
 261
 262         RandomSelection_Init();
 263         for(spot = firstspot; spot; spot = spot.chain)
 264                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 265
 266         return RandomSelection_chosen_ent;
 267 }
 268
 269 /*
 270 =============
 271 SelectSpawnPoint
 272
 273 Finds a point to respawn
 274 =============
 275 */
 276 entity SelectSpawnPoint (float anypoint)
 277 {
 278         local float teamcheck;
 279         local entity firstspot_new;
 280         local entity spot, firstspot, playerlist;
 281
 282         spot = find (world, classname, "testplayerstart");
 283         if (spot)
 284                 return spot;
 285
 286         teamcheck = 0;
 287
 288         if(!anypoint && have_team_spawns)
 289                 teamcheck = self.team;
 290
 291         // get the list of players
 292         playerlist = findchain(classname, "player");
 293         // get the entire list of spots
 294         firstspot = findchain(classname, "info_player_deathmatch");
 295         // filter out the bad ones
 296         // (note this returns the original list if none survived)
 297         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 298         if(!firstspot_new)
 299                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 300         firstspot = firstspot_new;
 301
 302         // there is 50/50 chance of choosing a random spot or the furthest spot
 303         // (this means that roughly every other spawn will be furthest, so you
 304         // usually won't get fragged at spawn twice in a row)
 305         if (arena_roundbased)
 306         {
 307                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 308                 if(firstspot_new)
 309                         firstspot = firstspot_new;
 310                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 311         }
 312         else if (random() > cvar("g_spawn_furthest"))
 313                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 314         else
 315                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 316
 317         if(cvar("spawn_debugview"))
 318         {
 319                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 320
 321                 entity e;
 322                 if(teamcheck)
 323                         for(e = firstspot; e; e = e.chain)
 324                                 if(e.team != teamcheck)
 325                                         error("invalid spawn found");
 326         }
 327
 328         if (!spot)
 329         {
 330                 if(cvar("spawn_debug"))
 331                         GotoNextMap();
 332                 else
 333                 {
 334                         if(some_spawn_has_been_used)
 335                                 return world; // team can't spawn any more, because of actions of other team
 336                         else
 337                                 error("Cannot find a spawn point - please fix the map!");
 338                 }
 339         }
 340
 341         return spot;
 342 }
 343
 344 /*
 345 =============
 346 CheckPlayerModel
 347
 348 Checks if the argument string can be a valid playermodel.
 349 Returns a valid one in doubt.
 350 =============
 351 */
 352 string FallbackPlayerModel = "models/player/marine.zym";
 353 string CheckPlayerModel(string plyermodel) {
 354         if(strlen(plyermodel) < 4)
 355                 return FallbackPlayerModel;
 356         if( substring(plyermodel,0,14) != "models/player/")
 357                 return FallbackPlayerModel;
 358         else if(cvar("sv_servermodelsonly"))
 359         {
 360                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 361                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 362                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 363                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 364                         return FallbackPlayerModel;
 365 #ifdef ALLOW_VARIABLE_LOD
 366                 // forbid the LOD models
 367                 if(substring(plyermodel, strlen(plyermodel)-6,2) == "_1")
 368                         return FallbackPlayerModel;
 369                 if(substring(plyermodel, strlen(plyermodel)-6,2) == "_2")
 370                         return FallbackPlayerModel;
 371 #endif
 372                 if(plyermodel != strtolower(plyermodel))
 373                         return FallbackPlayerModel;
 374                 if(!fexists(plyermodel))
 375                         return FallbackPlayerModel;
 376         }
 377         return plyermodel;
 378 }
 379
 380 /*
 381 =============
 382 Client_customizeentityforclient
 383
 384 LOD reduction
 385 =============
 386 */
 387 float Client_customizeentityforclient()
 388 {
 389 #ifdef ALLOW_VARIABLE_LOD
 390         // self: me
 391         // other: the player viewing me
 392         float distance;
 393         float f;
 394
 395         if(self.classname != "player")
 396                 return TRUE;
 397
 398         if(other.cvar_cl_playerdetailreduction <= 0)
 399         {
 400                 if(other.cvar_cl_playerdetailreduction <= -2)
 401                         self.modelindex = self.modelindex_lod2;
 402                 else if(other.cvar_cl_playerdetailreduction <= -1)
 403                         self.modelindex = self.modelindex_lod1;
 404                 else
 405                         self.modelindex = self.modelindex_lod0;
 406         }
 407         else
 408         {
 409                 distance = vlen(self.origin - other.origin);
 410                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 411                 if(f > 10000)
 412                         self.modelindex = self.modelindex_lod2;
 413                 else if(f > 5000)
 414                         self.modelindex = self.modelindex_lod1;
 415                 else
 416                         self.modelindex = self.modelindex_lod0;
 417         }
 418 #endif
 419
 420         return TRUE;
 421 }
 422
 423 void UpdatePlayerSounds();
 424 void setmodel_lod(entity e, string modelname)
 425 {
 426 #ifdef ALLOW_VARIABLE_LOD
 427         string s;
 428
 429         // FIXME: this only supports 3-letter extensions
 430         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 431         if(fexists(s))
 432         {
 433                 precache_model(s);
 434                 setmodel(e, s); // players have high precision
 435                 self.modelindex_lod1 = self.modelindex;
 436         }
 437         else
 438                 self.modelindex_lod1 = -1;
 439
 440         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 441         if(fexists(s))
 442         {
 443                 precache_model(s);
 444                 setmodel(e, s); // players have high precision
 445                 self.modelindex_lod2 = self.modelindex;
 446         }
 447         else
 448                 self.modelindex_lod2 = -1;
 449
 450         precache_model(modelname);
 451         setmodel(e, modelname); // players have high precision
 452         self.modelindex_lod0 = self.modelindex;
 453
 454         if(self.modelindex_lod1 < 0)
 455                 self.modelindex_lod1 = self.modelindex;
 456
 457         if(self.modelindex_lod2 < 0)
 458                 self.modelindex_lod2 = self.modelindex;
 459 #else
 460         precache_model(modelname);
 461         setmodel(e, modelname); // players have high precision
 462 #endif
 463         player_setupanimsformodel();
 464         UpdatePlayerSounds();
 465 }
 466
 467 /*
 468 =============
 469 PutObserverInServer
 470
 471 putting a client as observer in the server
 472 =============
 473 */
 474 void PutObserverInServer (void)
 475 {
 476         entity  spot;
 477
 478         race_PreSpawnObserver();
 479
 480         spot = SelectSpawnPoint (TRUE);
 481         if(!spot)
 482                 error("No spawnpoints for observers?!?\n");
 483         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 484
 485         if(clienttype(self) == CLIENTTYPE_REAL)
 486         {
 487                 msg_entity = self;
 488                 WriteByte(MSG_ONE, SVC_SETVIEW);
 489                 WriteEntity(MSG_ONE, self);
 490         }
 491
 492         DropAllRunes(self);
 493         kh_Key_DropAll(self, TRUE);
 494
 495         Portal_ClearAll(self);
 496
 497         if(self.flagcarried)
 498                 DropFlag(self.flagcarried, world, world);
 499         if(self.ballcarried)
 500                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 501
 502         WaypointSprite_PlayerDead();
 503
 504         if(self.killcount != -666)
 505         {
 506                 if(g_lms)
 507                 {
 508                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 509                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 510                         else
 511                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 512                 }
 513                 else
 514                         bprint ("^4", self.netname, "^4 is spectating now\n");
 515         }
 516
 517         PlayerScore_Clear(self); // clear scores when needed
 518
 519         self.spectatortime = time;
 520
 521         self.classname = "observer";
 522         self.iscreature = FALSE;
 523         self.health = -666;
 524         self.takedamage = DAMAGE_NO;
 525         self.solid = SOLID_NOT;
 526         self.movetype = MOVETYPE_NOCLIP;
 527         self.flags = FL_CLIENT | FL_NOTARGET;
 528         self.armorvalue = 666;
 529         self.effects = 0;
 530         self.armorvalue = cvar("g_balance_armor_start");
 531         self.pauserotarmor_finished = 0;
 532         self.pauserothealth_finished = 0;
 533         self.pauseregen_finished = 0;
 534         self.damageforcescale = 0;
 535         self.death_time = 0;
 536         self.dead_frame = 0;
 537         self.alpha = 0;
 538         self.scale = 0;
 539         self.fade_time = 0;
 540         self.pain_frame = 0;
 541         self.pain_finished = 0;
 542         self.strength_finished = 0;
 543         self.invincible_finished = 0;
 544         self.pushltime = 0;
 545         self.think = SUB_Null;
 546         self.nextthink = 0;
 547         self.hook_time = 0;
 548         self.runes = 0;
 549         self.deadflag = DEAD_NO;
 550         self.angles = spot.angles;
 551         self.angles_z = 0;
 552         self.fixangle = TRUE;
 553         self.crouch = FALSE;
 554
 555         self.view_ofs = PL_VIEW_OFS;
 556         setorigin (self, spot.origin);
 557         setsize (self, '0 0 0', '0 0 0');
 558         self.prevorigin = self.origin;
 559         self.items = 0;
 560         self.weapons = 0;
 561         self.model = "";
 562         self.modelindex = 0;
 563         self.weapon = 0;
 564         self.weaponmodel = "";
 565         self.weaponentity = world;
 566         self.exteriorweaponentity = world;
 567         self.killcount = -666;
 568         self.velocity = '0 0 0';
 569         self.avelocity = '0 0 0';
 570         self.punchangle = '0 0 0';
 571         self.punchvector = '0 0 0';
 572         self.oldvelocity = self.velocity;
 573         self.customizeentityforclient = Client_customizeentityforclient;
 574
 575         self.team = -1;
 576
 577         if(g_arena)
 578         {
 579                 if(self.version_mismatch)
 580                 {
 581                         Spawnqueue_Unmark(self);
 582                         Spawnqueue_Remove(self);
 583                 }
 584                 else
 585                 {
 586                         Spawnqueue_Insert(self);
 587                 }
 588         }
 589         else if(g_lms)
 590         {
 591                 // Only if the player cannot play at all
 592                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 593                         self.frags = FRAGS_SPECTATOR;
 594                 else
 595                         self.frags = FRAGS_LMS_LOSER;
 596         }
 597         else
 598                 self.frags = FRAGS_SPECTATOR;
 599 }
 600
 601 float RestrictSkin(float s)
 602 {
 603         if(!teams_matter)
 604                 return s;
 605         if(s == 6)
 606                 return 6;
 607         return mod(s, 3);
 608 }
 609
 610 void FixPlayermodel()
 611 {
 612         local string defaultmodel;
 613         local float defaultskin;
 614         local vector m1, m2;
 615
 616         defaultmodel = "";
 617
 618         if(cvar("sv_defaultcharacter") == 1) {
 619                 defaultskin = 0;
 620
 621                 if(teams_matter)
 622                 {
 623                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 624                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 625                 }
 626
 627                 if(defaultmodel == "")
 628                 {
 629                         defaultmodel = cvar_string("sv_defaultplayermodel");
 630                         defaultskin = cvar("sv_defaultplayerskin");
 631                 }
 632         }
 633
 634         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 635         {
 636                 if(self.model != "")
 637                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 638                 self.model = ""; // force the != checks to return true
 639         }
 640
 641         if(defaultmodel != "")
 642         {
 643                 if (defaultmodel != self.model)
 644                 {
 645                         m1 = self.mins;
 646                         m2 = self.maxs;
 647                         setmodel_lod (self, defaultmodel);
 648                         setsize (self, m1, m2);
 649                 }
 650
 651                 self.skin = defaultskin;
 652         } else {
 653                 if (self.playermodel != self.model)
 654                 {
 655                         self.playermodel = CheckPlayerModel(self.playermodel);
 656                         m1 = self.mins;
 657                         m2 = self.maxs;
 658                         setmodel_lod (self, self.playermodel);
 659                         setsize (self, m1, m2);
 660                 }
 661
 662                 self.skin = RestrictSkin(stof(self.playerskin));
 663         }
 664
 665         if(!teams_matter)
 666                 if(strlen(cvar_string("sv_defaultplayercolors")))
 667                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 668                                 setcolor(self, cvar("sv_defaultplayercolors"));
 669 }
 670
 671 void PlayerTouchExplode(entity p1, entity p2)
 672 {
 673         vector org;
 674         org = (p1.origin + p2.origin) * 0.5;
 675         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 676
 677         te_explosion(org);
 678
 679         entity e;
 680         e = spawn();
 681         setorigin(e, org);
 682         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 683         remove(e);
 684 }
 685
 686 /*
 687 =============
 688 PutClientInServer
 689
 690 Called when a client spawns in the server
 691 =============
 692 */
 693 //void() ctf_playerchanged;
 694 void PutClientInServer (void)
 695 {
 696         if(clienttype(self) == CLIENTTYPE_BOT)
 697         {
 698                 self.classname = "player";
 699         }
 700         else if(clienttype(self) == CLIENTTYPE_REAL)
 701         {
 702                 msg_entity = self;
 703                 WriteByte(MSG_ONE, SVC_SETVIEW);
 704                 WriteEntity(MSG_ONE, self);
 705         }
 706
 707         // player is dead and becomes observer
 708         // FIXME fix LMS scoring for new system
 709         if(g_lms)
 710         {
 711                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 712                         self.classname = "observer";
 713         }
 714
 715         if(g_arena)
 716         if(!self.spawned)
 717                 self.classname = "observer";
 718
 719         if(self.classname == "player") {
 720                 entity spot, oldself;
 721
 722                 if(self.team < 0)
 723                         JoinBestTeam(self, FALSE, TRUE);
 724
 725                 race_PreSpawn();
 726
 727                 spot = SelectSpawnPoint (FALSE);
 728                 if(!spot)
 729                 {
 730                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 731                         return; // spawn failed
 732                 }
 733
 734                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 735                 self.campingrifle_bulletcounter = 0;
 736
 737                 self.classname = "player";
 738                 self.wasplayer = TRUE;
 739                 self.iscreature = TRUE;
 740                 self.movetype = MOVETYPE_WALK;
 741                 self.solid = SOLID_SLIDEBOX;
 742                 self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 743                 self.frags = FRAGS_PLAYER;
 744                 if(independent_players)
 745                         MAKE_INDEPENDENT_PLAYER(self);
 746                 self.flags = FL_CLIENT;
 747                 self.takedamage = DAMAGE_AIM;
 748                 if(g_minstagib)
 749                         self.effects = EF_FULLBRIGHT;
 750                 else
 751                         self.effects = 0;
 752                 self.air_finished = time + 12;
 753                 self.dmg = 2;
 754
 755                 if(inWarmupStage)
 756                 {
 757                         self.ammo_shells = warmup_start_ammo_shells;
 758                         self.ammo_nails = warmup_start_ammo_nails;
 759                         self.ammo_rockets = warmup_start_ammo_rockets;
 760                         self.ammo_cells = warmup_start_ammo_cells;
 761                         self.ammo_fuel = warmup_start_ammo_fuel;
 762                         self.health = warmup_start_health;
 763                         self.armorvalue = warmup_start_armorvalue;
 764                         self.weapons = warmup_start_weapons;
 765                 }
 766                 else
 767                 {
 768                         self.ammo_shells = start_ammo_shells;
 769                         self.ammo_nails = start_ammo_nails;
 770                         self.ammo_rockets = start_ammo_rockets;
 771                         self.ammo_cells = start_ammo_cells;
 772                         self.ammo_fuel = start_ammo_fuel;
 773                         self.health = start_health;
 774                         self.armorvalue = start_armorvalue;
 775                         self.weapons = start_weapons;
 776                 }
 777                 self.items = start_items;
 778                 self.switchweapon = w_getbestweapon(self);
 779                 self.cnt = self.switchweapon;
 780                 self.weapon = 0;
 781                 self.jump_interval = time;
 782
 783                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 784                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 785                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 786                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
 787                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 788                 //extend the pause of rotting if client was reset at the beginning of the countdown
 789                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 790                         self.spawnshieldtime += game_starttime - time;
 791                         self.pauserotarmor_finished += game_starttime - time;
 792                         self.pauserothealth_finished += game_starttime - time;
 793                         self.pauseregen_finished += game_starttime - time;
 794                 }
 795                 self.damageforcescale = 2;
 796                 self.death_time = 0;
 797                 self.dead_frame = 0;
 798                 self.alpha = 0;
 799                 self.scale = 0;
 800                 self.fade_time = 0;
 801                 self.pain_frame = 0;
 802                 self.pain_finished = 0;
 803                 self.strength_finished = 0;
 804                 self.invincible_finished = 0;
 805                 self.pushltime = 0;
 806                 //self.speed_finished = 0;
 807                 //self.slowmo_finished = 0;
 808                 // players have no think function
 809                 self.think = SUB_Null;
 810                 self.nextthink = 0;
 811                 self.hook_time = 0;
 812                 self.dmg_team = 0;
 813
 814                 self.metertime = 0;
 815
 816                 self.runes = 0;
 817
 818                 self.deadflag = DEAD_NO;
 819
 820                 self.angles = spot.angles;
 821
 822                 self.angles_z = 0; // never spawn tilted even if the spot says to
 823                 self.fixangle = TRUE; // turn this way immediately
 824                 self.velocity = '0 0 0';
 825                 self.avelocity = '0 0 0';
 826                 self.punchangle = '0 0 0';
 827                 self.punchvector = '0 0 0';
 828                 self.oldvelocity = self.velocity;
 829
 830                 msg_entity = self;
 831                 WRITESPECTATABLE_MSG_ONE({
 832                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 833                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 834                 });
 835
 836                 self.customizeentityforclient = Client_customizeentityforclient;
 837
 838                 self.model = "";
 839                 FixPlayermodel();
 840
 841                 self.crouch = FALSE;
 842                 self.view_ofs = PL_VIEW_OFS;
 843                 setsize (self, PL_MIN, PL_MAX);
 844                 self.spawnorigin = spot.origin;
 845                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 846                 // don't reset back to last position, even if new position is stuck in solid
 847                 self.oldorigin = self.origin;
 848                 self.prevorigin = self.origin;
 849
 850                 if(g_arena)
 851                 {
 852                         Spawnqueue_Remove(self);
 853                         Spawnqueue_Mark(self);
 854                 }
 855
 856                 self.event_damage = PlayerDamage;
 857
 858                 self.bot_attack = TRUE;
 859
 860                 self.statdraintime = time + 5;
 861                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 862
 863                 if(self.killcount == -666) {
 864                         PlayerScore_Clear(self);
 865                         self.killcount = 0;
 866                 }
 867
 868                 self.cnt = WEP_LASER;
 869                 self.nixnex_lastchange_id = -1;
 870
 871                 CL_SpawnWeaponentity();
 872                 self.alpha = default_player_alpha;
 873                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 874                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 875
 876                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 877                 self.lms_traveled_distance = 0;
 878                 self.speedrunning = FALSE;
 879
 880                 race_PostSpawn(spot);
 881
 882                 if(cvar("spawn_debug"))
 883                 {
 884                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 885                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 886                 }
 887
 888                 //stuffcmd(self, "chase_active 0");
 889                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 890
 891                 if (cvar("g_spawnsound"))
 892                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 893
 894                 if(g_assault) {
 895                         if(self.team == assault_attacker_team)
 896                                 centerprint(self, "You are attacking!");
 897                         else
 898                                 centerprint(self, "You are defending!");
 899                 }
 900
 901                 target_voicescript_clear(self);
 902
 903                 oldself = self;
 904                 self = spot;
 905                         activator = oldself;
 906                                 SUB_UseTargets();
 907                         activator = world;
 908                 self = oldself;
 909
 910         } else if(self.classname == "observer") {
 911                 PutObserverInServer ();
 912         }
 913
 914         //if(g_ctf)
 915         //      ctf_playerchanged();
 916 }
 917
 918 float ClientInit_SendEntity(entity to, float sf)
 919 {
 920         float i;
 921         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 922         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 923         for(i = 1; i <= 24; ++i)
 924                 WriteByte(MSG_ENTITY, (get_weaponinfo(i)).impulse + 1);
 925         WriteCoord(MSG_ENTITY, hook_shotorigin_x);
 926         WriteCoord(MSG_ENTITY, hook_shotorigin_y);
 927         WriteCoord(MSG_ENTITY, hook_shotorigin_z);
 928
 929         if(sv_foginterval && world.fog != "")
 930                 WriteString(MSG_ENTITY, world.fog);
 931         else
 932                 WriteString(MSG_ENTITY, "");
 933         WriteByte(MSG_ENTITY, cvar("g_balance_armor_blockpercent") * 255.0);
 934         return TRUE;
 935 }
 936
 937 void ClientInit_Spawn()
 938 {
 939         Net_LinkEntity(spawn(), FALSE, 0, ClientInit_SendEntity);
 940 }
 941
 942 /*
 943 =============
 944 SetNewParms
 945 =============
 946 */
 947 void SetNewParms (void)
 948 {
 949         // initialize parms for a new player
 950         parm1 = -(86400 * 366);
 951 }
 952
 953 /*
 954 =============
 955 SetChangeParms
 956 =============
 957 */
 958 void SetChangeParms (void)
 959 {
 960         // save parms for level change
 961         parm1 = self.parm_idlesince - time;
 962 }
 963
 964 /*
 965 =============
 966 DecodeLevelParms
 967 =============
 968 */
 969 void DecodeLevelParms (void)
 970 {
 971         // load parms
 972         self.parm_idlesince = parm1;
 973         if(self.parm_idlesince == -(86400 * 366))
 974                 self.parm_idlesince = time;
 975
 976         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 977         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 978 }
 979
 980 /*
 981 =============
 982 ClientKill
 983
 984 Called when a client types 'kill' in the console
 985 =============
 986 */
 987
 988 void ClientKill_Now_TeamChange()
 989 {
 990         if(self.killindicator_teamchange == -1)
 991         {
 992                 self.team = -1;
 993                 JoinBestTeam( self, FALSE, FALSE );
 994         }
 995         else
 996                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 997 }
 998
 999 void ClientKill_Now()
1000 {
1001         if(self.killindicator_teamchange)
1002                 ClientKill_Now_TeamChange();
1003
1004         // in any case:
1005         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1006
1007         if(self.killindicator)
1008         {
1009                 dprint("Cleaned up after a leaked kill indicator.\n");
1010                 remove(self.killindicator);
1011                 self.killindicator = world;
1012         }
1013 }
1014 void KillIndicator_Think()
1015 {
1016         if (!self.owner.modelindex)
1017         {
1018                 self.owner.killindicator = world;
1019                 remove(self);
1020                 return;
1021         }
1022
1023         if(self.cnt <= 0)
1024         {
1025                 self = self.owner;
1026                 ClientKill_Now(); // no oldself needed
1027                 return;
1028         }
1029         else
1030         {
1031                 if(self.cnt <= 10)
1032                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1033                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1034                 {
1035                         if(self.cnt <= 10)
1036                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".wav"));
1037                         if(self.owner.killindicator_teamchange)
1038                         {
1039                                 if(self.owner.killindicator_teamchange == -1)
1040                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1041                                 else
1042                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1043                         }
1044                         else
1045                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1046                 }
1047                 self.nextthink = time + 1;
1048                 self.cnt -= 1;
1049         }
1050 }
1051
1052 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1053 {
1054         float killtime;
1055         entity e;
1056         killtime = cvar("g_balance_kill_delay");
1057
1058         self.killindicator_teamchange = targetteam;
1059
1060         if(!self.killindicator)
1061         {
1062                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1063                 {
1064                         ClientKill_Now();
1065                 }
1066                 else
1067                 {
1068                         self.killindicator = spawn();
1069                         self.killindicator.owner = self;
1070                         self.killindicator.scale = 0.5;
1071                         setattachment(self.killindicator, self, "");
1072                         setorigin(self.killindicator, '0 0 52');
1073                         self.killindicator.think = KillIndicator_Think;
1074                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1075                         self.killindicator.cnt = ceil(killtime);
1076                         self.killindicator.count = bound(0, ceil(killtime), 10);
1077                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1078
1079                         for(e = world; (e = find(e, classname, "body")) != world; )
1080                         {
1081                                 if(e.enemy != self)
1082                                         continue;
1083                                 e.killindicator = spawn();
1084                                 e.killindicator.owner = e;
1085                                 e.killindicator.scale = 0.5;
1086                                 setattachment(e.killindicator, e, "");
1087                                 setorigin(e.killindicator, '0 0 52');
1088                                 e.killindicator.think = KillIndicator_Think;
1089                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1090                                 e.killindicator.cnt = ceil(killtime);
1091                         }
1092                         self.lip = 0;
1093                 }
1094         }
1095         if(self.killindicator)
1096         {
1097                 if(targetteam)
1098                         self.killindicator.colormod = TeamColor(targetteam);
1099                 else
1100                         self.killindicator.colormod = '0 0 0';
1101         }
1102 }
1103
1104 void ClientKill (void)
1105 {
1106         ClientKill_TeamChange(0);
1107 }
1108
1109 void DoTeamChange(float destteam)
1110 {
1111         float t, c0;
1112         if(!teams_matter)
1113         {
1114                 if(destteam >= 0)
1115                         SetPlayerColors(self, destteam);
1116                 return;
1117         }
1118         if(self.classname == "player")
1119         if(destteam == -1)
1120         {
1121                 CheckAllowedTeams(self);
1122                 t = FindSmallestTeam(self, TRUE);
1123                 switch(self.team)
1124                 {
1125                         case COLOR_TEAM1: c0 = c1; break;
1126                         case COLOR_TEAM2: c0 = c2; break;
1127                         case COLOR_TEAM3: c0 = c3; break;
1128                         case COLOR_TEAM4: c0 = c4; break;
1129                         default:          c0 = 999;
1130                 }
1131                 switch(t)
1132                 {
1133                         case 1:
1134                                 if(c0 > c1)
1135                                         destteam = COLOR_TEAM1;
1136                                 break;
1137                         case 2:
1138                                 if(c0 > c2)
1139                                         destteam = COLOR_TEAM2;
1140                                 break;
1141                         case 3:
1142                                 if(c0 > c3)
1143                                         destteam = COLOR_TEAM3;
1144                                 break;
1145                         case 4:
1146                                 if(c0 > c4)
1147                                         destteam = COLOR_TEAM4;
1148                                 break;
1149                 }
1150                 if(destteam == -1)
1151                         return;
1152         }
1153         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1154                 return;
1155         ClientKill_TeamChange(destteam);
1156 }
1157
1158 void FixClientCvars(entity e)
1159 {
1160         // send prediction settings to the client
1161         stuffcmd(e, "\nin_bindmap 0 0\n");
1162         /*
1163          * we no longer need to stuff this. Remove this comment block if you feel
1164          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1165         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1166         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1167         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1168         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1169         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1170         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1171         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1172         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1173         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1174         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1175         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1176         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1177         stuffcmd(e, "cl_movement_edgefriction 1\n");
1178          */
1179 }
1180
1181 /*
1182 =============
1183 ClientConnect
1184
1185 Called when a client connects to the server
1186 =============
1187 */
1188 //void ctf_clientconnect();
1189 string ColoredTeamName(float t);
1190 void DecodeLevelParms (void);
1191 //void dom_player_join_team(entity pl);
1192 void ClientConnect (void)
1193 {
1194         local string s;
1195         float t;
1196
1197         if(self.flags & FL_CLIENT)
1198         {
1199                 print("Warning: ClientConnect, but already connected!\n");
1200                 return;
1201         }
1202
1203         if(Ban_MaybeEnforceBan(self))
1204                 return;
1205
1206         DecodeLevelParms();
1207
1208         self.classname = "player_joining";
1209
1210         self.flags = FL_CLIENT;
1211         self.version_nagtime = time + 10 + random() * 10;
1212
1213         if(player_count<0)
1214         {
1215                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1216                 player_count = 0;
1217         }
1218
1219         PlayerScore_Attach(self);
1220         ClientData_Attach();
1221
1222         bot_clientconnect();
1223
1224         race_PreSpawnObserver();
1225
1226         //if(g_domination)
1227         //      dom_player_join_team(self);
1228
1229         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1230
1231         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1232                 self.classname = "observer";
1233         } else {
1234                 if(teams_matter)
1235                 {
1236                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1237                         {
1238                                 self.classname = "player";
1239                                 campaign_bots_may_start = 1;
1240                         }
1241                         else
1242                         {
1243                                 self.classname = "observer"; // do it anyway
1244                         }
1245                 }
1246                 else
1247                 {
1248                         self.classname = "player";
1249                         campaign_bots_may_start = 1;
1250                 }
1251         }
1252
1253         self.playerid = (playerid_last = playerid_last + 1);
1254         if(cvar("sv_eventlog"))
1255         {
1256                 if(clienttype(self) == CLIENTTYPE_REAL)
1257                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", self.netaddress, ":", self.netname));
1258                 else
1259                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":bot:", self.netname));
1260                 s = strcat(":team:", ftos(self.playerid), ":");
1261                 s = strcat(s, ftos(self.team));
1262                 GameLogEcho(s);
1263         }
1264         self.netname_previous = strzone(self.netname);
1265
1266         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1267
1268         bprint ("^4",self.netname);
1269         bprint ("^4 connected");
1270
1271         if(g_domination || g_ctf)
1272         {
1273                 bprint(" and joined the ");
1274                 bprint(ColoredTeamName(self.team));
1275         }
1276
1277         bprint("\n");
1278
1279         self.welcomemessage_time = 0;
1280
1281         stuffcmd(self, strcat(clientstuff, "\n"));
1282         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1283         stuffcmd(self, "cl_particles_reloadeffects\n");
1284
1285         FixClientCvars(self);
1286
1287         // spawnfunc_waypoint sprites
1288         WaypointSprite_InitClient(self);
1289
1290         // Wazat's grappling hook
1291         SetGrappleHookBindings();
1292
1293         // get autoswitch state from player when he toggles it
1294         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1295
1296         // get version info from player
1297         stuffcmd(self, "cmd clientversion $gameversion\n");
1298
1299         // get other cvars from player
1300         GetCvars(0);
1301
1302         // set cvar for team scoreboard
1303         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1304
1305         // notify about available teams
1306         if(teams_matter)
1307         {
1308                 CheckAllowedTeams(self);
1309                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1310                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1311         }
1312         else
1313                 stuffcmd(self, "set _teams_available 0\n");
1314
1315         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1316
1317         if(g_arena)
1318         {
1319                 self.classname = "observer";
1320                 Spawnqueue_Insert(self);
1321         }
1322         /*else if(g_ctf)
1323         {
1324                 ctf_clientconnect();
1325         }*/
1326
1327         if(teams_matter || sv_cheats)
1328                 attach_entcs();
1329
1330         bot_relinkplayerlist();
1331
1332         self.spectatortime = time;
1333         if(blockSpectators)
1334         {
1335                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1336         }
1337
1338         self.jointime = time;
1339         self.allowedTimeouts = cvar("sv_timeout_number");
1340
1341         if(clienttype(self) == CLIENTTYPE_REAL)
1342         {
1343                 if(cvar("g_bugrigs"))
1344                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1345         }
1346
1347         if(g_lms)
1348         {
1349                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1350                 {
1351                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1352                         self.frags = FRAGS_SPECTATOR;
1353                 }
1354         }
1355
1356         if(!sv_foginterval && world.fog != "")
1357                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1358
1359         SoundEntity_Attach(self);
1360
1361         if(cvar("g_hitplots"))
1362         {
1363                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1364                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1365         }
1366         else
1367                 self.hitplotfh = -1;
1368 }
1369
1370 /*
1371 =============
1372 ClientDisconnect
1373
1374 Called when a client disconnects from the server
1375 =============
1376 */
1377 .entity chatbubbleentity;
1378 .entity teambubbleentity;
1379 void ReadyCount();
1380 void ClientDisconnect (void)
1381 {
1382         if not(self.flags & FL_CLIENT)
1383         {
1384                 print("Warning: ClientDisconnect without ClientConnect\n");
1385                 return;
1386         }
1387
1388         if(self.hitplotfh >= 0)
1389         {
1390                 fclose(self.hitplotfh);
1391                 self.hitplotfh = -1;
1392         }
1393
1394         bot_clientdisconnect();
1395
1396         if(self.entcs)
1397                 detach_entcs();
1398
1399         if(cvar("sv_eventlog"))
1400                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1401         bprint ("^4",self.netname);
1402         bprint ("^4 disconnected\n");
1403
1404         SoundEntity_Detach(self);
1405
1406         DropAllRunes(self);
1407         kh_Key_DropAll(self, TRUE);
1408
1409         Portal_ClearAll(self);
1410
1411         if(self.flagcarried)
1412                 DropFlag(self.flagcarried, world, world);
1413         if(self.ballcarried)
1414                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1415
1416         // Here, everything has been done that requires this player to be a client.
1417
1418         self.flags &~= FL_CLIENT;
1419
1420         if (self.chatbubbleentity)
1421                 remove (self.chatbubbleentity);
1422
1423         if (self.teambubbleentity)
1424                 remove (self.teambubbleentity);
1425
1426         if (self.killindicator)
1427                 remove (self.killindicator);
1428
1429         WaypointSprite_PlayerGone();
1430
1431         bot_relinkplayerlist();
1432
1433         // remove laserdot
1434         if(self.weaponentity)
1435                 if(self.weaponentity.lasertarget)
1436                         remove(self.weaponentity.lasertarget);
1437
1438         if(g_arena)
1439         {
1440                 Spawnqueue_Unmark(self);
1441                 Spawnqueue_Remove(self);
1442         }
1443
1444         ClientData_Detach();
1445         PlayerScore_Detach(self);
1446
1447         if(self.netname_previous)
1448                 strunzone(self.netname_previous);
1449
1450         ClearPlayerSounds();
1451
1452         self.playerid = 0;
1453         ReadyCount();
1454
1455         // free cvars
1456         GetCvars(-1);
1457 }
1458
1459 .float BUTTON_CHAT;
1460 void ChatBubbleThink()
1461 {
1462         self.nextthink = time;
1463         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1464         {
1465                 if(self.owner) // but why can that ever be world?
1466                         self.owner.chatbubbleentity = world;
1467                 remove(self);
1468                 return;
1469         }
1470         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1471                 self.model = self.mdl;
1472         else
1473                 self.model = "";
1474 };
1475
1476 void UpdateChatBubble()
1477 {
1478         if (!self.modelindex)
1479                 return;
1480         // spawn a chatbubble entity if needed
1481         if (!self.chatbubbleentity)
1482         {
1483                 self.chatbubbleentity = spawn();
1484                 self.chatbubbleentity.owner = self;
1485                 self.chatbubbleentity.exteriormodeltoclient = self;
1486                 self.chatbubbleentity.think = ChatBubbleThink;
1487                 self.chatbubbleentity.nextthink = time;
1488                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1489                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1490                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1491                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1492                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1493                 self.chatbubbleentity.model = "";
1494                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1495         }
1496 }
1497
1498
1499 void TeamBubbleThink()
1500 {
1501         self.nextthink = time;
1502         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1503         {
1504                 if(self.owner) // but why can that ever be world?
1505                         self.owner.teambubbleentity = world;
1506                 remove(self);
1507                 return;
1508         }
1509 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1510         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1511                 self.model = "";
1512         else
1513                 self.model = self.mdl;
1514
1515 };
1516
1517 float TeamBubble_customizeentityforclient()
1518 {
1519         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1520 }
1521
1522 void UpdateTeamBubble()
1523 {
1524         if (!self.modelindex || !teams_matter)
1525                 return;
1526         // spawn a teambubble entity if needed
1527         if (!self.teambubbleentity && teams_matter)
1528         {
1529                 self.teambubbleentity = spawn();
1530                 self.teambubbleentity.owner = self;
1531                 self.teambubbleentity.exteriormodeltoclient = self;
1532                 self.teambubbleentity.think = TeamBubbleThink;
1533                 self.teambubbleentity.nextthink = time;
1534                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1535 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1536                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1537                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1538                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1539                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1540                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1541                 self.teambubbleentity.effects = EF_LOWPRECISION;
1542         }
1543 }
1544
1545 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1546 // added to the model skins
1547 /*void UpdateColorModHack()
1548 {
1549         local float c;
1550         c = self.clientcolors & 15;
1551         // LordHavoc: only bothering to support white, green, red, yellow, blue
1552              if (!teams_matter) self.colormod = '0 0 0';
1553         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1554         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1555         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1556         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1557         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1558         else self.colormod = '1 1 1';
1559 };*/
1560
1561 void respawn(void)
1562 {
1563         CopyBody(1);
1564         self.effects |= EF_NODRAW; // prevent another CopyBody
1565         PutClientInServer();
1566 }
1567
1568 void play_countdown(float finished, string samp)
1569 {
1570         if(clienttype(self) == CLIENTTYPE_REAL)
1571                 if(floor(finished - time - frametime) != floor(finished - time))
1572                         if(finished - time < 6)
1573                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1574 }
1575
1576 /**
1577  * When sv_timeout is used this function returs strings like
1578  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1579  * Called by centerprint functions
1580  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1581  */
1582 string getTimeoutText(float addOneSecond) {
1583         if (!cvar("sv_timeout") || !timeoutStatus)
1584                 return "";
1585
1586         local string retStr;
1587         if (timeoutStatus == 1) {
1588                 if (addOneSecond == 1) {
1589                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1590                 }
1591                 else {
1592                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1593                 }
1594                 return retStr;
1595         }
1596         else if (timeoutStatus == 2) {
1597                 if (addOneSecond) {
1598                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1599                         //don't show messages like "Timeout ends in 0 seconds"...
1600                         if ((remainingTimeoutTime + 1) > 0)
1601                                 return retStr;
1602                         else
1603                                 return "";
1604                 }
1605                 else {
1606                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1607                         //don't show messages like "Timeout ends in 0 seconds"...
1608                         if (remainingTimeoutTime > 0)
1609                                 return retStr;
1610                         else
1611                                 return "";
1612                 }
1613         }
1614         else return "";
1615 }
1616
1617 void player_powerups (void)
1618 {
1619         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1620         {
1621                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, ATTN_IDLE);
1622                 self.modelflags |= MF_ROCKET;
1623         }
1624         else
1625         {
1626                 SoundEntity_StopSound(self, CHAN_PLAYER);
1627                 self.modelflags &~= MF_ROCKET;
1628         }
1629
1630         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1631
1632         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1633                 return;
1634
1635         if (g_minstagib)
1636         {
1637                 self.effects |= EF_FULLBRIGHT;
1638
1639                 if (self.items & IT_STRENGTH)
1640                 {
1641                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1642                         if (time > self.strength_finished)
1643                         {
1644                                 self.alpha = default_player_alpha;
1645                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1646                                 self.items &~= IT_STRENGTH;
1647                                 sprint(self, "^3Invisibility has worn off\n");
1648                         }
1649                 }
1650                 else
1651                 {
1652                         if (time < self.strength_finished)
1653                         {
1654                                 self.alpha = g_minstagib_invis_alpha;
1655                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1656                                 self.items |= IT_STRENGTH;
1657                                 sprint(self, "^3You are invisible\n");
1658                         }
1659                 }
1660
1661                 if (self.items & IT_INVINCIBLE)
1662                 {
1663                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1664                         if (time > self.invincible_finished)
1665                         {
1666                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1667                                 sprint(self, "^3Speed has worn off\n");
1668                         }
1669                 }
1670                 else
1671                 {
1672                         if (time < self.invincible_finished)
1673                         {
1674                                 self.items = self.items | IT_INVINCIBLE;
1675                                 sprint(self, "^3You are on speed\n");
1676                         }
1677                 }
1678                 return;
1679         }
1680
1681         if (self.items & IT_STRENGTH)
1682         {
1683                 play_countdown(self.strength_finished, "misc/poweroff.wav");
1684                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1685                 if (time > self.strength_finished)
1686                 {
1687                         self.items = self.items - (self.items & IT_STRENGTH);
1688                         sprint(self, "^3Strength has worn off\n");
1689                 }
1690         }
1691         else
1692         {
1693                 if (time < self.strength_finished)
1694                 {
1695                         self.items = self.items | IT_STRENGTH;
1696                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1697                 }
1698         }
1699         if (self.items & IT_INVINCIBLE)
1700         {
1701                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
1702                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1703                 if (time > self.invincible_finished)
1704                 {
1705                         self.items = self.items - (self.items & IT_INVINCIBLE);
1706                         sprint(self, "^3Shield has worn off\n");
1707                 }
1708         }
1709         else
1710         {
1711                 if (time < self.invincible_finished)
1712                 {
1713                         self.items = self.items | IT_INVINCIBLE;
1714                         sprint(self, "^3Shield surrounds you\n");
1715                 }
1716         }
1717
1718         if (cvar("g_fullbrightplayers"))
1719                 self.effects = self.effects | EF_FULLBRIGHT;
1720
1721         // midair gamemode: damage only while in the air
1722         // if in midair mode, being on ground grants temporary invulnerability
1723         // (this is so that multishot weapon don't clear the ground flag on the
1724         // first damage in the frame, leaving the player vulnerable to the
1725         // remaining hits in the same frame)
1726         if (self.flags & FL_ONGROUND)
1727         if (g_midair)
1728                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1729
1730         if (time >= game_starttime)
1731         if (time < self.spawnshieldtime)
1732                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1733 }
1734
1735 float CalcRegen(float current, float stable, float regenfactor)
1736 {
1737         if(current > stable)
1738                 return current;
1739         else if(current > stable - 0.25) // when close enough, "snap"
1740                 return stable;
1741         else
1742                 return min(stable, current + (stable - current) * regenfactor * frametime);
1743 }
1744
1745 void player_regen (void)
1746 {
1747         float maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1748         maxh = cvar("g_balance_health_stable");
1749         maxa = cvar("g_balance_armor_stable");
1750         maxf = cvar("g_balance_fuel_stable");
1751         limith = cvar("g_balance_health_limit");
1752         limita = cvar("g_balance_armor_limit");
1753         limitf = cvar("g_balance_fuel_limit");
1754
1755         max_mod = regen_mod = rot_mod = limit_mod = 1;
1756
1757         if (self.runes & RUNE_REGEN)
1758         {
1759                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1760                 {
1761                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1762                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1763                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1764                 }
1765                 else
1766                 {
1767                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1768                         max_mod = cvar("g_balance_rune_regen_hpmod");
1769                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1770                 }
1771         }
1772         else if (self.runes & CURSE_VENOM)
1773         {
1774                 max_mod = cvar("g_balance_curse_venom_hpmod");
1775                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1776                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1777                 else
1778                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1779                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1780                 //if (!self.runes & RUNE_REGEN)
1781                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1782         }
1783         maxh = maxh * max_mod;
1784         //maxa = maxa * max_mod;
1785         //maxf = maxf * max_mod;
1786         limith = limith * limit_mod;
1787         limita = limita * limit_mod;
1788         //limitf = limitf * limit_mod;
1789
1790         if (!g_minstagib && (!g_lms || cvar("g_lms_regenerate")))
1791         {
1792                 if (self.armorvalue > maxa)
1793                 {
1794                         if (time > self.pauserotarmor_finished)
1795                         {
1796                                 self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1797                                 self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1798                         }
1799                 }
1800                 else if (self.armorvalue < maxa)
1801                 {
1802                         if (time > self.pauseregen_finished)
1803                         {
1804                                 self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1805                                 self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1806                         }
1807                 }
1808                 if (self.armorvalue > limita)
1809                         self.armorvalue = limita;
1810
1811                 if (self.health > maxh)
1812                 {
1813                         if (time > self.pauserothealth_finished)
1814                         {
1815                                 self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1816                                 self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1817                         }
1818                 }
1819                 else if (self.health < maxh)
1820                 {
1821                         if (time > self.pauseregen_finished)
1822                         {
1823                                 self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1824                                 self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1825                         }
1826                 }
1827                 if (self.health > limith)
1828                         self.health = limith;
1829
1830                 // if player rotted to death...  die!
1831                 if(self.health < 1)
1832                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1833         }
1834
1835         if (self.ammo_fuel > maxf)
1836         {
1837                 if (time > self.pauserotfuel_finished)
1838                 {
1839                         self.ammo_fuel = max(maxf, self.ammo_fuel + (maxf - self.ammo_fuel) * rot_mod*cvar("g_balance_fuel_rot") * frametime);
1840                         self.ammo_fuel = max(maxf, self.ammo_fuel - rot_mod*cvar("g_balance_fuel_rotlinear") * frametime);
1841                 }
1842         }
1843         else if (self.ammo_fuel < maxf)
1844         {
1845                 if(self.items & IT_FUEL_REGEN)
1846                 {
1847                         if (time > self.pauseregen_finished)
1848                         {
1849                                 self.ammo_fuel = CalcRegen(self.ammo_fuel, maxf, regen_mod * cvar("g_balance_fuel_regen"));
1850                                 self.ammo_fuel = min(maxf, self.ammo_fuel + regen_mod*cvar("g_balance_fuel_regenlinear") * frametime);
1851                         }
1852                 }
1853         }
1854         if (self.ammo_fuel > limitf)
1855                 self.ammo_fuel = limitf;
1856 }
1857
1858 float zoomstate_set;
1859 void SetZoomState(float z)
1860 {
1861         if(z != self.zoomstate)
1862                 ClientData_Touch(self);
1863         zoomstate_set = 1;
1864 }
1865
1866 void GetPressedKeys(void) {
1867         if (self.movement_x > 0) // get if movement keys are pressed
1868         {       // forward key pressed
1869                 self.pressedkeys |= KEY_FORWARD;
1870                 self.pressedkeys &~= KEY_BACKWARD;
1871         }
1872         else if (self.movement_x < 0)
1873         {       // backward key pressed
1874                 self.pressedkeys |= KEY_BACKWARD;
1875                 self.pressedkeys &~= KEY_FORWARD;
1876         }
1877         else
1878         {       // no x input
1879                 self.pressedkeys &~= KEY_FORWARD;
1880                 self.pressedkeys &~= KEY_BACKWARD;
1881         }
1882
1883         if (self.movement_y > 0)
1884         {       // right key pressed
1885                 self.pressedkeys |= KEY_RIGHT;
1886                 self.pressedkeys &~= KEY_LEFT;
1887         }
1888         else if (self.movement_y < 0)
1889         {       // left key pressed
1890                 self.pressedkeys |= KEY_LEFT;
1891                 self.pressedkeys &~= KEY_RIGHT;
1892         }
1893         else
1894         {       // no y input
1895                 self.pressedkeys &~= KEY_RIGHT;
1896                 self.pressedkeys &~= KEY_LEFT;
1897         }
1898
1899         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1900                 self.pressedkeys |= KEY_JUMP;
1901         else
1902                 self.pressedkeys &~= KEY_JUMP;
1903         if (self.BUTTON_CROUCH)
1904                 self.pressedkeys |= KEY_CROUCH;
1905         else
1906                 self.pressedkeys &~= KEY_CROUCH;
1907 }
1908
1909 /*
1910 ======================
1911 spectate mode routines
1912 ======================
1913 */
1914 void SpectateCopy(entity spectatee) {
1915         self.armortype = spectatee.armortype;
1916         self.armorvalue = spectatee.armorvalue;
1917         self.ammo_cells = spectatee.ammo_cells;
1918         self.ammo_shells = spectatee.ammo_shells;
1919         self.ammo_nails = spectatee.ammo_nails;
1920         self.ammo_rockets = spectatee.ammo_rockets;
1921         self.ammo_fuel = spectatee.ammo_fuel;
1922         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1923         self.health = spectatee.health;
1924         self.impulse = 0;
1925         self.items = spectatee.items;
1926         self.metertime = spectatee.metertime;
1927         self.strength_finished = spectatee.strength_finished;
1928         self.invincible_finished = spectatee.invincible_finished;
1929         self.pressedkeys = spectatee.pressedkeys;
1930         self.weapons = spectatee.weapons;
1931         self.switchweapon = spectatee.switchweapon;
1932         self.weapon = spectatee.weapon;
1933         self.punchangle = spectatee.punchangle;
1934         self.view_ofs = spectatee.view_ofs;
1935         self.v_angle = spectatee.v_angle;
1936         self.velocity = spectatee.velocity;
1937         self.dmg_take = spectatee.dmg_take;
1938         self.dmg_save = spectatee.dmg_save;
1939         self.dmg_inflictor = spectatee.dmg_inflictor;
1940         self.angles = spectatee.v_angle;
1941         self.fixangle = TRUE;
1942         setorigin(self, spectatee.origin);
1943         setsize(self, spectatee.mins, spectatee.maxs);
1944         SetZoomState(spectatee.zoomstate);
1945 }
1946
1947 float SpectateUpdate() {
1948         if(!self.enemy)
1949                 return 0;
1950
1951         if (self == self.enemy)
1952                 return 0;
1953
1954         if(self.enemy.classname != "player")
1955                 return 0;
1956
1957         SpectateCopy(self.enemy);
1958
1959         return 1;
1960 }
1961
1962 float SpectateNext() {
1963         other = find(self.enemy, classname, "player");
1964         if (!other) {
1965                 other = find(other, classname, "player");
1966         }
1967         if (other) {
1968                 self.enemy = other;
1969         }
1970         if(self.enemy.classname == "player") {
1971                 msg_entity = self;
1972                 WriteByte(MSG_ONE, SVC_SETVIEW);
1973                 WriteEntity(MSG_ONE, self.enemy);
1974                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1975                 if(!SpectateUpdate())
1976                         PutObserverInServer();
1977                 return 1;
1978         } else {
1979                 return 0;
1980         }
1981 }
1982
1983 /*
1984 =============
1985 ShowRespawnCountdown()
1986
1987 Update a respawn countdown display.
1988 =============
1989 */
1990 void ShowRespawnCountdown()
1991 {
1992         float number;
1993         if(self.deadflag == DEAD_NO) // just respawned?
1994                 return;
1995         else
1996         {
1997                 number = ceil(self.death_time - time);
1998                 if(number <= 0)
1999                         return;
2000                 if(number <= self.respawn_countdown)
2001                 {
2002                         self.respawn_countdown = number - 1;
2003                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2004                                 announce(self, strcat("announcer/robotic/", ftos(number), ".wav"));
2005                 }
2006         }
2007 }
2008
2009 void LeaveSpectatorMode()
2010 {
2011         if(isJoinAllowed()) {
2012                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
2013                         self.classname = "player";
2014                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2015                                 JoinBestTeam(self, FALSE, TRUE);
2016                         if(cvar("g_campaign"))
2017                                 campaign_bots_may_start = 1;
2018                         PutClientInServer();
2019                         if(self.classname == "player")
2020                                 bprint ("^4", self.netname, "^4 is playing now\n");
2021                         if(!cvar("g_campaign"))
2022                                 centerprint(self,""); // clear MOTD
2023                         return;
2024                 } else {
2025                         stuffcmd(self,"menu_showteamselect\n");
2026                         return;
2027                 }
2028         }
2029         else {
2030                 //player may not join because of g_maxplayers is set
2031                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2032         }
2033 }
2034
2035 /**
2036  * Determines whether the player is allowed to join. This depends on cvar
2037  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2038  * it checks whether the number of currently playing players exceeds g_maxplayers.
2039  * @return bool TRUE if the player is allowed to join, false otherwise
2040  */
2041 float isJoinAllowed() {
2042         if (!cvar("g_maxplayers"))
2043                 return TRUE;
2044
2045         local entity e;
2046         local float currentlyPlaying;
2047         FOR_EACH_REALPLAYER(e) {
2048                 if(e.classname == "player")
2049                         currentlyPlaying += 1;
2050         }
2051         if(currentlyPlaying < cvar("g_maxplayers"))
2052                 return TRUE;
2053
2054         return FALSE;
2055 }
2056
2057 /**
2058  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2059  * g_maxplayers_spectator_blocktime seconds
2060  */
2061 void checkSpectatorBlock() {
2062         if(self.classname == "spectator" || self.classname == "observer") {
2063                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2064                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2065                         dropclient(self);
2066                 }
2067         }
2068 }
2069
2070 float vercmp_recursive(string v1, string v2)
2071 {
2072         float dot1, dot2;
2073         string s1, s2;
2074         float r;
2075
2076         dot1 = strstrofs(v1, ".", 0);
2077         dot2 = strstrofs(v2, ".", 0);
2078         if(dot1 == -1)
2079                 s1 = v1;
2080         else
2081                 s1 = substring(v1, 0, dot1);
2082         if(dot2 == -1)
2083                 s2 = v2;
2084         else
2085                 s2 = substring(v2, 0, dot2);
2086
2087         r = stof(s1) - stof(s2);
2088         if(r != 0)
2089                 return r;
2090
2091         r = strcasecmp(s1, s2);
2092         if(r != 0)
2093                 return r;
2094
2095         if(dot1 == -1)
2096                 if(dot2 == -1)
2097                         return 0;
2098                 else
2099                         return -1;
2100         else
2101                 if(dot2 == -1)
2102                         return 1;
2103                 else
2104                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2105 }
2106
2107 float vercmp(string v1, string v2)
2108 {
2109         if(strcasecmp(v1, v2) == 0) // early out check
2110                 return 0;
2111         return vercmp_recursive(v1, v2);
2112 }
2113
2114 void ObserverThink()
2115 {
2116         if (self.flags & FL_JUMPRELEASED) {
2117                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2118                         self.welcomemessage_time = 0;
2119                         self.flags &~= FL_JUMPRELEASED;
2120                         self.flags |= FL_SPAWNING;
2121                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2122                         self.welcomemessage_time = 0;
2123                         self.flags &~= FL_JUMPRELEASED;
2124                         if(SpectateNext() == 1) {
2125                                 self.classname = "spectator";
2126                         }
2127                 }
2128         } else {
2129                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2130                         self.flags |= FL_JUMPRELEASED;
2131                         if(self.flags & FL_SPAWNING)
2132                         {
2133                                 self.flags &~= FL_SPAWNING;
2134                                 LeaveSpectatorMode();
2135                                 return;
2136                         }
2137                 }
2138         }
2139         PrintWelcomeMessage(self);
2140 }
2141
2142 void SpectatorThink()
2143 {
2144         if (self.flags & FL_JUMPRELEASED) {
2145                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2146                         self.welcomemessage_time = 0;
2147                         self.flags &~= FL_JUMPRELEASED;
2148                         self.flags |= FL_SPAWNING;
2149                 } else if(self.BUTTON_ATCK) {
2150                         self.welcomemessage_time = 0;
2151                         self.flags &~= FL_JUMPRELEASED;
2152                         if(SpectateNext() == 1) {
2153                                 self.classname = "spectator";
2154                         } else {
2155                                 self.classname = "observer";
2156                                 PutClientInServer();
2157                         }
2158                 } else if (self.BUTTON_ATCK2) {
2159                         self.welcomemessage_time = 0;
2160                         self.flags &~= FL_JUMPRELEASED;
2161                         self.classname = "observer";
2162                         PutClientInServer();
2163                 } else {
2164                         if(!SpectateUpdate())
2165                                 PutObserverInServer();
2166                 }
2167         } else {
2168                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2169                         self.flags |= FL_JUMPRELEASED;
2170                         if(self.flags & FL_SPAWNING)
2171                         {
2172                                 self.flags &~= FL_SPAWNING;
2173                                 LeaveSpectatorMode();
2174                                 return;
2175                         }
2176                 }
2177         }
2178         PrintWelcomeMessage(self);
2179         self.flags |= FL_CLIENT | FL_NOTARGET;
2180 }
2181
2182 .float touchexplode_time;
2183
2184 /*
2185 =============
2186 PlayerPreThink
2187
2188 Called every frame for each client before the physics are run
2189 =============
2190 */
2191 void() ctf_setstatus;
2192 void() nexball_setstatus;
2193 .float items_added;
2194 void PlayerPreThink (void)
2195 {
2196         self.stat_sys_ticrate = cvar("sys_ticrate");
2197         self.stat_game_starttime = game_starttime;
2198         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2199
2200         if(blockSpectators && frametime)
2201                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2202                 checkSpectatorBlock();
2203
2204         zoomstate_set = 0;
2205
2206         if(self.netname_previous != self.netname)
2207         {
2208                 if(cvar("sv_eventlog"))
2209                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2210                 if(self.netname_previous)
2211                         strunzone(self.netname_previous);
2212                 self.netname_previous = strzone(self.netname);
2213         }
2214
2215         // version nagging
2216         if(self.version_nagtime)
2217                 if(self.cvar_g_nexuizversion)
2218                         if(time > self.version_nagtime)
2219                         {
2220                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
2221                                 {
2222                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
2223                                         {
2224                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2225                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2226                                         }
2227                                         else
2228                                         {
2229                                                 float r;
2230                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
2231                                                 if(r < 0)
2232                                                 {
2233                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
2234                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
2235                                                 }
2236                                                 else if(r > 0)
2237                                                 {
2238                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2239                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2240                                                 }
2241                                         }
2242                                 }
2243                                 self.version_nagtime = 0;
2244                         }
2245
2246         // GOD MODE info
2247         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2248         {
2249                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2250                 self.max_armorvalue = 0;
2251         }
2252
2253         if(frametime)
2254                 antilag_record(self);
2255
2256         if(self.classname == "player") {
2257 //              if(self.netname == "Wazat")
2258 //                      bprint(self.classname, "\n");
2259
2260                 CheckRules_Player();
2261
2262                 PrintWelcomeMessage(self);
2263
2264                 if (intermission_running)
2265                 {
2266                         IntermissionThink ();   // otherwise a button could be missed between
2267                         return;                                 // the think tics
2268                 }
2269
2270                 if(self.teleport_time)
2271                 if(time > self.teleport_time)
2272                 {
2273                         self.teleport_time = 0;
2274                         self.effects = self.effects - (self.effects & EF_NODRAW);
2275                 }
2276
2277                 Nixnex_GiveCurrentWeapon();
2278
2279                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2280                         UpdateSelectedPlayer();
2281
2282                 //don't allow the player to turn around while game is paused!
2283                 if(timeoutStatus == 2) {
2284                         self.v_angle = self.lastV_angle;
2285                         self.angles = self.lastV_angle;
2286                         self.fixangle = TRUE;
2287                 }
2288
2289                 if(frametime)
2290                         player_powerups();
2291
2292                 if (self.deadflag != DEAD_NO)
2293                 {
2294                         float button_pressed, force_respawn;
2295                         if(frametime)
2296                                 player_anim();
2297                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2298                         force_respawn = (g_lms || cvar("g_forced_respawn"));
2299                         if (self.deadflag == DEAD_DYING)
2300                         {
2301                                 if(force_respawn)
2302                                         self.deadflag = DEAD_RESPAWNING;
2303                                 else if(!button_pressed)
2304                                         self.deadflag = DEAD_DEAD;
2305                         }
2306                         else if (self.deadflag == DEAD_DEAD)
2307                         {
2308                                 if(button_pressed)
2309                                         self.deadflag = DEAD_RESPAWNABLE;
2310                         }
2311                         else if (self.deadflag == DEAD_RESPAWNABLE)
2312                         {
2313                                 if(!button_pressed)
2314                                         self.deadflag = DEAD_RESPAWNING;
2315                         }
2316                         else if (self.deadflag == DEAD_RESPAWNING)
2317                         {
2318                                 if(time > self.death_time)
2319                                 {
2320                                         self.death_time = time + 1; // only retry once a second
2321                                         respawn();
2322                                 }
2323                         }
2324                         ShowRespawnCountdown();
2325                         return;
2326                 }
2327
2328                 if(g_touchexplode)
2329                 if(time > self.touchexplode_time)
2330                 if(self.classname == "player")
2331                 if(self.deadflag == DEAD_NO)
2332                 if not(IS_INDEPENDENT_PLAYER(self))
2333                 FOR_EACH_PLAYER(other) if(self != other)
2334                 {
2335                         if(time > other.touchexplode_time)
2336                         if(other.classname == "player")
2337                         if(other.deadflag == DEAD_NO)
2338                         if not(IS_INDEPENDENT_PLAYER(other))
2339                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2340                         {
2341                                 PlayerTouchExplode(self, other);
2342                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2343                         }
2344                 }
2345
2346                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2347                 {
2348                         vector dist;
2349
2350                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2351                         dist = self.prevorigin - self.origin;
2352                         dist_z = 0;
2353                         self.lms_traveled_distance += fabs(vlen(dist));
2354
2355                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2356                         {
2357                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2358                                 self.lms_traveled_distance = 0;
2359                         }
2360
2361                         if(time > self.lms_nextcheck)
2362                         {
2363                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2364                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2365                                 {
2366                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2367                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2368                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2369                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2370                                 }
2371                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2372                                 self.lms_traveled_distance = 0;
2373                         }
2374                 }
2375
2376                 self.prevorigin = self.origin;
2377
2378                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2379                 {
2380                         if (!self.crouch)
2381                         {
2382                                 self.crouch = TRUE;
2383                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2384                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2385                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2386                         }
2387                 }
2388                 else
2389                 {
2390                         if (self.crouch)
2391                         {
2392                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2393                                 if (!trace_startsolid)
2394                                 {
2395                                         self.crouch = FALSE;
2396                                         self.view_ofs = PL_VIEW_OFS;
2397                                         setsize (self, PL_MIN, PL_MAX);
2398                                 }
2399                         }
2400                 }
2401
2402                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2403                 {
2404                         if(self.bloodloss_timer < time)
2405                         {
2406                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2407                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2408                         }
2409                 }
2410
2411                 FixPlayermodel();
2412
2413                 GrapplingHookFrame();
2414
2415                 if(frametime)
2416                 {
2417                         self.items &~= self.items_added;
2418
2419                         W_WeaponFrame();
2420
2421                         self.items_added = 0;
2422                         if(self.items & IT_JETPACK)
2423                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2424                                         self.items_added |= IT_FUEL;
2425
2426                         self.items |= self.items_added;
2427                 }
2428
2429                 player_regen();
2430                 if(frametime)
2431                         player_anim();
2432
2433                 if (g_minstagib)
2434                         minstagib_ammocheck();
2435
2436                 ctf_setstatus();
2437                 kh_setstatus();
2438                 nexball_setstatus();
2439
2440                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2441
2442                 //self.angles_y=self.v_angle_y + 90;   // temp
2443
2444                 //if (TetrisPreFrame()) return;
2445         } else if(gameover) {
2446                 if (intermission_running)
2447                         IntermissionThink ();   // otherwise a button could be missed between
2448                 return;
2449         } else if(self.classname == "observer") {
2450                 ObserverThink();
2451         } else if(self.classname == "spectator") {
2452                 SpectatorThink();
2453         }
2454
2455         if(!zoomstate_set)
2456                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2457
2458         float oldspectatee_status;
2459         oldspectatee_status = self.spectatee_status;
2460         if(self.classname == "spectator")
2461                 self.spectatee_status = num_for_edict(self.enemy);
2462         else if(self.classname == "observer")
2463                 self.spectatee_status = num_for_edict(self);
2464         else
2465                 self.spectatee_status = 0;
2466         if(self.spectatee_status != oldspectatee_status)
2467         {
2468                 ClientData_Touch(self);
2469                 if(g_race)
2470                         race_InitSpectator();
2471         }
2472
2473         if(self.teamkill_soundtime)
2474         if(time > self.teamkill_soundtime)
2475         {
2476                 self.teamkill_soundtime = 0;
2477
2478                 entity oldpusher, oldself;
2479
2480                 oldself = self; self = self.teamkill_soundsource;
2481                 oldpusher = self.pusher; self.pusher = oldself;
2482
2483                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2484
2485                 self.pusher = oldpusher;
2486                 self = oldself;
2487         }
2488
2489         if(self.taunt_soundtime)
2490         if(time > self.taunt_soundtime)
2491         {
2492                 self.taunt_soundtime = 0;
2493                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2494         }
2495
2496         target_voicescript_next(self);
2497 }
2498
2499 // on dragger:
2500 .entity dragentity;
2501 .float draggravity;
2502 .float dragspeed; // speed of mouse wheel action
2503 .float dragdistance; // distance of dragentity's draglocalvector from view_ofs
2504 .vector draglocalvector; // local attachment vector of the dragentity
2505 .float draglocalangle;
2506 // on draggee:
2507 .entity draggedby;
2508 .float dragmovetype;
2509 void Drag_Begin(entity dragger, entity draggee, vector touchpoint)
2510 {
2511         float tagscale;
2512
2513         draggee.dragmovetype = draggee.movetype;
2514         draggee.draggravity = draggee.gravity;
2515         draggee.movetype = MOVETYPE_WALK;
2516         draggee.gravity = 0.00001;
2517         draggee.flags &~= FL_ONGROUND;
2518         draggee.draggedby = dragger;
2519
2520         dragger.dragentity = draggee;
2521
2522         dragger.dragdistance = vlen(touchpoint - dragger.origin - dragger.view_ofs);
2523         dragger.draglocalangle = draggee.angles_y - dragger.v_angle_y;
2524         touchpoint = touchpoint - gettaginfo(draggee, 0);
2525         tagscale = pow(vlen(v_forward), -2);
2526         dragger.draglocalvector_x = touchpoint * v_forward * tagscale;
2527         dragger.draglocalvector_y = touchpoint * v_right * tagscale;
2528         dragger.draglocalvector_z = touchpoint * v_up * tagscale;
2529
2530         dragger.dragspeed = 64;
2531 }
2532
2533 void Drag_Finish(entity dragger)
2534 {
2535         entity draggee;
2536         draggee = dragger.dragentity;
2537         if(dragger)
2538                 dragger.dragentity = world;
2539         draggee.draggedby = world;
2540         draggee.movetype = draggee.dragmovetype;
2541         draggee.gravity = draggee.draggravity;
2542
2543         switch(draggee.movetype)
2544         {
2545                 case MOVETYPE_TOSS:
2546                 case MOVETYPE_WALK:
2547                 case MOVETYPE_STEP:
2548                 case MOVETYPE_FLYMISSILE:
2549                 case MOVETYPE_BOUNCE:
2550                 case MOVETYPE_BOUNCEMISSILE:
2551                         break;
2552                 default:
2553                         draggee.velocity = '0 0 0';
2554                         break;
2555         }
2556
2557         if((draggee.flags & FL_ITEM) && (vlen(draggee.velocity) < 32))
2558         {
2559                 draggee.velocity = '0 0 0';
2560                 draggee.flags |= FL_ONGROUND; // floating items are FUN
2561         }
2562 }
2563
2564 float Drag_IsDraggable(entity draggee)
2565 {
2566         // TODO add more checks for bad stuff here
2567         if(draggee.classname == "func_bobbing")
2568                 return FALSE;
2569         if(draggee.classname == "door") // FIXME find out why these must be excluded, or work around the problem (trying to drag these causes like 4 fps)
2570                 return FALSE;
2571         if(draggee.classname == "plat")
2572                 return FALSE;
2573         if(draggee.classname == "func_button")
2574                 return FALSE;
2575         if(draggee.model == "")
2576                 return FALSE;
2577         if(draggee.classname == "spectator")
2578                 return FALSE;
2579         if(draggee.classname == "observer")
2580                 return FALSE;
2581         if(draggee.classname == "exteriorweaponentity")
2582                 return FALSE;
2583
2584         return TRUE;
2585 }
2586
2587 float Drag_MayChangeAngles(entity draggee)
2588 {
2589         // TODO add more checks for bad stuff here
2590         if(substring(draggee.model, 0, 1) == "*")
2591                 return FALSE;
2592         return TRUE;
2593 }
2594
2595 void Drag_MoveForward(entity dragger)
2596 {
2597         dragger.dragdistance += dragger.dragspeed;
2598 }
2599
2600 void Drag_SetSpeed(entity dragger, float s)
2601 {
2602         dragger.dragspeed = pow(2, s);
2603 }
2604
2605 void Drag_MoveBackward(entity dragger)
2606 {
2607         dragger.dragdistance = max(0, dragger.dragdistance - dragger.dragspeed);
2608 }
2609
2610 void Drag_Update(entity dragger)
2611 {
2612         vector curorigin, neworigin, goodvelocity;
2613         float f;
2614         entity draggee;
2615
2616         draggee = dragger.dragentity;
2617         draggee.flags &~= FL_ONGROUND;
2618
2619         curorigin = gettaginfo(draggee, 0);
2620         curorigin = curorigin + v_forward * dragger.draglocalvector_x + v_right * dragger.draglocalvector_y + v_up * dragger.draglocalvector_z;
2621         makevectors(dragger.v_angle);
2622         neworigin = dragger.origin + dragger.view_ofs + v_forward * dragger.dragdistance;
2623         goodvelocity = (neworigin - curorigin) * (1 / frametime);
2624
2625         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle > 180)
2626                 dragger.draglocalangle += 360;
2627         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle <= -180)
2628                 dragger.draglocalangle -= 360;
2629
2630         f = min(frametime * 10, 1);
2631         draggee.velocity = draggee.velocity * (1 - f) + goodvelocity * f;
2632
2633         if(Drag_MayChangeAngles(draggee))
2634                 draggee.angles_y = draggee.angles_y * (1 - f) + (dragger.v_angle_y + dragger.draglocalangle) * f;
2635
2636         draggee.ltime = max(servertime + serverframetime, draggee.ltime); // fixes func_train breakage
2637
2638         te_lightning1(dragger, dragger.origin + dragger.view_ofs, curorigin);
2639 }
2640
2641 float Drag_CanDrag(entity dragger)
2642 {
2643         return (dragger.deadflag == DEAD_NO) || (dragger.classname == "player");
2644 }
2645
2646 float Drag_IsDragging(entity dragger)
2647 {
2648         if(!dragger.dragentity)
2649                 return FALSE;
2650         if(wasfreed(dragger.dragentity) || dragger.dragentity.draggedby != dragger)
2651         {
2652                 dragger.dragentity = world;
2653                 return FALSE;
2654         }
2655         if(!Drag_CanDrag(dragger) || !Drag_IsDraggable(dragger.dragentity))
2656         {
2657                 Drag_Finish(dragger);
2658                 return FALSE;
2659         }
2660         return TRUE;
2661 }
2662
2663 void Drag_MoveDrag(entity from, entity to)
2664 {
2665         if(from.draggedby)
2666         {
2667                 to.draggedby = from.draggedby;
2668                 to.draggedby.dragentity = to;
2669                 from.draggedby = world;
2670         }
2671 }
2672
2673 /*
2674 =============
2675 PlayerPostThink
2676
2677 Called every frame for each client after the physics are run
2678 =============
2679 */
2680 .float idlekick_lasttimeleft;
2681 .float race_penalty;
2682 .float race_penalty_nagged;
2683 .float race_penalty_nagtime;
2684 void PlayerPostThink (void)
2685 {
2686         // Savage: Check for nameless players
2687         if (strlen(self.netname) < 1) {
2688                 self.netname = "Player";
2689                 stuffcmd(self, "seta _cl_name Player\n");
2690         }
2691
2692         if(sv_maxidle && frametime)
2693         {
2694                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2695                 float timeleft;
2696                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2697                 if(timeleft <= 0)
2698                 {
2699                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2700                         announce(self, "announcer/robotic/terminated.wav");
2701                         dropclient(self);
2702                         return;
2703                 }
2704                 else if(timeleft <= 10)
2705                 {
2706                         if(timeleft != self.idlekick_lasttimeleft)
2707                         {
2708                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2709                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".wav"));
2710                         }
2711                 }
2712                 else
2713                 {
2714                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2715                 }
2716                 self.idlekick_lasttimeleft = timeleft;
2717         }
2718
2719         if(sv_cheats)
2720                 if(Drag_CanDrag(self))
2721                         if(self.BUTTON_DRAG)
2722                                 if(!self.dragentity)
2723                                         if(self.cursor_trace_ent)
2724                                                 if(Drag_IsDraggable(self.cursor_trace_ent))
2725                                                 {
2726                                                         if(self.cursor_trace_ent.draggedby)
2727                                                                 Drag_Finish(self.cursor_trace_ent.draggedby);
2728                                                         if(self.cursor_trace_ent.tag_entity)
2729                                                                 detach_sameorigin(self.cursor_trace_ent);
2730                                                         Drag_Begin(self, self.cursor_trace_ent, self.cursor_trace_endpos);
2731                                                 }
2732
2733         if(Drag_IsDragging(self))
2734         {
2735                 if(self.BUTTON_DRAG)
2736                 {
2737                         if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
2738                         {
2739                                 Drag_MoveForward(self);
2740                                 self.impulse = 0;
2741                         }
2742                         else if(self.impulse == 12 || self.impulse == 16 || self.impulse == 19)
2743                         {
2744                                 Drag_MoveBackward(self);
2745                                 self.impulse = 0;
2746                         }
2747                         else if(self.impulse >= 1 && self.impulse <= 9)
2748                         {
2749                                 Drag_SetSpeed(self, self.impulse - 1);
2750                         }
2751                         else if(self.impulse == 14)
2752                         {
2753                                 Drag_SetSpeed(self, 9);
2754                         }
2755
2756                         if(frametime)
2757                                 Drag_Update(self);
2758                 }
2759                 else
2760                 {
2761                         Drag_Finish(self);
2762                 }
2763         }
2764
2765         if(self.classname == "player") {
2766                 CheckRules_Player();
2767                 UpdateChatBubble();
2768                 UpdateTeamBubble();
2769                 if (self.impulse)
2770                         ImpulseCommands();
2771                 if (intermission_running)
2772                         return;         // intermission or finale
2773
2774                 //if (TetrisPostFrame()) return;
2775
2776                 // restart countdown
2777                         if(time < game_starttime) {
2778                                 if (!cvar("sv_ready_restart_after_countdown"))
2779                                 {
2780                                         if(self.movement != '0 0 0' && g_race && !g_race_qualifying)
2781                                         {
2782                                                 if(time < game_starttime - 2)
2783                                                 {
2784                                                         if(!self.race_penalty_nagged)
2785                                                         {
2786                                                                 // TODO better notification for this!
2787                                                                 self.race_penalty_nagtime = 0;
2788                                                                 self.race_penalty_nagged = 1;
2789                                                         }
2790                                                 }
2791                                                 else if(!self.race_penalty)
2792                                                 {
2793                                                         self.race_penalty_nagtime = 0;
2794                                                         self.race_penalty = time + 5;
2795                                                 }
2796                                         }
2797                                         if(time > self.race_penalty_nagtime)
2798                                         {
2799                                                 if(self.race_penalty > time)
2800                                                 {
2801                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1FIVE SECONDS PENALTY.");
2802                                                 }
2803                                                 else if(self.race_penalty_nagged && time < game_starttime - 2)
2804                                                 {
2805                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1DO NOT MOVE DURING THE COUNTDOWN.");
2806                                                 }
2807                                                 self.race_penalty_nagtime = time + self.cvar_scr_centertime * 0.6;
2808                                         }
2809                                         self.movetype = MOVETYPE_NONE;
2810                                         self.velocity = '0 0 0';
2811                                         self.avelocity = '0 0 0';
2812                                         self.movement = '0 0 0';
2813                                 }
2814                         }
2815                         else if (time < self.race_penalty)
2816                         {
2817                                 self.movetype = MOVETYPE_NONE;
2818                                 self.velocity = '0 0 0';
2819                                 self.avelocity = '0 0 0';
2820                                 self.movement = '0 0 0';
2821                         }
2822                         else
2823                         {
2824                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2825                                 if (!cvar("sv_ready_restart_after_countdown"))
2826                                 {
2827                                         if(self.movetype == MOVETYPE_NONE)
2828                                         {
2829                                                 self.movetype = MOVETYPE_WALK;
2830                                         }
2831                                         self.race_penalty = 0;
2832                                         self.race_penalty_nagged = 0;
2833                                 }
2834                         }
2835                 GetPressedKeys();
2836         } else if (self.classname == "observer") {
2837                 //do nothing
2838         } else if (self.classname == "spectator") {
2839                 //do nothing
2840         }
2841
2842         /*
2843         float i;
2844         for(i = 0; i < 1000; ++i)
2845         {
2846                 vector end;
2847                 end = self.origin + '0 0 1024' + 512 * randomvec();
2848                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2849                 if(trace_fraction < 1)
2850                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2851                 {
2852                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2853                         break;
2854                 }
2855         }
2856         */
2857
2858         Arena_Warmup();
2859
2860         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2861 }