data/qcsrc/server/cl_client.qc

   1 // let's abuse an existing field
   2 #define SPAWNPOINT_SCORE frags
   3
   4 .float wantswelcomemessage;
   5 .string netname_previous;
   6
   7 void spawnfunc_info_player_survivor (void)
   8 {
   9         spawnfunc_info_player_deathmatch();
  10 }
  11
  12 void spawnfunc_info_player_start (void)
  13 {
  14         spawnfunc_info_player_deathmatch();
  15 }
  16
  17 void spawnfunc_info_player_deathmatch (void)
  18 {
  19         self.classname = "info_player_deathmatch";
  20         relocate_spawnpoint();
  21 }
  22
  23 void spawnpoint_use()
  24 {
  25         if(teams_matter)
  26         if(have_team_spawns)
  27         {
  28                 self.team = activator.team;
  29                 some_spawn_has_been_used = 1;
  30         }
  31 };
  32
  33 // Returns:
  34 //   -1 if a spawn can't be used
  35 //   otherwise, a weight of the spawnpoint
  36 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
  37 {
  38         float shortest, thisdist;
  39         entity player;
  40
  41         // filter out spots for the wrong team
  42         if(teamcheck)
  43         if(spot.team != teamcheck)
  44                 return -1;
  45
  46         if(race_spawns)
  47                 if(spot.target == "")
  48                         return -1;
  49
  50         // filter out spots for assault
  51         if(spot.target != "") {
  52                 local entity ent;
  53                 float good;
  54                 ent = find(world, targetname, spot.target);
  55                 while(ent) {
  56                         if(ent.classname == "target_objective")
  57                         {
  58                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  59                                         return -1;
  60                                 good = 1;
  61                         }
  62                         else if(ent.classname == "trigger_race_checkpoint")
  63                         {
  64                                 if(self.classname == "player") // spectators may spawn everywhere
  65                                 {
  66                                         if(ent.race_checkpoint != race_PreviousCheckpoint(self.race_checkpoint))
  67                                                 return -1;
  68                                         float pl;
  69                                         pl = self.race_place;
  70                                         if(pl > race_highest_place_spawn)
  71                                                 pl = 0;
  72                                         if(spot.race_place != pl)
  73                                                 return -1;
  74                                 }
  75                                 good = 1;
  76                         }
  77                         else
  78                         {
  79                         }
  80                         ent = find(ent, targetname, spot.target);
  81                 }
  82
  83                 if(!good)
  84                         return -1;
  85         }
  86
  87         player = playerlist;
  88         shortest = vlen(world.maxs - world.mins);
  89         for(player = playerlist; player; player = player.chain)
  90                 if (player != self)
  91                 {
  92                         thisdist = vlen(player.origin - spot.origin);
  93                         if (thisdist < shortest)
  94                                 shortest = thisdist;
  95                 }
  96         return shortest;
  97 }
  98
  99 float spawn_allbad;
 100 float spawn_allgood;
 101 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
 102 {
 103         local entity spot, spotlist, spotlistend;
 104         spawn_allgood = TRUE;
 105         spawn_allbad = TRUE;
 106
 107         spotlist = world;
 108         spotlistend = world;
 109
 110         for(spot = firstspot; spot; spot = spot.chain)
 111         {
 112                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
 113
 114                 if(cvar("spawn_debugview"))
 115                 {
 116                         setmodel(spot, "models/runematch/rune.mdl");
 117                         if(spot.SPAWNPOINT_SCORE < mindist)
 118                         {
 119                                 spot.colormod = '1 0 0';
 120                                 spot.scale = 1;
 121                         }
 122                         else
 123                         {
 124                                 spot.colormod = '0 1 0';
 125                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
 126                         }
 127                 }
 128
 129                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 130                 {
 131                         if(spot.SPAWNPOINT_SCORE < mindist)
 132                         {
 133                                 // too short distance
 134                                 spawn_allgood = FALSE;
 135                         }
 136                         else
 137                         {
 138                                 // perfect
 139                                 spawn_allbad = FALSE;
 140
 141                                 if(spotlistend)
 142                                         spotlistend.chain = spot;
 143                                 spotlistend = spot;
 144                                 if(!spotlist)
 145                                         spotlist = spot;
 146
 147                                 /*
 148                                 if(teamcheck)
 149                                 if(spot.team != teamcheck)
 150                                         error("invalid spawn added");
 151
 152                                 print("added ", etos(spot), "\n");
 153                                 */
 154                         }
 155                 }
 156         }
 157         if(spotlistend)
 158                 spotlistend.chain = world;
 159
 160         /*
 161                 entity e;
 162                 if(teamcheck)
 163                         for(e = spotlist; e; e = e.chain)
 164                         {
 165                                 print("seen ", etos(e), "\n");
 166                                 if(e.team != teamcheck)
 167                                         error("invalid spawn found");
 168                         }
 169         */
 170
 171         return spotlist;
 172 }
 173
 174 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 175 {
 176         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 177         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 178         local entity spot;
 179
 180         RandomSelection_Init();
 181         for(spot = firstspot; spot; spot = spot.chain)
 182                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 183
 184         return RandomSelection_chosen_ent;
 185 }
 186
 187 /*
 188 =============
 189 SelectSpawnPoint
 190
 191 Finds a point to respawn
 192 =============
 193 */
 194 entity SelectSpawnPoint (float anypoint)
 195 {
 196         local float teamcheck;
 197         local entity firstspot_new;
 198         local entity spot, firstspot, playerlist;
 199
 200         spot = find (world, classname, "testplayerstart");
 201         if (spot)
 202                 return spot;
 203
 204         teamcheck = 0;
 205
 206         if(!anypoint && have_team_spawns)
 207                 teamcheck = self.team;
 208
 209         // get the list of players
 210         playerlist = findchain(classname, "player");
 211         // get the entire list of spots
 212         firstspot = findchain(classname, "info_player_deathmatch");
 213         // filter out the bad ones
 214         // (note this returns the original list if none survived)
 215         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 216         if(!firstspot_new)
 217                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 218         firstspot = firstspot_new;
 219
 220         // there is 50/50 chance of choosing a random spot or the furthest spot
 221         // (this means that roughly every other spawn will be furthest, so you
 222         // usually won't get fragged at spawn twice in a row)
 223         if (arena_roundbased)
 224         {
 225                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 226                 if(firstspot_new)
 227                         firstspot = firstspot_new;
 228                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 229         }
 230         else if (random() > cvar("g_spawn_furthest"))
 231                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 232         else
 233                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 234
 235         if(cvar("spawn_debugview"))
 236         {
 237                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 238
 239                 entity e;
 240                 if(teamcheck)
 241                         for(e = firstspot; e; e = e.chain)
 242                                 if(e.team != teamcheck)
 243                                         error("invalid spawn found");
 244         }
 245
 246         if (!spot)
 247         {
 248                 if(cvar("spawn_debug"))
 249                         GotoNextMap();
 250                 else
 251                 {
 252                         if(some_spawn_has_been_used)
 253                                 return world; // team can't spawn any more, because of actions of other team
 254                         else
 255                                 error("Cannot find a spawn point - please fix the map!");
 256                 }
 257         }
 258
 259         return spot;
 260 }
 261
 262 /*
 263 =============
 264 CheckPlayerModel
 265
 266 Checks if the argument string can be a valid playermodel.
 267 Returns a valid one in doubt.
 268 =============
 269 */
 270 string FallbackPlayerModel = "models/player/marine.zym";
 271 string CheckPlayerModel(string plyermodel) {
 272         if(strlen(plyermodel) < 4)
 273                 return FallbackPlayerModel;
 274         if( substring(plyermodel,0,14) != "models/player/")
 275                 return FallbackPlayerModel;
 276         else if(cvar("sv_servermodelsonly"))
 277         {
 278                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 279                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 280                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 281                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 282                         return FallbackPlayerModel;
 283                 if(!fexists(plyermodel))
 284                         return FallbackPlayerModel;
 285         }
 286         return plyermodel;
 287 }
 288
 289 /*
 290 =============
 291 Client_customizeentityforclient
 292
 293 LOD reduction
 294 =============
 295 */
 296 float Client_customizeentityforclient()
 297 {
 298 #ifdef ALLOW_VARIABLE_LOD
 299         // self: me
 300         // other: the player viewing me
 301         float distance;
 302         float f;
 303
 304         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 305                 return TRUE;
 306
 307         if(other.cvar_cl_playerdetailreduction <= 0)
 308         {
 309                 if(other.cvar_cl_playerdetailreduction <= -2)
 310                         self.modelindex = self.modelindex_lod2;
 311                 else if(other.cvar_cl_playerdetailreduction <= -1)
 312                         self.modelindex = self.modelindex_lod1;
 313                 else
 314                         self.modelindex = self.modelindex_lod0;
 315         }
 316         else
 317         {
 318                 distance = vlen(self.origin - other.origin);
 319                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 320                 if(f > 10000)
 321                         self.modelindex = self.modelindex_lod2;
 322                 else if(f > 5000)
 323                         self.modelindex = self.modelindex_lod1;
 324                 else
 325                         self.modelindex = self.modelindex_lod0;
 326         }
 327 #endif
 328
 329         return TRUE;
 330 }
 331
 332 void UpdatePlayerSounds();
 333 void setmodel_lod(entity e, string modelname)
 334 {
 335 #ifdef ALLOW_VARIABLE_LOD
 336         string s;
 337
 338         // FIXME: this only supports 3-letter extensions
 339         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 340         if(fexists(s))
 341         {
 342                 precache_model(s);
 343                 setmodel(e, s); // players have high precision
 344                 self.modelindex_lod1 = self.modelindex;
 345         }
 346         else
 347                 self.modelindex_lod1 = -1;
 348
 349         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 350         if(fexists(s))
 351         {
 352                 precache_model(s);
 353                 setmodel(e, s); // players have high precision
 354                 self.modelindex_lod2 = self.modelindex;
 355         }
 356         else
 357                 self.modelindex_lod2 = -1;
 358
 359         precache_model(modelname);
 360         setmodel(e, modelname); // players have high precision
 361         self.modelindex_lod0 = self.modelindex;
 362
 363         if(self.modelindex_lod1 < 0)
 364                 self.modelindex_lod1 = self.modelindex;
 365
 366         if(self.modelindex_lod2 < 0)
 367                 self.modelindex_lod2 = self.modelindex;
 368 #else
 369         precache_model(modelname);
 370         setmodel(e, modelname); // players have high precision
 371 #endif
 372         player_setupanimsformodel();
 373         UpdatePlayerSounds();
 374 }
 375
 376 /*
 377 =============
 378 PutObserverInServer
 379
 380 putting a client as observer in the server
 381 =============
 382 */
 383 void PutObserverInServer (void)
 384 {
 385         entity  spot;
 386
 387         race_PreSpawnObserver();
 388
 389         spot = SelectSpawnPoint (TRUE);
 390         if(!spot)
 391                 error("No spawnpoints for observers?!?\n");
 392         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 393
 394         if(clienttype(self) == CLIENTTYPE_REAL)
 395         {
 396                 msg_entity = self;
 397                 WriteByte(MSG_ONE, SVC_SETVIEW);
 398                 WriteEntity(MSG_ONE, self);
 399         }
 400
 401         DropAllRunes(self);
 402         kh_Key_DropAll(self, TRUE);
 403
 404         Portal_ClearAll(self);
 405
 406         if(self.flagcarried)
 407                 DropFlag(self.flagcarried);
 408
 409         WaypointSprite_PlayerDead();
 410
 411         if(self.killcount != -666)
 412         {
 413                 if(g_lms)
 414                 {
 415                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 416                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 417                         else
 418                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 419                 }
 420                 else
 421                         bprint ("^4", self.netname, "^4 is spectating now\n");
 422         }
 423
 424         PlayerScore_Clear(self); // clear scores when needed
 425
 426         self.spectatortime = time;
 427
 428         self.classname = "observer";
 429         self.health = -666;
 430         self.takedamage = DAMAGE_NO;
 431         self.solid = SOLID_NOT;
 432         self.movetype = MOVETYPE_NOCLIP;
 433         self.flags = FL_CLIENT | FL_NOTARGET;
 434         self.armorvalue = 666;
 435         self.effects = 0;
 436         self.armorvalue = cvar("g_balance_armor_start");
 437         self.pauserotarmor_finished = 0;
 438         self.pauserothealth_finished = 0;
 439         self.pauseregen_finished = 0;
 440         self.damageforcescale = 0;
 441         self.death_time = 0;
 442         self.dead_frame = 0;
 443         self.alpha = 0;
 444         self.scale = 0;
 445         self.fade_time = 0;
 446         self.pain_frame = 0;
 447         self.pain_finished = 0;
 448         self.strength_finished = 0;
 449         self.invincible_finished = 0;
 450         self.pushltime = 0;
 451         self.think = SUB_Null;
 452         self.nextthink = 0;
 453         self.hook_time = 0;
 454         self.runes = 0;
 455         self.deadflag = DEAD_NO;
 456         self.angles = spot.angles;
 457         self.angles_z = 0;
 458         self.fixangle = TRUE;
 459         self.crouch = FALSE;
 460
 461         self.view_ofs = PL_VIEW_OFS;
 462         setorigin (self, spot.origin);
 463         setsize (self, '0 0 0', '0 0 0');
 464         self.oldorigin = self.origin;
 465         self.items = 0;
 466         self.weapons = 0;
 467         self.model = "";
 468         self.modelindex = 0;
 469         self.weapon = 0;
 470         self.weaponmodel = "";
 471         self.weaponentity = world;
 472         self.killcount = -666;
 473         self.velocity = '0 0 0';
 474         self.avelocity = '0 0 0';
 475         self.punchangle = '0 0 0';
 476         self.punchvector = '0 0 0';
 477         self.oldvelocity = self.velocity;
 478         self.customizeentityforclient = Client_customizeentityforclient;
 479         self.wantswelcomemessage = 1;
 480
 481         if(g_arena)
 482         {
 483                 if(self.version_mismatch)
 484                 {
 485                         Spawnqueue_Unmark(self);
 486                         Spawnqueue_Remove(self);
 487                 }
 488                 else
 489                 {
 490                         Spawnqueue_Insert(self);
 491                 }
 492         }
 493         else if(g_lms)
 494         {
 495                 // Only if the player cannot play at all
 496                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 497                         self.frags = -666;
 498                 else
 499                         self.frags = -667;
 500         }
 501         else
 502                 self.frags = -666;
 503 }
 504
 505 float RestrictSkin(float s)
 506 {
 507         if(!teams_matter)
 508                 return s;
 509         if(s == 6)
 510                 return 6;
 511         return mod(s, 3);
 512 }
 513
 514 void FixPlayermodel()
 515 {
 516         local string defaultmodel;
 517         local float defaultskin;
 518         local vector m1, m2;
 519
 520         defaultmodel = "";
 521
 522         if(cvar("sv_defaultcharacter") == 1) {
 523                 defaultskin = 0;
 524
 525                 if(teams_matter)
 526                 {
 527                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 528                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 529                 }
 530
 531                 if(defaultmodel == "")
 532                 {
 533                         defaultmodel = cvar_string("sv_defaultplayermodel");
 534                         defaultskin = cvar("sv_defaultplayerskin");
 535                 }
 536         }
 537
 538         if(defaultmodel != "")
 539         {
 540                 if (defaultmodel != self.model)
 541                 {
 542                         m1 = self.mins;
 543                         m2 = self.maxs;
 544                         setmodel_lod (self, defaultmodel);
 545                         setsize (self, m1, m2);
 546                 }
 547
 548                 self.skin = defaultskin;
 549         } else {
 550                 if (self.playermodel != self.model)
 551                 {
 552                         self.playermodel = CheckPlayerModel(self.playermodel);
 553                         m1 = self.mins;
 554                         m2 = self.maxs;
 555                         setmodel_lod (self, self.playermodel);
 556                         setsize (self, m1, m2);
 557                 }
 558
 559                 self.skin = RestrictSkin(stof(self.playerskin));
 560         }
 561
 562         if(!teams_matter)
 563                 if(strlen(cvar_string("sv_defaultplayercolors")))
 564                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 565                                 setcolor(self, cvar("sv_defaultplayercolors"));
 566 }
 567
 568 /*
 569 =============
 570 PutClientInServer
 571
 572 Called when a client spawns in the server
 573 =============
 574 */
 575 //void() ctf_playerchanged;
 576 void PutClientInServer (void)
 577 {
 578         if(clienttype(self) == CLIENTTYPE_BOT)
 579         {
 580                 self.classname = "player";
 581         }
 582         else if(clienttype(self) == CLIENTTYPE_REAL)
 583         {
 584                 msg_entity = self;
 585                 WriteByte(MSG_ONE, SVC_SETVIEW);
 586                 WriteEntity(MSG_ONE, self);
 587         }
 588
 589         if(g_tourney)
 590         {
 591                 msg_entity = self;
 592                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
 593                 WriteByte(MSG_ONE, TE_CSQC_WARMUP);
 594                 WriteByte(MSG_ONE, !tourneyInMatchStage);
 595         }
 596
 597         // player is dead and becomes observer
 598         // FIXME fix LMS scoring for new system
 599         if(g_lms)
 600         {
 601                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 602                         self.classname = "observer";
 603         }
 604
 605         if(g_arena)
 606         if(!self.spawned)
 607                 self.classname = "observer";
 608
 609         if(self.classname == "player") {
 610                 entity  spot;
 611
 612                 race_PreSpawn();
 613
 614                 spot = SelectSpawnPoint (FALSE);
 615                 if(!spot)
 616                 {
 617                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 618                         return; // spawn failed
 619                 }
 620
 621                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 622
 623                 self.classname = "player";
 624                 self.iscreature = TRUE;
 625                 self.movetype = MOVETYPE_WALK;
 626                 self.solid = SOLID_SLIDEBOX;
 627                 if(independent_players)
 628                         MAKE_INDEPENDENT_PLAYER(self);
 629                 self.flags = FL_CLIENT;
 630                 self.takedamage = DAMAGE_AIM;
 631                 if(g_minstagib)
 632                         self.effects = EF_FULLBRIGHT;
 633                 else
 634                         self.effects = 0;
 635                 self.air_finished = time + 12;
 636                 self.dmg = 2;
 637
 638                 self.ammo_shells = start_ammo_shells;
 639                 self.ammo_nails = start_ammo_nails;
 640                 self.ammo_rockets = start_ammo_rockets;
 641                 self.ammo_cells = start_ammo_cells;
 642                 self.health = start_health;
 643                 self.armorvalue = start_armorvalue;
 644                 self.items = start_items;
 645                 self.weapons = start_weapons;
 646                 self.switchweapon = start_switchweapon;
 647                 self.cnt = start_switchweapon;
 648                 self.weapon = 0;
 649                 self.jump_interval = time;
 650
 651                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 652                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 653                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 654                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 655                 //extend the pause of rotting if client was reset at the beginning of the countdown
 656                 if(!cvar("sv_ready_restart_after_countdown") && time < restart_countdown) {
 657                         self.spawnshieldtime += RESTART_COUNTDOWN;
 658                         self.pauserotarmor_finished += RESTART_COUNTDOWN;
 659                         self.pauserothealth_finished += RESTART_COUNTDOWN;
 660                         self.pauseregen_finished += RESTART_COUNTDOWN;
 661                 }
 662                 self.damageforcescale = 2;
 663                 self.death_time = 0;
 664                 self.dead_frame = 0;
 665                 self.alpha = 0;
 666                 self.scale = 0;
 667                 self.fade_time = 0;
 668                 self.pain_frame = 0;
 669                 self.pain_finished = 0;
 670                 self.strength_finished = 0;
 671                 self.invincible_finished = 0;
 672                 self.pushltime = 0;
 673                 //self.speed_finished = 0;
 674                 //self.slowmo_finished = 0;
 675                 // players have no think function
 676                 self.think = SUB_Null;
 677                 self.nextthink = 0;
 678                 self.hook_time = 0;
 679
 680                 self.runes = 0;
 681
 682                 self.deadflag = DEAD_NO;
 683
 684                 self.angles = spot.angles;
 685
 686                 self.angles_z = 0; // never spawn tilted even if the spot says to
 687                 self.fixangle = TRUE; // turn this way immediately
 688                 self.velocity = '0 0 0';
 689                 self.avelocity = '0 0 0';
 690                 self.punchangle = '0 0 0';
 691                 self.punchvector = '0 0 0';
 692                 self.oldvelocity = self.velocity;
 693
 694                 msg_entity = self;
 695                 WRITESPECTATABLE_MSG_ONE({
 696                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 697                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 698                 });
 699
 700                 self.customizeentityforclient = Client_customizeentityforclient;
 701
 702                 self.model = "";
 703                 FixPlayermodel();
 704
 705                 self.crouch = FALSE;
 706                 self.view_ofs = PL_VIEW_OFS;
 707                 setsize (self, PL_MIN, PL_MAX);
 708                 self.spawnorigin = spot.origin;
 709                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 710                 // don't reset back to last position, even if new position is stuck in solid
 711                 self.oldorigin = self.origin;
 712
 713                 if(g_arena)
 714                 {
 715                         Spawnqueue_Remove(self);
 716                         Spawnqueue_Mark(self);
 717                 }
 718
 719                 self.event_damage = PlayerDamage;
 720
 721                 self.bot_attack = TRUE;
 722
 723                 self.statdraintime = time + 5;
 724                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 725
 726                 if(self.killcount == -666) {
 727                         PlayerScore_Clear(self);
 728                         self.killcount = 0;
 729                         self.frags = 0;
 730                 }
 731
 732                 self.cnt = WEP_LASER;
 733                 self.nixnex_lastchange_id = -1;
 734
 735                 CL_SpawnWeaponentity();
 736                 self.alpha = default_player_alpha;
 737                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 738                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 739
 740                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 741                 self.lms_traveled_distance = 0;
 742                 self.speedrunning = FALSE;
 743
 744                 race_PostSpawn(spot);
 745
 746                 if(cvar("spawn_debug"))
 747                 {
 748                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 749                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 750                 }
 751
 752                 //stuffcmd(self, "chase_active 0");
 753                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 754
 755                 if (cvar("g_spawnsound"))
 756                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 757
 758                 if(g_assault) {
 759                         if(self.team == assault_attacker_team)
 760                                 centerprint(self, "You are attacking!\n");
 761                         else
 762                                 centerprint(self, "You are defending!\n");
 763                 }
 764
 765         } else if(self.classname == "observer") {
 766                 PutObserverInServer ();
 767         }
 768
 769         //if(g_ctf)
 770         //      ctf_playerchanged();
 771 }
 772
 773 /*
 774 =============
 775 SendCSQCInfo
 776
 777 Send whatever CSQC needs NOW and cannot wait for SendServerInfo to happen...
 778 =============
 779 */
 780 void SendCSQCInfo(void)
 781 {
 782         float i;
 783         if(clienttype(self) != CLIENTTYPE_REAL)
 784                 return;
 785         msg_entity = self;
 786         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 787         WriteByte(MSG_ONE, TE_CSQC_INIT);
 788         WriteShort(MSG_ONE, CSQC_REVISION);
 789         WriteByte(MSG_ONE, maxclients);
 790         for(i = 1; i <= 24; ++i)
 791                 WriteByte(MSG_ONE, (get_weaponinfo(i)).impulse + 1);
 792 }
 793
 794 /*
 795 =============
 796 SetNewParms
 797 =============
 798 */
 799 void SetNewParms (void)
 800 {
 801         // initialize parms for a new player
 802         parm1 = -(86400 * 366);
 803 }
 804
 805 /*
 806 =============
 807 SetChangeParms
 808 =============
 809 */
 810 void SetChangeParms (void)
 811 {
 812         // save parms for level change
 813         parm1 = self.parm_idlesince - time;
 814 }
 815
 816 /*
 817 =============
 818 DecodeLevelParms
 819 =============
 820 */
 821 void DecodeLevelParms (void)
 822 {
 823         // load parms
 824         self.parm_idlesince = parm1;
 825         if(self.parm_idlesince == -(86400 * 366))
 826                 self.parm_idlesince = time;
 827 }
 828
 829 /*
 830 =============
 831 ClientKill
 832
 833 Called when a client types 'kill' in the console
 834 =============
 835 */
 836
 837 void ClientKill_Now_TeamChange()
 838 {
 839         if(self.killindicator_teamchange == -1)
 840         {
 841                 self.team = -1;
 842                 JoinBestTeam( self, FALSE, FALSE );
 843         }
 844         else
 845         {
 846                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 847         }
 848 }
 849
 850 void ClientKill_Now()
 851 {
 852         if(self.killindicator_teamchange)
 853                 ClientKill_Now_TeamChange();
 854
 855         // in any case:
 856         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 857
 858         if(self.killindicator)
 859         {
 860                 dprint("Cleaned up after a leaked kill indicator.\n");
 861                 remove(self.killindicator);
 862                 self.killindicator = world;
 863         }
 864 }
 865 void KillIndicator_Think()
 866 {
 867         if (!self.owner.modelindex)
 868         {
 869                 self.owner.killindicator = world;
 870                 remove(self);
 871                 return;
 872         }
 873
 874         if(self.cnt <= 0)
 875         {
 876                 self = self.owner;
 877                 ClientKill_Now(); // no oldself needed
 878                 return;
 879         }
 880         else
 881         {
 882                 if(self.cnt <= 10)
 883                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 884                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 885                 {
 886                         if(self.cnt <= 10)
 887                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 888                         if(self.owner.killindicator_teamchange)
 889                         {
 890                                 if(self.owner.killindicator_teamchange == -1)
 891                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 892                                 else
 893                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 894                         }
 895                         else
 896                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 897                 }
 898                 self.nextthink = time + 1;
 899                 self.cnt -= 1;
 900         }
 901 }
 902
 903 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 904 {
 905         float killtime;
 906         entity e;
 907         killtime = cvar("g_balance_kill_delay");
 908
 909         self.killindicator_teamchange = targetteam;
 910
 911         if(!self.killindicator)
 912         {
 913                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 914                 {
 915                         ClientKill_Now();
 916                 }
 917                 else
 918                 {
 919                         self.killindicator = spawn();
 920                         self.killindicator.owner = self;
 921                         self.killindicator.scale = 0.5;
 922                         setattachment(self.killindicator, self, "");
 923                         setorigin(self.killindicator, '0 0 52');
 924                         self.killindicator.think = KillIndicator_Think;
 925                         self.killindicator.nextthink = time + (self.lip) * 0.05;
 926                         self.killindicator.cnt = ceil(killtime);
 927                         self.killindicator.count = bound(0, ceil(killtime), 10);
 928                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 929
 930                         for(e = world; (e = find(e, classname, "body")) != world; )
 931                         {
 932                                 if(e.enemy != self)
 933                                         continue;
 934                                 e.killindicator = spawn();
 935                                 e.killindicator.owner = e;
 936                                 e.killindicator.scale = 0.5;
 937                                 setattachment(e.killindicator, e, "");
 938                                 setorigin(e.killindicator, '0 0 52');
 939                                 e.killindicator.think = KillIndicator_Think;
 940                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
 941                                 e.killindicator.cnt = ceil(killtime);
 942                         }
 943                         self.lip = 0;
 944                 }
 945         }
 946         if(self.killindicator)
 947         {
 948                 if(targetteam)
 949                         self.killindicator.colormod = TeamColor(targetteam);
 950                 else
 951                         self.killindicator.colormod = '0 0 0';
 952         }
 953 }
 954
 955 void ClientKill (void)
 956 {
 957         ClientKill_TeamChange(0);
 958 }
 959
 960 void DoTeamChange(float destteam)
 961 {
 962         float t, c0;
 963         if(!cvar("teamplay"))
 964         {
 965                 if(destteam >= 0)
 966                         SetPlayerColors(self, destteam);
 967                 return;
 968         }
 969         if(self.classname == "player")
 970         if(destteam == -1)
 971         {
 972                 CheckAllowedTeams(self);
 973                 t = FindSmallestTeam(self, TRUE);
 974                 switch(self.team)
 975                 {
 976                         case COLOR_TEAM1: c0 = c1; break;
 977                         case COLOR_TEAM2: c0 = c2; break;
 978                         case COLOR_TEAM3: c0 = c3; break;
 979                         case COLOR_TEAM4: c0 = c4; break;
 980                         default:          c0 = 999;
 981                 }
 982                 switch(t)
 983                 {
 984                         case 1:
 985                                 if(c0 > c1)
 986                                         destteam = COLOR_TEAM1;
 987                                 break;
 988                         case 2:
 989                                 if(c0 > c2)
 990                                         destteam = COLOR_TEAM2;
 991                                 break;
 992                         case 3:
 993                                 if(c0 > c3)
 994                                         destteam = COLOR_TEAM3;
 995                                 break;
 996                         case 4:
 997                                 if(c0 > c4)
 998                                         destteam = COLOR_TEAM4;
 999                                 break;
1000                 }
1001                 if(destteam == -1)
1002                         return;
1003         }
1004         if(destteam == self.team && !self.killindicator)
1005                 return;
1006         ClientKill_TeamChange(destteam);
1007 }
1008
1009 void FixClientCvars(entity e)
1010 {
1011         // send prediction settings to the client
1012         stuffcmd(e, "\nin_bindmap 0 0\n");
1013         /*
1014          * we no longer need to stuff this. Remove this comment block if you feel
1015          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1016         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1017         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1018         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1019         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1020         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1021         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1022         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1023         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1024         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1025         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1026         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1027         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1028         stuffcmd(e, "cl_movement_edgefriction 1\n");
1029          */
1030 }
1031
1032 /*
1033 =============
1034 ClientConnect
1035
1036 Called when a client connects to the server
1037 =============
1038 */
1039 //void ctf_clientconnect();
1040 string ColoredTeamName(float t);
1041 void DecodeLevelParms (void);
1042 //void dom_player_join_team(entity pl);
1043 void ClientConnect (void)
1044 {
1045         local string s;
1046
1047         if(self.flags & FL_CLIENT)
1048         {
1049                 print("Warning: ClientConnect, but already connected!\n");
1050                 return;
1051         }
1052
1053         if(Ban_IsClientBanned(self))
1054         {
1055                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
1056                 dropclient(self);
1057                 bprint(s);
1058                 return;
1059         }
1060
1061         DecodeLevelParms();
1062
1063         self.classname = "player_joining";
1064
1065         self.flags = self.flags | FL_CLIENT;
1066         self.version_nagtime = time + 10 + random() * 10;
1067
1068         if(player_count<0)
1069         {
1070                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1071                 player_count = 0;
1072         }
1073
1074         PlayerScore_Attach(self);
1075
1076         bot_clientconnect();
1077
1078         race_PreSpawnObserver();
1079
1080         //if(g_domination)
1081         //      dom_player_join_team(self);
1082
1083         //JoinBestTeam(self, FALSE, FALSE);
1084
1085         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1086                 self.classname = "observer";
1087         } else {
1088                 self.classname = "player";
1089                 campaign_bots_may_start = 1;
1090         }
1091
1092         self.playerid = (playerid_last = playerid_last + 1);
1093         if(cvar("sv_eventlog"))
1094         {
1095                 if(clienttype(self) == CLIENTTYPE_REAL)
1096                         s = "player";
1097                 else
1098                         s = "bot";
1099                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", ftos(num_for_edict(self)), ":", self.netname));
1100                 s = strcat(":team:", ftos(self.playerid), ":");
1101                 s = strcat(s, ftos(self.team));
1102                 GameLogEcho(s);
1103         }
1104         self.netname_previous = strzone(self.netname);
1105
1106         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1107
1108         bprint ("^4",self.netname);
1109         bprint ("^4 connected");
1110
1111         if(g_domination || g_ctf)
1112         {
1113                 bprint(" and joined the ");
1114                 bprint(ColoredTeamName(self.team));
1115         }
1116
1117         bprint("\n");
1118
1119         self.welcomemessage_time = 0;
1120
1121         stuffcmd(self, strcat(clientstuff, "\n"));
1122         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1123         stuffcmd(self, "cl_particles_reloadeffects\n");
1124
1125         FixClientCvars(self);
1126
1127         // spawnfunc_waypoint sprites
1128         WaypointSprite_InitClient(self);
1129
1130         // Wazat's grappling hook
1131         SetGrappleHookBindings();
1132
1133         // get autoswitch state from player when he toggles it
1134         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1135
1136         // get version info from player
1137         stuffcmd(self, "cmd clientversion $gameversion\n");
1138
1139         // get other cvars from player
1140         GetCvars(0);
1141
1142         // set cvar for team scoreboard
1143         if (teams_matter)
1144         {
1145                 local float t;
1146                 t = cvar("teamplay");
1147                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1148                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1149         }
1150         else
1151                 stuffcmd(self, "set teamplay 0\n");
1152
1153         // notify about available teams
1154         if(teamplay)
1155         {
1156                 CheckAllowedTeams(self);
1157                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1158                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1159         }
1160         else
1161                 stuffcmd(self, "set _teams_available 0\n");
1162
1163         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1164
1165         if(g_arena)
1166         {
1167                 self.classname = "observer";
1168                 Spawnqueue_Insert(self);
1169         }
1170         /*else if(g_ctf)
1171         {
1172                 ctf_clientconnect();
1173         }*/
1174
1175         if(entcs_start)
1176                 attach_entcs();
1177
1178         bot_relinkplayerlist();
1179
1180         self.spectatortime = time;
1181         if(blockSpectators)
1182         {
1183                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1184         }
1185
1186         self.jointime = time;
1187         self.allowedTimeouts = cvar("sv_timeout_number");
1188
1189         if(clienttype(self) == CLIENTTYPE_REAL)
1190         {
1191                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1192                 SendCSQCInfo();
1193                 msg_entity = self;
1194                 if(mapvote_initialized && !cvar("g_maplist_textonly"))
1195                 {
1196                         MapVote_SendData(MSG_ONE);
1197                         MapVote_UpdateData(MSG_ONE);
1198                 }
1199                 ScoreInfo_Write(MSG_ONE);
1200         }
1201
1202         if(g_lms)
1203         {
1204                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1205                 {
1206                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1207                         self.frags = -666; // FIXME do we still need this?
1208                 }
1209         }
1210 }
1211
1212 /*
1213 =============
1214 ClientDisconnect
1215
1216 Called when a client disconnects from the server
1217 =============
1218 */
1219 void(entity e) DropFlag;
1220 .entity chatbubbleentity;
1221 .entity teambubbleentity;
1222 void ReadyCount();
1223 //void() ctf_clientdisconnect;
1224 void ClientDisconnect (void)
1225 {
1226         float save;
1227
1228         if not(self.flags & FL_CLIENT)
1229         {
1230                 print("Warning: ClientDisconnect without ClientConnect\n");
1231                 return;
1232         }
1233
1234         bot_clientdisconnect();
1235
1236         if(entcs_start)
1237                 detach_entcs();
1238
1239         if(cvar("sv_eventlog"))
1240                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1241         bprint ("^4",self.netname);
1242         bprint ("^4 disconnected\n");
1243
1244         if (self.chatbubbleentity)
1245         {
1246                 remove (self.chatbubbleentity);
1247                 self.chatbubbleentity = world;
1248         }
1249
1250         if (self.teambubbleentity)
1251         {
1252                 remove (self.teambubbleentity);
1253                 self.teambubbleentity = world;
1254         }
1255
1256         if (self.killindicator)
1257         {
1258                 remove (self.killindicator);
1259                 self.killindicator = world;
1260         }
1261
1262         WaypointSprite_PlayerGone();
1263
1264         DropAllRunes(self);
1265         kh_Key_DropAll(self, TRUE);
1266
1267         Portal_ClearAll(self);
1268
1269         if(self.flagcarried)
1270                 DropFlag(self.flagcarried);
1271
1272         save = self.flags;
1273         self.flags = self.flags - (self.flags & FL_CLIENT);
1274         bot_relinkplayerlist();
1275         self.flags = save;
1276
1277         // remove laserdot
1278         if(self.weaponentity)
1279                 if(self.weaponentity.lasertarget)
1280                         remove(self.weaponentity.lasertarget);
1281
1282         if(g_arena)
1283         {
1284                 Spawnqueue_Unmark(self);
1285                 Spawnqueue_Remove(self);
1286         }
1287         /*if(g_ctf)
1288         {
1289                 ctf_clientdisconnect();
1290         }
1291         */
1292
1293         PlayerScore_Detach(self);
1294
1295         if(self.netname_previous)
1296                 strunzone(self.netname_previous);
1297
1298         ClearPlayerSounds();
1299
1300         // free cvars
1301         GetCvars(-1);
1302         self.playerid = 0;
1303
1304         ReadyCount();
1305 }
1306
1307 .float BUTTON_CHAT;
1308 void ChatBubbleThink()
1309 {
1310         self.nextthink = time;
1311         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1312         {
1313                 self.owner.chatbubbleentity = world;
1314                 remove(self);
1315                 return;
1316         }
1317         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1318         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1319                 self.model = self.mdl;
1320         else
1321                 self.model = "";
1322 };
1323
1324 void UpdateChatBubble()
1325 {
1326         if (!self.modelindex)
1327                 return;
1328         // spawn a chatbubble entity if needed
1329         if (!self.chatbubbleentity)
1330         {
1331                 self.chatbubbleentity = spawn();
1332                 self.chatbubbleentity.owner = self;
1333                 self.chatbubbleentity.exteriormodeltoclient = self;
1334                 self.chatbubbleentity.think = ChatBubbleThink;
1335                 self.chatbubbleentity.nextthink = time;
1336                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1337                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1338                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1339                 self.chatbubbleentity.model = "";
1340                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1341         }
1342 }
1343
1344
1345 void TeamBubbleThink()
1346 {
1347         self.nextthink = time;
1348         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1349         {
1350                 self.owner.teambubbleentity = world;
1351                 remove(self);
1352                 return;
1353         }
1354 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1355         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1356                 self.model = "";
1357         else
1358                 self.model = self.mdl;
1359
1360 };
1361
1362 float TeamBubble_customizeentityforclient()
1363 {
1364         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1365 }
1366
1367 void UpdateTeamBubble()
1368 {
1369         if (!self.modelindex || !cvar("teamplay"))
1370                 return;
1371         // spawn a teambubble entity if needed
1372         if (!self.teambubbleentity && cvar("teamplay"))
1373         {
1374                 self.teambubbleentity = spawn();
1375                 self.teambubbleentity.owner = self;
1376                 self.teambubbleentity.exteriormodeltoclient = self;
1377                 self.teambubbleentity.think = TeamBubbleThink;
1378                 self.teambubbleentity.nextthink = time;
1379                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1380 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1381                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1382                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1383                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1384                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1385                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1386                 self.teambubbleentity.effects = EF_LOWPRECISION;
1387         }
1388 }
1389
1390 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1391 // added to the model skins
1392 /*void UpdateColorModHack()
1393 {
1394         local float c;
1395         c = self.clientcolors & 15;
1396         // LordHavoc: only bothering to support white, green, red, yellow, blue
1397              if (teamplay == 0) self.colormod = '0 0 0';
1398         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1399         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1400         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1401         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1402         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1403         else self.colormod = '1 1 1';
1404 };*/
1405
1406 void respawn(void)
1407 {
1408         CopyBody(1);
1409         self.effects |= EF_NODRAW; // prevent another CopyBody
1410         PutClientInServer();
1411 }
1412
1413 /**
1414  * When sv_timeout is used this function returs strings like
1415  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1416  * Called by centerprint functions
1417  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1418  */
1419 string getTimeoutText(float addOneSecond) {
1420         if (!cvar("sv_timeout") || !timeoutStatus)
1421                 return "";
1422
1423         local string retStr;
1424         if (timeoutStatus == 1) {
1425                 if (addOneSecond == 1) {
1426                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1427                 }
1428                 else {
1429                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1430                 }
1431                 return retStr;
1432         }
1433         else if (timeoutStatus == 2) {
1434                 if (addOneSecond) {
1435                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1436                         //don't show messages like "Timeout ends in 0 seconds"...
1437                         if ((remainingTimeoutTime + 1) > 0)
1438                                 return retStr;
1439                         else
1440                                 return "";
1441                 }
1442                 else {
1443                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1444                         //don't show messages like "Timeout ends in 0 seconds"...
1445                         if (remainingTimeoutTime > 0)
1446                                 return retStr;
1447                         else
1448                                 return "";
1449                 }
1450         }
1451         else return "";
1452 }
1453
1454 void player_powerups (void)
1455 {
1456         if (g_minstagib)
1457         {
1458                 if (self.items & IT_STRENGTH)
1459                 {
1460                         if (time > self.strength_finished)
1461                         {
1462                                 if (g_minstagib_invis_alpha > 0)
1463                                 {
1464                                         self.alpha = default_player_alpha;
1465                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1466                                         self.effects = self.effects | EF_FULLBRIGHT;
1467                                 }
1468                                 else
1469                                 {
1470                                         self.effects -= self.effects & EF_NODRAW;
1471                                 }
1472                                 self.items = self.items - (self.items & IT_STRENGTH);
1473                                 sprint(self, "^3Invisibility has worn off\n");
1474                         }
1475                 }
1476                 else
1477                 {
1478                         if (time < self.strength_finished)
1479                         {
1480                                 if (g_minstagib_invis_alpha > 0)
1481                                 {
1482                                         self.alpha = g_minstagib_invis_alpha;
1483                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1484                                         self.effects -= self.effects & EF_FULLBRIGHT;
1485                                 }
1486                                 else
1487                                 {
1488                                         self.effects = self.effects | EF_NODRAW;
1489                                 }
1490                                 self.items = self.items | IT_STRENGTH;
1491                                 sprint(self, "^3You are invisible\n");
1492                         }
1493                 }
1494
1495                 if (self.items & IT_INVINCIBLE)
1496                 {
1497                         if (time > self.invincible_finished)
1498                         {
1499                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1500                                 sprint(self, "^3Speed has worn off\n");
1501                         }
1502                 }
1503                 else
1504                 {
1505                         if (time < self.invincible_finished)
1506                         {
1507                                 self.items = self.items | IT_INVINCIBLE;
1508                                 sprint(self, "^3You are on speed\n");
1509                         }
1510                 }
1511                 return;
1512         }
1513
1514         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1515         if (self.items & IT_STRENGTH)
1516         {
1517                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1518                 if (time > self.strength_finished)
1519                 {
1520                         self.items = self.items - (self.items & IT_STRENGTH);
1521                         sprint(self, "^3Strength has worn off\n");
1522                 }
1523         }
1524         else
1525         {
1526                 if (time < self.strength_finished)
1527                 {
1528                         self.items = self.items | IT_STRENGTH;
1529                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1530                 }
1531         }
1532         if (self.items & IT_INVINCIBLE)
1533         {
1534                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1535                 if (time > self.invincible_finished)
1536                 {
1537                         self.items = self.items - (self.items & IT_INVINCIBLE);
1538                         sprint(self, "^3Shield has worn off\n");
1539                 }
1540         }
1541         else
1542         {
1543                 if (time < self.invincible_finished)
1544                 {
1545                         self.items = self.items | IT_INVINCIBLE;
1546                         sprint(self, "^3Shield surrounds you\n");
1547                 }
1548         }
1549
1550         if (cvar("g_fullbrightplayers"))
1551                 self.effects = self.effects | EF_FULLBRIGHT;
1552
1553         // midair gamemode: damage only while in the air
1554         // if in midair mode, being on ground grants temporary invulnerability
1555         // (this is so that multishot weapon don't clear the ground flag on the
1556         // first damage in the frame, leaving the player vulnerable to the
1557         // remaining hits in the same frame)
1558         if (self.flags & FL_ONGROUND)
1559         if (g_midair)
1560                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1561
1562         if (time > restart_countdown)
1563         if (time < self.spawnshieldtime)
1564                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1565 }
1566
1567 float CalcRegen(float current, float stable, float regenfactor)
1568 {
1569         if(current > stable)
1570                 return current;
1571         else if(current > stable - 0.25) // when close enough, "snap"
1572                 return stable;
1573         else
1574                 return min(stable, current + (stable - current) * regenfactor * frametime);
1575 }
1576
1577 void player_regen (void)
1578 {
1579         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1580         maxh = cvar("g_balance_health_stable");
1581         maxa = cvar("g_balance_armor_stable");
1582         limith = cvar("g_balance_health_limit");
1583         limita = cvar("g_balance_armor_limit");
1584
1585         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1586                 return;
1587
1588         max_mod = regen_mod = rot_mod = limit_mod = 1;
1589
1590         if (self.runes & RUNE_REGEN)
1591         {
1592                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1593                 {
1594                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1595                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1596                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1597                 }
1598                 else
1599                 {
1600                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1601                         max_mod = cvar("g_balance_rune_regen_hpmod");
1602                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1603                 }
1604         }
1605         else if (self.runes & CURSE_VENOM)
1606         {
1607                 max_mod = cvar("g_balance_curse_venom_hpmod");
1608                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1609                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1610                 else
1611                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1612                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1613                 //if (!self.runes & RUNE_REGEN)
1614                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1615         }
1616         maxh = maxh * max_mod;
1617         //maxa = maxa * max_mod;
1618         limith = limith * limit_mod;
1619         limita = limita * limit_mod;
1620
1621         if (self.armorvalue > maxa)
1622         {
1623                 if (time > self.pauserotarmor_finished)
1624                 {
1625                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1626                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1627                 }
1628         }
1629         else if (self.armorvalue < maxa)
1630         {
1631                 if (time > self.pauseregen_finished)
1632                 {
1633                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1634                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1635                 }
1636         }
1637         if (self.health > maxh)
1638         {
1639                 if (time > self.pauserothealth_finished)
1640                 {
1641                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1642                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1643                 }
1644         }
1645         else if (self.health < maxh)
1646         {
1647                 if (time > self.pauseregen_finished)
1648                 {
1649                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1650                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1651                 }
1652         }
1653
1654         if (self.health > limith)
1655                 self.health = limith;
1656         if (self.armorvalue > limita)
1657                 self.armorvalue = limita;
1658
1659         // if player rotted to death...  die!
1660         if(self.health < 1)
1661                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1662 }
1663
1664 .float zoomstate;
1665 float zoomstate_set;
1666 void SetZoomState(float z)
1667 {
1668         if(z != self.zoomstate)
1669         {
1670                 msg_entity = self;
1671                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
1672                 WriteByte(MSG_ONE, TE_CSQC_ZOOMNOTIFY);
1673                 WriteByte(MSG_ONE, z);
1674                 self.zoomstate = z;
1675         }
1676         zoomstate_set = 1;
1677 }
1678
1679 /*
1680 ======================
1681 spectate mode routines
1682 ======================
1683 */
1684 void SpectateCopy(entity spectatee) {
1685         self.armortype = spectatee.armortype;
1686         self.armorvalue = spectatee.armorvalue;
1687         self.currentammo = spectatee.currentammo;
1688         self.effects = spectatee.effects;
1689         self.health = spectatee.health;
1690         self.impulse = 0;
1691         self.items = spectatee.items;
1692         self.weapons = spectatee.weapons;
1693         self.punchangle = spectatee.punchangle;
1694         self.view_ofs = spectatee.view_ofs;
1695         self.v_angle = spectatee.v_angle;
1696         self.velocity = spectatee.velocity;
1697         self.dmg_take = spectatee.dmg_take;
1698         self.dmg_save = spectatee.dmg_save;
1699         self.dmg_inflictor = spectatee.dmg_inflictor;
1700         self.angles = spectatee.v_angle;
1701         self.fixangle = TRUE;
1702         setorigin(self, spectatee.origin);
1703         setsize(self, spectatee.mins, spectatee.maxs);
1704         SetZoomState(spectatee.zoomstate);
1705 }
1706
1707 float SpectateUpdate() {
1708         if(!self.enemy)
1709                 return 0;
1710
1711         if (self == self.enemy)
1712                 return 0;
1713
1714         if(self.enemy.flags & FL_NOTARGET)
1715                 return 0;
1716
1717         SpectateCopy(self.enemy);
1718
1719         return 1;
1720 }
1721
1722 float SpectateNext() {
1723         other = find(self.enemy, classname, "player");
1724         if (!other) {
1725                 other = find(other, classname, "player");
1726         }
1727         if (other) {
1728                 self.enemy = other;
1729         }
1730         if(self.enemy.classname == "player") {
1731                 msg_entity = self;
1732                 WriteByte(MSG_ONE, SVC_SETVIEW);
1733                 WriteEntity(MSG_ONE, self.enemy);
1734                 self.wantswelcomemessage = 1;
1735                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1736                 if(!SpectateUpdate())
1737                         PutObserverInServer();
1738                 return 1;
1739         } else {
1740                 return 0;
1741         }
1742 }
1743
1744 /*
1745 =============
1746 ShowRespawnCountdown()
1747
1748 Update a respawn countdown display.
1749 =============
1750 */
1751 void ShowRespawnCountdown()
1752 {
1753         float number;
1754         if(self.deadflag == DEAD_NO) // just respawned?
1755                 return;
1756         else
1757         {
1758                 number = ceil(self.death_time - time);
1759                 if(number <= 0)
1760                         return;
1761                 if(number <= self.respawn_countdown)
1762                 {
1763                         self.respawn_countdown = number - 1;
1764                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1765                                 announce(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1766                 }
1767         }
1768 }
1769
1770 void LeaveSpectatorMode()
1771 {
1772         if(isJoinAllowed()) {
1773                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1774                         self.classname = "player";
1775                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1776                                 JoinBestTeam(self, FALSE, TRUE);
1777                         if(cvar("g_campaign"))
1778                                 campaign_bots_may_start = 1;
1779                         PutClientInServer();
1780                         if(!(self.flags & FL_NOTARGET))
1781                                 bprint ("^4", self.netname, "^4 is playing now\n");
1782                         centerprint(self,"");
1783                         return;
1784                 } else {
1785                         stuffcmd(self,"menu_showteamselect\n");
1786                         return;
1787                 }
1788         }
1789         else {
1790                 //player may not join because of g_maxplayers is set
1791                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1792         }
1793 }
1794
1795 /**
1796  * Determines whether the player is allowed to join. This depends on cvar
1797  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1798  * it checks whether the number of currently playing players exceeds g_maxplayers.
1799  * @return bool TRUE if the player is allowed to join, false otherwise
1800  */
1801 float isJoinAllowed() {
1802         if (!cvar("g_maxplayers"))
1803                 return TRUE;
1804
1805         local entity e;
1806         local float currentlyPlaying;
1807         FOR_EACH_REALPLAYER(e) {
1808                 if(e.classname == "player")
1809                         currentlyPlaying += 1;
1810         }
1811         if(currentlyPlaying < cvar("g_maxplayers"))
1812                 return TRUE;
1813
1814         return FALSE;
1815 }
1816
1817 /**
1818  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1819  * g_maxplayers_spectator_blocktime seconds
1820  */
1821 void checkSpectatorBlock() {
1822         if(self.classname == "spectator" || self.classname == "observer") {
1823                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1824                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1825                         dropclient(self);
1826                 }
1827         }
1828 }
1829
1830 float vercmp_recursive(string v1, string v2)
1831 {
1832         float dot1, dot2;
1833         string s1, s2;
1834         float r;
1835
1836         dot1 = strstrofs(v1, ".", 0);
1837         dot2 = strstrofs(v2, ".", 0);
1838         if(dot1 == -1)
1839                 s1 = v1;
1840         else
1841                 s1 = substring(v1, 0, dot1);
1842         if(dot2 == -1)
1843                 s2 = v2;
1844         else
1845                 s2 = substring(v2, 0, dot2);
1846
1847         r = stof(s1) - stof(s2);
1848         if(r != 0)
1849                 return r;
1850
1851         r = strcasecmp(s1, s2);
1852         if(r != 0)
1853                 return r;
1854
1855         if(dot1 == -1)
1856                 if(dot2 == -1)
1857                         return 0;
1858                 else
1859                         return -1;
1860         else
1861                 if(dot2 == -1)
1862                         return 1;
1863                 else
1864                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1865 }
1866
1867 float vercmp(string v1, string v2)
1868 {
1869         if(strcasecmp(v1, v2) == 0) // early out check
1870                 return 0;
1871         return vercmp_recursive(v1, v2);
1872 }
1873
1874 void ObserverThink()
1875 {
1876         if (self.flags & FL_JUMPRELEASED) {
1877                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1878                         self.welcomemessage_time = 0;
1879                         self.flags = self.flags - FL_JUMPRELEASED;
1880                         LeaveSpectatorMode();
1881                         return;
1882                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
1883                         self.welcomemessage_time = 0;
1884                         self.flags = self.flags - FL_JUMPRELEASED;
1885                         if(SpectateNext() == 1) {
1886                                 self.classname = "spectator";
1887                         }
1888                 }
1889         } else {
1890                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
1891                         self.flags = self.flags | FL_JUMPRELEASED;
1892                 }
1893         }
1894         if(self.BUTTON_ZOOM)
1895                 self.wantswelcomemessage = 0;
1896         if(self.wantswelcomemessage)
1897                 PrintWelcomeMessage(self);
1898 }
1899
1900 void SpectatorThink()
1901 {
1902         if (self.flags & FL_JUMPRELEASED) {
1903                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1904                         self.welcomemessage_time = 0;
1905                         self.flags = self.flags - FL_JUMPRELEASED;
1906                         LeaveSpectatorMode();
1907                         return;
1908                 } else if(self.BUTTON_ATCK) {
1909                         self.welcomemessage_time = 0;
1910                         self.flags = self.flags - FL_JUMPRELEASED;
1911                         if(SpectateNext() == 1) {
1912                                 self.classname = "spectator";
1913                         } else {
1914                                 self.classname = "observer";
1915                                 PutClientInServer();
1916                         }
1917                 } else if (self.BUTTON_ATCK2) {
1918                         self.welcomemessage_time = 0;
1919                         self.flags = self.flags - FL_JUMPRELEASED;
1920                         self.classname = "observer";
1921                         PutClientInServer();
1922                 } else {
1923                         if(!SpectateUpdate())
1924                                 PutObserverInServer();
1925                 }
1926         } else {
1927                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
1928                         self.flags = self.flags | FL_JUMPRELEASED;
1929                 }
1930         }
1931         if(self.BUTTON_ZOOM)
1932                 self.wantswelcomemessage = 0;
1933         if(self.wantswelcomemessage)
1934                 PrintWelcomeMessage(self);
1935         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1936 }
1937
1938 /*
1939 =============
1940 PlayerPreThink
1941
1942 Called every frame for each client before the physics are run
1943 =============
1944 */
1945 void() ctf_setstatus;
1946 .float vote_nagtime;
1947 .float spectatee_status;
1948 void PlayerPreThink (void)
1949 {
1950         self.stat_sys_ticrate = cvar("sys_ticrate");
1951         if(blockSpectators)
1952                 checkSpectatorBlock();
1953
1954         zoomstate_set = 0;
1955
1956         if(self.netname_previous != self.netname)
1957         {
1958                 if(cvar("sv_eventlog"))
1959                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
1960                 if(self.netname_previous)
1961                         strunzone(self.netname_previous);
1962                 self.netname_previous = strzone(self.netname);
1963         }
1964
1965         // version nagging
1966         if(self.version_nagtime)
1967                 if(self.cvar_g_nexuizversion)
1968                         if(time > self.version_nagtime)
1969                         {
1970                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1971                                 {
1972                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
1973                                         {
1974                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1975                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1976                                         }
1977                                         else
1978                                         {
1979                                                 float r;
1980                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
1981                                                 if(r < 0)
1982                                                 {
1983                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
1984                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
1985                                                 }
1986                                                 else if(r > 0)
1987                                                 {
1988                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1989                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1990                                                 }
1991                                         }
1992                                 }
1993                                 self.version_nagtime = 0;
1994                         }
1995
1996         // vote nagging
1997         if(self.cvar_scr_centertime)
1998                 if(time > self.vote_nagtime)
1999                 {
2000                         VoteNag();
2001                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
2002                 }
2003
2004         // GOD MODE info
2005         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2006         {
2007                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2008                 self.max_armorvalue = 0;
2009         }
2010
2011         if(frametime)
2012                 antilag_record(self);
2013
2014         if(self.classname == "player") {
2015 //              if(self.netname == "Wazat")
2016 //                      bprint(self.classname, "\n");
2017
2018                 CheckRules_Player();
2019
2020                 if(self.BUTTON_INFO)
2021                         PrintWelcomeMessage(self);
2022
2023                 if(g_lms || !cvar("sv_spectate"))
2024                 if((time - self.jointime) <= cvar("welcome_message_time"))
2025                         PrintWelcomeMessage(self);
2026
2027                 if (intermission_running)
2028                 {
2029                         IntermissionThink ();   // otherwise a button could be missed between
2030                         return;                                 // the think tics
2031                 }
2032
2033                 if(self.teleport_time)
2034                 if(time > self.teleport_time)
2035                 {
2036                         self.teleport_time = 0;
2037                         self.effects = self.effects - (self.effects & EF_NODRAW);
2038                         if(self.weaponentity)
2039                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
2040                 }
2041
2042                 Nixnex_GiveCurrentWeapon();
2043
2044                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2045                         UpdateSelectedPlayer();
2046
2047                 //don't allow the player to turn around while game is paused!
2048                 if(timeoutStatus == 2) {
2049                         self.v_angle = self.lastV_angle;
2050                         self.angles = self.lastV_angle;
2051                         self.fixangle = TRUE;
2052                 }
2053
2054                 if (self.deadflag != DEAD_NO)
2055                 {
2056                         float button_pressed, force_respawn;
2057                         player_anim();
2058                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2059                         force_respawn = (g_lms || cvar("g_forced_respawn"));
2060                         if (self.deadflag == DEAD_DYING)
2061                         {
2062                                 if(force_respawn)
2063                                         self.deadflag = DEAD_RESPAWNING;
2064                                 else if(!button_pressed)
2065                                         self.deadflag = DEAD_DEAD;
2066                         }
2067                         else if (self.deadflag == DEAD_DEAD)
2068                         {
2069                                 if(button_pressed)
2070                                         self.deadflag = DEAD_RESPAWNABLE;
2071                         }
2072                         else if (self.deadflag == DEAD_RESPAWNABLE)
2073                         {
2074                                 if(!button_pressed)
2075                                         self.deadflag = DEAD_RESPAWNING;
2076                         }
2077                         else if (self.deadflag == DEAD_RESPAWNING)
2078                         {
2079                                 if(time > self.death_time)
2080                                 {
2081                                         self.death_time = time + 1; // only retry once a second
2082                                         respawn();
2083                                 }
2084                         }
2085                         ShowRespawnCountdown();
2086                         return;
2087                 }
2088
2089                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2090                 {
2091                         vector dist;
2092
2093                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2094                         dist = self.oldorigin - self.origin;
2095                         dist_z = 0;
2096                         self.lms_traveled_distance += fabs(vlen(dist));
2097
2098                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
2099                         {
2100                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2101                                 self.lms_traveled_distance = 0;
2102                         }
2103
2104                         if(time > self.lms_nextcheck)
2105                         {
2106                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2107                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2108                                 {
2109                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2110                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2111                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2112                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2113                                 }
2114                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2115                                 self.lms_traveled_distance = 0;
2116                         }
2117                 }
2118
2119                 if (self.BUTTON_CROUCH && !self.hook.state)
2120                 {
2121                         if (!self.crouch)
2122                         {
2123                                 self.crouch = TRUE;
2124                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2125                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2126                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
2127                         }
2128                 }
2129                 else
2130                 {
2131                         if (self.crouch)
2132                         {
2133                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2134                                 if (!trace_startsolid)
2135                                 {
2136                                         self.crouch = FALSE;
2137                                         self.view_ofs = PL_VIEW_OFS;
2138                                         setsize (self, PL_MIN, PL_MAX);
2139                                 }
2140                         }
2141                 }
2142
2143                 FixPlayermodel();
2144
2145                 GrapplingHookFrame();
2146
2147                 W_WeaponFrame();
2148
2149                 player_powerups();
2150                 player_regen();
2151                 player_anim();
2152
2153                 if (g_minstagib)
2154                         minstagib_ammocheck();
2155
2156                 ctf_setstatus();
2157                 kh_setstatus();
2158
2159                 //self.angles_y=self.v_angle_y + 90;   // temp
2160
2161                 //if (TetrisPreFrame()) return;
2162         } else if(gameover) {
2163                 if (intermission_running)
2164                         IntermissionThink ();   // otherwise a button could be missed between
2165                 return;
2166         } else if(self.classname == "observer") {
2167                 ObserverThink();
2168         } else if(self.classname == "spectator") {
2169                 SpectatorThink();
2170         }
2171
2172         if(!zoomstate_set)
2173                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2174
2175         float oldspectatee_status;
2176         oldspectatee_status = self.spectatee_status;
2177         if(self.classname == "spectator")
2178                 self.spectatee_status = num_for_edict(self.enemy);
2179         else if(self.classname == "observer")
2180                 self.spectatee_status = num_for_edict(self);
2181         else
2182                 self.spectatee_status = 0;
2183         if(self.spectatee_status != oldspectatee_status)
2184         {
2185                 msg_entity = self;
2186                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
2187                 WriteByte(MSG_ONE, TE_CSQC_SPECTATING);
2188                 WriteByte(MSG_ONE, self.spectatee_status);
2189                 if(g_race)
2190                         race_InitSpectator();
2191         }
2192 }
2193
2194
2195 /*
2196 =============
2197 PlayerPostThink
2198
2199 Called every frame for each client after the physics are run
2200 =============
2201 */
2202 .float idlekick_lasttimeleft;
2203 .float race_penalty;
2204 .float race_penalty_nagged;
2205 void PlayerPostThink (void)
2206 {
2207         // Savage: Check for nameless players
2208         if (strlen(self.netname) < 1) {
2209                 self.netname = "Player";
2210                 stuffcmd(self, "seta _cl_name Player\n");
2211         }
2212
2213         if(sv_maxidle)
2214         {
2215                 float timeleft;
2216                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2217                 if(timeleft <= 0)
2218                 {
2219                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2220                         announce(self, "announcer/robotic/terminated.ogg");
2221                         dropclient(self);
2222                         return;
2223                 }
2224                 else if(timeleft <= 10)
2225                 {
2226                         if(timeleft != self.idlekick_lasttimeleft)
2227                         {
2228                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2229                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".ogg"));
2230                         }
2231                 }
2232                 else
2233                 {
2234                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2235                 }
2236                 self.idlekick_lasttimeleft = timeleft;
2237         }
2238
2239         if(self.classname == "player") {
2240                 CheckRules_Player();
2241                 UpdateChatBubble();
2242                 UpdateTeamBubble();
2243                 if (self.impulse)
2244                         ImpulseCommands();
2245                 if (intermission_running)
2246                         return;         // intermission or finale
2247
2248                 //PrintWelcomeMessage(self);
2249                 //if (TetrisPostFrame()) return;
2250
2251                 // restart countdown
2252                 if (restart_countdown) {
2253                         if(time < restart_countdown) {
2254                                 if (!cvar("sv_ready_restart_after_countdown"))
2255                                 {
2256                                         if(self.movement != '0 0 0' && g_race && !g_race_qualifying)
2257                                         {
2258                                                 if(time < restart_countdown - 2)
2259                                                 {
2260                                                         if(!self.race_penalty_nagged)
2261                                                         {
2262                                                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1DO NOT MOVE DURING THE COUNTDOWN.");
2263                                                                 self.race_penalty_nagged = 1;
2264                                                         }
2265                                                 }
2266                                                 else if(!self.race_penalty)
2267                                                 {
2268                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1FIVE SECONDS PENALTY.");
2269                                                         self.race_penalty = time + 5;
2270                                                 }
2271                                         }
2272                                         self.movetype = MOVETYPE_NONE;
2273                                         self.velocity = '0 0 0';
2274                                         self.avelocity = '0 0 0';
2275                                         self.movement = '0 0 0';
2276                                 }
2277                         }
2278                         else if (time < self.race_penalty)
2279                         {
2280                                 self.movetype = MOVETYPE_NONE;
2281                                 self.velocity = '0 0 0';
2282                                 self.avelocity = '0 0 0';
2283                                 self.movement = '0 0 0';
2284                         }
2285                         else
2286                         {
2287                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2288                                 if (!cvar("sv_ready_restart_after_countdown"))
2289                                 {
2290                                         if(self.movetype == MOVETYPE_NONE)
2291                                         {
2292                                                 self.movetype = MOVETYPE_WALK;
2293                                         }
2294                                         self.race_penalty = 0;
2295                                         self.race_penalty_nagged = 0;
2296                                 }
2297                         }
2298                 }
2299
2300         } else if (self.classname == "observer") {
2301                 //do nothing
2302         } else if (self.classname == "spectator") {
2303                 //do nothing
2304         }
2305
2306         /*
2307         float i;
2308         for(i = 0; i < 1000; ++i)
2309         {
2310                 vector end;
2311                 end = self.origin + '0 0 1024' + 512 * randomvec();
2312                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2313                 if(trace_fraction < 1)
2314                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2315                 {
2316                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2317                         break;
2318                 }
2319         }
2320         */
2321
2322         Arena_Warmup();
2323 }