data/qcsrc/server/cl_client.qc

   1 .float wantswelcomemessage;
   2 .string netname_previous;
   3
   4 void spawnfunc_info_player_survivor (void)
   5 {
   6         spawnfunc_info_player_deathmatch();
   7 }
   8
   9 void spawnfunc_info_player_start (void)
  10 {
  11         spawnfunc_info_player_deathmatch();
  12 }
  13
  14 void spawnfunc_info_player_deathmatch (void)
  15 {
  16         self.classname = "info_player_deathmatch";
  17         relocate_spawnpoint();
  18 }
  19
  20 void spawnpoint_use()
  21 {
  22         if(teams_matter)
  23         if(have_team_spawns)
  24         {
  25                 self.team = activator.team;
  26                 some_spawn_has_been_used = 1;
  27         }
  28 };
  29
  30 // Returns:
  31 //   -1 if a spawn can't be used
  32 //   otherwise, a weight of the spawnpoint
  33 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
  34 {
  35         float shortest, thisdist;
  36         entity player;
  37
  38         // filter out spots for the wrong team
  39         if(teamcheck)
  40         if(spot.team != teamcheck)
  41                 return -1;
  42
  43         // filter out spots for assault
  44         if(spot.target != "") {
  45                 local entity ent;
  46                 ent = find(world, targetname, spot.target);
  47                 while(ent) {
  48                         if(ent.classname == "target_objective")
  49                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  50                                         return -1;
  51                         ent = find(ent, targetname, spot.target);
  52                 }
  53         }
  54
  55         player = playerlist;
  56         shortest = vlen(world.maxs - world.mins);
  57         for(player = playerlist; player; player = player.chain)
  58                 if (player != self)
  59                 {
  60                         thisdist = vlen(player.origin - spot.origin);
  61                         if (thisdist < shortest)
  62                                 shortest = thisdist;
  63                 }
  64         return shortest;
  65 }
  66
  67 float spawn_allbad;
  68 float spawn_allgood;
  69 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  70 {
  71         local entity spot, spotlist, spotlistend;
  72         spawn_allgood = TRUE;
  73         spawn_allbad = TRUE;
  74
  75         spotlist = world;
  76         spotlistend = world;
  77
  78         for(spot = firstspot; spot; spot = spot.chain)
  79         {
  80                 spot.frags = Spawn_Score(spot, playerlist, teamcheck);
  81
  82                 if(cvar("spawn_debugview"))
  83                 {
  84                         setmodel(spot, "models/runematch/rune.mdl");
  85                         if(spot.frags < mindist)
  86                         {
  87                                 spot.colormod = '1 0 0';
  88                                 spot.scale = 1;
  89                         }
  90                         else
  91                         {
  92                                 spot.colormod = '0 1 0';
  93                                 spot.scale = spot.frags / mindist;
  94                         }
  95                 }
  96
  97                 if(spot.frags >= 0) // spawning allowed here
  98                 {
  99                         if(spot.frags < mindist)
 100                         {
 101                                 // too short distance
 102                                 spawn_allgood = FALSE;
 103                         }
 104                         else
 105                         {
 106                                 // perfect
 107                                 spawn_allbad = FALSE;
 108
 109                                 if(spotlistend)
 110                                         spotlistend.chain = spot;
 111                                 spotlistend = spot;
 112                                 if(!spotlist)
 113                                         spotlist = spot;
 114
 115                                 /*
 116                                 if(teamcheck)
 117                                 if(spot.team != teamcheck)
 118                                         error("invalid spawn added");
 119
 120                                 print("added ", etos(spot), "\n");
 121                                 */
 122                         }
 123                 }
 124         }
 125         if(spotlistend)
 126                 spotlistend.chain = world;
 127
 128         /*
 129                 entity e;
 130                 if(teamcheck)
 131                         for(e = spotlist; e; e = e.chain)
 132                         {
 133                                 print("seen ", etos(e), "\n");
 134                                 if(e.team != teamcheck)
 135                                         error("invalid spawn found");
 136                         }
 137         */
 138
 139         return spotlist;
 140 }
 141
 142 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 143 {
 144         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 145         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 146         local entity spot;
 147
 148         RandomSelection_Init();
 149         for(spot = firstspot; spot; spot = spot.chain)
 150                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.frags, upper), exponent) * spot.cnt, spot.frags >= lower);
 151
 152         return RandomSelection_chosen_ent;
 153 }
 154
 155 /*
 156 =============
 157 SelectSpawnPoint
 158
 159 Finds a point to respawn
 160 =============
 161 */
 162 entity SelectSpawnPoint (float anypoint)
 163 {
 164         local float teamcheck;
 165         local entity firstspot_new;
 166         local entity spot, firstspot, playerlist;
 167
 168         spot = find (world, classname, "testplayerstart");
 169         if (spot)
 170                 return spot;
 171
 172         teamcheck = 0;
 173
 174         if(!anypoint && have_team_spawns)
 175                 teamcheck = self.team;
 176
 177         // get the list of players
 178         playerlist = findchain(classname, "player");
 179         // get the entire list of spots
 180         firstspot = findchain(classname, "info_player_deathmatch");
 181         // filter out the bad ones
 182         // (note this returns the original list if none survived)
 183         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 184         if(!firstspot_new)
 185                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 186         firstspot = firstspot_new;
 187
 188         // there is 50/50 chance of choosing a random spot or the furthest spot
 189         // (this means that roughly every other spawn will be furthest, so you
 190         // usually won't get fragged at spawn twice in a row)
 191         if (arena_roundbased)
 192         {
 193                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 194                 if(firstspot_new)
 195                         firstspot = firstspot_new;
 196                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 197         }
 198         else if (random() > cvar("g_spawn_furthest"))
 199                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 200         else
 201                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 202
 203         if(cvar("spawn_debugview"))
 204         {
 205                 print("spot mindistance: ", ftos(spot.frags), "\n");
 206
 207                 entity e;
 208                 if(teamcheck)
 209                         for(e = firstspot; e; e = e.chain)
 210                                 if(e.team != teamcheck)
 211                                         error("invalid spawn found");
 212         }
 213
 214         if (!spot)
 215         {
 216                 if(cvar("spawn_debug"))
 217                         GotoNextMap();
 218                 else
 219                 {
 220                         if(some_spawn_has_been_used)
 221                                 return world; // team can't spawn any more, because of actions of other team
 222                         else
 223                                 error("Cannot find a spawn point - please fix the map!");
 224                 }
 225         }
 226
 227         return spot;
 228 }
 229
 230 /*
 231 =============
 232 CheckPlayerModel
 233
 234 Checks if the argument string can be a valid playermodel.
 235 Returns a valid one in doubt.
 236 =============
 237 */
 238 string FallbackPlayerModel = "models/player/marine.zym";
 239 string CheckPlayerModel(string plyermodel) {
 240         if(strlen(plyermodel) < 4)
 241                 return FallbackPlayerModel;
 242         if( substring(plyermodel,0,14) != "models/player/")
 243                 return FallbackPlayerModel;
 244         else if(cvar("sv_servermodelsonly"))
 245         {
 246                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 247                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 248                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 249                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 250                         return FallbackPlayerModel;
 251                 if(!fexists(plyermodel))
 252                         return FallbackPlayerModel;
 253         }
 254         return plyermodel;
 255 }
 256
 257 /*
 258 =============
 259 Client_customizeentityforclient
 260
 261 LOD reduction
 262 =============
 263 */
 264 float Client_customizeentityforclient()
 265 {
 266 #ifdef ALLOW_VARIABLE_LOD
 267         // self: me
 268         // other: the player viewing me
 269         float distance;
 270         float f;
 271
 272         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 273                 return TRUE;
 274
 275         if(other.cvar_cl_playerdetailreduction <= 0)
 276         {
 277                 if(other.cvar_cl_playerdetailreduction <= -2)
 278                         self.modelindex = self.modelindex_lod2;
 279                 else if(other.cvar_cl_playerdetailreduction <= -1)
 280                         self.modelindex = self.modelindex_lod1;
 281                 else
 282                         self.modelindex = self.modelindex_lod0;
 283         }
 284         else
 285         {
 286                 distance = vlen(self.origin - other.origin);
 287                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 288                 if(f > 10000)
 289                         self.modelindex = self.modelindex_lod2;
 290                 else if(f > 5000)
 291                         self.modelindex = self.modelindex_lod1;
 292                 else
 293                         self.modelindex = self.modelindex_lod0;
 294         }
 295 #endif
 296
 297         return TRUE;
 298 }
 299
 300 void UpdatePlayerSounds();
 301 void setmodel_lod(entity e, string modelname)
 302 {
 303 #ifdef ALLOW_VARIABLE_LOD
 304         string s;
 305
 306         // FIXME: this only supports 3-letter extensions
 307         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 308         if(fexists(s))
 309         {
 310                 precache_model(s);
 311                 setmodel(e, s); // players have high precision
 312                 self.modelindex_lod1 = self.modelindex;
 313         }
 314         else
 315                 self.modelindex_lod1 = -1;
 316
 317         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 318         if(fexists(s))
 319         {
 320                 precache_model(s);
 321                 setmodel(e, s); // players have high precision
 322                 self.modelindex_lod2 = self.modelindex;
 323         }
 324         else
 325                 self.modelindex_lod2 = -1;
 326
 327         precache_model(modelname);
 328         setmodel(e, modelname); // players have high precision
 329         self.modelindex_lod0 = self.modelindex;
 330
 331         if(self.modelindex_lod1 < 0)
 332                 self.modelindex_lod1 = self.modelindex;
 333
 334         if(self.modelindex_lod2 < 0)
 335                 self.modelindex_lod2 = self.modelindex;
 336 #else
 337         precache_model(modelname);
 338         setmodel(e, modelname); // players have high precision
 339 #endif
 340         player_setupanimsformodel();
 341         UpdatePlayerSounds();
 342 }
 343
 344 /*
 345 =============
 346 PutObserverInServer
 347
 348 putting a client as observer in the server
 349 =============
 350 */
 351 void ctf_UpdateCaptures(float);
 352 void ctf_UpdateReturns(float);
 353 void PutObserverInServer (void)
 354 {
 355         entity  spot;
 356         spot = SelectSpawnPoint (TRUE);
 357         if(!spot)
 358                 error("No spawnpoints for observers?!?\n");
 359         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 360
 361         if(clienttype(self) == CLIENTTYPE_REAL)
 362         {
 363                 msg_entity = self;
 364                 WriteByte(MSG_ONE, SVC_SETVIEW);
 365                 WriteEntity(MSG_ONE, self);
 366         }
 367
 368         DropAllRunes(self);
 369         kh_Key_DropAll(self, TRUE);
 370
 371         if(self.flagcarried)
 372                 DropFlag(self.flagcarried);
 373
 374         WaypointSprite_PlayerDead();
 375
 376         DistributeFragsAmongTeam(self, self.team, 1);
 377         if(g_ctf)
 378         {
 379                 self.captures = 0;
 380                 ctf_UpdateCaptures(MSG_BROADCAST);
 381         }
 382
 383         if(self.frags <= 0 && self.frags > -666 && g_lms && self.killcount != -666)
 384                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 385         else if(self.killcount != -666)
 386                 bprint ("^4", self.netname, "^4 is spectating now\n");
 387
 388         self.spectatortime = time;
 389
 390         self.classname = "observer";
 391         self.health = -666;
 392         self.takedamage = DAMAGE_NO;
 393         self.solid = SOLID_NOT;
 394         self.movetype = MOVETYPE_NOCLIP;
 395         self.flags = FL_CLIENT | FL_NOTARGET;
 396         self.armorvalue = 666;
 397         self.effects = 0;
 398         self.armorvalue = cvar("g_balance_armor_start");
 399         self.pauserotarmor_finished = 0;
 400         self.pauserothealth_finished = 0;
 401         self.pauseregen_finished = 0;
 402         self.damageforcescale = 0;
 403         self.death_time = 0;
 404         self.dead_frame = 0;
 405         self.deaths = 0;
 406         self.captures = 0;
 407         self.returns = 0;
 408         self.alpha = 0;
 409         self.scale = 0;
 410         self.fade_time = 0;
 411         self.pain_frame = 0;
 412         self.pain_finished = 0;
 413         self.strength_finished = 0;
 414         self.invincible_finished = 0;
 415         self.pushltime = 0;
 416         self.think = SUB_Null;
 417         self.nextthink = 0;
 418         self.hook_time = 0;
 419         self.runes = 0;
 420         self.deadflag = DEAD_NO;
 421         self.angles = spot.angles;
 422         self.angles_z = 0;
 423         self.fixangle = TRUE;
 424         self.crouch = FALSE;
 425
 426         self.view_ofs = PL_VIEW_OFS;
 427         setorigin (self, spot.origin);
 428         setsize (self, '0 0 0', '0 0 0');
 429         self.oldorigin = self.origin;
 430         self.items = 0;
 431         self.model = "";
 432         self.modelindex = 0;
 433         self.weapon = 0;
 434         self.weaponmodel = "";
 435         self.weaponentity = world;
 436         self.killcount = -666;
 437         self.velocity = '0 0 0';
 438         self.avelocity = '0 0 0';
 439         self.punchangle = '0 0 0';
 440         self.punchvector = '0 0 0';
 441         self.oldvelocity = self.velocity;
 442         self.customizeentityforclient = Client_customizeentityforclient;
 443         self.viewzoom = 1;
 444         self.wantswelcomemessage = 1;
 445
 446         if(g_arena)
 447         {
 448                 if(self.frags != -2)
 449                 {
 450                         Spawnqueue_Insert(self);
 451                 }
 452                 else
 453                 {
 454                         Spawnqueue_Unmark(self);
 455                         Spawnqueue_Remove(self);
 456                 }
 457         }
 458         else if(!g_lms)
 459                 self.frags = -666;
 460
 461         net_UpdateDeaths(MSG_BROADCAST);
 462 }
 463
 464 float RestrictSkin(float s)
 465 {
 466         if(!teams_matter)
 467                 return s;
 468         if(s == 6)
 469                 return 6;
 470         return mod(s, 3);
 471 }
 472
 473 void FixPlayermodel()
 474 {
 475         local string defaultmodel;
 476         local float defaultskin;
 477         local vector m1, m2;
 478
 479         defaultmodel = "";
 480
 481         if(cvar("sv_defaultcharacter") == 1) {
 482                 defaultskin = 0;
 483
 484                 if(teams_matter)
 485                 {
 486                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 487                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 488                 }
 489
 490                 if(defaultmodel == "")
 491                 {
 492                         defaultmodel = cvar_string("sv_defaultplayermodel");
 493                         defaultskin = cvar("sv_defaultplayerskin");
 494                 }
 495         }
 496
 497         if(defaultmodel != "")
 498         {
 499                 if (defaultmodel != self.model)
 500                 {
 501                         m1 = self.mins;
 502                         m2 = self.maxs;
 503                         setmodel_lod (self, defaultmodel);
 504                         setsize (self, m1, m2);
 505                 }
 506
 507                 self.skin = defaultskin;
 508         } else {
 509                 if (self.playermodel != self.model)
 510                 {
 511                         self.playermodel = CheckPlayerModel(self.playermodel);
 512                         m1 = self.mins;
 513                         m2 = self.maxs;
 514                         setmodel_lod (self, self.playermodel);
 515                         setsize (self, m1, m2);
 516                 }
 517
 518                 self.skin = RestrictSkin(stof(self.playerskin));
 519         }
 520
 521         if(!teams_matter)
 522                 if(strlen(cvar_string("sv_defaultplayercolors")))
 523                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 524                                 setcolor(self, cvar("sv_defaultplayercolors"));
 525 }
 526
 527 /*
 528 =============
 529 PutClientInServer
 530
 531 Called when a client spawns in the server
 532 =============
 533 */
 534 //void() ctf_playerchanged;
 535 void PutClientInServer (void)
 536 {
 537         if(clienttype(self) == CLIENTTYPE_BOT)
 538         {
 539                 self.classname = "player";
 540         }
 541         else if(clienttype(self) == CLIENTTYPE_REAL)
 542         {
 543                 msg_entity = self;
 544                 WriteByte(MSG_ONE, SVC_SETVIEW);
 545                 WriteEntity(MSG_ONE, self);
 546         }
 547
 548         // player is dead and becomes observer
 549         if(g_lms && self.frags < 1)
 550                 self.classname = "observer";
 551
 552         if(g_arena)
 553         if(!self.spawned)
 554                 self.classname = "observer";
 555
 556         if(self.classname == "player") {
 557                 entity  spot;
 558
 559                 spot = SelectSpawnPoint (FALSE);
 560                 if(!spot)
 561                 {
 562                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 563                         return; // spawn failed
 564                 }
 565
 566                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 567
 568                 self.classname = "player";
 569                 self.iscreature = TRUE;
 570                 self.movetype = MOVETYPE_WALK;
 571                 self.solid = SOLID_SLIDEBOX;
 572                 self.flags = FL_CLIENT;
 573                 self.takedamage = DAMAGE_AIM;
 574                 if(g_minstagib)
 575                         self.effects = EF_FULLBRIGHT;
 576                 else
 577                         self.effects = 0;
 578                 self.air_finished = time + 12;
 579                 self.dmg = 2;
 580
 581                 self.ammo_shells = start_ammo_shells;
 582                 self.ammo_nails = start_ammo_nails;
 583                 self.ammo_rockets = start_ammo_rockets;
 584                 self.ammo_cells = start_ammo_cells;
 585                 self.health = start_health;
 586                 self.armorvalue = start_armorvalue;
 587                 self.items = start_items;
 588                 self.switchweapon = start_switchweapon;
 589                 self.cnt = start_switchweapon;
 590                 self.weapon = 0;
 591                 self.jump_interval = time;
 592
 593                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 594                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 595                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 596                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 597                 //extend the pause of rotting if client was reset at the beginning of the countdown
 598                 if(!cvar("sv_ready_restart_after_countdown") && time < restart_countdown) {
 599                         self.spawnshieldtime += RESTART_COUNTDOWN;
 600                         self.pauserotarmor_finished += RESTART_COUNTDOWN;
 601                         self.pauserothealth_finished += RESTART_COUNTDOWN;
 602                         self.pauseregen_finished += RESTART_COUNTDOWN;
 603                 }
 604                 self.damageforcescale = 2;
 605                 self.death_time = 0;
 606                 self.dead_frame = 0;
 607                 self.alpha = 0;
 608                 self.scale = 0;
 609                 self.fade_time = 0;
 610                 self.pain_frame = 0;
 611                 self.pain_finished = 0;
 612                 self.strength_finished = 0;
 613                 self.invincible_finished = 0;
 614                 self.pushltime = 0;
 615                 //self.speed_finished = 0;
 616                 //self.slowmo_finished = 0;
 617                 // players have no think function
 618                 self.think = SUB_Null;
 619                 self.nextthink = 0;
 620                 self.hook_time = 0;
 621
 622                 self.runes = 0;
 623
 624                 self.deadflag = DEAD_NO;
 625
 626                 self.angles = spot.angles;
 627
 628                 self.angles_z = 0; // never spawn tilted even if the spot says to
 629                 self.fixangle = TRUE; // turn this way immediately
 630                 self.velocity = '0 0 0';
 631                 self.avelocity = '0 0 0';
 632                 self.punchangle = '0 0 0';
 633                 self.punchvector = '0 0 0';
 634                 self.oldvelocity = self.velocity;
 635
 636                 self.viewzoom = 0.6;
 637                 self.has_zoomed = 0;
 638
 639                 self.customizeentityforclient = Client_customizeentityforclient;
 640
 641                 self.model = "";
 642                 FixPlayermodel();
 643
 644                 self.crouch = FALSE;
 645                 self.view_ofs = PL_VIEW_OFS;
 646                 setsize (self, PL_MIN, PL_MAX);
 647                 self.spawnorigin = spot.origin;
 648                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 649                 // don't reset back to last position, even if new position is stuck in solid
 650                 self.oldorigin = self.origin;
 651
 652                 if(g_arena)
 653                 {
 654                         Spawnqueue_Remove(self);
 655                         Spawnqueue_Mark(self);
 656                 }
 657
 658                 self.event_damage = PlayerDamage;
 659
 660                 self.bot_attack = TRUE;
 661
 662                 self.statdraintime = time + 5;
 663                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 664
 665                 if(self.killcount == -666) {
 666                         self.killcount = 0;
 667                         if(!g_arena)
 668                         if(!g_lms)
 669                                 self.frags = 0;
 670                         if(g_ctf)
 671                         {
 672                                 self.captures = 0;
 673                                 self.returns = 0;
 674                                 ctf_UpdateCaptures(MSG_BROADCAST);
 675                                 ctf_UpdateReturns(MSG_BROADCAST);
 676                         }
 677                         self.deaths = 0;
 678                         net_UpdateDeaths(MSG_BROADCAST);
 679                 }
 680
 681                 self.cnt = WEP_LASER;
 682                 self.nixnex_lastchange_id = -1;
 683
 684                 CL_SpawnWeaponentity();
 685                 self.alpha = default_player_alpha;
 686                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 687                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 688
 689                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 690                 self.lms_traveled_distance = 0;
 691                 self.speedrunning = FALSE;
 692
 693                 if(cvar("spawn_debug"))
 694                 {
 695                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 696                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 697                 }
 698
 699                 //stuffcmd(self, "chase_active 0");
 700                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 701
 702                 if (cvar("g_spawnsound"))
 703                         sound (self, CHAN_AUTO, "misc/spawn.wav", 1, ATTN_NORM);
 704
 705                 if(g_assault) {
 706                         if(self.team == assault_attacker_team)
 707                                 centerprint(self, "You are attacking!\n");
 708                         else
 709                                 centerprint(self, "You are defending!\n");
 710                 }
 711
 712         } else if(self.classname == "observer") {
 713                 PutObserverInServer ();
 714         }
 715
 716         //if(g_ctf)
 717         //      ctf_playerchanged();
 718 }
 719
 720 /*
 721 =============
 722 SendCSQCInfo
 723
 724 Send whatever CSQC needs NOW and cannot wait for SendServerInfo to happen...
 725 =============
 726 */
 727 void SendCSQCInfo(void)
 728 {
 729         if(clienttype(self) != CLIENTTYPE_REAL)
 730                 return;
 731         msg_entity = self;
 732         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 733         WriteByte(MSG_ONE, TE_CSQC_INIT);
 734         WriteShort(MSG_ONE, CSQC_REVISION);
 735         WriteByte(MSG_ONE, maxclients);
 736 }
 737
 738 /*
 739 =============
 740 SetNewParms
 741 =============
 742 */
 743 void SetNewParms (void)
 744 {
 745         // initialize parms for a new player
 746         parm1 = -(86400 * 366);
 747 }
 748
 749 /*
 750 =============
 751 SetChangeParms
 752 =============
 753 */
 754 void SetChangeParms (void)
 755 {
 756         // save parms for level change
 757         parm1 = self.parm_idlesince - time;
 758 }
 759
 760 /*
 761 =============
 762 DecodeLevelParms
 763 =============
 764 */
 765 void DecodeLevelParms (void)
 766 {
 767         // load parms
 768         self.parm_idlesince = parm1;
 769         if(self.parm_idlesince == -(86400 * 366))
 770                 self.parm_idlesince = time;
 771 }
 772
 773 /*
 774 =============
 775 ClientKill
 776
 777 Called when a client types 'kill' in the console
 778 =============
 779 */
 780
 781 void ClientKill_Now_TeamChange()
 782 {
 783         if(g_ctf)
 784         {
 785                 self.captures = 0;
 786                 self.returns = 0;
 787                 ctf_UpdateCaptures(MSG_BROADCAST);
 788                 ctf_UpdateReturns(MSG_BROADCAST);
 789         }
 790         self.deaths = 0;
 791         net_UpdateDeaths(MSG_BROADCAST);
 792         if(self.killindicator_teamchange == -1)
 793         {
 794                 self.team = -1;
 795                 JoinBestTeam( self, FALSE, FALSE );
 796         }
 797         else
 798         {
 799                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 800         }
 801 }
 802
 803 void ClientKill_Now()
 804 {
 805         if(self.killindicator_teamchange)
 806                 ClientKill_Now_TeamChange();
 807
 808         // in any case:
 809         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 810 }
 811 void KillIndicator_Think()
 812 {
 813         if (!self.owner.modelindex)
 814         {
 815                 self.owner.killindicator = world;
 816                 remove(self);
 817                 return;
 818         }
 819
 820         if(self.cnt <= 0)
 821         {
 822                 self = self.owner;
 823                 ClientKill_Now(); // no oldself needed
 824                 return;
 825         }
 826         else
 827         {
 828                 if(self.cnt <= 10)
 829                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 830                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 831                 {
 832                         if(self.cnt <= 10)
 833                                 play2(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 834                         if(self.owner.killindicator_teamchange)
 835                         {
 836                                 if(self.owner.killindicator_teamchange == -1)
 837                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 838                                 else
 839                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 840                         }
 841                         else
 842                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 843                 }
 844                 self.nextthink = time + 1;
 845                 self.cnt -= 1;
 846         }
 847 }
 848
 849 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 850 {
 851         float killtime;
 852         entity e;
 853         killtime = cvar("g_balance_kill_delay");
 854
 855         self.killindicator_teamchange = targetteam;
 856
 857         if(!self.killindicator)
 858         {
 859                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 860                 {
 861                         ClientKill_Now();
 862                 }
 863                 else
 864                 {
 865                         self.killindicator = spawn();
 866                         self.killindicator.owner = self;
 867                         self.killindicator.scale = 0.5;
 868                         setattachment(self.killindicator, self, "");
 869                         setorigin(self.killindicator, '0 0 52');
 870                         self.killindicator.think = KillIndicator_Think;
 871                         self.killindicator.nextthink = time + (self.lip) * 0.05;
 872                         self.killindicator.cnt = ceil(killtime);
 873                         self.killindicator.count = bound(0, ceil(killtime), 10);
 874                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 875
 876                         for(e = world; (e = find(e, classname, "body")) != world; )
 877                         {
 878                                 if(e.enemy != self)
 879                                         continue;
 880                                 e.killindicator = spawn();
 881                                 e.killindicator.owner = e;
 882                                 e.killindicator.scale = 0.5;
 883                                 setattachment(e.killindicator, e, "");
 884                                 setorigin(e.killindicator, '0 0 52');
 885                                 e.killindicator.think = KillIndicator_Think;
 886                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
 887                                 e.killindicator.cnt = ceil(killtime);
 888                         }
 889                         self.lip = 0;
 890                 }
 891         }
 892         if(self.killindicator)
 893         {
 894                 if(targetteam)
 895                         self.killindicator.colormod = TeamColor(targetteam);
 896                 else
 897                         self.killindicator.colormod = '0 0 0';
 898         }
 899 }
 900
 901 void ClientKill (void)
 902 {
 903         ClientKill_TeamChange(0);
 904 }
 905
 906 void DoTeamChange(float destteam)
 907 {
 908         float t, c0;
 909         if(!cvar("teamplay"))
 910         {
 911                 if(destteam >= 0)
 912                         SetPlayerColors(self, destteam);
 913                 return;
 914         }
 915         if(self.classname == "player")
 916         if(destteam == -1)
 917         {
 918                 CheckAllowedTeams(self);
 919                 t = FindSmallestTeam(self, TRUE);
 920                 switch(self.team)
 921                 {
 922                         case COLOR_TEAM1: c0 = c1; break;
 923                         case COLOR_TEAM2: c0 = c2; break;
 924                         case COLOR_TEAM3: c0 = c3; break;
 925                         case COLOR_TEAM4: c0 = c4; break;
 926                         default:          c0 = 999;
 927                 }
 928                 switch(t)
 929                 {
 930                         case 1:
 931                                 if(c0 > c1)
 932                                         destteam = COLOR_TEAM1;
 933                                 break;
 934                         case 2:
 935                                 if(c0 > c2)
 936                                         destteam = COLOR_TEAM2;
 937                                 break;
 938                         case 3:
 939                                 if(c0 > c3)
 940                                         destteam = COLOR_TEAM3;
 941                                 break;
 942                         case 4:
 943                                 if(c0 > c4)
 944                                         destteam = COLOR_TEAM4;
 945                                 break;
 946                 }
 947                 if(destteam == -1)
 948                         return;
 949         }
 950         if(destteam == self.team && !self.killindicator)
 951                 return;
 952         ClientKill_TeamChange(destteam);
 953 }
 954
 955 void FixClientCvars(entity e)
 956 {
 957         // send prediction settings to the client
 958         stuffcmd(e, "\nin_bindmap 0 0\n");
 959         /*
 960          * we no longer need to stuff this. Remove this comment block if you feel
 961          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 962         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
 963         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 964         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 965         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 966         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 967         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 968         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 969         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
 970         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 971         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 972         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 973         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 974         stuffcmd(e, "cl_movement_edgefriction 1\n");
 975          */
 976 }
 977
 978 /*
 979 =============
 980 ClientConnect
 981
 982 Called when a client connects to the server
 983 =============
 984 */
 985 //void ctf_clientconnect();
 986 string ColoredTeamName(float t);
 987 void DecodeLevelParms (void);
 988 //void dom_player_join_team(entity pl);
 989 void ClientConnect (void)
 990 {
 991         local string s;
 992         float wep;
 993
 994         if(Ban_IsClientBanned(self))
 995         {
 996                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
 997                 dropclient(self);
 998                 bprint(s);
 999                 return;
1000         }
1001
1002         DecodeLevelParms();
1003
1004         self.classname = "player_joining";
1005         self.flags = self.flags | FL_CLIENT;
1006         self.version_nagtime = time + 10 + random() * 10;
1007
1008         if(player_count<0)
1009         {
1010                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1011                 player_count = 0;
1012         }
1013
1014         bot_clientconnect();
1015
1016         //if(g_domination)
1017         //      dom_player_join_team(self);
1018
1019         //JoinBestTeam(self, FALSE, FALSE);
1020
1021         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1022                 self.classname = "observer";
1023         } else {
1024                 self.classname = "player";
1025                 campaign_bots_may_start = 1;
1026         }
1027
1028         self.playerid = (playerid_last = playerid_last + 1);
1029         if(cvar("sv_eventlog"))
1030         {
1031                 if(clienttype(self) == CLIENTTYPE_REAL)
1032                         s = "player";
1033                 else
1034                         s = "bot";
1035                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
1036                 s = strcat(":team:", ftos(self.playerid), ":");
1037                 s = strcat(s, ftos(self.team));
1038                 GameLogEcho(s, FALSE);
1039         }
1040         self.netname_previous = strzone(self.netname);
1041
1042         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1043
1044         bprint ("^4",self.netname);
1045         bprint ("^4 connected");
1046
1047         if(g_domination || g_ctf)
1048         {
1049                 bprint(" and joined the ");
1050                 bprint(ColoredTeamName(self.team));
1051         }
1052
1053         bprint("\n");
1054
1055         self.welcomemessage_time = 0;
1056
1057         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1058         // TODO: is this being used for anything else than cd tracks?
1059         // Remember: SVC_CDTRACK exists. Maybe it should be used.
1060         //
1061         stuffcmd(self, "cl_particles_reloadeffects\n");
1062
1063         FixClientCvars(self);
1064
1065         // spawnfunc_waypoint sprites
1066         WaypointSprite_InitClient(self);
1067
1068         // Wazat's grappling hook
1069         SetGrappleHookBindings();
1070
1071         // get autoswitch state from player when he toggles it
1072         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1073
1074         // get version info from player
1075         stuffcmd(self, "cmd clientversion $gameversion\n");
1076
1077         // send all weapon info strings
1078         stuffcmd(self, "register_bestweapon clear\n"); // clear the Quake stuff
1079         wep = WEP_FIRST;
1080         while (wep <= WEP_LAST)
1081         {
1082                 weapon_action(wep, WR_REGISTER);
1083                 wep = wep + 1;
1084         }
1085
1086         // get other cvars from player
1087         GetCvars(0);
1088
1089         // set cvar for team scoreboard
1090         if (teams_matter)
1091         {
1092                 local float t;
1093                 t = cvar("teamplay");
1094                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1095                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1096         }
1097         else
1098                 stuffcmd(self, "set teamplay 0\n");
1099
1100         // notify about available teams
1101         if(teamplay)
1102         {
1103                 CheckAllowedTeams(self);
1104                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1105                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1106         }
1107         else
1108                 stuffcmd(self, "set _teams_available 0\n");
1109
1110         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1111
1112         if(g_lms)
1113         {
1114                 self.frags = LMS_NewPlayerLives();
1115                 if(!self.frags)
1116                         self.frags = -666;
1117         }
1118         else if(g_arena)
1119         {
1120                 self.classname = "observer";
1121                 Spawnqueue_Insert(self);
1122         }
1123         /*else if(g_ctf)
1124         {
1125                 ctf_clientconnect();
1126         }*/
1127
1128         if(entcs_start)
1129                 attach_entcs();
1130
1131 #ifdef CSQCSCORES
1132         PlayerScore_Attach(self);
1133 #endif
1134
1135         bot_relinkplayerlist();
1136
1137         self.spectatortime = time;
1138         if(blockSpectators)
1139         {
1140                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1141         }
1142
1143         self.jointime = time;
1144         self.allowedTimeouts = cvar("sv_timeout_number");
1145
1146         if(clienttype(self) == CLIENTTYPE_REAL)
1147         {
1148                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1149                 SendCSQCInfo();
1150                 msg_entity = self;
1151                 ctf_UpdateCaptures(MSG_ONE);
1152                 ctf_UpdateReturns(MSG_ONE);
1153                 net_UpdateDeaths(MSG_ONE);
1154                 if(mapvote_initialized && !cvar("g_maplist_textonly"))
1155                 {
1156                         MapVote_SendData(MSG_ONE);
1157                         MapVote_UpdateData(MSG_ONE);
1158                 }
1159         }
1160 }
1161
1162 /*
1163 =============
1164 ClientDisconnect
1165
1166 Called when a client disconnects from the server
1167 =============
1168 */
1169 void(entity e) DropFlag;
1170 .entity chatbubbleentity;
1171 .entity teambubbleentity;
1172 //void() ctf_clientdisconnect;
1173 void ClientDisconnect (void)
1174 {
1175         float save;
1176
1177         bot_clientdisconnect();
1178
1179 #ifdef CSQCSCORES
1180         PlayerScore_Detach(self);
1181 #endif
1182
1183         if(entcs_start)
1184                 detach_entcs();
1185
1186         if(cvar("sv_eventlog"))
1187                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
1188         bprint ("^4",self.netname);
1189         bprint ("^4 disconnected\n");
1190
1191         if (self.chatbubbleentity)
1192         {
1193                 remove (self.chatbubbleentity);
1194                 self.chatbubbleentity = world;
1195         }
1196
1197         if (self.teambubbleentity)
1198         {
1199                 remove (self.teambubbleentity);
1200                 self.teambubbleentity = world;
1201         }
1202
1203         if (self.killindicator)
1204         {
1205                 remove (self.killindicator);
1206                 self.killindicator = world;
1207         }
1208
1209         WaypointSprite_PlayerGone();
1210
1211         DropAllRunes(self);
1212         kh_Key_DropAll(self, TRUE);
1213
1214         if(self.flagcarried)
1215                 DropFlag(self.flagcarried);
1216
1217         DistributeFragsAmongTeam(self, self.team, 1);
1218         if(g_ctf)
1219         {
1220                 self.captures = 0;
1221                 ctf_UpdateCaptures(MSG_BROADCAST);
1222         }
1223
1224         save = self.flags;
1225         self.flags = self.flags - (self.flags & FL_CLIENT);
1226         bot_relinkplayerlist();
1227         self.flags = save;
1228
1229         // remove laserdot
1230         if(self.weaponentity)
1231                 if(self.weaponentity.lasertarget)
1232                         remove(self.weaponentity.lasertarget);
1233
1234         if(g_arena)
1235         {
1236                 Spawnqueue_Unmark(self);
1237                 Spawnqueue_Remove(self);
1238         }
1239         /*if(g_ctf)
1240         {
1241                 ctf_clientdisconnect();
1242         }
1243         */
1244
1245         if(self.netname_previous)
1246                 strunzone(self.netname_previous);
1247
1248         // free cvars
1249         GetCvars(-1);
1250 }
1251
1252 .float BUTTON_CHAT;
1253 void ChatBubbleThink()
1254 {
1255         self.nextthink = time;
1256         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1257         {
1258                 self.owner.chatbubbleentity = world;
1259                 remove(self);
1260                 return;
1261         }
1262         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1263         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1264                 self.model = self.mdl;
1265         else
1266                 self.model = "";
1267 };
1268
1269 void UpdateChatBubble()
1270 {
1271         if (!self.modelindex)
1272                 return;
1273         // spawn a chatbubble entity if needed
1274         if (!self.chatbubbleentity)
1275         {
1276                 self.chatbubbleentity = spawn();
1277                 self.chatbubbleentity.owner = self;
1278                 self.chatbubbleentity.exteriormodeltoclient = self;
1279                 self.chatbubbleentity.think = ChatBubbleThink;
1280                 self.chatbubbleentity.nextthink = time;
1281                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1282                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1283                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1284                 self.chatbubbleentity.model = "";
1285                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1286         }
1287 }
1288
1289
1290 void TeamBubbleThink()
1291 {
1292         self.nextthink = time;
1293         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1294         {
1295                 self.owner.teambubbleentity = world;
1296                 remove(self);
1297                 return;
1298         }
1299 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1300         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1301                 self.model = "";
1302         else
1303                 self.model = self.mdl;
1304
1305 };
1306
1307 float TeamBubble_customizeentityforclient()
1308 {
1309         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1310 }
1311
1312 void UpdateTeamBubble()
1313 {
1314         if (!self.modelindex || !cvar("teamplay"))
1315                 return;
1316         // spawn a teambubble entity if needed
1317         if (!self.teambubbleentity && cvar("teamplay"))
1318         {
1319                 self.teambubbleentity = spawn();
1320                 self.teambubbleentity.owner = self;
1321                 self.teambubbleentity.exteriormodeltoclient = self;
1322                 self.teambubbleentity.think = TeamBubbleThink;
1323                 self.teambubbleentity.nextthink = time;
1324                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1325 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1326                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1327                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1328                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1329                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1330                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1331                 self.teambubbleentity.effects = EF_LOWPRECISION;
1332         }
1333 }
1334
1335 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1336 // added to the model skins
1337 /*void UpdateColorModHack()
1338 {
1339         local float c;
1340         c = self.clientcolors & 15;
1341         // LordHavoc: only bothering to support white, green, red, yellow, blue
1342              if (teamplay == 0) self.colormod = '0 0 0';
1343         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1344         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1345         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1346         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1347         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1348         else self.colormod = '1 1 1';
1349 };*/
1350
1351 void respawn(void)
1352 {
1353         CopyBody(1);
1354         self.effects |= EF_NODRAW; // prevent another CopyBody
1355         PutClientInServer();
1356 }
1357
1358 /**
1359  * When sv_timeout is used this function returs strings like
1360  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1361  * Called by centerprint functions
1362  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1363  */
1364 string getTimeoutText(float addOneSecond) {
1365         if (!cvar("sv_timeout") || !timeoutStatus)
1366                 return "";
1367
1368         local string retStr;
1369         if (timeoutStatus == 1) {
1370                 if (addOneSecond == 1) {
1371                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1372                 }
1373                 else {
1374                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1375                 }
1376                 return retStr;
1377         }
1378         else if (timeoutStatus == 2) {
1379                 if (addOneSecond) {
1380                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1381                         //don't show messages like "Timeout ends in 0 seconds"...
1382                         if ((remainingTimeoutTime + 1) > 0)
1383                                 return retStr;
1384                         else
1385                                 return "";
1386                 }
1387                 else {
1388                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1389                         //don't show messages like "Timeout ends in 0 seconds"...
1390                         if (remainingTimeoutTime > 0)
1391                                 return retStr;
1392                         else
1393                                 return "";
1394                 }
1395         }
1396         else return "";
1397 }
1398
1399 void player_powerups (void)
1400 {
1401         if (g_minstagib)
1402         {
1403                 if (self.items & IT_STRENGTH)
1404                 {
1405                         if (time > self.strength_finished)
1406                         {
1407                                 if (g_minstagib_invis_alpha > 0)
1408                                 {
1409                                         self.alpha = default_player_alpha;
1410                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1411                                         self.effects = self.effects | EF_FULLBRIGHT;
1412                                 }
1413                                 else
1414                                 {
1415                                         self.effects -= self.effects & EF_NODRAW;
1416                                 }
1417                                 self.items = self.items - (self.items & IT_STRENGTH);
1418                                 sprint(self, "^3Invisibility has worn off\n");
1419                         }
1420                 }
1421                 else
1422                 {
1423                         if (time < self.strength_finished)
1424                         {
1425                                 if (g_minstagib_invis_alpha > 0)
1426                                 {
1427                                         self.alpha = g_minstagib_invis_alpha;
1428                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1429                                         self.effects -= self.effects & EF_FULLBRIGHT;
1430                                 }
1431                                 else
1432                                 {
1433                                         self.effects = self.effects | EF_NODRAW;
1434                                 }
1435                                 self.items = self.items | IT_STRENGTH;
1436                                 sprint(self, "^3You are invisible\n");
1437                         }
1438                 }
1439
1440                 if (self.items & IT_INVINCIBLE)
1441                 {
1442                         if (time > self.invincible_finished)
1443                         {
1444                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1445                                 sprint(self, "^3Speed has worn off\n");
1446                         }
1447                 }
1448                 else
1449                 {
1450                         if (time < self.invincible_finished)
1451                         {
1452                                 self.items = self.items | IT_INVINCIBLE;
1453                                 sprint(self, "^3You are on speed\n");
1454                         }
1455                 }
1456                 return;
1457         }
1458
1459         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1460         if (self.items & IT_STRENGTH)
1461         {
1462                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1463                 if (time > self.strength_finished)
1464                 {
1465                         self.items = self.items - (self.items & IT_STRENGTH);
1466                         sprint(self, "^3Strength has worn off\n");
1467                 }
1468         }
1469         else
1470         {
1471                 if (time < self.strength_finished)
1472                 {
1473                         self.items = self.items | IT_STRENGTH;
1474                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1475                 }
1476         }
1477         if (self.items & IT_INVINCIBLE)
1478         {
1479                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1480                 if (time > self.invincible_finished)
1481                 {
1482                         self.items = self.items - (self.items & IT_INVINCIBLE);
1483                         sprint(self, "^3Shield has worn off\n");
1484                 }
1485         }
1486         else
1487         {
1488                 if (time < self.invincible_finished)
1489                 {
1490                         self.items = self.items | IT_INVINCIBLE;
1491                         sprint(self, "^3Shield surrounds you\n");
1492                 }
1493         }
1494
1495         if (cvar("g_fullbrightplayers"))
1496                 self.effects = self.effects | EF_FULLBRIGHT;
1497
1498         // midair gamemode: damage only while in the air
1499         // if in midair mode, being on ground grants temporary invulnerability
1500         // (this is so that multishot weapon don't clear the ground flag on the
1501         // first damage in the frame, leaving the player vulnerable to the
1502         // remaining hits in the same frame)
1503         if (self.flags & FL_ONGROUND)
1504         if (g_midair)
1505                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1506
1507         if (time < self.spawnshieldtime)
1508                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1509 }
1510
1511 float CalcRegen(float current, float stable, float regenfactor)
1512 {
1513         if(current > stable)
1514                 return current;
1515         else if(current > stable - 0.25) // when close enough, "snap"
1516                 return stable;
1517         else
1518                 return min(stable, current + (stable - current) * regenfactor * frametime);
1519 }
1520
1521 void player_regen (void)
1522 {
1523         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1524         maxh = cvar("g_balance_health_stable");
1525         maxa = cvar("g_balance_armor_stable");
1526         limith = cvar("g_balance_health_limit");
1527         limita = cvar("g_balance_armor_limit");
1528
1529         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1530                 return;
1531
1532         max_mod = regen_mod = rot_mod = limit_mod = 1;
1533
1534         if (self.runes & RUNE_REGEN)
1535         {
1536                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1537                 {
1538                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1539                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1540                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1541                 }
1542                 else
1543                 {
1544                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1545                         max_mod = cvar("g_balance_rune_regen_hpmod");
1546                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1547                 }
1548         }
1549         else if (self.runes & CURSE_VENOM)
1550         {
1551                 max_mod = cvar("g_balance_curse_venom_hpmod");
1552                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1553                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1554                 else
1555                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1556                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1557                 //if (!self.runes & RUNE_REGEN)
1558                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1559         }
1560         maxh = maxh * max_mod;
1561         //maxa = maxa * max_mod;
1562         limith = limith * limit_mod;
1563         limita = limita * limit_mod;
1564
1565         if (self.armorvalue > maxa)
1566         {
1567                 if (time > self.pauserotarmor_finished)
1568                 {
1569                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1570                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1571                 }
1572         }
1573         else if (self.armorvalue < maxa)
1574         {
1575                 if (time > self.pauseregen_finished)
1576                 {
1577                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1578                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1579                 }
1580         }
1581         if (self.health > maxh)
1582         {
1583                 if (time > self.pauserothealth_finished)
1584                 {
1585                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1586                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1587                 }
1588         }
1589         else if (self.health < maxh)
1590         {
1591                 if (time > self.pauseregen_finished)
1592                 {
1593                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1594                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1595                 }
1596         }
1597
1598         if (self.health > limith)
1599                 self.health = limith;
1600         if (self.armorvalue > limita)
1601                 self.armorvalue = limita;
1602
1603         // if player rotted to death...  die!
1604         if(self.health < 1)
1605                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1606 }
1607
1608 /*
1609 ======================
1610 spectate mode routines
1611 ======================
1612 */
1613 void SpectateCopy(entity spectatee) {
1614         self.armortype = spectatee.armortype;
1615         self.armorvalue = spectatee.armorvalue;
1616         self.currentammo = spectatee.currentammo;
1617         self.effects = spectatee.effects;
1618         self.health = spectatee.health;
1619         self.impulse = 0;
1620         self.items = spectatee.items;
1621         self.punchangle = spectatee.punchangle;
1622         self.view_ofs = spectatee.view_ofs;
1623         self.v_angle = spectatee.v_angle;
1624         self.viewzoom = spectatee.viewzoom;
1625         self.velocity = spectatee.velocity;
1626         self.dmg_take = spectatee.dmg_take;
1627         self.dmg_save = spectatee.dmg_save;
1628         self.dmg_inflictor = spectatee.dmg_inflictor;
1629         self.angles = spectatee.v_angle;
1630         self.fixangle = TRUE;
1631         setorigin(self, spectatee.origin);
1632         setsize(self, spectatee.mins, spectatee.maxs);
1633 }
1634
1635 float SpectateUpdate() {
1636         if(!self.enemy)
1637                 return 0;
1638
1639         if (self == self.enemy)
1640                 return 0;
1641
1642         if(self.enemy.flags & FL_NOTARGET)
1643                 return 0;
1644
1645         SpectateCopy(self.enemy);
1646
1647         return 1;
1648 }
1649
1650 float SpectateNext() {
1651         other = find(self.enemy, classname, "player");
1652         if (!other) {
1653                 other = find(other, classname, "player");
1654         }
1655         if (other) {
1656                 self.enemy = other;
1657         }
1658         if(self.enemy.classname == "player") {
1659                 msg_entity = self;
1660                 WriteByte(MSG_ONE, SVC_SETVIEW);
1661                 WriteEntity(MSG_ONE, self.enemy);
1662                 self.wantswelcomemessage = 1;
1663                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1664                 if(!SpectateUpdate())
1665                         PutObserverInServer();
1666                 return 1;
1667         } else {
1668                 return 0;
1669         }
1670 }
1671
1672 /*
1673 =============
1674 ShowRespawnCountdown()
1675
1676 Update a respawn countdown display.
1677 =============
1678 */
1679 void ShowRespawnCountdown()
1680 {
1681         float number;
1682         if(self.deadflag == DEAD_NO) // just respawned?
1683                 return;
1684         else
1685         {
1686                 number = ceil(self.death_time - time);
1687                 if(number <= 0)
1688                         return;
1689                 if(number <= self.respawn_countdown)
1690                 {
1691                         self.respawn_countdown = number - 1;
1692                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1693                                 play2(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1694                 }
1695         }
1696 }
1697
1698 void LeaveSpectatorMode()
1699 {
1700         if(isJoinAllowed()) {
1701                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1702                         self.classname = "player";
1703                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1704                                 JoinBestTeam(self, FALSE, TRUE);
1705                         if(cvar("g_campaign"))
1706                                 campaign_bots_may_start = 1;
1707                         PutClientInServer();
1708                         if(!(self.flags & FL_NOTARGET))
1709                                 bprint ("^4", self.netname, "^4 is playing now\n");
1710                         centerprint(self,"");
1711                         return;
1712                 } else {
1713                         stuffcmd(self,"menu_showteamselect\n");
1714                         return;
1715                 }
1716         }
1717         else {
1718                 //player may not join because of g_maxplayers is set
1719                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1720         }
1721 }
1722
1723 /**
1724  * Determines whether the player is allowed to join. This depends on cvar
1725  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1726  * it checks whether the number of currently playing players exceeds g_maxplayers.
1727  * @return bool TRUE if the player is allowed to join, false otherwise
1728  */
1729 float isJoinAllowed() {
1730         if (!cvar("g_maxplayers"))
1731                 return TRUE;
1732
1733         local entity e;
1734         local float currentlyPlaying;
1735         FOR_EACH_REALPLAYER(e) {
1736                 if(e.classname == "player")
1737                         currentlyPlaying += 1;
1738         }
1739         if(currentlyPlaying < cvar("g_maxplayers"))
1740                 return TRUE;
1741
1742         return FALSE;
1743 }
1744
1745 /**
1746  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1747  * g_maxplayers_spectator_blocktime seconds
1748  */
1749 void checkSpectatorBlock() {
1750         if(self.classname == "spectator" || self.classname == "observer") {
1751                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1752                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1753                         dropclient(self);
1754                 }
1755         }
1756 }
1757
1758 float vercmp_recursive(string v1, string v2)
1759 {
1760         float dot1, dot2;
1761         string s1, s2;
1762         float r;
1763
1764         dot1 = strstrofs(v1, ".", 0);
1765         dot2 = strstrofs(v2, ".", 0);
1766         if(dot1 == -1)
1767                 s1 = v1;
1768         else
1769                 s1 = substring(v1, 0, dot1);
1770         if(dot2 == -1)
1771                 s2 = v2;
1772         else
1773                 s2 = substring(v2, 0, dot2);
1774
1775         r = stof(s1) - stof(s2);
1776         if(r != 0)
1777                 return r;
1778
1779         r = strcasecmp(s1, s2);
1780         if(r != 0)
1781                 return r;
1782
1783         if(dot1 == -1)
1784                 if(dot2 == -1)
1785                         return 0;
1786                 else
1787                         return -1;
1788         else
1789                 if(dot2 == -1)
1790                         return 1;
1791                 else
1792                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1793 }
1794
1795 float vercmp(string v1, string v2)
1796 {
1797         if(strcasecmp(v1, v2) == 0) // early out check
1798                 return 0;
1799         return vercmp_recursive(v1, v2);
1800 }
1801
1802 void ObserverThink()
1803 {
1804         if (self.flags & FL_JUMPRELEASED) {
1805                 if (self.BUTTON_JUMP && self.version == cvar("gameversion")) {
1806                         self.welcomemessage_time = 0;
1807                         self.flags = self.flags - FL_JUMPRELEASED;
1808                         LeaveSpectatorMode();
1809                         return;
1810                 } else if(self.BUTTON_ATCK && self.version == cvar("gameversion")) {
1811                         self.welcomemessage_time = 0;
1812                         self.flags = self.flags - FL_JUMPRELEASED;
1813                         if(SpectateNext() == 1) {
1814                                 self.classname = "spectator";
1815                         }
1816                 }
1817         } else {
1818                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
1819                         self.flags = self.flags | FL_JUMPRELEASED;
1820                 }
1821         }
1822         if(self.BUTTON_ZOOM)
1823                 self.wantswelcomemessage = 0;
1824         if(self.wantswelcomemessage)
1825                 PrintWelcomeMessage(self);
1826 }
1827
1828 void SpectatorThink()
1829 {
1830         if (self.flags & FL_JUMPRELEASED) {
1831                 if (self.BUTTON_JUMP && self.version == cvar("gameversion")) {
1832                         self.welcomemessage_time = 0;
1833                         self.flags = self.flags - FL_JUMPRELEASED;
1834                         LeaveSpectatorMode();
1835                         return;
1836                 } else if(self.BUTTON_ATCK) {
1837                         self.welcomemessage_time = 0;
1838                         self.flags = self.flags - FL_JUMPRELEASED;
1839                         if(SpectateNext() == 1) {
1840                                 self.classname = "spectator";
1841                         } else {
1842                                 self.classname = "observer";
1843                                 PutClientInServer();
1844                         }
1845                 } else if (self.BUTTON_ATCK2) {
1846                         self.welcomemessage_time = 0;
1847                         self.flags = self.flags - FL_JUMPRELEASED;
1848                         self.classname = "observer";
1849                         PutClientInServer();
1850                 } else {
1851                         if(!SpectateUpdate())
1852                                 PutObserverInServer();
1853                 }
1854         } else {
1855                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
1856                         self.flags = self.flags | FL_JUMPRELEASED;
1857                 }
1858         }
1859         if(self.BUTTON_ZOOM)
1860                 self.wantswelcomemessage = 0;
1861         if(self.wantswelcomemessage)
1862                 PrintWelcomeMessage(self);
1863         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1864 }
1865
1866 /*
1867 =============
1868 PlayerPreThink
1869
1870 Called every frame for each client before the physics are run
1871 =============
1872 */
1873 void() ctf_setstatus;
1874 .float vote_nagtime;
1875 void PlayerPreThink (void)
1876 {
1877         if(blockSpectators)
1878                 checkSpectatorBlock();
1879
1880         if(self.netname_previous != self.netname)
1881         {
1882                 if(cvar("sv_eventlog"))
1883                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname), TRUE);
1884                 if(self.netname_previous)
1885                         strunzone(self.netname_previous);
1886                 self.netname_previous = strzone(self.netname);
1887         }
1888
1889         // version nagging
1890         if(self.version_nagtime)
1891                 if(self.cvar_g_nexuizversion)
1892                         if(time > self.version_nagtime)
1893                         {
1894                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1895                                 {
1896                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
1897                                         {
1898                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1899                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1900                                         }
1901                                         else
1902                                         {
1903                                                 float r;
1904                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
1905                                                 if(r < 0)
1906                                                 {
1907                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
1908                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
1909                                                 }
1910                                                 else if(r > 0)
1911                                                 {
1912                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1913                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1914                                                 }
1915                                         }
1916                                 }
1917                                 self.version_nagtime = 0;
1918                         }
1919
1920         // vote nagging
1921         if(self.cvar_scr_centertime)
1922                 if(time > self.vote_nagtime)
1923                 {
1924                         VoteNag();
1925                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1926                 }
1927
1928         // GOD MODE info
1929         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
1930         {
1931                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
1932                 self.max_armorvalue = 0;
1933         }
1934
1935         if(frametime)
1936                 antilag_record(self);
1937
1938         if(self.classname == "player") {
1939 //              if(self.netname == "Wazat")
1940 //                      bprint(self.classname, "\n");
1941
1942                 CheckRules_Player();
1943
1944                 if(self.BUTTON_INFO)
1945                         PrintWelcomeMessage(self);
1946
1947                 if(g_lms || !cvar("sv_spectate"))
1948                 if((time - self.jointime) <= cvar("welcome_message_time"))
1949                         PrintWelcomeMessage(self);
1950
1951                 if (intermission_running)
1952                 {
1953                         IntermissionThink ();   // otherwise a button could be missed between
1954                         return;                                 // the think tics
1955                 }
1956
1957                 if(self.teleport_time)
1958                 if(time > self.teleport_time)
1959                 {
1960                         self.teleport_time = 0;
1961                         self.effects = self.effects - (self.effects & EF_NODRAW);
1962                         if(self.weaponentity)
1963                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
1964                 }
1965
1966                 Nixnex_GiveCurrentWeapon();
1967
1968                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
1969                         UpdateSelectedPlayer();
1970
1971                 //don't allow the player to turn around while game is paused!
1972                 if(timeoutStatus == 2) {
1973                         self.v_angle = self.lastV_angle;
1974                         self.angles = self.lastV_angle;
1975                         self.fixangle = TRUE;
1976                 }
1977
1978                 if (self.deadflag != DEAD_NO)
1979                 {
1980                         float button_pressed, force_respawn;
1981                         player_anim();
1982                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
1983                         force_respawn = (g_lms || cvar("g_forced_respawn"));
1984                         if (self.deadflag == DEAD_DYING)
1985                         {
1986                                 if(force_respawn)
1987                                         self.deadflag = DEAD_RESPAWNING;
1988                                 else if(!button_pressed)
1989                                         self.deadflag = DEAD_DEAD;
1990                         }
1991                         else if (self.deadflag == DEAD_DEAD)
1992                         {
1993                                 if(button_pressed)
1994                                         self.deadflag = DEAD_RESPAWNABLE;
1995                         }
1996                         else if (self.deadflag == DEAD_RESPAWNABLE)
1997                         {
1998                                 if(!button_pressed)
1999                                         self.deadflag = DEAD_RESPAWNING;
2000                         }
2001                         else if (self.deadflag == DEAD_RESPAWNING)
2002                         {
2003                                 if(time > self.death_time)
2004                                 {
2005                                         self.death_time = time + 1; // only retry once a second
2006                                         respawn();
2007                                 }
2008                         }
2009                         ShowRespawnCountdown();
2010                         return;
2011                 }
2012
2013                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2014                 {
2015                         vector dist;
2016
2017                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2018                         dist = self.oldorigin - self.origin;
2019                         dist_z = 0;
2020                         self.lms_traveled_distance += fabs(vlen(dist));
2021
2022                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
2023                         {
2024                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2025                                 self.lms_traveled_distance = 0;
2026                         }
2027
2028                         if(time > self.lms_nextcheck)
2029                         {
2030                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2031                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2032                                 {
2033                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2034                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2035                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2036                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2037                                 }
2038                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2039                                 self.lms_traveled_distance = 0;
2040                         }
2041                 }
2042
2043                 if (self.BUTTON_CROUCH && !self.hook.state)
2044                 {
2045                         if (!self.crouch)
2046                         {
2047                                 self.crouch = TRUE;
2048                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2049                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2050                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
2051                         }
2052                 }
2053                 else
2054                 {
2055                         if (self.crouch)
2056                         {
2057                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2058                                 if (!trace_startsolid)
2059                                 {
2060                                         self.crouch = FALSE;
2061                                         self.view_ofs = PL_VIEW_OFS;
2062                                         setsize (self, PL_MIN, PL_MAX);
2063                                 }
2064                         }
2065                 }
2066
2067                 FixPlayermodel();
2068
2069                 GrapplingHookFrame();
2070
2071                 W_WeaponFrame();
2072
2073                 {
2074                         float zoomfactor, zoomspeed, zoomdir;
2075                         zoomfactor = self.cvar_cl_zoomfactor;
2076                         if(zoomfactor < 1 || zoomfactor > 16)
2077                                 zoomfactor = 2.5;
2078                         zoomspeed = self.cvar_cl_zoomspeed;
2079                         if(zoomspeed >= 0) // < 0 is instant zoom
2080                                 if(zoomspeed < 0.5 || zoomspeed > 16)
2081                                         zoomspeed = 3.5;
2082
2083                         zoomdir = self.BUTTON_ZOOM;
2084                         if(self.BUTTON_ATCK2)
2085                                 if(self.weapon == WEP_NEX)
2086                                         if(!g_minstagib)
2087                                                 zoomdir = 1;
2088
2089                         if(zoomdir)
2090                                 self.has_zoomed = 1;
2091
2092                         if(self.has_zoomed)
2093                         {
2094                                 if(zoomspeed <= 0) // instant zoom
2095                                 {
2096                                         if(zoomdir)
2097                                                 self.viewzoom = 1 / zoomfactor;
2098                                         else
2099                                                 self.viewzoom = 1;
2100                                 }
2101                                 else
2102                                 {
2103                                         // geometric zoom would be:
2104                                         //   self.viewzoom = bound(1 / zoomfactor, self.viewzoom * pow(zoomfactor, (zoomdir ? -1 : 1) * frametime * zoomspeed), 1);
2105                                         // however, testing showed that arithmetic/harmonic zoom works better
2106                                         if(zoomdir)
2107                                                 // self.viewzoom = 1 / bound(1, 1 / self.viewzoom + (zoomdir ? 1 : -1) * frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2108                                                 // zoom in = arithmetic: 1x, 2x, 3x, 4x, ..., 8x
2109                                                 self.viewzoom = 1 / bound(1, 1 / self.viewzoom + frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2110                                         else
2111                                                 // self.viewzoom = bound(1 / zoomfactor, self.viewzoom + (zoomdir ? -1 : 1) * frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2112                                                 // zoom out = harmonic: 8/1x, 8/2x, 8/3x, 8/4x, ..., 8/8x
2113                                                 self.viewzoom = bound(1 / zoomfactor, self.viewzoom + frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2114                                 }
2115                         }
2116                         else
2117                                 self.viewzoom = min(1, self.viewzoom + frametime); // spawn zoom-in
2118                 }
2119
2120                 player_powerups();
2121                 player_regen();
2122                 player_anim();
2123
2124                 if (g_minstagib)
2125                         minstagib_ammocheck();
2126
2127                 ctf_setstatus();
2128                 kh_setstatus();
2129
2130                 //self.angles_y=self.v_angle_y + 90;   // temp
2131
2132                 //if (TetrisPreFrame()) return;
2133         } else if(gameover) {
2134                 if (intermission_running)
2135                         IntermissionThink ();   // otherwise a button could be missed between
2136                 return;
2137         } else if(self.classname == "observer") {
2138                 ObserverThink();
2139         } else if(self.classname == "spectator") {
2140                 SpectatorThink();
2141         }
2142 }
2143
2144
2145 /*
2146 =============
2147 PlayerPostThink
2148
2149 Called every frame for each client after the physics are run
2150 =============
2151 */
2152 .float idlekick_lasttimeleft;
2153 void PlayerPostThink (void)
2154 {
2155         // Savage: Check for nameless players
2156         if (strlen(self.netname) < 1) {
2157                 self.netname = "Player";
2158                 stuffcmd(self, "seta _cl_name Player\n");
2159         }
2160
2161         if(sv_maxidle)
2162         {
2163                 float timeleft;
2164                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2165                 if(timeleft <= 0)
2166                 {
2167                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2168                         play2(self, "announcer/robotic/terminated.ogg");
2169                         dropclient(self);
2170                         return;
2171                 }
2172                 else if(timeleft <= 10)
2173                 {
2174                         if(timeleft != self.idlekick_lasttimeleft)
2175                         {
2176                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2177                                 play2(self, strcat("announcer/robotic/", ftos(timeleft), ".ogg"));
2178                         }
2179                 }
2180                 else
2181                 {
2182                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2183                 }
2184                 self.idlekick_lasttimeleft = timeleft;
2185         }
2186
2187         if(self.classname == "player") {
2188                 CheckRules_Player();
2189                 UpdateChatBubble();
2190                 UpdateTeamBubble();
2191                 if (self.impulse)
2192                         ImpulseCommands();
2193                 if (intermission_running)
2194                         return;         // intermission or finale
2195
2196                 //PrintWelcomeMessage(self);
2197                 //if (TetrisPostFrame()) return;
2198
2199                 // restart countdown
2200                 if (restart_countdown) {
2201                         if(time < restart_countdown) {
2202                                 if (!cvar("sv_ready_restart_after_countdown"))
2203                                 {
2204                                         self.movetype = MOVETYPE_NONE;
2205                                         self.velocity = '0 0 0';
2206                                         self.avelocity = '0 0 0';
2207                                         self.movement = '0 0 0';
2208                                 }
2209                         }
2210                         else
2211                         {
2212                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2213                                 if (!cvar("sv_ready_restart_after_countdown"))
2214                                 {
2215                                         if(self.movetype == MOVETYPE_NONE)
2216                                         {
2217                                                 self.movetype = MOVETYPE_WALK;
2218                                         }
2219                                 }
2220                         }
2221                 }
2222
2223         } else if (self.classname == "observer") {
2224                 //do nothing
2225         } else if (self.classname == "spectator") {
2226                 //do nothing
2227         }
2228
2229         /*
2230         float i;
2231         for(i = 0; i < 1000; ++i)
2232         {
2233                 vector end;
2234                 end = self.origin + '0 0 1024' + 512 * randomvec();
2235                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2236                 if(trace_fraction < 1)
2237                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2238                 {
2239                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2240                         break;
2241                 }
2242         }
2243         */
2244
2245         Arena_Warmup();
2246 }