data/qcsrc/server/cl_client.qc

   1 .float wantswelcomemessage;
   2 .string netname_previous;
   3
   4 void spawnfunc_info_player_survivor (void)
   5 {
   6         spawnfunc_info_player_deathmatch();
   7 }
   8
   9 void spawnfunc_info_player_start (void)
  10 {
  11         spawnfunc_info_player_deathmatch();
  12 }
  13
  14 void spawnfunc_info_player_deathmatch (void)
  15 {
  16         self.classname = "info_player_deathmatch";
  17         relocate_spawnpoint();
  18 }
  19
  20 void spawnpoint_use()
  21 {
  22         if(teams_matter)
  23         if(have_team_spawns)
  24         {
  25                 self.team = activator.team;
  26                 some_spawn_has_been_used = 1;
  27         }
  28 };
  29
  30 // Returns:
  31 //   -1 if a spawn can't be used
  32 //   otherwise, a weight of the spawnpoint
  33 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
  34 {
  35         float shortest, thisdist;
  36         entity player;
  37
  38         // filter out spots for the wrong team
  39         if(teamcheck)
  40         if(spot.team != teamcheck)
  41                 return -1;
  42
  43         // filter out spots for assault
  44         if(spot.target != "") {
  45                 local entity ent;
  46                 ent = find(world, targetname, spot.target);
  47                 while(ent) {
  48                         if(ent.classname == "target_objective")
  49                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  50                                         return -1;
  51                         ent = find(ent, targetname, spot.target);
  52                 }
  53         }
  54
  55         player = playerlist;
  56         shortest = vlen(world.maxs - world.mins);
  57         for(player = playerlist; player; player = player.chain)
  58                 if (player != self)
  59                 {
  60                         thisdist = vlen(player.origin - spot.origin);
  61                         if (thisdist < shortest)
  62                                 shortest = thisdist;
  63                 }
  64         return shortest;
  65 }
  66
  67 float spawn_allbad;
  68 float spawn_allgood;
  69 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  70 {
  71         local entity spot, spotlist, spotlistend;
  72         spawn_allgood = TRUE;
  73         spawn_allbad = TRUE;
  74
  75         spotlist = world;
  76         spotlistend = world;
  77
  78         for(spot = firstspot; spot; spot = spot.chain)
  79         {
  80                 spot.frags = Spawn_Score(spot, playerlist, teamcheck);
  81
  82                 if(cvar("spawn_debugview"))
  83                 {
  84                         setmodel(spot, "models/runematch/rune.mdl");
  85                         if(spot.frags < mindist)
  86                         {
  87                                 spot.colormod = '1 0 0';
  88                                 spot.scale = 1;
  89                         }
  90                         else
  91                         {
  92                                 spot.colormod = '0 1 0';
  93                                 spot.scale = spot.frags / mindist;
  94                         }
  95                 }
  96
  97                 if(spot.frags >= 0) // spawning allowed here
  98                 {
  99                         if(spot.frags < mindist)
 100                         {
 101                                 // too short distance
 102                                 spawn_allgood = FALSE;
 103                         }
 104                         else
 105                         {
 106                                 // perfect
 107                                 spawn_allbad = FALSE;
 108
 109                                 if(spotlistend)
 110                                         spotlistend.chain = spot;
 111                                 spotlistend = spot;
 112                                 if(!spotlist)
 113                                         spotlist = spot;
 114
 115                                 /*
 116                                 if(teamcheck)
 117                                 if(spot.team != teamcheck)
 118                                         error("invalid spawn added");
 119
 120                                 print("added ", etos(spot), "\n");
 121                                 */
 122                         }
 123                 }
 124         }
 125         if(spotlistend)
 126                 spotlistend.chain = world;
 127
 128         /*
 129                 entity e;
 130                 if(teamcheck)
 131                         for(e = spotlist; e; e = e.chain)
 132                         {
 133                                 print("seen ", etos(e), "\n");
 134                                 if(e.team != teamcheck)
 135                                         error("invalid spawn found");
 136                         }
 137         */
 138
 139         return spotlist;
 140 }
 141
 142 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 143 {
 144         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 145         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 146         local entity spot;
 147
 148         RandomSelection_Init();
 149         for(spot = firstspot; spot; spot = spot.chain)
 150                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.frags, upper), exponent) * spot.cnt, spot.frags >= lower);
 151
 152         return RandomSelection_chosen_ent;
 153 }
 154
 155 /*
 156 =============
 157 SelectSpawnPoint
 158
 159 Finds a point to respawn
 160 =============
 161 */
 162 entity SelectSpawnPoint (float anypoint)
 163 {
 164         local float teamcheck;
 165         local entity firstspot_new;
 166         local entity spot, firstspot, playerlist;
 167
 168         spot = find (world, classname, "testplayerstart");
 169         if (spot)
 170                 return spot;
 171
 172         teamcheck = 0;
 173
 174         if(!anypoint && have_team_spawns)
 175                 teamcheck = self.team;
 176
 177         // get the list of players
 178         playerlist = findchain(classname, "player");
 179         // get the entire list of spots
 180         firstspot = findchain(classname, "info_player_deathmatch");
 181         // filter out the bad ones
 182         // (note this returns the original list if none survived)
 183         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 184         if(!firstspot_new)
 185                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 186         firstspot = firstspot_new;
 187
 188         // there is 50/50 chance of choosing a random spot or the furthest spot
 189         // (this means that roughly every other spawn will be furthest, so you
 190         // usually won't get fragged at spawn twice in a row)
 191         if (arena_roundbased)
 192         {
 193                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 194                 if(firstspot_new)
 195                         firstspot = firstspot_new;
 196                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 197         }
 198         else if (random() > cvar("g_spawn_furthest"))
 199                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 200         else
 201                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 202
 203         if(cvar("spawn_debugview"))
 204         {
 205                 print("spot mindistance: ", ftos(spot.frags), "\n");
 206
 207                 entity e;
 208                 if(teamcheck)
 209                         for(e = firstspot; e; e = e.chain)
 210                                 if(e.team != teamcheck)
 211                                         error("invalid spawn found");
 212         }
 213
 214         if (!spot)
 215         {
 216                 if(cvar("spawn_debug"))
 217                         GotoNextMap();
 218                 else
 219                 {
 220                         if(some_spawn_has_been_used)
 221                                 return world; // team can't spawn any more, because of actions of other team
 222                         else
 223                                 error("Cannot find a spawn point - please fix the map!");
 224                 }
 225         }
 226
 227         return spot;
 228 }
 229
 230 /*
 231 =============
 232 CheckPlayerModel
 233
 234 Checks if the argument string can be a valid playermodel.
 235 Returns a valid one in doubt.
 236 =============
 237 */
 238 string FallbackPlayerModel = "models/player/marine.zym";
 239 string CheckPlayerModel(string plyermodel) {
 240         if(strlen(plyermodel) < 4)
 241                 return FallbackPlayerModel;
 242         if( substring(plyermodel,0,14) != "models/player/")
 243                 return FallbackPlayerModel;
 244         else if(cvar("sv_servermodelsonly"))
 245         {
 246                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 247                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 248                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 249                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 250                         return FallbackPlayerModel;
 251                 if(!fexists(plyermodel))
 252                         return FallbackPlayerModel;
 253         }
 254         return plyermodel;
 255 }
 256
 257 /*
 258 =============
 259 Client_customizeentityforclient
 260
 261 LOD reduction
 262 =============
 263 */
 264 float Client_customizeentityforclient()
 265 {
 266 #ifdef ALLOW_VARIABLE_LOD
 267         // self: me
 268         // other: the player viewing me
 269         float distance;
 270         float f;
 271
 272         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 273                 return TRUE;
 274
 275         if(other.cvar_cl_playerdetailreduction <= 0)
 276         {
 277                 if(other.cvar_cl_playerdetailreduction <= -2)
 278                         self.modelindex = self.modelindex_lod2;
 279                 else if(other.cvar_cl_playerdetailreduction <= -1)
 280                         self.modelindex = self.modelindex_lod1;
 281                 else
 282                         self.modelindex = self.modelindex_lod0;
 283         }
 284         else
 285         {
 286                 distance = vlen(self.origin - other.origin);
 287                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 288                 if(f > 10000)
 289                         self.modelindex = self.modelindex_lod2;
 290                 else if(f > 5000)
 291                         self.modelindex = self.modelindex_lod1;
 292                 else
 293                         self.modelindex = self.modelindex_lod0;
 294         }
 295 #endif
 296
 297         return TRUE;
 298 }
 299
 300 void UpdatePlayerSounds();
 301 void setmodel_lod(entity e, string modelname)
 302 {
 303 #ifdef ALLOW_VARIABLE_LOD
 304         string s;
 305
 306         // FIXME: this only supports 3-letter extensions
 307         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 308         if(fexists(s))
 309         {
 310                 precache_model(s);
 311                 setmodel(e, s); // players have high precision
 312                 self.modelindex_lod1 = self.modelindex;
 313         }
 314         else
 315                 self.modelindex_lod1 = -1;
 316
 317         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 318         if(fexists(s))
 319         {
 320                 precache_model(s);
 321                 setmodel(e, s); // players have high precision
 322                 self.modelindex_lod2 = self.modelindex;
 323         }
 324         else
 325                 self.modelindex_lod2 = -1;
 326
 327         precache_model(modelname);
 328         setmodel(e, modelname); // players have high precision
 329         self.modelindex_lod0 = self.modelindex;
 330
 331         if(self.modelindex_lod1 < 0)
 332                 self.modelindex_lod1 = self.modelindex;
 333
 334         if(self.modelindex_lod2 < 0)
 335                 self.modelindex_lod2 = self.modelindex;
 336 #else
 337         precache_model(modelname);
 338         setmodel(e, modelname); // players have high precision
 339 #endif
 340         player_setupanimsformodel();
 341         UpdatePlayerSounds();
 342 }
 343
 344 /*
 345 =============
 346 PutObserverInServer
 347
 348 putting a client as observer in the server
 349 =============
 350 */
 351 void ctf_UpdateCaptures(float);
 352 void ctf_UpdateReturns(float);
 353 void PutObserverInServer (void)
 354 {
 355         entity  spot;
 356         spot = SelectSpawnPoint (TRUE);
 357         if(!spot)
 358                 error("No spawnpoints for observers?!?\n");
 359         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 360
 361         if(clienttype(self) == CLIENTTYPE_REAL)
 362         {
 363                 msg_entity = self;
 364                 WriteByte(MSG_ONE, SVC_SETVIEW);
 365                 WriteEntity(MSG_ONE, self);
 366         }
 367
 368         DropAllRunes(self);
 369         kh_Key_DropAll(self, TRUE);
 370
 371         if(self.flagcarried)
 372                 DropFlag(self.flagcarried);
 373
 374         WaypointSprite_PlayerDead();
 375
 376         DistributeFragsAmongTeam(self, self.team, 1);
 377         if(g_ctf)
 378         {
 379                 self.captures = 0;
 380                 ctf_UpdateCaptures(MSG_BROADCAST);
 381         }
 382
 383         if(self.frags <= 0 && self.frags > -666 && g_lms && self.killcount != -666)
 384                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 385         else if(self.killcount != -666)
 386                 bprint ("^4", self.netname, "^4 is spectating now\n");
 387
 388         PlayerScore_Clear(self); // clear scores when needed
 389
 390         self.spectatortime = time;
 391
 392         self.classname = "observer";
 393         self.health = -666;
 394         self.takedamage = DAMAGE_NO;
 395         self.solid = SOLID_NOT;
 396         self.movetype = MOVETYPE_NOCLIP;
 397         self.flags = FL_CLIENT | FL_NOTARGET;
 398         self.armorvalue = 666;
 399         self.effects = 0;
 400         self.armorvalue = cvar("g_balance_armor_start");
 401         self.pauserotarmor_finished = 0;
 402         self.pauserothealth_finished = 0;
 403         self.pauseregen_finished = 0;
 404         self.damageforcescale = 0;
 405         self.death_time = 0;
 406         self.dead_frame = 0;
 407         self.deaths = 0;
 408         self.captures = 0;
 409         self.returns = 0;
 410         self.alpha = 0;
 411         self.scale = 0;
 412         self.fade_time = 0;
 413         self.pain_frame = 0;
 414         self.pain_finished = 0;
 415         self.strength_finished = 0;
 416         self.invincible_finished = 0;
 417         self.pushltime = 0;
 418         self.think = SUB_Null;
 419         self.nextthink = 0;
 420         self.hook_time = 0;
 421         self.runes = 0;
 422         self.deadflag = DEAD_NO;
 423         self.angles = spot.angles;
 424         self.angles_z = 0;
 425         self.fixangle = TRUE;
 426         self.crouch = FALSE;
 427
 428         self.view_ofs = PL_VIEW_OFS;
 429         setorigin (self, spot.origin);
 430         setsize (self, '0 0 0', '0 0 0');
 431         self.oldorigin = self.origin;
 432         self.items = 0;
 433         self.model = "";
 434         self.modelindex = 0;
 435         self.weapon = 0;
 436         self.weaponmodel = "";
 437         self.weaponentity = world;
 438         self.killcount = -666;
 439         self.velocity = '0 0 0';
 440         self.avelocity = '0 0 0';
 441         self.punchangle = '0 0 0';
 442         self.punchvector = '0 0 0';
 443         self.oldvelocity = self.velocity;
 444         self.customizeentityforclient = Client_customizeentityforclient;
 445         self.viewzoom = 1;
 446         self.wantswelcomemessage = 1;
 447
 448         if(g_arena)
 449         {
 450                 if(self.frags != -2)
 451                 {
 452                         Spawnqueue_Insert(self);
 453                 }
 454                 else
 455                 {
 456                         Spawnqueue_Unmark(self);
 457                         Spawnqueue_Remove(self);
 458                 }
 459         }
 460         else if(!g_lms)
 461                 self.frags = -666;
 462
 463         net_UpdateDeaths(MSG_BROADCAST);
 464 }
 465
 466 float RestrictSkin(float s)
 467 {
 468         if(!teams_matter)
 469                 return s;
 470         if(s == 6)
 471                 return 6;
 472         return mod(s, 3);
 473 }
 474
 475 void FixPlayermodel()
 476 {
 477         local string defaultmodel;
 478         local float defaultskin;
 479         local vector m1, m2;
 480
 481         defaultmodel = "";
 482
 483         if(cvar("sv_defaultcharacter") == 1) {
 484                 defaultskin = 0;
 485
 486                 if(teams_matter)
 487                 {
 488                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 489                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 490                 }
 491
 492                 if(defaultmodel == "")
 493                 {
 494                         defaultmodel = cvar_string("sv_defaultplayermodel");
 495                         defaultskin = cvar("sv_defaultplayerskin");
 496                 }
 497         }
 498
 499         if(defaultmodel != "")
 500         {
 501                 if (defaultmodel != self.model)
 502                 {
 503                         m1 = self.mins;
 504                         m2 = self.maxs;
 505                         setmodel_lod (self, defaultmodel);
 506                         setsize (self, m1, m2);
 507                 }
 508
 509                 self.skin = defaultskin;
 510         } else {
 511                 if (self.playermodel != self.model)
 512                 {
 513                         self.playermodel = CheckPlayerModel(self.playermodel);
 514                         m1 = self.mins;
 515                         m2 = self.maxs;
 516                         setmodel_lod (self, self.playermodel);
 517                         setsize (self, m1, m2);
 518                 }
 519
 520                 self.skin = RestrictSkin(stof(self.playerskin));
 521         }
 522
 523         if(!teams_matter)
 524                 if(strlen(cvar_string("sv_defaultplayercolors")))
 525                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 526                                 setcolor(self, cvar("sv_defaultplayercolors"));
 527 }
 528
 529 /*
 530 =============
 531 PutClientInServer
 532
 533 Called when a client spawns in the server
 534 =============
 535 */
 536 //void() ctf_playerchanged;
 537 void PutClientInServer (void)
 538 {
 539         if(clienttype(self) == CLIENTTYPE_BOT)
 540         {
 541                 self.classname = "player";
 542         }
 543         else if(clienttype(self) == CLIENTTYPE_REAL)
 544         {
 545                 msg_entity = self;
 546                 WriteByte(MSG_ONE, SVC_SETVIEW);
 547                 WriteEntity(MSG_ONE, self);
 548         }
 549
 550         // player is dead and becomes observer
 551         if(g_lms && self.frags < 1)
 552                 self.classname = "observer";
 553
 554         if(g_arena)
 555         if(!self.spawned)
 556                 self.classname = "observer";
 557
 558         if(self.classname == "player") {
 559                 entity  spot;
 560
 561                 spot = SelectSpawnPoint (FALSE);
 562                 if(!spot)
 563                 {
 564                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 565                         return; // spawn failed
 566                 }
 567
 568                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 569
 570                 self.classname = "player";
 571                 self.iscreature = TRUE;
 572                 self.movetype = MOVETYPE_WALK;
 573                 self.solid = SOLID_SLIDEBOX;
 574                 self.flags = FL_CLIENT;
 575                 self.takedamage = DAMAGE_AIM;
 576                 if(g_minstagib)
 577                         self.effects = EF_FULLBRIGHT;
 578                 else
 579                         self.effects = 0;
 580                 self.air_finished = time + 12;
 581                 self.dmg = 2;
 582
 583                 self.ammo_shells = start_ammo_shells;
 584                 self.ammo_nails = start_ammo_nails;
 585                 self.ammo_rockets = start_ammo_rockets;
 586                 self.ammo_cells = start_ammo_cells;
 587                 self.health = start_health;
 588                 self.armorvalue = start_armorvalue;
 589                 self.items = start_items;
 590                 self.switchweapon = start_switchweapon;
 591                 self.cnt = start_switchweapon;
 592                 self.weapon = 0;
 593                 self.jump_interval = time;
 594
 595                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 596                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 597                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 598                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 599                 //extend the pause of rotting if client was reset at the beginning of the countdown
 600                 if(!cvar("sv_ready_restart_after_countdown") && time < restart_countdown) {
 601                         self.spawnshieldtime += RESTART_COUNTDOWN;
 602                         self.pauserotarmor_finished += RESTART_COUNTDOWN;
 603                         self.pauserothealth_finished += RESTART_COUNTDOWN;
 604                         self.pauseregen_finished += RESTART_COUNTDOWN;
 605                 }
 606                 self.damageforcescale = 2;
 607                 self.death_time = 0;
 608                 self.dead_frame = 0;
 609                 self.alpha = 0;
 610                 self.scale = 0;
 611                 self.fade_time = 0;
 612                 self.pain_frame = 0;
 613                 self.pain_finished = 0;
 614                 self.strength_finished = 0;
 615                 self.invincible_finished = 0;
 616                 self.pushltime = 0;
 617                 //self.speed_finished = 0;
 618                 //self.slowmo_finished = 0;
 619                 // players have no think function
 620                 self.think = SUB_Null;
 621                 self.nextthink = 0;
 622                 self.hook_time = 0;
 623
 624                 self.runes = 0;
 625
 626                 self.deadflag = DEAD_NO;
 627
 628                 self.angles = spot.angles;
 629
 630                 self.angles_z = 0; // never spawn tilted even if the spot says to
 631                 self.fixangle = TRUE; // turn this way immediately
 632                 self.velocity = '0 0 0';
 633                 self.avelocity = '0 0 0';
 634                 self.punchangle = '0 0 0';
 635                 self.punchvector = '0 0 0';
 636                 self.oldvelocity = self.velocity;
 637
 638                 self.viewzoom = 0.6;
 639                 self.has_zoomed = 0;
 640
 641                 self.customizeentityforclient = Client_customizeentityforclient;
 642
 643                 self.model = "";
 644                 FixPlayermodel();
 645
 646                 self.crouch = FALSE;
 647                 self.view_ofs = PL_VIEW_OFS;
 648                 setsize (self, PL_MIN, PL_MAX);
 649                 self.spawnorigin = spot.origin;
 650                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 651                 // don't reset back to last position, even if new position is stuck in solid
 652                 self.oldorigin = self.origin;
 653
 654                 if(g_arena)
 655                 {
 656                         Spawnqueue_Remove(self);
 657                         Spawnqueue_Mark(self);
 658                 }
 659
 660                 self.event_damage = PlayerDamage;
 661
 662                 self.bot_attack = TRUE;
 663
 664                 self.statdraintime = time + 5;
 665                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 666
 667                 if(self.killcount == -666) {
 668                         self.killcount = 0;
 669                         if(!g_arena)
 670                         if(!g_lms)
 671                                 self.frags = 0;
 672                         if(g_ctf)
 673                         {
 674                                 self.captures = 0;
 675                                 self.returns = 0;
 676                                 ctf_UpdateCaptures(MSG_BROADCAST);
 677                                 ctf_UpdateReturns(MSG_BROADCAST);
 678                         }
 679                         self.deaths = 0;
 680                         net_UpdateDeaths(MSG_BROADCAST);
 681                 }
 682
 683                 self.cnt = WEP_LASER;
 684                 self.nixnex_lastchange_id = -1;
 685
 686                 CL_SpawnWeaponentity();
 687                 self.alpha = default_player_alpha;
 688                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 689                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 690
 691                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 692                 self.lms_traveled_distance = 0;
 693                 self.speedrunning = FALSE;
 694
 695                 if(cvar("spawn_debug"))
 696                 {
 697                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 698                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 699                 }
 700
 701                 //stuffcmd(self, "chase_active 0");
 702                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 703
 704                 if (cvar("g_spawnsound"))
 705                         sound (self, CHAN_AUTO, "misc/spawn.wav", 1, ATTN_NORM);
 706
 707                 if(g_assault) {
 708                         if(self.team == assault_attacker_team)
 709                                 centerprint(self, "You are attacking!\n");
 710                         else
 711                                 centerprint(self, "You are defending!\n");
 712                 }
 713
 714         } else if(self.classname == "observer") {
 715                 PutObserverInServer ();
 716         }
 717
 718         //if(g_ctf)
 719         //      ctf_playerchanged();
 720 }
 721
 722 /*
 723 =============
 724 SendCSQCInfo
 725
 726 Send whatever CSQC needs NOW and cannot wait for SendServerInfo to happen...
 727 =============
 728 */
 729 void SendCSQCInfo(void)
 730 {
 731         if(clienttype(self) != CLIENTTYPE_REAL)
 732                 return;
 733         msg_entity = self;
 734         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 735         WriteByte(MSG_ONE, TE_CSQC_INIT);
 736         WriteShort(MSG_ONE, CSQC_REVISION);
 737         WriteByte(MSG_ONE, maxclients);
 738 }
 739
 740 /*
 741 =============
 742 SetNewParms
 743 =============
 744 */
 745 void SetNewParms (void)
 746 {
 747         // initialize parms for a new player
 748         parm1 = -(86400 * 366);
 749 }
 750
 751 /*
 752 =============
 753 SetChangeParms
 754 =============
 755 */
 756 void SetChangeParms (void)
 757 {
 758         // save parms for level change
 759         parm1 = self.parm_idlesince - time;
 760 }
 761
 762 /*
 763 =============
 764 DecodeLevelParms
 765 =============
 766 */
 767 void DecodeLevelParms (void)
 768 {
 769         // load parms
 770         self.parm_idlesince = parm1;
 771         if(self.parm_idlesince == -(86400 * 366))
 772                 self.parm_idlesince = time;
 773 }
 774
 775 /*
 776 =============
 777 ClientKill
 778
 779 Called when a client types 'kill' in the console
 780 =============
 781 */
 782
 783 void ClientKill_Now_TeamChange()
 784 {
 785         if(g_ctf)
 786         {
 787                 self.captures = 0;
 788                 self.returns = 0;
 789                 ctf_UpdateCaptures(MSG_BROADCAST);
 790                 ctf_UpdateReturns(MSG_BROADCAST);
 791         }
 792         self.deaths = 0;
 793         net_UpdateDeaths(MSG_BROADCAST);
 794         if(self.killindicator_teamchange == -1)
 795         {
 796                 self.team = -1;
 797                 JoinBestTeam( self, FALSE, FALSE );
 798         }
 799         else
 800         {
 801                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 802         }
 803 }
 804
 805 void ClientKill_Now()
 806 {
 807         if(self.killindicator_teamchange)
 808                 ClientKill_Now_TeamChange();
 809
 810         // in any case:
 811         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 812 }
 813 void KillIndicator_Think()
 814 {
 815         if (!self.owner.modelindex)
 816         {
 817                 self.owner.killindicator = world;
 818                 remove(self);
 819                 return;
 820         }
 821
 822         if(self.cnt <= 0)
 823         {
 824                 self = self.owner;
 825                 ClientKill_Now(); // no oldself needed
 826                 return;
 827         }
 828         else
 829         {
 830                 if(self.cnt <= 10)
 831                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 832                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 833                 {
 834                         if(self.cnt <= 10)
 835                                 play2(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 836                         if(self.owner.killindicator_teamchange)
 837                         {
 838                                 if(self.owner.killindicator_teamchange == -1)
 839                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 840                                 else
 841                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 842                         }
 843                         else
 844                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 845                 }
 846                 self.nextthink = time + 1;
 847                 self.cnt -= 1;
 848         }
 849 }
 850
 851 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 852 {
 853         float killtime;
 854         entity e;
 855         killtime = cvar("g_balance_kill_delay");
 856
 857         self.killindicator_teamchange = targetteam;
 858
 859         if(!self.killindicator)
 860         {
 861                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 862                 {
 863                         ClientKill_Now();
 864                 }
 865                 else
 866                 {
 867                         self.killindicator = spawn();
 868                         self.killindicator.owner = self;
 869                         self.killindicator.scale = 0.5;
 870                         setattachment(self.killindicator, self, "");
 871                         setorigin(self.killindicator, '0 0 52');
 872                         self.killindicator.think = KillIndicator_Think;
 873                         self.killindicator.nextthink = time + (self.lip) * 0.05;
 874                         self.killindicator.cnt = ceil(killtime);
 875                         self.killindicator.count = bound(0, ceil(killtime), 10);
 876                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 877
 878                         for(e = world; (e = find(e, classname, "body")) != world; )
 879                         {
 880                                 if(e.enemy != self)
 881                                         continue;
 882                                 e.killindicator = spawn();
 883                                 e.killindicator.owner = e;
 884                                 e.killindicator.scale = 0.5;
 885                                 setattachment(e.killindicator, e, "");
 886                                 setorigin(e.killindicator, '0 0 52');
 887                                 e.killindicator.think = KillIndicator_Think;
 888                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
 889                                 e.killindicator.cnt = ceil(killtime);
 890                         }
 891                         self.lip = 0;
 892                 }
 893         }
 894         if(self.killindicator)
 895         {
 896                 if(targetteam)
 897                         self.killindicator.colormod = TeamColor(targetteam);
 898                 else
 899                         self.killindicator.colormod = '0 0 0';
 900         }
 901 }
 902
 903 void ClientKill (void)
 904 {
 905         ClientKill_TeamChange(0);
 906 }
 907
 908 void DoTeamChange(float destteam)
 909 {
 910         float t, c0;
 911         if(!cvar("teamplay"))
 912         {
 913                 if(destteam >= 0)
 914                         SetPlayerColors(self, destteam);
 915                 return;
 916         }
 917         if(self.classname == "player")
 918         if(destteam == -1)
 919         {
 920                 CheckAllowedTeams(self);
 921                 t = FindSmallestTeam(self, TRUE);
 922                 switch(self.team)
 923                 {
 924                         case COLOR_TEAM1: c0 = c1; break;
 925                         case COLOR_TEAM2: c0 = c2; break;
 926                         case COLOR_TEAM3: c0 = c3; break;
 927                         case COLOR_TEAM4: c0 = c4; break;
 928                         default:          c0 = 999;
 929                 }
 930                 switch(t)
 931                 {
 932                         case 1:
 933                                 if(c0 > c1)
 934                                         destteam = COLOR_TEAM1;
 935                                 break;
 936                         case 2:
 937                                 if(c0 > c2)
 938                                         destteam = COLOR_TEAM2;
 939                                 break;
 940                         case 3:
 941                                 if(c0 > c3)
 942                                         destteam = COLOR_TEAM3;
 943                                 break;
 944                         case 4:
 945                                 if(c0 > c4)
 946                                         destteam = COLOR_TEAM4;
 947                                 break;
 948                 }
 949                 if(destteam == -1)
 950                         return;
 951         }
 952         if(destteam == self.team && !self.killindicator)
 953                 return;
 954         ClientKill_TeamChange(destteam);
 955 }
 956
 957 void FixClientCvars(entity e)
 958 {
 959         // send prediction settings to the client
 960         stuffcmd(e, "\nin_bindmap 0 0\n");
 961         /*
 962          * we no longer need to stuff this. Remove this comment block if you feel
 963          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 964         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
 965         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 966         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 967         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 968         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 969         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 970         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 971         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
 972         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 973         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 974         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 975         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 976         stuffcmd(e, "cl_movement_edgefriction 1\n");
 977          */
 978 }
 979
 980 /*
 981 =============
 982 ClientConnect
 983
 984 Called when a client connects to the server
 985 =============
 986 */
 987 //void ctf_clientconnect();
 988 string ColoredTeamName(float t);
 989 void DecodeLevelParms (void);
 990 //void dom_player_join_team(entity pl);
 991 void ClientConnect (void)
 992 {
 993         local string s;
 994         float wep;
 995
 996         if(Ban_IsClientBanned(self))
 997         {
 998                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
 999                 dropclient(self);
1000                 bprint(s);
1001                 return;
1002         }
1003
1004         DecodeLevelParms();
1005
1006         self.classname = "player_joining";
1007         self.flags = self.flags | FL_CLIENT;
1008         self.version_nagtime = time + 10 + random() * 10;
1009
1010         if(player_count<0)
1011         {
1012                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1013                 player_count = 0;
1014         }
1015
1016         bot_clientconnect();
1017
1018         //if(g_domination)
1019         //      dom_player_join_team(self);
1020
1021         //JoinBestTeam(self, FALSE, FALSE);
1022
1023         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1024                 self.classname = "observer";
1025         } else {
1026                 self.classname = "player";
1027                 campaign_bots_may_start = 1;
1028         }
1029
1030         self.playerid = (playerid_last = playerid_last + 1);
1031         if(cvar("sv_eventlog"))
1032         {
1033                 if(clienttype(self) == CLIENTTYPE_REAL)
1034                         s = "player";
1035                 else
1036                         s = "bot";
1037                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
1038                 s = strcat(":team:", ftos(self.playerid), ":");
1039                 s = strcat(s, ftos(self.team));
1040                 GameLogEcho(s, FALSE);
1041         }
1042         self.netname_previous = strzone(self.netname);
1043
1044         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1045
1046         bprint ("^4",self.netname);
1047         bprint ("^4 connected");
1048
1049         if(g_domination || g_ctf)
1050         {
1051                 bprint(" and joined the ");
1052                 bprint(ColoredTeamName(self.team));
1053         }
1054
1055         bprint("\n");
1056
1057         self.welcomemessage_time = 0;
1058
1059         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1060         // TODO: is this being used for anything else than cd tracks?
1061         // Remember: SVC_CDTRACK exists. Maybe it should be used.
1062         //
1063         stuffcmd(self, "cl_particles_reloadeffects\n");
1064
1065         FixClientCvars(self);
1066
1067         // spawnfunc_waypoint sprites
1068         WaypointSprite_InitClient(self);
1069
1070         // Wazat's grappling hook
1071         SetGrappleHookBindings();
1072
1073         // get autoswitch state from player when he toggles it
1074         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1075
1076         // get version info from player
1077         stuffcmd(self, "cmd clientversion $gameversion\n");
1078
1079         // send all weapon info strings
1080         stuffcmd(self, "register_bestweapon clear\n"); // clear the Quake stuff
1081         wep = WEP_FIRST;
1082         while (wep <= WEP_LAST)
1083         {
1084                 weapon_action(wep, WR_REGISTER);
1085                 wep = wep + 1;
1086         }
1087
1088         // get other cvars from player
1089         GetCvars(0);
1090
1091         // set cvar for team scoreboard
1092         if (teams_matter)
1093         {
1094                 local float t;
1095                 t = cvar("teamplay");
1096                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1097                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1098         }
1099         else
1100                 stuffcmd(self, "set teamplay 0\n");
1101
1102         // notify about available teams
1103         if(teamplay)
1104         {
1105                 CheckAllowedTeams(self);
1106                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1107                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1108         }
1109         else
1110                 stuffcmd(self, "set _teams_available 0\n");
1111
1112         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1113
1114         if(g_lms)
1115         {
1116                 self.frags = LMS_NewPlayerLives();
1117                 if(!self.frags)
1118                         self.frags = -666;
1119         }
1120         else if(g_arena)
1121         {
1122                 self.classname = "observer";
1123                 Spawnqueue_Insert(self);
1124         }
1125         /*else if(g_ctf)
1126         {
1127                 ctf_clientconnect();
1128         }*/
1129
1130         if(entcs_start)
1131                 attach_entcs();
1132
1133 #ifdef CSQCSCORES
1134         PlayerScore_Attach(self);
1135 #endif
1136
1137         bot_relinkplayerlist();
1138
1139         self.spectatortime = time;
1140         if(blockSpectators)
1141         {
1142                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1143         }
1144
1145         self.jointime = time;
1146         self.allowedTimeouts = cvar("sv_timeout_number");
1147
1148         if(clienttype(self) == CLIENTTYPE_REAL)
1149         {
1150                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1151                 SendCSQCInfo();
1152                 msg_entity = self;
1153                 ctf_UpdateCaptures(MSG_ONE);
1154                 ctf_UpdateReturns(MSG_ONE);
1155                 net_UpdateDeaths(MSG_ONE);
1156                 if(mapvote_initialized && !cvar("g_maplist_textonly"))
1157                 {
1158                         MapVote_SendData(MSG_ONE);
1159                         MapVote_UpdateData(MSG_ONE);
1160                 }
1161         }
1162 }
1163
1164 /*
1165 =============
1166 ClientDisconnect
1167
1168 Called when a client disconnects from the server
1169 =============
1170 */
1171 void(entity e) DropFlag;
1172 .entity chatbubbleentity;
1173 .entity teambubbleentity;
1174 //void() ctf_clientdisconnect;
1175 void ClientDisconnect (void)
1176 {
1177         float save;
1178
1179         bot_clientdisconnect();
1180
1181         if(entcs_start)
1182                 detach_entcs();
1183
1184         if(cvar("sv_eventlog"))
1185                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
1186         bprint ("^4",self.netname);
1187         bprint ("^4 disconnected\n");
1188
1189         if (self.chatbubbleentity)
1190         {
1191                 remove (self.chatbubbleentity);
1192                 self.chatbubbleentity = world;
1193         }
1194
1195         if (self.teambubbleentity)
1196         {
1197                 remove (self.teambubbleentity);
1198                 self.teambubbleentity = world;
1199         }
1200
1201         if (self.killindicator)
1202         {
1203                 remove (self.killindicator);
1204                 self.killindicator = world;
1205         }
1206
1207         WaypointSprite_PlayerGone();
1208
1209         DropAllRunes(self);
1210         kh_Key_DropAll(self, TRUE);
1211
1212         if(self.flagcarried)
1213                 DropFlag(self.flagcarried);
1214
1215         DistributeFragsAmongTeam(self, self.team, 1);
1216         if(g_ctf)
1217         {
1218                 self.captures = 0;
1219                 ctf_UpdateCaptures(MSG_BROADCAST);
1220         }
1221
1222         save = self.flags;
1223         self.flags = self.flags - (self.flags & FL_CLIENT);
1224         bot_relinkplayerlist();
1225         self.flags = save;
1226
1227         // remove laserdot
1228         if(self.weaponentity)
1229                 if(self.weaponentity.lasertarget)
1230                         remove(self.weaponentity.lasertarget);
1231
1232         if(g_arena)
1233         {
1234                 Spawnqueue_Unmark(self);
1235                 Spawnqueue_Remove(self);
1236         }
1237         /*if(g_ctf)
1238         {
1239                 ctf_clientdisconnect();
1240         }
1241         */
1242
1243 #ifdef CSQCSCORES
1244         PlayerScore_Detach(self);
1245 #endif
1246
1247         if(self.netname_previous)
1248                 strunzone(self.netname_previous);
1249
1250         // free cvars
1251         GetCvars(-1);
1252 }
1253
1254 .float BUTTON_CHAT;
1255 void ChatBubbleThink()
1256 {
1257         self.nextthink = time;
1258         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1259         {
1260                 self.owner.chatbubbleentity = world;
1261                 remove(self);
1262                 return;
1263         }
1264         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1265         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1266                 self.model = self.mdl;
1267         else
1268                 self.model = "";
1269 };
1270
1271 void UpdateChatBubble()
1272 {
1273         if (!self.modelindex)
1274                 return;
1275         // spawn a chatbubble entity if needed
1276         if (!self.chatbubbleentity)
1277         {
1278                 self.chatbubbleentity = spawn();
1279                 self.chatbubbleentity.owner = self;
1280                 self.chatbubbleentity.exteriormodeltoclient = self;
1281                 self.chatbubbleentity.think = ChatBubbleThink;
1282                 self.chatbubbleentity.nextthink = time;
1283                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1284                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1285                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1286                 self.chatbubbleentity.model = "";
1287                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1288         }
1289 }
1290
1291
1292 void TeamBubbleThink()
1293 {
1294         self.nextthink = time;
1295         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1296         {
1297                 self.owner.teambubbleentity = world;
1298                 remove(self);
1299                 return;
1300         }
1301 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1302         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1303                 self.model = "";
1304         else
1305                 self.model = self.mdl;
1306
1307 };
1308
1309 float TeamBubble_customizeentityforclient()
1310 {
1311         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1312 }
1313
1314 void UpdateTeamBubble()
1315 {
1316         if (!self.modelindex || !cvar("teamplay"))
1317                 return;
1318         // spawn a teambubble entity if needed
1319         if (!self.teambubbleentity && cvar("teamplay"))
1320         {
1321                 self.teambubbleentity = spawn();
1322                 self.teambubbleentity.owner = self;
1323                 self.teambubbleentity.exteriormodeltoclient = self;
1324                 self.teambubbleentity.think = TeamBubbleThink;
1325                 self.teambubbleentity.nextthink = time;
1326                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1327 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1328                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1329                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1330                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1331                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1332                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1333                 self.teambubbleentity.effects = EF_LOWPRECISION;
1334         }
1335 }
1336
1337 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1338 // added to the model skins
1339 /*void UpdateColorModHack()
1340 {
1341         local float c;
1342         c = self.clientcolors & 15;
1343         // LordHavoc: only bothering to support white, green, red, yellow, blue
1344              if (teamplay == 0) self.colormod = '0 0 0';
1345         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1346         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1347         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1348         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1349         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1350         else self.colormod = '1 1 1';
1351 };*/
1352
1353 void respawn(void)
1354 {
1355         CopyBody(1);
1356         self.effects |= EF_NODRAW; // prevent another CopyBody
1357         PutClientInServer();
1358 }
1359
1360 /**
1361  * When sv_timeout is used this function returs strings like
1362  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1363  * Called by centerprint functions
1364  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1365  */
1366 string getTimeoutText(float addOneSecond) {
1367         if (!cvar("sv_timeout") || !timeoutStatus)
1368                 return "";
1369
1370         local string retStr;
1371         if (timeoutStatus == 1) {
1372                 if (addOneSecond == 1) {
1373                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1374                 }
1375                 else {
1376                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1377                 }
1378                 return retStr;
1379         }
1380         else if (timeoutStatus == 2) {
1381                 if (addOneSecond) {
1382                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1383                         //don't show messages like "Timeout ends in 0 seconds"...
1384                         if ((remainingTimeoutTime + 1) > 0)
1385                                 return retStr;
1386                         else
1387                                 return "";
1388                 }
1389                 else {
1390                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1391                         //don't show messages like "Timeout ends in 0 seconds"...
1392                         if (remainingTimeoutTime > 0)
1393                                 return retStr;
1394                         else
1395                                 return "";
1396                 }
1397         }
1398         else return "";
1399 }
1400
1401 void player_powerups (void)
1402 {
1403         if (g_minstagib)
1404         {
1405                 if (self.items & IT_STRENGTH)
1406                 {
1407                         if (time > self.strength_finished)
1408                         {
1409                                 if (g_minstagib_invis_alpha > 0)
1410                                 {
1411                                         self.alpha = default_player_alpha;
1412                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1413                                         self.effects = self.effects | EF_FULLBRIGHT;
1414                                 }
1415                                 else
1416                                 {
1417                                         self.effects -= self.effects & EF_NODRAW;
1418                                 }
1419                                 self.items = self.items - (self.items & IT_STRENGTH);
1420                                 sprint(self, "^3Invisibility has worn off\n");
1421                         }
1422                 }
1423                 else
1424                 {
1425                         if (time < self.strength_finished)
1426                         {
1427                                 if (g_minstagib_invis_alpha > 0)
1428                                 {
1429                                         self.alpha = g_minstagib_invis_alpha;
1430                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1431                                         self.effects -= self.effects & EF_FULLBRIGHT;
1432                                 }
1433                                 else
1434                                 {
1435                                         self.effects = self.effects | EF_NODRAW;
1436                                 }
1437                                 self.items = self.items | IT_STRENGTH;
1438                                 sprint(self, "^3You are invisible\n");
1439                         }
1440                 }
1441
1442                 if (self.items & IT_INVINCIBLE)
1443                 {
1444                         if (time > self.invincible_finished)
1445                         {
1446                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1447                                 sprint(self, "^3Speed has worn off\n");
1448                         }
1449                 }
1450                 else
1451                 {
1452                         if (time < self.invincible_finished)
1453                         {
1454                                 self.items = self.items | IT_INVINCIBLE;
1455                                 sprint(self, "^3You are on speed\n");
1456                         }
1457                 }
1458                 return;
1459         }
1460
1461         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1462         if (self.items & IT_STRENGTH)
1463         {
1464                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1465                 if (time > self.strength_finished)
1466                 {
1467                         self.items = self.items - (self.items & IT_STRENGTH);
1468                         sprint(self, "^3Strength has worn off\n");
1469                 }
1470         }
1471         else
1472         {
1473                 if (time < self.strength_finished)
1474                 {
1475                         self.items = self.items | IT_STRENGTH;
1476                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1477                 }
1478         }
1479         if (self.items & IT_INVINCIBLE)
1480         {
1481                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1482                 if (time > self.invincible_finished)
1483                 {
1484                         self.items = self.items - (self.items & IT_INVINCIBLE);
1485                         sprint(self, "^3Shield has worn off\n");
1486                 }
1487         }
1488         else
1489         {
1490                 if (time < self.invincible_finished)
1491                 {
1492                         self.items = self.items | IT_INVINCIBLE;
1493                         sprint(self, "^3Shield surrounds you\n");
1494                 }
1495         }
1496
1497         if (cvar("g_fullbrightplayers"))
1498                 self.effects = self.effects | EF_FULLBRIGHT;
1499
1500         // midair gamemode: damage only while in the air
1501         // if in midair mode, being on ground grants temporary invulnerability
1502         // (this is so that multishot weapon don't clear the ground flag on the
1503         // first damage in the frame, leaving the player vulnerable to the
1504         // remaining hits in the same frame)
1505         if (self.flags & FL_ONGROUND)
1506         if (g_midair)
1507                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1508
1509         if (time < self.spawnshieldtime)
1510                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1511 }
1512
1513 float CalcRegen(float current, float stable, float regenfactor)
1514 {
1515         if(current > stable)
1516                 return current;
1517         else if(current > stable - 0.25) // when close enough, "snap"
1518                 return stable;
1519         else
1520                 return min(stable, current + (stable - current) * regenfactor * frametime);
1521 }
1522
1523 void player_regen (void)
1524 {
1525         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1526         maxh = cvar("g_balance_health_stable");
1527         maxa = cvar("g_balance_armor_stable");
1528         limith = cvar("g_balance_health_limit");
1529         limita = cvar("g_balance_armor_limit");
1530
1531         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1532                 return;
1533
1534         max_mod = regen_mod = rot_mod = limit_mod = 1;
1535
1536         if (self.runes & RUNE_REGEN)
1537         {
1538                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1539                 {
1540                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1541                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1542                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1543                 }
1544                 else
1545                 {
1546                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1547                         max_mod = cvar("g_balance_rune_regen_hpmod");
1548                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1549                 }
1550         }
1551         else if (self.runes & CURSE_VENOM)
1552         {
1553                 max_mod = cvar("g_balance_curse_venom_hpmod");
1554                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1555                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1556                 else
1557                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1558                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1559                 //if (!self.runes & RUNE_REGEN)
1560                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1561         }
1562         maxh = maxh * max_mod;
1563         //maxa = maxa * max_mod;
1564         limith = limith * limit_mod;
1565         limita = limita * limit_mod;
1566
1567         if (self.armorvalue > maxa)
1568         {
1569                 if (time > self.pauserotarmor_finished)
1570                 {
1571                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1572                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1573                 }
1574         }
1575         else if (self.armorvalue < maxa)
1576         {
1577                 if (time > self.pauseregen_finished)
1578                 {
1579                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1580                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1581                 }
1582         }
1583         if (self.health > maxh)
1584         {
1585                 if (time > self.pauserothealth_finished)
1586                 {
1587                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1588                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1589                 }
1590         }
1591         else if (self.health < maxh)
1592         {
1593                 if (time > self.pauseregen_finished)
1594                 {
1595                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1596                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1597                 }
1598         }
1599
1600         if (self.health > limith)
1601                 self.health = limith;
1602         if (self.armorvalue > limita)
1603                 self.armorvalue = limita;
1604
1605         // if player rotted to death...  die!
1606         if(self.health < 1)
1607                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1608 }
1609
1610 /*
1611 ======================
1612 spectate mode routines
1613 ======================
1614 */
1615 void SpectateCopy(entity spectatee) {
1616         self.armortype = spectatee.armortype;
1617         self.armorvalue = spectatee.armorvalue;
1618         self.currentammo = spectatee.currentammo;
1619         self.effects = spectatee.effects;
1620         self.health = spectatee.health;
1621         self.impulse = 0;
1622         self.items = spectatee.items;
1623         self.punchangle = spectatee.punchangle;
1624         self.view_ofs = spectatee.view_ofs;
1625         self.v_angle = spectatee.v_angle;
1626         self.viewzoom = spectatee.viewzoom;
1627         self.velocity = spectatee.velocity;
1628         self.dmg_take = spectatee.dmg_take;
1629         self.dmg_save = spectatee.dmg_save;
1630         self.dmg_inflictor = spectatee.dmg_inflictor;
1631         self.angles = spectatee.v_angle;
1632         self.fixangle = TRUE;
1633         setorigin(self, spectatee.origin);
1634         setsize(self, spectatee.mins, spectatee.maxs);
1635 }
1636
1637 float SpectateUpdate() {
1638         if(!self.enemy)
1639                 return 0;
1640
1641         if (self == self.enemy)
1642                 return 0;
1643
1644         if(self.enemy.flags & FL_NOTARGET)
1645                 return 0;
1646
1647         SpectateCopy(self.enemy);
1648
1649         return 1;
1650 }
1651
1652 float SpectateNext() {
1653         other = find(self.enemy, classname, "player");
1654         if (!other) {
1655                 other = find(other, classname, "player");
1656         }
1657         if (other) {
1658                 self.enemy = other;
1659         }
1660         if(self.enemy.classname == "player") {
1661                 msg_entity = self;
1662                 WriteByte(MSG_ONE, SVC_SETVIEW);
1663                 WriteEntity(MSG_ONE, self.enemy);
1664                 self.wantswelcomemessage = 1;
1665                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1666                 if(!SpectateUpdate())
1667                         PutObserverInServer();
1668                 return 1;
1669         } else {
1670                 return 0;
1671         }
1672 }
1673
1674 /*
1675 =============
1676 ShowRespawnCountdown()
1677
1678 Update a respawn countdown display.
1679 =============
1680 */
1681 void ShowRespawnCountdown()
1682 {
1683         float number;
1684         if(self.deadflag == DEAD_NO) // just respawned?
1685                 return;
1686         else
1687         {
1688                 number = ceil(self.death_time - time);
1689                 if(number <= 0)
1690                         return;
1691                 if(number <= self.respawn_countdown)
1692                 {
1693                         self.respawn_countdown = number - 1;
1694                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1695                                 play2(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1696                 }
1697         }
1698 }
1699
1700 void LeaveSpectatorMode()
1701 {
1702         if(isJoinAllowed()) {
1703                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1704                         self.classname = "player";
1705                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1706                                 JoinBestTeam(self, FALSE, TRUE);
1707                         if(cvar("g_campaign"))
1708                                 campaign_bots_may_start = 1;
1709                         PutClientInServer();
1710                         if(!(self.flags & FL_NOTARGET))
1711                                 bprint ("^4", self.netname, "^4 is playing now\n");
1712                         centerprint(self,"");
1713                         return;
1714                 } else {
1715                         stuffcmd(self,"menu_showteamselect\n");
1716                         return;
1717                 }
1718         }
1719         else {
1720                 //player may not join because of g_maxplayers is set
1721                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1722         }
1723 }
1724
1725 /**
1726  * Determines whether the player is allowed to join. This depends on cvar
1727  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1728  * it checks whether the number of currently playing players exceeds g_maxplayers.
1729  * @return bool TRUE if the player is allowed to join, false otherwise
1730  */
1731 float isJoinAllowed() {
1732         if (!cvar("g_maxplayers"))
1733                 return TRUE;
1734
1735         local entity e;
1736         local float currentlyPlaying;
1737         FOR_EACH_REALPLAYER(e) {
1738                 if(e.classname == "player")
1739                         currentlyPlaying += 1;
1740         }
1741         if(currentlyPlaying < cvar("g_maxplayers"))
1742                 return TRUE;
1743
1744         return FALSE;
1745 }
1746
1747 /**
1748  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1749  * g_maxplayers_spectator_blocktime seconds
1750  */
1751 void checkSpectatorBlock() {
1752         if(self.classname == "spectator" || self.classname == "observer") {
1753                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1754                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1755                         dropclient(self);
1756                 }
1757         }
1758 }
1759
1760 float vercmp_recursive(string v1, string v2)
1761 {
1762         float dot1, dot2;
1763         string s1, s2;
1764         float r;
1765
1766         dot1 = strstrofs(v1, ".", 0);
1767         dot2 = strstrofs(v2, ".", 0);
1768         if(dot1 == -1)
1769                 s1 = v1;
1770         else
1771                 s1 = substring(v1, 0, dot1);
1772         if(dot2 == -1)
1773                 s2 = v2;
1774         else
1775                 s2 = substring(v2, 0, dot2);
1776
1777         r = stof(s1) - stof(s2);
1778         if(r != 0)
1779                 return r;
1780
1781         r = strcasecmp(s1, s2);
1782         if(r != 0)
1783                 return r;
1784
1785         if(dot1 == -1)
1786                 if(dot2 == -1)
1787                         return 0;
1788                 else
1789                         return -1;
1790         else
1791                 if(dot2 == -1)
1792                         return 1;
1793                 else
1794                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1795 }
1796
1797 float vercmp(string v1, string v2)
1798 {
1799         if(strcasecmp(v1, v2) == 0) // early out check
1800                 return 0;
1801         return vercmp_recursive(v1, v2);
1802 }
1803
1804 void ObserverThink()
1805 {
1806         if (self.flags & FL_JUMPRELEASED) {
1807                 if (self.BUTTON_JUMP && self.version == cvar("gameversion")) {
1808                         self.welcomemessage_time = 0;
1809                         self.flags = self.flags - FL_JUMPRELEASED;
1810                         LeaveSpectatorMode();
1811                         return;
1812                 } else if(self.BUTTON_ATCK && self.version == cvar("gameversion")) {
1813                         self.welcomemessage_time = 0;
1814                         self.flags = self.flags - FL_JUMPRELEASED;
1815                         if(SpectateNext() == 1) {
1816                                 self.classname = "spectator";
1817                         }
1818                 }
1819         } else {
1820                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
1821                         self.flags = self.flags | FL_JUMPRELEASED;
1822                 }
1823         }
1824         if(self.BUTTON_ZOOM)
1825                 self.wantswelcomemessage = 0;
1826         if(self.wantswelcomemessage)
1827                 PrintWelcomeMessage(self);
1828 }
1829
1830 void SpectatorThink()
1831 {
1832         if (self.flags & FL_JUMPRELEASED) {
1833                 if (self.BUTTON_JUMP && self.version == cvar("gameversion")) {
1834                         self.welcomemessage_time = 0;
1835                         self.flags = self.flags - FL_JUMPRELEASED;
1836                         LeaveSpectatorMode();
1837                         return;
1838                 } else if(self.BUTTON_ATCK) {
1839                         self.welcomemessage_time = 0;
1840                         self.flags = self.flags - FL_JUMPRELEASED;
1841                         if(SpectateNext() == 1) {
1842                                 self.classname = "spectator";
1843                         } else {
1844                                 self.classname = "observer";
1845                                 PutClientInServer();
1846                         }
1847                 } else if (self.BUTTON_ATCK2) {
1848                         self.welcomemessage_time = 0;
1849                         self.flags = self.flags - FL_JUMPRELEASED;
1850                         self.classname = "observer";
1851                         PutClientInServer();
1852                 } else {
1853                         if(!SpectateUpdate())
1854                                 PutObserverInServer();
1855                 }
1856         } else {
1857                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
1858                         self.flags = self.flags | FL_JUMPRELEASED;
1859                 }
1860         }
1861         if(self.BUTTON_ZOOM)
1862                 self.wantswelcomemessage = 0;
1863         if(self.wantswelcomemessage)
1864                 PrintWelcomeMessage(self);
1865         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1866 }
1867
1868 /*
1869 =============
1870 PlayerPreThink
1871
1872 Called every frame for each client before the physics are run
1873 =============
1874 */
1875 void() ctf_setstatus;
1876 .float vote_nagtime;
1877 void PlayerPreThink (void)
1878 {
1879         if(blockSpectators)
1880                 checkSpectatorBlock();
1881
1882         if(self.netname_previous != self.netname)
1883         {
1884                 if(cvar("sv_eventlog"))
1885                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname), TRUE);
1886                 if(self.netname_previous)
1887                         strunzone(self.netname_previous);
1888                 self.netname_previous = strzone(self.netname);
1889         }
1890
1891         // version nagging
1892         if(self.version_nagtime)
1893                 if(self.cvar_g_nexuizversion)
1894                         if(time > self.version_nagtime)
1895                         {
1896                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1897                                 {
1898                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
1899                                         {
1900                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1901                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1902                                         }
1903                                         else
1904                                         {
1905                                                 float r;
1906                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
1907                                                 if(r < 0)
1908                                                 {
1909                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
1910                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
1911                                                 }
1912                                                 else if(r > 0)
1913                                                 {
1914                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1915                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1916                                                 }
1917                                         }
1918                                 }
1919                                 self.version_nagtime = 0;
1920                         }
1921
1922         // vote nagging
1923         if(self.cvar_scr_centertime)
1924                 if(time > self.vote_nagtime)
1925                 {
1926                         VoteNag();
1927                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1928                 }
1929
1930         // GOD MODE info
1931         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
1932         {
1933                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
1934                 self.max_armorvalue = 0;
1935         }
1936
1937         if(frametime)
1938                 antilag_record(self);
1939
1940         if(self.classname == "player") {
1941 //              if(self.netname == "Wazat")
1942 //                      bprint(self.classname, "\n");
1943
1944                 CheckRules_Player();
1945
1946                 if(self.BUTTON_INFO)
1947                         PrintWelcomeMessage(self);
1948
1949                 if(g_lms || !cvar("sv_spectate"))
1950                 if((time - self.jointime) <= cvar("welcome_message_time"))
1951                         PrintWelcomeMessage(self);
1952
1953                 if (intermission_running)
1954                 {
1955                         IntermissionThink ();   // otherwise a button could be missed between
1956                         return;                                 // the think tics
1957                 }
1958
1959                 if(self.teleport_time)
1960                 if(time > self.teleport_time)
1961                 {
1962                         self.teleport_time = 0;
1963                         self.effects = self.effects - (self.effects & EF_NODRAW);
1964                         if(self.weaponentity)
1965                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
1966                 }
1967
1968                 Nixnex_GiveCurrentWeapon();
1969
1970                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
1971                         UpdateSelectedPlayer();
1972
1973                 //don't allow the player to turn around while game is paused!
1974                 if(timeoutStatus == 2) {
1975                         self.v_angle = self.lastV_angle;
1976                         self.angles = self.lastV_angle;
1977                         self.fixangle = TRUE;
1978                 }
1979
1980                 if (self.deadflag != DEAD_NO)
1981                 {
1982                         float button_pressed, force_respawn;
1983                         player_anim();
1984                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
1985                         force_respawn = (g_lms || cvar("g_forced_respawn"));
1986                         if (self.deadflag == DEAD_DYING)
1987                         {
1988                                 if(force_respawn)
1989                                         self.deadflag = DEAD_RESPAWNING;
1990                                 else if(!button_pressed)
1991                                         self.deadflag = DEAD_DEAD;
1992                         }
1993                         else if (self.deadflag == DEAD_DEAD)
1994                         {
1995                                 if(button_pressed)
1996                                         self.deadflag = DEAD_RESPAWNABLE;
1997                         }
1998                         else if (self.deadflag == DEAD_RESPAWNABLE)
1999                         {
2000                                 if(!button_pressed)
2001                                         self.deadflag = DEAD_RESPAWNING;
2002                         }
2003                         else if (self.deadflag == DEAD_RESPAWNING)
2004                         {
2005                                 if(time > self.death_time)
2006                                 {
2007                                         self.death_time = time + 1; // only retry once a second
2008                                         respawn();
2009                                 }
2010                         }
2011                         ShowRespawnCountdown();
2012                         return;
2013                 }
2014
2015                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2016                 {
2017                         vector dist;
2018
2019                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2020                         dist = self.oldorigin - self.origin;
2021                         dist_z = 0;
2022                         self.lms_traveled_distance += fabs(vlen(dist));
2023
2024                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
2025                         {
2026                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2027                                 self.lms_traveled_distance = 0;
2028                         }
2029
2030                         if(time > self.lms_nextcheck)
2031                         {
2032                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2033                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2034                                 {
2035                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2036                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2037                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2038                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2039                                 }
2040                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2041                                 self.lms_traveled_distance = 0;
2042                         }
2043                 }
2044
2045                 if (self.BUTTON_CROUCH && !self.hook.state)
2046                 {
2047                         if (!self.crouch)
2048                         {
2049                                 self.crouch = TRUE;
2050                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2051                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2052                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
2053                         }
2054                 }
2055                 else
2056                 {
2057                         if (self.crouch)
2058                         {
2059                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2060                                 if (!trace_startsolid)
2061                                 {
2062                                         self.crouch = FALSE;
2063                                         self.view_ofs = PL_VIEW_OFS;
2064                                         setsize (self, PL_MIN, PL_MAX);
2065                                 }
2066                         }
2067                 }
2068
2069                 FixPlayermodel();
2070
2071                 GrapplingHookFrame();
2072
2073                 W_WeaponFrame();
2074
2075                 {
2076                         float zoomfactor, zoomspeed, zoomdir;
2077                         zoomfactor = self.cvar_cl_zoomfactor;
2078                         if(zoomfactor < 1 || zoomfactor > 16)
2079                                 zoomfactor = 2.5;
2080                         zoomspeed = self.cvar_cl_zoomspeed;
2081                         if(zoomspeed >= 0) // < 0 is instant zoom
2082                                 if(zoomspeed < 0.5 || zoomspeed > 16)
2083                                         zoomspeed = 3.5;
2084
2085                         zoomdir = self.BUTTON_ZOOM;
2086                         if(self.BUTTON_ATCK2)
2087                                 if(self.weapon == WEP_NEX)
2088                                         if(!g_minstagib)
2089                                                 zoomdir = 1;
2090
2091                         if(zoomdir)
2092                                 self.has_zoomed = 1;
2093
2094                         if(self.has_zoomed)
2095                         {
2096                                 if(zoomspeed <= 0) // instant zoom
2097                                 {
2098                                         if(zoomdir)
2099                                                 self.viewzoom = 1 / zoomfactor;
2100                                         else
2101                                                 self.viewzoom = 1;
2102                                 }
2103                                 else
2104                                 {
2105                                         // geometric zoom would be:
2106                                         //   self.viewzoom = bound(1 / zoomfactor, self.viewzoom * pow(zoomfactor, (zoomdir ? -1 : 1) * frametime * zoomspeed), 1);
2107                                         // however, testing showed that arithmetic/harmonic zoom works better
2108                                         if(zoomdir)
2109                                                 // self.viewzoom = 1 / bound(1, 1 / self.viewzoom + (zoomdir ? 1 : -1) * frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2110                                                 // zoom in = arithmetic: 1x, 2x, 3x, 4x, ..., 8x
2111                                                 self.viewzoom = 1 / bound(1, 1 / self.viewzoom + frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2112                                         else
2113                                                 // self.viewzoom = bound(1 / zoomfactor, self.viewzoom + (zoomdir ? -1 : 1) * frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2114                                                 // zoom out = harmonic: 8/1x, 8/2x, 8/3x, 8/4x, ..., 8/8x
2115                                                 self.viewzoom = bound(1 / zoomfactor, self.viewzoom + frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2116                                 }
2117                         }
2118                         else
2119                                 self.viewzoom = min(1, self.viewzoom + frametime); // spawn zoom-in
2120                 }
2121
2122                 player_powerups();
2123                 player_regen();
2124                 player_anim();
2125
2126                 if (g_minstagib)
2127                         minstagib_ammocheck();
2128
2129                 ctf_setstatus();
2130                 kh_setstatus();
2131
2132                 //self.angles_y=self.v_angle_y + 90;   // temp
2133
2134                 //if (TetrisPreFrame()) return;
2135         } else if(gameover) {
2136                 if (intermission_running)
2137                         IntermissionThink ();   // otherwise a button could be missed between
2138                 return;
2139         } else if(self.classname == "observer") {
2140                 ObserverThink();
2141         } else if(self.classname == "spectator") {
2142                 SpectatorThink();
2143         }
2144 }
2145
2146
2147 /*
2148 =============
2149 PlayerPostThink
2150
2151 Called every frame for each client after the physics are run
2152 =============
2153 */
2154 .float idlekick_lasttimeleft;
2155 void PlayerPostThink (void)
2156 {
2157         // Savage: Check for nameless players
2158         if (strlen(self.netname) < 1) {
2159                 self.netname = "Player";
2160                 stuffcmd(self, "seta _cl_name Player\n");
2161         }
2162
2163         if(sv_maxidle)
2164         {
2165                 float timeleft;
2166                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2167                 if(timeleft <= 0)
2168                 {
2169                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2170                         play2(self, "announcer/robotic/terminated.ogg");
2171                         dropclient(self);
2172                         return;
2173                 }
2174                 else if(timeleft <= 10)
2175                 {
2176                         if(timeleft != self.idlekick_lasttimeleft)
2177                         {
2178                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2179                                 play2(self, strcat("announcer/robotic/", ftos(timeleft), ".ogg"));
2180                         }
2181                 }
2182                 else
2183                 {
2184                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2185                 }
2186                 self.idlekick_lasttimeleft = timeleft;
2187         }
2188
2189         if(self.classname == "player") {
2190                 CheckRules_Player();
2191                 UpdateChatBubble();
2192                 UpdateTeamBubble();
2193                 if (self.impulse)
2194                         ImpulseCommands();
2195                 if (intermission_running)
2196                         return;         // intermission or finale
2197
2198                 //PrintWelcomeMessage(self);
2199                 //if (TetrisPostFrame()) return;
2200
2201                 // restart countdown
2202                 if (restart_countdown) {
2203                         if(time < restart_countdown) {
2204                                 if (!cvar("sv_ready_restart_after_countdown"))
2205                                 {
2206                                         self.movetype = MOVETYPE_NONE;
2207                                         self.velocity = '0 0 0';
2208                                         self.avelocity = '0 0 0';
2209                                         self.movement = '0 0 0';
2210                                 }
2211                         }
2212                         else
2213                         {
2214                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2215                                 if (!cvar("sv_ready_restart_after_countdown"))
2216                                 {
2217                                         if(self.movetype == MOVETYPE_NONE)
2218                                         {
2219                                                 self.movetype = MOVETYPE_WALK;
2220                                         }
2221                                 }
2222                         }
2223                 }
2224
2225         } else if (self.classname == "observer") {
2226                 //do nothing
2227         } else if (self.classname == "spectator") {
2228                 //do nothing
2229         }
2230
2231         /*
2232         float i;
2233         for(i = 0; i < 1000; ++i)
2234         {
2235                 vector end;
2236                 end = self.origin + '0 0 1024' + 512 * randomvec();
2237                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2238                 if(trace_fraction < 1)
2239                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2240                 {
2241                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2242                         break;
2243                 }
2244         }
2245         */
2246
2247         Arena_Warmup();
2248 }