data/qcsrc/server/cl_client.qc

   1 // let's abuse an existing field
   2 #define SPAWNPOINT_SCORE frags
   3
   4 .float wantswelcomemessage;
   5 .string netname_previous;
   6
   7 void spawnfunc_info_player_survivor (void)
   8 {
   9         spawnfunc_info_player_deathmatch();
  10 }
  11
  12 void spawnfunc_info_player_start (void)
  13 {
  14         spawnfunc_info_player_deathmatch();
  15 }
  16
  17 void spawnfunc_info_player_deathmatch (void)
  18 {
  19         self.classname = "info_player_deathmatch";
  20         relocate_spawnpoint();
  21 }
  22
  23 void spawnpoint_use()
  24 {
  25         if(teams_matter)
  26         if(have_team_spawns)
  27         {
  28                 self.team = activator.team;
  29                 some_spawn_has_been_used = 1;
  30         }
  31 };
  32
  33 // Returns:
  34 //   -1 if a spawn can't be used
  35 //   otherwise, a weight of the spawnpoint
  36 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
  37 {
  38         float shortest, thisdist;
  39         entity player;
  40
  41         // filter out spots for the wrong team
  42         if(teamcheck)
  43         if(spot.team != teamcheck)
  44                 return -1;
  45
  46         if(race_spawns)
  47                 if(spot.target == "")
  48                         return -1;
  49
  50         // filter out spots for assault
  51         if(spot.target != "") {
  52                 local entity ent;
  53                 ent = find(world, targetname, spot.target);
  54                 if(!ent)
  55                 {
  56                         return -1;
  57                 }
  58                 while(ent) {
  59                         if(ent.classname == "target_objective")
  60                         {
  61                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  62                                         return -1;
  63                         }
  64                         else if(ent.classname == "trigger_race_checkpoint")
  65                         {
  66                                 if(self.classname == "player") // spectators may spawn everywhere
  67                                 if(ent.cnt != race_PreviousCheckpoint(self.race_checkpoint))
  68                                         // checkpoint -1 players (freshly spawned) spawn close to finish!
  69                                         return -1;
  70                         }
  71                         else
  72                         {
  73                         }
  74                         ent = find(ent, targetname, spot.target);
  75                 }
  76         }
  77
  78         player = playerlist;
  79         shortest = vlen(world.maxs - world.mins);
  80         for(player = playerlist; player; player = player.chain)
  81                 if (player != self)
  82                 {
  83                         thisdist = vlen(player.origin - spot.origin);
  84                         if (thisdist < shortest)
  85                                 shortest = thisdist;
  86                 }
  87         return shortest;
  88 }
  89
  90 float spawn_allbad;
  91 float spawn_allgood;
  92 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  93 {
  94         local entity spot, spotlist, spotlistend;
  95         spawn_allgood = TRUE;
  96         spawn_allbad = TRUE;
  97
  98         spotlist = world;
  99         spotlistend = world;
 100
 101         for(spot = firstspot; spot; spot = spot.chain)
 102         {
 103                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
 104
 105                 if(cvar("spawn_debugview"))
 106                 {
 107                         setmodel(spot, "models/runematch/rune.mdl");
 108                         if(spot.SPAWNPOINT_SCORE < mindist)
 109                         {
 110                                 spot.colormod = '1 0 0';
 111                                 spot.scale = 1;
 112                         }
 113                         else
 114                         {
 115                                 spot.colormod = '0 1 0';
 116                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
 117                         }
 118                 }
 119
 120                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 121                 {
 122                         if(spot.SPAWNPOINT_SCORE < mindist)
 123                         {
 124                                 // too short distance
 125                                 spawn_allgood = FALSE;
 126                         }
 127                         else
 128                         {
 129                                 // perfect
 130                                 spawn_allbad = FALSE;
 131
 132                                 if(spotlistend)
 133                                         spotlistend.chain = spot;
 134                                 spotlistend = spot;
 135                                 if(!spotlist)
 136                                         spotlist = spot;
 137
 138                                 /*
 139                                 if(teamcheck)
 140                                 if(spot.team != teamcheck)
 141                                         error("invalid spawn added");
 142
 143                                 print("added ", etos(spot), "\n");
 144                                 */
 145                         }
 146                 }
 147         }
 148         if(spotlistend)
 149                 spotlistend.chain = world;
 150
 151         /*
 152                 entity e;
 153                 if(teamcheck)
 154                         for(e = spotlist; e; e = e.chain)
 155                         {
 156                                 print("seen ", etos(e), "\n");
 157                                 if(e.team != teamcheck)
 158                                         error("invalid spawn found");
 159                         }
 160         */
 161
 162         return spotlist;
 163 }
 164
 165 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 166 {
 167         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 168         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 169         local entity spot;
 170
 171         RandomSelection_Init();
 172         for(spot = firstspot; spot; spot = spot.chain)
 173                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 174
 175         return RandomSelection_chosen_ent;
 176 }
 177
 178 /*
 179 =============
 180 SelectSpawnPoint
 181
 182 Finds a point to respawn
 183 =============
 184 */
 185 entity SelectSpawnPoint (float anypoint)
 186 {
 187         local float teamcheck;
 188         local entity firstspot_new;
 189         local entity spot, firstspot, playerlist;
 190
 191         spot = find (world, classname, "testplayerstart");
 192         if (spot)
 193                 return spot;
 194
 195         teamcheck = 0;
 196
 197         if(!anypoint && have_team_spawns)
 198                 teamcheck = self.team;
 199
 200         // get the list of players
 201         playerlist = findchain(classname, "player");
 202         // get the entire list of spots
 203         firstspot = findchain(classname, "info_player_deathmatch");
 204         // filter out the bad ones
 205         // (note this returns the original list if none survived)
 206         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 207         if(!firstspot_new)
 208                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 209         firstspot = firstspot_new;
 210
 211         // there is 50/50 chance of choosing a random spot or the furthest spot
 212         // (this means that roughly every other spawn will be furthest, so you
 213         // usually won't get fragged at spawn twice in a row)
 214         if (arena_roundbased)
 215         {
 216                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 217                 if(firstspot_new)
 218                         firstspot = firstspot_new;
 219                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 220         }
 221         else if (random() > cvar("g_spawn_furthest"))
 222                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 223         else
 224                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 225
 226         if(cvar("spawn_debugview"))
 227         {
 228                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 229
 230                 entity e;
 231                 if(teamcheck)
 232                         for(e = firstspot; e; e = e.chain)
 233                                 if(e.team != teamcheck)
 234                                         error("invalid spawn found");
 235         }
 236
 237         if (!spot)
 238         {
 239                 if(cvar("spawn_debug"))
 240                         GotoNextMap();
 241                 else
 242                 {
 243                         if(some_spawn_has_been_used)
 244                                 return world; // team can't spawn any more, because of actions of other team
 245                         else
 246                                 error("Cannot find a spawn point - please fix the map!");
 247                 }
 248         }
 249
 250         return spot;
 251 }
 252
 253 /*
 254 =============
 255 CheckPlayerModel
 256
 257 Checks if the argument string can be a valid playermodel.
 258 Returns a valid one in doubt.
 259 =============
 260 */
 261 string FallbackPlayerModel = "models/player/marine.zym";
 262 string CheckPlayerModel(string plyermodel) {
 263         if(strlen(plyermodel) < 4)
 264                 return FallbackPlayerModel;
 265         if( substring(plyermodel,0,14) != "models/player/")
 266                 return FallbackPlayerModel;
 267         else if(cvar("sv_servermodelsonly"))
 268         {
 269                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 270                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 271                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 272                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 273                         return FallbackPlayerModel;
 274                 if(!fexists(plyermodel))
 275                         return FallbackPlayerModel;
 276         }
 277         return plyermodel;
 278 }
 279
 280 /*
 281 =============
 282 Client_customizeentityforclient
 283
 284 LOD reduction
 285 =============
 286 */
 287 float Client_customizeentityforclient()
 288 {
 289 #ifdef ALLOW_VARIABLE_LOD
 290         // self: me
 291         // other: the player viewing me
 292         float distance;
 293         float f;
 294
 295         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 296                 return TRUE;
 297
 298         if(other.cvar_cl_playerdetailreduction <= 0)
 299         {
 300                 if(other.cvar_cl_playerdetailreduction <= -2)
 301                         self.modelindex = self.modelindex_lod2;
 302                 else if(other.cvar_cl_playerdetailreduction <= -1)
 303                         self.modelindex = self.modelindex_lod1;
 304                 else
 305                         self.modelindex = self.modelindex_lod0;
 306         }
 307         else
 308         {
 309                 distance = vlen(self.origin - other.origin);
 310                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 311                 if(f > 10000)
 312                         self.modelindex = self.modelindex_lod2;
 313                 else if(f > 5000)
 314                         self.modelindex = self.modelindex_lod1;
 315                 else
 316                         self.modelindex = self.modelindex_lod0;
 317         }
 318 #endif
 319
 320         return TRUE;
 321 }
 322
 323 void UpdatePlayerSounds();
 324 void setmodel_lod(entity e, string modelname)
 325 {
 326 #ifdef ALLOW_VARIABLE_LOD
 327         string s;
 328
 329         // FIXME: this only supports 3-letter extensions
 330         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 331         if(fexists(s))
 332         {
 333                 precache_model(s);
 334                 setmodel(e, s); // players have high precision
 335                 self.modelindex_lod1 = self.modelindex;
 336         }
 337         else
 338                 self.modelindex_lod1 = -1;
 339
 340         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 341         if(fexists(s))
 342         {
 343                 precache_model(s);
 344                 setmodel(e, s); // players have high precision
 345                 self.modelindex_lod2 = self.modelindex;
 346         }
 347         else
 348                 self.modelindex_lod2 = -1;
 349
 350         precache_model(modelname);
 351         setmodel(e, modelname); // players have high precision
 352         self.modelindex_lod0 = self.modelindex;
 353
 354         if(self.modelindex_lod1 < 0)
 355                 self.modelindex_lod1 = self.modelindex;
 356
 357         if(self.modelindex_lod2 < 0)
 358                 self.modelindex_lod2 = self.modelindex;
 359 #else
 360         precache_model(modelname);
 361         setmodel(e, modelname); // players have high precision
 362 #endif
 363         player_setupanimsformodel();
 364         UpdatePlayerSounds();
 365 }
 366
 367 /*
 368 =============
 369 PutObserverInServer
 370
 371 putting a client as observer in the server
 372 =============
 373 */
 374 void PutObserverInServer (void)
 375 {
 376         entity  spot;
 377         spot = SelectSpawnPoint (TRUE);
 378         if(!spot)
 379                 error("No spawnpoints for observers?!?\n");
 380         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 381
 382         if(clienttype(self) == CLIENTTYPE_REAL)
 383         {
 384                 msg_entity = self;
 385                 WriteByte(MSG_ONE, SVC_SETVIEW);
 386                 WriteEntity(MSG_ONE, self);
 387         }
 388
 389         DropAllRunes(self);
 390         kh_Key_DropAll(self, TRUE);
 391
 392         if(self.flagcarried)
 393                 DropFlag(self.flagcarried);
 394
 395         WaypointSprite_PlayerDead();
 396
 397         if(self.killcount != -666)
 398         {
 399                 if(g_lms)
 400                 {
 401                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 402                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 403                         else
 404                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 405                 }
 406                 else
 407                         bprint ("^4", self.netname, "^4 is spectating now\n");
 408         }
 409
 410         PlayerScore_Clear(self); // clear scores when needed
 411
 412         self.spectatortime = time;
 413
 414         self.classname = "observer";
 415         self.health = -666;
 416         self.takedamage = DAMAGE_NO;
 417         self.solid = SOLID_NOT;
 418         self.movetype = MOVETYPE_NOCLIP;
 419         self.flags = FL_CLIENT | FL_NOTARGET;
 420         self.armorvalue = 666;
 421         self.effects = 0;
 422         self.armorvalue = cvar("g_balance_armor_start");
 423         self.pauserotarmor_finished = 0;
 424         self.pauserothealth_finished = 0;
 425         self.pauseregen_finished = 0;
 426         self.damageforcescale = 0;
 427         self.death_time = 0;
 428         self.dead_frame = 0;
 429         self.alpha = 0;
 430         self.scale = 0;
 431         self.fade_time = 0;
 432         self.pain_frame = 0;
 433         self.pain_finished = 0;
 434         self.strength_finished = 0;
 435         self.invincible_finished = 0;
 436         self.pushltime = 0;
 437         self.think = SUB_Null;
 438         self.nextthink = 0;
 439         self.hook_time = 0;
 440         self.runes = 0;
 441         self.deadflag = DEAD_NO;
 442         self.angles = spot.angles;
 443         self.angles_z = 0;
 444         self.fixangle = TRUE;
 445         self.crouch = FALSE;
 446
 447         self.view_ofs = PL_VIEW_OFS;
 448         setorigin (self, spot.origin);
 449         setsize (self, '0 0 0', '0 0 0');
 450         self.oldorigin = self.origin;
 451         self.items = 0;
 452         self.model = "";
 453         self.modelindex = 0;
 454         self.weapon = 0;
 455         self.weaponmodel = "";
 456         self.weaponentity = world;
 457         self.killcount = -666;
 458         self.velocity = '0 0 0';
 459         self.avelocity = '0 0 0';
 460         self.punchangle = '0 0 0';
 461         self.punchvector = '0 0 0';
 462         self.oldvelocity = self.velocity;
 463         self.customizeentityforclient = Client_customizeentityforclient;
 464         self.viewzoom = 1;
 465         self.wantswelcomemessage = 1;
 466
 467         if(g_race)
 468                 race_PreparePlayer();
 469
 470         if(g_arena)
 471         {
 472                 if(self.version_mismatch)
 473                 {
 474                         Spawnqueue_Unmark(self);
 475                         Spawnqueue_Remove(self);
 476                 }
 477                 else
 478                 {
 479                         Spawnqueue_Insert(self);
 480                 }
 481         }
 482         else if(g_lms)
 483         {
 484                 // Only if the player cannot play at all
 485                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 486                         self.frags = -666;
 487                 else
 488                         self.frags = -667;
 489         }
 490         else
 491                 self.frags = -666;
 492 }
 493
 494 float RestrictSkin(float s)
 495 {
 496         if(!teams_matter)
 497                 return s;
 498         if(s == 6)
 499                 return 6;
 500         return mod(s, 3);
 501 }
 502
 503 void FixPlayermodel()
 504 {
 505         local string defaultmodel;
 506         local float defaultskin;
 507         local vector m1, m2;
 508
 509         defaultmodel = "";
 510
 511         if(cvar("sv_defaultcharacter") == 1) {
 512                 defaultskin = 0;
 513
 514                 if(teams_matter)
 515                 {
 516                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 517                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 518                 }
 519
 520                 if(defaultmodel == "")
 521                 {
 522                         defaultmodel = cvar_string("sv_defaultplayermodel");
 523                         defaultskin = cvar("sv_defaultplayerskin");
 524                 }
 525         }
 526
 527         if(defaultmodel != "")
 528         {
 529                 if (defaultmodel != self.model)
 530                 {
 531                         m1 = self.mins;
 532                         m2 = self.maxs;
 533                         setmodel_lod (self, defaultmodel);
 534                         setsize (self, m1, m2);
 535                 }
 536
 537                 self.skin = defaultskin;
 538         } else {
 539                 if (self.playermodel != self.model)
 540                 {
 541                         self.playermodel = CheckPlayerModel(self.playermodel);
 542                         m1 = self.mins;
 543                         m2 = self.maxs;
 544                         setmodel_lod (self, self.playermodel);
 545                         setsize (self, m1, m2);
 546                 }
 547
 548                 self.skin = RestrictSkin(stof(self.playerskin));
 549         }
 550
 551         if(!teams_matter)
 552                 if(strlen(cvar_string("sv_defaultplayercolors")))
 553                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 554                                 setcolor(self, cvar("sv_defaultplayercolors"));
 555 }
 556
 557 /*
 558 =============
 559 PutClientInServer
 560
 561 Called when a client spawns in the server
 562 =============
 563 */
 564 //void() ctf_playerchanged;
 565 void PutClientInServer (void)
 566 {
 567         if(clienttype(self) == CLIENTTYPE_BOT)
 568         {
 569                 self.classname = "player";
 570         }
 571         else if(clienttype(self) == CLIENTTYPE_REAL)
 572         {
 573                 msg_entity = self;
 574                 WriteByte(MSG_ONE, SVC_SETVIEW);
 575                 WriteEntity(MSG_ONE, self);
 576         }
 577
 578         // player is dead and becomes observer
 579         // FIXME fix LMS scoring for new system
 580         if(g_lms)
 581         {
 582                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 583                         self.classname = "observer";
 584         }
 585
 586         if(g_arena)
 587         if(!self.spawned)
 588                 self.classname = "observer";
 589
 590         if(self.classname == "player") {
 591                 entity  spot;
 592
 593                 if(g_race)
 594                         if(self.killcount == -666)
 595                                 race_PreparePlayer();
 596
 597                 spot = SelectSpawnPoint (FALSE);
 598                 if(!spot)
 599                 {
 600                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 601                         return; // spawn failed
 602                 }
 603
 604                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 605
 606                 self.classname = "player";
 607                 self.iscreature = TRUE;
 608                 self.movetype = MOVETYPE_WALK;
 609                 self.solid = SOLID_SLIDEBOX;
 610                 self.flags = FL_CLIENT;
 611                 self.takedamage = DAMAGE_AIM;
 612                 if(g_minstagib)
 613                         self.effects = EF_FULLBRIGHT;
 614                 else
 615                         self.effects = 0;
 616                 self.air_finished = time + 12;
 617                 self.dmg = 2;
 618
 619                 self.ammo_shells = start_ammo_shells;
 620                 self.ammo_nails = start_ammo_nails;
 621                 self.ammo_rockets = start_ammo_rockets;
 622                 self.ammo_cells = start_ammo_cells;
 623                 self.health = start_health;
 624                 self.armorvalue = start_armorvalue;
 625                 self.items = start_items;
 626                 self.switchweapon = start_switchweapon;
 627                 self.cnt = start_switchweapon;
 628                 self.weapon = 0;
 629                 self.jump_interval = time;
 630
 631                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 632                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 633                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 634                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 635                 //extend the pause of rotting if client was reset at the beginning of the countdown
 636                 if(!cvar("sv_ready_restart_after_countdown") && time < restart_countdown) {
 637                         self.spawnshieldtime += RESTART_COUNTDOWN;
 638                         self.pauserotarmor_finished += RESTART_COUNTDOWN;
 639                         self.pauserothealth_finished += RESTART_COUNTDOWN;
 640                         self.pauseregen_finished += RESTART_COUNTDOWN;
 641                 }
 642                 self.damageforcescale = 2;
 643                 self.death_time = 0;
 644                 self.dead_frame = 0;
 645                 self.alpha = 0;
 646                 self.scale = 0;
 647                 self.fade_time = 0;
 648                 self.pain_frame = 0;
 649                 self.pain_finished = 0;
 650                 self.strength_finished = 0;
 651                 self.invincible_finished = 0;
 652                 self.pushltime = 0;
 653                 //self.speed_finished = 0;
 654                 //self.slowmo_finished = 0;
 655                 // players have no think function
 656                 self.think = SUB_Null;
 657                 self.nextthink = 0;
 658                 self.hook_time = 0;
 659
 660                 self.runes = 0;
 661
 662                 self.deadflag = DEAD_NO;
 663
 664                 self.angles = spot.angles;
 665
 666                 self.angles_z = 0; // never spawn tilted even if the spot says to
 667                 self.fixangle = TRUE; // turn this way immediately
 668                 self.velocity = '0 0 0';
 669                 self.avelocity = '0 0 0';
 670                 self.punchangle = '0 0 0';
 671                 self.punchvector = '0 0 0';
 672                 self.oldvelocity = self.velocity;
 673
 674                 self.viewzoom = 0.6;
 675                 self.has_zoomed = 0;
 676
 677                 self.customizeentityforclient = Client_customizeentityforclient;
 678
 679                 self.model = "";
 680                 FixPlayermodel();
 681
 682                 self.crouch = FALSE;
 683                 self.view_ofs = PL_VIEW_OFS;
 684                 setsize (self, PL_MIN, PL_MAX);
 685                 self.spawnorigin = spot.origin;
 686                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 687                 // don't reset back to last position, even if new position is stuck in solid
 688                 self.oldorigin = self.origin;
 689
 690                 if(g_arena)
 691                 {
 692                         Spawnqueue_Remove(self);
 693                         Spawnqueue_Mark(self);
 694                 }
 695
 696                 self.event_damage = PlayerDamage;
 697
 698                 self.bot_attack = TRUE;
 699
 700                 self.statdraintime = time + 5;
 701                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 702
 703                 if(g_race)
 704                         if(self.killcount != -666)
 705                         {
 706                                 if(spot.target == "")
 707                                         // let the player run without timing, if he did not spawn at a targetting spawnpoint
 708                                         race_PreparePlayer();
 709                                 else
 710                                         race_RetractPlayer();
 711                         }
 712
 713                 if(self.killcount == -666) {
 714                         PlayerScore_Clear(self);
 715                         self.killcount = 0;
 716                         self.frags = 0;
 717                 }
 718
 719                 self.cnt = WEP_LASER;
 720                 self.nixnex_lastchange_id = -1;
 721
 722                 CL_SpawnWeaponentity();
 723                 self.alpha = default_player_alpha;
 724                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 725                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 726
 727                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 728                 self.lms_traveled_distance = 0;
 729                 self.speedrunning = FALSE;
 730
 731                 if(cvar("spawn_debug"))
 732                 {
 733                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 734                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 735                 }
 736
 737                 //stuffcmd(self, "chase_active 0");
 738                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 739
 740                 if (cvar("g_spawnsound"))
 741                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 742
 743                 if(g_assault) {
 744                         if(self.team == assault_attacker_team)
 745                                 centerprint(self, "You are attacking!\n");
 746                         else
 747                                 centerprint(self, "You are defending!\n");
 748                 }
 749
 750         } else if(self.classname == "observer") {
 751                 PutObserverInServer ();
 752         }
 753
 754         //if(g_ctf)
 755         //      ctf_playerchanged();
 756 }
 757
 758 /*
 759 =============
 760 SendCSQCInfo
 761
 762 Send whatever CSQC needs NOW and cannot wait for SendServerInfo to happen...
 763 =============
 764 */
 765 void SendCSQCInfo(void)
 766 {
 767         if(clienttype(self) != CLIENTTYPE_REAL)
 768                 return;
 769         msg_entity = self;
 770         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 771         WriteByte(MSG_ONE, TE_CSQC_INIT);
 772         WriteShort(MSG_ONE, CSQC_REVISION);
 773         WriteByte(MSG_ONE, maxclients);
 774 }
 775
 776 /*
 777 =============
 778 SetNewParms
 779 =============
 780 */
 781 void SetNewParms (void)
 782 {
 783         // initialize parms for a new player
 784         parm1 = -(86400 * 366);
 785 }
 786
 787 /*
 788 =============
 789 SetChangeParms
 790 =============
 791 */
 792 void SetChangeParms (void)
 793 {
 794         // save parms for level change
 795         parm1 = self.parm_idlesince - time;
 796 }
 797
 798 /*
 799 =============
 800 DecodeLevelParms
 801 =============
 802 */
 803 void DecodeLevelParms (void)
 804 {
 805         // load parms
 806         self.parm_idlesince = parm1;
 807         if(self.parm_idlesince == -(86400 * 366))
 808                 self.parm_idlesince = time;
 809 }
 810
 811 /*
 812 =============
 813 ClientKill
 814
 815 Called when a client types 'kill' in the console
 816 =============
 817 */
 818
 819 void ClientKill_Now_TeamChange()
 820 {
 821         if(self.killindicator_teamchange == -1)
 822         {
 823                 self.team = -1;
 824                 JoinBestTeam( self, FALSE, FALSE );
 825         }
 826         else
 827         {
 828                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 829         }
 830 }
 831
 832 void ClientKill_Now()
 833 {
 834         if(self.killindicator_teamchange)
 835                 ClientKill_Now_TeamChange();
 836
 837         // in any case:
 838         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 839
 840         if(self.killindicator)
 841         {
 842                 dprint("Cleaned up after a leaked kill indicator.\n");
 843                 remove(self.killindicator);
 844                 self.killindicator = world;
 845         }
 846 }
 847 void KillIndicator_Think()
 848 {
 849         if (!self.owner.modelindex)
 850         {
 851                 self.owner.killindicator = world;
 852                 remove(self);
 853                 return;
 854         }
 855
 856         if(self.cnt <= 0)
 857         {
 858                 self = self.owner;
 859                 ClientKill_Now(); // no oldself needed
 860                 return;
 861         }
 862         else
 863         {
 864                 if(self.cnt <= 10)
 865                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 866                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 867                 {
 868                         if(self.cnt <= 10)
 869                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 870                         if(self.owner.killindicator_teamchange)
 871                         {
 872                                 if(self.owner.killindicator_teamchange == -1)
 873                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 874                                 else
 875                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 876                         }
 877                         else
 878                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 879                 }
 880                 self.nextthink = time + 1;
 881                 self.cnt -= 1;
 882         }
 883 }
 884
 885 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 886 {
 887         float killtime;
 888         entity e;
 889         killtime = cvar("g_balance_kill_delay");
 890
 891         self.killindicator_teamchange = targetteam;
 892
 893         if(!self.killindicator)
 894         {
 895                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 896                 {
 897                         ClientKill_Now();
 898                 }
 899                 else
 900                 {
 901                         self.killindicator = spawn();
 902                         self.killindicator.owner = self;
 903                         self.killindicator.scale = 0.5;
 904                         setattachment(self.killindicator, self, "");
 905                         setorigin(self.killindicator, '0 0 52');
 906                         self.killindicator.think = KillIndicator_Think;
 907                         self.killindicator.nextthink = time + (self.lip) * 0.05;
 908                         self.killindicator.cnt = ceil(killtime);
 909                         self.killindicator.count = bound(0, ceil(killtime), 10);
 910                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 911
 912                         for(e = world; (e = find(e, classname, "body")) != world; )
 913                         {
 914                                 if(e.enemy != self)
 915                                         continue;
 916                                 e.killindicator = spawn();
 917                                 e.killindicator.owner = e;
 918                                 e.killindicator.scale = 0.5;
 919                                 setattachment(e.killindicator, e, "");
 920                                 setorigin(e.killindicator, '0 0 52');
 921                                 e.killindicator.think = KillIndicator_Think;
 922                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
 923                                 e.killindicator.cnt = ceil(killtime);
 924                         }
 925                         self.lip = 0;
 926                 }
 927         }
 928         if(self.killindicator)
 929         {
 930                 if(targetteam)
 931                         self.killindicator.colormod = TeamColor(targetteam);
 932                 else
 933                         self.killindicator.colormod = '0 0 0';
 934         }
 935 }
 936
 937 void ClientKill (void)
 938 {
 939         ClientKill_TeamChange(0);
 940 }
 941
 942 void DoTeamChange(float destteam)
 943 {
 944         float t, c0;
 945         if(!cvar("teamplay"))
 946         {
 947                 if(destteam >= 0)
 948                         SetPlayerColors(self, destteam);
 949                 return;
 950         }
 951         if(self.classname == "player")
 952         if(destteam == -1)
 953         {
 954                 CheckAllowedTeams(self);
 955                 t = FindSmallestTeam(self, TRUE);
 956                 switch(self.team)
 957                 {
 958                         case COLOR_TEAM1: c0 = c1; break;
 959                         case COLOR_TEAM2: c0 = c2; break;
 960                         case COLOR_TEAM3: c0 = c3; break;
 961                         case COLOR_TEAM4: c0 = c4; break;
 962                         default:          c0 = 999;
 963                 }
 964                 switch(t)
 965                 {
 966                         case 1:
 967                                 if(c0 > c1)
 968                                         destteam = COLOR_TEAM1;
 969                                 break;
 970                         case 2:
 971                                 if(c0 > c2)
 972                                         destteam = COLOR_TEAM2;
 973                                 break;
 974                         case 3:
 975                                 if(c0 > c3)
 976                                         destteam = COLOR_TEAM3;
 977                                 break;
 978                         case 4:
 979                                 if(c0 > c4)
 980                                         destteam = COLOR_TEAM4;
 981                                 break;
 982                 }
 983                 if(destteam == -1)
 984                         return;
 985         }
 986         if(destteam == self.team && !self.killindicator)
 987                 return;
 988         ClientKill_TeamChange(destteam);
 989 }
 990
 991 void FixClientCvars(entity e)
 992 {
 993         // send prediction settings to the client
 994         stuffcmd(e, "\nin_bindmap 0 0\n");
 995         /*
 996          * we no longer need to stuff this. Remove this comment block if you feel
 997          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 998         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
 999         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1000         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1001         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1002         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1003         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1004         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1005         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1006         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1007         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1008         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1009         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1010         stuffcmd(e, "cl_movement_edgefriction 1\n");
1011          */
1012 }
1013
1014 /*
1015 =============
1016 ClientConnect
1017
1018 Called when a client connects to the server
1019 =============
1020 */
1021 //void ctf_clientconnect();
1022 string ColoredTeamName(float t);
1023 void DecodeLevelParms (void);
1024 //void dom_player_join_team(entity pl);
1025 void ClientConnect (void)
1026 {
1027         local string s;
1028         float wep;
1029
1030         if(self.flags & FL_CLIENT)
1031         {
1032                 print("Warning: ClientConnect, but already connected!\n");
1033                 return;
1034         }
1035
1036         if(Ban_IsClientBanned(self))
1037         {
1038                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
1039                 dropclient(self);
1040                 bprint(s);
1041                 return;
1042         }
1043
1044         DecodeLevelParms();
1045
1046         self.classname = "player_joining";
1047
1048         self.flags = self.flags | FL_CLIENT;
1049         self.version_nagtime = time + 10 + random() * 10;
1050
1051         if(player_count<0)
1052         {
1053                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1054                 player_count = 0;
1055         }
1056
1057         PlayerScore_Attach(self);
1058
1059         bot_clientconnect();
1060
1061         //if(g_domination)
1062         //      dom_player_join_team(self);
1063
1064         //JoinBestTeam(self, FALSE, FALSE);
1065
1066         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1067                 self.classname = "observer";
1068         } else {
1069                 self.classname = "player";
1070                 campaign_bots_may_start = 1;
1071         }
1072
1073         self.playerid = (playerid_last = playerid_last + 1);
1074         if(cvar("sv_eventlog"))
1075         {
1076                 if(clienttype(self) == CLIENTTYPE_REAL)
1077                         s = "player";
1078                 else
1079                         s = "bot";
1080                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
1081                 s = strcat(":team:", ftos(self.playerid), ":");
1082                 s = strcat(s, ftos(self.team));
1083                 GameLogEcho(s, FALSE);
1084         }
1085         self.netname_previous = strzone(self.netname);
1086
1087         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1088
1089         bprint ("^4",self.netname);
1090         bprint ("^4 connected");
1091
1092         if(g_domination || g_ctf)
1093         {
1094                 bprint(" and joined the ");
1095                 bprint(ColoredTeamName(self.team));
1096         }
1097
1098         bprint("\n");
1099
1100         self.welcomemessage_time = 0;
1101
1102         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1103         // TODO: is this being used for anything else than cd tracks?
1104         // Remember: SVC_CDTRACK exists. Maybe it should be used.
1105         //
1106         stuffcmd(self, "cl_particles_reloadeffects\n");
1107
1108         FixClientCvars(self);
1109
1110         // spawnfunc_waypoint sprites
1111         WaypointSprite_InitClient(self);
1112
1113         // Wazat's grappling hook
1114         SetGrappleHookBindings();
1115
1116         // get autoswitch state from player when he toggles it
1117         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1118
1119         // get version info from player
1120         stuffcmd(self, "cmd clientversion $gameversion\n");
1121
1122         // send all weapon info strings
1123         stuffcmd(self, "register_bestweapon clear\n"); // clear the Quake stuff
1124         wep = WEP_FIRST;
1125         while (wep <= WEP_LAST)
1126         {
1127                 weapon_action(wep, WR_REGISTER);
1128                 wep = wep + 1;
1129         }
1130
1131         // get other cvars from player
1132         GetCvars(0);
1133
1134         // set cvar for team scoreboard
1135         if (teams_matter)
1136         {
1137                 local float t;
1138                 t = cvar("teamplay");
1139                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1140                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1141         }
1142         else
1143                 stuffcmd(self, "set teamplay 0\n");
1144
1145         // notify about available teams
1146         if(teamplay)
1147         {
1148                 CheckAllowedTeams(self);
1149                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1150                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1151         }
1152         else
1153                 stuffcmd(self, "set _teams_available 0\n");
1154
1155         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1156
1157         if(g_arena)
1158         {
1159                 self.classname = "observer";
1160                 Spawnqueue_Insert(self);
1161         }
1162         /*else if(g_ctf)
1163         {
1164                 ctf_clientconnect();
1165         }*/
1166
1167         if(entcs_start)
1168                 attach_entcs();
1169
1170         bot_relinkplayerlist();
1171
1172         self.spectatortime = time;
1173         if(blockSpectators)
1174         {
1175                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1176         }
1177
1178         self.jointime = time;
1179         self.allowedTimeouts = cvar("sv_timeout_number");
1180
1181         if(clienttype(self) == CLIENTTYPE_REAL)
1182         {
1183                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1184                 SendCSQCInfo();
1185                 msg_entity = self;
1186                 if(mapvote_initialized && !cvar("g_maplist_textonly"))
1187                 {
1188                         MapVote_SendData(MSG_ONE);
1189                         MapVote_UpdateData(MSG_ONE);
1190                 }
1191                 ScoreInfo_Write(MSG_ONE);
1192         }
1193
1194         if(g_lms)
1195         {
1196                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1197                 {
1198                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1199                         self.frags = -666; // FIXME do we still need this?
1200                 }
1201         }
1202 }
1203
1204 /*
1205 =============
1206 ClientDisconnect
1207
1208 Called when a client disconnects from the server
1209 =============
1210 */
1211 void(entity e) DropFlag;
1212 .entity chatbubbleentity;
1213 .entity teambubbleentity;
1214 //void() ctf_clientdisconnect;
1215 void ClientDisconnect (void)
1216 {
1217         float save;
1218
1219         if not(self.flags & FL_CLIENT)
1220         {
1221                 print("Warning: ClientDisconnect without ClientConnect\n");
1222                 return;
1223         }
1224
1225         bot_clientdisconnect();
1226
1227         if(entcs_start)
1228                 detach_entcs();
1229
1230         if(cvar("sv_eventlog"))
1231                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
1232         bprint ("^4",self.netname);
1233         bprint ("^4 disconnected\n");
1234
1235         if (self.chatbubbleentity)
1236         {
1237                 remove (self.chatbubbleentity);
1238                 self.chatbubbleentity = world;
1239         }
1240
1241         if (self.teambubbleentity)
1242         {
1243                 remove (self.teambubbleentity);
1244                 self.teambubbleentity = world;
1245         }
1246
1247         if (self.killindicator)
1248         {
1249                 remove (self.killindicator);
1250                 self.killindicator = world;
1251         }
1252
1253         WaypointSprite_PlayerGone();
1254
1255         DropAllRunes(self);
1256         kh_Key_DropAll(self, TRUE);
1257
1258         if(self.flagcarried)
1259                 DropFlag(self.flagcarried);
1260
1261         save = self.flags;
1262         self.flags = self.flags - (self.flags & FL_CLIENT);
1263         bot_relinkplayerlist();
1264         self.flags = save;
1265
1266         // remove laserdot
1267         if(self.weaponentity)
1268                 if(self.weaponentity.lasertarget)
1269                         remove(self.weaponentity.lasertarget);
1270
1271         if(g_arena)
1272         {
1273                 Spawnqueue_Unmark(self);
1274                 Spawnqueue_Remove(self);
1275         }
1276         /*if(g_ctf)
1277         {
1278                 ctf_clientdisconnect();
1279         }
1280         */
1281
1282         PlayerScore_Detach(self);
1283
1284         if(self.netname_previous)
1285                 strunzone(self.netname_previous);
1286
1287         ClearPlayerSounds();
1288
1289         // free cvars
1290         GetCvars(-1);
1291         self.playerid = 0;
1292 }
1293
1294 .float BUTTON_CHAT;
1295 void ChatBubbleThink()
1296 {
1297         self.nextthink = time;
1298         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1299         {
1300                 self.owner.chatbubbleentity = world;
1301                 remove(self);
1302                 return;
1303         }
1304         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1305         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1306                 self.model = self.mdl;
1307         else
1308                 self.model = "";
1309 };
1310
1311 void UpdateChatBubble()
1312 {
1313         if (!self.modelindex)
1314                 return;
1315         // spawn a chatbubble entity if needed
1316         if (!self.chatbubbleentity)
1317         {
1318                 self.chatbubbleentity = spawn();
1319                 self.chatbubbleentity.owner = self;
1320                 self.chatbubbleentity.exteriormodeltoclient = self;
1321                 self.chatbubbleentity.think = ChatBubbleThink;
1322                 self.chatbubbleentity.nextthink = time;
1323                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1324                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1325                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1326                 self.chatbubbleentity.model = "";
1327                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1328         }
1329 }
1330
1331
1332 void TeamBubbleThink()
1333 {
1334         self.nextthink = time;
1335         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1336         {
1337                 self.owner.teambubbleentity = world;
1338                 remove(self);
1339                 return;
1340         }
1341 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1342         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1343                 self.model = "";
1344         else
1345                 self.model = self.mdl;
1346
1347 };
1348
1349 float TeamBubble_customizeentityforclient()
1350 {
1351         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1352 }
1353
1354 void UpdateTeamBubble()
1355 {
1356         if (!self.modelindex || !cvar("teamplay"))
1357                 return;
1358         // spawn a teambubble entity if needed
1359         if (!self.teambubbleentity && cvar("teamplay"))
1360         {
1361                 self.teambubbleentity = spawn();
1362                 self.teambubbleentity.owner = self;
1363                 self.teambubbleentity.exteriormodeltoclient = self;
1364                 self.teambubbleentity.think = TeamBubbleThink;
1365                 self.teambubbleentity.nextthink = time;
1366                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1367 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1368                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1369                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1370                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1371                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1372                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1373                 self.teambubbleentity.effects = EF_LOWPRECISION;
1374         }
1375 }
1376
1377 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1378 // added to the model skins
1379 /*void UpdateColorModHack()
1380 {
1381         local float c;
1382         c = self.clientcolors & 15;
1383         // LordHavoc: only bothering to support white, green, red, yellow, blue
1384              if (teamplay == 0) self.colormod = '0 0 0';
1385         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1386         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1387         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1388         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1389         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1390         else self.colormod = '1 1 1';
1391 };*/
1392
1393 void respawn(void)
1394 {
1395         CopyBody(1);
1396         self.effects |= EF_NODRAW; // prevent another CopyBody
1397         PutClientInServer();
1398 }
1399
1400 /**
1401  * When sv_timeout is used this function returs strings like
1402  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1403  * Called by centerprint functions
1404  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1405  */
1406 string getTimeoutText(float addOneSecond) {
1407         if (!cvar("sv_timeout") || !timeoutStatus)
1408                 return "";
1409
1410         local string retStr;
1411         if (timeoutStatus == 1) {
1412                 if (addOneSecond == 1) {
1413                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1414                 }
1415                 else {
1416                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1417                 }
1418                 return retStr;
1419         }
1420         else if (timeoutStatus == 2) {
1421                 if (addOneSecond) {
1422                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1423                         //don't show messages like "Timeout ends in 0 seconds"...
1424                         if ((remainingTimeoutTime + 1) > 0)
1425                                 return retStr;
1426                         else
1427                                 return "";
1428                 }
1429                 else {
1430                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1431                         //don't show messages like "Timeout ends in 0 seconds"...
1432                         if (remainingTimeoutTime > 0)
1433                                 return retStr;
1434                         else
1435                                 return "";
1436                 }
1437         }
1438         else return "";
1439 }
1440
1441 void player_powerups (void)
1442 {
1443         if (g_minstagib)
1444         {
1445                 if (self.items & IT_STRENGTH)
1446                 {
1447                         if (time > self.strength_finished)
1448                         {
1449                                 if (g_minstagib_invis_alpha > 0)
1450                                 {
1451                                         self.alpha = default_player_alpha;
1452                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1453                                         self.effects = self.effects | EF_FULLBRIGHT;
1454                                 }
1455                                 else
1456                                 {
1457                                         self.effects -= self.effects & EF_NODRAW;
1458                                 }
1459                                 self.items = self.items - (self.items & IT_STRENGTH);
1460                                 sprint(self, "^3Invisibility has worn off\n");
1461                         }
1462                 }
1463                 else
1464                 {
1465                         if (time < self.strength_finished)
1466                         {
1467                                 if (g_minstagib_invis_alpha > 0)
1468                                 {
1469                                         self.alpha = g_minstagib_invis_alpha;
1470                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1471                                         self.effects -= self.effects & EF_FULLBRIGHT;
1472                                 }
1473                                 else
1474                                 {
1475                                         self.effects = self.effects | EF_NODRAW;
1476                                 }
1477                                 self.items = self.items | IT_STRENGTH;
1478                                 sprint(self, "^3You are invisible\n");
1479                         }
1480                 }
1481
1482                 if (self.items & IT_INVINCIBLE)
1483                 {
1484                         if (time > self.invincible_finished)
1485                         {
1486                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1487                                 sprint(self, "^3Speed has worn off\n");
1488                         }
1489                 }
1490                 else
1491                 {
1492                         if (time < self.invincible_finished)
1493                         {
1494                                 self.items = self.items | IT_INVINCIBLE;
1495                                 sprint(self, "^3You are on speed\n");
1496                         }
1497                 }
1498                 return;
1499         }
1500
1501         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1502         if (self.items & IT_STRENGTH)
1503         {
1504                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1505                 if (time > self.strength_finished)
1506                 {
1507                         self.items = self.items - (self.items & IT_STRENGTH);
1508                         sprint(self, "^3Strength has worn off\n");
1509                 }
1510         }
1511         else
1512         {
1513                 if (time < self.strength_finished)
1514                 {
1515                         self.items = self.items | IT_STRENGTH;
1516                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1517                 }
1518         }
1519         if (self.items & IT_INVINCIBLE)
1520         {
1521                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1522                 if (time > self.invincible_finished)
1523                 {
1524                         self.items = self.items - (self.items & IT_INVINCIBLE);
1525                         sprint(self, "^3Shield has worn off\n");
1526                 }
1527         }
1528         else
1529         {
1530                 if (time < self.invincible_finished)
1531                 {
1532                         self.items = self.items | IT_INVINCIBLE;
1533                         sprint(self, "^3Shield surrounds you\n");
1534                 }
1535         }
1536
1537         if (cvar("g_fullbrightplayers"))
1538                 self.effects = self.effects | EF_FULLBRIGHT;
1539
1540         // midair gamemode: damage only while in the air
1541         // if in midair mode, being on ground grants temporary invulnerability
1542         // (this is so that multishot weapon don't clear the ground flag on the
1543         // first damage in the frame, leaving the player vulnerable to the
1544         // remaining hits in the same frame)
1545         if (self.flags & FL_ONGROUND)
1546         if (g_midair)
1547                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1548
1549         if (time < self.spawnshieldtime)
1550                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1551 }
1552
1553 float CalcRegen(float current, float stable, float regenfactor)
1554 {
1555         if(current > stable)
1556                 return current;
1557         else if(current > stable - 0.25) // when close enough, "snap"
1558                 return stable;
1559         else
1560                 return min(stable, current + (stable - current) * regenfactor * frametime);
1561 }
1562
1563 void player_regen (void)
1564 {
1565         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1566         maxh = cvar("g_balance_health_stable");
1567         maxa = cvar("g_balance_armor_stable");
1568         limith = cvar("g_balance_health_limit");
1569         limita = cvar("g_balance_armor_limit");
1570
1571         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1572                 return;
1573
1574         max_mod = regen_mod = rot_mod = limit_mod = 1;
1575
1576         if (self.runes & RUNE_REGEN)
1577         {
1578                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1579                 {
1580                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1581                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1582                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1583                 }
1584                 else
1585                 {
1586                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1587                         max_mod = cvar("g_balance_rune_regen_hpmod");
1588                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1589                 }
1590         }
1591         else if (self.runes & CURSE_VENOM)
1592         {
1593                 max_mod = cvar("g_balance_curse_venom_hpmod");
1594                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1595                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1596                 else
1597                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1598                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1599                 //if (!self.runes & RUNE_REGEN)
1600                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1601         }
1602         maxh = maxh * max_mod;
1603         //maxa = maxa * max_mod;
1604         limith = limith * limit_mod;
1605         limita = limita * limit_mod;
1606
1607         if (self.armorvalue > maxa)
1608         {
1609                 if (time > self.pauserotarmor_finished)
1610                 {
1611                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1612                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1613                 }
1614         }
1615         else if (self.armorvalue < maxa)
1616         {
1617                 if (time > self.pauseregen_finished)
1618                 {
1619                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1620                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1621                 }
1622         }
1623         if (self.health > maxh)
1624         {
1625                 if (time > self.pauserothealth_finished)
1626                 {
1627                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1628                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1629                 }
1630         }
1631         else if (self.health < maxh)
1632         {
1633                 if (time > self.pauseregen_finished)
1634                 {
1635                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1636                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1637                 }
1638         }
1639
1640         if (self.health > limith)
1641                 self.health = limith;
1642         if (self.armorvalue > limita)
1643                 self.armorvalue = limita;
1644
1645         // if player rotted to death...  die!
1646         if(self.health < 1)
1647                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1648 }
1649
1650 /*
1651 ======================
1652 spectate mode routines
1653 ======================
1654 */
1655 void SpectateCopy(entity spectatee) {
1656         self.armortype = spectatee.armortype;
1657         self.armorvalue = spectatee.armorvalue;
1658         self.currentammo = spectatee.currentammo;
1659         self.effects = spectatee.effects;
1660         self.health = spectatee.health;
1661         self.impulse = 0;
1662         self.items = spectatee.items;
1663         self.punchangle = spectatee.punchangle;
1664         self.view_ofs = spectatee.view_ofs;
1665         self.v_angle = spectatee.v_angle;
1666         self.viewzoom = spectatee.viewzoom;
1667         self.velocity = spectatee.velocity;
1668         self.dmg_take = spectatee.dmg_take;
1669         self.dmg_save = spectatee.dmg_save;
1670         self.dmg_inflictor = spectatee.dmg_inflictor;
1671         self.angles = spectatee.v_angle;
1672         self.fixangle = TRUE;
1673         setorigin(self, spectatee.origin);
1674         setsize(self, spectatee.mins, spectatee.maxs);
1675 }
1676
1677 float SpectateUpdate() {
1678         if(!self.enemy)
1679                 return 0;
1680
1681         if (self == self.enemy)
1682                 return 0;
1683
1684         if(self.enemy.flags & FL_NOTARGET)
1685                 return 0;
1686
1687         SpectateCopy(self.enemy);
1688
1689         return 1;
1690 }
1691
1692 float SpectateNext() {
1693         other = find(self.enemy, classname, "player");
1694         if (!other) {
1695                 other = find(other, classname, "player");
1696         }
1697         if (other) {
1698                 self.enemy = other;
1699         }
1700         if(self.enemy.classname == "player") {
1701                 msg_entity = self;
1702                 WriteByte(MSG_ONE, SVC_SETVIEW);
1703                 WriteEntity(MSG_ONE, self.enemy);
1704                 self.wantswelcomemessage = 1;
1705                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1706                 if(!SpectateUpdate())
1707                         PutObserverInServer();
1708                 return 1;
1709         } else {
1710                 return 0;
1711         }
1712 }
1713
1714 /*
1715 =============
1716 ShowRespawnCountdown()
1717
1718 Update a respawn countdown display.
1719 =============
1720 */
1721 void ShowRespawnCountdown()
1722 {
1723         float number;
1724         if(self.deadflag == DEAD_NO) // just respawned?
1725                 return;
1726         else
1727         {
1728                 number = ceil(self.death_time - time);
1729                 if(number <= 0)
1730                         return;
1731                 if(number <= self.respawn_countdown)
1732                 {
1733                         self.respawn_countdown = number - 1;
1734                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1735                                 announce(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1736                 }
1737         }
1738 }
1739
1740 void LeaveSpectatorMode()
1741 {
1742         if(isJoinAllowed()) {
1743                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1744                         self.classname = "player";
1745                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1746                                 JoinBestTeam(self, FALSE, TRUE);
1747                         if(cvar("g_campaign"))
1748                                 campaign_bots_may_start = 1;
1749                         PutClientInServer();
1750                         if(!(self.flags & FL_NOTARGET))
1751                                 bprint ("^4", self.netname, "^4 is playing now\n");
1752                         centerprint(self,"");
1753                         return;
1754                 } else {
1755                         stuffcmd(self,"menu_showteamselect\n");
1756                         return;
1757                 }
1758         }
1759         else {
1760                 //player may not join because of g_maxplayers is set
1761                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1762         }
1763 }
1764
1765 /**
1766  * Determines whether the player is allowed to join. This depends on cvar
1767  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1768  * it checks whether the number of currently playing players exceeds g_maxplayers.
1769  * @return bool TRUE if the player is allowed to join, false otherwise
1770  */
1771 float isJoinAllowed() {
1772         if (!cvar("g_maxplayers"))
1773                 return TRUE;
1774
1775         local entity e;
1776         local float currentlyPlaying;
1777         FOR_EACH_REALPLAYER(e) {
1778                 if(e.classname == "player")
1779                         currentlyPlaying += 1;
1780         }
1781         if(currentlyPlaying < cvar("g_maxplayers"))
1782                 return TRUE;
1783
1784         return FALSE;
1785 }
1786
1787 /**
1788  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1789  * g_maxplayers_spectator_blocktime seconds
1790  */
1791 void checkSpectatorBlock() {
1792         if(self.classname == "spectator" || self.classname == "observer") {
1793                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1794                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1795                         dropclient(self);
1796                 }
1797         }
1798 }
1799
1800 float vercmp_recursive(string v1, string v2)
1801 {
1802         float dot1, dot2;
1803         string s1, s2;
1804         float r;
1805
1806         dot1 = strstrofs(v1, ".", 0);
1807         dot2 = strstrofs(v2, ".", 0);
1808         if(dot1 == -1)
1809                 s1 = v1;
1810         else
1811                 s1 = substring(v1, 0, dot1);
1812         if(dot2 == -1)
1813                 s2 = v2;
1814         else
1815                 s2 = substring(v2, 0, dot2);
1816
1817         r = stof(s1) - stof(s2);
1818         if(r != 0)
1819                 return r;
1820
1821         r = strcasecmp(s1, s2);
1822         if(r != 0)
1823                 return r;
1824
1825         if(dot1 == -1)
1826                 if(dot2 == -1)
1827                         return 0;
1828                 else
1829                         return -1;
1830         else
1831                 if(dot2 == -1)
1832                         return 1;
1833                 else
1834                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1835 }
1836
1837 float vercmp(string v1, string v2)
1838 {
1839         if(strcasecmp(v1, v2) == 0) // early out check
1840                 return 0;
1841         return vercmp_recursive(v1, v2);
1842 }
1843
1844 void ObserverThink()
1845 {
1846         if (self.flags & FL_JUMPRELEASED) {
1847                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1848                         self.welcomemessage_time = 0;
1849                         self.flags = self.flags - FL_JUMPRELEASED;
1850                         LeaveSpectatorMode();
1851                         return;
1852                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
1853                         self.welcomemessage_time = 0;
1854                         self.flags = self.flags - FL_JUMPRELEASED;
1855                         if(SpectateNext() == 1) {
1856                                 self.classname = "spectator";
1857                         }
1858                 }
1859         } else {
1860                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
1861                         self.flags = self.flags | FL_JUMPRELEASED;
1862                 }
1863         }
1864         if(self.BUTTON_ZOOM)
1865                 self.wantswelcomemessage = 0;
1866         if(self.wantswelcomemessage)
1867                 PrintWelcomeMessage(self);
1868 }
1869
1870 void SpectatorThink()
1871 {
1872         if (self.flags & FL_JUMPRELEASED) {
1873                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1874                         self.welcomemessage_time = 0;
1875                         self.flags = self.flags - FL_JUMPRELEASED;
1876                         LeaveSpectatorMode();
1877                         return;
1878                 } else if(self.BUTTON_ATCK) {
1879                         self.welcomemessage_time = 0;
1880                         self.flags = self.flags - FL_JUMPRELEASED;
1881                         if(SpectateNext() == 1) {
1882                                 self.classname = "spectator";
1883                         } else {
1884                                 self.classname = "observer";
1885                                 PutClientInServer();
1886                         }
1887                 } else if (self.BUTTON_ATCK2) {
1888                         self.welcomemessage_time = 0;
1889                         self.flags = self.flags - FL_JUMPRELEASED;
1890                         self.classname = "observer";
1891                         PutClientInServer();
1892                 } else {
1893                         if(!SpectateUpdate())
1894                                 PutObserverInServer();
1895                 }
1896         } else {
1897                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
1898                         self.flags = self.flags | FL_JUMPRELEASED;
1899                 }
1900         }
1901         if(self.BUTTON_ZOOM)
1902                 self.wantswelcomemessage = 0;
1903         if(self.wantswelcomemessage)
1904                 PrintWelcomeMessage(self);
1905         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1906 }
1907
1908 /*
1909 =============
1910 PlayerPreThink
1911
1912 Called every frame for each client before the physics are run
1913 =============
1914 */
1915 void() ctf_setstatus;
1916 .float vote_nagtime;
1917 void PlayerPreThink (void)
1918 {
1919         if(blockSpectators)
1920                 checkSpectatorBlock();
1921
1922         if(self.netname_previous != self.netname)
1923         {
1924                 if(cvar("sv_eventlog"))
1925                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname), TRUE);
1926                 if(self.netname_previous)
1927                         strunzone(self.netname_previous);
1928                 self.netname_previous = strzone(self.netname);
1929         }
1930
1931         // version nagging
1932         if(self.version_nagtime)
1933                 if(self.cvar_g_nexuizversion)
1934                         if(time > self.version_nagtime)
1935                         {
1936                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1937                                 {
1938                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
1939                                         {
1940                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1941                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1942                                         }
1943                                         else
1944                                         {
1945                                                 float r;
1946                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
1947                                                 if(r < 0)
1948                                                 {
1949                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
1950                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
1951                                                 }
1952                                                 else if(r > 0)
1953                                                 {
1954                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1955                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1956                                                 }
1957                                         }
1958                                 }
1959                                 self.version_nagtime = 0;
1960                         }
1961
1962         // vote nagging
1963         if(self.cvar_scr_centertime)
1964                 if(time > self.vote_nagtime)
1965                 {
1966                         VoteNag();
1967                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1968                 }
1969
1970         // GOD MODE info
1971         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
1972         {
1973                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
1974                 self.max_armorvalue = 0;
1975         }
1976
1977         if(frametime)
1978                 antilag_record(self);
1979
1980         if(self.classname == "player") {
1981 //              if(self.netname == "Wazat")
1982 //                      bprint(self.classname, "\n");
1983
1984                 CheckRules_Player();
1985
1986                 if(self.BUTTON_INFO)
1987                         PrintWelcomeMessage(self);
1988
1989                 if(g_lms || !cvar("sv_spectate"))
1990                 if((time - self.jointime) <= cvar("welcome_message_time"))
1991                         PrintWelcomeMessage(self);
1992
1993                 if (intermission_running)
1994                 {
1995                         IntermissionThink ();   // otherwise a button could be missed between
1996                         return;                                 // the think tics
1997                 }
1998
1999                 if(self.teleport_time)
2000                 if(time > self.teleport_time)
2001                 {
2002                         self.teleport_time = 0;
2003                         self.effects = self.effects - (self.effects & EF_NODRAW);
2004                         if(self.weaponentity)
2005                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
2006                 }
2007
2008                 Nixnex_GiveCurrentWeapon();
2009
2010                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2011                         UpdateSelectedPlayer();
2012
2013                 //don't allow the player to turn around while game is paused!
2014                 if(timeoutStatus == 2) {
2015                         self.v_angle = self.lastV_angle;
2016                         self.angles = self.lastV_angle;
2017                         self.fixangle = TRUE;
2018                 }
2019
2020                 if (self.deadflag != DEAD_NO)
2021                 {
2022                         float button_pressed, force_respawn;
2023                         player_anim();
2024                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2025                         force_respawn = (g_lms || cvar("g_forced_respawn"));
2026                         if (self.deadflag == DEAD_DYING)
2027                         {
2028                                 if(force_respawn)
2029                                         self.deadflag = DEAD_RESPAWNING;
2030                                 else if(!button_pressed)
2031                                         self.deadflag = DEAD_DEAD;
2032                         }
2033                         else if (self.deadflag == DEAD_DEAD)
2034                         {
2035                                 if(button_pressed)
2036                                         self.deadflag = DEAD_RESPAWNABLE;
2037                         }
2038                         else if (self.deadflag == DEAD_RESPAWNABLE)
2039                         {
2040                                 if(!button_pressed)
2041                                         self.deadflag = DEAD_RESPAWNING;
2042                         }
2043                         else if (self.deadflag == DEAD_RESPAWNING)
2044                         {
2045                                 if(time > self.death_time)
2046                                 {
2047                                         self.death_time = time + 1; // only retry once a second
2048                                         respawn();
2049                                 }
2050                         }
2051                         ShowRespawnCountdown();
2052                         return;
2053                 }
2054
2055                 if((g_race || g_lms) && !self.deadflag && cvar("g_lms_campcheck_interval"))
2056                 {
2057                         vector dist;
2058
2059                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2060                         dist = self.oldorigin - self.origin;
2061                         dist_z = 0;
2062                         self.lms_traveled_distance += fabs(vlen(dist));
2063
2064                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
2065                         {
2066                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2067                                 self.lms_traveled_distance = 0;
2068                         }
2069
2070                         if(time > self.lms_nextcheck)
2071                         {
2072                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2073                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2074                                 {
2075                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2076                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2077                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2078                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2079                                 }
2080                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2081                                 self.lms_traveled_distance = 0;
2082                         }
2083                 }
2084
2085                 if (self.BUTTON_CROUCH && !self.hook.state)
2086                 {
2087                         if (!self.crouch)
2088                         {
2089                                 self.crouch = TRUE;
2090                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2091                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2092                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
2093                         }
2094                 }
2095                 else
2096                 {
2097                         if (self.crouch)
2098                         {
2099                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2100                                 if (!trace_startsolid)
2101                                 {
2102                                         self.crouch = FALSE;
2103                                         self.view_ofs = PL_VIEW_OFS;
2104                                         setsize (self, PL_MIN, PL_MAX);
2105                                 }
2106                         }
2107                 }
2108
2109                 FixPlayermodel();
2110
2111                 GrapplingHookFrame();
2112
2113                 W_WeaponFrame();
2114
2115                 {
2116                         float zoomfactor, zoomspeed, zoomdir;
2117                         zoomfactor = self.cvar_cl_zoomfactor;
2118                         if(zoomfactor < 1 || zoomfactor > 16)
2119                                 zoomfactor = 2.5;
2120                         zoomspeed = self.cvar_cl_zoomspeed;
2121                         if(zoomspeed >= 0) // < 0 is instant zoom
2122                                 if(zoomspeed < 0.5 || zoomspeed > 16)
2123                                         zoomspeed = 3.5;
2124
2125                         zoomdir = self.BUTTON_ZOOM;
2126                         if(self.BUTTON_ATCK2)
2127                                 if(self.weapon == WEP_NEX)
2128                                         if(!g_minstagib)
2129                                                 zoomdir = 1;
2130
2131                         if(zoomdir)
2132                                 self.has_zoomed = 1;
2133
2134                         if(self.has_zoomed)
2135                         {
2136                                 if(zoomspeed <= 0) // instant zoom
2137                                 {
2138                                         if(zoomdir)
2139                                                 self.viewzoom = 1 / zoomfactor;
2140                                         else
2141                                                 self.viewzoom = 1;
2142                                 }
2143                                 else
2144                                 {
2145                                         // geometric zoom would be:
2146                                         //   self.viewzoom = bound(1 / zoomfactor, self.viewzoom * pow(zoomfactor, (zoomdir ? -1 : 1) * frametime * zoomspeed), 1);
2147                                         // however, testing showed that arithmetic/harmonic zoom works better
2148                                         if(zoomdir)
2149                                                 // self.viewzoom = 1 / bound(1, 1 / self.viewzoom + (zoomdir ? 1 : -1) * frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2150                                                 // zoom in = arithmetic: 1x, 2x, 3x, 4x, ..., 8x
2151                                                 self.viewzoom = 1 / bound(1, 1 / self.viewzoom + frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2152                                         else
2153                                                 // self.viewzoom = bound(1 / zoomfactor, self.viewzoom + (zoomdir ? -1 : 1) * frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2154                                                 // zoom out = harmonic: 8/1x, 8/2x, 8/3x, 8/4x, ..., 8/8x
2155                                                 self.viewzoom = bound(1 / zoomfactor, self.viewzoom + frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2156                                 }
2157                         }
2158                         else
2159                                 self.viewzoom = min(1, self.viewzoom + frametime); // spawn zoom-in
2160                 }
2161
2162                 player_powerups();
2163                 player_regen();
2164                 player_anim();
2165
2166                 if (g_minstagib)
2167                         minstagib_ammocheck();
2168
2169                 ctf_setstatus();
2170                 kh_setstatus();
2171
2172                 //self.angles_y=self.v_angle_y + 90;   // temp
2173
2174                 //if (TetrisPreFrame()) return;
2175         } else if(gameover) {
2176                 if (intermission_running)
2177                         IntermissionThink ();   // otherwise a button could be missed between
2178                 return;
2179         } else if(self.classname == "observer") {
2180                 ObserverThink();
2181         } else if(self.classname == "spectator") {
2182                 SpectatorThink();
2183         }
2184 }
2185
2186
2187 /*
2188 =============
2189 PlayerPostThink
2190
2191 Called every frame for each client after the physics are run
2192 =============
2193 */
2194 .float idlekick_lasttimeleft;
2195 void PlayerPostThink (void)
2196 {
2197         // Savage: Check for nameless players
2198         if (strlen(self.netname) < 1) {
2199                 self.netname = "Player";
2200                 stuffcmd(self, "seta _cl_name Player\n");
2201         }
2202
2203         if(sv_maxidle)
2204         {
2205                 float timeleft;
2206                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2207                 if(timeleft <= 0)
2208                 {
2209                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2210                         announce(self, "announcer/robotic/terminated.ogg");
2211                         dropclient(self);
2212                         return;
2213                 }
2214                 else if(timeleft <= 10)
2215                 {
2216                         if(timeleft != self.idlekick_lasttimeleft)
2217                         {
2218                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2219                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".ogg"));
2220                         }
2221                 }
2222                 else
2223                 {
2224                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2225                 }
2226                 self.idlekick_lasttimeleft = timeleft;
2227         }
2228
2229         if(self.classname == "player") {
2230                 CheckRules_Player();
2231                 UpdateChatBubble();
2232                 UpdateTeamBubble();
2233                 if (self.impulse)
2234                         ImpulseCommands();
2235                 if (intermission_running)
2236                         return;         // intermission or finale
2237
2238                 //PrintWelcomeMessage(self);
2239                 //if (TetrisPostFrame()) return;
2240
2241                 // restart countdown
2242                 if (restart_countdown) {
2243                         if(time < restart_countdown) {
2244                                 if (!cvar("sv_ready_restart_after_countdown"))
2245                                 {
2246                                         self.movetype = MOVETYPE_NONE;
2247                                         self.velocity = '0 0 0';
2248                                         self.avelocity = '0 0 0';
2249                                         self.movement = '0 0 0';
2250                                 }
2251                         }
2252                         else
2253                         {
2254                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2255                                 if (!cvar("sv_ready_restart_after_countdown"))
2256                                 {
2257                                         if(self.movetype == MOVETYPE_NONE)
2258                                         {
2259                                                 self.movetype = MOVETYPE_WALK;
2260                                         }
2261                                 }
2262                         }
2263                 }
2264
2265         } else if (self.classname == "observer") {
2266                 //do nothing
2267         } else if (self.classname == "spectator") {
2268                 //do nothing
2269         }
2270
2271         /*
2272         float i;
2273         for(i = 0; i < 1000; ++i)
2274         {
2275                 vector end;
2276                 end = self.origin + '0 0 1024' + 512 * randomvec();
2277                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2278                 if(trace_fraction < 1)
2279                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2280                 {
2281                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2282                         break;
2283                 }
2284         }
2285         */
2286
2287         Arena_Warmup();
2288 }