data/qcsrc/server/cl_client.qc

   1 void info_player_survivor (void)
   2 {
   3         info_player_deathmatch();
   4 }
   5
   6 void info_player_start (void)
   7 {
   8         info_player_deathmatch();
   9 }
  10
  11 void info_player_deathmatch (void)
  12 {
  13         self.classname = "info_player_deathmatch";
  14         relocate_spawnpoint();
  15 }
  16
  17 void() spawnpoint_use =
  18 {
  19         if(teams_matter)
  20         if(have_team_spawns)
  21         {
  22                 self.team = activator.team;
  23                 some_spawn_has_been_used = 1;
  24         }
  25 };
  26
  27 float spawn_allbad;
  28 float spawn_allgood;
  29 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  30 {
  31         local entity spot, player, nextspot, previousspot, newfirstspot;
  32         local float pcount;
  33         spot = firstspot;
  34         newfirstspot = world;
  35         previousspot = world;
  36         spawn_allgood = TRUE;
  37         spawn_allbad = TRUE;
  38         while (spot)
  39         {
  40                 nextspot = spot.chain;
  41                 // count team mismatches as bad spots
  42
  43                 local float spotactive;
  44                 spotactive = 1;
  45
  46                 // filter out spots for assault
  47                 if(spot.target != "") {
  48                         local entity ent;
  49                         ent = find(world, targetname, spot.target);
  50                         while(ent) {
  51                                 if(ent.classname == "target_objective")
  52                                         if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  53                                                 spotactive = 0;
  54                                 ent = find(ent, targetname, spot.target);
  55                         }
  56                 }
  57
  58                 if ((!teamcheck || spot.team == teamcheck) && spotactive > 0)
  59                 {
  60                         pcount = 0;
  61                         player = playerlist;
  62                         while (player)
  63                         {
  64                                 if (player != self)
  65                                 if (vlen(player.origin - spot.origin) < mindist)
  66                                         pcount = pcount + 1;
  67                                 player = player.chain;
  68                         }
  69                         if (!pcount)
  70                         {
  71                                 spawn_allbad = FALSE;
  72                                 if (newfirstspot)
  73                                         previousspot.chain = spot;
  74                                 else
  75                                         newfirstspot = spot;
  76                                 previousspot = spot;
  77                                 spot.chain = world;
  78                         }
  79                         else
  80                                 spawn_allgood = FALSE;
  81                 }
  82                 spot = nextspot;
  83         }
  84         // if we couldn't find ANY good points, return world
  85         return newfirstspot;
  86 }
  87
  88 entity Spawn_RandomPoint(entity firstspot)
  89 {
  90         local entity spot;
  91         local float numspots;
  92         // count number of spots
  93         numspots = 0;
  94         spot = firstspot;
  95         while (spot)
  96         {
  97                 numspots = numspots + 1;
  98                 spot = spot.chain;
  99         }
 100         // pick a random one
 101         numspots = numspots * random();
 102         spot = firstspot;
 103         while (spot.chain && numspots >= 1)
 104         {
 105                 numspots = numspots - 1;
 106                 spot = spot.chain;
 107         }
 108         return spot;
 109 }
 110
 111 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
 112 {
 113         local entity best, spot, player;
 114         local float bestrating, rating;
 115         best = world;
 116         bestrating = -1000000;
 117         spot = firstspot;
 118         while (spot)
 119         {
 120                 rating = 1000000000;
 121                 player = playerlist;
 122                 while (player)
 123                 {
 124                         if (player != self)
 125                                 rating = min(rating, vlen(player.origin - spot.origin));
 126                         player = player.chain;
 127                 }
 128                 rating = rating + random() * 16;
 129                 if (bestrating < rating)
 130                 {
 131                         best = spot;
 132                         bestrating = rating;
 133                 }
 134                 spot = spot.chain;
 135         }
 136         return best;
 137 }
 138
 139 /*
 140 =============
 141 SelectSpawnPoint
 142
 143 Finds a point to respawn
 144 =============
 145 */
 146 entity SelectSpawnPoint (float anypoint)
 147 {
 148         local float teamcheck;
 149         local entity firstspot_new;
 150         local entity spot, firstspot, playerlist;
 151
 152         spot = find (world, classname, "testplayerstart");
 153         if (spot)
 154                 return spot;
 155
 156         teamcheck = 0;
 157
 158         if(!anypoint && have_team_spawns)
 159                 teamcheck = self.team;
 160
 161         // get the list of players
 162         playerlist = findchain(classname, "player");
 163         // get the entire list of spots
 164         firstspot = findchain(classname, "info_player_deathmatch");
 165         // filter out the bad ones
 166         // (note this returns the original list if none survived)
 167         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 168         if(!firstspot_new)
 169                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 170         firstspot = firstspot_new;
 171
 172         // there is 50/50 chance of choosing a random spot or the furthest spot
 173         // (this means that roughly every other spawn will be furthest, so you
 174         // usually won't get fragged at spawn twice in a row)
 175         if (arena_roundbased)
 176         {
 177                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 178                 if(firstspot_new)
 179                         firstspot = firstspot_new;
 180                 spot = Spawn_RandomPoint(firstspot);
 181         }
 182         else if (random() > 0.5 || spawn_allbad || spawn_allgood)
 183                 spot = Spawn_RandomPoint(firstspot);
 184         else
 185                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 186
 187         if (!spot)
 188         {
 189                 if(cvar("spawn_debug"))
 190                         GotoNextMap();
 191                 else
 192                 {
 193                         if(some_spawn_has_been_used)
 194                                 return world; // team can't spawn any more, because of actions of other team
 195                         else
 196                                 error("Cannot find a spawn point - please fix the map!");
 197                 }
 198         }
 199
 200         return spot;
 201 }
 202
 203 /*
 204 =============
 205 CheckPlayerModel
 206
 207 Checks if the argument string can be a valid playermodel.
 208 Returns a valid one in doubt.
 209 =============
 210 */
 211 string FallbackPlayerModel = "models/player/marine.zym";
 212 string CheckPlayerModel(string plyermodel) {
 213         if(strlen(plyermodel) < 4)
 214                 return FallbackPlayerModel;
 215         if( substring(plyermodel,0,14) != "models/player/")
 216                 return FallbackPlayerModel;
 217         else if(cvar("sv_servermodelsonly"))
 218         {
 219                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 220                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 221                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 222                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 223                         return FallbackPlayerModel;
 224                 if(!fexists(plyermodel))
 225                         return FallbackPlayerModel;
 226         }
 227         return plyermodel;
 228 }
 229
 230 /*
 231 =============
 232 Client_customizeentityforclient
 233
 234 LOD reduction
 235 =============
 236 */
 237 float Client_customizeentityforclient()
 238 {
 239 #ifdef ALLOW_VARIABLE_LOD
 240         // self: me
 241         // other: the player viewing me
 242         float distance;
 243         float f;
 244
 245         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 246                 return TRUE;
 247
 248         if(other.cvar_cl_playerdetailreduction <= 0)
 249         {
 250                 if(other.cvar_cl_playerdetailreduction <= -2)
 251                         self.modelindex = self.modelindex_lod2;
 252                 else if(other.cvar_cl_playerdetailreduction <= -1)
 253                         self.modelindex = self.modelindex_lod1;
 254                 else
 255                         self.modelindex = self.modelindex_lod0;
 256         }
 257         else
 258         {
 259                 distance = vlen(self.origin - other.origin);
 260                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 261                 if(f > 10000)
 262                         self.modelindex = self.modelindex_lod2;
 263                 else if(f > 5000)
 264                         self.modelindex = self.modelindex_lod1;
 265                 else
 266                         self.modelindex = self.modelindex_lod0;
 267         }
 268 #endif
 269
 270         return TRUE;
 271 }
 272
 273 void UpdatePlayerSounds();
 274 void setmodel_lod(entity e, string modelname)
 275 {
 276 #ifdef ALLOW_VARIABLE_LOD
 277         string s;
 278
 279         // FIXME: this only supports 3-letter extensions
 280         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 281         if(fexists(s))
 282         {
 283                 precache_model(s);
 284                 setmodel(e, s); // players have high precision
 285                 self.modelindex_lod1 = self.modelindex;
 286         }
 287         else
 288                 self.modelindex_lod1 = -1;
 289
 290         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 291         if(fexists(s))
 292         {
 293                 precache_model(s);
 294                 setmodel(e, s); // players have high precision
 295                 self.modelindex_lod2 = self.modelindex;
 296         }
 297         else
 298                 self.modelindex_lod2 = -1;
 299
 300         precache_model(modelname);
 301         setmodel(e, modelname); // players have high precision
 302         self.modelindex_lod0 = self.modelindex;
 303
 304         if(self.modelindex_lod1 < 0)
 305                 self.modelindex_lod1 = self.modelindex;
 306
 307         if(self.modelindex_lod2 < 0)
 308                 self.modelindex_lod2 = self.modelindex;
 309 #else
 310         precache_model(modelname);
 311         setmodel(e, modelname); // players have high precision
 312 #endif
 313         player_setupanimsformodel();
 314         UpdatePlayerSounds();
 315 }
 316
 317 /*
 318 =============
 319 PutObserverInServer
 320
 321 putting a client as observer in the server
 322 =============
 323 */
 324 void PutObserverInServer (void)
 325 {
 326         entity  spot;
 327         spot = SelectSpawnPoint (TRUE);
 328         if(!spot)
 329                 error("No spawnpoints for observers?!?\n");
 330         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 331
 332         if(clienttype(self) == CLIENTTYPE_REAL)
 333         {
 334                 msg_entity = self;
 335                 WriteByte(MSG_ONE, SVC_SETVIEW);
 336                 WriteEntity(MSG_ONE, self);
 337         }
 338
 339         DropAllRunes(self);
 340         kh_Key_DropAll(self, TRUE);
 341
 342         if(self.flagcarried)
 343                 DropFlag(self.flagcarried);
 344
 345         WaypointSprite_PlayerDead();
 346
 347         DistributeFragsAmongTeam(self, self.team, 1);
 348
 349         if(self.frags <= 0 && self.frags > -666 && g_lms && self.killcount != -666)
 350                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 351         else if(self.killcount != -666)
 352                 bprint ("^4", self.netname, "^4 is spectating now\n");
 353
 354         self.classname = "observer";
 355         self.health = -666;
 356         self.takedamage = DAMAGE_NO;
 357         self.solid = SOLID_NOT;
 358         self.movetype = MOVETYPE_NOCLIP;
 359         self.flags = FL_CLIENT | FL_NOTARGET;
 360         self.armorvalue = 666;
 361         self.effects = 0;
 362         self.armorvalue = cvar("g_balance_armor_start");
 363         self.pauserotarmor_finished = 0;
 364         self.pauserothealth_finished = 0;
 365         self.pauseregen_finished = 0;
 366         self.damageforcescale = 0;
 367         self.death_time = 0;
 368         self.dead_frame = 0;
 369         self.deaths = 0;
 370         self.alpha = 0;
 371         self.scale = 0;
 372         self.fade_time = 0;
 373         self.pain_frame = 0;
 374         self.pain_finished = 0;
 375         self.strength_finished = 0;
 376         self.invincible_finished = 0;
 377         self.pushltime = 0;
 378         self.think = SUB_Null;
 379         self.nextthink = 0;
 380         self.hook_time = 0;
 381         self.runes = 0;
 382         self.deadflag = DEAD_NO;
 383         self.angles = spot.angles;
 384         self.angles_z = 0;
 385         self.fixangle = TRUE;
 386         self.crouch = FALSE;
 387
 388         self.view_ofs = PL_VIEW_OFS;
 389         setorigin (self, spot.origin);
 390         setsize (self, '0 0 0', '0 0 0');
 391         self.oldorigin = self.origin;
 392         self.items = 0;
 393         self.model = "";
 394         self.modelindex = 0;
 395         self.weapon = 0;
 396         self.weaponmodel = "";
 397         self.weaponentity = world;
 398         self.killcount = -666;
 399         self.velocity = '0 0 0';
 400         self.avelocity = '0 0 0';
 401         self.punchangle = '0 0 0';
 402         self.punchvector = '0 0 0';
 403         self.oldvelocity = self.velocity;
 404         self.customizeentityforclient = Client_customizeentityforclient;
 405         self.viewzoom = 1;
 406
 407         if(g_arena)
 408         {
 409                 if(self.frags != -2)
 410                 {
 411                         Spawnqueue_Insert(self);
 412                 }
 413                 else
 414                 {
 415                         Spawnqueue_Unmark(self);
 416                         Spawnqueue_Remove(self);
 417                 }
 418         }
 419         else if(!g_lms)
 420                 self.frags = -666;
 421 }
 422
 423 float RestrictSkin(float s)
 424 {
 425         if(!teams_matter)
 426                 return s;
 427         if(s == 6)
 428                 return 6;
 429         return mod(s, 3);
 430 }
 431
 432 void FixPlayermodel()
 433 {
 434         local string defaultmodel;
 435         local float defaultskin;
 436         local vector m1, m2;
 437
 438         if(cvar("sv_defaultcharacter") == 1) {
 439                 defaultmodel = "";
 440                 defaultskin = 0;
 441
 442                 if(teams_matter)
 443                 {
 444                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 445                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 446                 }
 447
 448                 if(defaultmodel == "")
 449                 {
 450                         defaultmodel = cvar_string("sv_defaultplayermodel");
 451                         defaultskin = cvar("sv_defaultplayerskin");
 452                 }
 453
 454                 if (defaultmodel != self.model)
 455                 {
 456                         m1 = self.mins;
 457                         m2 = self.maxs;
 458                         setmodel_lod (self, defaultmodel);
 459                         setsize (self, m1, m2);
 460                 }
 461
 462                 self.skin = defaultskin;
 463         } else {
 464                 if (self.playermodel != self.model)
 465                 {
 466                         self.playermodel = CheckPlayerModel(self.playermodel);
 467                         m1 = self.mins;
 468                         m2 = self.maxs;
 469                         setmodel_lod (self, self.playermodel);
 470                         setsize (self, m1, m2);
 471                 }
 472
 473                 self.skin = RestrictSkin(stof(self.playerskin));
 474         }
 475
 476         if(!teams_matter)
 477                 if(strlen(cvar_string("sv_defaultplayercolors")))
 478                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 479                                 setcolor(self, cvar("sv_defaultplayercolors"));
 480 }
 481
 482 /*
 483 =============
 484 PutClientInServer
 485
 486 Called when a client spawns in the server
 487 =============
 488 */
 489 void PutClientInServer (void)
 490 {
 491         if(clienttype(self) == CLIENTTYPE_BOT)
 492         {
 493                 self.classname = "player";
 494         }
 495         else if(clienttype(self) == CLIENTTYPE_REAL)
 496         {
 497                 msg_entity = self;
 498                 WriteByte(MSG_ONE, SVC_SETVIEW);
 499                 WriteEntity(MSG_ONE, self);
 500         }
 501
 502         // player is dead and becomes observer
 503         if(g_lms && self.frags < 1)
 504                 self.classname = "observer";
 505
 506         if(g_arena)
 507         if(!self.spawned)
 508                 self.classname = "observer";
 509
 510         if(self.classname == "player") {
 511                 entity  spot;
 512
 513                 spot = SelectSpawnPoint (FALSE);
 514                 if(!spot)
 515                 {
 516                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 517                         return; // spawn failed
 518                 }
 519
 520                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 521
 522                 self.classname = "player";
 523                 self.iscreature = TRUE;
 524                 self.movetype = MOVETYPE_WALK;
 525                 self.solid = SOLID_SLIDEBOX;
 526                 self.flags = FL_CLIENT;
 527                 self.takedamage = DAMAGE_AIM;
 528                 if(g_minstagib)
 529                         self.effects = EF_FULLBRIGHT;
 530                 else
 531                         self.effects = 0;
 532                 self.air_finished = time + 12;
 533                 self.dmg = 2;
 534
 535                 self.ammo_shells = start_ammo_shells;
 536                 self.ammo_nails = start_ammo_nails;
 537                 self.ammo_rockets = start_ammo_rockets;
 538                 self.ammo_cells = start_ammo_cells;
 539                 self.health = start_health;
 540                 self.armorvalue = start_armorvalue;
 541                 self.items = start_items;
 542                 self.switchweapon = start_switchweapon;
 543                 self.cnt = start_switchweapon;
 544                 self.weapon = 0;
 545                 self.jump_interval = time;
 546
 547                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 548                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 549                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 550                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 551                 self.damageforcescale = 2;
 552                 self.death_time = 0;
 553                 self.dead_frame = 0;
 554                 self.alpha = 0;
 555                 self.scale = 0;
 556                 self.fade_time = 0;
 557                 self.pain_frame = 0;
 558                 self.pain_finished = 0;
 559                 self.strength_finished = 0;
 560                 self.invincible_finished = 0;
 561                 self.pushltime = 0;
 562                 //self.speed_finished = 0;
 563                 //self.slowmo_finished = 0;
 564                 // players have no think function
 565                 self.think = SUB_Null;
 566                 self.nextthink = 0;
 567                 self.hook_time = 0;
 568
 569                 self.runes = 0;
 570
 571                 self.deadflag = DEAD_NO;
 572
 573                 self.angles = spot.angles;
 574
 575                 self.angles_z = 0; // never spawn tilted even if the spot says to
 576                 self.fixangle = TRUE; // turn this way immediately
 577                 self.velocity = '0 0 0';
 578                 self.avelocity = '0 0 0';
 579                 self.punchangle = '0 0 0';
 580                 self.punchvector = '0 0 0';
 581                 self.oldvelocity = self.velocity;
 582
 583                 self.viewzoom = 0.6;
 584                 self.has_zoomed = 0;
 585
 586                 self.customizeentityforclient = Client_customizeentityforclient;
 587
 588                 self.model = "";
 589                 FixPlayermodel();
 590
 591                 self.crouch = FALSE;
 592                 self.view_ofs = PL_VIEW_OFS;
 593                 setsize (self, PL_MIN, PL_MAX);
 594                 self.spawnorigin = spot.origin;
 595                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 596                 // don't reset back to last position, even if new position is stuck in solid
 597                 self.oldorigin = self.origin;
 598
 599                 if(g_arena)
 600                 {
 601                         Spawnqueue_Remove(self);
 602                         Spawnqueue_Mark(self);
 603                 }
 604
 605                 self.event_damage = PlayerDamage;
 606
 607                 self.bot_attack = TRUE;
 608
 609                 self.statdraintime = time + 5;
 610                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 611
 612                 if(self.killcount == -666) {
 613                         self.killcount = 0;
 614                         if(!g_arena)
 615                         if(!g_lms)
 616                                 self.frags = 0;
 617                 }
 618
 619                 self.cnt = WEP_LASER;
 620                 self.nixnex_lastchange_id = -1;
 621
 622                 CL_SpawnWeaponentity();
 623                 self.alpha = default_player_alpha;
 624                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 625                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 626
 627                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 628                 self.lms_traveled_distance = 0;
 629                 self.speedrunning = FALSE;
 630
 631                 if(cvar("spawn_debug"))
 632                 {
 633                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 634                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 635                 }
 636
 637                 //stuffcmd(self, "chase_active 0");
 638                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 639
 640                 if (cvar("g_spawnsound"))
 641                         sound (self, CHAN_AUTO, "misc/spawn.wav", 1, ATTN_NORM);
 642
 643                 if(g_assault) {
 644                         if(self.team == assault_attacker_team)
 645                                 centerprint(self, "You are attacking!\n");
 646                         else
 647                                 centerprint(self, "You are defending!\n");
 648                 }
 649
 650         } else if(self.classname == "observer") {
 651                 PutObserverInServer ();
 652         }
 653 }
 654
 655 /*
 656 =============
 657 SetNewParms
 658 =============
 659 */
 660 void SetNewParms (void)
 661 {
 662
 663 }
 664
 665 /*
 666 =============
 667 SetChangeParms
 668 =============
 669 */
 670 void SetChangeParms (void)
 671 {
 672
 673 }
 674
 675 /*
 676 =============
 677 ClientKill
 678
 679 Called when a client types 'kill' in the console
 680 =============
 681 */
 682 void ClientKill (void)
 683 {
 684         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 685 }
 686
 687 void FixClientCvars(entity e)
 688 {
 689         float t;
 690         // send prediction settings to the client
 691         stuffcmd(e, "\nin_bindmap 0 0\n");
 692         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
 693         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 694         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 695         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 696         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 697         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 698         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 699         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
 700         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 701         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 702         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 703         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 704         stuffcmd(e, "cl_movement_edgefriction 1\n");
 705
 706         // notify about available teams
 707         if(teamplay)
 708         {
 709                 CheckAllowedTeams(e);
 710                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
 711                 stuffcmd(e, strcat("set _teams_available ", ftos(t), "\n"));
 712         }
 713         else
 714                 stuffcmd(e, "set _teams_available 0\n");
 715 }
 716
 717 /*
 718 =============
 719 ClientConnect
 720
 721 Called when a client connects to the server
 722 =============
 723 */
 724 string ColoredTeamName(float t);
 725 //void dom_player_join_team(entity pl);
 726 void ClientConnect (void)
 727 {
 728         local string s;
 729         float wep;
 730
 731         if(Ban_IsClientBanned(self))
 732         {
 733                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
 734                 dropclient(self);
 735                 bprint(s);
 736                 return;
 737         }
 738
 739         self.classname = "player_joining";
 740         self.flags = self.flags | FL_CLIENT;
 741         self.version_nagtime = time + 10 + random() * 10;
 742
 743         if(player_count<0)
 744         {
 745                 dprint("BUG player count is lower than zero, this cannot happen!\n");
 746                 player_count = 0;
 747         }
 748
 749         bot_clientconnect();
 750
 751         //if(g_domination)
 752         //      dom_player_join_team(self);
 753
 754         //JoinBestTeam(self, FALSE);
 755
 756         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
 757                 self.classname = "observer";
 758         } else {
 759                 self.classname = "player";
 760                 campaign_bots_may_start = 1;
 761         }
 762
 763         self.playerid = (playerid_last = playerid_last + 1);
 764         if(cvar("sv_eventlog"))
 765         {
 766                 if(clienttype(self) == CLIENTTYPE_REAL)
 767                         s = "player";
 768                 else
 769                         s = "bot";
 770                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 771                 s = strcat(":team:", ftos(self.playerid), ":");
 772                 s = strcat(s, ftos(self.team));
 773                 GameLogEcho(s, FALSE);
 774         }
 775
 776         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 777
 778         bprint ("^4",self.netname);
 779         bprint ("^4 connected");
 780
 781         if(g_domination || g_ctf)
 782         {
 783                 bprint(" and joined the ");
 784                 bprint(ColoredTeamName(self.team));
 785         }
 786
 787         bprint("\n");
 788
 789         self.welcomemessage_time = 0;
 790
 791         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 792         // TODO: is this being used for anything else than cd tracks?
 793         // Remember: SVC_CDTRACK exists. Maybe it should be used.
 794
 795         FixClientCvars(self);
 796
 797         // waypoint sprites
 798         WaypointSprite_InitClient(self);
 799
 800         // Wazat's grappling hook
 801         SetGrappleHookBindings();
 802
 803         // get autoswitch state from player when he toggles it
 804         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n");
 805
 806         // get version info from player
 807         stuffcmd(self, "cmd clientversion $gameversion\n");
 808
 809         // send all weapon info strings
 810         stuffcmd(self, "register_bestweapon clear\n"); // clear the Quake stuff
 811         wep = WEP_FIRST;
 812         while (wep <= WEP_LAST)
 813         {
 814                 weapon_action(wep, WR_REGISTER);
 815                 wep = wep + 1;
 816         }
 817
 818         // get other cvars from player
 819         GetCvars(0);
 820
 821         // set cvar for team scoreboard
 822         if (teams_matter)
 823         {
 824                 local float t;
 825                 t = cvar("teamplay");
 826                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
 827                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
 828         }
 829         else
 830                 stuffcmd(self, "set teamplay 0\n");
 831
 832         if(g_lms)
 833         {
 834                 self.frags = LMS_NewPlayerLives();
 835                 if(!self.frags)
 836                         self.frags = -666;
 837         }
 838         else if(g_arena)
 839         {
 840                 self.classname = "observer";
 841                 Spawnqueue_Insert(self);
 842         }
 843
 844         bot_relinkplayerlist();
 845
 846         self.jointime = time;
 847 }
 848
 849 /*
 850 =============
 851 ClientDisconnect
 852
 853 Called when a client disconnects from the server
 854 =============
 855 */
 856 void(entity e) DropFlag;
 857 .entity chatbubbleentity;
 858 .entity teambubbleentity;
 859 void ClientDisconnect (void)
 860 {
 861         float save;
 862         if(cvar("sv_eventlog"))
 863                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
 864         bprint ("^4",self.netname);
 865         bprint ("^4 disconnected\n");
 866
 867         if (self.chatbubbleentity)
 868         {
 869                 remove (self.chatbubbleentity);
 870                 self.chatbubbleentity = world;
 871         }
 872
 873         if (self.teambubbleentity)
 874         {
 875                 remove (self.teambubbleentity);
 876                 self.teambubbleentity = world;
 877         }
 878
 879         WaypointSprite_PlayerGone();
 880
 881         DropAllRunes(self);
 882         kh_Key_DropAll(self, TRUE);
 883
 884         if(self.flagcarried)
 885                 DropFlag(self.flagcarried);
 886
 887         DistributeFragsAmongTeam(self, self.team, 1);
 888
 889         save = self.flags;
 890         self.flags = self.flags - (self.flags & FL_CLIENT);
 891         bot_relinkplayerlist();
 892         self.flags = save;
 893
 894         // remove laserdot
 895         if(self.weaponentity)
 896                 if(self.weaponentity.lasertarget)
 897                         remove(self.weaponentity.lasertarget);
 898
 899         if(g_arena)
 900         {
 901                 Spawnqueue_Unmark(self);
 902                 Spawnqueue_Remove(self);
 903         }
 904
 905         // free cvars
 906         GetCvars(-1);
 907 }
 908
 909 .float buttonchat;
 910 void() ChatBubbleThink =
 911 {
 912         self.nextthink = time;
 913         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 914         {
 915                 self.owner.chatbubbleentity = world;
 916                 remove(self);
 917                 return;
 918         }
 919         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 920         if (self.owner.buttonchat && !self.owner.deadflag)
 921                 self.model = self.mdl;
 922         else
 923                 self.model = "";
 924 };
 925
 926 void() UpdateChatBubble =
 927 {
 928         if (!self.modelindex)
 929                 return;
 930         // spawn a chatbubble entity if needed
 931         if (!self.chatbubbleentity)
 932         {
 933                 self.chatbubbleentity = spawn();
 934                 self.chatbubbleentity.owner = self;
 935                 self.chatbubbleentity.exteriormodeltoclient = self;
 936                 self.chatbubbleentity.think = ChatBubbleThink;
 937                 self.chatbubbleentity.nextthink = time;
 938                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
 939                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 940                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 941                 self.chatbubbleentity.model = "";
 942                 self.chatbubbleentity.effects = EF_LOWPRECISION;
 943         }
 944 }
 945
 946
 947 void() TeamBubbleThink =
 948 {
 949         self.nextthink = time;
 950         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 951         {
 952                 self.owner.teambubbleentity = world;
 953                 remove(self);
 954                 return;
 955         }
 956 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 957         if (self.owner.buttonchat || self.owner.deadflag)
 958                 self.model = "";
 959         else
 960                 self.model = self.mdl;
 961
 962 };
 963
 964 float() TeamBubble_customizeentityforclient
 965 {
 966         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
 967 }
 968
 969 void() UpdateTeamBubble =
 970 {
 971         if (!self.modelindex || !cvar("teamplay"))
 972                 return;
 973         // spawn a teambubble entity if needed
 974         if (!self.teambubbleentity && cvar("teamplay"))
 975         {
 976                 self.teambubbleentity = spawn();
 977                 self.teambubbleentity.owner = self;
 978                 self.teambubbleentity.exteriormodeltoclient = self;
 979                 self.teambubbleentity.think = TeamBubbleThink;
 980                 self.teambubbleentity.nextthink = time;
 981                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
 982 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 983                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 984                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 985                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 986                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 987                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
 988                 self.teambubbleentity.effects = EF_LOWPRECISION;
 989         }
 990 }
 991
 992 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 993 // added to the model skins
 994 /*void() UpdateColorModHack =
 995 {
 996         local float c;
 997         c = self.clientcolors & 15;
 998         // LordHavoc: only bothering to support white, green, red, yellow, blue
 999              if (teamplay == 0) self.colormod = '0 0 0';
1000         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1001         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1002         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1003         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1004         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1005         else self.colormod = '1 1 1';
1006 };*/
1007
1008 void respawn(void)
1009 {
1010         CopyBody(1);
1011         self.effects |= EF_NODRAW; // prevent another CopyBody
1012         PutClientInServer();
1013 }
1014
1015 void player_powerups (void)
1016 {
1017         if (g_minstagib)
1018         {
1019                 if (self.items & IT_STRENGTH)
1020                 {
1021                         if (time > self.strength_finished)
1022                         {
1023                                 if (g_minstagib_invis_alpha > 0)
1024                                 {
1025                                         self.alpha = default_player_alpha;
1026                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1027                                         self.effects = self.effects | EF_FULLBRIGHT;
1028                                 }
1029                                 else
1030                                 {
1031                                         self.effects -= self.effects & EF_NODRAW;
1032                                 }
1033                                 self.items = self.items - (self.items & IT_STRENGTH);
1034                                 sprint(self, "^3Invisibility has worn off\n");
1035                         }
1036                 }
1037                 else
1038                 {
1039                         if (time < self.strength_finished)
1040                         {
1041                                 if (g_minstagib_invis_alpha > 0)
1042                                 {
1043                                         self.alpha = g_minstagib_invis_alpha;
1044                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1045                                         self.effects -= self.effects & EF_FULLBRIGHT;
1046                                 }
1047                                 else
1048                                 {
1049                                         self.effects = self.effects | EF_NODRAW;
1050                                 }
1051                                 self.items = self.items | IT_STRENGTH;
1052                                 sprint(self, "^3You are invisible\n");
1053                         }
1054                 }
1055
1056                 if (self.items & IT_INVINCIBLE)
1057                 {
1058                         if (time > self.invincible_finished)
1059                         {
1060                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1061                                 sprint(self, "^3Speed has worn off\n");
1062                         }
1063                 }
1064                 else
1065                 {
1066                         if (time < self.invincible_finished)
1067                         {
1068                                 self.items = self.items | IT_INVINCIBLE;
1069                                 sprint(self, "^3You are on speed\n");
1070                         }
1071                 }
1072                 return;
1073         }
1074
1075         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1076         if (self.items & IT_STRENGTH)
1077         {
1078                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1079                 if (time > self.strength_finished)
1080                 {
1081                         self.items = self.items - (self.items & IT_STRENGTH);
1082                         sprint(self, "^3Strength has worn off\n");
1083                 }
1084         }
1085         else
1086         {
1087                 if (time < self.strength_finished)
1088                 {
1089                         self.items = self.items | IT_STRENGTH;
1090                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1091                 }
1092         }
1093         if (self.items & IT_INVINCIBLE)
1094         {
1095                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1096                 if (time > self.invincible_finished)
1097                 {
1098                         self.items = self.items - (self.items & IT_INVINCIBLE);
1099                         sprint(self, "^3Shield has worn off\n");
1100                 }
1101         }
1102         else
1103         {
1104                 if (time < self.invincible_finished)
1105                 {
1106                         self.items = self.items | IT_INVINCIBLE;
1107                         sprint(self, "^3Shield surrounds you\n");
1108                 }
1109         }
1110
1111         if (cvar("g_fullbrightplayers"))
1112                 self.effects = self.effects | EF_FULLBRIGHT;
1113
1114         // midair gamemode: damage only while in the air
1115         // if in midair mode, being on ground grants temporary invulnerability
1116         // (this is so that multishot weapon don't clear the ground flag on the
1117         // first damage in the frame, leaving the player vulnerable to the
1118         // remaining hits in the same frame)
1119         if (self.flags & FL_ONGROUND)
1120         if (g_midair)
1121                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1122
1123         if (time < self.spawnshieldtime)
1124                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1125 }
1126
1127 float CalcRegen(float current, float stable, float regenfactor)
1128 {
1129         if(current > stable)
1130                 return current;
1131         else if(current > stable - 0.25) // when close enough, "snap"
1132                 return stable;
1133         else
1134                 return min(stable, current + (stable - current) * regenfactor * frametime);
1135 }
1136
1137 void player_regen (void)
1138 {
1139         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1140         maxh = cvar("g_balance_health_stable");
1141         maxa = cvar("g_balance_armor_stable");
1142         limith = cvar("g_balance_health_limit");
1143         limita = cvar("g_balance_armor_limit");
1144
1145         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1146                 return;
1147
1148         max_mod = regen_mod = rot_mod = limit_mod = 1;
1149
1150         if (self.runes & RUNE_REGEN)
1151         {
1152                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1153                 {
1154                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1155                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1156                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1157                 }
1158                 else
1159                 {
1160                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1161                         max_mod = cvar("g_balance_rune_regen_hpmod");
1162                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1163                 }
1164         }
1165         else if (self.runes & CURSE_VENOM)
1166         {
1167                 max_mod = cvar("g_balance_curse_venom_hpmod");
1168                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1169                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1170                 else
1171                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1172                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1173                 //if (!self.runes & RUNE_REGEN)
1174                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1175         }
1176         maxh = maxh * max_mod;
1177         //maxa = maxa * max_mod;
1178         limith = limith * limit_mod;
1179         limita = limita * limit_mod;
1180
1181         if (self.armorvalue > maxa)
1182         {
1183                 if (time > self.pauserotarmor_finished)
1184                 {
1185                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1186                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1187                 }
1188         }
1189         else if (self.armorvalue < maxa)
1190         {
1191                 if (time > self.pauseregen_finished)
1192                 {
1193                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1194                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1195                 }
1196         }
1197         if (self.health > maxh)
1198         {
1199                 if (time > self.pauserothealth_finished)
1200                 {
1201                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1202                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1203                 }
1204         }
1205         else if (self.health < maxh)
1206         {
1207                 if (time > self.pauseregen_finished)
1208                 {
1209                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1210                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1211                 }
1212         }
1213
1214         if (self.health > limith)
1215                 self.health = limith;
1216         if (self.armorvalue > limita)
1217                 self.armorvalue = limita;
1218
1219         // if player rotted to death...  die!
1220         if(self.health < 1)
1221                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1222 }
1223
1224 /*
1225 ======================
1226 spectate mode routines
1227 ======================
1228 */
1229 void SpectateCopy(entity spectatee) {
1230         self.armortype = spectatee.armortype;
1231         self.armorvalue = spectatee.armorvalue;
1232         self.currentammo = spectatee.currentammo;
1233         self.effects = spectatee.effects;
1234         self.health = spectatee.health;
1235         self.impulse = 0;
1236         self.items = spectatee.items;
1237         self.punchangle = spectatee.punchangle;
1238         self.view_ofs = spectatee.view_ofs;
1239         self.v_angle = spectatee.v_angle;
1240         self.viewzoom = spectatee.viewzoom;
1241         self.velocity = spectatee.velocity;
1242         self.dmg_take = spectatee.dmg_take;
1243         self.dmg_save = spectatee.dmg_save;
1244         self.dmg_inflictor = spectatee.dmg_inflictor;
1245         self.angles = spectatee.v_angle;
1246         self.fixangle = TRUE;
1247         setorigin(self, spectatee.origin);
1248         setsize(self, spectatee.mins, spectatee.maxs);
1249 }
1250
1251 void SpectateUpdate() {
1252         if(!self.enemy)
1253                         PutObserverInServer();
1254
1255         if (self != self.enemy) {
1256                 if(self.enemy.flags & FL_NOTARGET)
1257                         PutObserverInServer();
1258                 SpectateCopy(self.enemy);
1259                 //msg_entity = self;
1260                 //WriteByte(MSG_ONE, SVC_SETANGLE);
1261                 //WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1262                 //WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1263                 //WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1264         }
1265 }
1266
1267 float SpectateNext() {
1268         other = find(self.enemy, classname, "player");
1269         if (!other) {
1270                 other = find(other, classname, "player");
1271         }
1272         if (other) {
1273                 self.enemy = other;
1274         }
1275         if(self.enemy.classname == "player") {
1276                 msg_entity = self;
1277                 WriteByte(MSG_ONE, SVC_SETVIEW);
1278                 WriteEntity(MSG_ONE, self.enemy);
1279                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1280                 SpectateUpdate();
1281                 return 1;
1282         } else {
1283                 return 0;
1284         }
1285 }
1286
1287 /*
1288 =============
1289 ShowRespawnCountdown()
1290
1291 Update a respawn countdown display.
1292 =============
1293 */
1294 void ShowRespawnCountdown()
1295 {
1296         float number;
1297         if(self.deadflag == DEAD_NO) // just respawned?
1298                 return;
1299         else
1300         {
1301                 number = ceil(self.death_time - time);
1302                 if(number <= 0)
1303                         return;
1304                 if(number <= self.respawn_countdown)
1305                 {
1306                         self.respawn_countdown = number - 1;
1307                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1308                                 play2(self, strcat("announcer/robotic/", ftos(number), "announcer/.ogg"));
1309                 }
1310         }
1311 }
1312
1313 void LeaveSpectatorMode()
1314 {
1315         if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1316                 self.classname = "player";
1317                 if(cvar("g_campaign") || cvar("g_balance_teams"))
1318                         JoinBestTeam(self, 0);
1319                 if(cvar("g_campaign"))
1320                         campaign_bots_may_start = 1;
1321                 PutClientInServer();
1322                 if(!(self.flags & FL_NOTARGET))
1323                         bprint ("^4", self.netname, "^4 is playing now\n");
1324                 centerprint(self,"");
1325                 return;
1326         } else {
1327                 stuffcmd(self,"menu_showteamselect\n");
1328                 return;
1329         }
1330 }
1331
1332 /*
1333 =============
1334 PlayerPreThink
1335
1336 Called every frame for each client before the physics are run
1337 =============
1338 */
1339 void() ctf_setstatus;
1340 .float vote_nagtime;
1341 void PlayerPreThink (void)
1342 {
1343         // version nagging
1344         if(self.version_nagtime)
1345                 if(self.cvar_g_nexuizversion)
1346                         if(time > self.version_nagtime)
1347                         {
1348                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1349                                         if(self.cvar_g_nexuizversion != cvar_string("g_nexuizversion"))
1350                                         {
1351                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n");
1352                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n"));
1353                                         }
1354                                 self.version_nagtime = 0;
1355                         }
1356
1357         // vote nagging
1358         if(self.cvar_scr_centertime)
1359                 if(time > self.vote_nagtime)
1360                 {
1361                         VoteNag();
1362                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1363                 }
1364
1365         // GOD MODE info
1366         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
1367         {
1368                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
1369                 self.max_armorvalue = 0;
1370         }
1371
1372         if(frametime)
1373                 antilag_record(self);
1374
1375         if(self.classname == "player") {
1376 //              if(self.netname == "Wazat")
1377 //                      bprint(self.classname, "\n");
1378
1379                 CheckRules_Player();
1380
1381                 if(self.button7)
1382                         PrintWelcomeMessage(self);
1383
1384                 if(g_lms || !cvar("sv_spectate"))
1385                 if((time - self.jointime) <= cvar("welcome_message_time"))
1386                         PrintWelcomeMessage(self);
1387
1388                 if (intermission_running)
1389                 {
1390                         IntermissionThink ();   // otherwise a button could be missed between
1391                         return;                                 // the think tics
1392                 }
1393
1394                 if(self.teleport_time)
1395                 if(time > self.teleport_time)
1396                 {
1397                         self.teleport_time = 0;
1398                         self.effects = self.effects - (self.effects & EF_NODRAW);
1399                         if(self.weaponentity)
1400                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
1401                 }
1402
1403                 Nixnex_GiveCurrentWeapon();
1404
1405                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
1406                         UpdateSelectedPlayer();
1407
1408                 if (self.deadflag != DEAD_NO)
1409                 {
1410                         float button_pressed, force_respawn;
1411                         player_anim();
1412                         button_pressed = (self.button0 || self.button2 || self.button3 || self.button6 || self.buttonuse);
1413                         force_respawn = (g_lms || cvar("g_forced_respawn"));
1414                         if (self.deadflag == DEAD_DYING)
1415                         {
1416                                 if(force_respawn)
1417                                         self.deadflag = DEAD_RESPAWNING;
1418                                 else if(!button_pressed)
1419                                         self.deadflag = DEAD_DEAD;
1420                         }
1421                         else if (self.deadflag == DEAD_DEAD)
1422                         {
1423                                 if(button_pressed)
1424                                         self.deadflag = DEAD_RESPAWNABLE;
1425                         }
1426                         else if (self.deadflag == DEAD_RESPAWNABLE)
1427                         {
1428                                 if(!button_pressed)
1429                                         self.deadflag = DEAD_RESPAWNING;
1430                         }
1431                         else if (self.deadflag == DEAD_RESPAWNING)
1432                         {
1433                                 if(time > self.death_time)
1434                                 {
1435                                         self.death_time = time + 1; // only retry once a second
1436                                         respawn();
1437                                 }
1438                         }
1439                         ShowRespawnCountdown();
1440                         return;
1441                 }
1442
1443                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
1444                 {
1445                         vector dist;
1446
1447                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1448                         dist = self.oldorigin - self.origin;
1449                         dist_z = 0;
1450                         self.lms_traveled_distance += fabs(vlen(dist));
1451
1452                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
1453                         {
1454                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1455                                 self.lms_traveled_distance = 0;
1456                         }
1457
1458                         if(time > self.lms_nextcheck)
1459                         {
1460                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1461                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1462                                 {
1463                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1464                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1465                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1466                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1467                                 }
1468                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1469                                 self.lms_traveled_distance = 0;
1470                         }
1471                 }
1472
1473                 if (self.button5 && !self.hook.state)
1474                 {
1475                         if (!self.crouch)
1476                         {
1477                                 self.crouch = TRUE;
1478                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1479                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1480                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
1481                         }
1482                 }
1483                 else
1484                 {
1485                         if (self.crouch)
1486                         {
1487                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1488                                 if (!trace_startsolid)
1489                                 {
1490                                         self.crouch = FALSE;
1491                                         self.view_ofs = PL_VIEW_OFS;
1492                                         setsize (self, PL_MIN, PL_MAX);
1493                                 }
1494                         }
1495                 }
1496
1497                 FixPlayermodel();
1498
1499                 GrapplingHookFrame();
1500
1501                 W_WeaponFrame();
1502
1503                 {
1504                         float zoomfactor, zoomspeed, zoomdir;
1505                         zoomfactor = self.cvar_cl_zoomfactor;
1506                         if(zoomfactor < 1 || zoomfactor > 16)
1507                                 zoomfactor = 2.5;
1508                         zoomspeed = self.cvar_cl_zoomspeed;
1509                         if(zoomspeed >= 0) // < 0 is instant zoom
1510                                 if(zoomspeed < 0.5 || zoomspeed > 16)
1511                                         zoomspeed = 3.5;
1512
1513                         zoomdir = self.button4;
1514                         if(self.button3)
1515                                 if(self.weapon == WEP_NEX)
1516                                         if(!g_minstagib)
1517                                                 zoomdir = 1;
1518
1519                         if(zoomdir)
1520                                 self.has_zoomed = 1;
1521
1522                         if(self.has_zoomed)
1523                         {
1524                                 if(zoomspeed <= 0) // instant zoom
1525                                 {
1526                                         if(zoomdir)
1527                                                 self.viewzoom = 1 / zoomfactor;
1528                                         else
1529                                                 self.viewzoom = 1;
1530                                 }
1531                                 else
1532                                 {
1533                                         // geometric zoom would be:
1534                                         //   self.viewzoom = bound(1 / zoomfactor, self.viewzoom * pow(zoomfactor, (zoomdir ? -1 : 1) * frametime * zoomspeed), 1);
1535                                         // however, testing showed that arithmetic/harmonic zoom works better
1536                                         if(zoomdir)
1537                                                 // self.viewzoom = 1 / bound(1, 1 / self.viewzoom + (zoomdir ? 1 : -1) * frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
1538                                                 // zoom in = arithmetic: 1x, 2x, 3x, 4x, ..., 8x
1539                                                 self.viewzoom = 1 / bound(1, 1 / self.viewzoom + frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
1540                                         else
1541                                                 // self.viewzoom = bound(1 / zoomfactor, self.viewzoom + (zoomdir ? -1 : 1) * frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
1542                                                 // zoom out = harmonic: 8/1x, 8/2x, 8/3x, 8/4x, ..., 8/8x
1543                                                 self.viewzoom = bound(1 / zoomfactor, self.viewzoom + frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
1544                                 }
1545                         }
1546                         else
1547                                 self.viewzoom = min(1, self.viewzoom + frametime); // spawn zoom-in
1548                 }
1549
1550                 player_powerups();
1551                 player_regen();
1552                 player_anim();
1553
1554                 if (g_minstagib)
1555                         minstagib_ammocheck();
1556
1557                 ctf_setstatus();
1558                 kh_setstatus();
1559
1560                 //self.angles_y=self.v_angle_y + 90;   // temp
1561
1562                 //if (TetrisPreFrame()) return;
1563         } else if(gameover) {
1564                 if (intermission_running)
1565                         IntermissionThink ();   // otherwise a button could be missed between
1566                 return;
1567         } else if(self.classname == "observer") {
1568
1569                 if (self.flags & FL_JUMPRELEASED) {
1570                         if (self.button2 && self.version == cvar("gameversion")) {
1571                                 self.welcomemessage_time = 0;
1572                                 self.flags = self.flags - FL_JUMPRELEASED;
1573                                 LeaveSpectatorMode();
1574                                 return;
1575                         } else if(self.button0 && self.version == cvar("gameversion")) {
1576                                 self.welcomemessage_time = 0;
1577                                 self.flags = self.flags - FL_JUMPRELEASED;
1578                                 if(SpectateNext() == 1) {
1579                                         self.classname = "spectator";
1580                                 }
1581                         }
1582                 } else {
1583                         if (!(self.button0 || self.button2)) {
1584                                 self.flags = self.flags | FL_JUMPRELEASED;
1585                         }
1586                 }
1587                 PrintWelcomeMessage(self);
1588         } else if(self.classname == "spectator") {
1589                 if (self.flags & FL_JUMPRELEASED) {
1590                         if (self.button2 && self.version == cvar("gameversion")) {
1591                                 self.welcomemessage_time = 0;
1592                                 self.flags = self.flags - FL_JUMPRELEASED;
1593                                 LeaveSpectatorMode();
1594                                 return;
1595                         } else if(self.button0) {
1596                                 self.welcomemessage_time = 0;
1597                                 self.flags = self.flags - FL_JUMPRELEASED;
1598                                 if(SpectateNext() == 1) {
1599                                         self.classname = "spectator";
1600                                 } else {
1601                                         self.classname = "observer";
1602                                         PutClientInServer();
1603                                 }
1604                         } else if (self.button3) {
1605                                 self.welcomemessage_time = 0;
1606                                 self.flags = self.flags - FL_JUMPRELEASED;
1607                                 self.classname = "observer";
1608                                 PutClientInServer();
1609                         } else {
1610                                 SpectateUpdate();
1611                         }
1612                 } else {
1613                         if (!(self.button0 || self.button3)) {
1614                                 self.flags = self.flags | FL_JUMPRELEASED;
1615                         }
1616                 }
1617                 PrintWelcomeMessage(self);
1618                 self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1619         }
1620 }
1621
1622
1623 /*
1624 =============
1625 PlayerPostThink
1626
1627 Called every frame for each client after the physics are run
1628 =============
1629 */
1630 void PlayerPostThink (void)
1631 {
1632         // Savage: Check for nameless players
1633         if (strlen(self.netname) < 1) {
1634                 self.netname = "Player";
1635                 stuffcmd(self, "seta _cl_name Player\n");
1636         }
1637
1638         if(self.classname == "player") {
1639                 CheckRules_Player();
1640                 UpdateChatBubble();
1641                 UpdateTeamBubble();
1642                 if (self.impulse)
1643                         ImpulseCommands();
1644                 if (intermission_running)
1645                         return;         // intermission or finale
1646
1647                 //PrintWelcomeMessage(self);
1648                 //if (TetrisPostFrame()) return;
1649
1650                 // restart countdown
1651                 if(time < restart_countdown)
1652                 {
1653                         string s;
1654                         float sec;
1655
1656                         sec = ceil(restart_countdown-time);
1657                         s = strcat(NEWLINES, "^1Game starts in ", ftos(sec), " seconds");
1658                         centerprint(self, s);
1659                         self.movetype = MOVETYPE_NONE;
1660                         self.velocity = '0 0 0';
1661                         self.avelocity = '0 0 0';
1662                         self.movement = '0 0 0';
1663                 }
1664                 else if(self.movetype == MOVETYPE_NONE)
1665                 {
1666                         self.movetype = MOVETYPE_WALK;
1667                         centerprint(self, "\n");
1668                 }
1669         } else if (self.classname == "observer") {
1670                 //do nothing
1671         } else if (self.classname == "spectator") {
1672                 //do nothing
1673         }
1674
1675         Arena_Warmup();
1676 }