data/qcsrc/server/cl_client.qc

   1 #define SPAWNPOINT_SCORE frags
   2
   3 .float wantswelcomemessage;
   4 .string netname_previous;
   5
   6 void spawnfunc_info_player_survivor (void)
   7 {
   8         spawnfunc_info_player_deathmatch();
   9 }
  10
  11 void spawnfunc_info_player_start (void)
  12 {
  13         spawnfunc_info_player_deathmatch();
  14 }
  15
  16 void spawnfunc_info_player_deathmatch (void)
  17 {
  18         self.classname = "info_player_deathmatch";
  19         relocate_spawnpoint();
  20 }
  21
  22 void spawnpoint_use()
  23 {
  24         if(teams_matter)
  25         if(have_team_spawns)
  26         {
  27                 self.team = activator.team;
  28                 some_spawn_has_been_used = 1;
  29         }
  30 };
  31
  32 // Returns:
  33 //   -1 if a spawn can't be used
  34 //   otherwise, a weight of the spawnpoint
  35 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
  36 {
  37         float shortest, thisdist;
  38         entity player;
  39
  40         // filter out spots for the wrong team
  41         if(teamcheck)
  42         if(spot.team != teamcheck)
  43                 return -1;
  44
  45         if(race_spawns)
  46                 if(spot.target == "")
  47                         return -1;
  48
  49         // filter out spots for assault
  50         if(spot.target != "") {
  51                 local entity ent;
  52                 float good;
  53                 ent = find(world, targetname, spot.target);
  54                 while(ent) {
  55                         if(ent.classname == "target_objective")
  56                         {
  57                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  58                                         return -1;
  59                                 good = 1;
  60                         }
  61                         else if(ent.classname == "trigger_race_checkpoint")
  62                         {
  63                                 if(self.classname == "player") // spectators may spawn everywhere
  64                                 {
  65                                         if(g_race_qualifying)
  66                                         {
  67                                                 // spawn at first
  68                                                 if(ent.race_checkpoint != 0)
  69                                                         return -1;
  70                                                 if(spot.race_place != race_lowest_place_spawn)
  71                                                         return -1;
  72                                         }
  73                                         else
  74                                         {
  75                                                 if(ent.race_checkpoint != race_PreviousCheckpoint(self.race_checkpoint))
  76                                                         return -1;
  77                                                 float pl;
  78                                                 pl = self.race_place;
  79                                                 if(pl > race_highest_place_spawn)
  80                                                         pl = 0;
  81                                                 if(spot.race_place != pl)
  82                                                         return -1;
  83                                         }
  84                                 }
  85                                 good = 1;
  86                         }
  87                         else
  88                         {
  89                         }
  90                         ent = find(ent, targetname, spot.target);
  91                 }
  92
  93                 if(!good)
  94                         return -1;
  95         }
  96
  97         player = playerlist;
  98         shortest = vlen(world.maxs - world.mins);
  99         for(player = playerlist; player; player = player.chain)
 100                 if (player != self)
 101                 {
 102                         thisdist = vlen(player.origin - spot.origin);
 103                         if (thisdist < shortest)
 104                                 shortest = thisdist;
 105                 }
 106         return shortest;
 107 }
 108
 109 float spawn_allbad;
 110 float spawn_allgood;
 111 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
 112 {
 113         local entity spot, spotlist, spotlistend;
 114         spawn_allgood = TRUE;
 115         spawn_allbad = TRUE;
 116
 117         spotlist = world;
 118         spotlistend = world;
 119
 120         for(spot = firstspot; spot; spot = spot.chain)
 121         {
 122                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
 123
 124                 if(cvar("spawn_debugview"))
 125                 {
 126                         setmodel(spot, "models/runematch/rune.mdl");
 127                         if(spot.SPAWNPOINT_SCORE < mindist)
 128                         {
 129                                 spot.colormod = '1 0 0';
 130                                 spot.scale = 1;
 131                         }
 132                         else
 133                         {
 134                                 spot.colormod = '0 1 0';
 135                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
 136                         }
 137                 }
 138
 139                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 140                 {
 141                         if(spot.SPAWNPOINT_SCORE < mindist)
 142                         {
 143                                 // too short distance
 144                                 spawn_allgood = FALSE;
 145                         }
 146                         else
 147                         {
 148                                 // perfect
 149                                 spawn_allbad = FALSE;
 150
 151                                 if(spotlistend)
 152                                         spotlistend.chain = spot;
 153                                 spotlistend = spot;
 154                                 if(!spotlist)
 155                                         spotlist = spot;
 156
 157                                 /*
 158                                 if(teamcheck)
 159                                 if(spot.team != teamcheck)
 160                                         error("invalid spawn added");
 161
 162                                 print("added ", etos(spot), "\n");
 163                                 */
 164                         }
 165                 }
 166         }
 167         if(spotlistend)
 168                 spotlistend.chain = world;
 169
 170         /*
 171                 entity e;
 172                 if(teamcheck)
 173                         for(e = spotlist; e; e = e.chain)
 174                         {
 175                                 print("seen ", etos(e), "\n");
 176                                 if(e.team != teamcheck)
 177                                         error("invalid spawn found");
 178                         }
 179         */
 180
 181         return spotlist;
 182 }
 183
 184 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 185 {
 186         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 187         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 188         local entity spot;
 189
 190         RandomSelection_Init();
 191         for(spot = firstspot; spot; spot = spot.chain)
 192                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 193
 194         return RandomSelection_chosen_ent;
 195 }
 196
 197 /*
 198 =============
 199 SelectSpawnPoint
 200
 201 Finds a point to respawn
 202 =============
 203 */
 204 entity SelectSpawnPoint (float anypoint)
 205 {
 206         local float teamcheck;
 207         local entity firstspot_new;
 208         local entity spot, firstspot, playerlist;
 209
 210         spot = find (world, classname, "testplayerstart");
 211         if (spot)
 212                 return spot;
 213
 214         teamcheck = 0;
 215
 216         if(!anypoint && have_team_spawns)
 217                 teamcheck = self.team;
 218
 219         // get the list of players
 220         playerlist = findchain(classname, "player");
 221         // get the entire list of spots
 222         firstspot = findchain(classname, "info_player_deathmatch");
 223         // filter out the bad ones
 224         // (note this returns the original list if none survived)
 225         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 226         if(!firstspot_new)
 227                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 228         firstspot = firstspot_new;
 229
 230         // there is 50/50 chance of choosing a random spot or the furthest spot
 231         // (this means that roughly every other spawn will be furthest, so you
 232         // usually won't get fragged at spawn twice in a row)
 233         if (arena_roundbased)
 234         {
 235                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 236                 if(firstspot_new)
 237                         firstspot = firstspot_new;
 238                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 239         }
 240         else if (random() > cvar("g_spawn_furthest"))
 241                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 242         else
 243                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 244
 245         if(cvar("spawn_debugview"))
 246         {
 247                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 248
 249                 entity e;
 250                 if(teamcheck)
 251                         for(e = firstspot; e; e = e.chain)
 252                                 if(e.team != teamcheck)
 253                                         error("invalid spawn found");
 254         }
 255
 256         if (!spot)
 257         {
 258                 if(cvar("spawn_debug"))
 259                         GotoNextMap();
 260                 else
 261                 {
 262                         if(some_spawn_has_been_used)
 263                                 return world; // team can't spawn any more, because of actions of other team
 264                         else
 265                                 error("Cannot find a spawn point - please fix the map!");
 266                 }
 267         }
 268
 269         return spot;
 270 }
 271
 272 /*
 273 =============
 274 CheckPlayerModel
 275
 276 Checks if the argument string can be a valid playermodel.
 277 Returns a valid one in doubt.
 278 =============
 279 */
 280 string FallbackPlayerModel = "models/player/marine.zym";
 281 string CheckPlayerModel(string plyermodel) {
 282         if(strlen(plyermodel) < 4)
 283                 return FallbackPlayerModel;
 284         if( substring(plyermodel,0,14) != "models/player/")
 285                 return FallbackPlayerModel;
 286         else if(cvar("sv_servermodelsonly"))
 287         {
 288                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 289                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 290                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 291                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 292                         return FallbackPlayerModel;
 293                 if(plyermodel != strtolower(plyermodel))
 294                         return FallbackPlayerModel;
 295                 if(!fexists(plyermodel))
 296                         return FallbackPlayerModel;
 297         }
 298         return plyermodel;
 299 }
 300
 301 /*
 302 =============
 303 Client_customizeentityforclient
 304
 305 LOD reduction
 306 =============
 307 */
 308 float Client_customizeentityforclient()
 309 {
 310 #ifdef ALLOW_VARIABLE_LOD
 311         // self: me
 312         // other: the player viewing me
 313         float distance;
 314         float f;
 315
 316         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 317                 return TRUE;
 318
 319         if(other.cvar_cl_playerdetailreduction <= 0)
 320         {
 321                 if(other.cvar_cl_playerdetailreduction <= -2)
 322                         self.modelindex = self.modelindex_lod2;
 323                 else if(other.cvar_cl_playerdetailreduction <= -1)
 324                         self.modelindex = self.modelindex_lod1;
 325                 else
 326                         self.modelindex = self.modelindex_lod0;
 327         }
 328         else
 329         {
 330                 distance = vlen(self.origin - other.origin);
 331                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 332                 if(f > 10000)
 333                         self.modelindex = self.modelindex_lod2;
 334                 else if(f > 5000)
 335                         self.modelindex = self.modelindex_lod1;
 336                 else
 337                         self.modelindex = self.modelindex_lod0;
 338         }
 339 #endif
 340
 341         return TRUE;
 342 }
 343
 344 void UpdatePlayerSounds();
 345 void setmodel_lod(entity e, string modelname)
 346 {
 347 #ifdef ALLOW_VARIABLE_LOD
 348         string s;
 349
 350         // FIXME: this only supports 3-letter extensions
 351         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 352         if(fexists(s))
 353         {
 354                 precache_model(s);
 355                 setmodel(e, s); // players have high precision
 356                 self.modelindex_lod1 = self.modelindex;
 357         }
 358         else
 359                 self.modelindex_lod1 = -1;
 360
 361         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 362         if(fexists(s))
 363         {
 364                 precache_model(s);
 365                 setmodel(e, s); // players have high precision
 366                 self.modelindex_lod2 = self.modelindex;
 367         }
 368         else
 369                 self.modelindex_lod2 = -1;
 370
 371         precache_model(modelname);
 372         setmodel(e, modelname); // players have high precision
 373         self.modelindex_lod0 = self.modelindex;
 374
 375         if(self.modelindex_lod1 < 0)
 376                 self.modelindex_lod1 = self.modelindex;
 377
 378         if(self.modelindex_lod2 < 0)
 379                 self.modelindex_lod2 = self.modelindex;
 380 #else
 381         precache_model(modelname);
 382         setmodel(e, modelname); // players have high precision
 383 #endif
 384         player_setupanimsformodel();
 385         UpdatePlayerSounds();
 386 }
 387
 388 /*
 389 =============
 390 PutObserverInServer
 391
 392 putting a client as observer in the server
 393 =============
 394 */
 395 void PutObserverInServer (void)
 396 {
 397         entity  spot;
 398
 399         race_PreSpawnObserver();
 400
 401         spot = SelectSpawnPoint (TRUE);
 402         if(!spot)
 403                 error("No spawnpoints for observers?!?\n");
 404         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 405
 406         if(clienttype(self) == CLIENTTYPE_REAL)
 407         {
 408                 msg_entity = self;
 409                 WriteByte(MSG_ONE, SVC_SETVIEW);
 410                 WriteEntity(MSG_ONE, self);
 411         }
 412
 413         DropAllRunes(self);
 414         kh_Key_DropAll(self, TRUE);
 415
 416         Portal_ClearAll(self);
 417
 418         if(self.flagcarried)
 419                 DropFlag(self.flagcarried, world, world);
 420
 421         WaypointSprite_PlayerDead();
 422
 423         if(self.killcount != -666)
 424         {
 425                 if(g_lms)
 426                 {
 427                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 428                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 429                         else
 430                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 431                 }
 432                 else
 433                         bprint ("^4", self.netname, "^4 is spectating now\n");
 434         }
 435
 436         PlayerScore_Clear(self); // clear scores when needed
 437
 438         self.spectatortime = time;
 439
 440         self.classname = "observer";
 441         self.iscreature = FALSE;
 442         self.health = -666;
 443         self.takedamage = DAMAGE_NO;
 444         self.solid = SOLID_NOT;
 445         self.movetype = MOVETYPE_NOCLIP;
 446         self.flags = FL_CLIENT | FL_NOTARGET;
 447         self.armorvalue = 666;
 448         self.effects = 0;
 449         self.armorvalue = cvar("g_balance_armor_start");
 450         self.pauserotarmor_finished = 0;
 451         self.pauserothealth_finished = 0;
 452         self.pauseregen_finished = 0;
 453         self.damageforcescale = 0;
 454         self.death_time = 0;
 455         self.dead_frame = 0;
 456         self.alpha = 0;
 457         self.scale = 0;
 458         self.fade_time = 0;
 459         self.pain_frame = 0;
 460         self.pain_finished = 0;
 461         self.strength_finished = 0;
 462         self.invincible_finished = 0;
 463         self.pushltime = 0;
 464         self.think = SUB_Null;
 465         self.nextthink = 0;
 466         self.hook_time = 0;
 467         self.runes = 0;
 468         self.deadflag = DEAD_NO;
 469         self.angles = spot.angles;
 470         self.angles_z = 0;
 471         self.fixangle = TRUE;
 472         self.crouch = FALSE;
 473
 474         self.view_ofs = PL_VIEW_OFS;
 475         setorigin (self, spot.origin);
 476         setsize (self, '0 0 0', '0 0 0');
 477         self.oldorigin = self.origin;
 478         self.items = 0;
 479         self.weapons = 0;
 480         self.model = "";
 481         self.modelindex = 0;
 482         self.weapon = 0;
 483         self.weaponmodel = "";
 484         self.weaponentity = world;
 485         self.killcount = -666;
 486         self.velocity = '0 0 0';
 487         self.avelocity = '0 0 0';
 488         self.punchangle = '0 0 0';
 489         self.punchvector = '0 0 0';
 490         self.oldvelocity = self.velocity;
 491         self.customizeentityforclient = Client_customizeentityforclient;
 492         self.wantswelcomemessage = 1;
 493
 494         if(g_arena)
 495         {
 496                 if(self.version_mismatch)
 497                 {
 498                         Spawnqueue_Unmark(self);
 499                         Spawnqueue_Remove(self);
 500                 }
 501                 else
 502                 {
 503                         Spawnqueue_Insert(self);
 504                 }
 505         }
 506         else if(g_lms)
 507         {
 508                 // Only if the player cannot play at all
 509                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 510                         self.frags = -666;
 511                 else
 512                         self.frags = -667;
 513         }
 514         else
 515                 self.frags = -666;
 516 }
 517
 518 float RestrictSkin(float s)
 519 {
 520         if(!teams_matter)
 521                 return s;
 522         if(s == 6)
 523                 return 6;
 524         return mod(s, 3);
 525 }
 526
 527 void FixPlayermodel()
 528 {
 529         local string defaultmodel;
 530         local float defaultskin;
 531         local vector m1, m2;
 532
 533         defaultmodel = "";
 534
 535         if(cvar("sv_defaultcharacter") == 1) {
 536                 defaultskin = 0;
 537
 538                 if(teams_matter)
 539                 {
 540                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 541                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 542                 }
 543
 544                 if(defaultmodel == "")
 545                 {
 546                         defaultmodel = cvar_string("sv_defaultplayermodel");
 547                         defaultskin = cvar("sv_defaultplayerskin");
 548                 }
 549         }
 550
 551         if(self.modelindex == 0)
 552         {
 553                 if(self.model != "")
 554                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 555                 self.model = ""; // force the != checks to return true
 556         }
 557
 558         if(defaultmodel != "")
 559         {
 560                 if (defaultmodel != self.model)
 561                 {
 562                         m1 = self.mins;
 563                         m2 = self.maxs;
 564                         setmodel_lod (self, defaultmodel);
 565                         setsize (self, m1, m2);
 566                 }
 567
 568                 self.skin = defaultskin;
 569         } else {
 570                 if (self.playermodel != self.model)
 571                 {
 572                         self.playermodel = CheckPlayerModel(self.playermodel);
 573                         m1 = self.mins;
 574                         m2 = self.maxs;
 575                         setmodel_lod (self, self.playermodel);
 576                         setsize (self, m1, m2);
 577                 }
 578
 579                 self.skin = RestrictSkin(stof(self.playerskin));
 580         }
 581
 582         if(!teams_matter)
 583                 if(strlen(cvar_string("sv_defaultplayercolors")))
 584                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 585                                 setcolor(self, cvar("sv_defaultplayercolors"));
 586 }
 587
 588 /*
 589 =============
 590 PutClientInServer
 591
 592 Called when a client spawns in the server
 593 =============
 594 */
 595 //void() ctf_playerchanged;
 596 void PutClientInServer (void)
 597 {
 598         if(clienttype(self) == CLIENTTYPE_BOT)
 599         {
 600                 self.classname = "player";
 601         }
 602         else if(clienttype(self) == CLIENTTYPE_REAL)
 603         {
 604                 msg_entity = self;
 605                 WriteByte(MSG_ONE, SVC_SETVIEW);
 606                 WriteEntity(MSG_ONE, self);
 607         }
 608
 609         // player is dead and becomes observer
 610         // FIXME fix LMS scoring for new system
 611         if(g_lms)
 612         {
 613                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 614                         self.classname = "observer";
 615         }
 616
 617         if(g_arena)
 618         if(!self.spawned)
 619                 self.classname = "observer";
 620
 621         if(self.classname == "player") {
 622                 entity spot, oldself;
 623
 624                 race_PreSpawn();
 625
 626                 spot = SelectSpawnPoint (FALSE);
 627                 if(!spot)
 628                 {
 629                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 630                         return; // spawn failed
 631                 }
 632
 633                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 634
 635                 self.classname = "player";
 636                 self.iscreature = TRUE;
 637                 self.movetype = MOVETYPE_WALK;
 638                 self.solid = SOLID_SLIDEBOX;
 639                 self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 640                 if(independent_players)
 641                         MAKE_INDEPENDENT_PLAYER(self);
 642                 self.flags = FL_CLIENT;
 643                 self.takedamage = DAMAGE_AIM;
 644                 if(g_minstagib)
 645                         self.effects = EF_FULLBRIGHT;
 646                 else
 647                         self.effects = 0;
 648                 self.air_finished = time + 12;
 649                 self.dmg = 2;
 650
 651                 if(inWarmupStage)
 652                 {
 653                         self.ammo_shells = warmup_start_ammo_shells;
 654                         self.ammo_nails = warmup_start_ammo_nails;
 655                         self.ammo_rockets = warmup_start_ammo_rockets;
 656                         self.ammo_cells = warmup_start_ammo_cells;
 657                         self.health = warmup_start_health;
 658                         self.armorvalue = warmup_start_armorvalue;
 659                         self.weapons = warmup_start_weapons;
 660                 }
 661                 else
 662                 {
 663                         self.ammo_shells = start_ammo_shells;
 664                         self.ammo_nails = start_ammo_nails;
 665                         self.ammo_rockets = start_ammo_rockets;
 666                         self.ammo_cells = start_ammo_cells;
 667                         self.health = start_health;
 668                         self.armorvalue = start_armorvalue;
 669                         self.weapons = start_weapons;
 670                 }
 671                 self.items = start_items;
 672                 self.switchweapon = w_getbestweapon(self);
 673                 self.cnt = self.switchweapon;
 674                 self.weapon = 0;
 675                 self.jump_interval = time;
 676
 677                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 678                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 679                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 680                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 681                 //extend the pause of rotting if client was reset at the beginning of the countdown
 682                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 683                         self.spawnshieldtime += game_starttime - time;
 684                         self.pauserotarmor_finished += game_starttime - time;
 685                         self.pauserothealth_finished += game_starttime - time;
 686                         self.pauseregen_finished += game_starttime - time;
 687                 }
 688                 self.damageforcescale = 2;
 689                 self.death_time = 0;
 690                 self.dead_frame = 0;
 691                 self.alpha = 0;
 692                 self.scale = 0;
 693                 self.fade_time = 0;
 694                 self.pain_frame = 0;
 695                 self.pain_finished = 0;
 696                 self.strength_finished = 0;
 697                 self.invincible_finished = 0;
 698                 self.pushltime = 0;
 699                 //self.speed_finished = 0;
 700                 //self.slowmo_finished = 0;
 701                 // players have no think function
 702                 self.think = SUB_Null;
 703                 self.nextthink = 0;
 704                 self.hook_time = 0;
 705
 706                 self.runes = 0;
 707
 708                 self.deadflag = DEAD_NO;
 709
 710                 self.angles = spot.angles;
 711
 712                 self.angles_z = 0; // never spawn tilted even if the spot says to
 713                 self.fixangle = TRUE; // turn this way immediately
 714                 self.velocity = '0 0 0';
 715                 self.avelocity = '0 0 0';
 716                 self.punchangle = '0 0 0';
 717                 self.punchvector = '0 0 0';
 718                 self.oldvelocity = self.velocity;
 719
 720                 msg_entity = self;
 721                 WRITESPECTATABLE_MSG_ONE({
 722                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 723                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 724                 });
 725
 726                 self.customizeentityforclient = Client_customizeentityforclient;
 727
 728                 self.model = "";
 729                 FixPlayermodel();
 730
 731                 self.crouch = FALSE;
 732                 self.view_ofs = PL_VIEW_OFS;
 733                 setsize (self, PL_MIN, PL_MAX);
 734                 self.spawnorigin = spot.origin;
 735                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 736                 // don't reset back to last position, even if new position is stuck in solid
 737                 self.oldorigin = self.origin;
 738
 739                 if(g_arena)
 740                 {
 741                         Spawnqueue_Remove(self);
 742                         Spawnqueue_Mark(self);
 743                 }
 744
 745                 self.event_damage = PlayerDamage;
 746
 747                 self.bot_attack = TRUE;
 748
 749                 self.statdraintime = time + 5;
 750                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 751
 752                 if(self.killcount == -666) {
 753                         PlayerScore_Clear(self);
 754                         self.killcount = 0;
 755                         self.frags = 0;
 756                 }
 757
 758                 self.cnt = WEP_LASER;
 759                 self.nixnex_lastchange_id = -1;
 760
 761                 CL_SpawnWeaponentity();
 762                 self.alpha = default_player_alpha;
 763                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 764                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 765
 766                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 767                 self.lms_traveled_distance = 0;
 768                 self.speedrunning = FALSE;
 769
 770                 race_PostSpawn(spot);
 771
 772                 if(cvar("spawn_debug"))
 773                 {
 774                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 775                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 776                 }
 777
 778                 //stuffcmd(self, "chase_active 0");
 779                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 780
 781                 if (cvar("g_spawnsound"))
 782                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 783
 784                 if(g_assault) {
 785                         if(self.team == assault_attacker_team)
 786                                 centerprint(self, "You are attacking!\n");
 787                         else
 788                                 centerprint(self, "You are defending!\n");
 789                 }
 790
 791                 target_voicescript_clear(self);
 792
 793                 oldself = self;
 794                 self = spot;
 795                         activator = oldself;
 796                                 SUB_UseTargets();
 797                         activator = world;
 798                 self = oldself;
 799
 800         } else if(self.classname == "observer") {
 801                 PutObserverInServer ();
 802         }
 803
 804         //if(g_ctf)
 805         //      ctf_playerchanged();
 806 }
 807
 808 /*
 809 =============
 810 SendCSQCInfo
 811
 812 Send whatever CSQC needs NOW and cannot wait for SendServerInfo to happen...
 813 =============
 814 */
 815 void SendCSQCInfo(void)
 816 {
 817         float i;
 818         if(clienttype(self) != CLIENTTYPE_REAL)
 819                 return;
 820         msg_entity = self;
 821         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 822         WriteByte(MSG_ONE, TE_CSQC_INIT);
 823         WriteShort(MSG_ONE, CSQC_REVISION);
 824         WriteByte(MSG_ONE, maxclients);
 825         for(i = 1; i <= 24; ++i)
 826                 WriteByte(MSG_ONE, (get_weaponinfo(i)).impulse + 1);
 827         WriteCoord(MSG_ONE, hook_shotorigin_x);
 828         WriteCoord(MSG_ONE, hook_shotorigin_y);
 829         WriteCoord(MSG_ONE, hook_shotorigin_z);
 830 }
 831
 832 /*
 833 =============
 834 SetNewParms
 835 =============
 836 */
 837 void SetNewParms (void)
 838 {
 839         // initialize parms for a new player
 840         parm1 = -(86400 * 366);
 841 }
 842
 843 /*
 844 =============
 845 SetChangeParms
 846 =============
 847 */
 848 void SetChangeParms (void)
 849 {
 850         // save parms for level change
 851         parm1 = self.parm_idlesince - time;
 852 }
 853
 854 /*
 855 =============
 856 DecodeLevelParms
 857 =============
 858 */
 859 void DecodeLevelParms (void)
 860 {
 861         // load parms
 862         self.parm_idlesince = parm1;
 863         if(self.parm_idlesince == -(86400 * 366))
 864                 self.parm_idlesince = time;
 865 }
 866
 867 /*
 868 =============
 869 ClientKill
 870
 871 Called when a client types 'kill' in the console
 872 =============
 873 */
 874
 875 void ClientKill_Now_TeamChange()
 876 {
 877         if(self.killindicator_teamchange == -1)
 878         {
 879                 self.team = -1;
 880                 JoinBestTeam( self, FALSE, FALSE );
 881         }
 882         else
 883         {
 884                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 885         }
 886 }
 887
 888 void ClientKill_Now()
 889 {
 890         if(self.killindicator_teamchange)
 891                 ClientKill_Now_TeamChange();
 892
 893         // in any case:
 894         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 895
 896         if(self.killindicator)
 897         {
 898                 dprint("Cleaned up after a leaked kill indicator.\n");
 899                 remove(self.killindicator);
 900                 self.killindicator = world;
 901         }
 902 }
 903 void KillIndicator_Think()
 904 {
 905         if (!self.owner.modelindex)
 906         {
 907                 self.owner.killindicator = world;
 908                 remove(self);
 909                 return;
 910         }
 911
 912         if(self.cnt <= 0)
 913         {
 914                 self = self.owner;
 915                 ClientKill_Now(); // no oldself needed
 916                 return;
 917         }
 918         else
 919         {
 920                 if(self.cnt <= 10)
 921                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 922                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 923                 {
 924                         if(self.cnt <= 10)
 925                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".wav"));
 926                         if(self.owner.killindicator_teamchange)
 927                         {
 928                                 if(self.owner.killindicator_teamchange == -1)
 929                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 930                                 else
 931                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 932                         }
 933                         else
 934                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 935                 }
 936                 self.nextthink = time + 1;
 937                 self.cnt -= 1;
 938         }
 939 }
 940
 941 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 942 {
 943         float killtime;
 944         entity e;
 945         killtime = cvar("g_balance_kill_delay");
 946
 947         self.killindicator_teamchange = targetteam;
 948
 949         if(!self.killindicator)
 950         {
 951                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 952                 {
 953                         ClientKill_Now();
 954                 }
 955                 else
 956                 {
 957                         self.killindicator = spawn();
 958                         self.killindicator.owner = self;
 959                         self.killindicator.scale = 0.5;
 960                         setattachment(self.killindicator, self, "");
 961                         setorigin(self.killindicator, '0 0 52');
 962                         self.killindicator.think = KillIndicator_Think;
 963                         self.killindicator.nextthink = time + (self.lip) * 0.05;
 964                         self.killindicator.cnt = ceil(killtime);
 965                         self.killindicator.count = bound(0, ceil(killtime), 10);
 966                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 967
 968                         for(e = world; (e = find(e, classname, "body")) != world; )
 969                         {
 970                                 if(e.enemy != self)
 971                                         continue;
 972                                 e.killindicator = spawn();
 973                                 e.killindicator.owner = e;
 974                                 e.killindicator.scale = 0.5;
 975                                 setattachment(e.killindicator, e, "");
 976                                 setorigin(e.killindicator, '0 0 52');
 977                                 e.killindicator.think = KillIndicator_Think;
 978                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
 979                                 e.killindicator.cnt = ceil(killtime);
 980                         }
 981                         self.lip = 0;
 982                 }
 983         }
 984         if(self.killindicator)
 985         {
 986                 if(targetteam)
 987                         self.killindicator.colormod = TeamColor(targetteam);
 988                 else
 989                         self.killindicator.colormod = '0 0 0';
 990         }
 991 }
 992
 993 void ClientKill (void)
 994 {
 995         ClientKill_TeamChange(0);
 996 }
 997
 998 void DoTeamChange(float destteam)
 999 {
1000         float t, c0;
1001         if(!cvar("teamplay"))
1002         {
1003                 if(destteam >= 0)
1004                         SetPlayerColors(self, destteam);
1005                 return;
1006         }
1007         if(self.classname == "player")
1008         if(destteam == -1)
1009         {
1010                 CheckAllowedTeams(self);
1011                 t = FindSmallestTeam(self, TRUE);
1012                 switch(self.team)
1013                 {
1014                         case COLOR_TEAM1: c0 = c1; break;
1015                         case COLOR_TEAM2: c0 = c2; break;
1016                         case COLOR_TEAM3: c0 = c3; break;
1017                         case COLOR_TEAM4: c0 = c4; break;
1018                         default:          c0 = 999;
1019                 }
1020                 switch(t)
1021                 {
1022                         case 1:
1023                                 if(c0 > c1)
1024                                         destteam = COLOR_TEAM1;
1025                                 break;
1026                         case 2:
1027                                 if(c0 > c2)
1028                                         destteam = COLOR_TEAM2;
1029                                 break;
1030                         case 3:
1031                                 if(c0 > c3)
1032                                         destteam = COLOR_TEAM3;
1033                                 break;
1034                         case 4:
1035                                 if(c0 > c4)
1036                                         destteam = COLOR_TEAM4;
1037                                 break;
1038                 }
1039                 if(destteam == -1)
1040                         return;
1041         }
1042         if(destteam == self.team && !self.killindicator)
1043                 return;
1044         ClientKill_TeamChange(destteam);
1045 }
1046
1047 void FixClientCvars(entity e)
1048 {
1049         // send prediction settings to the client
1050         stuffcmd(e, "\nin_bindmap 0 0\n");
1051         /*
1052          * we no longer need to stuff this. Remove this comment block if you feel
1053          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1054         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1055         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1056         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1057         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1058         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1059         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1060         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1061         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1062         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1063         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1064         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1065         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1066         stuffcmd(e, "cl_movement_edgefriction 1\n");
1067          */
1068 }
1069
1070 .float fog_set;
1071 void SendFog()
1072 {
1073         if(clienttype(self) == CLIENTTYPE_REAL)
1074         if(world.fog) // NOT string_null!
1075         {
1076                 if(!self.fog_set)
1077                 {
1078                         if(sv_foginterval)
1079                         {
1080                                 msg_entity = self;
1081                                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
1082                                 WriteByte(MSG_ONE, TE_CSQC_FOG);
1083                                 WriteCoord(MSG_ONE, sv_foginterval);
1084                                 WriteString(MSG_ONE, world.fog);
1085                         }
1086                         else
1087                                 // set it once
1088                                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1089
1090                         self.fog_set = 1;
1091                 }
1092         }
1093 }
1094
1095 /*
1096 =============
1097 ClientConnect
1098
1099 Called when a client connects to the server
1100 =============
1101 */
1102 //void ctf_clientconnect();
1103 string ColoredTeamName(float t);
1104 void DecodeLevelParms (void);
1105 //void dom_player_join_team(entity pl);
1106 void ClientConnect (void)
1107 {
1108         local string s;
1109
1110         if(self.flags & FL_CLIENT)
1111         {
1112                 print("Warning: ClientConnect, but already connected!\n");
1113                 return;
1114         }
1115
1116         if(Ban_MaybeEnforceBan(self))
1117                 return;
1118
1119         DecodeLevelParms();
1120
1121         self.classname = "player_joining";
1122
1123         self.flags = self.flags | FL_CLIENT;
1124         self.version_nagtime = time + 10 + random() * 10;
1125
1126         if(player_count<0)
1127         {
1128                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1129                 player_count = 0;
1130         }
1131
1132         PlayerScore_Attach(self);
1133
1134         bot_clientconnect();
1135
1136         race_PreSpawnObserver();
1137
1138         //if(g_domination)
1139         //      dom_player_join_team(self);
1140
1141         //JoinBestTeam(self, FALSE, FALSE);
1142         //
1143         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1144                 self.classname = "observer";
1145         } else {
1146                 self.classname = "player";
1147                 campaign_bots_may_start = 1;
1148         }
1149
1150         self.playerid = (playerid_last = playerid_last + 1);
1151         if(cvar("sv_eventlog"))
1152         {
1153                 if(clienttype(self) == CLIENTTYPE_REAL)
1154                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", self.netaddress, ":", self.netname));
1155                 else
1156                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":bot:", self.netname));
1157                 s = strcat(":team:", ftos(self.playerid), ":");
1158                 s = strcat(s, ftos(self.team));
1159                 GameLogEcho(s);
1160         }
1161         self.netname_previous = strzone(self.netname);
1162
1163         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1164
1165         bprint ("^4",self.netname);
1166         bprint ("^4 connected");
1167
1168         if(g_domination || g_ctf)
1169         {
1170                 bprint(" and joined the ");
1171                 bprint(ColoredTeamName(self.team));
1172         }
1173
1174         bprint("\n");
1175
1176         self.welcomemessage_time = 0;
1177
1178         stuffcmd(self, strcat(clientstuff, "\n"));
1179         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1180         stuffcmd(self, "cl_particles_reloadeffects\n");
1181
1182         FixClientCvars(self);
1183
1184         // spawnfunc_waypoint sprites
1185         WaypointSprite_InitClient(self);
1186
1187         // Wazat's grappling hook
1188         SetGrappleHookBindings();
1189
1190         // get autoswitch state from player when he toggles it
1191         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1192
1193         // get version info from player
1194         stuffcmd(self, "cmd clientversion $gameversion\n");
1195
1196         // get other cvars from player
1197         GetCvars(0);
1198
1199         // set cvar for team scoreboard
1200         if (teams_matter)
1201         {
1202                 local float t;
1203                 t = cvar("teamplay");
1204                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1205                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1206         }
1207         else
1208                 stuffcmd(self, "set teamplay 0\n");
1209
1210         // notify about available teams
1211         if(teamplay)
1212         {
1213                 CheckAllowedTeams(self);
1214                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1215                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1216         }
1217         else
1218                 stuffcmd(self, "set _teams_available 0\n");
1219
1220         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1221
1222         if(g_arena)
1223         {
1224                 self.classname = "observer";
1225                 Spawnqueue_Insert(self);
1226         }
1227         /*else if(g_ctf)
1228         {
1229                 ctf_clientconnect();
1230         }*/
1231
1232         if(teams_matter)
1233                 attach_entcs();
1234
1235         bot_relinkplayerlist();
1236
1237         self.spectatortime = time;
1238         if(blockSpectators)
1239         {
1240                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1241         }
1242
1243         self.jointime = time;
1244         self.allowedTimeouts = cvar("sv_timeout_number");
1245
1246         if(clienttype(self) == CLIENTTYPE_REAL)
1247         {
1248                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1249                 SendCSQCInfo();
1250                 msg_entity = self;
1251                 if(mapvote_initialized && !cvar("g_maplist_textonly"))
1252                 {
1253                         MapVote_SendData(MSG_ONE);
1254                         MapVote_UpdateData(MSG_ONE);
1255                 }
1256                 ScoreInfo_Write(MSG_ONE);
1257         }
1258
1259         if(inWarmupStage)
1260         {
1261                 msg_entity = self;
1262                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
1263                 WriteByte(MSG_ONE, TE_CSQC_WARMUP);
1264                 WriteByte(MSG_ONE, 1);
1265         }
1266
1267         if(g_lms)
1268         {
1269                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1270                 {
1271                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1272                         self.frags = -666; // FIXME do we still need this?
1273                 }
1274         }
1275
1276         SendFog();
1277 }
1278
1279 /*
1280 =============
1281 ClientDisconnect
1282
1283 Called when a client disconnects from the server
1284 =============
1285 */
1286 .entity chatbubbleentity;
1287 .entity teambubbleentity;
1288 void ReadyCount();
1289 void ClientDisconnect (void)
1290 {
1291         if not(self.flags & FL_CLIENT)
1292         {
1293                 print("Warning: ClientDisconnect without ClientConnect\n");
1294                 return;
1295         }
1296
1297         bot_clientdisconnect();
1298
1299         if(teams_matter)
1300                 detach_entcs();
1301
1302         if(cvar("sv_eventlog"))
1303                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1304         bprint ("^4",self.netname);
1305         bprint ("^4 disconnected\n");
1306
1307         DropAllRunes(self);
1308         kh_Key_DropAll(self, TRUE);
1309
1310         Portal_ClearAll(self);
1311
1312         if(self.flagcarried)
1313                 DropFlag(self.flagcarried, world, world);
1314
1315         // Here, everything has been done that requires this player to be a client.
1316
1317         self.flags (-) FL_CLIENT;
1318
1319         if (self.chatbubbleentity)
1320                 remove (self.chatbubbleentity);
1321
1322         if (self.teambubbleentity)
1323                 remove (self.teambubbleentity);
1324
1325         if (self.killindicator)
1326                 remove (self.killindicator);
1327
1328         WaypointSprite_PlayerGone();
1329
1330         bot_relinkplayerlist();
1331
1332         // remove laserdot
1333         if(self.weaponentity)
1334                 if(self.weaponentity.lasertarget)
1335                         remove(self.weaponentity.lasertarget);
1336
1337         if(g_arena)
1338         {
1339                 Spawnqueue_Unmark(self);
1340                 Spawnqueue_Remove(self);
1341         }
1342
1343         PlayerScore_Detach(self);
1344
1345         if(self.netname_previous)
1346                 strunzone(self.netname_previous);
1347
1348         ClearPlayerSounds();
1349
1350         self.playerid = 0;
1351         ReadyCount();
1352
1353         // free cvars
1354         GetCvars(-1);
1355 }
1356
1357 .float BUTTON_CHAT;
1358 void ChatBubbleThink()
1359 {
1360         self.nextthink = time;
1361         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1362         {
1363                 if(self.owner) // but why can that ever be world?
1364                         self.owner.chatbubbleentity = world;
1365                 remove(self);
1366                 return;
1367         }
1368         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1369         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1370                 self.model = self.mdl;
1371         else
1372                 self.model = "";
1373 };
1374
1375 void UpdateChatBubble()
1376 {
1377         if (!self.modelindex)
1378                 return;
1379         // spawn a chatbubble entity if needed
1380         if (!self.chatbubbleentity)
1381         {
1382                 self.chatbubbleentity = spawn();
1383                 self.chatbubbleentity.owner = self;
1384                 self.chatbubbleentity.exteriormodeltoclient = self;
1385                 self.chatbubbleentity.think = ChatBubbleThink;
1386                 self.chatbubbleentity.nextthink = time;
1387                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1388                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1389                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1390                 self.chatbubbleentity.model = "";
1391                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1392         }
1393 }
1394
1395
1396 void TeamBubbleThink()
1397 {
1398         self.nextthink = time;
1399         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1400         {
1401                 if(self.owner) // but why can that ever be world?
1402                         self.owner.teambubbleentity = world;
1403                 remove(self);
1404                 return;
1405         }
1406 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1407         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1408                 self.model = "";
1409         else
1410                 self.model = self.mdl;
1411
1412 };
1413
1414 float TeamBubble_customizeentityforclient()
1415 {
1416         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1417 }
1418
1419 void UpdateTeamBubble()
1420 {
1421         if (!self.modelindex || !cvar("teamplay"))
1422                 return;
1423         // spawn a teambubble entity if needed
1424         if (!self.teambubbleentity && cvar("teamplay"))
1425         {
1426                 self.teambubbleentity = spawn();
1427                 self.teambubbleentity.owner = self;
1428                 self.teambubbleentity.exteriormodeltoclient = self;
1429                 self.teambubbleentity.think = TeamBubbleThink;
1430                 self.teambubbleentity.nextthink = time;
1431                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1432 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1433                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1434                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1435                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1436                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1437                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1438                 self.teambubbleentity.effects = EF_LOWPRECISION;
1439         }
1440 }
1441
1442 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1443 // added to the model skins
1444 /*void UpdateColorModHack()
1445 {
1446         local float c;
1447         c = self.clientcolors & 15;
1448         // LordHavoc: only bothering to support white, green, red, yellow, blue
1449              if (teamplay == 0) self.colormod = '0 0 0';
1450         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1451         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1452         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1453         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1454         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1455         else self.colormod = '1 1 1';
1456 };*/
1457
1458 void respawn(void)
1459 {
1460         CopyBody(1);
1461         self.effects |= EF_NODRAW; // prevent another CopyBody
1462         PutClientInServer();
1463 }
1464
1465 /**
1466  * When sv_timeout is used this function returs strings like
1467  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1468  * Called by centerprint functions
1469  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1470  */
1471 string getTimeoutText(float addOneSecond) {
1472         if (!cvar("sv_timeout") || !timeoutStatus)
1473                 return "";
1474
1475         local string retStr;
1476         if (timeoutStatus == 1) {
1477                 if (addOneSecond == 1) {
1478                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1479                 }
1480                 else {
1481                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1482                 }
1483                 return retStr;
1484         }
1485         else if (timeoutStatus == 2) {
1486                 if (addOneSecond) {
1487                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1488                         //don't show messages like "Timeout ends in 0 seconds"...
1489                         if ((remainingTimeoutTime + 1) > 0)
1490                                 return retStr;
1491                         else
1492                                 return "";
1493                 }
1494                 else {
1495                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1496                         //don't show messages like "Timeout ends in 0 seconds"...
1497                         if (remainingTimeoutTime > 0)
1498                                 return retStr;
1499                         else
1500                                 return "";
1501                 }
1502         }
1503         else return "";
1504 }
1505
1506 void player_powerups (void)
1507 {
1508         if (g_minstagib)
1509         {
1510                 if (self.items & IT_STRENGTH)
1511                 {
1512                         if (time > self.strength_finished)
1513                         {
1514                                 if (g_minstagib_invis_alpha > 0)
1515                                 {
1516                                         self.alpha = default_player_alpha;
1517                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1518                                         self.effects = self.effects | EF_FULLBRIGHT;
1519                                 }
1520                                 else
1521                                 {
1522                                         self.effects -= self.effects & EF_NODRAW;
1523                                 }
1524                                 self.items = self.items - (self.items & IT_STRENGTH);
1525                                 sprint(self, "^3Invisibility has worn off\n");
1526                         }
1527                 }
1528                 else
1529                 {
1530                         if (time < self.strength_finished)
1531                         {
1532                                 if (g_minstagib_invis_alpha > 0)
1533                                 {
1534                                         self.alpha = g_minstagib_invis_alpha;
1535                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1536                                         self.effects -= self.effects & EF_FULLBRIGHT;
1537                                 }
1538                                 else
1539                                 {
1540                                         self.effects = self.effects | EF_NODRAW;
1541                                 }
1542                                 self.items = self.items | IT_STRENGTH;
1543                                 sprint(self, "^3You are invisible\n");
1544                         }
1545                 }
1546
1547                 if (self.items & IT_INVINCIBLE)
1548                 {
1549                         if (time > self.invincible_finished)
1550                         {
1551                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1552                                 sprint(self, "^3Speed has worn off\n");
1553                         }
1554                 }
1555                 else
1556                 {
1557                         if (time < self.invincible_finished)
1558                         {
1559                                 self.items = self.items | IT_INVINCIBLE;
1560                                 sprint(self, "^3You are on speed\n");
1561                         }
1562                 }
1563                 return;
1564         }
1565
1566         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1567         if (self.items & IT_STRENGTH)
1568         {
1569                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1570                 if (time > self.strength_finished)
1571                 {
1572                         self.items = self.items - (self.items & IT_STRENGTH);
1573                         sprint(self, "^3Strength has worn off\n");
1574                 }
1575         }
1576         else
1577         {
1578                 if (time < self.strength_finished)
1579                 {
1580                         self.items = self.items | IT_STRENGTH;
1581                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1582                 }
1583         }
1584         if (self.items & IT_INVINCIBLE)
1585         {
1586                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1587                 if (time > self.invincible_finished)
1588                 {
1589                         self.items = self.items - (self.items & IT_INVINCIBLE);
1590                         sprint(self, "^3Shield has worn off\n");
1591                 }
1592         }
1593         else
1594         {
1595                 if (time < self.invincible_finished)
1596                 {
1597                         self.items = self.items | IT_INVINCIBLE;
1598                         sprint(self, "^3Shield surrounds you\n");
1599                 }
1600         }
1601
1602         if (cvar("g_fullbrightplayers"))
1603                 self.effects = self.effects | EF_FULLBRIGHT;
1604
1605         // midair gamemode: damage only while in the air
1606         // if in midair mode, being on ground grants temporary invulnerability
1607         // (this is so that multishot weapon don't clear the ground flag on the
1608         // first damage in the frame, leaving the player vulnerable to the
1609         // remaining hits in the same frame)
1610         if (self.flags & FL_ONGROUND)
1611         if (g_midair)
1612                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1613
1614         if (time >= game_starttime)
1615         if (time < self.spawnshieldtime)
1616                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1617 }
1618
1619 float CalcRegen(float current, float stable, float regenfactor)
1620 {
1621         if(current > stable)
1622                 return current;
1623         else if(current > stable - 0.25) // when close enough, "snap"
1624                 return stable;
1625         else
1626                 return min(stable, current + (stable - current) * regenfactor * frametime);
1627 }
1628
1629 void player_regen (void)
1630 {
1631         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1632         maxh = cvar("g_balance_health_stable");
1633         maxa = cvar("g_balance_armor_stable");
1634         limith = cvar("g_balance_health_limit");
1635         limita = cvar("g_balance_armor_limit");
1636
1637         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1638                 return;
1639
1640         max_mod = regen_mod = rot_mod = limit_mod = 1;
1641
1642         if (self.runes & RUNE_REGEN)
1643         {
1644                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1645                 {
1646                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1647                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1648                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1649                 }
1650                 else
1651                 {
1652                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1653                         max_mod = cvar("g_balance_rune_regen_hpmod");
1654                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1655                 }
1656         }
1657         else if (self.runes & CURSE_VENOM)
1658         {
1659                 max_mod = cvar("g_balance_curse_venom_hpmod");
1660                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1661                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1662                 else
1663                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1664                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1665                 //if (!self.runes & RUNE_REGEN)
1666                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1667         }
1668         maxh = maxh * max_mod;
1669         //maxa = maxa * max_mod;
1670         limith = limith * limit_mod;
1671         limita = limita * limit_mod;
1672
1673         if (self.armorvalue > maxa)
1674         {
1675                 if (time > self.pauserotarmor_finished)
1676                 {
1677                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1678                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1679                 }
1680         }
1681         else if (self.armorvalue < maxa)
1682         {
1683                 if (time > self.pauseregen_finished)
1684                 {
1685                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1686                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1687                 }
1688         }
1689         if (self.health > maxh)
1690         {
1691                 if (time > self.pauserothealth_finished)
1692                 {
1693                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1694                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1695                 }
1696         }
1697         else if (self.health < maxh)
1698         {
1699                 if (time > self.pauseregen_finished)
1700                 {
1701                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1702                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1703                 }
1704         }
1705
1706         if (self.health > limith)
1707                 self.health = limith;
1708         if (self.armorvalue > limita)
1709                 self.armorvalue = limita;
1710
1711         // if player rotted to death...  die!
1712         if(self.health < 1)
1713                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1714 }
1715
1716 .float zoomstate;
1717 float zoomstate_set;
1718 void SetZoomState(float z)
1719 {
1720         if(z != self.zoomstate)
1721         {
1722                 msg_entity = self;
1723                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
1724                 WriteByte(MSG_ONE, TE_CSQC_ZOOMNOTIFY);
1725                 WriteByte(MSG_ONE, z);
1726                 self.zoomstate = z;
1727         }
1728         zoomstate_set = 1;
1729 }
1730
1731 /*
1732 ======================
1733 spectate mode routines
1734 ======================
1735 */
1736 void SpectateCopy(entity spectatee) {
1737         self.armortype = spectatee.armortype;
1738         self.armorvalue = spectatee.armorvalue;
1739         self.currentammo = spectatee.currentammo;
1740         self.effects = spectatee.effects;
1741         self.health = spectatee.health;
1742         self.impulse = 0;
1743         self.items = spectatee.items;
1744         self.weapons = spectatee.weapons;
1745         self.switchweapon = spectatee.switchweapon;
1746         self.weapon = spectatee.weapon;
1747         self.punchangle = spectatee.punchangle;
1748         self.view_ofs = spectatee.view_ofs;
1749         self.v_angle = spectatee.v_angle;
1750         self.velocity = spectatee.velocity;
1751         self.dmg_take = spectatee.dmg_take;
1752         self.dmg_save = spectatee.dmg_save;
1753         self.dmg_inflictor = spectatee.dmg_inflictor;
1754         self.angles = spectatee.v_angle;
1755         self.fixangle = TRUE;
1756         setorigin(self, spectatee.origin);
1757         setsize(self, spectatee.mins, spectatee.maxs);
1758         SetZoomState(spectatee.zoomstate);
1759 }
1760
1761 float SpectateUpdate() {
1762         if(!self.enemy)
1763                 return 0;
1764
1765         if (self == self.enemy)
1766                 return 0;
1767
1768         if(self.enemy.flags & FL_NOTARGET)
1769                 return 0;
1770
1771         SpectateCopy(self.enemy);
1772
1773         return 1;
1774 }
1775
1776 float SpectateNext() {
1777         other = find(self.enemy, classname, "player");
1778         if (!other) {
1779                 other = find(other, classname, "player");
1780         }
1781         if (other) {
1782                 self.enemy = other;
1783         }
1784         if(self.enemy.classname == "player") {
1785                 msg_entity = self;
1786                 WriteByte(MSG_ONE, SVC_SETVIEW);
1787                 WriteEntity(MSG_ONE, self.enemy);
1788                 self.wantswelcomemessage = 1;
1789                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1790                 if(!SpectateUpdate())
1791                         PutObserverInServer();
1792                 return 1;
1793         } else {
1794                 return 0;
1795         }
1796 }
1797
1798 /*
1799 =============
1800 ShowRespawnCountdown()
1801
1802 Update a respawn countdown display.
1803 =============
1804 */
1805 void ShowRespawnCountdown()
1806 {
1807         float number;
1808         if(self.deadflag == DEAD_NO) // just respawned?
1809                 return;
1810         else
1811         {
1812                 number = ceil(self.death_time - time);
1813                 if(number <= 0)
1814                         return;
1815                 if(number <= self.respawn_countdown)
1816                 {
1817                         self.respawn_countdown = number - 1;
1818                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1819                                 announce(self, strcat("announcer/robotic/", ftos(number), ".wav"));
1820                 }
1821         }
1822 }
1823
1824 void LeaveSpectatorMode()
1825 {
1826         if(isJoinAllowed()) {
1827                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1828                         self.classname = "player";
1829                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1830                                 JoinBestTeam(self, FALSE, TRUE);
1831                         if(cvar("g_campaign"))
1832                                 campaign_bots_may_start = 1;
1833                         PutClientInServer();
1834                         if(!(self.flags & FL_NOTARGET))
1835                                 bprint ("^4", self.netname, "^4 is playing now\n");
1836                         centerprint(self,"");
1837                         return;
1838                 } else {
1839                         stuffcmd(self,"menu_showteamselect\n");
1840                         return;
1841                 }
1842         }
1843         else {
1844                 //player may not join because of g_maxplayers is set
1845                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1846         }
1847 }
1848
1849 /**
1850  * Determines whether the player is allowed to join. This depends on cvar
1851  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1852  * it checks whether the number of currently playing players exceeds g_maxplayers.
1853  * @return bool TRUE if the player is allowed to join, false otherwise
1854  */
1855 float isJoinAllowed() {
1856         if (!cvar("g_maxplayers"))
1857                 return TRUE;
1858
1859         local entity e;
1860         local float currentlyPlaying;
1861         FOR_EACH_REALPLAYER(e) {
1862                 if(e.classname == "player")
1863                         currentlyPlaying += 1;
1864         }
1865         if(currentlyPlaying < cvar("g_maxplayers"))
1866                 return TRUE;
1867
1868         return FALSE;
1869 }
1870
1871 /**
1872  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1873  * g_maxplayers_spectator_blocktime seconds
1874  */
1875 void checkSpectatorBlock() {
1876         if(self.classname == "spectator" || self.classname == "observer") {
1877                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1878                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1879                         dropclient(self);
1880                 }
1881         }
1882 }
1883
1884 float vercmp_recursive(string v1, string v2)
1885 {
1886         float dot1, dot2;
1887         string s1, s2;
1888         float r;
1889
1890         dot1 = strstrofs(v1, ".", 0);
1891         dot2 = strstrofs(v2, ".", 0);
1892         if(dot1 == -1)
1893                 s1 = v1;
1894         else
1895                 s1 = substring(v1, 0, dot1);
1896         if(dot2 == -1)
1897                 s2 = v2;
1898         else
1899                 s2 = substring(v2, 0, dot2);
1900
1901         r = stof(s1) - stof(s2);
1902         if(r != 0)
1903                 return r;
1904
1905         r = strcasecmp(s1, s2);
1906         if(r != 0)
1907                 return r;
1908
1909         if(dot1 == -1)
1910                 if(dot2 == -1)
1911                         return 0;
1912                 else
1913                         return -1;
1914         else
1915                 if(dot2 == -1)
1916                         return 1;
1917                 else
1918                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1919 }
1920
1921 float vercmp(string v1, string v2)
1922 {
1923         if(strcasecmp(v1, v2) == 0) // early out check
1924                 return 0;
1925         return vercmp_recursive(v1, v2);
1926 }
1927
1928 void ObserverThink()
1929 {
1930         if (self.flags & FL_JUMPRELEASED) {
1931                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1932                         self.welcomemessage_time = 0;
1933                         self.flags = self.flags - FL_JUMPRELEASED;
1934                         LeaveSpectatorMode();
1935                         return;
1936                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
1937                         self.welcomemessage_time = 0;
1938                         self.flags = self.flags - FL_JUMPRELEASED;
1939                         if(SpectateNext() == 1) {
1940                                 self.classname = "spectator";
1941                         }
1942                 }
1943         } else {
1944                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
1945                         self.flags = self.flags | FL_JUMPRELEASED;
1946                 }
1947         }
1948         /*
1949         if(self.BUTTON_ZOOM)
1950                 self.wantswelcomemessage = 0;
1951         */
1952         if(self.wantswelcomemessage)
1953                 PrintWelcomeMessage(self);
1954 }
1955
1956 void SpectatorThink()
1957 {
1958         if (self.flags & FL_JUMPRELEASED) {
1959                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1960                         self.welcomemessage_time = 0;
1961                         self.flags = self.flags - FL_JUMPRELEASED;
1962                         LeaveSpectatorMode();
1963                         return;
1964                 } else if(self.BUTTON_ATCK) {
1965                         self.welcomemessage_time = 0;
1966                         self.flags = self.flags - FL_JUMPRELEASED;
1967                         if(SpectateNext() == 1) {
1968                                 self.classname = "spectator";
1969                         } else {
1970                                 self.classname = "observer";
1971                                 PutClientInServer();
1972                         }
1973                 } else if (self.BUTTON_ATCK2) {
1974                         self.welcomemessage_time = 0;
1975                         self.flags = self.flags - FL_JUMPRELEASED;
1976                         self.classname = "observer";
1977                         PutClientInServer();
1978                 } else {
1979                         if(!SpectateUpdate())
1980                                 PutObserverInServer();
1981                 }
1982         } else {
1983                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
1984                         self.flags = self.flags | FL_JUMPRELEASED;
1985                 }
1986         }
1987         /*
1988         if(self.BUTTON_ZOOM)
1989                 self.wantswelcomemessage = 0;
1990         */
1991         if(self.wantswelcomemessage)
1992                 PrintWelcomeMessage(self);
1993         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1994 }
1995
1996 /*
1997 =============
1998 PlayerPreThink
1999
2000 Called every frame for each client before the physics are run
2001 =============
2002 */
2003 void() ctf_setstatus;
2004 .float spectatee_status;
2005 void PlayerPreThink (void)
2006 {
2007         self.stat_sys_ticrate = cvar("sys_ticrate");
2008         self.stat_game_starttime = game_starttime;
2009
2010         if(blockSpectators)
2011                 checkSpectatorBlock();
2012
2013         zoomstate_set = 0;
2014
2015         if(self.netname_previous != self.netname)
2016         {
2017                 if(cvar("sv_eventlog"))
2018                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2019                 if(self.netname_previous)
2020                         strunzone(self.netname_previous);
2021                 self.netname_previous = strzone(self.netname);
2022         }
2023
2024         // version nagging
2025         if(self.version_nagtime)
2026                 if(self.cvar_g_nexuizversion)
2027                         if(time > self.version_nagtime)
2028                         {
2029                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
2030                                 {
2031                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
2032                                         {
2033                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2034                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2035                                         }
2036                                         else
2037                                         {
2038                                                 float r;
2039                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
2040                                                 if(r < 0)
2041                                                 {
2042                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
2043                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
2044                                                 }
2045                                                 else if(r > 0)
2046                                                 {
2047                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2048                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2049                                                 }
2050                                         }
2051                                 }
2052                                 self.version_nagtime = 0;
2053                         }
2054
2055         // GOD MODE info
2056         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2057         {
2058                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2059                 self.max_armorvalue = 0;
2060         }
2061
2062         if(frametime)
2063         {
2064                 SendFog();
2065                 antilag_record(self);
2066         }
2067
2068         if(self.classname == "player") {
2069 //              if(self.netname == "Wazat")
2070 //                      bprint(self.classname, "\n");
2071
2072                 CheckRules_Player();
2073
2074                 if(self.BUTTON_INFO)
2075                         PrintWelcomeMessage(self);
2076
2077                 if(g_lms || !cvar("sv_spectate"))
2078                 if((time - self.jointime) <= cvar("welcome_message_time"))
2079                         PrintWelcomeMessage(self);
2080
2081                 if (intermission_running)
2082                 {
2083                         IntermissionThink ();   // otherwise a button could be missed between
2084                         return;                                 // the think tics
2085                 }
2086
2087                 if(self.teleport_time)
2088                 if(time > self.teleport_time)
2089                 {
2090                         self.teleport_time = 0;
2091                         self.effects = self.effects - (self.effects & EF_NODRAW);
2092                         if(self.weaponentity)
2093                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
2094                 }
2095
2096                 Nixnex_GiveCurrentWeapon();
2097
2098                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2099                         UpdateSelectedPlayer();
2100
2101                 //don't allow the player to turn around while game is paused!
2102                 if(timeoutStatus == 2) {
2103                         self.v_angle = self.lastV_angle;
2104                         self.angles = self.lastV_angle;
2105                         self.fixangle = TRUE;
2106                 }
2107
2108                 if (self.deadflag != DEAD_NO)
2109                 {
2110                         float button_pressed, force_respawn;
2111                         player_anim();
2112                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2113                         force_respawn = (g_lms || cvar("g_forced_respawn"));
2114                         if (self.deadflag == DEAD_DYING)
2115                         {
2116                                 if(force_respawn)
2117                                         self.deadflag = DEAD_RESPAWNING;
2118                                 else if(!button_pressed)
2119                                         self.deadflag = DEAD_DEAD;
2120                         }
2121                         else if (self.deadflag == DEAD_DEAD)
2122                         {
2123                                 if(button_pressed)
2124                                         self.deadflag = DEAD_RESPAWNABLE;
2125                         }
2126                         else if (self.deadflag == DEAD_RESPAWNABLE)
2127                         {
2128                                 if(!button_pressed)
2129                                         self.deadflag = DEAD_RESPAWNING;
2130                         }
2131                         else if (self.deadflag == DEAD_RESPAWNING)
2132                         {
2133                                 if(time > self.death_time)
2134                                 {
2135                                         self.death_time = time + 1; // only retry once a second
2136                                         respawn();
2137                                 }
2138                         }
2139                         ShowRespawnCountdown();
2140                         return;
2141                 }
2142
2143                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2144                 {
2145                         vector dist;
2146
2147                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2148                         dist = self.oldorigin - self.origin;
2149                         dist_z = 0;
2150                         self.lms_traveled_distance += fabs(vlen(dist));
2151
2152                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2153                         {
2154                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2155                                 self.lms_traveled_distance = 0;
2156                         }
2157
2158                         if(time > self.lms_nextcheck)
2159                         {
2160                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2161                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2162                                 {
2163                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2164                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2165                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2166                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2167                                 }
2168                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2169                                 self.lms_traveled_distance = 0;
2170                         }
2171                 }
2172
2173                 if (self.BUTTON_CROUCH && !self.hook.state)
2174                 {
2175                         if (!self.crouch)
2176                         {
2177                                 self.crouch = TRUE;
2178                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2179                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2180                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
2181                         }
2182                 }
2183                 else
2184                 {
2185                         if (self.crouch)
2186                         {
2187                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2188                                 if (!trace_startsolid)
2189                                 {
2190                                         self.crouch = FALSE;
2191                                         self.view_ofs = PL_VIEW_OFS;
2192                                         setsize (self, PL_MIN, PL_MAX);
2193                                 }
2194                         }
2195                 }
2196
2197                 FixPlayermodel();
2198
2199                 GrapplingHookFrame();
2200
2201                 W_WeaponFrame();
2202
2203                 player_powerups();
2204                 player_regen();
2205                 player_anim();
2206
2207                 if (g_minstagib)
2208                         minstagib_ammocheck();
2209
2210                 ctf_setstatus();
2211                 kh_setstatus();
2212
2213                 //self.angles_y=self.v_angle_y + 90;   // temp
2214
2215                 //if (TetrisPreFrame()) return;
2216         } else if(gameover) {
2217                 if (intermission_running)
2218                         IntermissionThink ();   // otherwise a button could be missed between
2219                 return;
2220         } else if(self.classname == "observer") {
2221                 ObserverThink();
2222         } else if(self.classname == "spectator") {
2223                 SpectatorThink();
2224         }
2225
2226         if(!zoomstate_set)
2227                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2228
2229         float oldspectatee_status;
2230         oldspectatee_status = self.spectatee_status;
2231         if(self.classname == "spectator")
2232                 self.spectatee_status = num_for_edict(self.enemy);
2233         else if(self.classname == "observer")
2234                 self.spectatee_status = num_for_edict(self);
2235         else
2236                 self.spectatee_status = 0;
2237         if(self.spectatee_status != oldspectatee_status)
2238         {
2239                 msg_entity = self;
2240                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
2241                 WriteByte(MSG_ONE, TE_CSQC_SPECTATING);
2242                 WriteByte(MSG_ONE, self.spectatee_status);
2243                 if(g_race)
2244                         race_InitSpectator();
2245         }
2246
2247         if(self.teamkill_soundtime)
2248         if(time > self.teamkill_soundtime)
2249         {
2250                 self.teamkill_soundtime = 0;
2251
2252                 entity oldpusher, oldself;
2253
2254                 oldself = self; self = self.teamkill_soundsource;
2255                 oldpusher = self.pusher; self.pusher = oldself;
2256
2257                 VoiceMessage("teamshoot_auto");
2258
2259                 self.pusher = oldpusher;
2260                 self = oldself;
2261         }
2262
2263         target_voicescript_next(self);
2264 }
2265
2266
2267 /*
2268 =============
2269 PlayerPostThink
2270
2271 Called every frame for each client after the physics are run
2272 =============
2273 */
2274 .float idlekick_lasttimeleft;
2275 .float race_penalty;
2276 .float race_penalty_nagged;
2277 .float race_penalty_nagtime;
2278 void PlayerPostThink (void)
2279 {
2280         // Savage: Check for nameless players
2281         if (strlen(self.netname) < 1) {
2282                 self.netname = "Player";
2283                 stuffcmd(self, "seta _cl_name Player\n");
2284         }
2285
2286         if(sv_maxidle)
2287         {
2288                 float timeleft;
2289                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2290                 if(timeleft <= 0)
2291                 {
2292                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2293                         announce(self, "announcer/robotic/terminated.wav");
2294                         dropclient(self);
2295                         return;
2296                 }
2297                 else if(timeleft <= 10)
2298                 {
2299                         if(timeleft != self.idlekick_lasttimeleft)
2300                         {
2301                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2302                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".wav"));
2303                         }
2304                 }
2305                 else
2306                 {
2307                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2308                 }
2309                 self.idlekick_lasttimeleft = timeleft;
2310         }
2311
2312         if(self.classname == "player") {
2313                 CheckRules_Player();
2314                 UpdateChatBubble();
2315                 UpdateTeamBubble();
2316                 if (self.impulse)
2317                         ImpulseCommands();
2318                 if (intermission_running)
2319                         return;         // intermission or finale
2320
2321                 //PrintWelcomeMessage(self);
2322                 //if (TetrisPostFrame()) return;
2323
2324                 // restart countdown
2325                         if(time < game_starttime) {
2326                                 if (!cvar("sv_ready_restart_after_countdown"))
2327                                 {
2328                                         if(self.movement != '0 0 0' && g_race && !g_race_qualifying)
2329                                         {
2330                                                 if(time < game_starttime - 2)
2331                                                 {
2332                                                         if(!self.race_penalty_nagged)
2333                                                         {
2334                                                                 // TODO better notification for this!
2335                                                                 self.race_penalty_nagtime = 0;
2336                                                                 self.race_penalty_nagged = 1;
2337                                                         }
2338                                                 }
2339                                                 else if(!self.race_penalty)
2340                                                 {
2341                                                         self.race_penalty_nagtime = 0;
2342                                                         self.race_penalty = time + 5;
2343                                                 }
2344                                         }
2345                                         if(time > self.race_penalty_nagtime)
2346                                         {
2347                                                 if(self.race_penalty > time)
2348                                                 {
2349                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1FIVE SECONDS PENALTY.");
2350                                                 }
2351                                                 else if(self.race_penalty_nagged && time < game_starttime - 2)
2352                                                 {
2353                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1DO NOT MOVE DURING THE COUNTDOWN.");
2354                                                 }
2355                                                 self.race_penalty_nagtime = time + self.cvar_scr_centertime * 0.6;
2356                                         }
2357                                         self.movetype = MOVETYPE_NONE;
2358                                         self.velocity = '0 0 0';
2359                                         self.avelocity = '0 0 0';
2360                                         self.movement = '0 0 0';
2361                                 }
2362                         }
2363                         else if (time < self.race_penalty)
2364                         {
2365                                 self.movetype = MOVETYPE_NONE;
2366                                 self.velocity = '0 0 0';
2367                                 self.avelocity = '0 0 0';
2368                                 self.movement = '0 0 0';
2369                         }
2370                         else
2371                         {
2372                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2373                                 if (!cvar("sv_ready_restart_after_countdown"))
2374                                 {
2375                                         if(self.movetype == MOVETYPE_NONE)
2376                                         {
2377                                                 self.movetype = MOVETYPE_WALK;
2378                                         }
2379                                         self.race_penalty = 0;
2380                                         self.race_penalty_nagged = 0;
2381                                 }
2382                         }
2383
2384         } else if (self.classname == "observer") {
2385                 //do nothing
2386         } else if (self.classname == "spectator") {
2387                 //do nothing
2388         }
2389
2390         /*
2391         float i;
2392         for(i = 0; i < 1000; ++i)
2393         {
2394                 vector end;
2395                 end = self.origin + '0 0 1024' + 512 * randomvec();
2396                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2397                 if(trace_fraction < 1)
2398                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2399                 {
2400                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2401                         break;
2402                 }
2403         }
2404         */
2405
2406         Arena_Warmup();
2407
2408         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2409 }