data/qcsrc/server/cl_client.qc

   1 // let's abuse an existing field
   2 #define SPAWNPOINT_SCORE frags
   3
   4 .float wantswelcomemessage;
   5 .string netname_previous;
   6
   7 void spawnfunc_info_player_survivor (void)
   8 {
   9         spawnfunc_info_player_deathmatch();
  10 }
  11
  12 void spawnfunc_info_player_start (void)
  13 {
  14         spawnfunc_info_player_deathmatch();
  15 }
  16
  17 void spawnfunc_info_player_deathmatch (void)
  18 {
  19         self.classname = "info_player_deathmatch";
  20         relocate_spawnpoint();
  21 }
  22
  23 void spawnpoint_use()
  24 {
  25         if(teams_matter)
  26         if(have_team_spawns)
  27         {
  28                 self.team = activator.team;
  29                 some_spawn_has_been_used = 1;
  30         }
  31 };
  32
  33 // Returns:
  34 //   -1 if a spawn can't be used
  35 //   otherwise, a weight of the spawnpoint
  36 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
  37 {
  38         float shortest, thisdist;
  39         entity player;
  40
  41         // filter out spots for the wrong team
  42         if(teamcheck)
  43         if(spot.team != teamcheck)
  44                 return -1;
  45
  46         // filter out spots for assault
  47         if(spot.target != "") {
  48                 local entity ent;
  49                 ent = find(world, targetname, spot.target);
  50                 while(ent) {
  51                         if(ent.classname == "target_objective")
  52                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  53                                         return -1;
  54                         ent = find(ent, targetname, spot.target);
  55                 }
  56         }
  57
  58         player = playerlist;
  59         shortest = vlen(world.maxs - world.mins);
  60         for(player = playerlist; player; player = player.chain)
  61                 if (player != self)
  62                 {
  63                         thisdist = vlen(player.origin - spot.origin);
  64                         if (thisdist < shortest)
  65                                 shortest = thisdist;
  66                 }
  67         return shortest;
  68 }
  69
  70 float spawn_allbad;
  71 float spawn_allgood;
  72 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  73 {
  74         local entity spot, spotlist, spotlistend;
  75         spawn_allgood = TRUE;
  76         spawn_allbad = TRUE;
  77
  78         spotlist = world;
  79         spotlistend = world;
  80
  81         for(spot = firstspot; spot; spot = spot.chain)
  82         {
  83                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
  84
  85                 if(cvar("spawn_debugview"))
  86                 {
  87                         setmodel(spot, "models/runematch/rune.mdl");
  88                         if(spot.SPAWNPOINT_SCORE < mindist)
  89                         {
  90                                 spot.colormod = '1 0 0';
  91                                 spot.scale = 1;
  92                         }
  93                         else
  94                         {
  95                                 spot.colormod = '0 1 0';
  96                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
  97                         }
  98                 }
  99
 100                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 101                 {
 102                         if(spot.SPAWNPOINT_SCORE < mindist)
 103                         {
 104                                 // too short distance
 105                                 spawn_allgood = FALSE;
 106                         }
 107                         else
 108                         {
 109                                 // perfect
 110                                 spawn_allbad = FALSE;
 111
 112                                 if(spotlistend)
 113                                         spotlistend.chain = spot;
 114                                 spotlistend = spot;
 115                                 if(!spotlist)
 116                                         spotlist = spot;
 117
 118                                 /*
 119                                 if(teamcheck)
 120                                 if(spot.team != teamcheck)
 121                                         error("invalid spawn added");
 122
 123                                 print("added ", etos(spot), "\n");
 124                                 */
 125                         }
 126                 }
 127         }
 128         if(spotlistend)
 129                 spotlistend.chain = world;
 130
 131         /*
 132                 entity e;
 133                 if(teamcheck)
 134                         for(e = spotlist; e; e = e.chain)
 135                         {
 136                                 print("seen ", etos(e), "\n");
 137                                 if(e.team != teamcheck)
 138                                         error("invalid spawn found");
 139                         }
 140         */
 141
 142         return spotlist;
 143 }
 144
 145 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 146 {
 147         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 148         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 149         local entity spot;
 150
 151         RandomSelection_Init();
 152         for(spot = firstspot; spot; spot = spot.chain)
 153                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 154
 155         return RandomSelection_chosen_ent;
 156 }
 157
 158 /*
 159 =============
 160 SelectSpawnPoint
 161
 162 Finds a point to respawn
 163 =============
 164 */
 165 entity SelectSpawnPoint (float anypoint)
 166 {
 167         local float teamcheck;
 168         local entity firstspot_new;
 169         local entity spot, firstspot, playerlist;
 170
 171         spot = find (world, classname, "testplayerstart");
 172         if (spot)
 173                 return spot;
 174
 175         teamcheck = 0;
 176
 177         if(!anypoint && have_team_spawns)
 178                 teamcheck = self.team;
 179
 180         // get the list of players
 181         playerlist = findchain(classname, "player");
 182         // get the entire list of spots
 183         firstspot = findchain(classname, "info_player_deathmatch");
 184         // filter out the bad ones
 185         // (note this returns the original list if none survived)
 186         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 187         if(!firstspot_new)
 188                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 189         firstspot = firstspot_new;
 190
 191         // there is 50/50 chance of choosing a random spot or the furthest spot
 192         // (this means that roughly every other spawn will be furthest, so you
 193         // usually won't get fragged at spawn twice in a row)
 194         if (arena_roundbased)
 195         {
 196                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 197                 if(firstspot_new)
 198                         firstspot = firstspot_new;
 199                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 200         }
 201         else if (random() > cvar("g_spawn_furthest"))
 202                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 203         else
 204                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 205
 206         if(cvar("spawn_debugview"))
 207         {
 208                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 209
 210                 entity e;
 211                 if(teamcheck)
 212                         for(e = firstspot; e; e = e.chain)
 213                                 if(e.team != teamcheck)
 214                                         error("invalid spawn found");
 215         }
 216
 217         if (!spot)
 218         {
 219                 if(cvar("spawn_debug"))
 220                         GotoNextMap();
 221                 else
 222                 {
 223                         if(some_spawn_has_been_used)
 224                                 return world; // team can't spawn any more, because of actions of other team
 225                         else
 226                                 error("Cannot find a spawn point - please fix the map!");
 227                 }
 228         }
 229
 230         return spot;
 231 }
 232
 233 /*
 234 =============
 235 CheckPlayerModel
 236
 237 Checks if the argument string can be a valid playermodel.
 238 Returns a valid one in doubt.
 239 =============
 240 */
 241 string FallbackPlayerModel = "models/player/marine.zym";
 242 string CheckPlayerModel(string plyermodel) {
 243         if(strlen(plyermodel) < 4)
 244                 return FallbackPlayerModel;
 245         if( substring(plyermodel,0,14) != "models/player/")
 246                 return FallbackPlayerModel;
 247         else if(cvar("sv_servermodelsonly"))
 248         {
 249                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 250                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 251                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 252                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 253                         return FallbackPlayerModel;
 254                 if(!fexists(plyermodel))
 255                         return FallbackPlayerModel;
 256         }
 257         return plyermodel;
 258 }
 259
 260 /*
 261 =============
 262 Client_customizeentityforclient
 263
 264 LOD reduction
 265 =============
 266 */
 267 float Client_customizeentityforclient()
 268 {
 269 #ifdef ALLOW_VARIABLE_LOD
 270         // self: me
 271         // other: the player viewing me
 272         float distance;
 273         float f;
 274
 275         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 276                 return TRUE;
 277
 278         if(other.cvar_cl_playerdetailreduction <= 0)
 279         {
 280                 if(other.cvar_cl_playerdetailreduction <= -2)
 281                         self.modelindex = self.modelindex_lod2;
 282                 else if(other.cvar_cl_playerdetailreduction <= -1)
 283                         self.modelindex = self.modelindex_lod1;
 284                 else
 285                         self.modelindex = self.modelindex_lod0;
 286         }
 287         else
 288         {
 289                 distance = vlen(self.origin - other.origin);
 290                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 291                 if(f > 10000)
 292                         self.modelindex = self.modelindex_lod2;
 293                 else if(f > 5000)
 294                         self.modelindex = self.modelindex_lod1;
 295                 else
 296                         self.modelindex = self.modelindex_lod0;
 297         }
 298 #endif
 299
 300         return TRUE;
 301 }
 302
 303 void UpdatePlayerSounds();
 304 void setmodel_lod(entity e, string modelname)
 305 {
 306 #ifdef ALLOW_VARIABLE_LOD
 307         string s;
 308
 309         // FIXME: this only supports 3-letter extensions
 310         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 311         if(fexists(s))
 312         {
 313                 precache_model(s);
 314                 setmodel(e, s); // players have high precision
 315                 self.modelindex_lod1 = self.modelindex;
 316         }
 317         else
 318                 self.modelindex_lod1 = -1;
 319
 320         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 321         if(fexists(s))
 322         {
 323                 precache_model(s);
 324                 setmodel(e, s); // players have high precision
 325                 self.modelindex_lod2 = self.modelindex;
 326         }
 327         else
 328                 self.modelindex_lod2 = -1;
 329
 330         precache_model(modelname);
 331         setmodel(e, modelname); // players have high precision
 332         self.modelindex_lod0 = self.modelindex;
 333
 334         if(self.modelindex_lod1 < 0)
 335                 self.modelindex_lod1 = self.modelindex;
 336
 337         if(self.modelindex_lod2 < 0)
 338                 self.modelindex_lod2 = self.modelindex;
 339 #else
 340         precache_model(modelname);
 341         setmodel(e, modelname); // players have high precision
 342 #endif
 343         player_setupanimsformodel();
 344         UpdatePlayerSounds();
 345 }
 346
 347 /*
 348 =============
 349 PutObserverInServer
 350
 351 putting a client as observer in the server
 352 =============
 353 */
 354 void PutObserverInServer (void)
 355 {
 356         entity  spot;
 357         spot = SelectSpawnPoint (TRUE);
 358         if(!spot)
 359                 error("No spawnpoints for observers?!?\n");
 360         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 361
 362         if(clienttype(self) == CLIENTTYPE_REAL)
 363         {
 364                 msg_entity = self;
 365                 WriteByte(MSG_ONE, SVC_SETVIEW);
 366                 WriteEntity(MSG_ONE, self);
 367         }
 368
 369         DropAllRunes(self);
 370         kh_Key_DropAll(self, TRUE);
 371
 372         if(self.flagcarried)
 373                 DropFlag(self.flagcarried);
 374
 375         WaypointSprite_PlayerDead();
 376
 377         if(self.killcount != -666)
 378         {
 379                 if(g_lms)
 380                 {
 381                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 382                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 383                         else
 384                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 385                 }
 386                 else
 387                         bprint ("^4", self.netname, "^4 is spectating now\n");
 388         }
 389
 390         PlayerScore_Clear(self); // clear scores when needed
 391
 392         self.spectatortime = time;
 393
 394         self.classname = "observer";
 395         self.health = -666;
 396         self.takedamage = DAMAGE_NO;
 397         self.solid = SOLID_NOT;
 398         self.movetype = MOVETYPE_NOCLIP;
 399         self.flags = FL_CLIENT | FL_NOTARGET;
 400         self.armorvalue = 666;
 401         self.effects = 0;
 402         self.armorvalue = cvar("g_balance_armor_start");
 403         self.pauserotarmor_finished = 0;
 404         self.pauserothealth_finished = 0;
 405         self.pauseregen_finished = 0;
 406         self.damageforcescale = 0;
 407         self.death_time = 0;
 408         self.dead_frame = 0;
 409         self.alpha = 0;
 410         self.scale = 0;
 411         self.fade_time = 0;
 412         self.pain_frame = 0;
 413         self.pain_finished = 0;
 414         self.strength_finished = 0;
 415         self.invincible_finished = 0;
 416         self.pushltime = 0;
 417         self.think = SUB_Null;
 418         self.nextthink = 0;
 419         self.hook_time = 0;
 420         self.runes = 0;
 421         self.deadflag = DEAD_NO;
 422         self.angles = spot.angles;
 423         self.angles_z = 0;
 424         self.fixangle = TRUE;
 425         self.crouch = FALSE;
 426
 427         self.view_ofs = PL_VIEW_OFS;
 428         setorigin (self, spot.origin);
 429         setsize (self, '0 0 0', '0 0 0');
 430         self.oldorigin = self.origin;
 431         self.items = 0;
 432         self.model = "";
 433         self.modelindex = 0;
 434         self.weapon = 0;
 435         self.weaponmodel = "";
 436         self.weaponentity = world;
 437         self.killcount = -666;
 438         self.velocity = '0 0 0';
 439         self.avelocity = '0 0 0';
 440         self.punchangle = '0 0 0';
 441         self.punchvector = '0 0 0';
 442         self.oldvelocity = self.velocity;
 443         self.customizeentityforclient = Client_customizeentityforclient;
 444         self.viewzoom = 1;
 445         self.wantswelcomemessage = 1;
 446
 447         if(g_arena)
 448         {
 449                 if(self.frags != -2)
 450                 {
 451                         Spawnqueue_Insert(self);
 452                         // FIXME what IS this?
 453                 }
 454                 else
 455                 {
 456                         Spawnqueue_Unmark(self);
 457                         Spawnqueue_Remove(self);
 458                 }
 459         }
 460         else if(g_lms)
 461         {
 462                 // Only if the player cannot play at all
 463                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 464                         self.frags = -666;
 465                 else
 466                         self.frags = -667;
 467         }
 468         else
 469                 self.frags = -666;
 470 }
 471
 472 float RestrictSkin(float s)
 473 {
 474         if(!teams_matter)
 475                 return s;
 476         if(s == 6)
 477                 return 6;
 478         return mod(s, 3);
 479 }
 480
 481 void FixPlayermodel()
 482 {
 483         local string defaultmodel;
 484         local float defaultskin;
 485         local vector m1, m2;
 486
 487         defaultmodel = "";
 488
 489         if(cvar("sv_defaultcharacter") == 1) {
 490                 defaultskin = 0;
 491
 492                 if(teams_matter)
 493                 {
 494                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 495                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 496                 }
 497
 498                 if(defaultmodel == "")
 499                 {
 500                         defaultmodel = cvar_string("sv_defaultplayermodel");
 501                         defaultskin = cvar("sv_defaultplayerskin");
 502                 }
 503         }
 504
 505         if(defaultmodel != "")
 506         {
 507                 if (defaultmodel != self.model)
 508                 {
 509                         m1 = self.mins;
 510                         m2 = self.maxs;
 511                         setmodel_lod (self, defaultmodel);
 512                         setsize (self, m1, m2);
 513                 }
 514
 515                 self.skin = defaultskin;
 516         } else {
 517                 if (self.playermodel != self.model)
 518                 {
 519                         self.playermodel = CheckPlayerModel(self.playermodel);
 520                         m1 = self.mins;
 521                         m2 = self.maxs;
 522                         setmodel_lod (self, self.playermodel);
 523                         setsize (self, m1, m2);
 524                 }
 525
 526                 self.skin = RestrictSkin(stof(self.playerskin));
 527         }
 528
 529         if(!teams_matter)
 530                 if(strlen(cvar_string("sv_defaultplayercolors")))
 531                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 532                                 setcolor(self, cvar("sv_defaultplayercolors"));
 533 }
 534
 535 /*
 536 =============
 537 PutClientInServer
 538
 539 Called when a client spawns in the server
 540 =============
 541 */
 542 //void() ctf_playerchanged;
 543 void PutClientInServer (void)
 544 {
 545         if(clienttype(self) == CLIENTTYPE_BOT)
 546         {
 547                 self.classname = "player";
 548         }
 549         else if(clienttype(self) == CLIENTTYPE_REAL)
 550         {
 551                 msg_entity = self;
 552                 WriteByte(MSG_ONE, SVC_SETVIEW);
 553                 WriteEntity(MSG_ONE, self);
 554         }
 555
 556         // player is dead and becomes observer
 557         // FIXME fix LMS scoring for new system
 558         if(g_lms)
 559         {
 560                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 561                         self.classname = "observer";
 562         }
 563
 564         if(g_arena)
 565         if(!self.spawned)
 566                 self.classname = "observer";
 567
 568         if(self.classname == "player") {
 569                 entity  spot;
 570
 571                 spot = SelectSpawnPoint (FALSE);
 572                 if(!spot)
 573                 {
 574                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 575                         return; // spawn failed
 576                 }
 577
 578                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 579
 580                 self.classname = "player";
 581                 self.iscreature = TRUE;
 582                 self.movetype = MOVETYPE_WALK;
 583                 self.solid = SOLID_SLIDEBOX;
 584                 self.flags = FL_CLIENT;
 585                 self.takedamage = DAMAGE_AIM;
 586                 if(g_minstagib)
 587                         self.effects = EF_FULLBRIGHT;
 588                 else
 589                         self.effects = 0;
 590                 self.air_finished = time + 12;
 591                 self.dmg = 2;
 592
 593                 self.ammo_shells = start_ammo_shells;
 594                 self.ammo_nails = start_ammo_nails;
 595                 self.ammo_rockets = start_ammo_rockets;
 596                 self.ammo_cells = start_ammo_cells;
 597                 self.health = start_health;
 598                 self.armorvalue = start_armorvalue;
 599                 self.items = start_items;
 600                 self.switchweapon = start_switchweapon;
 601                 self.cnt = start_switchweapon;
 602                 self.weapon = 0;
 603                 self.jump_interval = time;
 604
 605                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 606                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 607                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 608                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 609                 //extend the pause of rotting if client was reset at the beginning of the countdown
 610                 if(!cvar("sv_ready_restart_after_countdown") && time < restart_countdown) {
 611                         self.spawnshieldtime += RESTART_COUNTDOWN;
 612                         self.pauserotarmor_finished += RESTART_COUNTDOWN;
 613                         self.pauserothealth_finished += RESTART_COUNTDOWN;
 614                         self.pauseregen_finished += RESTART_COUNTDOWN;
 615                 }
 616                 self.damageforcescale = 2;
 617                 self.death_time = 0;
 618                 self.dead_frame = 0;
 619                 self.alpha = 0;
 620                 self.scale = 0;
 621                 self.fade_time = 0;
 622                 self.pain_frame = 0;
 623                 self.pain_finished = 0;
 624                 self.strength_finished = 0;
 625                 self.invincible_finished = 0;
 626                 self.pushltime = 0;
 627                 //self.speed_finished = 0;
 628                 //self.slowmo_finished = 0;
 629                 // players have no think function
 630                 self.think = SUB_Null;
 631                 self.nextthink = 0;
 632                 self.hook_time = 0;
 633
 634                 self.runes = 0;
 635
 636                 self.deadflag = DEAD_NO;
 637
 638                 self.angles = spot.angles;
 639
 640                 self.angles_z = 0; // never spawn tilted even if the spot says to
 641                 self.fixangle = TRUE; // turn this way immediately
 642                 self.velocity = '0 0 0';
 643                 self.avelocity = '0 0 0';
 644                 self.punchangle = '0 0 0';
 645                 self.punchvector = '0 0 0';
 646                 self.oldvelocity = self.velocity;
 647
 648                 self.viewzoom = 0.6;
 649                 self.has_zoomed = 0;
 650
 651                 self.customizeentityforclient = Client_customizeentityforclient;
 652
 653                 self.model = "";
 654                 FixPlayermodel();
 655
 656                 self.crouch = FALSE;
 657                 self.view_ofs = PL_VIEW_OFS;
 658                 setsize (self, PL_MIN, PL_MAX);
 659                 self.spawnorigin = spot.origin;
 660                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 661                 // don't reset back to last position, even if new position is stuck in solid
 662                 self.oldorigin = self.origin;
 663
 664                 if(g_arena)
 665                 {
 666                         Spawnqueue_Remove(self);
 667                         Spawnqueue_Mark(self);
 668                 }
 669
 670                 self.event_damage = PlayerDamage;
 671
 672                 self.bot_attack = TRUE;
 673
 674                 self.statdraintime = time + 5;
 675                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 676
 677                 if(self.killcount == -666) {
 678                         PlayerScore_Clear(self);
 679                         self.killcount = 0;
 680                         self.frags = 0;
 681                 }
 682
 683                 self.cnt = WEP_LASER;
 684                 self.nixnex_lastchange_id = -1;
 685
 686                 CL_SpawnWeaponentity();
 687                 self.alpha = default_player_alpha;
 688                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 689                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 690
 691                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 692                 self.lms_traveled_distance = 0;
 693                 self.speedrunning = FALSE;
 694
 695                 if(cvar("spawn_debug"))
 696                 {
 697                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 698                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 699                 }
 700
 701                 //stuffcmd(self, "chase_active 0");
 702                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 703
 704                 if (cvar("g_spawnsound"))
 705                         sound (self, CHAN_AUTO, "misc/spawn.wav", 1, ATTN_NORM);
 706
 707                 if(g_assault) {
 708                         if(self.team == assault_attacker_team)
 709                                 centerprint(self, "You are attacking!\n");
 710                         else
 711                                 centerprint(self, "You are defending!\n");
 712                 }
 713
 714         } else if(self.classname == "observer") {
 715                 PutObserverInServer ();
 716         }
 717
 718         //if(g_ctf)
 719         //      ctf_playerchanged();
 720 }
 721
 722 /*
 723 =============
 724 SendCSQCInfo
 725
 726 Send whatever CSQC needs NOW and cannot wait for SendServerInfo to happen...
 727 =============
 728 */
 729 void SendCSQCInfo(void)
 730 {
 731         if(clienttype(self) != CLIENTTYPE_REAL)
 732                 return;
 733         msg_entity = self;
 734         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 735         WriteByte(MSG_ONE, TE_CSQC_INIT);
 736         WriteShort(MSG_ONE, CSQC_REVISION);
 737         WriteByte(MSG_ONE, maxclients);
 738 }
 739
 740 /*
 741 =============
 742 SetNewParms
 743 =============
 744 */
 745 void SetNewParms (void)
 746 {
 747         // initialize parms for a new player
 748         parm1 = -(86400 * 366);
 749 }
 750
 751 /*
 752 =============
 753 SetChangeParms
 754 =============
 755 */
 756 void SetChangeParms (void)
 757 {
 758         // save parms for level change
 759         parm1 = self.parm_idlesince - time;
 760 }
 761
 762 /*
 763 =============
 764 DecodeLevelParms
 765 =============
 766 */
 767 void DecodeLevelParms (void)
 768 {
 769         // load parms
 770         self.parm_idlesince = parm1;
 771         if(self.parm_idlesince == -(86400 * 366))
 772                 self.parm_idlesince = time;
 773 }
 774
 775 /*
 776 =============
 777 ClientKill
 778
 779 Called when a client types 'kill' in the console
 780 =============
 781 */
 782
 783 void ClientKill_Now_TeamChange()
 784 {
 785         if(self.killindicator_teamchange == -1)
 786         {
 787                 self.team = -1;
 788                 JoinBestTeam( self, FALSE, FALSE );
 789         }
 790         else
 791         {
 792                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 793         }
 794 }
 795
 796 void ClientKill_Now()
 797 {
 798         if(self.killindicator_teamchange)
 799                 ClientKill_Now_TeamChange();
 800
 801         // in any case:
 802         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 803
 804         if(self.killindicator)
 805         {
 806                 dprint("Cleaned up after a leaked kill indicator.\n");
 807                 remove(self.killindicator);
 808                 self.killindicator = world;
 809         }
 810 }
 811 void KillIndicator_Think()
 812 {
 813         if (!self.owner.modelindex)
 814         {
 815                 self.owner.killindicator = world;
 816                 remove(self);
 817                 return;
 818         }
 819
 820         if(self.cnt <= 0)
 821         {
 822                 self = self.owner;
 823                 ClientKill_Now(); // no oldself needed
 824                 return;
 825         }
 826         else
 827         {
 828                 if(self.cnt <= 10)
 829                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 830                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 831                 {
 832                         if(self.cnt <= 10)
 833                                 play2(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 834                         if(self.owner.killindicator_teamchange)
 835                         {
 836                                 if(self.owner.killindicator_teamchange == -1)
 837                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 838                                 else
 839                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 840                         }
 841                         else
 842                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 843                 }
 844                 self.nextthink = time + 1;
 845                 self.cnt -= 1;
 846         }
 847 }
 848
 849 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 850 {
 851         float killtime;
 852         entity e;
 853         killtime = cvar("g_balance_kill_delay");
 854
 855         self.killindicator_teamchange = targetteam;
 856
 857         if(!self.killindicator)
 858         {
 859                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 860                 {
 861                         ClientKill_Now();
 862                 }
 863                 else
 864                 {
 865                         self.killindicator = spawn();
 866                         self.killindicator.owner = self;
 867                         self.killindicator.scale = 0.5;
 868                         setattachment(self.killindicator, self, "");
 869                         setorigin(self.killindicator, '0 0 52');
 870                         self.killindicator.think = KillIndicator_Think;
 871                         self.killindicator.nextthink = time + (self.lip) * 0.05;
 872                         self.killindicator.cnt = ceil(killtime);
 873                         self.killindicator.count = bound(0, ceil(killtime), 10);
 874                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 875
 876                         for(e = world; (e = find(e, classname, "body")) != world; )
 877                         {
 878                                 if(e.enemy != self)
 879                                         continue;
 880                                 e.killindicator = spawn();
 881                                 e.killindicator.owner = e;
 882                                 e.killindicator.scale = 0.5;
 883                                 setattachment(e.killindicator, e, "");
 884                                 setorigin(e.killindicator, '0 0 52');
 885                                 e.killindicator.think = KillIndicator_Think;
 886                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
 887                                 e.killindicator.cnt = ceil(killtime);
 888                         }
 889                         self.lip = 0;
 890                 }
 891         }
 892         if(self.killindicator)
 893         {
 894                 if(targetteam)
 895                         self.killindicator.colormod = TeamColor(targetteam);
 896                 else
 897                         self.killindicator.colormod = '0 0 0';
 898         }
 899 }
 900
 901 void ClientKill (void)
 902 {
 903         ClientKill_TeamChange(0);
 904 }
 905
 906 void DoTeamChange(float destteam)
 907 {
 908         float t, c0;
 909         if(!cvar("teamplay"))
 910         {
 911                 if(destteam >= 0)
 912                         SetPlayerColors(self, destteam);
 913                 return;
 914         }
 915         if(self.classname == "player")
 916         if(destteam == -1)
 917         {
 918                 CheckAllowedTeams(self);
 919                 t = FindSmallestTeam(self, TRUE);
 920                 switch(self.team)
 921                 {
 922                         case COLOR_TEAM1: c0 = c1; break;
 923                         case COLOR_TEAM2: c0 = c2; break;
 924                         case COLOR_TEAM3: c0 = c3; break;
 925                         case COLOR_TEAM4: c0 = c4; break;
 926                         default:          c0 = 999;
 927                 }
 928                 switch(t)
 929                 {
 930                         case 1:
 931                                 if(c0 > c1)
 932                                         destteam = COLOR_TEAM1;
 933                                 break;
 934                         case 2:
 935                                 if(c0 > c2)
 936                                         destteam = COLOR_TEAM2;
 937                                 break;
 938                         case 3:
 939                                 if(c0 > c3)
 940                                         destteam = COLOR_TEAM3;
 941                                 break;
 942                         case 4:
 943                                 if(c0 > c4)
 944                                         destteam = COLOR_TEAM4;
 945                                 break;
 946                 }
 947                 if(destteam == -1)
 948                         return;
 949         }
 950         if(destteam == self.team && !self.killindicator)
 951                 return;
 952         ClientKill_TeamChange(destteam);
 953 }
 954
 955 void FixClientCvars(entity e)
 956 {
 957         // send prediction settings to the client
 958         stuffcmd(e, "\nin_bindmap 0 0\n");
 959         /*
 960          * we no longer need to stuff this. Remove this comment block if you feel
 961          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 962         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
 963         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 964         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 965         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 966         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 967         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 968         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 969         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
 970         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 971         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 972         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 973         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 974         stuffcmd(e, "cl_movement_edgefriction 1\n");
 975          */
 976 }
 977
 978 /*
 979 =============
 980 ClientConnect
 981
 982 Called when a client connects to the server
 983 =============
 984 */
 985 //void ctf_clientconnect();
 986 string ColoredTeamName(float t);
 987 void DecodeLevelParms (void);
 988 //void dom_player_join_team(entity pl);
 989 void ClientConnect (void)
 990 {
 991         local string s;
 992         float wep;
 993
 994         if(self.flags & FL_CLIENT)
 995         {
 996                 print("Warning: ClientConnect, but already connected!\n");
 997                 return;
 998         }
 999
1000         if(Ban_IsClientBanned(self))
1001         {
1002                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
1003                 dropclient(self);
1004                 bprint(s);
1005                 return;
1006         }
1007
1008         DecodeLevelParms();
1009
1010         self.classname = "player_joining";
1011
1012         self.flags = self.flags | FL_CLIENT;
1013         self.version_nagtime = time + 10 + random() * 10;
1014
1015         if(player_count<0)
1016         {
1017                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1018                 player_count = 0;
1019         }
1020
1021         PlayerScore_Attach(self);
1022
1023         bot_clientconnect();
1024
1025         //if(g_domination)
1026         //      dom_player_join_team(self);
1027
1028         //JoinBestTeam(self, FALSE, FALSE);
1029
1030         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1031                 self.classname = "observer";
1032         } else {
1033                 self.classname = "player";
1034                 campaign_bots_may_start = 1;
1035         }
1036
1037         self.playerid = (playerid_last = playerid_last + 1);
1038         if(cvar("sv_eventlog"))
1039         {
1040                 if(clienttype(self) == CLIENTTYPE_REAL)
1041                         s = "player";
1042                 else
1043                         s = "bot";
1044                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
1045                 s = strcat(":team:", ftos(self.playerid), ":");
1046                 s = strcat(s, ftos(self.team));
1047                 GameLogEcho(s, FALSE);
1048         }
1049         self.netname_previous = strzone(self.netname);
1050
1051         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1052
1053         bprint ("^4",self.netname);
1054         bprint ("^4 connected");
1055
1056         if(g_domination || g_ctf)
1057         {
1058                 bprint(" and joined the ");
1059                 bprint(ColoredTeamName(self.team));
1060         }
1061
1062         bprint("\n");
1063
1064         self.welcomemessage_time = 0;
1065
1066         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1067         // TODO: is this being used for anything else than cd tracks?
1068         // Remember: SVC_CDTRACK exists. Maybe it should be used.
1069         //
1070         stuffcmd(self, "cl_particles_reloadeffects\n");
1071
1072         FixClientCvars(self);
1073
1074         // spawnfunc_waypoint sprites
1075         WaypointSprite_InitClient(self);
1076
1077         // Wazat's grappling hook
1078         SetGrappleHookBindings();
1079
1080         // get autoswitch state from player when he toggles it
1081         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1082
1083         // get version info from player
1084         stuffcmd(self, "cmd clientversion $gameversion\n");
1085
1086         // send all weapon info strings
1087         stuffcmd(self, "register_bestweapon clear\n"); // clear the Quake stuff
1088         wep = WEP_FIRST;
1089         while (wep <= WEP_LAST)
1090         {
1091                 weapon_action(wep, WR_REGISTER);
1092                 wep = wep + 1;
1093         }
1094
1095         // get other cvars from player
1096         GetCvars(0);
1097
1098         // set cvar for team scoreboard
1099         if (teams_matter)
1100         {
1101                 local float t;
1102                 t = cvar("teamplay");
1103                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1104                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1105         }
1106         else
1107                 stuffcmd(self, "set teamplay 0\n");
1108
1109         // notify about available teams
1110         if(teamplay)
1111         {
1112                 CheckAllowedTeams(self);
1113                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1114                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1115         }
1116         else
1117                 stuffcmd(self, "set _teams_available 0\n");
1118
1119         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1120
1121         if(g_arena)
1122         {
1123                 self.classname = "observer";
1124                 Spawnqueue_Insert(self);
1125         }
1126         /*else if(g_ctf)
1127         {
1128                 ctf_clientconnect();
1129         }*/
1130
1131         if(entcs_start)
1132                 attach_entcs();
1133
1134         bot_relinkplayerlist();
1135
1136         self.spectatortime = time;
1137         if(blockSpectators)
1138         {
1139                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1140         }
1141
1142         self.jointime = time;
1143         self.allowedTimeouts = cvar("sv_timeout_number");
1144
1145         if(clienttype(self) == CLIENTTYPE_REAL)
1146         {
1147                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1148                 SendCSQCInfo();
1149                 msg_entity = self;
1150                 if(mapvote_initialized && !cvar("g_maplist_textonly"))
1151                 {
1152                         MapVote_SendData(MSG_ONE);
1153                         MapVote_UpdateData(MSG_ONE);
1154                 }
1155                 ScoreInfo_Write(MSG_ONE);
1156         }
1157
1158         if(g_lms)
1159         {
1160                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1161                 {
1162                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1163                         self.frags = -666; // FIXME do we still need this?
1164                 }
1165         }
1166 }
1167
1168 /*
1169 =============
1170 ClientDisconnect
1171
1172 Called when a client disconnects from the server
1173 =============
1174 */
1175 void(entity e) DropFlag;
1176 .entity chatbubbleentity;
1177 .entity teambubbleentity;
1178 //void() ctf_clientdisconnect;
1179 void ClientDisconnect (void)
1180 {
1181         float save;
1182
1183         if not(self.flags & FL_CLIENT)
1184         {
1185                 print("Warning: ClientDisconnect without ClientConnect\n");
1186                 return;
1187         }
1188
1189         bot_clientdisconnect();
1190
1191         if(entcs_start)
1192                 detach_entcs();
1193
1194         if(cvar("sv_eventlog"))
1195                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
1196         bprint ("^4",self.netname);
1197         bprint ("^4 disconnected\n");
1198
1199         if (self.chatbubbleentity)
1200         {
1201                 remove (self.chatbubbleentity);
1202                 self.chatbubbleentity = world;
1203         }
1204
1205         if (self.teambubbleentity)
1206         {
1207                 remove (self.teambubbleentity);
1208                 self.teambubbleentity = world;
1209         }
1210
1211         if (self.killindicator)
1212         {
1213                 remove (self.killindicator);
1214                 self.killindicator = world;
1215         }
1216
1217         WaypointSprite_PlayerGone();
1218
1219         DropAllRunes(self);
1220         kh_Key_DropAll(self, TRUE);
1221
1222         if(self.flagcarried)
1223                 DropFlag(self.flagcarried);
1224
1225         save = self.flags;
1226         self.flags = self.flags - (self.flags & FL_CLIENT);
1227         bot_relinkplayerlist();
1228         self.flags = save;
1229
1230         // remove laserdot
1231         if(self.weaponentity)
1232                 if(self.weaponentity.lasertarget)
1233                         remove(self.weaponentity.lasertarget);
1234
1235         if(g_arena)
1236         {
1237                 Spawnqueue_Unmark(self);
1238                 Spawnqueue_Remove(self);
1239         }
1240         /*if(g_ctf)
1241         {
1242                 ctf_clientdisconnect();
1243         }
1244         */
1245
1246         PlayerScore_Detach(self);
1247
1248         if(self.netname_previous)
1249                 strunzone(self.netname_previous);
1250
1251         ClearPlayerSounds();
1252
1253         // free cvars
1254         GetCvars(-1);
1255         self.playerid = 0;
1256 }
1257
1258 .float BUTTON_CHAT;
1259 void ChatBubbleThink()
1260 {
1261         self.nextthink = time;
1262         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1263         {
1264                 self.owner.chatbubbleentity = world;
1265                 remove(self);
1266                 return;
1267         }
1268         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1269         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1270                 self.model = self.mdl;
1271         else
1272                 self.model = "";
1273 };
1274
1275 void UpdateChatBubble()
1276 {
1277         if (!self.modelindex)
1278                 return;
1279         // spawn a chatbubble entity if needed
1280         if (!self.chatbubbleentity)
1281         {
1282                 self.chatbubbleentity = spawn();
1283                 self.chatbubbleentity.owner = self;
1284                 self.chatbubbleentity.exteriormodeltoclient = self;
1285                 self.chatbubbleentity.think = ChatBubbleThink;
1286                 self.chatbubbleentity.nextthink = time;
1287                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1288                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1289                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1290                 self.chatbubbleentity.model = "";
1291                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1292         }
1293 }
1294
1295
1296 void TeamBubbleThink()
1297 {
1298         self.nextthink = time;
1299         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1300         {
1301                 self.owner.teambubbleentity = world;
1302                 remove(self);
1303                 return;
1304         }
1305 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1306         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1307                 self.model = "";
1308         else
1309                 self.model = self.mdl;
1310
1311 };
1312
1313 float TeamBubble_customizeentityforclient()
1314 {
1315         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1316 }
1317
1318 void UpdateTeamBubble()
1319 {
1320         if (!self.modelindex || !cvar("teamplay"))
1321                 return;
1322         // spawn a teambubble entity if needed
1323         if (!self.teambubbleentity && cvar("teamplay"))
1324         {
1325                 self.teambubbleentity = spawn();
1326                 self.teambubbleentity.owner = self;
1327                 self.teambubbleentity.exteriormodeltoclient = self;
1328                 self.teambubbleentity.think = TeamBubbleThink;
1329                 self.teambubbleentity.nextthink = time;
1330                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1331 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1332                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1333                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1334                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1335                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1336                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1337                 self.teambubbleentity.effects = EF_LOWPRECISION;
1338         }
1339 }
1340
1341 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1342 // added to the model skins
1343 /*void UpdateColorModHack()
1344 {
1345         local float c;
1346         c = self.clientcolors & 15;
1347         // LordHavoc: only bothering to support white, green, red, yellow, blue
1348              if (teamplay == 0) self.colormod = '0 0 0';
1349         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1350         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1351         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1352         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1353         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1354         else self.colormod = '1 1 1';
1355 };*/
1356
1357 void respawn(void)
1358 {
1359         CopyBody(1);
1360         self.effects |= EF_NODRAW; // prevent another CopyBody
1361         PutClientInServer();
1362 }
1363
1364 /**
1365  * When sv_timeout is used this function returs strings like
1366  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1367  * Called by centerprint functions
1368  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1369  */
1370 string getTimeoutText(float addOneSecond) {
1371         if (!cvar("sv_timeout") || !timeoutStatus)
1372                 return "";
1373
1374         local string retStr;
1375         if (timeoutStatus == 1) {
1376                 if (addOneSecond == 1) {
1377                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1378                 }
1379                 else {
1380                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1381                 }
1382                 return retStr;
1383         }
1384         else if (timeoutStatus == 2) {
1385                 if (addOneSecond) {
1386                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1387                         //don't show messages like "Timeout ends in 0 seconds"...
1388                         if ((remainingTimeoutTime + 1) > 0)
1389                                 return retStr;
1390                         else
1391                                 return "";
1392                 }
1393                 else {
1394                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1395                         //don't show messages like "Timeout ends in 0 seconds"...
1396                         if (remainingTimeoutTime > 0)
1397                                 return retStr;
1398                         else
1399                                 return "";
1400                 }
1401         }
1402         else return "";
1403 }
1404
1405 void player_powerups (void)
1406 {
1407         if (g_minstagib)
1408         {
1409                 if (self.items & IT_STRENGTH)
1410                 {
1411                         if (time > self.strength_finished)
1412                         {
1413                                 if (g_minstagib_invis_alpha > 0)
1414                                 {
1415                                         self.alpha = default_player_alpha;
1416                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1417                                         self.effects = self.effects | EF_FULLBRIGHT;
1418                                 }
1419                                 else
1420                                 {
1421                                         self.effects -= self.effects & EF_NODRAW;
1422                                 }
1423                                 self.items = self.items - (self.items & IT_STRENGTH);
1424                                 sprint(self, "^3Invisibility has worn off\n");
1425                         }
1426                 }
1427                 else
1428                 {
1429                         if (time < self.strength_finished)
1430                         {
1431                                 if (g_minstagib_invis_alpha > 0)
1432                                 {
1433                                         self.alpha = g_minstagib_invis_alpha;
1434                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1435                                         self.effects -= self.effects & EF_FULLBRIGHT;
1436                                 }
1437                                 else
1438                                 {
1439                                         self.effects = self.effects | EF_NODRAW;
1440                                 }
1441                                 self.items = self.items | IT_STRENGTH;
1442                                 sprint(self, "^3You are invisible\n");
1443                         }
1444                 }
1445
1446                 if (self.items & IT_INVINCIBLE)
1447                 {
1448                         if (time > self.invincible_finished)
1449                         {
1450                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1451                                 sprint(self, "^3Speed has worn off\n");
1452                         }
1453                 }
1454                 else
1455                 {
1456                         if (time < self.invincible_finished)
1457                         {
1458                                 self.items = self.items | IT_INVINCIBLE;
1459                                 sprint(self, "^3You are on speed\n");
1460                         }
1461                 }
1462                 return;
1463         }
1464
1465         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1466         if (self.items & IT_STRENGTH)
1467         {
1468                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1469                 if (time > self.strength_finished)
1470                 {
1471                         self.items = self.items - (self.items & IT_STRENGTH);
1472                         sprint(self, "^3Strength has worn off\n");
1473                 }
1474         }
1475         else
1476         {
1477                 if (time < self.strength_finished)
1478                 {
1479                         self.items = self.items | IT_STRENGTH;
1480                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1481                 }
1482         }
1483         if (self.items & IT_INVINCIBLE)
1484         {
1485                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1486                 if (time > self.invincible_finished)
1487                 {
1488                         self.items = self.items - (self.items & IT_INVINCIBLE);
1489                         sprint(self, "^3Shield has worn off\n");
1490                 }
1491         }
1492         else
1493         {
1494                 if (time < self.invincible_finished)
1495                 {
1496                         self.items = self.items | IT_INVINCIBLE;
1497                         sprint(self, "^3Shield surrounds you\n");
1498                 }
1499         }
1500
1501         if (cvar("g_fullbrightplayers"))
1502                 self.effects = self.effects | EF_FULLBRIGHT;
1503
1504         // midair gamemode: damage only while in the air
1505         // if in midair mode, being on ground grants temporary invulnerability
1506         // (this is so that multishot weapon don't clear the ground flag on the
1507         // first damage in the frame, leaving the player vulnerable to the
1508         // remaining hits in the same frame)
1509         if (self.flags & FL_ONGROUND)
1510         if (g_midair)
1511                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1512
1513         if (time < self.spawnshieldtime)
1514                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1515 }
1516
1517 float CalcRegen(float current, float stable, float regenfactor)
1518 {
1519         if(current > stable)
1520                 return current;
1521         else if(current > stable - 0.25) // when close enough, "snap"
1522                 return stable;
1523         else
1524                 return min(stable, current + (stable - current) * regenfactor * frametime);
1525 }
1526
1527 void player_regen (void)
1528 {
1529         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1530         maxh = cvar("g_balance_health_stable");
1531         maxa = cvar("g_balance_armor_stable");
1532         limith = cvar("g_balance_health_limit");
1533         limita = cvar("g_balance_armor_limit");
1534
1535         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1536                 return;
1537
1538         max_mod = regen_mod = rot_mod = limit_mod = 1;
1539
1540         if (self.runes & RUNE_REGEN)
1541         {
1542                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1543                 {
1544                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1545                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1546                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1547                 }
1548                 else
1549                 {
1550                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1551                         max_mod = cvar("g_balance_rune_regen_hpmod");
1552                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1553                 }
1554         }
1555         else if (self.runes & CURSE_VENOM)
1556         {
1557                 max_mod = cvar("g_balance_curse_venom_hpmod");
1558                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1559                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1560                 else
1561                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1562                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1563                 //if (!self.runes & RUNE_REGEN)
1564                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1565         }
1566         maxh = maxh * max_mod;
1567         //maxa = maxa * max_mod;
1568         limith = limith * limit_mod;
1569         limita = limita * limit_mod;
1570
1571         if (self.armorvalue > maxa)
1572         {
1573                 if (time > self.pauserotarmor_finished)
1574                 {
1575                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1576                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1577                 }
1578         }
1579         else if (self.armorvalue < maxa)
1580         {
1581                 if (time > self.pauseregen_finished)
1582                 {
1583                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1584                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1585                 }
1586         }
1587         if (self.health > maxh)
1588         {
1589                 if (time > self.pauserothealth_finished)
1590                 {
1591                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1592                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1593                 }
1594         }
1595         else if (self.health < maxh)
1596         {
1597                 if (time > self.pauseregen_finished)
1598                 {
1599                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1600                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1601                 }
1602         }
1603
1604         if (self.health > limith)
1605                 self.health = limith;
1606         if (self.armorvalue > limita)
1607                 self.armorvalue = limita;
1608
1609         // if player rotted to death...  die!
1610         if(self.health < 1)
1611                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1612 }
1613
1614 /*
1615 ======================
1616 spectate mode routines
1617 ======================
1618 */
1619 void SpectateCopy(entity spectatee) {
1620         self.armortype = spectatee.armortype;
1621         self.armorvalue = spectatee.armorvalue;
1622         self.currentammo = spectatee.currentammo;
1623         self.effects = spectatee.effects;
1624         self.health = spectatee.health;
1625         self.impulse = 0;
1626         self.items = spectatee.items;
1627         self.punchangle = spectatee.punchangle;
1628         self.view_ofs = spectatee.view_ofs;
1629         self.v_angle = spectatee.v_angle;
1630         self.viewzoom = spectatee.viewzoom;
1631         self.velocity = spectatee.velocity;
1632         self.dmg_take = spectatee.dmg_take;
1633         self.dmg_save = spectatee.dmg_save;
1634         self.dmg_inflictor = spectatee.dmg_inflictor;
1635         self.angles = spectatee.v_angle;
1636         self.fixangle = TRUE;
1637         setorigin(self, spectatee.origin);
1638         setsize(self, spectatee.mins, spectatee.maxs);
1639 }
1640
1641 float SpectateUpdate() {
1642         if(!self.enemy)
1643                 return 0;
1644
1645         if (self == self.enemy)
1646                 return 0;
1647
1648         if(self.enemy.flags & FL_NOTARGET)
1649                 return 0;
1650
1651         SpectateCopy(self.enemy);
1652
1653         return 1;
1654 }
1655
1656 float SpectateNext() {
1657         other = find(self.enemy, classname, "player");
1658         if (!other) {
1659                 other = find(other, classname, "player");
1660         }
1661         if (other) {
1662                 self.enemy = other;
1663         }
1664         if(self.enemy.classname == "player") {
1665                 msg_entity = self;
1666                 WriteByte(MSG_ONE, SVC_SETVIEW);
1667                 WriteEntity(MSG_ONE, self.enemy);
1668                 self.wantswelcomemessage = 1;
1669                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1670                 if(!SpectateUpdate())
1671                         PutObserverInServer();
1672                 return 1;
1673         } else {
1674                 return 0;
1675         }
1676 }
1677
1678 /*
1679 =============
1680 ShowRespawnCountdown()
1681
1682 Update a respawn countdown display.
1683 =============
1684 */
1685 void ShowRespawnCountdown()
1686 {
1687         float number;
1688         if(self.deadflag == DEAD_NO) // just respawned?
1689                 return;
1690         else
1691         {
1692                 number = ceil(self.death_time - time);
1693                 if(number <= 0)
1694                         return;
1695                 if(number <= self.respawn_countdown)
1696                 {
1697                         self.respawn_countdown = number - 1;
1698                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1699                                 play2(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1700                 }
1701         }
1702 }
1703
1704 void LeaveSpectatorMode()
1705 {
1706         if(isJoinAllowed()) {
1707                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1708                         self.classname = "player";
1709                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1710                                 JoinBestTeam(self, FALSE, TRUE);
1711                         if(cvar("g_campaign"))
1712                                 campaign_bots_may_start = 1;
1713                         PutClientInServer();
1714                         if(!(self.flags & FL_NOTARGET))
1715                                 bprint ("^4", self.netname, "^4 is playing now\n");
1716                         centerprint(self,"");
1717                         return;
1718                 } else {
1719                         stuffcmd(self,"menu_showteamselect\n");
1720                         return;
1721                 }
1722         }
1723         else {
1724                 //player may not join because of g_maxplayers is set
1725                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1726         }
1727 }
1728
1729 /**
1730  * Determines whether the player is allowed to join. This depends on cvar
1731  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1732  * it checks whether the number of currently playing players exceeds g_maxplayers.
1733  * @return bool TRUE if the player is allowed to join, false otherwise
1734  */
1735 float isJoinAllowed() {
1736         if (!cvar("g_maxplayers"))
1737                 return TRUE;
1738
1739         local entity e;
1740         local float currentlyPlaying;
1741         FOR_EACH_REALPLAYER(e) {
1742                 if(e.classname == "player")
1743                         currentlyPlaying += 1;
1744         }
1745         if(currentlyPlaying < cvar("g_maxplayers"))
1746                 return TRUE;
1747
1748         return FALSE;
1749 }
1750
1751 /**
1752  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1753  * g_maxplayers_spectator_blocktime seconds
1754  */
1755 void checkSpectatorBlock() {
1756         if(self.classname == "spectator" || self.classname == "observer") {
1757                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1758                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1759                         dropclient(self);
1760                 }
1761         }
1762 }
1763
1764 float vercmp_recursive(string v1, string v2)
1765 {
1766         float dot1, dot2;
1767         string s1, s2;
1768         float r;
1769
1770         dot1 = strstrofs(v1, ".", 0);
1771         dot2 = strstrofs(v2, ".", 0);
1772         if(dot1 == -1)
1773                 s1 = v1;
1774         else
1775                 s1 = substring(v1, 0, dot1);
1776         if(dot2 == -1)
1777                 s2 = v2;
1778         else
1779                 s2 = substring(v2, 0, dot2);
1780
1781         r = stof(s1) - stof(s2);
1782         if(r != 0)
1783                 return r;
1784
1785         r = strcasecmp(s1, s2);
1786         if(r != 0)
1787                 return r;
1788
1789         if(dot1 == -1)
1790                 if(dot2 == -1)
1791                         return 0;
1792                 else
1793                         return -1;
1794         else
1795                 if(dot2 == -1)
1796                         return 1;
1797                 else
1798                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1799 }
1800
1801 float vercmp(string v1, string v2)
1802 {
1803         if(strcasecmp(v1, v2) == 0) // early out check
1804                 return 0;
1805         return vercmp_recursive(v1, v2);
1806 }
1807
1808 void ObserverThink()
1809 {
1810         if (self.flags & FL_JUMPRELEASED) {
1811                 if (self.BUTTON_JUMP && self.version == cvar("gameversion")) {
1812                         self.welcomemessage_time = 0;
1813                         self.flags = self.flags - FL_JUMPRELEASED;
1814                         LeaveSpectatorMode();
1815                         return;
1816                 } else if(self.BUTTON_ATCK && self.version == cvar("gameversion")) {
1817                         self.welcomemessage_time = 0;
1818                         self.flags = self.flags - FL_JUMPRELEASED;
1819                         if(SpectateNext() == 1) {
1820                                 self.classname = "spectator";
1821                         }
1822                 }
1823         } else {
1824                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
1825                         self.flags = self.flags | FL_JUMPRELEASED;
1826                 }
1827         }
1828         if(self.BUTTON_ZOOM)
1829                 self.wantswelcomemessage = 0;
1830         if(self.wantswelcomemessage)
1831                 PrintWelcomeMessage(self);
1832 }
1833
1834 void SpectatorThink()
1835 {
1836         if (self.flags & FL_JUMPRELEASED) {
1837                 if (self.BUTTON_JUMP && self.version == cvar("gameversion")) {
1838                         self.welcomemessage_time = 0;
1839                         self.flags = self.flags - FL_JUMPRELEASED;
1840                         LeaveSpectatorMode();
1841                         return;
1842                 } else if(self.BUTTON_ATCK) {
1843                         self.welcomemessage_time = 0;
1844                         self.flags = self.flags - FL_JUMPRELEASED;
1845                         if(SpectateNext() == 1) {
1846                                 self.classname = "spectator";
1847                         } else {
1848                                 self.classname = "observer";
1849                                 PutClientInServer();
1850                         }
1851                 } else if (self.BUTTON_ATCK2) {
1852                         self.welcomemessage_time = 0;
1853                         self.flags = self.flags - FL_JUMPRELEASED;
1854                         self.classname = "observer";
1855                         PutClientInServer();
1856                 } else {
1857                         if(!SpectateUpdate())
1858                                 PutObserverInServer();
1859                 }
1860         } else {
1861                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
1862                         self.flags = self.flags | FL_JUMPRELEASED;
1863                 }
1864         }
1865         if(self.BUTTON_ZOOM)
1866                 self.wantswelcomemessage = 0;
1867         if(self.wantswelcomemessage)
1868                 PrintWelcomeMessage(self);
1869         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1870 }
1871
1872 /*
1873 =============
1874 PlayerPreThink
1875
1876 Called every frame for each client before the physics are run
1877 =============
1878 */
1879 void() ctf_setstatus;
1880 .float vote_nagtime;
1881 void PlayerPreThink (void)
1882 {
1883         if(blockSpectators)
1884                 checkSpectatorBlock();
1885
1886         if(self.netname_previous != self.netname)
1887         {
1888                 if(cvar("sv_eventlog"))
1889                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname), TRUE);
1890                 if(self.netname_previous)
1891                         strunzone(self.netname_previous);
1892                 self.netname_previous = strzone(self.netname);
1893         }
1894
1895         // version nagging
1896         if(self.version_nagtime)
1897                 if(self.cvar_g_nexuizversion)
1898                         if(time > self.version_nagtime)
1899                         {
1900                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1901                                 {
1902                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
1903                                         {
1904                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1905                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1906                                         }
1907                                         else
1908                                         {
1909                                                 float r;
1910                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
1911                                                 if(r < 0)
1912                                                 {
1913                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
1914                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
1915                                                 }
1916                                                 else if(r > 0)
1917                                                 {
1918                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1919                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1920                                                 }
1921                                         }
1922                                 }
1923                                 self.version_nagtime = 0;
1924                         }
1925
1926         // vote nagging
1927         if(self.cvar_scr_centertime)
1928                 if(time > self.vote_nagtime)
1929                 {
1930                         VoteNag();
1931                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1932                 }
1933
1934         // GOD MODE info
1935         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
1936         {
1937                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
1938                 self.max_armorvalue = 0;
1939         }
1940
1941         if(frametime)
1942                 antilag_record(self);
1943
1944         if(self.classname == "player") {
1945 //              if(self.netname == "Wazat")
1946 //                      bprint(self.classname, "\n");
1947
1948                 CheckRules_Player();
1949
1950                 if(self.BUTTON_INFO)
1951                         PrintWelcomeMessage(self);
1952
1953                 if(g_lms || !cvar("sv_spectate"))
1954                 if((time - self.jointime) <= cvar("welcome_message_time"))
1955                         PrintWelcomeMessage(self);
1956
1957                 if (intermission_running)
1958                 {
1959                         IntermissionThink ();   // otherwise a button could be missed between
1960                         return;                                 // the think tics
1961                 }
1962
1963                 if(self.teleport_time)
1964                 if(time > self.teleport_time)
1965                 {
1966                         self.teleport_time = 0;
1967                         self.effects = self.effects - (self.effects & EF_NODRAW);
1968                         if(self.weaponentity)
1969                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
1970                 }
1971
1972                 Nixnex_GiveCurrentWeapon();
1973
1974                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
1975                         UpdateSelectedPlayer();
1976
1977                 //don't allow the player to turn around while game is paused!
1978                 if(timeoutStatus == 2) {
1979                         self.v_angle = self.lastV_angle;
1980                         self.angles = self.lastV_angle;
1981                         self.fixangle = TRUE;
1982                 }
1983
1984                 if (self.deadflag != DEAD_NO)
1985                 {
1986                         float button_pressed, force_respawn;
1987                         player_anim();
1988                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
1989                         force_respawn = (g_lms || cvar("g_forced_respawn"));
1990                         if (self.deadflag == DEAD_DYING)
1991                         {
1992                                 if(force_respawn)
1993                                         self.deadflag = DEAD_RESPAWNING;
1994                                 else if(!button_pressed)
1995                                         self.deadflag = DEAD_DEAD;
1996                         }
1997                         else if (self.deadflag == DEAD_DEAD)
1998                         {
1999                                 if(button_pressed)
2000                                         self.deadflag = DEAD_RESPAWNABLE;
2001                         }
2002                         else if (self.deadflag == DEAD_RESPAWNABLE)
2003                         {
2004                                 if(!button_pressed)
2005                                         self.deadflag = DEAD_RESPAWNING;
2006                         }
2007                         else if (self.deadflag == DEAD_RESPAWNING)
2008                         {
2009                                 if(time > self.death_time)
2010                                 {
2011                                         self.death_time = time + 1; // only retry once a second
2012                                         respawn();
2013                                 }
2014                         }
2015                         ShowRespawnCountdown();
2016                         return;
2017                 }
2018
2019                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2020                 {
2021                         vector dist;
2022
2023                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2024                         dist = self.oldorigin - self.origin;
2025                         dist_z = 0;
2026                         self.lms_traveled_distance += fabs(vlen(dist));
2027
2028                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
2029                         {
2030                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2031                                 self.lms_traveled_distance = 0;
2032                         }
2033
2034                         if(time > self.lms_nextcheck)
2035                         {
2036                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2037                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2038                                 {
2039                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2040                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2041                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2042                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2043                                 }
2044                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2045                                 self.lms_traveled_distance = 0;
2046                         }
2047                 }
2048
2049                 if (self.BUTTON_CROUCH && !self.hook.state)
2050                 {
2051                         if (!self.crouch)
2052                         {
2053                                 self.crouch = TRUE;
2054                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2055                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2056                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
2057                         }
2058                 }
2059                 else
2060                 {
2061                         if (self.crouch)
2062                         {
2063                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2064                                 if (!trace_startsolid)
2065                                 {
2066                                         self.crouch = FALSE;
2067                                         self.view_ofs = PL_VIEW_OFS;
2068                                         setsize (self, PL_MIN, PL_MAX);
2069                                 }
2070                         }
2071                 }
2072
2073                 FixPlayermodel();
2074
2075                 GrapplingHookFrame();
2076
2077                 W_WeaponFrame();
2078
2079                 {
2080                         float zoomfactor, zoomspeed, zoomdir;
2081                         zoomfactor = self.cvar_cl_zoomfactor;
2082                         if(zoomfactor < 1 || zoomfactor > 16)
2083                                 zoomfactor = 2.5;
2084                         zoomspeed = self.cvar_cl_zoomspeed;
2085                         if(zoomspeed >= 0) // < 0 is instant zoom
2086                                 if(zoomspeed < 0.5 || zoomspeed > 16)
2087                                         zoomspeed = 3.5;
2088
2089                         zoomdir = self.BUTTON_ZOOM;
2090                         if(self.BUTTON_ATCK2)
2091                                 if(self.weapon == WEP_NEX)
2092                                         if(!g_minstagib)
2093                                                 zoomdir = 1;
2094
2095                         if(zoomdir)
2096                                 self.has_zoomed = 1;
2097
2098                         if(self.has_zoomed)
2099                         {
2100                                 if(zoomspeed <= 0) // instant zoom
2101                                 {
2102                                         if(zoomdir)
2103                                                 self.viewzoom = 1 / zoomfactor;
2104                                         else
2105                                                 self.viewzoom = 1;
2106                                 }
2107                                 else
2108                                 {
2109                                         // geometric zoom would be:
2110                                         //   self.viewzoom = bound(1 / zoomfactor, self.viewzoom * pow(zoomfactor, (zoomdir ? -1 : 1) * frametime * zoomspeed), 1);
2111                                         // however, testing showed that arithmetic/harmonic zoom works better
2112                                         if(zoomdir)
2113                                                 // self.viewzoom = 1 / bound(1, 1 / self.viewzoom + (zoomdir ? 1 : -1) * frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2114                                                 // zoom in = arithmetic: 1x, 2x, 3x, 4x, ..., 8x
2115                                                 self.viewzoom = 1 / bound(1, 1 / self.viewzoom + frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2116                                         else
2117                                                 // self.viewzoom = bound(1 / zoomfactor, self.viewzoom + (zoomdir ? -1 : 1) * frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2118                                                 // zoom out = harmonic: 8/1x, 8/2x, 8/3x, 8/4x, ..., 8/8x
2119                                                 self.viewzoom = bound(1 / zoomfactor, self.viewzoom + frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2120                                 }
2121                         }
2122                         else
2123                                 self.viewzoom = min(1, self.viewzoom + frametime); // spawn zoom-in
2124                 }
2125
2126                 player_powerups();
2127                 player_regen();
2128                 player_anim();
2129
2130                 if (g_minstagib)
2131                         minstagib_ammocheck();
2132
2133                 ctf_setstatus();
2134                 kh_setstatus();
2135
2136                 //self.angles_y=self.v_angle_y + 90;   // temp
2137
2138                 //if (TetrisPreFrame()) return;
2139         } else if(gameover) {
2140                 if (intermission_running)
2141                         IntermissionThink ();   // otherwise a button could be missed between
2142                 return;
2143         } else if(self.classname == "observer") {
2144                 ObserverThink();
2145         } else if(self.classname == "spectator") {
2146                 SpectatorThink();
2147         }
2148 }
2149
2150
2151 /*
2152 =============
2153 PlayerPostThink
2154
2155 Called every frame for each client after the physics are run
2156 =============
2157 */
2158 .float idlekick_lasttimeleft;
2159 void PlayerPostThink (void)
2160 {
2161         // Savage: Check for nameless players
2162         if (strlen(self.netname) < 1) {
2163                 self.netname = "Player";
2164                 stuffcmd(self, "seta _cl_name Player\n");
2165         }
2166
2167         if(sv_maxidle)
2168         {
2169                 float timeleft;
2170                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2171                 if(timeleft <= 0)
2172                 {
2173                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2174                         play2(self, "announcer/robotic/terminated.ogg");
2175                         dropclient(self);
2176                         return;
2177                 }
2178                 else if(timeleft <= 10)
2179                 {
2180                         if(timeleft != self.idlekick_lasttimeleft)
2181                         {
2182                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2183                                 play2(self, strcat("announcer/robotic/", ftos(timeleft), ".ogg"));
2184                         }
2185                 }
2186                 else
2187                 {
2188                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2189                 }
2190                 self.idlekick_lasttimeleft = timeleft;
2191         }
2192
2193         if(self.classname == "player") {
2194                 CheckRules_Player();
2195                 UpdateChatBubble();
2196                 UpdateTeamBubble();
2197                 if (self.impulse)
2198                         ImpulseCommands();
2199                 if (intermission_running)
2200                         return;         // intermission or finale
2201
2202                 //PrintWelcomeMessage(self);
2203                 //if (TetrisPostFrame()) return;
2204
2205                 // restart countdown
2206                 if (restart_countdown) {
2207                         if(time < restart_countdown) {
2208                                 if (!cvar("sv_ready_restart_after_countdown"))
2209                                 {
2210                                         self.movetype = MOVETYPE_NONE;
2211                                         self.velocity = '0 0 0';
2212                                         self.avelocity = '0 0 0';
2213                                         self.movement = '0 0 0';
2214                                 }
2215                         }
2216                         else
2217                         {
2218                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2219                                 if (!cvar("sv_ready_restart_after_countdown"))
2220                                 {
2221                                         if(self.movetype == MOVETYPE_NONE)
2222                                         {
2223                                                 self.movetype = MOVETYPE_WALK;
2224                                         }
2225                                 }
2226                         }
2227                 }
2228
2229         } else if (self.classname == "observer") {
2230                 //do nothing
2231         } else if (self.classname == "spectator") {
2232                 //do nothing
2233         }
2234
2235         /*
2236         float i;
2237         for(i = 0; i < 1000; ++i)
2238         {
2239                 vector end;
2240                 end = self.origin + '0 0 1024' + 512 * randomvec();
2241                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2242                 if(trace_fraction < 1)
2243                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2244                 {
2245                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2246                         break;
2247                 }
2248         }
2249         */
2250
2251         Arena_Warmup();
2252 }