data/qcsrc/server/cl_client.qc

   1 void info_player_start (void)
   2 {
   3         self.classname = "info_player_deathmatch";
   4         relocate_spawnpoint();
   5 }
   6
   7 void info_player_deathmatch (void)
   8 {
   9         relocate_spawnpoint();
  10 }
  11
  12 float spawn_allbad;
  13 float spawn_allgood;
  14 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  15 {
  16         local entity spot, player, nextspot, previousspot, newfirstspot;
  17         local float pcount;
  18         spot = firstspot;
  19         newfirstspot = world;
  20         previousspot = world;
  21         spawn_allgood = TRUE;
  22         spawn_allbad = TRUE;
  23         while (spot)
  24         {
  25                 nextspot = spot.chain;
  26                 // count team mismatches as bad spots
  27                 if (spot.team == teamcheck)
  28                 {
  29                         pcount = 0;
  30                         player = playerlist;
  31                         while (player)
  32                         {
  33                                 if (player != self)
  34                                 if (vlen(player.origin - spot.origin) < mindist)
  35                                         pcount = pcount + 1;
  36                                 player = player.chain;
  37                         }
  38                         if (!pcount)
  39                         {
  40                                 spawn_allbad = FALSE;
  41                                 if (newfirstspot)
  42                                         previousspot.chain = spot;
  43                                 else
  44                                         newfirstspot = spot;
  45                                 previousspot = spot;
  46                                 spot.chain = world;
  47                         }
  48                         else
  49                                 spawn_allgood = FALSE;
  50                 }
  51                 spot = nextspot;
  52         }
  53         // if we couldn't find ANY good points, return the original list
  54         if (!newfirstspot)
  55                 newfirstspot = firstspot;
  56         return newfirstspot;
  57 }
  58
  59 entity Spawn_RandomPoint(entity firstspot)
  60 {
  61         local entity spot;
  62         local float numspots;
  63         // count number of spots
  64         numspots = 0;
  65         spot = firstspot;
  66         while (spot)
  67         {
  68                 numspots = numspots + 1;
  69                 spot = spot.chain;
  70         }
  71         // pick a random one
  72         numspots = numspots * random();
  73         spot = firstspot;
  74         while (spot.chain && numspots >= 1)
  75         {
  76                 numspots = numspots - 1;
  77                 spot = spot.chain;
  78         }
  79         return spot;
  80 }
  81
  82 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  83 {
  84         local entity best, spot, player;
  85         local float bestrating, rating;
  86         best = world;
  87         bestrating = -1000000;
  88         spot = firstspot;
  89         while (spot)
  90         {
  91                 rating = 1000000000;
  92                 player = playerlist;
  93                 while (player)
  94                 {
  95                         if (player != self)
  96                                 rating = min(rating, vlen(player.origin - spot.origin));
  97                         player = player.chain;
  98                 }
  99                 rating = rating + random() * 16;
 100                 if (bestrating < rating)
 101                 {
 102                         best = spot;
 103                         bestrating = rating;
 104                 }
 105                 spot = spot.chain;
 106         }
 107         return best;
 108 }
 109
 110 /*
 111 =============
 112 SelectSpawnPoint
 113
 114 Finds a point to respawn
 115 =============
 116 */
 117 entity SelectSpawnPoint (float anypoint)
 118 {
 119         local float teamcheck;
 120         local entity spot, firstspot, playerlist;
 121
 122         spot = find (world, classname, "testplayerstart");
 123         if (spot)
 124                 return spot;
 125
 126         teamcheck = 0;
 127
 128         if(!anypoint && cvar("g_ctf") )
 129                 teamcheck = self.team;
 130
 131         // get the list of players
 132         playerlist = findchain(classname, "player");
 133         // get the entire list of spots
 134         firstspot = findchain(classname, "info_player_deathmatch");
 135         // filter out the bad ones
 136         // (note this returns the original list if none survived)
 137         firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 138
 139         // there is 50/50 chance of choosing a random spot or the furthest spot
 140         // (this means that roughly every other spawn will be furthest, so you
 141         // usually won't get fragged at spawn twice in a row)
 142         if (arena_roundbased)
 143         {
 144                 firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 145                 spot = Spawn_RandomPoint(firstspot);
 146         }
 147         else if (random() > 0.5 || spawn_allbad || spawn_allgood)
 148                 spot = Spawn_RandomPoint(firstspot);
 149         else
 150                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 151
 152         if (!spot)
 153         {
 154                 if(cvar("spawn_debug"))
 155                         GotoNextMap();
 156                 else
 157                         error ("PutClientInServer: no start points on level");
 158         }
 159
 160         return spot;
 161 }
 162
 163 /*
 164 =============
 165 CheckPlayerModel
 166
 167 Checks if the argument string can be a valid playermodel.
 168 Returns a valid one in doubt.
 169 =============
 170 */
 171 string FallbackPlayerModel = "models/player/marine.zym";
 172 string CheckPlayerModel(string plyermodel) {
 173         if(strlen(plyermodel) < 4)
 174                 return FallbackPlayerModel;
 175         if( substring(plyermodel,0,14) != "models/player/")
 176                 return FallbackPlayerModel;
 177         else if(cvar("sv_servermodelsonly"))
 178         {
 179                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 180                         return FallbackPlayerModel;
 181                 if(!fexists(plyermodel))
 182                         return FallbackPlayerModel;
 183         }
 184         return plyermodel;
 185 }
 186
 187 /*
 188 =============
 189 Client_customizeentityforclient
 190
 191 LOD reduction
 192 =============
 193 */
 194 float Client_customizeentityforclient()
 195 {
 196 #ifdef ALLOW_VARIABLE_LOD
 197         // self: me
 198         // other: the player viewing me
 199         float distance;
 200         float f;
 201
 202         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 203                 return TRUE;
 204
 205         if(other.cvar_cl_playerdetailreduction <= 0)
 206         {
 207                 if(other.cvar_cl_playerdetailreduction <= -2)
 208                         self.modelindex = self.modelindex_lod2;
 209                 else if(other.cvar_cl_playerdetailreduction <= -1)
 210                         self.modelindex = self.modelindex_lod1;
 211                 else
 212                         self.modelindex = self.modelindex_lod0;
 213         }
 214         else
 215         {
 216                 distance = vlen(self.origin - other.origin);
 217                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 218                 if(f > 10000)
 219                         self.modelindex = self.modelindex_lod2;
 220                 else if(f > 5000)
 221                         self.modelindex = self.modelindex_lod1;
 222                 else
 223                         self.modelindex = self.modelindex_lod0;
 224         }
 225 #endif
 226
 227         return TRUE;
 228 }
 229
 230 void setmodel_lod(entity e, string modelname)
 231 {
 232 #ifdef ALLOW_VARIABLE_LOD
 233         string s;
 234
 235         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1.zym");
 236         if(fexists(s))
 237         {
 238                 precache_model(s);
 239                 setmodel(e, s);
 240                 self.modelindex_lod1 = self.modelindex;
 241         }
 242         else
 243                 self.modelindex_lod1 = -1;
 244
 245         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2.zym");
 246         if(fexists(s))
 247         {
 248                 precache_model(s);
 249                 setmodel(e, s);
 250                 self.modelindex_lod2 = self.modelindex;
 251         }
 252         else
 253                 self.modelindex_lod2 = -1;
 254
 255         precache_model(modelname);
 256         setmodel(e, modelname);
 257         self.modelindex_lod0 = self.modelindex;
 258
 259         if(self.modelindex_lod1 < 0)
 260                 self.modelindex_lod1 = self.modelindex;
 261
 262         if(self.modelindex_lod2 < 0)
 263                 self.modelindex_lod2 = self.modelindex;
 264 #else
 265         precache_model(modelname);
 266         setmodel(e, modelname);
 267 #endif
 268 }
 269
 270 /*
 271 =============
 272 PutObserverInServer
 273
 274 putting a client as observer in the server
 275 =============
 276 */
 277 void PutObserverInServer (void)
 278 {
 279         entity  spot;
 280         spot = SelectSpawnPoint (FALSE);
 281         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 282
 283         if(clienttype(self) == CLIENTTYPE_REAL)
 284         {
 285                 msg_entity = self;
 286                 WriteByte(MSG_ONE, SVC_SETVIEW);
 287                 WriteEntity(MSG_ONE, self);
 288         }
 289
 290         if (cvar("g_runematch"))
 291                 DropAllRunes(self);
 292
 293         DistributeFragsAmongTeam(self, self.team, 1);
 294
 295         if(self.frags <= 0 && self.frags > -666 && cvar("g_lms") && self.killcount != -666)
 296                 bprint (strcat("^4", self.netname, "^4 has no more lives left\n"));
 297         else if(self.killcount != -666)
 298                 bprint (strcat("^4", self.netname, "^4 is spectating now\n"));
 299
 300         self.classname = "observer";
 301         self.health = -666;
 302         self.takedamage = DAMAGE_NO;
 303         self.solid = SOLID_NOT;
 304         self.movetype = MOVETYPE_NOCLIP;
 305         self.flags = FL_CLIENT | FL_NOTARGET;
 306         self.armorvalue = 666;
 307         self.effects = 0;
 308         self.armorvalue = cvar("g_balance_armor_start");
 309         self.pauserotarmor_finished = 0;
 310         self.pauserothealth_finished = 0;
 311         self.pauseregen_finished = 0;
 312         self.damageforcescale = 0;
 313         self.death_time = 0;
 314         self.dead_time = 0;
 315         self.dead_frame = 0;
 316         self.die_frame = 0;
 317         self.deaths = 0;
 318         self.alpha = 0;
 319         self.scale = 0;
 320         self.fade_time = 0;
 321         self.pain_frame = 0;
 322         self.pain_finished = 0;
 323         self.strength_finished = 0;
 324         self.invincible_finished = 0;
 325         self.pushltime = 0;
 326         self.think = SUB_Null;
 327         self.nextthink = 0;
 328         self.hook_time = 0;
 329         self.runes = 0;
 330         self.deadflag = DEAD_NO;
 331         self.angles = spot.angles;
 332         self.angles_z = 0;
 333         self.fixangle = TRUE;
 334         self.crouch = FALSE;
 335
 336         self.view_ofs = PL_VIEW_OFS;
 337         setorigin (self, spot.origin);
 338         setsize (self, '0 0 0', '0 0 0');
 339         self.oldorigin = self.origin;
 340         self.items = 0;
 341         self.model = "";
 342         self.modelindex = 0;
 343         self.weapon = 0;
 344         self.weaponmodel = "";
 345         self.weaponentity = world;
 346         self.killcount = -666;
 347         self.velocity = '0 0 0';
 348         self.avelocity = '0 0 0';
 349         self.punchangle = '0 0 0';
 350         self.punchvector = '0 0 0';
 351         self.oldvelocity = self.velocity;
 352         self.customizeentityforclient = Client_customizeentityforclient;
 353
 354         if(cvar("g_arena"))
 355         {
 356                 if(self.frags != -2)
 357                 {
 358                         Spawnqueue_Insert(self);
 359                 }
 360                 else
 361                 {
 362                         Spawnqueue_Unmark(self);
 363                         Spawnqueue_Remove(self);
 364                 }
 365         }
 366         else if(!cvar("g_lms"))
 367                 self.frags = -666;
 368 }
 369
 370
 371 /*
 372 =============
 373 PutClientInServer
 374
 375 Called when a client spawns in the server
 376 =============
 377 */
 378 void PutClientInServer (void)
 379 {
 380         if(clienttype(self) == CLIENTTYPE_BOT)
 381         {
 382                 self.classname = "player";
 383         }
 384         else if(clienttype(self) == CLIENTTYPE_REAL)
 385         {
 386                 msg_entity = self;
 387                 WriteByte(MSG_ONE, SVC_SETVIEW);
 388                 WriteEntity(MSG_ONE, self);
 389         }
 390
 391         // player is dead and becomes observer
 392         if(cvar("g_lms") && self.frags < 1)
 393                 self.classname = "observer";
 394
 395         if(cvar("g_arena"))
 396         if(!self.spawned)
 397                 self.classname = "observer";
 398
 399         if(self.classname == "player") {
 400                 entity  spot;
 401
 402                 spot = SelectSpawnPoint (FALSE);
 403
 404                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 405
 406                 self.classname = "player";
 407                 self.iscreature = TRUE;
 408                 self.movetype = MOVETYPE_WALK;
 409                 self.solid = SOLID_SLIDEBOX;
 410                 self.flags = FL_CLIENT;
 411                 self.takedamage = DAMAGE_AIM;
 412                 self.effects = 0;
 413                 self.health = cvar("g_balance_health_start");
 414                 self.armorvalue = cvar("g_balance_armor_start");
 415                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 416                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 417                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 418                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 419                 self.damageforcescale = 2;
 420                 self.death_time = 0;
 421                 self.dead_time = 0;
 422                 self.dead_frame = 0;
 423                 self.die_frame = 0;
 424                 self.alpha = 0;
 425                 self.scale = 0;
 426                 self.fade_time = 0;
 427                 self.pain_frame = 0;
 428                 self.pain_finished = 0;
 429                 self.strength_finished = 0;
 430                 self.invincible_finished = 0;
 431                 self.pushltime = 0;
 432                 //self.speed_finished = 0;
 433                 //self.slowmo_finished = 0;
 434                 // players have no think function
 435                 self.think = SUB_Null;
 436                 self.nextthink = 0;
 437                 self.weapon = 0;
 438                 self.switchweapon = 0;
 439                 self.hook_time = 0;
 440
 441                 self.runes = 0;
 442
 443                 self.deadflag = DEAD_NO;
 444
 445                 self.angles = spot.angles;
 446
 447                 self.angles_z = 0; // never spawn tilted even if the spot says to
 448                 self.fixangle = TRUE; // turn this way immediately
 449                 self.velocity = '0 0 0';
 450                 self.avelocity = '0 0 0';
 451                 self.punchangle = '0 0 0';
 452                 self.punchvector = '0 0 0';
 453                 self.oldvelocity = self.velocity;
 454
 455                 self.viewzoom = 0.6;
 456
 457                 self.customizeentityforclient = Client_customizeentityforclient;
 458
 459                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
 460                         local string defaultmodel;
 461                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
 462                         setmodel_lod (self, defaultmodel);
 463                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 464                 } else {
 465                         self.playermodel = CheckPlayerModel(self.playermodel);
 466                         setmodel_lod (self, self.playermodel);
 467                         if(teams_matter)
 468                                 self.skin = math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY);
 469                         else
 470                                 self.skin = stof(self.playerskin);
 471                 }
 472
 473                 self.crouch = FALSE;
 474                 self.view_ofs = PL_VIEW_OFS;
 475                 setsize (self, PL_MIN, PL_MAX);
 476                 self.spawnorigin = spot.origin;
 477                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 478                 // don't reset back to last position, even if new position is stuck in solid
 479                 self.oldorigin = self.origin;
 480
 481                 if(cvar("g_lms"))
 482                 {
 483                         self.ammo_shells = cvar("g_lms_start_ammo_shells");
 484                         self.ammo_nails = cvar("g_lms_start_ammo_nails");
 485                         self.ammo_rockets = cvar("g_lms_start_ammo_rockets");
 486                         self.ammo_cells = cvar("g_lms_start_ammo_cells");
 487                         self.health = cvar("g_lms_start_health");
 488                         self.armorvalue = cvar("g_lms_start_armor");
 489                 }
 490                 else if (cvar("g_use_ammunition")) {
 491                         self.ammo_shells = cvar("g_start_ammo_shells");
 492                         self.ammo_nails = cvar("g_start_ammo_nails");
 493                         self.ammo_rockets = cvar("g_start_ammo_rockets");
 494                         self.ammo_cells = cvar("g_start_ammo_cells");
 495                 } else {
 496                         self.ammo_shells = 999;
 497                         self.ammo_nails = 999;
 498                         self.ammo_rockets = 999;
 499                         self.ammo_cells = 999;
 500                 }
 501
 502                 self.items = 0;
 503                 if (cvar("g_start_weapon_laser") || cvar("g_lms"))
 504                 {
 505                         self.items = self.items | IT_LASER;
 506                         self.switchweapon = WEP_LASER;
 507                 }
 508                 if (cvar("g_start_weapon_shotgun") || cvar("g_lms"))
 509                 {
 510                         self.items = self.items | IT_SHOTGUN;
 511                         self.switchweapon = WEP_SHOTGUN;
 512                 }
 513                 if (cvar("g_start_weapon_uzi") || cvar("g_lms"))
 514                 {
 515                         self.items = self.items | IT_UZI;
 516                         self.switchweapon = WEP_UZI;
 517                 }
 518                 if (cvar("g_start_weapon_grenadelauncher") || cvar("g_lms"))
 519                 {
 520                         self.items = self.items | IT_GRENADE_LAUNCHER;
 521                         self.switchweapon = WEP_GRENADE_LAUNCHER;
 522                 }
 523                 if (cvar("g_start_weapon_electro") || cvar("g_lms"))
 524                 {
 525                         self.items = self.items | IT_ELECTRO;
 526                         self.switchweapon = WEP_ELECTRO;
 527                 }
 528                 if (cvar("g_start_weapon_crylink") || cvar("g_lms"))
 529                 {
 530                         self.items = self.items | IT_CRYLINK;
 531                         self.switchweapon = WEP_CRYLINK;
 532                 }
 533                 if (cvar("g_start_weapon_nex") || cvar("g_lms"))
 534                 {
 535                         self.items = self.items | IT_NEX;
 536                         self.switchweapon = WEP_NEX;
 537                 }
 538                 if (cvar("g_start_weapon_hagar") || cvar("g_lms"))
 539                 {
 540                         self.items = self.items | IT_HAGAR;
 541                         self.switchweapon = WEP_HAGAR;
 542                 }
 543                 if (cvar("g_start_weapon_rocketlauncher") || cvar("g_lms"))
 544                 {
 545                         self.items = self.items | IT_ROCKET_LAUNCHER;
 546                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 547                 }
 548
 549                 if(cvar("g_instagib"))
 550                 {
 551                         self.items = IT_NEX;
 552                         self.switchweapon = WEP_NEX;
 553                         self.ammo_cells = 999;
 554                 }
 555
 556                 if(cvar("g_rocketarena"))
 557                 {
 558                         self.items = IT_ROCKET_LAUNCHER;
 559                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 560                         self.ammo_rockets = 999;
 561                 }
 562
 563                 if(cvar("g_nixnex"))
 564                 {
 565                         self.items = 0;
 566                         // will be done later
 567                 }
 568
 569                 if(cvar("g_minstagib"))
 570                 {
 571                         self.health = 100;
 572                         self.armorvalue = 0;
 573                         self.items = IT_NEX;
 574                         self.switchweapon = WEP_NEX;
 575                         self.ammo_cells = cvar("g_minstagib_ammo_start");
 576                         self.jump_interval = time;
 577                 }
 578
 579                 if(cvar("g_arena"))
 580                 {
 581                         Spawnqueue_Remove(self);
 582                         Spawnqueue_Mark(self);
 583                 }
 584
 585                 self.event_damage = PlayerDamage;
 586
 587                 self.bot_attack = TRUE;
 588
 589                 self.statdraintime = time + 5;
 590                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 591
 592                 if(self.killcount == -666) {
 593                         self.killcount = 0;
 594                         if(!cvar("g_arena"))
 595                         if(!cvar("g_lms"))
 596                                 self.frags = 0;
 597                 }
 598
 599                 self.cnt = WEP_LASER;
 600                 self.nixnex_lastchange_id = -1;
 601
 602                 CL_SpawnWeaponentity();
 603                 self.alpha = default_player_alpha;
 604                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 605
 606                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 607                 self.lms_traveled_distance = 0;
 608
 609                 if(cvar("spawn_debug"))
 610                 {
 611                                 sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 612                                 remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 613                 }
 614
 615                 //stuffcmd(self, "chase_active 0");
 616                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 617         } else if(self.classname == "observer") {
 618                 PutObserverInServer ();
 619         }
 620 }
 621
 622 /*
 623 =============
 624 SetNewParms
 625 =============
 626 */
 627 void SetNewParms (void)
 628 {
 629
 630 }
 631
 632 /*
 633 =============
 634 SetChangeParms
 635 =============
 636 */
 637 void SetChangeParms (void)
 638 {
 639
 640 }
 641
 642 /*
 643 =============
 644 ClientKill
 645
 646 Called when a client types 'kill' in the console
 647 =============
 648 */
 649 void ClientKill (void)
 650 {
 651         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 652 }
 653
 654 /*
 655 =============
 656 ClientConnect
 657
 658 Called when a client connects to the server
 659 =============
 660 */
 661 string ColoredTeamName(float t);
 662 //void dom_player_join_team(entity pl);
 663 void ClientConnect (void)
 664 {
 665         //local float fh;
 666         local string s;
 667
 668         self.classname = "player_joining";
 669         self.flags = self.flags | FL_CLIENT;
 670
 671         if(player_count<0) player_count = 0;
 672
 673         bot_clientconnect();
 674
 675         //if(cvar("g_domination"))
 676         //      dom_player_join_team(self);
 677
 678         //JoinBestTeam(self, FALSE);
 679
 680         if((cvar("sv_spectate") == 1 && !cvar("g_lms")) || cvar("g_campaign")) {
 681                 self.classname = "observer";
 682         } else {
 683                 self.classname = "player";
 684                 campaign_bots_may_start = 1;
 685         }
 686
 687         self.playerid = (playerid_last = playerid_last + 1);
 688         if(cvar("sv_eventlog"))
 689         {
 690                 if(clienttype(self) == CLIENTTYPE_REAL)
 691                         s = "player";
 692                 else
 693                         s = "bot";
 694                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 695                 s = strcat(":team:", ftos(self.playerid), ":");
 696                 s = strcat(s, ftos(self.team));
 697                 GameLogEcho(s, FALSE);
 698         }
 699
 700         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 701
 702         bprint ("^4",self.netname);
 703         bprint ("^4 connected");
 704
 705         if(cvar("g_domination") || cvar("g_ctf"))
 706         {
 707                 bprint(" and joined the ");
 708                 bprint(ColoredTeamName(self.team));
 709         }
 710
 711         bprint("\n");
 712
 713         self.welcomemessage_time = time + cvar("welcome_message_time");
 714         self.welcomemessage_time2 = 0;
 715
 716         /*
 717         // the client might not have his maps/%s.cfg file yet!
 718         // so send the one from the server...
 719         fh = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 720         if(fh >= 0)
 721         {
 722                 while((s = fgets(fh)))
 723                         stuffcmd(self, strcat(s, "\n"));
 724                 fclose(fh);
 725         }
 726         // and then execute the client's so he can still override CD tracks
 727
 728         not needed any more: current map download system disconnects and reconnects
 729         after the download, and then the file will be there
 730         */
 731         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 732
 733         // TODO: is this being used for anything else than cd tracks?
 734         // Remember: SVC_CDTRACK exists. Maybe it should be used.
 735
 736         // send prediction settings to the client
 737         stuffcmd(self, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 738         stuffcmd(self, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 739         stuffcmd(self, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 740         stuffcmd(self, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 741         stuffcmd(self, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 742         stuffcmd(self, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 743         stuffcmd(self, strcat("cl_movement_jumpvelocity ", ftos(cvar("g_balance_jumpheight")), "\n"));
 744         stuffcmd(self, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 745         stuffcmd(self, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 746         stuffcmd(self, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 747         stuffcmd(self, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 748         stuffcmd(self, strcat("cl_movement_edgefriction 0\n"));
 749         // Wazat's grappling hook
 750         SetGrappleHookBindings();
 751
 752         // get autoswitch state from player
 753         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1; cmd autoswitch $1\"\n");
 754         stuffcmd(self, "cmd autoswitch $cl_autoswitch\n");
 755
 756         // get version info from player
 757         stuffcmd(self, "cmd clientversion $gameversion\n");
 758
 759         // get other cvars from player
 760         GetCvars(0);
 761
 762         // set cvar for team scoreboard
 763         if (teams_matter)
 764         {
 765                 local float t;
 766                 t = cvar("teamplay");
 767                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
 768                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
 769         }
 770         else
 771                 stuffcmd(self, strcat("set teamplay 0\n"));
 772
 773         if(cvar("g_lms"))
 774         {
 775                 self.frags = cvar("fraglimit");
 776                 // no fraglimit was set, so player gets 999 lives
 777                 if(self.frags < 1)
 778                         self.frags = 999;
 779
 780                 // disallow player to join after the worst player has lost g_lms_last_join lives
 781                 // if "g_lms_join_anytime" new players spawn with same amount of lives as the worst active player
 782                 if(((cvar("fraglimit") - cvar("g_lms_last_join")) > lms_lowest_lives && !cvar("g_lms_join_anytime")) || lms_lowest_lives < 1)
 783                 {
 784                         self.frags = -666;
 785                         lms_dead_count += 1;
 786                 }
 787                 else if(cvar("fraglimit") > lms_lowest_lives)
 788                 {
 789                         self.frags = lms_lowest_lives;
 790                 }
 791         }
 792         else if(cvar("g_arena"))
 793         {
 794                 self.classname = "observer";
 795                 Spawnqueue_Insert(self);
 796         }
 797
 798         bot_relinkplayerlist();
 799
 800         self.jointime = time;
 801 }
 802
 803 /*
 804 =============
 805 ClientDisconnect
 806
 807 Called when a client disconnects from the server
 808 =============
 809 */
 810 void(entity e) DropFlag;
 811 .entity chatbubbleentity;
 812 .entity teambubbleentity;
 813 void ClientDisconnect (void)
 814 {
 815         float save;
 816         if(cvar("sv_eventlog"))
 817                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
 818         bprint ("^4",self.netname);
 819         bprint ("^4 disconnected\n");
 820
 821         if (self.chatbubbleentity)
 822         {
 823                 remove (self.chatbubbleentity);
 824                 self.chatbubbleentity = world;
 825         }
 826
 827         if (self.teambubbleentity)
 828         {
 829                 remove (self.teambubbleentity);
 830                 self.teambubbleentity = world;
 831         }
 832
 833         DropAllRunes(self);
 834
 835         if(self.flagcarried)
 836                 DropFlag(self.flagcarried);
 837
 838         DistributeFragsAmongTeam(self, self.team, 1);
 839
 840         save = self.flags;
 841         self.flags = self.flags - (self.flags & FL_CLIENT);
 842         bot_relinkplayerlist();
 843         self.flags = save;
 844
 845         // remove laserdot
 846         if(self.weaponentity)
 847                 if(self.weaponentity.lasertarget)
 848                         remove(self.weaponentity.lasertarget);
 849
 850         // player was dead, decrease dead count
 851         if(cvar("g_lms") && self.frags < 0)
 852                 lms_dead_count -= 1;
 853         else if(cvar("g_arena"))
 854         {
 855                 Spawnqueue_Unmark(self);
 856                 Spawnqueue_Remove(self);
 857         }
 858 }
 859
 860 .float buttonchat;
 861 void() ChatBubbleThink =
 862 {
 863         self.nextthink = time;
 864         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 865         {
 866                 self.owner.chatbubbleentity = world;
 867                 remove(self);
 868                 return;
 869         }
 870         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 871         if (self.owner.buttonchat && !self.owner.deadflag)
 872                 self.model = self.mdl;
 873         else
 874                 self.model = "";
 875 };
 876
 877 void() UpdateChatBubble =
 878 {
 879         if (!self.modelindex)
 880                 return;
 881         // spawn a chatbubble entity if needed
 882         if (!self.chatbubbleentity)
 883         {
 884                 self.chatbubbleentity = spawn();
 885                 self.chatbubbleentity.owner = self;
 886                 self.chatbubbleentity.exteriormodeltoclient = self;
 887                 self.chatbubbleentity.think = ChatBubbleThink;
 888                 self.chatbubbleentity.nextthink = time;
 889                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr");
 890                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 891                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 892                 self.chatbubbleentity.model = "";
 893         }
 894 }
 895
 896
 897 void() TeamBubbleThink =
 898 {
 899         self.nextthink = time;
 900         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 901         {
 902                 self.owner.teambubbleentity = world;
 903                 remove(self);
 904                 return;
 905         }
 906 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 907         if (self.owner.buttonchat || self.owner.deadflag)
 908                 self.model = "";
 909         else
 910                 self.model = self.mdl;
 911
 912 };
 913
 914 float() TeamBubble_customizeentityforclient
 915 {
 916         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
 917 }
 918
 919 void() UpdateTeamBubble =
 920 {
 921         if (!self.modelindex || !cvar("teamplay"))
 922                 return;
 923         // spawn a teambubble entity if needed
 924         if (!self.teambubbleentity && cvar("teamplay"))
 925         {
 926                 self.teambubbleentity = spawn();
 927                 self.teambubbleentity.owner = self;
 928                 self.teambubbleentity.exteriormodeltoclient = self;
 929                 self.teambubbleentity.think = TeamBubbleThink;
 930                 self.teambubbleentity.nextthink = time;
 931                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr");
 932 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 933                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 934                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 935                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 936                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 937                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
 938         }
 939 }
 940
 941 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 942 // added to the model skins
 943 /*void() UpdateColorModHack =
 944 {
 945         local float c;
 946         c = self.clientcolors & 15;
 947         // LordHavoc: only bothering to support white, green, red, yellow, blue
 948              if (teamplay == 0) self.colormod = '0 0 0';
 949         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 950         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 951         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 952         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 953         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 954         else self.colormod = '1 1 1';
 955 };*/
 956
 957 /*
 958 =============
 959 PlayerJump
 960
 961 When you press the jump key
 962 =============
 963 */
 964 void PlayerJump (void)
 965 {
 966         float mjumpheight;
 967
 968         mjumpheight = cvar("g_balance_jumpheight");
 969         if (self.waterlevel >= 2)
 970         {
 971                 if (self.watertype == CONTENT_WATER)
 972                         self.velocity_z = 200;
 973                 else if (self.watertype == CONTENT_SLIME)
 974                         self.velocity_z = 80;
 975                 else
 976                         self.velocity_z = 50;
 977
 978                 return;
 979         }
 980
 981
 982         if (!(self.flags & FL_ONGROUND))
 983                 return;
 984
 985         if (!(self.flags & FL_JUMPRELEASED))
 986                 return;
 987
 988         if(cvar("g_runematch"))
 989         {
 990                 if(self.runes & RUNE_SPEED)
 991                 {
 992                         if(self.runes & CURSE_SLOW)
 993                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
 994                         else
 995                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 996                 }
 997                 else if(self.runes & CURSE_SLOW)
 998                 {
 999                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
1000                 }
1001         }
1002
1003         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
1004         {
1005                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
1006         }
1007
1008         self.velocity_z = self.velocity_z + mjumpheight;
1009         self.oldvelocity_z = self.velocity_z;
1010
1011         self.flags = self.flags - FL_ONGROUND;
1012         self.flags = self.flags - FL_JUMPRELEASED;
1013 }
1014
1015 void() CheckWaterJump =
1016 {
1017         local vector start, end;
1018
1019 // check for a jump-out-of-water
1020         makevectors (self.angles);
1021         start = self.origin;
1022         start_z = start_z + 8;
1023         v_forward_z = 0;
1024         normalize(v_forward);
1025         end = start + v_forward*24;
1026         traceline (start, end, TRUE, self);
1027         if (trace_fraction < 1)
1028         {       // solid at waist
1029                 start_z = start_z + self.maxs_z - 8;
1030                 end = start + v_forward*24;
1031                 self.movedir = trace_plane_normal * -50;
1032                 traceline (start, end, TRUE, self);
1033                 if (trace_fraction == 1)
1034                 {       // open at eye level
1035                         self.flags = self.flags | FL_WATERJUMP;
1036                         self.velocity_z = 225;
1037                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
1038                         self.teleport_time = time + 2;  // safety net
1039                         return;
1040                 }
1041         }
1042 };
1043
1044
1045 void respawn(void)
1046 {
1047         CopyBody(1);
1048         PutClientInServer();
1049 }
1050
1051 void player_powerups (void)
1052 {
1053         if (cvar("g_minstagib"))
1054         {
1055                 self.effects = EF_FULLBRIGHT;
1056                 if (self.items & IT_STRENGTH)
1057                 {
1058                         if (time > self.strength_finished)
1059                         {
1060                                 self.alpha = default_player_alpha;
1061                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1062                                 self.items = self.items - (self.items & IT_STRENGTH);
1063                                 sprint(self, "^3Invisibility has worn off\n");
1064                         }
1065                 }
1066                 else
1067                 {
1068                         if (time < self.strength_finished)
1069                         {
1070                                 self.alpha = cvar("g_minstagib_invis_alpha");
1071                                 self.exteriorweaponentity.alpha = cvar("g_minstagib_invis_alpha");
1072                                 self.items = self.items | IT_STRENGTH;
1073                                 sprint(self, "^3You are invisible\n");
1074                         }
1075                 }
1076
1077                 if (self.items & IT_INVINCIBLE)
1078                 {
1079                         if (time > self.invincible_finished)
1080                         {
1081                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1082                                 sprint(self, "^3Speed has worn off\n");
1083                         }
1084                 }
1085                 else
1086                 {
1087                         if (time < self.invincible_finished)
1088                         {
1089                                 self.items = self.items | IT_INVINCIBLE;
1090                                 sprint(self, "^3You are on speed\n");
1091                         }
1092                 }
1093                 return;
1094         }
1095
1096         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1097         if (self.items & IT_STRENGTH)
1098         {
1099                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1100                 if (time > self.strength_finished)
1101                 {
1102                         self.items = self.items - (self.items & IT_STRENGTH);
1103                         sprint(self, "^3Strength has worn off\n");
1104                 }
1105         }
1106         else
1107         {
1108                 if (time < self.strength_finished)
1109                 {
1110                         self.items = self.items | IT_STRENGTH;
1111                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1112                 }
1113         }
1114         if (self.items & IT_INVINCIBLE)
1115         {
1116                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1117                 if (time > self.invincible_finished)
1118                 {
1119                         self.items = self.items - (self.items & IT_INVINCIBLE);
1120                         sprint(self, "^3Shield has worn off\n");
1121                 }
1122         }
1123         else
1124         {
1125                 if (time < self.invincible_finished)
1126                 {
1127                         self.items = self.items | IT_INVINCIBLE;
1128                         sprint(self, "^3Shield surrounds you\n");
1129                 }
1130         }
1131
1132         if (cvar("g_fullbrightplayers"))
1133                 self.effects = self.effects | EF_FULLBRIGHT;
1134
1135         // midair gamemode: damage only while in the air
1136         // if in midair mode, being on ground grants temporary invulnerability
1137         // (this is so that multishot weapon don't clear the ground flag on the
1138         // first damage in the frame, leaving the player vulnerable to the
1139         // remaining hits in the same frame)
1140         if (self.flags & FL_ONGROUND)
1141         if (cvar("g_midair"))
1142                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1143
1144         if (time < self.spawnshieldtime)
1145                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1146 }
1147
1148 float CalcRegen(float current, float stable, float maxv, float regenfactor)
1149 {
1150         if(current > stable)
1151                 return current;
1152         else if(current > stable - 0.25) // when close enough, "snap"
1153                 return stable;
1154         else
1155                 return bound(0, current + (stable - current) * regenfactor * frametime, maxv);
1156 }
1157
1158 void player_regen (void)
1159 {
1160         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1161         maxh = cvar("g_balance_health_stable");
1162         maxa = cvar("g_balance_armor_stable");
1163         limith = cvar("g_balance_health_limit");
1164         limita = cvar("g_balance_armor_limit");
1165
1166         if (cvar("g_minstagib") || (cvar("g_lms") && !cvar("g_lms_regenerate")))
1167                 return;
1168
1169         if(cvar("g_runematch"))
1170         {
1171                 max_mod = regen_mod = rot_mod = limit_mod = 1;
1172                 if (self.runes & RUNE_REGEN)
1173                 {
1174                         if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1175                         {
1176                                 regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1177                                 max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1178                                 limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1179                         }
1180                         else
1181                         {
1182                                 regen_mod = cvar("g_balance_rune_regen_regenrate");
1183                                 max_mod = cvar("g_balance_rune_regen_hpmod");
1184                                 limit_mod = cvar("g_balance_rune_regen_limitmod");
1185                         }
1186                 }
1187                 else if (self.runes & CURSE_VENOM)
1188                 {
1189                         max_mod = cvar("g_balance_curse_venom_hpmod");
1190                         if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1191                                 rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1192                         else
1193                                 rot_mod = cvar("g_balance_curse_venom_rotrate");
1194                         limit_mod = cvar("g_balance_curse_venom_limitmod");
1195                         //if (!self.runes & RUNE_REGEN)
1196                         //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1197                 }
1198                 maxh = maxh * max_mod;
1199                 //maxa = maxa * max_mod;
1200
1201                 if (time > self.pauserotarmor_finished)
1202                 {
1203                         if (self.armorvalue > maxa)
1204                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1205                 }
1206                 if (time > self.pauserothealth_finished)
1207                 {
1208                         if (self.health > maxh)
1209                                 self.health = bound(0, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime, 1000);
1210                 }
1211                 if (time > self.pauseregen_finished)
1212                 {
1213                         self.health = CalcRegen(self.health, maxh, 1000, regen_mod * cvar("g_balance_health_regen"));
1214                         self.armorvalue = CalcRegen(self.armorvalue, maxa, 1000, cvar("g_balance_armor_regen"));
1215                 }
1216         }
1217         else
1218         {
1219                 if (time > self.pauserothealth_finished)
1220                 if (self.health > maxh)
1221                         self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_rot") * frametime, 1000);
1222                 if (time > self.pauserotarmor_finished)
1223                 if (self.armorvalue > maxa)
1224                         self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1225                 if (time > self.pauseregen_finished)
1226                 {
1227                         self.health = CalcRegen(self.health, maxh, 1000, cvar("g_balance_health_regen"));
1228                         self.armorvalue = CalcRegen(self.armorvalue, maxa, 1000, cvar("g_balance_armor_regen"));
1229                 }
1230         }
1231
1232         if (self.health > limith)
1233                 self.health = limith;
1234         if(self.health < 1)
1235                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1236         if (self.armorvalue > limita)
1237                 self.armorvalue = limita;
1238 }
1239
1240 /*
1241 ======================
1242 spectate mode routines
1243 ======================
1244 */
1245 void SpectateCopy(entity spectatee) {
1246         self.armortype = spectatee.armortype;
1247         self.armorvalue = spectatee.armorvalue;
1248         self.currentammo = spectatee.currentammo;
1249         self.effects = spectatee.effects;
1250         self.health = spectatee.health;
1251         self.impulse = 0;
1252         self.items = spectatee.items;
1253         self.punchangle = spectatee.punchangle;
1254         self.view_ofs = spectatee.view_ofs;
1255         self.v_angle = spectatee.v_angle;
1256         self.viewzoom = spectatee.viewzoom;
1257         setorigin(self, spectatee.origin);
1258         setsize(self, spectatee.mins, spectatee.maxs);
1259 }
1260
1261 void SpectateUpdate() {
1262         if(!self.enemy)
1263                         PutObserverInServer();
1264
1265         if (self != self.enemy) {
1266                 if(self.enemy.flags & FL_NOTARGET)
1267                         PutObserverInServer();
1268                 SpectateCopy(self.enemy);
1269                 self.dmg_take = self.enemy.dmg_take;
1270                 self.dmg_save = self.enemy.dmg_save;
1271                 self.dmg_inflictor = self.enemy.dmg_inflictor;
1272                 self.fixangle = TRUE;
1273                 self.angles = self.enemy.v_angle;
1274                 //msg_entity = self;
1275                 //WriteByte(MSG_ONE, SVC_SETANGLE);
1276                 //WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1277                 //WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1278                 //WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1279         }
1280 }
1281
1282 float SpectateNext() {
1283         other = find(self.enemy, classname, "player");
1284         if (!other) {
1285                 other = find(other, classname, "player");
1286         }
1287         if (other) {
1288                 self.enemy = other;
1289         }
1290         if(self.enemy.classname == "player") {
1291                 msg_entity = self;
1292                 WriteByte(MSG_ONE, SVC_SETVIEW);
1293                 WriteEntity(MSG_ONE, self.enemy);
1294                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1295                 SpectateUpdate();
1296                 return 1;
1297         } else {
1298                 return 0;
1299         }
1300 }
1301
1302 /*
1303 =============
1304 PlayerPreThink
1305
1306 Called every frame for each client before the physics are run
1307 =============
1308 */
1309 void() ctf_setstatus;
1310 void PlayerPreThink (void)
1311 {
1312         if(self.classname == "player") {
1313                 local vector m1, m2;
1314
1315 //              if(self.netname == "Wazat")
1316 //                      bprint(strcat(self.classname, "\n"));
1317
1318                 CheckRules_Player();
1319
1320                 Nixnex_GiveCurrentWeapon();
1321
1322                 if(self.button7)
1323                         PrintWelcomeMessage(self);
1324
1325                 if(cvar("g_lms") || !cvar("sv_spectate"))
1326                 if((time - self.jointime) <= cvar("welcome_message_time"))
1327                         PrintWelcomeMessage(self);
1328
1329                 if (intermission_running)
1330                 {
1331                         IntermissionThink ();   // otherwise a button could be missed between
1332                         return;                                 // the think tics
1333                 }
1334
1335                 if (self.deadflag != DEAD_NO)
1336                 {
1337                         player_anim();
1338                         if (self.deadflag == DEAD_DYING)
1339                         {
1340                                 if (time > self.dead_time)
1341                                         self.deadflag = DEAD_DEAD;
1342                         }
1343                         else if (self.deadflag == DEAD_DEAD)
1344                         {
1345                                 if (cvar("g_lms") || cvar("g_arena") || cvar("g_forced_respawn"))
1346                                         self.deadflag = DEAD_RESPAWNABLE;
1347                                 else if (!self.button0 && !self.button2 && !self.button3)
1348                                         self.deadflag = DEAD_RESPAWNABLE;
1349                         }
1350                         else if (self.deadflag == DEAD_RESPAWNABLE)
1351                         {
1352                                 if (self.button0  ||
1353                                     self.button2  ||
1354                                     self.button3  ||
1355                                     self.button4  ||
1356                                     self.button5  ||
1357                                     self.button6  ||
1358                                     self.button7  ||
1359                                     self.button8  ||
1360                                     self.buttonuse ||
1361                                     cvar("g_lms") ||
1362                                     cvar("g_forced_respawn"))
1363                                         respawn();
1364                         }
1365                         return;
1366                 }
1367
1368                 if(cvar("g_lms") && !self.deadflag && cvar("g_lms_campcheck_interval"))
1369                 {
1370                         vector dist;
1371
1372                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1373                         dist = self.oldorigin - self.origin;
1374                         dist_z = 0;
1375                         self.lms_traveled_distance += fabs(vlen(dist));
1376
1377                         if(cvar("g_campaign"))
1378                         if(!campaign_bots_may_start)
1379                         {
1380                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1381                                 self.lms_traveled_distance = 0;
1382                         }
1383
1384                         if(time > self.lms_nextcheck)
1385                         {
1386                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1387                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1388                                 {
1389                                         centermsg_set(CENTERMSG_CAMP, cvar_string("g_lms_campcheck_message"));
1390                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1391                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1392                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1393                                 }
1394                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1395                                 self.lms_traveled_distance = 0;
1396                         }
1397                 }
1398
1399                 if (self.button5 && !self.hook.state)
1400                 {
1401                         if (!self.crouch)
1402                         {
1403                                 self.crouch = TRUE;
1404                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1405                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1406                         }
1407                 }
1408                 else
1409                 {
1410                         if (self.crouch)
1411                         {
1412                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1413                                 if (!trace_startsolid)
1414                                 {
1415                                         self.crouch = FALSE;
1416                                         self.view_ofs = PL_VIEW_OFS;
1417                                         setsize (self, PL_MIN, PL_MAX);
1418                                 }
1419                         }
1420                 }
1421
1422                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
1423                         local string defaultmodel;
1424                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
1425
1426                         if (defaultmodel != self.model)
1427                         {
1428                                 m1 = self.mins;
1429                                 m2 = self.maxs;
1430                                 setmodel_lod (self, defaultmodel);
1431                                 setsize (self, m1, m2);
1432                         }
1433
1434                         if (self.skin != cvar("sv_defaultplayerskin"))
1435                                 self.skin = cvar("sv_defaultplayerskin");
1436                 } else {
1437                         if (self.playermodel != self.model)
1438                         {
1439                                 self.playermodel = CheckPlayerModel(self.playermodel);
1440                                 m1 = self.mins;
1441                                 m2 = self.maxs;
1442                                 setmodel_lod (self, self.playermodel);
1443                                 setsize (self, m1, m2);
1444                         }
1445
1446                         if(teams_matter)
1447                         {
1448                                 if (self.skin != math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY))
1449                                         self.skin = math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY);
1450                         }
1451                         else
1452                         {
1453                                 if (self.skin != stof(self.playerskin))
1454                                         self.skin = stof(self.playerskin);
1455                         }
1456                 }
1457                 // Savage: Check for nameless players
1458                 if (strlen(self.netname) < 1) {
1459                         self.netname = "Player";
1460                         stuffcmd(self, "name Player\n");
1461                 }
1462
1463                 GrapplingHookFrame();
1464
1465                 W_WeaponFrame();
1466
1467                 if (self.button4 || (self.weapon == WEP_NEX && self.button3))
1468                 {
1469                         if (cvar("g_minstagib") && self.button3)
1470                         {
1471                                 if (self.jump_interval <= (time + 0.1))
1472                                 {
1473                                         self.jump_interval = time + 1;
1474                                         W_Laser_Attack();
1475                                 }
1476                         }
1477                         else if (self.viewzoom > 0.4)
1478                                 self.viewzoom = max (0.4, self.viewzoom - frametime * 2);
1479                 }
1480                 else if (self.viewzoom < 1.0)
1481                         self.viewzoom = min (1.0, self.viewzoom + frametime);
1482
1483
1484                 if (self.button2)
1485                         PlayerJump ();
1486                 else
1487                         self.flags = self.flags | FL_JUMPRELEASED;
1488
1489                 player_powerups();
1490                 player_regen();
1491                 player_anim();
1492
1493                 if (cvar("g_minstagib"))
1494                         minstagib_ammocheck();
1495
1496                 ctf_setstatus();
1497
1498                 //self.angles_y=self.v_angle_y + 90;   // temp
1499
1500                 if (self.waterlevel == 2)
1501                         CheckWaterJump ();
1502
1503                 //if (TetrisPreFrame()) return;
1504         } else if(gameover) {
1505                 if (intermission_running)
1506                         IntermissionThink ();   // otherwise a button could be missed between
1507                 return;
1508         } else if(self.classname == "observer") {
1509
1510                 if (self.flags & FL_JUMPRELEASED) {
1511                         if (self.button2 && self.version == cvar("gameversion")) {
1512                                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1513                                         self.flags = self.flags & !FL_JUMPRELEASED;
1514                                         self.classname = "player";
1515                                         if(cvar("g_campaign") || cvar("g_balance_teams"))
1516                                                 JoinBestTeam(self, 0);
1517                                         if(cvar("g_campaign"))
1518                                                 campaign_bots_may_start = 1;
1519                                         PutClientInServer();
1520                                         if(self.flags & !FL_NOTARGET)
1521                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1522                                         centermsg_reset();
1523                                         return;
1524                                 } else {
1525                                         self.flags = self.flags & !FL_JUMPRELEASED;
1526                                         stuffcmd(self,"menu_showteamselect\n");
1527                                         return;
1528                                 }
1529                         } else if(self.button0 && self.version == cvar("gameversion")) {
1530                                 self.flags = self.flags & !FL_JUMPRELEASED;
1531                                 if(SpectateNext() == 1) {
1532                                         self.classname = "spectator";
1533                                 }
1534                         }
1535                 } else {
1536                         if (!(self.button0 || self.button2)) {
1537                                 self.flags = self.flags | FL_JUMPRELEASED;
1538                         }
1539                 }
1540                 PrintWelcomeMessage(self);
1541         } else if(self.classname == "spectator") {
1542                 if (self.flags & FL_JUMPRELEASED) {
1543                         if (self.button2 && self.version == cvar("gameversion")) {
1544                                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1545                                         self.flags = self.flags & !FL_JUMPRELEASED;
1546                                         self.classname = "player";
1547                                         if(!cvar("g_lms"))
1548                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1549
1550                                         if(cvar("g_campaign") || cvar("g_balance_teams"))
1551                                                 JoinBestTeam(self, 0);
1552                                         if(cvar("g_campaign"))
1553                                                 campaign_bots_may_start = 1;
1554                                         PutClientInServer();
1555                                         centermsg_reset();
1556                                         return;
1557                                 } else {
1558                                         self.flags = self.flags & !FL_JUMPRELEASED;
1559                                         stuffcmd(self,"menu_showteamselect\n");
1560                                         return;
1561                                 }
1562                         } else if(self.button0) {
1563                                 self.flags = self.flags & !FL_JUMPRELEASED;
1564                                 if(SpectateNext() == 1) {
1565                                         self.classname = "spectator";
1566                                 } else {
1567                                         self.classname = "observer";
1568                                         PutClientInServer();
1569                                 }
1570                         } else if (self.button3) {
1571                                 self.flags = self.flags & !FL_JUMPRELEASED;
1572                                 self.classname = "observer";
1573                                 PutClientInServer();
1574                         } else {
1575                                 SpectateUpdate();
1576                         }
1577                 } else {
1578                         if (!(self.button0 || self.button3)) {
1579                                 self.flags = self.flags | FL_JUMPRELEASED;
1580                         }
1581                 }
1582                 PrintWelcomeMessage(self);
1583                 self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1584         }
1585 }
1586
1587
1588 /*
1589 =============
1590 PlayerPostThink
1591
1592 Called every frame for each client after the physics are run
1593 =============
1594 */
1595 void PlayerPostThink (void)
1596 {
1597         if(self.classname == "player") {
1598                 CheckRules_Player();
1599                 UpdateChatBubble();
1600                 UpdateTeamBubble();
1601                 if (self.deadflag == DEAD_NO)
1602                 if (self.impulse)
1603                         ImpulseCommands ();
1604                 if (intermission_running)
1605                         return;         // intermission or finale
1606
1607                 //PrintWelcomeMessage(self);
1608                 //if (TetrisPostFrame()) return;
1609         } else if (self.classname == "observer") {
1610                 //do nothing
1611         } else if (self.classname == "spectator") {
1612                 //do nothing
1613         }
1614         Arena_Warmup();
1615 }