data/qcsrc/server/cl_client.qc

   1 // let's abuse an existing field
   2 #define SPAWNPOINT_SCORE frags
   3
   4 .float wantswelcomemessage;
   5 .string netname_previous;
   6
   7 void spawnfunc_info_player_survivor (void)
   8 {
   9         spawnfunc_info_player_deathmatch();
  10 }
  11
  12 void spawnfunc_info_player_start (void)
  13 {
  14         spawnfunc_info_player_deathmatch();
  15 }
  16
  17 void spawnfunc_info_player_deathmatch (void)
  18 {
  19         self.classname = "info_player_deathmatch";
  20         relocate_spawnpoint();
  21 }
  22
  23 void spawnpoint_use()
  24 {
  25         if(teams_matter)
  26         if(have_team_spawns)
  27         {
  28                 self.team = activator.team;
  29                 some_spawn_has_been_used = 1;
  30         }
  31 };
  32
  33 // Returns:
  34 //   -1 if a spawn can't be used
  35 //   otherwise, a weight of the spawnpoint
  36 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
  37 {
  38         float shortest, thisdist;
  39         entity player;
  40
  41         // filter out spots for the wrong team
  42         if(teamcheck)
  43         if(spot.team != teamcheck)
  44                 return -1;
  45
  46         if(race_spawns)
  47                 if(spot.target == "")
  48                         return -1;
  49
  50         // filter out spots for assault
  51         if(spot.target != "") {
  52                 local entity ent;
  53                 float good;
  54                 ent = find(world, targetname, spot.target);
  55                 while(ent) {
  56                         if(ent.classname == "target_objective")
  57                         {
  58                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  59                                         return -1;
  60                                 good = 1;
  61                         }
  62                         else if(ent.classname == "trigger_race_checkpoint")
  63                         {
  64                                 if(self.classname == "player") // spectators may spawn everywhere
  65                                 {
  66                                         if(ent.race_checkpoint != race_PreviousCheckpoint(self.race_checkpoint))
  67                                                 return -1;
  68                                         float pl;
  69                                         pl = self.race_place;
  70                                         if(pl > race_highest_place_spawn)
  71                                                 pl = 0;
  72                                         if(spot.race_place != pl)
  73                                                 return -1;
  74                                 }
  75                                 good = 1;
  76                         }
  77                         else
  78                         {
  79                         }
  80                         ent = find(ent, targetname, spot.target);
  81                 }
  82
  83                 if(!good)
  84                         return -1;
  85         }
  86
  87         player = playerlist;
  88         shortest = vlen(world.maxs - world.mins);
  89         for(player = playerlist; player; player = player.chain)
  90                 if (player != self)
  91                 {
  92                         thisdist = vlen(player.origin - spot.origin);
  93                         if (thisdist < shortest)
  94                                 shortest = thisdist;
  95                 }
  96         return shortest;
  97 }
  98
  99 float spawn_allbad;
 100 float spawn_allgood;
 101 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
 102 {
 103         local entity spot, spotlist, spotlistend;
 104         spawn_allgood = TRUE;
 105         spawn_allbad = TRUE;
 106
 107         spotlist = world;
 108         spotlistend = world;
 109
 110         for(spot = firstspot; spot; spot = spot.chain)
 111         {
 112                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
 113
 114                 if(cvar("spawn_debugview"))
 115                 {
 116                         setmodel(spot, "models/runematch/rune.mdl");
 117                         if(spot.SPAWNPOINT_SCORE < mindist)
 118                         {
 119                                 spot.colormod = '1 0 0';
 120                                 spot.scale = 1;
 121                         }
 122                         else
 123                         {
 124                                 spot.colormod = '0 1 0';
 125                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
 126                         }
 127                 }
 128
 129                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 130                 {
 131                         if(spot.SPAWNPOINT_SCORE < mindist)
 132                         {
 133                                 // too short distance
 134                                 spawn_allgood = FALSE;
 135                         }
 136                         else
 137                         {
 138                                 // perfect
 139                                 spawn_allbad = FALSE;
 140
 141                                 if(spotlistend)
 142                                         spotlistend.chain = spot;
 143                                 spotlistend = spot;
 144                                 if(!spotlist)
 145                                         spotlist = spot;
 146
 147                                 /*
 148                                 if(teamcheck)
 149                                 if(spot.team != teamcheck)
 150                                         error("invalid spawn added");
 151
 152                                 print("added ", etos(spot), "\n");
 153                                 */
 154                         }
 155                 }
 156         }
 157         if(spotlistend)
 158                 spotlistend.chain = world;
 159
 160         /*
 161                 entity e;
 162                 if(teamcheck)
 163                         for(e = spotlist; e; e = e.chain)
 164                         {
 165                                 print("seen ", etos(e), "\n");
 166                                 if(e.team != teamcheck)
 167                                         error("invalid spawn found");
 168                         }
 169         */
 170
 171         return spotlist;
 172 }
 173
 174 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 175 {
 176         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 177         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 178         local entity spot;
 179
 180         RandomSelection_Init();
 181         for(spot = firstspot; spot; spot = spot.chain)
 182                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 183
 184         return RandomSelection_chosen_ent;
 185 }
 186
 187 /*
 188 =============
 189 SelectSpawnPoint
 190
 191 Finds a point to respawn
 192 =============
 193 */
 194 entity SelectSpawnPoint (float anypoint)
 195 {
 196         local float teamcheck;
 197         local entity firstspot_new;
 198         local entity spot, firstspot, playerlist;
 199
 200         spot = find (world, classname, "testplayerstart");
 201         if (spot)
 202                 return spot;
 203
 204         teamcheck = 0;
 205
 206         if(!anypoint && have_team_spawns)
 207                 teamcheck = self.team;
 208
 209         // get the list of players
 210         playerlist = findchain(classname, "player");
 211         // get the entire list of spots
 212         firstspot = findchain(classname, "info_player_deathmatch");
 213         // filter out the bad ones
 214         // (note this returns the original list if none survived)
 215         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 216         if(!firstspot_new)
 217                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 218         firstspot = firstspot_new;
 219
 220         // there is 50/50 chance of choosing a random spot or the furthest spot
 221         // (this means that roughly every other spawn will be furthest, so you
 222         // usually won't get fragged at spawn twice in a row)
 223         if (arena_roundbased)
 224         {
 225                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 226                 if(firstspot_new)
 227                         firstspot = firstspot_new;
 228                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 229         }
 230         else if (random() > cvar("g_spawn_furthest"))
 231                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 232         else
 233                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 234
 235         if(cvar("spawn_debugview"))
 236         {
 237                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 238
 239                 entity e;
 240                 if(teamcheck)
 241                         for(e = firstspot; e; e = e.chain)
 242                                 if(e.team != teamcheck)
 243                                         error("invalid spawn found");
 244         }
 245
 246         if (!spot)
 247         {
 248                 if(cvar("spawn_debug"))
 249                         GotoNextMap();
 250                 else
 251                 {
 252                         if(some_spawn_has_been_used)
 253                                 return world; // team can't spawn any more, because of actions of other team
 254                         else
 255                                 error("Cannot find a spawn point - please fix the map!");
 256                 }
 257         }
 258
 259         return spot;
 260 }
 261
 262 /*
 263 =============
 264 CheckPlayerModel
 265
 266 Checks if the argument string can be a valid playermodel.
 267 Returns a valid one in doubt.
 268 =============
 269 */
 270 string FallbackPlayerModel = "models/player/marine.zym";
 271 string CheckPlayerModel(string plyermodel) {
 272         if(strlen(plyermodel) < 4)
 273                 return FallbackPlayerModel;
 274         if( substring(plyermodel,0,14) != "models/player/")
 275                 return FallbackPlayerModel;
 276         else if(cvar("sv_servermodelsonly"))
 277         {
 278                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 279                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 280                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 281                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 282                         return FallbackPlayerModel;
 283                 if(!fexists(plyermodel))
 284                         return FallbackPlayerModel;
 285         }
 286         return plyermodel;
 287 }
 288
 289 /*
 290 =============
 291 Client_customizeentityforclient
 292
 293 LOD reduction
 294 =============
 295 */
 296 float Client_customizeentityforclient()
 297 {
 298 #ifdef ALLOW_VARIABLE_LOD
 299         // self: me
 300         // other: the player viewing me
 301         float distance;
 302         float f;
 303
 304         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 305                 return TRUE;
 306
 307         if(other.cvar_cl_playerdetailreduction <= 0)
 308         {
 309                 if(other.cvar_cl_playerdetailreduction <= -2)
 310                         self.modelindex = self.modelindex_lod2;
 311                 else if(other.cvar_cl_playerdetailreduction <= -1)
 312                         self.modelindex = self.modelindex_lod1;
 313                 else
 314                         self.modelindex = self.modelindex_lod0;
 315         }
 316         else
 317         {
 318                 distance = vlen(self.origin - other.origin);
 319                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 320                 if(f > 10000)
 321                         self.modelindex = self.modelindex_lod2;
 322                 else if(f > 5000)
 323                         self.modelindex = self.modelindex_lod1;
 324                 else
 325                         self.modelindex = self.modelindex_lod0;
 326         }
 327 #endif
 328
 329         return TRUE;
 330 }
 331
 332 void UpdatePlayerSounds();
 333 void setmodel_lod(entity e, string modelname)
 334 {
 335 #ifdef ALLOW_VARIABLE_LOD
 336         string s;
 337
 338         // FIXME: this only supports 3-letter extensions
 339         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 340         if(fexists(s))
 341         {
 342                 precache_model(s);
 343                 setmodel(e, s); // players have high precision
 344                 self.modelindex_lod1 = self.modelindex;
 345         }
 346         else
 347                 self.modelindex_lod1 = -1;
 348
 349         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 350         if(fexists(s))
 351         {
 352                 precache_model(s);
 353                 setmodel(e, s); // players have high precision
 354                 self.modelindex_lod2 = self.modelindex;
 355         }
 356         else
 357                 self.modelindex_lod2 = -1;
 358
 359         precache_model(modelname);
 360         setmodel(e, modelname); // players have high precision
 361         self.modelindex_lod0 = self.modelindex;
 362
 363         if(self.modelindex_lod1 < 0)
 364                 self.modelindex_lod1 = self.modelindex;
 365
 366         if(self.modelindex_lod2 < 0)
 367                 self.modelindex_lod2 = self.modelindex;
 368 #else
 369         precache_model(modelname);
 370         setmodel(e, modelname); // players have high precision
 371 #endif
 372         player_setupanimsformodel();
 373         UpdatePlayerSounds();
 374 }
 375
 376 /*
 377 =============
 378 PutObserverInServer
 379
 380 putting a client as observer in the server
 381 =============
 382 */
 383 void PutObserverInServer (void)
 384 {
 385         entity  spot;
 386
 387         race_PreSpawnObserver();
 388
 389         spot = SelectSpawnPoint (TRUE);
 390         if(!spot)
 391                 error("No spawnpoints for observers?!?\n");
 392         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 393
 394         if(clienttype(self) == CLIENTTYPE_REAL)
 395         {
 396                 msg_entity = self;
 397                 WriteByte(MSG_ONE, SVC_SETVIEW);
 398                 WriteEntity(MSG_ONE, self);
 399         }
 400
 401         DropAllRunes(self);
 402         kh_Key_DropAll(self, TRUE);
 403
 404         Portal_ClearAll(self);
 405
 406         if(self.flagcarried)
 407                 DropFlag(self.flagcarried);
 408
 409         WaypointSprite_PlayerDead();
 410
 411         if(self.killcount != -666)
 412         {
 413                 if(g_lms)
 414                 {
 415                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 416                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 417                         else
 418                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 419                 }
 420                 else
 421                         bprint ("^4", self.netname, "^4 is spectating now\n");
 422         }
 423
 424         PlayerScore_Clear(self); // clear scores when needed
 425
 426         self.spectatortime = time;
 427
 428         self.classname = "observer";
 429         self.health = -666;
 430         self.takedamage = DAMAGE_NO;
 431         self.solid = SOLID_NOT;
 432         self.movetype = MOVETYPE_NOCLIP;
 433         self.flags = FL_CLIENT | FL_NOTARGET;
 434         self.armorvalue = 666;
 435         self.effects = 0;
 436         self.armorvalue = cvar("g_balance_armor_start");
 437         self.pauserotarmor_finished = 0;
 438         self.pauserothealth_finished = 0;
 439         self.pauseregen_finished = 0;
 440         self.damageforcescale = 0;
 441         self.death_time = 0;
 442         self.dead_frame = 0;
 443         self.alpha = 0;
 444         self.scale = 0;
 445         self.fade_time = 0;
 446         self.pain_frame = 0;
 447         self.pain_finished = 0;
 448         self.strength_finished = 0;
 449         self.invincible_finished = 0;
 450         self.pushltime = 0;
 451         self.think = SUB_Null;
 452         self.nextthink = 0;
 453         self.hook_time = 0;
 454         self.runes = 0;
 455         self.deadflag = DEAD_NO;
 456         self.angles = spot.angles;
 457         self.angles_z = 0;
 458         self.fixangle = TRUE;
 459         self.crouch = FALSE;
 460
 461         self.view_ofs = PL_VIEW_OFS;
 462         setorigin (self, spot.origin);
 463         setsize (self, '0 0 0', '0 0 0');
 464         self.oldorigin = self.origin;
 465         self.items = 0;
 466         self.weapons = 0;
 467         self.model = "";
 468         self.modelindex = 0;
 469         self.weapon = 0;
 470         self.weaponmodel = "";
 471         self.weaponentity = world;
 472         self.killcount = -666;
 473         self.velocity = '0 0 0';
 474         self.avelocity = '0 0 0';
 475         self.punchangle = '0 0 0';
 476         self.punchvector = '0 0 0';
 477         self.oldvelocity = self.velocity;
 478         self.customizeentityforclient = Client_customizeentityforclient;
 479         self.wantswelcomemessage = 1;
 480
 481         if(g_arena)
 482         {
 483                 if(self.version_mismatch)
 484                 {
 485                         Spawnqueue_Unmark(self);
 486                         Spawnqueue_Remove(self);
 487                 }
 488                 else
 489                 {
 490                         Spawnqueue_Insert(self);
 491                 }
 492         }
 493         else if(g_lms)
 494         {
 495                 // Only if the player cannot play at all
 496                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 497                         self.frags = -666;
 498                 else
 499                         self.frags = -667;
 500         }
 501         else
 502                 self.frags = -666;
 503 }
 504
 505 float RestrictSkin(float s)
 506 {
 507         if(!teams_matter)
 508                 return s;
 509         if(s == 6)
 510                 return 6;
 511         return mod(s, 3);
 512 }
 513
 514 void FixPlayermodel()
 515 {
 516         local string defaultmodel;
 517         local float defaultskin;
 518         local vector m1, m2;
 519
 520         defaultmodel = "";
 521
 522         if(cvar("sv_defaultcharacter") == 1) {
 523                 defaultskin = 0;
 524
 525                 if(teams_matter)
 526                 {
 527                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 528                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 529                 }
 530
 531                 if(defaultmodel == "")
 532                 {
 533                         defaultmodel = cvar_string("sv_defaultplayermodel");
 534                         defaultskin = cvar("sv_defaultplayerskin");
 535                 }
 536         }
 537
 538         if(defaultmodel != "")
 539         {
 540                 if (defaultmodel != self.model)
 541                 {
 542                         m1 = self.mins;
 543                         m2 = self.maxs;
 544                         setmodel_lod (self, defaultmodel);
 545                         setsize (self, m1, m2);
 546                 }
 547
 548                 self.skin = defaultskin;
 549         } else {
 550                 if (self.playermodel != self.model)
 551                 {
 552                         self.playermodel = CheckPlayerModel(self.playermodel);
 553                         m1 = self.mins;
 554                         m2 = self.maxs;
 555                         setmodel_lod (self, self.playermodel);
 556                         setsize (self, m1, m2);
 557                 }
 558
 559                 self.skin = RestrictSkin(stof(self.playerskin));
 560         }
 561
 562         if(!teams_matter)
 563                 if(strlen(cvar_string("sv_defaultplayercolors")))
 564                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 565                                 setcolor(self, cvar("sv_defaultplayercolors"));
 566 }
 567
 568 /*
 569 =============
 570 PutClientInServer
 571
 572 Called when a client spawns in the server
 573 =============
 574 */
 575 //void() ctf_playerchanged;
 576 void PutClientInServer (void)
 577 {
 578         if(clienttype(self) == CLIENTTYPE_BOT)
 579         {
 580                 self.classname = "player";
 581         }
 582         else if(clienttype(self) == CLIENTTYPE_REAL)
 583         {
 584                 msg_entity = self;
 585                 WriteByte(MSG_ONE, SVC_SETVIEW);
 586                 WriteEntity(MSG_ONE, self);
 587         }
 588
 589         msg_entity = self;
 590         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 591         WriteByte(MSG_ONE, TE_CSQC_WARMUP);
 592         WriteByte(MSG_ONE, !tourneyInMatchStage);
 593
 594         // player is dead and becomes observer
 595         // FIXME fix LMS scoring for new system
 596         if(g_lms)
 597         {
 598                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 599                         self.classname = "observer";
 600         }
 601
 602         if(g_arena)
 603         if(!self.spawned)
 604                 self.classname = "observer";
 605
 606         if(self.classname == "player") {
 607                 entity  spot;
 608
 609                 race_PreSpawn();
 610
 611                 spot = SelectSpawnPoint (FALSE);
 612                 if(!spot)
 613                 {
 614                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 615                         return; // spawn failed
 616                 }
 617
 618                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 619
 620                 self.classname = "player";
 621                 self.iscreature = TRUE;
 622                 self.movetype = MOVETYPE_WALK;
 623                 self.solid = SOLID_SLIDEBOX;
 624                 if(independent_players)
 625                         MAKE_INDEPENDENT_PLAYER(self);
 626                 self.flags = FL_CLIENT;
 627                 self.takedamage = DAMAGE_AIM;
 628                 if(g_minstagib)
 629                         self.effects = EF_FULLBRIGHT;
 630                 else
 631                         self.effects = 0;
 632                 self.air_finished = time + 12;
 633                 self.dmg = 2;
 634
 635                 self.ammo_shells = start_ammo_shells;
 636                 self.ammo_nails = start_ammo_nails;
 637                 self.ammo_rockets = start_ammo_rockets;
 638                 self.ammo_cells = start_ammo_cells;
 639                 self.health = start_health;
 640                 self.armorvalue = start_armorvalue;
 641                 self.items = start_items;
 642                 self.weapons = start_weapons;
 643                 self.switchweapon = start_switchweapon;
 644                 self.cnt = start_switchweapon;
 645                 self.weapon = 0;
 646                 self.jump_interval = time;
 647
 648                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 649                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 650                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 651                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 652                 //extend the pause of rotting if client was reset at the beginning of the countdown
 653                 if(!cvar("sv_ready_restart_after_countdown") && time < restart_countdown) {
 654                         self.spawnshieldtime += RESTART_COUNTDOWN;
 655                         self.pauserotarmor_finished += RESTART_COUNTDOWN;
 656                         self.pauserothealth_finished += RESTART_COUNTDOWN;
 657                         self.pauseregen_finished += RESTART_COUNTDOWN;
 658                 }
 659                 self.damageforcescale = 2;
 660                 self.death_time = 0;
 661                 self.dead_frame = 0;
 662                 self.alpha = 0;
 663                 self.scale = 0;
 664                 self.fade_time = 0;
 665                 self.pain_frame = 0;
 666                 self.pain_finished = 0;
 667                 self.strength_finished = 0;
 668                 self.invincible_finished = 0;
 669                 self.pushltime = 0;
 670                 //self.speed_finished = 0;
 671                 //self.slowmo_finished = 0;
 672                 // players have no think function
 673                 self.think = SUB_Null;
 674                 self.nextthink = 0;
 675                 self.hook_time = 0;
 676
 677                 self.runes = 0;
 678
 679                 self.deadflag = DEAD_NO;
 680
 681                 self.angles = spot.angles;
 682
 683                 self.angles_z = 0; // never spawn tilted even if the spot says to
 684                 self.fixangle = TRUE; // turn this way immediately
 685                 self.velocity = '0 0 0';
 686                 self.avelocity = '0 0 0';
 687                 self.punchangle = '0 0 0';
 688                 self.punchvector = '0 0 0';
 689                 self.oldvelocity = self.velocity;
 690
 691                 msg_entity = self;
 692                 WRITESPECTATABLE_MSG_ONE({
 693                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 694                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 695                 });
 696
 697                 self.customizeentityforclient = Client_customizeentityforclient;
 698
 699                 self.model = "";
 700                 FixPlayermodel();
 701
 702                 self.crouch = FALSE;
 703                 self.view_ofs = PL_VIEW_OFS;
 704                 setsize (self, PL_MIN, PL_MAX);
 705                 self.spawnorigin = spot.origin;
 706                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 707                 // don't reset back to last position, even if new position is stuck in solid
 708                 self.oldorigin = self.origin;
 709
 710                 if(g_arena)
 711                 {
 712                         Spawnqueue_Remove(self);
 713                         Spawnqueue_Mark(self);
 714                 }
 715
 716                 self.event_damage = PlayerDamage;
 717
 718                 self.bot_attack = TRUE;
 719
 720                 self.statdraintime = time + 5;
 721                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 722
 723                 if(self.killcount == -666) {
 724                         PlayerScore_Clear(self);
 725                         self.killcount = 0;
 726                         self.frags = 0;
 727                 }
 728
 729                 self.cnt = WEP_LASER;
 730                 self.nixnex_lastchange_id = -1;
 731
 732                 CL_SpawnWeaponentity();
 733                 self.alpha = default_player_alpha;
 734                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 735                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 736
 737                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 738                 self.lms_traveled_distance = 0;
 739                 self.speedrunning = FALSE;
 740
 741                 race_PostSpawn(spot);
 742
 743                 if(cvar("spawn_debug"))
 744                 {
 745                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 746                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 747                 }
 748
 749                 //stuffcmd(self, "chase_active 0");
 750                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 751
 752                 if (cvar("g_spawnsound"))
 753                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 754
 755                 if(g_assault) {
 756                         if(self.team == assault_attacker_team)
 757                                 centerprint(self, "You are attacking!\n");
 758                         else
 759                                 centerprint(self, "You are defending!\n");
 760                 }
 761
 762         } else if(self.classname == "observer") {
 763                 PutObserverInServer ();
 764         }
 765
 766         //if(g_ctf)
 767         //      ctf_playerchanged();
 768 }
 769
 770 /*
 771 =============
 772 SendCSQCInfo
 773
 774 Send whatever CSQC needs NOW and cannot wait for SendServerInfo to happen...
 775 =============
 776 */
 777 void SendCSQCInfo(void)
 778 {
 779         float i;
 780         if(clienttype(self) != CLIENTTYPE_REAL)
 781                 return;
 782         msg_entity = self;
 783         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 784         WriteByte(MSG_ONE, TE_CSQC_INIT);
 785         WriteShort(MSG_ONE, CSQC_REVISION);
 786         WriteByte(MSG_ONE, maxclients);
 787         for(i = 1; i <= 24; ++i)
 788                 WriteByte(MSG_ONE, (get_weaponinfo(i)).impulse + 1);
 789 }
 790
 791 /*
 792 =============
 793 SetNewParms
 794 =============
 795 */
 796 void SetNewParms (void)
 797 {
 798         // initialize parms for a new player
 799         parm1 = -(86400 * 366);
 800 }
 801
 802 /*
 803 =============
 804 SetChangeParms
 805 =============
 806 */
 807 void SetChangeParms (void)
 808 {
 809         // save parms for level change
 810         parm1 = self.parm_idlesince - time;
 811 }
 812
 813 /*
 814 =============
 815 DecodeLevelParms
 816 =============
 817 */
 818 void DecodeLevelParms (void)
 819 {
 820         // load parms
 821         self.parm_idlesince = parm1;
 822         if(self.parm_idlesince == -(86400 * 366))
 823                 self.parm_idlesince = time;
 824 }
 825
 826 /*
 827 =============
 828 ClientKill
 829
 830 Called when a client types 'kill' in the console
 831 =============
 832 */
 833
 834 void ClientKill_Now_TeamChange()
 835 {
 836         if(self.killindicator_teamchange == -1)
 837         {
 838                 self.team = -1;
 839                 JoinBestTeam( self, FALSE, FALSE );
 840         }
 841         else
 842         {
 843                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 844         }
 845 }
 846
 847 void ClientKill_Now()
 848 {
 849         if(self.killindicator_teamchange)
 850                 ClientKill_Now_TeamChange();
 851
 852         // in any case:
 853         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 854
 855         if(self.killindicator)
 856         {
 857                 dprint("Cleaned up after a leaked kill indicator.\n");
 858                 remove(self.killindicator);
 859                 self.killindicator = world;
 860         }
 861 }
 862 void KillIndicator_Think()
 863 {
 864         if (!self.owner.modelindex)
 865         {
 866                 self.owner.killindicator = world;
 867                 remove(self);
 868                 return;
 869         }
 870
 871         if(self.cnt <= 0)
 872         {
 873                 self = self.owner;
 874                 ClientKill_Now(); // no oldself needed
 875                 return;
 876         }
 877         else
 878         {
 879                 if(self.cnt <= 10)
 880                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 881                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 882                 {
 883                         if(self.cnt <= 10)
 884                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 885                         if(self.owner.killindicator_teamchange)
 886                         {
 887                                 if(self.owner.killindicator_teamchange == -1)
 888                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 889                                 else
 890                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 891                         }
 892                         else
 893                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 894                 }
 895                 self.nextthink = time + 1;
 896                 self.cnt -= 1;
 897         }
 898 }
 899
 900 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 901 {
 902         float killtime;
 903         entity e;
 904         killtime = cvar("g_balance_kill_delay");
 905
 906         self.killindicator_teamchange = targetteam;
 907
 908         if(!self.killindicator)
 909         {
 910                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 911                 {
 912                         ClientKill_Now();
 913                 }
 914                 else
 915                 {
 916                         self.killindicator = spawn();
 917                         self.killindicator.owner = self;
 918                         self.killindicator.scale = 0.5;
 919                         setattachment(self.killindicator, self, "");
 920                         setorigin(self.killindicator, '0 0 52');
 921                         self.killindicator.think = KillIndicator_Think;
 922                         self.killindicator.nextthink = time + (self.lip) * 0.05;
 923                         self.killindicator.cnt = ceil(killtime);
 924                         self.killindicator.count = bound(0, ceil(killtime), 10);
 925                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 926
 927                         for(e = world; (e = find(e, classname, "body")) != world; )
 928                         {
 929                                 if(e.enemy != self)
 930                                         continue;
 931                                 e.killindicator = spawn();
 932                                 e.killindicator.owner = e;
 933                                 e.killindicator.scale = 0.5;
 934                                 setattachment(e.killindicator, e, "");
 935                                 setorigin(e.killindicator, '0 0 52');
 936                                 e.killindicator.think = KillIndicator_Think;
 937                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
 938                                 e.killindicator.cnt = ceil(killtime);
 939                         }
 940                         self.lip = 0;
 941                 }
 942         }
 943         if(self.killindicator)
 944         {
 945                 if(targetteam)
 946                         self.killindicator.colormod = TeamColor(targetteam);
 947                 else
 948                         self.killindicator.colormod = '0 0 0';
 949         }
 950 }
 951
 952 void ClientKill (void)
 953 {
 954         ClientKill_TeamChange(0);
 955 }
 956
 957 void DoTeamChange(float destteam)
 958 {
 959         float t, c0;
 960         if(!cvar("teamplay"))
 961         {
 962                 if(destteam >= 0)
 963                         SetPlayerColors(self, destteam);
 964                 return;
 965         }
 966         if(self.classname == "player")
 967         if(destteam == -1)
 968         {
 969                 CheckAllowedTeams(self);
 970                 t = FindSmallestTeam(self, TRUE);
 971                 switch(self.team)
 972                 {
 973                         case COLOR_TEAM1: c0 = c1; break;
 974                         case COLOR_TEAM2: c0 = c2; break;
 975                         case COLOR_TEAM3: c0 = c3; break;
 976                         case COLOR_TEAM4: c0 = c4; break;
 977                         default:          c0 = 999;
 978                 }
 979                 switch(t)
 980                 {
 981                         case 1:
 982                                 if(c0 > c1)
 983                                         destteam = COLOR_TEAM1;
 984                                 break;
 985                         case 2:
 986                                 if(c0 > c2)
 987                                         destteam = COLOR_TEAM2;
 988                                 break;
 989                         case 3:
 990                                 if(c0 > c3)
 991                                         destteam = COLOR_TEAM3;
 992                                 break;
 993                         case 4:
 994                                 if(c0 > c4)
 995                                         destteam = COLOR_TEAM4;
 996                                 break;
 997                 }
 998                 if(destteam == -1)
 999                         return;
1000         }
1001         if(destteam == self.team && !self.killindicator)
1002                 return;
1003         ClientKill_TeamChange(destteam);
1004 }
1005
1006 void FixClientCvars(entity e)
1007 {
1008         // send prediction settings to the client
1009         stuffcmd(e, "\nin_bindmap 0 0\n");
1010         /*
1011          * we no longer need to stuff this. Remove this comment block if you feel
1012          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1013         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1014         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1015         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1016         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1017         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1018         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1019         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1020         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1021         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1022         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1023         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1024         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1025         stuffcmd(e, "cl_movement_edgefriction 1\n");
1026          */
1027 }
1028
1029 /*
1030 =============
1031 ClientConnect
1032
1033 Called when a client connects to the server
1034 =============
1035 */
1036 //void ctf_clientconnect();
1037 string ColoredTeamName(float t);
1038 void DecodeLevelParms (void);
1039 //void dom_player_join_team(entity pl);
1040 void ClientConnect (void)
1041 {
1042         local string s;
1043
1044         if(self.flags & FL_CLIENT)
1045         {
1046                 print("Warning: ClientConnect, but already connected!\n");
1047                 return;
1048         }
1049
1050         if(Ban_IsClientBanned(self))
1051         {
1052                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
1053                 dropclient(self);
1054                 bprint(s);
1055                 return;
1056         }
1057
1058         DecodeLevelParms();
1059
1060         self.classname = "player_joining";
1061
1062         self.flags = self.flags | FL_CLIENT;
1063         self.version_nagtime = time + 10 + random() * 10;
1064
1065         if(player_count<0)
1066         {
1067                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1068                 player_count = 0;
1069         }
1070
1071         PlayerScore_Attach(self);
1072
1073         bot_clientconnect();
1074
1075         race_PreSpawnObserver();
1076
1077         //if(g_domination)
1078         //      dom_player_join_team(self);
1079
1080         //JoinBestTeam(self, FALSE, FALSE);
1081
1082         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1083                 self.classname = "observer";
1084         } else {
1085                 self.classname = "player";
1086                 campaign_bots_may_start = 1;
1087         }
1088
1089         self.playerid = (playerid_last = playerid_last + 1);
1090         if(cvar("sv_eventlog"))
1091         {
1092                 if(clienttype(self) == CLIENTTYPE_REAL)
1093                         s = "player";
1094                 else
1095                         s = "bot";
1096                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname));
1097                 s = strcat(":team:", ftos(self.playerid), ":");
1098                 s = strcat(s, ftos(self.team));
1099                 GameLogEcho(s);
1100         }
1101         self.netname_previous = strzone(self.netname);
1102
1103         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1104
1105         bprint ("^4",self.netname);
1106         bprint ("^4 connected");
1107
1108         if(g_domination || g_ctf)
1109         {
1110                 bprint(" and joined the ");
1111                 bprint(ColoredTeamName(self.team));
1112         }
1113
1114         bprint("\n");
1115
1116         self.welcomemessage_time = 0;
1117
1118         stuffcmd(self, strcat(clientstuff, "\n"));
1119         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1120         stuffcmd(self, "cl_particles_reloadeffects\n");
1121
1122         FixClientCvars(self);
1123
1124         // spawnfunc_waypoint sprites
1125         WaypointSprite_InitClient(self);
1126
1127         // Wazat's grappling hook
1128         SetGrappleHookBindings();
1129
1130         // get autoswitch state from player when he toggles it
1131         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1132
1133         // get version info from player
1134         stuffcmd(self, "cmd clientversion $gameversion\n");
1135
1136         // get other cvars from player
1137         GetCvars(0);
1138
1139         // set cvar for team scoreboard
1140         if (teams_matter)
1141         {
1142                 local float t;
1143                 t = cvar("teamplay");
1144                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1145                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1146         }
1147         else
1148                 stuffcmd(self, "set teamplay 0\n");
1149
1150         // notify about available teams
1151         if(teamplay)
1152         {
1153                 CheckAllowedTeams(self);
1154                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1155                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1156         }
1157         else
1158                 stuffcmd(self, "set _teams_available 0\n");
1159
1160         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1161
1162         if(g_arena)
1163         {
1164                 self.classname = "observer";
1165                 Spawnqueue_Insert(self);
1166         }
1167         /*else if(g_ctf)
1168         {
1169                 ctf_clientconnect();
1170         }*/
1171
1172         if(entcs_start)
1173                 attach_entcs();
1174
1175         bot_relinkplayerlist();
1176
1177         self.spectatortime = time;
1178         if(blockSpectators)
1179         {
1180                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1181         }
1182
1183         self.jointime = time;
1184         self.allowedTimeouts = cvar("sv_timeout_number");
1185
1186         if(clienttype(self) == CLIENTTYPE_REAL)
1187         {
1188                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1189                 SendCSQCInfo();
1190                 msg_entity = self;
1191                 if(mapvote_initialized && !cvar("g_maplist_textonly"))
1192                 {
1193                         MapVote_SendData(MSG_ONE);
1194                         MapVote_UpdateData(MSG_ONE);
1195                 }
1196                 ScoreInfo_Write(MSG_ONE);
1197         }
1198
1199         if(g_lms)
1200         {
1201                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1202                 {
1203                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1204                         self.frags = -666; // FIXME do we still need this?
1205                 }
1206         }
1207 }
1208
1209 /*
1210 =============
1211 ClientDisconnect
1212
1213 Called when a client disconnects from the server
1214 =============
1215 */
1216 void(entity e) DropFlag;
1217 .entity chatbubbleentity;
1218 .entity teambubbleentity;
1219 void ReadyCount();
1220 //void() ctf_clientdisconnect;
1221 void ClientDisconnect (void)
1222 {
1223         float save;
1224
1225         if not(self.flags & FL_CLIENT)
1226         {
1227                 print("Warning: ClientDisconnect without ClientConnect\n");
1228                 return;
1229         }
1230
1231         bot_clientdisconnect();
1232
1233         if(entcs_start)
1234                 detach_entcs();
1235
1236         if(cvar("sv_eventlog"))
1237                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1238         bprint ("^4",self.netname);
1239         bprint ("^4 disconnected\n");
1240
1241         if (self.chatbubbleentity)
1242         {
1243                 remove (self.chatbubbleentity);
1244                 self.chatbubbleentity = world;
1245         }
1246
1247         if (self.teambubbleentity)
1248         {
1249                 remove (self.teambubbleentity);
1250                 self.teambubbleentity = world;
1251         }
1252
1253         if (self.killindicator)
1254         {
1255                 remove (self.killindicator);
1256                 self.killindicator = world;
1257         }
1258
1259         WaypointSprite_PlayerGone();
1260
1261         DropAllRunes(self);
1262         kh_Key_DropAll(self, TRUE);
1263
1264         Portal_ClearAll(self);
1265
1266         if(self.flagcarried)
1267                 DropFlag(self.flagcarried);
1268
1269         save = self.flags;
1270         self.flags = self.flags - (self.flags & FL_CLIENT);
1271         bot_relinkplayerlist();
1272         self.flags = save;
1273
1274         // remove laserdot
1275         if(self.weaponentity)
1276                 if(self.weaponentity.lasertarget)
1277                         remove(self.weaponentity.lasertarget);
1278
1279         if(g_arena)
1280         {
1281                 Spawnqueue_Unmark(self);
1282                 Spawnqueue_Remove(self);
1283         }
1284         /*if(g_ctf)
1285         {
1286                 ctf_clientdisconnect();
1287         }
1288         */
1289
1290         PlayerScore_Detach(self);
1291
1292         if(self.netname_previous)
1293                 strunzone(self.netname_previous);
1294
1295         ClearPlayerSounds();
1296
1297         // free cvars
1298         GetCvars(-1);
1299         self.playerid = 0;
1300
1301         ReadyCount();
1302 }
1303
1304 .float BUTTON_CHAT;
1305 void ChatBubbleThink()
1306 {
1307         self.nextthink = time;
1308         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1309         {
1310                 self.owner.chatbubbleentity = world;
1311                 remove(self);
1312                 return;
1313         }
1314         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1315         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1316                 self.model = self.mdl;
1317         else
1318                 self.model = "";
1319 };
1320
1321 void UpdateChatBubble()
1322 {
1323         if (!self.modelindex)
1324                 return;
1325         // spawn a chatbubble entity if needed
1326         if (!self.chatbubbleentity)
1327         {
1328                 self.chatbubbleentity = spawn();
1329                 self.chatbubbleentity.owner = self;
1330                 self.chatbubbleentity.exteriormodeltoclient = self;
1331                 self.chatbubbleentity.think = ChatBubbleThink;
1332                 self.chatbubbleentity.nextthink = time;
1333                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1334                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1335                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1336                 self.chatbubbleentity.model = "";
1337                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1338         }
1339 }
1340
1341
1342 void TeamBubbleThink()
1343 {
1344         self.nextthink = time;
1345         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1346         {
1347                 self.owner.teambubbleentity = world;
1348                 remove(self);
1349                 return;
1350         }
1351 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1352         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1353                 self.model = "";
1354         else
1355                 self.model = self.mdl;
1356
1357 };
1358
1359 float TeamBubble_customizeentityforclient()
1360 {
1361         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1362 }
1363
1364 void UpdateTeamBubble()
1365 {
1366         if (!self.modelindex || !cvar("teamplay"))
1367                 return;
1368         // spawn a teambubble entity if needed
1369         if (!self.teambubbleentity && cvar("teamplay"))
1370         {
1371                 self.teambubbleentity = spawn();
1372                 self.teambubbleentity.owner = self;
1373                 self.teambubbleentity.exteriormodeltoclient = self;
1374                 self.teambubbleentity.think = TeamBubbleThink;
1375                 self.teambubbleentity.nextthink = time;
1376                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1377 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1378                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1379                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1380                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1381                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1382                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1383                 self.teambubbleentity.effects = EF_LOWPRECISION;
1384         }
1385 }
1386
1387 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1388 // added to the model skins
1389 /*void UpdateColorModHack()
1390 {
1391         local float c;
1392         c = self.clientcolors & 15;
1393         // LordHavoc: only bothering to support white, green, red, yellow, blue
1394              if (teamplay == 0) self.colormod = '0 0 0';
1395         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1396         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1397         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1398         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1399         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1400         else self.colormod = '1 1 1';
1401 };*/
1402
1403 void respawn(void)
1404 {
1405         CopyBody(1);
1406         self.effects |= EF_NODRAW; // prevent another CopyBody
1407         PutClientInServer();
1408 }
1409
1410 /**
1411  * When sv_timeout is used this function returs strings like
1412  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1413  * Called by centerprint functions
1414  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1415  */
1416 string getTimeoutText(float addOneSecond) {
1417         if (!cvar("sv_timeout") || !timeoutStatus)
1418                 return "";
1419
1420         local string retStr;
1421         if (timeoutStatus == 1) {
1422                 if (addOneSecond == 1) {
1423                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1424                 }
1425                 else {
1426                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1427                 }
1428                 return retStr;
1429         }
1430         else if (timeoutStatus == 2) {
1431                 if (addOneSecond) {
1432                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1433                         //don't show messages like "Timeout ends in 0 seconds"...
1434                         if ((remainingTimeoutTime + 1) > 0)
1435                                 return retStr;
1436                         else
1437                                 return "";
1438                 }
1439                 else {
1440                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1441                         //don't show messages like "Timeout ends in 0 seconds"...
1442                         if (remainingTimeoutTime > 0)
1443                                 return retStr;
1444                         else
1445                                 return "";
1446                 }
1447         }
1448         else return "";
1449 }
1450
1451 void player_powerups (void)
1452 {
1453         if (g_minstagib)
1454         {
1455                 if (self.items & IT_STRENGTH)
1456                 {
1457                         if (time > self.strength_finished)
1458                         {
1459                                 if (g_minstagib_invis_alpha > 0)
1460                                 {
1461                                         self.alpha = default_player_alpha;
1462                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1463                                         self.effects = self.effects | EF_FULLBRIGHT;
1464                                 }
1465                                 else
1466                                 {
1467                                         self.effects -= self.effects & EF_NODRAW;
1468                                 }
1469                                 self.items = self.items - (self.items & IT_STRENGTH);
1470                                 sprint(self, "^3Invisibility has worn off\n");
1471                         }
1472                 }
1473                 else
1474                 {
1475                         if (time < self.strength_finished)
1476                         {
1477                                 if (g_minstagib_invis_alpha > 0)
1478                                 {
1479                                         self.alpha = g_minstagib_invis_alpha;
1480                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1481                                         self.effects -= self.effects & EF_FULLBRIGHT;
1482                                 }
1483                                 else
1484                                 {
1485                                         self.effects = self.effects | EF_NODRAW;
1486                                 }
1487                                 self.items = self.items | IT_STRENGTH;
1488                                 sprint(self, "^3You are invisible\n");
1489                         }
1490                 }
1491
1492                 if (self.items & IT_INVINCIBLE)
1493                 {
1494                         if (time > self.invincible_finished)
1495                         {
1496                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1497                                 sprint(self, "^3Speed has worn off\n");
1498                         }
1499                 }
1500                 else
1501                 {
1502                         if (time < self.invincible_finished)
1503                         {
1504                                 self.items = self.items | IT_INVINCIBLE;
1505                                 sprint(self, "^3You are on speed\n");
1506                         }
1507                 }
1508                 return;
1509         }
1510
1511         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1512         if (self.items & IT_STRENGTH)
1513         {
1514                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1515                 if (time > self.strength_finished)
1516                 {
1517                         self.items = self.items - (self.items & IT_STRENGTH);
1518                         sprint(self, "^3Strength has worn off\n");
1519                 }
1520         }
1521         else
1522         {
1523                 if (time < self.strength_finished)
1524                 {
1525                         self.items = self.items | IT_STRENGTH;
1526                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1527                 }
1528         }
1529         if (self.items & IT_INVINCIBLE)
1530         {
1531                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1532                 if (time > self.invincible_finished)
1533                 {
1534                         self.items = self.items - (self.items & IT_INVINCIBLE);
1535                         sprint(self, "^3Shield has worn off\n");
1536                 }
1537         }
1538         else
1539         {
1540                 if (time < self.invincible_finished)
1541                 {
1542                         self.items = self.items | IT_INVINCIBLE;
1543                         sprint(self, "^3Shield surrounds you\n");
1544                 }
1545         }
1546
1547         if (cvar("g_fullbrightplayers"))
1548                 self.effects = self.effects | EF_FULLBRIGHT;
1549
1550         // midair gamemode: damage only while in the air
1551         // if in midair mode, being on ground grants temporary invulnerability
1552         // (this is so that multishot weapon don't clear the ground flag on the
1553         // first damage in the frame, leaving the player vulnerable to the
1554         // remaining hits in the same frame)
1555         if (self.flags & FL_ONGROUND)
1556         if (g_midair)
1557                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1558
1559         if (time > restart_countdown)
1560         if (time < self.spawnshieldtime)
1561                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1562 }
1563
1564 float CalcRegen(float current, float stable, float regenfactor)
1565 {
1566         if(current > stable)
1567                 return current;
1568         else if(current > stable - 0.25) // when close enough, "snap"
1569                 return stable;
1570         else
1571                 return min(stable, current + (stable - current) * regenfactor * frametime);
1572 }
1573
1574 void player_regen (void)
1575 {
1576         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1577         maxh = cvar("g_balance_health_stable");
1578         maxa = cvar("g_balance_armor_stable");
1579         limith = cvar("g_balance_health_limit");
1580         limita = cvar("g_balance_armor_limit");
1581
1582         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1583                 return;
1584
1585         max_mod = regen_mod = rot_mod = limit_mod = 1;
1586
1587         if (self.runes & RUNE_REGEN)
1588         {
1589                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1590                 {
1591                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1592                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1593                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1594                 }
1595                 else
1596                 {
1597                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1598                         max_mod = cvar("g_balance_rune_regen_hpmod");
1599                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1600                 }
1601         }
1602         else if (self.runes & CURSE_VENOM)
1603         {
1604                 max_mod = cvar("g_balance_curse_venom_hpmod");
1605                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1606                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1607                 else
1608                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1609                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1610                 //if (!self.runes & RUNE_REGEN)
1611                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1612         }
1613         maxh = maxh * max_mod;
1614         //maxa = maxa * max_mod;
1615         limith = limith * limit_mod;
1616         limita = limita * limit_mod;
1617
1618         if (self.armorvalue > maxa)
1619         {
1620                 if (time > self.pauserotarmor_finished)
1621                 {
1622                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1623                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1624                 }
1625         }
1626         else if (self.armorvalue < maxa)
1627         {
1628                 if (time > self.pauseregen_finished)
1629                 {
1630                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1631                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1632                 }
1633         }
1634         if (self.health > maxh)
1635         {
1636                 if (time > self.pauserothealth_finished)
1637                 {
1638                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1639                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1640                 }
1641         }
1642         else if (self.health < maxh)
1643         {
1644                 if (time > self.pauseregen_finished)
1645                 {
1646                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1647                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1648                 }
1649         }
1650
1651         if (self.health > limith)
1652                 self.health = limith;
1653         if (self.armorvalue > limita)
1654                 self.armorvalue = limita;
1655
1656         // if player rotted to death...  die!
1657         if(self.health < 1)
1658                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1659 }
1660
1661 .float zoomstate;
1662 float zoomstate_set;
1663 void SetZoomState(float z)
1664 {
1665         if(z != self.zoomstate)
1666         {
1667                 msg_entity = self;
1668                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
1669                 WriteByte(MSG_ONE, TE_CSQC_ZOOMNOTIFY);
1670                 WriteByte(MSG_ONE, z);
1671                 self.zoomstate = z;
1672         }
1673         zoomstate_set = 1;
1674 }
1675
1676 /*
1677 ======================
1678 spectate mode routines
1679 ======================
1680 */
1681 void SpectateCopy(entity spectatee) {
1682         self.armortype = spectatee.armortype;
1683         self.armorvalue = spectatee.armorvalue;
1684         self.currentammo = spectatee.currentammo;
1685         self.effects = spectatee.effects;
1686         self.health = spectatee.health;
1687         self.impulse = 0;
1688         self.items = spectatee.items;
1689         self.weapons = spectatee.weapons;
1690         self.punchangle = spectatee.punchangle;
1691         self.view_ofs = spectatee.view_ofs;
1692         self.v_angle = spectatee.v_angle;
1693         self.velocity = spectatee.velocity;
1694         self.dmg_take = spectatee.dmg_take;
1695         self.dmg_save = spectatee.dmg_save;
1696         self.dmg_inflictor = spectatee.dmg_inflictor;
1697         self.angles = spectatee.v_angle;
1698         self.fixangle = TRUE;
1699         setorigin(self, spectatee.origin);
1700         setsize(self, spectatee.mins, spectatee.maxs);
1701         SetZoomState(spectatee.zoomstate);
1702 }
1703
1704 float SpectateUpdate() {
1705         if(!self.enemy)
1706                 return 0;
1707
1708         if (self == self.enemy)
1709                 return 0;
1710
1711         if(self.enemy.flags & FL_NOTARGET)
1712                 return 0;
1713
1714         SpectateCopy(self.enemy);
1715
1716         return 1;
1717 }
1718
1719 float SpectateNext() {
1720         other = find(self.enemy, classname, "player");
1721         if (!other) {
1722                 other = find(other, classname, "player");
1723         }
1724         if (other) {
1725                 self.enemy = other;
1726         }
1727         if(self.enemy.classname == "player") {
1728                 msg_entity = self;
1729                 WriteByte(MSG_ONE, SVC_SETVIEW);
1730                 WriteEntity(MSG_ONE, self.enemy);
1731                 self.wantswelcomemessage = 1;
1732                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1733                 if(!SpectateUpdate())
1734                         PutObserverInServer();
1735                 return 1;
1736         } else {
1737                 return 0;
1738         }
1739 }
1740
1741 /*
1742 =============
1743 ShowRespawnCountdown()
1744
1745 Update a respawn countdown display.
1746 =============
1747 */
1748 void ShowRespawnCountdown()
1749 {
1750         float number;
1751         if(self.deadflag == DEAD_NO) // just respawned?
1752                 return;
1753         else
1754         {
1755                 number = ceil(self.death_time - time);
1756                 if(number <= 0)
1757                         return;
1758                 if(number <= self.respawn_countdown)
1759                 {
1760                         self.respawn_countdown = number - 1;
1761                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1762                                 announce(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1763                 }
1764         }
1765 }
1766
1767 void LeaveSpectatorMode()
1768 {
1769         if(isJoinAllowed()) {
1770                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1771                         self.classname = "player";
1772                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1773                                 JoinBestTeam(self, FALSE, TRUE);
1774                         if(cvar("g_campaign"))
1775                                 campaign_bots_may_start = 1;
1776                         PutClientInServer();
1777                         if(!(self.flags & FL_NOTARGET))
1778                                 bprint ("^4", self.netname, "^4 is playing now\n");
1779                         centerprint(self,"");
1780                         return;
1781                 } else {
1782                         stuffcmd(self,"menu_showteamselect\n");
1783                         return;
1784                 }
1785         }
1786         else {
1787                 //player may not join because of g_maxplayers is set
1788                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1789         }
1790 }
1791
1792 /**
1793  * Determines whether the player is allowed to join. This depends on cvar
1794  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1795  * it checks whether the number of currently playing players exceeds g_maxplayers.
1796  * @return bool TRUE if the player is allowed to join, false otherwise
1797  */
1798 float isJoinAllowed() {
1799         if (!cvar("g_maxplayers"))
1800                 return TRUE;
1801
1802         local entity e;
1803         local float currentlyPlaying;
1804         FOR_EACH_REALPLAYER(e) {
1805                 if(e.classname == "player")
1806                         currentlyPlaying += 1;
1807         }
1808         if(currentlyPlaying < cvar("g_maxplayers"))
1809                 return TRUE;
1810
1811         return FALSE;
1812 }
1813
1814 /**
1815  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1816  * g_maxplayers_spectator_blocktime seconds
1817  */
1818 void checkSpectatorBlock() {
1819         if(self.classname == "spectator" || self.classname == "observer") {
1820                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1821                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1822                         dropclient(self);
1823                 }
1824         }
1825 }
1826
1827 float vercmp_recursive(string v1, string v2)
1828 {
1829         float dot1, dot2;
1830         string s1, s2;
1831         float r;
1832
1833         dot1 = strstrofs(v1, ".", 0);
1834         dot2 = strstrofs(v2, ".", 0);
1835         if(dot1 == -1)
1836                 s1 = v1;
1837         else
1838                 s1 = substring(v1, 0, dot1);
1839         if(dot2 == -1)
1840                 s2 = v2;
1841         else
1842                 s2 = substring(v2, 0, dot2);
1843
1844         r = stof(s1) - stof(s2);
1845         if(r != 0)
1846                 return r;
1847
1848         r = strcasecmp(s1, s2);
1849         if(r != 0)
1850                 return r;
1851
1852         if(dot1 == -1)
1853                 if(dot2 == -1)
1854                         return 0;
1855                 else
1856                         return -1;
1857         else
1858                 if(dot2 == -1)
1859                         return 1;
1860                 else
1861                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1862 }
1863
1864 float vercmp(string v1, string v2)
1865 {
1866         if(strcasecmp(v1, v2) == 0) // early out check
1867                 return 0;
1868         return vercmp_recursive(v1, v2);
1869 }
1870
1871 void ObserverThink()
1872 {
1873         if (self.flags & FL_JUMPRELEASED) {
1874                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1875                         self.welcomemessage_time = 0;
1876                         self.flags = self.flags - FL_JUMPRELEASED;
1877                         LeaveSpectatorMode();
1878                         return;
1879                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
1880                         self.welcomemessage_time = 0;
1881                         self.flags = self.flags - FL_JUMPRELEASED;
1882                         if(SpectateNext() == 1) {
1883                                 self.classname = "spectator";
1884                         }
1885                 }
1886         } else {
1887                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
1888                         self.flags = self.flags | FL_JUMPRELEASED;
1889                 }
1890         }
1891         if(self.BUTTON_ZOOM)
1892                 self.wantswelcomemessage = 0;
1893         if(self.wantswelcomemessage)
1894                 PrintWelcomeMessage(self);
1895 }
1896
1897 void SpectatorThink()
1898 {
1899         if (self.flags & FL_JUMPRELEASED) {
1900                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1901                         self.welcomemessage_time = 0;
1902                         self.flags = self.flags - FL_JUMPRELEASED;
1903                         LeaveSpectatorMode();
1904                         return;
1905                 } else if(self.BUTTON_ATCK) {
1906                         self.welcomemessage_time = 0;
1907                         self.flags = self.flags - FL_JUMPRELEASED;
1908                         if(SpectateNext() == 1) {
1909                                 self.classname = "spectator";
1910                         } else {
1911                                 self.classname = "observer";
1912                                 PutClientInServer();
1913                         }
1914                 } else if (self.BUTTON_ATCK2) {
1915                         self.welcomemessage_time = 0;
1916                         self.flags = self.flags - FL_JUMPRELEASED;
1917                         self.classname = "observer";
1918                         PutClientInServer();
1919                 } else {
1920                         if(!SpectateUpdate())
1921                                 PutObserverInServer();
1922                 }
1923         } else {
1924                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
1925                         self.flags = self.flags | FL_JUMPRELEASED;
1926                 }
1927         }
1928         if(self.BUTTON_ZOOM)
1929                 self.wantswelcomemessage = 0;
1930         if(self.wantswelcomemessage)
1931                 PrintWelcomeMessage(self);
1932         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1933 }
1934
1935 /*
1936 =============
1937 PlayerPreThink
1938
1939 Called every frame for each client before the physics are run
1940 =============
1941 */
1942 void() ctf_setstatus;
1943 .float vote_nagtime;
1944 .float spectatee_status;
1945 void PlayerPreThink (void)
1946 {
1947         self.stat_sys_ticrate = cvar("sys_ticrate");
1948         if(blockSpectators)
1949                 checkSpectatorBlock();
1950
1951         zoomstate_set = 0;
1952
1953         if(self.netname_previous != self.netname)
1954         {
1955                 if(cvar("sv_eventlog"))
1956                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
1957                 if(self.netname_previous)
1958                         strunzone(self.netname_previous);
1959                 self.netname_previous = strzone(self.netname);
1960         }
1961
1962         // version nagging
1963         if(self.version_nagtime)
1964                 if(self.cvar_g_nexuizversion)
1965                         if(time > self.version_nagtime)
1966                         {
1967                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1968                                 {
1969                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
1970                                         {
1971                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1972                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1973                                         }
1974                                         else
1975                                         {
1976                                                 float r;
1977                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
1978                                                 if(r < 0)
1979                                                 {
1980                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
1981                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
1982                                                 }
1983                                                 else if(r > 0)
1984                                                 {
1985                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1986                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1987                                                 }
1988                                         }
1989                                 }
1990                                 self.version_nagtime = 0;
1991                         }
1992
1993         // vote nagging
1994         if(self.cvar_scr_centertime)
1995                 if(time > self.vote_nagtime)
1996                 {
1997                         VoteNag();
1998                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1999                 }
2000
2001         // GOD MODE info
2002         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2003         {
2004                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2005                 self.max_armorvalue = 0;
2006         }
2007
2008         if(frametime)
2009                 antilag_record(self);
2010
2011         if(self.classname == "player") {
2012 //              if(self.netname == "Wazat")
2013 //                      bprint(self.classname, "\n");
2014
2015                 CheckRules_Player();
2016
2017                 if(self.BUTTON_INFO)
2018                         PrintWelcomeMessage(self);
2019
2020                 if(g_lms || !cvar("sv_spectate"))
2021                 if((time - self.jointime) <= cvar("welcome_message_time"))
2022                         PrintWelcomeMessage(self);
2023
2024                 if (intermission_running)
2025                 {
2026                         IntermissionThink ();   // otherwise a button could be missed between
2027                         return;                                 // the think tics
2028                 }
2029
2030                 if(self.teleport_time)
2031                 if(time > self.teleport_time)
2032                 {
2033                         self.teleport_time = 0;
2034                         self.effects = self.effects - (self.effects & EF_NODRAW);
2035                         if(self.weaponentity)
2036                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
2037                 }
2038
2039                 Nixnex_GiveCurrentWeapon();
2040
2041                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2042                         UpdateSelectedPlayer();
2043
2044                 //don't allow the player to turn around while game is paused!
2045                 if(timeoutStatus == 2) {
2046                         self.v_angle = self.lastV_angle;
2047                         self.angles = self.lastV_angle;
2048                         self.fixangle = TRUE;
2049                 }
2050
2051                 if (self.deadflag != DEAD_NO)
2052                 {
2053                         float button_pressed, force_respawn;
2054                         player_anim();
2055                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2056                         force_respawn = (g_lms || cvar("g_forced_respawn"));
2057                         if (self.deadflag == DEAD_DYING)
2058                         {
2059                                 if(force_respawn)
2060                                         self.deadflag = DEAD_RESPAWNING;
2061                                 else if(!button_pressed)
2062                                         self.deadflag = DEAD_DEAD;
2063                         }
2064                         else if (self.deadflag == DEAD_DEAD)
2065                         {
2066                                 if(button_pressed)
2067                                         self.deadflag = DEAD_RESPAWNABLE;
2068                         }
2069                         else if (self.deadflag == DEAD_RESPAWNABLE)
2070                         {
2071                                 if(!button_pressed)
2072                                         self.deadflag = DEAD_RESPAWNING;
2073                         }
2074                         else if (self.deadflag == DEAD_RESPAWNING)
2075                         {
2076                                 if(time > self.death_time)
2077                                 {
2078                                         self.death_time = time + 1; // only retry once a second
2079                                         respawn();
2080                                 }
2081                         }
2082                         ShowRespawnCountdown();
2083                         return;
2084                 }
2085
2086                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2087                 {
2088                         vector dist;
2089
2090                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2091                         dist = self.oldorigin - self.origin;
2092                         dist_z = 0;
2093                         self.lms_traveled_distance += fabs(vlen(dist));
2094
2095                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
2096                         {
2097                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2098                                 self.lms_traveled_distance = 0;
2099                         }
2100
2101                         if(time > self.lms_nextcheck)
2102                         {
2103                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2104                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2105                                 {
2106                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2107                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2108                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2109                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2110                                 }
2111                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2112                                 self.lms_traveled_distance = 0;
2113                         }
2114                 }
2115
2116                 if (self.BUTTON_CROUCH && !self.hook.state)
2117                 {
2118                         if (!self.crouch)
2119                         {
2120                                 self.crouch = TRUE;
2121                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2122                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2123                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
2124                         }
2125                 }
2126                 else
2127                 {
2128                         if (self.crouch)
2129                         {
2130                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2131                                 if (!trace_startsolid)
2132                                 {
2133                                         self.crouch = FALSE;
2134                                         self.view_ofs = PL_VIEW_OFS;
2135                                         setsize (self, PL_MIN, PL_MAX);
2136                                 }
2137                         }
2138                 }
2139
2140                 FixPlayermodel();
2141
2142                 GrapplingHookFrame();
2143
2144                 W_WeaponFrame();
2145
2146                 player_powerups();
2147                 player_regen();
2148                 player_anim();
2149
2150                 if (g_minstagib)
2151                         minstagib_ammocheck();
2152
2153                 ctf_setstatus();
2154                 kh_setstatus();
2155
2156                 //self.angles_y=self.v_angle_y + 90;   // temp
2157
2158                 //if (TetrisPreFrame()) return;
2159         } else if(gameover) {
2160                 if (intermission_running)
2161                         IntermissionThink ();   // otherwise a button could be missed between
2162                 return;
2163         } else if(self.classname == "observer") {
2164                 ObserverThink();
2165         } else if(self.classname == "spectator") {
2166                 SpectatorThink();
2167         }
2168
2169         if(!zoomstate_set)
2170                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2171
2172         float oldspectatee_status;
2173         oldspectatee_status = self.spectatee_status;
2174         if(self.classname == "spectator")
2175                 self.spectatee_status = num_for_edict(self.enemy);
2176         else if(self.classname == "observer")
2177                 self.spectatee_status = num_for_edict(self);
2178         else
2179                 self.spectatee_status = 0;
2180         if(self.spectatee_status != oldspectatee_status)
2181         {
2182                 msg_entity = self;
2183                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
2184                 WriteByte(MSG_ONE, TE_CSQC_SPECTATING);
2185                 WriteByte(MSG_ONE, self.spectatee_status);
2186                 if(g_race)
2187                         race_InitSpectator();
2188         }
2189 }
2190
2191
2192 /*
2193 =============
2194 PlayerPostThink
2195
2196 Called every frame for each client after the physics are run
2197 =============
2198 */
2199 .float idlekick_lasttimeleft;
2200 .float race_penalty;
2201 .float race_penalty_nagged;
2202 void PlayerPostThink (void)
2203 {
2204         // Savage: Check for nameless players
2205         if (strlen(self.netname) < 1) {
2206                 self.netname = "Player";
2207                 stuffcmd(self, "seta _cl_name Player\n");
2208         }
2209
2210         if(sv_maxidle)
2211         {
2212                 float timeleft;
2213                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2214                 if(timeleft <= 0)
2215                 {
2216                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2217                         announce(self, "announcer/robotic/terminated.ogg");
2218                         dropclient(self);
2219                         return;
2220                 }
2221                 else if(timeleft <= 10)
2222                 {
2223                         if(timeleft != self.idlekick_lasttimeleft)
2224                         {
2225                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2226                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".ogg"));
2227                         }
2228                 }
2229                 else
2230                 {
2231                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2232                 }
2233                 self.idlekick_lasttimeleft = timeleft;
2234         }
2235
2236         if(self.classname == "player") {
2237                 CheckRules_Player();
2238                 UpdateChatBubble();
2239                 UpdateTeamBubble();
2240                 if (self.impulse)
2241                         ImpulseCommands();
2242                 if (intermission_running)
2243                         return;         // intermission or finale
2244
2245                 //PrintWelcomeMessage(self);
2246                 //if (TetrisPostFrame()) return;
2247
2248                 // restart countdown
2249                 if (restart_countdown) {
2250                         if(time < restart_countdown) {
2251                                 if (!cvar("sv_ready_restart_after_countdown"))
2252                                 {
2253                                         if(self.movement != '0 0 0' && g_race && !g_race_qualifying)
2254                                         {
2255                                                 if(time < restart_countdown - 2)
2256                                                 {
2257                                                         if(!self.race_penalty_nagged)
2258                                                         {
2259                                                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1DO NOT MOVE DURING THE COUNTDOWN.");
2260                                                                 self.race_penalty_nagged = 1;
2261                                                         }
2262                                                 }
2263                                                 else if(!self.race_penalty)
2264                                                 {
2265                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1FIVE SECONDS PENALTY.");
2266                                                         self.race_penalty = time + 5;
2267                                                 }
2268                                         }
2269                                         self.movetype = MOVETYPE_NONE;
2270                                         self.velocity = '0 0 0';
2271                                         self.avelocity = '0 0 0';
2272                                         self.movement = '0 0 0';
2273                                 }
2274                         }
2275                         else if (time < self.race_penalty)
2276                         {
2277                                 self.movetype = MOVETYPE_NONE;
2278                                 self.velocity = '0 0 0';
2279                                 self.avelocity = '0 0 0';
2280                                 self.movement = '0 0 0';
2281                         }
2282                         else
2283                         {
2284                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2285                                 if (!cvar("sv_ready_restart_after_countdown"))
2286                                 {
2287                                         if(self.movetype == MOVETYPE_NONE)
2288                                         {
2289                                                 self.movetype = MOVETYPE_WALK;
2290                                         }
2291                                         self.race_penalty = 0;
2292                                         self.race_penalty_nagged = 0;
2293                                 }
2294                         }
2295                 }
2296
2297         } else if (self.classname == "observer") {
2298                 //do nothing
2299         } else if (self.classname == "spectator") {
2300                 //do nothing
2301         }
2302
2303         /*
2304         float i;
2305         for(i = 0; i < 1000; ++i)
2306         {
2307                 vector end;
2308                 end = self.origin + '0 0 1024' + 512 * randomvec();
2309                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2310                 if(trace_fraction < 1)
2311                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2312                 {
2313                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2314                         break;
2315                 }
2316         }
2317         */
2318
2319         Arena_Warmup();
2320 }