data/qcsrc/server/cheats.qc

   1 void CopyBody(float keepvelocity);
   2
   3 #ifdef NOCHEATS
   4
   5 float CheatImpulse(float i) { return 0; }
   6 float CheatCommand(float argc) { return 0; }
   7 float CheatFrame() { return 0; }
   8 void CheatInit() { cheatcount_total = world.cheatcount; }
   9 void CheatShutdown() { }
  10 void CheatInitClient() { }
  11 void CheatShutdownClient() { }
  12 void Drag_MoveDrag(entity from, entity to) { }
  13
  14 #else
  15
  16 .float maycheat;
  17 float sv_cheats;
  18
  19 #define CHIMPULSE_SPEEDRUN_INIT 30
  20 #define CHIMPULSE_GIVE_ALL 99
  21 #define CHIMPULSE_CLONE_MOVING 140
  22 #define CHIMPULSE_SPEEDRUN 141
  23 #define CHIMPULSE_CLONE_STANDING 142
  24 #define CHIMPULSE_TELEPORT 143
  25 #define CHIMPULSE_R00T 148
  26
  27 #define CHRAME_DRAG 8
  28
  29 void CheatInit()
  30 {
  31         sv_cheats = cvar("sv_cheats");
  32 }
  33
  34 void CheatShutdown()
  35 {
  36 }
  37
  38 void CheatInitClient()
  39 {
  40 }
  41
  42 void CheatShutdownClient()
  43 {
  44 }
  45
  46 float CheatsAllowed(float i, float argc, float fr) // the cheat gets passed as argument for possible future ACL checking
  47 {
  48         // dead people cannot cheat
  49         if(self.deadflag != DEAD_NO)
  50                 return 0;
  51         if(self.classname != "player")
  52                 return 0;
  53
  54         // sv_clones
  55         if(i == CHIMPULSE_CLONE_MOVING || i == CHIMPULSE_CLONE_STANDING)
  56                 if(self.lip < sv_clones)
  57                         return 1;
  58
  59         // haha
  60         if(self.maycheat)
  61                 return 1;
  62
  63         // sv_cheats
  64         if(sv_cheats && autocvar_sv_cheats)
  65                 return 1;
  66
  67         // if we get here, player is not allowed to cheat. Log it.
  68         if(i)
  69                 bprint(sprintf("Player %s^7 tried to use cheat 'impulse %d'\n", self.netname, i));
  70         else if(argc)
  71                 bprint(sprintf("Player %s^7 tried to use cheat '%s'\n", self.netname, argv(0)));
  72         else if(fr)
  73                 bprint(sprintf("Player %s^7 tried to use cheat frame %d\n", self.netname, fr));
  74         else
  75                 bprint(sprintf("Player %s^7 tried to use an unknown cheat\n", self.netname));
  76
  77         return 0;
  78 }
  79
  80 #define BEGIN_CHEAT_FUNCTION() \
  81         float cheating, attempting; \
  82         cheating = 0; attempting = 0
  83 #define DID_CHEAT() \
  84         ++cheating
  85 #define ADD_CHEATS(e,n) \
  86         cheatcount_total += n; \
  87         e.cheatcount += n
  88 #define END_CHEAT_FUNCTION() \
  89         ADD_CHEATS(self,cheating); \
  90         return attempting
  91 #define IS_CHEAT(i,argc,fr) \
  92         ++attempting; \
  93         if(!CheatsAllowed(i,argc,fr)) \
  94                 break
  95
  96 float CheatImpulse(float i)
  97 {
  98         BEGIN_CHEAT_FUNCTION();
  99         switch(i)
 100         {
 101                 entity e, e2;
 102                 vector org;
 103
 104                 case CHIMPULSE_SPEEDRUN_INIT: // deploy personal waypoint
 105                         // shared with regular waypoint init, so this is not a cheat by itself
 106                         if(!self.personal)
 107                         {
 108                                 self.personal = spawn();
 109                                 self.personal.classname = "personal_wp";
 110                         }
 111                         self.personal.origin = self.origin;
 112                         self.personal.v_angle = self.v_angle;
 113                         self.personal.velocity = self.velocity;
 114                         self.personal.ammo_rockets = self.ammo_rockets;
 115                         self.personal.ammo_nails = self.ammo_nails;
 116                         self.personal.ammo_cells = self.ammo_cells;
 117                         self.personal.ammo_shells = self.ammo_shells;
 118                         self.personal.ammo_fuel = self.ammo_fuel;
 119                         self.personal.health = self.health;
 120                         self.personal.armorvalue = self.armorvalue;
 121                         self.personal.weapons = self.weapons;
 122                         self.personal.items = self.items;
 123                         self.personal.pauserotarmor_finished = self.pauserotarmor_finished;
 124                         self.personal.pauserothealth_finished = self.pauserothealth_finished;
 125                         self.personal.pauserotfuel_finished = self.pauserotfuel_finished;
 126                         self.personal.pauseregen_finished = self.pauseregen_finished;
 127                         self.personal.strength_finished = self.strength_finished;
 128                         self.personal.invincible_finished = self.invincible_finished;
 129                         self.personal.teleport_time = time;
 130                         break; // this part itself doesn't cheat, so let's not count this
 131                 case CHIMPULSE_CLONE_MOVING:
 132                         IS_CHEAT(i, 0, 0);
 133                         makevectors (self.v_angle);
 134                         self.velocity = self.velocity + v_forward * 300;
 135                         CopyBody(1);
 136                         self.lip += 1;
 137                         self.velocity = self.velocity - v_forward * 300;
 138                         DID_CHEAT();
 139                         break;
 140                 case CHIMPULSE_CLONE_STANDING:
 141                         IS_CHEAT(i, 0, 0);
 142                         CopyBody(0);
 143                         self.lip += 1;
 144                         DID_CHEAT();
 145                         break;
 146                 case CHIMPULSE_GIVE_ALL:
 147                         IS_CHEAT(i, 0, 0);
 148                         CheatCommand(tokenize_console("give all"));
 149                         break; // already counted as cheat
 150                 case CHIMPULSE_SPEEDRUN:
 151                         IS_CHEAT(i, 0, 0);
 152                         if(self.personal)
 153                         {
 154                                 self.speedrunning = TRUE;
 155                                 tracebox(self.personal.origin, self.mins, self.maxs, self.personal.origin, MOVE_WORLDONLY, self);
 156                                 if(trace_startsolid)
 157                                 {
 158                                         sprint(self, "Cannot move there, cheater - only waypoints set using g_waypointsprite_personal work\n");
 159                                 }
 160                                 else
 161                                 {
 162                                         // Abort speedrun, teleport back
 163                                         setorigin(self, self.personal.origin);
 164                                         self.oldvelocity = self.velocity = self.personal.velocity;
 165                                         self.angles = self.personal.v_angle;
 166                                         self.fixangle = TRUE;
 167                                         if(self.flagcarried)
 168                                         {
 169                                                 bprint("The ", self.flagcarried.netname, " was returned to base by its carrier\n");
 170                                                 ReturnFlag(self.flagcarried);
 171                                         }
 172                                 }
 173                                 if(g_ctf)
 174                                 {
 175                                         self.ammo_rockets = 999;
 176                                         self.ammo_nails = 999;
 177                                         self.ammo_cells = 999;
 178                                         self.ammo_shells = 999;
 179                                         self.ammo_fuel = 999;
 180                                         self.health = start_health;
 181                                         self.armorvalue = start_armorvalue;
 182                                         self.weapons |= weaponsInMap;
 183                                         self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 184                                         self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 185                                         self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
 186                                         self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 187                                         self.strength_finished = 0;
 188                                         self.invincible_finished = 0;
 189                                 }
 190                                 else
 191                                 {
 192                                         self.ammo_rockets = self.personal.ammo_rockets;
 193                                         self.ammo_nails = self.personal.ammo_nails;
 194                                         self.ammo_cells = self.personal.ammo_cells;
 195                                         self.ammo_shells = self.personal.ammo_shells;
 196                                         self.ammo_fuel = self.personal.ammo_fuel;
 197                                         self.health = self.personal.health;
 198                                         self.armorvalue = self.personal.armorvalue;
 199                                         self.weapons = self.personal.weapons;
 200                                         self.items = self.personal.items;
 201                                         self.pauserotarmor_finished = time + self.personal.pauserotarmor_finished - self.personal.teleport_time;
 202                                         self.pauserothealth_finished = time + self.personal.pauserothealth_finished - self.personal.teleport_time;
 203                                         self.pauserotfuel_finished = time + self.personal.pauserotfuel_finished - self.personal.teleport_time;
 204                                         self.pauseregen_finished = time + self.personal.pauseregen_finished - self.personal.teleport_time;
 205                                         self.strength_finished = time + self.personal.strength_finished - self.personal.teleport_time;
 206                                         self.invincible_finished = time + self.personal.invincible_finished - self.personal.teleport_time;
 207                                 }
 208                                 DID_CHEAT();
 209                                 break;
 210                         }
 211                         if(self.deadflag != DEAD_NO)
 212                                 sprint(self, "UR DEAD AHAHAH))\n");
 213                         else
 214                                 sprint(self, "No waypoint set, cheater (use g_waypointsprite_personal to set one)\n");
 215                         break;
 216                 case CHIMPULSE_TELEPORT:
 217                         IS_CHEAT(i, 0, 0);
 218                         if(MoveToRandomMapLocation(self, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, ((sv_cheats >= 2) ? 100000 : 100), 1024, 256))
 219                         {
 220                                 self.angles_x = -self.angles_x;
 221                                 self.fixangle = TRUE;
 222                                 self.velocity = '0 0 0';
 223                                 DID_CHEAT();
 224                                 break;
 225                         }
 226                         sprint(self, "Emergency teleport could not find a good location, forget it!\n");
 227                         break;
 228                 case CHIMPULSE_R00T:
 229                         IS_CHEAT(i, 0, 0);
 230                         FOR_EACH_PLAYER(e)
 231                         {
 232                                 if( e.playermodel == "models/player/jeandarc.zym"
 233                                                 ||  e.playermodel == "models/player/pyria.zym"
 234                                                 ||  e.playermodel == "models/player/skadi.zym"
 235                                                 || (e.playermodel == "models/player/specop.zym" && random() < 0.5) // you never know
 236                                                 ||  e.playermodel == "models/player/visitant.zym")
 237                                 {
 238                                         makevectors(e.angles);
 239                                         traceline(e.origin, e.origin + v_right * 256, MOVE_NORMAL, e);
 240                                 }
 241                                 else
 242                                 {
 243                                         org_x = random();
 244                                         org_y = random();
 245                                         org_z = 0;
 246                                         org = normalize(org);
 247                                         traceline(e.origin, e.origin + org * 256, MOVE_NORMAL, e); // random direction
 248                                 }
 249
 250                                 org = findbetterlocation(trace_endpos, 12);
 251
 252                                 e2 = spawn();
 253                                 setorigin(e2, org);
 254                                 pointparticles(particleeffectnum("rocket_explode"), org, '0 0 0', 1);
 255                                 sound(e2, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 256                                 RadiusDamage(e2, e, 1000, 0, 128, e, 500, DEATH_CHEAT, world);
 257                                 remove(e2);
 258                         }
 259                         print("404 Sportsmanship not found.\n");
 260                         DID_CHEAT();
 261                         break;
 262         }
 263
 264         END_CHEAT_FUNCTION();
 265 }
 266
 267 void DragBox_Think();
 268 float drag_lastcnt;
 269 float CheatCommand(float argc)
 270 {
 271         BEGIN_CHEAT_FUNCTION();
 272         string cmd;
 273         cmd = argv(0);
 274         switch(cmd)
 275         {
 276                 entity e;
 277                 float effectnum, f;
 278                 vector start, end;
 279                 entity oldself;
 280
 281                 case "pointparticles":
 282                         IS_CHEAT(0, argc, 0);
 283                         if(argc == 5)
 284                         {
 285                                 // arguments:
 286                                 //   effectname
 287                                 //   origin (0..1, on crosshair line)
 288                                 //   velocity
 289                                 //   howmany
 290                                 effectnum = particleeffectnum(argv(1));
 291                                 f = stof(argv(2));
 292                                 start = (1-f) * self.origin + f * self.cursor_trace_endpos;
 293                                 end = stov(argv(3));
 294                                 f = stof(argv(4));
 295                                 pointparticles(effectnum, start, end, f);
 296                                 DID_CHEAT();
 297                                 break;
 298                         }
 299                         sprint(self, "Usage: sv_cheats 1; restart; cmd pointparticles effectname position(0..1) velocityvector multiplier\n");
 300                         break;
 301                 case "trailparticles":
 302                         IS_CHEAT(0, argc, 0);
 303                         if(argc == 2)
 304                         {
 305                                 // arguments:
 306                                 //   effectname
 307                                 effectnum = particleeffectnum(argv(1));
 308                                 W_SetupShot(self, FALSE, FALSE, "",0);
 309                                 traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
 310                                 trailparticles(self, effectnum, w_shotorg, trace_endpos);
 311                                 DID_CHEAT();
 312                                 break;
 313                         }
 314                         sprint(self, "Usage: sv_cheats 1; restart; cmd trailparticles effectname\n");
 315                         break;
 316                 case "make":
 317                         IS_CHEAT(0, argc, 0);
 318                         if(argc == 3)
 319                         {
 320                                 // arguments:
 321                                 //   modelname mode
 322                                 f = stof(argv(2));
 323                                 W_SetupShot(self, FALSE, FALSE, "", 0);
 324                                 traceline(w_shotorg, w_shotorg + w_shotdir * 2048, MOVE_NORMAL, self);
 325                                 if((trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT) || trace_fraction == 1)
 326                                 {
 327                                         sprint(self, "cannot make stuff there (bad surface)\n");
 328                                 }
 329                                 else
 330                                 {
 331                                         e = spawn();
 332                                         e.model = strzone(argv(1));
 333                                         e.mdl = "rocket_explode";
 334                                         e.health = 1000;
 335                                         setorigin(e, trace_endpos);
 336                                         e.effects = EF_NOMODELFLAGS;
 337                                         if(f == 1)
 338                                         {
 339                                                 e.angles = fixedvectoangles2(trace_plane_normal, v_forward);
 340                                                 e.angles = AnglesTransform_Multiply(e.angles, '-90 0 0'); // so unrotated models work
 341                                         }
 342                                         oldself = self;
 343                                         self = e;
 344                                         spawnfunc_func_breakable();
 345                                         self = oldself;
 346                                         // now, is it valid?
 347                                         if(f == 0)
 348                                         {
 349                                                 tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_NORMAL, e);
 350                                                 if(trace_startsolid)
 351                                                 {
 352                                                         remove(e);
 353                                                         sprint(self, "cannot make stuff there (no space)\n");
 354                                                 }
 355                                                 else
 356                                                         DID_CHEAT();
 357                                         }
 358                                         else
 359                                                 DID_CHEAT();
 360                                 }
 361                         }
 362                         else
 363                                 sprint(self, "Usage: sv_cheats 1; restart; cmd make models/... 0/1/2\n");
 364                         break;
 365                 case "penalty":
 366                         IS_CHEAT(0, argc, 0);
 367                         if(argc == 3)
 368                         {
 369                                 race_ImposePenaltyTime(self, stof(argv(1)), argv(2));
 370                                 DID_CHEAT();
 371                                 break;
 372                         }
 373                         sprint(self, "Usage: sv_cheats 1; restart; cmd penalty 5.0 AHAHAHAHAHAHAH))\n");
 374                         break;
 375                 case "dragbox_spawn":
 376                         IS_CHEAT(0, argc, 0);
 377                         e = spawn();
 378                         e.classname = "dragbox_box";
 379                         e.think = DragBox_Think;
 380                         e.nextthink = time;
 381                         e.solid = -1; // black
 382                         setmodel(e, "null"); // network it
 383                         if(argc == 4)
 384                                 e.cnt = stof(argv(1));
 385                         else
 386                                 e.cnt = max(0, drag_lastcnt);
 387
 388                         e.aiment = spawn();
 389                         e.aiment.classname = "dragbox_corner_1";
 390                         e.aiment.owner = e;
 391                         setmodel(e.aiment, "models/marker.md3");
 392                         e.aiment.skin = 0;
 393                         setsize(e.aiment, '0 0 0', '0 0 0');
 394                         if(argc == 4)
 395                                 setorigin(e.aiment, stov(argv(2)));
 396                         else
 397                                 setorigin(e.aiment, self.cursor_trace_endpos);
 398
 399                         e.enemy = spawn();
 400                         e.enemy.classname = "dragbox_corner_2";
 401                         e.enemy.owner = e;
 402                         setmodel(e.enemy, "models/marker.md3");
 403                         e.enemy.skin = 1;
 404                         setsize(e.enemy, '0 0 0', '0 0 0');
 405                         end = normalize(self.cursor_trace_start - e.aiment.origin);
 406                         end_x = (end_x > 0) * 2 - 1;
 407                         end_y = (end_y > 0) * 2 - 1;
 408                         end_z = (end_z > 0) * 2 - 1;
 409                         if(argc == 4)
 410                                 setorigin(e.enemy, stov(argv(3)));
 411                         else
 412                                 setorigin(e.enemy, e.aiment.origin + 32 * end);
 413
 414                         e.killindicator = spawn();
 415                         e.killindicator.classname = "drag_digit";
 416                         e.killindicator.owner = e;
 417                         setattachment(e.killindicator, e, "");
 418                         setorigin(e.killindicator, '0 0 -8');
 419                         e.killindicator.killindicator = spawn();
 420                         e.killindicator.killindicator.classname = "drag_digit";
 421                         e.killindicator.killindicator.owner = e;
 422                         setattachment(e.killindicator.killindicator, e, "");
 423                         setorigin(e.killindicator.killindicator, '0 0 8');
 424                         DID_CHEAT();
 425                         break;
 426                 case "dragpoint_spawn":
 427                         IS_CHEAT(0, argc, 0);
 428                         e = spawn();
 429                         e.classname = "dragpoint";
 430                         e.think = DragBox_Think;
 431                         e.nextthink = time;
 432                         e.solid = 0; // nothing special
 433                         setmodel(e, "models/marker.md3");
 434                         setsize(e, PL_MIN, PL_MAX);
 435                         e.skin = 2;
 436                         if(argc == 3)
 437                                 e.cnt = stof(argv(1));
 438                         else
 439                                 e.cnt = drag_lastcnt;
 440                         if(argc == 3)
 441                                 setorigin(e, stov(argv(2)));
 442                         else
 443                         {
 444                                 setorigin(e, self.cursor_trace_endpos + normalize(self.cursor_trace_start - self.cursor_trace_endpos));
 445                                 move_out_of_solid(e);
 446                         }
 447
 448                         e.killindicator = spawn();
 449                         e.killindicator.classname = "drag_digit";
 450                         e.killindicator.owner = e;
 451                         setattachment(e.killindicator, e, "");
 452                         setorigin(e.killindicator, '0 0 40');
 453                         e.killindicator.killindicator = spawn();
 454                         e.killindicator.killindicator.classname = "drag_digit";
 455                         e.killindicator.killindicator.owner = e;
 456                         setattachment(e.killindicator.killindicator, e, "");
 457                         setorigin(e.killindicator.killindicator, '0 0 56');
 458                         DID_CHEAT();
 459                         break;
 460                 case "drag_remove":
 461                         IS_CHEAT(0, argc, 0);
 462                         RandomSelection_Init();
 463                         for(e = world; (e = find(e, classname, "dragbox_box")); )
 464                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - self.cursor_trace_endpos));
 465                         for(e = world; (e = find(e, classname, "dragpoint")); )
 466                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - self.cursor_trace_endpos));
 467                         if(RandomSelection_chosen_ent)
 468                         {
 469                                 remove(RandomSelection_chosen_ent.killindicator.killindicator);
 470                                 remove(RandomSelection_chosen_ent.killindicator);
 471                                 if(RandomSelection_chosen_ent.aiment)
 472                                         remove(RandomSelection_chosen_ent.aiment);
 473                                 if(RandomSelection_chosen_ent.enemy)
 474                                         remove(RandomSelection_chosen_ent.enemy);
 475                                 remove(RandomSelection_chosen_ent);
 476                         }
 477                         DID_CHEAT();
 478                         break;
 479                 case "drag_setcnt":
 480                         IS_CHEAT(0, argc, 0);
 481                         if(argc == 2)
 482                         {
 483                                 RandomSelection_Init();
 484                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 485                                         RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - self.cursor_trace_endpos));
 486                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 487                                         RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - self.cursor_trace_endpos));
 488                                 if(RandomSelection_chosen_ent)
 489                                 {
 490                                         if(substring(argv(1), 0, 1) == "*")
 491                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = RandomSelection_chosen_ent.cnt + stof(substring(argv(1), 1, -1));
 492                                         else
 493                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = stof(argv(1));
 494                                 }
 495                                 DID_CHEAT();
 496                                 break;
 497                         }
 498                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_setcnt cnt\n");
 499                         break;
 500                 case "drag_save":
 501                         IS_CHEAT(0, argc, 0);
 502                         if(argc == 2)
 503                         {
 504                                 f = fopen(argv(1), FILE_WRITE);
 505                                 fputs(f, "cmd drag_clear\n");
 506                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 507                                 {
 508                                         fputs(f, strcat("cmd dragbox_spawn ", ftos(e.cnt), " \"", vtos(e.aiment.origin), "\" \"", vtos(e.enemy.origin), "\"\n"));
 509                                 }
 510                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 511                                 {
 512                                         fputs(f, strcat("cmd dragpoint_spawn ", ftos(e.cnt), " \"", vtos(e.origin), "\"\n"));
 513                                 }
 514                                 fclose(f);
 515                                 DID_CHEAT();
 516                                 break;
 517                         }
 518                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 519                         break;
 520                 case "drag_saveraceent":
 521                         IS_CHEAT(0, argc, 0);
 522                         if(argc == 2)
 523                         {
 524                                 f = fopen(argv(1), FILE_WRITE);
 525                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 526                                 {
 527                                         fputs(f, "{\n");
 528                                         fputs(f, "\"classname\" \"trigger_race_checkpoint\"\n");
 529                                         fputs(f, strcat("\"origin\" \"", ftos(e.absmin_x), " ", ftos(e.absmin_y), " ", ftos(e.absmin_z), "\"\n"));
 530                                         fputs(f, strcat("\"maxs\" \"", ftos(e.absmax_x - e.absmin_x), " ", ftos(e.absmax_y - e.absmin_y), " ", ftos(e.absmax_z - e.absmin_z), "\"\n"));
 531                                         fputs(f, strcat("\"cnt\" \"", ftos(e.cnt), "\"\n"));
 532                                         fputs(f, strcat("\"targetname\" \"checkpoint", ftos(e.cnt), "\"\n"));
 533                                         fputs(f, "}\n");
 534                                 }
 535                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 536                                 {
 537                                         start = '0 0 0';
 538                                         effectnum = 0;
 539                                         for(oldself = world; (oldself = find(oldself, classname, "dragbox_box")); )
 540                                         {
 541                                                 if(e.cnt <= 0 && oldself.cnt == 0 || e.cnt == oldself.cnt)
 542                                                 {
 543                                                         start = start + oldself.origin;
 544                                                         ++effectnum;
 545                                                 }
 546                                         }
 547                                         start *= 1 / effectnum;
 548                                         fputs(f, "{\n");
 549                                         fputs(f, "\"classname\" \"info_player_race\"\n");
 550                                         fputs(f, strcat("\"angle\" \"", ftos(vectoyaw(start - e.origin)), "\"\n"));
 551                                         fputs(f, strcat("\"origin\" \"", ftos(e.origin_x), " ", ftos(e.origin_y), " ", ftos(e.origin_z), "\"\n"));
 552                                         if(e.cnt == -2)
 553                                         {
 554                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 555                                                 fputs(f, "\"race_place\" \"0\"\n");
 556                                         }
 557                                         else if(e.cnt == -1)
 558                                         {
 559                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 560                                                 fputs(f, "\"race_place\" \"-1\"\n");
 561                                         }
 562                                         else
 563                                         {
 564                                                 fputs(f, strcat("\"target\" \"checkpoint", ftos(e.cnt), "\"\n"));
 565                                                 if(e.cnt == 0)
 566                                                 {
 567                                                         // these need race_place
 568                                                         // counting...
 569                                                         effectnum = 1;
 570                                                         for(oldself = world; (oldself = find(oldself, classname, "dragpoint")); )
 571                                                         if(oldself.cnt == 0)
 572                                                         {
 573                                                                 if(vlen(oldself.origin - start) < vlen(e.origin - start))
 574                                                                         ++effectnum;
 575                                                                 else if(vlen(oldself.origin - start) == vlen(e.origin - start) && num_for_edict(oldself) < num_for_edict(e))
 576                                                                         ++effectnum;
 577                                                         }
 578                                                         fputs(f, strcat("\"race_place\" \"", ftos(effectnum), "\"\n"));
 579                                                 }
 580                                         }
 581                                         fputs(f, "}\n");
 582                                 }
 583                                 fclose(f);
 584                                 DID_CHEAT();
 585                                 break;
 586                         }
 587                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 588                         break;
 589                 case "drag_clear":
 590                         IS_CHEAT(0, argc, 0);
 591                         for(e = world; (e = find(e, classname, "dragbox_box")); )
 592                                 remove(e);
 593                         for(e = world; (e = find(e, classname, "dragbox_corner_1")); )
 594                                 remove(e);
 595                         for(e = world; (e = find(e, classname, "dragbox_corner_2")); )
 596                                 remove(e);
 597                         for(e = world; (e = find(e, classname, "dragpoint")); )
 598                                 remove(e);
 599                         for(e = world; (e = find(e, classname, "drag_digit")); )
 600                                 remove(e);
 601                         DID_CHEAT();
 602                         break;
 603                 case "warp":
 604                         IS_CHEAT(0, argc, 0);
 605                         if(argc == 2) if(cvar("g_campaign"))
 606                         {
 607                                 CampaignLevelWarp(stof(argv(1)));
 608                                 DID_CHEAT();
 609                         }
 610                         break;
 611                 case "god":
 612                         IS_CHEAT(0, argc, 0);
 613                         BITXOR_ASSIGN(self.flags, FL_GODMODE);
 614                         if(self.flags & FL_GODMODE)
 615                         {
 616                                 sprint(self, "godmode ON\n");
 617                                 DID_CHEAT();
 618                         }
 619                         else
 620                                 sprint(self, "godmode OFF\n");
 621                         break;
 622                 case "notarget":
 623                         IS_CHEAT(0, argc, 0);
 624                         BITXOR_ASSIGN(self.flags, FL_NOTARGET);
 625                         if(self.flags & FL_NOTARGET)
 626                         {
 627                                 sprint(self, "notarget ON\n");
 628                                 DID_CHEAT();
 629                         }
 630                         else
 631                                 sprint(self, "notarget OFF\n");
 632                         break;
 633                 case "noclip":
 634                         IS_CHEAT(0, argc, 0);
 635                         if(self.movetype != MOVETYPE_NOCLIP)
 636                         {
 637                                 self.movetype = MOVETYPE_NOCLIP;
 638                                 sprint(self, "noclip ON\n");
 639                                 DID_CHEAT();
 640                         }
 641                         else
 642                         {
 643                                 self.movetype = MOVETYPE_WALK;
 644                                 sprint(self, "noclip OFF\n");
 645                         }
 646                         break;
 647                 case "fly":
 648                         IS_CHEAT(0, argc, 0);
 649                         if(self.movetype != MOVETYPE_FLY)
 650                         {
 651                                 self.movetype = MOVETYPE_FLY;
 652                                 sprint(self, "flmodey ON\n");
 653                                 DID_CHEAT();
 654                         }
 655                         else
 656                         {
 657                                 self.movetype = MOVETYPE_WALK;
 658                                 sprint(self, "flymode OFF\n");
 659                         }
 660                         break;
 661                 case "give":
 662                         IS_CHEAT(0, argc, 0);
 663                         if(GiveItems(self, 1, argc))
 664                                 DID_CHEAT();
 665                         break;
 666         }
 667
 668         END_CHEAT_FUNCTION();
 669 }
 670
 671 void Drag_Begin(entity dragger, entity draggee, vector touchpoint);
 672 void Drag_Finish(entity dragger);
 673 float Drag_IsDraggable(entity draggee);
 674 float Drag_MayChangeAngles(entity draggee);
 675 void Drag_MoveForward(entity dragger);
 676 void Drag_SetSpeed(entity dragger, float s);
 677 void Drag_MoveBackward(entity dragger);
 678 void Drag_Update(entity dragger);
 679 float Drag_CanDrag(entity dragger);
 680 float Drag_IsDragging(entity dragger);
 681 void Drag_MoveDrag(entity from, entity to);
 682 .entity dragentity;
 683
 684 float CheatFrame()
 685 {
 686         BEGIN_CHEAT_FUNCTION();
 687
 688         if(Drag_IsDragging(self))
 689         {
 690                 if(self.BUTTON_DRAG)
 691                 {
 692                         if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 693                         {
 694                                 Drag_MoveForward(self);
 695                                 self.impulse = 0;
 696                         }
 697                         else if(self.impulse == 12 || self.impulse == 16 || self.impulse == 19)
 698                         {
 699                                 Drag_MoveBackward(self);
 700                                 self.impulse = 0;
 701                         }
 702                         else if(self.impulse >= 1 && self.impulse <= 9)
 703                         {
 704                                 Drag_SetSpeed(self, self.impulse - 1);
 705                         }
 706                         else if(self.impulse == 14)
 707                         {
 708                                 Drag_SetSpeed(self, 9);
 709                         }
 710
 711                         if(frametime)
 712                                 Drag_Update(self);
 713                 }
 714                 else
 715                 {
 716                         Drag_Finish(self);
 717                 }
 718         }
 719         else
 720         {
 721                 if(Drag_CanDrag(self))
 722                         if(self.BUTTON_DRAG)
 723                                 if(self.cursor_trace_ent)
 724                                         if(Drag_IsDraggable(self.cursor_trace_ent))
 725                                                 switch(0)
 726                                                 {
 727                                                         default:
 728                                                                 IS_CHEAT(0, 0, CHRAME_DRAG);
 729                                                                 if(self.cursor_trace_ent.draggedby)
 730                                                                         Drag_Finish(self.cursor_trace_ent.draggedby);
 731                                                                 if(self.cursor_trace_ent.tag_entity)
 732                                                                         detach_sameorigin(self.cursor_trace_ent);
 733                                                                 Drag_Begin(self, self.cursor_trace_ent, self.cursor_trace_endpos);
 734                                                                 DID_CHEAT();
 735                                                                 break;
 736                                                 }
 737         }
 738
 739         END_CHEAT_FUNCTION();
 740 }
 741
 742
 743
 744
 745
 746 // ENTITY DRAGGING
 747
 748 // on dragger:
 749 .float draggravity;
 750 .float dragspeed; // speed of mouse wheel action
 751 .float dragdistance; // distance of dragentity's draglocalvector from view_ofs
 752 .vector draglocalvector; // local attachment vector of the dragentity
 753 .float draglocalangle;
 754 // on draggee:
 755 .entity draggedby;
 756 .float dragmovetype;
 757 void Drag_Begin(entity dragger, entity draggee, vector touchpoint)
 758 {
 759         float tagscale;
 760
 761         draggee.dragmovetype = draggee.movetype;
 762         draggee.draggravity = draggee.gravity;
 763         draggee.movetype = MOVETYPE_WALK;
 764         draggee.gravity = 0.00001;
 765         draggee.flags &~= FL_ONGROUND;
 766         draggee.draggedby = dragger;
 767
 768         dragger.dragentity = draggee;
 769
 770         dragger.dragdistance = vlen(touchpoint - dragger.origin - dragger.view_ofs);
 771         dragger.draglocalangle = draggee.angles_y - dragger.v_angle_y;
 772         touchpoint = touchpoint - gettaginfo(draggee, 0);
 773         tagscale = pow(vlen(v_forward), -2);
 774         dragger.draglocalvector_x = touchpoint * v_forward * tagscale;
 775         dragger.draglocalvector_y = touchpoint * v_right * tagscale;
 776         dragger.draglocalvector_z = touchpoint * v_up * tagscale;
 777
 778         dragger.dragspeed = 64;
 779 }
 780
 781 void Drag_Finish(entity dragger)
 782 {
 783         entity draggee;
 784         draggee = dragger.dragentity;
 785         if(dragger)
 786                 dragger.dragentity = world;
 787         draggee.draggedby = world;
 788         draggee.movetype = draggee.dragmovetype;
 789         draggee.gravity = draggee.draggravity;
 790
 791         switch(draggee.movetype)
 792         {
 793                 case MOVETYPE_TOSS:
 794                 case MOVETYPE_WALK:
 795                 case MOVETYPE_STEP:
 796                 case MOVETYPE_FLYMISSILE:
 797                 case MOVETYPE_BOUNCE:
 798                 case MOVETYPE_BOUNCEMISSILE:
 799                 case MOVETYPE_PHYSICS:
 800                         break;
 801                 default:
 802                         draggee.velocity = '0 0 0';
 803                         break;
 804         }
 805
 806         if((draggee.flags & FL_ITEM) && (vlen(draggee.velocity) < 32))
 807         {
 808                 draggee.velocity = '0 0 0';
 809                 draggee.flags |= FL_ONGROUND; // floating items are FUN
 810         }
 811 }
 812
 813 float Drag_IsDraggable(entity draggee)
 814 {
 815         // TODO add more checks for bad stuff here
 816         if(draggee.classname == "func_bobbing")
 817                 return FALSE;
 818         if(draggee.classname == "door") // FIXME find out why these must be excluded, or work around the problem (trying to drag these causes like 4 fps)
 819                 return FALSE;
 820         if(draggee.classname == "plat")
 821                 return FALSE;
 822         if(draggee.classname == "func_button")
 823                 return FALSE;
 824         if(draggee.model == "")
 825                 return FALSE;
 826         if(draggee.classname == "spectator")
 827                 return FALSE;
 828         if(draggee.classname == "observer")
 829                 return FALSE;
 830         if(draggee.classname == "exteriorweaponentity")
 831                 return FALSE;
 832
 833         return TRUE;
 834 }
 835
 836 float Drag_MayChangeAngles(entity draggee)
 837 {
 838         // TODO add more checks for bad stuff here
 839         if(substring(draggee.model, 0, 1) == "*")
 840                 return FALSE;
 841         return TRUE;
 842 }
 843
 844 void Drag_MoveForward(entity dragger)
 845 {
 846         dragger.dragdistance += dragger.dragspeed;
 847 }
 848
 849 void Drag_SetSpeed(entity dragger, float s)
 850 {
 851         dragger.dragspeed = pow(2, s);
 852 }
 853
 854 void Drag_MoveBackward(entity dragger)
 855 {
 856         dragger.dragdistance = max(0, dragger.dragdistance - dragger.dragspeed);
 857 }
 858
 859 void Drag_Update(entity dragger)
 860 {
 861         vector curorigin, neworigin, goodvelocity;
 862         float f;
 863         entity draggee;
 864
 865         draggee = dragger.dragentity;
 866         draggee.flags &~= FL_ONGROUND;
 867
 868         curorigin = gettaginfo(draggee, 0);
 869         curorigin = curorigin + v_forward * dragger.draglocalvector_x + v_right * dragger.draglocalvector_y + v_up * dragger.draglocalvector_z;
 870         makevectors(dragger.v_angle);
 871         neworigin = dragger.origin + dragger.view_ofs + v_forward * dragger.dragdistance;
 872         goodvelocity = (neworigin - curorigin) * (1 / frametime);
 873
 874         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle > 180)
 875                 dragger.draglocalangle += 360;
 876         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle <= -180)
 877                 dragger.draglocalangle -= 360;
 878
 879         f = min(frametime * 10, 1);
 880         draggee.velocity = draggee.velocity * (1 - f) + goodvelocity * f;
 881
 882         if(Drag_MayChangeAngles(draggee))
 883                 draggee.angles_y = draggee.angles_y * (1 - f) + (dragger.v_angle_y + dragger.draglocalangle) * f;
 884
 885         draggee.ltime = max(servertime + serverframetime, draggee.ltime); // fixes func_train breakage
 886
 887         te_lightning1(dragger, dragger.origin + dragger.view_ofs, curorigin);
 888 }
 889
 890 float Drag_CanDrag(entity dragger)
 891 {
 892         return (dragger.deadflag == DEAD_NO) || (dragger.classname == "player");
 893 }
 894
 895 float Drag_IsDragging(entity dragger)
 896 {
 897         if(!dragger.dragentity)
 898                 return FALSE;
 899         if(wasfreed(dragger.dragentity) || dragger.dragentity.draggedby != dragger)
 900         {
 901                 dragger.dragentity = world;
 902                 return FALSE;
 903         }
 904         if(!Drag_CanDrag(dragger) || !Drag_IsDraggable(dragger.dragentity))
 905         {
 906                 Drag_Finish(dragger);
 907                 return FALSE;
 908         }
 909         return TRUE;
 910 }
 911
 912 void Drag_MoveDrag(entity from, entity to)
 913 {
 914         if(from.draggedby)
 915         {
 916                 to.draggedby = from.draggedby;
 917                 to.draggedby.dragentity = to;
 918                 from.draggedby = world;
 919         }
 920 }
 921
 922
 923
 924
 925
 926
 927 void DragBox_Think()
 928 {
 929         if(self.aiment && self.enemy)
 930         {
 931                 self.origin_x = (self.aiment.origin_x + self.enemy.origin_x) * 0.5;
 932                 self.origin_y = (self.aiment.origin_y + self.enemy.origin_y) * 0.5;
 933                 self.origin_z = (self.aiment.origin_z + self.enemy.origin_z) * 0.5;
 934                 self.maxs_x = fabs(self.aiment.origin_x - self.enemy.origin_x) * 0.5;
 935                 self.maxs_y = fabs(self.aiment.origin_y - self.enemy.origin_y) * 0.5;
 936                 self.maxs_z = fabs(self.aiment.origin_z - self.enemy.origin_z) * 0.5;
 937                 self.mins = -1 * self.maxs;
 938                 setorigin(self, self.origin); setsize(self, self.mins, self.maxs); // link edict
 939         }
 940
 941         if(self.cnt == -1) // actually race_place -1
 942         {
 943                 // show "10 10" for qualifying spawns
 944                 setmodel(self.killindicator, "models/sprites/10.spr32");
 945                 setmodel(self.killindicator.killindicator, "models/sprites/10.spr32");
 946         }
 947         else if(self.cnt == -2) // actually race_place 0
 948         {
 949                 // show "10 0" for loser spawns
 950                 setmodel(self.killindicator, "models/sprites/10.spr32");
 951                 setmodel(self.killindicator.killindicator, "models/sprites/0.spr32");
 952         }
 953         else
 954         {
 955                 setmodel(self.killindicator, strcat("models/sprites/", ftos(mod(self.cnt, 10)), ".spr32"));
 956                 setmodel(self.killindicator.killindicator, strcat("models/sprites/", ftos(floor(self.cnt / 10)), ".spr32"));
 957         }
 958
 959         self.nextthink = time;
 960 }
 961
 962 #endif