data/qcsrc/server/cl_client.qc

   1 // let's abuse an existing field
   2 #define SPAWNPOINT_SCORE frags
   3
   4 .float wantswelcomemessage;
   5 .string netname_previous;
   6
   7 void spawnfunc_info_player_survivor (void)
   8 {
   9         spawnfunc_info_player_deathmatch();
  10 }
  11
  12 void spawnfunc_info_player_start (void)
  13 {
  14         spawnfunc_info_player_deathmatch();
  15 }
  16
  17 void spawnfunc_info_player_deathmatch (void)
  18 {
  19         self.classname = "info_player_deathmatch";
  20         relocate_spawnpoint();
  21 }
  22
  23 void spawnpoint_use()
  24 {
  25         if(teams_matter)
  26         if(have_team_spawns)
  27         {
  28                 self.team = activator.team;
  29                 some_spawn_has_been_used = 1;
  30         }
  31 };
  32
  33 // Returns:
  34 //   -1 if a spawn can't be used
  35 //   otherwise, a weight of the spawnpoint
  36 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
  37 {
  38         float shortest, thisdist;
  39         entity player;
  40
  41         // filter out spots for the wrong team
  42         if(teamcheck)
  43         if(spot.team != teamcheck)
  44                 return -1;
  45
  46         if(race_spawns)
  47                 if(spot.target == "")
  48                         return -1;
  49
  50         // filter out spots for assault
  51         if(spot.target != "") {
  52                 local entity ent;
  53                 float good;
  54                 ent = find(world, targetname, spot.target);
  55                 while(ent) {
  56                         if(ent.classname == "target_objective")
  57                         {
  58                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  59                                         return -1;
  60                                 good = 1;
  61                         }
  62                         else if(ent.classname == "trigger_race_checkpoint")
  63                         {
  64                                 if(self.classname == "player") // spectators may spawn everywhere
  65                                 {
  66                                         if(ent.race_checkpoint != race_PreviousCheckpoint(self.race_checkpoint))
  67                                                 return -1;
  68                                         float pl;
  69                                         pl = self.race_place;
  70                                         if(pl > race_highest_place_spawn)
  71                                                 pl = 0;
  72                                         if(spot.race_place != pl)
  73                                                 return -1;
  74                                 }
  75                                 good = 1;
  76                         }
  77                         else
  78                         {
  79                         }
  80                         ent = find(ent, targetname, spot.target);
  81                 }
  82
  83                 if(!good)
  84                         return -1;
  85         }
  86
  87         player = playerlist;
  88         shortest = vlen(world.maxs - world.mins);
  89         for(player = playerlist; player; player = player.chain)
  90                 if (player != self)
  91                 {
  92                         thisdist = vlen(player.origin - spot.origin);
  93                         if (thisdist < shortest)
  94                                 shortest = thisdist;
  95                 }
  96         return shortest;
  97 }
  98
  99 float spawn_allbad;
 100 float spawn_allgood;
 101 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
 102 {
 103         local entity spot, spotlist, spotlistend;
 104         spawn_allgood = TRUE;
 105         spawn_allbad = TRUE;
 106
 107         spotlist = world;
 108         spotlistend = world;
 109
 110         for(spot = firstspot; spot; spot = spot.chain)
 111         {
 112                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
 113
 114                 if(cvar("spawn_debugview"))
 115                 {
 116                         setmodel(spot, "models/runematch/rune.mdl");
 117                         if(spot.SPAWNPOINT_SCORE < mindist)
 118                         {
 119                                 spot.colormod = '1 0 0';
 120                                 spot.scale = 1;
 121                         }
 122                         else
 123                         {
 124                                 spot.colormod = '0 1 0';
 125                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
 126                         }
 127                 }
 128
 129                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 130                 {
 131                         if(spot.SPAWNPOINT_SCORE < mindist)
 132                         {
 133                                 // too short distance
 134                                 spawn_allgood = FALSE;
 135                         }
 136                         else
 137                         {
 138                                 // perfect
 139                                 spawn_allbad = FALSE;
 140
 141                                 if(spotlistend)
 142                                         spotlistend.chain = spot;
 143                                 spotlistend = spot;
 144                                 if(!spotlist)
 145                                         spotlist = spot;
 146
 147                                 /*
 148                                 if(teamcheck)
 149                                 if(spot.team != teamcheck)
 150                                         error("invalid spawn added");
 151
 152                                 print("added ", etos(spot), "\n");
 153                                 */
 154                         }
 155                 }
 156         }
 157         if(spotlistend)
 158                 spotlistend.chain = world;
 159
 160         /*
 161                 entity e;
 162                 if(teamcheck)
 163                         for(e = spotlist; e; e = e.chain)
 164                         {
 165                                 print("seen ", etos(e), "\n");
 166                                 if(e.team != teamcheck)
 167                                         error("invalid spawn found");
 168                         }
 169         */
 170
 171         return spotlist;
 172 }
 173
 174 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 175 {
 176         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 177         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 178         local entity spot;
 179
 180         RandomSelection_Init();
 181         for(spot = firstspot; spot; spot = spot.chain)
 182                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 183
 184         return RandomSelection_chosen_ent;
 185 }
 186
 187 /*
 188 =============
 189 SelectSpawnPoint
 190
 191 Finds a point to respawn
 192 =============
 193 */
 194 entity SelectSpawnPoint (float anypoint)
 195 {
 196         local float teamcheck;
 197         local entity firstspot_new;
 198         local entity spot, firstspot, playerlist;
 199
 200         spot = find (world, classname, "testplayerstart");
 201         if (spot)
 202                 return spot;
 203
 204         teamcheck = 0;
 205
 206         if(!anypoint && have_team_spawns)
 207                 teamcheck = self.team;
 208
 209         // get the list of players
 210         playerlist = findchain(classname, "player");
 211         // get the entire list of spots
 212         firstspot = findchain(classname, "info_player_deathmatch");
 213         // filter out the bad ones
 214         // (note this returns the original list if none survived)
 215         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 216         if(!firstspot_new)
 217                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 218         firstspot = firstspot_new;
 219
 220         // there is 50/50 chance of choosing a random spot or the furthest spot
 221         // (this means that roughly every other spawn will be furthest, so you
 222         // usually won't get fragged at spawn twice in a row)
 223         if (arena_roundbased)
 224         {
 225                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 226                 if(firstspot_new)
 227                         firstspot = firstspot_new;
 228                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 229         }
 230         else if (random() > cvar("g_spawn_furthest"))
 231                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 232         else
 233                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 234
 235         if(cvar("spawn_debugview"))
 236         {
 237                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 238
 239                 entity e;
 240                 if(teamcheck)
 241                         for(e = firstspot; e; e = e.chain)
 242                                 if(e.team != teamcheck)
 243                                         error("invalid spawn found");
 244         }
 245
 246         if (!spot)
 247         {
 248                 if(cvar("spawn_debug"))
 249                         GotoNextMap();
 250                 else
 251                 {
 252                         if(some_spawn_has_been_used)
 253                                 return world; // team can't spawn any more, because of actions of other team
 254                         else
 255                                 error("Cannot find a spawn point - please fix the map!");
 256                 }
 257         }
 258
 259         return spot;
 260 }
 261
 262 /*
 263 =============
 264 CheckPlayerModel
 265
 266 Checks if the argument string can be a valid playermodel.
 267 Returns a valid one in doubt.
 268 =============
 269 */
 270 string FallbackPlayerModel = "models/player/marine.zym";
 271 string CheckPlayerModel(string plyermodel) {
 272         if(strlen(plyermodel) < 4)
 273                 return FallbackPlayerModel;
 274         if( substring(plyermodel,0,14) != "models/player/")
 275                 return FallbackPlayerModel;
 276         else if(cvar("sv_servermodelsonly"))
 277         {
 278                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 279                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 280                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 281                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 282                         return FallbackPlayerModel;
 283                 if(!fexists(plyermodel))
 284                         return FallbackPlayerModel;
 285         }
 286         return plyermodel;
 287 }
 288
 289 /*
 290 =============
 291 Client_customizeentityforclient
 292
 293 LOD reduction
 294 =============
 295 */
 296 float Client_customizeentityforclient()
 297 {
 298 #ifdef ALLOW_VARIABLE_LOD
 299         // self: me
 300         // other: the player viewing me
 301         float distance;
 302         float f;
 303
 304         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 305                 return TRUE;
 306
 307         if(other.cvar_cl_playerdetailreduction <= 0)
 308         {
 309                 if(other.cvar_cl_playerdetailreduction <= -2)
 310                         self.modelindex = self.modelindex_lod2;
 311                 else if(other.cvar_cl_playerdetailreduction <= -1)
 312                         self.modelindex = self.modelindex_lod1;
 313                 else
 314                         self.modelindex = self.modelindex_lod0;
 315         }
 316         else
 317         {
 318                 distance = vlen(self.origin - other.origin);
 319                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 320                 if(f > 10000)
 321                         self.modelindex = self.modelindex_lod2;
 322                 else if(f > 5000)
 323                         self.modelindex = self.modelindex_lod1;
 324                 else
 325                         self.modelindex = self.modelindex_lod0;
 326         }
 327 #endif
 328
 329         return TRUE;
 330 }
 331
 332 void UpdatePlayerSounds();
 333 void setmodel_lod(entity e, string modelname)
 334 {
 335 #ifdef ALLOW_VARIABLE_LOD
 336         string s;
 337
 338         // FIXME: this only supports 3-letter extensions
 339         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 340         if(fexists(s))
 341         {
 342                 precache_model(s);
 343                 setmodel(e, s); // players have high precision
 344                 self.modelindex_lod1 = self.modelindex;
 345         }
 346         else
 347                 self.modelindex_lod1 = -1;
 348
 349         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 350         if(fexists(s))
 351         {
 352                 precache_model(s);
 353                 setmodel(e, s); // players have high precision
 354                 self.modelindex_lod2 = self.modelindex;
 355         }
 356         else
 357                 self.modelindex_lod2 = -1;
 358
 359         precache_model(modelname);
 360         setmodel(e, modelname); // players have high precision
 361         self.modelindex_lod0 = self.modelindex;
 362
 363         if(self.modelindex_lod1 < 0)
 364                 self.modelindex_lod1 = self.modelindex;
 365
 366         if(self.modelindex_lod2 < 0)
 367                 self.modelindex_lod2 = self.modelindex;
 368 #else
 369         precache_model(modelname);
 370         setmodel(e, modelname); // players have high precision
 371 #endif
 372         player_setupanimsformodel();
 373         UpdatePlayerSounds();
 374 }
 375
 376 /*
 377 =============
 378 PutObserverInServer
 379
 380 putting a client as observer in the server
 381 =============
 382 */
 383 void PutObserverInServer (void)
 384 {
 385         entity  spot;
 386
 387         race_PreSpawnObserver();
 388
 389         spot = SelectSpawnPoint (TRUE);
 390         if(!spot)
 391                 error("No spawnpoints for observers?!?\n");
 392         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 393
 394         if(clienttype(self) == CLIENTTYPE_REAL)
 395         {
 396                 msg_entity = self;
 397                 WriteByte(MSG_ONE, SVC_SETVIEW);
 398                 WriteEntity(MSG_ONE, self);
 399         }
 400
 401         DropAllRunes(self);
 402         kh_Key_DropAll(self, TRUE);
 403
 404         Portal_ClearAll(self);
 405
 406         if(self.flagcarried)
 407                 DropFlag(self.flagcarried);
 408
 409         WaypointSprite_PlayerDead();
 410
 411         if(self.killcount != -666)
 412         {
 413                 if(g_lms)
 414                 {
 415                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 416                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 417                         else
 418                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 419                 }
 420                 else
 421                         bprint ("^4", self.netname, "^4 is spectating now\n");
 422         }
 423
 424         PlayerScore_Clear(self); // clear scores when needed
 425
 426         self.spectatortime = time;
 427
 428         self.classname = "observer";
 429         self.health = -666;
 430         self.takedamage = DAMAGE_NO;
 431         self.solid = SOLID_NOT;
 432         self.movetype = MOVETYPE_NOCLIP;
 433         self.flags = FL_CLIENT | FL_NOTARGET;
 434         self.armorvalue = 666;
 435         self.effects = 0;
 436         self.armorvalue = cvar("g_balance_armor_start");
 437         self.pauserotarmor_finished = 0;
 438         self.pauserothealth_finished = 0;
 439         self.pauseregen_finished = 0;
 440         self.damageforcescale = 0;
 441         self.death_time = 0;
 442         self.dead_frame = 0;
 443         self.alpha = 0;
 444         self.scale = 0;
 445         self.fade_time = 0;
 446         self.pain_frame = 0;
 447         self.pain_finished = 0;
 448         self.strength_finished = 0;
 449         self.invincible_finished = 0;
 450         self.pushltime = 0;
 451         self.think = SUB_Null;
 452         self.nextthink = 0;
 453         self.hook_time = 0;
 454         self.runes = 0;
 455         self.deadflag = DEAD_NO;
 456         self.angles = spot.angles;
 457         self.angles_z = 0;
 458         self.fixangle = TRUE;
 459         self.crouch = FALSE;
 460
 461         self.view_ofs = PL_VIEW_OFS;
 462         setorigin (self, spot.origin);
 463         setsize (self, '0 0 0', '0 0 0');
 464         self.oldorigin = self.origin;
 465         self.items = 0;
 466         self.weapons = 0;
 467         self.model = "";
 468         self.modelindex = 0;
 469         self.weapon = 0;
 470         self.weaponmodel = "";
 471         self.weaponentity = world;
 472         self.killcount = -666;
 473         self.velocity = '0 0 0';
 474         self.avelocity = '0 0 0';
 475         self.punchangle = '0 0 0';
 476         self.punchvector = '0 0 0';
 477         self.oldvelocity = self.velocity;
 478         self.customizeentityforclient = Client_customizeentityforclient;
 479         self.wantswelcomemessage = 1;
 480
 481         if(g_arena)
 482         {
 483                 if(self.version_mismatch)
 484                 {
 485                         Spawnqueue_Unmark(self);
 486                         Spawnqueue_Remove(self);
 487                 }
 488                 else
 489                 {
 490                         Spawnqueue_Insert(self);
 491                 }
 492         }
 493         else if(g_lms)
 494         {
 495                 // Only if the player cannot play at all
 496                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 497                         self.frags = -666;
 498                 else
 499                         self.frags = -667;
 500         }
 501         else
 502                 self.frags = -666;
 503 }
 504
 505 float RestrictSkin(float s)
 506 {
 507         if(!teams_matter)
 508                 return s;
 509         if(s == 6)
 510                 return 6;
 511         return mod(s, 3);
 512 }
 513
 514 void FixPlayermodel()
 515 {
 516         local string defaultmodel;
 517         local float defaultskin;
 518         local vector m1, m2;
 519
 520         defaultmodel = "";
 521
 522         if(cvar("sv_defaultcharacter") == 1) {
 523                 defaultskin = 0;
 524
 525                 if(teams_matter)
 526                 {
 527                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 528                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 529                 }
 530
 531                 if(defaultmodel == "")
 532                 {
 533                         defaultmodel = cvar_string("sv_defaultplayermodel");
 534                         defaultskin = cvar("sv_defaultplayerskin");
 535                 }
 536         }
 537
 538         if(defaultmodel != "")
 539         {
 540                 if (defaultmodel != self.model)
 541                 {
 542                         m1 = self.mins;
 543                         m2 = self.maxs;
 544                         setmodel_lod (self, defaultmodel);
 545                         setsize (self, m1, m2);
 546                 }
 547
 548                 self.skin = defaultskin;
 549         } else {
 550                 if (self.playermodel != self.model)
 551                 {
 552                         self.playermodel = CheckPlayerModel(self.playermodel);
 553                         m1 = self.mins;
 554                         m2 = self.maxs;
 555                         setmodel_lod (self, self.playermodel);
 556                         setsize (self, m1, m2);
 557                 }
 558
 559                 self.skin = RestrictSkin(stof(self.playerskin));
 560         }
 561
 562         if(!teams_matter)
 563                 if(strlen(cvar_string("sv_defaultplayercolors")))
 564                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 565                                 setcolor(self, cvar("sv_defaultplayercolors"));
 566 }
 567
 568 /*
 569 =============
 570 PutClientInServer
 571
 572 Called when a client spawns in the server
 573 =============
 574 */
 575 //void() ctf_playerchanged;
 576 void PutClientInServer (void)
 577 {
 578         if(clienttype(self) == CLIENTTYPE_BOT)
 579         {
 580                 self.classname = "player";
 581         }
 582         else if(clienttype(self) == CLIENTTYPE_REAL)
 583         {
 584                 msg_entity = self;
 585                 WriteByte(MSG_ONE, SVC_SETVIEW);
 586                 WriteEntity(MSG_ONE, self);
 587         }
 588
 589         if(g_tourney)
 590         {
 591                 msg_entity = self;
 592                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
 593                 WriteByte(MSG_ONE, TE_CSQC_WARMUP);
 594                 WriteByte(MSG_ONE, !tourneyInMatchStage);
 595         }
 596
 597         // player is dead and becomes observer
 598         // FIXME fix LMS scoring for new system
 599         if(g_lms)
 600         {
 601                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 602                         self.classname = "observer";
 603         }
 604
 605         if(g_arena)
 606         if(!self.spawned)
 607                 self.classname = "observer";
 608
 609         if(self.classname == "player") {
 610                 entity  spot;
 611
 612                 race_PreSpawn();
 613
 614                 spot = SelectSpawnPoint (FALSE);
 615                 if(!spot)
 616                 {
 617                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 618                         return; // spawn failed
 619                 }
 620
 621                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 622
 623                 self.classname = "player";
 624                 self.iscreature = TRUE;
 625                 self.movetype = MOVETYPE_WALK;
 626                 self.solid = SOLID_SLIDEBOX;
 627                 if(independent_players)
 628                         MAKE_INDEPENDENT_PLAYER(self);
 629                 self.flags = FL_CLIENT;
 630                 self.takedamage = DAMAGE_AIM;
 631                 if(g_minstagib)
 632                         self.effects = EF_FULLBRIGHT;
 633                 else
 634                         self.effects = 0;
 635                 self.air_finished = time + 12;
 636                 self.dmg = 2;
 637
 638                 self.ammo_shells = start_ammo_shells;
 639                 self.ammo_nails = start_ammo_nails;
 640                 self.ammo_rockets = start_ammo_rockets;
 641                 self.ammo_cells = start_ammo_cells;
 642                 self.health = start_health;
 643                 self.armorvalue = start_armorvalue;
 644                 self.items = start_items;
 645                 self.weapons = start_weapons;
 646                 self.switchweapon = start_switchweapon;
 647                 self.cnt = start_switchweapon;
 648                 self.weapon = 0;
 649                 self.jump_interval = time;
 650
 651                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 652                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 653                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 654                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 655                 //extend the pause of rotting if client was reset at the beginning of the countdown
 656                 if(!cvar("sv_ready_restart_after_countdown") && time < restart_countdown) {
 657                         self.spawnshieldtime += RESTART_COUNTDOWN;
 658                         self.pauserotarmor_finished += RESTART_COUNTDOWN;
 659                         self.pauserothealth_finished += RESTART_COUNTDOWN;
 660                         self.pauseregen_finished += RESTART_COUNTDOWN;
 661                 }
 662                 self.damageforcescale = 2;
 663                 self.death_time = 0;
 664                 self.dead_frame = 0;
 665                 self.alpha = 0;
 666                 self.scale = 0;
 667                 self.fade_time = 0;
 668                 self.pain_frame = 0;
 669                 self.pain_finished = 0;
 670                 self.strength_finished = 0;
 671                 self.invincible_finished = 0;
 672                 self.pushltime = 0;
 673                 //self.speed_finished = 0;
 674                 //self.slowmo_finished = 0;
 675                 // players have no think function
 676                 self.think = SUB_Null;
 677                 self.nextthink = 0;
 678                 self.hook_time = 0;
 679
 680                 self.runes = 0;
 681
 682                 self.deadflag = DEAD_NO;
 683
 684                 self.angles = spot.angles;
 685
 686                 self.angles_z = 0; // never spawn tilted even if the spot says to
 687                 self.fixangle = TRUE; // turn this way immediately
 688                 self.velocity = '0 0 0';
 689                 self.avelocity = '0 0 0';
 690                 self.punchangle = '0 0 0';
 691                 self.punchvector = '0 0 0';
 692                 self.oldvelocity = self.velocity;
 693
 694                 msg_entity = self;
 695                 WRITESPECTATABLE_MSG_ONE({
 696                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 697                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 698                 });
 699
 700                 self.customizeentityforclient = Client_customizeentityforclient;
 701
 702                 self.model = "";
 703                 FixPlayermodel();
 704
 705                 self.crouch = FALSE;
 706                 self.view_ofs = PL_VIEW_OFS;
 707                 setsize (self, PL_MIN, PL_MAX);
 708                 self.spawnorigin = spot.origin;
 709                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 710                 // don't reset back to last position, even if new position is stuck in solid
 711                 self.oldorigin = self.origin;
 712
 713                 if(g_arena)
 714                 {
 715                         Spawnqueue_Remove(self);
 716                         Spawnqueue_Mark(self);
 717                 }
 718
 719                 self.event_damage = PlayerDamage;
 720
 721                 self.bot_attack = TRUE;
 722
 723                 self.statdraintime = time + 5;
 724                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 725
 726                 if(self.killcount == -666) {
 727                         PlayerScore_Clear(self);
 728                         self.killcount = 0;
 729                         self.frags = 0;
 730                 }
 731
 732                 self.cnt = WEP_LASER;
 733                 self.nixnex_lastchange_id = -1;
 734
 735                 CL_SpawnWeaponentity();
 736                 self.alpha = default_player_alpha;
 737                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 738                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 739
 740                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 741                 self.lms_traveled_distance = 0;
 742                 self.speedrunning = FALSE;
 743
 744                 race_PostSpawn(spot);
 745
 746                 if(cvar("spawn_debug"))
 747                 {
 748                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 749                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 750                 }
 751
 752                 //stuffcmd(self, "chase_active 0");
 753                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 754
 755                 if (cvar("g_spawnsound"))
 756                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 757
 758                 if(g_assault) {
 759                         if(self.team == assault_attacker_team)
 760                                 centerprint(self, "You are attacking!\n");
 761                         else
 762                                 centerprint(self, "You are defending!\n");
 763                 }
 764
 765         } else if(self.classname == "observer") {
 766                 PutObserverInServer ();
 767         }
 768
 769         //if(g_ctf)
 770         //      ctf_playerchanged();
 771 }
 772
 773 /*
 774 =============
 775 SendCSQCInfo
 776
 777 Send whatever CSQC needs NOW and cannot wait for SendServerInfo to happen...
 778 =============
 779 */
 780 void SendCSQCInfo(void)
 781 {
 782         float i;
 783         if(clienttype(self) != CLIENTTYPE_REAL)
 784                 return;
 785         msg_entity = self;
 786         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 787         WriteByte(MSG_ONE, TE_CSQC_INIT);
 788         WriteShort(MSG_ONE, CSQC_REVISION);
 789         WriteByte(MSG_ONE, maxclients);
 790         for(i = 1; i <= 24; ++i)
 791                 WriteByte(MSG_ONE, (get_weaponinfo(i)).impulse + 1);
 792 }
 793
 794 /*
 795 =============
 796 SetNewParms
 797 =============
 798 */
 799 void SetNewParms (void)
 800 {
 801         // initialize parms for a new player
 802         parm1 = -(86400 * 366);
 803 }
 804
 805 /*
 806 =============
 807 SetChangeParms
 808 =============
 809 */
 810 void SetChangeParms (void)
 811 {
 812         // save parms for level change
 813         parm1 = self.parm_idlesince - time;
 814 }
 815
 816 /*
 817 =============
 818 DecodeLevelParms
 819 =============
 820 */
 821 void DecodeLevelParms (void)
 822 {
 823         // load parms
 824         self.parm_idlesince = parm1;
 825         if(self.parm_idlesince == -(86400 * 366))
 826                 self.parm_idlesince = time;
 827 }
 828
 829 /*
 830 =============
 831 ClientKill
 832
 833 Called when a client types 'kill' in the console
 834 =============
 835 */
 836
 837 void ClientKill_Now_TeamChange()
 838 {
 839         if(self.killindicator_teamchange == -1)
 840         {
 841                 self.team = -1;
 842                 JoinBestTeam( self, FALSE, FALSE );
 843         }
 844         else
 845         {
 846                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 847         }
 848 }
 849
 850 void ClientKill_Now()
 851 {
 852         if(self.killindicator_teamchange)
 853                 ClientKill_Now_TeamChange();
 854
 855         // in any case:
 856         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 857
 858         if(self.killindicator)
 859         {
 860                 dprint("Cleaned up after a leaked kill indicator.\n");
 861                 remove(self.killindicator);
 862                 self.killindicator = world;
 863         }
 864 }
 865 void KillIndicator_Think()
 866 {
 867         if (!self.owner.modelindex)
 868         {
 869                 self.owner.killindicator = world;
 870                 remove(self);
 871                 return;
 872         }
 873
 874         if(self.cnt <= 0)
 875         {
 876                 self = self.owner;
 877                 ClientKill_Now(); // no oldself needed
 878                 return;
 879         }
 880         else
 881         {
 882                 if(self.cnt <= 10)
 883                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 884                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 885                 {
 886                         if(self.cnt <= 10)
 887                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 888                         if(self.owner.killindicator_teamchange)
 889                         {
 890                                 if(self.owner.killindicator_teamchange == -1)
 891                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 892                                 else
 893                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 894                         }
 895                         else
 896                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 897                 }
 898                 self.nextthink = time + 1;
 899                 self.cnt -= 1;
 900         }
 901 }
 902
 903 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 904 {
 905         float killtime;
 906         entity e;
 907         killtime = cvar("g_balance_kill_delay");
 908
 909         self.killindicator_teamchange = targetteam;
 910
 911         if(!self.killindicator)
 912         {
 913                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 914                 {
 915                         ClientKill_Now();
 916                 }
 917                 else
 918                 {
 919                         self.killindicator = spawn();
 920                         self.killindicator.owner = self;
 921                         self.killindicator.scale = 0.5;
 922                         setattachment(self.killindicator, self, "");
 923                         setorigin(self.killindicator, '0 0 52');
 924                         self.killindicator.think = KillIndicator_Think;
 925                         self.killindicator.nextthink = time + (self.lip) * 0.05;
 926                         self.killindicator.cnt = ceil(killtime);
 927                         self.killindicator.count = bound(0, ceil(killtime), 10);
 928                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 929
 930                         for(e = world; (e = find(e, classname, "body")) != world; )
 931                         {
 932                                 if(e.enemy != self)
 933                                         continue;
 934                                 e.killindicator = spawn();
 935                                 e.killindicator.owner = e;
 936                                 e.killindicator.scale = 0.5;
 937                                 setattachment(e.killindicator, e, "");
 938                                 setorigin(e.killindicator, '0 0 52');
 939                                 e.killindicator.think = KillIndicator_Think;
 940                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
 941                                 e.killindicator.cnt = ceil(killtime);
 942                         }
 943                         self.lip = 0;
 944                 }
 945         }
 946         if(self.killindicator)
 947         {
 948                 if(targetteam)
 949                         self.killindicator.colormod = TeamColor(targetteam);
 950                 else
 951                         self.killindicator.colormod = '0 0 0';
 952         }
 953 }
 954
 955 void ClientKill (void)
 956 {
 957         ClientKill_TeamChange(0);
 958 }
 959
 960 void DoTeamChange(float destteam)
 961 {
 962         float t, c0;
 963         if(!cvar("teamplay"))
 964         {
 965                 if(destteam >= 0)
 966                         SetPlayerColors(self, destteam);
 967                 return;
 968         }
 969         if(self.classname == "player")
 970         if(destteam == -1)
 971         {
 972                 CheckAllowedTeams(self);
 973                 t = FindSmallestTeam(self, TRUE);
 974                 switch(self.team)
 975                 {
 976                         case COLOR_TEAM1: c0 = c1; break;
 977                         case COLOR_TEAM2: c0 = c2; break;
 978                         case COLOR_TEAM3: c0 = c3; break;
 979                         case COLOR_TEAM4: c0 = c4; break;
 980                         default:          c0 = 999;
 981                 }
 982                 switch(t)
 983                 {
 984                         case 1:
 985                                 if(c0 > c1)
 986                                         destteam = COLOR_TEAM1;
 987                                 break;
 988                         case 2:
 989                                 if(c0 > c2)
 990                                         destteam = COLOR_TEAM2;
 991                                 break;
 992                         case 3:
 993                                 if(c0 > c3)
 994                                         destteam = COLOR_TEAM3;
 995                                 break;
 996                         case 4:
 997                                 if(c0 > c4)
 998                                         destteam = COLOR_TEAM4;
 999                                 break;
1000                 }
1001                 if(destteam == -1)
1002                         return;
1003         }
1004         if(destteam == self.team && !self.killindicator)
1005                 return;
1006         ClientKill_TeamChange(destteam);
1007 }
1008
1009 void FixClientCvars(entity e)
1010 {
1011         // send prediction settings to the client
1012         stuffcmd(e, "\nin_bindmap 0 0\n");
1013         /*
1014          * we no longer need to stuff this. Remove this comment block if you feel
1015          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1016         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1017         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1018         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1019         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1020         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1021         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1022         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1023         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1024         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1025         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1026         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1027         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1028         stuffcmd(e, "cl_movement_edgefriction 1\n");
1029          */
1030 }
1031
1032 /*
1033 =============
1034 ClientConnect
1035
1036 Called when a client connects to the server
1037 =============
1038 */
1039 //void ctf_clientconnect();
1040 string ColoredTeamName(float t);
1041 void DecodeLevelParms (void);
1042 //void dom_player_join_team(entity pl);
1043 void ClientConnect (void)
1044 {
1045         local string s;
1046
1047         if(self.flags & FL_CLIENT)
1048         {
1049                 print("Warning: ClientConnect, but already connected!\n");
1050                 return;
1051         }
1052
1053         if(Ban_IsClientBanned(self))
1054         {
1055                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
1056                 dropclient(self);
1057                 bprint(s);
1058                 return;
1059         }
1060
1061         DecodeLevelParms();
1062
1063         self.classname = "player_joining";
1064
1065         self.flags = self.flags | FL_CLIENT;
1066         self.version_nagtime = time + 10 + random() * 10;
1067
1068         if(player_count<0)
1069         {
1070                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1071                 player_count = 0;
1072         }
1073
1074         PlayerScore_Attach(self);
1075
1076         bot_clientconnect();
1077
1078         race_PreSpawnObserver();
1079
1080         //if(g_domination)
1081         //      dom_player_join_team(self);
1082
1083         //JoinBestTeam(self, FALSE, FALSE);
1084
1085         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1086                 self.classname = "observer";
1087         } else {
1088                 self.classname = "player";
1089                 campaign_bots_may_start = 1;
1090         }
1091
1092         self.playerid = (playerid_last = playerid_last + 1);
1093         if(cvar("sv_eventlog"))
1094         {
1095                 if(clienttype(self) == CLIENTTYPE_REAL)
1096                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", self.netaddress, ":", self.netname));
1097                 else
1098                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":bot:", self.netname));
1099                 s = strcat(":team:", ftos(self.playerid), ":");
1100                 s = strcat(s, ftos(self.team));
1101                 GameLogEcho(s);
1102         }
1103         self.netname_previous = strzone(self.netname);
1104
1105         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1106
1107         bprint ("^4",self.netname);
1108         bprint ("^4 connected");
1109
1110         if(g_domination || g_ctf)
1111         {
1112                 bprint(" and joined the ");
1113                 bprint(ColoredTeamName(self.team));
1114         }
1115
1116         bprint("\n");
1117
1118         self.welcomemessage_time = 0;
1119
1120         stuffcmd(self, strcat(clientstuff, "\n"));
1121         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1122         stuffcmd(self, "cl_particles_reloadeffects\n");
1123
1124         FixClientCvars(self);
1125
1126         // spawnfunc_waypoint sprites
1127         WaypointSprite_InitClient(self);
1128
1129         // Wazat's grappling hook
1130         SetGrappleHookBindings();
1131
1132         // get autoswitch state from player when he toggles it
1133         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1134
1135         // get version info from player
1136         stuffcmd(self, "cmd clientversion $gameversion\n");
1137
1138         // get other cvars from player
1139         GetCvars(0);
1140
1141         // set cvar for team scoreboard
1142         if (teams_matter)
1143         {
1144                 local float t;
1145                 t = cvar("teamplay");
1146                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1147                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1148         }
1149         else
1150                 stuffcmd(self, "set teamplay 0\n");
1151
1152         // notify about available teams
1153         if(teamplay)
1154         {
1155                 CheckAllowedTeams(self);
1156                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1157                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1158         }
1159         else
1160                 stuffcmd(self, "set _teams_available 0\n");
1161
1162         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1163
1164         if(g_arena)
1165         {
1166                 self.classname = "observer";
1167                 Spawnqueue_Insert(self);
1168         }
1169         /*else if(g_ctf)
1170         {
1171                 ctf_clientconnect();
1172         }*/
1173
1174         if(entcs_start)
1175                 attach_entcs();
1176
1177         bot_relinkplayerlist();
1178
1179         self.spectatortime = time;
1180         if(blockSpectators)
1181         {
1182                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1183         }
1184
1185         self.jointime = time;
1186         self.allowedTimeouts = cvar("sv_timeout_number");
1187
1188         if(clienttype(self) == CLIENTTYPE_REAL)
1189         {
1190                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1191                 SendCSQCInfo();
1192                 msg_entity = self;
1193                 if(mapvote_initialized && !cvar("g_maplist_textonly"))
1194                 {
1195                         MapVote_SendData(MSG_ONE);
1196                         MapVote_UpdateData(MSG_ONE);
1197                 }
1198                 ScoreInfo_Write(MSG_ONE);
1199         }
1200
1201         if(g_lms)
1202         {
1203                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1204                 {
1205                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1206                         self.frags = -666; // FIXME do we still need this?
1207                 }
1208         }
1209 }
1210
1211 /*
1212 =============
1213 ClientDisconnect
1214
1215 Called when a client disconnects from the server
1216 =============
1217 */
1218 void(entity e) DropFlag;
1219 .entity chatbubbleentity;
1220 .entity teambubbleentity;
1221 void ReadyCount();
1222 //void() ctf_clientdisconnect;
1223 void ClientDisconnect (void)
1224 {
1225         float save;
1226
1227         if not(self.flags & FL_CLIENT)
1228         {
1229                 print("Warning: ClientDisconnect without ClientConnect\n");
1230                 return;
1231         }
1232
1233         bot_clientdisconnect();
1234
1235         if(entcs_start)
1236                 detach_entcs();
1237
1238         if(cvar("sv_eventlog"))
1239                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1240         bprint ("^4",self.netname);
1241         bprint ("^4 disconnected\n");
1242
1243         if (self.chatbubbleentity)
1244         {
1245                 remove (self.chatbubbleentity);
1246                 self.chatbubbleentity = world;
1247         }
1248
1249         if (self.teambubbleentity)
1250         {
1251                 remove (self.teambubbleentity);
1252                 self.teambubbleentity = world;
1253         }
1254
1255         if (self.killindicator)
1256         {
1257                 remove (self.killindicator);
1258                 self.killindicator = world;
1259         }
1260
1261         WaypointSprite_PlayerGone();
1262
1263         DropAllRunes(self);
1264         kh_Key_DropAll(self, TRUE);
1265
1266         Portal_ClearAll(self);
1267
1268         if(self.flagcarried)
1269                 DropFlag(self.flagcarried);
1270
1271         save = self.flags;
1272         self.flags = self.flags - (self.flags & FL_CLIENT);
1273         bot_relinkplayerlist();
1274         self.flags = save;
1275
1276         // remove laserdot
1277         if(self.weaponentity)
1278                 if(self.weaponentity.lasertarget)
1279                         remove(self.weaponentity.lasertarget);
1280
1281         if(g_arena)
1282         {
1283                 Spawnqueue_Unmark(self);
1284                 Spawnqueue_Remove(self);
1285         }
1286         /*if(g_ctf)
1287         {
1288                 ctf_clientdisconnect();
1289         }
1290         */
1291
1292         PlayerScore_Detach(self);
1293
1294         if(self.netname_previous)
1295                 strunzone(self.netname_previous);
1296
1297         ClearPlayerSounds();
1298
1299         // free cvars
1300         GetCvars(-1);
1301         self.playerid = 0;
1302
1303         ReadyCount();
1304 }
1305
1306 .float BUTTON_CHAT;
1307 void ChatBubbleThink()
1308 {
1309         self.nextthink = time;
1310         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1311         {
1312                 self.owner.chatbubbleentity = world;
1313                 remove(self);
1314                 return;
1315         }
1316         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1317         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1318                 self.model = self.mdl;
1319         else
1320                 self.model = "";
1321 };
1322
1323 void UpdateChatBubble()
1324 {
1325         if (!self.modelindex)
1326                 return;
1327         // spawn a chatbubble entity if needed
1328         if (!self.chatbubbleentity)
1329         {
1330                 self.chatbubbleentity = spawn();
1331                 self.chatbubbleentity.owner = self;
1332                 self.chatbubbleentity.exteriormodeltoclient = self;
1333                 self.chatbubbleentity.think = ChatBubbleThink;
1334                 self.chatbubbleentity.nextthink = time;
1335                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1336                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1337                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1338                 self.chatbubbleentity.model = "";
1339                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1340         }
1341 }
1342
1343
1344 void TeamBubbleThink()
1345 {
1346         self.nextthink = time;
1347         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1348         {
1349                 self.owner.teambubbleentity = world;
1350                 remove(self);
1351                 return;
1352         }
1353 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1354         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1355                 self.model = "";
1356         else
1357                 self.model = self.mdl;
1358
1359 };
1360
1361 float TeamBubble_customizeentityforclient()
1362 {
1363         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1364 }
1365
1366 void UpdateTeamBubble()
1367 {
1368         if (!self.modelindex || !cvar("teamplay"))
1369                 return;
1370         // spawn a teambubble entity if needed
1371         if (!self.teambubbleentity && cvar("teamplay"))
1372         {
1373                 self.teambubbleentity = spawn();
1374                 self.teambubbleentity.owner = self;
1375                 self.teambubbleentity.exteriormodeltoclient = self;
1376                 self.teambubbleentity.think = TeamBubbleThink;
1377                 self.teambubbleentity.nextthink = time;
1378                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1379 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1380                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1381                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1382                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1383                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1384                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1385                 self.teambubbleentity.effects = EF_LOWPRECISION;
1386         }
1387 }
1388
1389 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1390 // added to the model skins
1391 /*void UpdateColorModHack()
1392 {
1393         local float c;
1394         c = self.clientcolors & 15;
1395         // LordHavoc: only bothering to support white, green, red, yellow, blue
1396              if (teamplay == 0) self.colormod = '0 0 0';
1397         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1398         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1399         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1400         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1401         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1402         else self.colormod = '1 1 1';
1403 };*/
1404
1405 void respawn(void)
1406 {
1407         CopyBody(1);
1408         self.effects |= EF_NODRAW; // prevent another CopyBody
1409         PutClientInServer();
1410 }
1411
1412 /**
1413  * When sv_timeout is used this function returs strings like
1414  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1415  * Called by centerprint functions
1416  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1417  */
1418 string getTimeoutText(float addOneSecond) {
1419         if (!cvar("sv_timeout") || !timeoutStatus)
1420                 return "";
1421
1422         local string retStr;
1423         if (timeoutStatus == 1) {
1424                 if (addOneSecond == 1) {
1425                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1426                 }
1427                 else {
1428                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1429                 }
1430                 return retStr;
1431         }
1432         else if (timeoutStatus == 2) {
1433                 if (addOneSecond) {
1434                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1435                         //don't show messages like "Timeout ends in 0 seconds"...
1436                         if ((remainingTimeoutTime + 1) > 0)
1437                                 return retStr;
1438                         else
1439                                 return "";
1440                 }
1441                 else {
1442                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1443                         //don't show messages like "Timeout ends in 0 seconds"...
1444                         if (remainingTimeoutTime > 0)
1445                                 return retStr;
1446                         else
1447                                 return "";
1448                 }
1449         }
1450         else return "";
1451 }
1452
1453 void player_powerups (void)
1454 {
1455         if (g_minstagib)
1456         {
1457                 if (self.items & IT_STRENGTH)
1458                 {
1459                         if (time > self.strength_finished)
1460                         {
1461                                 if (g_minstagib_invis_alpha > 0)
1462                                 {
1463                                         self.alpha = default_player_alpha;
1464                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1465                                         self.effects = self.effects | EF_FULLBRIGHT;
1466                                 }
1467                                 else
1468                                 {
1469                                         self.effects -= self.effects & EF_NODRAW;
1470                                 }
1471                                 self.items = self.items - (self.items & IT_STRENGTH);
1472                                 sprint(self, "^3Invisibility has worn off\n");
1473                         }
1474                 }
1475                 else
1476                 {
1477                         if (time < self.strength_finished)
1478                         {
1479                                 if (g_minstagib_invis_alpha > 0)
1480                                 {
1481                                         self.alpha = g_minstagib_invis_alpha;
1482                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1483                                         self.effects -= self.effects & EF_FULLBRIGHT;
1484                                 }
1485                                 else
1486                                 {
1487                                         self.effects = self.effects | EF_NODRAW;
1488                                 }
1489                                 self.items = self.items | IT_STRENGTH;
1490                                 sprint(self, "^3You are invisible\n");
1491                         }
1492                 }
1493
1494                 if (self.items & IT_INVINCIBLE)
1495                 {
1496                         if (time > self.invincible_finished)
1497                         {
1498                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1499                                 sprint(self, "^3Speed has worn off\n");
1500                         }
1501                 }
1502                 else
1503                 {
1504                         if (time < self.invincible_finished)
1505                         {
1506                                 self.items = self.items | IT_INVINCIBLE;
1507                                 sprint(self, "^3You are on speed\n");
1508                         }
1509                 }
1510                 return;
1511         }
1512
1513         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1514         if (self.items & IT_STRENGTH)
1515         {
1516                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1517                 if (time > self.strength_finished)
1518                 {
1519                         self.items = self.items - (self.items & IT_STRENGTH);
1520                         sprint(self, "^3Strength has worn off\n");
1521                 }
1522         }
1523         else
1524         {
1525                 if (time < self.strength_finished)
1526                 {
1527                         self.items = self.items | IT_STRENGTH;
1528                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1529                 }
1530         }
1531         if (self.items & IT_INVINCIBLE)
1532         {
1533                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1534                 if (time > self.invincible_finished)
1535                 {
1536                         self.items = self.items - (self.items & IT_INVINCIBLE);
1537                         sprint(self, "^3Shield has worn off\n");
1538                 }
1539         }
1540         else
1541         {
1542                 if (time < self.invincible_finished)
1543                 {
1544                         self.items = self.items | IT_INVINCIBLE;
1545                         sprint(self, "^3Shield surrounds you\n");
1546                 }
1547         }
1548
1549         if (cvar("g_fullbrightplayers"))
1550                 self.effects = self.effects | EF_FULLBRIGHT;
1551
1552         // midair gamemode: damage only while in the air
1553         // if in midair mode, being on ground grants temporary invulnerability
1554         // (this is so that multishot weapon don't clear the ground flag on the
1555         // first damage in the frame, leaving the player vulnerable to the
1556         // remaining hits in the same frame)
1557         if (self.flags & FL_ONGROUND)
1558         if (g_midair)
1559                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1560
1561         if (time > restart_countdown)
1562         if (time < self.spawnshieldtime)
1563                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1564 }
1565
1566 float CalcRegen(float current, float stable, float regenfactor)
1567 {
1568         if(current > stable)
1569                 return current;
1570         else if(current > stable - 0.25) // when close enough, "snap"
1571                 return stable;
1572         else
1573                 return min(stable, current + (stable - current) * regenfactor * frametime);
1574 }
1575
1576 void player_regen (void)
1577 {
1578         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1579         maxh = cvar("g_balance_health_stable");
1580         maxa = cvar("g_balance_armor_stable");
1581         limith = cvar("g_balance_health_limit");
1582         limita = cvar("g_balance_armor_limit");
1583
1584         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1585                 return;
1586
1587         max_mod = regen_mod = rot_mod = limit_mod = 1;
1588
1589         if (self.runes & RUNE_REGEN)
1590         {
1591                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1592                 {
1593                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1594                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1595                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1596                 }
1597                 else
1598                 {
1599                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1600                         max_mod = cvar("g_balance_rune_regen_hpmod");
1601                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1602                 }
1603         }
1604         else if (self.runes & CURSE_VENOM)
1605         {
1606                 max_mod = cvar("g_balance_curse_venom_hpmod");
1607                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1608                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1609                 else
1610                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1611                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1612                 //if (!self.runes & RUNE_REGEN)
1613                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1614         }
1615         maxh = maxh * max_mod;
1616         //maxa = maxa * max_mod;
1617         limith = limith * limit_mod;
1618         limita = limita * limit_mod;
1619
1620         if (self.armorvalue > maxa)
1621         {
1622                 if (time > self.pauserotarmor_finished)
1623                 {
1624                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1625                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1626                 }
1627         }
1628         else if (self.armorvalue < maxa)
1629         {
1630                 if (time > self.pauseregen_finished)
1631                 {
1632                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1633                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1634                 }
1635         }
1636         if (self.health > maxh)
1637         {
1638                 if (time > self.pauserothealth_finished)
1639                 {
1640                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1641                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1642                 }
1643         }
1644         else if (self.health < maxh)
1645         {
1646                 if (time > self.pauseregen_finished)
1647                 {
1648                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1649                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1650                 }
1651         }
1652
1653         if (self.health > limith)
1654                 self.health = limith;
1655         if (self.armorvalue > limita)
1656                 self.armorvalue = limita;
1657
1658         // if player rotted to death...  die!
1659         if(self.health < 1)
1660                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1661 }
1662
1663 .float zoomstate;
1664 float zoomstate_set;
1665 void SetZoomState(float z)
1666 {
1667         if(z != self.zoomstate)
1668         {
1669                 msg_entity = self;
1670                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
1671                 WriteByte(MSG_ONE, TE_CSQC_ZOOMNOTIFY);
1672                 WriteByte(MSG_ONE, z);
1673                 self.zoomstate = z;
1674         }
1675         zoomstate_set = 1;
1676 }
1677
1678 /*
1679 ======================
1680 spectate mode routines
1681 ======================
1682 */
1683 void SpectateCopy(entity spectatee) {
1684         self.armortype = spectatee.armortype;
1685         self.armorvalue = spectatee.armorvalue;
1686         self.currentammo = spectatee.currentammo;
1687         self.effects = spectatee.effects;
1688         self.health = spectatee.health;
1689         self.impulse = 0;
1690         self.items = spectatee.items;
1691         self.weapons = spectatee.weapons;
1692         self.punchangle = spectatee.punchangle;
1693         self.view_ofs = spectatee.view_ofs;
1694         self.v_angle = spectatee.v_angle;
1695         self.velocity = spectatee.velocity;
1696         self.dmg_take = spectatee.dmg_take;
1697         self.dmg_save = spectatee.dmg_save;
1698         self.dmg_inflictor = spectatee.dmg_inflictor;
1699         self.angles = spectatee.v_angle;
1700         self.fixangle = TRUE;
1701         setorigin(self, spectatee.origin);
1702         setsize(self, spectatee.mins, spectatee.maxs);
1703         SetZoomState(spectatee.zoomstate);
1704 }
1705
1706 float SpectateUpdate() {
1707         if(!self.enemy)
1708                 return 0;
1709
1710         if (self == self.enemy)
1711                 return 0;
1712
1713         if(self.enemy.flags & FL_NOTARGET)
1714                 return 0;
1715
1716         SpectateCopy(self.enemy);
1717
1718         return 1;
1719 }
1720
1721 float SpectateNext() {
1722         other = find(self.enemy, classname, "player");
1723         if (!other) {
1724                 other = find(other, classname, "player");
1725         }
1726         if (other) {
1727                 self.enemy = other;
1728         }
1729         if(self.enemy.classname == "player") {
1730                 msg_entity = self;
1731                 WriteByte(MSG_ONE, SVC_SETVIEW);
1732                 WriteEntity(MSG_ONE, self.enemy);
1733                 self.wantswelcomemessage = 1;
1734                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1735                 if(!SpectateUpdate())
1736                         PutObserverInServer();
1737                 return 1;
1738         } else {
1739                 return 0;
1740         }
1741 }
1742
1743 /*
1744 =============
1745 ShowRespawnCountdown()
1746
1747 Update a respawn countdown display.
1748 =============
1749 */
1750 void ShowRespawnCountdown()
1751 {
1752         float number;
1753         if(self.deadflag == DEAD_NO) // just respawned?
1754                 return;
1755         else
1756         {
1757                 number = ceil(self.death_time - time);
1758                 if(number <= 0)
1759                         return;
1760                 if(number <= self.respawn_countdown)
1761                 {
1762                         self.respawn_countdown = number - 1;
1763                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1764                                 announce(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1765                 }
1766         }
1767 }
1768
1769 void LeaveSpectatorMode()
1770 {
1771         if(isJoinAllowed()) {
1772                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1773                         self.classname = "player";
1774                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1775                                 JoinBestTeam(self, FALSE, TRUE);
1776                         if(cvar("g_campaign"))
1777                                 campaign_bots_may_start = 1;
1778                         PutClientInServer();
1779                         if(!(self.flags & FL_NOTARGET))
1780                                 bprint ("^4", self.netname, "^4 is playing now\n");
1781                         centerprint(self,"");
1782                         return;
1783                 } else {
1784                         stuffcmd(self,"menu_showteamselect\n");
1785                         return;
1786                 }
1787         }
1788         else {
1789                 //player may not join because of g_maxplayers is set
1790                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1791         }
1792 }
1793
1794 /**
1795  * Determines whether the player is allowed to join. This depends on cvar
1796  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1797  * it checks whether the number of currently playing players exceeds g_maxplayers.
1798  * @return bool TRUE if the player is allowed to join, false otherwise
1799  */
1800 float isJoinAllowed() {
1801         if (!cvar("g_maxplayers"))
1802                 return TRUE;
1803
1804         local entity e;
1805         local float currentlyPlaying;
1806         FOR_EACH_REALPLAYER(e) {
1807                 if(e.classname == "player")
1808                         currentlyPlaying += 1;
1809         }
1810         if(currentlyPlaying < cvar("g_maxplayers"))
1811                 return TRUE;
1812
1813         return FALSE;
1814 }
1815
1816 /**
1817  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1818  * g_maxplayers_spectator_blocktime seconds
1819  */
1820 void checkSpectatorBlock() {
1821         if(self.classname == "spectator" || self.classname == "observer") {
1822                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1823                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1824                         dropclient(self);
1825                 }
1826         }
1827 }
1828
1829 float vercmp_recursive(string v1, string v2)
1830 {
1831         float dot1, dot2;
1832         string s1, s2;
1833         float r;
1834
1835         dot1 = strstrofs(v1, ".", 0);
1836         dot2 = strstrofs(v2, ".", 0);
1837         if(dot1 == -1)
1838                 s1 = v1;
1839         else
1840                 s1 = substring(v1, 0, dot1);
1841         if(dot2 == -1)
1842                 s2 = v2;
1843         else
1844                 s2 = substring(v2, 0, dot2);
1845
1846         r = stof(s1) - stof(s2);
1847         if(r != 0)
1848                 return r;
1849
1850         r = strcasecmp(s1, s2);
1851         if(r != 0)
1852                 return r;
1853
1854         if(dot1 == -1)
1855                 if(dot2 == -1)
1856                         return 0;
1857                 else
1858                         return -1;
1859         else
1860                 if(dot2 == -1)
1861                         return 1;
1862                 else
1863                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1864 }
1865
1866 float vercmp(string v1, string v2)
1867 {
1868         if(strcasecmp(v1, v2) == 0) // early out check
1869                 return 0;
1870         return vercmp_recursive(v1, v2);
1871 }
1872
1873 void ObserverThink()
1874 {
1875         if (self.flags & FL_JUMPRELEASED) {
1876                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1877                         self.welcomemessage_time = 0;
1878                         self.flags = self.flags - FL_JUMPRELEASED;
1879                         LeaveSpectatorMode();
1880                         return;
1881                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
1882                         self.welcomemessage_time = 0;
1883                         self.flags = self.flags - FL_JUMPRELEASED;
1884                         if(SpectateNext() == 1) {
1885                                 self.classname = "spectator";
1886                         }
1887                 }
1888         } else {
1889                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
1890                         self.flags = self.flags | FL_JUMPRELEASED;
1891                 }
1892         }
1893         if(self.BUTTON_ZOOM)
1894                 self.wantswelcomemessage = 0;
1895         if(self.wantswelcomemessage)
1896                 PrintWelcomeMessage(self);
1897 }
1898
1899 void SpectatorThink()
1900 {
1901         if (self.flags & FL_JUMPRELEASED) {
1902                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1903                         self.welcomemessage_time = 0;
1904                         self.flags = self.flags - FL_JUMPRELEASED;
1905                         LeaveSpectatorMode();
1906                         return;
1907                 } else if(self.BUTTON_ATCK) {
1908                         self.welcomemessage_time = 0;
1909                         self.flags = self.flags - FL_JUMPRELEASED;
1910                         if(SpectateNext() == 1) {
1911                                 self.classname = "spectator";
1912                         } else {
1913                                 self.classname = "observer";
1914                                 PutClientInServer();
1915                         }
1916                 } else if (self.BUTTON_ATCK2) {
1917                         self.welcomemessage_time = 0;
1918                         self.flags = self.flags - FL_JUMPRELEASED;
1919                         self.classname = "observer";
1920                         PutClientInServer();
1921                 } else {
1922                         if(!SpectateUpdate())
1923                                 PutObserverInServer();
1924                 }
1925         } else {
1926                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
1927                         self.flags = self.flags | FL_JUMPRELEASED;
1928                 }
1929         }
1930         if(self.BUTTON_ZOOM)
1931                 self.wantswelcomemessage = 0;
1932         if(self.wantswelcomemessage)
1933                 PrintWelcomeMessage(self);
1934         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1935 }
1936
1937 /*
1938 =============
1939 PlayerPreThink
1940
1941 Called every frame for each client before the physics are run
1942 =============
1943 */
1944 void() ctf_setstatus;
1945 .float vote_nagtime;
1946 .float spectatee_status;
1947 void PlayerPreThink (void)
1948 {
1949         self.stat_sys_ticrate = cvar("sys_ticrate");
1950         if(blockSpectators)
1951                 checkSpectatorBlock();
1952
1953         zoomstate_set = 0;
1954
1955         if(self.netname_previous != self.netname)
1956         {
1957                 if(cvar("sv_eventlog"))
1958                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
1959                 if(self.netname_previous)
1960                         strunzone(self.netname_previous);
1961                 self.netname_previous = strzone(self.netname);
1962         }
1963
1964         // version nagging
1965         if(self.version_nagtime)
1966                 if(self.cvar_g_nexuizversion)
1967                         if(time > self.version_nagtime)
1968                         {
1969                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1970                                 {
1971                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
1972                                         {
1973                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1974                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1975                                         }
1976                                         else
1977                                         {
1978                                                 float r;
1979                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
1980                                                 if(r < 0)
1981                                                 {
1982                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
1983                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
1984                                                 }
1985                                                 else if(r > 0)
1986                                                 {
1987                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1988                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1989                                                 }
1990                                         }
1991                                 }
1992                                 self.version_nagtime = 0;
1993                         }
1994
1995         // vote nagging
1996         if(self.cvar_scr_centertime)
1997                 if(time > self.vote_nagtime)
1998                 {
1999                         VoteNag();
2000                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
2001                 }
2002
2003         // GOD MODE info
2004         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2005         {
2006                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2007                 self.max_armorvalue = 0;
2008         }
2009
2010         if(frametime)
2011                 antilag_record(self);
2012
2013         if(self.classname == "player") {
2014 //              if(self.netname == "Wazat")
2015 //                      bprint(self.classname, "\n");
2016
2017                 CheckRules_Player();
2018
2019                 if(self.BUTTON_INFO)
2020                         PrintWelcomeMessage(self);
2021
2022                 if(g_lms || !cvar("sv_spectate"))
2023                 if((time - self.jointime) <= cvar("welcome_message_time"))
2024                         PrintWelcomeMessage(self);
2025
2026                 if (intermission_running)
2027                 {
2028                         IntermissionThink ();   // otherwise a button could be missed between
2029                         return;                                 // the think tics
2030                 }
2031
2032                 if(self.teleport_time)
2033                 if(time > self.teleport_time)
2034                 {
2035                         self.teleport_time = 0;
2036                         self.effects = self.effects - (self.effects & EF_NODRAW);
2037                         if(self.weaponentity)
2038                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
2039                 }
2040
2041                 Nixnex_GiveCurrentWeapon();
2042
2043                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2044                         UpdateSelectedPlayer();
2045
2046                 //don't allow the player to turn around while game is paused!
2047                 if(timeoutStatus == 2) {
2048                         self.v_angle = self.lastV_angle;
2049                         self.angles = self.lastV_angle;
2050                         self.fixangle = TRUE;
2051                 }
2052
2053                 if (self.deadflag != DEAD_NO)
2054                 {
2055                         float button_pressed, force_respawn;
2056                         player_anim();
2057                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2058                         force_respawn = (g_lms || cvar("g_forced_respawn"));
2059                         if (self.deadflag == DEAD_DYING)
2060                         {
2061                                 if(force_respawn)
2062                                         self.deadflag = DEAD_RESPAWNING;
2063                                 else if(!button_pressed)
2064                                         self.deadflag = DEAD_DEAD;
2065                         }
2066                         else if (self.deadflag == DEAD_DEAD)
2067                         {
2068                                 if(button_pressed)
2069                                         self.deadflag = DEAD_RESPAWNABLE;
2070                         }
2071                         else if (self.deadflag == DEAD_RESPAWNABLE)
2072                         {
2073                                 if(!button_pressed)
2074                                         self.deadflag = DEAD_RESPAWNING;
2075                         }
2076                         else if (self.deadflag == DEAD_RESPAWNING)
2077                         {
2078                                 if(time > self.death_time)
2079                                 {
2080                                         self.death_time = time + 1; // only retry once a second
2081                                         respawn();
2082                                 }
2083                         }
2084                         ShowRespawnCountdown();
2085                         return;
2086                 }
2087
2088                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2089                 {
2090                         vector dist;
2091
2092                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2093                         dist = self.oldorigin - self.origin;
2094                         dist_z = 0;
2095                         self.lms_traveled_distance += fabs(vlen(dist));
2096
2097                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
2098                         {
2099                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2100                                 self.lms_traveled_distance = 0;
2101                         }
2102
2103                         if(time > self.lms_nextcheck)
2104                         {
2105                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2106                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2107                                 {
2108                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2109                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2110                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2111                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2112                                 }
2113                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2114                                 self.lms_traveled_distance = 0;
2115                         }
2116                 }
2117
2118                 if (self.BUTTON_CROUCH && !self.hook.state)
2119                 {
2120                         if (!self.crouch)
2121                         {
2122                                 self.crouch = TRUE;
2123                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2124                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2125                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
2126                         }
2127                 }
2128                 else
2129                 {
2130                         if (self.crouch)
2131                         {
2132                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2133                                 if (!trace_startsolid)
2134                                 {
2135                                         self.crouch = FALSE;
2136                                         self.view_ofs = PL_VIEW_OFS;
2137                                         setsize (self, PL_MIN, PL_MAX);
2138                                 }
2139                         }
2140                 }
2141
2142                 FixPlayermodel();
2143
2144                 GrapplingHookFrame();
2145
2146                 W_WeaponFrame();
2147
2148                 player_powerups();
2149                 player_regen();
2150                 player_anim();
2151
2152                 if (g_minstagib)
2153                         minstagib_ammocheck();
2154
2155                 ctf_setstatus();
2156                 kh_setstatus();
2157
2158                 //self.angles_y=self.v_angle_y + 90;   // temp
2159
2160                 //if (TetrisPreFrame()) return;
2161         } else if(gameover) {
2162                 if (intermission_running)
2163                         IntermissionThink ();   // otherwise a button could be missed between
2164                 return;
2165         } else if(self.classname == "observer") {
2166                 ObserverThink();
2167         } else if(self.classname == "spectator") {
2168                 SpectatorThink();
2169         }
2170
2171         if(!zoomstate_set)
2172                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2173
2174         float oldspectatee_status;
2175         oldspectatee_status = self.spectatee_status;
2176         if(self.classname == "spectator")
2177                 self.spectatee_status = num_for_edict(self.enemy);
2178         else if(self.classname == "observer")
2179                 self.spectatee_status = num_for_edict(self);
2180         else
2181                 self.spectatee_status = 0;
2182         if(self.spectatee_status != oldspectatee_status)
2183         {
2184                 msg_entity = self;
2185                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
2186                 WriteByte(MSG_ONE, TE_CSQC_SPECTATING);
2187                 WriteByte(MSG_ONE, self.spectatee_status);
2188                 if(g_race)
2189                         race_InitSpectator();
2190         }
2191 }
2192
2193
2194 /*
2195 =============
2196 PlayerPostThink
2197
2198 Called every frame for each client after the physics are run
2199 =============
2200 */
2201 .float idlekick_lasttimeleft;
2202 .float race_penalty;
2203 .float race_penalty_nagged;
2204 void PlayerPostThink (void)
2205 {
2206         // Savage: Check for nameless players
2207         if (strlen(self.netname) < 1) {
2208                 self.netname = "Player";
2209                 stuffcmd(self, "seta _cl_name Player\n");
2210         }
2211
2212         if(sv_maxidle)
2213         {
2214                 float timeleft;
2215                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2216                 if(timeleft <= 0)
2217                 {
2218                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2219                         announce(self, "announcer/robotic/terminated.ogg");
2220                         dropclient(self);
2221                         return;
2222                 }
2223                 else if(timeleft <= 10)
2224                 {
2225                         if(timeleft != self.idlekick_lasttimeleft)
2226                         {
2227                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2228                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".ogg"));
2229                         }
2230                 }
2231                 else
2232                 {
2233                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2234                 }
2235                 self.idlekick_lasttimeleft = timeleft;
2236         }
2237
2238         if(self.classname == "player") {
2239                 CheckRules_Player();
2240                 UpdateChatBubble();
2241                 UpdateTeamBubble();
2242                 if (self.impulse)
2243                         ImpulseCommands();
2244                 if (intermission_running)
2245                         return;         // intermission or finale
2246
2247                 //PrintWelcomeMessage(self);
2248                 //if (TetrisPostFrame()) return;
2249
2250                 // restart countdown
2251                 if (restart_countdown) {
2252                         if(time < restart_countdown) {
2253                                 if (!cvar("sv_ready_restart_after_countdown"))
2254                                 {
2255                                         if(self.movement != '0 0 0' && g_race && !g_race_qualifying)
2256                                         {
2257                                                 if(time < restart_countdown - 2)
2258                                                 {
2259                                                         if(!self.race_penalty_nagged)
2260                                                         {
2261                                                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1DO NOT MOVE DURING THE COUNTDOWN.");
2262                                                                 self.race_penalty_nagged = 1;
2263                                                         }
2264                                                 }
2265                                                 else if(!self.race_penalty)
2266                                                 {
2267                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1FIVE SECONDS PENALTY.");
2268                                                         self.race_penalty = time + 5;
2269                                                 }
2270                                         }
2271                                         self.movetype = MOVETYPE_NONE;
2272                                         self.velocity = '0 0 0';
2273                                         self.avelocity = '0 0 0';
2274                                         self.movement = '0 0 0';
2275                                 }
2276                         }
2277                         else if (time < self.race_penalty)
2278                         {
2279                                 self.movetype = MOVETYPE_NONE;
2280                                 self.velocity = '0 0 0';
2281                                 self.avelocity = '0 0 0';
2282                                 self.movement = '0 0 0';
2283                         }
2284                         else
2285                         {
2286                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2287                                 if (!cvar("sv_ready_restart_after_countdown"))
2288                                 {
2289                                         if(self.movetype == MOVETYPE_NONE)
2290                                         {
2291                                                 self.movetype = MOVETYPE_WALK;
2292                                         }
2293                                         self.race_penalty = 0;
2294                                         self.race_penalty_nagged = 0;
2295                                 }
2296                         }
2297                 }
2298
2299         } else if (self.classname == "observer") {
2300                 //do nothing
2301         } else if (self.classname == "spectator") {
2302                 //do nothing
2303         }
2304
2305         /*
2306         float i;
2307         for(i = 0; i < 1000; ++i)
2308         {
2309                 vector end;
2310                 end = self.origin + '0 0 1024' + 512 * randomvec();
2311                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2312                 if(trace_fraction < 1)
2313                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2314                 {
2315                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2316                         break;
2317                 }
2318         }
2319         */
2320
2321         Arena_Warmup();
2322 }