data/qcsrc/server/cl_client.qc

   1 .float spectatee_status;
   2 .float zoomstate;
   3 .float bloodloss_timer;
   4
   5 .entity clientdata;
   6 float ClientData_Send(entity to, float sf)
   7 {
   8         if(to != self.owner)
   9         {
  10                 error("wtf");
  11                 return FALSE;
  12         }
  13
  14         entity e;
  15
  16         e = to;
  17         if(to.classname == "spectator")
  18                 e = to.enemy;
  19
  20         sf = 0;
  21
  22         if(e.race_completed)
  23                 sf |= 1; // forced scoreboard
  24         if(to.spectatee_status)
  25                 sf |= 2; // spectator ent number follows
  26         if(e.zoomstate)
  27                 sf |= 4; // zoomed
  28         if(e.porto_v_angle_held)
  29                 sf |= 8; // angles held
  30
  31         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  32         WriteByte(MSG_ENTITY, sf);
  33
  34         if(sf & 2)
  35                 WriteByte(MSG_ENTITY, to.spectatee_status);
  36
  37         if(sf & 8)
  38         {
  39                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  40                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  41         }
  42
  43         return TRUE;
  44 }
  45
  46 void ClientData_Attach()
  47 {
  48         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  49         self.clientdata.drawonlytoclient = self;
  50         self.clientdata.owner = self;
  51 }
  52
  53 void ClientData_Detach()
  54 {
  55         remove(self.clientdata);
  56         self.clientdata = world;
  57 }
  58
  59 void ClientData_Touch(entity e)
  60 {
  61         e.clientdata.SendFlags = 1;
  62
  63         // make it spectatable
  64         entity e2;
  65         FOR_EACH_REALCLIENT(e2)
  66         {
  67                 if(e2 != e)
  68                         if(e2.classname == "spectator")
  69                                 if(e2.enemy == e)
  70                                         e2.clientdata.SendFlags = 1;
  71         }
  72 }
  73
  74
  75 #define SPAWNPOINT_SCORE frags
  76
  77 .string netname_previous;
  78
  79 void spawnfunc_info_player_survivor (void)
  80 {
  81         spawnfunc_info_player_deathmatch();
  82 }
  83
  84 void spawnfunc_info_player_start (void)
  85 {
  86         spawnfunc_info_player_deathmatch();
  87 }
  88
  89 void spawnfunc_info_player_deathmatch (void)
  90 {
  91         self.classname = "info_player_deathmatch";
  92         relocate_spawnpoint();
  93 }
  94
  95 void spawnpoint_use()
  96 {
  97         if(teams_matter)
  98         if(have_team_spawns)
  99         {
 100                 self.team = activator.team;
 101                 some_spawn_has_been_used = 1;
 102         }
 103 };
 104
 105 // Returns:
 106 //   -1 if a spawn can't be used
 107 //   otherwise, a weight of the spawnpoint
 108 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
 109 {
 110         float shortest, thisdist;
 111         entity player;
 112
 113         // filter out spots for the wrong team
 114         if(teamcheck)
 115         if(spot.team != teamcheck)
 116                 return -1;
 117
 118         if(race_spawns)
 119                 if(spot.target == "")
 120                         return -1;
 121
 122         // filter out spots for assault
 123         if(spot.target != "") {
 124                 local entity ent;
 125                 float good, found;
 126                 ent = find(world, targetname, spot.target);
 127                 while(ent) {
 128                         if(ent.classname == "target_objective")
 129                         {
 130                                 found = 1;
 131                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 132                                         return -1;
 133                                 good = 1;
 134                         }
 135                         else if(ent.classname == "trigger_race_checkpoint")
 136                         {
 137                                 found = 1;
 138                                 if(self.classname == "player") // spectators may spawn everywhere
 139                                 {
 140                                         if(g_race_qualifying)
 141                                         {
 142                                                 // spawn at first
 143                                                 if(ent.race_checkpoint != 0)
 144                                                         return -1;
 145                                                 if(spot.race_place != race_lowest_place_spawn)
 146                                                         return -1;
 147                                         }
 148                                         else
 149                                         {
 150                                                 if(ent.race_checkpoint != race_PreviousCheckpoint(self.race_checkpoint))
 151                                                         return -1;
 152                                                 float pl;
 153                                                 pl = self.race_place;
 154                                                 if(pl > race_highest_place_spawn)
 155                                                         pl = 0;
 156                                                 if(spot.race_place != pl)
 157                                                         return -1;
 158                                         }
 159                                 }
 160                                 good = 1;
 161                         }
 162                         ent = find(ent, targetname, spot.target);
 163                 }
 164
 165                 if(found && !good)
 166                         return -1;
 167         }
 168
 169         player = playerlist;
 170         shortest = vlen(world.maxs - world.mins);
 171         for(player = playerlist; player; player = player.chain)
 172                 if (player != self)
 173                 {
 174                         thisdist = vlen(player.origin - spot.origin);
 175                         if (thisdist < shortest)
 176                                 shortest = thisdist;
 177                 }
 178         return shortest;
 179 }
 180
 181 float spawn_allbad;
 182 float spawn_allgood;
 183 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
 184 {
 185         local entity spot, spotlist, spotlistend;
 186         spawn_allgood = TRUE;
 187         spawn_allbad = TRUE;
 188
 189         spotlist = world;
 190         spotlistend = world;
 191
 192         for(spot = firstspot; spot; spot = spot.chain)
 193         {
 194                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
 195
 196                 if(cvar("spawn_debugview"))
 197                 {
 198                         setmodel(spot, "models/runematch/rune.mdl");
 199                         if(spot.SPAWNPOINT_SCORE < mindist)
 200                         {
 201                                 spot.colormod = '1 0 0';
 202                                 spot.scale = 1;
 203                         }
 204                         else
 205                         {
 206                                 spot.colormod = '0 1 0';
 207                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
 208                         }
 209                 }
 210
 211                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 212                 {
 213                         if(spot.SPAWNPOINT_SCORE < mindist)
 214                         {
 215                                 // too short distance
 216                                 spawn_allgood = FALSE;
 217                         }
 218                         else
 219                         {
 220                                 // perfect
 221                                 spawn_allbad = FALSE;
 222
 223                                 if(spotlistend)
 224                                         spotlistend.chain = spot;
 225                                 spotlistend = spot;
 226                                 if(!spotlist)
 227                                         spotlist = spot;
 228
 229                                 /*
 230                                 if(teamcheck)
 231                                 if(spot.team != teamcheck)
 232                                         error("invalid spawn added");
 233
 234                                 print("added ", etos(spot), "\n");
 235                                 */
 236                         }
 237                 }
 238         }
 239         if(spotlistend)
 240                 spotlistend.chain = world;
 241
 242         /*
 243                 entity e;
 244                 if(teamcheck)
 245                         for(e = spotlist; e; e = e.chain)
 246                         {
 247                                 print("seen ", etos(e), "\n");
 248                                 if(e.team != teamcheck)
 249                                         error("invalid spawn found");
 250                         }
 251         */
 252
 253         return spotlist;
 254 }
 255
 256 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 257 {
 258         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 259         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 260         local entity spot;
 261
 262         RandomSelection_Init();
 263         for(spot = firstspot; spot; spot = spot.chain)
 264                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 265
 266         return RandomSelection_chosen_ent;
 267 }
 268
 269 /*
 270 =============
 271 SelectSpawnPoint
 272
 273 Finds a point to respawn
 274 =============
 275 */
 276 entity SelectSpawnPoint (float anypoint)
 277 {
 278         local float teamcheck;
 279         local entity firstspot_new;
 280         local entity spot, firstspot, playerlist;
 281
 282         spot = find (world, classname, "testplayerstart");
 283         if (spot)
 284                 return spot;
 285
 286         teamcheck = 0;
 287
 288         if(!anypoint && have_team_spawns)
 289                 teamcheck = self.team;
 290
 291         // get the list of players
 292         playerlist = findchain(classname, "player");
 293         // get the entire list of spots
 294         firstspot = findchain(classname, "info_player_deathmatch");
 295         // filter out the bad ones
 296         // (note this returns the original list if none survived)
 297         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 298         if(!firstspot_new)
 299                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 300         firstspot = firstspot_new;
 301
 302         // there is 50/50 chance of choosing a random spot or the furthest spot
 303         // (this means that roughly every other spawn will be furthest, so you
 304         // usually won't get fragged at spawn twice in a row)
 305         if (arena_roundbased)
 306         {
 307                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 308                 if(firstspot_new)
 309                         firstspot = firstspot_new;
 310                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 311         }
 312         else if (random() > cvar("g_spawn_furthest"))
 313                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 314         else
 315                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 316
 317         if(cvar("spawn_debugview"))
 318         {
 319                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 320
 321                 entity e;
 322                 if(teamcheck)
 323                         for(e = firstspot; e; e = e.chain)
 324                                 if(e.team != teamcheck)
 325                                         error("invalid spawn found");
 326         }
 327
 328         if (!spot)
 329         {
 330                 if(cvar("spawn_debug"))
 331                         GotoNextMap();
 332                 else
 333                 {
 334                         if(some_spawn_has_been_used)
 335                                 return world; // team can't spawn any more, because of actions of other team
 336                         else
 337                                 error("Cannot find a spawn point - please fix the map!");
 338                 }
 339         }
 340
 341         return spot;
 342 }
 343
 344 /*
 345 =============
 346 CheckPlayerModel
 347
 348 Checks if the argument string can be a valid playermodel.
 349 Returns a valid one in doubt.
 350 =============
 351 */
 352 string FallbackPlayerModel = "models/player/marine.zym";
 353 string CheckPlayerModel(string plyermodel) {
 354         if(strlen(plyermodel) < 4)
 355                 return FallbackPlayerModel;
 356         if( substring(plyermodel,0,14) != "models/player/")
 357                 return FallbackPlayerModel;
 358         else if(cvar("sv_servermodelsonly"))
 359         {
 360                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 361                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 362                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 363                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 364                         return FallbackPlayerModel;
 365                 if(plyermodel != strtolower(plyermodel))
 366                         return FallbackPlayerModel;
 367                 if(!fexists(plyermodel))
 368                         return FallbackPlayerModel;
 369         }
 370         return plyermodel;
 371 }
 372
 373 /*
 374 =============
 375 Client_customizeentityforclient
 376
 377 LOD reduction
 378 =============
 379 */
 380 float Client_customizeentityforclient()
 381 {
 382 #ifdef ALLOW_VARIABLE_LOD
 383         // self: me
 384         // other: the player viewing me
 385         float distance;
 386         float f;
 387
 388         if(self.classname != "player")
 389                 return TRUE;
 390
 391         if(other.cvar_cl_playerdetailreduction <= 0)
 392         {
 393                 if(other.cvar_cl_playerdetailreduction <= -2)
 394                         self.modelindex = self.modelindex_lod2;
 395                 else if(other.cvar_cl_playerdetailreduction <= -1)
 396                         self.modelindex = self.modelindex_lod1;
 397                 else
 398                         self.modelindex = self.modelindex_lod0;
 399         }
 400         else
 401         {
 402                 distance = vlen(self.origin - other.origin);
 403                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 404                 if(f > 10000)
 405                         self.modelindex = self.modelindex_lod2;
 406                 else if(f > 5000)
 407                         self.modelindex = self.modelindex_lod1;
 408                 else
 409                         self.modelindex = self.modelindex_lod0;
 410         }
 411 #endif
 412
 413         return TRUE;
 414 }
 415
 416 void UpdatePlayerSounds();
 417 void setmodel_lod(entity e, string modelname)
 418 {
 419 #ifdef ALLOW_VARIABLE_LOD
 420         string s;
 421
 422         // FIXME: this only supports 3-letter extensions
 423         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 424         if(fexists(s))
 425         {
 426                 precache_model(s);
 427                 setmodel(e, s); // players have high precision
 428                 self.modelindex_lod1 = self.modelindex;
 429         }
 430         else
 431                 self.modelindex_lod1 = -1;
 432
 433         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 434         if(fexists(s))
 435         {
 436                 precache_model(s);
 437                 setmodel(e, s); // players have high precision
 438                 self.modelindex_lod2 = self.modelindex;
 439         }
 440         else
 441                 self.modelindex_lod2 = -1;
 442
 443         precache_model(modelname);
 444         setmodel(e, modelname); // players have high precision
 445         self.modelindex_lod0 = self.modelindex;
 446
 447         if(self.modelindex_lod1 < 0)
 448                 self.modelindex_lod1 = self.modelindex;
 449
 450         if(self.modelindex_lod2 < 0)
 451                 self.modelindex_lod2 = self.modelindex;
 452 #else
 453         precache_model(modelname);
 454         setmodel(e, modelname); // players have high precision
 455 #endif
 456         player_setupanimsformodel();
 457         UpdatePlayerSounds();
 458 }
 459
 460 /*
 461 =============
 462 PutObserverInServer
 463
 464 putting a client as observer in the server
 465 =============
 466 */
 467 void PutObserverInServer (void)
 468 {
 469         entity  spot;
 470
 471         race_PreSpawnObserver();
 472
 473         spot = SelectSpawnPoint (TRUE);
 474         if(!spot)
 475                 error("No spawnpoints for observers?!?\n");
 476         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 477
 478         if(clienttype(self) == CLIENTTYPE_REAL)
 479         {
 480                 msg_entity = self;
 481                 WriteByte(MSG_ONE, SVC_SETVIEW);
 482                 WriteEntity(MSG_ONE, self);
 483         }
 484
 485         DropAllRunes(self);
 486         kh_Key_DropAll(self, TRUE);
 487
 488         Portal_ClearAll(self);
 489
 490         if(self.flagcarried)
 491                 DropFlag(self.flagcarried, world, world);
 492         if(self.ballcarried)
 493                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 494
 495         WaypointSprite_PlayerDead();
 496
 497         if(self.killcount != -666)
 498         {
 499                 if(g_lms)
 500                 {
 501                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 502                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 503                         else
 504                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 505                 }
 506                 else
 507                         bprint ("^4", self.netname, "^4 is spectating now\n");
 508         }
 509
 510         PlayerScore_Clear(self); // clear scores when needed
 511
 512         self.spectatortime = time;
 513
 514         self.classname = "observer";
 515         self.iscreature = FALSE;
 516         self.health = -666;
 517         self.takedamage = DAMAGE_NO;
 518         self.solid = SOLID_NOT;
 519         self.movetype = MOVETYPE_NOCLIP;
 520         self.flags = FL_CLIENT | FL_NOTARGET;
 521         self.armorvalue = 666;
 522         self.effects = 0;
 523         self.armorvalue = cvar("g_balance_armor_start");
 524         self.pauserotarmor_finished = 0;
 525         self.pauserothealth_finished = 0;
 526         self.pauseregen_finished = 0;
 527         self.damageforcescale = 0;
 528         self.death_time = 0;
 529         self.dead_frame = 0;
 530         self.alpha = 0;
 531         self.scale = 0;
 532         self.fade_time = 0;
 533         self.pain_frame = 0;
 534         self.pain_finished = 0;
 535         self.strength_finished = 0;
 536         self.invincible_finished = 0;
 537         self.pushltime = 0;
 538         self.think = SUB_Null;
 539         self.nextthink = 0;
 540         self.hook_time = 0;
 541         self.runes = 0;
 542         self.deadflag = DEAD_NO;
 543         self.angles = spot.angles;
 544         self.angles_z = 0;
 545         self.fixangle = TRUE;
 546         self.crouch = FALSE;
 547
 548         self.view_ofs = PL_VIEW_OFS;
 549         setorigin (self, spot.origin);
 550         setsize (self, '0 0 0', '0 0 0');
 551         self.prevorigin = self.origin;
 552         self.items = 0;
 553         self.weapons = 0;
 554         self.model = "";
 555         self.modelindex = 0;
 556         self.weapon = 0;
 557         self.weaponmodel = "";
 558         self.weaponentity = world;
 559         self.exteriorweaponentity = world;
 560         self.killcount = -666;
 561         self.velocity = '0 0 0';
 562         self.avelocity = '0 0 0';
 563         self.punchangle = '0 0 0';
 564         self.punchvector = '0 0 0';
 565         self.oldvelocity = self.velocity;
 566         self.customizeentityforclient = Client_customizeentityforclient;
 567
 568         self.team = -1;
 569
 570         if(g_arena)
 571         {
 572                 if(self.version_mismatch)
 573                 {
 574                         Spawnqueue_Unmark(self);
 575                         Spawnqueue_Remove(self);
 576                 }
 577                 else
 578                 {
 579                         Spawnqueue_Insert(self);
 580                 }
 581         }
 582         else if(g_lms)
 583         {
 584                 // Only if the player cannot play at all
 585                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 586                         self.frags = FRAGS_SPECTATOR;
 587                 else
 588                         self.frags = FRAGS_LMS_LOSER;
 589         }
 590         else
 591                 self.frags = FRAGS_SPECTATOR;
 592 }
 593
 594 float RestrictSkin(float s)
 595 {
 596         if(!teams_matter)
 597                 return s;
 598         if(s == 6)
 599                 return 6;
 600         return mod(s, 3);
 601 }
 602
 603 void FixPlayermodel()
 604 {
 605         local string defaultmodel;
 606         local float defaultskin;
 607         local vector m1, m2;
 608
 609         defaultmodel = "";
 610
 611         if(cvar("sv_defaultcharacter") == 1) {
 612                 defaultskin = 0;
 613
 614                 if(teams_matter)
 615                 {
 616                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 617                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 618                 }
 619
 620                 if(defaultmodel == "")
 621                 {
 622                         defaultmodel = cvar_string("sv_defaultplayermodel");
 623                         defaultskin = cvar("sv_defaultplayerskin");
 624                 }
 625         }
 626
 627         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 628         {
 629                 if(self.model != "")
 630                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 631                 self.model = ""; // force the != checks to return true
 632         }
 633
 634         if(defaultmodel != "")
 635         {
 636                 if (defaultmodel != self.model)
 637                 {
 638                         m1 = self.mins;
 639                         m2 = self.maxs;
 640                         setmodel_lod (self, defaultmodel);
 641                         setsize (self, m1, m2);
 642                 }
 643
 644                 self.skin = defaultskin;
 645         } else {
 646                 if (self.playermodel != self.model)
 647                 {
 648                         self.playermodel = CheckPlayerModel(self.playermodel);
 649                         m1 = self.mins;
 650                         m2 = self.maxs;
 651                         setmodel_lod (self, self.playermodel);
 652                         setsize (self, m1, m2);
 653                 }
 654
 655                 self.skin = RestrictSkin(stof(self.playerskin));
 656         }
 657
 658         if(!teams_matter)
 659                 if(strlen(cvar_string("sv_defaultplayercolors")))
 660                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 661                                 setcolor(self, cvar("sv_defaultplayercolors"));
 662 }
 663
 664 void PlayerTouchExplode(entity p1, entity p2)
 665 {
 666         vector org;
 667         org = (p1.origin + p2.origin) * 0.5;
 668         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 669
 670         te_explosion(org);
 671
 672         entity e;
 673         e = spawn();
 674         setorigin(e, org);
 675         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 676         remove(e);
 677 }
 678
 679 /*
 680 =============
 681 PutClientInServer
 682
 683 Called when a client spawns in the server
 684 =============
 685 */
 686 //void() ctf_playerchanged;
 687 void PutClientInServer (void)
 688 {
 689         if(clienttype(self) == CLIENTTYPE_BOT)
 690         {
 691                 self.classname = "player";
 692         }
 693         else if(clienttype(self) == CLIENTTYPE_REAL)
 694         {
 695                 msg_entity = self;
 696                 WriteByte(MSG_ONE, SVC_SETVIEW);
 697                 WriteEntity(MSG_ONE, self);
 698         }
 699
 700         // player is dead and becomes observer
 701         // FIXME fix LMS scoring for new system
 702         if(g_lms)
 703         {
 704                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 705                         self.classname = "observer";
 706         }
 707
 708         if(g_arena)
 709         if(!self.spawned)
 710                 self.classname = "observer";
 711
 712         if(self.classname == "player") {
 713                 entity spot, oldself;
 714
 715                 if(self.team < 0)
 716                         JoinBestTeam(self, FALSE, TRUE);
 717
 718                 race_PreSpawn();
 719
 720                 spot = SelectSpawnPoint (FALSE);
 721                 if(!spot)
 722                 {
 723                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 724                         return; // spawn failed
 725                 }
 726
 727                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 728                 self.campingrifle_bulletcounter = 0;
 729
 730                 self.classname = "player";
 731                 self.wasplayer = TRUE;
 732                 self.iscreature = TRUE;
 733                 self.movetype = MOVETYPE_WALK;
 734                 self.solid = SOLID_SLIDEBOX;
 735                 self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 736                 self.frags = FRAGS_PLAYER;
 737                 if(independent_players)
 738                         MAKE_INDEPENDENT_PLAYER(self);
 739                 self.flags = FL_CLIENT;
 740                 self.takedamage = DAMAGE_AIM;
 741                 if(g_minstagib)
 742                         self.effects = EF_FULLBRIGHT;
 743                 else
 744                         self.effects = 0;
 745                 self.air_finished = time + 12;
 746                 self.dmg = 2;
 747
 748                 if(inWarmupStage)
 749                 {
 750                         self.ammo_shells = warmup_start_ammo_shells;
 751                         self.ammo_nails = warmup_start_ammo_nails;
 752                         self.ammo_rockets = warmup_start_ammo_rockets;
 753                         self.ammo_cells = warmup_start_ammo_cells;
 754                         self.ammo_fuel = warmup_start_ammo_fuel;
 755                         self.health = warmup_start_health;
 756                         self.armorvalue = warmup_start_armorvalue;
 757                         self.weapons = warmup_start_weapons;
 758                 }
 759                 else
 760                 {
 761                         self.ammo_shells = start_ammo_shells;
 762                         self.ammo_nails = start_ammo_nails;
 763                         self.ammo_rockets = start_ammo_rockets;
 764                         self.ammo_cells = start_ammo_cells;
 765                         self.ammo_fuel = start_ammo_fuel;
 766                         self.health = start_health;
 767                         self.armorvalue = start_armorvalue;
 768                         self.weapons = start_weapons;
 769                 }
 770                 self.items = start_items;
 771                 self.switchweapon = w_getbestweapon(self);
 772                 self.cnt = self.switchweapon;
 773                 self.weapon = 0;
 774                 self.jump_interval = time;
 775
 776                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 777                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 778                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 779                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
 780                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 781                 //extend the pause of rotting if client was reset at the beginning of the countdown
 782                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 783                         self.spawnshieldtime += game_starttime - time;
 784                         self.pauserotarmor_finished += game_starttime - time;
 785                         self.pauserothealth_finished += game_starttime - time;
 786                         self.pauseregen_finished += game_starttime - time;
 787                 }
 788                 self.damageforcescale = 2;
 789                 self.death_time = 0;
 790                 self.dead_frame = 0;
 791                 self.alpha = 0;
 792                 self.scale = 0;
 793                 self.fade_time = 0;
 794                 self.pain_frame = 0;
 795                 self.pain_finished = 0;
 796                 self.strength_finished = 0;
 797                 self.invincible_finished = 0;
 798                 self.pushltime = 0;
 799                 //self.speed_finished = 0;
 800                 //self.slowmo_finished = 0;
 801                 // players have no think function
 802                 self.think = SUB_Null;
 803                 self.nextthink = 0;
 804                 self.hook_time = 0;
 805                 self.dmg_team = 0;
 806
 807                 self.metertime = 0;
 808
 809                 self.runes = 0;
 810
 811                 self.deadflag = DEAD_NO;
 812
 813                 self.angles = spot.angles;
 814
 815                 self.angles_z = 0; // never spawn tilted even if the spot says to
 816                 self.fixangle = TRUE; // turn this way immediately
 817                 self.velocity = '0 0 0';
 818                 self.avelocity = '0 0 0';
 819                 self.punchangle = '0 0 0';
 820                 self.punchvector = '0 0 0';
 821                 self.oldvelocity = self.velocity;
 822
 823                 msg_entity = self;
 824                 WRITESPECTATABLE_MSG_ONE({
 825                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 826                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 827                 });
 828
 829                 self.customizeentityforclient = Client_customizeentityforclient;
 830
 831                 self.model = "";
 832                 FixPlayermodel();
 833
 834                 self.crouch = FALSE;
 835                 self.view_ofs = PL_VIEW_OFS;
 836                 setsize (self, PL_MIN, PL_MAX);
 837                 self.spawnorigin = spot.origin;
 838                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 839                 // don't reset back to last position, even if new position is stuck in solid
 840                 self.oldorigin = self.origin;
 841                 self.prevorigin = self.origin;
 842
 843                 if(g_arena)
 844                 {
 845                         Spawnqueue_Remove(self);
 846                         Spawnqueue_Mark(self);
 847                 }
 848
 849                 self.event_damage = PlayerDamage;
 850
 851                 self.bot_attack = TRUE;
 852
 853                 self.statdraintime = time + 5;
 854                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 855
 856                 if(self.killcount == -666) {
 857                         PlayerScore_Clear(self);
 858                         self.killcount = 0;
 859                 }
 860
 861                 self.cnt = WEP_LASER;
 862                 self.nixnex_lastchange_id = -1;
 863
 864                 CL_SpawnWeaponentity();
 865                 self.alpha = default_player_alpha;
 866                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 867                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 868
 869                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 870                 self.lms_traveled_distance = 0;
 871                 self.speedrunning = FALSE;
 872
 873                 race_PostSpawn(spot);
 874
 875                 if(cvar("spawn_debug"))
 876                 {
 877                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 878                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 879                 }
 880
 881                 //stuffcmd(self, "chase_active 0");
 882                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 883
 884                 if (cvar("g_spawnsound"))
 885                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 886
 887                 if(g_assault) {
 888                         if(self.team == assault_attacker_team)
 889                                 centerprint(self, "You are attacking!");
 890                         else
 891                                 centerprint(self, "You are defending!");
 892                 }
 893
 894                 target_voicescript_clear(self);
 895
 896                 oldself = self;
 897                 self = spot;
 898                         activator = oldself;
 899                                 SUB_UseTargets();
 900                         activator = world;
 901                 self = oldself;
 902
 903         } else if(self.classname == "observer") {
 904                 PutObserverInServer ();
 905         }
 906
 907         //if(g_ctf)
 908         //      ctf_playerchanged();
 909 }
 910
 911 float ClientInit_SendEntity(entity to, float sf)
 912 {
 913         float i;
 914         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 915         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 916         for(i = 1; i <= 24; ++i)
 917                 WriteByte(MSG_ENTITY, (get_weaponinfo(i)).impulse + 1);
 918         WriteCoord(MSG_ENTITY, hook_shotorigin_x);
 919         WriteCoord(MSG_ENTITY, hook_shotorigin_y);
 920         WriteCoord(MSG_ENTITY, hook_shotorigin_z);
 921
 922         if(sv_foginterval && world.fog != "")
 923                 WriteString(MSG_ENTITY, world.fog);
 924         else
 925                 WriteString(MSG_ENTITY, "");
 926
 927         return TRUE;
 928 }
 929
 930 void ClientInit_Spawn()
 931 {
 932         Net_LinkEntity(spawn(), FALSE, 0, ClientInit_SendEntity);
 933 }
 934
 935 /*
 936 =============
 937 SetNewParms
 938 =============
 939 */
 940 void SetNewParms (void)
 941 {
 942         // initialize parms for a new player
 943         parm1 = -(86400 * 366);
 944 }
 945
 946 /*
 947 =============
 948 SetChangeParms
 949 =============
 950 */
 951 void SetChangeParms (void)
 952 {
 953         // save parms for level change
 954         parm1 = self.parm_idlesince - time;
 955 }
 956
 957 /*
 958 =============
 959 DecodeLevelParms
 960 =============
 961 */
 962 void DecodeLevelParms (void)
 963 {
 964         // load parms
 965         self.parm_idlesince = parm1;
 966         if(self.parm_idlesince == -(86400 * 366))
 967                 self.parm_idlesince = time;
 968
 969         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 970         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 971 }
 972
 973 /*
 974 =============
 975 ClientKill
 976
 977 Called when a client types 'kill' in the console
 978 =============
 979 */
 980
 981 void ClientKill_Now_TeamChange()
 982 {
 983         if(self.killindicator_teamchange == -1)
 984         {
 985                 self.team = -1;
 986                 JoinBestTeam( self, FALSE, FALSE );
 987         }
 988         else
 989                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 990 }
 991
 992 void ClientKill_Now()
 993 {
 994         if(self.killindicator_teamchange)
 995                 ClientKill_Now_TeamChange();
 996
 997         // in any case:
 998         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 999
1000         if(self.killindicator)
1001         {
1002                 dprint("Cleaned up after a leaked kill indicator.\n");
1003                 remove(self.killindicator);
1004                 self.killindicator = world;
1005         }
1006 }
1007 void KillIndicator_Think()
1008 {
1009         if (!self.owner.modelindex)
1010         {
1011                 self.owner.killindicator = world;
1012                 remove(self);
1013                 return;
1014         }
1015
1016         if(self.cnt <= 0)
1017         {
1018                 self = self.owner;
1019                 ClientKill_Now(); // no oldself needed
1020                 return;
1021         }
1022         else
1023         {
1024                 if(self.cnt <= 10)
1025                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1026                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1027                 {
1028                         if(self.cnt <= 10)
1029                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".wav"));
1030                         if(self.owner.killindicator_teamchange)
1031                         {
1032                                 if(self.owner.killindicator_teamchange == -1)
1033                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1034                                 else
1035                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1036                         }
1037                         else
1038                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1039                 }
1040                 self.nextthink = time + 1;
1041                 self.cnt -= 1;
1042         }
1043 }
1044
1045 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1046 {
1047         float killtime;
1048         entity e;
1049         killtime = cvar("g_balance_kill_delay");
1050
1051         self.killindicator_teamchange = targetteam;
1052
1053         if(!self.killindicator)
1054         {
1055                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1056                 {
1057                         ClientKill_Now();
1058                 }
1059                 else
1060                 {
1061                         self.killindicator = spawn();
1062                         self.killindicator.owner = self;
1063                         self.killindicator.scale = 0.5;
1064                         setattachment(self.killindicator, self, "");
1065                         setorigin(self.killindicator, '0 0 52');
1066                         self.killindicator.think = KillIndicator_Think;
1067                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1068                         self.killindicator.cnt = ceil(killtime);
1069                         self.killindicator.count = bound(0, ceil(killtime), 10);
1070                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1071
1072                         for(e = world; (e = find(e, classname, "body")) != world; )
1073                         {
1074                                 if(e.enemy != self)
1075                                         continue;
1076                                 e.killindicator = spawn();
1077                                 e.killindicator.owner = e;
1078                                 e.killindicator.scale = 0.5;
1079                                 setattachment(e.killindicator, e, "");
1080                                 setorigin(e.killindicator, '0 0 52');
1081                                 e.killindicator.think = KillIndicator_Think;
1082                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1083                                 e.killindicator.cnt = ceil(killtime);
1084                         }
1085                         self.lip = 0;
1086                 }
1087         }
1088         if(self.killindicator)
1089         {
1090                 if(targetteam)
1091                         self.killindicator.colormod = TeamColor(targetteam);
1092                 else
1093                         self.killindicator.colormod = '0 0 0';
1094         }
1095 }
1096
1097 void ClientKill (void)
1098 {
1099         ClientKill_TeamChange(0);
1100 }
1101
1102 void DoTeamChange(float destteam)
1103 {
1104         float t, c0;
1105         if(!teams_matter)
1106         {
1107                 if(destteam >= 0)
1108                         SetPlayerColors(self, destteam);
1109                 return;
1110         }
1111         if(self.classname == "player")
1112         if(destteam == -1)
1113         {
1114                 CheckAllowedTeams(self);
1115                 t = FindSmallestTeam(self, TRUE);
1116                 switch(self.team)
1117                 {
1118                         case COLOR_TEAM1: c0 = c1; break;
1119                         case COLOR_TEAM2: c0 = c2; break;
1120                         case COLOR_TEAM3: c0 = c3; break;
1121                         case COLOR_TEAM4: c0 = c4; break;
1122                         default:          c0 = 999;
1123                 }
1124                 switch(t)
1125                 {
1126                         case 1:
1127                                 if(c0 > c1)
1128                                         destteam = COLOR_TEAM1;
1129                                 break;
1130                         case 2:
1131                                 if(c0 > c2)
1132                                         destteam = COLOR_TEAM2;
1133                                 break;
1134                         case 3:
1135                                 if(c0 > c3)
1136                                         destteam = COLOR_TEAM3;
1137                                 break;
1138                         case 4:
1139                                 if(c0 > c4)
1140                                         destteam = COLOR_TEAM4;
1141                                 break;
1142                 }
1143                 if(destteam == -1)
1144                         return;
1145         }
1146         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1147                 return;
1148         ClientKill_TeamChange(destteam);
1149 }
1150
1151 void FixClientCvars(entity e)
1152 {
1153         // send prediction settings to the client
1154         stuffcmd(e, "\nin_bindmap 0 0\n");
1155         /*
1156          * we no longer need to stuff this. Remove this comment block if you feel
1157          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1158         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1159         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1160         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1161         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1162         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1163         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1164         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1165         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1166         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1167         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1168         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1169         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1170         stuffcmd(e, "cl_movement_edgefriction 1\n");
1171          */
1172 }
1173
1174 /*
1175 =============
1176 ClientConnect
1177
1178 Called when a client connects to the server
1179 =============
1180 */
1181 //void ctf_clientconnect();
1182 string ColoredTeamName(float t);
1183 void DecodeLevelParms (void);
1184 //void dom_player_join_team(entity pl);
1185 void ClientConnect (void)
1186 {
1187         local string s;
1188         float t;
1189
1190         if(self.flags & FL_CLIENT)
1191         {
1192                 print("Warning: ClientConnect, but already connected!\n");
1193                 return;
1194         }
1195
1196         if(Ban_MaybeEnforceBan(self))
1197                 return;
1198
1199         DecodeLevelParms();
1200
1201         self.classname = "player_joining";
1202
1203         self.flags = FL_CLIENT;
1204         self.version_nagtime = time + 10 + random() * 10;
1205
1206         if(player_count<0)
1207         {
1208                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1209                 player_count = 0;
1210         }
1211
1212         PlayerScore_Attach(self);
1213         ClientData_Attach();
1214
1215         bot_clientconnect();
1216
1217         race_PreSpawnObserver();
1218
1219         //if(g_domination)
1220         //      dom_player_join_team(self);
1221
1222         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1223
1224         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1225                 self.classname = "observer";
1226         } else {
1227                 if(teams_matter)
1228                 {
1229                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1230                         {
1231                                 self.classname = "player";
1232                                 campaign_bots_may_start = 1;
1233                         }
1234                         else
1235                         {
1236                                 self.classname = "observer"; // do it anyway
1237                         }
1238                 }
1239                 else
1240                 {
1241                         self.classname = "player";
1242                         campaign_bots_may_start = 1;
1243                 }
1244         }
1245
1246         self.playerid = (playerid_last = playerid_last + 1);
1247         if(cvar("sv_eventlog"))
1248         {
1249                 if(clienttype(self) == CLIENTTYPE_REAL)
1250                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", self.netaddress, ":", self.netname));
1251                 else
1252                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":bot:", self.netname));
1253                 s = strcat(":team:", ftos(self.playerid), ":");
1254                 s = strcat(s, ftos(self.team));
1255                 GameLogEcho(s);
1256         }
1257         self.netname_previous = strzone(self.netname);
1258
1259         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1260
1261         bprint ("^4",self.netname);
1262         bprint ("^4 connected");
1263
1264         if(g_domination || g_ctf)
1265         {
1266                 bprint(" and joined the ");
1267                 bprint(ColoredTeamName(self.team));
1268         }
1269
1270         bprint("\n");
1271
1272         self.welcomemessage_time = 0;
1273
1274         stuffcmd(self, strcat(clientstuff, "\n"));
1275         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1276         stuffcmd(self, "cl_particles_reloadeffects\n");
1277
1278         FixClientCvars(self);
1279
1280         // spawnfunc_waypoint sprites
1281         WaypointSprite_InitClient(self);
1282
1283         // Wazat's grappling hook
1284         SetGrappleHookBindings();
1285
1286         // get autoswitch state from player when he toggles it
1287         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1288
1289         // get version info from player
1290         stuffcmd(self, "cmd clientversion $gameversion\n");
1291
1292         // get other cvars from player
1293         GetCvars(0);
1294
1295         // set cvar for team scoreboard
1296         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1297
1298         // notify about available teams
1299         if(teams_matter)
1300         {
1301                 CheckAllowedTeams(self);
1302                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1303                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1304         }
1305         else
1306                 stuffcmd(self, "set _teams_available 0\n");
1307
1308         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1309
1310         if(g_arena)
1311         {
1312                 self.classname = "observer";
1313                 Spawnqueue_Insert(self);
1314         }
1315         /*else if(g_ctf)
1316         {
1317                 ctf_clientconnect();
1318         }*/
1319
1320         if(teams_matter || sv_cheats)
1321                 attach_entcs();
1322
1323         bot_relinkplayerlist();
1324
1325         self.spectatortime = time;
1326         if(blockSpectators)
1327         {
1328                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1329         }
1330
1331         self.jointime = time;
1332         self.allowedTimeouts = cvar("sv_timeout_number");
1333
1334         if(clienttype(self) == CLIENTTYPE_REAL)
1335         {
1336                 if(cvar("g_bugrigs"))
1337                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1338         }
1339
1340         if(g_lms)
1341         {
1342                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1343                 {
1344                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1345                         self.frags = FRAGS_SPECTATOR;
1346                 }
1347         }
1348
1349         if(!sv_foginterval && world.fog != "")
1350                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1351
1352         SoundEntity_Attach(self);
1353 }
1354
1355 /*
1356 =============
1357 ClientDisconnect
1358
1359 Called when a client disconnects from the server
1360 =============
1361 */
1362 .entity chatbubbleentity;
1363 .entity teambubbleentity;
1364 void ReadyCount();
1365 void ClientDisconnect (void)
1366 {
1367         if not(self.flags & FL_CLIENT)
1368         {
1369                 print("Warning: ClientDisconnect without ClientConnect\n");
1370                 return;
1371         }
1372
1373         bot_clientdisconnect();
1374
1375         if(self.entcs)
1376                 detach_entcs();
1377
1378         if(cvar("sv_eventlog"))
1379                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1380         bprint ("^4",self.netname);
1381         bprint ("^4 disconnected\n");
1382
1383         SoundEntity_Detach(self);
1384
1385         DropAllRunes(self);
1386         kh_Key_DropAll(self, TRUE);
1387
1388         Portal_ClearAll(self);
1389
1390         if(self.flagcarried)
1391                 DropFlag(self.flagcarried, world, world);
1392         if(self.ballcarried)
1393                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1394
1395         // Here, everything has been done that requires this player to be a client.
1396
1397         self.flags &~= FL_CLIENT;
1398
1399         if (self.chatbubbleentity)
1400                 remove (self.chatbubbleentity);
1401
1402         if (self.teambubbleentity)
1403                 remove (self.teambubbleentity);
1404
1405         if (self.killindicator)
1406                 remove (self.killindicator);
1407
1408         WaypointSprite_PlayerGone();
1409
1410         bot_relinkplayerlist();
1411
1412         // remove laserdot
1413         if(self.weaponentity)
1414                 if(self.weaponentity.lasertarget)
1415                         remove(self.weaponentity.lasertarget);
1416
1417         if(g_arena)
1418         {
1419                 Spawnqueue_Unmark(self);
1420                 Spawnqueue_Remove(self);
1421         }
1422
1423         ClientData_Detach();
1424         PlayerScore_Detach(self);
1425
1426         if(self.netname_previous)
1427                 strunzone(self.netname_previous);
1428
1429         ClearPlayerSounds();
1430
1431         self.playerid = 0;
1432         ReadyCount();
1433
1434         // free cvars
1435         GetCvars(-1);
1436 }
1437
1438 .float BUTTON_CHAT;
1439 void ChatBubbleThink()
1440 {
1441         self.nextthink = time;
1442         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1443         {
1444                 if(self.owner) // but why can that ever be world?
1445                         self.owner.chatbubbleentity = world;
1446                 remove(self);
1447                 return;
1448         }
1449         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1450                 self.model = self.mdl;
1451         else
1452                 self.model = "";
1453 };
1454
1455 void UpdateChatBubble()
1456 {
1457         if (!self.modelindex)
1458                 return;
1459         // spawn a chatbubble entity if needed
1460         if (!self.chatbubbleentity)
1461         {
1462                 self.chatbubbleentity = spawn();
1463                 self.chatbubbleentity.owner = self;
1464                 self.chatbubbleentity.exteriormodeltoclient = self;
1465                 self.chatbubbleentity.think = ChatBubbleThink;
1466                 self.chatbubbleentity.nextthink = time;
1467                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1468                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1469                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1470                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1471                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1472                 self.chatbubbleentity.model = "";
1473                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1474         }
1475 }
1476
1477
1478 void TeamBubbleThink()
1479 {
1480         self.nextthink = time;
1481         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1482         {
1483                 if(self.owner) // but why can that ever be world?
1484                         self.owner.teambubbleentity = world;
1485                 remove(self);
1486                 return;
1487         }
1488 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1489         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1490                 self.model = "";
1491         else
1492                 self.model = self.mdl;
1493
1494 };
1495
1496 float TeamBubble_customizeentityforclient()
1497 {
1498         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1499 }
1500
1501 void UpdateTeamBubble()
1502 {
1503         if (!self.modelindex || !teams_matter)
1504                 return;
1505         // spawn a teambubble entity if needed
1506         if (!self.teambubbleentity && teams_matter)
1507         {
1508                 self.teambubbleentity = spawn();
1509                 self.teambubbleentity.owner = self;
1510                 self.teambubbleentity.exteriormodeltoclient = self;
1511                 self.teambubbleentity.think = TeamBubbleThink;
1512                 self.teambubbleentity.nextthink = time;
1513                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1514 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1515                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1516                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1517                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1518                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1519                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1520                 self.teambubbleentity.effects = EF_LOWPRECISION;
1521         }
1522 }
1523
1524 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1525 // added to the model skins
1526 /*void UpdateColorModHack()
1527 {
1528         local float c;
1529         c = self.clientcolors & 15;
1530         // LordHavoc: only bothering to support white, green, red, yellow, blue
1531              if (!teams_matter) self.colormod = '0 0 0';
1532         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1533         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1534         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1535         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1536         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1537         else self.colormod = '1 1 1';
1538 };*/
1539
1540 void respawn(void)
1541 {
1542         CopyBody(1);
1543         self.effects |= EF_NODRAW; // prevent another CopyBody
1544         PutClientInServer();
1545 }
1546
1547 void play_countdown(float finished, string samp)
1548 {
1549         if(clienttype(self) == CLIENTTYPE_REAL)
1550                 if(floor(finished - time - frametime) != floor(finished - time))
1551                         if(finished - time < 6)
1552                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1553 }
1554
1555 /**
1556  * When sv_timeout is used this function returs strings like
1557  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1558  * Called by centerprint functions
1559  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1560  */
1561 string getTimeoutText(float addOneSecond) {
1562         if (!cvar("sv_timeout") || !timeoutStatus)
1563                 return "";
1564
1565         local string retStr;
1566         if (timeoutStatus == 1) {
1567                 if (addOneSecond == 1) {
1568                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1569                 }
1570                 else {
1571                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1572                 }
1573                 return retStr;
1574         }
1575         else if (timeoutStatus == 2) {
1576                 if (addOneSecond) {
1577                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1578                         //don't show messages like "Timeout ends in 0 seconds"...
1579                         if ((remainingTimeoutTime + 1) > 0)
1580                                 return retStr;
1581                         else
1582                                 return "";
1583                 }
1584                 else {
1585                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1586                         //don't show messages like "Timeout ends in 0 seconds"...
1587                         if (remainingTimeoutTime > 0)
1588                                 return retStr;
1589                         else
1590                                 return "";
1591                 }
1592         }
1593         else return "";
1594 }
1595
1596 void player_powerups (void)
1597 {
1598         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1599         {
1600                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, ATTN_IDLE);
1601                 self.modelflags |= MF_ROCKET;
1602         }
1603         else
1604         {
1605                 SoundEntity_StopSound(self, CHAN_PLAYER);
1606                 self.modelflags &~= MF_ROCKET;
1607         }
1608
1609         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1610
1611         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1612                 return;
1613
1614         if (g_minstagib)
1615         {
1616                 if (self.items & IT_STRENGTH)
1617                 {
1618                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1619                         if (time > self.strength_finished)
1620                         {
1621                                 self.alpha = default_player_alpha;
1622                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1623                                 self.items &~= IT_STRENGTH;
1624                                 sprint(self, "^3Invisibility has worn off\n");
1625                         }
1626                 }
1627                 else
1628                 {
1629                         if (time < self.strength_finished)
1630                         {
1631                                 self.alpha = g_minstagib_invis_alpha;
1632                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1633                                 self.items |= IT_STRENGTH;
1634                                 sprint(self, "^3You are invisible\n");
1635                         }
1636                 }
1637
1638                 if (self.items & IT_INVINCIBLE)
1639                 {
1640                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1641                         if (time > self.invincible_finished)
1642                         {
1643                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1644                                 sprint(self, "^3Speed has worn off\n");
1645                         }
1646                 }
1647                 else
1648                 {
1649                         if (time < self.invincible_finished)
1650                         {
1651                                 self.items = self.items | IT_INVINCIBLE;
1652                                 sprint(self, "^3You are on speed\n");
1653                         }
1654                 }
1655                 return;
1656         }
1657
1658         if (self.items & IT_STRENGTH)
1659         {
1660                 play_countdown(self.strength_finished, "misc/poweroff.wav");
1661                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1662                 if (time > self.strength_finished)
1663                 {
1664                         self.items = self.items - (self.items & IT_STRENGTH);
1665                         sprint(self, "^3Strength has worn off\n");
1666                 }
1667         }
1668         else
1669         {
1670                 if (time < self.strength_finished)
1671                 {
1672                         self.items = self.items | IT_STRENGTH;
1673                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1674                 }
1675         }
1676         if (self.items & IT_INVINCIBLE)
1677         {
1678                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
1679                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1680                 if (time > self.invincible_finished)
1681                 {
1682                         self.items = self.items - (self.items & IT_INVINCIBLE);
1683                         sprint(self, "^3Shield has worn off\n");
1684                 }
1685         }
1686         else
1687         {
1688                 if (time < self.invincible_finished)
1689                 {
1690                         self.items = self.items | IT_INVINCIBLE;
1691                         sprint(self, "^3Shield surrounds you\n");
1692                 }
1693         }
1694
1695         if (cvar("g_fullbrightplayers"))
1696                 self.effects = self.effects | EF_FULLBRIGHT;
1697
1698         // midair gamemode: damage only while in the air
1699         // if in midair mode, being on ground grants temporary invulnerability
1700         // (this is so that multishot weapon don't clear the ground flag on the
1701         // first damage in the frame, leaving the player vulnerable to the
1702         // remaining hits in the same frame)
1703         if (self.flags & FL_ONGROUND)
1704         if (g_midair)
1705                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1706
1707         if (time >= game_starttime)
1708         if (time < self.spawnshieldtime)
1709                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1710 }
1711
1712 float CalcRegen(float current, float stable, float regenfactor)
1713 {
1714         if(current > stable)
1715                 return current;
1716         else if(current > stable - 0.25) // when close enough, "snap"
1717                 return stable;
1718         else
1719                 return min(stable, current + (stable - current) * regenfactor * frametime);
1720 }
1721
1722 void player_regen (void)
1723 {
1724         float maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1725         maxh = cvar("g_balance_health_stable");
1726         maxa = cvar("g_balance_armor_stable");
1727         maxf = cvar("g_balance_fuel_stable");
1728         limith = cvar("g_balance_health_limit");
1729         limita = cvar("g_balance_armor_limit");
1730         limitf = cvar("g_balance_fuel_limit");
1731
1732         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1733                 return;
1734
1735         max_mod = regen_mod = rot_mod = limit_mod = 1;
1736
1737         if (self.runes & RUNE_REGEN)
1738         {
1739                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1740                 {
1741                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1742                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1743                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1744                 }
1745                 else
1746                 {
1747                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1748                         max_mod = cvar("g_balance_rune_regen_hpmod");
1749                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1750                 }
1751         }
1752         else if (self.runes & CURSE_VENOM)
1753         {
1754                 max_mod = cvar("g_balance_curse_venom_hpmod");
1755                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1756                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1757                 else
1758                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1759                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1760                 //if (!self.runes & RUNE_REGEN)
1761                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1762         }
1763         maxh = maxh * max_mod;
1764         //maxa = maxa * max_mod;
1765         //maxf = maxf * max_mod;
1766         limith = limith * limit_mod;
1767         limita = limita * limit_mod;
1768         //limitf = limitf * limit_mod;
1769
1770         if (self.armorvalue > maxa)
1771         {
1772                 if (time > self.pauserotarmor_finished)
1773                 {
1774                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1775                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1776                 }
1777         }
1778         else if (self.armorvalue < maxa)
1779         {
1780                 if (time > self.pauseregen_finished)
1781                 {
1782                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1783                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1784                 }
1785         }
1786         if (self.health > maxh)
1787         {
1788                 if (time > self.pauserothealth_finished)
1789                 {
1790                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1791                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1792                 }
1793         }
1794         else if (self.health < maxh)
1795         {
1796                 if (time > self.pauseregen_finished)
1797                 {
1798                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1799                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1800                 }
1801         }
1802         if (self.ammo_fuel > maxf)
1803         {
1804                 if (time > self.pauserotfuel_finished)
1805                 {
1806                         self.ammo_fuel = max(maxf, self.ammo_fuel + (maxf - self.ammo_fuel) * rot_mod*cvar("g_balance_fuel_rot") * frametime);
1807                         self.ammo_fuel = max(maxf, self.ammo_fuel - rot_mod*cvar("g_balance_fuel_rotlinear") * frametime);
1808                 }
1809         }
1810         else if (self.ammo_fuel < maxf)
1811         {
1812                 if(self.items & IT_FUEL_REGEN)
1813                 {
1814                         if (time > self.pauseregen_finished)
1815                         {
1816                                 self.ammo_fuel = CalcRegen(self.ammo_fuel, maxf, regen_mod * cvar("g_balance_fuel_regen"));
1817                                 self.ammo_fuel = min(maxf, self.ammo_fuel + regen_mod*cvar("g_balance_fuel_regenlinear") * frametime);
1818                         }
1819                 }
1820         }
1821
1822         if (self.health > limith)
1823                 self.health = limith;
1824         if (self.armorvalue > limita)
1825                 self.armorvalue = limita;
1826         if (self.ammo_fuel > limitf)
1827                 self.ammo_fuel = limitf;
1828
1829         // if player rotted to death...  die!
1830         if(self.health < 1)
1831                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1832 }
1833
1834 float zoomstate_set;
1835 void SetZoomState(float z)
1836 {
1837         if(z != self.zoomstate)
1838                 ClientData_Touch(self);
1839         zoomstate_set = 1;
1840 }
1841
1842 void GetPressedKeys(void) {
1843         if (self.movement_x > 0) // get if movement keys are pressed
1844         {       // forward key pressed
1845                 self.pressedkeys |= KEY_FORWARD;
1846                 self.pressedkeys &~= KEY_BACKWARD;
1847         }
1848         else if (self.movement_x < 0)
1849         {       // backward key pressed
1850                 self.pressedkeys |= KEY_BACKWARD;
1851                 self.pressedkeys &~= KEY_FORWARD;
1852         }
1853         else
1854         {       // no x input
1855                 self.pressedkeys &~= KEY_FORWARD;
1856                 self.pressedkeys &~= KEY_BACKWARD;
1857         }
1858
1859         if (self.movement_y > 0)
1860         {       // right key pressed
1861                 self.pressedkeys |= KEY_RIGHT;
1862                 self.pressedkeys &~= KEY_LEFT;
1863         }
1864         else if (self.movement_y < 0)
1865         {       // left key pressed
1866                 self.pressedkeys |= KEY_LEFT;
1867                 self.pressedkeys &~= KEY_RIGHT;
1868         }
1869         else
1870         {       // no y input
1871                 self.pressedkeys &~= KEY_RIGHT;
1872                 self.pressedkeys &~= KEY_LEFT;
1873         }
1874
1875         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1876                 self.pressedkeys |= KEY_JUMP;
1877         else
1878                 self.pressedkeys &~= KEY_JUMP;
1879         if (self.BUTTON_CROUCH)
1880                 self.pressedkeys |= KEY_CROUCH;
1881         else
1882                 self.pressedkeys &~= KEY_CROUCH;
1883 }
1884
1885 /*
1886 ======================
1887 spectate mode routines
1888 ======================
1889 */
1890 void SpectateCopy(entity spectatee) {
1891         self.armortype = spectatee.armortype;
1892         self.armorvalue = spectatee.armorvalue;
1893         self.ammo_cells = spectatee.ammo_cells;
1894         self.ammo_shells = spectatee.ammo_shells;
1895         self.ammo_nails = spectatee.ammo_nails;
1896         self.ammo_rockets = spectatee.ammo_rockets;
1897         self.ammo_fuel = spectatee.ammo_fuel;
1898         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1899         self.health = spectatee.health;
1900         self.impulse = 0;
1901         self.items = spectatee.items;
1902         self.metertime = spectatee.metertime;
1903         self.strength_finished = spectatee.strength_finished;
1904         self.invincible_finished = spectatee.invincible_finished;
1905         self.pressedkeys = spectatee.pressedkeys;
1906         self.weapons = spectatee.weapons;
1907         self.switchweapon = spectatee.switchweapon;
1908         self.weapon = spectatee.weapon;
1909         self.punchangle = spectatee.punchangle;
1910         self.view_ofs = spectatee.view_ofs;
1911         self.v_angle = spectatee.v_angle;
1912         self.velocity = spectatee.velocity;
1913         self.dmg_take = spectatee.dmg_take;
1914         self.dmg_save = spectatee.dmg_save;
1915         self.dmg_inflictor = spectatee.dmg_inflictor;
1916         self.angles = spectatee.v_angle;
1917         self.fixangle = TRUE;
1918         setorigin(self, spectatee.origin);
1919         setsize(self, spectatee.mins, spectatee.maxs);
1920         SetZoomState(spectatee.zoomstate);
1921 }
1922
1923 float SpectateUpdate() {
1924         if(!self.enemy)
1925                 return 0;
1926
1927         if (self == self.enemy)
1928                 return 0;
1929
1930         if(self.enemy.classname != "player")
1931                 return 0;
1932
1933         SpectateCopy(self.enemy);
1934
1935         return 1;
1936 }
1937
1938 float SpectateNext() {
1939         other = find(self.enemy, classname, "player");
1940         if (!other) {
1941                 other = find(other, classname, "player");
1942         }
1943         if (other) {
1944                 self.enemy = other;
1945         }
1946         if(self.enemy.classname == "player") {
1947                 msg_entity = self;
1948                 WriteByte(MSG_ONE, SVC_SETVIEW);
1949                 WriteEntity(MSG_ONE, self.enemy);
1950                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1951                 if(!SpectateUpdate())
1952                         PutObserverInServer();
1953                 return 1;
1954         } else {
1955                 return 0;
1956         }
1957 }
1958
1959 /*
1960 =============
1961 ShowRespawnCountdown()
1962
1963 Update a respawn countdown display.
1964 =============
1965 */
1966 void ShowRespawnCountdown()
1967 {
1968         float number;
1969         if(self.deadflag == DEAD_NO) // just respawned?
1970                 return;
1971         else
1972         {
1973                 number = ceil(self.death_time - time);
1974                 if(number <= 0)
1975                         return;
1976                 if(number <= self.respawn_countdown)
1977                 {
1978                         self.respawn_countdown = number - 1;
1979                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1980                                 announce(self, strcat("announcer/robotic/", ftos(number), ".wav"));
1981                 }
1982         }
1983 }
1984
1985 void LeaveSpectatorMode()
1986 {
1987         if(isJoinAllowed()) {
1988                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
1989                         self.classname = "player";
1990                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1991                                 JoinBestTeam(self, FALSE, TRUE);
1992                         if(cvar("g_campaign"))
1993                                 campaign_bots_may_start = 1;
1994                         PutClientInServer();
1995                         if(self.classname == "player")
1996                                 bprint ("^4", self.netname, "^4 is playing now\n");
1997                         if(!cvar("g_campaign"))
1998                                 centerprint(self,""); // clear MOTD
1999                         return;
2000                 } else {
2001                         stuffcmd(self,"menu_showteamselect\n");
2002                         return;
2003                 }
2004         }
2005         else {
2006                 //player may not join because of g_maxplayers is set
2007                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2008         }
2009 }
2010
2011 /**
2012  * Determines whether the player is allowed to join. This depends on cvar
2013  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2014  * it checks whether the number of currently playing players exceeds g_maxplayers.
2015  * @return bool TRUE if the player is allowed to join, false otherwise
2016  */
2017 float isJoinAllowed() {
2018         if (!cvar("g_maxplayers"))
2019                 return TRUE;
2020
2021         local entity e;
2022         local float currentlyPlaying;
2023         FOR_EACH_REALPLAYER(e) {
2024                 if(e.classname == "player")
2025                         currentlyPlaying += 1;
2026         }
2027         if(currentlyPlaying < cvar("g_maxplayers"))
2028                 return TRUE;
2029
2030         return FALSE;
2031 }
2032
2033 /**
2034  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2035  * g_maxplayers_spectator_blocktime seconds
2036  */
2037 void checkSpectatorBlock() {
2038         if(self.classname == "spectator" || self.classname == "observer") {
2039                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2040                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2041                         dropclient(self);
2042                 }
2043         }
2044 }
2045
2046 float vercmp_recursive(string v1, string v2)
2047 {
2048         float dot1, dot2;
2049         string s1, s2;
2050         float r;
2051
2052         dot1 = strstrofs(v1, ".", 0);
2053         dot2 = strstrofs(v2, ".", 0);
2054         if(dot1 == -1)
2055                 s1 = v1;
2056         else
2057                 s1 = substring(v1, 0, dot1);
2058         if(dot2 == -1)
2059                 s2 = v2;
2060         else
2061                 s2 = substring(v2, 0, dot2);
2062
2063         r = stof(s1) - stof(s2);
2064         if(r != 0)
2065                 return r;
2066
2067         r = strcasecmp(s1, s2);
2068         if(r != 0)
2069                 return r;
2070
2071         if(dot1 == -1)
2072                 if(dot2 == -1)
2073                         return 0;
2074                 else
2075                         return -1;
2076         else
2077                 if(dot2 == -1)
2078                         return 1;
2079                 else
2080                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2081 }
2082
2083 float vercmp(string v1, string v2)
2084 {
2085         if(strcasecmp(v1, v2) == 0) // early out check
2086                 return 0;
2087         return vercmp_recursive(v1, v2);
2088 }
2089
2090 void ObserverThink()
2091 {
2092         if (self.flags & FL_JUMPRELEASED) {
2093                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2094                         self.welcomemessage_time = 0;
2095                         self.flags &~= FL_JUMPRELEASED;
2096                         self.flags |= FL_SPAWNING;
2097                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2098                         self.welcomemessage_time = 0;
2099                         self.flags &~= FL_JUMPRELEASED;
2100                         if(SpectateNext() == 1) {
2101                                 self.classname = "spectator";
2102                         }
2103                 }
2104         } else {
2105                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2106                         self.flags |= FL_JUMPRELEASED;
2107                         if(self.flags & FL_SPAWNING)
2108                         {
2109                                 self.flags &~= FL_SPAWNING;
2110                                 LeaveSpectatorMode();
2111                                 return;
2112                         }
2113                 }
2114         }
2115         PrintWelcomeMessage(self);
2116 }
2117
2118 void SpectatorThink()
2119 {
2120         if (self.flags & FL_JUMPRELEASED) {
2121                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2122                         self.welcomemessage_time = 0;
2123                         self.flags &~= FL_JUMPRELEASED;
2124                         self.flags |= FL_SPAWNING;
2125                 } else if(self.BUTTON_ATCK) {
2126                         self.welcomemessage_time = 0;
2127                         self.flags &~= FL_JUMPRELEASED;
2128                         if(SpectateNext() == 1) {
2129                                 self.classname = "spectator";
2130                         } else {
2131                                 self.classname = "observer";
2132                                 PutClientInServer();
2133                         }
2134                 } else if (self.BUTTON_ATCK2) {
2135                         self.welcomemessage_time = 0;
2136                         self.flags &~= FL_JUMPRELEASED;
2137                         self.classname = "observer";
2138                         PutClientInServer();
2139                 } else {
2140                         if(!SpectateUpdate())
2141                                 PutObserverInServer();
2142                 }
2143         } else {
2144                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2145                         self.flags |= FL_JUMPRELEASED;
2146                         if(self.flags & FL_SPAWNING)
2147                         {
2148                                 self.flags &~= FL_SPAWNING;
2149                                 LeaveSpectatorMode();
2150                                 return;
2151                         }
2152                 }
2153         }
2154         PrintWelcomeMessage(self);
2155         self.flags |= FL_CLIENT | FL_NOTARGET;
2156 }
2157
2158 .float touchexplode_time;
2159
2160 /*
2161 =============
2162 PlayerPreThink
2163
2164 Called every frame for each client before the physics are run
2165 =============
2166 */
2167 void() ctf_setstatus;
2168 void() nexball_setstatus;
2169 void PlayerPreThink (void)
2170 {
2171         self.stat_sys_ticrate = cvar("sys_ticrate");
2172         self.stat_game_starttime = game_starttime;
2173         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2174
2175         if(blockSpectators && frametime)
2176                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2177                 checkSpectatorBlock();
2178
2179         zoomstate_set = 0;
2180
2181         if(self.netname_previous != self.netname)
2182         {
2183                 if(cvar("sv_eventlog"))
2184                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2185                 if(self.netname_previous)
2186                         strunzone(self.netname_previous);
2187                 self.netname_previous = strzone(self.netname);
2188         }
2189
2190         // version nagging
2191         if(self.version_nagtime)
2192                 if(self.cvar_g_nexuizversion)
2193                         if(time > self.version_nagtime)
2194                         {
2195                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
2196                                 {
2197                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
2198                                         {
2199                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2200                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2201                                         }
2202                                         else
2203                                         {
2204                                                 float r;
2205                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
2206                                                 if(r < 0)
2207                                                 {
2208                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
2209                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
2210                                                 }
2211                                                 else if(r > 0)
2212                                                 {
2213                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2214                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2215                                                 }
2216                                         }
2217                                 }
2218                                 self.version_nagtime = 0;
2219                         }
2220
2221         // GOD MODE info
2222         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2223         {
2224                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2225                 self.max_armorvalue = 0;
2226         }
2227
2228         if(frametime)
2229                 antilag_record(self);
2230
2231         if(self.classname == "player") {
2232 //              if(self.netname == "Wazat")
2233 //                      bprint(self.classname, "\n");
2234
2235                 CheckRules_Player();
2236
2237                 PrintWelcomeMessage(self);
2238
2239                 if (intermission_running)
2240                 {
2241                         IntermissionThink ();   // otherwise a button could be missed between
2242                         return;                                 // the think tics
2243                 }
2244
2245                 if(self.teleport_time)
2246                 if(time > self.teleport_time)
2247                 {
2248                         self.teleport_time = 0;
2249                         self.effects = self.effects - (self.effects & EF_NODRAW);
2250                 }
2251
2252                 Nixnex_GiveCurrentWeapon();
2253
2254                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2255                         UpdateSelectedPlayer();
2256
2257                 //don't allow the player to turn around while game is paused!
2258                 if(timeoutStatus == 2) {
2259                         self.v_angle = self.lastV_angle;
2260                         self.angles = self.lastV_angle;
2261                         self.fixangle = TRUE;
2262                 }
2263
2264                 if(frametime)
2265                         player_powerups();
2266
2267                 if (self.deadflag != DEAD_NO)
2268                 {
2269                         float button_pressed, force_respawn;
2270                         if(frametime)
2271                                 player_anim();
2272                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2273                         force_respawn = (g_lms || cvar("g_forced_respawn"));
2274                         if (self.deadflag == DEAD_DYING)
2275                         {
2276                                 if(force_respawn)
2277                                         self.deadflag = DEAD_RESPAWNING;
2278                                 else if(!button_pressed)
2279                                         self.deadflag = DEAD_DEAD;
2280                         }
2281                         else if (self.deadflag == DEAD_DEAD)
2282                         {
2283                                 if(button_pressed)
2284                                         self.deadflag = DEAD_RESPAWNABLE;
2285                         }
2286                         else if (self.deadflag == DEAD_RESPAWNABLE)
2287                         {
2288                                 if(!button_pressed)
2289                                         self.deadflag = DEAD_RESPAWNING;
2290                         }
2291                         else if (self.deadflag == DEAD_RESPAWNING)
2292                         {
2293                                 if(time > self.death_time)
2294                                 {
2295                                         self.death_time = time + 1; // only retry once a second
2296                                         respawn();
2297                                 }
2298                         }
2299                         ShowRespawnCountdown();
2300                         return;
2301                 }
2302
2303                 if(g_touchexplode)
2304                 if(time > self.touchexplode_time)
2305                 if(self.classname == "player")
2306                 if(self.deadflag == DEAD_NO)
2307                 if not(IS_INDEPENDENT_PLAYER(self))
2308                 FOR_EACH_PLAYER(other) if(self != other)
2309                 {
2310                         if(time > other.touchexplode_time)
2311                         if(other.classname == "player")
2312                         if(other.deadflag == DEAD_NO)
2313                         if not(IS_INDEPENDENT_PLAYER(other))
2314                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2315                         {
2316                                 PlayerTouchExplode(self, other);
2317                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2318                         }
2319                 }
2320
2321                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2322                 {
2323                         vector dist;
2324
2325                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2326                         dist = self.prevorigin - self.origin;
2327                         dist_z = 0;
2328                         self.lms_traveled_distance += fabs(vlen(dist));
2329
2330                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2331                         {
2332                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2333                                 self.lms_traveled_distance = 0;
2334                         }
2335
2336                         if(time > self.lms_nextcheck)
2337                         {
2338                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2339                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2340                                 {
2341                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2342                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2343                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2344                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2345                                 }
2346                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2347                                 self.lms_traveled_distance = 0;
2348                         }
2349                 }
2350
2351                 self.prevorigin = self.origin;
2352
2353                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2354                 {
2355                         if (!self.crouch)
2356                         {
2357                                 self.crouch = TRUE;
2358                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2359                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2360                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2361                         }
2362                 }
2363                 else
2364                 {
2365                         if (self.crouch)
2366                         {
2367                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2368                                 if (!trace_startsolid)
2369                                 {
2370                                         self.crouch = FALSE;
2371                                         self.view_ofs = PL_VIEW_OFS;
2372                                         setsize (self, PL_MIN, PL_MAX);
2373                                 }
2374                         }
2375                 }
2376
2377                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2378                 {
2379                         if(self.bloodloss_timer < time)
2380                         {
2381                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2382                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2383                         }
2384                 }
2385
2386                 FixPlayermodel();
2387
2388                 GrapplingHookFrame();
2389
2390                 if(frametime)
2391                 {
2392                         W_WeaponFrame();
2393
2394                         self.items &~= IT_FUEL; // TODO don't do this if the current weapon actually USES fuel...
2395                         if(self.items & IT_JETPACK)
2396                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2397                                         self.items |= IT_FUEL;
2398                 }
2399
2400                 player_regen();
2401                 if(frametime)
2402                         player_anim();
2403
2404                 if (g_minstagib)
2405                         minstagib_ammocheck();
2406
2407                 ctf_setstatus();
2408                 kh_setstatus();
2409                 nexball_setstatus();
2410
2411                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2412
2413                 //self.angles_y=self.v_angle_y + 90;   // temp
2414
2415                 //if (TetrisPreFrame()) return;
2416         } else if(gameover) {
2417                 if (intermission_running)
2418                         IntermissionThink ();   // otherwise a button could be missed between
2419                 return;
2420         } else if(self.classname == "observer") {
2421                 ObserverThink();
2422         } else if(self.classname == "spectator") {
2423                 SpectatorThink();
2424         }
2425
2426         if(!zoomstate_set)
2427                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2428
2429         float oldspectatee_status;
2430         oldspectatee_status = self.spectatee_status;
2431         if(self.classname == "spectator")
2432                 self.spectatee_status = num_for_edict(self.enemy);
2433         else if(self.classname == "observer")
2434                 self.spectatee_status = num_for_edict(self);
2435         else
2436                 self.spectatee_status = 0;
2437         if(self.spectatee_status != oldspectatee_status)
2438         {
2439                 ClientData_Touch(self);
2440                 if(g_race)
2441                         race_InitSpectator();
2442         }
2443
2444         if(self.teamkill_soundtime)
2445         if(time > self.teamkill_soundtime)
2446         {
2447                 self.teamkill_soundtime = 0;
2448
2449                 entity oldpusher, oldself;
2450
2451                 oldself = self; self = self.teamkill_soundsource;
2452                 oldpusher = self.pusher; self.pusher = oldself;
2453
2454                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2455
2456                 self.pusher = oldpusher;
2457                 self = oldself;
2458         }
2459
2460         if(self.taunt_soundtime)
2461         if(time > self.taunt_soundtime)
2462         {
2463                 self.taunt_soundtime = 0;
2464                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2465         }
2466
2467         target_voicescript_next(self);
2468 }
2469
2470 // on dragger:
2471 .entity dragentity;
2472 .float draggravity;
2473 .float dragspeed; // speed of mouse wheel action
2474 .float dragdistance; // distance of dragentity's draglocalvector from view_ofs
2475 .vector draglocalvector; // local attachment vector of the dragentity
2476 .float draglocalangle;
2477 // on draggee:
2478 .entity draggedby;
2479 .float dragmovetype;
2480 void Drag_Begin(entity dragger, entity draggee, vector touchpoint)
2481 {
2482         float tagscale;
2483
2484         draggee.dragmovetype = draggee.movetype;
2485         draggee.draggravity = draggee.gravity;
2486         draggee.movetype = MOVETYPE_WALK;
2487         draggee.gravity = 0.00001;
2488         draggee.flags &~= FL_ONGROUND;
2489         draggee.draggedby = dragger;
2490
2491         dragger.dragentity = draggee;
2492
2493         dragger.dragdistance = vlen(touchpoint - dragger.origin - dragger.view_ofs);
2494         dragger.draglocalangle = draggee.angles_y - dragger.v_angle_y;
2495         touchpoint = touchpoint - gettaginfo(draggee, 0);
2496         tagscale = pow(vlen(v_forward), -2);
2497         dragger.draglocalvector_x = touchpoint * v_forward * tagscale;
2498         dragger.draglocalvector_y = touchpoint * v_right * tagscale;
2499         dragger.draglocalvector_z = touchpoint * v_up * tagscale;
2500
2501         dragger.dragspeed = 64;
2502 }
2503
2504 void Drag_Finish(entity dragger)
2505 {
2506         entity draggee;
2507         draggee = dragger.dragentity;
2508         if(dragger)
2509                 dragger.dragentity = world;
2510         draggee.draggedby = world;
2511         draggee.movetype = draggee.dragmovetype;
2512         draggee.gravity = draggee.draggravity;
2513
2514         switch(draggee.movetype)
2515         {
2516                 case MOVETYPE_TOSS:
2517                 case MOVETYPE_WALK:
2518                 case MOVETYPE_STEP:
2519                 case MOVETYPE_FLYMISSILE:
2520                 case MOVETYPE_BOUNCE:
2521                 case MOVETYPE_BOUNCEMISSILE:
2522                         break;
2523                 default:
2524                         draggee.velocity = '0 0 0';
2525                         break;
2526         }
2527
2528         if((draggee.flags & FL_ITEM) && (vlen(draggee.velocity) < 32))
2529         {
2530                 draggee.velocity = '0 0 0';
2531                 draggee.flags |= FL_ONGROUND; // floating items are FUN
2532         }
2533 }
2534
2535 float Drag_IsDraggable(entity draggee)
2536 {
2537         // TODO add more checks for bad stuff here
2538         if(draggee.classname == "func_bobbing")
2539                 return FALSE;
2540         if(draggee.classname == "door") // FIXME find out why these must be excluded, or work around the problem (trying to drag these causes like 4 fps)
2541                 return FALSE;
2542         if(draggee.classname == "plat")
2543                 return FALSE;
2544         if(draggee.classname == "func_button")
2545                 return FALSE;
2546         if(draggee.model == "")
2547                 return FALSE;
2548         if(draggee.classname == "spectator")
2549                 return FALSE;
2550         if(draggee.classname == "observer")
2551                 return FALSE;
2552         if(draggee.classname == "exteriorweaponentity")
2553                 return FALSE;
2554
2555         return TRUE;
2556 }
2557
2558 float Drag_MayChangeAngles(entity draggee)
2559 {
2560         // TODO add more checks for bad stuff here
2561         if(substring(draggee.model, 0, 1) == "*")
2562                 return FALSE;
2563         return TRUE;
2564 }
2565
2566 void Drag_MoveForward(entity dragger)
2567 {
2568         dragger.dragdistance += dragger.dragspeed;
2569 }
2570
2571 void Drag_SetSpeed(entity dragger, float s)
2572 {
2573         dragger.dragspeed = pow(2, s);
2574 }
2575
2576 void Drag_MoveBackward(entity dragger)
2577 {
2578         dragger.dragdistance = max(0, dragger.dragdistance - dragger.dragspeed);
2579 }
2580
2581 void Drag_Update(entity dragger)
2582 {
2583         vector curorigin, neworigin, goodvelocity;
2584         float f;
2585         entity draggee;
2586
2587         draggee = dragger.dragentity;
2588         draggee.flags &~= FL_ONGROUND;
2589
2590         curorigin = gettaginfo(draggee, 0);
2591         curorigin = curorigin + v_forward * dragger.draglocalvector_x + v_right * dragger.draglocalvector_y + v_up * dragger.draglocalvector_z;
2592         makevectors(dragger.v_angle);
2593         neworigin = dragger.origin + dragger.view_ofs + v_forward * dragger.dragdistance;
2594         goodvelocity = (neworigin - curorigin) * (1 / frametime);
2595
2596         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle > 180)
2597                 dragger.draglocalangle += 360;
2598         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle <= -180)
2599                 dragger.draglocalangle -= 360;
2600
2601         f = min(frametime * 10, 1);
2602         draggee.velocity = draggee.velocity * (1 - f) + goodvelocity * f;
2603
2604         if(Drag_MayChangeAngles(draggee))
2605                 draggee.angles_y = draggee.angles_y * (1 - f) + (dragger.v_angle_y + dragger.draglocalangle) * f;
2606
2607         draggee.ltime = max(servertime + serverframetime, draggee.ltime); // fixes func_train breakage
2608
2609         te_lightning1(dragger, dragger.origin + dragger.view_ofs, curorigin);
2610 }
2611
2612 float Drag_CanDrag(entity dragger)
2613 {
2614         return (dragger.deadflag == DEAD_NO) || (dragger.classname == "player");
2615 }
2616
2617 float Drag_IsDragging(entity dragger)
2618 {
2619         if(!dragger.dragentity)
2620                 return FALSE;
2621         if(wasfreed(dragger.dragentity) || dragger.dragentity.draggedby != dragger)
2622         {
2623                 dragger.dragentity = world;
2624                 return FALSE;
2625         }
2626         if(!Drag_CanDrag(dragger) || !Drag_IsDraggable(dragger.dragentity))
2627         {
2628                 Drag_Finish(dragger);
2629                 return FALSE;
2630         }
2631         return TRUE;
2632 }
2633
2634 void Drag_MoveDrag(entity from, entity to)
2635 {
2636         if(from.draggedby)
2637         {
2638                 to.draggedby = from.draggedby;
2639                 to.draggedby.dragentity = to;
2640                 from.draggedby = world;
2641         }
2642 }
2643
2644 /*
2645 =============
2646 PlayerPostThink
2647
2648 Called every frame for each client after the physics are run
2649 =============
2650 */
2651 .float idlekick_lasttimeleft;
2652 .float race_penalty;
2653 .float race_penalty_nagged;
2654 .float race_penalty_nagtime;
2655 void PlayerPostThink (void)
2656 {
2657         // Savage: Check for nameless players
2658         if (strlen(self.netname) < 1) {
2659                 self.netname = "Player";
2660                 stuffcmd(self, "seta _cl_name Player\n");
2661         }
2662
2663         if(sv_maxidle && frametime)
2664         {
2665                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2666                 float timeleft;
2667                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2668                 if(timeleft <= 0)
2669                 {
2670                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2671                         announce(self, "announcer/robotic/terminated.wav");
2672                         dropclient(self);
2673                         return;
2674                 }
2675                 else if(timeleft <= 10)
2676                 {
2677                         if(timeleft != self.idlekick_lasttimeleft)
2678                         {
2679                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2680                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".wav"));
2681                         }
2682                 }
2683                 else
2684                 {
2685                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2686                 }
2687                 self.idlekick_lasttimeleft = timeleft;
2688         }
2689
2690         if(sv_cheats)
2691                 if(Drag_CanDrag(self))
2692                         if(self.BUTTON_DRAG)
2693                                 if(!self.dragentity)
2694                                         if(self.cursor_trace_ent)
2695                                                 if(Drag_IsDraggable(self.cursor_trace_ent))
2696                                                 {
2697                                                         if(self.cursor_trace_ent.draggedby)
2698                                                                 Drag_Finish(self.cursor_trace_ent.draggedby);
2699                                                         if(self.cursor_trace_ent.tag_entity)
2700                                                                 detach_sameorigin(self.cursor_trace_ent);
2701                                                         Drag_Begin(self, self.cursor_trace_ent, self.cursor_trace_endpos);
2702                                                 }
2703
2704         if(Drag_IsDragging(self))
2705         {
2706                 if(self.BUTTON_DRAG)
2707                 {
2708                         if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
2709                         {
2710                                 Drag_MoveForward(self);
2711                                 self.impulse = 0;
2712                         }
2713                         else if(self.impulse == 12 || self.impulse == 16 || self.impulse == 19)
2714                         {
2715                                 Drag_MoveBackward(self);
2716                                 self.impulse = 0;
2717                         }
2718                         else if(self.impulse >= 1 && self.impulse <= 9)
2719                         {
2720                                 Drag_SetSpeed(self, self.impulse - 1);
2721                         }
2722                         else if(self.impulse == 14)
2723                         {
2724                                 Drag_SetSpeed(self, 9);
2725                         }
2726
2727                         if(frametime)
2728                                 Drag_Update(self);
2729                 }
2730                 else
2731                 {
2732                         Drag_Finish(self);
2733                 }
2734         }
2735
2736         if(self.classname == "player") {
2737                 CheckRules_Player();
2738                 UpdateChatBubble();
2739                 UpdateTeamBubble();
2740                 if (self.impulse)
2741                         ImpulseCommands();
2742                 if (intermission_running)
2743                         return;         // intermission or finale
2744
2745                 //if (TetrisPostFrame()) return;
2746
2747                 // restart countdown
2748                         if(time < game_starttime) {
2749                                 if (!cvar("sv_ready_restart_after_countdown"))
2750                                 {
2751                                         if(self.movement != '0 0 0' && g_race && !g_race_qualifying)
2752                                         {
2753                                                 if(time < game_starttime - 2)
2754                                                 {
2755                                                         if(!self.race_penalty_nagged)
2756                                                         {
2757                                                                 // TODO better notification for this!
2758                                                                 self.race_penalty_nagtime = 0;
2759                                                                 self.race_penalty_nagged = 1;
2760                                                         }
2761                                                 }
2762                                                 else if(!self.race_penalty)
2763                                                 {
2764                                                         self.race_penalty_nagtime = 0;
2765                                                         self.race_penalty = time + 5;
2766                                                 }
2767                                         }
2768                                         if(time > self.race_penalty_nagtime)
2769                                         {
2770                                                 if(self.race_penalty > time)
2771                                                 {
2772                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1FIVE SECONDS PENALTY.");
2773                                                 }
2774                                                 else if(self.race_penalty_nagged && time < game_starttime - 2)
2775                                                 {
2776                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1DO NOT MOVE DURING THE COUNTDOWN.");
2777                                                 }
2778                                                 self.race_penalty_nagtime = time + self.cvar_scr_centertime * 0.6;
2779                                         }
2780                                         self.movetype = MOVETYPE_NONE;
2781                                         self.velocity = '0 0 0';
2782                                         self.avelocity = '0 0 0';
2783                                         self.movement = '0 0 0';
2784                                 }
2785                         }
2786                         else if (time < self.race_penalty)
2787                         {
2788                                 self.movetype = MOVETYPE_NONE;
2789                                 self.velocity = '0 0 0';
2790                                 self.avelocity = '0 0 0';
2791                                 self.movement = '0 0 0';
2792                         }
2793                         else
2794                         {
2795                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2796                                 if (!cvar("sv_ready_restart_after_countdown"))
2797                                 {
2798                                         if(self.movetype == MOVETYPE_NONE)
2799                                         {
2800                                                 self.movetype = MOVETYPE_WALK;
2801                                         }
2802                                         self.race_penalty = 0;
2803                                         self.race_penalty_nagged = 0;
2804                                 }
2805                         }
2806                 GetPressedKeys();
2807         } else if (self.classname == "observer") {
2808                 //do nothing
2809         } else if (self.classname == "spectator") {
2810                 //do nothing
2811         }
2812
2813         /*
2814         float i;
2815         for(i = 0; i < 1000; ++i)
2816         {
2817                 vector end;
2818                 end = self.origin + '0 0 1024' + 512 * randomvec();
2819                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2820                 if(trace_fraction < 1)
2821                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2822                 {
2823                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2824                         break;
2825                 }
2826         }
2827         */
2828
2829         Arena_Warmup();
2830
2831         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2832 }