data/qcsrc/server/cl_client.qc

   1 // let's abuse an existing field
   2 #define SPAWNPOINT_SCORE frags
   3
   4 .float wantswelcomemessage;
   5 .string netname_previous;
   6
   7 void spawnfunc_info_player_survivor (void)
   8 {
   9         spawnfunc_info_player_deathmatch();
  10 }
  11
  12 void spawnfunc_info_player_start (void)
  13 {
  14         spawnfunc_info_player_deathmatch();
  15 }
  16
  17 void spawnfunc_info_player_deathmatch (void)
  18 {
  19         self.classname = "info_player_deathmatch";
  20         relocate_spawnpoint();
  21 }
  22
  23 void spawnpoint_use()
  24 {
  25         if(teams_matter)
  26         if(have_team_spawns)
  27         {
  28                 self.team = activator.team;
  29                 some_spawn_has_been_used = 1;
  30         }
  31 };
  32
  33 // Returns:
  34 //   -1 if a spawn can't be used
  35 //   otherwise, a weight of the spawnpoint
  36 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
  37 {
  38         float shortest, thisdist;
  39         entity player;
  40
  41         // filter out spots for the wrong team
  42         if(teamcheck)
  43         if(spot.team != teamcheck)
  44                 return -1;
  45
  46         if(race_spawns)
  47                 if(spot.target == "")
  48                         return -1;
  49
  50         // filter out spots for assault
  51         if(spot.target != "") {
  52                 local entity ent;
  53                 float good;
  54                 ent = find(world, targetname, spot.target);
  55                 while(ent) {
  56                         if(ent.classname == "target_objective")
  57                         {
  58                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  59                                         return -1;
  60                                 good = 1;
  61                         }
  62                         else if(ent.classname == "trigger_race_checkpoint")
  63                         {
  64                                 if(self.classname == "player") // spectators may spawn everywhere
  65                                 {
  66                                         if(ent.race_checkpoint != race_PreviousCheckpoint(self.race_checkpoint))
  67                                                 return -1;
  68                                         float pl;
  69                                         pl = self.race_place;
  70                                         if(pl > race_highest_place_spawn)
  71                                                 pl = 0;
  72                                         if(spot.race_place != pl)
  73                                                 return -1;
  74                                 }
  75                                 good = 1;
  76                         }
  77                         else
  78                         {
  79                         }
  80                         ent = find(ent, targetname, spot.target);
  81                 }
  82
  83                 if(!good)
  84                         return -1;
  85         }
  86
  87         player = playerlist;
  88         shortest = vlen(world.maxs - world.mins);
  89         for(player = playerlist; player; player = player.chain)
  90                 if (player != self)
  91                 {
  92                         thisdist = vlen(player.origin - spot.origin);
  93                         if (thisdist < shortest)
  94                                 shortest = thisdist;
  95                 }
  96         return shortest;
  97 }
  98
  99 float spawn_allbad;
 100 float spawn_allgood;
 101 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
 102 {
 103         local entity spot, spotlist, spotlistend;
 104         spawn_allgood = TRUE;
 105         spawn_allbad = TRUE;
 106
 107         spotlist = world;
 108         spotlistend = world;
 109
 110         for(spot = firstspot; spot; spot = spot.chain)
 111         {
 112                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
 113
 114                 if(cvar("spawn_debugview"))
 115                 {
 116                         setmodel(spot, "models/runematch/rune.mdl");
 117                         if(spot.SPAWNPOINT_SCORE < mindist)
 118                         {
 119                                 spot.colormod = '1 0 0';
 120                                 spot.scale = 1;
 121                         }
 122                         else
 123                         {
 124                                 spot.colormod = '0 1 0';
 125                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
 126                         }
 127                 }
 128
 129                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 130                 {
 131                         if(spot.SPAWNPOINT_SCORE < mindist)
 132                         {
 133                                 // too short distance
 134                                 spawn_allgood = FALSE;
 135                         }
 136                         else
 137                         {
 138                                 // perfect
 139                                 spawn_allbad = FALSE;
 140
 141                                 if(spotlistend)
 142                                         spotlistend.chain = spot;
 143                                 spotlistend = spot;
 144                                 if(!spotlist)
 145                                         spotlist = spot;
 146
 147                                 /*
 148                                 if(teamcheck)
 149                                 if(spot.team != teamcheck)
 150                                         error("invalid spawn added");
 151
 152                                 print("added ", etos(spot), "\n");
 153                                 */
 154                         }
 155                 }
 156         }
 157         if(spotlistend)
 158                 spotlistend.chain = world;
 159
 160         /*
 161                 entity e;
 162                 if(teamcheck)
 163                         for(e = spotlist; e; e = e.chain)
 164                         {
 165                                 print("seen ", etos(e), "\n");
 166                                 if(e.team != teamcheck)
 167                                         error("invalid spawn found");
 168                         }
 169         */
 170
 171         return spotlist;
 172 }
 173
 174 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 175 {
 176         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 177         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 178         local entity spot;
 179
 180         RandomSelection_Init();
 181         for(spot = firstspot; spot; spot = spot.chain)
 182                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 183
 184         return RandomSelection_chosen_ent;
 185 }
 186
 187 /*
 188 =============
 189 SelectSpawnPoint
 190
 191 Finds a point to respawn
 192 =============
 193 */
 194 entity SelectSpawnPoint (float anypoint)
 195 {
 196         local float teamcheck;
 197         local entity firstspot_new;
 198         local entity spot, firstspot, playerlist;
 199
 200         spot = find (world, classname, "testplayerstart");
 201         if (spot)
 202                 return spot;
 203
 204         teamcheck = 0;
 205
 206         if(!anypoint && have_team_spawns)
 207                 teamcheck = self.team;
 208
 209         // get the list of players
 210         playerlist = findchain(classname, "player");
 211         // get the entire list of spots
 212         firstspot = findchain(classname, "info_player_deathmatch");
 213         // filter out the bad ones
 214         // (note this returns the original list if none survived)
 215         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 216         if(!firstspot_new)
 217                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 218         firstspot = firstspot_new;
 219
 220         // there is 50/50 chance of choosing a random spot or the furthest spot
 221         // (this means that roughly every other spawn will be furthest, so you
 222         // usually won't get fragged at spawn twice in a row)
 223         if (arena_roundbased)
 224         {
 225                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 226                 if(firstspot_new)
 227                         firstspot = firstspot_new;
 228                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 229         }
 230         else if (random() > cvar("g_spawn_furthest"))
 231                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 232         else
 233                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 234
 235         if(cvar("spawn_debugview"))
 236         {
 237                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 238
 239                 entity e;
 240                 if(teamcheck)
 241                         for(e = firstspot; e; e = e.chain)
 242                                 if(e.team != teamcheck)
 243                                         error("invalid spawn found");
 244         }
 245
 246         if (!spot)
 247         {
 248                 if(cvar("spawn_debug"))
 249                         GotoNextMap();
 250                 else
 251                 {
 252                         if(some_spawn_has_been_used)
 253                                 return world; // team can't spawn any more, because of actions of other team
 254                         else
 255                                 error("Cannot find a spawn point - please fix the map!");
 256                 }
 257         }
 258
 259         return spot;
 260 }
 261
 262 /*
 263 =============
 264 CheckPlayerModel
 265
 266 Checks if the argument string can be a valid playermodel.
 267 Returns a valid one in doubt.
 268 =============
 269 */
 270 string FallbackPlayerModel = "models/player/marine.zym";
 271 string CheckPlayerModel(string plyermodel) {
 272         if(strlen(plyermodel) < 4)
 273                 return FallbackPlayerModel;
 274         if( substring(plyermodel,0,14) != "models/player/")
 275                 return FallbackPlayerModel;
 276         else if(cvar("sv_servermodelsonly"))
 277         {
 278                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 279                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 280                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 281                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 282                         return FallbackPlayerModel;
 283                 if(!fexists(plyermodel))
 284                         return FallbackPlayerModel;
 285         }
 286         return plyermodel;
 287 }
 288
 289 /*
 290 =============
 291 Client_customizeentityforclient
 292
 293 LOD reduction
 294 =============
 295 */
 296 float Client_customizeentityforclient()
 297 {
 298 #ifdef ALLOW_VARIABLE_LOD
 299         // self: me
 300         // other: the player viewing me
 301         float distance;
 302         float f;
 303
 304         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 305                 return TRUE;
 306
 307         if(other.cvar_cl_playerdetailreduction <= 0)
 308         {
 309                 if(other.cvar_cl_playerdetailreduction <= -2)
 310                         self.modelindex = self.modelindex_lod2;
 311                 else if(other.cvar_cl_playerdetailreduction <= -1)
 312                         self.modelindex = self.modelindex_lod1;
 313                 else
 314                         self.modelindex = self.modelindex_lod0;
 315         }
 316         else
 317         {
 318                 distance = vlen(self.origin - other.origin);
 319                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 320                 if(f > 10000)
 321                         self.modelindex = self.modelindex_lod2;
 322                 else if(f > 5000)
 323                         self.modelindex = self.modelindex_lod1;
 324                 else
 325                         self.modelindex = self.modelindex_lod0;
 326         }
 327 #endif
 328
 329         return TRUE;
 330 }
 331
 332 void UpdatePlayerSounds();
 333 void setmodel_lod(entity e, string modelname)
 334 {
 335 #ifdef ALLOW_VARIABLE_LOD
 336         string s;
 337
 338         // FIXME: this only supports 3-letter extensions
 339         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 340         if(fexists(s))
 341         {
 342                 precache_model(s);
 343                 setmodel(e, s); // players have high precision
 344                 self.modelindex_lod1 = self.modelindex;
 345         }
 346         else
 347                 self.modelindex_lod1 = -1;
 348
 349         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 350         if(fexists(s))
 351         {
 352                 precache_model(s);
 353                 setmodel(e, s); // players have high precision
 354                 self.modelindex_lod2 = self.modelindex;
 355         }
 356         else
 357                 self.modelindex_lod2 = -1;
 358
 359         precache_model(modelname);
 360         setmodel(e, modelname); // players have high precision
 361         self.modelindex_lod0 = self.modelindex;
 362
 363         if(self.modelindex_lod1 < 0)
 364                 self.modelindex_lod1 = self.modelindex;
 365
 366         if(self.modelindex_lod2 < 0)
 367                 self.modelindex_lod2 = self.modelindex;
 368 #else
 369         precache_model(modelname);
 370         setmodel(e, modelname); // players have high precision
 371 #endif
 372         player_setupanimsformodel();
 373         UpdatePlayerSounds();
 374 }
 375
 376 /*
 377 =============
 378 PutObserverInServer
 379
 380 putting a client as observer in the server
 381 =============
 382 */
 383 void PutObserverInServer (void)
 384 {
 385         entity  spot;
 386
 387         race_PreSpawnObserver();
 388
 389         spot = SelectSpawnPoint (TRUE);
 390         if(!spot)
 391                 error("No spawnpoints for observers?!?\n");
 392         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 393
 394         if(clienttype(self) == CLIENTTYPE_REAL)
 395         {
 396                 msg_entity = self;
 397                 WriteByte(MSG_ONE, SVC_SETVIEW);
 398                 WriteEntity(MSG_ONE, self);
 399         }
 400
 401         DropAllRunes(self);
 402         kh_Key_DropAll(self, TRUE);
 403
 404         if(self.flagcarried)
 405                 DropFlag(self.flagcarried);
 406
 407         WaypointSprite_PlayerDead();
 408
 409         if(self.killcount != -666)
 410         {
 411                 if(g_lms)
 412                 {
 413                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 414                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 415                         else
 416                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 417                 }
 418                 else
 419                         bprint ("^4", self.netname, "^4 is spectating now\n");
 420         }
 421
 422         PlayerScore_Clear(self); // clear scores when needed
 423
 424         self.spectatortime = time;
 425
 426         self.classname = "observer";
 427         self.health = -666;
 428         self.takedamage = DAMAGE_NO;
 429         self.solid = SOLID_NOT;
 430         self.movetype = MOVETYPE_NOCLIP;
 431         self.flags = FL_CLIENT | FL_NOTARGET;
 432         self.armorvalue = 666;
 433         self.effects = 0;
 434         self.armorvalue = cvar("g_balance_armor_start");
 435         self.pauserotarmor_finished = 0;
 436         self.pauserothealth_finished = 0;
 437         self.pauseregen_finished = 0;
 438         self.damageforcescale = 0;
 439         self.death_time = 0;
 440         self.dead_frame = 0;
 441         self.alpha = 0;
 442         self.scale = 0;
 443         self.fade_time = 0;
 444         self.pain_frame = 0;
 445         self.pain_finished = 0;
 446         self.strength_finished = 0;
 447         self.invincible_finished = 0;
 448         self.pushltime = 0;
 449         self.think = SUB_Null;
 450         self.nextthink = 0;
 451         self.hook_time = 0;
 452         self.runes = 0;
 453         self.deadflag = DEAD_NO;
 454         self.angles = spot.angles;
 455         self.angles_z = 0;
 456         self.fixangle = TRUE;
 457         self.crouch = FALSE;
 458
 459         self.view_ofs = PL_VIEW_OFS;
 460         setorigin (self, spot.origin);
 461         setsize (self, '0 0 0', '0 0 0');
 462         self.oldorigin = self.origin;
 463         self.items = 0;
 464         self.weapons = 0;
 465         self.model = "";
 466         self.modelindex = 0;
 467         self.weapon = 0;
 468         self.weaponmodel = "";
 469         self.weaponentity = world;
 470         self.killcount = -666;
 471         self.velocity = '0 0 0';
 472         self.avelocity = '0 0 0';
 473         self.punchangle = '0 0 0';
 474         self.punchvector = '0 0 0';
 475         self.oldvelocity = self.velocity;
 476         self.customizeentityforclient = Client_customizeentityforclient;
 477         self.wantswelcomemessage = 1;
 478
 479         if(g_arena)
 480         {
 481                 if(self.version_mismatch)
 482                 {
 483                         Spawnqueue_Unmark(self);
 484                         Spawnqueue_Remove(self);
 485                 }
 486                 else
 487                 {
 488                         Spawnqueue_Insert(self);
 489                 }
 490         }
 491         else if(g_lms)
 492         {
 493                 // Only if the player cannot play at all
 494                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 495                         self.frags = -666;
 496                 else
 497                         self.frags = -667;
 498         }
 499         else
 500                 self.frags = -666;
 501 }
 502
 503 float RestrictSkin(float s)
 504 {
 505         if(!teams_matter)
 506                 return s;
 507         if(s == 6)
 508                 return 6;
 509         return mod(s, 3);
 510 }
 511
 512 void FixPlayermodel()
 513 {
 514         local string defaultmodel;
 515         local float defaultskin;
 516         local vector m1, m2;
 517
 518         defaultmodel = "";
 519
 520         if(cvar("sv_defaultcharacter") == 1) {
 521                 defaultskin = 0;
 522
 523                 if(teams_matter)
 524                 {
 525                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 526                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 527                 }
 528
 529                 if(defaultmodel == "")
 530                 {
 531                         defaultmodel = cvar_string("sv_defaultplayermodel");
 532                         defaultskin = cvar("sv_defaultplayerskin");
 533                 }
 534         }
 535
 536         if(defaultmodel != "")
 537         {
 538                 if (defaultmodel != self.model)
 539                 {
 540                         m1 = self.mins;
 541                         m2 = self.maxs;
 542                         setmodel_lod (self, defaultmodel);
 543                         setsize (self, m1, m2);
 544                 }
 545
 546                 self.skin = defaultskin;
 547         } else {
 548                 if (self.playermodel != self.model)
 549                 {
 550                         self.playermodel = CheckPlayerModel(self.playermodel);
 551                         m1 = self.mins;
 552                         m2 = self.maxs;
 553                         setmodel_lod (self, self.playermodel);
 554                         setsize (self, m1, m2);
 555                 }
 556
 557                 self.skin = RestrictSkin(stof(self.playerskin));
 558         }
 559
 560         if(!teams_matter)
 561                 if(strlen(cvar_string("sv_defaultplayercolors")))
 562                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 563                                 setcolor(self, cvar("sv_defaultplayercolors"));
 564 }
 565
 566 /*
 567 =============
 568 PutClientInServer
 569
 570 Called when a client spawns in the server
 571 =============
 572 */
 573 //void() ctf_playerchanged;
 574 void PutClientInServer (void)
 575 {
 576         if(clienttype(self) == CLIENTTYPE_BOT)
 577         {
 578                 self.classname = "player";
 579         }
 580         else if(clienttype(self) == CLIENTTYPE_REAL)
 581         {
 582                 msg_entity = self;
 583                 WriteByte(MSG_ONE, SVC_SETVIEW);
 584                 WriteEntity(MSG_ONE, self);
 585         }
 586
 587         // player is dead and becomes observer
 588         // FIXME fix LMS scoring for new system
 589         if(g_lms)
 590         {
 591                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 592                         self.classname = "observer";
 593         }
 594
 595         if(g_arena)
 596         if(!self.spawned)
 597                 self.classname = "observer";
 598
 599         if(self.classname == "player") {
 600                 entity  spot;
 601
 602                 race_PreSpawn();
 603
 604                 spot = SelectSpawnPoint (FALSE);
 605                 if(!spot)
 606                 {
 607                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 608                         return; // spawn failed
 609                 }
 610
 611                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 612
 613                 self.classname = "player";
 614                 self.iscreature = TRUE;
 615                 self.movetype = MOVETYPE_WALK;
 616                 self.solid = SOLID_SLIDEBOX;
 617                 if(independent_players)
 618                         MAKE_INDEPENDENT_PLAYER(self);
 619                 self.flags = FL_CLIENT;
 620                 self.takedamage = DAMAGE_AIM;
 621                 if(g_minstagib)
 622                         self.effects = EF_FULLBRIGHT;
 623                 else
 624                         self.effects = 0;
 625                 self.air_finished = time + 12;
 626                 self.dmg = 2;
 627
 628                 self.ammo_shells = start_ammo_shells;
 629                 self.ammo_nails = start_ammo_nails;
 630                 self.ammo_rockets = start_ammo_rockets;
 631                 self.ammo_cells = start_ammo_cells;
 632                 self.health = start_health;
 633                 self.armorvalue = start_armorvalue;
 634                 self.items = 0;
 635                 self.weapons = start_weapons;
 636                 self.switchweapon = start_switchweapon;
 637                 self.cnt = start_switchweapon;
 638                 self.weapon = 0;
 639                 self.jump_interval = time;
 640
 641                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 642                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 643                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 644                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 645                 //extend the pause of rotting if client was reset at the beginning of the countdown
 646                 if(!cvar("sv_ready_restart_after_countdown") && time < restart_countdown) {
 647                         self.spawnshieldtime += RESTART_COUNTDOWN;
 648                         self.pauserotarmor_finished += RESTART_COUNTDOWN;
 649                         self.pauserothealth_finished += RESTART_COUNTDOWN;
 650                         self.pauseregen_finished += RESTART_COUNTDOWN;
 651                 }
 652                 self.damageforcescale = 2;
 653                 self.death_time = 0;
 654                 self.dead_frame = 0;
 655                 self.alpha = 0;
 656                 self.scale = 0;
 657                 self.fade_time = 0;
 658                 self.pain_frame = 0;
 659                 self.pain_finished = 0;
 660                 self.strength_finished = 0;
 661                 self.invincible_finished = 0;
 662                 self.pushltime = 0;
 663                 //self.speed_finished = 0;
 664                 //self.slowmo_finished = 0;
 665                 // players have no think function
 666                 self.think = SUB_Null;
 667                 self.nextthink = 0;
 668                 self.hook_time = 0;
 669
 670                 self.runes = 0;
 671
 672                 self.deadflag = DEAD_NO;
 673
 674                 self.angles = spot.angles;
 675
 676                 self.angles_z = 0; // never spawn tilted even if the spot says to
 677                 self.fixangle = TRUE; // turn this way immediately
 678                 self.velocity = '0 0 0';
 679                 self.avelocity = '0 0 0';
 680                 self.punchangle = '0 0 0';
 681                 self.punchvector = '0 0 0';
 682                 self.oldvelocity = self.velocity;
 683
 684                 msg_entity = self;
 685                 WRITESPECTATABLE_MSG_ONE({
 686                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 687                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 688                 });
 689
 690                 self.customizeentityforclient = Client_customizeentityforclient;
 691
 692                 self.model = "";
 693                 FixPlayermodel();
 694
 695                 self.crouch = FALSE;
 696                 self.view_ofs = PL_VIEW_OFS;
 697                 setsize (self, PL_MIN, PL_MAX);
 698                 self.spawnorigin = spot.origin;
 699                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 700                 // don't reset back to last position, even if new position is stuck in solid
 701                 self.oldorigin = self.origin;
 702
 703                 if(g_arena)
 704                 {
 705                         Spawnqueue_Remove(self);
 706                         Spawnqueue_Mark(self);
 707                 }
 708
 709                 self.event_damage = PlayerDamage;
 710
 711                 self.bot_attack = TRUE;
 712
 713                 self.statdraintime = time + 5;
 714                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 715
 716                 if(self.killcount == -666) {
 717                         PlayerScore_Clear(self);
 718                         self.killcount = 0;
 719                         self.frags = 0;
 720                 }
 721
 722                 self.cnt = WEP_LASER;
 723                 self.nixnex_lastchange_id = -1;
 724
 725                 CL_SpawnWeaponentity();
 726                 self.alpha = default_player_alpha;
 727                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 728                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 729
 730                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 731                 self.lms_traveled_distance = 0;
 732                 self.speedrunning = FALSE;
 733
 734                 race_PostSpawn(spot);
 735
 736                 if(cvar("spawn_debug"))
 737                 {
 738                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 739                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 740                 }
 741
 742                 //stuffcmd(self, "chase_active 0");
 743                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 744
 745                 if (cvar("g_spawnsound"))
 746                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 747
 748                 if(g_assault) {
 749                         if(self.team == assault_attacker_team)
 750                                 centerprint(self, "You are attacking!\n");
 751                         else
 752                                 centerprint(self, "You are defending!\n");
 753                 }
 754
 755         } else if(self.classname == "observer") {
 756                 PutObserverInServer ();
 757         }
 758
 759         //if(g_ctf)
 760         //      ctf_playerchanged();
 761 }
 762
 763 /*
 764 =============
 765 SendCSQCInfo
 766
 767 Send whatever CSQC needs NOW and cannot wait for SendServerInfo to happen...
 768 =============
 769 */
 770 void SendCSQCInfo(void)
 771 {
 772         if(clienttype(self) != CLIENTTYPE_REAL)
 773                 return;
 774         msg_entity = self;
 775         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 776         WriteByte(MSG_ONE, TE_CSQC_INIT);
 777         WriteShort(MSG_ONE, CSQC_REVISION);
 778         WriteByte(MSG_ONE, maxclients);
 779         WriteByte(MSG_ONE, g_minstagib);
 780 }
 781
 782 /*
 783 =============
 784 SetNewParms
 785 =============
 786 */
 787 void SetNewParms (void)
 788 {
 789         // initialize parms for a new player
 790         parm1 = -(86400 * 366);
 791 }
 792
 793 /*
 794 =============
 795 SetChangeParms
 796 =============
 797 */
 798 void SetChangeParms (void)
 799 {
 800         // save parms for level change
 801         parm1 = self.parm_idlesince - time;
 802 }
 803
 804 /*
 805 =============
 806 DecodeLevelParms
 807 =============
 808 */
 809 void DecodeLevelParms (void)
 810 {
 811         // load parms
 812         self.parm_idlesince = parm1;
 813         if(self.parm_idlesince == -(86400 * 366))
 814                 self.parm_idlesince = time;
 815 }
 816
 817 /*
 818 =============
 819 ClientKill
 820
 821 Called when a client types 'kill' in the console
 822 =============
 823 */
 824
 825 void ClientKill_Now_TeamChange()
 826 {
 827         if(self.killindicator_teamchange == -1)
 828         {
 829                 self.team = -1;
 830                 JoinBestTeam( self, FALSE, FALSE );
 831         }
 832         else
 833         {
 834                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 835         }
 836 }
 837
 838 void ClientKill_Now()
 839 {
 840         if(self.killindicator_teamchange)
 841                 ClientKill_Now_TeamChange();
 842
 843         // in any case:
 844         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 845
 846         if(self.killindicator)
 847         {
 848                 dprint("Cleaned up after a leaked kill indicator.\n");
 849                 remove(self.killindicator);
 850                 self.killindicator = world;
 851         }
 852 }
 853 void KillIndicator_Think()
 854 {
 855         if (!self.owner.modelindex)
 856         {
 857                 self.owner.killindicator = world;
 858                 remove(self);
 859                 return;
 860         }
 861
 862         if(self.cnt <= 0)
 863         {
 864                 self = self.owner;
 865                 ClientKill_Now(); // no oldself needed
 866                 return;
 867         }
 868         else
 869         {
 870                 if(self.cnt <= 10)
 871                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 872                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 873                 {
 874                         if(self.cnt <= 10)
 875                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 876                         if(self.owner.killindicator_teamchange)
 877                         {
 878                                 if(self.owner.killindicator_teamchange == -1)
 879                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 880                                 else
 881                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 882                         }
 883                         else
 884                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 885                 }
 886                 self.nextthink = time + 1;
 887                 self.cnt -= 1;
 888         }
 889 }
 890
 891 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 892 {
 893         float killtime;
 894         entity e;
 895         killtime = cvar("g_balance_kill_delay");
 896
 897         self.killindicator_teamchange = targetteam;
 898
 899         if(!self.killindicator)
 900         {
 901                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 902                 {
 903                         ClientKill_Now();
 904                 }
 905                 else
 906                 {
 907                         self.killindicator = spawn();
 908                         self.killindicator.owner = self;
 909                         self.killindicator.scale = 0.5;
 910                         setattachment(self.killindicator, self, "");
 911                         setorigin(self.killindicator, '0 0 52');
 912                         self.killindicator.think = KillIndicator_Think;
 913                         self.killindicator.nextthink = time + (self.lip) * 0.05;
 914                         self.killindicator.cnt = ceil(killtime);
 915                         self.killindicator.count = bound(0, ceil(killtime), 10);
 916                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 917
 918                         for(e = world; (e = find(e, classname, "body")) != world; )
 919                         {
 920                                 if(e.enemy != self)
 921                                         continue;
 922                                 e.killindicator = spawn();
 923                                 e.killindicator.owner = e;
 924                                 e.killindicator.scale = 0.5;
 925                                 setattachment(e.killindicator, e, "");
 926                                 setorigin(e.killindicator, '0 0 52');
 927                                 e.killindicator.think = KillIndicator_Think;
 928                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
 929                                 e.killindicator.cnt = ceil(killtime);
 930                         }
 931                         self.lip = 0;
 932                 }
 933         }
 934         if(self.killindicator)
 935         {
 936                 if(targetteam)
 937                         self.killindicator.colormod = TeamColor(targetteam);
 938                 else
 939                         self.killindicator.colormod = '0 0 0';
 940         }
 941 }
 942
 943 void ClientKill (void)
 944 {
 945         ClientKill_TeamChange(0);
 946 }
 947
 948 void DoTeamChange(float destteam)
 949 {
 950         float t, c0;
 951         if(!cvar("teamplay"))
 952         {
 953                 if(destteam >= 0)
 954                         SetPlayerColors(self, destteam);
 955                 return;
 956         }
 957         if(self.classname == "player")
 958         if(destteam == -1)
 959         {
 960                 CheckAllowedTeams(self);
 961                 t = FindSmallestTeam(self, TRUE);
 962                 switch(self.team)
 963                 {
 964                         case COLOR_TEAM1: c0 = c1; break;
 965                         case COLOR_TEAM2: c0 = c2; break;
 966                         case COLOR_TEAM3: c0 = c3; break;
 967                         case COLOR_TEAM4: c0 = c4; break;
 968                         default:          c0 = 999;
 969                 }
 970                 switch(t)
 971                 {
 972                         case 1:
 973                                 if(c0 > c1)
 974                                         destteam = COLOR_TEAM1;
 975                                 break;
 976                         case 2:
 977                                 if(c0 > c2)
 978                                         destteam = COLOR_TEAM2;
 979                                 break;
 980                         case 3:
 981                                 if(c0 > c3)
 982                                         destteam = COLOR_TEAM3;
 983                                 break;
 984                         case 4:
 985                                 if(c0 > c4)
 986                                         destteam = COLOR_TEAM4;
 987                                 break;
 988                 }
 989                 if(destteam == -1)
 990                         return;
 991         }
 992         if(destteam == self.team && !self.killindicator)
 993                 return;
 994         ClientKill_TeamChange(destteam);
 995 }
 996
 997 void FixClientCvars(entity e)
 998 {
 999         // send prediction settings to the client
1000         stuffcmd(e, "\nin_bindmap 0 0\n");
1001         /*
1002          * we no longer need to stuff this. Remove this comment block if you feel
1003          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1004         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1005         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1006         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1007         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1008         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1009         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1010         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1011         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1012         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1013         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1014         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1015         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1016         stuffcmd(e, "cl_movement_edgefriction 1\n");
1017          */
1018 }
1019
1020 /*
1021 =============
1022 ClientConnect
1023
1024 Called when a client connects to the server
1025 =============
1026 */
1027 //void ctf_clientconnect();
1028 string ColoredTeamName(float t);
1029 void DecodeLevelParms (void);
1030 //void dom_player_join_team(entity pl);
1031 void ClientConnect (void)
1032 {
1033         local string s;
1034         float wep;
1035
1036         if(self.flags & FL_CLIENT)
1037         {
1038                 print("Warning: ClientConnect, but already connected!\n");
1039                 return;
1040         }
1041
1042         if(Ban_IsClientBanned(self))
1043         {
1044                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
1045                 dropclient(self);
1046                 bprint(s);
1047                 return;
1048         }
1049
1050         DecodeLevelParms();
1051
1052         self.classname = "player_joining";
1053
1054         self.flags = self.flags | FL_CLIENT;
1055         self.version_nagtime = time + 10 + random() * 10;
1056
1057         if(player_count<0)
1058         {
1059                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1060                 player_count = 0;
1061         }
1062
1063         PlayerScore_Attach(self);
1064
1065         bot_clientconnect();
1066
1067         race_PreSpawnObserver();
1068
1069         //if(g_domination)
1070         //      dom_player_join_team(self);
1071
1072         //JoinBestTeam(self, FALSE, FALSE);
1073
1074         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1075                 self.classname = "observer";
1076         } else {
1077                 self.classname = "player";
1078                 campaign_bots_may_start = 1;
1079         }
1080
1081         self.playerid = (playerid_last = playerid_last + 1);
1082         if(cvar("sv_eventlog"))
1083         {
1084                 if(clienttype(self) == CLIENTTYPE_REAL)
1085                         s = "player";
1086                 else
1087                         s = "bot";
1088                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname));
1089                 s = strcat(":team:", ftos(self.playerid), ":");
1090                 s = strcat(s, ftos(self.team));
1091                 GameLogEcho(s);
1092         }
1093         self.netname_previous = strzone(self.netname);
1094
1095         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1096
1097         bprint ("^4",self.netname);
1098         bprint ("^4 connected");
1099
1100         if(g_domination || g_ctf)
1101         {
1102                 bprint(" and joined the ");
1103                 bprint(ColoredTeamName(self.team));
1104         }
1105
1106         bprint("\n");
1107
1108         self.welcomemessage_time = 0;
1109
1110         stuffcmd(self, strcat(clientstuff, "\n"));
1111         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1112         stuffcmd(self, "cl_particles_reloadeffects\n");
1113
1114         FixClientCvars(self);
1115
1116         // spawnfunc_waypoint sprites
1117         WaypointSprite_InitClient(self);
1118
1119         // Wazat's grappling hook
1120         SetGrappleHookBindings();
1121
1122         // get autoswitch state from player when he toggles it
1123         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1124
1125         // get version info from player
1126         stuffcmd(self, "cmd clientversion $gameversion\n");
1127
1128         // get other cvars from player
1129         GetCvars(0);
1130
1131         // set cvar for team scoreboard
1132         if (teams_matter)
1133         {
1134                 local float t;
1135                 t = cvar("teamplay");
1136                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1137                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1138         }
1139         else
1140                 stuffcmd(self, "set teamplay 0\n");
1141
1142         // notify about available teams
1143         if(teamplay)
1144         {
1145                 CheckAllowedTeams(self);
1146                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1147                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1148         }
1149         else
1150                 stuffcmd(self, "set _teams_available 0\n");
1151
1152         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1153
1154         if(g_arena)
1155         {
1156                 self.classname = "observer";
1157                 Spawnqueue_Insert(self);
1158         }
1159         /*else if(g_ctf)
1160         {
1161                 ctf_clientconnect();
1162         }*/
1163
1164         if(entcs_start)
1165                 attach_entcs();
1166
1167         bot_relinkplayerlist();
1168
1169         self.spectatortime = time;
1170         if(blockSpectators)
1171         {
1172                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1173         }
1174
1175         self.jointime = time;
1176         self.allowedTimeouts = cvar("sv_timeout_number");
1177
1178         if(clienttype(self) == CLIENTTYPE_REAL)
1179         {
1180                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1181                 SendCSQCInfo();
1182                 msg_entity = self;
1183                 if(mapvote_initialized && !cvar("g_maplist_textonly"))
1184                 {
1185                         MapVote_SendData(MSG_ONE);
1186                         MapVote_UpdateData(MSG_ONE);
1187                 }
1188                 ScoreInfo_Write(MSG_ONE);
1189         }
1190
1191         if(g_lms)
1192         {
1193                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1194                 {
1195                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1196                         self.frags = -666; // FIXME do we still need this?
1197                 }
1198         }
1199 }
1200
1201 /*
1202 =============
1203 ClientDisconnect
1204
1205 Called when a client disconnects from the server
1206 =============
1207 */
1208 void(entity e) DropFlag;
1209 .entity chatbubbleentity;
1210 .entity teambubbleentity;
1211 void ReadyCount();
1212 //void() ctf_clientdisconnect;
1213 void ClientDisconnect (void)
1214 {
1215         float save;
1216
1217         if not(self.flags & FL_CLIENT)
1218         {
1219                 print("Warning: ClientDisconnect without ClientConnect\n");
1220                 return;
1221         }
1222
1223         bot_clientdisconnect();
1224
1225         if(entcs_start)
1226                 detach_entcs();
1227
1228         if(cvar("sv_eventlog"))
1229                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1230         bprint ("^4",self.netname);
1231         bprint ("^4 disconnected\n");
1232
1233         if (self.chatbubbleentity)
1234         {
1235                 remove (self.chatbubbleentity);
1236                 self.chatbubbleentity = world;
1237         }
1238
1239         if (self.teambubbleentity)
1240         {
1241                 remove (self.teambubbleentity);
1242                 self.teambubbleentity = world;
1243         }
1244
1245         if (self.killindicator)
1246         {
1247                 remove (self.killindicator);
1248                 self.killindicator = world;
1249         }
1250
1251         WaypointSprite_PlayerGone();
1252
1253         DropAllRunes(self);
1254         kh_Key_DropAll(self, TRUE);
1255
1256         if(self.flagcarried)
1257                 DropFlag(self.flagcarried);
1258
1259         save = self.flags;
1260         self.flags = self.flags - (self.flags & FL_CLIENT);
1261         bot_relinkplayerlist();
1262         self.flags = save;
1263
1264         // remove laserdot
1265         if(self.weaponentity)
1266                 if(self.weaponentity.lasertarget)
1267                         remove(self.weaponentity.lasertarget);
1268
1269         if(g_arena)
1270         {
1271                 Spawnqueue_Unmark(self);
1272                 Spawnqueue_Remove(self);
1273         }
1274         /*if(g_ctf)
1275         {
1276                 ctf_clientdisconnect();
1277         }
1278         */
1279
1280         PlayerScore_Detach(self);
1281
1282         if(self.netname_previous)
1283                 strunzone(self.netname_previous);
1284
1285         ClearPlayerSounds();
1286
1287         // free cvars
1288         GetCvars(-1);
1289         self.playerid = 0;
1290
1291         ReadyCount();
1292 }
1293
1294 .float BUTTON_CHAT;
1295 void ChatBubbleThink()
1296 {
1297         self.nextthink = time;
1298         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1299         {
1300                 self.owner.chatbubbleentity = world;
1301                 remove(self);
1302                 return;
1303         }
1304         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1305         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1306                 self.model = self.mdl;
1307         else
1308                 self.model = "";
1309 };
1310
1311 void UpdateChatBubble()
1312 {
1313         if (!self.modelindex)
1314                 return;
1315         // spawn a chatbubble entity if needed
1316         if (!self.chatbubbleentity)
1317         {
1318                 self.chatbubbleentity = spawn();
1319                 self.chatbubbleentity.owner = self;
1320                 self.chatbubbleentity.exteriormodeltoclient = self;
1321                 self.chatbubbleentity.think = ChatBubbleThink;
1322                 self.chatbubbleentity.nextthink = time;
1323                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1324                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1325                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1326                 self.chatbubbleentity.model = "";
1327                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1328         }
1329 }
1330
1331
1332 void TeamBubbleThink()
1333 {
1334         self.nextthink = time;
1335         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1336         {
1337                 self.owner.teambubbleentity = world;
1338                 remove(self);
1339                 return;
1340         }
1341 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1342         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1343                 self.model = "";
1344         else
1345                 self.model = self.mdl;
1346
1347 };
1348
1349 float TeamBubble_customizeentityforclient()
1350 {
1351         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1352 }
1353
1354 void UpdateTeamBubble()
1355 {
1356         if (!self.modelindex || !cvar("teamplay"))
1357                 return;
1358         // spawn a teambubble entity if needed
1359         if (!self.teambubbleentity && cvar("teamplay"))
1360         {
1361                 self.teambubbleentity = spawn();
1362                 self.teambubbleentity.owner = self;
1363                 self.teambubbleentity.exteriormodeltoclient = self;
1364                 self.teambubbleentity.think = TeamBubbleThink;
1365                 self.teambubbleentity.nextthink = time;
1366                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1367 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1368                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1369                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1370                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1371                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1372                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1373                 self.teambubbleentity.effects = EF_LOWPRECISION;
1374         }
1375 }
1376
1377 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1378 // added to the model skins
1379 /*void UpdateColorModHack()
1380 {
1381         local float c;
1382         c = self.clientcolors & 15;
1383         // LordHavoc: only bothering to support white, green, red, yellow, blue
1384              if (teamplay == 0) self.colormod = '0 0 0';
1385         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1386         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1387         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1388         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1389         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1390         else self.colormod = '1 1 1';
1391 };*/
1392
1393 void respawn(void)
1394 {
1395         CopyBody(1);
1396         self.effects |= EF_NODRAW; // prevent another CopyBody
1397         PutClientInServer();
1398 }
1399
1400 /**
1401  * When sv_timeout is used this function returs strings like
1402  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1403  * Called by centerprint functions
1404  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1405  */
1406 string getTimeoutText(float addOneSecond) {
1407         if (!cvar("sv_timeout") || !timeoutStatus)
1408                 return "";
1409
1410         local string retStr;
1411         if (timeoutStatus == 1) {
1412                 if (addOneSecond == 1) {
1413                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1414                 }
1415                 else {
1416                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1417                 }
1418                 return retStr;
1419         }
1420         else if (timeoutStatus == 2) {
1421                 if (addOneSecond) {
1422                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1423                         //don't show messages like "Timeout ends in 0 seconds"...
1424                         if ((remainingTimeoutTime + 1) > 0)
1425                                 return retStr;
1426                         else
1427                                 return "";
1428                 }
1429                 else {
1430                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1431                         //don't show messages like "Timeout ends in 0 seconds"...
1432                         if (remainingTimeoutTime > 0)
1433                                 return retStr;
1434                         else
1435                                 return "";
1436                 }
1437         }
1438         else return "";
1439 }
1440
1441 void player_powerups (void)
1442 {
1443         if (g_minstagib)
1444         {
1445                 if (self.items & IT_STRENGTH)
1446                 {
1447                         if (time > self.strength_finished)
1448                         {
1449                                 if (g_minstagib_invis_alpha > 0)
1450                                 {
1451                                         self.alpha = default_player_alpha;
1452                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1453                                         self.effects = self.effects | EF_FULLBRIGHT;
1454                                 }
1455                                 else
1456                                 {
1457                                         self.effects -= self.effects & EF_NODRAW;
1458                                 }
1459                                 self.items = self.items - (self.items & IT_STRENGTH);
1460                                 sprint(self, "^3Invisibility has worn off\n");
1461                         }
1462                 }
1463                 else
1464                 {
1465                         if (time < self.strength_finished)
1466                         {
1467                                 if (g_minstagib_invis_alpha > 0)
1468                                 {
1469                                         self.alpha = g_minstagib_invis_alpha;
1470                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1471                                         self.effects -= self.effects & EF_FULLBRIGHT;
1472                                 }
1473                                 else
1474                                 {
1475                                         self.effects = self.effects | EF_NODRAW;
1476                                 }
1477                                 self.items = self.items | IT_STRENGTH;
1478                                 sprint(self, "^3You are invisible\n");
1479                         }
1480                 }
1481
1482                 if (self.items & IT_INVINCIBLE)
1483                 {
1484                         if (time > self.invincible_finished)
1485                         {
1486                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1487                                 sprint(self, "^3Speed has worn off\n");
1488                         }
1489                 }
1490                 else
1491                 {
1492                         if (time < self.invincible_finished)
1493                         {
1494                                 self.items = self.items | IT_INVINCIBLE;
1495                                 sprint(self, "^3You are on speed\n");
1496                         }
1497                 }
1498                 return;
1499         }
1500
1501         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1502         if (self.items & IT_STRENGTH)
1503         {
1504                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1505                 if (time > self.strength_finished)
1506                 {
1507                         self.items = self.items - (self.items & IT_STRENGTH);
1508                         sprint(self, "^3Strength has worn off\n");
1509                 }
1510         }
1511         else
1512         {
1513                 if (time < self.strength_finished)
1514                 {
1515                         self.items = self.items | IT_STRENGTH;
1516                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1517                 }
1518         }
1519         if (self.items & IT_INVINCIBLE)
1520         {
1521                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1522                 if (time > self.invincible_finished)
1523                 {
1524                         self.items = self.items - (self.items & IT_INVINCIBLE);
1525                         sprint(self, "^3Shield has worn off\n");
1526                 }
1527         }
1528         else
1529         {
1530                 if (time < self.invincible_finished)
1531                 {
1532                         self.items = self.items | IT_INVINCIBLE;
1533                         sprint(self, "^3Shield surrounds you\n");
1534                 }
1535         }
1536
1537         if (cvar("g_fullbrightplayers"))
1538                 self.effects = self.effects | EF_FULLBRIGHT;
1539
1540         // midair gamemode: damage only while in the air
1541         // if in midair mode, being on ground grants temporary invulnerability
1542         // (this is so that multishot weapon don't clear the ground flag on the
1543         // first damage in the frame, leaving the player vulnerable to the
1544         // remaining hits in the same frame)
1545         if (self.flags & FL_ONGROUND)
1546         if (g_midair)
1547                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1548
1549         if (time > restart_countdown)
1550         if (time < self.spawnshieldtime)
1551                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1552 }
1553
1554 float CalcRegen(float current, float stable, float regenfactor)
1555 {
1556         if(current > stable)
1557                 return current;
1558         else if(current > stable - 0.25) // when close enough, "snap"
1559                 return stable;
1560         else
1561                 return min(stable, current + (stable - current) * regenfactor * frametime);
1562 }
1563
1564 void player_regen (void)
1565 {
1566         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1567         maxh = cvar("g_balance_health_stable");
1568         maxa = cvar("g_balance_armor_stable");
1569         limith = cvar("g_balance_health_limit");
1570         limita = cvar("g_balance_armor_limit");
1571
1572         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1573                 return;
1574
1575         max_mod = regen_mod = rot_mod = limit_mod = 1;
1576
1577         if (self.runes & RUNE_REGEN)
1578         {
1579                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1580                 {
1581                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1582                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1583                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1584                 }
1585                 else
1586                 {
1587                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1588                         max_mod = cvar("g_balance_rune_regen_hpmod");
1589                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1590                 }
1591         }
1592         else if (self.runes & CURSE_VENOM)
1593         {
1594                 max_mod = cvar("g_balance_curse_venom_hpmod");
1595                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1596                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1597                 else
1598                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1599                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1600                 //if (!self.runes & RUNE_REGEN)
1601                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1602         }
1603         maxh = maxh * max_mod;
1604         //maxa = maxa * max_mod;
1605         limith = limith * limit_mod;
1606         limita = limita * limit_mod;
1607
1608         if (self.armorvalue > maxa)
1609         {
1610                 if (time > self.pauserotarmor_finished)
1611                 {
1612                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1613                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1614                 }
1615         }
1616         else if (self.armorvalue < maxa)
1617         {
1618                 if (time > self.pauseregen_finished)
1619                 {
1620                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1621                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1622                 }
1623         }
1624         if (self.health > maxh)
1625         {
1626                 if (time > self.pauserothealth_finished)
1627                 {
1628                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1629                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1630                 }
1631         }
1632         else if (self.health < maxh)
1633         {
1634                 if (time > self.pauseregen_finished)
1635                 {
1636                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1637                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1638                 }
1639         }
1640
1641         if (self.health > limith)
1642                 self.health = limith;
1643         if (self.armorvalue > limita)
1644                 self.armorvalue = limita;
1645
1646         // if player rotted to death...  die!
1647         if(self.health < 1)
1648                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1649 }
1650
1651 .float zoomstate;
1652 float zoomstate_set;
1653 void SetZoomState(float z)
1654 {
1655         if(z != self.zoomstate)
1656         {
1657                 msg_entity = self;
1658                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
1659                 WriteByte(MSG_ONE, TE_CSQC_ZOOMNOTIFY);
1660                 WriteByte(MSG_ONE, z);
1661                 self.zoomstate = z;
1662         }
1663         zoomstate_set = 1;
1664 }
1665
1666 /*
1667 ======================
1668 spectate mode routines
1669 ======================
1670 */
1671 void SpectateCopy(entity spectatee) {
1672         self.armortype = spectatee.armortype;
1673         self.armorvalue = spectatee.armorvalue;
1674         self.currentammo = spectatee.currentammo;
1675         self.effects = spectatee.effects;
1676         self.health = spectatee.health;
1677         self.impulse = 0;
1678         self.items = spectatee.items;
1679         self.weapons = spectatee.weapons;
1680         self.punchangle = spectatee.punchangle;
1681         self.view_ofs = spectatee.view_ofs;
1682         self.v_angle = spectatee.v_angle;
1683         self.velocity = spectatee.velocity;
1684         self.dmg_take = spectatee.dmg_take;
1685         self.dmg_save = spectatee.dmg_save;
1686         self.dmg_inflictor = spectatee.dmg_inflictor;
1687         self.angles = spectatee.v_angle;
1688         self.fixangle = TRUE;
1689         setorigin(self, spectatee.origin);
1690         setsize(self, spectatee.mins, spectatee.maxs);
1691         SetZoomState(spectatee.zoomstate);
1692 }
1693
1694 float SpectateUpdate() {
1695         if(!self.enemy)
1696                 return 0;
1697
1698         if (self == self.enemy)
1699                 return 0;
1700
1701         if(self.enemy.flags & FL_NOTARGET)
1702                 return 0;
1703
1704         SpectateCopy(self.enemy);
1705
1706         return 1;
1707 }
1708
1709 float SpectateNext() {
1710         other = find(self.enemy, classname, "player");
1711         if (!other) {
1712                 other = find(other, classname, "player");
1713         }
1714         if (other) {
1715                 self.enemy = other;
1716         }
1717         if(self.enemy.classname == "player") {
1718                 msg_entity = self;
1719                 WriteByte(MSG_ONE, SVC_SETVIEW);
1720                 WriteEntity(MSG_ONE, self.enemy);
1721                 self.wantswelcomemessage = 1;
1722                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1723                 if(!SpectateUpdate())
1724                         PutObserverInServer();
1725                 return 1;
1726         } else {
1727                 return 0;
1728         }
1729 }
1730
1731 /*
1732 =============
1733 ShowRespawnCountdown()
1734
1735 Update a respawn countdown display.
1736 =============
1737 */
1738 void ShowRespawnCountdown()
1739 {
1740         float number;
1741         if(self.deadflag == DEAD_NO) // just respawned?
1742                 return;
1743         else
1744         {
1745                 number = ceil(self.death_time - time);
1746                 if(number <= 0)
1747                         return;
1748                 if(number <= self.respawn_countdown)
1749                 {
1750                         self.respawn_countdown = number - 1;
1751                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1752                                 announce(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1753                 }
1754         }
1755 }
1756
1757 void LeaveSpectatorMode()
1758 {
1759         if(isJoinAllowed()) {
1760                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1761                         self.classname = "player";
1762                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1763                                 JoinBestTeam(self, FALSE, TRUE);
1764                         if(cvar("g_campaign"))
1765                                 campaign_bots_may_start = 1;
1766                         PutClientInServer();
1767                         if(!(self.flags & FL_NOTARGET))
1768                                 bprint ("^4", self.netname, "^4 is playing now\n");
1769                         centerprint(self,"");
1770                         return;
1771                 } else {
1772                         stuffcmd(self,"menu_showteamselect\n");
1773                         return;
1774                 }
1775         }
1776         else {
1777                 //player may not join because of g_maxplayers is set
1778                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1779         }
1780 }
1781
1782 /**
1783  * Determines whether the player is allowed to join. This depends on cvar
1784  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1785  * it checks whether the number of currently playing players exceeds g_maxplayers.
1786  * @return bool TRUE if the player is allowed to join, false otherwise
1787  */
1788 float isJoinAllowed() {
1789         if (!cvar("g_maxplayers"))
1790                 return TRUE;
1791
1792         local entity e;
1793         local float currentlyPlaying;
1794         FOR_EACH_REALPLAYER(e) {
1795                 if(e.classname == "player")
1796                         currentlyPlaying += 1;
1797         }
1798         if(currentlyPlaying < cvar("g_maxplayers"))
1799                 return TRUE;
1800
1801         return FALSE;
1802 }
1803
1804 /**
1805  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1806  * g_maxplayers_spectator_blocktime seconds
1807  */
1808 void checkSpectatorBlock() {
1809         if(self.classname == "spectator" || self.classname == "observer") {
1810                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1811                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1812                         dropclient(self);
1813                 }
1814         }
1815 }
1816
1817 float vercmp_recursive(string v1, string v2)
1818 {
1819         float dot1, dot2;
1820         string s1, s2;
1821         float r;
1822
1823         dot1 = strstrofs(v1, ".", 0);
1824         dot2 = strstrofs(v2, ".", 0);
1825         if(dot1 == -1)
1826                 s1 = v1;
1827         else
1828                 s1 = substring(v1, 0, dot1);
1829         if(dot2 == -1)
1830                 s2 = v2;
1831         else
1832                 s2 = substring(v2, 0, dot2);
1833
1834         r = stof(s1) - stof(s2);
1835         if(r != 0)
1836                 return r;
1837
1838         r = strcasecmp(s1, s2);
1839         if(r != 0)
1840                 return r;
1841
1842         if(dot1 == -1)
1843                 if(dot2 == -1)
1844                         return 0;
1845                 else
1846                         return -1;
1847         else
1848                 if(dot2 == -1)
1849                         return 1;
1850                 else
1851                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1852 }
1853
1854 float vercmp(string v1, string v2)
1855 {
1856         if(strcasecmp(v1, v2) == 0) // early out check
1857                 return 0;
1858         return vercmp_recursive(v1, v2);
1859 }
1860
1861 void ObserverThink()
1862 {
1863         if (self.flags & FL_JUMPRELEASED) {
1864                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1865                         self.welcomemessage_time = 0;
1866                         self.flags = self.flags - FL_JUMPRELEASED;
1867                         LeaveSpectatorMode();
1868                         return;
1869                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
1870                         self.welcomemessage_time = 0;
1871                         self.flags = self.flags - FL_JUMPRELEASED;
1872                         if(SpectateNext() == 1) {
1873                                 self.classname = "spectator";
1874                         }
1875                 }
1876         } else {
1877                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
1878                         self.flags = self.flags | FL_JUMPRELEASED;
1879                 }
1880         }
1881         if(self.BUTTON_ZOOM)
1882                 self.wantswelcomemessage = 0;
1883         if(self.wantswelcomemessage)
1884                 PrintWelcomeMessage(self);
1885 }
1886
1887 void SpectatorThink()
1888 {
1889         if (self.flags & FL_JUMPRELEASED) {
1890                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1891                         self.welcomemessage_time = 0;
1892                         self.flags = self.flags - FL_JUMPRELEASED;
1893                         LeaveSpectatorMode();
1894                         return;
1895                 } else if(self.BUTTON_ATCK) {
1896                         self.welcomemessage_time = 0;
1897                         self.flags = self.flags - FL_JUMPRELEASED;
1898                         if(SpectateNext() == 1) {
1899                                 self.classname = "spectator";
1900                         } else {
1901                                 self.classname = "observer";
1902                                 PutClientInServer();
1903                         }
1904                 } else if (self.BUTTON_ATCK2) {
1905                         self.welcomemessage_time = 0;
1906                         self.flags = self.flags - FL_JUMPRELEASED;
1907                         self.classname = "observer";
1908                         PutClientInServer();
1909                 } else {
1910                         if(!SpectateUpdate())
1911                                 PutObserverInServer();
1912                 }
1913         } else {
1914                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
1915                         self.flags = self.flags | FL_JUMPRELEASED;
1916                 }
1917         }
1918         if(self.BUTTON_ZOOM)
1919                 self.wantswelcomemessage = 0;
1920         if(self.wantswelcomemessage)
1921                 PrintWelcomeMessage(self);
1922         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1923 }
1924
1925 /*
1926 =============
1927 PlayerPreThink
1928
1929 Called every frame for each client before the physics are run
1930 =============
1931 */
1932 void() ctf_setstatus;
1933 .float vote_nagtime;
1934 .float spectatee_status;
1935 void PlayerPreThink (void)
1936 {
1937         self.stat_sys_ticrate = cvar("sys_ticrate");
1938         if(blockSpectators)
1939                 checkSpectatorBlock();
1940
1941         zoomstate_set = 0;
1942
1943         if(self.netname_previous != self.netname)
1944         {
1945                 if(cvar("sv_eventlog"))
1946                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
1947                 if(self.netname_previous)
1948                         strunzone(self.netname_previous);
1949                 self.netname_previous = strzone(self.netname);
1950         }
1951
1952         // version nagging
1953         if(self.version_nagtime)
1954                 if(self.cvar_g_nexuizversion)
1955                         if(time > self.version_nagtime)
1956                         {
1957                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1958                                 {
1959                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
1960                                         {
1961                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1962                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1963                                         }
1964                                         else
1965                                         {
1966                                                 float r;
1967                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
1968                                                 if(r < 0)
1969                                                 {
1970                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
1971                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
1972                                                 }
1973                                                 else if(r > 0)
1974                                                 {
1975                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1976                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1977                                                 }
1978                                         }
1979                                 }
1980                                 self.version_nagtime = 0;
1981                         }
1982
1983         // vote nagging
1984         if(self.cvar_scr_centertime)
1985                 if(time > self.vote_nagtime)
1986                 {
1987                         VoteNag();
1988                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1989                 }
1990
1991         // GOD MODE info
1992         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
1993         {
1994                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
1995                 self.max_armorvalue = 0;
1996         }
1997
1998         if(frametime)
1999                 antilag_record(self);
2000
2001         if(self.classname == "player") {
2002 //              if(self.netname == "Wazat")
2003 //                      bprint(self.classname, "\n");
2004
2005                 CheckRules_Player();
2006
2007                 if(self.BUTTON_INFO)
2008                         PrintWelcomeMessage(self);
2009
2010                 if(g_lms || !cvar("sv_spectate"))
2011                 if((time - self.jointime) <= cvar("welcome_message_time"))
2012                         PrintWelcomeMessage(self);
2013
2014                 if (intermission_running)
2015                 {
2016                         IntermissionThink ();   // otherwise a button could be missed between
2017                         return;                                 // the think tics
2018                 }
2019
2020                 if(self.teleport_time)
2021                 if(time > self.teleport_time)
2022                 {
2023                         self.teleport_time = 0;
2024                         self.effects = self.effects - (self.effects & EF_NODRAW);
2025                         if(self.weaponentity)
2026                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
2027                 }
2028
2029                 Nixnex_GiveCurrentWeapon();
2030
2031                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2032                         UpdateSelectedPlayer();
2033
2034                 //don't allow the player to turn around while game is paused!
2035                 if(timeoutStatus == 2) {
2036                         self.v_angle = self.lastV_angle;
2037                         self.angles = self.lastV_angle;
2038                         self.fixangle = TRUE;
2039                 }
2040
2041                 if (self.deadflag != DEAD_NO)
2042                 {
2043                         float button_pressed, force_respawn;
2044                         player_anim();
2045                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2046                         force_respawn = (g_lms || cvar("g_forced_respawn"));
2047                         if (self.deadflag == DEAD_DYING)
2048                         {
2049                                 if(force_respawn)
2050                                         self.deadflag = DEAD_RESPAWNING;
2051                                 else if(!button_pressed)
2052                                         self.deadflag = DEAD_DEAD;
2053                         }
2054                         else if (self.deadflag == DEAD_DEAD)
2055                         {
2056                                 if(button_pressed)
2057                                         self.deadflag = DEAD_RESPAWNABLE;
2058                         }
2059                         else if (self.deadflag == DEAD_RESPAWNABLE)
2060                         {
2061                                 if(!button_pressed)
2062                                         self.deadflag = DEAD_RESPAWNING;
2063                         }
2064                         else if (self.deadflag == DEAD_RESPAWNING)
2065                         {
2066                                 if(time > self.death_time)
2067                                 {
2068                                         self.death_time = time + 1; // only retry once a second
2069                                         respawn();
2070                                 }
2071                         }
2072                         ShowRespawnCountdown();
2073                         return;
2074                 }
2075
2076                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2077                 {
2078                         vector dist;
2079
2080                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2081                         dist = self.oldorigin - self.origin;
2082                         dist_z = 0;
2083                         self.lms_traveled_distance += fabs(vlen(dist));
2084
2085                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
2086                         {
2087                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2088                                 self.lms_traveled_distance = 0;
2089                         }
2090
2091                         if(time > self.lms_nextcheck)
2092                         {
2093                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2094                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2095                                 {
2096                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2097                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2098                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2099                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2100                                 }
2101                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2102                                 self.lms_traveled_distance = 0;
2103                         }
2104                 }
2105
2106                 if (self.BUTTON_CROUCH && !self.hook.state)
2107                 {
2108                         if (!self.crouch)
2109                         {
2110                                 self.crouch = TRUE;
2111                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2112                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2113                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
2114                         }
2115                 }
2116                 else
2117                 {
2118                         if (self.crouch)
2119                         {
2120                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2121                                 if (!trace_startsolid)
2122                                 {
2123                                         self.crouch = FALSE;
2124                                         self.view_ofs = PL_VIEW_OFS;
2125                                         setsize (self, PL_MIN, PL_MAX);
2126                                 }
2127                         }
2128                 }
2129
2130                 FixPlayermodel();
2131
2132                 GrapplingHookFrame();
2133
2134                 W_WeaponFrame();
2135
2136                 player_powerups();
2137                 player_regen();
2138                 player_anim();
2139
2140                 if (g_minstagib)
2141                         minstagib_ammocheck();
2142
2143                 ctf_setstatus();
2144                 kh_setstatus();
2145
2146                 //self.angles_y=self.v_angle_y + 90;   // temp
2147
2148                 //if (TetrisPreFrame()) return;
2149         } else if(gameover) {
2150                 if (intermission_running)
2151                         IntermissionThink ();   // otherwise a button could be missed between
2152                 return;
2153         } else if(self.classname == "observer") {
2154                 ObserverThink();
2155         } else if(self.classname == "spectator") {
2156                 SpectatorThink();
2157         }
2158
2159         if(!zoomstate_set)
2160                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && !g_minstagib && self.weapon == WEP_NEX));
2161
2162         float oldspectatee_status;
2163         oldspectatee_status = self.spectatee_status;
2164         if(self.classname == "spectator")
2165                 self.spectatee_status = num_for_edict(self.enemy);
2166         else if(self.classname == "observer")
2167                 self.spectatee_status = num_for_edict(self);
2168         else
2169                 self.spectatee_status = 0;
2170         if(self.spectatee_status != oldspectatee_status)
2171         {
2172                 msg_entity = self;
2173                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
2174                 WriteByte(MSG_ONE, TE_CSQC_SPECTATING);
2175                 WriteByte(MSG_ONE, self.spectatee_status);
2176                 if(g_race)
2177                         race_InitSpectator();
2178         }
2179 }
2180
2181
2182 /*
2183 =============
2184 PlayerPostThink
2185
2186 Called every frame for each client after the physics are run
2187 =============
2188 */
2189 .float idlekick_lasttimeleft;
2190 .float race_penalty;
2191 .float race_penalty_nagged;
2192 void PlayerPostThink (void)
2193 {
2194         // Savage: Check for nameless players
2195         if (strlen(self.netname) < 1) {
2196                 self.netname = "Player";
2197                 stuffcmd(self, "seta _cl_name Player\n");
2198         }
2199
2200         if(sv_maxidle)
2201         {
2202                 float timeleft;
2203                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2204                 if(timeleft <= 0)
2205                 {
2206                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2207                         announce(self, "announcer/robotic/terminated.ogg");
2208                         dropclient(self);
2209                         return;
2210                 }
2211                 else if(timeleft <= 10)
2212                 {
2213                         if(timeleft != self.idlekick_lasttimeleft)
2214                         {
2215                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2216                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".ogg"));
2217                         }
2218                 }
2219                 else
2220                 {
2221                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2222                 }
2223                 self.idlekick_lasttimeleft = timeleft;
2224         }
2225
2226         if(self.classname == "player") {
2227                 CheckRules_Player();
2228                 UpdateChatBubble();
2229                 UpdateTeamBubble();
2230                 if (self.impulse)
2231                         ImpulseCommands();
2232                 if (intermission_running)
2233                         return;         // intermission or finale
2234
2235                 //PrintWelcomeMessage(self);
2236                 //if (TetrisPostFrame()) return;
2237
2238                 // restart countdown
2239                 if (restart_countdown) {
2240                         if(time < restart_countdown) {
2241                                 if (!cvar("sv_ready_restart_after_countdown"))
2242                                 {
2243                                         if(self.movement != '0 0 0' && g_race && !g_race_qualifying)
2244                                         {
2245                                                 if(time < restart_countdown - 2)
2246                                                 {
2247                                                         if(!self.race_penalty_nagged)
2248                                                         {
2249                                                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1DO NOT MOVE DURING THE COUNTDOWN.");
2250                                                                 self.race_penalty_nagged = 1;
2251                                                         }
2252                                                 }
2253                                                 else if(!self.race_penalty)
2254                                                 {
2255                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1FIVE SECONDS PENALTY.");
2256                                                         self.race_penalty = time + 5;
2257                                                 }
2258                                         }
2259                                         self.movetype = MOVETYPE_NONE;
2260                                         self.velocity = '0 0 0';
2261                                         self.avelocity = '0 0 0';
2262                                         self.movement = '0 0 0';
2263                                 }
2264                         }
2265                         else if (time < self.race_penalty)
2266                         {
2267                                 self.movetype = MOVETYPE_NONE;
2268                                 self.velocity = '0 0 0';
2269                                 self.avelocity = '0 0 0';
2270                                 self.movement = '0 0 0';
2271                         }
2272                         else
2273                         {
2274                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2275                                 if (!cvar("sv_ready_restart_after_countdown"))
2276                                 {
2277                                         if(self.movetype == MOVETYPE_NONE)
2278                                         {
2279                                                 self.movetype = MOVETYPE_WALK;
2280                                         }
2281                                         self.race_penalty = 0;
2282                                         self.race_penalty_nagged = 0;
2283                                 }
2284                         }
2285                 }
2286
2287         } else if (self.classname == "observer") {
2288                 //do nothing
2289         } else if (self.classname == "spectator") {
2290                 //do nothing
2291         }
2292
2293         /*
2294         float i;
2295         for(i = 0; i < 1000; ++i)
2296         {
2297                 vector end;
2298                 end = self.origin + '0 0 1024' + 512 * randomvec();
2299                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2300                 if(trace_fraction < 1)
2301                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2302                 {
2303                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2304                         break;
2305                 }
2306         }
2307         */
2308
2309         Arena_Warmup();
2310 }