data/qcsrc/server/cl_client.qc

   1 .float wantswelcomemessage;
   2
   3 void info_player_survivor (void)
   4 {
   5         info_player_deathmatch();
   6 }
   7
   8 void info_player_start (void)
   9 {
  10         info_player_deathmatch();
  11 }
  12
  13 void info_player_deathmatch (void)
  14 {
  15         self.classname = "info_player_deathmatch";
  16         relocate_spawnpoint();
  17 }
  18
  19 void() spawnpoint_use =
  20 {
  21         if(teams_matter)
  22         if(have_team_spawns)
  23         {
  24                 self.team = activator.team;
  25                 some_spawn_has_been_used = 1;
  26         }
  27 };
  28
  29 float spawn_allbad;
  30 float spawn_allgood;
  31 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  32 {
  33         local entity spot, player, nextspot, previousspot, newfirstspot;
  34         local float pcount;
  35         spot = firstspot;
  36         newfirstspot = world;
  37         previousspot = world;
  38         spawn_allgood = TRUE;
  39         spawn_allbad = TRUE;
  40         while (spot)
  41         {
  42                 nextspot = spot.chain;
  43                 // count team mismatches as bad spots
  44
  45                 local float spotactive;
  46                 spotactive = 1;
  47
  48                 // filter out spots for assault
  49                 if(spot.target != "") {
  50                         local entity ent;
  51                         ent = find(world, targetname, spot.target);
  52                         while(ent) {
  53                                 if(ent.classname == "target_objective")
  54                                         if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  55                                                 spotactive = 0;
  56                                 ent = find(ent, targetname, spot.target);
  57                         }
  58                 }
  59
  60                 if ((!teamcheck || spot.team == teamcheck) && spotactive > 0)
  61                 {
  62                         pcount = 0;
  63                         player = playerlist;
  64                         while (player)
  65                         {
  66                                 if (player != self)
  67                                 if (vlen(player.origin - spot.origin) < mindist)
  68                                         pcount = pcount + 1;
  69                                 player = player.chain;
  70                         }
  71                         if (!pcount)
  72                         {
  73                                 spawn_allbad = FALSE;
  74                                 if (newfirstspot)
  75                                         previousspot.chain = spot;
  76                                 else
  77                                         newfirstspot = spot;
  78                                 previousspot = spot;
  79                                 spot.chain = world;
  80                         }
  81                         else
  82                                 spawn_allgood = FALSE;
  83                 }
  84                 spot = nextspot;
  85         }
  86         // if we couldn't find ANY good points, return world
  87         return newfirstspot;
  88 }
  89
  90 entity Spawn_RandomPoint(entity firstspot)
  91 {
  92         local entity spot;
  93         local float numspots;
  94         // count number of spots
  95         numspots = 0;
  96         spot = firstspot;
  97         while (spot)
  98         {
  99                 numspots = numspots + 1;
 100                 spot = spot.chain;
 101         }
 102         // pick a random one
 103         numspots = numspots * random();
 104         spot = firstspot;
 105         while (spot.chain && numspots >= 1)
 106         {
 107                 numspots = numspots - 1;
 108                 spot = spot.chain;
 109         }
 110         return spot;
 111 }
 112
 113 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
 114 {
 115         local entity best, spot, player;
 116         local float bestrating, rating;
 117         best = world;
 118         bestrating = -1000000;
 119         spot = firstspot;
 120         while (spot)
 121         {
 122                 rating = 1000000000;
 123                 player = playerlist;
 124                 while (player)
 125                 {
 126                         if (player != self)
 127                                 rating = min(rating, vlen(player.origin - spot.origin));
 128                         player = player.chain;
 129                 }
 130                 rating = rating + random() * 16;
 131                 if (bestrating < rating)
 132                 {
 133                         best = spot;
 134                         bestrating = rating;
 135                 }
 136                 spot = spot.chain;
 137         }
 138         return best;
 139 }
 140
 141 /*
 142 =============
 143 SelectSpawnPoint
 144
 145 Finds a point to respawn
 146 =============
 147 */
 148 entity SelectSpawnPoint (float anypoint)
 149 {
 150         local float teamcheck;
 151         local entity firstspot_new;
 152         local entity spot, firstspot, playerlist;
 153
 154         spot = find (world, classname, "testplayerstart");
 155         if (spot)
 156                 return spot;
 157
 158         teamcheck = 0;
 159
 160         if(!anypoint && have_team_spawns)
 161                 teamcheck = self.team;
 162
 163         // get the list of players
 164         playerlist = findchain(classname, "player");
 165         // get the entire list of spots
 166         firstspot = findchain(classname, "info_player_deathmatch");
 167         // filter out the bad ones
 168         // (note this returns the original list if none survived)
 169         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 170         if(!firstspot_new)
 171                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 172         firstspot = firstspot_new;
 173
 174         // there is 50/50 chance of choosing a random spot or the furthest spot
 175         // (this means that roughly every other spawn will be furthest, so you
 176         // usually won't get fragged at spawn twice in a row)
 177         if (arena_roundbased)
 178         {
 179                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 180                 if(firstspot_new)
 181                         firstspot = firstspot_new;
 182                 spot = Spawn_RandomPoint(firstspot);
 183         }
 184         else if (random() > 0.5 || spawn_allbad || spawn_allgood)
 185                 spot = Spawn_RandomPoint(firstspot);
 186         else
 187                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 188
 189         if (!spot)
 190         {
 191                 if(cvar("spawn_debug"))
 192                         GotoNextMap();
 193                 else
 194                 {
 195                         if(some_spawn_has_been_used)
 196                                 return world; // team can't spawn any more, because of actions of other team
 197                         else
 198                                 error("Cannot find a spawn point - please fix the map!");
 199                 }
 200         }
 201
 202         return spot;
 203 }
 204
 205 /*
 206 =============
 207 CheckPlayerModel
 208
 209 Checks if the argument string can be a valid playermodel.
 210 Returns a valid one in doubt.
 211 =============
 212 */
 213 string FallbackPlayerModel = "models/player/marine.zym";
 214 string CheckPlayerModel(string plyermodel) {
 215         if(strlen(plyermodel) < 4)
 216                 return FallbackPlayerModel;
 217         if( substring(plyermodel,0,14) != "models/player/")
 218                 return FallbackPlayerModel;
 219         else if(cvar("sv_servermodelsonly"))
 220         {
 221                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 222                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 223                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 224                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 225                         return FallbackPlayerModel;
 226                 if(!fexists(plyermodel))
 227                         return FallbackPlayerModel;
 228         }
 229         return plyermodel;
 230 }
 231
 232 /*
 233 =============
 234 Client_customizeentityforclient
 235
 236 LOD reduction
 237 =============
 238 */
 239 float Client_customizeentityforclient()
 240 {
 241 #ifdef ALLOW_VARIABLE_LOD
 242         // self: me
 243         // other: the player viewing me
 244         float distance;
 245         float f;
 246
 247         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 248                 return TRUE;
 249
 250         if(other.cvar_cl_playerdetailreduction <= 0)
 251         {
 252                 if(other.cvar_cl_playerdetailreduction <= -2)
 253                         self.modelindex = self.modelindex_lod2;
 254                 else if(other.cvar_cl_playerdetailreduction <= -1)
 255                         self.modelindex = self.modelindex_lod1;
 256                 else
 257                         self.modelindex = self.modelindex_lod0;
 258         }
 259         else
 260         {
 261                 distance = vlen(self.origin - other.origin);
 262                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 263                 if(f > 10000)
 264                         self.modelindex = self.modelindex_lod2;
 265                 else if(f > 5000)
 266                         self.modelindex = self.modelindex_lod1;
 267                 else
 268                         self.modelindex = self.modelindex_lod0;
 269         }
 270 #endif
 271
 272         return TRUE;
 273 }
 274
 275 void UpdatePlayerSounds();
 276 void setmodel_lod(entity e, string modelname)
 277 {
 278 #ifdef ALLOW_VARIABLE_LOD
 279         string s;
 280
 281         // FIXME: this only supports 3-letter extensions
 282         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 283         if(fexists(s))
 284         {
 285                 precache_model(s);
 286                 setmodel(e, s); // players have high precision
 287                 self.modelindex_lod1 = self.modelindex;
 288         }
 289         else
 290                 self.modelindex_lod1 = -1;
 291
 292         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 293         if(fexists(s))
 294         {
 295                 precache_model(s);
 296                 setmodel(e, s); // players have high precision
 297                 self.modelindex_lod2 = self.modelindex;
 298         }
 299         else
 300                 self.modelindex_lod2 = -1;
 301
 302         precache_model(modelname);
 303         setmodel(e, modelname); // players have high precision
 304         self.modelindex_lod0 = self.modelindex;
 305
 306         if(self.modelindex_lod1 < 0)
 307                 self.modelindex_lod1 = self.modelindex;
 308
 309         if(self.modelindex_lod2 < 0)
 310                 self.modelindex_lod2 = self.modelindex;
 311 #else
 312         precache_model(modelname);
 313         setmodel(e, modelname); // players have high precision
 314 #endif
 315         player_setupanimsformodel();
 316         UpdatePlayerSounds();
 317 }
 318
 319 /*
 320 =============
 321 PutObserverInServer
 322
 323 putting a client as observer in the server
 324 =============
 325 */
 326 void PutObserverInServer (void)
 327 {
 328         entity  spot;
 329         spot = SelectSpawnPoint (TRUE);
 330         if(!spot)
 331                 error("No spawnpoints for observers?!?\n");
 332         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 333
 334         if(clienttype(self) == CLIENTTYPE_REAL)
 335         {
 336                 msg_entity = self;
 337                 WriteByte(MSG_ONE, SVC_SETVIEW);
 338                 WriteEntity(MSG_ONE, self);
 339         }
 340
 341         DropAllRunes(self);
 342         kh_Key_DropAll(self, TRUE);
 343
 344         if(self.flagcarried)
 345                 DropFlag(self.flagcarried);
 346
 347         WaypointSprite_PlayerDead();
 348
 349         DistributeFragsAmongTeam(self, self.team, 1);
 350
 351         if(self.frags <= 0 && self.frags > -666 && g_lms && self.killcount != -666)
 352                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 353         else if(self.killcount != -666)
 354                 bprint ("^4", self.netname, "^4 is spectating now\n");
 355
 356         self.classname = "observer";
 357         self.health = -666;
 358         self.takedamage = DAMAGE_NO;
 359         self.solid = SOLID_NOT;
 360         self.movetype = MOVETYPE_NOCLIP;
 361         self.flags = FL_CLIENT | FL_NOTARGET;
 362         self.armorvalue = 666;
 363         self.effects = 0;
 364         self.armorvalue = cvar("g_balance_armor_start");
 365         self.pauserotarmor_finished = 0;
 366         self.pauserothealth_finished = 0;
 367         self.pauseregen_finished = 0;
 368         self.damageforcescale = 0;
 369         self.death_time = 0;
 370         self.dead_frame = 0;
 371         self.deaths = 0;
 372         self.alpha = 0;
 373         self.scale = 0;
 374         self.fade_time = 0;
 375         self.pain_frame = 0;
 376         self.pain_finished = 0;
 377         self.strength_finished = 0;
 378         self.invincible_finished = 0;
 379         self.pushltime = 0;
 380         self.think = SUB_Null;
 381         self.nextthink = 0;
 382         self.hook_time = 0;
 383         self.runes = 0;
 384         self.deadflag = DEAD_NO;
 385         self.angles = spot.angles;
 386         self.angles_z = 0;
 387         self.fixangle = TRUE;
 388         self.crouch = FALSE;
 389
 390         self.view_ofs = PL_VIEW_OFS;
 391         setorigin (self, spot.origin);
 392         setsize (self, '0 0 0', '0 0 0');
 393         self.oldorigin = self.origin;
 394         self.items = 0;
 395         self.model = "";
 396         self.modelindex = 0;
 397         self.weapon = 0;
 398         self.weaponmodel = "";
 399         self.weaponentity = world;
 400         self.killcount = -666;
 401         self.velocity = '0 0 0';
 402         self.avelocity = '0 0 0';
 403         self.punchangle = '0 0 0';
 404         self.punchvector = '0 0 0';
 405         self.oldvelocity = self.velocity;
 406         self.customizeentityforclient = Client_customizeentityforclient;
 407         self.viewzoom = 1;
 408         self.wantswelcomemessage = 1;
 409
 410         if(g_arena)
 411         {
 412                 if(self.frags != -2)
 413                 {
 414                         Spawnqueue_Insert(self);
 415                 }
 416                 else
 417                 {
 418                         Spawnqueue_Unmark(self);
 419                         Spawnqueue_Remove(self);
 420                 }
 421         }
 422         else if(!g_lms)
 423                 self.frags = -666;
 424 }
 425
 426 float RestrictSkin(float s)
 427 {
 428         if(!teams_matter)
 429                 return s;
 430         if(s == 6)
 431                 return 6;
 432         return mod(s, 3);
 433 }
 434
 435 void FixPlayermodel()
 436 {
 437         local string defaultmodel;
 438         local float defaultskin;
 439         local vector m1, m2;
 440
 441         defaultmodel = "";
 442
 443         if(cvar("sv_defaultcharacter") == 1) {
 444                 defaultskin = 0;
 445
 446                 if(teams_matter)
 447                 {
 448                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 449                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 450                 }
 451
 452                 if(defaultmodel == "")
 453                 {
 454                         defaultmodel = cvar_string("sv_defaultplayermodel");
 455                         defaultskin = cvar("sv_defaultplayerskin");
 456                 }
 457         }
 458
 459         if(defaultmodel != "")
 460         {
 461                 if (defaultmodel != self.model)
 462                 {
 463                         m1 = self.mins;
 464                         m2 = self.maxs;
 465                         setmodel_lod (self, defaultmodel);
 466                         setsize (self, m1, m2);
 467                 }
 468
 469                 self.skin = defaultskin;
 470         } else {
 471                 if (self.playermodel != self.model)
 472                 {
 473                         self.playermodel = CheckPlayerModel(self.playermodel);
 474                         m1 = self.mins;
 475                         m2 = self.maxs;
 476                         setmodel_lod (self, self.playermodel);
 477                         setsize (self, m1, m2);
 478                 }
 479
 480                 self.skin = RestrictSkin(stof(self.playerskin));
 481         }
 482
 483         if(!teams_matter)
 484                 if(strlen(cvar_string("sv_defaultplayercolors")))
 485                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 486                                 setcolor(self, cvar("sv_defaultplayercolors"));
 487 }
 488
 489 /*
 490 =============
 491 PutClientInServer
 492
 493 Called when a client spawns in the server
 494 =============
 495 */
 496 void PutClientInServer (void)
 497 {
 498         if(clienttype(self) == CLIENTTYPE_BOT)
 499         {
 500                 self.classname = "player";
 501         }
 502         else if(clienttype(self) == CLIENTTYPE_REAL)
 503         {
 504                 msg_entity = self;
 505                 WriteByte(MSG_ONE, SVC_SETVIEW);
 506                 WriteEntity(MSG_ONE, self);
 507         }
 508
 509         // player is dead and becomes observer
 510         if(g_lms && self.frags < 1)
 511                 self.classname = "observer";
 512
 513         if(g_arena)
 514         if(!self.spawned)
 515                 self.classname = "observer";
 516
 517         if(self.classname == "player") {
 518                 entity  spot;
 519
 520                 spot = SelectSpawnPoint (FALSE);
 521                 if(!spot)
 522                 {
 523                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 524                         return; // spawn failed
 525                 }
 526
 527                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 528
 529                 self.classname = "player";
 530                 self.iscreature = TRUE;
 531                 self.movetype = MOVETYPE_WALK;
 532                 self.solid = SOLID_SLIDEBOX;
 533                 self.flags = FL_CLIENT;
 534                 self.takedamage = DAMAGE_AIM;
 535                 if(g_minstagib)
 536                         self.effects = EF_FULLBRIGHT;
 537                 else
 538                         self.effects = 0;
 539                 self.air_finished = time + 12;
 540                 self.dmg = 2;
 541
 542                 self.ammo_shells = start_ammo_shells;
 543                 self.ammo_nails = start_ammo_nails;
 544                 self.ammo_rockets = start_ammo_rockets;
 545                 self.ammo_cells = start_ammo_cells;
 546                 self.health = start_health;
 547                 self.armorvalue = start_armorvalue;
 548                 self.items = start_items;
 549                 self.switchweapon = start_switchweapon;
 550                 self.cnt = start_switchweapon;
 551                 self.weapon = 0;
 552                 self.jump_interval = time;
 553
 554                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 555                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 556                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 557                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 558                 self.damageforcescale = 2;
 559                 self.death_time = 0;
 560                 self.dead_frame = 0;
 561                 self.alpha = 0;
 562                 self.scale = 0;
 563                 self.fade_time = 0;
 564                 self.pain_frame = 0;
 565                 self.pain_finished = 0;
 566                 self.strength_finished = 0;
 567                 self.invincible_finished = 0;
 568                 self.pushltime = 0;
 569                 //self.speed_finished = 0;
 570                 //self.slowmo_finished = 0;
 571                 // players have no think function
 572                 self.think = SUB_Null;
 573                 self.nextthink = 0;
 574                 self.hook_time = 0;
 575
 576                 self.runes = 0;
 577
 578                 self.deadflag = DEAD_NO;
 579
 580                 self.angles = spot.angles;
 581
 582                 self.angles_z = 0; // never spawn tilted even if the spot says to
 583                 self.fixangle = TRUE; // turn this way immediately
 584                 self.velocity = '0 0 0';
 585                 self.avelocity = '0 0 0';
 586                 self.punchangle = '0 0 0';
 587                 self.punchvector = '0 0 0';
 588                 self.oldvelocity = self.velocity;
 589
 590                 self.viewzoom = 0.6;
 591                 self.has_zoomed = 0;
 592
 593                 self.customizeentityforclient = Client_customizeentityforclient;
 594
 595                 self.model = "";
 596                 FixPlayermodel();
 597
 598                 self.crouch = FALSE;
 599                 self.view_ofs = PL_VIEW_OFS;
 600                 setsize (self, PL_MIN, PL_MAX);
 601                 self.spawnorigin = spot.origin;
 602                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 603                 // don't reset back to last position, even if new position is stuck in solid
 604                 self.oldorigin = self.origin;
 605
 606                 if(g_arena)
 607                 {
 608                         Spawnqueue_Remove(self);
 609                         Spawnqueue_Mark(self);
 610                 }
 611
 612                 self.event_damage = PlayerDamage;
 613
 614                 self.bot_attack = TRUE;
 615
 616                 self.statdraintime = time + 5;
 617                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 618
 619                 if(self.killcount == -666) {
 620                         self.killcount = 0;
 621                         if(!g_arena)
 622                         if(!g_lms)
 623                                 self.frags = 0;
 624                 }
 625
 626                 self.cnt = WEP_LASER;
 627                 self.nixnex_lastchange_id = -1;
 628
 629                 CL_SpawnWeaponentity();
 630                 self.alpha = default_player_alpha;
 631                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 632                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 633
 634                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 635                 self.lms_traveled_distance = 0;
 636                 self.speedrunning = FALSE;
 637
 638                 if(cvar("spawn_debug"))
 639                 {
 640                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 641                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 642                 }
 643
 644                 //stuffcmd(self, "chase_active 0");
 645                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 646
 647                 if (cvar("g_spawnsound"))
 648                         sound (self, CHAN_AUTO, "misc/spawn.wav", 1, ATTN_NORM);
 649
 650                 if(g_assault) {
 651                         if(self.team == assault_attacker_team)
 652                                 centerprint(self, "You are attacking!\n");
 653                         else
 654                                 centerprint(self, "You are defending!\n");
 655                 }
 656
 657         } else if(self.classname == "observer") {
 658                 PutObserverInServer ();
 659         }
 660 }
 661
 662 /*
 663 =============
 664 SetNewParms
 665 =============
 666 */
 667 void SetNewParms (void)
 668 {
 669
 670 }
 671
 672 /*
 673 =============
 674 SetChangeParms
 675 =============
 676 */
 677 void SetChangeParms (void)
 678 {
 679
 680 }
 681
 682 /*
 683 =============
 684 ClientKill
 685
 686 Called when a client types 'kill' in the console
 687 =============
 688 */
 689
 690 void ClientKill_Now_TeamChange()
 691 {
 692         if(self.killindicator_teamchange == -1)
 693         {
 694                 self.team = -1;
 695                 JoinBestTeam( self, FALSE, FALSE );
 696         }
 697         else
 698         {
 699                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 700         }
 701 }
 702
 703 void ClientKill_Now()
 704 {
 705         if(self.killindicator_teamchange)
 706                 ClientKill_Now_TeamChange();
 707
 708         // in any case:
 709         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 710 }
 711 void KillIndicator_Think()
 712 {
 713         if (!self.owner.modelindex)
 714         {
 715                 self.owner.killindicator = world;
 716                 remove(self);
 717                 return;
 718         }
 719
 720         if(self.cnt <= 0)
 721         {
 722                 self = self.owner;
 723                 ClientKill_Now(); // no oldself needed
 724                 return;
 725         }
 726         else
 727         {
 728                 if(self.cnt <= 10)
 729                 {
 730                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 731                         play2(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 732                 }
 733                 if(self.owner.killindicator_teamchange)
 734                 {
 735                         if(self.owner.killindicator_teamchange == -1)
 736                                 centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 737                         else
 738                                 centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 739                 }
 740                 else
 741                         centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 742                 self.nextthink = time + 1;
 743                 self.cnt -= 1;
 744         }
 745 }
 746
 747 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 748 {
 749         float killtime;
 750         killtime = cvar("g_balance_kill_delay");
 751
 752         self.killindicator_teamchange = targetteam;
 753
 754         if(!self.killindicator)
 755         {
 756                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 757                 {
 758                         ClientKill_Now();
 759                 }
 760                 else
 761                 {
 762                         self.killindicator = spawn();
 763                         self.killindicator.owner = self;
 764                         self.killindicator.scale = 0.5;
 765                         setattachment(self.killindicator, self, "");
 766                         setorigin(self.killindicator, '0 0 52');
 767                         self.killindicator.think = KillIndicator_Think;
 768                         self.killindicator.nextthink = time;
 769                         self.killindicator.cnt = ceil(killtime);
 770                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 771                 }
 772         }
 773         if(self.killindicator)
 774         {
 775                 if(targetteam)
 776                         self.killindicator.colormod = TeamColor(targetteam);
 777                 else
 778                         self.killindicator.colormod = '0 0 0';
 779         }
 780 }
 781
 782 void ClientKill (void)
 783 {
 784         ClientKill_TeamChange(0);
 785 }
 786
 787 void DoTeamChange(float destteam)
 788 {
 789         if(!cvar("teamplay"))
 790         {
 791                 if(destteam >= 0)
 792                         SetPlayerColors(self, destteam);
 793                 return;
 794         }
 795         if(destteam == self.team && !self.killindicator)
 796                 return;
 797         ClientKill_TeamChange(destteam);
 798 }
 799
 800 void FixClientCvars(entity e)
 801 {
 802         float t;
 803         // send prediction settings to the client
 804         stuffcmd(e, "\nin_bindmap 0 0\n");
 805         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
 806         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 807         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 808         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 809         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 810         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 811         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 812         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
 813         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 814         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 815         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 816         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 817         stuffcmd(e, "cl_movement_edgefriction 1\n");
 818
 819         // notify about available teams
 820         if(teamplay)
 821         {
 822                 CheckAllowedTeams(e);
 823                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
 824                 stuffcmd(e, strcat("set _teams_available ", ftos(t), "\n"));
 825         }
 826         else
 827                 stuffcmd(e, "set _teams_available 0\n");
 828 }
 829
 830 /*
 831 =============
 832 ClientConnect
 833
 834 Called when a client connects to the server
 835 =============
 836 */
 837 string ColoredTeamName(float t);
 838 //void dom_player_join_team(entity pl);
 839 void ClientConnect (void)
 840 {
 841         local string s;
 842         float wep;
 843
 844         if(Ban_IsClientBanned(self))
 845         {
 846                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
 847                 dropclient(self);
 848                 bprint(s);
 849                 return;
 850         }
 851
 852         self.classname = "player_joining";
 853         self.flags = self.flags | FL_CLIENT;
 854         self.version_nagtime = time + 10 + random() * 10;
 855
 856         if(player_count<0)
 857         {
 858                 dprint("BUG player count is lower than zero, this cannot happen!\n");
 859                 player_count = 0;
 860         }
 861
 862         bot_clientconnect();
 863
 864         //if(g_domination)
 865         //      dom_player_join_team(self);
 866
 867         //JoinBestTeam(self, FALSE, FALSE);
 868
 869         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
 870                 self.classname = "observer";
 871         } else {
 872                 self.classname = "player";
 873                 campaign_bots_may_start = 1;
 874         }
 875
 876         self.playerid = (playerid_last = playerid_last + 1);
 877         if(cvar("sv_eventlog"))
 878         {
 879                 if(clienttype(self) == CLIENTTYPE_REAL)
 880                         s = "player";
 881                 else
 882                         s = "bot";
 883                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 884                 s = strcat(":team:", ftos(self.playerid), ":");
 885                 s = strcat(s, ftos(self.team));
 886                 GameLogEcho(s, FALSE);
 887         }
 888
 889         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 890
 891         bprint ("^4",self.netname);
 892         bprint ("^4 connected");
 893
 894         if(g_domination || g_ctf)
 895         {
 896                 bprint(" and joined the ");
 897                 bprint(ColoredTeamName(self.team));
 898         }
 899
 900         bprint("\n");
 901
 902         self.welcomemessage_time = 0;
 903
 904         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 905         // TODO: is this being used for anything else than cd tracks?
 906         // Remember: SVC_CDTRACK exists. Maybe it should be used.
 907
 908         FixClientCvars(self);
 909
 910         // waypoint sprites
 911         WaypointSprite_InitClient(self);
 912
 913         // Wazat's grappling hook
 914         SetGrappleHookBindings();
 915
 916         // get autoswitch state from player when he toggles it
 917         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n");
 918
 919         // get version info from player
 920         stuffcmd(self, "cmd clientversion $gameversion\n");
 921
 922         // send all weapon info strings
 923         stuffcmd(self, "register_bestweapon clear\n"); // clear the Quake stuff
 924         wep = WEP_FIRST;
 925         while (wep <= WEP_LAST)
 926         {
 927                 weapon_action(wep, WR_REGISTER);
 928                 wep = wep + 1;
 929         }
 930
 931         // get other cvars from player
 932         GetCvars(0);
 933
 934         // set cvar for team scoreboard
 935         if (teams_matter)
 936         {
 937                 local float t;
 938                 t = cvar("teamplay");
 939                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
 940                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
 941         }
 942         else
 943                 stuffcmd(self, "set teamplay 0\n");
 944
 945         if(g_lms)
 946         {
 947                 self.frags = LMS_NewPlayerLives();
 948                 if(!self.frags)
 949                         self.frags = -666;
 950         }
 951         else if(g_arena)
 952         {
 953                 self.classname = "observer";
 954                 Spawnqueue_Insert(self);
 955         }
 956
 957         bot_relinkplayerlist();
 958
 959         self.jointime = time;
 960 }
 961
 962 /*
 963 =============
 964 ClientDisconnect
 965
 966 Called when a client disconnects from the server
 967 =============
 968 */
 969 void(entity e) DropFlag;
 970 .entity chatbubbleentity;
 971 .entity teambubbleentity;
 972 void ClientDisconnect (void)
 973 {
 974         float save;
 975         if(cvar("sv_eventlog"))
 976                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
 977         bprint ("^4",self.netname);
 978         bprint ("^4 disconnected\n");
 979
 980         if (self.chatbubbleentity)
 981         {
 982                 remove (self.chatbubbleentity);
 983                 self.chatbubbleentity = world;
 984         }
 985
 986         if (self.teambubbleentity)
 987         {
 988                 remove (self.teambubbleentity);
 989                 self.teambubbleentity = world;
 990         }
 991
 992         if (self.killindicator)
 993         {
 994                 remove (self.killindicator);
 995                 self.killindicator = world;
 996         }
 997
 998         WaypointSprite_PlayerGone();
 999
1000         DropAllRunes(self);
1001         kh_Key_DropAll(self, TRUE);
1002
1003         if(self.flagcarried)
1004                 DropFlag(self.flagcarried);
1005
1006         DistributeFragsAmongTeam(self, self.team, 1);
1007
1008         save = self.flags;
1009         self.flags = self.flags - (self.flags & FL_CLIENT);
1010         bot_relinkplayerlist();
1011         self.flags = save;
1012
1013         // remove laserdot
1014         if(self.weaponentity)
1015                 if(self.weaponentity.lasertarget)
1016                         remove(self.weaponentity.lasertarget);
1017
1018         if(g_arena)
1019         {
1020                 Spawnqueue_Unmark(self);
1021                 Spawnqueue_Remove(self);
1022         }
1023
1024         // free cvars
1025         GetCvars(-1);
1026 }
1027
1028 .float buttonchat;
1029 void() ChatBubbleThink =
1030 {
1031         self.nextthink = time;
1032         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1033         {
1034                 self.owner.chatbubbleentity = world;
1035                 remove(self);
1036                 return;
1037         }
1038         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1039         if (self.owner.buttonchat && !self.owner.deadflag)
1040                 self.model = self.mdl;
1041         else
1042                 self.model = "";
1043 };
1044
1045 void() UpdateChatBubble =
1046 {
1047         if (!self.modelindex)
1048                 return;
1049         // spawn a chatbubble entity if needed
1050         if (!self.chatbubbleentity)
1051         {
1052                 self.chatbubbleentity = spawn();
1053                 self.chatbubbleentity.owner = self;
1054                 self.chatbubbleentity.exteriormodeltoclient = self;
1055                 self.chatbubbleentity.think = ChatBubbleThink;
1056                 self.chatbubbleentity.nextthink = time;
1057                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1058                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1059                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1060                 self.chatbubbleentity.model = "";
1061                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1062         }
1063 }
1064
1065
1066 void() TeamBubbleThink =
1067 {
1068         self.nextthink = time;
1069         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1070         {
1071                 self.owner.teambubbleentity = world;
1072                 remove(self);
1073                 return;
1074         }
1075 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1076         if (self.owner.buttonchat || self.owner.deadflag || self.owner.killindicator)
1077                 self.model = "";
1078         else
1079                 self.model = self.mdl;
1080
1081 };
1082
1083 float() TeamBubble_customizeentityforclient
1084 {
1085         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1086 }
1087
1088 void() UpdateTeamBubble =
1089 {
1090         if (!self.modelindex || !cvar("teamplay"))
1091                 return;
1092         // spawn a teambubble entity if needed
1093         if (!self.teambubbleentity && cvar("teamplay"))
1094         {
1095                 self.teambubbleentity = spawn();
1096                 self.teambubbleentity.owner = self;
1097                 self.teambubbleentity.exteriormodeltoclient = self;
1098                 self.teambubbleentity.think = TeamBubbleThink;
1099                 self.teambubbleentity.nextthink = time;
1100                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1101 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1102                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1103                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1104                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1105                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1106                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1107                 self.teambubbleentity.effects = EF_LOWPRECISION;
1108         }
1109 }
1110
1111 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1112 // added to the model skins
1113 /*void() UpdateColorModHack =
1114 {
1115         local float c;
1116         c = self.clientcolors & 15;
1117         // LordHavoc: only bothering to support white, green, red, yellow, blue
1118              if (teamplay == 0) self.colormod = '0 0 0';
1119         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1120         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1121         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1122         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1123         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1124         else self.colormod = '1 1 1';
1125 };*/
1126
1127 void respawn(void)
1128 {
1129         CopyBody(1);
1130         self.effects |= EF_NODRAW; // prevent another CopyBody
1131         PutClientInServer();
1132 }
1133
1134 void player_powerups (void)
1135 {
1136         if (g_minstagib)
1137         {
1138                 if (self.items & IT_STRENGTH)
1139                 {
1140                         if (time > self.strength_finished)
1141                         {
1142                                 if (g_minstagib_invis_alpha > 0)
1143                                 {
1144                                         self.alpha = default_player_alpha;
1145                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1146                                         self.effects = self.effects | EF_FULLBRIGHT;
1147                                 }
1148                                 else
1149                                 {
1150                                         self.effects -= self.effects & EF_NODRAW;
1151                                 }
1152                                 self.items = self.items - (self.items & IT_STRENGTH);
1153                                 sprint(self, "^3Invisibility has worn off\n");
1154                         }
1155                 }
1156                 else
1157                 {
1158                         if (time < self.strength_finished)
1159                         {
1160                                 if (g_minstagib_invis_alpha > 0)
1161                                 {
1162                                         self.alpha = g_minstagib_invis_alpha;
1163                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1164                                         self.effects -= self.effects & EF_FULLBRIGHT;
1165                                 }
1166                                 else
1167                                 {
1168                                         self.effects = self.effects | EF_NODRAW;
1169                                 }
1170                                 self.items = self.items | IT_STRENGTH;
1171                                 sprint(self, "^3You are invisible\n");
1172                         }
1173                 }
1174
1175                 if (self.items & IT_INVINCIBLE)
1176                 {
1177                         if (time > self.invincible_finished)
1178                         {
1179                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1180                                 sprint(self, "^3Speed has worn off\n");
1181                         }
1182                 }
1183                 else
1184                 {
1185                         if (time < self.invincible_finished)
1186                         {
1187                                 self.items = self.items | IT_INVINCIBLE;
1188                                 sprint(self, "^3You are on speed\n");
1189                         }
1190                 }
1191                 return;
1192         }
1193
1194         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1195         if (self.items & IT_STRENGTH)
1196         {
1197                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1198                 if (time > self.strength_finished)
1199                 {
1200                         self.items = self.items - (self.items & IT_STRENGTH);
1201                         sprint(self, "^3Strength has worn off\n");
1202                 }
1203         }
1204         else
1205         {
1206                 if (time < self.strength_finished)
1207                 {
1208                         self.items = self.items | IT_STRENGTH;
1209                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1210                 }
1211         }
1212         if (self.items & IT_INVINCIBLE)
1213         {
1214                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1215                 if (time > self.invincible_finished)
1216                 {
1217                         self.items = self.items - (self.items & IT_INVINCIBLE);
1218                         sprint(self, "^3Shield has worn off\n");
1219                 }
1220         }
1221         else
1222         {
1223                 if (time < self.invincible_finished)
1224                 {
1225                         self.items = self.items | IT_INVINCIBLE;
1226                         sprint(self, "^3Shield surrounds you\n");
1227                 }
1228         }
1229
1230         if (cvar("g_fullbrightplayers"))
1231                 self.effects = self.effects | EF_FULLBRIGHT;
1232
1233         // midair gamemode: damage only while in the air
1234         // if in midair mode, being on ground grants temporary invulnerability
1235         // (this is so that multishot weapon don't clear the ground flag on the
1236         // first damage in the frame, leaving the player vulnerable to the
1237         // remaining hits in the same frame)
1238         if (self.flags & FL_ONGROUND)
1239         if (g_midair)
1240                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1241
1242         if (time < self.spawnshieldtime)
1243                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1244 }
1245
1246 float CalcRegen(float current, float stable, float regenfactor)
1247 {
1248         if(current > stable)
1249                 return current;
1250         else if(current > stable - 0.25) // when close enough, "snap"
1251                 return stable;
1252         else
1253                 return min(stable, current + (stable - current) * regenfactor * frametime);
1254 }
1255
1256 void player_regen (void)
1257 {
1258         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1259         maxh = cvar("g_balance_health_stable");
1260         maxa = cvar("g_balance_armor_stable");
1261         limith = cvar("g_balance_health_limit");
1262         limita = cvar("g_balance_armor_limit");
1263
1264         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1265                 return;
1266
1267         max_mod = regen_mod = rot_mod = limit_mod = 1;
1268
1269         if (self.runes & RUNE_REGEN)
1270         {
1271                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1272                 {
1273                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1274                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1275                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1276                 }
1277                 else
1278                 {
1279                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1280                         max_mod = cvar("g_balance_rune_regen_hpmod");
1281                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1282                 }
1283         }
1284         else if (self.runes & CURSE_VENOM)
1285         {
1286                 max_mod = cvar("g_balance_curse_venom_hpmod");
1287                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1288                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1289                 else
1290                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1291                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1292                 //if (!self.runes & RUNE_REGEN)
1293                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1294         }
1295         maxh = maxh * max_mod;
1296         //maxa = maxa * max_mod;
1297         limith = limith * limit_mod;
1298         limita = limita * limit_mod;
1299
1300         if (self.armorvalue > maxa)
1301         {
1302                 if (time > self.pauserotarmor_finished)
1303                 {
1304                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1305                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1306                 }
1307         }
1308         else if (self.armorvalue < maxa)
1309         {
1310                 if (time > self.pauseregen_finished)
1311                 {
1312                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1313                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1314                 }
1315         }
1316         if (self.health > maxh)
1317         {
1318                 if (time > self.pauserothealth_finished)
1319                 {
1320                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1321                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1322                 }
1323         }
1324         else if (self.health < maxh)
1325         {
1326                 if (time > self.pauseregen_finished)
1327                 {
1328                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1329                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1330                 }
1331         }
1332
1333         if (self.health > limith)
1334                 self.health = limith;
1335         if (self.armorvalue > limita)
1336                 self.armorvalue = limita;
1337
1338         // if player rotted to death...  die!
1339         if(self.health < 1)
1340                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1341 }
1342
1343 /*
1344 ======================
1345 spectate mode routines
1346 ======================
1347 */
1348 void SpectateCopy(entity spectatee) {
1349         self.armortype = spectatee.armortype;
1350         self.armorvalue = spectatee.armorvalue;
1351         self.currentammo = spectatee.currentammo;
1352         self.effects = spectatee.effects;
1353         self.health = spectatee.health;
1354         self.impulse = 0;
1355         self.items = spectatee.items;
1356         self.punchangle = spectatee.punchangle;
1357         self.view_ofs = spectatee.view_ofs;
1358         self.v_angle = spectatee.v_angle;
1359         self.viewzoom = spectatee.viewzoom;
1360         self.velocity = spectatee.velocity;
1361         self.dmg_take = spectatee.dmg_take;
1362         self.dmg_save = spectatee.dmg_save;
1363         self.dmg_inflictor = spectatee.dmg_inflictor;
1364         self.angles = spectatee.v_angle;
1365         self.fixangle = TRUE;
1366         setorigin(self, spectatee.origin);
1367         setsize(self, spectatee.mins, spectatee.maxs);
1368 }
1369
1370 void SpectateUpdate() {
1371         if(!self.enemy)
1372                         PutObserverInServer();
1373
1374         if (self != self.enemy) {
1375                 if(self.enemy.flags & FL_NOTARGET)
1376                         PutObserverInServer();
1377                 SpectateCopy(self.enemy);
1378                 //msg_entity = self;
1379                 //WriteByte(MSG_ONE, SVC_SETANGLE);
1380                 //WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1381                 //WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1382                 //WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1383         }
1384 }
1385
1386 float SpectateNext() {
1387         other = find(self.enemy, classname, "player");
1388         if (!other) {
1389                 other = find(other, classname, "player");
1390         }
1391         if (other) {
1392                 self.enemy = other;
1393         }
1394         if(self.enemy.classname == "player") {
1395                 msg_entity = self;
1396                 WriteByte(MSG_ONE, SVC_SETVIEW);
1397                 WriteEntity(MSG_ONE, self.enemy);
1398                 self.wantswelcomemessage = 1;
1399                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1400                 SpectateUpdate();
1401                 return 1;
1402         } else {
1403                 return 0;
1404         }
1405 }
1406
1407 /*
1408 =============
1409 ShowRespawnCountdown()
1410
1411 Update a respawn countdown display.
1412 =============
1413 */
1414 void ShowRespawnCountdown()
1415 {
1416         float number;
1417         if(self.deadflag == DEAD_NO) // just respawned?
1418                 return;
1419         else
1420         {
1421                 number = ceil(self.death_time - time);
1422                 if(number <= 0)
1423                         return;
1424                 if(number <= self.respawn_countdown)
1425                 {
1426                         self.respawn_countdown = number - 1;
1427                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1428                                 play2(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1429                 }
1430         }
1431 }
1432
1433 void LeaveSpectatorMode()
1434 {
1435         if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1436                 self.classname = "player";
1437                 if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1438                         JoinBestTeam(self, FALSE, TRUE);
1439                 if(cvar("g_campaign"))
1440                         campaign_bots_may_start = 1;
1441                 PutClientInServer();
1442                 if(!(self.flags & FL_NOTARGET))
1443                         bprint ("^4", self.netname, "^4 is playing now\n");
1444                 centerprint(self,"");
1445                 return;
1446         } else {
1447                 stuffcmd(self,"menu_showteamselect\n");
1448                 return;
1449         }
1450 }
1451
1452 /*
1453 =============
1454 PlayerPreThink
1455
1456 Called every frame for each client before the physics are run
1457 =============
1458 */
1459 void() ctf_setstatus;
1460 .float vote_nagtime;
1461 void PlayerPreThink (void)
1462 {
1463         // version nagging
1464         if(self.version_nagtime)
1465                 if(self.cvar_g_nexuizversion)
1466                         if(time > self.version_nagtime)
1467                         {
1468                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1469                                         if(self.cvar_g_nexuizversion != cvar_string("g_nexuizversion"))
1470                                         {
1471                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n");
1472                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n"));
1473                                         }
1474                                 self.version_nagtime = 0;
1475                         }
1476
1477         // vote nagging
1478         if(self.cvar_scr_centertime)
1479                 if(time > self.vote_nagtime)
1480                 {
1481                         VoteNag();
1482                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1483                 }
1484
1485         // GOD MODE info
1486         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
1487         {
1488                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
1489                 self.max_armorvalue = 0;
1490         }
1491
1492         if(frametime)
1493                 antilag_record(self);
1494
1495         if(self.classname == "player") {
1496 //              if(self.netname == "Wazat")
1497 //                      bprint(self.classname, "\n");
1498
1499                 CheckRules_Player();
1500
1501                 if(self.button7)
1502                         PrintWelcomeMessage(self);
1503
1504                 if(g_lms || !cvar("sv_spectate"))
1505                 if((time - self.jointime) <= cvar("welcome_message_time"))
1506                         PrintWelcomeMessage(self);
1507
1508                 if (intermission_running)
1509                 {
1510                         IntermissionThink ();   // otherwise a button could be missed between
1511                         return;                                 // the think tics
1512                 }
1513
1514                 if(self.teleport_time)
1515                 if(time > self.teleport_time)
1516                 {
1517                         self.teleport_time = 0;
1518                         self.effects = self.effects - (self.effects & EF_NODRAW);
1519                         if(self.weaponentity)
1520                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
1521                 }
1522
1523                 Nixnex_GiveCurrentWeapon();
1524
1525                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
1526                         UpdateSelectedPlayer();
1527
1528                 if (self.deadflag != DEAD_NO)
1529                 {
1530                         float button_pressed, force_respawn;
1531                         player_anim();
1532                         button_pressed = (self.button0 || self.button2 || self.button3 || self.button6 || self.buttonuse);
1533                         force_respawn = (g_lms || cvar("g_forced_respawn"));
1534                         if (self.deadflag == DEAD_DYING)
1535                         {
1536                                 if(force_respawn)
1537                                         self.deadflag = DEAD_RESPAWNING;
1538                                 else if(!button_pressed)
1539                                         self.deadflag = DEAD_DEAD;
1540                         }
1541                         else if (self.deadflag == DEAD_DEAD)
1542                         {
1543                                 if(button_pressed)
1544                                         self.deadflag = DEAD_RESPAWNABLE;
1545                         }
1546                         else if (self.deadflag == DEAD_RESPAWNABLE)
1547                         {
1548                                 if(!button_pressed)
1549                                         self.deadflag = DEAD_RESPAWNING;
1550                         }
1551                         else if (self.deadflag == DEAD_RESPAWNING)
1552                         {
1553                                 if(time > self.death_time)
1554                                 {
1555                                         self.death_time = time + 1; // only retry once a second
1556                                         respawn();
1557                                 }
1558                         }
1559                         ShowRespawnCountdown();
1560                         return;
1561                 }
1562
1563                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
1564                 {
1565                         vector dist;
1566
1567                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1568                         dist = self.oldorigin - self.origin;
1569                         dist_z = 0;
1570                         self.lms_traveled_distance += fabs(vlen(dist));
1571
1572                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
1573                         {
1574                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1575                                 self.lms_traveled_distance = 0;
1576                         }
1577
1578                         if(time > self.lms_nextcheck)
1579                         {
1580                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1581                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1582                                 {
1583                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1584                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1585                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1586                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1587                                 }
1588                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1589                                 self.lms_traveled_distance = 0;
1590                         }
1591                 }
1592
1593                 if (self.button5 && !self.hook.state)
1594                 {
1595                         if (!self.crouch)
1596                         {
1597                                 self.crouch = TRUE;
1598                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1599                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1600                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
1601                         }
1602                 }
1603                 else
1604                 {
1605                         if (self.crouch)
1606                         {
1607                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1608                                 if (!trace_startsolid)
1609                                 {
1610                                         self.crouch = FALSE;
1611                                         self.view_ofs = PL_VIEW_OFS;
1612                                         setsize (self, PL_MIN, PL_MAX);
1613                                 }
1614                         }
1615                 }
1616
1617                 FixPlayermodel();
1618
1619                 GrapplingHookFrame();
1620
1621                 W_WeaponFrame();
1622
1623                 {
1624                         float zoomfactor, zoomspeed, zoomdir;
1625                         zoomfactor = self.cvar_cl_zoomfactor;
1626                         if(zoomfactor < 1 || zoomfactor > 16)
1627                                 zoomfactor = 2.5;
1628                         zoomspeed = self.cvar_cl_zoomspeed;
1629                         if(zoomspeed >= 0) // < 0 is instant zoom
1630                                 if(zoomspeed < 0.5 || zoomspeed > 16)
1631                                         zoomspeed = 3.5;
1632
1633                         zoomdir = self.button4;
1634                         if(self.button3)
1635                                 if(self.weapon == WEP_NEX)
1636                                         if(!g_minstagib)
1637                                                 zoomdir = 1;
1638
1639                         if(zoomdir)
1640                                 self.has_zoomed = 1;
1641
1642                         if(self.has_zoomed)
1643                         {
1644                                 if(zoomspeed <= 0) // instant zoom
1645                                 {
1646                                         if(zoomdir)
1647                                                 self.viewzoom = 1 / zoomfactor;
1648                                         else
1649                                                 self.viewzoom = 1;
1650                                 }
1651                                 else
1652                                 {
1653                                         // geometric zoom would be:
1654                                         //   self.viewzoom = bound(1 / zoomfactor, self.viewzoom * pow(zoomfactor, (zoomdir ? -1 : 1) * frametime * zoomspeed), 1);
1655                                         // however, testing showed that arithmetic/harmonic zoom works better
1656                                         if(zoomdir)
1657                                                 // self.viewzoom = 1 / bound(1, 1 / self.viewzoom + (zoomdir ? 1 : -1) * frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
1658                                                 // zoom in = arithmetic: 1x, 2x, 3x, 4x, ..., 8x
1659                                                 self.viewzoom = 1 / bound(1, 1 / self.viewzoom + frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
1660                                         else
1661                                                 // self.viewzoom = bound(1 / zoomfactor, self.viewzoom + (zoomdir ? -1 : 1) * frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
1662                                                 // zoom out = harmonic: 8/1x, 8/2x, 8/3x, 8/4x, ..., 8/8x
1663                                                 self.viewzoom = bound(1 / zoomfactor, self.viewzoom + frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
1664                                 }
1665                         }
1666                         else
1667                                 self.viewzoom = min(1, self.viewzoom + frametime); // spawn zoom-in
1668                 }
1669
1670                 player_powerups();
1671                 player_regen();
1672                 player_anim();
1673
1674                 if (g_minstagib)
1675                         minstagib_ammocheck();
1676
1677                 ctf_setstatus();
1678                 kh_setstatus();
1679
1680                 //self.angles_y=self.v_angle_y + 90;   // temp
1681
1682                 //if (TetrisPreFrame()) return;
1683         } else if(gameover) {
1684                 if (intermission_running)
1685                         IntermissionThink ();   // otherwise a button could be missed between
1686                 return;
1687         } else if(self.classname == "observer") {
1688                 if (self.flags & FL_JUMPRELEASED) {
1689                         if (self.button2 && self.version == cvar("gameversion")) {
1690                                 self.welcomemessage_time = 0;
1691                                 self.flags = self.flags - FL_JUMPRELEASED;
1692                                 LeaveSpectatorMode();
1693                                 return;
1694                         } else if(self.button0 && self.version == cvar("gameversion")) {
1695                                 self.welcomemessage_time = 0;
1696                                 self.flags = self.flags - FL_JUMPRELEASED;
1697                                 if(SpectateNext() == 1) {
1698                                         self.classname = "spectator";
1699                                 }
1700                         }
1701                 } else {
1702                         if (!(self.button0 || self.button2)) {
1703                                 self.flags = self.flags | FL_JUMPRELEASED;
1704                         }
1705                 }
1706                 if(self.button4)
1707                         self.wantswelcomemessage = 0;
1708                 if(self.wantswelcomemessage)
1709                         PrintWelcomeMessage(self);
1710         } else if(self.classname == "spectator") {
1711                 if (self.flags & FL_JUMPRELEASED) {
1712                         if (self.button2 && self.version == cvar("gameversion")) {
1713                                 self.welcomemessage_time = 0;
1714                                 self.flags = self.flags - FL_JUMPRELEASED;
1715                                 LeaveSpectatorMode();
1716                                 return;
1717                         } else if(self.button0) {
1718                                 self.welcomemessage_time = 0;
1719                                 self.flags = self.flags - FL_JUMPRELEASED;
1720                                 if(SpectateNext() == 1) {
1721                                         self.classname = "spectator";
1722                                 } else {
1723                                         self.classname = "observer";
1724                                         PutClientInServer();
1725                                 }
1726                         } else if (self.button3) {
1727                                 self.welcomemessage_time = 0;
1728                                 self.flags = self.flags - FL_JUMPRELEASED;
1729                                 self.classname = "observer";
1730                                 PutClientInServer();
1731                         } else {
1732                                 SpectateUpdate();
1733                         }
1734                 } else {
1735                         if (!(self.button0 || self.button3)) {
1736                                 self.flags = self.flags | FL_JUMPRELEASED;
1737                         }
1738                 }
1739                 if(self.button4)
1740                         self.wantswelcomemessage = 0;
1741                 if(self.wantswelcomemessage)
1742                         PrintWelcomeMessage(self);
1743                 self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1744         }
1745 }
1746
1747
1748 /*
1749 =============
1750 PlayerPostThink
1751
1752 Called every frame for each client after the physics are run
1753 =============
1754 */
1755 void PlayerPostThink (void)
1756 {
1757         // Savage: Check for nameless players
1758         if (strlen(self.netname) < 1) {
1759                 self.netname = "Player";
1760                 stuffcmd(self, "seta _cl_name Player\n");
1761         }
1762
1763         if(self.classname == "player") {
1764                 CheckRules_Player();
1765                 UpdateChatBubble();
1766                 UpdateTeamBubble();
1767                 if (self.impulse)
1768                         ImpulseCommands();
1769                 if (intermission_running)
1770                         return;         // intermission or finale
1771
1772                 //PrintWelcomeMessage(self);
1773                 //if (TetrisPostFrame()) return;
1774
1775                 // restart countdown
1776                 if(time < restart_countdown)
1777                 {
1778                         string s;
1779                         float sec;
1780
1781                         sec = ceil(restart_countdown-time);
1782                         s = strcat(NEWLINES, "^1Game starts in ", ftos(sec), " seconds");
1783                         centerprint(self, s);
1784                         self.movetype = MOVETYPE_NONE;
1785                         self.velocity = '0 0 0';
1786                         self.avelocity = '0 0 0';
1787                         self.movement = '0 0 0';
1788                 }
1789                 else if(self.movetype == MOVETYPE_NONE)
1790                 {
1791                         self.movetype = MOVETYPE_WALK;
1792                         centerprint(self, "\n");
1793                 }
1794         } else if (self.classname == "observer") {
1795                 //do nothing
1796         } else if (self.classname == "spectator") {
1797                 //do nothing
1798         }
1799
1800         Arena_Warmup();
1801 }