data/qcsrc/server/cl_client.qc

   1 .float wantswelcomemessage;
   2 .string netname_previous;
   3
   4 void spawnfunc_info_player_survivor (void)
   5 {
   6         spawnfunc_info_player_deathmatch();
   7 }
   8
   9 void spawnfunc_info_player_start (void)
  10 {
  11         spawnfunc_info_player_deathmatch();
  12 }
  13
  14 void spawnfunc_info_player_deathmatch (void)
  15 {
  16         self.classname = "info_player_deathmatch";
  17         relocate_spawnpoint();
  18 }
  19
  20 void spawnpoint_use()
  21 {
  22         if(teams_matter)
  23         if(have_team_spawns)
  24         {
  25                 self.team = activator.team;
  26                 some_spawn_has_been_used = 1;
  27         }
  28 };
  29
  30 // Returns:
  31 //   -1 if a spawn can't be used
  32 //   otherwise, a weight of the spawnpoint
  33 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
  34 {
  35         float shortest, thisdist;
  36         entity player;
  37
  38         // filter out spots for the wrong team
  39         if(teamcheck)
  40         if(spot.team != teamcheck)
  41                 return -1;
  42
  43         // filter out spots for assault
  44         if(spot.target != "") {
  45                 local entity ent;
  46                 ent = find(world, targetname, spot.target);
  47                 while(ent) {
  48                         if(ent.classname == "target_objective")
  49                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  50                                         return -1;
  51                         ent = find(ent, targetname, spot.target);
  52                 }
  53         }
  54
  55         player = playerlist;
  56         shortest = vlen(world.maxs - world.mins);
  57         for(player = playerlist; player; player = player.chain)
  58                 if (player != self)
  59                 {
  60                         thisdist = vlen(player.origin - spot.origin);
  61                         if (thisdist < shortest)
  62                                 shortest = thisdist;
  63                 }
  64         return shortest;
  65 }
  66
  67 float spawn_allbad;
  68 float spawn_allgood;
  69 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  70 {
  71         local entity spot, spotlist, spotlistend;
  72         spawn_allgood = TRUE;
  73         spawn_allbad = TRUE;
  74
  75         spotlist = world;
  76         spotlistend = world;
  77
  78         for(spot = firstspot; spot; spot = spot.chain)
  79         {
  80                 spot.frags = Spawn_Score(spot, playerlist, teamcheck);
  81
  82                 if(cvar("spawn_debugview"))
  83                 {
  84                         setmodel(spot, "models/runematch/rune.mdl");
  85                         if(spot.frags < mindist)
  86                         {
  87                                 spot.colormod = '1 0 0';
  88                                 spot.scale = 1;
  89                         }
  90                         else
  91                         {
  92                                 spot.colormod = '0 1 0';
  93                                 spot.scale = spot.frags / mindist;
  94                         }
  95                 }
  96
  97                 if(spot.frags >= 0) // spawning allowed here
  98                 {
  99                         if(spot.frags < mindist)
 100                         {
 101                                 // too short distance
 102                                 spawn_allgood = FALSE;
 103                         }
 104                         else
 105                         {
 106                                 // perfect
 107                                 spawn_allbad = FALSE;
 108
 109                                 if(spotlistend)
 110                                         spotlistend.chain = spot;
 111                                 spotlistend = spot;
 112                                 if(!spotlist)
 113                                         spotlist = spot;
 114
 115                                 /*
 116                                 if(teamcheck)
 117                                 if(spot.team != teamcheck)
 118                                         error("invalid spawn added");
 119
 120                                 print("added ", etos(spot), "\n");
 121                                 */
 122                         }
 123                 }
 124         }
 125         if(spotlistend)
 126                 spotlistend.chain = world;
 127
 128         /*
 129                 entity e;
 130                 if(teamcheck)
 131                         for(e = spotlist; e; e = e.chain)
 132                         {
 133                                 print("seen ", etos(e), "\n");
 134                                 if(e.team != teamcheck)
 135                                         error("invalid spawn found");
 136                         }
 137         */
 138
 139         return spotlist;
 140 }
 141
 142 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 143 {
 144         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 145         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 146         local entity spot;
 147
 148         RandomSelection_Init();
 149         for(spot = firstspot; spot; spot = spot.chain)
 150                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.frags, upper), exponent) * spot.cnt, spot.frags >= lower);
 151
 152         return RandomSelection_chosen_ent;
 153 }
 154
 155 /*
 156 =============
 157 SelectSpawnPoint
 158
 159 Finds a point to respawn
 160 =============
 161 */
 162 entity SelectSpawnPoint (float anypoint)
 163 {
 164         local float teamcheck;
 165         local entity firstspot_new;
 166         local entity spot, firstspot, playerlist;
 167
 168         spot = find (world, classname, "testplayerstart");
 169         if (spot)
 170                 return spot;
 171
 172         teamcheck = 0;
 173
 174         if(!anypoint && have_team_spawns)
 175                 teamcheck = self.team;
 176
 177         // get the list of players
 178         playerlist = findchain(classname, "player");
 179         // get the entire list of spots
 180         firstspot = findchain(classname, "info_player_deathmatch");
 181         // filter out the bad ones
 182         // (note this returns the original list if none survived)
 183         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 184         if(!firstspot_new)
 185                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 186         firstspot = firstspot_new;
 187
 188         // there is 50/50 chance of choosing a random spot or the furthest spot
 189         // (this means that roughly every other spawn will be furthest, so you
 190         // usually won't get fragged at spawn twice in a row)
 191         if (arena_roundbased)
 192         {
 193                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 194                 if(firstspot_new)
 195                         firstspot = firstspot_new;
 196                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 197         }
 198         else if (random() > cvar("g_spawn_furthest"))
 199                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 200         else
 201                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 202
 203         if(cvar("spawn_debugview"))
 204         {
 205                 print("spot mindistance: ", ftos(spot.frags), "\n");
 206
 207                 entity e;
 208                 if(teamcheck)
 209                         for(e = firstspot; e; e = e.chain)
 210                                 if(e.team != teamcheck)
 211                                         error("invalid spawn found");
 212         }
 213
 214         if (!spot)
 215         {
 216                 if(cvar("spawn_debug"))
 217                         GotoNextMap();
 218                 else
 219                 {
 220                         if(some_spawn_has_been_used)
 221                                 return world; // team can't spawn any more, because of actions of other team
 222                         else
 223                                 error("Cannot find a spawn point - please fix the map!");
 224                 }
 225         }
 226
 227         return spot;
 228 }
 229
 230 /*
 231 =============
 232 CheckPlayerModel
 233
 234 Checks if the argument string can be a valid playermodel.
 235 Returns a valid one in doubt.
 236 =============
 237 */
 238 string FallbackPlayerModel = "models/player/marine.zym";
 239 string CheckPlayerModel(string plyermodel) {
 240         if(strlen(plyermodel) < 4)
 241                 return FallbackPlayerModel;
 242         if( substring(plyermodel,0,14) != "models/player/")
 243                 return FallbackPlayerModel;
 244         else if(cvar("sv_servermodelsonly"))
 245         {
 246                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 247                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 248                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 249                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 250                         return FallbackPlayerModel;
 251                 if(!fexists(plyermodel))
 252                         return FallbackPlayerModel;
 253         }
 254         return plyermodel;
 255 }
 256
 257 /*
 258 =============
 259 Client_customizeentityforclient
 260
 261 LOD reduction
 262 =============
 263 */
 264 float Client_customizeentityforclient()
 265 {
 266 #ifdef ALLOW_VARIABLE_LOD
 267         // self: me
 268         // other: the player viewing me
 269         float distance;
 270         float f;
 271
 272         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 273                 return TRUE;
 274
 275         if(other.cvar_cl_playerdetailreduction <= 0)
 276         {
 277                 if(other.cvar_cl_playerdetailreduction <= -2)
 278                         self.modelindex = self.modelindex_lod2;
 279                 else if(other.cvar_cl_playerdetailreduction <= -1)
 280                         self.modelindex = self.modelindex_lod1;
 281                 else
 282                         self.modelindex = self.modelindex_lod0;
 283         }
 284         else
 285         {
 286                 distance = vlen(self.origin - other.origin);
 287                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 288                 if(f > 10000)
 289                         self.modelindex = self.modelindex_lod2;
 290                 else if(f > 5000)
 291                         self.modelindex = self.modelindex_lod1;
 292                 else
 293                         self.modelindex = self.modelindex_lod0;
 294         }
 295 #endif
 296
 297         return TRUE;
 298 }
 299
 300 void UpdatePlayerSounds();
 301 void setmodel_lod(entity e, string modelname)
 302 {
 303 #ifdef ALLOW_VARIABLE_LOD
 304         string s;
 305
 306         // FIXME: this only supports 3-letter extensions
 307         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 308         if(fexists(s))
 309         {
 310                 precache_model(s);
 311                 setmodel(e, s); // players have high precision
 312                 self.modelindex_lod1 = self.modelindex;
 313         }
 314         else
 315                 self.modelindex_lod1 = -1;
 316
 317         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 318         if(fexists(s))
 319         {
 320                 precache_model(s);
 321                 setmodel(e, s); // players have high precision
 322                 self.modelindex_lod2 = self.modelindex;
 323         }
 324         else
 325                 self.modelindex_lod2 = -1;
 326
 327         precache_model(modelname);
 328         setmodel(e, modelname); // players have high precision
 329         self.modelindex_lod0 = self.modelindex;
 330
 331         if(self.modelindex_lod1 < 0)
 332                 self.modelindex_lod1 = self.modelindex;
 333
 334         if(self.modelindex_lod2 < 0)
 335                 self.modelindex_lod2 = self.modelindex;
 336 #else
 337         precache_model(modelname);
 338         setmodel(e, modelname); // players have high precision
 339 #endif
 340         player_setupanimsformodel();
 341         UpdatePlayerSounds();
 342 }
 343
 344 /*
 345 =============
 346 PutObserverInServer
 347
 348 putting a client as observer in the server
 349 =============
 350 */
 351 void ctf_UpdateCaptures(float);
 352 void ctf_UpdateReturns(float);
 353 void PutObserverInServer (void)
 354 {
 355         entity  spot;
 356         spot = SelectSpawnPoint (TRUE);
 357         if(!spot)
 358                 error("No spawnpoints for observers?!?\n");
 359         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 360
 361         if(clienttype(self) == CLIENTTYPE_REAL)
 362         {
 363                 msg_entity = self;
 364                 WriteByte(MSG_ONE, SVC_SETVIEW);
 365                 WriteEntity(MSG_ONE, self);
 366         }
 367
 368         DropAllRunes(self);
 369         kh_Key_DropAll(self, TRUE);
 370
 371         if(self.flagcarried)
 372                 DropFlag(self.flagcarried);
 373
 374         WaypointSprite_PlayerDead();
 375
 376         if(self.killcount != -666)
 377         {
 378                 if(g_lms)
 379                 {
 380                         if(PlayerScoreAdd(self, SP_LMS_PLACE, 0) > 0)
 381                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 382                         else
 383                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 384                 }
 385                 else
 386                         bprint ("^4", self.netname, "^4 is spectating now\n");
 387         }
 388
 389         PlayerScore_Clear(self); // clear scores when needed
 390
 391         self.spectatortime = time;
 392
 393         self.classname = "observer";
 394         self.health = -666;
 395         self.takedamage = DAMAGE_NO;
 396         self.solid = SOLID_NOT;
 397         self.movetype = MOVETYPE_NOCLIP;
 398         self.flags = FL_CLIENT | FL_NOTARGET;
 399         self.armorvalue = 666;
 400         self.effects = 0;
 401         self.armorvalue = cvar("g_balance_armor_start");
 402         self.pauserotarmor_finished = 0;
 403         self.pauserothealth_finished = 0;
 404         self.pauseregen_finished = 0;
 405         self.damageforcescale = 0;
 406         self.death_time = 0;
 407         self.dead_frame = 0;
 408         self.deaths = 0;
 409         self.captures = 0;
 410         self.returns = 0;
 411         self.alpha = 0;
 412         self.scale = 0;
 413         self.fade_time = 0;
 414         self.pain_frame = 0;
 415         self.pain_finished = 0;
 416         self.strength_finished = 0;
 417         self.invincible_finished = 0;
 418         self.pushltime = 0;
 419         self.think = SUB_Null;
 420         self.nextthink = 0;
 421         self.hook_time = 0;
 422         self.runes = 0;
 423         self.deadflag = DEAD_NO;
 424         self.angles = spot.angles;
 425         self.angles_z = 0;
 426         self.fixangle = TRUE;
 427         self.crouch = FALSE;
 428
 429         self.view_ofs = PL_VIEW_OFS;
 430         setorigin (self, spot.origin);
 431         setsize (self, '0 0 0', '0 0 0');
 432         self.oldorigin = self.origin;
 433         self.items = 0;
 434         self.model = "";
 435         self.modelindex = 0;
 436         self.weapon = 0;
 437         self.weaponmodel = "";
 438         self.weaponentity = world;
 439         self.killcount = -666;
 440         self.velocity = '0 0 0';
 441         self.avelocity = '0 0 0';
 442         self.punchangle = '0 0 0';
 443         self.punchvector = '0 0 0';
 444         self.oldvelocity = self.velocity;
 445         self.customizeentityforclient = Client_customizeentityforclient;
 446         self.viewzoom = 1;
 447         self.wantswelcomemessage = 1;
 448
 449         if(g_arena)
 450         {
 451                 if(self.frags != -2)
 452                 {
 453                         Spawnqueue_Insert(self);
 454                         // FIXME what IS this?
 455                 }
 456                 else
 457                 {
 458                         Spawnqueue_Unmark(self);
 459                         Spawnqueue_Remove(self);
 460                 }
 461         }
 462         else
 463                 self.frags = -666;
 464
 465         net_UpdateDeaths(MSG_BROADCAST);
 466 }
 467
 468 float RestrictSkin(float s)
 469 {
 470         if(!teams_matter)
 471                 return s;
 472         if(s == 6)
 473                 return 6;
 474         return mod(s, 3);
 475 }
 476
 477 void FixPlayermodel()
 478 {
 479         local string defaultmodel;
 480         local float defaultskin;
 481         local vector m1, m2;
 482
 483         defaultmodel = "";
 484
 485         if(cvar("sv_defaultcharacter") == 1) {
 486                 defaultskin = 0;
 487
 488                 if(teams_matter)
 489                 {
 490                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 491                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 492                 }
 493
 494                 if(defaultmodel == "")
 495                 {
 496                         defaultmodel = cvar_string("sv_defaultplayermodel");
 497                         defaultskin = cvar("sv_defaultplayerskin");
 498                 }
 499         }
 500
 501         if(defaultmodel != "")
 502         {
 503                 if (defaultmodel != self.model)
 504                 {
 505                         m1 = self.mins;
 506                         m2 = self.maxs;
 507                         setmodel_lod (self, defaultmodel);
 508                         setsize (self, m1, m2);
 509                 }
 510
 511                 self.skin = defaultskin;
 512         } else {
 513                 if (self.playermodel != self.model)
 514                 {
 515                         self.playermodel = CheckPlayerModel(self.playermodel);
 516                         m1 = self.mins;
 517                         m2 = self.maxs;
 518                         setmodel_lod (self, self.playermodel);
 519                         setsize (self, m1, m2);
 520                 }
 521
 522                 self.skin = RestrictSkin(stof(self.playerskin));
 523         }
 524
 525         if(!teams_matter)
 526                 if(strlen(cvar_string("sv_defaultplayercolors")))
 527                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 528                                 setcolor(self, cvar("sv_defaultplayercolors"));
 529 }
 530
 531 /*
 532 =============
 533 PutClientInServer
 534
 535 Called when a client spawns in the server
 536 =============
 537 */
 538 //void() ctf_playerchanged;
 539 void PutClientInServer (void)
 540 {
 541         if(clienttype(self) == CLIENTTYPE_BOT)
 542         {
 543                 self.classname = "player";
 544         }
 545         else if(clienttype(self) == CLIENTTYPE_REAL)
 546         {
 547                 msg_entity = self;
 548                 WriteByte(MSG_ONE, SVC_SETVIEW);
 549                 WriteEntity(MSG_ONE, self);
 550         }
 551
 552         // player is dead and becomes observer
 553         // FIXME fix LMS scoring for new system
 554         if(g_lms)
 555         {
 556                 if(PlayerScoreAdd(self, SP_LMS_PLACE, 0) > 0)
 557                         self.classname = "observer";
 558         }
 559
 560         if(g_arena)
 561         if(!self.spawned)
 562                 self.classname = "observer";
 563
 564         if(self.classname == "player") {
 565                 entity  spot;
 566
 567                 spot = SelectSpawnPoint (FALSE);
 568                 if(!spot)
 569                 {
 570                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 571                         return; // spawn failed
 572                 }
 573
 574                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 575
 576                 self.classname = "player";
 577                 self.iscreature = TRUE;
 578                 self.movetype = MOVETYPE_WALK;
 579                 self.solid = SOLID_SLIDEBOX;
 580                 self.flags = FL_CLIENT;
 581                 self.takedamage = DAMAGE_AIM;
 582                 if(g_minstagib)
 583                         self.effects = EF_FULLBRIGHT;
 584                 else
 585                         self.effects = 0;
 586                 self.air_finished = time + 12;
 587                 self.dmg = 2;
 588
 589                 self.ammo_shells = start_ammo_shells;
 590                 self.ammo_nails = start_ammo_nails;
 591                 self.ammo_rockets = start_ammo_rockets;
 592                 self.ammo_cells = start_ammo_cells;
 593                 self.health = start_health;
 594                 self.armorvalue = start_armorvalue;
 595                 self.items = start_items;
 596                 self.switchweapon = start_switchweapon;
 597                 self.cnt = start_switchweapon;
 598                 self.weapon = 0;
 599                 self.jump_interval = time;
 600
 601                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 602                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 603                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 604                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 605                 //extend the pause of rotting if client was reset at the beginning of the countdown
 606                 if(!cvar("sv_ready_restart_after_countdown") && time < restart_countdown) {
 607                         self.spawnshieldtime += RESTART_COUNTDOWN;
 608                         self.pauserotarmor_finished += RESTART_COUNTDOWN;
 609                         self.pauserothealth_finished += RESTART_COUNTDOWN;
 610                         self.pauseregen_finished += RESTART_COUNTDOWN;
 611                 }
 612                 self.damageforcescale = 2;
 613                 self.death_time = 0;
 614                 self.dead_frame = 0;
 615                 self.alpha = 0;
 616                 self.scale = 0;
 617                 self.fade_time = 0;
 618                 self.pain_frame = 0;
 619                 self.pain_finished = 0;
 620                 self.strength_finished = 0;
 621                 self.invincible_finished = 0;
 622                 self.pushltime = 0;
 623                 //self.speed_finished = 0;
 624                 //self.slowmo_finished = 0;
 625                 // players have no think function
 626                 self.think = SUB_Null;
 627                 self.nextthink = 0;
 628                 self.hook_time = 0;
 629
 630                 self.runes = 0;
 631
 632                 self.deadflag = DEAD_NO;
 633
 634                 self.angles = spot.angles;
 635
 636                 self.angles_z = 0; // never spawn tilted even if the spot says to
 637                 self.fixangle = TRUE; // turn this way immediately
 638                 self.velocity = '0 0 0';
 639                 self.avelocity = '0 0 0';
 640                 self.punchangle = '0 0 0';
 641                 self.punchvector = '0 0 0';
 642                 self.oldvelocity = self.velocity;
 643
 644                 self.viewzoom = 0.6;
 645                 self.has_zoomed = 0;
 646
 647                 self.customizeentityforclient = Client_customizeentityforclient;
 648
 649                 self.model = "";
 650                 FixPlayermodel();
 651
 652                 self.crouch = FALSE;
 653                 self.view_ofs = PL_VIEW_OFS;
 654                 setsize (self, PL_MIN, PL_MAX);
 655                 self.spawnorigin = spot.origin;
 656                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 657                 // don't reset back to last position, even if new position is stuck in solid
 658                 self.oldorigin = self.origin;
 659
 660                 if(g_arena)
 661                 {
 662                         Spawnqueue_Remove(self);
 663                         Spawnqueue_Mark(self);
 664                 }
 665
 666                 self.event_damage = PlayerDamage;
 667
 668                 self.bot_attack = TRUE;
 669
 670                 self.statdraintime = time + 5;
 671                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 672
 673                 if(self.killcount == -666) {
 674                         PlayerScore_Clear(self);
 675                         self.killcount = 0;
 676                         self.frags = 0;
 677                 }
 678
 679                 self.cnt = WEP_LASER;
 680                 self.nixnex_lastchange_id = -1;
 681
 682                 CL_SpawnWeaponentity();
 683                 self.alpha = default_player_alpha;
 684                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 685                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 686
 687                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 688                 self.lms_traveled_distance = 0;
 689                 self.speedrunning = FALSE;
 690
 691                 if(cvar("spawn_debug"))
 692                 {
 693                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 694                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 695                 }
 696
 697                 //stuffcmd(self, "chase_active 0");
 698                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 699
 700                 if (cvar("g_spawnsound"))
 701                         sound (self, CHAN_AUTO, "misc/spawn.wav", 1, ATTN_NORM);
 702
 703                 if(g_assault) {
 704                         if(self.team == assault_attacker_team)
 705                                 centerprint(self, "You are attacking!\n");
 706                         else
 707                                 centerprint(self, "You are defending!\n");
 708                 }
 709
 710         } else if(self.classname == "observer") {
 711                 PutObserverInServer ();
 712         }
 713
 714         //if(g_ctf)
 715         //      ctf_playerchanged();
 716 }
 717
 718 /*
 719 =============
 720 SendCSQCInfo
 721
 722 Send whatever CSQC needs NOW and cannot wait for SendServerInfo to happen...
 723 =============
 724 */
 725 void SendCSQCInfo(void)
 726 {
 727         if(clienttype(self) != CLIENTTYPE_REAL)
 728                 return;
 729         msg_entity = self;
 730         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 731         WriteByte(MSG_ONE, TE_CSQC_INIT);
 732         WriteShort(MSG_ONE, CSQC_REVISION);
 733         WriteByte(MSG_ONE, maxclients);
 734 }
 735
 736 /*
 737 =============
 738 SetNewParms
 739 =============
 740 */
 741 void SetNewParms (void)
 742 {
 743         // initialize parms for a new player
 744         parm1 = -(86400 * 366);
 745 }
 746
 747 /*
 748 =============
 749 SetChangeParms
 750 =============
 751 */
 752 void SetChangeParms (void)
 753 {
 754         // save parms for level change
 755         parm1 = self.parm_idlesince - time;
 756 }
 757
 758 /*
 759 =============
 760 DecodeLevelParms
 761 =============
 762 */
 763 void DecodeLevelParms (void)
 764 {
 765         // load parms
 766         self.parm_idlesince = parm1;
 767         if(self.parm_idlesince == -(86400 * 366))
 768                 self.parm_idlesince = time;
 769 }
 770
 771 /*
 772 =============
 773 ClientKill
 774
 775 Called when a client types 'kill' in the console
 776 =============
 777 */
 778
 779 void ClientKill_Now_TeamChange()
 780 {
 781         if(g_ctf)
 782         {
 783                 self.captures = 0;
 784                 self.returns = 0;
 785                 ctf_UpdateCaptures(MSG_BROADCAST);
 786                 ctf_UpdateReturns(MSG_BROADCAST);
 787         }
 788         self.deaths = 0;
 789         net_UpdateDeaths(MSG_BROADCAST);
 790         if(self.killindicator_teamchange == -1)
 791         {
 792                 self.team = -1;
 793                 JoinBestTeam( self, FALSE, FALSE );
 794         }
 795         else
 796         {
 797                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 798         }
 799 }
 800
 801 void ClientKill_Now()
 802 {
 803         if(self.killindicator_teamchange)
 804                 ClientKill_Now_TeamChange();
 805
 806         // in any case:
 807         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 808 }
 809 void KillIndicator_Think()
 810 {
 811         if (!self.owner.modelindex)
 812         {
 813                 self.owner.killindicator = world;
 814                 remove(self);
 815                 return;
 816         }
 817
 818         if(self.cnt <= 0)
 819         {
 820                 self = self.owner;
 821                 ClientKill_Now(); // no oldself needed
 822                 return;
 823         }
 824         else
 825         {
 826                 if(self.cnt <= 10)
 827                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 828                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 829                 {
 830                         if(self.cnt <= 10)
 831                                 play2(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 832                         if(self.owner.killindicator_teamchange)
 833                         {
 834                                 if(self.owner.killindicator_teamchange == -1)
 835                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 836                                 else
 837                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 838                         }
 839                         else
 840                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 841                 }
 842                 self.nextthink = time + 1;
 843                 self.cnt -= 1;
 844         }
 845 }
 846
 847 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 848 {
 849         float killtime;
 850         entity e;
 851         killtime = cvar("g_balance_kill_delay");
 852
 853         self.killindicator_teamchange = targetteam;
 854
 855         if(!self.killindicator)
 856         {
 857                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 858                 {
 859                         ClientKill_Now();
 860                 }
 861                 else
 862                 {
 863                         self.killindicator = spawn();
 864                         self.killindicator.owner = self;
 865                         self.killindicator.scale = 0.5;
 866                         setattachment(self.killindicator, self, "");
 867                         setorigin(self.killindicator, '0 0 52');
 868                         self.killindicator.think = KillIndicator_Think;
 869                         self.killindicator.nextthink = time + (self.lip) * 0.05;
 870                         self.killindicator.cnt = ceil(killtime);
 871                         self.killindicator.count = bound(0, ceil(killtime), 10);
 872                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 873
 874                         for(e = world; (e = find(e, classname, "body")) != world; )
 875                         {
 876                                 if(e.enemy != self)
 877                                         continue;
 878                                 e.killindicator = spawn();
 879                                 e.killindicator.owner = e;
 880                                 e.killindicator.scale = 0.5;
 881                                 setattachment(e.killindicator, e, "");
 882                                 setorigin(e.killindicator, '0 0 52');
 883                                 e.killindicator.think = KillIndicator_Think;
 884                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
 885                                 e.killindicator.cnt = ceil(killtime);
 886                         }
 887                         self.lip = 0;
 888                 }
 889         }
 890         if(self.killindicator)
 891         {
 892                 if(targetteam)
 893                         self.killindicator.colormod = TeamColor(targetteam);
 894                 else
 895                         self.killindicator.colormod = '0 0 0';
 896         }
 897 }
 898
 899 void ClientKill (void)
 900 {
 901         ClientKill_TeamChange(0);
 902 }
 903
 904 void DoTeamChange(float destteam)
 905 {
 906         float t, c0;
 907         if(!cvar("teamplay"))
 908         {
 909                 if(destteam >= 0)
 910                         SetPlayerColors(self, destteam);
 911                 return;
 912         }
 913         if(self.classname == "player")
 914         if(destteam == -1)
 915         {
 916                 CheckAllowedTeams(self);
 917                 t = FindSmallestTeam(self, TRUE);
 918                 switch(self.team)
 919                 {
 920                         case COLOR_TEAM1: c0 = c1; break;
 921                         case COLOR_TEAM2: c0 = c2; break;
 922                         case COLOR_TEAM3: c0 = c3; break;
 923                         case COLOR_TEAM4: c0 = c4; break;
 924                         default:          c0 = 999;
 925                 }
 926                 switch(t)
 927                 {
 928                         case 1:
 929                                 if(c0 > c1)
 930                                         destteam = COLOR_TEAM1;
 931                                 break;
 932                         case 2:
 933                                 if(c0 > c2)
 934                                         destteam = COLOR_TEAM2;
 935                                 break;
 936                         case 3:
 937                                 if(c0 > c3)
 938                                         destteam = COLOR_TEAM3;
 939                                 break;
 940                         case 4:
 941                                 if(c0 > c4)
 942                                         destteam = COLOR_TEAM4;
 943                                 break;
 944                 }
 945                 if(destteam == -1)
 946                         return;
 947         }
 948         if(destteam == self.team && !self.killindicator)
 949                 return;
 950         ClientKill_TeamChange(destteam);
 951 }
 952
 953 void FixClientCvars(entity e)
 954 {
 955         // send prediction settings to the client
 956         stuffcmd(e, "\nin_bindmap 0 0\n");
 957         /*
 958          * we no longer need to stuff this. Remove this comment block if you feel
 959          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 960         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
 961         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 962         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 963         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 964         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 965         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 966         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 967         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
 968         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 969         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 970         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 971         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 972         stuffcmd(e, "cl_movement_edgefriction 1\n");
 973          */
 974 }
 975
 976 /*
 977 =============
 978 ClientConnect
 979
 980 Called when a client connects to the server
 981 =============
 982 */
 983 //void ctf_clientconnect();
 984 string ColoredTeamName(float t);
 985 void DecodeLevelParms (void);
 986 //void dom_player_join_team(entity pl);
 987 void ClientConnect (void)
 988 {
 989         local string s;
 990         float wep;
 991
 992         if(Ban_IsClientBanned(self))
 993         {
 994                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
 995                 dropclient(self);
 996                 bprint(s);
 997                 return;
 998         }
 999
1000         DecodeLevelParms();
1001
1002         self.classname = "player_joining";
1003         self.flags = self.flags | FL_CLIENT;
1004         self.version_nagtime = time + 10 + random() * 10;
1005
1006         if(player_count<0)
1007         {
1008                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1009                 player_count = 0;
1010         }
1011
1012         bot_clientconnect();
1013
1014         //if(g_domination)
1015         //      dom_player_join_team(self);
1016
1017         //JoinBestTeam(self, FALSE, FALSE);
1018
1019         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1020                 self.classname = "observer";
1021         } else {
1022                 self.classname = "player";
1023                 campaign_bots_may_start = 1;
1024         }
1025
1026         self.playerid = (playerid_last = playerid_last + 1);
1027         if(cvar("sv_eventlog"))
1028         {
1029                 if(clienttype(self) == CLIENTTYPE_REAL)
1030                         s = "player";
1031                 else
1032                         s = "bot";
1033                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
1034                 s = strcat(":team:", ftos(self.playerid), ":");
1035                 s = strcat(s, ftos(self.team));
1036                 GameLogEcho(s, FALSE);
1037         }
1038         self.netname_previous = strzone(self.netname);
1039
1040         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1041
1042         bprint ("^4",self.netname);
1043         bprint ("^4 connected");
1044
1045         if(g_domination || g_ctf)
1046         {
1047                 bprint(" and joined the ");
1048                 bprint(ColoredTeamName(self.team));
1049         }
1050
1051         bprint("\n");
1052
1053         self.welcomemessage_time = 0;
1054
1055         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1056         // TODO: is this being used for anything else than cd tracks?
1057         // Remember: SVC_CDTRACK exists. Maybe it should be used.
1058         //
1059         stuffcmd(self, "cl_particles_reloadeffects\n");
1060
1061         FixClientCvars(self);
1062
1063         // spawnfunc_waypoint sprites
1064         WaypointSprite_InitClient(self);
1065
1066         // Wazat's grappling hook
1067         SetGrappleHookBindings();
1068
1069         // get autoswitch state from player when he toggles it
1070         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1071
1072         // get version info from player
1073         stuffcmd(self, "cmd clientversion $gameversion\n");
1074
1075         // send all weapon info strings
1076         stuffcmd(self, "register_bestweapon clear\n"); // clear the Quake stuff
1077         wep = WEP_FIRST;
1078         while (wep <= WEP_LAST)
1079         {
1080                 weapon_action(wep, WR_REGISTER);
1081                 wep = wep + 1;
1082         }
1083
1084         // get other cvars from player
1085         GetCvars(0);
1086
1087         // set cvar for team scoreboard
1088         if (teams_matter)
1089         {
1090                 local float t;
1091                 t = cvar("teamplay");
1092                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1093                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1094         }
1095         else
1096                 stuffcmd(self, "set teamplay 0\n");
1097
1098         // notify about available teams
1099         if(teamplay)
1100         {
1101                 CheckAllowedTeams(self);
1102                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1103                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1104         }
1105         else
1106                 stuffcmd(self, "set _teams_available 0\n");
1107
1108         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1109
1110         if(g_arena)
1111         {
1112                 self.classname = "observer";
1113                 Spawnqueue_Insert(self);
1114         }
1115         /*else if(g_ctf)
1116         {
1117                 ctf_clientconnect();
1118         }*/
1119
1120         if(entcs_start)
1121                 attach_entcs();
1122
1123         PlayerScore_Attach(self);
1124
1125         bot_relinkplayerlist();
1126
1127         self.spectatortime = time;
1128         if(blockSpectators)
1129         {
1130                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1131         }
1132
1133         self.jointime = time;
1134         self.allowedTimeouts = cvar("sv_timeout_number");
1135
1136         if(clienttype(self) == CLIENTTYPE_REAL)
1137         {
1138                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1139                 SendCSQCInfo();
1140                 msg_entity = self;
1141                 ctf_UpdateCaptures(MSG_ONE);
1142                 ctf_UpdateReturns(MSG_ONE);
1143                 net_UpdateDeaths(MSG_ONE);
1144                 if(mapvote_initialized && !cvar("g_maplist_textonly"))
1145                 {
1146                         MapVote_SendData(MSG_ONE);
1147                         MapVote_UpdateData(MSG_ONE);
1148                 }
1149         }
1150
1151         if(g_lms)
1152         {
1153                 if(PlayerScoreAdd(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1154                 {
1155                         PlayerScoreAdd(self, SP_LMS_PLACE, 666);
1156                         self.frags = -666; // FIXME do we still need this?
1157                 }
1158         }
1159 }
1160
1161 /*
1162 =============
1163 ClientDisconnect
1164
1165 Called when a client disconnects from the server
1166 =============
1167 */
1168 void(entity e) DropFlag;
1169 .entity chatbubbleentity;
1170 .entity teambubbleentity;
1171 //void() ctf_clientdisconnect;
1172 void ClientDisconnect (void)
1173 {
1174         float save;
1175
1176         bot_clientdisconnect();
1177
1178         if(entcs_start)
1179                 detach_entcs();
1180
1181         if(cvar("sv_eventlog"))
1182                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
1183         bprint ("^4",self.netname);
1184         bprint ("^4 disconnected\n");
1185
1186         if (self.chatbubbleentity)
1187         {
1188                 remove (self.chatbubbleentity);
1189                 self.chatbubbleentity = world;
1190         }
1191
1192         if (self.teambubbleentity)
1193         {
1194                 remove (self.teambubbleentity);
1195                 self.teambubbleentity = world;
1196         }
1197
1198         if (self.killindicator)
1199         {
1200                 remove (self.killindicator);
1201                 self.killindicator = world;
1202         }
1203
1204         WaypointSprite_PlayerGone();
1205
1206         DropAllRunes(self);
1207         kh_Key_DropAll(self, TRUE);
1208
1209         if(self.flagcarried)
1210                 DropFlag(self.flagcarried);
1211
1212         save = self.flags;
1213         self.flags = self.flags - (self.flags & FL_CLIENT);
1214         bot_relinkplayerlist();
1215         self.flags = save;
1216
1217         // remove laserdot
1218         if(self.weaponentity)
1219                 if(self.weaponentity.lasertarget)
1220                         remove(self.weaponentity.lasertarget);
1221
1222         if(g_arena)
1223         {
1224                 Spawnqueue_Unmark(self);
1225                 Spawnqueue_Remove(self);
1226         }
1227         /*if(g_ctf)
1228         {
1229                 ctf_clientdisconnect();
1230         }
1231         */
1232
1233         PlayerScore_Detach(self);
1234
1235         if(self.netname_previous)
1236                 strunzone(self.netname_previous);
1237
1238         // free cvars
1239         GetCvars(-1);
1240 }
1241
1242 .float BUTTON_CHAT;
1243 void ChatBubbleThink()
1244 {
1245         self.nextthink = time;
1246         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1247         {
1248                 self.owner.chatbubbleentity = world;
1249                 remove(self);
1250                 return;
1251         }
1252         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1253         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1254                 self.model = self.mdl;
1255         else
1256                 self.model = "";
1257 };
1258
1259 void UpdateChatBubble()
1260 {
1261         if (!self.modelindex)
1262                 return;
1263         // spawn a chatbubble entity if needed
1264         if (!self.chatbubbleentity)
1265         {
1266                 self.chatbubbleentity = spawn();
1267                 self.chatbubbleentity.owner = self;
1268                 self.chatbubbleentity.exteriormodeltoclient = self;
1269                 self.chatbubbleentity.think = ChatBubbleThink;
1270                 self.chatbubbleentity.nextthink = time;
1271                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1272                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1273                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1274                 self.chatbubbleentity.model = "";
1275                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1276         }
1277 }
1278
1279
1280 void TeamBubbleThink()
1281 {
1282         self.nextthink = time;
1283         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1284         {
1285                 self.owner.teambubbleentity = world;
1286                 remove(self);
1287                 return;
1288         }
1289 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1290         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1291                 self.model = "";
1292         else
1293                 self.model = self.mdl;
1294
1295 };
1296
1297 float TeamBubble_customizeentityforclient()
1298 {
1299         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1300 }
1301
1302 void UpdateTeamBubble()
1303 {
1304         if (!self.modelindex || !cvar("teamplay"))
1305                 return;
1306         // spawn a teambubble entity if needed
1307         if (!self.teambubbleentity && cvar("teamplay"))
1308         {
1309                 self.teambubbleentity = spawn();
1310                 self.teambubbleentity.owner = self;
1311                 self.teambubbleentity.exteriormodeltoclient = self;
1312                 self.teambubbleentity.think = TeamBubbleThink;
1313                 self.teambubbleentity.nextthink = time;
1314                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1315 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1316                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1317                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1318                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1319                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1320                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1321                 self.teambubbleentity.effects = EF_LOWPRECISION;
1322         }
1323 }
1324
1325 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1326 // added to the model skins
1327 /*void UpdateColorModHack()
1328 {
1329         local float c;
1330         c = self.clientcolors & 15;
1331         // LordHavoc: only bothering to support white, green, red, yellow, blue
1332              if (teamplay == 0) self.colormod = '0 0 0';
1333         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1334         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1335         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1336         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1337         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1338         else self.colormod = '1 1 1';
1339 };*/
1340
1341 void respawn(void)
1342 {
1343         CopyBody(1);
1344         self.effects |= EF_NODRAW; // prevent another CopyBody
1345         PutClientInServer();
1346 }
1347
1348 /**
1349  * When sv_timeout is used this function returs strings like
1350  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1351  * Called by centerprint functions
1352  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1353  */
1354 string getTimeoutText(float addOneSecond) {
1355         if (!cvar("sv_timeout") || !timeoutStatus)
1356                 return "";
1357
1358         local string retStr;
1359         if (timeoutStatus == 1) {
1360                 if (addOneSecond == 1) {
1361                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1362                 }
1363                 else {
1364                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1365                 }
1366                 return retStr;
1367         }
1368         else if (timeoutStatus == 2) {
1369                 if (addOneSecond) {
1370                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1371                         //don't show messages like "Timeout ends in 0 seconds"...
1372                         if ((remainingTimeoutTime + 1) > 0)
1373                                 return retStr;
1374                         else
1375                                 return "";
1376                 }
1377                 else {
1378                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1379                         //don't show messages like "Timeout ends in 0 seconds"...
1380                         if (remainingTimeoutTime > 0)
1381                                 return retStr;
1382                         else
1383                                 return "";
1384                 }
1385         }
1386         else return "";
1387 }
1388
1389 void player_powerups (void)
1390 {
1391         if (g_minstagib)
1392         {
1393                 if (self.items & IT_STRENGTH)
1394                 {
1395                         if (time > self.strength_finished)
1396                         {
1397                                 if (g_minstagib_invis_alpha > 0)
1398                                 {
1399                                         self.alpha = default_player_alpha;
1400                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1401                                         self.effects = self.effects | EF_FULLBRIGHT;
1402                                 }
1403                                 else
1404                                 {
1405                                         self.effects -= self.effects & EF_NODRAW;
1406                                 }
1407                                 self.items = self.items - (self.items & IT_STRENGTH);
1408                                 sprint(self, "^3Invisibility has worn off\n");
1409                         }
1410                 }
1411                 else
1412                 {
1413                         if (time < self.strength_finished)
1414                         {
1415                                 if (g_minstagib_invis_alpha > 0)
1416                                 {
1417                                         self.alpha = g_minstagib_invis_alpha;
1418                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1419                                         self.effects -= self.effects & EF_FULLBRIGHT;
1420                                 }
1421                                 else
1422                                 {
1423                                         self.effects = self.effects | EF_NODRAW;
1424                                 }
1425                                 self.items = self.items | IT_STRENGTH;
1426                                 sprint(self, "^3You are invisible\n");
1427                         }
1428                 }
1429
1430                 if (self.items & IT_INVINCIBLE)
1431                 {
1432                         if (time > self.invincible_finished)
1433                         {
1434                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1435                                 sprint(self, "^3Speed has worn off\n");
1436                         }
1437                 }
1438                 else
1439                 {
1440                         if (time < self.invincible_finished)
1441                         {
1442                                 self.items = self.items | IT_INVINCIBLE;
1443                                 sprint(self, "^3You are on speed\n");
1444                         }
1445                 }
1446                 return;
1447         }
1448
1449         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1450         if (self.items & IT_STRENGTH)
1451         {
1452                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1453                 if (time > self.strength_finished)
1454                 {
1455                         self.items = self.items - (self.items & IT_STRENGTH);
1456                         sprint(self, "^3Strength has worn off\n");
1457                 }
1458         }
1459         else
1460         {
1461                 if (time < self.strength_finished)
1462                 {
1463                         self.items = self.items | IT_STRENGTH;
1464                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1465                 }
1466         }
1467         if (self.items & IT_INVINCIBLE)
1468         {
1469                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1470                 if (time > self.invincible_finished)
1471                 {
1472                         self.items = self.items - (self.items & IT_INVINCIBLE);
1473                         sprint(self, "^3Shield has worn off\n");
1474                 }
1475         }
1476         else
1477         {
1478                 if (time < self.invincible_finished)
1479                 {
1480                         self.items = self.items | IT_INVINCIBLE;
1481                         sprint(self, "^3Shield surrounds you\n");
1482                 }
1483         }
1484
1485         if (cvar("g_fullbrightplayers"))
1486                 self.effects = self.effects | EF_FULLBRIGHT;
1487
1488         // midair gamemode: damage only while in the air
1489         // if in midair mode, being on ground grants temporary invulnerability
1490         // (this is so that multishot weapon don't clear the ground flag on the
1491         // first damage in the frame, leaving the player vulnerable to the
1492         // remaining hits in the same frame)
1493         if (self.flags & FL_ONGROUND)
1494         if (g_midair)
1495                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1496
1497         if (time < self.spawnshieldtime)
1498                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1499 }
1500
1501 float CalcRegen(float current, float stable, float regenfactor)
1502 {
1503         if(current > stable)
1504                 return current;
1505         else if(current > stable - 0.25) // when close enough, "snap"
1506                 return stable;
1507         else
1508                 return min(stable, current + (stable - current) * regenfactor * frametime);
1509 }
1510
1511 void player_regen (void)
1512 {
1513         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1514         maxh = cvar("g_balance_health_stable");
1515         maxa = cvar("g_balance_armor_stable");
1516         limith = cvar("g_balance_health_limit");
1517         limita = cvar("g_balance_armor_limit");
1518
1519         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1520                 return;
1521
1522         max_mod = regen_mod = rot_mod = limit_mod = 1;
1523
1524         if (self.runes & RUNE_REGEN)
1525         {
1526                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1527                 {
1528                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1529                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1530                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1531                 }
1532                 else
1533                 {
1534                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1535                         max_mod = cvar("g_balance_rune_regen_hpmod");
1536                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1537                 }
1538         }
1539         else if (self.runes & CURSE_VENOM)
1540         {
1541                 max_mod = cvar("g_balance_curse_venom_hpmod");
1542                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1543                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1544                 else
1545                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1546                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1547                 //if (!self.runes & RUNE_REGEN)
1548                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1549         }
1550         maxh = maxh * max_mod;
1551         //maxa = maxa * max_mod;
1552         limith = limith * limit_mod;
1553         limita = limita * limit_mod;
1554
1555         if (self.armorvalue > maxa)
1556         {
1557                 if (time > self.pauserotarmor_finished)
1558                 {
1559                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1560                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1561                 }
1562         }
1563         else if (self.armorvalue < maxa)
1564         {
1565                 if (time > self.pauseregen_finished)
1566                 {
1567                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1568                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1569                 }
1570         }
1571         if (self.health > maxh)
1572         {
1573                 if (time > self.pauserothealth_finished)
1574                 {
1575                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1576                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1577                 }
1578         }
1579         else if (self.health < maxh)
1580         {
1581                 if (time > self.pauseregen_finished)
1582                 {
1583                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1584                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1585                 }
1586         }
1587
1588         if (self.health > limith)
1589                 self.health = limith;
1590         if (self.armorvalue > limita)
1591                 self.armorvalue = limita;
1592
1593         // if player rotted to death...  die!
1594         if(self.health < 1)
1595                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1596 }
1597
1598 /*
1599 ======================
1600 spectate mode routines
1601 ======================
1602 */
1603 void SpectateCopy(entity spectatee) {
1604         self.armortype = spectatee.armortype;
1605         self.armorvalue = spectatee.armorvalue;
1606         self.currentammo = spectatee.currentammo;
1607         self.effects = spectatee.effects;
1608         self.health = spectatee.health;
1609         self.impulse = 0;
1610         self.items = spectatee.items;
1611         self.punchangle = spectatee.punchangle;
1612         self.view_ofs = spectatee.view_ofs;
1613         self.v_angle = spectatee.v_angle;
1614         self.viewzoom = spectatee.viewzoom;
1615         self.velocity = spectatee.velocity;
1616         self.dmg_take = spectatee.dmg_take;
1617         self.dmg_save = spectatee.dmg_save;
1618         self.dmg_inflictor = spectatee.dmg_inflictor;
1619         self.angles = spectatee.v_angle;
1620         self.fixangle = TRUE;
1621         setorigin(self, spectatee.origin);
1622         setsize(self, spectatee.mins, spectatee.maxs);
1623 }
1624
1625 float SpectateUpdate() {
1626         if(!self.enemy)
1627                 return 0;
1628
1629         if (self == self.enemy)
1630                 return 0;
1631
1632         if(self.enemy.flags & FL_NOTARGET)
1633                 return 0;
1634
1635         SpectateCopy(self.enemy);
1636
1637         return 1;
1638 }
1639
1640 float SpectateNext() {
1641         other = find(self.enemy, classname, "player");
1642         if (!other) {
1643                 other = find(other, classname, "player");
1644         }
1645         if (other) {
1646                 self.enemy = other;
1647         }
1648         if(self.enemy.classname == "player") {
1649                 msg_entity = self;
1650                 WriteByte(MSG_ONE, SVC_SETVIEW);
1651                 WriteEntity(MSG_ONE, self.enemy);
1652                 self.wantswelcomemessage = 1;
1653                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1654                 if(!SpectateUpdate())
1655                         PutObserverInServer();
1656                 return 1;
1657         } else {
1658                 return 0;
1659         }
1660 }
1661
1662 /*
1663 =============
1664 ShowRespawnCountdown()
1665
1666 Update a respawn countdown display.
1667 =============
1668 */
1669 void ShowRespawnCountdown()
1670 {
1671         float number;
1672         if(self.deadflag == DEAD_NO) // just respawned?
1673                 return;
1674         else
1675         {
1676                 number = ceil(self.death_time - time);
1677                 if(number <= 0)
1678                         return;
1679                 if(number <= self.respawn_countdown)
1680                 {
1681                         self.respawn_countdown = number - 1;
1682                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1683                                 play2(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1684                 }
1685         }
1686 }
1687
1688 void LeaveSpectatorMode()
1689 {
1690         if(isJoinAllowed()) {
1691                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1692                         self.classname = "player";
1693                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1694                                 JoinBestTeam(self, FALSE, TRUE);
1695                         if(cvar("g_campaign"))
1696                                 campaign_bots_may_start = 1;
1697                         PutClientInServer();
1698                         if(!(self.flags & FL_NOTARGET))
1699                                 bprint ("^4", self.netname, "^4 is playing now\n");
1700                         centerprint(self,"");
1701                         return;
1702                 } else {
1703                         stuffcmd(self,"menu_showteamselect\n");
1704                         return;
1705                 }
1706         }
1707         else {
1708                 //player may not join because of g_maxplayers is set
1709                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1710         }
1711 }
1712
1713 /**
1714  * Determines whether the player is allowed to join. This depends on cvar
1715  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1716  * it checks whether the number of currently playing players exceeds g_maxplayers.
1717  * @return bool TRUE if the player is allowed to join, false otherwise
1718  */
1719 float isJoinAllowed() {
1720         if (!cvar("g_maxplayers"))
1721                 return TRUE;
1722
1723         local entity e;
1724         local float currentlyPlaying;
1725         FOR_EACH_REALPLAYER(e) {
1726                 if(e.classname == "player")
1727                         currentlyPlaying += 1;
1728         }
1729         if(currentlyPlaying < cvar("g_maxplayers"))
1730                 return TRUE;
1731
1732         return FALSE;
1733 }
1734
1735 /**
1736  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1737  * g_maxplayers_spectator_blocktime seconds
1738  */
1739 void checkSpectatorBlock() {
1740         if(self.classname == "spectator" || self.classname == "observer") {
1741                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1742                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1743                         dropclient(self);
1744                 }
1745         }
1746 }
1747
1748 float vercmp_recursive(string v1, string v2)
1749 {
1750         float dot1, dot2;
1751         string s1, s2;
1752         float r;
1753
1754         dot1 = strstrofs(v1, ".", 0);
1755         dot2 = strstrofs(v2, ".", 0);
1756         if(dot1 == -1)
1757                 s1 = v1;
1758         else
1759                 s1 = substring(v1, 0, dot1);
1760         if(dot2 == -1)
1761                 s2 = v2;
1762         else
1763                 s2 = substring(v2, 0, dot2);
1764
1765         r = stof(s1) - stof(s2);
1766         if(r != 0)
1767                 return r;
1768
1769         r = strcasecmp(s1, s2);
1770         if(r != 0)
1771                 return r;
1772
1773         if(dot1 == -1)
1774                 if(dot2 == -1)
1775                         return 0;
1776                 else
1777                         return -1;
1778         else
1779                 if(dot2 == -1)
1780                         return 1;
1781                 else
1782                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1783 }
1784
1785 float vercmp(string v1, string v2)
1786 {
1787         if(strcasecmp(v1, v2) == 0) // early out check
1788                 return 0;
1789         return vercmp_recursive(v1, v2);
1790 }
1791
1792 void ObserverThink()
1793 {
1794         if (self.flags & FL_JUMPRELEASED) {
1795                 if (self.BUTTON_JUMP && self.version == cvar("gameversion")) {
1796                         self.welcomemessage_time = 0;
1797                         self.flags = self.flags - FL_JUMPRELEASED;
1798                         LeaveSpectatorMode();
1799                         return;
1800                 } else if(self.BUTTON_ATCK && self.version == cvar("gameversion")) {
1801                         self.welcomemessage_time = 0;
1802                         self.flags = self.flags - FL_JUMPRELEASED;
1803                         if(SpectateNext() == 1) {
1804                                 self.classname = "spectator";
1805                         }
1806                 }
1807         } else {
1808                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
1809                         self.flags = self.flags | FL_JUMPRELEASED;
1810                 }
1811         }
1812         if(self.BUTTON_ZOOM)
1813                 self.wantswelcomemessage = 0;
1814         if(self.wantswelcomemessage)
1815                 PrintWelcomeMessage(self);
1816 }
1817
1818 void SpectatorThink()
1819 {
1820         if (self.flags & FL_JUMPRELEASED) {
1821                 if (self.BUTTON_JUMP && self.version == cvar("gameversion")) {
1822                         self.welcomemessage_time = 0;
1823                         self.flags = self.flags - FL_JUMPRELEASED;
1824                         LeaveSpectatorMode();
1825                         return;
1826                 } else if(self.BUTTON_ATCK) {
1827                         self.welcomemessage_time = 0;
1828                         self.flags = self.flags - FL_JUMPRELEASED;
1829                         if(SpectateNext() == 1) {
1830                                 self.classname = "spectator";
1831                         } else {
1832                                 self.classname = "observer";
1833                                 PutClientInServer();
1834                         }
1835                 } else if (self.BUTTON_ATCK2) {
1836                         self.welcomemessage_time = 0;
1837                         self.flags = self.flags - FL_JUMPRELEASED;
1838                         self.classname = "observer";
1839                         PutClientInServer();
1840                 } else {
1841                         if(!SpectateUpdate())
1842                                 PutObserverInServer();
1843                 }
1844         } else {
1845                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
1846                         self.flags = self.flags | FL_JUMPRELEASED;
1847                 }
1848         }
1849         if(self.BUTTON_ZOOM)
1850                 self.wantswelcomemessage = 0;
1851         if(self.wantswelcomemessage)
1852                 PrintWelcomeMessage(self);
1853         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1854 }
1855
1856 /*
1857 =============
1858 PlayerPreThink
1859
1860 Called every frame for each client before the physics are run
1861 =============
1862 */
1863 void() ctf_setstatus;
1864 .float vote_nagtime;
1865 void PlayerPreThink (void)
1866 {
1867         if(blockSpectators)
1868                 checkSpectatorBlock();
1869
1870         if(self.netname_previous != self.netname)
1871         {
1872                 if(cvar("sv_eventlog"))
1873                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname), TRUE);
1874                 if(self.netname_previous)
1875                         strunzone(self.netname_previous);
1876                 self.netname_previous = strzone(self.netname);
1877         }
1878
1879         // version nagging
1880         if(self.version_nagtime)
1881                 if(self.cvar_g_nexuizversion)
1882                         if(time > self.version_nagtime)
1883                         {
1884                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1885                                 {
1886                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
1887                                         {
1888                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1889                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1890                                         }
1891                                         else
1892                                         {
1893                                                 float r;
1894                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
1895                                                 if(r < 0)
1896                                                 {
1897                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
1898                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
1899                                                 }
1900                                                 else if(r > 0)
1901                                                 {
1902                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1903                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1904                                                 }
1905                                         }
1906                                 }
1907                                 self.version_nagtime = 0;
1908                         }
1909
1910         // vote nagging
1911         if(self.cvar_scr_centertime)
1912                 if(time > self.vote_nagtime)
1913                 {
1914                         VoteNag();
1915                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1916                 }
1917
1918         // GOD MODE info
1919         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
1920         {
1921                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
1922                 self.max_armorvalue = 0;
1923         }
1924
1925         if(frametime)
1926                 antilag_record(self);
1927
1928         if(self.classname == "player") {
1929 //              if(self.netname == "Wazat")
1930 //                      bprint(self.classname, "\n");
1931
1932                 CheckRules_Player();
1933
1934                 if(self.BUTTON_INFO)
1935                         PrintWelcomeMessage(self);
1936
1937                 if(g_lms || !cvar("sv_spectate"))
1938                 if((time - self.jointime) <= cvar("welcome_message_time"))
1939                         PrintWelcomeMessage(self);
1940
1941                 if (intermission_running)
1942                 {
1943                         IntermissionThink ();   // otherwise a button could be missed between
1944                         return;                                 // the think tics
1945                 }
1946
1947                 if(self.teleport_time)
1948                 if(time > self.teleport_time)
1949                 {
1950                         self.teleport_time = 0;
1951                         self.effects = self.effects - (self.effects & EF_NODRAW);
1952                         if(self.weaponentity)
1953                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
1954                 }
1955
1956                 Nixnex_GiveCurrentWeapon();
1957
1958                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
1959                         UpdateSelectedPlayer();
1960
1961                 //don't allow the player to turn around while game is paused!
1962                 if(timeoutStatus == 2) {
1963                         self.v_angle = self.lastV_angle;
1964                         self.angles = self.lastV_angle;
1965                         self.fixangle = TRUE;
1966                 }
1967
1968                 if (self.deadflag != DEAD_NO)
1969                 {
1970                         float button_pressed, force_respawn;
1971                         player_anim();
1972                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
1973                         force_respawn = (g_lms || cvar("g_forced_respawn"));
1974                         if (self.deadflag == DEAD_DYING)
1975                         {
1976                                 if(force_respawn)
1977                                         self.deadflag = DEAD_RESPAWNING;
1978                                 else if(!button_pressed)
1979                                         self.deadflag = DEAD_DEAD;
1980                         }
1981                         else if (self.deadflag == DEAD_DEAD)
1982                         {
1983                                 if(button_pressed)
1984                                         self.deadflag = DEAD_RESPAWNABLE;
1985                         }
1986                         else if (self.deadflag == DEAD_RESPAWNABLE)
1987                         {
1988                                 if(!button_pressed)
1989                                         self.deadflag = DEAD_RESPAWNING;
1990                         }
1991                         else if (self.deadflag == DEAD_RESPAWNING)
1992                         {
1993                                 if(time > self.death_time)
1994                                 {
1995                                         self.death_time = time + 1; // only retry once a second
1996                                         respawn();
1997                                 }
1998                         }
1999                         ShowRespawnCountdown();
2000                         return;
2001                 }
2002
2003                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2004                 {
2005                         vector dist;
2006
2007                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2008                         dist = self.oldorigin - self.origin;
2009                         dist_z = 0;
2010                         self.lms_traveled_distance += fabs(vlen(dist));
2011
2012                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
2013                         {
2014                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2015                                 self.lms_traveled_distance = 0;
2016                         }
2017
2018                         if(time > self.lms_nextcheck)
2019                         {
2020                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2021                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2022                                 {
2023                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2024                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2025                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2026                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2027                                 }
2028                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2029                                 self.lms_traveled_distance = 0;
2030                         }
2031                 }
2032
2033                 if (self.BUTTON_CROUCH && !self.hook.state)
2034                 {
2035                         if (!self.crouch)
2036                         {
2037                                 self.crouch = TRUE;
2038                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2039                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2040                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
2041                         }
2042                 }
2043                 else
2044                 {
2045                         if (self.crouch)
2046                         {
2047                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2048                                 if (!trace_startsolid)
2049                                 {
2050                                         self.crouch = FALSE;
2051                                         self.view_ofs = PL_VIEW_OFS;
2052                                         setsize (self, PL_MIN, PL_MAX);
2053                                 }
2054                         }
2055                 }
2056
2057                 FixPlayermodel();
2058
2059                 GrapplingHookFrame();
2060
2061                 W_WeaponFrame();
2062
2063                 {
2064                         float zoomfactor, zoomspeed, zoomdir;
2065                         zoomfactor = self.cvar_cl_zoomfactor;
2066                         if(zoomfactor < 1 || zoomfactor > 16)
2067                                 zoomfactor = 2.5;
2068                         zoomspeed = self.cvar_cl_zoomspeed;
2069                         if(zoomspeed >= 0) // < 0 is instant zoom
2070                                 if(zoomspeed < 0.5 || zoomspeed > 16)
2071                                         zoomspeed = 3.5;
2072
2073                         zoomdir = self.BUTTON_ZOOM;
2074                         if(self.BUTTON_ATCK2)
2075                                 if(self.weapon == WEP_NEX)
2076                                         if(!g_minstagib)
2077                                                 zoomdir = 1;
2078
2079                         if(zoomdir)
2080                                 self.has_zoomed = 1;
2081
2082                         if(self.has_zoomed)
2083                         {
2084                                 if(zoomspeed <= 0) // instant zoom
2085                                 {
2086                                         if(zoomdir)
2087                                                 self.viewzoom = 1 / zoomfactor;
2088                                         else
2089                                                 self.viewzoom = 1;
2090                                 }
2091                                 else
2092                                 {
2093                                         // geometric zoom would be:
2094                                         //   self.viewzoom = bound(1 / zoomfactor, self.viewzoom * pow(zoomfactor, (zoomdir ? -1 : 1) * frametime * zoomspeed), 1);
2095                                         // however, testing showed that arithmetic/harmonic zoom works better
2096                                         if(zoomdir)
2097                                                 // self.viewzoom = 1 / bound(1, 1 / self.viewzoom + (zoomdir ? 1 : -1) * frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2098                                                 // zoom in = arithmetic: 1x, 2x, 3x, 4x, ..., 8x
2099                                                 self.viewzoom = 1 / bound(1, 1 / self.viewzoom + frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2100                                         else
2101                                                 // self.viewzoom = bound(1 / zoomfactor, self.viewzoom + (zoomdir ? -1 : 1) * frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2102                                                 // zoom out = harmonic: 8/1x, 8/2x, 8/3x, 8/4x, ..., 8/8x
2103                                                 self.viewzoom = bound(1 / zoomfactor, self.viewzoom + frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2104                                 }
2105                         }
2106                         else
2107                                 self.viewzoom = min(1, self.viewzoom + frametime); // spawn zoom-in
2108                 }
2109
2110                 player_powerups();
2111                 player_regen();
2112                 player_anim();
2113
2114                 if (g_minstagib)
2115                         minstagib_ammocheck();
2116
2117                 ctf_setstatus();
2118                 kh_setstatus();
2119
2120                 //self.angles_y=self.v_angle_y + 90;   // temp
2121
2122                 //if (TetrisPreFrame()) return;
2123         } else if(gameover) {
2124                 if (intermission_running)
2125                         IntermissionThink ();   // otherwise a button could be missed between
2126                 return;
2127         } else if(self.classname == "observer") {
2128                 ObserverThink();
2129         } else if(self.classname == "spectator") {
2130                 SpectatorThink();
2131         }
2132 }
2133
2134
2135 /*
2136 =============
2137 PlayerPostThink
2138
2139 Called every frame for each client after the physics are run
2140 =============
2141 */
2142 .float idlekick_lasttimeleft;
2143 void PlayerPostThink (void)
2144 {
2145         // Savage: Check for nameless players
2146         if (strlen(self.netname) < 1) {
2147                 self.netname = "Player";
2148                 stuffcmd(self, "seta _cl_name Player\n");
2149         }
2150
2151         if(sv_maxidle)
2152         {
2153                 float timeleft;
2154                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2155                 if(timeleft <= 0)
2156                 {
2157                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2158                         play2(self, "announcer/robotic/terminated.ogg");
2159                         dropclient(self);
2160                         return;
2161                 }
2162                 else if(timeleft <= 10)
2163                 {
2164                         if(timeleft != self.idlekick_lasttimeleft)
2165                         {
2166                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2167                                 play2(self, strcat("announcer/robotic/", ftos(timeleft), ".ogg"));
2168                         }
2169                 }
2170                 else
2171                 {
2172                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2173                 }
2174                 self.idlekick_lasttimeleft = timeleft;
2175         }
2176
2177         if(self.classname == "player") {
2178                 CheckRules_Player();
2179                 UpdateChatBubble();
2180                 UpdateTeamBubble();
2181                 if (self.impulse)
2182                         ImpulseCommands();
2183                 if (intermission_running)
2184                         return;         // intermission or finale
2185
2186                 //PrintWelcomeMessage(self);
2187                 //if (TetrisPostFrame()) return;
2188
2189                 // restart countdown
2190                 if (restart_countdown) {
2191                         if(time < restart_countdown) {
2192                                 if (!cvar("sv_ready_restart_after_countdown"))
2193                                 {
2194                                         self.movetype = MOVETYPE_NONE;
2195                                         self.velocity = '0 0 0';
2196                                         self.avelocity = '0 0 0';
2197                                         self.movement = '0 0 0';
2198                                 }
2199                         }
2200                         else
2201                         {
2202                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2203                                 if (!cvar("sv_ready_restart_after_countdown"))
2204                                 {
2205                                         if(self.movetype == MOVETYPE_NONE)
2206                                         {
2207                                                 self.movetype = MOVETYPE_WALK;
2208                                         }
2209                                 }
2210                         }
2211                 }
2212
2213         } else if (self.classname == "observer") {
2214                 //do nothing
2215         } else if (self.classname == "spectator") {
2216                 //do nothing
2217         }
2218
2219         /*
2220         float i;
2221         for(i = 0; i < 1000; ++i)
2222         {
2223                 vector end;
2224                 end = self.origin + '0 0 1024' + 512 * randomvec();
2225                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2226                 if(trace_fraction < 1)
2227                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2228                 {
2229                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2230                         break;
2231                 }
2232         }
2233         */
2234
2235         Arena_Warmup();
2236 }