data/qcsrc/menu/menu.qc

   1 ///////////////////////////////////////////////
   2 // Menu Source File
   3 ///////////////////////
   4 // This file belongs to dpmod/darkplaces
   5 // AK contains all menu functions (especially the required ones)
   6 ///////////////////////////////////////////////
   7
   8 float mouseButtonsPressed;
   9 vector menuMousePos;
  10 float menuShiftState;
  11 float menuPrevTime;
  12 float menuAlpha;
  13 float menuLogoAlpha;
  14 float prevMenuAlpha;
  15 float menuInitialized;
  16 float menuNotTheFirstFrame;
  17 float menuMouseMode;
  18
  19 void SUB_Null() { };
  20
  21 void() m_init =
  22 {
  23         dprint_load();
  24         check_unacceptable_compiler_bugs();
  25
  26         // list all game dirs (TEST)
  27         if(cvar("developer"))
  28         {
  29                 float i;
  30                 string s;
  31                 for(i = 0; ; ++i)
  32                 {
  33                         s = getgamedirinfo(i, GETGAMEDIRINFO_NAME);
  34                         if not(s)
  35                                 break;
  36                         print(s, ": ", getgamedirinfo(i, GETGAMEDIRINFO_DESCRIPTION));
  37                 }
  38         }
  39 }
  40
  41 void UpdateConWidthHeight()
  42 {
  43         float conwidth_s, conheight_s;
  44         conwidth_s = conwidth;
  45         conheight_s = conheight;
  46         conwidth = cvar("vid_conwidth");
  47         conheight = cvar("vid_conheight");
  48         if(conwidth < 800)
  49         {
  50                 conheight *= 800 / conwidth;
  51                 conwidth = 800;
  52         }
  53         if(conheight < 600)
  54         {
  55                 conwidth *= 600 / conheight;
  56                 conheight = 600;
  57         }
  58         if(main)
  59         {
  60                 if(conwidth_s != conwidth || conheight_s != conheight)
  61                 {
  62                         draw_reset();
  63                         main.resizeNotify(main, '0 0 0', eX * conwidth + eY * conheight, '0 0 0', eX * conwidth + eY * conheight);
  64                 }
  65         }
  66 }
  67
  68 void() m_init_delayed =
  69 {
  70         float fh, glob, n, i;
  71         string s;
  72
  73         dprint_load();
  74
  75         menuInitialized = 0;
  76         if(!preMenuInit())
  77                 return;
  78         menuInitialized = 1;
  79         GameCommand_Init();
  80
  81         RegisterWeapons();
  82
  83         fh = -1;
  84         if(cvar_string("menu_skin") != "")
  85         {
  86                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  87                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  88         }
  89         if(fh < 0)
  90         if(cvar_defstring("menu_skin") != "")
  91         {
  92                 draw_currentSkin = strcat("gfx/menu/", cvar_defstring("menu_skin"));
  93                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  94         }
  95         if(fh < 0)
  96         {
  97                 draw_currentSkin = "gfx/menu/default";
  98                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  99         }
 100         draw_currentSkin = strzone(draw_currentSkin);
 101         while((s = fgets(fh)))
 102         {
 103                 // these two are handled by skinlist.qc
 104                 if(substring(s, 0, 6) == "title ")
 105                         continue;
 106                 if(substring(s, 0, 7) == "author ")
 107                         continue;
 108                 n = tokenize_console(s);
 109                 if(n >= 2)
 110                         Skin_ApplySetting(argv(0), substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 111         }
 112         fclose(fh);
 113
 114         glob = search_begin(strcat(draw_currentSkin, "/*.tga"), TRUE, TRUE);
 115         if(glob >= 0)
 116         {
 117                 n = search_getsize(glob);
 118                 for(i = 0; i < n; ++i)
 119                         precache_pic(search_getfilename(glob, i));
 120                 search_end(glob);
 121         }
 122
 123         draw_setMousePointer(SKINGFX_CURSOR, SKINSIZE_CURSOR, SKINOFFSET_CURSOR);
 124
 125         conwidth = conheight = -1;
 126         draw_reset();
 127         UpdateConWidthHeight();
 128
 129         loadTooltips();
 130         main = spawnMainWindow(); main.configureMainWindow(main);
 131         unloadTooltips();
 132
 133         main.resizeNotify(main, '0 0 0', eX * conwidth + eY * conheight, '0 0 0', eX * conwidth + eY * conheight);
 134         main.focused = 1;
 135         menuShiftState = 0;
 136         menuMousePos = '0.5 0.5 0';
 137
 138         if(Menu_Active)
 139                 m_display(); // delayed menu display
 140 };
 141
 142 void(float key, float ascii) m_keyup =
 143 {
 144         if(!menuInitialized)
 145                 return;
 146         if(!Menu_Active)
 147                 return;
 148         draw_reset();
 149         main.keyUp(main, key, ascii, menuShiftState);
 150         if(key >= K_MOUSE1 && key <= K_MOUSE3)
 151         {
 152                 --mouseButtonsPressed;
 153                 if(!mouseButtonsPressed)
 154                         main.mouseRelease(main, menuMousePos);
 155                 if(mouseButtonsPressed < 0)
 156                 {
 157                         mouseButtonsPressed = 0;
 158                         print("Warning: released an already released button\n");
 159                 }
 160         }
 161         if(key == K_ALT) menuShiftState -= (menuShiftState & S_ALT);
 162         if(key == K_CTRL) menuShiftState -= (menuShiftState & S_CTRL);
 163         if(key == K_SHIFT) menuShiftState -= (menuShiftState & S_SHIFT);
 164 };
 165
 166 void(float key, float ascii) m_keydown =
 167 {
 168         if(!menuInitialized)
 169                 return;
 170         if(!Menu_Active)
 171                 return;
 172         if(keyGrabber)
 173         {
 174                 entity e;
 175                 e = keyGrabber;
 176                 keyGrabber = NULL;
 177                 e.keyGrabbed(e, key, ascii);
 178         }
 179         else
 180         {
 181                 draw_reset();
 182                 if(key >= K_MOUSE1 && key <= K_MOUSE3)
 183                         if(!mouseButtonsPressed)
 184                                 main.mousePress(main, menuMousePos);
 185                 if(!main.keyDown(main, key, ascii, menuShiftState))
 186                         if(key == K_ESCAPE)
 187                                 if(gamestatus & (GAME_ISSERVER | GAME_CONNECTED)) // don't back out to console only
 188                                         m_hide(); // disable menu on unhandled ESC
 189         }
 190         if(key >= K_MOUSE1 && key <= K_MOUSE3)
 191         {
 192                 ++mouseButtonsPressed;
 193                 if(mouseButtonsPressed > 10)
 194                 {
 195                         mouseButtonsPressed = 10;
 196                         print("Warning: pressed an already pressed button\n");
 197                 }
 198         }
 199         if(key == K_ALT) menuShiftState |= S_ALT;
 200         if(key == K_CTRL) menuShiftState |= S_CTRL;
 201         if(key == K_SHIFT) menuShiftState |= S_SHIFT;
 202 };
 203
 204 void(string img, float a, float algn) drawBackground =
 205 {
 206         vector sz;
 207         vector isz;
 208         vector tl, ce, br;
 209         vector v;
 210         string s;
 211         float i, f;
 212         sz = draw_PictureSize(img);
 213         // keep aspect of image
 214         if(sz_x * draw_scale_y >= sz_y * draw_scale_x)
 215         {
 216                 // that is, sz_x/sz_y >= draw_scale_x/draw_scale_y
 217                 // match up the height
 218                 isz_y = 1;
 219                 isz_x = isz_y * (sz_x / sz_y) * (draw_scale_y / draw_scale_x);
 220         }
 221         else
 222         {
 223                 // that is, sz_x/sz_y <= draw_scale_x/draw_scale_y
 224                 // match up the width
 225                 isz_x = 1;
 226                 isz_y = isz_x * (sz_y / sz_x) * (draw_scale_x / draw_scale_y);
 227         }
 228         tl = '0 0 0';
 229         ce = '0.5 0.5 0' - 0.5 * isz;
 230         br = '1 1 0' - isz;
 231
 232         s = ftos(algn);
 233         v_z = 0;
 234         for(i = 0; i < strlen(s); ++i)
 235         {
 236                 f = stof(substring(s, i, 1));
 237                 switch(f)
 238                 {
 239                         case 1: case 4: case 7: v_x = tl_x; break;
 240                         case 2: case 5: case 8: v_x = ce_x; break;
 241                         case 3: case 6: case 9: v_x = br_x; break;
 242                         default: v_x = tl_x + (br_x - tl_x) * random(); break;
 243                 }
 244                 switch(f)
 245                 {
 246                         case 7: case 8: case 9: v_y = tl_y; break;
 247                         case 4: case 5: case 6: v_y = ce_y; break;
 248                         case 1: case 2: case 3: v_y = br_y; break;
 249                         default: v_y = tl_y + (br_y - tl_y) * random(); break;
 250                 }
 251                 if(i == 0)
 252                         draw_Picture(v, img, isz, '1 1 1', a);
 253                 else
 254                         draw_Picture(v, strcat(img, "_l", ftos(i+1)), isz, '1 1 1', a);
 255         }
 256 }
 257
 258 vector menuTooltipAveragedMousePos;
 259 entity menuTooltipItem;
 260 vector menuTooltipOrigin;
 261 vector menuTooltipSize;
 262 float menuTooltipAlpha;
 263 float menuTooltipState; // 0: no tooltip, 1: fading in, 2: displaying, 3: fading out
 264 float m_testmousetooltipbox(vector pos)
 265 {
 266         if(pos_x >= menuTooltipOrigin_x && pos_x < menuTooltipOrigin_x + menuTooltipSize_x)
 267         if(pos_y >= menuTooltipOrigin_y && pos_y < menuTooltipOrigin_y + menuTooltipSize_y)
 268                 return FALSE;
 269         return TRUE;
 270 }
 271 float m_testtooltipbox(vector tooltippos)
 272 {
 273         if(tooltippos_x < 0)
 274                 return FALSE;
 275         if(tooltippos_y < 0)
 276                 return FALSE;
 277         if(tooltippos_x + menuTooltipSize_x > 1)
 278                 return FALSE;
 279         if(tooltippos_y + menuTooltipSize_y > 1)
 280                 return FALSE;
 281         /*
 282         menuTooltipOrigin_x = rint(tooltippos_x * cvar("vid_width")) / cvar("vid_width");
 283         menuTooltipOrigin_y = rint(tooltippos_y * cvar("vid_height")) / cvar("vid_height");
 284         menuTooltipOrigin_z = 0;
 285         */
 286         menuTooltipOrigin = tooltippos;
 287         return TRUE;
 288 }
 289 float m_allocatetooltipbox(vector pos)
 290 {
 291         vector avoidplus, avoidminus;
 292         vector v;
 293
 294         avoidplus_x = (SKINAVOID_TOOLTIP_x + SKINSIZE_CURSOR_x - SKINOFFSET_CURSOR_x) / conwidth;
 295         avoidplus_y = (SKINAVOID_TOOLTIP_y + SKINSIZE_CURSOR_y - SKINOFFSET_CURSOR_y) / conheight;
 296         avoidplus_z = 0;
 297
 298         avoidminus_x = (SKINAVOID_TOOLTIP_x + SKINOFFSET_CURSOR_x) / conwidth + menuTooltipSize_x;
 299         avoidminus_y = (SKINAVOID_TOOLTIP_y + SKINOFFSET_CURSOR_y) / conheight + menuTooltipSize_y;
 300         avoidminus_z = 0;
 301
 302         // bottom right
 303         v = pos + avoidplus;
 304         if(m_testtooltipbox(v))
 305                 return TRUE;
 306
 307         // bottom center
 308         v_x = pos_x - menuTooltipSize_x * 0.5;
 309         if(m_testtooltipbox(v))
 310                 return TRUE;
 311
 312         // bottom left
 313         v_x = pos_x - avoidminus_x;
 314         if(m_testtooltipbox(v))
 315                 return TRUE;
 316
 317         // top left
 318         v_y = pos_y - avoidminus_y;
 319         if(m_testtooltipbox(v))
 320                 return TRUE;
 321
 322         // top center
 323         v_x = pos_x - menuTooltipSize_x * 0.5;
 324         if(m_testtooltipbox(v))
 325                 return TRUE;
 326
 327         // top right
 328         v_x = pos_x + avoidplus_x;
 329         if(m_testtooltipbox(v))
 330                 return TRUE;
 331
 332         return FALSE;
 333 }
 334 entity m_findtooltipitem(entity root, vector pos)
 335 {
 336         entity it;
 337         entity best;
 338
 339         best = world;
 340         it = root;
 341
 342         while(it.instanceOfContainer)
 343         {
 344                 while(it.instanceOfNexposee && it.focusedChild)
 345                 {
 346                         it = it.focusedChild;
 347                         pos = globalToBox(pos, it.Container_origin, it.Container_size);
 348                 }
 349                 if(it.instanceOfNexposee)
 350                 {
 351                         it = it.itemFromPoint(it, pos);
 352                         if(it.tooltip)
 353                                 best = it;
 354                         it = world;
 355                 }
 356                 else if(it.instanceOfModalController)
 357                         it = it.focusedChild;
 358                 else
 359                         it = it.itemFromPoint(it, pos);
 360                 if(!it)
 361                         break;
 362                 if(it.tooltip)
 363                         best = it;
 364                 pos = globalToBox(pos, it.Container_origin, it.Container_size);
 365         }
 366
 367         return best;
 368 }
 369 void m_tooltip(vector pos)
 370 {
 371         float f, i, w;
 372         entity it;
 373         vector fontsize, p;
 374         string s;
 375
 376         fontsize = '1 0 0' * (SKINFONTSIZE_TOOLTIP / conwidth) + '0 1 0' * (SKINFONTSIZE_TOOLTIP / conheight);
 377
 378         f = bound(0, frametime * 2, 1);
 379         menuTooltipAveragedMousePos = menuTooltipAveragedMousePos * (1 - f) + pos * f;
 380         f = vlen(pos - menuTooltipAveragedMousePos);
 381
 382         if(f < 0.01)
 383                 it = m_findtooltipitem(main, pos);
 384         else
 385                 it = world;
 386
 387         // float menuTooltipState; // 0: static, 1: fading in, 2: fading out
 388         if(it != menuTooltipItem)
 389         {
 390                 switch(menuTooltipState)
 391                 {
 392                         case 0:
 393                                 if(menuTooltipItem)
 394                                 {
 395                                         // another item: fade out first
 396                                         menuTooltipState = 2;
 397                                 }
 398                                 else
 399                                 {
 400                                         // new item: fade in
 401                                         menuTooltipState = 1;
 402                                         menuTooltipItem = it;
 403
 404                                         menuTooltipOrigin_x = -1; // unallocated
 405                                         i = 0;
 406                                         w =  0;
 407                                         getWrappedLine_remaining = it.tooltip;
 408                                         while(getWrappedLine_remaining)
 409                                         {
 410                                                 s = getWrappedLine(SKINWIDTH_TOOLTIP / fontsize_x, draw_TextWidth_WithoutColors);
 411                                                 ++i;
 412                                                 f = draw_TextWidth(s, FALSE);
 413                                                 if(f > w)
 414                                                         w = f;
 415                                         }
 416                                         menuTooltipSize_x = w * fontsize_x + 2 * (SKINMARGIN_TOOLTIP_x / conwidth);
 417                                         menuTooltipSize_y = i * fontsize_y + 2 * (SKINMARGIN_TOOLTIP_y / conheight);
 418                                         menuTooltipSize_z = 0;
 419                                 }
 420                                 break;
 421                         case 1:
 422                                 // changing item while fading in: fade out first
 423                                 menuTooltipState = 2;
 424                                 break;
 425                         case 2:
 426                                 // changing item while fading out: can't
 427                                 break;
 428                 }
 429         }
 430         else if(menuTooltipState == 2) // re-fade in?
 431                 menuTooltipState = 1;
 432
 433         if(menuTooltipItem)
 434                 if(!m_testmousetooltipbox(pos))
 435                         menuTooltipState = 2; // fade out if mouse touches it
 436
 437         switch(menuTooltipState)
 438         {
 439                 case 1:
 440                         menuTooltipAlpha = bound(0, menuTooltipAlpha + 5 * frametime, 1);
 441                         if(menuTooltipAlpha == 1)
 442                                 menuTooltipState = 0;
 443                         break;
 444                 case 2:
 445                         menuTooltipAlpha = bound(0, menuTooltipAlpha - 2 * frametime, 1);
 446                         if(menuTooltipAlpha == 0)
 447                         {
 448                                 menuTooltipState = 0;
 449                                 menuTooltipItem = world;
 450                         }
 451                         break;
 452         }
 453
 454         if(menuTooltipItem)
 455         {
 456                 if(menuTooltipOrigin_x < 0) // unallocated?
 457                         m_allocatetooltipbox(pos);
 458
 459                 if(menuTooltipOrigin_x >= 0)
 460                 {
 461                         // draw the tooltip!
 462                         p = SKINBORDER_TOOLTIP;
 463                         p_x *= 1 / conwidth;
 464                         p_y *= 1 / conheight;
 465                         draw_BorderPicture(menuTooltipOrigin, SKINGFX_TOOLTIP, menuTooltipSize, '1 1 1', menuTooltipAlpha, p);
 466                         p = menuTooltipOrigin;
 467                         p_x += SKINMARGIN_TOOLTIP_x / conwidth;
 468                         p_y += SKINMARGIN_TOOLTIP_y / conheight;
 469                         getWrappedLine_remaining = menuTooltipItem.tooltip;
 470                         while(getWrappedLine_remaining)
 471                         {
 472                                 s = getWrappedLine(SKINWIDTH_TOOLTIP / fontsize_x, draw_TextWidth_WithoutColors);
 473                                 draw_Text(p, s, fontsize, '1 1 1', SKINALPHA_TOOLTIP * menuTooltipAlpha, FALSE);
 474                                 p_y += fontsize_y;
 475                         }
 476                 }
 477         }
 478 }
 479
 480 void() m_draw =
 481 {
 482         float t;
 483         float realFrametime;
 484
 485         menuMouseMode = cvar("menu_mouse_absolute");
 486
 487         if(main)
 488                 UpdateConWidthHeight();
 489
 490         if(!menuInitialized)
 491         {
 492                 // TODO draw an info image about this situation
 493                 m_init_delayed();
 494                 return;
 495         }
 496         if(!menuNotTheFirstFrame)
 497         {
 498                 menuNotTheFirstFrame = 1;
 499                 if(Menu_Active)
 500                 if(!cvar("menu_video_played"))
 501                 {
 502                         localcmd("set menu_video_played 1; cd loop $menu_cdtrack; play sound/announcer/male/welcome.ogg\n");
 503                         menuLogoAlpha = -0.8; // no idea why, but when I start this at zero, it jumps instead of fading
 504                 }
 505         }
 506
 507         t = gettime();
 508         realFrametime = frametime = min(0.2, t - menuPrevTime);
 509         menuPrevTime = t;
 510         time += frametime;
 511
 512         t = cvar("menu_slowmo");
 513         if(t)
 514         {
 515                 frametime *= t;
 516                 realFrametime *= t;
 517         }
 518         else
 519                 t = 1;
 520
 521         if(Menu_Active)
 522         {
 523                 if(getmousetarget() == (menuMouseMode ? MT_CLIENT : MT_MENU) && (getkeydest() == KEY_MENU || getkeydest() == KEY_MENU_GRABBED))
 524                         setkeydest(keyGrabber ? KEY_MENU_GRABBED : KEY_MENU);
 525                 else
 526                         m_hide();
 527         }
 528
 529         if(cvar("cl_capturevideo"))
 530                 frametime = t / cvar("cl_capturevideo_fps"); // make capturevideo work smoothly
 531
 532         dprint_load();
 533         gamestatus = 0;
 534         if(isserver())
 535                 gamestatus = gamestatus | GAME_ISSERVER;
 536         if(clientstate() == CS_CONNECTED)
 537                 gamestatus = gamestatus | GAME_CONNECTED;
 538         if(cvar("developer"))
 539                 gamestatus = gamestatus | GAME_DEVELOPER;
 540
 541         prevMenuAlpha = menuAlpha;
 542         if(Menu_Active)
 543         {
 544                 if(menuAlpha == 0 && menuLogoAlpha < 2)
 545                 {
 546                         menuLogoAlpha = menuLogoAlpha + frametime * 2;
 547                 }
 548                 else
 549                 {
 550                         menuAlpha = min(1, menuAlpha + frametime * 5);
 551                         menuLogoAlpha = 2;
 552                 }
 553         }
 554         else
 555         {
 556                 menuAlpha = max(0, menuAlpha - frametime * 5);
 557                 menuLogoAlpha = 2;
 558         }
 559
 560         draw_reset();
 561
 562         if(!(gamestatus & (GAME_CONNECTED | GAME_ISSERVER)))
 563         {
 564                 if(menuLogoAlpha > 0)
 565                 {
 566                         drawBackground(SKINGFX_BACKGROUND, bound(0, menuLogoAlpha, 1), SKINALIGN_BACKGROUND);
 567                         if(menuAlpha <= 0 && SKINALPHA_CURSOR_INTRO > 0)
 568                         {
 569                                 draw_alpha = SKINALPHA_CURSOR_INTRO * bound(0, menuLogoAlpha, 1);
 570                                 draw_drawMousePointer(menuMousePos);
 571                                 draw_alpha = 1;
 572                         }
 573                 }
 574         }
 575         else if(SKINALPHA_BACKGROUND_INGAME)
 576         {
 577                 if(menuAlpha > 0)
 578                         drawBackground(SKINGFX_BACKGROUND_INGAME, menuAlpha * SKINALPHA_BACKGROUND_INGAME, SKINALIGN_BACKGROUND_INGAME);
 579         }
 580
 581         draw_reset();
 582         preMenuDraw();
 583         draw_reset();
 584
 585         if(menuAlpha <= 0)
 586         {
 587                 if(prevMenuAlpha > 0)
 588                         main.initializeDialog(main, main.firstChild);
 589                 draw_reset();
 590                 postMenuDraw();
 591                 return;
 592         }
 593
 594         draw_alpha *= menuAlpha;
 595
 596         if(menuMouseMode)
 597         {
 598                 vector newMouse;
 599                 newMouse = globalToBoxSize(getmousepos(), draw_scale);
 600                 if(newMouse != '0 0 0')
 601                         if(newMouse != menuMousePos)
 602                         {
 603                                 menuMousePos = newMouse;
 604                                 if(mouseButtonsPressed)
 605                                         main.mouseDrag(main, menuMousePos);
 606                                 else
 607                                         main.mouseMove(main, menuMousePos);
 608                         }
 609         }
 610         else
 611         {
 612                 if(frametime > 0)
 613                 {
 614                         vector dMouse;
 615                         dMouse = getmousepos() * (frametime / realFrametime); // for capturevideo
 616                         if(dMouse != '0 0 0')
 617                         {
 618                                 dMouse = globalToBoxSize(dMouse, draw_scale);
 619                                 menuMousePos += dMouse * cvar("menu_mouse_speed");
 620                                 menuMousePos_x = bound(0, menuMousePos_x, 1);
 621                                 menuMousePos_y = bound(0, menuMousePos_y, 1);
 622                                 if(mouseButtonsPressed)
 623                                         main.mouseDrag(main, menuMousePos);
 624                                 else
 625                                         main.mouseMove(main, menuMousePos);
 626                         }
 627                 }
 628         }
 629         main.draw(main);
 630
 631         m_tooltip(menuMousePos);
 632
 633         draw_alpha = max(draw_alpha, SKINALPHA_CURSOR_INTRO * bound(0, menuLogoAlpha, 1));
 634
 635         draw_drawMousePointer(menuMousePos);
 636
 637         draw_reset();
 638         postMenuDraw();
 639
 640         frametime = 0;
 641 };
 642
 643 void() m_display =
 644 {
 645         Menu_Active = true;
 646         setkeydest(KEY_MENU);
 647         setmousetarget((menuMouseMode ? MT_CLIENT : MT_MENU));
 648
 649         if(!menuInitialized)
 650                 return;
 651
 652         if(mouseButtonsPressed)
 653                 main.mouseRelease(main, menuMousePos);
 654         mouseButtonsPressed = 0;
 655
 656         main.focusEnter(main);
 657         main.showNotify(main);
 658 };
 659
 660 void() m_hide =
 661 {
 662         Menu_Active = false;
 663         setkeydest(KEY_GAME);
 664         setmousetarget(MT_CLIENT);
 665
 666         if(!menuInitialized)
 667                 return;
 668
 669         main.focusLeave(main);
 670         main.hideNotify(main);
 671 };
 672
 673 void() m_toggle =
 674 {
 675         if(Menu_Active)
 676                 m_hide();
 677         else
 678                 m_display();
 679 };
 680
 681 void() m_shutdown =
 682 {
 683         entity e;
 684
 685         m_hide();
 686         for(e = NULL; (e = nextent(e)) != NULL; )
 687         {
 688                 if(e.destroy)
 689                         e.destroy(e);
 690         }
 691 };
 692
 693 void m_focus_item_chain(entity outermost, entity innermost)
 694 {
 695         if(innermost.parent != outermost)
 696                 m_focus_item_chain(outermost, innermost.parent);
 697         innermost.parent.setFocus(innermost.parent, innermost);
 698 }
 699
 700 void m_activate_window(entity wnd)
 701 {
 702         entity par;
 703         par = wnd.parent;
 704         if(par)
 705                 m_activate_window(par);
 706
 707         if(par.instanceOfModalController)
 708         {
 709                 if(wnd.tabSelectingButton)
 710                         // tabs
 711                         TabButton_Click(wnd.tabSelectingButton, wnd);
 712                 else
 713                         // root
 714                         par.initializeDialog(par, wnd);
 715         }
 716         else if(par.instanceOfNexposee)
 717         {
 718                 // nexposee (sorry for violating abstraction here)
 719                 par.selectedChild = wnd;
 720                 par.animationState = 1;
 721                 setFocusContainer(par, NULL);
 722         }
 723         else if(par.instanceOfContainer)
 724         {
 725                 // other containers
 726                 if(par.focused)
 727                         par.setFocus(par, wnd);
 728         }
 729 }
 730
 731 void m_setpointerfocus(entity wnd)
 732 {
 733         if(wnd.instanceOfContainer)
 734         {
 735                 entity focus = wnd.preferredFocusedGrandChild(wnd);
 736                 if(focus)
 737                 {
 738                         menuMousePos = focus.origin + 0.5 * focus.size;
 739                         menuMousePos_x *= 1 / conwidth;
 740                         menuMousePos_y *= 1 / conheight;
 741                         if(wnd.focused) // why does this never happen?
 742                                 m_focus_item_chain(wnd, focus);
 743                 }
 744         }
 745 }
 746
 747 void(string itemname) m_goto =
 748 {
 749         entity e;
 750         if(!menuInitialized)
 751                 return;
 752         if(itemname == "") // this can be called by GameCommand
 753         {
 754                 if(gamestatus & (GAME_ISSERVER | GAME_CONNECTED))
 755                         m_hide();
 756                 else
 757                 {
 758                         m_activate_window(main.mainNexposee);
 759                         m_display();
 760                 }
 761         }
 762         else
 763         {
 764                 e = findstring(NULL, name, itemname);
 765                 if(e)
 766                 {
 767                         m_hide();
 768                         m_activate_window(e);
 769                         m_setpointerfocus(e);
 770                         m_display();
 771                 }
 772         }
 773 }
 774
 775 void() m_goto_skin_selector =
 776 {
 777         if(!menuInitialized)
 778                 return;
 779         // TODO add code to switch back to the skin selector (no idea how to do it now)
 780         m_goto("skinselector");
 781 }